*temp knows_about_houtian false
*temp manipulation_difficulty 0
*temp accident false
*temp trial_result 0
*temp contr_points_fine 0
*temp solitary_confinement_time 0
*temp attempted_neg false
*gosub_scene subroutines randomize 1 3 3 "random_bracelet_miss"
After landing in the sect and handling the mosquitoes over to the dozens of disciples waiting nearby, He Jun organizes all of you in a line and leads the group to the Administrative Hall. 

It's a large, multi-story building with wooden red posts supporting gabled, tiled roofs between the floors — a construction similar to others in the sect. When you enter, a young man with a blue brooch pinned on his chest — which indicates his status as an Inner Disciple — runs up to greet He Jun.

"This disciple greets Envoy Jun." — he says, bowing in respect — "These are recruits of the year, I take it?"

He Jun nods in return.

"Register them and give them their badges."

"Of course, Envoy." 

"Is your Mistress present?" — asks He Jun.

"She is, though I believe she is… occupied." — the young man answers, scratching his neck.

He Jun snorts.

"Yes, I am quite familiar with her [i]occupations[/i]. Sect business is more important. Take care of the new recruits, I'll be taking these three to see Elder Rin." 

He gestures to you, Tang Ruo and the Tigress to follow him before climbing the stairs leading to the second floor.

*page_break Follow He Jun
He Jun barely performs the courtesy of knocking, before he pushes the door leading to the Elder's quarters open. 

Inside, a mature woman, somewhere in her thirties judging by appearance, sits in a large, lavish chair that resembles more a royal throne than an ordinary piece of furniture. Her long, shapely legs are stretched out, supported by the back of an obedient servant plastered on the ground underneath them. Two more servants massage her bare feet, one for each, their fingers trembling in fear of attracting her dissatisfaction. Another slave stands near her, with a plate full of fruit, and places grapes inside the woman's mouth whenever she turns her marble-made, exquisite face to him.

All the varlets have their looks in common: they are young men, tall and wide-shouldered, with pretty features and the cleanest pale skin. They also seem to lack articles of clothing that could cover up their upper-bodies, carrying their duties out half-naked. 

"Someone has a deathwish." — Elder Rin seethes as the opened door interrupts her peaceful harmony. 

*set characters_11_opinion 50
[[b]Ma Rin[/b] added to [b]Character Glossary[/b]]

"Elder Rin, I have urgent matters to discuss." — He Jun replies, the current sight not flustering him in the slightest.

Elder Rin opens her eyes, almond-shaped and of the same color as her silver hair, just to immediately roll them afterwards.

"Oh. It's you, Ugly Jun." — she sighs in disappointment — "How many times do I have to scold you for barging into my lodgings? I know that you hope to catch me in an indecent state, but such actions warrant a well-deserved [i]punishment[/i]."

You notice how He Jun clenches his fists, his nails almost puncturing the skin from the sheer force of his squeeze. 

"This is of paramount importance to the sect, Elder Rin. Please, stop your jests."

"Fine, fine, what is it?" — her eyes leave He Jun and land the on the trio behind him — "This must be our new disciples?"   

"Handsome enough, but your name carries too much trouble. A shame." — she evaluates Tang Ruo.
	
"Gods no, this one is more beast than a human"

The Tigress growls, but Elder Rin pays it no heed and glances at you.

*if (mc_trait_3)
	She beams, her sullen countenance caused by He Jun's interruption lightens in an instant.
	
	"What a sweet thing you are!" — she exclaims and licks her lips —
	*if mc_sex = 0
		"Just how I like them." 
	*else
		"I usually prefer boys, but for such a darling I'd make an exception." 

	Her hand reaches for your cheek and pinches it.

	*choice
		#"I'm flattered by the Elder's compliment." 
			"As you should be, hehe, this beauty has very refined tastes." — Elder Rin giggles, pats your cheek one last time and recalls her hand — "Tell me, what's your name?"
		#Stand there awkwardly. 
			"Don't be shy, this lady doesn't bite. Unless you ask her nicely." — Elder Rin giggles, pats your cheek one last time and recalls her hand — "Tell me, what's your name?" 
		#"You're creeping me out."
			"There's no need to be afraid, this lady won't hurt you. Unless you ask her nicely." — Elder Rin giggles, pats your cheek one last time and recalls her hand — "Tell me, what's your name?" 
		#Slap away her hand. 
			She stares at her slapped hand in incredulity.

			"Feisty." — Elder Rin giggles — "We're going to have so much fun. Tell me, what's your name?"

	"Wu ${mc_name}." 

	"Tsk. Why didn't you say so? The best ones always have old monsters hiding in their shadow. How disappointing." — she says, her lips pressing tightly, before she once again focuses on He Jun — "What is it you disturbed me for? I assume these three must be talented enough that you want to put them in the list of potential Core Disciples?"
