*label stats

[b]Profile[/b]
*if ((hair = true) and (headscarf = false))
  *stat_chart
    text Name
    text hair_color Hair Color
    text eye_color Eye Color
    text skin_tone Skin Tone
    text height_d Height
*elseif ((hair = false) or (headscarf = true))
  *stat_chart
    text Name
    text eye_color Eyes
    text skin_tone Skin Tone
*else
  *bug

[b]Personality[/b]
*stat_chart
  opposed_pair awk
    Awkward
    Smooth
  opposed_pair cha
    Charming
    Intimidating
  opposed_pair dir
    Direct
    Subtle
  opposed_pair gen
    Genuine
    Sarcastic
  opposed_pair hum
    Humble
    Confident
  opposed_pair org
    Organized
    Spontaneous
  opposed_pair per
    Perceptive
    Reflective
  opposed_pair yie
    Yielding
    Stubborn

*choice
  #Farm stats.
    [b]Totals[/b]
    *stat_chart
      text ap_round Animal Points
      text cp_round Crafting Points
      text hp_round Harvest Points
      text rp Renown Points
      text qp Quest Points

    *fake_choice
      *if (farm_stats_yr1 = true)
        #View year one farm stats.
          --
      *if (farm_stats_yr2 = true)
        #View year two farm stats.
          --
      *if (farm_stats_yr2 = true)
        #View year three farm stats.
          --
      *if (farm_stats_yr2 = true)
        #View year four farm stats.
          --
      *if (farm_stats_yr2 = true)
        #View year five farm stats.
          --
      #Return to the stats menu.
        *goto stats

    *page_break
    *goto stats
  #Relationship stats.
    *if (meet_o)
      [b]Oliver Bates[/b]

      Judy's teenage cousin.
      Light skin, brown eyes, and strawberry blonde hair.
      *stat_chart
        text o Friendship

    *if (meet_b)
      [b]${bertie} Carroll[/b]

      The contractor you hired to renovate the castle.
      Lightly tanned skin, light green eyes, and short, dirty blonde hair.
      *stat_chart
        text b Friendship

    *if (meet_c)
      [b]Charlotte Carroll[/b]
      
      Your next-door neighbor and fellow farmer.
      Lightly tanned skin, blue eyes, and strawberry blonde hair.
      *stat_chart
        text c Friendship

    *if (meet_f)
      [b]${frankie} Carroll[/b]
      A local school teacher.
      Ivory colored skin, light brown eyes, and dirty blonde hair.
      *stat_chart
        text f Friendship

    *if (meet_g)
      [b]${gabby} Duchamp[/b]
 
      The chef and owner of the local restaurant, [i]La Chambre Rose[/i].
      Olive colored skin, hazel eyes, and curly, brown hair.
      *stat_chart
        text g Friendship

    *if (meet_i)
      [b]Ines Duchamp[/b]

      The president of the local historical society.
      Porcelain colored skin, brown eyes, and pearl-gray hair.
      *stat_chart
        text i Friendship

    *if (meet_r)
      [b]${rash} Khalef[/b]

      A local artist.
      Bronze colored skin, brown eyes, and long, black hair.
      *stat_chart
        text r Friendship

    *if (meet_z)
      [b]${zhenya} ${khitrov}[/b]

      Your business rival.
      Alabaster colored skin, ice-blue eyes, and short, blonde hair.
      *stat_chart
        text z Friendship

    [b]${alex} McNally[/b]
    
    Your best, childhood friend.
    Tanned skin, blue-green eyes, and wavy, brown hair.
    *stat_chart
      text a Friendship

    *if (meet_s)
      [b]Sebastian More[/b]

      The mayor of Talverton.
      Sable colored skin, brown eyes, and short, black hair.
      *stat_chart
        text s Friendship

    *if (meet_t)
      [b]${tony} Ruiz[/b]

      The owner and bartender at [i]Bar None[/i].
      Tawny colored skin, forest green eyes, and curly brown hair.
      *stat_chart
        text t Friendship

    *if (meet_j)
      [b]Judy Shaw[/b]

      The owner of the local bakery.   
      Beige colored skin, black eyes, and long, black hair.
      *stat_chart
        text j Friendship

    *page_break
    *goto stats
  *if (social_media = true)
    #Social media.
      *gosub_scene mechanics_setup social
      *page_break
      *goto stats
  #Other.
    What would you like to do?
    *choice
      #View changelog.
        *gosub_scene mechanics_setup changelog
        *page_break
        *goto stats
      #View cookbook.
        *gosub_scene mechanics_setup cookbook
        *page_break
        *goto stats
      #Toggle curses.
        What would you like to do?
        *fake_choice
          #Turn curses on.
            *set ass "ass"
            *set asshole "asshole"
            *set fuck "fuck"
            *set goddamnit "goddamnit"
            *set goddammit "goddamnit"
            *set shit "shit"
          #Turn curses off.
            *set ass "jerk"
            *set asshole "jerk"
            *set fuck "frick"
            *set goddamnit "dag nabbit"
            *set goddammit "dang flabbit"
            *set shit "sugar"
        *page_break
        *goto stats
      #View feedback suggestions.
        *gosub_scene mechanics_setup feedback
        *page_break
        *goto stats
      #Enter God Mode.
        *gosub_scene mechanics_god_mode god_mode
        *page_break
        *goto stats
      #View images and game lore.
        What would you like to do?
        *choice
          #View the the layout of Darbury Estate.
            *gosub_scene mechanics_setup layout
            *page_break
            *goto stats
          #View the map of Eprea.
            *gosub_scene mechanics_setup map
            *page_break
            *goto stats
          *if (collages = true)
            #View the collages I have collected.
              *gosub_scene mechanics_setup collages
              *page_break
              *goto stats  
          #Toggle image descriptions.
            Would you like to turn image descripts on or off?
            *fake_choice
              #Turn image descriptions on.
                *set image_description true
                *page_break
                *goto stats
              #Turn image descriptions off.
                *set image_description false
        *page_break
        *goto stats
      #View important links.
        *gosub_scene mechanics_setup links
        *page_break
        *goto stats
      #Change pronouns.
        *gosub_scene mechanics_setup pronouns
        *page_break
        *goto stats
      #View the Q&A.
        *gosub_scene mechanics_setup q_a
        *page_break
        *goto stats
      #Return to the previous page.
        *page_break
        *goto stats