*temp ability_to_surrender
*gosub_scene cslib_string find history "tourney_tigress_victory|"
*if cslib_ret = 0
	*gosub_scene cslib_string find history "prologue_tourney_lost_xiaochun|"
	*if cslib_ret = 0
		You are surprised when you notice Yuan Fang walking straight to you. 

		Quirking your brow, you wait for him to speak.

		"Yuan Fang greets ${YM} ${mc_name}. I don't believe we have been previously introduced."

		"We haven't been." — you answer him.
		"I hope we can rectify it then." — he says, and brings out a bottle of wine alongside a couple of cups that look comically small in his gigantic hand — "You drink?"
		*choice
			#"I do".
				*gosub_scene subroutines change_personality 2 "indulgent" "+"
				He pours the alcohol into the cup and passes it to you.

				"To our meeting." — Yuan Fang drains his cup in a single gulp and you follow suit — "The reason I sought you out is that I'm going to surrender in our fight for the third place as well."

				"What? Why?"

				"Do you want me to be honest?" — he wonders.

				You nod in response.

				"I have nothing to gain by achieving third place. Don't take offense, ${YM}, but with you being
				*if mc_health < mc_health_total
					injured
				*else
					exhausted   
				from your previous battle, I believe that I can take you." — Yuan Fang drinks another cup, the wine seemingly having no effect on him — "However, this will only place a target on my back. Can you imagine, a Minor Noble from an unknown clan taking out the great prodigy of the Wu's? I wish not to have that kind of attention on me. Let the Tigress have it if she so wants."

				"Not to mention, you will certainly desire revenge on me." — he continues — "And I once heard this excellent advice: it's better to be friends with Young Masters than enemies."

				"I hope you will seek me out in the sect so that we drink can more. And something stronger as well, this diluted excuse for wine doesn't even tickle my tongue."

				"Farewell, ${YM} ${mc_name}." — concludes Yuan Fang and steps away with a bow.

				You don't stop him — his remarks are true, if you really lost against him, it would be too shameful...
			#"I don't".
				*gosub_scene subroutines change_personality 2 "indulgent" "-"
				He still pours the alcohol into both cups.

				"Then I'll drink for the both of us. To our meeting." — Yuan Fang drains the cups in a single gulp each — "The reason I sought you out is that I'm going to surrender in our fight for the third place as well."

				"What? Why?"

				"Do you want me to be honest?" — he wonders.

				You nod in response.

				"I have nothing to gain by achieving third place. Don't take offense, ${YM}, but with you being
				*if mc_health < mc_health_total
					injured
				*else
					exhausted   
				from your previous battle, I believe that I can take you." — Yuan Fang drinks another cup, the wine seemingly having no effect on him — "However, this will only place a target on my back. Can you imagine, a Minor Noble from an unknown clan taking out the great prodigy of the Wu's? I wish not to have that kind of attention on me. Let the Tigress have it if she so wants."

				"Not to mention, you will certainly desire revenge on me." — he continues — "And I once heard this excellent advice: it's better to be friends with Young Masters than enemies."

				"I hope you will seek me out in the sect so that we can talk more."

				"Farewell, ${YM} ${mc_name}." — concludes Yuan Fang and steps away with a bow.

				You don't stop him — his remarks are true, if you really lost against him, it would be too shameful...

	*goto tangruo_versus_tigress

[i]So soon?[/i] 
*temp attempted_strikes false
*temp attempted_sweep false
*temp attempted_tackle false
*temp attempted_count 0
*temp value mc_vit
*gosub_scene subroutines increase_health value

*if mc_health < mc_health_total
	You look over your injuries that are yet to fully heal. Facing Prince Ruo not in your top condition strikes you as a terrible idea. 

	You can always try and ask He Jun for a delay, but begging that man for anything [i]irks[/i] you. 

	*choice
		#Ask for more time to heal.
			*gosub_scene cslib_string find history "hejun_proposition"
			*if cslib_ret = 0
				"Will you ask enemies on a battlefield to wait for you too? Pathetic." — he snorts — "Go out and fight, you little shit."

			*else
				"I can give you an hour since your last fight has been rather difficult."

				"Thank you." — you reply in gratitude. 

				An hour later. 
				*gosub_scene cslib_string find history "tourney_healing_paste"
				*if cslib_ret > 0
					*set mc_health mc_health_total
					*set mc_stamina 0
					[b]Phoenix Healing Paste has completely restored your health and stamina.[/b]
					
					You get up, take a deep breath and walk to the circle.

					"Be careful, ${polite_address} ${mc_name}. Tang Ruo... is not a normal mortal." — you hear a minute whisper from behind.
					*goto dialogue_before_fight
				*else
					*gosub_scene subroutines increase_health value
		#Continue as is. 
			*gosub_scene subroutines change_personality 2 "arrogant" "+"
			You would rather lose than plead to that bastard.

	Left without a choice, you get up, take a deep breath and walk to the circle.

