*temp no_elbow true
*temp no_submission true
*temp no_punches true

Xiao Chun wields a sword. He holds it in both hands — likely to keep it from trembling — in the most amateurish stance you've ever seen. With a thin frame and a young, naive-looking face the most impressive thing about him is the huge gulps he makes to combat his nervousness. 

"Xi-Xiao Chu-Chun g-greets the ${YM} of the W-Wu Clan…." — he mumbles and you barely recognize half the words he says. His eyes dart around, looking anywhere but at you: you have a feeling your previous performance in the Trial of Blood has left him shaken to core. 

You nod at him.

"Let's get it over with."

*label start_fight
Xiao Chun returns your nod in an awkward manner. He yells to grant himself a dose of adrenaline and runs forward, swinging his sword right at you.
*if (precognition_enabled)
	*set fight_option_1 "Ignore the sword. @{(tooltip) [b][CON][/b] |} @{(mc_con >= 30) ✅ |❌}"
	*set fight_option_2 "Evade it. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= 30) ✅ |❌}" 
	*set fight_option_3 "Knock the sword out of his hand. @{(tooltip) [b][AGI/STRI][/b] |} @{((mc_str >= 30) and (mc_agi >= 25)) ✅ |❌}"
*else
	*set fight_option_1 "Ignore the sword. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Evade it. @{(tooltip) [b][AGI][/b] |}" 
	*set fight_option_3 "Knock the sword out of his hand. @{(tooltip) [b][AGI/STRI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto start_fight
*set fight_string "1_${cslib_ret}"
*goto {fight_string}

*label 1_0
*bug fuck quicktest

*label 1_1
*gosub_scene subroutines stat_check_crit "con" 6 4
*if (crit_stat_check)
	Wielded by a man with the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the sword poses you no threat. 

	You don't bother evading or blocking: the blade hits just below your shoulder and… gets deflected by your tough skin, almost flying out of his hand. Xiao Chun eyes go wide in terror.
	
	*goto sword_blocked

*if (stat_check)
	Wielded by a man with the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the sword poses you no threat. 

	You don't bother evading or blocking: the blade hits just below your shoulder, pierces your skin and… gets stuck in the thick layer of your muscle. You tense your bicep, and see Xiao Chun, eyes wide and terrified, frantically try and pull it back from the grip of your flesh.

	He manages to do it, causing a trail of blood to pour. You grunt, but otherwise don't pay attention to the wound.

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	*goto sword_blocked
*else
	Although the one who wields it has the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the sword is still sharp and sharpness poses danger to the mortal flesh. 

	The blade hits just below your shoulder, pierces your skin and draws blood. Xiao Chun pulls it back, leaving a nasty wound on your arm, and you see him gain confidence due to his successful attack. 

	*gosub_scene subroutines add_injury 3

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_1"
	
	*goto sword_not_blocked

*label 1_2
*gosub_scene subroutines stat_check "agi" 4
*if (stat_check)
	Wielded by a man with the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the sword poses no threat to you. 

	Just as the sword arrives close, you tilt your body backwards, right out of its way. The blade goes wide, only hitting empty air with a swish.

	*goto sword_blocked
*else
	Although the one who wields it has the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the sword still has enough speed to pose you danger.

	When it arrives close, you tilt your body backwards, but the blade still catches you in the chest. It pierces your skin, draws blood and leaves a nasty wound. 

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_1"

	*gosub_scene subroutines add_injury 3

	You grunt and step back, while Xiao Chun gains confidence due to his successful attack.
	
	*goto sword_not_blocked

*label 1_3
Although the one who wields it has the strength of a twelve-year old child and the accuracy of an untrained barbarian archer, the blade still poses danger for your mortal flesh.

It's better to get rid of it.

You analyze the trajectory of sword's path and the grip of Xiao Chun on its hilt.

*gosub_scene subroutines stat_check "agi" 4
*if (stat_check)

	When the cold steel comes close, you step out of its way, causing it to go wide and only hit the empty air.

	You figure out the best spot to strike and send a palm towards his wrist.

	*gosub_scene subroutines stat_check "str" 4
	*if (stat_check)

		It connects and the sword escapes from Xiao Chun's grasp, drops to the side.

		*goto no_sword
	*else
		It connects, but lacks the power to knock the sword out of his grasp.

		*goto sword_blocked
