*temp question_count 0
*gosub_scene cslib_string find history "prologue_reached_houtian|"
*if cslib_ret > 0
	For the second time, the crowd exists in a state of astonished silence. They gawk at you, not knowing how to react. Not only have you accomplished the unimaginable upset — prevailing over the imperial heir — you also have reached Houtian, the realm of true martial artists, without any preparation or alchemical help. 
	
	[i]"The First Emperor has reincarnated…"[/i]
	
	The simple phrase, said by a random noble, stirred the crowd into a hum of whispers that soon morphs into shouts and screams. 
	
	[i]"$!{pronoun_1}'s the second coming of the Living God!"[/i]
	
	[i]"A new era, a new era is coming…" 
	
	[i]"Shut up. The Prince only lost because he fought without his sword. I'm not sure he's trained fist techniques at all."
	
	[i]"You guys need to stop exaggerating. The Wu Clan heir won by a stroke of luck. Even then, the Prince could keep up the pace with ${pronoun_2} until ${pronoun_1} used ${pronoun_2} Inner Energy."
	
	[i]"Phh, should I bring you his shoes to lick? Bunch of ass-kissers."
	
	[i]"Both of them have a chance at reaching Shangtian, right?"
	
	[i]"So many geniuses in a single year… That zombie guy, the savage, the Prince and ${YM} ${mc_name}. Heavens, their competition is going to be insane." 
	
	[i]"Yeah… How unlucky are we to be in the same generation?"
	
	"QUIET!" — yells He Jun and the excitement of the crowd dies down. 
	
	"The tourney is over. The winner is…" — he turns to you and you notice how unstable his emotions are. He didn't expect you to win, knowledgeable enough about the Prince's prowess. You have a feeling that
	*gosub_scene cslib_string find history "hejun_proposition"
	*if cslib_ret > 0
		if you don't talk to him in the sect, he would turn hostile and do everything in his power to eliminate you.
	*else
		he would do everything in his power to eliminate you. 
	— "Wu ${mc_name}. $!{pronoun_1} will be granted an artifact of ${pronoun_2} choice from the Sect Treasury. Also, as promised, both ${pronoun_2} and Tang Ruo will be granted statuses of Inner Disciples." 
	
	"Third place goes to Yuan Fang, fourth to the Tigress." — he continues. 
	
	Yuan Fang, the cunning zombie, gave up on his fight with the Prince to avoid any detriments to his fighting ability: as result, he, in his prime condition, fought against the still injured and exhausted Tigress. 
	
	It was a very convincing victory. 
	
	You also watch out for the Jing Guo's name, but he hasn't even reached top ten, finding himself in a 17th position instead. 
	
	"Get your things in order. We'll be flying to the sect in half an hour."
	
	*gosub_scene subroutines prestige_change 60 "+"
	*gosub_scene subroutines give_exp 50 ""
	*goto dialogue_during_flight
	
*gosub_scene cslib_string find history "tourney_tigress_victory"
*if cslib_ret > 0
	Although you've lost your bout against the imperial prince, you still have reached the second place amongst two hundred of participants — a very impressive result, one that you can be proud of.
	
	"The tourney is over." — announces He Jun — "The winner is Tang Ruo, the Celestial Heir."
	
	His statement stirs the crowd, causing it to erupt in a hum of whispers. 
	
	[i]"As expected…"
	
	[i]"No one can defeat him amongst our age group. That guy is insane."
	
	[i]"He might have a chance at reaching Shangtian, right?"
	
	[i]What about ${YM} of the Wu Clan? $!{pronoun_2} affinity seemed to be even higher…
	
	[i]So what? Three percent do not make much of a difference. Tang Ruo won against Wu ${mc_name} now, and will wipe the floor with ${pronoun_2} again in the future.
	
	[i]Still, isn't our generation a bit too insane? The Zombie, who, although of average affinity, wields insane strength with his mutated body. The savage barbarian-woman, the ${YM} ${mc_name}, Tang Ruo… How can we compete against them?
	
	"QUIET!" — yells He Jun, his shout killing the excitement of the nobles— "Second place goes to Wu ${mc_name}. As promised, both of them will be taken in as Inner Disciples."
	
	"Third place — Yuan Fang. Fourth place —the Tigress."
	
	Yuan Fang, the cunning zombie, gave up on his fight with the Prince to avoid any detriments to his fighting ability: as a result, he, in his prime condition, fought against the still injured and exhausted Tigress. 
	
	It was a very convincing victory. 
	
	You also watch out for the Jing Guo's name, but he hasn't even reached top ten, finding himself in a 17th position instead. 
	
	"Get your things in order. We'll be flying to the sect in half an hour."
	*goto dialogue_during_flight

*gosub_scene cslib_string find history "prologue_tourney_lost_xiaochun"
*if cslib_ret > 0
	"The tourney is over." — announces He Jun — "The winner is Tang Ruo, the Celestial Heir."
	
	His statement stirs the crowd, causing it to erupt in a hum of whispers. 
	
	[i]"As expected…"
	
	[i]"No one can defeat him amongst our age group. That guy is insane."
	
	[i]"What about ${YM} of the Wu Clan? $!{pronoun_2} affinity seemed to be even higher…"
	
	[i]"HAHA THAT GUY? Isn't ${pronoun_1} the loser who got beaten by the Xiao kid? You think ${pronoun_1}'ll rival Tang Ruo? What a joke."
	
	[i]"Still, isn't our generation a bit too insane? The Zombie, who, although of average affinity, wields insane strength with his mutated body. The savage barbarian-woman, Tang Ruo… How can we compete against them?"
	
	"QUIET!" — yells He Jun, his shout killing the excitement of the nobles — "Second place goes to the Tigress. As promised, Tang Ruo will be given the status of an Inner Disciple. ${YM} ${mc_name} on the other hand…"
	
	He Jun gives you a look of contempt. Staring at you with such disdain, such mocking that it causes the deep hidden rage inside you to erupt… Alas, you can only suck it up in silence: the Martial World respects strength and you have shown none of it.
	
	"In truth, a weakling like you has no place in the Heavenly Ascension Sect." — says He Jun. 
	
	You heart sinks. Can it be, that you will be the first in generations of your clan not to get accepted in a Heavenly Sect? Even with your absurd affinity?
	
	"Unfortunately, the Heavens have blessed you with a talent that we cannot ignore. You will be accepted, as a rare exception."
	
	He Jun then turns away and continues listing the top-fifty participants of the tourney: the Immortal Zombie finished fourth, while Jing Guo found himself in a 16th position. The guy you lost to, Xiao Chun, was eliminated in the following your fight round.
	
	"Get your things in order. We'll be flying to the sect in half an hour."
	*goto dialogue_during_flight
*else
	"The tourney is over." — announces He Jun — "The winner is Tang Ruo, the Celestial Heir."
	
	His statement stirs the crowd, causing it to erupt in a hum of whispers. 
	
	[i]As expected…
	
	[i]No one can defeat him amongst our age group. That guy is insane. 
	
	[i]"He might have a chance at reaching Shangtian, right?"
	
	[i]What about ${YM} of the Wu Clan? $!{pronoun_2} affinity seemed to be even higher…
	
	[i]I'm not sure. $!{pronoun_1} beat a couple of people, but couldn't even get past the barbarian woman. Would ${pronoun_1} be able to rival Tang Ruo? 
	
	[i]Still, isn't our generation a bit too insane? The Zombie, who, although of average affinity, wields insane strength with his mutated body. The savage, the ${YM} ${mc_name}, Tang Ruo… How can we compete against them?
	
	"QUIET!" — yells He Jun, his shout killing the excitement of the nobles — "Second place goes to the Tigress. As promised, Tang Ruo will be given the status of an Inner Disciple. ${YM} ${mc_name} on the other hand has not displayed sufficient prowess to deserve such treatment."
	
	He Jun then continues listing the top-fifty participants of the tourney: the Immortal Zombie finished fourth, while Jing Guo found himself in a 16th position.
	
	"Get your things in order. We'll be flying to the sect in half an hour."
	*goto dialogue_during_flight
	
	
