[i]July 4th[/i]

*if (a >= 6)
  *if (((yr1_01_16_20 = 2) or (yr1_04_15_20 = 1)) or (yr1_06_14_20_1 = 2))
    *set yr1_07_04_20_a true
*if (a >= 5)
  *if ((yr1_01_16_20 = 2) and (yr1_04_15_20 = 1))
    *set yr1_07_04_20_a true
  *if ((yr1_01_16_20 = 2) and (yr1_06_14_20_1 = 2))
    *set yr1_07_04_20_a true
  *if ((yr1_04_15_20 = 1) and (yr1_06_14_20_1 = 2))
    *set yr1_07_04_20_a true
*if (a >= 4)
  *if (((yr1_01_16_20 = 2) and (yr1_04_15_20 = 1)) and (yr1_06_14_20_1 = 2))
    *set yr1_07_04_20_a true

You 
*if (yr1_07_04_20_a = true)
  and Alex
make your way along the side street.
Cozy houses with thatched roofs line your path, and children with flushed faces and bubbling laughter dart around the stone fence in a game of tag.
Fanning yourself with your hand, you try to duck out of the way of the overbearing summer sun.
Every so often you step into the shade of a sympathetic tree but never long enough to feel any relief.

*if (yr1_07_04_20_a = true)
  "Lord, it's hot," Alex observes.

  "You don't say," you drawl.

  "Shut up.
  My brain cells are fried."

  "Think we could fry an egg on the pavement?"

  "Why, planning to make a don't-do-drugs-PSA?"

  "[i]No[/i]," you wheedle, "a horror movie.
  Obviously."

  "If it wasn't too hot to move, I'd smack you," ${a_they} answers.

When
*if (yr1_07_04_20_a = true)
  the two of
you get closer to the river bank, the wind picks up enough to tease you.
The sweat rolling down your neck doesn't respond.
*if (yr1_07_04_20_a = true)

  "Jesus.
  Why didn't we take the truck?
  I'm melting out here."

  You sigh.
  "You oughta feel right at home then.
  It's over a hundred in Valley Creek this weekend.
  They're not even setting fireworks off tonight because of the fire hazard."

  Alex makes a strangled noise in response, and you're too focused on your own discomfort to inquire further.

  "There it is," you announce with a groan.

*if (yr1_06_14_20_2 = 4)
  Sebastian's bright red door
*else
  A smart row of town houses 
comes into view.

*if (yr1_07_04_20_a = true)
  "Thank God," Alex huffs as you near the entrance.

Freeing your dominant hand, you reach out for the knocker, and within seconds, Daisy is ushering you into the sweet, sweet air conditioning.

*page_break

The living room that you step into leads directly into a well-lit dining room.
A built-in china hutch divides the two spaces and displays a selection of Blue Italian dishware.
Large pieces of furniture, including a chintz armchair whose lumpy cushions attest to its favored status, crowd the narrow room, and you weave around them as Daisy leads you to the kitchen.

Setting the jar of pickles you've been carrying on the tile counter, you explain to Daisy, "These are some of our first pickles."

"Oh!
Are we the guinea pigs?"
Her dark eyes sparkle with laughter.

"Yep,"
*if (yr1_07_04_20_a = true)
  Alex says
*else
  you say
with a laugh.
"Gotta test them out on someone before we release them into the wild."

Daisy bats her eyelashes at you.
"Well I for one am honored."

"Also brought tomatoes!" 
*if (yr1_07_04_20_a = true)
  you add.

"At this rate, you're going to spoil us rotten."

The patio door slides open and Sebastian steps inside in all his paternal glory.
Wearing an apron that reads [i]Kiss the cook![/i] and holding a spatula in his hand, he flashes you a wide smile.

The glass door opens again, and
*if ((yr1_03_14_20_2 = 2) or (yr1_06_14_20_2 = 4))
  Eddie rushes in behind his dad,
*else
  Sebastian's mini-me appears behind the couple,
leaving the door open behind him.

"Something tells me the kids won't agree."

"Well nobody asked them!" Daisy says before leaning in to kiss her husband's cheek.

"Nobody asked us what?" Eddie demands.

"To eat fresh vegetables."

The boy wrinkles his nose at the suggestion and bolts back out the door before anyone can try to ply him with greens.
Daisy rolls her eyes and closes the door.
"These-kids-are-always-leaving-the-door-open," she complains under her breath.
*set num 0
*if ((yr1_03_14_20_2 != 2) and (yr1_06_14_20_2 != 4))
  *set num 1
