*page_break Next Fights

The next couple of fights go by in a blink of an eye. You battle against people of similar skill level to Xiao Chun and win your duels without much of a hassle, advancing further and further into the tournament. 

"Next round is the 1/4th of the tourney." — He Jun announces, before looking at both you and Tang Ruo — "As I said before, should you win your fights this time, you'll be accepted as Inner Disciples. If you lose, however, there are no second chances. Even with your affinities."

You nod at him and step into the circle again. You understand clearly — your next fight will be anything but easy. 

Her bright red hair gathered in a braid, your opponent gives you a feral grin. She scrapes her metal claws together, producing a harsh, ear-aching noise.  

*if mc_bodytype = "skinny"
	"The Tigress needs a toothpick." — she cackles as she crouches, her crimson eyes regarding you with disdain — "Can she use your arms?" 
*elseif mc_bodytype = "lean"
	"You aren't going to run away, are you?" — cackles as she crouches, her crimson eyes regarding you with disdain — "With that skinny body of yours, you can't be good at anything else."  
*elseif mc_bodytype = "chunky"
	*temp sexname "boy"
	*if mc_sex = 1
		*set sexname "girl"
	"Be careful not to lose any weight during our fight, fat ${sexname}." — she cackles as she crouches, her crimson eyes regarding you as a very appetizing prey. 
*elseif mc_bodytype = "muscular"
	*gosub_scene cslib_string find characters_5_history "cheated_armwrestle"
	*if cslib_ret > 0
		"It's you! The dirty cheater!" — the Tigress exclaims as she crouches, her crimson eyes regarding you with unresolved anger — "Without your tricks, the Tigress will tear you limb from limb."
		
		[i]Your previous actions have angered the Tigress. This fight will be harder due to her rage.[/i]
		*set fight_difficulty 1
	*else
		*if characters_5_opinion >= 55
			"It's you! The Tigress does not wish to hurt your pretty face…" — the Tigress exclaims as she crouches, her crimson eyes regarding you with longing — "You are not the Tigress's match. Give up and she will take good care of you."
			
			[i]Your previous actions have pleased the Tigress. This fight will be easier due to her considerations.[/i]
			*set fight_difficulty 0
			*set fight_difficulty -5
		*else
			"Ah, yes, you are that beautiful yet impotent ${pronoun_4}." — the Tigress exclaims as she crouches, her crimson eyes regarding you with disinterest — "The Tigress will not go easy on you just because you look pretty." 

*choice
	#"Who let you out of your cage, you foul savage?"
		A dangerous glint flashes in her gaze. 
		
		"Your tongue is sharp, but is it as sharp as the Tigress's claws?"
	#"It's good to see you too." 
		"No one is ever happy to see the Tigress…" — she shakes her head, replacing the flicker of uncertainty with a dangerous glint — "You just haven't met the real Tigress yet. Let her introduce herself." 
	#Keep silent.
		"Strong and silent? Hehe, the Tigress likes this type the most." — a dangerous glint flashes in her gaze — "But the Tigress loves killing more."

*label round_1
From her crouched position, she leaps. Her body, horizontal in the air and with her clawed fingers spread wide apart, pounces forward. She reaches for your throat.
*if (precognition_enabled)
	*set fight_option_1 "Shield your face. @{(tooltip) [b][CON][/b] |} @{(mc_con >= (60+fight_difficulty)) ✅ |❌}"
	*set fight_option_2 "Catch her hands. @{(tooltip) [b][STR][/b] |} @{(mc_str >= (50+fight_difficulty)) ✅ |❌}" 
	*set fight_option_3 "Jump to the side. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= (70+fight_difficulty)) ✅ |❌}"
*else
	*set fight_option_1 "Shield your face. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Catch her hands. @{(tooltip) [b][STR][/b] |}" 
	*set fight_option_3 "Jump to the side. @{(tooltip) [b][AGI][/b] |}"

*set precognition_enabled false
*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto round_1
*set fight_string "1_${cslib_ret}"
*goto {fight_string}

*comment Shield your face
*label 1_0
*bug "FUCK QUICKTEST"
*label 1_1
You raise your forearms, protecting your head from her sudden attack.

