*temp path 0
*temp f_round 0
*temp attempted_wrestle false
*temp attempted_armbar false
*temp attempted_trade false
*temp attempted_tiring false
*label start_fight
*page_break Continue
*if (path != 99) and (not (precognition_enabled))
	*set f_round +1
*if path = 99
	*if (((attempted_wrestle) and (attempted_armbar)) and ((attempted_trade) and (attempted_tiring)))
		The innkeeper grows tired trying to hold you on the ground and gets up.
		*set path 1
		*goto start_fight
*temp string "round_${f_round}"
*goto {string}

*label round_1
*stat_chart
	percent round(((mc_health/mc_health_total)*100)) Health
You will not tolerate such insolence from a mortal. 

How do you wish to attack?

*if precognition_enabled
	*set fight_option_1 "Pull him over the counter. @{(tooltip) [b][STR][/b] |} @{(mc_str >= 6) ✅ |❌}"
	*set fight_option_2 "Smash his head on a chopstick. @{(tooltip) [b][STR/AGI][/b] |} @{((mc_str >= 6) and (mc_agi >= 6)) ✅ |❌}"
	*set fight_option_3 "Swing at him with a bottle. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= 5) ✅ |❌}"
*else
	*set fight_option_1 "Pull him over the counter. @{(tooltip) [b][STR][/b] |}"
	*set fight_option_2 "Smash his head on a chopstick. @{(tooltip) [b][STR/AGI][/b] |}"
	*set fight_option_3 "Swing at him with a bottle. @{(tooltip) [b][AGI][/b] |}"
*set precognition_enabled false

*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
*gosub_scene subroutines clear_fight_options
*if cslib_ret = 10
	You close your eyes, your mind constructing infinite variations of the near future…
	*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
	*set precognition_enabled "true"
	*page_break Continue
	*goto round_1
*set fight_string "1_${cslib_ret}"
*goto {fight_string}

*label 1_0
*bug fuck quick test

*label 1_1
*set path 1
*gosub_scene subroutines stat_check "str" 6
*if (stat_check)
	Putting your hands around his collar, you catch him smirk in contempt. He weighs at least three hundred pounds — a behemoth of a man. What are you going to do? Lift him? What a hilarious tho-

	His eyes widen in terror when his feet leave the floor. He fights against your grip, but it is a bit too late as you send him flying across the room like a pebble shot from a sling. His enormous body first hits a table, blowing it into wooden splinters, and then an unfortunate woman. She doesn't even have time to scream — dead on impact, her neck snapped by the man's weight.

	The innkeeper stands up, more angry than hurt. 
	*goto start_fight
*else

	*set path 2
	Putting your hands around his neck, you do your best to lift him — but he's just too heavy. He weighs at least three hundred pounds, a behemoth of a man.  And you are not strong enough raise such weight into the air.

	He scoffs, pulls back his arm and hits you right in the jaw.

	You fall to the ground from the impact. 
	*gosub_scene subroutines reduce_health_return 2 "fight_innkeeper"
	*if mc_health <= 0
		*goto defeat
	*goto start_fight

*label 1_2
*gosub_scene subroutines stat_check_double "str" "agi" 6
*if (stat_check)
	You put your right palm on the side of the innkeeper's head and press it down. At the same time, you grab a nearby chopstick with your left hand and put it on the counter. 

	The pointed end of the chopstick pierces through the innkeeper's ear, drawing blood. You press his head further, until the chopstick is so deep in the innkeeper's brain that you can barely see its tip. 

	The innkeeper dies, his brain punctured, and lies limp on the table. 
	*set path 3
	*goto win
*else
	*set path 2
	A good idea, but your execution lacked in speed and strength. The innkeeper swats away your hand like an annoying fly and hits you squarely on the jaw.

	You fall to the ground from the impact.
	*gosub_scene subroutines reduce_health_return 2 "fight_innkeeper"
*goto start_fight

*label 1_3
*gosub_scene subroutines stat_check "agi" 5
*if (stat_check)
	*set path 4
	You grab a nearby bottle of rum and swing it at his head. You are successful, as the bottle shatters into shards of glass, but your attack results in just a simple graze on his temple. 

	He gives you a scoff, pushes you away and jumps over the counter.
*else
	*set path 2
	The innkeeper swats away your hand like an annoying fly and hits you squarely on the jaw.

	You fall to the ground from the impact.
	*gosub_scene subroutines reduce_health_return 2 "fight_innkeeper"