*if ((num = 1) or (yr1_07_04_20_a = true))
  Turning to
  *if (yr1_07_04_20_a = true)
    Alex, 
  *else
    you,
  she adds, "That was Eddie, by the way."

  "A pleasure, I'm sure."

Sebastian laughs.
"Come on!
Lets get 
*if (yr1_07_04_20_a = true)
  the two of
you barbecuing!"
He shuffles you out of the air conditioning and into the heat.

*page_break

The grill stands close to the back door on a stone patio, enabling you to find some respite in the shadow cast by the house.
*if (yr1_06_14_20_2 != 4)
  Shapely topiaries, browning in the the summer sun, punctuate the enclosed garden, pebble pathways looping around them and the nearby flower beds.

*if ((yr1_03_14_20_2 = 2) or (yr1_06_14_20_2 = 4))
  Summer
*else
  A girl
bursts out of the shrubbery with a shriek.
The cause of her alarm quickly becomes apparent when Eddie follows suit, a water gun in his hands.

"Summer!" Sebastian calls.
"Come say hello to ${name} and Alex."

"Pause!" she shouts at her brother, eying him suspiciously.
She marches up to you.
*if ((yr1_07_04_20_a = true) or (num = 1))

  "This is Summer," Sebastian says to
  *if (num != 1)
    Alex.

    "Nice water gun," Alex says to the two of them.

    "Thanks!" Eddie beams.

  *else
    you.
 
    *fake_choice
      #"It's nice to meet you," I say.
      #"Hi," I say.

    Eddie runs up to join your little group.
    "$!{theyre} the one with the castle," he whispers excitedly to his sister.

    "Hi," she says.
  "Can we go now?"

  Sebastian sighs.
  "Yes—

  Summer skids away, Eddie at her heels, spraying water at her with abandon.

  "—but don't get any water on grill," Sebastian finishes in a mutter.
*else
  "Hi," she says.

  Before you can return the greeting, she's on the run again, Eddie at her heels.

  Sebastian smiles at you.
  "Kids."

The glass door slides open again, and Daisy emerges with a bundle in her arms.
"The last guest has joined the party."

*if ((yr1_07_04_20_a = true) or (num = 1))
  "And who's this?"
  *if (yr1_07_04_20_a = true)
    Alex asks with a grin for the baby.
  *else
    you ask.

  "This lovely lady is Margot," she says.

  Margot looks
  *if (yr1_07_04_20_a = true)
    between you and Alex
  *else
    at you
  with curiosity before
  *if (yr1_07_04_20_a = true)
    reaching out to your best friend.

    "She likes you," Daisy says with a smile that your friend returns, opening ${a_their} arms for the baby.
    Daisy releases her burden to Alex in one deft motion.

    "And I like babies."
    Alex bounces Margot on ${a_their} hip like a natural.
    
    *if (a_rom >= 2)
      It's something like a premonition, watching Alex make faces at a giggling baby.
  *else
    settling back into her mother's arms.
*else
  "Hi there, Margot," you say with a smile for the baby.

  She cocks her head at you and watches.

"We just woke up from a nap," Daisy explains.
*if (yr1_07_04_20_a = false)
  She and Margot settle onto 
*else
  She leads Alex over to
a quilt spread out under 
*if (yr1_07_04_20_a = false)
  a shady tree.
  She and Margot exchange nonsensical chatter with each other
  
*else
  a tree and helps them settle into the shade before joining them.
  The two adults chat with each other with Margot's occasional contribution by way of nonsensical babble.
  
Sebastian draws your attention back to himself.
Gesturing to the grill with his spatula, he asks, "So what'll you have today?"

*fake_choice
  #"How about a burger?"
    *set var "burger"
  #"How about a hotdog?"
    *set var "hotdog"
  #"How about a kebab?"
    *set var "kebab"

"How about a ${var}?" you ask.

A smile alights on Sebastian's face.
"Great choice!"
Mr. Kiss-the-Cook
*if (var = "burger")
  flips another uncooked patty 
*elseif (var = "hotdog")
  flings a few hotdogs
*elseif (var = "kebab")
  thrusts a handful of wooden skewers into your hands and 
*else
  *bug
*if (var != "kebab")
  onto the hot grill with a satisfying sizzle.
  Then he turns and
guides you to a buffet of 
*if (var = "kebab")
  ingredients: chicken, tofu, pork; a rainbow of vegetables; and several attractive glazes.
