*bug Subroutine scene called without label. Make sure to specify the subroutine to be called by label.
*label add_exhaustion
*params value return_scene
*gosub add_exhaustion_return value return_scene true
*return

*label add_exhaustion_return
*params value return_scene need_return
*set value round(value-0.5)
*if (not (need_return))
	*set stat_check true
*if (precognition_enabled)
	*return
*set mc_stamina -value

*if mc_stamina <= 0
	*if (mc_trait_6) and (mc_trait_6_cost != 999)
		*set mc_stamina (mc_stamina_total/2)
		*set mc_trait_6_cost 999
		
		[b]Second Wind[/b] activated!
		*gosub reduce_true_health (mc_health/2)
	*else
		*set mc_stamina 0
		*if (need_return)
			The action takes too much of your energy as your body grows limps and your head dizzy.

			Your vision goes black and you fall down, unconscious.
			*if return_scene = ""
				*set return_scene "game_over"
			*goto_scene {return_scene} defeat
		*else
			*set stat_check false
			*return

*if (show_health_text)
	*if value != 0
		*stat_chart
			percent round((mc_stamina/mc_stamina_total)*100) Inner Energy

*return

*label heal_injuries_weekly
*params days
*temp n 1
*temp total_injuries 0
*temp healing_cost 0
*label heal_weekly_loop
*if (injuries[n])
	*set total_injuries +1
	*if (not (mc_trait_1))
		*set healing_cost +(injuries[n]["healingreq"]*10)
	*set injuries[n]["healing"] 0
	*set injuries[n] false
*set n+1
*if n <= injuries_count
	*goto heal_weekly_loop

*if total_injuries > 0
	*if (healing_cost) > 0
		[b]Sect healers help you treat your injuries for the price of ${healing_cost} Contribution Points.[/b]
	*else
		[b]Your regeneration allows you to mend your injuries without asking sect healers for treatment.[/b]
*if (mc_trait_1)
	*if mc_health < mc_health_total
		[b]Your body steadily restores its peak condition.[/b]
		*gosub increase_health ((1+round((mc_vit*0.1)-0.5))*(days*2))
*else
	*if mc_health < mc_health_total
		[b]Your body slowly recovers its peak condition.[/b]
		*gosub increase_health ((1+round((mc_vit*0.1)-0.5))*(days))
*return

*label heal_injuries
*params value
*temp n 1
*label heal_loop
*if (injuries[n])
	*set injuries[n]["healing"] +mc_vit
	*if injuries[n]["healing"] >= injuries[n]["healingreq"]

		[b]One of your injuries has healed.[/b]
		*set injuries[n]["healing"] 0
		*set injuries[n] false
*set n+1
*if n <= injuries_count
	*goto heal_loop
*if (mc_trait_1)
	*if mc_health < mc_health_total
		*if mc_tattoo_phoenix = 2
			*gosub increase_health (2*(1+round((mc_vit*0.1)-0.5)))
			*set mc_tattoo_phoenix 1
		*else
			*gosub increase_health (1+round((mc_vit*0.1)-0.5))
*return

*label increase_health
*params value
*set mc_health +value
*if mc_health > mc_health_total
	*set mc_health mc_health_total
*stat_chart
	percent round(((mc_health/mc_health_total)*100)) Health 
*return

*label dodge
*temp twenty_percent_stamina round((mc_stamina_total*0.2)-0.5)
*if (mc_trait_10) and (mc_stamina > twenty_percent_stamina) 
	*set dodged true
	[b]Battle Sense activated.[/b]
	*gosub_scene subroutines add_exhaustion twenty_percent_stamina fight_scene 

*else
	*set dodged false
	
*return

*label reduce_true_health_return
*params value return_scene armor
*set value round(value-0.5)
*if (precognition_enabled)
	*return
*if value > 0
	*if (not (armor))
		*goto suffer_damage
	*if (mc_con) > value
		*set value 1
		*set blocked true
		
	*else
		*label suffer_damage
		*set value -round((mc_con*0.1)-0.5)
		*if mc_tattoo_turtle = 2
			*set value -2
			*if value < 0
				*set value 0
			*set mc_tattoo_turtle 1
		*set blocked false
		*if (injuries_7)
			[b]You rib is broken. You suffer additional damage.
			*set value +1
		
		*if (injuries_3)
			[b][/i]You are bleeding! Additional damage received.[/b][/i]
			*set value +1