*else
	"Ugly, ugly." — She shakes her head in disappointment — 	"I hope that the rest of the batch has some pretty people in it."
	
	*fake_choice
		#"You are not that beautiful yourself."
			Elder Rin laughs out loud. Then, she puts her hands underneath her very impressive bust and lifts it up, the tight dress she wears accentuating her curves.

			"I have two friends here that profoundly disagree."
		#Keep silent.
		#"This is unfair. No one can match the Elder's beauty."
			"Ah, if only your looks were as sweet as your tongue… We could've had much fun together."
		#"Be careful with your words."
			Elder Rin laughs out loud.
	
			"I haven't been threatened by a mortal in a good century. What a feisty child."
	
			*if mc_level = 1
				"I'm not a mortal."

				She takes a closer look at you and her brows soon rise in surprise.

				"You've reached Houtian before coming to the sect? Impressive. Still ugly, though."

				*set knows_about_houtian true
				"What is it you disturbed me for?" — Elder Rin asks He Jun — "I assume these three must be talented enough to be potential Core Disciples?"
	

"Yes, Elder." — agrees He Jun — "Their blood purity is shocking." 

"Go on."

"The savage woman has eighty-four percent."

"And here I thought the blood of barbarians is too frozen by the coldness of the West to be awakened."

"The Prince has ninety-seven percent." — the Envoy continues  —  "A talent unseen in thousand of years." 

At once, Elder Rin loses her humor and becomes serious.

"That's… That's higher than the Dragon Taming Emperor, right, boy?"

"Correct. Grandpa has ninety-three." — Tang Ruo answers with a smirk. 

"A family of freaks, freaks I say…" — murmurs Elder Rin — "And how is the last one?"

"A hundred."

"What?" — she spouts in disbelief — "That's not possible."

"The mirror [i]broke[/i], Elder Rin. It fell apart in my hands."

"Maybe you squeezed it too hard. You're not the most graceful man."

"Elder Rin." — He Jun exasperates.

"It's easier to believe in your clumsiness than in the reincarnation of Tang Wei." — Elder Rin replies, but soon comes to terms with your exceptionalness — "I'll need to report this to the Council."

Then, a glint of mischief flashes in her eyes as she addresses He Jun.

*temp sexname "boy"
*if mc_sex = 1
	*set sexname "girl"

"Say, on a scale of one to bash your head open against a wall, how frustrated are you that the second coming of the First Emperor is Wu Chao's ${sexname}? Your father must have poisoned your ears about that handsome bastard, hasn't he?"

*choice
	#"You knew my father?"
		"Knew him?" — Elder Rin chuckles — "Yes, I knew him. Very [i]intimately[/i], if I may add. Then again, half the sect at the time had similar relations with your old man." 

		She points at He Jun.

		"His mother included."
	
	#"What does my father have to do with Envoy Jun?"
		"Nothing much, nothing much. Just fucked his mom, that's all." 
	#"How dare you insult my father?"
		"Careful, ${sexname}. Or I will discipline you in your father's stead."

		Elder Rin chuckles.

		"Or, I can ask your elder almost brother to do it." 
	#Stay silent.
		He Jun struggles to hold himself back, the veins on his forehead and neck throbbing from the contained anger.
	
		Elder Rin chuckles.
	
		"I'm sure that your father had the same rage-filled expression when the whole sect referred to him as 'Cuckold Bojing'. 
	

"SHUT UP!" — He Jun shouts as his body erupts with an unimaginable for your speed. 

A blink ago, he stood a good dozen meters away from Elder Rin — now he's up close, his hand aiming for the Elder's face and its sheer momentum slices apart the air. However, Elder Rin catches his, no doubt capable of annihilating you, fist with a pinch of her thumb and index finger. She doesn't even bother to stand up, instead wordlessly asking her servant for another grape. Such nonchalance sobers him up. There are hundreds of Envoys in the sect, but only thirteen elders: the disparity between them is massive.

"If you're so strong, why don't you go and find trouble with Wu Chao? All he does is drink and fuck, while you train like a maniac every second of the day. I'm sure you can defeat him, why do you have to release your anger on this weak lady?"