*else
  toppings and condiments.

"Build your own," he invites, "use whatever you like and however much you want."
  
*if ((s >= 2) and (num != 1))
  *set yr1_07_04_20_1 true
  Your eyes rake over the collection of jars and bottles.
  Ketchup, mustard, relish—even a jar of chow chow?!
  Most of them are new, unopened, including the jar of pickles that you brought with you.

  "Did you get all of this just for today?"

  Sebastian's ears flush red, and a crooked grin tugs at his mouth.
  "Well—yes."
  Rubbing the back of his neck, he adds, "We wanted you to feel at home, you know, as much as you could from a few thousand miles away."

  "How did you find the chow chow?" you ask, more than a little awed.

  He chuckles.
  "We had to special order that."

  *set boo true
  *fake_choice
    #"Thanks, Sebastian," I say.
      *set awk %- 5
      *set s +1
      You look up from the motley bottles and meet the flustered mayor's eyes.
      "Thanks, Sebastian."

      His unease evaporates in an instant, his crooked grin replaced with a self-assured smile.
    #Is there something in my eye?
      *set awk %+ 5
      *set gen %+ 5
      *set org %- 5
      *set s +1
      You feel unshed tears collect on the edge of your eyelid and blink them back before they can spill over.
      Sebastian's eyes grow wide, and he steps forward, pulling you into a hug.
      Sniffing as unobtrusively as possible, you mumble into his shoulder, "That was really nice of you."

      Sebastian's hug tightens for a moment before he lets go.
    #I go for the hug.
      *set cha %+ 5
      *set dir %+ 5
      *set gen %+ 5
      *set s +1
      A look of surprise overtakes Sebastian's face, replacing the uncertain grin, as you step forward and pull him
      *if (s_taller = true)
        down
      into a hug.  
      He laughs, squeezing you tight for a moment before you let go.
    #"You didn't have to go to all that trouble," I say
      *set cha %- 5
      *set gen %- 5
      *set per %- 5
      *set yie %- 5
      *set boo false
      A frown tugging at the corner of your mouth, you say, "You didn't have to go to all that trouble."

      Sebastian's grin falters, and he lets out a nervous chuckle.
      "It wasn't any trouble—it was a pleasure."

      You tug at your ${tic}.
      "Well thanks.
      I appreciate it."
  *if (boo = true)
    "You're welcome, ${name}!"
    Picking up the jar of chow chow, he continues, "Is this any good?"

    "If you like relish or pickles, then yeah.
    If you don't, probably not for you."
*else
  "Thanks," you say as you sort through the collection, picking out what you want.

Sebastian nods, turning back to the grill when the grease of an overzealous burger pops at him.
*if (var = "kebab")
  Once you've constructed your kebabs, you hand the skewers over to Sebastian, and he finds an open space for them on the hot grill.
There's barely room for all the food crackling in the heat.
Your stomach rumbles in anticipation, and you can only regret that Sebastian's cooking with gas instead of charcoal.

*page_break A bit later...

"Order up!" Sebastian calls out to
*if (yr1_07_04_20_a = true)
  his family and guests
*else
  you and his family.

Eddie abandons his watergun with gusto, grabbing Summer by her wrist and dragging her back to the patio.
*if (yr1_07_04_20_a = true)
  Alex and Daisy, slower in their old age, come next with Margot.
*else
  Daisy and Margot appear next.

"Pass out the plates?" 
*if (yr1_07_04_20_a = true)
  Daisy
*else
  she 
asks Eddie, though it's less suggestion and more command.
Eager to please, he obeys, and a struggle to separate the paper plates from each other ensues.
He won't accept his mothers help, however.

"Here!" he says, shoving one of plates toward you.
He flits off to 
*if (yr1_07_04_20_a = true)
  Alex
*else
  his sister
as soon as it touches your fingers.

"I think Eddie's ready to eat," Sebastian says.
"Ready Eddie!"

The boy wrinkles his nose at the moniker.

With plates in hand, the 
*if (yr1_07_04_20_a = true)
  six
*else
  five
of you line up, and Sebastian distributes burgers, dogs, and babs aplenty before Daisy leads your little group to an outdoor table.

Eddie grabs a seat next to you.
*if (yr1_03_14_20_2 = 2)
  "Have you caught the ghost yet?"
*else
  "Is Darbury [i]really[/i] haunted?"