*set mc_health -value
*set damage value

*if mc_health > mc_health_total
	*set mc_health mc_health_total

*if (show_health_text)
	*stat_chart
		percent round(((mc_health/mc_health_total)*100)) Health 
	
*else
	*temp string " "
	
	${string}
	
*if mc_health <= 0
	*if (mc_equipped_robe = 1)
		*if fight_scene = "fight_arena_yunge"
			*goto set_health_0
		*if fight_scene = "sect_tigress_second"
			*goto set_health_0
		*else
			*set mc_health mc_health_total
			*gosub disequip_item "con" 1
			*set equipment_1 0
			*set mc_equipped_robe 0

			[b] Father's love [/b] activated!
	*elseif (mc_tattoo_phoenix > 0)
		*set mc_tattoo_phoenix 0
		The Phoenix on your chest refuses to sit idle and let you die: it's wings flop, it's mouth lets out a rumbling shriek and, as if by a divine will, your body returns to its peak condition.
		
		*set mc_stamina mc_stamina_total
		*set mc_health mc_health_total
	*else
		*label set_health_0
		*set mc_health 0
		*if return_scene != "game_over"
			*goto_scene {return_scene} defeat
		*else
			*goto_scene game_over
		
*return

*label reduce_health
*params value
*gosub reduce_true_health_return value "game_over" true
*return

*label reduce_health_return
*params value return_scene
*gosub reduce_true_health_return value return_scene false
*return

*label reduce_true_health
*params value
*gosub reduce_health_return value "game_over" false
*return

*label spend_exp
*params value atr
*gosub parent_give_exp value atr true true
*return

*label parent_give_exp
*params value atr display meditation
*line_break
*temp modded_value value
*if atr = ""
	*if difficulty != 999
		*set mc_EXP +modded_value
		*if (display)
			[b]🡹 +${modded_value} FREE EXP 🡹[/b]	
*else
	*temp exp_left 50+(mc[atr]*10)
	*temp old_value modded_value
	*set modded_value *(mc[atr]["mod"]/100)
	*if (meditation) and (mc[atr]["mod"] != 1)
		[b]EXP has been changed by ${round((modded_value-old_value))} due to your bodytype/traits/items.[/b]
		*set old_value modded_value
		*line_break
	*set modded_value *(1-(mc_impurities/100))
	*if (meditation) and (mc_impurities != 0)
		[b]EXP has been reduced by ${round((modded_value-old_value))} due to the impurities in your blood.[/b]
		*set old_value modded_value
		*line_break
	*set modded_value round(modded_value-0.5)
	*if (meditation)
		*set mc_exp - value
	*else
		*set modded_value * difficulty 
	*set mc[atr]["exp"] + modded_value
	*if mc[atr]["exp"] >= exp_left
		*gosub increase_atr atr true
	*else
		[b]🡹 +${modded_value} $!{atr} EXP 🡹[/b]			
		
*return

*label give_exp_text
*params value atr display
*gosub parent_give_exp value atr display false
*return

*label give_exp
*params value atr
*gosub give_exp_text value atr true
*return

*label increase_atr_multiple
*params atr increase account_for_exp
*temp i 0
*set increase (round(increase-0.5))
*if (account_for_exp)
	*set mc[atr]["exp"] -(100+(100*round((mc[atr]/10)-0.5)))
*label increase_atr_loop
*if i < increase
	*if mc[atr] < (10+(10*mc_level))
		*set mc[atr] + 1
		*if atr = "vit"
			*set mc_health_total +1
	*set i +1
	*goto increase_atr_loop
*if (increase > 1)
	[b]🡹 +${increase} ${atr} 🡹[/b]	
*else
	[b]🡹 +${atr} 🡹[/b]	
*if (account_for_exp)
	*if mc[atr]["exp"] >= (100+(100*round((mc[atr]/10)-0.5)))
		*gosub increase_atr atr account_for_exp		

*return

*label increase_atr
*params atr account_for_exp
*gosub increase_atr_multiple atr 1 account_for_exp
*return

*label change_opinion
*params char value type
*temp string "characters_${char}_opinion"
*temp mod round((mc_chr*0.1)-0.5)
*if characters[char]["status"] = "Hostile"
	*set characters[char]["opinion"] 0
	*return
