*temp arrogant_prick false
*temp cheapinn false
A tall mountain pierces the heavens, its peak soaring beyond the lofty clouds. On its top — a location you barely see, even this high from the ground — the headquarters of the Heavenly Ascension Sect prepare for the upcoming Trials. 

Despite the sect being your final destination, Uncle Tao changes the fenghuang's course, directing it to the bustling city beneath. Not to mention outsiders, the disciples of the sect themselves are not allowed to fly up the mountain, such offense serving as the greatest disrespect.

Near the city gate, a huge amount of mortals wait their turn to pay the toll and gain entry. Young and old, fit and sick all stand in a single line, not daring to make a fuss. Those with the fanciest clothes and most expensive horses — most likely merchants on the sect's payroll — standing right behind the unwashed peasants dressed in rags. The rich wrinkle their noses in contempt, but otherwise keep quiet.

Flapping its wings, your bird creates a gust of wind as it descends onto the ground. Dust and pebbles rise and scatter, forcing the people nearby to shield their eyes from the airborne dirt. Many of them are thunderstruck by a beast this large, many panic and hide their children. 

The city guards do not delay and a squad of four is immediately dispatched to greet you. They are all armed with short swords and wear a metallic cuirass, complimented by chainmail boosts, greaves, and gauntlets. Their captain — you assume, by the white cloak decorating his back — steps out and speaks.

"Please, accept our most sincere welcome. Which esteemed guests honor us with their presence?"

Despite his warm words, his hand doesn't leave the hilt of his cold blade. The fenghuang and its potential for wanton destruction worries him, while the silent old man riding it causes his limbs to shake in terror. You, he only gives a fleeting glance.

With his eyes closed, Uncle Tao clearly does not intend to speak. He's done his job, and from this point onward will only ensure your safety. It's up to you to converse with the guards.

*choice
	#Don't waste time on a commoner. 
		*gosub_scene subroutines change_personality 1 "arrogant" "+"
		In one smooth movement, you throw one of your legs to the same side as the other and jump down from the saddle. When you land, you clasp your hands behind your back.
		*if mc_height < 4
			The captain boasts a tall frame, forcing you to lift your head to match your gaze with his. However, you still manage to look down at him — the arrogance contained behind your
			*if mc_eye_left = mc_eye_right
				${mc_eye_left} eyes
			*else
				polychromic eyes
			too strong to be affected by insufficient height. 
		*elsif mc_height = 4
			The captain boasts a tall frame, but so do you. You match your gaze with his and, despite the equal height, manage to look down at him — 		the arrogance contained behind your
			*if mc_eye_left = mc_eye_right
				${mc_eye_left} eyes
			*else
				polychromic eyes
			overpowers his servile spirit.
		*elsif mc_height > 4
			The captain boasts a tall frame, but you are taller. Already looking down at him, 		the arrogance contained behind your
			*if mc_eye_left = mc_eye_right
				${mc_eye_left} eyes
			*else
				polychromic eyes
			overpowers his servile spirit.
		
		"Wu ${mc_name}." — you state, not elaborating further. 
		
		You do not introduce either your goal in coming here or Uncle Tao  — the former the captain should figure out by himself and the latter he doesn't need to know. You expect your name — or, at the very least, the name of your clan — to be an ample enough explanation. And it is, as you see the captain perform a bow in recognition. If your haughty conduct bothers him, the captain doesn't show it: already used to such demeanor from other Great Clans.
		
		"This humble one is named Qiang, ${YM}." — the guard responds, not mentioning his surname. Although commoners do have family names, bringing them up when dealing with nobles is treachery: heavens forbid some fool will by accident impersonate a noble scion. — "Should I -"
		
		"Enough talk." — you interrupt him with a gesture — "Take care of my beast and guide me to the best inn you have."
		
		*set arrogant_prick true
		
	#Reply with the expected of you politeness.
		In one smooth movement, you throw one of your legs to the same side as the other and jump down from the saddle.
		
		"Wu ${mc_name}, ${YM} of the Wu Clan. This -" — you point towards Uncle Tao — "is my escort. You can address him as his Excellency if the need arises."
		
		The guard manages to produce a smile, despite his nervousness.
		
		"This humble one is named Qiang, ${YM}." — he responds, not mentioning his surname. Although commoners do have family names, bringing them up when dealing with nobles is treachery: heavens forbid some fool will by accident impersonate a noble scion. — "I assume you are here for the Trials?" 
		
		"Correct. I will need you to take care of my beast and show me a few inns to spend the night in."
		
		"No problem, noble one." 
	#Greet him in a friendly way.
		*gosub_scene subroutines change_personality 1 "arrogant" "-"
		In one smooth movement, you throw one of your legs to the same side as the other and jump down from the saddle. You plaster a smile on your face — the guard's job is already tough enough, no need to be another burden. 
		
		"Name's Wu ${mc_name} of the Wu Clan." — you introduce yourself — "What's yours, friend?"
		
		The captain's brows shoot up in surprise. He's not used to even basic politeness out of nobles, not to mention friendliness. For a second, he's stupefied, not knowing how to react.
		
		"You-" — the captain coughs to clear his throat — "You can call me Qiang." 
		
		Although commoners do have family names, bringing them up when dealing with nobles is treachery: heavens forbid some fool will by accident impersonate a noble scion.
		
		"Haha! Nice to meet you, Qiang. I'm going to need your help with both my beast and accommodations for the night."
		
		"Of course, no problem at all." 
	