*else
	It's good that you are in your top condition, at least. Facing Tang Ruo otherwise strikes you as a terrible idea.

	You get up, take a deep breath and walk to the circle.
	*gosub_scene cslib_string find history "tourney_healing_paste"
	*if cslib_ret > 0
		*gosub_scene cslib_string find history "hejun_proposition"
		*if cslib_ret > 0
			"Be careful, ${polite_address} ${mc_name}. Tang Ruo... is not a normal mortal." — you hear a minute whisper from behind.
	*goto dialogue_before_fight


*label dialogue_before_fight
"Tang Ruo, the imperial prince, the heir to the Celestial Throne versus Wu ${mc_name}, ${YM} of the Wu Clan. The winner of this match will be considered the winner of the whole tournament and will be granted an artifact of his choice from the Sect Treasury."

The Imperial Prince seems to come alive as you enter the dueling grounds. His lazy expression flashes with interest. With anticipation and expectancy.

"I've been waiting for you. The only entertaining thing about this farce of a tourney." — he says, stretching his shoulders and neck — "They say your talent matches, if not exceeds mine."

"Somehow, I find that hard to believe." — Tang Ruo grins, his grin one of unadulterated arrogance —
*gosub_scene cslib_string find history "prologue_offended_TangRuo"
*if cslib_ret > 0
	"You have courted death by insulting my clan. Do you have the strength to back it up?"
	*set fight_difficulty 1

	[b]You have offended Tang Ruo. This fight will be harder.[/b] 
	
	"Why don't we find out?"
	*goto proceed_with_fight

"I will give you one chance to surrender. Are you smart enough to take it?"
*choice
	#Surrender.
		*gosub_scene subroutines change_opinion 4 5 "-"
		You can't win. You know it, he knows it, and everybody else present also knows it. Second place is already good enough, especially considering your, despite your great status, decadent upbringing. Your affinity is higher than his — you don't have anything to prove, just wait and grow until he's not your match any longer. 

		"I am. I concede."

		*label surrender
		Whatever interest the Prince had in you disappears. With this decision, you cement your status as but another noble in his view. He has been looking for an equal — and by submitting, you lose the right to be one. 

		"Very well. How disappointing. I thought I'd finally have at least a semblance of a rival."
		
		*gosub_scene subroutines prestige_change 10 "-"

		*set history history		&"surrendered_in_tourney|"

		He enlarges his flying sword, jumps on top of it, and floats back to He Jun. 

		*goto_scene tourney_result
	#Refuse.
		"Since I've reached here, I will naturally fight it out with you."

		"Have you thought this through? I'm many things, but being merciful is not one of them. I will [i]cripple[/i] you."

		*choice
			#Proceed with the fight.
				*label proceed_with_fight
				"Good. You have guts." — he nods — "I'm going to give you a chance. Don't let me down."

				His spatial ring flashes and his sword disappears inside. A dozen of rings, a good number of bracelets, a necklace, and an earring all go into the pile near his feet. He then proceeds to take off his robe and shoes, a pair of pants the only element of clothing left on his naked and barefoot self.  

				*choice
					*selectable_if (mc_equipped_robe = 1) #Also get rid of your protective robe.
						*gosub_scene subroutines change_personality 2 "arrogant" "+"
						He thinks you are not worthy of him using his equipment? He's not worthy of yours!
						*gosub_scene subroutines disequip_item "con" 1
						*set mc_equipped_robe 0

						You remove the robe your father gave you.

						"Oh?" — the Prince exclaims — "How refreshing. Someone with actual dignity."
					#"What are you doing?"
						"Removing my artifacts. We wouldn't want you breaking your brittle hands against Jade Silk, would we?" — the Prince says.
					#"Maybe lose the pants too?"
						*gosub_scene subroutines change_personality 1 "indulgent" "+"
						He gives you a disgusted look.

						"Pervert."

						"What?" — you rush to defend your dignity — "I'm just worried there is another artifact hidden in your underwear."

						"There is not. Stop speaking nonsense."
				*goto start_fight
			#Surrender.
				*goto surrender
	#"You are courting death!"
		*gosub_scene subroutines change_personality 1 "impulsive" "+"
		*goto proceed_with_fight
		
*label start_fight
*if attempted_count = 1
	"Got anything else?" — he smirks, observing his carefully trimmed nails. 
*elseif attempted_count = 2
	"Is that all?" — he gives you a bored glance and you swear, he almost yawns.
*if (((attempted_strikes) and (attempted_tackle)) and (attempted_sweep))
	*goto difference_between
