*label meditate
*temp chosen_skill ""
*temp supportive false
*temp supportive_skill "mc_supportive_1"
*temp chosen_level ""
*temp exp_cost 0
*temp grade_string ""
*temp chosen_level 0
*temp level_string ""
*temp record_id ""
You sit down in your room, cross-legged, as you focus inwards and attempt to find inner peace and harmony. Inner Energy flows through your veins like an unstoppable tidal wave and it's your job to take control of it. To guide it and nourish, improve your body with its power.

*choice
	#Raise Attributes.
		*goto exp_spending
	*if (mc_level > 0) and (date > 12) 
		#Comprehend Martial Arts. 
			*label comprehend_ma
			Martial Arts are an essential part of the Martial Artist's power: without them, the journey of the Jianghu becomes ten times as difficult. You'll encounter various techniques to assist or harm you, some are grandiosely powerful, others sneakily lethal. 

			You yourself will have an opportunity to learn some of those Arts as well. To start with, you have 4 Offensive, 2 Defensive and 2 Footwork-type skills inherited from your clan.

			You can spend EXP to comprehend them. The higher your comprehension level, the more powerful the skill will be and the more opportunities to use it will unlock. 

			*set chosen_skill ""
			*set supportive false
			*choice
				#Offensive Arts.
					*choice
						*selectable_if (mc_offensive_1_mastery < 4) #Heavenly Crushing Palm.
							*set chosen_skill "mc_offensive_1_mastery"
						*selectable_if (mc_offensive_2_mastery < 4) 					#Sixty-Four Earth Shaking Fists.
							*set chosen_skill "mc_offensive_2_mastery"
						*selectable_if (mc_offensive_3_mastery < 4) 					#Extreme Demon Finger.
							*set chosen_skill "mc_offensive_3_mastery"
						*selectable_if (mc_offensive_4_mastery < 4) #Flesh-Scorching Kicks.
							*set chosen_skill "mc_offensive_4_mastery"
						#Go back.
							*goto comprehend_ma
				#Defensive Arts.
					*choice
						*selectable_if (mc_defensive_1_mastery < 4) 					#Celestial Shell.
							*set chosen_skill "mc_defensive_1_mastery"
						*selectable_if (mc_defensive_2_mastery < 4) #Void Step.
							*set chosen_skill "mc_defensive_2_mastery"
						#Go back.
							*goto comprehend_ma
				#Footwork Arts.
					*choice
						*selectable_if (mc_footwork_1_mastery < 4) 					#Gale Stream.
							*set chosen_skill "mc_footwork_1_mastery"
						*selectable_if (mc_footwork_2_mastery < 4) #Lightning Flicker.
							*set chosen_skill "mc_footwork_2_mastery"
						#Go back.
							*goto comprehend_ma
				#Supportive Arts.
					*choice
						*if (mc_supportive_1)
							*selectable_if (mc_supportive_1_mastery < 4) #Aura Perception.
								*set supportive_skill "mc_supportive_1"
								*set supportive true
						*if (mc_supportive_2)
							*selectable_if (mc_supportive_2_mastery < 4) 						#Energy Concealment.
								*set supportive_skill "mc_supportive_2" 
								*set supportive true
						*if (mc_supportive_3)
							*selectable_if (mc_supportive_3_mastery < 4) #Cosmic Field.
								*set supportive_skill "mc_supportive_3"
								*set supportive true
						#Go back.
							*goto comprehend_ma
				#Leave.
					*goto meditate

			*label comprehend_skills
			*gosub_scene subroutines randomize 1 100 1 "r_v"
			*set r_v -mc_int
			*set exp_cost 50
			*if (not (supportive))			
				*set chosen_level {chosen_skill}
				*set level_string ""
				*if chosen_level = 0
					*set level_string "Not comprehended."
				*elsif chosen_level = 1
					*gosub_scene cslib_string find chosen_skill "supportive"
					*if cslib_ret > 0
						*set level_string "Comprehended."
					*else
						*set level_string "Initial Success."
				*elsif chosen_level = 2
					*set level_string "Small Success."
				*elsif chosen_level = 3
					*set level_string "Large Success."
				*elsif chosen_level = 4
					*set level_string "Perfection."
				Current Comprehension: [b]${level_string}[/b].

				[b]Attempting to comprehend a Martial Art will advance the time forward. It also has 66% of failing.[/b]
				*choice
					*selectable_if (chosen_level = 0) #Comprehend up to Initial Success. (${(exp_cost*(1-chosen_level))} [b]EXP[/b])
						*set exp_cost exp_cost
						*set chosen_level 1
					*selectable_if (chosen_level <= 1) #Comprehend up to Small Success. (${(exp_cost*(2-chosen_level))} [b]EXP[/b])
						*if (chosen_skill = "mc_offensive_3_mastery")
							Extreme Demon Finger cannot be raised through normal means: you'll have to acquire Heart Blood of True Swordsmen to comprehend it further.
							*page_break
							*goto comprehend_ma
						*elsif (chosen_skill = "mc_defensive_2_mastery")
							Void Step cannot be raised through normal means: you'll have to 	acquire various Void-related treasures to comprehend it further.
							*page_break
							*goto comprehend_ma
						*set exp_cost *(2-chosen_level)
						*set chosen_level 2
					*selectable_if (chosen_level <= 2) 			#Comprehend up to Large Success. (${(exp_cost*(3-chosen_level))} [b]EXP[/b])
						*if (chosen_skill = "mc_offensive_3_mastery")
							Extreme Demon Finger cannot be raised through normal means: you'll have to acquire Heart Blood of True Swordsmen to comprehend it further.
							*page_break
							*goto comprehend_ma
						*elsif (chosen_skill = "mc_defensive_2_mastery")
							Void Step cannot be raised through normal means: you'll have to 	acquire various Void-related treasures to comprehend it further.
							*page_break
							*goto comprehend_ma
						*set exp_cost *(3-chosen_level)
						*set chosen_level 3
					*selectable_if (chosen_level <= 3) #Comprehend up to Perfection. (${(exp_cost*(4-chosen_level))} [b]EXP[/b])
						*if (chosen_skill = "mc_offensive_3_mastery")
							Extreme Demon Finger cannot be raised through normal means: you'll have to acquire Heart Blood of True Swordsmen to comprehend it further.
							*page_break
							*goto comprehend_ma
						*elsif (chosen_skill = "mc_defensive_2_mastery")
							Void Step cannot be raised through normal means: you'll have to 	acquire various Void-related treasures to comprehend it further.
							*page_break
							*goto comprehend_ma
						*set exp_cost *(4-chosen_level)
						*set chosen_level 4
					#Go back.
						*goto comprehend_ma
			*else
				Supportive Martial Arts only have one level of comprehension.

				*set grade_string {"${supportive_skill}_grade"}
				*set chosen_skill "${supportive_skill}_mastery"
				*set chosen_level {chosen_skill}
				Current Comprehension: 
				*if chosen_level = 0
					[b] 	not comprehended.[/b]
				*else
					[b] comprehended.[/b]
				*choice
					*selectable_if (chosen_level = 0) #Comprehend the Martial Art. (${(exp_cost*grade_string)} [b]EXP[/b])
						*set exp_cost *grade_string
						*set chosen_level 1
					#Go back.
						*goto comprehend_ma
			*if (inv_1 > 0)
				*set inv_1 -1
				*set exp_cost /2
				[b]Thinking Incense helps you reduce the required EXP by half.[/b]

			*if mc_exp < exp_cost
				You don't have enough EXP.
				*page_break
				*goto comprehend_ma
			*if (mc_trait_2)
				*set r_v 0
			*set mc_exp -exp_cost
			*if r_v <= 33
				*set {chosen_skill} chosen_level
				*if r_v = 0
					You easily comprehend the technique, failure not even plausible for a genius like you.
				*else
					Congratulations! You have successfully comprehended the technique.
				*page_break
				*goto_scene free_roam
			*else
				Sadly, enlightenment eludes you: the complex theory behind the Martial Art leaves you flabbergasted. You will have to try again.
				*page_break
				*goto_scene free_roam
	#Enter your Spatial Ring.
		*set inventory_page 0
		*gosub_scene inv_scene
		*page_break
		*goto meditate
	*if equipment_2 > 0
		#Record a Skill into Skill-Storing Ring.
			*if equipment_2_stored = 0
				Currently, your Skill-Storing Ring does not hold any recorded skills.
			*else
				Currently, your Skill-Storing Ring holds these skills:
				*line_break
				*if ring_offensive_1 > 0
					*line_break
					[b]Heaven Crushing Palm[/b] x${ring_offensive_1}.
				*if ring_offensive_2 > 0
					*line_break
					[b]Sixty-Four Earth Shaking Fists[/b] x${ring_offensive_2}.
				*if ring_offensive_1 > 0
					*line_break
					[b]Extreme Demon Finger[/b] x${ring_offensive_3}.
				*if ring_offensive_2 > 0
					*line_break
					[b]Flesh-Scorching Kicks[/b] x${ring_offensive_4}.
				*if ring_defensive_1 > 0
					*line_break
					[b]Celestial Shell[/b] x${ring_defensive_1}.
				*if ring_defensive_2 > 0
					*line_break
					[b]Void Step[/b] x${ring_defensive_2}.
				*if ring_footwork_1 > 0
					*line_break
					[b]Gale Stream[/b] x${ring_footwork_1}.
				*if ring_footwork_2 > 0
					*line_break
					[b]Lightning Flicker[/b] x${ring_footwork_2}.				
			
			*if equipment_2_stored >= 4
				You don't have any available space in your Skill-Storing Ring. Use one of the recorded skills to free it up. 
				*choice
					#Go back.
						*goto meditate
					
			What skill would you like to store? ([b]Available Slots: ${4-equipment_2_stored}[/b])
			*choice
				#Offensive.
					*label offensive_skill_record
					*rand r_v 1 100
					*choice
						*if mc_offensive_1_mastery >= 1
							#Heaven Crushing Palm.
								*set record_id "offensive_1"
						*if mc_offensive_2_mastery >= 1
							#Sixty-Four Earth Shaking Fists.
								*set record_id "offensive_2"
						*if mc_offensive_3_mastery >= 1
							#Extreme Demon Finger.
								*set record_id "offensive_3"
						*if mc_offensive_4_mastery >= 1
							#Flesh-Scorching Kicks.
								*set record_id "offensive_4"
						#I changed my mind.
							*goto meditate
					*goto skill_recording
				#Defensive.
					*label defensive_skill_record
					*rand r_v 1 100
					*choice
						*if mc_defensive_1_mastery >= 1
							#Celestial Shell.
								*set record_id "defensive_1"
						*if mc_defensive_2_mastery >= 1
							#Void Step.
								*set record_id "defensive_2"
						#I changed my mind.
							*goto meditate
					*goto skill_recording
				#Footwork.
					*rand r_v 1 100
					*choice
						*if mc_footwork_1_mastery >= 1
							#Gale Stream.
								*set record_id "footwork_1"
						*if mc_footwork_2_mastery >= 1
							#Lightning Flicker.
								*set record_id "footwork_2"
						#I changed my mind.
							*goto meditate
					*goto skill_recording
				#Supportive.
					*rand r_v 1 100
					*choice
						*if mc_supportive_1_mastery >= 1
							#Aura Perception.
								*set record_id "supportive_1"
						*if mc_supportive_2_mastery >= 1
							#Energy Concealment.
								*set record_id "supportive_2"
						*if mc_supportive_3_mastery >=	 1
							#Anti-Missile Field.
								*set record_id "supportive_3"
						#I changed my mind.
							*goto meditate
					*goto skill_recording
				#I changed my mind.
					*goto meditate
	*if equipment_3 > 0
		#Apply a poison on the Needle of Absolute Penetration.
			Which poison would you like to apply?
			*gosub_scene cslib_menu build_array_filter "inv" "name" true "conditions" "poison_check"
			*if cslib_ret = 0
				*goto meditate
			*set inv[cslib_ret] -1
			*set equipment_3_stored cslib_ret
			
			You have successfully applied [i]${inv[cslib_ret]["name"]}[/i] to Needle of Absolute Penetration.
			*page_break Hoorah!
			*goto meditate
	#Go back.
		*goto_scene free_roam free_time