he asks you just as you take a bite of your ${var}.
*if (yr1_03_14_20_2 != 2)
  By his wide, intent eyes, he seems more excited than scared.
*else
  He watches you with intent eyes and a wide grin.

*if (yr1_07_04_20_a = true)
  "What's this about a ghost?" Alex asks with a sly smile in your direction.

  "You oughta remember," you drawl,
  *if (yr1_01_03_20 = 1)
    "you made me get up to look for it 
  *elseif (yr1_01_03_20 = 2)
    "you went lookin' for it
  *elseif (yr1_01_03_20 = 3)
    "it came lookin' for us
  *else
    *bug
  in the middle of the night."

  *if (yr1_01_03_20 = 1)
    "The way I remember it," ${a_they} counters, "is [i]you[/i] volunteered!"

    "Yeah, well, I didn't know I had volunteered for a broken nose!"
  *elseif (yr1_01_03_20 = 2)
    "Yeah, well, [i]someone[/i] had to," ${a_they} retorts.

    "Did someone also have to break my nose?!"
  *else
    "Maybe if you had gone after [i]it[/i] like I asked it wouldn't've come after [i]us[/i]."

    "Yeah, and maybe it wouldn't have broken my nose," you retort with a glare.
    
  "It wasn't broken!" ${a_they} equivocates with a high-pitched voice.
  "It was just a nosebleed."

  "[i]Just[/i]?!"

  "You [i]fought[/i] the ghost?!" Eddie breaks in.
  "So it really [i]is[/i] haunted!"

  You and Alex exchange an amused glance.
*else
  You set your ${var} back down.
  Thinking back to your first night in the castle, you suppress a laugh.

"Well, there's definitely [i]something[/i] lurking in the halls.
Or there was anyway.
*if ((a_rom = 0) and (yr1_07_04_20_a = true))
  Until Alex scared it away with ${a_their} ugly face."
  
  $!{a_they} sticks ${a_their} tongue out at you to punctuate the point.

*else
  *if (yr1_01_03_20 = 1)
    But I scared it away."
  *elseif (yr1_01_03_20 = 2)
    But 
    *if (yr1_07_04_20_a = true)
      my friend
    Alex scared it away."
  *else
    But we scared it away."

"Oh," Eddie says, disappointed.

*if (yr1_07_04_20_a = true)
  "Well, [i]maybe[/i] it's still around," Alex says.
  "It's hard to tell with all the noise nowadays."
*else
  "It could still be there hiding somewhere, couldn't it?" Sebastian suggests uncertainly.

"You [i]really[/i] think so?"
*if (yr1_07_04_20_a = false)
  Eddie asks, oblivious to the censorious glare that Daisy directs toward her husband.

You shrug, pulling Eddie's attention back to you.
    
*fake_choice
  #"What makes you interested in the ghost?" I ask.
    *set awk %- 5
    *set dir %- 5
    *set per %- 5
    You look down at your table-mate.
    "What makes you interested in the ghost?"

    His eyes light up.
    "Think about how much he knows!"

    "What makes you think the ghost is a 'he?'" Sebastian prompts.

    Eddie's eyes screw up as he thinks about it.
    But before he can formulate a satisfactory answer, his sister interrupts.
  *if (yr1_07_04_20_a = true)
    #"It wouldn't dare mess with the pair of us," I say, gesturing toward Alex.
      *label scary
      *set cha %- 5
      *set hum %- 5
      *if (yr1_07_04_20_a = true)
        You nod your head toward Alex.
        "It wouldn't dare mess with the pair of us."
  
        Eddie looks over at your best friend, who flexes ${a_their} arms like a strongman.
        "I'll protect you from the ghost, ${nickname}."        

        You snicker.
        "Yeah, you did a real good job of that last time."

        $!{a_they} rolls ${a_their} eyes at you.        
      *else
        You scoff theatrically.
        "It wouldn't dare mess with me and Alex."

        Summer giggles at your bravado.

        "Is it a mean ghost?" Eddie asks.
  *else
    #"It wouldn't dare mess with me and Alex," I say.
      *goto scary
  #"You never can tell," I agree.
    *set dir %- 5
    *set yie %+ 5
    You cock your head to the side in feigned consideration of the philosophical proposition before you.
    With another shrug of your shoulders, you say, "You never can tell."

    Eddie answers with a bright grin.
  #"I think the ghost is gone," I say with a sympathetic smile.
    *set dir %+ 5
    *set yie %- 5  
    You smile at Eddie and answer in a low, soothing voice.
    "I think the ghost is gone."

    Eddie's shoulders droop, and
    *if (yr1_07_04_20_a = true)
      Alex glares at you from across the table.

      You shrug at ${a_them}.
      He'd find out eventually.
    *else
      Sebastian rubs his hand over Eddie's back.
      