She throws him to the side, her dainty arm not bothered by the weight in the slightest, and He Jun grunts as his body collides with a wall. 

"You know, they had to perform a blood test on him to determine who his real father was. Humiliating, isn't it? " — Elder Rin says to you — "If you really want to get under his skin, just call the guy Bastard Jun."

You hear a loud thud and glance at He Jun, who has broken the floor with his hand in fury, yet isn't willing to attack again. Although none of them used their full strength, the previous exchange was enough to understand the pointlessness of such attempts.

'That'd be six thousand gold in compensation." — she warned — "Now, is there anything else?"

*gosub_scene cslib_string find history "tourney_tigress_victory|"
*if cslib_ret > 0
	"Yes. Both Wu ${mc_name} and Prince Ruo are to be made Inner Disciples, due to their high potential and outstanding performance in the tourney." — He Jun replies as he stands up, a mask of indifference glued to his face.
	
	"Seems reasonable." — nods Elder Rin. Her spatial ring flashes, materializing two blue pins in her palm, which she then gives to you and the Prince.
	
	*comment make items / create unequip function
	
	*if (knows_about_houtian)
		"Since you already have reached Houtian, you satisfy the basic requirement of being an Inner Disciple. I recommend you spent the following month, before the official Acceptance Ceremony, familiarizing yourself with the Sect and the town at the foot of the mountain."
		*set mc_sect_position "inner"
	*else
		"The most basic requirement of being an Inner Disciple is undergoing Houtian. This is your immediate goal for the following month and you must accomplish it before the official Acceptance Ceremony."
	
		*if mc_level = 1
			"Actually, Elder Rin, I've already reached Houtian." — you respond to her.

			She takes a closer look at you and her brows soon rise in surprise.

			"You've reached Houtian before coming to the sect? Impressive. Then you should spend this time familiarizing yourself with the Sect and the town at the foot of the mountain."
			
			*set mc_sect_position "inner"
		*else
			*set quests_1 true
			*set mc_sect_position "inner"
*else
	"Yes. Prince Ruo is to be made an Inner Disciple, due to his high potential and outstanding performance in the tourney." — He Jun replies as he stands up, a mask of indifference glued to his face.
	
	"Seems reasonable." — nods Elder Rin — "What about ${YM}?"
	
	"$!{pronoun_3} result was less than satisfactory." 
	
	"I see."
	
	She contemplates for a minute, before flashing you a smile. 
	
	"I'll give you a chance, kid. Reach Houtian in one month, before the official Acceptance Ceremony, and I'll make you an Inner Disciple. Your talent is too high to be ignored. Deal?"
	
	You agree without hesitation: who would refuse such an opportunity?
	
	*set quests_1 true
	
	*set mc_sect_position "outer"
	
*page_break Leave

*if mc_sect_position = "outer"
	*comment give item outer disciple pin

Out of the Elder's quarters, He Jun gathers all the new members of the sect in a single crowd and beckons an Inner Disciple with his finger.