*else
	When the cold steel comes close, you step out of its way, but the blade catches you in the chest. It pierces your skin, draws blood and leaves a nasty wound. 
	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_1"

	*gosub_scene subroutines add_injury 3

	You grunt, while Xiao Chun gains confidence due to his successful attack.

	*goto sword_not_blocked


*label sword_blocked

Having successfully repelled his attack, you go on the offensive.

*if (precognition_enabled)
	*set fight_option_1 "Tackle him to the ground. @{(tooltip) [b][CON][/b] |} @{(mc_str >= 20) ✅ |❌}"
	*set fight_option_2 "Palm strike to the chest. @{(tooltip) [b][AGI/STR][/b] |} @{((mc_str >= 30) and (mc_agi >= 20)) ✅ |❌}" 
	*set fight_option_3 "High kick in the head. @{(tooltip) [b][AGI/STRI][/b] |} @{((mc_str >= 20) and (mc_agi >= 30)) ✅ |❌}"
*else
	*set fight_option_1 "Tackle him to the ground. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Palm strike to the chest. @{(tooltip) [b][AGI/STR][/b] |}" 
	*set fight_option_3 "High kick in the head. @{(tooltip) [b][AGI/STRI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto sword_blocked
*set fight_string "2_${cslib_ret}"
*goto {fight_string}

*label 2_1
*gosub_scene subroutines stat_check "str" 3
*if (stat_check)
	You hit his waist with your shoulder and grab his legs from underneath him, slamming the boy into the ground. His sword drops somewhere to the side.

	*goto tackled
*else
	You hit his waist with your shoulder and grab his legs from underneath him, but lack the strength to lift him from the ground. Xiao Chun drops his sword to the side and elbows you in the back, causing you to let go.

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	*goto no_sword

*label 2_2
*gosub_scene subroutines stat_check "agi" 3
*if (stat_check)
	Your legs planted wide, you take a deep breath. You channel all your strength into a single palm and let out a strike aimed straight at his chest. 

	"AYAH!"

	*gosub_scene subroutines stat_check_crit "str" 5 3
	*if (crit_stat_check)

		Your terrifying strength almost knocks the ever-living soul out of his body. Something in his chest breaks and the boy is sent flying out of the circle, straight into the crowd of observes. 

		He does not get up.
		*set fight_path "super palm strike"
		*goto win
	*elsif (stat_check)
		You strike to causes him to fall over backwards, unable to withstand the kinetic impact.

		*if (precognition_enabled)
			*set precognition_enabled false
			*page_break Turn Back Time
			*goto sword_blocked

		*goto tackled
	*else
		Your strike fails to do any significant damage, but it forces him to let go of the sword to protect himself.
		
		*goto no_sword
*else
	Your legs planted wide, you take a deep breath. You channel all your strength into a single palm and let out a strike aimed straight at his chest.

	However, before it can reach, Xian Chun overcomes his previous failure and slashes you once again with the blade. 

	Catching you in the chest, it pierces your skin, draws blood and leaves a nasty wound. 

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_1"

	You grunt and step back, while Xiao Chun gains confidence due to his successful attack.

	*gosub_scene subroutines add_injury 3

	*goto sword_not_blocked							

*label 2_3
*gosub_scene subroutines stat_check "agi" 3
*if (stat_check)
	You hop in place, raising your left foot on its tip-topes and lifting your right leg, bended at the knee, into the air. Rotating the foot to the side, you twist your hips and straighten out the other leg — releasing a kick to Xiao Chun's head. 

	*gosub_scene subroutines stat_check_crit "str" 3 2
	*if (crit_stat_check)
		A clean hit. His head bobbles like a tumbler, before he falls face-forward onto the ground with a thud.

		He does not get up.

		*set fight_path "high kick"
		*goto win
	*elsif (stat_check)
		The hit is not as clean as it could've been.  Xiao Chun falls backwards, unable maintain his balance after being rocked in the face, but still awake.

		*goto tackled

	*else
		Xiao Chuo hurriedly protects his face with his sword-bearing arm: it works, and you kick fails to do any significant damage, but it does force him to release his blade. It drops to the side.

		*goto no_sword
