[i]May 20th[/i]

"You 'bout ready to go?" Alex asks you.

"I think so.
I shouldn't be gone long anyway.
The studio's less than 30 miles from here."

"What do you you know about this guy anyway?"

*fake_choice
  #"Her name is Rashida."
    *set r_gender "f"
    *set r_person "woman"
    *set rash "Rashida"
    *set r_they "she"
    *set r_them "her"
    *set r_their "her"
    *set r_theirs "hers"
    *if height < 63
      *set r_taller true
  #"His name is Rashid."
    *set r_gender "m"
    *set r_person "man"
    *set rash "Rashid"
    *set r_they "he"
    *set r_them "him"
    *set r_their "his"
    *set r_theirs "his"
    *if height < 70
      *set r_taller true

"But that's about it.
Bertie said ${r_they}'s good with wood work, and there's no one else around here who can so do such delicate work."

"Well I guess Bertie wouldn't send you into the lair of a serial killer."

You groan.
"Not you too!"

Alex raises ${a_their} eyebrows at you.

"My mamaw is convinced some Mediterranean scoundrel is going to murder me.
Or marry me. 
She's not sure which alternative is worse.
But heaven forbid I die before I can produce a great-grand-baby."

Alex chuckles.
"Don't worry, I got the same spiel, except—" ${a_they} pokes you in the ribs for emphasis "—mine was worse because I'm an only child, and there was no one else around to distract my parents."

"I don't know, I think you got off pretty easy.
I had to deal with the inquisition from every angle."

Alex scoffs.
"Excuses, excuses."

Alex slides up next to you at the kitchen counter and grabs a strawberry from the colander in the sink.
*fake_choice
  #"Paws off—I'm taking those with me to butter up ${rash}."
    *set yr1_05_20_20_r true
    *set r +1
    You slap at Alex's hands.
    "Paws off—I'm taking those with me to butter up ${rash}."

    "Good thinking.
    Maybe ${r_they}'ll give us a discount on the sign.
    If that doesn't work, you'll have to seduce ${r_them}."

    "I'll take that under advisement."

    "And if all else fails, we'll just blame Bertie for a bad rec."

    "Excellent strategy."
  #"I just washed 'em, you want the bunch?"
    *set a +1
    You hold the colander up to allow Alex better access.
    "I just washed 'em, you want the bunch?"

    "Don't mind if I do," Alex responds.
    $!{a_they} grabs a bunch, picks the stem off, and sticks the lot of them in ${a_their} mouth like a hamster.

    "Maybe you're the one who oughta be careful.
    You're liable to choke if you don't slow down."

    "No time, people to go, places to see.
    Or was it the other way around?"

    "Maybe it's things to go and people to do?"

    "Just don't die.
    I'd hate to have to write home to your folks about this.
    Death by strawberries."
    
You pause a minute, looking away.
Alex munches on a few more strawberries, only the sound of running water as you wash your hands interrupting the silence.
"It was worth it though."
You look up and catch your best friend's eye, your best friend who gave up everything and followed you half way across the world.
"Wasn't it?"

"What?"

"Listening to your mom and dad's worries and doubts about following me out here.
Doing it anyway."

Alex cocks ${a_their} head and crosses ${a_their} arms across ${a_their} chest.
"Yeah... I 'spose so.
But be careful anyway, okay?
Don't get murdered by this dude.
I'd hate for you to prove your mamaw right."

"You got it boss."

Alex walks you to the truck.
You hop into the driver's seat and fasten your seatbelt.

"Need anything while I'm in town?"

"I could go for a million bucks."

"I'll see what I can do."

"Alright chief."
Alex pats the side of the truck.
"See you soon!"

You give ${a_them} a salute and pull away.

*page_break
*set meet_r true

The farther from Talverton and closer to sea level you get, the more the landscape changes.
The trees thin out, giving you an unobstructed view of the aquamarine Mediterranean.
Gulls call out to each other in the sky, and the smell of the salty ocean air wafts in through your open windows.

When you pull up to ${rash}'s studio, it's everything you could have imagined in a beach cottage.
Weathered shingles cover the outer walls, and metal chimes clink against each other in the breeze.
You climb up the rickety wooden steps to the deck above and rap lightly on the front door.