*label exp_spending
*temp str_lvl ""
*temp str_exp ""
*temp agi_lvl ""
*temp agi_exp ""
*temp con_lvl ""
*temp con_exp ""
*temp end_lvl ""
*temp end_exp ""
*temp vit_lvl ""
*temp vit_exp ""
*temp per_lvl ""
*temp per_exp ""
*temp int_lvl ""
*temp int_exp ""
*temp chr_lvl ""
*temp chr_exp ""
*temp atr_choice ""
*temp atr_increase 0
*temp exp_left 0
[b]ATTRIBUTES:[/b]
*line_break
*gosub format_atr "str"
*gosub format_atr "agi"
*gosub format_atr "con"
*gosub format_atr "end"
*gosub format_atr "vit"
*gosub format_atr "per"
*gosub format_atr "int"
*gosub format_atr "chr"

*gosub exp_until_increase "str"
[b]Strength:[/b] ${mc_str} ([i]${str_lvl}[/i]) (${exp_left - mc_str_exp} EXP needed)
*line_break
*gosub exp_until_increase "agi"
[b]Agility:[/b] ${mc_agi} ([i]${agi_lvl}[/i]) (${exp_left - mc_agi_exp} EXP needed)
*line_break
*gosub exp_until_increase "con"
[b]Constitution:[/b] ${mc_con} ([i]${con_lvl}[/i]) (${exp_left - mc_con_exp} EXP needed)
*line_break
*gosub exp_until_increase "vit"
[b]Vitality:[/b] ${mc_vit} ([i]${vit_lvl}[/i]) (${exp_left - mc_vit_exp} EXP needed)
*line_break
*gosub exp_until_increase "per"
[b]Perception:[/b] ${mc_per} ([i]${per_lvl}[/i]) (${exp_left - mc_per_exp} EXP needed)
*line_break
*gosub exp_until_increase "int"
[b]Intelligence:[/b] ${mc_int} ([i]${int_lvl}[/i]) (${exp_left - mc_int_exp} EXP needed)
*line_break
*gosub exp_until_increase "chr"
[b]Charisma:[/b] ${mc_chr} ([i]${chr_lvl}[/i]) (${exp_left - mc_chr_exp} EXP needed)