*if attempted_count = 0

	"Come." — he beckons you with his palm, before clasping his hands behind his back — "Why don't you show me what you can do?"

*if (precognition_enabled)
	*if (not (attempted_strikes))
		*set fight_option_1 "Try and hit him with strikes. @{(tooltip) [b][AGI/STR][/b] |} @{((mc_str >= (70+fight_difficulty)) and (mc_agi >= (70+fight_difficulty))) ✅ |❌}"
	*if (not (attempted_sweep))
		*set fight_option_2 "Try and sweep his leg. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= (80+fight_difficulty)) ✅ |❌}" 
	*if (not (attempted_tackle))
		*set fight_option_3 "Try and tackle him. @{(tooltip) [b][STR][/b] |} @{(mc_str >= (80+fight_difficulty)) ✅ |❌}"
*else
	*if (not (attempted_strikes))
		*set fight_option_1 "Try and hit him with strikes. @{(tooltip) [b][AGI/STR][/b] |}"
	*if (not (attempted_sweep))
		*set fight_option_2 "Try and sweep his leg. @{(tooltip) [b][AGI][/b] |}" 
	*if (not (attempted_tackle))
		*set fight_option_3 "Try and tackle him. @{(tooltip) [b][STR][/b] |}"	
*set precognition_enabled false
*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto start_fight

*set fight_string "fightstart_${cslib_ret}"
*goto {fight_string}

*label fightstart_0
*bug Fuck Quick Test

*comment try and hit him with strikes
*label fightstart_1
*set attempted_count +1
*set attempted_strikes true
Gathering your fingers into tight fists, you let out a breath and send a punch towards his face.
*gosub_scene subroutines stat_check_double "agi" "str" 6
*if (stat_check)
	He tilts his head out of the way, causing your fist to fly past its intended target. 
	
	However, you are fast enough to punch a second time, before Tang Ruo organizes a counter-offensive. 
	*page_break Second Punch
	*gosub_scene subroutines stat_check_double "agi" "str" 7
	*if (stat_check)
		His hand redirects your wrist, making you miss again.

		You raise your back leg and turn your body around. Your foot aims at his jaw.
		*page_break Spinning Back Kick
		*gosub_scene subroutines stat_check_double "agi" "str" 8
		*if (stat_check)
			His torso [i]bends[/i] backwards and your leg circles back to the ground, without finding success.

			"Not bad." — Tang Ruo praises — "You almost hit me."
		*else 
			He blocks your strike without much trouble, his forearm absorbing all its power. He pushes your only leg from underneath you and you fall to the ground, unable to keep your balance.

			Tang Ruo kicks you in the stomach and you slide backwards across the dirt-soiled earth. 

			*gosub_scene subroutines reduce_health_return 2 "fight_tourney_3"
			You grunt and stand up.
	*else
		He catches your wrist without much trouble. You attempt to wiggle it free, but Tang Ruo just kicks you in the stomach. Your body bends in half underneath the impact before you are thrown backwards. 

		"Disappointing." 
		*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"
*else
	He catches your wrist without much trouble. You attempt to wiggle it free, but Tang Ruo just kicks you in the stomach. Your body bends in half underneath the impact before you are thrown backwards. 

	"Disappointing."
	*gosub_scene subroutines reduce_health_return 4 "fight_tourney_3"
*page_break Try Something Else
*goto start_fight
*comment try and sweep leg
*label fightstart_2
*set attempted_count +1
*set attempted_sweep true
You crouch before targeting his ankles with your leg, hoping to shake his stable poise or, even better, bring him down.

*gosub_scene subroutines stat_check "agi" 8
*if (stat_check)
	Tang Ruo jumps over your sweep. It goes right below him, the steadiness of his stance remaining untouched.
	
	You barely get up in time to avoid his rebounding strike.
	
	"Your speed is decent. But it is not enough."
*else
	Tang Ruo lifts his knee and blocks your sweep with ease. He then strikes you in the chest with a palm, knocking out all the air in your lungs. 
	
	"Insufficient."
	
	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"
*page_break Try Something Else
*goto start_fight
*comment try and tackle
*label fightstart_3
*set attempted_count +1
*set attempted_tackle true
You feint with your right hand, attracting his attention to an incoming punch that was never thrown, and dive right in for a tackle, leveling your shoulders with his hips.
*gosub_scene subroutines stat_check "str" 8
*if (stat_check) 
	Tang Ruo puts his arm on the back of your head and [i]flips[/i] himself over your charging body. He taps your spine with his foot, causing you to stumble.
	
	"Acceptable strength, but nothing outstanding."
*else
	As you arrive close, he puts his arms under your biceps and, with sheer brute force, Prince Ruo [i]throws[/i] your charging body to the side.
	
	You hit the ground hard, grunting.
	
	"Inadequate."
	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"
