[i]May 30th[/i]

You sit on the tailgate of your truck with your legs dangling above the ground below.
Leaning against the beat-up wooden crates that sit in
*if (org >= 55)
  neat
*else
  off-kilter
stacks in the bed behind you, you'd almost be comfortable.
Almost.
But the May sun beats down on you, and you're beginning to feel sticky.
You glance over at the other vendors and envy the shade provided by their white vinyl tents.
It will only get worse as the day lingers on.

You've got an old white table set up in front of the truck, and a rainbow of vegetables overflows the clear plastic bins that seek to contain it.
Red beets, orange carrots, white cauliflower, green cucumbers.

A few early birds meander between the vendors.
You glance down at your phone: barely 8:00 AM.
The morning rush will begin soon and bring the shoppers with it.

*page_break
You settle into a routine.
Every few minutes a new person walks by your stand, and you
*if (awk >= 57)
  feel your palms start to sweat.
*elseif ((awk < 43) or (hum < 43))
  pull out your best smile and wait to make a sale.
*elseif ((awk < 57) and (hum > 43))
  hope simultaneously that they will and won't stop at your stand to buy something.
*else
  perk up, ready to engage.
But so far, no luck.

When you become bored, you begin to assign elaborate back-stories to everyone you see.
That man in the overalls selling the catch of the day is actually a spy with a tragic past.
He was a Colonel with the KGB who jumped ship when the Soviet Union went down back in '91.
He sold his secrets to the Brits, and they helped him create a new identity here in Eprea.
His daughter never made it out of Russia though, and he can never contact her.
She thinks he's dead, but he still sends her a postcard every year on her birthday.

And so the hours pass.

*page_break