*gosub_scene subroutines stat_check_crit "con" 6 3
*if (crit_stat_check)
	Her claws, otherwise metallic emissaries of death, are unable to cut through your flesh. They leave white marks but do not manage to draw blood. 
	
*elseif (stat_check)
	Her claws, metallic emissaries of death, manage to pierce through even your hardy flesh. They draw blood but are unable to cut too deeply.
	
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"

*else
	Her claws, metallic emissaries of death, cut through your flesh like a knife through butter. They leave deep, bleeding lacerations and are only stopped by the hardiness of your bones. 
	
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	
	*gosub_scene subroutines add_injury 3
	
While her hands drop to the ground, she doesn't stop or fall. Boosted by the momentum of her pounce, she puts her body in a perfect handstand and then wraps her legs around your neck. She tightens the pressure, blocking your airways, and swipes at your face like a wild beast. 
*gosub_scene subroutines reduce_health 2 "fight_tourney_2"

*goto round_2

*comment Catch her hands.
*label 1_2
You raise your arms to intercept her sudden attack. 
*gosub_scene subroutines stat_check "str" 5
*if (stat_check)
	You manage to stop her wrists in the air, not letting them cut through your skin. 
	
	Understanding the futility of her attempt, the Tigress leans into your tight grip and [i]flips[/i] herself. Her legs wrap around your neck, blocking your airways, while she wiggles out of your grasp and swipes at your undefended face.
*else
	Although you grab her wrists, her claws, metallic emissaries of death, still push through and reach your throat. They cut through your skin like knives through butter, drawing blood. 
	
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
	
	You can only be thankful that you managed to stop them before they got too close.
	
	
	The Tigress leans into your tight grip and [i]flips[/i] herself. Her legs wrap around your neck, blocking your airways, while she wiggles out of your grasp and swipes at your undefended face. 

*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"

*goto round_2
	
*label 1_3
*gosub_scene subroutines stat_check "agi" 7
*if (stat_check)
	The Tigress might be fast, but you are even faster. As her claws, metallic emissaries of death, come close, you jump to the side and avoid them.
	
	She doesn't let her temporary defeat dispirit her. Letting her hands fall to the ground, she uses them to perform a perfect handstand and then jumps back on you, wrapping her legs around your throat. She tightens the pressure, blocking your airways, and swipes at your undefended face. 
*else
	You might consider yourself fast, but the Tigress is [i]faster[/i]. As her claws, metallic emissaries of death, come close, you are unable to avoid them in time. You somewhat tilt your body, which allows you to not have your throat ripped open, but she still draws blood. 
	
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
	
	The Tigress puts her hands on the ground, uses them to perform a perfect handstand, and jumps back on you, wrapping her legs around your neck. She tightens the pressure, blocking your airways, and swipes at your undefended face. 

*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"

*goto round_2



*label round_2
*page_break Chokehold
You feel the supply of oxygen shorten in your lungs. 

Her murderous fingers press into your cheek and…
*gosub_scene subroutines stat_check_crit "con" 7 5
*if (crit_stat_check)
	… can't pierce through.
*elseif (stat_check)
	… only leave superficial wounds.
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
*else
	… rupture it, peeling away your skin and spraying blood. 
	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3

Having no other choice, you slam her onto the soil. 

*gosub_scene subroutines stat_check "str" 5
*if (stat_check)
	You smash her with all your might. She grunts in pain and releases her hold. You step back to catch your breath. 
*else
	You smash her with all your might, but your strength is not enough to force her to let go. She continues to choke you. 
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	
	*page_break Slam Again!
	
	*gosub_scene subroutines stat_check "str" 3
	*if (stat_check)
		She grunts in pain and releases her hold. You step back to catch your breath. 
	*else
		It's still not enough. She continues to choke you.
		
		*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
		
		*page_break Slam Again!
		*gosub_scene subroutines stat_check "str" 1
		*if (stat_check)
			She grunts in pain and releases her hold. You step back to catch your breath.
		*else
			She squeezes, using up the whole power of her thick thighs to submit you. You start to feel lightheaded…
			
			*set fight_path 10
			
			*gosub_scene subroutines reduce_health_return 4 "fight_tourney_2"
			
			*set fight_path 0
			
			You shake off the weakness and with the final smash, manage to get free from her unyielding hold.  