*page_break Try Something Else
*goto start_fight


*label difference_between

"That's enough." — Tang Ruo states, still standing unperturbed. Your full-powered efforts have not solicited even a drop of sweat — "You have potential, but it is still raw. Untapped. You lack training and you lack time. In a couple of years, you might pose some threat to me: now, you are far from having the qualifications to issue me a challenge."

"Our fight is.. is still not done." — you reply, panting.

Tang Ruo gives you a look of amusement.

"Setting aside our talent and equipment, there is still a vast difference between us. Do you know what it is?"

*choice
	#"I don't have a stick up my ass."
		*gosub_scene subroutines change_personality 1 "arrogant" "-"
		"Pride is a natural consequence of confidence. And if you wish to tread the Jianghu, you will falter, fall, and [i]die[/i] without having the supreme belief in your own ability."

		"Arrogance is different from self-assurance." — you reply. 

		"Is it?" — he tilts his head — "I believe that the former is the ultimate form of the latter."
	#"I'm more talented than you."
		*gosub_scene subroutines change_personality 1 "arrogant" "+"
		At this, Prince Ruo actually laughs out loud. 

		"You are a fool if you believe that three percent of affinity is enough to prevail over me. Don't tell me that you took that ancient prophecy literally?" — he shakes his head.
	#"I have better things to do then train all day long."
		*gosub_scene subroutines change_personality 1 "indulgent" "+"
		Prince Ruo shakes his head in contempt.

		"A waste of a heavenly gift."

	*if mc_sex = 0
		#"I'm more handsome."
			*label beauty_talk
			Prince Ruo shakes his head.

			"Beauty is [i]trivial[/i]. I like to look at pretty things but would disfigure my own face in an instant if it brought me power. In our world, only strength matters."
	*if mc_sex = 1
		#"I'm prettier."
			*goto beauty_talk
	#"Enlighten me."
		*goto true_difference
	#Say nothing.
		*gosub_scene subroutines change_personality 1 "impulsive" "-"
		"A stoic type?" — he laughs — "Understandable. I too tend to go quiet in serious battles." 

*label true_difference
"The true difference between us," — continues the Prince — "Is not our talent. It's not our looks or personality either. It's our upbringing instead. Our family. Our roots."

"Our upbringing?"

"I started training before I could walk: my aunt, the Celestial Sword Mistress, personally taught me the way of the blade; my grandfather, the strongest man under the Heavens, sparred with me for hours every morning. I drank enough elixirs to fill out a sea, consumed more pills than I can count, and rubbed in pastes to cover my body a thousandfold. I've long ago surpassed the limits of mortality, despite not undergoing Houtian."

His body — put on display in his half-naked state — is lean. Slim even, with wide shoulders, narrow hips, and a distinct V-line traveling from his stomach down below, into an area hidden by his pants. But when he acts, when he exerts his strength, his muscles unveil themselves in their outstanding glory: they [i]roar[/i] with power, like apex predators pouncing on prey.

"And you? I know everything about you, Wu ${mc_name}." — he says — "The only child of Wu Chao, a peak expert, yet devoid of his attention. Born into a Great Clan, yet lacking the resources Young Masters of some Minor Clans enjoy. Trained by the best Martial Artists your clan could afford, perhaps by the Wind Viper Demon himself, yet lacking access to the Martial World's real powerhouses."

"You truly believe that you can overcome the difference in our background?"

*fake_choice
	#"No. I give up."
		*gosub_scene subroutines change_personality 3 "arrogant" "-"
		*set fight_path "surrendered"
		*goto win
	#"I'm still better than you."
		*gosub_scene subroutines change_personality 2 "arrogant" "+"
	#"I will not shame my surname by forfeiting a tourney match."
		*gosub_scene subroutines change_personality 2 "ruthless" "-"
	#"A free pick of sect treasury sounds too enticing for me not to try."
		*gosub_scene subroutines change_personality 2 "egoistical" "+"
	#"Just shut up. You are fucking annoying."
		*gosub_scene subroutines change_personality 2 "impulsive" "+"
	#Remain silent.
		*gosub_scene subroutines change_personality 2 "impulsive" "-"

His gaze changes. From carefree and playful, it becomes intense. Domineering. You feel as if underneath his youthful visage, there hides an emperor. The ruler of all things, one whose authority cannot be argued or disputed.

"Then I will [i]hurt[/i] you. Maybe the pain will make you understand the disparity between us."

Tang Ruo moves. It's the first time you see him take a step since the fight began — not counting the dodges of your attacks.