"Escort them to the 1st level. I have matters to attend to." — he says —
*gosub_scene cslib_string find history "fubing_killed_prologue_mc"
*if cslib_ret > 0
	*gosub_scene cslib_string find history "hejun_helps_with_fubing"
	*if cslib_ret > 0
		— "I remember our deal, Wu ${mc_name}. There is no need to visit the Disciplinary Hall, I'll take care of it. Go and rest, the day has been long."

		The Inner Disciple bows and leads the group, including you, away from He Jun. The sect won't prosecute you and, for now, your cold-blooded murder goes unpunished. However, you're not sure whether owing a favor to a member of He Clan was worth it…
	*else
		— "Wu ${mc_name}, and you three come with me. The rest of you can go." 

		The Inner Disciple bows and leads the group out of your sight. You, on the other hand, accompany He Jun and three other nobles — who you recognize were all present during your altercation with Fu Bing — and prepare to handle yourself for the inevitable interrogation regarding regarding your cold-blooded murder.

		The Disciplinary Hall has the same style as the previous building, though it is quite a bit smaller than the hall of administration. Two people in black robes, a man and a woman, meet you inside. 

		"Envoy Jun." — the woman greets — "Trouble at enrollment?"

		"Enforcer Meirong, Enforcer Qingshan." — He Jun nods at them — "Yes. One potential disciple murdered another." 

		"The usual then." — Enforcer Meirong sniggers — "Follow me." 
	
		*page_break Follow Enforcer Meirong
		You find yourself in a large, empty except for a row of chairs and a table room. The enforcers sit down behind the table and gesture you to take your seats.

		"Since the victim cannot testify, we ask Envoy Jun to explain the matter to us. Please, refrain from passing judgment or expressing your opinion on the matter. Right now, we only need the facts of what has happened."

		"After the entry tourney came to the completion, Wu ${mc_name} and Fu Bing got into a conflict."

		As soon as your name was said, the Enforcers share a look. Then, the man, Qingshan, writes something down on a piece of paper. You know full well how justice works both in the sect and outside of it: neither guilt nor innocence matter. In the Martial World, the only law is strength: what these enforcers most concerned about is the relativity of your crime to your status, backing and potential. Although the Sect and Jianghu are supposed to be separate from the secular world of clans and nobles, no one is going to provoke a Peak-Xiantian expert — your father — for something as insignificant as a life of a no-name mortal. 

		"Words were exchanged, after which Wu ${mc_name} attacked with a Energy-fueled punch, crushing Fu Bing's skull and pulverizing his brain."

		"Energy-fueled punch? From a mortal?" — Enforcer Qingshan asks in confusion.

		He Jun shakes his head and gives you a look, on in which you see a clear hint of jealousy. 

		"Wu ${mc_name} ascended to Houtian during the tourney."

		"Oh?" — Enforcer Qingshan writes something down again — "Good to know. Wu ${mc_name}, we'd like to ask you a few questions now."

		"Of course."

		"Do you deny murdering Fu Bing?"

		*choice
			#"Yes, I'm innocent."
				Your declaration catches everyone off-guard. The question was nominal, symbolic more than anything else, as no one expected you to deny an act you did before dozens of people. 

				Such an obvious lie might not have been the smartest choice. 

				"Are you telling us that the accusation is false? I'd advice you against lying, disciple."
				*set manipulation_difficulty +1
				*choice
					#"Yes, it is."
						*gosub_scene subroutines reputation_change 5 "honor" "-"
						"Very well." — replies Enforcer Meirong and turns to the trio of witnesses — "What do the three of you have to say?"
						*set trial_result +5
					#"No. I misspoke. I did kill him."
						"Should've started with that.							 Now, disciple, tell us why did you decide to attack Fu Bing?"
						*set trial_result +2
						*goto why_attack_fubing
					#Actually, it was an accident." @{(tooltip) [b][Manipulation][/b] |}
						*goto accident_choice 
			#"No, I did it."
				*gosub_scene subroutines reputation_change 5 "honor" "+"
				*set trial_result +1
				They nod — it's the expected of you answer, since denying such an obvious, witnessed by dozen of people truth would be idiotic. 

				"Now, disciple, tell us why did you decide to attack Fu Bing?"

				*goto why_attack_fubing
			#"No. What I meant is it was an accident: I failed to control my strength." @{(tooltip) [b][Charisma][/b] |}
				*label accident_choice
				You go into detail about how your recent advancement has left you with no time to properly adjust to your new level of power. How, while you did intent to hurt him, the murder itself was but an unfortunate accident. 
				*label it_was_accident
				*gosub_scene subroutines stat_check "chr" 14
				*if (stat_check)
					*set accident true
					Your words manage to reach the ears of Enforcers. You speak so convincingly, with such confidence in your voice, that they can't help but believe you.

					"Sounds plausible." — Enforcer Qingshan says.

					"Indeed." — the other one adds. 

					"What?!" — shouts one of three witnesses — "He's lying! How the fuck does one flatten a skull by accident? This is bullsh-"

					"Silence." — Enforcer Meirong interrupts him, her petite figure exuding an air of undeniable authority — "Everyone will have their turn to speak."

					She fixes the witness with a dangerous glaze and he folds under the pressure, sitting quietly in his seat.

					"Now, disciple, tell us why did you decide to attack Fu Bing?"
					*label why_attack_fubing
					*choice
						#"He insulted my friend."
							"I take the dignity of my friends very seriously. If someone affronts them right in front of me, what kind of Martial Artist would I be if I don't retaliate?"

							*gosub_scene subroutines reputation_change 5 "honor" "+"

							"An honorable reason." — the Enforcers affirm — "People have been killed for less." 

							Enforcer Meirong turns to the witnesses.

							"What do the three of you have to say?"
						#"He refused to listen to me."
							*set trial_result +1
							"As someone that comes from a minor clan, he should've heeded my words and stopped making a scene. He didn't, making it clear that my name meant nothing to him — so I had to teach him a lesson." 

							"I guess that's understandable…" — one of the Enforcers says.

							"But not a reason good enough to kill someone." — the other retorts and turns to the witnesses — "What do the three of you have to say?"
						#"He was annoying."
							*set trial_result +2
							"He was screaming like a pig, hurling insults that I didn't wish to hear. I told him to stop making a scene, but he was too stupid to listen. I just won a tourney — was I supposed to tolerate his childish antics instead of enjoying my well-deserved rest?"

							"That's not a reason good enough to kill someone." — one of the Enforcers says — "You won't live long if you plan on murdering everybody that annoys you." 

							"I'm alive for now, aren't I?"

							Enforcer Meirong rolls her eyes before turning to the witnesses.

							"What do the three of you have to say?"
						#"No reason. Just felt like it."
							*set trial_result +3
							You gaze at them with contempt — who are they to question you? You are a heavenly genius, unprecedented in the history of the Celestial Empire — some sect workers are not qualified to judge you.

							"So that's how it is." — one of them snorts and turns to the witnesses — "What do the three of you have to say?"
				*else
					*gosub_scene subroutines reputation_change 5 "honor" "-"
					Although your argument contains sound logic, you just can't manage to make your words convincing enough to reach the Enforcers' ears. 

					"It's hardly believable that someone at your level can flatten a skull with a punch by accident." — the Enforcers say and you can tell that they didn't appreciate your dishonesty — "Why did you decide to attack Fu Bing?"
					*goto why_attack_fubing
		*label witness_testimony
		"${YM} ${mc_name} attacked Fu Bing absolutely unprovoked." 

		"Yes! He did it for that barbarian whore."

		"Killed a noble for not even a commoner, for an uncivilized wench. He should be punished!"

		The Enforcers note their words and stop the nobles before their shouts devolve into a mindless ruckus. 

		"Enough. The sect doesn't differentiate between a noble and a commoner. Envoy Jun, what's your opinion on this?"

		*gosub_scene cslib_string find history "hejun_proposition"
		*if cslib_ret > 0
			*if (accident)
				"I agree with what Disciple ${mc_name} has said. I personally has seen ${pronoun_2} reaching Houtian a mere hour before the incident: such a short span of time is not enough to acclimatize to the big increase in power a progression in martial level brings." 

				"While this doesn't excuse ${pronoun_3} transgression, given the circumstances and ${pronoun_2} possible value to the sect, I advice the Enforcers to be lenient." 
			*else
				"Although the crime of murder has happened, I advice the Enforcers to be lenient. Disciple ${mc_name}'s possible value to the sect is extremely high."
		*else
			He Jun sneers.

			"This little bastard is lawless and disobedient. He should be properly disciplined so that such an incident doesn't happen again."
			*set trial_result +2

		*label trial_result
		The enforcers take a minute to converse before they announce their verdict.

		*if trial_result = 0
			"All of this has been a misunderstanding. Disciple ${mc_name} is cleared in this matter and isn't liable for any punishment." 
		*elsif trial_result = 1
			"Although Disciple ${mc_name} is guilty, we do not believe the crime to be serious enough to warrant a punishment. Since Fu Bing wasn't a member of the sect, Disciple ${mc_name} is to pay ten Contribution Points for the loss of potential ${pronoun_1} has incurred. After that, this case is done." 
			*set contr_points_fine 10
		*elsif trial_result = 2
			"Although Disciple ${mc_name} is guilty, we do not believe the crime to be serious enough to warrant a punishment. Since Fu Bing wasn't a member of the sect, Disciple ${mc_name} is to pay thirty Contribution Points for the loss of potential ${pronoun_1} has incurred. After that, this case is done."
			*set contr_points_fine 30
		
		*elseif trial_result = 3
			"Although Fu Bing wasn't a member of the sect, Disciple ${mc_name} has incurred a serious loss of potential for the sect by killing a prospective disciple. $!{pronoun_1} is to be fined fifty Contribution Points and spend a week in solitary confinement." 
			*set contr_points_fine 50
			*set solitary_confinement_time 1
		*elseif trial_result = 4
			"Although Fu Bing wasn't a member of the sect, Disciple ${mc_name} has incurred a serious loss of potential for the sect by killing a prospective disciple. $!{pronoun_1} is to be fined seventy-five Contribution Points and spend two weeks in solitary confinement."
			*set contr_points_fine 75
			*set solitary_confinement_time 2
		*elseif trial_result = 5
			"Although Fu Bing wasn't a member of the sect, Disciple ${mc_name} has incurred a serious loss of potential for the sect by killing a prospective disciple. $!{pronoun_1} is to be fined a hundred Contribution Points and spend a three weeks in solitary confinement."
			*set contr_points_fine 100
			*set solitary_confinement_time 3
		*else
			"Although Fu Bing wasn't a member of the sect, murder is murder. Disciple ${mc_name} killed a very prospective seed for the sect, incurring a serios loss of potential. $!{pronoun_1} is to be fined two hundred Contribution Points and spend a month in solitary confinement.
			*set contr_points_fine 200
			*set solitary_confinement_time 4
		
		Do you accept this verdict?
		*choice
			#Yes.
				*label accept_punishment
				"Since you are a new disciples and don't have any Contribution Points, you will be considered in debt until your repay them."

				*if solitary_confinement_time = 0
					"You are free to go." — the Enforcers say — "Let's hope we won't meet again."
					*set mc_sect_points -contr_points_fine
					*page_break Leave
					You manage to catch up to the group of disciples, just as they make it to the mountain's edge, where a strange, metal box hangs above the cliff with the support of countless ropes. They both stretch to the sky and extend to the ground, long enough to escape your vision.

					*goto catch_inner_disciple
				*else
					"Come with me." — Enforcer Qingshan says.
					*set mc_sect_points -contr_points_fine
					*goto struggle_conf
			*selectable_if ((trial_result > 0) and (not (attempted_neg))) #No, attempt to argue it down.
				*gosub_scene subroutines stat_check "chr" 14
				*if (stat_check)
					You argue with the enforcers until they give up and agree to reduce your punishment.
					*set trial_result -1
					*if trial_result = 0
						"Disciple ${mc_name} is cleared in this matter and isn't liable for any punishment."
						*set contr_points_fine 0
					*elseif trial_result = 1
						"Disciple ${mc_name} is to pay ten Contribution Points."
						*set contr_points_fine 10
					*elseif trial_result = 2
						"Disciple ${mc_name} is to pay thirty Contribution Points."
						*set contr_points_fine 30
					*elseif trial_result = 3
						"Disciple ${mc_name} is to be fined fifty Contribution Points and spend a week in solitary confinement."
						*set contr_points_fine 50
						*set solitary_confinement_time 1
					*elseif trial_result = 4
						"Disciple ${mc_name} is to be fined seventy-five Contribution Points and spend two weeks in solitary confinement."
						*set contr_points_fine 75
						*set solitary_confinement_time 2
					*elseif trial_result >= 5
						"Disciple ${mc_name} is to be fined a hundred Contribution Points and spend three week in solitary confinement."
						*set contr_points_fine 100
						*set solitary_confinement_time 3
		
						*goto accept_punishment
				*else
					"Our decision is final."
					*set attempted_neg true
					*goto accept_punishment
			
			*selectable_if (trial_result > 0) #"Bullshit. You can fuck off to your solitary confinement yourself." 
				Enforcer Qingshan cackles.

				"Cute. You think it was a request?"
				*if trial_result <= 5
					— he gives a look to his partner — "I think his punishment should be increased."
					*set contr_points_fine 200
					*set solitary_confinement_time 4

					*set mc_sect_points -contr_points_fine

					He grabs you by the collar and starts dragging you towards, what you can only assume, is going to be the place of your confinement.
				*label struggle_conf
				*choice
					#Accept your fate.
						You understand the futility of struggle in this situation and make the smartest choice to cease resistance. 

						*page_break Solitary Confinement.
						*goto solitary_confinement
					#Resist.
						You try to struggle out of his grasp, but as soon as the Enforcer notices your fighting attempts, he grins, lifts you in the air and slam you into the ground.

						You lose consciousness. 
						*page_break Solitary Confinement.
						*goto solitary_confinement
	
	
	
	
