[i]April 8th[/i]
*set collage_ines true

*if (yr1_04_08_20_i = 4)
  You follow the directions on your phone and turn onto a narrow cobblestone road.
  Only the variation in color reveals that the stone houses on either side are individual units.
  Spring flowers bloom in the window boxes, and stubborn moss fills in the gaps between bricks.
  A church tower, twice as tall as the houses, looks down on the scene from above and chimes the hour.

  You come to a stop in front of a green door and knock.
  Ines appears in the doorway as elegant as ever and beckons you inside.

  Her house is just what you would expect it to be.
  Crown moulding and tall, complex wainscoting divide the walls into geometric sections, and large persian rugs carpet the floor.
  She opens a set of pocket doors and guides you into a sunny sitting room with light green walls.

  "I will return with the tea," she informs you, and you almost expect her to curtsy.
  "Please, make yourself comfortable."

  *page_break

  You take the opportunity to peruse the room.
  Two built in bookshelves flank the fireplace in the middle of the room.
  The titles, mostly French, are unfamiliar to you, though you notice there are a disproportionate number of cookbooks.

  The surfaces of the sitting room are free of those little knick-knacks that you associate with living, breathing spaces, but a few pictures draw your attention.
  In one, a little 
  *if (g_gender = "f")
    girl's    
  *if (g_gender = "m")
    boy's
  wild, curly hair flies out at all angles.
  $!{g_they}'s sitting in an over-sized mixing bowl, grinning at the camera.

  Ines glides into the room with the tea service and sets it down on a small pedestal table.
  "You have found my ${gabby}," she says, joining you in front of the picture.

  "Your
  *if (g_gender = "f")
    daughter?"    
  *if (g_gender = "m")
    son?"

  "Grand${g_child}," she corrects.
  *if (yr1_02_05_20_i = 3)
    A spark ignites in her eyes.
    "Perhaps you would like to look at photo albums, yes?
    But tea first."
  *else
    "Shall we?"
  She directs you to an overstuffed armchair near the tea pot.
  Delicate pink roses dot the porcelain of the pot and its matching cups and saucers.

  "How will you take your tea?" 

  *fake_choice
    #"Plain."
      *set var "tea"
      "Plain."
    #"With milk."
      *set var "tea"
      "With milk."
    #"With honey."
      *set var "tea"
      "With honey."
    #"With sugar."
      *set var "tea"
      "With sugar."
    #"With milk and honey."
      *set var "tea"
      "With milk and honey."
    #"With milk and sugar."
      *set var "tea"
      "With milk and sugar."
    #"With jam."
      *set var "tea"
      "With jam."
 
      "Jam?" Ines asks wide-eyed.

      *if (awk >= 55)
        You smile awkwardly and rub the back of your neck.
        "Yes, jam."

      *else
        "Yes," you say.
        "It's very good actually.
        The sugar sweetens the tea, and the fruit complements it."

      Ines sets the tea pot down and scurries out of the room.
      "I shall be right back."

      She returns with a selection of jams, jellies, and preserves and allows you to take your pick.
    #Although I don't typically drink tea, I say "With sugar."
      *set yie %+ 5
      *set var "tea"
      "With sugar, please."
    #"I actually don't drink tea."
      *set dir %+ 5
      *set yie %- 5
      *set var ""
      "I actually don't drink tea."

      "Oh," Ines says with raised eyebrows.
      "Would you prefer coffee?"

      "No, no," you shake your head and smile, "I will make do with scones."

    #"Might I stick to the pastries, actually?"
      *set dir %- 5
      *set var ""
      "Might I stick to the pastries, actually?"

      "Certainly," Ines replies as she hands you a saucer.
      
  *if (var = "tea")
    The tinkling of the silver spoon against the porcelain teacup as Ines prepares your tea casts a calming spell over you.
    She hands you the cup, and you hold it in both hands for a moment to feel the radiating warmth before you take a sip.

    "Thank you," you say, and she nods in acknowledgment.

  *if ((per >= 58) or (org >= 58))
    You watch Ines drizzle honey into her own teacup and store her preferences away for future use.

  After a careful examination, you pluck a tea cake from the top of the pile of pastries.
  "Thank you for inviting me to tea,"
  *if (awk >= 55)
    you say, searching for a subject to fill the empty void.
  *else
    you say.
    "I look forward to becoming more familiar with the community."

  "It is my pleasure to have you.
  Talverton is such a small place.
  I try to take a interest in [i]newcomers[/i]."

  You think back to the day that Ines stormed your castle to interrogate you and
  *if (gen <= 45)
    back bite a retort.
  *else
    suppress the smile that threatens to form on your lips.
  "How long have you lived here?" you ask, unsure if her French accent originates here in Eprea or from mainland France.

  "All of my life.
  My father and mother were from the East, and they came here when I was a child.
  I went away for a while when I was young, but something pulled me back."
  She examines you over her teacup.
  "I wonder—will you be like me?"   

  *if (var = "tea")
    You take a sip of tea before answering.
  "If you mean will I return to Valley Creek, then I don't know.
  That's not what I plan to do, but life rarely goes according to plan."

  "Indeed."

  *page_break

  The two of you continue to chat about inconsequential topics, and you feel as though you are a minor character in a regency novel, trapped in the ennui of social niceties.
  [i]What compels people to discuss the weather?[/i] you think to yourself.

  In the middle of your conversation, a plush, gray-striped cat trots into the drawing room and rubs against Ines' leg.
  The older lady's face lights up at the feline's entrance.
  She runs her hand down the cat's back before turning back to you to say, "This is Chouquette."
  Chouquette looks at you with her wide, yellow eyes, wrapping her tail protectively around Ines' hand.

  The sight of the pampered cat eying you with cautious curiosity is enough to draw you from your trance, and you decide to steer the conversation in a more interesting—and personal—direction.

  *fake_choice
    *if (yr1_03_14_20_2 = 1) #"How long have you been a librarian?"
      *set yr1_04_08_20_i 1
      "How long have you been a librarian?" you ask.
    *if (yr1_03_14_20_2 != 1) #"Sebastian tells me you work at the library."
      *set yr1_04_08_20_i 1
      "Sebastian tells me you work at the library," you say.

      Ines nods.
    #"What does the Historical Society in Talverton do?"
      *set yr1_04_08_20_i 2
    #"Does your grand${g_child} live in Talverton?"
      *set yr1_04_08_20_i 3

  *if (yr1_04_08_20_i = 1)
    "I have been a librarian little over thirty years," she answers.

    You hold in your curiosity.
    Ines must have been middle aged by the time she started to work at the library, and you wonder what prompted that decision at a time when most people are thinking about retirement rather than starting a new job.
    "You must enjoy it to have stayed so long," you say neutrally.

    She smiles and stirs her tea.
    "I was not always a librarian.
    When I was younger, like many women of my time, I kept house."

    Since she has introduced the subject, you consider pushing further.
    *fake_choice
      #"What changed?"
        *set dir %+ 5
        "What changed?" you ask.

        *if ((i >= 3) or (cha >= 58))
          "My husband died." 
          Ines looks away from you and out the window.
          
          "I'm sorry to hear that," you say in a quiet voice.

          "Thank you, but let us move to happier topics.
          How are the renovations coming?"

          You laugh.
          "I'm not sure I would call that a [i]happy[/i] topic."

        *else
          She glances away.
          "It became rather boring.
          I needed purpose in my life."

          *if (((gen >= 55) or (per >= 55)) or (dir >= 55))
            "What about the historical society?" you ask.
            "Does it not give you purpose?"

            "Perhaps I needed something away from the old biddies and their tea parties," she answers with a sly smile.

            You laugh.

            "How is your own project coming?"

            You sigh.

          *else
            "I can understand that."
            You came here nominally because you couldn't find a job, but you could have found [i]something[/i].
            The trouble was you knew it would strangle you from within to work at a job you hated in a field you never wanted to enter.

            "Yes, I believe you must to take on such a project.
            How are renovations coming?"

            You sigh.

          Ines' eyes grow large.
          "What has happened?"

          You back track a bit, remembering the way she reacted when she thought you were ruining the manor.
          "No, no, nothing has gone wrong, I just miss running water."
          
      #"My grandmother also went to work when her children grew up."
        *set per %+ 5
        "My grandmother also went to work when her children grew up," you observe like a true diplomat.

        *if (gender = "f")
          "You come from a line of formidable women, then," Ines says with approval.
        *else
          "That is where you learned your fortitude," Ines concludes.

        "She's definitely... something," you agree.
        "She was not very [i]pleased[/i] with my decision to come here."

        "Oh?
        Why not?"

        [i]Mediterranean scoundrels![/i] your grandmother's voice echoes in your head.
        "She was concerned for my safety."

        Ines nods.
        "It is a grandmother's duty to worry."

    *page_break

  *elseif (yr1_04_08_20_i = 2)
    "What does the Historical Society in Talverton do?" you ask.

    "Mostly we do this," Ines says, gesturing at the tea service.
    "Tea parties and chatter."

    *if (cha >= 55)
      "Does that make me an honorary member?" you ask with a smile.

      "I would be happy for you to be an [i]actual[/i] member."
      Ines returns your smile.
    *elseif (gen <= 45)   
      "Is the chatter at least about history?" you ask with a hint of smile on your lips.

      "Oh yes, if the histories of our lives count.
      I believe gossip is out favorite pastime."
      Ines smiles at you.
    *else
      "What history do you focus on?" you ask.
 
    "We focus on local matters, but in a place as old as Talverton, every building is bound to have some significance."

    "I suppose Darbury Manor ranks among those."

    "Yes, naturally," Ines agrees.
    "Perhaps when the renovations are complete, we might host tea there?"

    *fake_choice
      #I should make an effort to integrate into the community, and the Historical Society could help.
        *set gen %+ 5
      #Hosting a tea party definitely sounds fun.
        *set org %- 5
      #An alliance with Talverton's Historical Society could certainly be beneficial to my bottom line.
        *set per %+ 5
    
    "I would like that," you say.

    "I had always hoped to see the manor restored.
    No one has used it since I was quite a little girl."

    "Sebastian mentioned that it had been seventy years since the manor was occupied."

    Ines sips her tea.
    "Yes, the allies used it during the war, but when the peace came, they left, and the estate fell into disrepair."

    "As close as the island is to France and Italy, that must have been a rather fraught position."

    "Indeed," Ines says with a smile, "that's why they met in secret at Darbury, but that is a story for another day I think."

    *page_break  
  *elseif (yr1_04_08_20_i = 3)
    "Does your grand${g_child} live in Talverton?" you ask.

    *if (yr1_02_05_20_i = 3)
      The gleam you saw earlier when you were looking at ${gabby}'s photo returns to Ines' eyes.
    *else
      Ines' eyes light up.
    "Yes, my ${gabby} is a chef in town."

    "I think Sebastian mentioned ${g_them} to me earlier.
    $!{g_they} has a restaurant?"

    "Yes, [i]La Chambre Rose[/i].
    $!{g_they} trained in Paris, you know."
    A statement, not a question, but you can hardly fault her since you [i]did[/i] in fact know.

    "You must be very proud."

    "Oui," she says, getting up from her chair.
    She glides over to the bookshelves and pulls out a selection of leather bound albums.
    When she returns, she hands the album on top to you.
 
    The first picture, black and white, shows a much younger Ines sitting in a rocking chair feeding a baby.
    "$!{g_they} was a winter baby."

    *page_break

    As you flip through the albums, a few pictures stick out at you.
    A curly headed toddler sits on a red tricycle and grins.
    A child stands in the middle of a garden and displays ${g_their} bunch of carrots.
    A teenager holds ${g_their} hand up to block the camera.

    "$!{g_they} was such a dour
    *if (g_gender = "f")
      girl,"
    *if (g_gender = "m")
      boy,"
    Ines says with a fond smile.
    "But ${g_they} grew up well."

    The last picture in the album can't be more than a few years old.
    The 
    *if (g_gender = "f")
      girl
    *if (g_gender = "m")
      boy
    you've watched grow up through the pages is definitely a ${g_person}.

    $!{g_they} stands in front of a two-story brick building, [i]La Chambre Rose[/i] emblazoned across the storefront.
    $!{g_their} curly brown hair just reaches the top of ${g_their} shoulders, one rogue curl peaking out from behind ${g_their} ear.
    $!{g_their} soft olive-colored skin, so unlike Ines' coloring, contrasts with the harsh white of ${g_their} chef's coat.
    Arms crossed, ${g_they} stands with ${g_their} leg resting against the base of the building, a lopsided grin on ${g_their} face.

    *if (yr1_02_05_20_i = 3)
      "Isn't ${g_they} a beautiful
      *if (g_gender = "f")
        girl?"
      *if (g_gender = "m")
        boy?"
      Ines asks.
      *fake_choice
        #"Certainly," I agree for the sake of courtesy.
          You nod, barely glancing at the photograph.
          "Certainly."
        #"$!{g_they} is," I agree. ♥
          *set awk %- 5
          *set bol +1
          *set g_rom +1
          You take a closer look at the photograph.
          "$!{g_they} is," you agree.
        #"Sure," I agree.  $!{g_they}'d be more appealing without that smug look. ♥
          *set hos +1
          *set g_rom +1
          The smug look on ${g_their} face makes you want to roll your eyes, but you refrain.
          Isn't there a website called Punchable Faces or something?
          You nearly laugh.
          "Sure," you agree, finally.
          "Beautiful."
          [i]Beautifully punchable.[/i]
        #"In-indeed," I stutter, surprised by the question. ♥
          *set awk %+ 5
          *set shy +1
          *set g_rom +1
          Your eyes widen.
          "In-indeed," you stammer.

    *else
      "Such a beautiful
      *if (g_gender = "f")
        girl,"
      *if (g_gender = "m")
        boy,"
      Ines says.

      *fake_choice
        #Beauty is in the eye of the beholder, I suppose.
        #Privately, I agree.  
    
  *else
    bug

  *page_break
  
  *if (yr1_02_05_20_i = 3)
    *set meet_g true
    A knock on the door interrupts your
    *if (yr1_04_08_20_i = 3)
      appraisal of ${gabby}'s beauty,
    *else
      conversation,
    but the intruder doesn't wait for permission to enter, and the very
    *if (g_gender = "f")
      woman
    *if (g_gender = "m")
      man
    whose childhood
    *if (yr1_04_08_20_i = 3)
      photos sit in your lap 
    *else
      photo sits on Ines' bookshelf
    appears in the doorway.

    *gosub_scene mechanics_setup flirt_style
    *if ((yr1_04_08_20_i = 3) and (g_rom > 0))
      *if style = 3
        You look back and forth between the photograph and ${gabby} in the flesh and blush as you realize the invasion of privacy you've unintentionally committed by looking through Ines' old photographs.        
      *else
        You compare the flesh and blood in front of you to the most recent photograph in your hands.
      $!{g_they} has aged a bit, a few wrinkles around ${g_their} eyes, the stress of running a kitchen you imagine,
      *if (g_gender = "f")
        but she is mostly the same.
      *else
        and a shorter haircut.
    *elseif ((yr1_04_08_20_i = 3) and (g_rom = 0))
      ${gabby} in the flesh is the natural progression of the photos you've seen.
      $!{g_they} sports a few more wrinkles but is otherwise the same.
    *else
      You can see echoes of the
      *if (g_gender = "f")
        girl
      *if (g_gender = "m")
        boy
      in the ${g_person} before you.
      $!{g_their} curly brown hair just touches the 
      *if (g_gender = "f")
        shoulders 
      *else
        collar
      of ${g_their} leather jacket, and ${g_they} pushes an errant curl out of ${g_their} face.
      $!{g_their} olive-colored skin contrasts with Ines' marble-like coloring, though they share the same nose and lips.       
      
    Ines leaps from her chair and squeals.
    ${gabby} opens ${g_their} arms to hug Ines, never taking ${g_their} eyes off you.
    "You didn't tell me you were coming today, you troublemaker!" Ines chides.
    
    "I didn't realize you would have guests," ${g_they} says.
    $!{g_their} eyes harden as ${g_they} turns back to you.
    Unlike ${g_their} grandmother, ${g_they} speaks with a posh British accent.

    "Come!
    Sit down, you will join us for tea."

    ${gabby} does as ${g_they}'s told and heads toward the divan, but Ines takes ${g_them} by the elbow and guides ${g_them} to the chair closest to you.
    "I can seat myself, gramère," ${g_they} complains.

    "Apparently not since you are bent on being anti-social.
    I thought you had outgrown that."

    $!{g_they} frowns.
    You suppress a laugh at ${gabby}'s expense and direct your attention to your 
    *if (var = "tea")
      tepid tea.
    *else
      tea cake.

    "But it matters not," she continues.
    "I will not abide it.
    [i]This[/i]—" she gestures to you, "is ${first_name}, the one I mentioned.
    $!{they_have} taken over Darbury Manor."

    You're surprised to see that ${gabby} is capable of frowning more deeply.

    "It's nice to meet you," you say in an even tone.
    *if (yr1_04_08_20_i = 3)
      As Ines prepares ${gabby}'s tea, you take the opportunity to discretely move the photo album to the side table next to you.

    When Ines settles back into her chair, the three of you descend into an awkward silence, one—if ${g_their} scowl is any indication—${gabby} has no intention of interrupting.
    Chouquette jumps into ${g_their} lap and makes herself comfortable.
    ${gabby} strokes the spoiled cat, whose purr relieves the tension in the room.

    "My sources tell me—" you say, glancing at Ines "—that you are a chef."

    "Yes," ${g_they} says shortly.

    Ines swats at ${g_their} arm.
    "Behave," she growls.

    $!{g_their} eyes flick back to you.

    *fake_choice
      #"All those long hours in the kitchen must have made you too tired for conversation," I joke.
        *set awk %- 5
        *set cha %+ 5
        You flash an insincere smile.
        "All those long hours in the kitchen must have made you too tired for conversation."

        ${gabby} rolls ${g_their} eyes.
      #"I see you have inherited your grandmother's charm," I retort.
        *set gen %- 5
        You roll your eyes.
        "I see you have inherited your grandmother's charm."

        ${gabby} scoffs.
      #I raise an eyebrow at ${g_them}.
        *set dir %- 5
        You raise a defiant eyebrow at ${g_them}.

        ${gabby}'s lips form a hard, thin line.
      #I wink at ${g_them} to get a reaction. ♥
        *set awk %- 5
        *set hum %- 5
        *set org %- 5
        *set bol +1
        *set g_rom +1
        A smile playing at your lips, you wink at ${g_them}.

        ${gabby}'s eyes widen in surprise for a brief moment before ${g_their} scowl returns in full force.
      #I purse my lips and return the glare. ♥
        *set cha %- 5
        *set hos +1
        *set g_rom +1
        You purse your lips and return the glare.

        *if (cha <= 40)
          ${gabby} narrows ${g_their} eyes at you, sizing you up.
        *else
          ${gabby} sips ${g_their} tea, unfazed by your disapproval.
      #$!{g_their} gaze unnerves me, and I look away. ♥
        *set hum %+ 5
        *set shy +1
        *set g_rom +1
        It's like ${g_they}'s looking [i]through[/i] you, and you feel an intense need to hide.
        Your eyes settle on your lap.
        When you work up the courage to glance ${g_their} way again, curiosity has tempered the hostility of ${g_their} appraisal, but only just.

    Ines harrumphes, and ${gabby} sighs before asking, "Where are you from?"

    "I lived in New York before I came here, but I was born in Valley Creek, Kentucky."

    "I have never heard of it."

    You cock your head at ${g_them}.
    "No, I don't suppose you would anymore than I had heard of Talverton."
    [i]Or La Chambre Rose[/i], you add to yourself.

    $!{g_they} purses his lips and shifts in ${g_their} seat.
    "I wonder that you decided to move here then."

    *if (var = "tea")
      You stir your tea, by now far too cold to drink, 
    *else
      You pick at your tea cake, by now a bit stale, 
    to buy yourself time to overcome your exasperation and figure out what to say.

    "${first_name} will be an excellent addition to the community," Ines says sharply.

    "I suppose we shall see."
    ${gabby}'s gaze settles on you again as ${g_they} sips ${g_their} tea.
    $!{g_they} flicks a nonexistent piece of lint off of ${g_their} leather jacket in a show of nonchalance.
    You nearly laugh at ${g_their} pretension.
    You bet he ${g_they} reads Jameson or Adorno.
    Maybe Foucault.

    The clock sitting above the fireplace chimes the half hour.
    "I suppose tea time is over now," Ines announces.
    "${gabby}, ${first_name} walked here.
    You will drive ${them} home."

    You meet each other's eyes,
    *if (g_rom >= 1)
      in yours a mixture of apprehension and anticipation;
      in ${g_theirs}—pure rebellion.
    *else
      in yours resignation;
      in ${g_theirs}—annoyance.

    "As you wish, gramère."

    *page_break
    As soon as the two of you exit through the front door, ${gabby} stops in ${g_their} tracks and turns to you.
    *if (g_rom >= 1)
      "Just because my grandmother has taken you in like a stray cat, don't think that you're welcome here."

      *gosub_scene mechanics_setup flirt_style
      *if (style != 3)
        You scoff.
        "Yeah, because you had made me feel so welcome otherwise."
      *else
        You gape at ${g_them}, not knowing how to respond.

      "Come," ${g_they} commands and sets off at a brisk pace down the sidewalk.

      You haven't yet decided whether being driven home by ${g_them} is a reward or punishment, but since ${g_they}'s walking in the direction you need to go, you follow ${g_them} anyway.
      As the two of you round the corner, ${g_they} comes to a stop in front of a restored, olive-green motorcycle.

      "Here," ${g_they} says, shoving a helmet into your hands.
      $!{g_they} straddles the bike.

      "What about you?" you ask, gesturing to the helmet.

      $!{g_they} sighs.
      "Are you going to get on or not?"

      *fake_choice
        #"Thanks for your very [i]generous[/i] offer," I sneer, "but I'll walk."
          *set gen %- 5
          You cross your arms.
          "Thanks for your very [i]generous[/i] offer, but I'll walk."
        #"I think I'd rather walk," I say and hand back the helmet.
          *set dir %+ 5
          *set g +1
          You thrust the unnecessary helmet back into ${g_their} arms.
          "I think I'd rather walk."
        #"As lovely as it's been," I say with a grin, "I think I'll walk."
          *set cha %+ 5
          *set g +1
          You flash a cheeky grin at the drama queen.
          "As lovely as it's been, I think I'll walk."
        #I follow ${g_their} lead and straddle the bike, resting my hands on ${g_their} waist. ♥
          *set yr1_04_08_20_i_g 2
          *set bol +1
          *set g_rom +1
          You grab the helmet and climb onto the back of the bike, resting your hands on ${g_their} waist.

          ${gabby} stiffens slightly at your touch, but then ${g_they} says, "Hold on."
        #I scowl at ${g_them} and climb on.  Accepting the offer is as much a punishment to ${g_them} as it is to me. ♥
          *set yr1_04_08_20_i_g 2
          *set hos +1
          *set g_rom +1
          You scowl at ${g_them} and nearly stick your tongue out.
          Before you stalk off though, you realize that accepting the ride will annoy ${g_them}, and you climb onto the bike.

          "Hold on," ${g_they} commands.

          You grip ${g_their} waist with a huff.
        #I put on the helmet and climb onto the back of ${gabby}'s bike. ♥
          *set yr1_04_08_20_i_g 2
          *set shy +1
          *set g_rom +1
          You accept the helmet and climb onto the bike.
          You try to create distance between youself and ${gabby}, but the small size of the seat makes it difficult.

          "You're going to have to hold on," ${g_they} says.
          You place your hands lightly on ${g_their} waist.
          $!{g_they} shakes ${g_their} head and sighs.
          "If you don't want to fly off, it's got to be tighter than that."

      *if (yr1_04_08_20_i_g = 0)
        "Suit yourself," ${g_they} says.
        $!{g_they} put on the helmet and kick the kickstand out of the way.
        The engine roars to life, and ${gabby} speeds away from you without a backwards glance.

    *else
      "You can find your own way home, I'm not a chauffeur."
      $!{g_they} strides away from you and turns the corner.

      "Nice to meet you too," you grumble to yourself.

      You hear an engine roar to life, and ${gabby} zips by on a motorcycle in a blur of motion.
      You shake your head.

  *elseif (yr1_04_08_20_i_g = 0)
    *page_break
    The clock sitting above the fireplace chimes the half hour, interrupting your conversation.
    "I suppose tea time is over," Ines announces with a slight frown.

    Her prim and proper adherence to archaic social norms—including regulating the length of social calls—amuses you, and you fight to hide a smile.
    "Thank you for having me," you say instead.

    Ines beams at you.
    "I was very glad you came.
    You will come again, oui?"
    The uncertain hope in her eyes tugs at your heartstrings and reminds you of your own grandparents.
    Guilt pulses through you at the thought that you are not visiting [i]them[/i].

    "If you'll have me," you say, trying to lighten your mood, "I'd be glad to come."
    
    She smiles at you in reply. 
    "I will be right back!"

    As she disappears into another room, you take a look around the sitting room once more.
    The furniture, an array of ornate and traditional styles, is a bit bulky—and floral—for your taste, but it creates a cozy effect and reminds you somewhat of visits to your great-grandmother's house deep in Appalachia.
    
    Ines glides back into the room with a small cardboard box tied up with a pink ribbon.
    "Leftover tea cakes," she says as she hands it to you.
    "I hope your ${alex} will enjoy them."

    You smile, thank her, and make your goodbyes.

  *else 
    *bug

  *if (yr1_04_08_20_i_g = 0)
    *set yr1_04_08_20_i_g 1
    *page_break
    You set off toward home, enjoying the sunny spring day as you go.
    A soft breeze wafts through the village, 
    *if (hair)
      picking up the loose strands of your hair and trying to carry them away.
    *else 
      and you get a whiff of honeysuckle.

    Not many people are out and about at this awkward time of day right before offices close, but cheerful conversations pour out of the open windows of the buildings you pass.
    As you walk you reach your hand out and brush it against the fences and walls, warm in the sun.

    You begin to whistle quietly, cycling through melodies that you know well.          

    *if (j >= 1)
      *page_break

      As you walk past [i]Sugar & Spice[/i], Judy waves from the window, and the next thing you know, the bell over the door tinkles, and she steps out into the street to see you.
      "${name}!
      How are you?"

      "Hi," you respond with a smile.
      "Ready to get home, how about you?"

      She nods and yawns.
      "I could go for a nap.
      What are you up to?"

      "I just came from tea with Ines."

      "Oh?" she asks, the pitch of her voice rising slightly.
      "How was that?"

      *if (yr1_02_05_20_i = 3)
        "I met ${gabby}.
        $!{g_they} was kind of a..."

        "Jerk?" Judy finishes for you.

        You laugh.
        *fake_choice
          #"A real peach," I quip.
            *set gen %- 5
            "A real peach," you say.

            $!{g_they}'s very intense," Judy agrees.
          #"I'm sure ${g_they}'ll come to love me like everyone else," I say.
            *set cha %+ 5
            *set hum %- 5
            *set per %- 5
            You grin.
            "I'm sure ${g_they}'ll come to love me like everyone else."

            Judy raises an eyebrow at you.
          #"$!{g_they} doesn't seem to like me, that's for sure," I laugh.
            *set dir %+ 5
            You laugh.
            "$!{g_they} doesn't seem to like me, that's for sure."

            "That's pretty normal," Judy says.
          #"$!{g_they} wasn't that bad," I shrug it off.
            *set yie %- 5
            You shrug.
            "$!{g_they} wasn't that bad."

            "If you say so," Judy responds.
        "I supply desserts and pastries to ${g_their} restaurant.
        $!{g_they} can be difficult."

        *if (cha >= 55)
          "At least I know dessert will be good if I ever go."
        *else
          "So it seems," you laugh.
        *if (g_rom >= 1)
          $!{g_they} offered me a ride home, but I figured a walk would be more pleasant, and it seems I was right.
          Much better company."
        *else
          "Ines volunteered ${g_them} to give me a ride home, but ${g_they} babied out.
          Can't say I regret it though.
          The company on the walk home has been far better."
          You grin at Judy, and she rolls her eyes, but a smile tugs at the corners of her mouth.
      *if (yr1_02_05_20_i != 3)
        "A little awkward," you admit.

        "Ines has always scared me—" Judy pinches her index finger and thumb together "—just a little."
        
        "She was definitely a sight to behold the first time I met her.
        She stormed the castle to tell me just exactly what I was doing wrong."

        Judy's eyes grow large.
        "You're braver than me."

        "I don't know about that," you laugh, "but it seems to have worked out.
        She invited me for tea after all."

        "Still, I can't say I envy you."
        
      Raising the cardboard box in front of you, you add, "At least I got some tea cakes out of it!"
 
      Judy wrinkles her nose.
      "Speaking of which, I ought to get back inside.
      Stop by soon, yeah?"

      "Sure thing."

    *page_break       

    As you reach the outskirts of the village, the trees and greenery become more prevalent than the stone buildings.
    Little white blossoms fall from the trees and coat the ground in a blanket of fragrant blooms.

    You breathe in deeply and close your eyes.
    Sometimes you miss New York, but not in these moments of peace and quiet.

    Crossing over the bridge, you take a minute to lean out over the wall and watch the water trickle by.
    Although you know that it's far too cold, you feel an urge to slide down the bank and wade in the creek.
    You can remember the sensation of cold, mossy stones against your bare feet when you played in the water as a child.
    Your grandfather had even built you a swing between the two banks.

    You smile and continue on your way.

  *elseif (yr1_04_08_20_i_g = 2)
    *gosub_scene mechanics_setup flirt_style
    The engine roars to life, and the two of you jerk forward.
    *if (style = 1)
      You grip the bike with your legs, bringing you closer to ${gabby}
    *elseif (style = 2)
      "If I fall off, I'm blaming you."
    *else
      You forget to be shy and grip ${gabby} for dear life.

      "Told you," ${g_they} says, and you can hear the smug satisfaction in ${g_their} voice.

    The countryside rushes past you in a blur of color, and you feel more than a little off balance—and out of place—on the back of ${gabby}'s bike.
    *if (g_taller = false)
      You also feel more than a little absurd clinging to ${gabby}'s shorter frame but not absurd enough to stop you. 
    *if (style = 1)
      "Anxious to get rid of me so quickly?" you ask  
    *elseif (style = 2)
      "I didn't come all the way out here to get killed by some idiot on a bike," you growl
    *else
      "Do we have to go so fast?" you ask, the pitch of your voice wavering, 
    as ${g_they} speeds up.

    $!{g_they} ignores you and speeds up even more.

    *page_break

    *if (style = 1) 
      "If I didn't know any better, I'd say you were afraid to talk to me," you taunt ${g_them} and suppress the laughter the bubbles up when ${g_their} posture stiffens.
    *elseif (style = 2)
      "If you get me killed, I'm gonna haunt you for the rest of your life!"
    *else
      You grip ${gabby} even more tightly and consider saying your own last rites.
    You close your eyes and focus on the feel of the wind in your face rather than the terrifying speed at which the two of you are hurtling through the village.

    The last time you did anything remotely like this, you were a dumb 15-year-old on the back of Alex's fourwheeler.
    $!{a_they} at least had some compassion for you.
    You hadn't even learned to drive until last year, and you continue to avoid it as much as possible.
    Even sitting in the back of a cab puts you on edge, but [i]there[/i] at least you have the comfort of knowing that you're enclosed in a steel cage.
    The only thing standing between you and the asphalt today is ${gabby}.

    *page_break

    You feel ${g_them} slow down, and you glance up to see Darbury come into view.
    $!{g_they} lets the bike coast the last few feet before coming to a gentle stop.

    As you climb off the bike, your hands are trembling.
    You take off the helmet
    *if (style = 1) 
      and hand it to ${gabby} with a smile, trying to conceal your frayed nerves.
    *elseif (style = 2) 
      and shove it into ${gabby}'s chest.
      The resulting [i]oof[/i] gives you great satisfaction, despite your frayed nerves.
    *else
      and hand it to ${gabby}.
      "Thanks for the ride," you say, your voice as shaky as your hands. 

    *if (g_rom >= 2)
      "Are you alright?" ${g_they} asks after a moment of hesitation.

      *if (gen <= 45)
        "Never better," you quip      
      *else
        "I'll be fine," you say
      before taking a deep breath to steady yourself.
      *if (gen <= 45)
        "Your concern is touching, truly."

        $!{g_they} scowls.
      *else

        $!{g_they} eyes you carefully.
      "My grandmother would not be pleased if you came to harm while you were with me." 

      "I'm fine," you insist, and it's beginning to become true as your heart rate slows down and your breaths even out.

      "If you say so," ${g_they} shrugs.
    $!{g_they} puts ${g_their} helmet on and turns back the way you came without another word.

    *fake_choice
      #I watch ${gabby} disappear down the drive way before going inside.
        ${gabby} speeds down the gravel drive way, a cloud of dust rising in ${g_their} wake.
        You watch ${g_them} disappear before turning to go in side.

        Shaking your head, you say, "What a day."
        You don't know whether to make head or tails of ${gabby} and ${g_their} grandmother.
        Two of a kind, for sure.
      #${gabby} looks back at ${first_name} before speeding away.
        ${gabby} speeds down the gravel drive way, wind tugging at the collar of ${g_their} leather jacket.
        $!{g_they} barely suppresses a groan.
        $!{g_their} grandmother has attempted to play matchmaker with ${g_them} before, but she must really be getting desperate to try to push this [i]American[/i] onto ${g_them}.

        *if (g_rom > 2)
          [i]At least ${theyre} kind of[/i]
          *if (gender = "f")
            [i]pretty[/i],
          *else
            [i]attractive[/i],
          ${g_they} thinks to ${g_them}self before shaking ${g_their} head.
          [i]Stop that[/i].

        ${gabby} frowns as ${g_they} recalls the last time gramère tried to set ${g_them} up with someone.
        *rand roll 1 2
        *if (roll = 1)
          *set var "she"
          She was the granddaughter of one of the old biddies in the Historical society.
        *else
          *set var "he"
          He was one of the new interns at the library.
        $!{var}
        *if (style = 1)
          wilted under ${gabby}'s every glance, could barely answer a question without a blush or stutter.
        *elseif (style = 2)
          agreed with everything ${gabby} said, laughed at all ${g_their} jokes.
        *else
          touched ${gabby}'s forearm and flashed him a sultry smile every time ${var} spoke.      
        It had begun to grate well before ${g_they} could finish the first drink.

        *if (g_rom > 2)
          [i]The American's nothing like that[/i], ${g_they} thinks.
          [i]Fuck[/i].        

  *elseif (yr1_04_08_20_i_g = 0)
    *bug

*set roll 0
*set var ""
*achieve tea
*page_break
*goto_scene story_20_04_15