*if (type = "+")
	*set value +mod
	*set {string} + value
	*if {string} > 100
		*set {string} 100
*else 
	*set value -mod
	*set {string} - value
	*if {string} < 0
		*set {string} 0
*return

*label add_injury
*params id
*if (precognition_enabled)
	*return
*if (injuries[id])
	*set injuries[id]["healing"] 0
	*return
*if id = 2
	[b]Injured:[/b] [i]Your nose is broken.[/i]
	
	*set injuries_2 true
	*set injuries_2_healing 0
*if id = 3
	[b][i]You are bleeding![/b][/i]

	*set injuries_3 true
	*set injuries_3_healing 0

*elseif id = 4
	*set injuries_4 true
	*set injuries_4_healing 0

	[b]Injured:[/b] [i]Your leg is broken.[/i]
*elseif id = 5
	*set injuries_5 true
	*set injuries_5_healing 0
	
	[b]Injured:[/b] [i]Missing teeth.[/i]
*elseif id = 6
	*set injuries_6 true
	*set injuries_6_healing 0
	
	[b]Injured:[/b] [i]Broken back.[/i]
*elseif id = 7
	*set injuries_7 true
	*set injuries_7_healing 0
	
	[b]Injured:[/b] [i]Broken rib.[/i]

*elseif id = 8
	*set injuries_8 true
	*set injuries_8_healing 0
	
	[b]Injured:[/b] [i]Broken hand.[/i]
	
*elseif id = 9
	*set injuries_9 true
	*set injuries_9_healing 0
	
	[b]Injured:[/b] [i]Missing arm.[/i]


*return

*label equip_item
*params atr value
*temp total mc[atr] + value
*set mc[atr] +value
*set mc[atr]["temp"] + value
*return

*label disequip_item
*params atr value
*temp total (mc[atr]["temp"] - value)
*set mc[atr]["temp"] -value
*set mc[atr] -value

*if mc[atr] < 0
	*set mc[atr] 0
*return

*label clear_fight_options
*temp clear_options_temp 1
*set fight_option_count 10
*label clear_fightoptions_loop
*set fight_option[clear_options_temp] "none"
*if clear_options_temp < fight_option_count
	*set clear_options_temp +1
	*goto clear_fightoptions_loop
*return

*label clear_fight_variables
*temp clear_vars_temp 1
*label clear_fightvars_loop
*set fight_option[clear_vars_temp]["nonselect"] false
*if clear_vars_temp < fight_option_count
	*set clear_vars_temp +1
	*goto clear_fightvars_loop
*set fight_weakspot false
*set precognition_enabled false
*return

*label check_skill
*params atr type req
*temp string ""
*if atr = "per"
	*set string "Persuasion"
*elseif atr = "int"
	*set string "Intimidation"
*elseif atr = "sed"
	*set string "Seduction"
*elseif atr = "man"
	*set string "Manipulation"
*elseif atr = "neg"
	*set string "Negotiation"
*elseif atr = "ins"
	*set string "Insight"

*if (show_check_text)
	*if type = "pos"
		[b][i]${string} … ✅[/i][/b]
	*elseif type = "crit_pos"
		[b][i]${string} … ✅✅✅[/i][/b]
	*elseif type = "neg"
		[b][i]${string} … ❌ [/i][/b]
	*elseif type = "crit_neg"
		[b][i]${string} … ❌❌❌ [/i][/b]
	*if (show_check_text_req)
		[b][i] (Req: ${req}) [/b][/i]
*else
	*set string " "
	${string}

*return

*label check_text
*params atr type req
*gosub check_text_double atr "" type req
*return

*label check_text_double
*params atr1 atr2 type req
*temp string ""

*if atr1 = "str"
	*set string "Strength"
*elseif atr1 = "agi"
	*set string "Agility"
*elseif atr1 = "con"
	*set string "Constitution"
*elseif atr1 = "end"
	*set string "Endurance"
*elseif atr1 = "per"
	*set string "Perception"
*elseif atr1 = "vit"
	*set string "Vitality"
*elseif atr1 = "int"
	*set string "Intelligence"
*elseif atr1 = "chr"
	*set string "Charisma"