Something heavy crashes on the other side, followed by a string of curses.
The door swings open, revealing a half naked
*if (r_gender = "m")
  man.
  He's wearing a pair of wrinkled trousers, suspenders hanging at his sides.
  His chest is bare but for the thick hair that tapers suggestively down his toned torso and underneath the waist of his pants.
*if (r_gender = "f")
  woman.
  She's wearing a loose white dress shirt that stops just below the top of her thighs.
  Her long, toned legs peep out from underneath.
$!{r_they}'s holding a towel, obscuring ${r_their} face as ${r_they} pats ${r_their} wavy, black hair dry.

"Look, whatever you're selling, I'm not buying," ${r_they} says.
$!{r_they} pulls the towel away from ${r_their} face and looks at you sideways.

You begin to tap your foot in impatience.

"Oh," ${r_they} pauses.
$!{r_their} lips curl into a smile.
"Good morning."
Tossing the towel aside, ${r_they} reaches ${r_their} hand out toward you.
"The name's Rash."

You take ${r_their} hand out of force of habit while ${r_they} inspects your [i]person[/i] a bit too closely for your comfort.

"It's a [i]pleasure[/i] to see a, uh, new [i]face[/i] around here."

*fake_choice
  #I laugh awkwardly.  "Nice to meet you too..."
    *set awk %+ 5
    A nervous giggle bubbles out of your throat.
    "Nice to meet you too..."
  #I narrow my eyes at ${r_them}.
    *set cha %- 5
    *set yie %+ 5
    You narrow your eyes at ${r_them} and cross your arms in front of you.

    "Oh, don't tell me you've already found me wanting!
    You've got to give me at least a few hours to show you what I can really do."

    "I think my time would be better spent alone," you respond with a scowl.

    "You don't know what you're missing."

    "Whatever [i]it[/i] is, I can live without it."

    Rash shrugs.
  #"The pleasure is mine," I deadpan.
    *set gen %- 5
    With eyes glued to ${r_their} face—you won't give ${r_them} the satisfaction of an appreciative stare—you let a moment of silence pass.
    "The pleasure is mine," you say in a monotonous voice.

    Rash squints at you.
    "Yeah, I can see that.
    Maybe you'd be willing to share some with me?
    Pleasure—that it."

    "I'm afraid I have none to spare."

    "Shame," ${r_they} says with a shrug.
  #I give ${r_them} the same treatment and raise a skeptical brow. ♥
    *set awk %- 5
    *set hum %- 5
    *set bol +1
    *set r_rom +1
    You look ${r_them} up and down, your eyes pausing for a moment at ${r_their}
    *if (r_gender = "m")
      chest
    *else
      crotch
    before finally raising a skeptical eyebrow.

    Rash chuckles and leans against the door frame,
    *if (r_gender = "m")
      tucking his thumbs into the waist of his trousers.
    *if (r_gender = "f")
      her hands behind her, pushing her chest forward.
    "Oh, don't tell me you've already found me wanting!
    You've got to give me at least a few hours to show you what I can really do."

    "If it takes you that long, then I think my time would be better spent [i]alone[/i]."

    "Right through the ego!" ${r_they} moans, clutching the nonexistent wound in ${r_their} chest, but the cheshire grin never leaves ${r_their} face.
  #"Do you oggle all strangers like this or just the ones that happen across you half naked?" ♥
    *set dir %+ 5
    *set hos +1
    *set r_rom +1
    You cross your arms in front of you and scoff.
    "Do you oggle all strangers like this or just the ones that happen across you half naked?"

    Rash laughs and leans against the door frame,
    *if (r_gender = "m")
      tucking his thumbs into the waist of his trousers.
    *if (r_gender = "f")
      her hands behind her, pushing her chest forward.
    "Just the... [i]enticing[/i] ones," ${r_they} say with a shrug.

    You purse your lips.
  #I bite the inside of my cheek.  "Right... [i]face[/i]..." ♥
    *set awk %+ 5
    *set shy +1
    *set r_rom +1
    You bite the inside of your cheek and will yourself not to blush.
    "Right... [i]face[/i]..."[/i]

    Rash grins and leans against the door frame.
    *if (r_gender = "m")
      tucking his thumbs into the waist of his trousers.
    *if (r_gender = "f")
      her hands behind her, pushing her chest forward.
    "Don't worry, I don't bite.
    Unless you want me to, that is."

    You reach up and tug on your ${tic}.

    Rash chuckles at your unease.
    $!{r_they} bites ${r_their} bottom lip and lowers ${r_their} voice.
    "Well, I wouldn't be opposed to getting to know the rest of you better as well."

    You gulp heavily.