*page_break On Your Feet
Putting her hands behind her, the Tigress raises her legs to her head and in one, swift wave-like motion hops back onto her feet. She cranes her neck and fixes her hair, before nodding at you.

"You might give the Tigress a good fight. She thought she would end all you of nobles in a single move." 

*choice
	#Yawn theatrically.
		*gosub_scene subroutines change_personality 2 "arrogant" "+"
		You yawn and stretch your arms. Then, you fix her with a sleepy, bored gaze. 
		
		"When do we start our duel? This warm-up is getting too tedious…" — you boast and do not give her the chance to reply — "Forget it, I'll show you how it's done." 
	#"It's not good to underestimate your opponent."
		*gosub_scene subroutines change_personality 1 "arrogant" "-"
		"You should never underestimate your enemy and overestimate yourself." — you lecture her — "The world is full of crouching tigers and hidden dragons. I'll show you what it means."  
	#Keep silent.
		*gosub_scene subroutines change_personality 2 "impulsive" "-"
		Only a fool will talk during a fight. A smart ${pronoun_4} would use this opportunity to attack instead.
		
While you haven't learned any real Martial Skills — you could not have, in fact, as all of them use Inner Energy as fuel — the fundamentals of kung-fu have still been embedded into your body and mind. You had no reason to employ these teachings before, but this moment is as good as any to put them to use.    

You charge at the Tigress and jump up. You twist your body to the side, yell loudly "KIAH!" and straighten out your leg.

*page_break Flying Side Kick

*gosub_scene subroutines stat_check_crit "agi" 7 5
*if (crit_stat_check)
	You are lightning incarnate as even the far-from-slow Tigress cannot evade your glorious side kick. Your foot smashes into her chest and…
	*gosub_scene subroutines stat_check_crit "str" 4 2
	*if (crit_stat_check)
		… sends her soaring through the fighting circle, tumbling and in shock. However, she soon recovers and rolls over in the air, which allows her to land in quite a graceful manner. 
	*elseif (stat_check)
		… forces her a couple of steps back. She groans but otherwise doesn't suffer a lot of damage.
	*else
		…fails to move her. Also precise, your kick lacks power and momentum. It is you instead who suffers damage as the Tigress brings her claws to your shoulder…
		*label failed_flying_sidekick
		
		*gosub_scene subroutines stat_check_crit "con" 5 3
		*if (crit_stat_check)
			… but fails to penetrate your skin.
		*if (stat_check)
			… and grazes you skin, creating a shallow cut.
			*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
		*else
			… and cuts up a bleeding wound.
			*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
			*gosub_scene subroutines add_injury 3
*elseif (stat_check)
	Your kick goes in the right direction and, should the Tigress have stood still, would've even hit her in the chest. The warrior woman, however, refuses to be a rooted target. She evades the kick with a nimble side-step. 

*else 
	It's been years since you've practiced this move and, having gotten quite slow during this period of time, the kick you perform is far from graceful. It not only misses, it doesn't even reach your target — you land awkwardly before her.
	
	The Tigress watches you in amusement and brings her claws to your shoulder…
	*goto failed_flying_sidekick

*label round_4
You are not about to give her the initiative again: Heavens only know how dangerous she can be when given space to run around.

*if (precognition_enabled)
	*set fight_option_1 "A combination of punches. @{(tooltip) [b][STR/AGI][/b] |} @{((mc_str >= (50+fight_difficulty)) and (mc_agi >= (50+fight_difficulty))) ✅ |❌}"
	*set fight_option_2 "A series of kicks. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= (70+fight_difficulty)) ✅ |❌}" 
	*set fight_option_3 "Grapple. @{(tooltip) [b][STR/CON][/b] |} @{((mc_str >= (50+fight_difficulty)) and (mc_con >= (50+fight_difficulty))) ✅ |❌}"