*gosub_scene cslib_string find history "prologue_tigress_nokilling"
*if cslib_ret > 0
	"All of you can go."
	
	The Inner Disciple bows and leads the group, including you, away from He Jun.


*else
	— "Tigress, come with me to the Disciplinary Hall. The rest of you can go."
	
	The Inner Disciple bows and leads the group, including you, away from He Jun.
	
	….


Soon, you arrive to the mountain's edge  — where a strange, metal box hangs above the cliff with the support of countless ropes. They both stretch to the sky and extend to the ground, long enough to escape your vision.

*label catch_inner_disciple
"This device is called an 'elevator'." — explains the Inner Disciple — "A scholarly marvel that allows us to travel between levels of the sect without having to climb the mountain each time." 

He greets the guards and, after a small chat, starts organizing you in groups of five to use the 'elevator'. 

*if mc_level > 0
	As an Inner Disciple, it's only natural that you go first.
*else
	Although you had a poor performance in the tourney, this Inner Disciple must have heard about your outstanding affinity — he winks at you and allows you to go first, perhaps to make a good impression.

"$!{polite_address} ${mc_name}, you better hold on tight. The journey downwards is far faster than to the top." — he says as you enter the steel box, the space inside barely enough to contain your group.

"What do you me-"

Before you finish your sentence, the elevator [i]drops[/i]. Falls, as the assistance of ropes is taken away from it.
*page_break Elevator Falls
*gosub_scene subroutines stat_check "agi" 10
*if (stat_check)
	Everyone around you, except for the Inner Disciple, lose their footing — but you are agile enough to remain standing, albeit relying on the tight grip of your hands that have grabbed the railings. 
	
	"In all my years here, $!{polite_address} ${mc_name} is the only one to stay on ${pronoun_3} feet after the first elevator ride. Truly impressive." — the Inner Disciple chuckles — "For us, less talented folks, falling face forward is almost like a ritual of initiation." 