*if (meet_g = true)
  It's hot, and you're thirsty, so you hop off the tailgate to get a bottle of water.
  You're rooting around in the cab of the truck looking for one when you hear someone walk up to the stand behind you.
  You shimmy out of the truck with your best customer-service smile, ready to make your first sale of the day.
  Your smile falters somewhat as you meet the familiar hazel eyes of the ${g_person} in front of you.

  $!{g_they} lets out a prissy little huff.
  "[i]You[/i].
  What are you doing here?"

  You look around at your little produce stand.
  *fake_choice
    #"I thought that'd be pretty obvious," I quip.
      *set cha %- 5
      You look around at your vegetables before glancing conspicuously at the other vendors.

      ${gabby} taps ${g_their} foot impatiently.
      "What are you doing?"

      "Looking around to make sure I'm still at the farmer's market."

      $!{g_they} motions at you to make your point.

      "I thought it would be pretty obvious."

      "What would be obvious??"

      "That I'm selling my produce!"

      $!{g_they} rolls ${g_their} eyes.
    #"Selling my produce."
      *set dir %+ 5
      "Selling my produce," you answer.
    #"What are [i]you[/i] doing here?"
      *set dir %- 5
      "What are [i]you[/i] doing here?"
    #"Brain surgery," I deadpan.
      *set gen %- 5
      You look ${gabby} in the eye and wait until the silence is almost awkward.
      "Brain surgery," you answer tonelessly.
      "Maybe you could use some."

  $!{g_they} shifts ${g_their} weight from one foot to the other and snatches a strawberry off your table for inspection.
  *if ((g > 1) or (g_rom > 1))
    *set yr1_05_30_20_g 3
    $!{g_they} reaches a hand out to you, and you answer with a raised eyebrow.

    "You want a high-five or what?"

    $!{g_they} huffs.
    "Your water bottle."

    "You could've just said that," you grumble as you hand it over.

    $!{g_they} pours a bit of water into one of ${g_their} palms and brushes the delicate strawberry with the thumb of ${g_their} free hand.
    $!{g_their} fingers are long and slender, the hands of a pianist, you muse.

    When ${g_they} pops the strawberry into ${g_their} mouth, ${g_they} looks back to you and grimaces.

  *else
    "Have you even washed these?" ${g_they} asks with a wrinkled nose.

    You shake your head in the negative.
    If you wasted all your time on washing produce that you're not even gonna use to make something, you wouldn't have time for anything else.

    $!{g_they} wrinkles ${g_their} nose even more.
    "How can you expect anyone to buy your produce when it's covered in dirt?"

    You blink at ${g_them} a few times.
    A quick glance toward your fellow vendors confirms that you are hardly the only one whose produce retains the evidence of its origin in the Earth.

    *fake_choice
      #Clean a strawberry for ${g_them}.
        *set g +1
        *set yr1_05_30_20_g 3
        You make a big show of opening your water bottle and pouring a bit of water into the palm of your hand.
        You brush away the unseen dirt and present the [i]clean[/i] strawberry to the fussy chef for inspection.

        $!{g_they} hesitates a moment before accepting the offering and popping it into ${g_their} mouth.
        Then ${g_they} grimaces.

      #Leave ${g_them} to ${g_their} own devices.
        *set yr1_05_30_20_g 2
        "Well?"

        "Well what?" ${g_they} asks, scrunching ${g_their} shoulders up.

        "What do you want from me?"

        $!{g_they} frowns, plucks a strawberry sitting on your table, and huffs away.

  *if (yr1_05_30_20_g = 3)
    You find yourself mimicking ${g_their} expression as a pit of worry knaws at your innards.

    *page_break

    "[i]Anybody[/i] can grow strawberries," ${g_they} announces with a dismissive wave.

    You bite back a retort.
    Is ${g_they} always so contrary?

    "How much?"

    "Excuse me?"

    $!{g_they} gesticulates at the strawberries.
    "How much??"

    Your eyes widen in surprise, and you relay your price.

    $!{g_they} slides a business card to you.
    Pink.
    Like the envelope you received when Ines invited you to tea.
    You suspect that if you smelled this card, it too would smell of roses.

    "Deliver here," ${g_they} says, tapping at the address on the card.

    [i]Delivery wasn't part of the deal![/i] you think to yourself, but you stop just short of refusing.
    Forging a business alliance with this curmudgeony chef would be very advantageous for you.
    Still, you don't have to take this lying down.

    *set num g_rom

    *fake_choice
      #"Sure thing," I agree.
        *set gen %+ 5
        *set yie %+ 5
        You nod.
        "Sure thing."

        "See you later then," ${g_they} says without so much as a glance in your direction.
      #"Whatever," I grumble.
        *set cha %- 5
        *set yie %- 5
        You hold in your sigh.
        "Whatever."

        $!{g_they} ignores your less than enthusiastic response.
        "Just get the strawberries there."
      #I frown and let the comment pass.
        *set dir %- 5
        You frown.

        *if (gen <= 43)
          "No snarky quip?" ${g_they} asks.

          "Fresh out, I'm afraid."
          You flash ${g_them} an obviously insincere smile.
          *if (per >= 57)
            You note that the corner of ${g_their} mouth twitches ever so slightly upward.

        "See you later then," ${g_they} says without so much as a glance in your direction.          
      #"Hoping to see me again so soon?" I taunt. ♥
        *set cha %+ 5
        *set bol +1
        *set g_rom +1
        You lean closer to ${gabby} and let your voice drop an octave.
        "Hoping to see me again so soon?"

        $!{g_they} rolls ${g_their} eyes at you.
        "Just get the strawberries there."
      #"Sure thing, [i]your Highness[/i]," I scoff. ♥
        *set cha %- 5
        *set gen %- 5
        *set hos +1
        *set g_rom +1
        You roll your eyes and scoff.
        "Sure thing, [i]your Highness[/i].s"

        $!{g_their} eyes narrow at you.
        "Just get the strawberries there."
      #I bite my bottom lip.  "Sure thing." ♥
        *set dir %- 5
        *set yie %- 5
        *set shy +1
        *set g_rom +1
        You bite your bottom lip and glance up at ${gabby} from under your eyelashes.
        "Sure thing."

        $!{g_they} glances up at you.
        "See you later then."

    *if ((g_rom > num) and (g_rom >= 2))
      *set yr1_05_30_20_g 4
    *if (g >= 2)
      *set yr1_05_30_20_g 4

*set num 0