*else
	You hop in place, raising your left foot on its tip-topes and lifting your right leg, bended at the knee, into the air. Rotating the foot to the side, you twist your hips and straighten out the other leg — releasing a kick to Xiao Chun's head.

	However, before it can reach, Xian Chun overcomes his previous failure. He dodges and slashes you once again with the blade. 

	Catching you in the chest, it pierces your skin, draws blood and leaves a nasty wound. 

	*gosub_scene subroutines reduce_health_return 2 "fight_tourney_1"

	*gosub_scene subroutines add_injury 3

	You grunt and step back, while Xiao Chun gains confidence due to his successful attack.

	*goto sword_not_blocked

*label sword_not_blocked
Emboldened by the fresh blood on the edge of his blade, Xiao Chun thrusts it towards you. 

*if (precognition_enabled)
	*set fight_option_1 "Stop it with your hands. @{(tooltip) [b][STR][/b] |} @{(mc_str >= 20) ✅ |❌}"
	*set fight_option_2 "Endure it. @{(tooltip) [b][CON][/b] |} @{(mc_con >= 20) ✅ |❌}" 
	*set fight_option_3 "Duck to the side. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= 20) ✅ |❌}"
*else
	*set fight_option_1 "Tackle him to the ground. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Palm strike to the chest. @{(tooltip) [b][AGI/STR][/b] |}" 
	*set fight_option_3 "Duck to the side. @{(tooltip) [b][AGI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto sword_not_blocked
*set fight_string "3_${cslib_ret}"
*goto {fight_string}

*label 3_1
You take a step back and engulf the sword with both of yours palms.

*gosub_scene subroutines stat_check "str" 2
*if (stat_check)
	It halts inches away from your heart, scrapping your hands in the process. 

	You throw the sword to the side, leaving both of you without a weapon.

*else
	It doesn't halt, only changing its trajectory by a couple of inches, and punctures a hole near your heart.

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_1"

	Your strength wanes, your vision darkens and you feel light-heated, but, grasping at the last bits of your consciousness like a drowning man reaches for a helping hand, you power through. 

	WIth an angry grumble, you yank the blade from your flesh. You throw it to the side, leaving both of you without a weapon.

*goto no_sword

*label 3_2
You clench your teeth as the blades punctures a hole in your right breast. 

*gosub_scene subroutines stat_check "str" 2
*if (stat_check)
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	It halts half inch deep inside your flesh. With an angry roar, you yank the blade from your body and throw it to the side, leaving both of you without a weapon.
	
*else
	It doesn't halt, rupturing your flesh, a fortunate inch away from your heart.

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_1"

	Your strength wanes, your vision darkens and you feel light-heated, but, grasping at the last bits of your consciousness like a drowning man reaches for a helping hand, you power through. 

	WIth an angry grumble, you yank the blade from your flesh. You throw it to the side, leaving both of you without a weapon. 	

*goto no_sword

*label 3_3
You jump to the side, away from the harmful steel. 

*gosub_scene subroutines stat_check "agi" 2
*if (stat_check)
	The sword misses and you use this opportunity to knock it away from his grasp. The sword drops on the ground.

*else
	But, the speed of the sword prevails over yours. It punctures a hole in your right breast, rupturing your flesh.

	*gosub_scene subroutines reduce_health_return 3 "fight_tourney_1"

	Your strength wanes, your vision darkens and you feel light-heated, but, grasping at the last bits of your consciousness like a drowning man reaches for a helping hand, you power through. 

	WIth an angry grumble, you yank the blade from your flesh. You throw it to the side, leaving both of you without a weapon. 

*goto no_sword

*label no_sword
Both on your feet, you and Xiao Chun stare at each other. His self-assurance gone without his sword, Xiao Chun glances at his lost weapon, then back to you and hesitates. For a moment, you believe he'll recklessly sprint to pick it up, but in the end he determines that to be a bad idea. Instead, he roundhouse-kicks you in the stomach.

*if (precognition_enabled)
	*set fight_option_1 "Tank it. @{(tooltip) [b][CON][/b] |} @{(mc_con >= 20) ✅ |❌}"
	*set fight_option_2 "Block it. @{(tooltip) [b][STR][/b] |} @{(mc_str >= 20) ✅ |❌}" 
	*set fight_option_3 "Dodge. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= 10) ✅ |❌}"