And he's faster than you could ever have imagined.
*page_break Try To Survive
*gosub_scene subroutines stat_check "per" 7
*if (stat_check)
	The prince is a blur, a smudged image of a man. However, your eyes — trained and perceptive — gives you a split second to prepare yourself as he arrives close, his leg thrusting at your calf.

*else
	The prince is a blur in your eyes, a smudged image of a man. You realize, with a horrid jolt, that you can't react to his speed. Half a second ago, he stood several feet away from you — now, he's up close, his leg thrusting at your calf.

	*set fight_difficulty + 1
*page_break Withstand His Attack
*gosub_scene subroutines stat_check "con" 7
*if (stat_check)
	*set fight_difficulty -1
	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"
	Thank the Heavens for your hardy bones. Your leg doesn't snap, remaining whole and allowing you to continue being on your feet. 

	But sturdiness will not protect you from his second attack: one that carries far more power and momentum.

	*label tangruo_chopkick
	Another kick, this one coming from above. His leg chopping down like an axe, you need to think fast about how not to get knocked out.
	*choice
		#Cross your arms before your face. @{(tooltip) [b][STR][/b] |}
			You manage to cross your arms before your face just as his leg reaches your head.
			*gosub_scene subroutines stat_check "str" 8
			*if (stat_check)
				They successfully absorb most of the impact, blocking the dangerous kick. It still hurts, however.
				*gosub_scene subroutines reduce_health_return 1 "fight_tourney_3"
			*else
				Your arms barely help you in blocking his dangerous kick: they are smashed through almost in an instant. His foot lands on your jaw.
				*gosub_scene subroutines reduce_health_return 4 "fight_tourney_3"
				You keep onto your consciousness with desperate severity. 

		#Lean your head out of the way. @{(tooltip) [b][AGI][/b] |}
			*gosub_scene subroutines stat_check "agi" 8
			*if (stat_check)
				By a miraculous feat of agility, you manage to slant your head out of his leg's path.
			*else
				You try to slant your head out of his leg's path, but the kick still catches you in the jaw. 
				*gosub_scene subroutines reduce_health_return 5 "fight_tourney_3"
				You keep onto your consciousness with desperate severity. 
			
		#Pick up a defensive artifact from the pile of his things.
			Your mind working in an overdrive, you realize you are very close to the pile where Tang Ruo dropped off his unequipped artifacts — an arm's reach close. In an instant, you determine what item is most likely to serve a guarding purpose, pick it up and hope for the best. 

			The kick doesn't come. Tang Ruo watches you in scorn instead, waves his hand and all the items disappear into multiple spatial rings — including the one in your hand.
			
			Of course, those artifacts are bound to him. How could you forget? On the other hand, picking up a random artifact that you know neither the origin nor uses of doesn't exactly extol your intelligence...

			[i]Then[/i] comes the kick. His foot lands on your face, twirling your head.
			*gosub_scene subroutines reduce_health_return 5 "fight_tourney_3"
			You keep onto your consciousness with desperate severity. 
*else
	Your leg [i]snaps[/i]. The bone-breaking sound rings out throughout the fighting circle. The nobles nearby wince. 
	
	*gosub_scene subroutines reduce_health_return 6 "fight_tourney_3"

	*gosub_scene subroutines add_injury 4
	
	You bite into your cheek to contain the agonized scream and fall to your knee, unable to remain standing. 
	
	[b]Difficulty of defending against following attacks is significantly increased.[/b]
	*set fight_difficulty +1

	*goto tangruo_chopkick

Tang Ruo jumps, spins his body, and kicks you once more — in the chest this time. You are sent rolling rearward.

*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"

His steps light and casual and hands clasped behind his back, Prince Ruo walks next to you and crouches near your struggling to get up self.

"Huh?" — he blurts — "I'm surprised you're still not done."

*if mc_hair_length != "bald"
	You try to fight him as he grabs you by the hair. Your fingers dig into his skin but fail to stop him.

	You are exhausted and in pain.
*else
	You try to fight him as he grabs you by the back of the head. Your fingers dig into his skin but fail to stop him.

	You are exhausted and in pain. 

"Last chance to yield before this gets ugly."

*fake_choice
	#"Never... surrender..."
		*gosub_scene subroutines change_personality 2 "arrogant" "+"
	#"Fuck... Fuck you..."
		*gosub_scene subroutines change_personality 1 "impulsive" "+"
	#I give up.
		*gosub_scene subroutines change_personality 3 "arrogant" "-"
		*set fight_path "surrendered"
		*goto win

"Very well."

He [i]slams[/i] your face into the ground. It dazzles you and blood pours from your crushed nose.
*gosub_scene subroutines add_injury 2

*gosub_scene subroutines reduce_health_return 3 "fight_tourney_3"
*page_break Next Slam