*else
	*set fight_option_1 "A combination of punches. @{(tooltip) [b][STR/AGI][/b] |}"
	*set fight_option_2 "A series of kicks. @{(tooltip) [b][AGI][/b] |}" 
	*set fight_option_3 "Grapple. @{(tooltip) [b][STR/CON][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto round_4
*set fight_string "2_${cslib_ret}"
*goto {fight_string}

*comment A punch combination
*label 2_1
You raise your hands and throw a punch straight at her head. 

*gosub_scene subroutines stat_check_double "agi" "str" 4
*if (stat_check)
	It hits her right on the mouth, turning her face sideways. You immediately follow it up with a horizontal hand chop to keep her disoriented.

	Bringing back your punching hand, you send a palm strike into her chest.
	*page_break Palm Strike

	*gosub_scene subroutines stat_check_double "agi" "str" 5
	*if (stat_check)
		
		It knocks the breath out of her and you finish the combination by clubbing the Tigress right on the ear.

		*page_break Ear Club
		*gosub_scene subroutines stat_check_double "agi" "str" 6
		*if (stat_check)
			
			It staggers her and she topples onto the solid earth face-first.
			*goto knocked
		
		*else
			However, she finally finds her footing and manages to block your attack with her elbow.
	*else
		She intercepts it with both of her own, nullifying your attack.
*else
	She tilts her head out of the way and thrusts her blades into your stomach. 
	*label blades_in_stomach
	*gosub_scene subroutines stat_check_crit "con" 7 5
	*if (crit_stat_check)
		
		With a clang, your steel-like abs thwart their push. 
	*elseif (stat_check)
		They penetrate your skin, entering an inch deep.
		
		*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
		
		They hurt, but you'll survive.
	*else
		They drill into your abdomen, tearing apart your insides. When the Tigress pulls them out, blood gushes out like a fountain.
		
		*gosub_scene subroutines reduce_health_return 5 "fight_tourney_2"
		*gosub_scene subroutines add_injury 3
*goto dirt_in_eyes

*comment Revolving kicks
*label 2_2
You hop on your left leg and kick her into the side with your right. 

*gosub_scene subroutines stat_check "agi" 5
*if (stat_check)
	It catches the Tigress unprepared, quivering her stable torso.


	You don't waste a second as you change your stance and kick out with your other leg.
	
	*page_break Side Kick
	*gosub_scene subroutines stat_check "agi" 6
	*if (stat_check)
		Once again, you manage to hit her and she moans from ache. 
		You finish the combination by swinging your arms wildly to help you gain height, jumping and kicking her in the jaw.
		*page_break Front Kick
		*gosub_scene subroutines stat_check "agi" 7
		*if (stat_check)
			Your foot almost takes her head off as it smacks her chin. The Tigress is thrown backwards, now without even the pretense of grace as she topples onto the solid earth.  
			*goto knocked
		*else
			She tilts her head backwards and your kick goes wide. 
	*else
		She raises her own knee and blocks it. 
*else
	She raises her knee and blocks it with utter ease. Then, she thrusts her blades into your stomach.  
	*goto blades_in_stomach
*goto dirt_in_eyes

*comment Grapple.
*label 2_3
You're done dancing and prancing around. She wants to be a quick and agile tiger? Then you'll be a powerful bear! 

You engulf her, cutting off all ways of escape with your arms and close proximity.

*gosub_scene subroutines stat_check "str" 5
*if (stat_check)
	She wrestles inside the lock of your arms, rotating her shoulders in an attempt to find freedom, but your grip is tight and unrelenting. With her hanging legs, she kicks you...

	*gosub_scene subroutines stat_check "con" 5
	*if (stat_check)
		But you shrug off her attacks and lift her up. Then, with a roar, you bring her down onto your own knee. She screams out in agony, but just throw her onto the solid earth. 
		*goto knocked
	*else
		And breaks out of your grasp.
		*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
*else
	Your grip too flimsy to contain her, the Tigress breaks it and thrusts her blades into your stomach.
	*goto blades_in_stomach

*goto dirt_in_eyes