*label dialogue_during_flight

He Jun whistles and the sound soon attracts a literal swarm of enormous, though not as large as the previous three, mosquitoes. 

"You'll be traveling on these beasts. Each of them can carry two people, find yourself a pair."
*page_break Flight Preparation
The fifty or so people spread out between the mosquitoes, each attempting to find one bigger size. They mount the beasts, under the watchful gaze of the Martial Artists from the sect who, from time to time, have to calm the getting rowdy insects. 

Who do you want to ride with?
*temp tangruo_condition false
*temp jingguo_condition false
*temp meimei_condition false
*temp tigress_condition false
*gosub_scene cslib_string find history "prologue_reached_houtian"
*if cslib_ret > 0
	*set tangruo_condition true
*gosub_scene cslib_string find history "hejun_proposition"
*if cslib_ret > 0
	*set meimei_condition true
*if characters_5_opinion > 50
	*set tigress_condition true
*if characters_3_opinion > 50
	*set jingguo_condition true
*choice
	*selectable_if (tangruo_condition) #Ride with Tang Ruo.
		You find the Prince near the biggest mosquito. He isn't in a hurry to get on it: instead, he sits on the ground, cross-legged and with eyes closed. All the other nobles dare not to climb their own beast before the imperial heir does, dreadful of causing an unintentional offense. After all, the Prince might have lost to you — in a battle that many would consider inconclusive — but none of these people are qualified to clean his shoes, much less insult him. 
		
		As you come close,
		*if characters_4_opinion > 50
			the Prince opens his eyes and gives you a small smile that accentuates his perfect, almost deity-like features. He then gets up and gestures you to the mosquito. 
		*else
			the Prince opens his eyes and scowls, but gets up without causing a fuss. He gestures you to the mosquito.
		
		"After you." 
		
		"You letting me go first?" — you ask in wonder, not understanding what has brought on this courtesy. 
		
		The Prince nods. 
		
		"By the right of victory."
		
		Before you can answer him, a commotion happens near one other beast. You see the Tigress pouncing between the nobles, claiming their lives with her claws: however, before you can even decide if you want to interfere, He Jun flicks her forehead and causes her to go unconscious. What was that about, you wonder?   
		
		Never mind. That's a problem for another day. For now, you should just respond to Tang Ruo.
		*gosub_scene subroutines change_opinion 4 1 "+"
		*choice
			#"That's right. Don't forget that you have lost to me." 
				*gosub_scene subroutines change_personality 1 "arrogant" "+"
				Tang Ruo snorts, your arrogant words provoking an intense, challenging glare from his violet eyes. The sword flying above him hums with passion to take part in your rematch, but Tang Ruo reaction does not go further than his fierce stare. 
				
				"True. Enjoy your victory while you can. I'll come after you as soon as I undergo Houtian and, believe me, it's not going to be long."
			#"We both know that you haven't gone all out."
				*gosub_scene subroutines change_personality 1 "arrogant" "-"
				"It doesn't matter." — Tang Ruo replies — "I've made my choices in that fight and since those choices have led me to defeat, I will accept it. Don't get too complacent, however. I'll come after you as soon as I undergo Houtian."				
			#"I don't really care about whether I'm the first to board the mosquito or not."
				*gosub_scene subroutines change_personality 1 "impulsive" "-"
				"I do." — the Prince replies — "Order and hierarchy are paramount in our society. Since I've lost, it's up to you to lead the way. Don't get too complacent, however, since I'll come after you as soon as I undergo Houtian."
			#"I think we should make all the commoners ride on the smallest mosquitoes."
				*gosub_scene subroutines change_personality 2 "elitist" "+"
				"Do as you wish." — Tang Ruo replies — "All of this trash is the same to me."
				
				You go through the line of sixteen odd people, placing them in order that depends on the nobility of their background. The few commoners presents — the ones who should be tremendously talented if they've managed to reach this step — are not happy, but none have the courage to retort.
				
				*gosub_scene cslib_string find history "hurt_xiaochun"
				*if characters_9_opinion <= 100
					Except for a young ${ai_pronoun_4} with black hair gathered in a ponytail.
					
					You recognize ${ai_pronoun_2} as Ai, the same person who helped Xiao Chun after you hurt him during your bout. 
					
					"You again?" — you snort — "Have you decided to be a constant pain in my ass?"
					
					"All I do is fight for fairness, ${YM}. Why should we fly on beasts inferior to the nobles when we have displayed a higher talent?"
				*else
					*set ai_pronoun_1 "she"
					*set ai_pronoun_2 "her"
					*set ai_pronoun_3 "hers"
					*set ai_pronoun_4 "woman"
					Except for a young ${ai_pronoun_4} with black hair gathered in a ponytail.
					
					"${YM}, isn't it this unfair?" — ${ai_pronoun_1} asks you.
					
					"Who are you?"
					
					"My name is Ai. ${YM}, please, explain to me why should we fly on beasts inferior to the nobles when we have displayed a higher talent?" 
					
					*set characters_9_opinion 50
					[b][i]Ai[/i] added to Character Glossary[/b]
					
				*choice
					#"Because they have the blood of great ancestors flowing through their veins."
						*gosub_scene subroutines change_personality 1 "elitist" "+"
						"But the divine blood flows in us too! You saw it in the test yourself!" — ${ai_pronoun_1} replies. ${ai_pronoun_2} voice boosts in volume, until ${ai_pronoun_1}'s almost screaming in indignity. 

						"But you [i]do not[/i] have their upbringing. Enough. I will not debate semantics with you."

						"Well," — ${ai_pronoun_1} says, crossing ${ai_pronoun_2} arms and giving you a defiant look — "I'm still going to use a mosquito corresponding to my tourney position."
						*label ai_beating_choice
						*choice
							#"All of you allow this impudence?" — you turn to the nobles.
								*label group_beating
								*gosub_scene subroutines change_personality 2 "violent" "+"
								*gosub_scene subroutines change_personality 1 "ruthless" "+"
								The nobles were already quite ill-disposed towards the common folk — it's hard not to be, when you're told from childhood that they are the lesser people — and your question riles them even more.

								"These commoners are getting so fucking insolent." — one of the nobles, a ginger with cheeks full of freckles, gobs. The others murmur in agreement. 

								"And what are you going to do about it?" — you grin, taunting them further. 	

								Emboldened by your attitude, the noble who spoke returns your grin. He walks to Ai and then punches ${pronoun_2} right in the face. $!{ai_pronoun_1} dodges, jumping backwards, but agility does not matter much in a crowd this dense: ${ai_pronoun_1} collides with a few other nobles. They, seeing the situation develop, grip ${ai_pronoun_2} arms.

								"Stop this nonsense!" — ${ai_pronoun_1} yells — "Let me g-"

								The ginger silences ${ai_pronoun_2} with another punch. And another. He strikes ${ai_pronoun_2} two more times, bloodying ${ai_pronoun_2} face, before the group throws Ai to ground and starts kicking ${ai_pronoun_2} without mercy. More nobles soon join them, releasing their frustrations — for a bad performance in the tourney or the pent-up pressure from their families — onto Ai, who, curled up into a ball, tries to protect ${ai_pronoun_2} most vital areas. 

								You catch He Jun watching, but the one responsible for order and discipline amongst the new disciples clearly doesn't care to stop the beating. In fact, he seems to consider it deserved, even.

								"Alright, that's enough." — you command. The nobles give ${ai_pronoun_2} a few of farewell kicks and a couple of parting spits.

								As the commoners struggle to get Ai up, you halt the ginger by putting your hand on his shoulder.

								"What's your name?"

								"Fu Bing."

								"Good. I'll remember you." 

								You mount the giant mosquito and others follow suit. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.

								*set characters_10_opinion 50
								[b][i]Fu Bing[/i] added to Character Glossary.
								*set history history&"ai_group_beating"
								*gosub_scene subroutines change_opinion 9 100 "-"
								*set characters_9_status "Hostile"
								
								*gosub_scene subroutines reputation_change 15 "kindness" "-"
								*goto flight_to_the_sect_tangruo
							#Let her do as she wishes.
								*gosub_scene subroutines change_personality 1 "arrogant" "-"
								"Fine. I don't care." — you answer. 

								The nobles around you deflate and murmur in unhappiness, but Ai grins, no doubt happy with ${ai_pronoun_2}self. 

								You mount the giant mosquito and others follow suit. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
								*goto flight_to_the_sect_tangruo
							#Slap her.
								*label slap_ai
								*gosub_scene subroutines change_personality 1 "violent" "+"
								*gosub_scene subroutines change_opinion 9 30 "-"
								"Your audacity tires me."  — you answer, lift your hand and smack ${ai_pronoun_2} right in the face. $!{ai_pronoun_2} head almost spins from the power of your palm, its red print as visible as the shining sun in the cloudless sky. 

								Ai caresses ${ai_pronoun_2} cheek. $!{ai_pronoun_1} turns ${ai_pronoun_2} eyes, full of rage and accusation, on you.

								"You've struck me?!"
								
								*gosub_scene subroutines reputation_change 5 "kind" "-"

								Incredible. How bold can a commoner be?

								*choice
									#"I don't think she understood her lesson." — you hint to the nobles.
										*goto group_beating
									#"Get back in line before I do something worse." 
										$!{ai_pronoun_1} sneers.

										"Fucking nobles…" — ${ai_pronoun_1} whispers under ${ai_pronoun_2} breath as ${ai_pronoun_1} returns to ${ai_pronoun_2} place at the end of the queue. 

										You mount the giant mosquito and others follow suit. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
										*goto flight_to_the_sect_tangruo
					#"Because I said so."
						*gosub_scene subroutines change_personality 1"arrogant" "+"
						"And? Since when has your word become the law?"

						"Since I reached Houtian." 

						"Well, then I'll be committing a crime." — ${ai_pronoun_1} says, crossing ${ai_pronoun_2} arms and giving you a defiant look.
						*goto ai_beating_choice
					#"Shut the fuck up and get back in line."
						*gosub_scene subroutines change_opinion 9 2 "-"
						*gosub_scene subroutines change_personality 2 "impulsive" "+"
						"No." — ${ai_pronoun_1} says, crossing ${ai_pronoun_2} arms and giving you a defiant look — "I'm going to use a mosquito corresponding to my tourney position."
						*goto ai_beating_choice
					#Slap her. 
						*goto slap_ai
		
		"We'll see." — you chuckle — "Don't fall too far behind." 
				
		You mount the giant mosquito and others follow suit. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air. 
		*label flight_to_the_sect_tangruo
		*page_break Flight To The Sect.
		*gosub flight_text
		Tang Ruo a few questions.
		*temp goal_in_sect false
		*temp particular_elder false
		*temp bethrothed_question false
		*temp grandfather_question false
		*temp eyes_question false
		*temp advice_question false
		*label questions
		*if question_count = 2
			
			Your journey is halfway done: you'll be able to ask Tang Ruo a couple of questions more at most.
		*if question_count = 3
			
			The peak of the mountain and, therefore, the end of your flight is close. You can only ask one more question.
		*if question_count = 4
			*page_break Arrive In The Sect
			*goto sect_arrival
		*choice
			*selectable_if (not (goal_in_sect)) #"What's your goal in the sect?"
				"Isn't it obvious?" — he replies, confused as to why you would even ask him this — "To reach the peak of Martial Arts and achieve Shangtian."
				
				"Will you try for the Prime Disciple position?"
				
				"I do not need to try. It is already mine." — says Tang Ruo, but then hesitates as he realizes you are seated in front of him — "Though I guess with you present, there's going to be some competition." 
				*set goal_in_sect true
				*set question_count +1
				*goto questions
			*selectable_if (not (particular_elder))			#"A particular Elder in mind whom you want to study under?"
				"Elder Jian, of course." — he answers. 
				
				"Why?"
				
				"He's best the practitioner of the sword in the sect. Although he can't match my aunt — nobody can — their styles vary greatly. It's a necessity for me to learn the way of the blade from different sources, if I wish fuse them into the most absolute form of swordplay." 
				
				An intense, burning ambition burns inside his eyes.
				
				"And I do desire to accomplish that."
				*set particular_elder true
				*set question_count +1
				*goto questions
			*selectable_if (not (bethrothed_question)) #"Are you betrothed?"
				"I'm not." — he says — "Marriage should only happen between equals: and there is no one my age who I'd consider one."
				
				An awkward silence descends, both of you not sure what to say further, before Tang Ruo continues.
				
				"I do have half a dozen of concubines, however." 
				
				This immediately piques your interest. 
				
				"Oh? And what would you do with them if you find your 'equal'?
				
				Tang Ruo shrugs his shoulders.
				
				"Depends on my spouse's wishes. Keep them, get rid of them — I don't particularly care."
				*set bethrothed_question true
				*set question_count +1
				*goto questions
			*selectable_if (not (grandfather_question)) 			#"Is your grandfather well?"
				There have been rumors going around the Empire for a better part of the last decade: the strongest man under the Heavens, the undisputed number one expert of the world was battling against time itself. And it wasn't a battle that he, or anybody else could win. The 1500-year old Tang Yichen hasn't been seen in public for over two years and seemed weak, frail before that.
				
				However, none of the old monsters lurking in the world dared to test his lack of visible strength. The tyranny of the Dragon Taming Emperor is not something that could be forgotten in a century, much less these measly ten years or so.
				
				"He's fine." — Tang Ruo responds — "My grandfather might be old, but he's still full of vigor. He grew tired of the mortal matters and decided to seclude himself in the Divine Palace."
				
				Although Tang Ruo's words carry an impassive tone, his voice is almost too indifferent: as if the absence of emotion was a mask meant to protect his sincere feelings from leaking into his speech. 
				
				You decide not to press the matter further.
				*set grandfather_question true
				*set question_count +1
				*goto questions
			*selectable_if (not (eyes_question)) #"What's up with those reptilian eyes you had?"
				Tang Ruo fixes you with a gaze. An authoritative, imperious, near oppressive gaze that reminds you of the look he gave you during your fight — right before he effortlessly thrashed you in your non-Houtian state.
				
				Only this time, you feel a far bigger threat — your recent advancement having no effect on your screaming danger instincts. 
				
				"Don't ask that again." — he warns, before lifting the suffocating pressure. 
				*set eyes_question true
				*set question_count +1
				*goto questions
			*selectable_if (not (advice_question)) 			#"Do you have any advice for me?"
				"Train more." — the Prince suggests — "Don't waste your time on useless things. Money, status, connections, artifacts — all of this doesn't matter in the face of true power." 
				
				"Believe me, for I've seen what real strength can do." — he continues. His expression becomes reminiscing, with hints of a sad smile tugging at his lips — "My grandpa, at his peak…"
				
				He shakes his head.
				
				"Never mind. Just don't squander your talent." 
				*set advice_question true
				*set question_count +1
				*goto questions
		
	*selectable_if (tigress_condition) #Ride with the Tigress.
		*temp sect_punishment false
		You see a commotion near one of the insects. The Tigress, her tall, muscular frame easily found amidst the crowd, holds one of the nobles by the neck, his feet dangling in the air. 
		
		"Try it, [i]animal[/i]." — the noble grins, as the Tigress pushes her metallic claws into his throat — "Hurt me and see what happens." 
		
		The Tigress looks around. Nobles all around her regard her with hostile gazes, emboldened by their sheer numbers. She snarls, but the nobles pay no heed to the bestial sounds. He Jun, who watches the situation from the side and doesn't have much love for commoners, much less barbarians, also pressures her into releasing the noble. 
		
		"What happened here?" — you interrupt their confrontation. 
		
		The Tigress's head makes a sharp turn and notice her relief once she realizes it was you who spoke, not another unfamiliar to and prejudiced against her young scion. 
		
		"Someone has an extra tongue." — she answers. 
		
		"A savage should know its place." — says the noble. His face, marked by freckles, never losing its conceited smirk — "Don't you agree, ${YM}?" 
		
		"Who are you?" — you ask the target of the Tigress's rage, wondering who would have enough guts to insult the insane woman to her face.
		
		"Fu Bing."
		
		*set characters_10_opinion 50
		[b][i]Fu Bing[/i] added to Character Glossary.
		
		*choice
			#Stay out of this.
				*gosub_scene subroutines change_personality 1 "impulsive" "-"
				This is not your problem to solve. The Tigress is a grown woman and she can deal with her own troubles herself.
				
				Understanding that she will find no support in you, the Tigress judges the situation with the utmost clarity her ferocious nature can allow: a dozen of nobles ready for a fight, a Sect Envoy who looks for a justification to cause her difficulties…
				
				At one second, she's stuck in indecision — at another, she cackles like a woman possessed.  
				
				"You want to bully the Tigress? Let's see if you are qualified!"
				*label kill_fubing
				
				Her claws slash Fu Bing's throat. As the noble's eyes go wide in shock in horror, the Tigress pierces his stomach with her other hand. She then throws him to the side — to his certain death — and jumps straight into the fray, her blades reaping lives left and right. She manages to bring five unprepared for her brutality silkpants down, before she's overpowered by the crowd and restrained. Four nobles hold her limbs, while another two kick her without mercy. The Tigress struggles, but will means nothing without strength. With every kick, her struggles become weaker, until one of the nobles stomps her face with his boot and she goes limp.
				
				The nobles sigh out in relief. They look at their friends, who a minute ago were alive and jovial, yet now lie dead on the cold ground. Most of them express regret — a trivial insult surely wasn't worth a life and death scenario — but such is the way of the Martial World: a wrong word to a wrong person may very well lead to a lethal outcome. 
				
				One noble, however, feels [i]rage[/i] instead of sadness. He raises his leg and prepares to stomp the Tigress again, when she suddenly opens her eyes, wiggles out of the now-complacent attackers' grasp and and sweeps his leg with hers. The noble falls and the Tigress climbs upon of him. Her blades cut through his body like a mad painter waves her brush at the canvas. Covered in blood, she licks her lips and laughs. 
				
				The nobles, terrified, step back and watch how she tears skin and meat from their companion's chest. 
				
				"That's enough, little beast." — says He Jun, who grabs her by her long braid and [i]yanks[/i] her backwards. The Tigress tries to pounce on him too, but the Sect Envoy simply flicks her forehead and the light in her eyes disappears in an instant. 
				
				"All of you, disperse. The show's over." — He Jun orders the the nobles.
				
				"But, Sect Envoy, she kill-"
				
				"Take it up with her in the sect. Get revenge, involve your families, I don't care. This matter is done for now."
				
				He Jun ignores their complaints and walks back with a self-satisfied smile.
				
				*gosub_scene subroutines stat_check "int" 7
				*if (stat_check)
					You shake your head. This scheme of his is quite genius: he stood by while the Tigress with every swipe of her claws sown irreversible grudges with noble clan after noble clan. Now, should his He Clan offer her protection — which she no doubt will need — the Tigress would have no choice but join them. 
					
					Gaining a monstrous talent by doing nothing — This He Jun cannot be described as 'simple'. 
				*else
					You wonder why didn't He Jun intervene earlier? The Tigress is a monstrous talent, a great addition to the sect. Sadly, your mind cannot come up with a sufficient explanation.
					
				[b][i]Fu Bing[/i] has died.[/b]
				*set characters_10_alive false
				*set history history&"fubing_killed_prologue_tigress|"
				
				Since the Tigress is not available, you will have to ride with a random companion.				
				*goto flight_alone
						
			#Tell the Tigress to let Fu Bing go.
				"What?" — the Tigress exclaims — "Do all of you think the Tigress is easy to bully?"
				
				Her hand constricts, the blades attached to her fingers one action away from cutting Fu Bing's neck open. 
				
				*choice
					#Force her to let go. How dares she attack a noble?
						*gosub_scene subroutines change_opinion 5 7 "-"
						*gosub_scene subroutines change_personality 2 "elitist" "+"
						"You seem to misunderstand: I wasn't asking." 
						
						*gosub_scene cslib_string find history "tourney_tigress_victory"
						*if (cslib_ret > 0) or (tangruo_condition)
							The Tigress growls, but the prowess you displayed in the tourney is still fresh in her memory. 
							
							"Fine."
							
							She throws Fu Bing to the side, turns away and climbs the mosquito. 
							
							Fu Bing chuckles, as he caresses his nearly lacerated throat.
							
							"Thought so. Someone needs to teach these savages a lesson." — Fu Bing says — "Thank you for assistance. Although I'm not as talented as ${YM}, I'm an… unscrupulous person. I would gladly join your faction, should you need my services." 
							
							The Tigress does not converse with you, so you'll have to ride without a companion.
							*set history history&"prologue_tigress_nokilling|"
						*else
							"Words of the weak are empty air."
							*goto kill_fubing
					#Reason with her.
						*gosub_scene subroutines change_personality 1 "violent" "-"
						You put a hand on her shoulder — the Tigress recoils, not used to contact outside of battle — but you still lean forward and whisper into hear ear. 
						
						"Look around. You can't kill him here, not unless you wish to become the mortal enemy of a dozen clans in an instant. Let him go for now, you'll get your justice later on." 
						
						*gosub_scene subroutines stat_check "chr" 7
						*if (stat_check)
							
							The Tigress growls, but eventually nods. Your words make sense to her, your reasoning is something that she herself has already considered: it's her ferocious nature that didn't allow her to back down despite understanding the grave consequences.
							
							She throws Fu Bing to the side, turns away and climbs the mosquito.
							
							Fu Bing chuckles, as he caresses his nearly lacerated throat. 
							
							"Thought so. Someone needs to teach these savages a lesson." — Fu Bing says, before bowing to you — "I will be seeing you, ${YM}." 
							
							You decide it's time to mount the giant mosquito. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
							*set history history&"prologue_tigress_nokilling|"
							*goto flight_tigress
						*else
							She just snorts at your remarks.
							
							"The Tigress is not afraid of trouble."
							*goto kill_fubing
					#Let her do as wishes.
						You give up — persuading this woman is as the difficult as convincing a mountain to change location. 
						
						*goto kill_fubing
			#Tell Fu Bing to apologize. 
				*gosub_scene subroutines change_opinion 5 1 "+"
				"Your behavior is unbecoming of your noble status." — you scold Fu Bing — "Apologize." 
				
				"What?!" — he exclaims, shocked that you would rather support a savage from the wild tribes then a fellow aristocrat — "I'm not going to do that!"  
				
				*choice
					#"Stop making a scene."
						*gosub_scene subroutines change_personality 2 "violent" "-"
						You glance at him in contempt: the Tigress holds him as if he was a child and the fool thinks his provocation are worth be proud about. 
						
						"Apologize and move on." — you say, gesturing at him — "This is embarrassing." 
						
						*gosub_scene subroutines stat_check "chr" 8
						*if (stat_check)
							Confident and taunting a second ago, now Fu Bing feels nothing but shame. You words convinced him that instead of support and encouragement, other nobles only cast him gazes of ridicule.
							
							*label fubing_apology
							
							"I'm sorry…" — he stammers. For someone like him, a young master of a prominent clan, apologizing is certainly not a skill he has practiced well. 
							
							"I can't hear you." — you prompt.
							
							"I'm sorry!"
							
							"That's better." — you turn to the Tigress —  "Now, put him down. He's humiliated enough."
							
							The Tigress snorts, but listens. She lets him go and Fu Bing drops to the ground, before hastily getting up and scurrying away.
							
							You and the Tigress mount the giant mosquito. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
							*set history history&"prologue_tigress_nokilling|"
						*else
							"I said I'm not going to do that."
							
							"Heavens, the Tigress grows tired of his yapping."
							
							*goto kill_fubing
					#Threaten him.
						*gosub_scene subroutines change_personality 1 "violent" "+"
						"You seem to misunderstand. I wasn't asking." 
						
						You both stare at each other: you at him with command in your gaze and he at you with defiance. 
						
						Soon, the status of your clan overwhelms his pride. He bows down his head.
						
						*goto fubing_apology
					#Slap him.
						*gosub_scene subroutines change_personality 2 "violent" "+"
						You do not mince words: instead, you smack him right on the face.
						
						"You! How da-"
						
						You slap Fu Bing again.
						
						In indignity, Fu Bing looks around in search for support, but finds none: your status is higher than that of anyone nearby, and these nobles naturally would not provoke you for a measly Fu Bing. 
						
						Understanding his situation, Fu Bing bows down his head.
						
						*gosub_scene subroutines reputation_change 5 "kind" "-"
						
						*goto fubing_apology
				
				
			*selectable_if (tangruo_condition) #Kill Fu Bing.
				*gosub_scene subroutines change_personality 4 "violent" "+"
				*gosub_scene subroutines change_opinion 5 5 "+"
				*set characters_10_alive false
				*set history history&"fubing_killed_prologue_mc|"
				You don't know why, but this noble invokes in you the desire for murder. Perhaps it's the cockiness of his smile, perhaps the condescension for the common folk or, perhaps, you just don't like the way he treats the Tigress: you can't and you won't suppress this urge.
				
				"Put him down." — you say to the Tigress.
				
				"What?" — she reacts — "No! No one bullies the Tigress!"
				
				You nod at her.
				
				"Of course not. Trust me." 
				
				She stares at you, in defiance at first, but seeing the sincerity behind your eyes, she relents. 
				
				"Fine." — she drops Fu Bing to the ground and crosses her arms. 
				
				"Thought so." — Fu Bing laughs and, seeing you approach, he believes you are about to offer him a helping hand — "Thank you, ${YM}, for you-"
				
				Your fist strikes him on the temple. Boosted by the Inner Energy, your punch [i]breaks[/i] his skull. It pierces through, crushing the bone on its way, and travels forward until your hand reaches a soft blob of fat — his brain, smashing it too. 
				
				You pull your hand out of the now lifeless corpse and shake it to get rid of the cerebrospinal fluid.  
				*gosub_scene subroutines reputation_change 15 "kind" "-"
				
				Looking up, you see the Tigress shocked at first, but then giving you a look of an intense admiration and… ardent lust?
				
				Unfortunately, the moment is broken by He Jun, who kneels over Fu Bing, trying to somehow reverse his death. Then, he shakes his head.
				
				*gosub_scene cslib_string find history "hejun_proposition"
				*if cslib_ret > 0
					"What have you done?" — he asks you — "The Fu Clan will never forgive you for this. Neither will the sect just let you get away with the murder of one of its would-be disciples. You're lucky he wasn't officially initiated yet, otherwise even your talent would not have saved you." 
				
					"I can help you resolve the sect part, but the Fus would be yours to deal with." 
					*label hejun_favor
					*choice
						*selectable_if (not (sect_punishment)) #"How will the sect punish me?"
							"That will be up to the Disciplinary Hall to decide. Given your status, a hefty deduction of Sect Points and some period of solitary confinement." 
							*set sect_punishment true
							*goto hejun_favor
						#"What do you want for your help?"
							"A favor. A big one, since it'd require me to pull some strings with the Disciplinary Elder and such people do not like to be bothered."
							
							*choice
								#Accept his help.
									*set history history&"hejun_helps_with_fubing|"
									*gosub_scene subroutines change_opinion 7 2 "+"
									"Smart choice." — He Jun says before gesturing a couple of servants to take away the body — "We'll talk in the sect." 
									
									You nod at him before mounting the giant mosquito alongside the Tigress. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
								#Refuse his help.
									*gosub_scene subroutines change_opinion 7 1 "-"
									"Very well." — He Jun shrugs his shoulders — "It's your choice." 
									
									You nod at him before mounting the giant mosquito alongside the Tigress. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
						#"I don't care. The Fu Clan wouldn't dare touch me and the Sect would consider me too valuable to harm or stunt my growth."
							*gosub_scene subroutines change_personality 2 "arrogant" "+"
							*gosub_scene subroutines change_opinion 7 2 "-"
							He Jun chuckles.
							
							"Arrogance caused deaths of bigger geniuses than you.  Very well, it's your choice."
							
							You nod at him before mounting the giant mosquito alongside the Tigress. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
				*else
					"You are going to be in so much trouble, little bastard." — he laughs — "Perhaps Tang Ruo hit you in the head too hard if you truly believe you can get away with public murder like this. I'll march you into the Disciplinary Hall the first thing after your initiation."
					
					"However… I can help you." 
					
					*goto hejun_favor
				
		*label flight_tigress
		*gosub flight_text
		the Tigress a few questions.
		*temp home_question false
		*temp sect_question false
		*temp family_question false
		*temp claws_question false
		*temp advice_question false
		*temp goal_question false
		*label tigress_questions
		*if question_count = 2
			
			Your journey is halfway done: you'll be able to ask the Tigress a couple of questions more at most.
		*if question_count = 3
			
			The peak of the mountain and, therefore, the end of your flight is close. You can only ask one more question.
		*if question_count = 4
			*page_break Arrive In The Sect
			*goto sect_arrival
		*choice
			*selectable_if (not (home_question)) #"What are you doing so far from home?"
				*set question_count +1
				*if characters_5_opinion <= 54
					She hesitates — you see her crimson eyes dart around nervously, her mind considering whether or not to confide in you, but in the end she decides against it.
					
					"The Tigress likes to travel." — she says and turns away.
					
					The Tigress doesn't seem to trust you enough to reveal her secret.
					*set home_question true
					*goto tigress_questions
				*else
					She hesitates — you see her crimson eyes dart around nervously, considering whether or not to confide in you, but in the end she considers you to be worthy of her trust. Looking around at the people flying nearby, she moves closer to you, her firm, busty chest pressing against your body. She puts her mouth near your ear and whispers, the lower tone augmenting the hints of raspiness in her voice.
					
					"The Tigress found a treasure." — she says — "A very valuable treasure. The people in her tribe tried to take the treasure away from her, so she killed those she could and ran away from those she couldn't. However, her traitorous people announced to all tribes that the Tigress was in possession of an artifact. She couldn't stay there anymore, for there was a significant amount of Houtian and Xiantian amongst her pursuers." 
					
					"Now the Tigress is here. She will train, she will advance and on the day of her return to the wilderness, the eternal snow of the West will change it's color to blood-red."
					
					Her last word are said with such conviction, such absolute confidence behind them, that a picture of the Tigress standing above thousands of corpses, half a leg inside a snowdrift, forms unwillingly inside your mind.
					
					*choice
						#"What kind of treasure is it?"
							*gosub_scene subroutines change_opinion 5 1 "-"
							As soon as the word 'treasure' escapes your lips, the Tigress growls. 
							
							"Do you want to away it too? No! The Tigress won't let anybody take it!" 
							
							"Calm down!" — you exclaim, raising your hands in the air — "I was just curious."
							
							"The Tigress will watch you."  — she snorts and turns away.
							
							*set home_question true
							*goto tigress_questions
						#"I will protect you." 
							*if (tangruo_condition)
								*gosub_scene subroutines change_opinion 5 3"+"
								The tiniest of blushes makes it way onto her face. 
								
								"You have enough talent to say such things. But don't underestimate the warriors of the wild: they are much, much more fierce than your average Martial Artists."
							*else
								"Stop speaking nonsense. You couldn't even place first in the tourney, what hope do you have against the fierce warriors of the wild?"
								
							*set home_question true
							*goto tigress_questions
								
						#"I will help you when you decide to go back."
							*gosub_scene subroutines change_opinion 5 2 "+"
							"Thank you." — she says, giving you an appreciative smile. 
							*set home_question true
							*goto tigress_questions
						#"I want nothing to do with your revenge." 
							*gosub_scene subroutines change_opinion 5 3 "-"
							"The Tigress wasn't planning on asking you for help. She doesn't [i]need[/i] help." — she retorts — "Don't bother me anymore." 
							
							The Tigress refuses to entertain your questions further.
							
							*page_break Arrive In The Sect
							*set home_question true
							*goto sect_arrival
			*selectable_if (not (sect_question)) #"Why have you chosen Heavenly Ascension Sect?"
				*set question_count +1
				"Wouldn't the Heavenly Havoc sect a better fit for your… personality?" 
				
				The Tigress nods. 
				
				"It would be. But the Tigress is not stupid: for someone like her, without a background to lean on, she'd need to submit herself to an Elder, if she wants her safety guaranteed amidst the lawless demons. For her, the sect that promises the most freedom is the strictest cage."
			
				*set sect_question true
				*goto tigress_questions
			*selectable_if (not (goal_question)) #"What's your goal in the sect?"
				*set question_count +1
				"I've long heard tales of the famous Arena in the Heavenly Ascension Sect. The Tigress wishes to enter it and test herself against the so-called Martial Artists."
				*set goal_question true
				*goto tigress_questions
			*selectable_if (not (family_question)) 			#"Do you have any family?"
				*set question_count +1
				"I don't." — she replies and then her expression flickers with indecision and grief — "The Tigress had a husband, however…" 
				
				"Had?"
				
				"The Tigress killed him."
				
				She doesn't say another word.
				*set family_question true
				*goto tigress_questions
			*selectable_if (not (claws_question)) 			#""Why do you use claws?"
				*set question_count +1
				She stares at you, wondering why would you ask such a stupid question. 
				
				"Why don't you use claws?"
				
				"Fair point." 
				*set claws_question true
				*goto tigress_questions
			*selectable_if (not (advice_question)) 			#"Do you have any advice for me?"
				*set question_count +1
				"Don't let yourself be bound by rules. Don't owe anybody favors. Kill those whom you don't like."
				
				"That's it?"
				
				"That's it."
				*set advice_question true
				*goto tigress_questions
	*selectable_if (meimei_condition) #Ride with Mei Mei.
		You find Mei Mei already seated on one of the mosquitoes and are stupefied by how organized the future disciples under her supervision are. Looking around, you see and hear nobles arguing about who should ride which beast— a trivial thing, yet the Tigress already lifts someone by the neck for it. Commoners trade insults with aristocrats, the conflict thousands of years in the making flaring up after the temporal pause. And yet, around Mei Mei everything is calm. No yelling, no fighting, only peace and serenity: everybody too engaged with her beauty, with her gracefulness and cheeriness as she talks and laughs. 
		
		"$!{polite_address} ${mc_name}!" — Mei Mei exclaims, waving her hand in excitement — 
		*if (tangruo_condition)
			"Congratulations on your victory! You were [i]awesome[/i]!"
		
		"I'm glad you decided to join me." 
		
		Before you can answer, a commotion happens near one other beast. You see the Tigress pouncing between the nobles, claiming their lives with her claws: however, before you can even decide if you want to interfere, He Jun flicks her forehead and causes her to go unconscious. What was that about, you wonder?
		
		Never mind. That's a problem for another day. For now, you should just answer Mei Mei. 
		
		*choice
			#"Who said I'm here for you?"
				*gosub_scene subroutines change_opinion 6 2 "-"
				"Oh?" — Mei Mei crosses her arms and gives you a suspicious look — "Then who are you here for?" 
				
				You search through the crowd, but find nobody that you recognize.
				
				"Well… I wanted to ride by myself."
				
				Mei Mei snorts.
				
				"Fine! Then I just won't talk to you!" 
				
				She turns around and continues her conversation with the nobles, not sparing you a single glance. The nobles, however, snicker at your foolishness.
				
				*goto flight_alone
			#"Me too."
				*gosub_scene subroutines change_opinion 6 1 "+"
				Mei Mei beams, her smile infectious to the point where you feel your own lips tug at the corners of your mouth. 
				
				*label climb_meimei_mosqiuto
				"Come, come." — she pats an empty spot beside herself — "We have much to talk about!"
				
				You mount the giant mosquito. Soon, its long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
			#Nod at her.
				*goto climb_meimei_mosqiuto
	
		*gosub flight_text
		Mei Mei a few questions.

		*temp envoy_question false
		*temp concoctions_question false
		*temp bethrothal_question false
		*temp family_question false
		*temp hejun_question false
		*temp advice_question false
		*label flight_meimei
		*if question_count = 2

			Your journey is halfway done: you'll be able to ask Mei Mei a couple of questions more at most.
		*if question_count = 3

			The peak of the mountain and, therefore, the end of your flight is close. You can only ask one more question.
		*if question_count = 4
			*page_break Arrive In The Sect
			*goto sect_arrival
		*choice
			*selectable_if (not (envoy_question)) #"Are you also a Sect Envoy?"
				"Me? An Envoy?" — she chuckles— "Goodness, no. Envoys must at least be Early Xiantian-level Experts and that is just the first requirement. Only those of the most talent and highest status can become Envoys, as their every word carries the authority of the whole sect." 

				"I'm a Creationist, an alchemist to be exact. Envoys and Enforcers commission certain pills and other medicine from me for a price. It's a cushy life," — Mei Mei grins — "Don't have to put my life in danger, don't have to venture from the sect all the time. Plus, I have lots of friends! Everybody wants to get in my good graces, hehe." 

				"Are you that talented?"

				"I'm Alchemy Elder's personal disciple. What do you think?"

				Mei Mei stares at you, smugly, excepting praises.

				*choice
					#"That's incredible!"
						*gosub_scene subroutines change_opinion 6 1 "+"
						"I know, I know." — she says, flicking a strand of her golden blond hair away from her face.

						"Are you the Elder's only disciple?" — you ask. 
						*label meimei_alone_disciple
						*gosub_scene subroutines stat_check "per" 10
						*if (stat_check)

							She hesitates a little before giving you the answer.

							"I am. Doesn't it make me even more special?" 

							Mei Mei is not exactly lying, but you get the feeling that there is something that she decided to omit.
						*else
							"I am. Doesn't it make me even more special?" 
					#"Not bad." 
						*gosub_scene subroutines change_personality 1 "arrogant" "+"
						*gosub_scene subroutines change_opinion 6 1 "-"

						She snorts.

						"What do you mean 'not bad'? It's extraordinary!"

						"Are you the Elder's only disciple??" — you ask. 
						*goto meimei_alone_disciple

					#"Nothing impressive. In ten years, the Elders would be my disciples instead." 
						*gosub_scene subroutines change_personality 2 "arrogant" "+"
						She doesn't know whether she should laugh or be insulted by the sheer absurdness of your statement.

						"Well, we, [i]normal people[/i], have to take what we can get." 

						"Are you the only one?" — you ask — "Disciple of that Elder, I mean."

						*goto meimei_alone_disciple

				*set question_count +1
				*set envoy_question true
				*goto flight_meimei
			*selectable_if (not (concoctions_question)) #"What types of concoctions can you make?"
				"Everything within the Houtian Grade. Pills, elixirs, pastes — you name it. I mostly specialize in healing products and produce them at High-Quality. But I can concoct many other things, including even unfamiliar recipes with more than 60% chance of success." 

				"Is 60% a lot?"

				"The second highest in the sect. The first is my master, who has a near 90% success for new recipes. However, she only concocts either vital to the sect goods or something that arouses her curiosity. Good luck finding anything that does." 

				*set question_count +1
				*set concoctions_question true
				*goto flight_meimei
			*selectable_if (not (bethrothal_question))  #"Are you betrothed?" 
				Mei Mei blushes furiously. 

				"${polite_address}! What kind of question is that!" — she squeals. 

				"A reasonable and appropriate one." 

				"Hmph! No, I'm not." — says Mei Mei. 

				"Why not?"

				"Since I'm the Second Young Mistress of the He Clan, all matters of my marriage and my future partner are decided upon by Father and family elders. I fear I have no control over them." — she sighs, her slim figure exuding sadness that contaminates even your own mood. You suddenly feel the desire to comfort her, to hold her. Your body starts to move without your command…

				You shake your head and the fog that has embraced your mind lifts. That was [i]weird[/i]. 

				*gosub_scene subroutines stat_check "per" 11
				*if (stat_check)
					You catch a glimpse of surprise flicker across her expression, but she quickly covers it with her usual bashfulness.

				*set question_count +1
				*set bethrothal_question true
				*goto flight_meimei

			*selectable_if (not (family_question)) #"How is your relationship with your family?"
				"It's good, of course. I'm the only girl of my generation, so they all treat me as if I was a princess." — she cheers and but there is just something in her tone, in the way she said those words that you can't help but doubt them.

				*set question_count +1
				*set family_question true
				*goto flight_meimei
			*selectable_if (not (hejun_question)) #"He Jun told me to find him in the sect. Do you have any idea what he wants?"
				"I'm afraid that not I only I have an idea, I know for sure what he wants." 

				"What is it?"

				"As I'm sure you know, ever since my father ascended to Shangtian, my clan has been expanding its influence over the Celestial Empire. My father and his army have been waging war against other nobles, conquering their territory, but such actions are insufficient to make our clan a real equal to either Yangs or Su. For the clan to truly grow, it must have a young generation willing and capable of exploring Danger Zones: which is why we've been recruiting talents across the three Heavenly Sects."

				"You think He Jun is going to recruit me? After he tried to kill me?"

				"Yes." — she nods — "And if you don't accept, he will try again." 

				*choice
					#"I will never accept. He Clan has been an enemy of my family for generations and I will not betray my own."
						*gosub_scene subroutines change_personality 2 "ruthless" "-"
						"Thought so, although it saddens me that our family has reached a state of such deep enmity." 
					#"I will never accept. Those bastards kidnapped me, almost murdered me, and now want to me to work for them? What a joke!"
						*gosub_scene subroutines change_personality 2 "arrogant" "+"
						"Thought so, although it saddens me how much my family has hurt you."
					#"I doubt I'll accept. He Jun is already annoying, I can't image having to deal with more people like him." 
						*gosub_scene subroutines change_personality 2 "impulsive" "+"
						"Thought so. My family can be more than bothersome."
					#"I'm not against it, if the benefits are good enough."
						*gosub_scene subroutines change_personality 2 "egoistical" "+"
						"Are you serious? What about you family?"

						"What about them?" — you snort — "My father is a drunk who doesn't give a damn about me and I have no one else. What's stopping me from joining your side?"

						"I see." — Mei Mei looks surprised at first, but soon, she lits up in elation — "We will get along just fine then." 

						"What do you mean?"

						"Oh?" — she giggles — "Just that we will be meeting a lot more if you decide to accept Cousin's proposal, that's all."

				*set question_count +1
				*set hejun_question true
				*goto flight_meimei
			*selectable_if (not (advice_question)) #"Do you have any advice for me?"
				"Be careful who you trust. The sect is full of people smiling in your face just to stab you in the back." 

				"Speaking from experience?"

				She smiles slyly.

				"You can say so."


				*set question_count +1
				*set advice_question true
				*goto flight_meimei
	*selectable_if (jingguo_condition) #Ride with Jing Guo.
		Jing Guo has already climbed his beast, laying on its back, seemingly asleep. 
		
		"Brother Guo!" — you shout.
		
		He raises his head, rubs his eyes and waves at you.
		
		"${YM} ${mc_name}, it's you! Please, do come ride with me. I insist."
		
		You nod and climb up.. 
		
		*if (tangruo_condition)
			"I must say, ${polite_address} ${mc_name}, no one expected you to win this tourney. Me included."
			
			*fake_choice
				#"Don't underestimate me ever again."
					*gosub_scene subroutines change_personality 1 "arrogant" "+"
					"Of course. I apologize for doing so before." 
				#"To be honest, I was surprised myself."
					*gosub_scene subroutines change_personality 1 "arrogant" "-"
					"I do believe people all throughout the Empire will talk about sudden advancement to Houtian." 
				#"It is what it is." — you shrug your shoulders.
					*gosub_scene subroutines change_personality 1 "impulsive" "-"
		
		Soon, the mosquito's long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
		
		*gosub flight_text
		Jing Guo a few questions.
		*temp tourney_question false
		*temp sect_question false
		*temp style_question false
		*temp family_question false
		*temp bethrothed_question false
		*temp advice_question false
		*label guo_questions
		*if question_count = 2

			Your journey is halfway done: you'll be able to ask Jing Guo a couple of questions more at most.
		*if question_count = 3

			The peak of the mountain and, therefore, the end of your flight is close. You can only ask one more question.
		*if question_count = 4
			*page_break Arrive In The Sect
			*goto sect_arrival
		*choice
			*selectable_if (not (tourney_question)) #"Why have you placed so poorly in the tournament?"
				"In truth, I'm also disappointed in myself. I expected to at least get into top ten." 
				
				"What happened?"
				
				"I got unlucky! Unlucky! Met that zombie and he trashed me with me ease." — Jing Guo caresses his right side — "It still hurts, you know?"
				
				*set question_count +1
				*set tourney_question true
				*goto guo_questions
			*selectable_if (not (sect_question)) #"What are you planning to do in the sect?"
				"I'm glad you asked!" — Jing Guo replies, his chubby cheeks almost trembling in excitement — "I will open a business."
				
				"A business?"
				
				"Yes! Tell me, what's the important part of Martial Artist's everyday life?"
				
				*choice
					#Training.
						*gosub_scene subroutines give_exp 1 ""
						*gosub_scene subroutines change_personality 1 "indulgent" "-"
						"Eh? ${polite_address} ${mc_name}, don't speak nonsense! I was asking about the most important part, not the most hated one." 
					#Wine.
						*gosub_scene subroutines change_personality 1 "indulgent" "+"
						"Yes! I knew you would understand me!"
					#Sex.
						*gosub_scene subroutines change_personality 1 "indulgent" "+"
						"Hehe, ${polite_address} ${mc_name} sure has ${pronoun_2} priorities straight. But no, I was talking about something else."
					#Battles.
						*gosub_scene subroutines change_personality 1 "violent" "+"
						"Eh? ${polite_address} ${mc_name}, don't speak nonsense! I was asking about the most important part, not the most dangerous one.
					#Learning.
						*gosub_scene subroutines give_exp 1 "int"
						*gosub_scene subroutines change_personality 1 "indulgent" "-"
						"Eh? ${polite_address} ${mc_name}, don't speak nonsense! I was asking about the most important part, not the most tedious one."
					
				"How could Martial Artists live without wine? How could their drown their sorrows, bolster their happiness and relieve their boredom without it? That's right! The couldn't!" — he exclaims. 
				
				"But did you know that in the Heavenly Ascension Sect, the available wine is atrocious? As my older brother likes to describe it, 'They poured so much pisswater into the bottle, there was no room for actual wine inside'. So, can you imagine how wealthy I'd get, if I opened a wine store and sold my family's special wine there? I can already feel myself drowning in gold." 
				
				"There has to be a reason why nobody else did it before you."
				
				"Who cares, ${polite_address} ${mc_name}? I asked my brother, and he said that the Sect allows such businesses to exist. Encourages them even. So I see no problem with my idea." — he laughs — "Say, friend, do you want to get rich with me?"
				
				"What do you mean?"
				
				"I might have an amazing idea and connections to get the wine, but I lack money to acquire it in sufficient numbers. Would you like to go into business with me? I'll give you ten percent of all future profits for 10.000 gold."  
				
				*set history &"jingguo_knows_restaurant|"
				*temp tried_negotiation false
				*label options_to_buyin
				*choice
					#Buy 10% for 10 thousand gold.
						*gosub_scene subroutines change_opinion 3 4 "+"
						"Wonderful. I'll handle all the logistics, just find me in the sect in a few months. I'll have your cut ready for you." 
						
						[b]Gold -10,000[/b]
						*set mc_gold -10000
						
						*set restaurant_percentage 10
						
						*set history history&"bought_stock_jingguo|"
					#Buy 20% for 20 thousand gold.
						*gosub_scene subroutines change_opinion 3 5 "+"
						"Amazing! You'll double your gold in no time! I'll handle all the logistics, just find me in the sect in a few months."
						
						[b]Gold -20,000[/b]
						*set mc_gold -20000
						*set restaurant_percentage 20
						*set history history&"bought_bigstock_jingguo|"
					*selectable_if (not(tried_negotiation)) #"This is too expensive. How about 5 thousand for 10%." 
						*gosub_scene subroutines stat_check "chr" 12
						*if (stat_check)
							*gosub_scene subroutines change_opinion 3 3 "+"
							"Okay, okay, you've convinced me. I'll handle all the logistics, just find me in the sect in a few months. I'll have your cut ready for you."
							*set restaurant_percentage 10
							*set history history&"bought_stock_jingguo|"
							[b]Gold -5,000[/b]
							*set mc_gold -5000
							
						*else
							"No can do, ${polite_address} ${mc_name}. I need at least ten thousand to get the business going. Are you with me or not?"
							*set tried_negotiation true
							*goto options_to_buyin
					#"No, thank you."
						*gosub_scene subroutines change_opinion 3 2 "-"
						"It's your loss, ${polite_address} ${mc_name}, your loss. You could've doubled your gold in no time."
				
				*set question_count +1
				*set sect_question true
				*goto guo_questions
			*selectable_if (not( style_question)) #"What's your combat style?"
				"I'm sorry, Brother Guo, but I missed your battles in the tourney.
				
				Jing Guo scratches his head.
				
				"I don't really have one. I usually just let people hit me until they tire themselves out."
				
				"And it works?"
				
				"Sometimes it does, sometimes it doesn't. I hope I can learn the Turtle Shell Skill so that my defense would be even more impregnable."  
				
				*set question_count +1
				*set style_question true
				*goto guo_questions
			*selectable_if (not (family_question)) #"How did your family get so rich?"
				"Through trade." — Jing Guo answers — "And through mortals. My family makes extensive use of mortal artisans and crafters, which is why many amongst the noble circles mock us." 
				
				"But who cares what they think?" — he laughs, but you can tell that he's not as indifferent to ridiculing comments as he leads you to believe.
				*set question_count +1
				
				*set family_question true
				*goto guo_questions
			*selectable_if (not (bethrothed_question)) #"Are you betrothed?"
				"Heavens, no." —he refutes resolutely — "Who in their right mind would want to get married? Especially at our age? I'm not crazy."
				*set question_count +1
				
				*set bethrothed_question true
				*goto guo_questions
			*selectable_if (not (advice_question)) #"Do you have any advice?"
				"Live life as you want. Don't listen to that 'strength is everything' bullshit — what's the point of living if you can't even enjoy yourself?"
				*set question_count +1
				
				*set advice_question true
				*goto guo_questions
	#Ride with a stranger.
		*label flight_alone
		
		Before you climb onto a mosquito with some random noble, who's too terrified of your status to hold a conversation, a commotion happens near one other beast. You see the Tigress pouncing between the nobles, claiming their lives with her claws: however, before you can even decide if you want to interfere, He Jun flicks her forehead and causes her to go unconscious. What was that about, you wonder?   
		
		Soon, the mosquito's long, slender wings start to flutter. The frequency of flaps, as well as the loudness of consequent noise, increase until the monstrous insect rises in the air.
		
		The mosquito's speed leaves much to be desired: you're not sure whether your weight, or if the crawling pace is a deliberate gesture to display the majesty of the Heavenly Ascension Sect.

		Because the sect is [i]breathtaking[/i]. The mountain alone, its peak piercing so far into the Heavens that it cannot be seen from the ground, is worth a hundred praising poems. Forests with tall trees, hiding ferocious beasts inside their depths, also inspire marvel.  Yet, there is something even more impressive: buildings constructed thousands of feet above the sea level by a human hand. As you ascend higher, the buildings get more complex and more majestic, while their number expands. Soon, you see whole towns sprawled on the mountain, its landscape carved through artificial means to allow for this wonder.

		"The sect is divided into three main levels." — states He Jun — "First level, located the furthest from the top, is meant for the disciples. That's where you will live, train and socialize with your peers until you pass the Envoy Examination or acquire a position of similar importance." 

		"The second level is for the core of the sect, it's main force in the shape of Envoys, Enforcers and various Creationists. You'll find the best wares there, the best techniques and the best missions. However, unless you become an Envoy or a Core Disciple, you'll have to pay with Contribution Points in order to access it."

		"The third level is where Elders live. Only their personal disciples have the permission to enter it." 

		"There is also the peak, where the Sect Master and the Hidden Elder reside, but that's of no relevance to you."

		He Jun stops speaking, setting his gaze back on the mountain. 

		This flight promises to last for a considerable amount of time. You relax and take in the sights.
		*goto sect_arrival
	