*goto start_fight

*label round_2
*stat_chart
	percent round(((mc_health/mc_health_total)*100)) Health
*if path = 1
	The man looks at you with vigilance — he's never met someone who could throw him around like a ragdoll before — but rage soon overcomes his reason.
	*label incoming_tackle
	He roars, his voice almost bestial, and charges at you as if a bull.
	*if precognition_enabled
		*set fight_option_1 "Put him in a guillotine. @{(tooltip) [b][STR/AGI][/b] |} @{((mc_str >= 5) and (mc_agi >= 5)) ✅ |❌}"
		*set fight_option_2 "Knee him. @{(tooltip) [b][STR/AGI][/b] |} @{(mc_agi >= 7) ✅ |❌}"
		*set fight_option_3 "Evade him. @{(tooltip) [b][AGI][/b] |} @{(mc_agi >= 5) ✅ |❌}"
	*else
		*set fight_option_1 "Put him in a guillotine. @{(tooltip) [b][STR/AGI][/b] |}"
		*set fight_option_2 "Knee him. @{(tooltip) [b][STR/AGI][/b] |}"
		*set fight_option_3 "Evade him. @{(tooltip) [b][AGI][/b] |}"
	*set precognition_enabled false

	*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
	*gosub_scene subroutines clear_fight_options
	*if cslib_ret = 10
		You close your eyes, your mind constructing infinite variations of the near future…
		*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
		*set precognition_enabled "true"
		*page_break Continue
		*goto round_2
	*set fight_string "2_${cslib_ret}"
	*goto {fight_string}

*elsif path = 2
	You surely had some kind of a plan, but, after getting struck in the face, plans often come to ruin. You shake your head to come to your senses and begin to get up, but the innkeeper jumps over the counter and mounts you. 
	*goto tackled

*elsif path = 4
	*goto incoming_tackle

*elsif path = 99
	*goto tackle_escape

*label 2_1
*gosub_scene subroutines stat_check_double "str" "agi" 5
*if (stat_check)

	Just as he dives for a tackle, you weave you hands around his neck and cross your legs behind his back. With your limbs, you [i]pull[/i] — stretching him and restricting his supply of air. 

	The innkeeper panics and, as panicked people usually do, he acts on instinct, slamming you into the ground.
	*gosub_scene subroutines reduce_health_return 2 "fight_innkeeper"
	*gosub_scene subroutines stat_check "con" 4
	*if (stat_check)
		Your spine hurts from the smash, but you hold on. He slams you two more times and, realizing his efforts are futile, changes tactics. He pummels your ribs with his fists, but you feel as his attacks grow weaker and rarer. 

		After half a minute more of a meaningless struggle, the innkeeper falls unconscious. 
		*set path 1
		*goto win
	*else
		The pain forces you to let go. The innkeeper steps back, struggling to breathe, and you use this opportunity to get back on your feet.
		*set path 11
		*gosub_scene subroutines reduce_health_return 1 "fight_innkeeper"
		*goto start_fight
*else
	When the innkeeper dives in for the tackle, you weave your arms around his neck and your legs behind his back — but you are too slow. You don't manage to put him into a choke, before he tackles you to the ground. 
	*label tackled

	You are under him now, in a disadvantageous position. The man disregards any notion of skill: he just makes the biggest swings and hammers you with the heaviest punches. 
	*gosub_scene subroutines reduce_health_return 2 "fight_innkeeper"
	*label tackle_escape

	What are you going to do?
	*if precognition_enabled
		*if (not (attempted_wrestle))
			*set fight_option_1 "Wresle him off. @{(tooltip) [b][STR][/b] |} @{(mc_str >= 3) ✅ |❌}"
		*if (not (attempted_armbar))
			*set fight_option_2 "Armbar. @{(tooltip) [b][STR/AGI][/b] |} @{((mc_agi >= 3) and (mc_str >=30)) ✅ |❌}"
		*if (not (attempted_trade))
			*set fight_option_3 "Trade blows. @{(tooltip) [b][CON][/b] |} @{(mc_con >= 5) ✅ |❌}"
		*if (not (attempted_tiring))
			*set fight_option_4 "Tire him out. @{(tooltip) [b][END][/b] |} @{(mc_end >= 3) ✅ |❌}"
	*else
		*if (not (attempted_wrestle))
			*set fight_option_1 "Wresle him off. @{(tooltip) [b][STR][/b] |}"
		*if (not (attempted_armbar))
			*set fight_option_2 "Armbar. @{(tooltip) [b][STR/AGI][/b] |}"
		*if (not (attempted_trade))
			*set fight_option_3 "Trade blows. @{(tooltip) [b][CON][/b] |}"
		*if (not (attempted_tiring))
			*set fight_option_4 "Tire him out. @{(tooltip) [b][END][/b] |}"
	*set precognition_enabled false

	*gosub_scene cslib_menu build_array_filter "fight_option" "" false "conditions" "fight_option_check"
	*gosub_scene subroutines clear_fight_options
	*if cslib_ret = 10
		You close your eyes, your mind constructing infinite variations of the near future…
		*gosub_scene subroutines add_exhaustion 50 "fight_tourney_2"
		*set precognition_enabled "true"
		*page_break Continue
		*goto tackle_escape
	*set fight_string "3_${cslib_ret}"
	*goto {fight_string}