*label knocked
The Tigress struggles to get up, her limbs trembling from the suffering you have inflicted.

It would be an honorable thing to wait for her to be ready — it would be a pragmatic decision to capitalize on every chance you get.

*choice
	#Let her get up.
		*gosub_scene subroutines change_opinion 5 1 "-"
		Honor comes before victory — the reputation of a Martial Artist spreads wider than his glory. You allow her to come to her senses. 
		
		*gosub_scene subroutines reputation_change 5 "honor" "+"

		However, as she steadies herself, the Tigress does not seem to appreciate your upstanding gesture.

		"Nobles." — she spits in obvious contempt — "In the world I live in, being prim and proper equals being dead."


	#Kick her while she's down.
		*gosub_scene subroutines change_opinion 5 1 "+"
		As if she is a ball meant for games and entertainment, you kick her in the ribs. She crumbles and kisses the ground for the second time. However, before you kick her again, she rolls backward, snarling through the pain.
		
		*gosub_scene subroutines reputation_change 5 "honor" "-"
		
		"Good. Very good." — she spits — "You're ruthless enough, at least. But you know nothing of the real battle."

*label dirt_in_eyes
"Let me show you something." — the Tigress says, her tone jeering — "Something your tutors would never teach you."

She drops onto all fours, appearing more an animal than a human. You expect her to immediately pounce and prepare yourself, but she does something you forgot is allowed by the rules.

The Tigress gathers the dirt underneath her feet and spurts it into your eyes. The small grains seep underneath your lids, impairing your vision.

*label round_3
You give up on your sight and focus on [i]hearing[/i]. You search for something, anything that could reveal her location: a rustling of clothes, a loud step, an audible breath. However, the Tigress, born and raised in wild forests, is a predator unlike any you have faced before. Her every move — immaculate, her respiration almost non-existent. She's built for stalking prey, her presence vanishing into nothingness. 

*gosub_scene subroutines stat_check_crit "per" 5 3
*if (crit_stat_check)

	But it doesn't matter. Your senses have always been hyper-developed and fighting with a blindfold on is something every self-respecting Martial Artist trains from a young age. You can rely on your ears just as well as on your eyes.

	You notice her behind you, raising her claws in preparation.

*elseif (stat_check)

	With your eyes compromised, your fighting ability dwindles in correspondence. Although you do not experience a significant decline — after all, you've been trained to fight with a blindfold on since childhood — the battle becomes harder. 

	[b]You are partially blinded. Difficulty of all checks is raised.[/b]
	*set fight_difficulty +1

	You don't notice the Tigress until there is barely a foot between your back and her lethal claws. 

*else
	With your sight compromised, your fighting ability dwindles in correspondence. You experience a significant decline — you've never been good at fighting with a blindfold on, despite training from a young age.
	
	[b]You are blinded. Difficulty of all checks is significantly raised.[/b]
	*set fight_difficulty +2

	You don't notice the Tigress at all, not until her claws rip open your back. She then retreats, playing with you as with a toy, disappearing from your senses and leaving you in apprehension.
	
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 
	
	With another slash, she lacerates your stomach. The Tigress places five terrible gnashes across your abdomen, before withdrawing.

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 

	When she comes for the third time, The Tigress jumps on you, weaving her legs across your hips. Her mouth, with glistening teeth that never seemed so dangerous, reaches for your neck and although you try to keep her at range — like a rabid dog — she still bites into your flesh. Tearing off an ample chunk of meat and skin, the Tigress laughs in insanity.

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 

	*goto survived_blind
*if (precognition_enabled)
	*set fight_option_1 "Block them. @{(tooltip) [b][STR][/b] |} @{(mc_str >= (60+fight_difficulty)) ✅ |❌}"
	*set fight_option_2 "Dodge them. @{(tooltip) [b][AGI][/b] |} @{(mc_str >= (80+fight_difficulty)) ✅ |❌}" 
	*set fight_option_3 "Attempt a counterattack. @{(tooltip) [b][STR/AGI][/b] |} @{((mc_str >= 90) and (mc_agi >= (90+fight_difficulty))) ✅ |❌}"