*else
	Everyone around you, except for the Inner Disciple, lose their footing — you included, as even the tight grip of your hands on the railings isn't enough to help you remain standing. 
	
	"$!{polite_address} ${mc_name}, no need to be ashamed." — the Inner Disciple chuckles, as you attempt to get up. He offers you a helping hand — "In all my years here, no one has managed to stay on their feet after their first elevator ride. You can consider it a ritual of initiation." 

You step out of elevator and watch as the ropes above it tense, before beginning to slowly pull the steel casing upwards.

*temp slaves_question false
*temp name_question false
*temp devices_question false
*temp rules_question false
*temp question_count 0
You turn to the Inner Disciple, full of questions. 
*label haofan_questions
*if question_count = 4
	The elevator brings down the last group of the new disciples and Hao Fan guides
	*if mc_sect_position = "inner"
		you to your new residence. 
	*else
		them to their new residence.
	
	"Every Outer Disciple lives in buildings like this." — he says as you arrive to a row of uniform, rectangular buildings — "You'll have a room you'll share with three others, with a shared bathroom and kitchen at each floor." 
	
	"Go on then, what are you waiting for?" — Hao Fan nudges the hesitating nobles who undeniably are not used to such accommodations — "Prince Ruo, please, come with me. Inner Disciples reside in separate lodgings."
	
	*if mc_sect_position = "outer"
		"We'll see each other again, ${polite_address} ${mc_name}. I hope, by then, you'll carry the same badge I do."
		
		You enter the dorm, find yourself a room and collapse on the bed almost in an instant — despite the annoying buzz of your roommates. The day has been long and there's an eventful future awaiting you.
	*else
		"${polite_address} ${mc_name}, do follow as well."
		*page_break Inner Disciple House
		The house of an Inner Disciple is much nicer than the previous dorm — to start with, it's an actual house, albeit small and one-storied, where you'll be living alone without anyone bothering you.

		As you enter, you collapse on the bed almost in an instant — the day has been long and there's an eventful future awaiting you.
	
	*goto_scene free_roam