"Ghosts are boring," Summer complains.
"Are there any fairies?"

"Fairies aren't real!" Eddie retorts.

"Are too!"

"Are not!"

"Are too!"

"All this ghost talk is making me hungry," Daisy says in a loud voice, effectively closing the topic of discussion.

You won't complain: you're ready to take a bite of your ${var}.
Finally.

The
*if (yr1_07_04_20_a = true)
  seven
*else
  six
of you dig into your 4th-of-July supper, casual chatter taking the place of Eddie's excitable interrogation about the ghost.
Even Margot takes her turn, delightfully squealing "Bird!" when a robin lands on a nearby branch.

*page_break But all good things come to an end.

By the time you finish all the food on your plate, Eddie and Summer have run off into the garden again, and Margot has fallen asleep on the quilt.
Only the adults remain at the table, chatting and joking.

[i]Adult[/i]. 
Six months ago, sitting at the adult table with your family, you felt like you didn't belong.
Like you had to justify sitting there.
The label fits better now, like a pair of shoes you've grown into.

You smile.

"I'm stuffed," Sebastian declares, leaning back in his chair and clasping his hands over his swollen belly.

Daisy pats it affectionately.
"You did a good job, Seb."

*if (yr1_07_04_20_a = true)
  "Definitely," Alex agrees.
  "Thank you for inviting us."

  Sebastian swats the thanks away, but his grin betrays his pleasure.

"This is what my mamaw and papaw would call 'good eatin,'" you add.

*if (yr1_07_04_20_a = true)
  Sebastian's grin grows even larger.
*else
  Sebastian grins.
"It was our pleasure to have you."

"And many returns!" Daisy says.

*page_break POP-POP-POP!

The loud popping startles you from your food coma.

Eddie comes barging out of the garden.
Summer follows, pelting him with... rocks?

POP-POP-POP!

"Looks like they've gotten into the fun snaps," Daisy says.

*if (yr1_07_04_20_a = true)
  Alex smiles.
*else
  You smile.
"They call 'em bang snaps back home."

*if (yr1_07_04_20_a = true)
  Summer grabs Alex by the wrist and drags ${a_them} away from the table.
  "I guess I've been drafted," ${a_they} calls over ${a_their} shoulder with a laugh.

Daisy shakes her head and chuckles as she begins to clear the table.

"Do you wanna play, ${name}?" Eddie asks.

Sebastian smiles at you and nods his head toward the waiting guerrillas.

*fake_choice
  #Play with the kids
    *set yr1_07_04_20_2 true
    *if (yr1_07_04_20_a = true)
      *set a +1
  #Help the adults clean up.
    *set yr1_07_04_20_3 true
    *set s + 1

*if (yr1_07_04_20_2 = true)
  You grin at Eddie and open your palm to him.
  His face lights up, and he hands you a box of bang snaps.
  "This way, ${name}!"

  You climb out of the chair, feeling old in comparison to the spry, young 12-year-old, and follow him into the fray.

  *if (yr1_07_04_20_1 = true)
    "Alex is on my team!" Summer calls out.

    "Fine," Eddie says with an attitude, "I want ${name} on my team anyway!"

    "Well I guess that settles that," you say to your best friend.

    $!{a_they} smirks at you.
    "May the best team win."

    You nudge Eddie's shoulder.
    "That'll be us, right kid?"

    "Definitely!"

    With the arrangement settled, the four of you take up your positions,
  *else
    "${name} is on [i]my[/i] team," Eddie says to his sister with a note of pride in his voice.
  
    "Hey!
    That's not fair!" she complains.
    
    "Is too, ${theyre} [i]my[/i] friend.
    Right, ${name}?"

    Summer saves you from having to answer with further protest.
    "Both of you are bigger than me.
    ${name} should be on [i]my[/i] team!"

    They both turn to you.

    Out of the frying pan and into the fire.

    You clear your throat.
    *if ((((((awk <= 44) or (cha >= 56)) or (gen >= 56)) or (org <= 44)) or (per <= 44)) or (yie <= 44))
      "Why don't the two of you team up against me?"

      A trouble-making glint lights Summer's eyes, and you wonder if you'll regret your magnanimous suggestion.
    *else

      Daisy appears at your side like a ghost.
      "What seems to be the hold up?"

      "Eddie's being unfair!" Summer repeats at the same moment that Eddie says, "Summer's being a baby!"

      "Do I need to take the fun snaps away?"

      The kids answer as one.
      "NO!"

      "We can't decide on a fair arrangement," you explain to Daisy.

      "Oh, well that's easy enough!
      Summer, Eddie, the two of you will be on the same team."

      "But then ${name}'s all alone!" Eddie protests in your defense.

      Daisy shoots you an amused glance.
      "I think ${they} can handle ${them}self."

      With the conflict settled, Daisy returns to clean up duty, 
  and the battle begins.

  Summer's aim is accurate as she begins to pelt you with the bang snaps, and you let out a yelp of surprise in spite of yourself.
  Eddie, too bashful and inherently kind to really target
  *if (yr1_07_04_20_a = true)
    Alex and his sister,
  *else
    you,
  hangs back.

  Even as the sun goes down, it's not long before all this running around has you hot and sticky.
  The battle is over with no clear winner—though that doesn't stop Summer from declaring victory—by the time Daisy and Sebastian return to the garden.

  You pant and wipe the sweat from your forehead, and the 
  *if (yr1_07_04_20_a = true)
    four
  *else
    three
  of you make your way over to the patio.