*else
	*set fight_option_1 "Block them. @{(tooltip) [b][STR][/b] |}"
	*set fight_option_2 "Dodge them. @{(tooltip) [b][AGI][/b] |}" 
	*set fight_option_3 "Attempt a counterattack. @{(tooltip) [b][STR/AGI][/b] |}"
	

*set precognition_enabled false
*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto round_3
*set fight_string "3_${cslib_ret}"
*goto {fight_string}

*label 3_1
*gosub_scene subroutines stat_check "str" 3
*if (stat_check)
	You turn around and block her swipe by smacking her wrist away with your forearm. 
	
	Yet, she has no intention of stopping. The Tigress jumps back, disappearing from your senses and leaving you in apprehension. 
	*page_break Second Attack

	Her next attack comes from ahead, targeting your stomach. 
	*gosub_scene subroutines stat_check "str" 4
	*if (stat_check)
		You defend from it in the same way without suffering a scratch. 
		*page_break Third Attack
		In anticipation for the third one, you are stunned silly when instead of claws, you have to defend against [i]teeth[/i]. She jumps on you, weaving her legs around your hips. Her mouth darts towards your neck, compelling you to keep her head at range from your own as if she is a rabid dog.
		
		*gosub_scene subroutines stat_check "agi" 5
		*if (stat_check)
			You succeed in keeping the insane woman at bay until she tires.
		*else
			You fail, however, and the Tigress bites into your flesh. She tears off an ample chunk of meat and skin, laughing in insanity while doing so.
			*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
			*gosub_scene subroutines add_injury 3   
	*else
		You can't defend against it as she slashes her hand across your stomach, opening up a new wound. She then retreats, playing with you as with a toy, disappearing from your senses and leaving you in apprehension. In her next attack, she jumps on you, weaving her legs around your hips. Her mouth darts towards your neck as if she is a rabid dog. The Tigress bites into your flesh, tearing off an ample chunk of meat and skin while laughing in insanity.
		*gosub_scene subroutines reduce_health_return 4 "fight_tourney_2"
		*gosub_scene subroutines add_injury 3  
*else
	You can't defend even against her first swipe that slashes across your stomach and opens up a new wound. She then retreats, playing with you as with a toy, disappearing from your senses and leaving you in apprehension. 

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3  
	
	With another slash, she lacerates your back. The Tigress places five terrible gnashes across your spine, before withdrawing.

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 

	When she comes for the third time, The Tigress jumps on you, weaving her legs across your hips. Her mouth, with glistening teeth that never seemed so dangerous, reaches for your neck and although you try to keep her at range — like a rabid dog — she still bites into your flesh. Tearing off an ample chunk of meat and skin, the Tigress laughs in insanity.

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3  

You throw her away as far from you as you can.
*goto survived_blind

*label 3_2
*gosub_scene subroutines stat_check "agi" 5
*if (stat_check)
	You lean forward, put one of your legs ahead of the other, and jump. Your body twirls, your legs dangling like a butterfly, and avoids her swipe. 

	Yet, she has no intention of stopping. The Tigress disappears from your senses, leaving you in apprehension. 
	*page_break Second Attack

	Her next attack comes from a different direction, targeting your stomach. 

	*gosub_scene subroutines stat_check "agi" 6
	*if (stat_check)
		You tilt your whole torso backwards, until it is at a right angle against your lower body. You feel the ground with your hair and hear the swift swish of her claws hitting air. 
		
		The Tigress withdraws once again.
		*page_break Third Attack
		Returning with a whole new course of action, her mouth darts towards your neck as if a rabid dog's maw. She tries to weave her legs over your hips.
		
		*gosub_scene subroutines stat_check "agi" 8
		*if (stat_check)
			You manage to avoid her, narrowingly avoiding a very dangerous fate. You kick her in the abdomen, hurling her away.
			*goto survived_blind
		*else
			She hops onto you and her mouth bites into your flesh. It tears off an ample chunk of meat and skin, while the Tigress laughs in insanity.
			*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"
			*gosub_scene subroutines add_injury 3  
	*else
		You can't avoid it and she slashes her hand across your stomach, opening up a new wound. She then retreats, playing with you as with a toy, disappearing from your senses and leaving you in apprehension. In her next attack, she hops onto you, weaving her legs around your hips. Her mouth darts towards your neck as if she is a rabid dog. The Tigress bites into your flesh, tearing off an ample chunk of meat and skin while laughing in insanity.
		*gosub_scene subroutines reduce_health_return 4 "fight_tourney_2"
		*gosub_scene subroutines add_injury 3  