He slams you again. A few teeth are knocked loose. Your previously picture-perfect smile now will have wide gaps in it. 
*gosub_scene subroutines reduce_health_return 4 "fight_tourney_3"
*gosub_scene subroutines add_injury 5
*page_break Next Slam
Blood covers your face as if you washed in it. Your mind is in a fog, its grip on reality slipping. 
*gosub_scene subroutines reduce_health_return 5 "fight_tourney_3"
It should be the end. There is no possibility of victory — you're not sure you could even throw a punch in your current condition. You should just accept defeat...

Yet, an emotion of tyrannical intensity overwhelms you. Consumes you. 

You feel...
*fake_choice
	#Indignity. You [i]will never[/i] lose.
		*gosub_scene subroutines change_personality 2 "arrogant" "+"
		"I REFUSE!" — you yell at the Heavens, your cry infused with something that you cannot quite grasp: a will that transcends the mortal flesh.  
	#Shame. You let down your clan and your ancestors.
		*gosub_scene subroutines change_personality 2 "ruthless" "-"
		"I REFUSE!" — you yell at the Heavens, your cry infused with something that you cannot quite grasp: a will that transcends the mortal flesh. 
	#Helplessness. You want more power. You [i]need[/i] more power.
		*gosub_scene subroutines change_personality 2 "egoistical" "+"
		"I REFUSE!" — you yell at the Heavens, your cry infused with something that you cannot quite grasp: a will that transcends the mortal flesh. 
	#Anger. Pure and adultered fury.
		*gosub_scene subroutines change_personality 2 "impulsive" "+"
		"AARGH" — you yell at the Heavens, your bestial, animalistic cry infused with [i]something[/i] that you cannot quite grasp: a will that transcends the mortal flesh. 

Your whole body trembles. Your blood boils. It bursts, destroying your inner homeostasis. Your organs explode, one by one: your lungs, your liver, your kidneys. Your skin peels. Your eyeballs melt into a liquid and spill out from their sockets. Hair falls, leaving you bald on every inch. 

[i]Something[/i] keeps you alive. The rejection of death, the non-acceptance of the natural order of things fuels your raging blood even more. Soon, your bones grind into dust, your muscles atrophy and you become nothing but a pool of fluid meat. 

Except for your heart. For your heart that beats stronger and louder than ever. Its thumps radiate [i]divinity[/i].
*if (meimei_poisoned)
	Yet, you also notice a strange, black spot on it: you are not sure what it is or why it's there, but you are certain that it's nothing good.

The Heavens answer the beats of your heart. Dark, chaotic clouds form in the sunny summer sky. The world itself pauses. Halts. The clouds judge you...

And find you worthy. 

Golden lightning strikes down, tossing Prince Ruo away. Electricity enters you, bringing the sensation of unprecedented warmth and comfort alongside it. With coruscating sparks, your body reforms: new organs are formed, new bones are built, and new skin is grown.

Born again, you stand utterly naked underneath the dozens of astonished gazes: yet, the pride and joy coursing through you far surpass any notion of embarrassment. 

You've reached Houtian. At nineteen, before even joining the sect, you've already joined the ranks of real Martial Artists. 
*set event_sect_artifactchoosing 1
*set history history&"prologue_reached_houtian|"
*set injuries_2 false
*set injuries_4 false
*set injuries_5 false
*page_break Inspect Your Current State
*set mc_level 1
Summoning a clean robe from your spatial ring, you assess your own condition. All of your injuries have healed, your scars and imperfections — gone without a trace. 
*set mc_health mc_health_total
[b]Health: ${mc_health}/${mc_health_total}

You know, without a doubt, that you are stronger. Faster. Tougher. Smarter. The sheer absurdity of your transformation leaves you in awe.

*set mc_stamina_total (((mc_str + mc_agi) + (mc_con + mc_vit))/2)
*set mc_stamina mc_stamina_total

*gosub_scene subroutines increase_atr_multiple "str" (mc_str/2) false
*gosub_scene subroutines increase_atr_multiple "agi" (mc_agi/2) false
*gosub_scene subroutines increase_atr_multiple "con" (mc_con/2) false
*gosub_scene subroutines increase_atr_multiple "vit" (mc_vit/2) false
*gosub_scene subroutines increase_atr_multiple "per" (mc_per/2) false
*gosub_scene subroutines increase_atr_multiple "int" (mc_int/2) false
*gosub_scene subroutines increase_atr_multiple "chr" (mc_chr/2) false

*set mc_health mc_health_total

But that's not the most important thing. No, the new [i]power[/i] flowing through your body is far more significant instead.

At last, you feel it. Feel the power that truly separates the mortals from those who have ascended beyong — Inner Energy. The bread and butter of Martial Artists. You can finally practice Martial Skills more complex than simple kicks and punches. Skills that are magical in their abilities.