The captain nods and signals two of his subordinates to accomplish your first task. They hesitantly walk toward the fenghuang, but their lack of confidence is on blatant display. And wild beasts are not known to tolerate unsureness.

The fenghuang snarls, its beak parting open to let out a high-pitched shrill. It spreads out its colored wings and flaps them. More out of fear than of the blast's impact, one guard retreats and the other falls on his armored behind. Angered and humiliated by his subordinates' incompetence, the captain prepares to yell — but Uncle Tao acts quicker.

Previously still and serene, the old man strikes the bird with the speed of a ravenous viper. His palm hits its body, and the bird crashes down with a much louder thud than the guard before it did. The beast whimpers, its ached cries hurting your ears. 

*choice
	#"There was no need to be so rough." 
		*gosub_scene subroutines change_personality 1 "violent" "-"
		Was such violence really needed? The once proud beast lies and grovels, screaming in agony as the after-effects of the palm-strike — Xiantian attacks are never as straightforward as they seem — wreck its inner organs. You can't help but feel… pity.

		Uncle Tao ignores your remark. You do not command him, nor do your words have any weight in the man's eyes. To him, you are but a child he's tasked to protect. 

	#Ignore it.
	#"A disobedient beast is a useless beast."
		*gosub_scene subroutines change_personality 1 "violent" "+"
		Should've hit that bird harder, until the fire of resistance is extinguished in its soul completely. How dares it embarrass you before these commoners?

		Uncle Tao ignores your remark. You do not command him, nor do your words have any weight in the man's eyes. To him, you are but a child he's tasked to protect. 				


"Right." — the captain says, as the others lead the now docile beast by its reins — "Follow me into the city, please."
*page_break Follow him.

The city bursts with activity. Children play catch and tag, their silly game inevitably putting them on the cobbled pavement — and drivers of horse carriages shoo them out of the way. Stall owners call out from their stands, drumming up the interest of the passerby. The city smells of life, the same way it smells of shit and piss — like all mortal cities do.

*if mc_pers_elitist > 60
	[i]Filthy savages.[/i]
*temp intermediate_inn false
*label after_cheapinn
*if (interscene_temp = "inn")
	*set lock_exp_spending false
	*temp arrogant_prick false
	*temp cheapinn false
	*temp intermediate_inn false