*if (yr1_07_04_20_3 = true)
  "Thanks," you say to Eddie, "but I'm gonna help the grownups clean up."

  "Aw, you don't have to do that," Daisy says.
  "You're our guest today."

  You shake your head.
  "Cough it up to Southern manners."

  She smiles at you.
  "Well, I won't look a gift horse in the mouth."

  When Eddie begins to pout, Sebastian shoots him a dark look,
  *if (yr1_07_04_20_a = true)
    adding, "You already have Alex."
    Eddie thinks better of continuing to argue and
  *else
    and the kid 
  scampers back into the garden to rejoin the fray.

  *page_break

  You make quick work of most of the "dishes," gathering up the discarded paper plates and shoving them into a trash bag that Sebastian holds open for you.
  The actual dishes, a smattering of serving platters, cutting boards, and cookware, take more effort.
  Daisy stacks them with the strategy of an overworked waitress, and Sebastian carries them into the kitchen.

  The good news is that there aren't many of them.
  The bad news is that they won't fit in the dishwasher.

  You take your position on the left side of a double sink and begin to scrub.
  Sebastian, to your right, rinses it, and hands it off to Daisy to dry and put away in the cabinets behind you.
  The work develops a rhythm: a running faucet, splashing water, the creak of a cabinet as it opens.
  For a long time, those are the only noises that punctuate your time in the kitchen.

  *if (b_rom >= 3)
    *set yr1_07_04_20_3_1 1
    "I've noticed that the renovation isn't the only thing that Bertie's building at Darbury."
  *elseif ((yr1_04_08_20_i != 0) and (g_rom >= 5))
    *set yr1_07_04_20_3_1 2
    "$!{g_they}'s worth getting to know."
  *elseif ((yr1_04_08_20_i = 0) and (g_rom >= 3))
    *set yr1_07_04_20_3_1 2
    "I hope you don't give up on ${g_them}."
  *elseif (r_rom >= 3)
    *set yr1_07_04_20_3_1 3
    "I hope you know what you're getting yourself into with ${r_them}."
  *elseif (t_rom >= 2)
    *set yr1_07_04_20_3_1 4
    "If you're not sure about ${t_them}, you should back out before the kid is involved."
  *elseif ((a_rom >= 3) and (yr1_07_04_20_a = true))
    *set yr1_07_04_20_3_1 5
    "You're in love with ${a_them}, aren't you?"
  *else
    *set yr1_07_04_20_3_1 6
    "Was this an authentic Independence Day?"

  You drop a fork at the sudden sound of Sebastian's voice, and it plops into the water with a splash.

  *if (yr1_07_04_20_3_1 = 1)
    The observation is casual, nonchalant, but there's a spark of interest in Sebastian's eyes when you look into them.
  
    You breathe in.
    "What do you mean?"

    "Bertie's looking to build more than a house.
    $!{b_they} wants to build a home, a family."
  *elseif (yr1_07_04_20_3_1 = 2)
    Your eyes snap to Sebastian.

    "$!{g_they}'s prickly, but ${g_they}'s worth the discomfort."

    "What are you talking about?"

    Sebastian turns to look at you.
    "${gabby} has had a lot of ups and downs.
    $!{g_they} doesn't trust quickly or easily."
  *elseif (yr1_07_04_20_3_1 = 3)
    You shift to look at Sebastian.

    "$!{r_they}'s young, but then again, so are you."
 
    You cock your head at him, a question in your eyes.

    "${rash} has a lot of growing up to do." 
  *elseif (yr1_07_04_20_3_1 = 4)
    You shake your head and blink back your surprise.

    "Know your mind before you go any further."

    "Any further?" you repeat with sideways glance at Sebastian.

    "It's not fair to Claudia, or to Tony either, to play at house if you're not ready to commit."
  *elseif (yr1_07_04_20_3_1 = 5)
    "Excuse me?" you hear yourself ask, like it's somebody else's voice spilling from your lips.

    "I see it in the way you look at ${a_them}."
    Sebastian's brown eyes are soft, warm; sad.

    You blink, slowly, your ears ringing.
    
    He squeezes your shoulder, and it's only when he says "oops" with a rueful grin that you feel the water seep into your shirt and trickle down your arm.
    He shakes his head.
    "It's not my place."

    Your hands are in the water, squeezing a rag so tightly it hurts.

    "But if you ever want to talk about it..."
  *else
    You bite your lip and look over at your dish-washing partner.
    "Authentic?" you repeat.

    He nods.
    "Is this how people really celebrate?"

    "Yeah, sometimes," you agree.
    "Fireworks are the big thing, but also cookouts and beach trips and all the stuff you do for summer.
    Red, white, and blue everywhere."        
    
    "Do you have a favorite holiday memory?"

  You open your mouth to answer, but Daisy speaks before you can.

  "Are you gossiping like an old biddy again?" 

  Sebastian starts, and this time he's the one who drops a fork.
  It clatters onto the floor.

  Daisy scoops it up, one hand on her hip, and points it at her husband.
  "For shame!
  Ruining all of ${name}'s hard work!"

  Sebastian makes a show of picking the fork up and washing it himself.
  He won't even let Daisy dry it to put away.
  
  You drain the water from the sink and shake your hands dry.
  Outside, you see
  *if (yr1_07_04_20_a = true)
    Alex and 
  the kids running around with their bang snaps.
  You can [i]just[/i] hear them popping as they explode.
  By the time the three of you return to the garden, the fun is over.

  You take a seat with Sebastian and Daisy on the patio, and the battle-weary warriors soon join you.