*else
	*set fight_option_1 "Tank it. @{(tooltip) [b][CON][/b] |}"
	*set fight_option_2 "Block it. @{(tooltip) [b][STR][/b] |}"
	*set fight_option_3 "Dodge. @{(tooltip) [b][AGI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto no_sword
*set fight_string "4_${cslib_ret}"
*goto {fight_string}

*label 4_1
*gosub_scene subroutines stat_check_crit "str" 4 2
*if (crit_stat_check)
	You don't even feel the impact of his kick. Xiao Chun, however, experiences the impact of your rock-hard stomach in full.

	As his foot connects, you hear the sound of a bone fracturing into pieces. Followed by a resounding scream of pain.

	"AAAAH!" — Xiao Chun falls, holding his hurting feet with gentleness — "I-I think… I br-broke it…."

	You chuckle at winning a fight by being a a human wall of steel and shake your head.

	*set fight_path "broken leg"
	*goto win
*elsif (stat_check)
	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	His kick hurts, but you have been subjected to much worse punishments.

	Unbalanced and unprepared, Xiao Chun presents an easy target for a counterattack. 

	*label three_punches
	*choice
		#Punch him in the jaw.
			You decide not to stand on ceremony: since he gave you this opportunity, you will utilize it to the fullest and end the fight.

			Rotating your shoulder and putting your weight behind it, you let out a lightning-quick punch that catches him squarely on the jaw. 


			Lights out, he falls unconscious on the ground.
			*set fight_path "knocked out"
			*goto win
		#Punch him in the throat.
			*gosub_scene subroutines change_personality 2 "ruthless" "+"
			There is no mercy on the Martial Path. Only victory and defeat.

			Rotating your shoulder and putting your weight behind it, you let out a lightning-quick punch that catches him right in the neck. 

			However, you miscalculate your power: your fist crushes something inside his throat. Unconscious in an instant, Xiao Chun falls to the ground, his head making a loud [i]thud[/i].

			He does not seem to be breathing.
			*set fight_path "crushed throat"

			*goto win
		#Punch him in the chest. 
			*gosub_scene subroutines change_personality 1 "ruthless" "-"
			This boy never is going to be a great martial artist: he lacks both talent and character. You should at least end this tournament as painless for him as possible. 

			Rotating your shoulder and putting your weight behind it, you let out a lightning-quick punch that catches him right in the plexus. 


			The boy falls to the ground, struggling to breathe. He waves his hand, indicating his surrender.

			*set fight_path "plexus"
			*goto win
*else
	His kick hurts. It hurts a lot, causing you to bend over in pain.

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	Xiao Chun immediately follows it up with his fist, squashing your nose.
	*set injuries_2 true

	[[b]Injured:[/b] [i]Broken nose.[/i]]

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	You let out an angry roar, shove him away and counterattack. 
	
	*goto three_punches

*label 4_2
*gosub_scene subroutines stat_check "str" 2
*if (stat_check)
	You raise your knee in a well-timed block that absorbs all of the impact Xiao Chun's shin carried. 

	Unbalanced and unprepared, he presents an easy target for a counterattack.
	
	*goto three_punches
*else 
	You raise your knee in a well-timed block, but the impact of Xiao Chun's kick turns your unbalanced body and causes it to stumble. 

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	He immediately follows it up with a swift kick to the ribs.

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	With an angry roar, you stand up, shove him away and counterattack. 

	*goto three_punches

*label 4_3
*gosub_scene subroutines stat_check "agi" 1
*if (stat_check)
	You jump back and the kick misses. 


	Unbalanced and unprepared, he presents an easy target for a counterattack.

	*goto three_punches
*else
	You are not fast enough to jump away in time and his kick connects, causing you to bend over in pain.

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	Xiao Chun immediately follows it up with his fist, squashing your nose.
	*set injuries_2 true

	[[b]Injured:[/b] [i]Broken nose.[/i]]

	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	You let out an angry roar, shove him away and counterattack.

	*goto three_punches
			