*label 3_1
*gosub_scene subroutines stat_check "str" 4
*if (stat_check)

	Since he does not use technique, you won't either. With sheer brutal strength, you shove him to the side. 

	You use this opportunity to get back on your feet. 
	*set path 70
	*goto start_fight

*else
	*label failed_tackle_escape
	The Innkeeper resists your attempts of escape and continues his unrelenting assault.
	*gosub_scene subroutines reduce_health_return 3 "fight_innkeeper"
	*set attempted_wrestle true
	*set path 99
	*goto start_fight
		
*label 3_2
*gosub_scene subroutines stat_check_double "str" "agi" 4
*if (stat_check)
	Him being a dumb brute does not mean that you should be one as well. You dodge one of his punches and catch his arm with your two hands. Immediately, you move your legs, putting one on his neck and the other under his shoulder. Then, you thrust your hips — and feel his whole arm tense.

	"Yield." — you say, but the innkeeper doesn't listen. He tries to hit you with his left hand, tries to free his right one and all for naught — "Fucking yield!"

	The man is too far gone, too engulfed by fury to surrender. So you [i]force[/i] him to. 

	His arm breaks. Twists into unnatural angle, splits into two at the elbow. 

	You've never heard a man shriek so loud before. The innkeeper falls to the side, clutching his limp arm and yelling in agony. 
	*set path 12
	*goto win
*else
	*set path 99
	*set attempted_armbar true
	*goto failed_tackle_escape

*label 3_3
So what if you are on the ground? He punches you — you punch him back. A dangerous, self-harming strategy, but you will never yield to a commoner. 
*gosub_scene subroutines stat_check "str" 4
*if (stat_check)
	*gosub_scene subroutines reduce_health_return 4 "fight_innkeeper"
	Strike after strike, blow after blow, you break his face and he breaks yours. 

	But his breaks faster. 

	You shove the limp, covered in crimson figure to the side. You try and move your jaw — just to check if it still works , sneeze out the blood stuck in your nose and rub it off your eyes. 
	*set path 13
	*goto win
*else
	Strike after strike, blow after blow, you break his face and he breaks yours.
	*set attempted_trade true
	*gosub_scene subroutines reduce_health_return 5 "fight_innkeeper"
	Yet, soon you realize, that his ability to suck in damage just as good, if not better, then yours. You need to change your strategy, before he beats you unconscious. 
	*set path 99
	*goto start_fight

*label 3_4
*set attempted_trade true
He's a mountain of muscle — but muscles consume air like hungry peasants invited to a feast. You embrace him close, your grasp limiting his range of actions.
*gosub_scene subroutines stat_check "str" 4
*if (stat_check)
	Just as you expected, there is nothing he can do in this position. Soon, he grows tired and with tiredness comes weakness.

	You successfully shove him off you and get back up on your feet.
	*set path 70
	*goto start_fight
*else
	*set attempted_tiring true
	*goto failed_tackle_escape

*label 2_2
*gosub_scene subroutines stat_check "agi" 7
*if (stat_check)
	Just as he dives for a tackle, you jump. Your left knee connects cleanly with his face and nothing else is needed.

	The innkeeper falls to the ground, out cold. 
	*set path 14
	*goto win