*elseif atr1 = "prestige"
	*set string "Prestige"

*if atr2 != ""
	*if atr2 = "str"
		*set string string&"&Strength"
	*elseif atr2 = "agi"
		*set string string&"&Agility"
	*elseif atr2 = "con"
		*set string string&"&Constitution"
	*elseif atr2 = "end"
		*set string string&"&Endurance"
	*elseif atr2 = "per"
		*set string string&"&Perception"
	*elseif atr2 = "int"
		*set string string&"&Intelligence"
	*elseif atr2 = "chr"
		*set string string&"&Charisma"	



*if (show_check_text)
	*if type = "pos"
		[b][i]${string} … ✅[/i][/b]
	*elseif type = "crit_pos"
		[b][i]${string} … ✅✅✅[/i][/b]
	*elseif type = "neg"
		[b][i]${string} … ❌ [/i][/b]
	*elseif type = "crit_neg"
		[b][i]${string} … ❌❌❌ [/i][/b]
	*if (show_check_text_req)
		*if req = 0.1
			[b][i] (WEAKSPOT) [/b][/i]
		*else
			[b][i] (Req: ${req}) [/b][/i]
*else
	*set string " "
	${string}

*return


*label precog_turnback
*params return_scene return_label
*if (precognition_enabled)
	*set precognition_enabled false
	*page_break Go Back In Time
	*goto_scene {return_scene} {return_label}
*return

*label prestige_change
*params value operation
*if (mask_enabled)
	[b]You are wearing the Mask of Facelessness, so your prestige doesn't change.[/b]
	
	*return
*if operation = "+"
	*set mc_prestige +value
	
	[b]Your prestige has grown.[/b]
*else
	*set mc_prestige -value
	
	[b]Your prestige has decreased.[/b]

*return

*label reputation_change
*params value type operation

*if (mask_enabled)
	[b]You are wearing the Mask of Facelessness, so your reputation doesn't change.[/b]

	*return
*if type = "honor"
	*if operation = "+"		
		[b]People view you as more [i]honorable[/i].[/b]
		*set mc_reputation_honor + value
	*else
		[b]People view you as more [i]shameless[/i].[/b]
		*set mc_reputation_honor - value
*elseif type = "kindness"
	*if operation = "+"
		[b]People view you as more [i]righteous[/i].[/b]
		*set mc_reputation_kindness + value
	*else
		[b]People view you as more [i]demonic[/i].[/b]
		*set mc_reputation_kindness - value

*return

*label change_personality
*params value pers type
*temp modificator 0
*if type = "+"
	*if mc_goal = 1
		*if pers = "arrogant"
			*set modificator round(value/2)
			*set value +modificator
		*elseif pers = "violent"
			*set modificator round(value/3)
			*set value +modificator
	*elseif mc_goal = 2
		*if pers = "arrogant"
			*set modificator round(value/3)
			*set value +modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value -modificator
		*elseif pers = "ruthless"
			*set modificator round(value/3)
			*set value -modificator
	*elseif mc_goal = 3
		*if pers = "elitist"
			*set modificator round(value/2)
			*set value -modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value -modificator
	*elseif mc_goal = 4
		*if pers = "elitist"
			*set modificator round(value/2)
			*set value +modificator
		*elseif pers = "arrogant"
			*set modificator round(value/3)
			*set value +modificator
	*elseif mc_goal = 5
		*if pers = "egoistical"
			*set modificator round(value/2)
			*set value +modificator
		*elseif pers = "arrogant"
			*set modificator round(value/3)
			*set value +modificator
		*elseif pers = "impulsive"
			*set modificator round(value/3)
			*set value +modificator
	*elseif mc_goal = 6
		*if pers = "indulgent"
			*set modificator round(value/2)
			*set value +modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value +modificator
	*set mc_pers[pers] +value
	*if mc_pers[pers] > 100
		*set mc_pers[pers] 100