*label tackled
You mount the boy, and he doesn't even try to throw you off: just shields his face in desperation with his arms. 
*if (precognition_enabled)
	*if ((((mc_bodytype = "muscular") or (mc_bodytype = "chunky"))) and (no_elbow))
		*set fight_option_1 "Grip his wrists and elbow him in the face. @{(tooltip) [b][STR][/b] |} @{(mc_str >= 20) ✅ |❌}"
	*if (no_submission) 
		*set fight_option_2 "Perform a submission. @{(tooltip) [b][STR][/b] |} @{(mc_agi >= 30) ✅ |❌}"
	*if (no_punches)
		*set fight_option_3 "Punch through his guard. @{(tooltip) [b][STR/CON][/b] |} @{((mc_str >= 20) and (mc_con >= 20)) ✅ |❌}"
	*set fight_option_4 "Get up from the ground."
*else
	*if ((((mc_bodytype = "muscular") or (mc_bodytype = "chunky"))) and (no_elbow))
		*set fight_option_1 "Grip his wrists and elbow him in the face. @{(tooltip) [b][STR][/b] |}"
	*if (no_submission) 
		*set fight_option_2 "Perform a submission. @{(tooltip) [b][STR][/b] |}"
	*if (no_punches)
		*set fight_option_3 "Punch through his guard. @{(tooltip) [b][STR/CON][/b] |}"
	*set fight_option_4 "Get up from the ground."
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto tackled
*set fight_string "5_${cslib_ret}"
*goto {fight_string}

*label 5_1
*gosub_scene subroutines stat_check "str" 4 2
*if (crit_stat_check)
	You grip his skinny wrists with your large hand. He wiggles and struggles, yet his protests remain fruitless and you move his arms behind his head. Then, with his face unguarded, you elbow him right in the jaw. 


	As if a switch turned off inside his brain, his movements cease and the light inside his eyes dims. He goes limp.

	*set fight_path "elbowed"
	*goto win
*elseif (stat_check)
	You grip his skinny wrists with your large hand. He wiggles and struggles, yet his protests remain fruitless and you move his arms behind his head. Then, with his face unguarded, you elbow him right in the jaw.


	Xiao Chun manages to free one his hands and somewhat resist your strike, but your elbow still connects with his mouth. 

	*set no_elbow false
	*page_break Back To Mount
	*goto tackled
*else
	You try to grip his skinny wrists in your large hand, but Xiao Chun wiggles and struggles like a man possessed. 


	You fail.

	*set no_elbow false
	*page_break Back To Mount
	*goto tackled

*label 5_2
*gosub_scene subroutines stat_check "agi" 3
*if (stat_check)
	A panicked, scared opponent is no match for you skills and strength. You position yourself in a way where you waist touches his flailing arms, limiting their freedom of movement. You lean forward, weave your arm underneath one of his and pull back.


	"YIELD, I YIELD!" — he yells in an instant and taps your side. 

	*choice
		#Release him.
			*gosub_scene subroutines change_personality 2 "violent" "-"
			You let go of his arm and get up. This fight is won. 

			*set fight_path "submission"
			*goto win
		#Break his arm.
			*gosub_scene subroutines change_personality 2 "violent" "+"
			Letting out a cruel, sadistic smile you ignore his surrender and pull further. 

			Two things happen at once: his arm snaps, the bone unable to handle the pressure of the yank, and Xiao Chun screams like a dying beast.

			*set fight_path "broken arm"
			*goto win
*else
	Although panicked and scared, Xiao Chun still refuses to surrender, flailing his arms and moving his body in a way that makes it impossible for you to get a good grip. 

	*set no_submission false
	*goto tackled


*label 5_3
*gosub_scene subroutines stat_check_double "str" "con" 2
*if (stat_check)
	You don't care about his little block.

	Punch after punch, you continue raining hammer-fists onto him. Most of them either hit his forearms or miss entirely, landing on the hard ground. Your knuckles hurt and scrape, but you disregard the pain and, eventually, the result is worth the price: more and more of your punches land. His face gets bloodier and bloodier, his resistance grows weaker and weaker.


	Until he just goes limp under your rampage.

	*set fight_path "beaten"

	*goto win

*else
	Punch after punch, you rain hammer-fists onto him. Most of them either hit his forearms or miss entirely, landing on the hard ground. Your knuckles hurt and scrape, and, eventually, the pain becomes too much to ignore.


	*gosub_scene subroutines reduce_health_return 1 "fight_tourney_1"

	You stop.

	*set no_punches false
	*goto tackled