*page_break
  
The sun has sunk down over the horizon, leaving a hazy twilight in its wake.
Against the gray-purple sky, the first stars of the night appear like a splatter of white paint, dim in their eagerness to outshine the sun.
The world around you is a liminal space made up of blurs and silhouettes rather than real, tangible objects.

"You know what time it is," Daisy says to the group.

"Bed time?" Summer asks.
Her tone, accusatory and hostile, belies the large yawn that follows.

Daisy smiles.
"It's time for sparklers."

Eddie bounds off of the grass.
"I want one!"

Sebastian laughs quietly and distributes the sparklers.
The sun continues its rapid retreat, leaving barely enough light to see as Sebastian carefully ignites the small fireworks.
Eddie and Summer quickly run into the dark garden with their treasure.

He lights yours
*if (yr1_07_04_20_a = true)
  and Alex's
before lighting one for Daisy and finally himself.
"It's not quite the display you might find at home," Sebastian says with a sheepish smile, "but there will be bigger fireworks on Talverton Day."

"This is great."
*if (yr1_07_04_20_a = true)
  Alex says.
  "Really thoughful, kind."

  He beams at ${a_them}.
*else
  you say.

  Sebastian smiles.

You take a few steps beyond the patio and watch the sparks fly.

*page_break

Before you know it, you
*if (yr1_07_04_20_a = true)
  and Alex