[b]Your total Inner Energy Capacity is based on the arithmetic mean of your Strength, Agility, Constitution and Vitality. It will continue to grow as you advance in Martial Stages. 

[b]Inner Energy: ${mc_stamina}/${mc_stamina_total}[/b]

However, all of that will have to wait. For now, you have a fight to finish: and finish it you will.

You find Prince Ruo reeling in absolute shock. Disbelief over your sudden metamorphosis. Although advancement in battle is not unheard of, who would expect their own opponent to go through it?

"You..." — he takes a step back in uncertainty, before letting out a deep breath and steeling his nerves. With novel determination, he gives you a confident grin. — "I think you owe me a huge favor for granting you a free advancement. Go on then. I want to experience the strength of a Houtian."

So do you. 

You rush at him, your acceleration almost instantaneous. You cut through the air, your movements creating a gust of wind. 

Three punches. Right hand, left hand, right again: Tang Ruo dodges the first, blocks the second, and gets hit by the third. Your fist ruptures the skin on his cheek, drawing blood. 

Golden blood. 

Tang Ruo wipes it off, staring at the drops in turmoil. Then, he chuckles.

"I'm not sure your clan can afford to spill my blood."

"Well, I'm in the mood for spending big today."

That said, him blocking two of your attacks is extraordinary: a mortal holding his own against a Houtian. What in the Heavens do they feed him in Manyong?

Trying to hit him once more time proves to be impossible: his footwork, a mesmerizing dance, lets him evade your onslaught by a thin hair each and every time. You might be faster, yes, but not fast enough to overcome the sheer difference in skill. 

You decide to try something new. You focus on your Inner Energy and will it into your...
*choice
	#Finger.
		The warmth flows through your stomach into your arm. The energy then concentrates inside of your finger. This is not a Martial Skill, merely the most basic way of utilizing your new powers: ineffective and wasteful. But it is enough.

		Tang Ruo raises his palm to stop your attack — its speed too high to dodge —  yet your finger [i]pierces[/i] through his hand, and embeds into his flesh. You grab him by the arm and sweep his leg, dropping him onto the ground. 
	#Palm.
		The warmth flows through your stomach into your arm. The energy then concentrates inside your palm. This is not a Martial Skill, merely the most basic way of utilizing your new powers: ineffective and wasteful. But it is enough.

		Tang Ruo raises his forearms to stop your attack — its speed too high to dodge — yet your palm crashes everything in its path: his arms break, bend beyond their natural bendable angle, and he topples onto the ground.   
	#Foot.
		The warmth flows through your stomach into your leg. The energy then concentrates inside of your foot. This is not a Martial Skill, merely the most basic way of utilizing your new powers: ineffective and wasteful. But it is enough.

		Tang Ruo raises his forearms to stop your attack — its speed too high to dodge — yet your foot crashes everything in its path: his arms break, bend beyond their natural bendable angle, and he topples onto the ground. 

You mount him.

*choice
	#Choke him out.
		You put your hands around his throat and squeeze. He struggles underneath your weight, but his attempts are futile. His face turns redder and redder, his resistance becomes weaker and weaker until he goes limp...
	#Pound him into unconsciousness.
		*gosub_scene subroutines change_personality 2 "violent" "+"
		You punch him. And punch him. Again. And again. You release all of your pent-up anger and aggression, using him as a barely resisting outlet until he goes limp...
	#Gouge out his eyes.
		*gosub_scene subroutines change_personality 3 "violent" "+"
		*gosub_scene subroutines change_personality 2 "ruthless" "+"
		He's not getting out of this easy. Not after everything that he has put you through. You grab his face by the sides and push your thumbs into his eyes. He struggles underneath your weight, but you disregard his futile attempts and push further into the softness of his eyeballs until they pop...

*page_break ...
"STAY YOUR FUCKING HAND!"

You are pushed several feet away by what seems like air. When you come to your senses, you see a middle-aged man kneeling over Tang Ruo's body. The man puts his fingers on Tang Ruo's forehead before turning to you, seething in fury. 

"Arrogant brat. I will have your head for this."

"You will do no such thing." — says another voice, this one familiar to you.

[i]Uncle Tao.[/i]

In a split second, he stands before you, shielding you from the middle-aged man's retaliation. 

"Little Yuze, have you grown so shameless as to attack a child for a tourney bout?" — asks Uncle Tao. 

"So what if I am, Elder Brother? Are you going to stop me?" — Tang Yuze snorts — "You haven't even reached Peak Xiantian, stagnating after you abandoned the clan for that whore. After you abandoned [i]yourself[/i]."

"I dare you to say that word again." 

The atmosphere around you becomes a powder keg, the two experts of Xiantian holding a match near its fuse. Can you even survive the fallout of their battle?