*else
	You can't avoid her first swipe that slashes across your stomach and opens up a new wound. 
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3  
	
	She then retreats, playing with you as with a toy, disappearing from your senses and leaving you in apprehension. With another slash, she lacerates your back. The Tigress places five terrible gnashes across your spine, before withdrawing.
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 

	When she comes for the third time, The Tigress jumps on you, weaving her legs across your hips. Her mouth, with glistening teeth that never seemed so dangerous, reaches for your neck and although you try to keep her at range — like a rabid dog — she still bites into your flesh. Tearing off an ample chunk of meat and skin, the Tigress laughs in insanity. 

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 
	You throw her as far from you as you can.

*goto survived_blind


*label 3_3
You meet her charge by leaning forward and kicking out with your back leg. 

*gosub_scene subroutines stat_check_double "str" "agi" 8
*if (stat_check)
	It connects with her hunched figure and due to her bestial posture, hits her right in the face. Your foot fractures her nose and the Tigress is stopped dead in her tracks.
	*set characters_5_history characters_5_history&"broken_nose|" 
*else
	She dodges it with ease and your dangerous stunt harbors you [i]painful[/i] consequences.
	
	First, she lacerates your back. The Tigress places five terrible gnashes across your spine, before diving in between your legs. She slashes across your stomach and opens up a new wound. Then, she jumps on top of you, weaving her legs around your hips, and — like a rabid dog — bites into your flesh. Tearing off an ample chunk of meat and skin, the Tigress laughs in insanity.
	*gosub_scene subroutines reduce_health_return 5 "fight_tourney_2"
	*gosub_scene subroutines add_injury 3 

*goto survived_blind


*label survived_blind

The Tigress pants heavily.
*gosub_scene cslib_string find characters_5_history "broken_nose"
*if cslib_ret > 0
	She wheezes, her broken nose not allowing her to breathe in a normal way.

*label round_5
It's time to end this. What do you want to do?

*set fight_option_1 "Horse Stance Punch."
*set fight_option_2 "720° Spinning Kick." 
*set fight_option_3 "Hip Throw."
*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto round_5

*set fight_string "4_${cslib_ret}"
*goto {fight_string}

*label 4_1
You plant your legs wide and point your feet ahead of you. Your thighs parallel to the floor, your bum pushed out, you arch up your back to keep it from leaning forward.

You concentrate your whole strength into a single punch and let it free.

"HUEEAAGGGGHHH!"

Her whole chest [i]caves in[/i]. Her torso bends backwards and she's lifted from the ground, flying straight into the gathered crowd. Her body drops a couple of nobles by impact, scattering them like walls made of straw. 

The Tigress stays down. 
*goto fake_victory

*label 4_2
You clench your fists and [i]jump[/i]. Spinning yourself in the air, you maintain enough coordination to send precise kicks her way. Four fast like the wind strikes reach her before you land.

On the leg, to break her balance. On the stomach, to make her bend in agony. In the chest, to knock out her breath. In the head, to deprive her of her consciousness. 

The light in her eyes dims before she hits the ground. The Tigress stays down. 
*goto fake_victory

*label 4_3
With one hand, you grab her treacherous wrist, while the other makes its way to her back, grabbing her skirt. You pivot her behind yourself and [i]bend[/i]. Lifting her against your hips, you slam her into the ground. Just for precaution, you finish her with a powerful punch. 

The light in her eyes dims. The Tigress stays down.
*goto fake_victory

