*set event_sect_artifactchoosing 2
*temp inspect_needle true
*temp inspect_bracelet true
*temp inspect_ring true
"Of course." — the clerk nods — "Let me see if Elder Rin is available to open up the Sect Treasury." 

She leaves, having you wait in the Mission Hall. You sit on the couch, wondering for how long she's going to be gone — the answer finds you in more than two hours, when the clerk returns with a sleepy, messy-haired Elder Rin in tow. 

"Brat, I should take away your prize for disturbing my monthly sleep." — Elder Rin comments in irritation.

You give her a slight bow. 

"I apologize, Elder." 

She snorts but lets the topic rest.

"Follow me. There is no need for you to go to the treasury, we've already picked the items that might be of use to the current you."

You nod and walk with her back to her quarters, the same place you've gone with He Jun upon your arrival in the sect. There, she opens one of the doors in the room — and you almost [i]drown[/i] in the suffocating pressure emitted from the inside. It becomes hard to breathe and your legs start to buckle from underneath you…

*gosub_scene subroutines stat_check "str" 13 
*if (stat_check)
	You manage to remain standing underneath the pressure's might and due to your success catch an impressed glance from Ma Rin, who clearly hasn't expected you to withstand the leaking power of the heavenly treasures. Then, she opens the door a bit more — and now you have no choice but fall to your knees. She grins and you understand, this is the punishment for intruding on her slumber time.
*else
	You fall to your knees, unable to remain standing underneath the pressure's might. You catch Ma Rin grinning and understand, this is the punishment for intruding on her slumber time.

She takes out three items from the room and closes the entrance to the terrifying room. 

"Pick." — she says, throwing the no doubt priceless for you artifacts at your feet as if they were children's toys. 

*choice
	#"What was in that room?"
		Real artifacts — items with abilities that transcend common sense — all have a certain aura to them. And when a lot of powerful artifacts are gathered together, that aura is plenty to make any Houtian kneel with its sheer presence.

		"Didn't you say we weren't going to the treasury?" — you ask — "What in the Heavens was that room then?"

		Ma Rin chuckles.

		"If you think that was the Sect Treasury, you are in a for a surprise when you see the real one." — she answers — "This is just my personal collection." 

		"Now stop wasting my time. Pick your artifact and get out."
		*goto inspect_artifacts
	#"I'd ask you to warn me next time." 
		Real artifacts — items with abilities that transcend common sense — all have a certain aura to them. And when a lot of powerful artifacts are gathered together, that aura is plenty to make any Houtian kneel with its sheer presence.

		"I'd like to get a warning next time." — you say, as you get up.

		Elder Rin sneers.

		"And I'd like for you to shut the fuck up, pick your item and get out."
		*goto inspect_artifacts
	#"Don't you fucking dare do that again, bitch."
		Real artifacts — items with abilities that transcend common sense — all have a certain aura to them. And when a lot of powerful artifacts are gathered together, that aura is plenty to make any Houtian kneel with its sheer presence.

		What Elder Rin did, without warning you, served no other purpose apart from humiliating you. 

		"Don't you fucking dare do that again, bitch!" — you yell at her in your indignance, not caring about the differences in your statuses and personal power.

		Perhaps you should've.

		Elder Rin chortles, and steps closer to you. Not minding your anger filled stare, she lifts up your chin with her delicate finger.

		"Someone seems to be in need of a punishment." — she whispers in you ear. 

		You clench your fist, but, before you manage to reply, she grabs you by
		*if mc_hair_length != "bald"
			your hair
		*else
			your collar
		and [i]slams[/i] you into the floor.

		*gosub_scene subroutines add_injury 2
		*gosub_scene subroutines add_injury 5

		You lose consciousness…
		*page_break Wake Up
		When you come to your senses, you find yourself in the infirmary, with a healer standing nearby.
		
		The healer clasps her hands at you.
		
		"Elder Rin relays that she has takes your reward for herself as compensation for your offense. However, if you're willing, you can buy it back from the Disciple Store for Contribution Points."
		
		The healer then bows and exits the room.
		*set event_sect_artifactchoosing 2
		*goto_scene fr_infirmary
	#Inspect the artifacts.
		You decide that arguing with her about her little stunt is has no chance of ever ending up in a productive outcome — so you don't say anything, stand up and start to browse through the items.