*else
	You either miscalculated the distance or overestimated your abilities. Instead of knocking the innkeeper out, you help him tackle yourself by jumping up and losing the steady ground.
	*goto tackled

*label 2_3
*gosub_scene subroutines stat_check "agi" 5
*if (stat_check)
	Just as he dives for a tackle, you jump to the side. The innkeeper, unable to stop, crashes into the counter with a loud thud. 

	He punches the ground and stands up. 
	*set path 11
	*goto start_fight
*else
	You either miscalculated the distance or overestimated your abilities, but you don't jump away in time, letting the Innkeeper tackle you.
	*goto tackled

*label round_3
*stat_chart
	percent round(((mc_health/mc_health_total)*100)) Health
This fight is turning out to be more difficult than you originally planned. 

Glancing at the innkeeper, he appears fine and unhurt. Is this battle worth the trouble?

*choice 
	#Propose a draw. @{(tooltip) [b][CHR][/b] |}
		"Friend." — you say, raising your hands in the air — "This was a misunderstanding. How about we call it a day and go our separate ways?"
		*gosub_scene subroutines stat_check "chr" 6
		*if (stat_check)
			Your words manage to reach him. He nods and sighs, his imposing figure deflating in exhaustion. 
			
			"Leave then." — he answers and turns away, already thinking about the money needed to fix the damage to his inn. 
			
			You gather your companions and exit the building.
			
			*set mc_skill_persuasion +1
			
			*if (precognition_enabled)
				*set precognition_enabled false
				*page_break Turn Back Time
				*goto round_3
			*else
				
				*gosub_scene subroutines give_exp 10 ""
				*page_break Choose Another Inn
				*set interscene_temp "inn"
				*goto_scene tournament_1 after_cheapinn
		*else
			Your words contain reason, yet reason cannot reach through his thick shield of rage and adrenaline. He advances forward, fists drawn, and he's not the only one.
			*label uncle_intervention
			
			You hear chairs move and creak on the wooden floor. Five more men — the ones who before eyed you with burning glares — stand up and get ready to join the fight.
			
			Gulping, you are not sure what to do. You had trouble one-on-one, fighting six of them would be a suicide. 
			
			"Enough of this nonsense." — Uncle Tao suddenly speaks out. 
			
			He takes a single step and all you see are afterimages. A hundreds, a thousand of them fill the room as his speed ascends far beyond your capability to follow. 
			
			You blink and his shadows disappear. Uncle Tao stands in place, as if the previous scene was but a product of your imagination. 
			
			Feeling a wetness on your clothes, you glance down and notice the fresh blood staining your robe. 
			
			[i]Huh? Where did it come from?[/i]
			
			You look up and immediately understand. All six men are dead, their heads — exploded in a shower of teeth, brain and flesh. Their not-so-intact corpses still upright, perhaps themselves not realizing that their lives have ended. 
			
			"Umh… You-${YM}… You can't just kill people in this city…"  — the guard's captain mumbles.
			
			You sigh. You can't exactly force Uncle Tao to pay, can you?
			
			"How much per commoner?"
			
			"500 gold."
			
			"I trust that you will relay my deepest condolences for their fate to the Mayor." — You materialize a gold pouch and give it to the captain. He nods in response.
			
			[b]Gold -3000[/b]
			
			*set mc_gold -3000
			
			"Let's go." — Uncle Tao commands, and you have no choice but to obey — "Don't cause anymore trouble."
			*page_break Choose Another Inn
			*set interscene_temp "inn"
			*goto_scene tournament_1 after_cheapinn
	#Fight to the end.
		Since you have started this fight, you may as well finish it. You raise your guard, ready and concentrated, but soon you realize that the innkeeper is not alone.
		*goto uncle_intervention
			
			
*label win
*page_break End of The Fight
*set mc_trait_6_cost 35
*gosub_scene subroutines give_exp 20 ""
*if (eligible_achievements)
	*achieve victory_innkeeper