*else
	*if mc_goal = 1
		*if pers = "arrogant"
			*set modificator round(value/2)
			*set value -modificator
		*elseif pers = "violent"
			*set modificator round(value/3)
			*set value -modificator
	*elseif mc_goal = 2
		*if pers = "arrogant"
			*set modificator round(value/3)
			*set value -modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value +modificator
		*elseif pers = "ruthless"
			*set modificator round(value/3)
			*set value +modificator
	*elseif mc_goal = 3
		*if pers = "elitist"
			*set modificator round(value/2)
			*set value +modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value +modificator
	*elseif mc_goal = 4
		*if pers = "elitist"
			*set modificator round(value/2)
			*set value -modificator
		*elseif pers = "arrogant"
			*set modificator round(value/3)
			*set value -modificator
	*elseif mc_goal = 5
		*if pers = "egoistical"
			*set modificator round(value/2)
			*set value -modificator
		*elseif pers = "arrogant"
			*set modificator round(value/3)
			*set value -modificator
		*elseif pers = "impulsive"
			*set modificator round(value/3)
			*set value -modificator
	*elseif mc_goal = 6
		*if pers = "indulgent"
			*set modificator round(value/2)
			*set value -modificator
		*elseif pers = "egoistical"
			*set modificator round(value/3)
			*set value -modificator
	*set mc_pers[pers] -value
	*if mc_pers[pers] < 0
		*set mc_pers[pers] 0
*return

*label set_fightoption
*params category id atr type
*temp difficulty fight_req
*if type = "skill"
	*set fight_option[id] mc[category][id]["name"]
	*set fight_option[id] fight_option[id]&" @{(tooltip) [b][${atr}][/b] |}"
*elseif type = "spatial"
	*set fight_option[id] "[i]Open your spatial ring.[/i]"
*elseif type = "supportive"
	*set fight_option[id] "[i]Use a supportive skill.[/i]"
*return

*label randomize_roll
*gosub randomize 1 10 10 "randomized_roll"
*set randomized_roll -5
*return


*label parent_stat_check
*params stat_1 stat_2 enemy_stat crit_req req
*set stat_check false
*set crit_stat_check false

*if enemy_stat != "none"
	*comment this is for f_stat_check
	*if stat_2 = "none"
		*if (triple_bracelet)
			*if stat_1 = "agi"
				*if enemy_per <= (mc_agi-4)
					*if random_bracelet_miss != 1
						*set stat_check true

						[b]The Bracelet's illusion confuses your enemy.[/b]
						*gosub_scene subroutines randomize 1 3 3 "random_bracelet_miss"
						*return
	*if enemy_stat = ""
		*set enemy_stat stat_1
	*set req +fight_difficulty
	*if crit_req != "none"
		*set crit_req +fight_difficulty
	*temp string "enemy_${enemy_stat}"
	*set req + {string}
	*if crit_req != "none"
		*set crit_req + {string}

*if mc_tattoo_dragon = 2
	*set mc_str +3
	*set mc_con +3
	*set mc_agi +3
	*set mc_per +3
	*set mc_vit +3
*elsif mc_tattoo_dragon = 3
	*set mc_str +999
	*set mc_agi +999
	
*if mc_tattoo_turtle = 3
	*set mc_con +999

*temp stat_1_mc mc[stat_1]
*if (random_rolls)
	*gosub randomize_roll
	*set stat_1_mc + randomized_roll
	*if stat_1_mc < 0
		*set stat_1_mc 0
*if stat_2 != "none"
	*temp stat_2_mc mc[stat_2]
	*if (random_rolls)
		*gosub randomize_roll
		*set stat_2_mc + randomized_roll
		*if stat_2_mc < 0
			*set stat_2_mc 0
			
*if (stat_1 = "prestige") and (mask_enabled)
	*goto failed_stat_check

*if crit_req != "none"
	*if stat_1_mc >= crit_req
		*gosub check_text stat_1 "crit_pos" crit_req		
		*set crit_stat_check true
	*else
		*if stat_1_mc >= req
			*goto success_stat_check
		*else
			*goto failed_stat_check
*elsif stat_1_mc >= req
	*if stat_2 != "none"
		*if stat_2_mc >= req
			*label success_double_stat_check
			*gosub check_text_double stat_1 stat_2 "pos" req
			*set stat_check true
		*else
			*goto trying_infusion
	*else
		*label success_stat_check
		*gosub check_text stat_1 "pos" req
		*set stat_check true