*label inspect_artifacts
*page_break Artifacts
There are three items in front of you: a thin, metallic needle with a sharp-looking edge, a bracelet with an intricate design and a jade-made ring.

*choice
	*selectable_if (inspect_needle) #Inspect the needle.
		*set inspect_needle false
		You pick up the needle and put it in your hand. It's light, almost weightless and when you press your finger onto its tip, the needle easily pierces through your skin.
		
		"You ought to be careful with that." — Elder Rin says — "It's called Needle of Absolute Penetration. It's a High-Grade Houtian artifact, irresistible by any defense a Martial Artist of the same realm can conjure."
		
		You nod, but can't help but be skeptical.
		
		"That sounds good, but what's the use of it in a battle? I doubt something so tiny can harm a Martial Artist, even if it thrusts through."
		
		"You're right." — confirms Elder Rin — "By itself, the needle is quite inept. However, if you apply a potent poison onto its blade…" 
		
		She doesn't continue, but the possibility she hinted at already makes you salivate. 
		
		"Does the poi-"
		
		"No." — Elder Rin interrupts — "Poisons do not come with the artifact. You'll have to acquire them yourself. 
		
		Well, that's reasonable, you suppose. You put down the needle.
		*goto inspect_artifacts
	*selectable_if (inspect_bracelet) #Inspect the bracelet.
		*set inspect_bracelet false
		You pick up the bracelet and observe the runes engraved on exterior.
		
		*gosub_scene subroutines stat_check "int" 12
		*if (stat_check)
			You've seen something similar before — although you can't be certain what these runes do, they for sure are related to the power of illusions. 
		
		"This is a Bracelet of Triplication, a High-Grade artifact." — Elder Rin clarifies — "When used, it creates two identical clones of yourself, indistinguishable from the original. Although the clones are not real, due to the intricate work put into this bracelet, if your target cannot tell the difference, they will be able to inflict [i]actual[/i] damage onto it."
		
		"The Bracelet has three charges. You can replenish them, but that will cost you a costly sum."
		
		You nod and put the bracelet down.
		*goto inspect_artifacts
	*selectable_if (inspect_ring) #Inspect the ring.
		*set inspect_ring false
		You pick up the ring. It's made from a beautiful jade, but try as you might, you can't figure out its use. 
		
		"This is the most mysterious item we have. To be sure, even our best Enchanters are not sure how it works. If it wasn't limited to Houtian, we would never even offer it to you you."
		
		"What's its use?" — you eagerly inquire. 
		
		"It can store a single skill you know for future use. Without any cost attached." — she explains — "This might seem underwhelming with your current abilities. But imagine that you have an ultimate Skill, that requires a ton of Inner Energy to use: maybe even something else in order to be activated. Instead, you can prepare it beforehand and utilize the Skill to change the tides of battle. Moreover… that activation is always instantaneous, which isn't the case for most transcendent skills, as you'll find out when you encounter them."
		
		"Is it the only Top-Grade artifact offered?"
		
		"We're not sure if it's a Top-Grade. As I said, the ring is far too complicated for our Enchanters to determine. It doesn't give off any aura, if you haven't noticed."
		
		You put down the ring.
		*goto inspect_artifacts
	*if (((not (inspect_needle)) or (not (inspect_bracelet))) or (not (inspect_ring)))
		#Decide on the artifact.
			Which artifact would you like to pick?
			*choice
				#Needle of Absolute Penetration.
					"I'll take the needle." — you say to Elder Rin. 
					*set equipment_3 1
				#Bracelet of Triplication.
					"I'll take the bracelet." — you say to Elder Rin. 
					*set equipment_4 1
				#Skill-Storing Ring.
					"I'll take the ring." — you say to Elder Rin.
					*set equipment_2 1
					
			She nods and, with a wave of her hand, causes the other items to fly back into her treasure room.

			"If you want, you can purchase the other items in the store for disciples. However, they will only be available for a limited period of time. So hurry if you're interested."
			
			*set event_sect_artifactchoosing 2
			*goto_scene free_roam