What Attribute do you want to increase?

[b]${mc_EXP}[/b] EXP left.
*choice
	#Strength
		*set atr_choice "str"
	#Agility
		*set atr_choice "agi"
	#Constitution
		*set atr_choice "con"				
	#Vitality
		*set atr_choice "vit"				
	#Perception
		*set atr_choice "per"				
	#Intelligence
		*set atr_choice "int"				
	#Charisma
		*set atr_choice "chr"			
	#Go back.
		*goto meditate
How much EXP do you want to spend?

[b]${mc_EXP}[/b] EXP left.
*if mc_exp < 0
	*page_break BUG
	Somehow, you EXP has become less than the zero. This is [b]NOT[/b] intended, but I can't quite figure out why/where it happens. If you got this bug, I'd appreciate it if you contacted me on discord and told me how you got to this point. 
	
	For now, I've reset your exp to 0.
	*set mc_EXP 0
*if mc[atr_choice] >= (10 + (10*mc_level))
	
	This attribute is already at the maximum for your current stage. In order to increase it further, you'll need to advance in your Martial Rank.
	
	*page_break
	*goto exp_spending

*input_number atr_increase 0 mc_exp
*gosub_scene subroutines spend_exp atr_increase atr_choice
*goto exp_spending

*label format_atr
*params atr
*temp string_lvl "${atr}_lvl"
*temp string_exp "${atr}_exp"
*set {string_exp} mc[atr]
*if mc[atr] >= (10 + (10*mc_level))
	*set {string_lvl} "PEAK GENIUS"