*if path = 1
	You shove the innkeeper off to the side and catch your breath. Although you made it look easy, this mortal was a tough nut to crack.
	
	Glancing at his unconscious body, you are conflicted on what you should do next. 
	*label decision
	*choice
		#Let him be.
			*gosub_scene subroutines change_personality 2 "violent" "-"
			There is no reason to cross the line. Your battle wasn't one of life and death and this man is not your enemy.
			
			"Let's go." — you say to your companions —  "We are going to another inn."
			
			[b]🡹 +20 FREE EXP 🡹[/b]	
			*page_break Choose Another Inn
			*set interscene_temp "inn"
			*goto_scene tournament_1 after_cheapinn
		
		#Let him be and throw him some gold for the medicine.
			*gosub_scene subroutines change_personality 2 "violent" "-"
			*gosub_scene subroutines change_personality 2 "egoistical" "-"
			There is no reason to cross the line. Your battle wasn't one of life and death and this man is not your enemy. In fact, you feel that you owe this man a bit — you were the one that started the brawl, after all.
			
			"Let's go." — you say and throw some gold next to the innkeeper's body — "We are going to another inn."
			
			[b][Gold -200] [/b]
			
			*set mc_gold -200
			
			*gosub_scene subroutines reputation_change 5 "kindness" "+"
			*page_break Choose Another Inn
			*set interscene_temp "inn"
			*goto_scene tournament_1 after_cheapinn
		#Kill him.
			*gosub_scene subroutines change_personality 2 "violent" "+"
			This worm dared to turn you away. Such mortals need to be made example of.
			
			You twist his neck. Then, you summon a napkin from your ring and wipe his filth off your hands.
			
			"Umh… You-${YM}… You can't just kill people in this city…"  — the guard's captain mumbles.
			
			You sigh.
			
			"How much per commoner?"
			
			"500 gold."
			
			"I trust that you will relay my deepest condolences for his fate to the Mayor." — You materialize a gold pouch and give it to the captain. He nods in response.
			
			[b]Gold -500[/b]
			

			"Let's get out of here" — you say to your companions.

			*gosub_scene subroutines reputation_change 10 "kindness" "-"
			*page_break Choose Another Inn
			*set interscene_temp "inn"
			*goto_scene tournament_1 after_cheapinn

*if path = 12
	*gosub_scene subroutines change_personality 1 "violent" "+"
	You glance at the wailing innkeeper, who is clearly not in the state to fight any longer. 
	
	What should you do next?
	*goto decision
*if path = 13
	You glance at the unconscious innkeeper. Most of the bones in his face are broken — he will never be able to neither speak nor breath normally ever again.
	
	What should you do next?
	*goto decision
*if path = 14
	You glance at the unconscious innkeeper, who is clearly not in the state to fight any longer. Although you made it look easy, this mortal was a tough nut to crack.
	
	You are conflicted on what to do next.
	*goto decision
*if path = 3
	*gosub_scene subroutines change_personality 2 "violent" "+"
	You stare at the corpse. This man had a story. A life. He's seen a lot and experienced much, yet now, he's dead. 

	Because you didn't want to go to another inn. Which you still have to do, by the way: staying in the place whose owner you just killed doesn't seem like a good idea.

	"Let's go." — you say to your companions.
	
	*page_break Choose Another Inn
	*set interscene_temp "inn"
	*goto_scene tournament_1 after_cheapinn


*label defeat
*page_break End of The Fight
*set mc_trait_6_cost 35
You've overstimated yourself and your abilities. Perhaps you didn't train enough, perhaps you got unlucky — but the fact is, you lost to a random mortal. If any of the nobles knew, wouldn't they die of laughter?

*if mc_health = 0
	You are unable to withstand all the damage you took. You feel your vision darken and your consciousness slip away…
*else
	You are unable to continue moving. Your limbs don't listen and your breath is impossible to catch. You need to lie down, just for a minute…
*page_break Wake Up
"Do not start fights that you can't finish." — you hear Uncle Tao's voice. It pulls you out from the oblivion and it burns you in shame.

A hand bursts from the innkeeper's chest. It holds his heart in its grasp. The hand squeezes and the heart explodes.

The innkeeper covers you in blood as he falls limp on top of you. You shove the body aside and get up.

"Umh… You-${YM}… You can't just kill people in this city…"  — the guard's captain mumbles.

You sigh. You can't exactly force Uncle Tao to pay, can't you?

"How much per commoner?"

"500 gold."

"I trust that you will relay my deepest condolences for their fate to the Mayor." — You materialize a gold pouch and give it to the captain. He nods in response.

[b]Gold -500[/b]
			

"Let's go." — Uncle Tao says — "Don't cause anymore problems."
*set lock_exp_spending true
*page_break Choose Another Inn
*set interscene_temp "inn"
*goto_scene tournament_1 after_cheapinn