*if (meet_g = false)
  *set meet_g true
  You glance up as a shadow passes over your little vegetable stand.
  The ${g_person} in front of you wears a scowl on ${g_their} face.
  $!{g_their} unnaturally erect posture complements the crisp lines of ${g_their} pressed trousers and short-sleeved button-up.
  Even ${g_their} eyes, a light hazel brightened by a glint of suspicion, comply with the monotone ensemble.
  $!{g_their} brown curls take flight in the breeze, the only show of whimsy before you.

  "You're new," ${g_they} observes with a posh British accent before plucking one of your strawberries off the table for inspection.

  *fake_choice
    #"Yep," I agree and pull on my ${tic}.
      *set awk %+ 5
      You pull at your ${tic}.
      "Yep."
    #"New, and an improvement for the market."
      *set awk %- 5
      *set cha %+ 5
      *set hum %- 5
      You paste a customer-service-smile on your face.
      "New, and an improvement for the market," you say cheerfully.

      $!{g_they} raises ${g_their} eyes to you briefly before returning ${g_their} attention to your wares.
    #I purse my lips at ${g_them}.
      *set cha %- 5
      *set yie %- 5
      You purse your lips at ${g_them} but manage to not roll your eyes.
    #[i]Or maybe you're just old[i], I think to myself.
      *set dir %- 5
      *set gen %- 5
      [i]Or maybe you're just old[i].

  "Where are these from?"

  You swallow an amused smile at ${g_their} complete disinterest in [i]you[/i].
  "These were grown at Darbury Farm.
  It's
  *if (g > 0)
    *set yr1_05_30_20_g 2
    near Talverton."

    $!{g_they} nods ${g_their} head and frowns.
    "You're the one who took the manor."

    You raise your eyebrows.
    "Yeah... that's me.
    Who are you?"

    "I own [i]La Chambre Rose[i]."

    "The restaurant?" you ask tentatively.

    "Yes, the restaurant," ${g_they} huffs.
    "What are you doing here?"

    You glance around at your produce, unsure how to answer such an unnecessary question without sounding like a smart-ass.
    [i]Isn't it obvious?[/i]
    "I'm selling—"

    $!{g_they} rubs ${g_their} temples.
    "What are you doing in [i]Eprea[/i]??"
    $!{g_they} steps closer as if to punctuate ${g_their} speech.
    "You Americans think you can go wherever you like and do whatever you please."
  *else
    *set yr1_05_30_20_g 1    
    near—"

    $!{g_their} eyes snap to yours.
    "So [i]you're[/i] the one trying to colonize Talverton."

    You blink several times and shake your head.
    "Excuse me?"

    "You Americans think you can go wherever you like."

    You cross your arms.
    "Who the hell are you?"
    The words fly out of your mouth, slurring together and bringing a bit of that Kentucky twang to the forefront.
    [i]Whooth'helleryou?[/i]

    $!{g_they} draws ${g_their} lips into a thin line.
    "I own [i]La Chambre Rose[/i]."

    "You got a name?"

    "It's ${gabby}," ${g_they} answers through clenched teeth.

  *fake_choice
    #"Are you gonna buy anything or not?" I ask with an eyeroll.
      *set dir %+ 5
      *set hum %- 5
      You roll your eyes and cross your arms.
      "Are you gonna buy anything or not?"

      *if ((yr1_02_05_20_i = 0) or (yr1_02_05_20_i = 4))
        "I'll take my money elsewhere," ${g_they} replies in a clipped tone before stalking off.
      *else
        $!{g_their} eye twitches, and ${g_they} grabs a strawberry from your basket before stalking off.
    #"Look, I'm just trying to make a living, alright?"
      *set hum %- 5
      *set yie %+ 5
      You sigh. 
      It's too early in the day for this.
      "Look, I'm just trying to make a living, alright?"

      *if ((yr1_02_05_20_i = 0) or (yr1_02_05_20_i = 4))
        "Why don't you go back where you belong make it there?" ${g_they} growls before stalking off.
      *else
        ${g_they} scoffs and grabs a strawberry from your basket before stalking off.
    *if ((yr1_02_05_20_i = 0) or (yr1_02_05_20_i = 4))
      #"Listen here pal, you and your [i]British[/i] accent can buy some produce or take a hike."
        *set cha %- 5
        *set yie %- 5
        You take a step closer.
        "Listen here pal, you and your [i]British[/i] accent can buy some produce or take a hike."

        $!{g_they} flushes with indignation and stammers for a response before giving up and stalking off.
      #"The manor's been for sale for seventy years!  Why didn't [i]you[/i] buy it?"
        *set dir %- 5
        *set gen %+ 5
        You raise your shoulders.
        "The manor's been for sale for seventy years!
        Why didn't [i]you[/i] buy it?"

        $!{g_their} eyes widen and ${g_they} takes a step back as if slapped before stalking off.
    *if ((yr1_02_05_20_i != 0) and (yr1_02_05_20_i != 4))
      #I shrink back within myself.
        *set hum %+ 5
        *set yie %+ 5
        You shrink backward, your lips forming a nervous grimace.

        $!{g_they} frowns and grabs a strawberry from your basket before stalking off.
      #I raise an eyebrow and lean even closer.  "Paper... or plastic?" ♥
        *set awk %- 5
        *set hum %- 5
        *set bol +1
        *set g_rom +1
        You lean closer, keeping eye contact.
        "Paper... or plastic?"[/i]

        ${g_they} scoffs and grabs a strawberry from your basket before stalking off.
      #"Look buddy—" I poke ${g_their} chest, "do you want to buy anything or not?" ♥
        *set cha %- 5
        *set dir %+ 5
        *set hum %- 5
        *set yie %- 5
        *set hos +1
        *set g_rom +1
        You step closer and jam a finger into ${g_their} chest.
        "Look buddy, do you want to buy anything or not?"

        $!{g_their} eye twitches, and ${g_they} grabs a strawberry from your basket before stalking off.
      #$!{g_they}'s so close I can feel ${g_their} breath on my skin, and I'm at a loss for words. ♥
        *set hum %+ 5
        *set yie %+ 5
        *set shy +1
        *set g_rom +1
        You can feel ${g_their} warm and disgruntled breath against your skin, and you break out in goosebumps.
        Glancing down at your tingling skin, you can't quite form a coherent response.

        $!{g_they} eyes you warily and grabs a strawberry from your basket before surrendering the field.