As quickly as it appeared, Rash's philanderer veneer recedes, leaving only the glint of interest in ${r_their} brown eyes as evidence of ${r_their} desire.
"So what brings you here?"

"I need a wooden sign."

Rash gestures for you to come in.
"Let's talk then."
$!{r_they} leads you through the bohemian cottage—persian rugs, velvet upholstery, and metalic finishes—and into the kitchen.
$!{r_they} pushes ${r_them}self onto an empty counter
*if (r_gender = "m")
  You notice the way his muscles flex.
*if (r_gender = "f")
  You get a brief peek at her lacy, red panties.
"So what'd you have in mind?"

*if (yr1_05_20_20_r)
  You set your backpack down next to Rash and unload the fresh strawberries you brought with you.
  At this point, you're not sure you want to hand them over.
  But it's too late now.

  "Whatcha got there?" ${r_they} asks before you can pull out the plans.
  $!{r_they} cocks ${r_their} head to the side and waits for you to respond.

  *if (gen <= 45)
    You bite back a retort.
  "They're fresh from our garden," you say.
  "I thought they'd be a nice show of friendship.
  Or whatever."
  You sigh.

  Rash's eyes light up.
  "You're the one who took the manor!"

  "Yep."

  "Bertie Carroll told me about you.
  Makes sense now."

  $!{r_they} plucks a strawberry from the carton and slowly places it in ${r_their} mouth, watching you with rapt eyes as strawberry juice trickles down ${r_their} face.
  When ${r_they}'s finished, ${r_they} wipes it away with ${r_their} thumb and then sucks it off.

  "Thanks," ${r_they} says.
  "Tender and juicy—just the way I like it."

  *fake_choice
    #"Does everything have to be an innuendo?" I ask with a sigh.
      *set gen %+ 5
      *set dir %+ 5
      You let out a long-suffering sigh.
      "Does everything have to be an innuendo?"

      Rash laughs.
      "I could be more literal, if you like."

      You sigh.
      "Maybe my mamaw was right."

      "Mamaw?" Rash asks.

      You wave ${r_them} off.
      "Let's just get on with this."

      Rash nods and hops off the counter.
      "What do you have in mind?"

      You turn back to your bag and pull out the sketches and photographs that you and Alex put together. 
    #"I'm glad you like them!"
      *set per %- 5
      You beam.
      "I'm glad you like them!"

      Rash's brow creases, and ${r_they} rubs the back of ${r_their} neck.
      "Yeah, they're great.
      The [i]strawberries[/i].
      Tender... juicy... [i]stawberries[/i].
      Thanks for bringing them."

      You cock your head at ${r_them}, uncertain about ${r_their} emphasis.
      Shaking off your confusion, you say, "You're welcome!"

      Rash hops down off the counter.
      "So what do you have in mind for the sign?"

      You turn back to your bag and pull out the sketches and photographs that you and Alex put together. 
    #"So about that sign," I say, arms crossed.
      *set dir %+ 5
      *set yie %- 5
      You cross your arms.
      "So about that sign."

      "Spoilsport," ${r_they} complains, but ${r_they} doesn't push ${r_their} luck.
      "What do you have in mind for the sign?" ${r_they} asks, hopping down from the counter.

      You roll your eyes and turn back to your bag and pull out the sketches and photographs that you and Alex put together. 
    #"You missed a spot." ♥
      *set hum %- 5
      *set org %- 5
      *set bol +1
      *set r_rom +1
      "You missed a spot."
      You reach up and wipe away the leftover juice, sucking it off your thumb slowly and crinkle your nose.
      "Definitely too sour for me."

      Rash slides off the counter, closing the distance between the two of you.
      "Well I guess you need a little sugar then."

      You roll your eyes.

      "So the sign."

      Shaking your head, you turn back to your bag and pull out the sketches and photographs that you and Alex put together. 
    #I take a strawberry of my own and chomp down on it violently. ♥
      *set cha %- 5
      *set org %- 5
      *set hos +1
      *set r_rom +1
      You make eye contact with the 
      *if (r_gender = "f")
        coquette
      *else
        Casanova
      in front of you and grab one of the strawberries from the carton, chomping down on it with gusto.

      "A ${person} of [i]particular[/i] tastes, I see.
      Well I'm not one to back away from a challenge.
      No pain, no gain, eh?"

      $!{r_they} slides off the counter and closer to you, reaching across you to grab another strawberry.
      You get a whiff of ${r_their} shampoo from ${r_their} still-drying hair.
      $!{r_they} pops another strawberry into ${r_their} mouth, revealing a single canine as ${r_they} bites down.
      Licking ${r_their} bottom lip, ${r_they} runs a hand through ${r_their} messy hair.

      "So the sign."

      You roll your eyes and turn back to your bag to pull out the sketches and photographs that you and Alex put together. 
    #I nearly choke on the air. ♥
      *set awk %+ 5
      *set shy +1
      *set r_rom +1
      Your eyes go wide, and suddenly there's no air in your lungs.
      Coughing, you get the air moving again and take a step back.

      $!{r_they} slides off the counter and closer to you, reaching across you to grab another strawberry.
      You get a whiff of ${r_their} shampoo from ${r_their} still-drying hair.
      $!{r_they} pops another strawberry into ${r_their} mouth, revealing a single canine as ${r_they} bites down.
      Licking ${r_their} bottom lip, ${r_they} runs a hand through ${r_their} messy hair.

      "So the sign."

      You shake yourself out of the spell that ${rash} has cast over you and turn back to your bag to pull out the sketches and photographs that you and Alex put together. 
   