*label sect_arrival
*goto_scene sect_arrival

*label flight_text
The mosquito's speed leaves much to be desired: you're not sure whether the combined weight of the two of you strains it, or if the crawling pace is a deliberate gesture to display the majesty of the Heavenly Ascension Sect.

Because the sect is [i]breathtaking[/i]. The mountain alone, its peak piercing so far into the Heavens that it cannot be seen from the ground, is worth a hundred praising poems. Forests with tall trees, hiding ferocious beasts inside their depths, also inspire marvel.  Yet, there is something even more impressive: buildings constructed thousands of feet above the sea level by a human hand. As you ascend higher, the buildings get more complex and more majestic, while their number expands. Soon, you see whole towns sprawled on the mountain, its landscape carved through artificial means to allow for this wonder.

"The sect is divided into three main levels." — states He Jun — "First level, located the furthest from the top, is meant for the disciples. That's where you will live, train and socialize with your peers until you pass the Envoy Examination or acquire a position of similar importance." 

"The second level is for the core of the sect, it's main force in the shape of Envoys, Enforcers and various Creationists. You'll find the best wares there, the best techniques and the best missions. However, unless you become an Envoy or a Core Disciple, you'll have to pay with Contribution Points in order to access it."

"The third level is where Elders live. Only their personal disciples have the permission to enter it." 

"There is also the peak, where the Sect Master and the Hidden Elder reside, but that's of no relevance to you."

He Jun stops speaking, setting his gaze back on the mountain. 

This flight promises to last for a considerable amount of time. You have the opportunity to ask
*return