Tang Yuze grins. 

"Wh-"

"No need, Uncle Yuze." — interrupts Tang Ruo. The same Tang Ruo who should've been lying down in his decimated condition yet stands upright with only the left-over blood signifying his previous injuries. He casts you a look and you notice that his eyes, although maintaining their violet color, have become inhuman, reptilian slits instead. A blink — and they turn to normal back again.

"I lost. Wu ${mc_name} won. This matter ends here."

"Like hell you lost! That bastard got lucky and-" — Tang Yuze retorts.

"I said I lost."

"But if you use your sword or transform-"

"Enough!" — yells the Prince — "If you wish to brawl with the Wind Viper Demon, you can do so: but I will fight my own battles without yours or anybody else's help."

Tang Ruo gives you a nod of respect. 

"Good fight. I toyed with you too much and paid for it. Don't count on me making the same mistake next time."

He walks off, not bothering to spare his guardian another glance, and sits cross-legged near the Sect Envoy. 

Snarling at Uncle Tao, Tang Yuze disappears. Uncle Tao follows him, but not before telling you some words of encouragement.

"Good job, kid. Keep doing what you doing and don't worry about the ramblings of old men."

You are left alone — well, as alone as someone in the center of a crowd can be — baffled and confused.

[i]What the fuck just happened?[/i]
*gosub_scene subroutines change_opinion 4 3 "+"
*if (eligible_achievements)
	*achieve first_tourney_win
*goto win




*label defeat

You lose consciousness… 
*page_break DEFEAT
When you come to your senses, Tang Ruo has already left, not bothering to at least extend you a helping hand. You ruefully shake your head — at least you didn't surrender.

*goto_scene tourney_result

*label win
*if fight_path = "surrendered"
	*page_break Surrender
	You can't win. You know it, he knows it, and everybody else present also knows it. Second place is already good enough, especially considering your, despite your great status, decadent upbringing. Your affinity is higher than his — you don't have anything to prove, just wait and grow until he's not your match any longer. 
	
	The Prince shakes his hand, stays his hand and steps back.
	
	"Skill can be achieved through practice, strength gained through the exercise. But the pride, the backbone a true Martial Artist should have is something that you either have, or don't." — he says, and you notice how the gleam of interest he had in you has disappeared — "How can you wish to battle against the Heavens if you can't even gather the will to fight me?"
	
	Picking up his equipment, Tang Ruo puts on his robe walks to the Sect Envoy, the crowd parting before his figure.
	
	*gosub_scene subroutines prestige_change 5 "-"

*goto_scene tourney_result


*label tangruo_versus_tigress
*page_break Tang Ruo Against The Tigress
When the Tigress enters the circle, you notice how changed her demeanor has become. If before, she was an apex creature, someone at the top of the food chain who regarded her opponents as prey of different difficulty, now, while not submissive or afraid, she's cautious. Her eyes stay glued to Tang Ruo's figure, watching his every tiny movement with the highest degree of attention. Her bestial, predatory confidence is no longer present.

Tang Ruo gives her a look before glancing at you.

*gosub_scene cslib_string find history "prologue_offended_TangRuo"
*if cslib_ret = 1
	"With the loud words you spoke before, I hoped you at least had some degree of skill." 
*else
	*if characters_4_opinion >= 55
		"Do not fret. No one bullies the people that I, Tang Ruo, have taken an interest in."
	*else
		"Train more. I need at least a semblance of a rival."
- he says and turns back to the Tigress - "As for you, my apologies, but I wish not to entertain others. This tourney bores me."

Grasping its hilt with both hands, the Prince raises his sword. He takes half a step back, putting one of his legs behind himself, its foot raised on the tippy toes. Then, with one deep breath, he [i]moves[/i]. His figure leaving afterimage after afterimage, your eyes can't track him. The Tigress faces a similar plight, as, even with her speed, she barely succeeds in lifting her arms for protection before Tang Ruo arrives close.

The Prince goes past her, stopping a foot beyond the savage woman. His sword still in the same position, his expression still serene and unbothered: only the fresh crimson trace on the edge of his blade proves the happening of his previous attack. 

The Tigress looks at him, incredulous, before her throat erupts in a fountain of blood. She falls to her knees, desperate to clog up the wound with her palms. 

You gulp. [i]What if you were in her place?[/i] How are you supposed to fight [i]that[/i]?

Mei Mei runs up to the Tigress, hurriedly applying some kind of medicine onto her neck. The cut closes and the blood stops pouring, but she continues to look pale: both from her injury and from sheer horror. 

Swinging his sword to get rid of the blood, Tang Ruo, unconcerned, returns to his place. As he walks pasts you, he grins and says:
"I'll be waiting for you."
*goto_scene tourney_result