*if ((yr1_05_30_20_g = 1) or (yr1_05_30_20_g = 2))
  You watch ${g_their} retreating figure, disappearing through the morning crowd.
*if (yr1_05_30_20_g = 1)
  Could that have gone worse?

  You have a sinking feeling in the pit of your stomach as you think about your future in Talverton, more uncertain than you've ever been.
  The worst of it is, you don't even know why ${g_they} was so hostile to you.
  What did you ever do to ${g_them}??
*if (yr1_05_30_20_g = 2) 
  It could have gone worse, you guess.
  It also could have gone a lot better.
  You sigh, uncertainties about the future reignited.

*if ((yr1_05_30_20_g = 1) or (yr1_05_30_20_g = 2))
  You glance up at the sky.
  The shadows of the uncertain, early-morning sun have given way to true sunshine.
  The day is still young.

  *if (hum <= 45)
    There is hope.

  You resume watch on the edge of the tailgate and wait for the next customer.

*if ((yr1_05_30_20_g = 3) or (yr1_05_30_20_g = 4))
  You shake your head in frustration as you watch ${g_them} disappear into the growing crowd.
  You can't tell if you're coming or going with ${g_them}.

  [i]At least I made a sale[/i], you think to yourself.
  It's a start.
  You climb back onto the edge of the tailgate and wait for the next customer.