are alone.
Or mostly alone.
Deeper in the garden you can see Eddie and Summer drawing with their flickering sparklers, but Sebastian and Daisy have disappeared.
*if (yr1_07_04_20_a = true)

  "What are you thinking about?" Alex asks.

  "Being a kid."

  $!{a_they} nods.
  "It's probably been ten years or more since I had a sparkler."

  "Me too," you agree.

  A thoughtful smile shimmers over ${a_their} face.
  You can just see it in the sparkler's wavering light.

  "Your turn," you say.

  "My turn?"

  "What are [i]you[/i] thinking about?"

  The cautious smile transforms into a bashful grin.
  "Oh, I just..."

  "You just what?"

  "I thought maybe that... maybe the next time we have sparklers it'll be with our own kids."

  *if ((a_feelings = false) and (per >= 56))
    You grin at ${a_them} and nudge ${a_them} in the ribs.
    "Have a 
    *if (a_gender = "f")
      groom
    *else
      bride
    in mind?" you tease.
    "Perhaps a certain school teacher?"

    "Shut up," ${a_they} says, but ${a_they} smiles and nudges you back.
    *if (b_rom >= 3)
      "The way you make googly eyes at Bertie, maybe we'll be
      *if ((gender = "f") and (a_gender = "f"))
        sisters
      *elseif ((gender = "m") and (a_gender = "m"))
        brothers
      *else
        siblings
      one of these days."

      You stick your tongue out at ${a_them}.
  *elseif (a_feelings = true)
    You plaster a smile to your face.
    You know it doesn't reach your eyes, but that doesn't matter in the dark.

    [i]Our kids[/i].
    $!{a_they} means your kids [i]and[/i] ${a_their} kids.
    Yours.
    But not [i]yours[/i].
    
    You feel like the Earth is sinking beneath you, like you're drowning and can't get enough breath.
    But [i]still[/i] you smile, and you say, "Maybe."
  *else
    "Maybe," you agree.
      
  "Enough of this future talk," Alex declares.
  "What should we draw with our sparklers?"

  Actions speak louder than words, so you set straight to work.
  *fake_choice
    #I draw a penis.
      *set gen %- 5
      You draw a large penis in the air in front of you, finishing the testicles with a flourish.
      Or at least you [i]almost[/i] finish them, but Alex throws you off balance when ${a_they} elbows you in the side.

      "What are you doing?" ${a_they} hisses.
      "There are kids around here—not to mention their parents!"

      You snicker.
      "They can't see us all the way over here."

      Alex is unconvinced if ${a_their} glare is any indication.

      "It's not like it's permanent!"

      Hand on hip, Alex rolls ${a_their} eyes at you.
      "Forget what I said about kids and sparklers.
      Clearly I can't bring my kids around you."

      You stick your tongue out, and a twitch breaks ${a_their} façade.

      "You think it's funny!" you crow.

      "Shhh!
      I refuse to explain to Eddie and Summer [i]what[/i] I think is funny when they coming running over here with all your yelling."

      "Fine," you concede.
      "What would you have me draw?"
    #I draw a flower.
      *set gen %+ 5
      You trace the outline of a flower in the air in front of you.
      Nothing fancy—a daisy maybe, in honor of your hostess.

      *goto very_original
    #I draw my name.
      *set org %+ 5
      You draw your name in the air in front of you like you're signing an autograph for Mother Earth.

      *label very_original
      "Very original," Alex comments tartly.

      You stick your tongue out at ${a_them}.
      "Well then you draw something
      *if (a_gender = "f")
        Miss
      *else
        Mister
      Fancy-Pants."
    *if (a_feelings = true)
      #I draw a heart. ♥
        *set a_rom +1
        You draw a heart in the night sky.
        It's not perfect—a little lumpen, misshapen.
        Like your own.

        *goto very_original

  You turn around to face your best friend to see what ${a_they}'ll draw.
  $!{a_their} movements are precise.
  $!{a_they} obviously has a picture in ${a_their} head, but what that picture is you haven't the faintest idea.
  To you, it's just a bunch of swishing.

  "What's that supposed to be?" you ask.
  Tact is a thing of the past in a friendship as old as yours, if it ever existed to begin with.

  Alex stomps ${a_their} foot like a toddler.
  "It's a white-breasted nuthatch."

  *if (a >= 6)
    "Your favorite bird?"

    "You remembered!"

    "I don't think anyone could forget a nuthatch."
  *else
    "A white-breasted nuthatch??"

    "My favorite bird, duh!"

    "And you made fun of [i]me[/i]!"

  Alex swats at you, but there's more affection than reprimand in the gesture.   

  Your conversation fades into a comfortable silence, and you turn your attention back to your sparkler.
*else
  You turn your attention to your sparkler, memories of your childhood rising to the surface with each flare.
The hiss of the burning sparkler fills the quiet.
It burns quickly, until you're left with only the chirping of the crickets.

*if (yr1_07_04_20_a = true)
  *achieve fourth

*finish