*if (yr1_05_20_20_r = false)
  You set your backpack down next to Rash and unzip it, pulling out the sketches and photographs that you and Alex put together.
The sign will sit at the entrance to property and serve as the first impression your guests and visitors receive.
Rash takes the sketches from you.

"So you want—"
*fake_choice
  #"—an apple tree?"
  #"—the silhouette of the manor?"
  #"—a goose?"
  #"—SUGGESTIONS WELCOME?"

"That's doable," ${rash} says.
"I'll do some sketches and send them along?"

You nod your agreement.

"Great."
The corners of ${r_their} lips slide upward.
"Now that we've concluded business to our [i]mutal satisfaction[/i], we could do something a little more [i]fun[/i]?"
$!{r_they} chews on the word as if savoring it.

*if (r_rom > 0)
  *gosub_scene mechanics_setup flirt_style
  *if (style = 1)
    You smirk
  *elseif (style = 2)
    You glare 
  *else
    You tense up
  at ${r_their} innuendo.

  $!{r_they} saunters closer, and you catch a whiff of ${r_their}
  *if (r_gender = "f")
    perfume.
  *else
    cologne.

  *if (style = 1)
    "I'm sure [i]you[/i] would enjoy that, but I've got things to do."

    "Give me half a chance, and I'll make sure you enjoy it too."
  *elseif (style = 2)
    "Just let me know when you're finished with the sketches," you huff.

    $!{r_they} laugh.
    "Will do, boss."
  *else
    You hold your breath as if to protect yourself against ${r_their} seduction.
    "I-I really must be going," you stutter.

    $!{r_their} grin grows at your discomfort.

*else
  *if (gen <= 42)
    "I'll have to take a rain check," you say with a blank expression.
  *else
    "Not today," you say, unsure [i]exactly[/i] what ${r_they} means by "fun" and not keen to find out.

  "Your loss," ${r_they} says with a sing-song tone.

  You shrug.
  [i]You really must be going[/i].

${rash} escorts you back to the front door.
"Don't be a stranger," ${r_they} invites as you retreat to your truck.

You glance back at ${r_them} one more time, shaking your head.
[i]What a weirdo[/i].

*gosub_scene mechanics_setup pet_names_r

*finish