*label 5_4
The position on the ground, even in an advantageous mount, is not the one you find comfortable. You decide to get up and try you luck standing.
			
*goto no_sword

*label win
*page_break Victory

*gosub_scene subroutines give_exp 20 ""

*if fight_path = "super palm strike"
	A couple of nobles try to help Xiao Chun regain his senses and they eventually do, but the boy can't even breathe without grunting in pain. You shake your head. Fights against such weak opponents are no fun at all. 
*elseif fight_path = "high kick"
	*label knocked_out
	A couple of nobles — his friends, you wager — rush out from the crowd. They open up a vial and the strong aroma of the liquid inside helps Xiao Chun regain his senses. The first thing he does is spit out a couple of teeth. Then, he looks at you both with fear for your might and relief since the tourney for him ended without any lasting injuries. 
*elseif fight_path = "broken leg"
	A couple of nobles — his friends, you wager — rush out from the crowd. They lift Xian Chun, who still wails hysterically, and carry him away. You can't help but shake your head.
*elseif fight_path = "knocked out"
	*goto knocked_out
*elseif fight_path = "crushed throat"
	*set history history&"hurt_xiaochun|" 
	A couple of nobles — his friends, you wager — rush out from outside the circle. They open up a vial, but even the strong aroma of the liquid inside can't help Xiao Chun regain his senses. After a minute, he's still unconscious and still not breathing.
	
	"Help him!" — one of the friends shouts to He Jun — "He's dying!"
	
	"It's not my responsibility to care for the weaklings. He should not have partaken in the tourney with such measly strength." — He Jun responds, eying the dying boy without a shred of compassion. 
	
	"Wh-what? Please, please you have to help him!" 

	At this moment, another person — a simple-dressed woman — walks out from the crowd.
	*set ai_pronoun_1 "she"
	*set ai_pronoun_2 "her"
	*set ai_pronoun_3 "hers"
	*set ai_pronoun_4 "woman" 
	
	"Make room." — ${ai_pronoun_1} says as as ${ai_pronoun_1} squats next to Xiao Chun, shooing away his friends. $!{ai_pronoun_1} takes out a needle from ${ai_pronoun_2} bag and presses it right below his thyroid cartilage. $!{ai_pronoun_1} then pulls out a straw and puts it inside the newly created hole. 
	
	In a manner of seconds, air once again enters Xiao Chun's body. 
	
	"Thank you!" — his friends shout — "Thank you so much. May we know your name?"
	
	"Just call me Ai. He will live, but you need to get him to a healer as soon as possible." — ${ai_pronoun_1} responds, before turning around and facing you — "${YM}, must you be so cruel?"
	
	*if characters_9_opinion > 100
		*set characters_9_opinion 50
		[b][i]Ai[/i] added to Character Glossary[/b]
	*label ai_choice
	*temp boyname "boy"
	*if ai_pronoun_1 = "she"
		*set boyname "girl"
	*choice
		#"A village simpleton does not have the right to criticize my actions."
			*gosub_scene subroutines change_personality 1 "arrogant" "+"
			*gosub_scene subroutines change_personality 1 "elitist" "+"
			*gosub_scene subroutines change_opinion 9 3 "-"
			"Those whose sight is shortened by contempt tend to be blind towards the encroaching danger." 
			
			"Are you supposed to be the danger, little ${boyname}?" — you snort. 
			
			"Of course not, how can an insignificant me threaten a noble of such high status? I'm just sure a ${pronoun_4} like you is going to have a lot of enemies."
			
			$!{ai_pronoun_1} gets up and disappears into the crowd.
			
			*gosub_scene subroutines reputation_change 10 "kindness" "-"
		#"Should I maim you too?"
			*gosub_scene subroutines change_opinion 9 4 "-"
			*gosub_scene subroutines change_personality 1 "violent" "+"
			Your threat doesn't faze ${ai_pronoun_2}. 
			
			"Those who live in violence tend to find their end in it too."
			
			"Is that supposed to be a threat, little ${boyname}?" — you snort.

			"Of course not, how would I dare? I'm just sure a ${ai_pronoun_4} like you is going to have a lot of enemies."
			
			$!{ai_pronoun_1} gets up and disappears into the crowd.
			
			*gosub_scene subroutines reputation_change 10 "kindness" "-"
			
		#"I apologize. It was an accident." @{(tooltip) [b][PERSUASION][/b] |}
			*gosub_scene subroutines change_personality 1 "arrogant" "-"
			*gosub_scene subroutines stat_check "chr" 5
			*if (stat_check)
				
				$!{ai_pronoun_1} nods 			$!{ai_pronoun_2} head.
				
				"Such things do happen. You should at least offer him some monetary compensation." — 			${ai_pronoun_1} looks at you, expectantly.
				
				"Of course, of course."
				
				You throw a bag of gold to 			$!{ai_pronoun_2}, which 			$!{ai_pronoun_1} catches with a graceful movement. 
				
				[b]Gold - 500[/b]
				*set mc_gold -500
				
				"Thank you, ${YM}."
				
				${ai_pronoun_1} gets up and disappear into the crowd.
				
				*gosub_scene subroutines reputation_change 5 "kindness" "-"
			*else
				*gosub_scene subroutines change_opinion 9 2 "-"
				
				"Violent and untruthful — how benefiting for a noble of your status." 
				
				"Are you accusing me of lying, little ${boyname}?" — you snort. 
				
				"Why would you care about the words of some mortal ${ai_pronoun_4}?" — 			${ai_pronoun_1} shakes 			${ai_pronoun_2} head, gets up and disappears into the crowd.
				
				*gosub_scene subroutines reputation_change 10 "kindness" "-"
				*gosub_scene subroutines reputation_change 10 "honor" "-"