*label fake_victory
*page_break Victory?
You finally sigh in relief. If the Tigress was already so difficult to handle, what about Prince Ruo? You don't even dare to imagine. You shake your head, not wishing to tarnish your victory with pessimist thoughts. You look at He Jun, wondering why isn't he announcing the result of your battle — when your legs are swept away from underneath you. The Tigress climbs upon you, her eyes bloodshot and her expression mad with killing frenzy.

"I WILL CARVE OUT YOUR HEART!"

Faster than before, stronger than before, she swings her claws, intent to rend your chest asunder. 

*page_break Defend Yourself
Caught off-guard, you do not succeed in putting up any form of organized defense. 

*gosub_scene subroutines stat_check "con" 7
*if (stat_check)
	And yet, the absurd toughness of your body resists even her bersererked state. Her claws can't pierce through it, which drives her even crazier. 
*else
	She tears an enormous gash in your chest and the sight of blood drives her even crazier.
	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_2"

*label eat_flesh
"I WILL EAT YOUR FLESH!"

Her attacks accelerate, yet also become heavier and heavier with every swipe.

*if precognition_enabled
	*set fight_option_1 "Endure her attack. @{(tooltip) [b][CON][/b] |} @{(mc_con >= (90+fight_difficulty)) ✅ |❌}"
	*set fight_option_2 "Throw her off. @{(tooltip) [b][STR][/b] |} @{(mc_str >= (60+fight_difficulty)) ✅ |❌}"
	*set fight_option_3 "Flip her over. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= (90+fight_difficulty)) ✅ |❌}"	
*else
	*set fight_option_1 "Endure her attack. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Throw her off. @{(tooltip) [b][STR][/b] |}" 
	*set fight_option_3 "Flip her over. @{(tooltip) [b][AGI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto eat_flesh
*set fight_string "5_${cslib_ret}"
*goto {fight_string}

*label 5_1
*gosub_scene subroutines stat_check "con" 9
*if (stat_check)
	No matter how much she tries, she still can't pierce through the impregnable fortress that is your skin.
*else
	*gosub_scene subroutines check_text "con" "neg" (100+fight_difficulty)
	She pierces through your skin, her claws wreaking havoc. But for her, this is not enough.
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
*goto rage_attack

*label 5_2
*gosub_scene subroutines stat_check "str" 6
*if (stat_check)
	You put your hands onto her hips and [i]yank[/i] her away from yourself. She bounces right back. 
*else
	You put your hands on her hips, but can't push her way. She pierces through your skin, her claws wreaking havoc. But for her, this is not enough.
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
*goto rage_attack

*label 5_3
*gosub_scene subroutines stat_check "agi" 9
*if (stat_check)
	You are not going to just watch and wait as her claws wreak havoc on your body. You weave your leg underneath her extended arm and flip her over on her back. 

	You are safe from her attack, but are unable to pin her down: she does the same thing to you that you did to her, turning you over. Except she does it without even a mention of technique, with pure brute strength instead.
*else
	You try to weave your leg underneath her extended arm and flip her over, she nips your attempt in the bud and pierces through your skin. Her claws wreak havoc, but for her, this is not enough.
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_2"
*goto rage_attack

*label rage_attack
*page_break The Tigress's Wrath
Overcome with rage, the Tigress lets out a soul-shaking roar. Her metallic claws [i]glow[/i] with red light and her hands become a blur. 

"WHAT?" — you shout in complete disbelief at her display of a Martial Skill.

The cold steel enters your torso, ignoring any sturdiness it may possess. It searches for your most vital organ to destroy. 

*gosub_scene subroutines reduce_health_return 4 "fight_tourney_2"

Yet, you manage to survive even against that. You force her to pull the claws out of your body and prepare to beat her senseless, but her movements suddenly cease. Once fast and furious, they are now halted and docile. You see her tussle with fatigue, but she decisively loses that battle. Her eyes close and she falls unconscious on top of you.
*goto win


*label defeat
*if fight_path = 10
	*if (eligible_achievements)
		*achieve snusnu_death
*page_break Defeat
*goto_scene after_tourney_2


*label win
*gosub_scene subroutines give_exp 50 ""
*set history history&"tourney_tigress_victory|" 
*page_break Victory
*goto_scene after_tourney_2