*if (yr1_05_30_20_g = 4)
  *page_break

  The summer sun is still high in the sky when you begin to tear down your stand.
  It'll be a couple of hours at least before it disappears, but your muscles are convinced that you've put in at least a week's work in the last eight hours.
  Your arms ache as you load the last of the boxes into the bed of the truck.
  Despite your fears, you managed to dispose of most of your produce, leaving only a pitiful selection of dried-up vegetables to haul back to Darbury for the chickens.

  And ${gabby}'s strawberries.
  You had set them aside as soon as ${g_they} had left, and it was a good thing too since they completely sold out by noon.

  When at last you climb into the cab of your truck and turn the key in the ignition, a blast of heat hits your skin before the AC has a chance to catch up.
  As the air begins to cool down, you close your eyes and take a deep breath in, resting your arms against the steering wheel.
  Even the cold air feels hot against your sun-burned skin.
  Finally you sit up, shift into gear, and pull out of the square.

  *page_break

  The sun is just starting to set, sending flame-like rays chasing across the landscape, as you pull into the alley behind [i]La Chambre Rose[/i].
  The hum of the engine disappears, replaced by the steady chirps of the summer crickets.
  Occasionally a toad lends his voice to the arrangement.

  You slide out of the cab and trudge along to the back to begin unloading the strawberries.
  With one crate in hand, you make your way toward the service entrance.

  "Successful day?"

  You start at the question and whip around to see ${gabby} sitting on a wooden pallet against the wall of the restaurant. 
  With a wrinkled t-shirt barely tucked into ${g_their} black trousers and a
  *if (g_gender = "f")
    few loose curls escaping her tight bun,
  *else
    light stubble blanketing his face,
  the ${g_person} in front of you is a far cry from the fastidious nit-picker who bought your strawberries earlier in the day.

  "Pretty successful," you confirm.
  "Full house?"

  $!{g_they} nods.
  "How many of those do you have?"
  $!{g_they} mumbles the words over the cigarette ${g_they} has balanced on ${g_their} lips.

  "One more."

  *if (g_rom <= 2)
    *set num g_rom
    *goto exit

  *if (g_rom > 2)
    *page_break
    $!{g_they} pushes ${g_them}self onto ${g_their} feet and
    *if (g_gender = "f")
     brushes the hair out of her face.
    *else
      runs a hand through his curls.
    $!{g_they} brings ${g_their} cigarette up to ${g_their} lips, holding it between ${g_their} index finger and thumb, for a final puff before letting it fall to the asphalt and smothering it under ${g_their} boot.
    Strolling over to the back of your truck, ${g_they} grabs the second crate before guiding you into the kitchen.

    At your entrance, a casserole of chefs flick their gaze in your direction.
    As they inspect you, you make your own inspection of your new environment.

    The bright, sterile light, flashing against the stainless steel appliances, contrasts with the fading light in the alley outside.
    The chop-chop-chop of a knife against a wooden cutting board; the clatter of a lid against a pot as the boiling water whistles its way to escape; the burble of a simmering sauce: they all make it to your ear.
    And the smells—lemon, thyme, rosemary.
    And caramelized onions?

    When ${gabby} turns around to face the other chefs, they all avert their gaze and return to their work.
    $!{g_they} pulls ${g_their} white chef's coat off a nearby peg and shrugs into it.

    "You're still here?" ${g_they} asks when ${g_they} turns around and spots you.

    *set num g_rom

    *fake_choice
      #"I was just leaving," I sigh.
        *set dir %+ 5
        *set yie %+ 5
        You sigh.
        "I was just leaving."
      #I roll my eyes.  "I'll see myself out."
        *set dir %- 5
        You roll your eyes.
        "I'll see myself out."

        $!{g_they} grunts noncommitally.
      #"No, I left ten minutes ago."
        *set gen %- 5
        "No, I left ten minutes ago," you say.

        "I can see that," ${g_they} says in a dry tone.
      #"Afraid if I stay any longer your chefs will like me better?" I tease. ♥
        *set cha %+ 5
        *set gen %- 5
        *set bol +1
        *set g_rom +1
        You smile at the crotchety chef.
        "Afraid if I stay any longer your chefs will like me better?"

        $!{g_they} glances back at you.
        "Of course they'll like you better."

        You raise an eyebrow at ${g_them} and suppress the smile threatening at your lips.
        "Oh?"

        "You're a lot nicer than I am," ${g_they} elaborates with an air of indifference.
      #I cross my arms.  "I know object permanence is hard and all, but the Earth didn't swallow me while you weren't looking." ♥
        *set cha %- 5
        *set gen %- 5
        *set hos +1
        *set g_rom +1
        You cross your arms and scowl.
        "I know object permanence is hard and all, but the Earth didn't swallow me while you weren't looking."

        $!{g_their} eyes shoot daggers at you, but you don't back down. 
        "You're quite the charmer," ${g_they} retorts.

        "Takes one to know one."

        $!{g_they} rolls ${g_their} eyes at you.
      #I blush at ${g_their} renewed scrutiny. ♥
        *set shy +1
        *set g_rom +1
        You blush and look away.

        $!{g_they} half frowns.
    *if (g_rom > num)
      "Come."
      $!{g_they} gestures toward the door, and you follow.

      The other chefs return their attention to you, and you feel their eyes follow you toward the exit.

      ${gabby} pushes the door open and steps out into the alley, holding it for you.
      As you step past ${g_them} you catch a whiff of ${g_their}
      *if (g_gender = "f")
        perfume.
      *else
        cologne.

      You 
      *if (g_taller = true)
        glance up at ${g_them}
      *else
        catch ${g_their} eye
      and pause for a moment in the doorway, entirely too close.
      *gosub_scene mechanics_setup flirt_style
      *if (style = 1)
        You smile at ${g_them}.
        
      *elseif (style = 2)
        You scowl at ${g_them}.

      *else
        $!{g_they} tilts ${g_their} head slightly and inspects you.
      "Thank you for bringing the strawberries," ${g_they} says
      *if (style = 1)
        with a guarded expression.

        "You paid for them," you laugh and pat ${g_their} arm.
        "See you around."
      *elseif (style = 2)
        with a matching scowl.

        "Yeah well, free shipping on orders over $25."
        You flounce away before ${g_they} can retort and push the odd encounter out of your mind.
      *else
        in a quieter tone.

        "You're welcome," you murmur.
        "I should get going."
        And with that, you peel yourself away from the odd tension.

      You glance over your shoulder as you make your way to the truck
      *if (g_rom > 3)
        and lock eyes with ${gabby}.
        *if (style = 1)          
          You wink at ${g_them} and laugh when ${g_they} scowls.
        *elseif (style = 2)
          You frown and turn back around.
          "Weirdo," you mutter under your breath.
        *else
          A shiver travels down your spine, and you snap your eyes forward.
      *else
        just in time to see ${gabby} disappear into the kitchen.

    *else
      "Thanks for the strawberries."

      You nearly trip in surprise.
      "You paid for them."
      You shrug.

    *if (g_rom <= num)
      You set the crate down none too lightly next to the door and return to the back of the truck for the second while ${gabby} watches you from ${g_their} perch.
      They're not heavy, not really, but you don't relish ${gabby}'s skeptical gaze.
      [i]What does ${g_they} expect me to do?[/i] you wonder, [i] usurp ${g_their} rightful place as[/i]
      *if (g_gender = "f")
        [i]queen?[/i]
      *else
        [i]king?[/i]

      You set the second crate on top of the first and turn to leave, but ${gabby} is closer than you expected.
      *if (g_taller)
        The fiery look in ${g_their} eyes more than makes up for your height advantage.
      *else
        $!{g_they} looks down on you.
        Both literally and figuratively, you assume.

      You take an instinctive step back to find yourself against the wall.

      *set num g_rom
      *fake_choice
        #"Can I help you?" I ask with a flashy grin.
          *set cha %+ 5
          You flash an insincere smile.
          "Can I help you?"
        #"Ever heard of hoola-hoop space?  Sheesh!"
          *set dir %+ 5
          You stand up straighter.
          "Ever heard of hoola-hoop space?  Sheesh!"

          ${gabby} scowls and takes a step back.
        #I wait for ${g_them} to speak.
          *set yie %- 5
          You stand there and wait in silence.
        #I step closer before slipping past ${g_them}. ♥
          *set awk %- 5
          *set bol +1
          *set g_rom +1
          You take a step closer and then duck under ${g_their} arm at the last minute.
        #I poke ${g_them} in the chest.  "You got something to say?" ♥
          *set cha %- 5
          *set dir %+ 5
          *set hos +1
          *set g_rom +1
          You give ${g_them} a good poke.
          "You got something to say?"

          The frown on ${gabby}'s face deepens, and you push past ${g_them}.
        #I suddenly can't seem to get a good deep breath. ♥
          *set hum %+ 5
          *set shy +1
          *set g_rom +1
          Is it hot in here?
          You feel like you've run a mile and need a good deep gasp of air.

          The frown on ${gabby}'s face softens, and ${g_they} takes a step back.
      *label exit
      "Thank you for bringing the strawberries," ${g_they} grunts.

      *if (g_rom > num)
        *gosub_scene mechanics_setup flirt_style
        *if (style = 1)
          "It was my pleasure," you answer with a grin.
        *elseif (style = 2)
          "Yeah well, free shipping on orders over $25," you answer.
        *else
          "It was nothing," you shrug.
          
      *else
        *if ((cha >= 57) or (awk <= 43))
          You smile.
          "My pleasure."
        *elseif (gen <= 43)
          "What can I say?
          I couldn't resist such charming company," you answer dryly.
        *elseif ((dir >= 57) or (gen >= 57))
          "You paid for them," you shrug.
        *else
          "No problem."

      An awkward pause follows.
      "Well, I should be going."

      ${gabby} nods, and you part ways.     

*if (yr1_05_30_20_g = 0)
  *bug
*set num 0

*if ((yr1_05_30_20_g = 3) or (yr1_05_30_20_g = 4))
  *page_break
  *goto_scene story_20_06_01
*else
  *finish