*elsif mc[atr] >= (8 + (10*mc_level))
	*set {string_lvl} "GENIUS"
*elseif mc[atr] >= (5 + (10*mc_level))
	*set {string_lvl} "TALENTED"
*elseif mc[atr] >= (3 + (10*mc_level))
	*set {string_lvl} "MEDIOCRE"
*else
	*set {string_lvl} "MEAGER"

*return

*label skill_recording
*temp ring_string "ring_${record_id}"
*set {ring_string} +1
*set equipment_2_stored +1

The technique has been successfully recorded into the Skill-Storing ring. 

Available slots: ${4-equipment_2_stored}
*goto meditate


*label format_comprehension
*params skill_mastery
*set skill_mastery {"mc_${skill_mastery}_mastery"}
*set skill_mastery round((skill_mastery-0.5))
*if skill_mastery < 1
	*set comp_level "Not Comprehended"
*elsif skill_mastery < 25
	*set comp_level "Initial Success"
*elseif skill_mastery < 50
	*set comp_level "Small Success"
*elseif skill_mastery < 75
	*set comp_level "Large Success"
*elseif skill_mastery < 100
	*set comp_level "Mastered"
*elseif skill_mastery >= 100
	*set comp_level "Perfection"
	
*stat_chart
	percent skill_mastery ${comp_level}
*return

*label exp_until_increase
*params atr
*set exp_left 50+(mc[atr]*10)
*return