*elseif fight_path = "plexus"
	*label mercy
	Xiao Chun takes a minute to restore his breathing. He then stands up and bows to you.
	
	"Thank you, ${YM}, for showing mercy."
	
	You nod at him and he disappears into the crowd.
*elseif fight_path = "submission" 
	*goto mercy
*elseif fight_path = "broken arm"
	*set history history&"hurt_xiaochun|" 
	You smirk at Xiao Chun's pathetic wailing. You smirk even wider as a couple of nobles — his friends, you wager — rush out from outside the circle. They look at you in anger, before shouting towards He Jun.
	
	"That was intentionally cruel! We demand his disqualification!" 
	
	He Jun laughs out loud at their petition.
	
	"Backwater idiots are always so funny." — he responds — "Leave now, and carry your useless friend out of here."
	
	The nobles scowl their teeth, but dare not refute the Sect Envoy. At this moment, however, a simple-dressed
	*if characters_9_opinion > 100
		…
	*choice
		#Man.
			*set ai_pronoun_1 "he"
			*set ai_pronoun_2 "him"
			*set ai_pronoun_3 "his"
			*set ai_pronoun_4 "man"
		#Woman.
			*set ai_pronoun_1 "she"
			*set ai_pronoun_2 "her"
			*set ai_pronoun_3 "hers"
			*set ai_pronoun_4 "woman"
	${ai_pronoun_4} walks out form the crowd. $!{ai_pronoun_1} takes out some kind of vial from ${ai_pronoun_2} bag and rubs the ointment inside onto the Xian Chun's broken arm. 
	
	His cries grow duller.
	
	"Thank you!" — his friends shout — "Thank you so much. May we know your name?"
	
	"Just call me Ai. This will ease his pain, but you need to get him to a healer as soon as possible." — ${ai_pronoun_1} responds, before turning around and facing you — "${YM}, must you be so cruel?"
	
	*if characters_9_opinion > 100
		*set characters_9_opinion 50
		[b][i]Ai[/i] added to Character Glossary[/b]
	*goto ai_choice

*elseif fight_path = "elbowed"
	*goto knocked_out

*elseif fight_path = "beaten"
	*goto knocked_out

"Wu ${mc_name} wins!" — He Jun's voice bellows through the meadow. 

*goto_scene after_tourney_1
	
	
*label defeat

The world goes black and your consciousness slips away…

*page_break Defeat

You wake up to find He Jun standing over you.

"Such a pathetic display. I should've announced your Blood Trial alongside the mortals." — he says — "A heavenly talent wasted on a piece of trash. I guess I don't have to worry about your growth, after all." 
*set history history&"prologue_tourney_lost_xiaochun"

*if (eligible_achievements)
	*achieve lost_to_xiaochun
*goto_scene after_tourney_1