*else
	*label trying_infusion
	*if (energy_infusion)
		*gosub add_exhaustion (stat_1_mc/20) fight_scene
		*set stat_1_mc*1.1
		*set stat_1_mc round(stat_1_mc-0.5)
		*if stat_2 != "none"
			*set stat_2_mc*1.1
			*set stat_2_mc round(stat_2_mc-0.5)
			*if (stat_1_mc >= req) and (stat_2_mc >= req)
				*goto success_double_stat_check
			*else
				*goto failed_double_stat_check
		*elsif (stat_1_mc >= req)
			*goto success_stat_check
		
	*label failed_stat_check
	*gosub check_text stat_1 "neg" req
	*if mc_tattoo_dragon = 2
		*set mc_str -3
		*set mc_con -3
		*set mc_agi -3
		*set mc_per -3
		*set mc_vit -3
		*set mc_tattoo_dragon 1
	*elsif mc_tattoo_dragon = 3
		*set mc_str -999
		*set mc_agi -999
		*set mc_tattoo_dragon 0
	
	*if mc_tattoo_turtle = 3
		*set mc_con -999
		*set mc_tattoo_turtle 0
	*return

	*label failed_double_stat_check
	*gosub check_text_double stat_1 stat_2 "neg" req

*if mc_tattoo_dragon = 2
	*set mc_str -3
	*set mc_con -3
	*set mc_agi -3
	*set mc_per -3
	*set mc_vit -3
	*set mc_tattoo_dragon 1
*elsif mc_tattoo_dragon = 3
	*set mc_str -999
	*set mc_agi -999
	*set mc_tattoo_dragon 0
	
*if mc_tattoo_turtle = 3
	*set mc_con -999
	*set mc_tattoo_turtle 0
*return

*label f_stat_check
*params stat enemy_stat req
*gosub parent_stat_check stat "none" enemy_stat "none" req
*return

*label f_stat_check_double
*params stat_1 stat_2 enemy_stat req
*gosub parent_stat_check stat_1 stat_2 enemy_stat "none" req
*return

*label f_stat_check_crit
*params stat enemy_stat crit_req req
*gosub parent_stat_check stat "none" enemy_stat crit_req req
*return

*label stat_check
*params stat req
*gosub parent_stat_check stat "none" "none" "none" req
*return

*label stat_check_double
*params stat_1 stat_2 req
*gosub parent_stat_check stat_1 stat_2 "none" "none" req
*return

*label stat_check_crit
*params stat crit_req req
*gosub parent_stat_check stat "none" "none" crit_req req
*return

*label construct_fight_options
*params id 
*temp n 1
*choice
	*if fight_option_1 != "none"
		*if (fight_option_1_nonselect)
			*selectable_if (not_under_construction) #${fight_option_1}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_1}
				*set n 1
	*if fight_option_2 != "none"
		*if (fight_option_2_nonselect)
			*selectable_if (not_under_construction) #${fight_option_2}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_2}
				*set n 2
	*if fight_option_3 != "none"
		*if (fight_option_3_nonselect)
			*selectable_if (not_under_construction) #${fight_option_3}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_3}
				*set n 3
	*if fight_option_4 != "none"
		*if (fight_option_4_nonselect)
			*selectable_if (not_under_construction) #${fight_option_4}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_4}
				*set n 4
	*if fight_option_5 != "none"
		*if (fight_option_5_nonselect)
			*selectable_if (not_under_construction) #${fight_option_5}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_5}
				*set n 5
	*if fight_option_6 != "none"
		*if (fight_option_6_nonselect)
			*selectable_if (not_under_construction) #${fight_option_6}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_6}
				*set n 6
	*if fight_option_7 != "none"
		*if (fight_option_7_nonselect)
			*selectable_if (not_under_construction) #${fight_option_7}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_7}
				*set n 7
	*if fight_option_8 != "none"
		*if (fight_option_8_nonselect)
			*selectable_if (not_under_construction) #${fight_option_8}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_8}
				*set n 8
	*if fight_option_9 != "none"
		*if (fight_option_9_nonselect)
			*selectable_if (not_under_construction) #${fight_option_9}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_9}
				*set n 9
	*if fight_option_10 != "none"
		*if (fight_option_10_nonselect)
			*selectable_if (not_under_construction) #${fight_option_10}
				*bug SHOULD NOT HAPPEN
		*else
			#${fight_option_10}
				*set n 10
*gosub clear_fight_options
*rand r_v 1 100
*if n = 10
	*set fight_string "supportive"
	*return