*choice
	*selectable_if (not (slaves_question)) #"Senior Brother, how does this elevator work? Who hauls it?"
		"The ropes connected to the elevator's corners go deep into the mountain, into the caves containing generations of mortal slaves specifically bred for physical labor." 

		You know all about 'breeding' of slaves — you are a ${YM} of a noble clan, after all — a practice of feeding a controlled population of a few hundred mortals alchemical concoctions that increase strength and endurance in their off-spring. This usually comes at the expense of their longevity and quality of life, but Martial Artists hardy care about such insignificant side-effects.

		These slaves rarely get to experience a better life, stuck with the purpose chosen by their overseers for the entirety of their short existence. In this particular case, the mortals shouldn't even be aware that there exists a whole world outside their caves — pulling the rope is everything they know. 

		*choice
			#What a disgusting practice.
				Such barbarity is but another after-effect of the exploitative system where nobles lords over commoners  — where those without the right blood in their veins are considered lesser and inferior. 
			#Pitiful creatures.
				You can't help but feel pity towards these mortals — who are your brethren in flesh and blood, yet subjected to such cruelty. 
			#The world is cruel, I can't worry about some random slaves.
				These mortals can even be considered lucky — at least they don't have to worry about starvation and shelter. The Martial World is heartless and you'd rather carve out your own safe space in it before you waste your pity on the less fortunate.
			#This is the natural order of things.
				Those slaves are weak, their masters — strong. They should be thankful they have food to eat and don't have to worry about dangerous predators of the wild.
		*set slaves_question true
		*set question_count +1
		*goto haofan_questions
	*selectable_if (not (name_question)) #"Senior Brother, what's your name? I don't believe we've been introduced."
		*set characters_13_opinion 50
		"I'm Hao Fan. It's an honor to meet you, Wu ${mc_name}." — he clasps his hands and bows slightly.

		"You know of me?" — you ask.

		"Of course." — he says — "As soon as you landed in the sect, the rumors of your Blood Trial disembarked alongside you." 

		"Tell me, is it true what they say? That you are the second Tang Wei?"

		*choice
			#"Yes. I will be the future sovereign of the Martial World."
				"A bold claim, one that no doubt would cause you innumerable headaches should you follow it." — Hao Fan smiles — "An attitude befitting a heavenly genius."  
			#"That's an exaggeration. My affinity is just a bit higher than average."
				"Talented and humble." — Hao Fan smiles — "Such an attitude will get you far."
			#"Who knows? Time will tell."
				"Indeed it will." — Hao Fan smiles.

		"I'd like to invite fellow disciple for tea once ${pronoun_1} has time. Visit me in the Mission Hall, I believe we have much to talk about." 

		*set name_question true
		*set question_count +1
		*goto haofan_questions
	*selectable_if (not (devices_question)) #"Are there any more strange devices like this in the sect?"
		"Of course. The sect stood strong for thousands of years and we've had plenty of great scholars in this time." — he points to the pin on your chest — "Your Sect Badge is one of them."

		"What do you mean?"

		He takes off his own badge, presses something on it, and soon the sect symbol on it is exchanged with a number: [b]47,894[/b]. 

		"There is a button on the exterior. It's tiny, but you'll find it once you properly look." 

		You check your own badge and indeed, there is a button. 

		[b]${mc_sect_points}[/b].

		"It displays your Contribution Points — moreover, it allows for transfer of the points between disciples." 
	
		*choice
			#"This is incredible."
				"There are plenty of other interesting things in the sect."
			#"I was hoping for something more flashy."
				"There are plenty of other interesting things in the sect, don't be disappointed." 
			#"Maybe Senior Brother can show me how it works?" @{(tooltip) [b][CHARISMA][/b] |}
				*gosub_scene subroutines stat_check "chr" 12
				*if (stat_check)
					He gives you an amused look. 

					"Sure." 

					*set mc_sect_points +10
					Hao Fan touches his badge with yours, and the display on the latter soon becomes [b]${mc_sect_points}[/b]. 
				*else
					He gives you an amused look.

					"I think I'd let you find out by yourself."
		*set devices_question true
		*set question_count +1
		*goto haofan_questions
		
	*selectable_if (not (rules_question)) #"Can you tell me some main rules of the sect?"
		"Of course." 

		"The main thing is, the sect runs on Contribution Points. Although there are some stores that accept gold, they are an exception rather than the rule."

		"Plenty of ways available on how to earn them. Mission Hall lists hundreds of tasks everyday, from both other disciples and sect itself. Their completion will net you a solid amount of points. You can also become a creationist, concocting pills, drawing talismans or crafting equipment to exchange with the sect. Or, if you are a battle junkie, you can try your hand at the Arena — that's a good way to also make your name known." 

		"Secondly, serious violence of any kind is prohibited between disciples. There might be some fights and beatings going on, but leaving any permanent or even long-lasting harm will get you in trouble. If you have a dispute to settle, issue an official challenge to a duel. Believe me, even someone like you would not be immune from the consequences otherwise."

		"Lastly, try and offend as little people as you can. Especially be careful around Elders — some of then, like Lady Rin, are easy-going, but most would make you life a living hell if you insult them."
	
		*set rules_question true
		*set question_count +1
		*goto haofan_questions


*label solitary_confinement
*page_break Solitary Confinement
You spend the next ${solitary_confinement_time} weeks alone in a dark room without sunlight: your only solace is the decent food that you are fed. 
*comment *set date +(solitary_confinement_time*3)

It's a huge relief when you are finally out, limitations lifted from your freedom of movement. 
*goto_scene free_roam