*label choosing_inn
"${YM}, what kind of an inn do you wish to stay at?" — the captain asks. 
	
*choice 
	#The most expensive one.
		*if (arrogant_prick)
			You are a noble scion, a person of great status and pride — and you've behaved like one already, too. Staying anywhere but the most costly inn means losing face. 
		*else
			Renting a place from a mortal is humiliating enough, renting a [i]cheap[/i] place from a mortal is an insult to your noble standards. 
		
		Soon, you arrive at a well-maintained, three-story building. When you enter, you are immediately relieved: the place is clean and the stench of the streets remains outside. In addition, there don't seem to be any patrons inside, most probably scared off by the steep prices.
		
		*temp rooms ""
		*choice
			#Rent two rooms: for you and for Uncle Tao.
				*set rooms "Two rooms."
				[b]Gold -800 [/b]
				*set mc_gold -800
			*selectable_if (arrogant_prick) #Rent out the whole place.
				*gosub_scene subroutines change_personality 2 "arrogant" "+"
				[b]GOLD -10000 [/b]
				*set mc_gold -10000
				*set rooms "I'm renting this whole place."
		
		*if (arrogant_prick)
			You walk up next to the counter, materialize a pouch filled with gold — probably more than you need, but you have money to spare — and throw it at the keeper. Then, you extend your palm.			

			"${rooms}" — you say. 

			The bag collides with the innkeeper's nose, and the middle-aged bearded man yelps out in pain. Such flagrant disrespect makes him seethe in anger, but feeling the weight of the object thrown at him and seeing the armored guard act as your subordinate, he calms himself down.
		*else
			You walk up next to the counter. The innkeeper, a middle-aged man with a beard, stands behind it.
			
			"How much for a room?" 
			
			"Greetings, noble one. For your esteemed person, that would be 400 gold per room."
			
			You nod, materialize a pouch filled with gold, and throw it to the innkeeper.
			
		"This humble servant is delighted to host ${YM}." — the innkeeper plasters a smile as he hands
		*if rooms = "Two rooms."
			the keys over to you.
		*else
			the whole key chain over to you. 

		When you are already at the top of the stairs leading to the second floor,
		*if rooms = "Two rooms."
			you hear the doors of the inn open and a group of people walk in. Maybe you should've rented out the whole place?
		*else
			a voice calls out to you. 

			"Friend! Wait!"

			You turn around and meet with a man not only wearing the most opulent silk but also crawling with splendid jewelry. Fingers full of rings, a neck with multiple necklaces, and wrists bearing bracelets — this man is a noble, one who's rich and is not afraid to flaunt his wealth. 

			*temp sexname
			*if mc_sex = 0
				*set 		sexname "handsome brother"
			*else
				*set sexname "beautiful sister"
			"I'm Jing Guo. May I know ${sexname}'s name?

			[[b]Jing Guo[/b] added to [b]Character Glossary[/b]]
			*set characters_3_opinion 50

			The Jings are often regarded as equals to the Great Clans, despite being a Minor Family. Especially so in the recent hundred years, with their Patriarch carving a place under the sun for the whole family. Wide-known for their craftsmen and artisans, the Jings make a lot of money through performing commissions — even your Wu Clan might not match them in the amount of gold available. 

			*if mc_pers_arrogant > 55
				[i]Audacious upstarts.[/i]

			"Wu ${mc_name}." — you reply — "What does brother want?"

			"${YM} of the Wu Clan?" — he gasps and you can't tell whether his surprise is feigned or not — "So young, but already a
			*if mc_sex = 0
				dragon amongst men.
			*else
				phoenix amongst women.
			Your brawl with He Gang was a hot topic in the capital. It's a pleasure." 

			You reply likewise, not knowing quite what to make of the guy. He seems a bit [i]too[/i] courteous.

			"We both are in town for the same purpose, I gather. And we both were recommended the same inn. The ${YM} bought out all the floors — a grand gesture, worthy of a grand person. It's just that this brother does not wish to…" — he curls his lip and squints his eyes — "Mingle with the common folk, so to speak. I wonder if ${YM} could spare a room for this brother? I will naturally compensate you." 

			*if mc_sex = 0
				*set 		sexname "Brother"
			*else
				*set sexname "Sister"

			*temp attempted_negotiation false
			*choice
				#Lend him a room, free of charge.
					*set history history&"prologue_jingguo_gave_room|"
					"Brother does not need to speak more of such matters." — you shake your head — "Since you asked, I will naturally not refuse. There is no need to fret over the gold either: my Wu Clan is not so destitute to not afford a mortal inn."

					Jing Guo claps his hands in gratitude. 

					"${sexname} Wu ${mc_name} is truly generous. I will remember this favor." 

					You nod, give him one of the keys and go to your room.
					*gosub_scene subroutines change_opinion 3 3 "+"
				#Lend him a room, take the money.
					"I truly do not wish to see Brother Guo in a plight. However, the gold is already spent." — you let out a posed, sad sigh — "But I'm a reasonable person. For the right price, I'm sure we can come to an agreement."

					Jing Guo gives you a knowing smile — a smile he withholds for truly kindred spirits.

					"Of course, of course! Say, how about five hundred gold for one day's stay?"

					More than enough to cover the cost of a room, five hundred would be a sensible amount to rent one and leave some gold for the innkeeper as a tip. And yet, he is not renting the room, is he? He wants it from you, who bought out the whole establishment just to avoid other guests  — so the number he suggested is far too low. And he, coming from a family of merchants, should be aware of that.

					Is he purposefully lowballing you? You take a look at him and immediately realize the wrongness of your assumption — his expression, his smirk and a playful glint in his eyes suggest that this is a test.

					He's challenging you to a haggle.
					*temp amount 0
					*temp difficulty
					*set attempted_negotiation true

					*choice
						#Ask for 2000 gold. @{(tooltip) [b][NEGOTIATION][/b] |}
							*set difficulty 6
							*set amount 2000
						#Ask for 1500 gold. @{(tooltip) [b][NEGOTIATION][/b] |}
							*set difficulty 4
							*set amount 1500
						#Ask for 1000 gold. @{(tooltip) [b][NEGOTIATION][/b] |}
							*set difficulty 2
							*set amount 1000
						#"500 is fine."
							*set amount 500
							*goto repeated_haggle

					*gosub_scene subroutines stat_check "chr" difficulty
					*if (stat_check)
						You shake your head.

						"No deal, Brother Guo. The least I can do is ${amount} gold."

						*set amount ((amount/2)+250)

						"Oh?" — Jing Guo licks his lips — "I'm afraid my small clan cannot match the affluence of a Great Clan like the Wu. Would you show me some generosity? Let's say, ${amount}." 

						*choice
							#Accept.
								*label repeated_haggle
								"Wonderful! Wonderful!" — he cackles and then clasps his hands in gratitude —  "I will remember this favor, ${sexname} ${mc_name}."

								You nod, give him one of the keys and go to your room.

								[b]Gold +${amount} [/b]
								*gosub_scene subroutines 					change_opinion 3 1 "+"
								*set history history&"prologue_jingguo_gave_room|"
								*set mc_gold +amount
								*page_break Go To Your Room
								*goto room
							#Try to negotiate for the full amount. @{(tooltip) [b][NEGOTIATION][/b] |}
								*set difficulty +1
								*gosub_scene subroutines stat_check "chr" difficulty
								*if (stat_check)
									*set amount ((amount-250)*2)
									*if (eligible_achievements)
										*achieve first_haggle

									"Aya, Brother Guo has ears yet does not listen. I already said that I will not go below ${amount}."

									He stares at you and for a moment, you are unsure whether or not he'll accept your offer. But then, he throws his head back and laughs. 

									"You drive a hard bargain! A very hard bargain, ${sexname} ${mc_name}. Should this martial arts business fail, you have a future as a merchant. We have a deal."

									Both of you clasp hands at each other in consideration and it's clear to you that Jing Guo was not offended by your bargaining persistence. If anything, he looks amused by it and more interested in you.

									[b]Gold +${amount} [/b]
									*gosub_scene subroutines 					change_opinion 3 3 "+"
									*set history history&"prologue_jingguo_gave_room|"
									*set characters_3_status "Warm"
									*set mc_gold +amount
								*else
									You open your mouth to continue the bargain, but Jing Guo stops you.

									"I'm sorry, ${sexname} ${mc_name}, but this is my final offer. I will not go above it."

									His mind set, Jing Guo will not budge further. Do you accept the deal?
									*choice
										#Yes
											*goto repeated_haggle
										#No
											*goto bargain_refusal

							#Flirt with him. @{(tooltip) [b][SEDUCTION][/b] |}
								*gosub_scene subroutines stat_check "chr" 5
								*if (stat_check)
									You are not sure whether you have the bargaining skills to continue the negotiation — but you do have… other tools of persuasion.

									You come closer, putting your hand onto his heart and maintaining steady eye contact. 

									"Why do you have to drive such a hard bargain, Brother Guo? I'm sure we can circle back to my previous offer."

									He gulps, his gaze locked onto your hand. 

									"Huh? Yes, yes… sure." — he stammers and accepts. 

									You giggle and take back your hand. You toss him a key, turn around and wave him goodbye.

									"[i]Pleasure[/i] doing business with you, Brother Guo."
									
									*set history history&"prologue_jingguo_gave_room|"
									*gosub_scene subroutines change_opinion 2 2 "+"
								*else
									You open your mouth to try and flirth with him, but Jing Guo stops you.

									"I'm sorry, ${sexname} ${mc_name}, but this is my final offer. I will not go above it."

									His mind set, Jing Guo will not budge further. Do you accept the deal?
									*choice
										#Yes
											*goto repeated_haggle
										#No
											*goto bargain_refusal

					*else
						"${sexname} ${mc_name} must be kidding. Your price is far too much. Either take my deal or leave it."

						His mind set, Jing Guo will not budge further. Do you accept the deal?
						*choice
							#Yes
								*goto repeated_haggle
							#No
								*goto bargain_refusal
															
				#Refuse him.
					*label bargain_refusal
					*gosub_scene subroutines change_opinion 3 3 "-"
					"Oh?" — he says, his brows pulled down and together — "It seems ${sexname} ${mc_name} values a single room more than my friendship. Very well, then we have nothing more to talk about."

					He turns around and leaves, without even bothering to clasp his hands in farewell. You wonder, whether or not it was worth it to offend a fellow noble over such a trivial matter.

					*fake_choice
						#He can go fuck himself. These rooms are mine.
							*gosub_scene subroutines change_personality 2 "arrogant" "+"
						*selectable_if (attempted_negotiation) #A regrettable outcome of unfortunate negotiations. 
							*gosub_scene subroutines change_personality 2 "arrogant" "-"
						#You don't care. 
			                 
	*selectable_if ((not (arrogant_prick)) and (not (intermediate_inn))) #Not too cheap, but not too expensive either.
		You arrive at an inn with a generic name you don't bother to remember. You walk up to the front of the building and tug at the door. It's locked.
		
		You glance at Quang, who shrugs his shoulders.
		
		"Don't know what happened to it, ${YM}. It should be open." — the captain says. 
		
		Not fancying waiting, you decide on going to another inn.
	
		*set intermediate_inn true
		*goto choosing_inn
		
	*selectable_if ((not (arrogant_prick)) and (interscene_temp != "inn")) #The cheapest one. 
		Quang gives you a strange look. You are a noble, an heir to a Great Clan: you should be taking baths with gold instead of water, and yet choose the cheapest inn? He doesn't comment on it, however.
		
		Soon you arrive at a run-down, single-story building. A sign hangs above the front door — dilapidated due to time and neglect, it threatens to plummet on the head of some unfortunate drunk. There are many of those here, some trying to reach home on trembling legs, some entering and with every cup becoming closer to the fate of the former. Others lie on the ground near the building, soaked in their own urine and mumble slurred words in an inebriated sleep. 
		
		You push the door. It opens with a creak, gathering the attention of all the patrons onto you. They notice your clothes, your clear skin, and a captain of the city watch serving as your personal guard. Their reactions differ. Most immediately lower their heads and avert their gazes, not wishing to catch the unfortunate eye of a noble. A small group, however, glares at you with obvious hostility. Their animosity is surprising, though you can't help but commend their bravery. 
		
		Walking forward, you materialize a handful of gold coins and toss them onto the counter.
		
		"Have two rooms available?" — you ask the innkeeper. He's a giant of a man, with a big belly and a broad chest. Hideous scars — you can't tell whether they are from a dagger or a claw — embellish his face. 
		
		The man squints the only eye he has left, the second one gouged out.
		
		"Your kind is not welcome here. Leave." — he doesn't even glance at the gold, instead continuing wiping a glass with a towel.
		
		The innkeeper is clearly someone who has seen war and tasted death. He maintains his composure against two nobles and an armored soldier, being unarmed and only protected by his impressive mass. A dangerous mortal — one, you're not sure you can take.
		*temp tried_to_stay false
		*label cheapinn_choice
		*choice
			*selectable_if (not (tried_to_stay)) #"Come on, friend. We only want two rooms and do not seek trouble." @{(tooltip) [b][PERSUASION][/b] |} 
				The innkeeper looks at you with a scrutinizing gaze. He studies you from head to toe, evaluating whether or not it would be worth it to let you stay.
				
				*gosub_scene subroutines stat_check "chr" 5
				*if (stat_check)
					
					After a while, he sighs.
					
					"Fine. Though I will charge you extra — you don't seem to be struggling for gold." — the Innkeeper points his hand at the inn's current guests, a rabble bunch enjoying their cheap meals and cheap ale — "Like these fellows do."
					
					You nod your head and hand him the gold.
					
					[b]Gold -40.[/b]
					*set mc_gold -40
					*set cheapinn true
					*page_break Go To Your Room
				*else
					After a while, he shakes his head. 
					
					"No deal. People like you tend to attract trouble. Leave now, I will not ask again."
					*set tried_to_stay true
					*goto cheapinn_choice

			#Leave.
				You look at the innkeeper in wonder. This is the first time you've been rejected by an establishment, a mortal one at that. It feels… strange.
				
				Still, you decide not to create a fuss. This is their place of business and they are well within their rights to refuse service to anyone, even a noble. 
				
				"Very well." — you nod at the innkeeper and turn to your companions —  "We'll be on our way then."
				
				*gosub_scene subroutines reputation_change 10 "kindness" "+"
				*gosub_scene subroutines change_personality 2 "arrogant" "-2"
				
				*page_break Choose Another Inn
				*set interscene_temp "inn"
				*goto choosing_inn
			#Attack the innkeeper.
				*gosub_scene subroutines change_personality 2 "violent" "+"
				*goto_scene fight_innkeeper
		
*label room
[i]Tomorrow is going to be a difficult day.[/i] — you think, as you lay on a
*if (cheapinn)
	simple mattress made of straw. Your back hurts and you are far from comfortable. You still don't know why exactly you decided to be so frugal, spend the night in this dump of a place. But hey, even a mountain of gold is made up of single coins, is it not?
*else
	warm, comfortable bed. Although it can't compare to the one you had back home, at least you don't experience any discomfort. 

*goto_scene tournament_2