*if (n = 9)
	*set fight_string "spatial"
	*return
*if fight_lastchoice = "none"
	*set fight_lastchoice id
*elseif id != fight_lastchoice
	*set fight_lastchoice id
	*gosub clear_fight_variables
*set parameter_return n
*set fight_string "skill"
*return

*label injuries_check
*temp n 2
*set stat_check false
*label injuries_check_loop
*if (injuries[n])
	*set stat_check true
	*return
*else
	*if n < injuries_count
		*set n+1
		*goto injuries_check_loop
	*else
		*return

*label set_enemy_stats
*params str agi con vit per realm skill
*if realm = ""
	*set realm enemy_realm
*if skill = ""
	*set skill enemy_skill
*set enemy_str round(str)
*set enemy_agi round(agi)
*set enemy_con round(con)
*set enemy_vit round(vit)
*set enemy_per round(per)
*set enemy_realm "$!{realm} Houtian"
*set enemy_skill skill
*return

*label fr_restauraunt_popularity
*params value operation text
*if operation = "+"
	*set restaurant_popularity +value
	*if restaurant_popularity > 100
		*set restaurant_popularity 100
	*if (text)
		[b]The popularity of ${restaurant_name} has increased.[/b]
*else
	*set restaurant_popularity -value
	*if restaurant_popularity < 0
		*set restaurant_popularity 0
	*if (text)
		[b]The popularity of ${restaurant_name} has decreased.[/b]
*return

*label set_restauraunt_popularity
*params value operation
*gosub fr_restaurant_popularity value operation true
*return



*label reset_stones
*temp r 1
*label stone_reset_loop
*set newstone_name[r] "none"
*if r < newstone_name_max
	*set r+1
	*goto stone_reset_loop
*set bought_stones "|"
*return

*label f_p_b
*set skill_used false
*set aura_disabled false
*set needle_disabled false
*page_break
*return

*label f_c
*set skill_used false
*set aura_disabled false
*set needle_disabled false
*return

*label clear_fight_vars
*set mc_trait_6_cost 100
*set fight_scene "none"
*set fight_difficulty 0
*set triple_bracelet false
*set skill_used false
*set cosmic_field false
*set skill_storing_ring false
*set mask_enabled false
*set mc_str - talisman_str
*set mc_agi - talisman_agi
*set mc_con - talisman_con
*set talisman_str 0
*set talisman_agi 0
*set talisman_con 0
*set energy_infusion false
*return

*label skill_exhaustion
*params value return_scene skill
*if skill_storing_ring
	*set skill "ring_${skill}"
	*if {skill} > 0

		[b]Usage of the skill consumes 1 charge of the Skill-Storing Ring.[/b]

		*set {skill} -1
		*set equipment_2_stored -1
	*else
		*goto give_exh
*else
	*label give_exh
	*if (mc_trait_2)
		*set value /2
	*gosub add_exhaustion value return_scene
*return

*label change_impurities
*params value operation
*if (mc_trait_8)
	*return
*if operation = "+"
	*set mc_impurities +value
	*set mc_impurities round(mc_impurities)
	*stat_chart
		percent mc_impurities Alchemical Impurities
	
	*if mc_impurities >= 100
		Your body feels [i]bloated[/i]. Full of toxin gas and bile that urge for their freedom, that beg to be let out: you cannot resist.
		
		Your mouth opens by itself and black, darker than the night itself, goo comes it as you puke. With every second, your vision blurs, your limbs grow limper, until you fall unconscious, never to wake up again: your heart stopped beating, stopped [i]existing[/i] as it too had been corrupted and transformed into a void-colored muck. 
		
		*goto_scene game_over
*elsif operation = "-"
	*set mc_impurities -value
	*set mc_impurities round(mc_impurities)
	*if mc_impurities < 0
		*set mc_impurities 0
	*stat_chart
		percent mc_impurities Alchemical Impurities
*return

*label raven_money
*params days
*temp money 0
*rand money 50 100
*if (mc_trait_9)
	*set money 100
*set money * days
*set mc_gold +money
*return

*label randomize
*params value1 value2 target var
*if (mc_trait_9)
	*set {var} target
*else
	*rand {var} value1 value2
*return

*label get_grade_name
*params grade
*if grade = 1
	
*return