*set fight_scene "fight_arena_yunge"
*set fight_difficulty 0
*temp sexname ""
*set fight_sect_arena "none"
*gosub_scene subroutines set_enemy_stats 19 16 18 16 12 "early" "Nine Shooting Fists"
*temp v 0
The tribunes of the arena have some people on them, watching the ongoing battles, but the stadium is far from full. And even of those who who's currently present, only a tiny portion focuses their attention on your match — you are unknown in the arena, after all. 

*if mc_level >= 1
	Your enhanced, Houtian-level hearing picks up some of the chatter.
	
	*gosub_scene cslib_string find battle_history "sectarena_lost_yunge"
	*if cslib_ret = 0
		[i]"Who's that?"
		
		[i]"No idea. I watch unranked battles all the time but I've never seen ${pronoun_2} before."
		
		[i]"$!{pronoun_1} must've fought before if ${pronoun_1} now fights Yun Ge. That guy is in the official ranking." 
		
		[i]"Strange. Let's watch and see what ${pronoun_1} can do."
	*else
		*set sexname "guy"
		*if mc_sex = 1
			*set sexname "girl"
		[i]		"Oh? Isn't that the ${sexname} that already lost to Yun Ge before?"
		
		[i]"Seems like it. You think ${pronoun_1} improved and wants to try again?"
		
		[i]"No idea. Let's watch." 

Yun Ge is short for an average man, but much stockier than a normal one.  He has thick arms and thighs, with wide shoulders and wide hips and his whole frame contains muscles hidden underneath his green robe. 

He looks at you with contempt.

*set fight_difficulty 0
*gosub_scene cslib_string find battle_history "sectarena_lost_yunge"
*if cslib_ret = 0
	*if date <= 30
		"You've barely been a month in the sect, if even that, yet they picked me as your opponent?" — Yun Ge scowls — "What disrespect! Do they think I, Yun Ge, am some pushover?" 
		*label yunge_speech_choice
		*choice
			#"All this time in the sect and still stuck at Early-Houtian. Pathetic."
				*gosub_scene subroutines change_personality 2 "arrogant" "+"
				"Good. Very good." — he clenches his fist, the vein on his neck almost throbbing — "I'll be the one to teach you some humility."
				
				[b]You've angered Yun Ge. This fight will be harder.[/b]
				*set fight_difficulty 1
			#"I hope Senior Brother can give this junior a couple pointers."
				*gosub_scene subroutines change_personality 1 "manipulative" "+"
				Yun Ge gives you a look and you see his anger dissipate. He knows full well that he's not the most talented disciple — but everyone has their pride and fighting an opponent without any sort of battle history in the arena has injured his. 
				
				Your words soothe the wound as he nods.
				
				*set sexname "lad"
				*if mc_sex = 1
					*set sexname "lass"
				"Alright. You seem like a good ${sexname}. Watch carefully." 
				
				[b]You've managed to leave a good impression on Yun Ge. This fight will be easier.[/b]
				*set fight_difficulty -1
				
			#"Fighting is the business of the young. Have you considered retiring, old man?"
				*gosub_scene subroutines change_personality 1 "manipulative" "-"
				Yun Ge chuckles.
				
				"I hope your skills are as sharp as your tongue, kid. Let me give you a proper welcome to the Arena." 
			#Stay silent.
				Yun Ge chuckles.
				
				"So that's how it is. Fine, keep you silence."
	*else
		"They pick me as a first opponent for someone who hasn't fought unranked even once? — Yun Ge scowls — "What disrespect! Do they think I, Yun Ge, am some pushover?"
		*goto yunge_speech_choice
*else
	"You again. Wasn't the last time enough? Must you persist on wasting my time?" — Yun Ge sighs — "Fine. Let's get it over with."

*label first_round_yunge
Despite his intimidating build and intense demeanor, Yun Ge doesn't attack first. He raises his arms, covering his pressed against his neck head, and waits for you to take the initiative. 
*choice
	#Punch through his block.
		*gosub_scene subroutines f_stat_check_crit "str" "con" 2 0
		*if (crit_stat_check)
			Strength may be Yun Ge's forte, but who cares about his specializations when you are that much stronger?
			
			Your fist collides with his forearm: it [i]smashes[/i] the arm to the side, clearing up the way ahead. The blow doesn't just knock Yun Ge down, it sends him tumbling and rolling over on the ground. 
			
			*set enemy_health 80
			
			After a moment, Yun Ge stands up, spits out a mouthful of blood and eyes you with vigilance. It's obvious that he hasn't expected you, a rookie both to the Arena and the Sect, a junior ten years younger to be this strong.
			
			"If you think that this is enough to take my place, you're wrong!"
		*elseif (stat_check)
			Strength may be Yun Ge's forte, but you gladly take on the challenge. 
			
			Your fist collides with his forearm and forces a groan out of Yun Ge. He steps back from you, shaking his now aching arm. He gives you a vigilant look. 
			
			*set enemy_health 90
			
			"You are strong — but strength isn't everything." 
		*else
			Yun Ge is someone who specializes in brute strength — if that wasn't obvious from his bulging muscles — so, perhaps, contesting him in his forte was not the best idea.
			
			Your fist collides with his forearm and fails to do anything to his block. Instead, waiting 
			*label failed_first_attack
			precisely for this moment, Yun Ge counter-attacks with a pre-prepared upper-cut. 
			
			*gosub_scene subroutines f_stat_check "con" "str" 0
			*if (stat_check)
				It strikes you jaw, but you manage to remain standing, your bones too hardy to be rattled. 

				"A punching bag then?" — Yun Ge chuckles — "Let's see how many hits you can take."
			*else
				His attack lifts you off your feet with its sheer force, before you fall back down.
				*gosub_scene subroutines reduce_health 5
				*if mc_health <= 0
					You do not get up, your vision fades instead…
					*goto defeat			
	#Kick at his leg to make him lose balance.
		*gosub_scene subroutines f_stat_check_crit "agi" "" 2 0
		*if (crit_stat_check)
			You make the smartest choice as instead of entering a contest of strength, something in which Yun Ge specializes, you target his lower body instead.
			
			Your kick collides with his calf and Yun Ge's leg twists in an unnatural, painful-looking angle. He groans and jumps back as far from you and your kicks as possible. He inspects his leg, wiggles it and his face contorts when he does so. 
			
			*set enemy_health 80
			*set enemy_legbroken 10
			
			"Goddamn it…" — Yun Ge murmurs, before he shakes his head and focuses back on you. He does his best to appear as confident and as battle-ready as before, but you easily notice that his walk now has a limp to it — 		"If you think that this is enough to take my place, you're wrong!"
			
			[b]You've damaged Yun Ge's leg. It will be easier to hit him and dodge his attacks.[/b]
		*elseif (stat_check)
			You make the smartest choice as instead of entering a contest of strength, something in which Yun Ge specializes, you target his lower body instead.
			
			Your kick collides with his calf and Yun Ge groans in response. He's staggered, not enough for you to capitalize on, but enough to let him know that this fight isn't going to be as easy as he thought. 
			
			*set enemy_health 90
			
			"Come here!"
		*else
			Your kick collides with his calf, but fails to do any damage. Thankfully, you are too far away from him for Yun Ge counter-attack.
			
			He snorts.
			
			"Come here!"
	#Palm Strike at the chest.
		*gosub_scene subroutines f_stat_check_crit "str" "con" 2 0
		*if (crit_stat_check)
			Your palm lands right at his chest, avoiding his guard by an inch or two. The force contained within it folds his body into two as he's thrown backwards, tumbling and rolling over in the air. He falls back down, scraping his arms as he tries to regain his composure.
			
			*set enemy_health 80
			
			After a moment, Yun Ge stands up, spits out a mouthful of blood and eyes you with vigilance. It's obvious that he hasn't expected you, a rookie both to the Arena and the Sect, a junior ten years younger to be this strong.
			
			"If you think that this is enough to take my place, you're wrong!"
		*elseif (stat_check)
			Your palm lands right at his chest, avoiding his guard by an inch or two. The force contained within it forces him to take a step back and uncontrollably groan. Although he soon shakes the damage off, it's enough to make him realize: this fight isn't going to be as easy as he thought.
		*else
			Your palm lands right at his chest, avoiding his guard by an inch or two… and fails to do anything to his sturdy torso. He soaks the hit without a problem and then, as if waiting
			*goto failed_first_attack
	#[i]Skills.[/i]
		*gosub_scene skill_menu skill_menu
		*goto first_round_yunge
				

*gosub_scene subroutines f_p_b
*if enemy_health = 100
	*label first_attack
	Yun Ge doesn't consider you to be worthy of using a Skill: fully confident in himself, the man throws a simple punch at you. Then again, backed by his close to the limit Early Houtian-level, even a such a casual attack would seem overwhelming to a Mortal. 

	The fist flies at you, cutting through the air with a swish.
	
	*choice
		#Block it. 
			You raise your arms and let your forearms bear the incoming attack for you.
			*gosub_scene subroutines f_stat_check "str" "str" 1
			*if (stat_check)
				Your arms withstand his punch and you reply with one of your own, clipping him on the chin.
				*set enemy_health 5
			*else
				Yun Ge smashes through your defense, knocking you down. 
				*label failed_first_defense
				As your face plants into the floor of sand, you curl up to better protect yourself — but it doesn't help as Yun Ge kicks you with ruthless abandon. 
				
				Kick after kick, your body soon grows limp and your vision — dark…
				*goto defeat
		#Dodge it.
			*gosub_scene subroutines f_stat_check "agi" "" 1
			*if (stat_check)
				You side-step his punch and reply with one of your own, clipping him on the chin.
			*else
				Yun Ge catches you before you manage to evade, knocking you down.
				*goto failed_first_defense
		#Let it hit you.
			You tense up your body, preparing to take on the attack with your sturdiness alone.
			*gosub_scene subroutines f_stat_check "con" "str" 1
			*if (stat_check)
				You succeed as, although his fist hits you, it doesn't even phase you. Capitalizing on Yun Ge's bewilderment, you reply with a punch of your own, clipping him on the chin.
				*set enemy_health 5
			*else
				Yun Ge's punch knocks you down, your chin is not quite tough enough to withstand it.
				*goto failed_first_defense
		#[i]Skills.[/i]
			*gosub_scene skill_menu skill_menu
			*goto first_attack
*page_break
Yun Ge's whole body glows with a blue light as he suddenly accelerates: he moves in a zig-zag, jumping from left to right, from right to left. 
*if enemy_legbroken > 0
	Although you don't know how fast this skill is supposed to be exactly, you realize that he's much slower due to his injured leg than he would've been otherwise.
	*set fight_req 10
*else
	*set fight_req 15
He's intending to confuse you, to not let you know from which side his next attack is going to come from.
	
*gosub_scene subroutines stat_check "per" fight_req
*if (stat_check)
	It doesn't work, however, as your eyes can still track him with ease.
*else
	It works as he becomes but a blur in your eyes.
	*set fight_difficulty +1
	
*label second_attack

His first blow is a heavy, loaded with power hook to the side of your face.
*choice
	#Try to block it.
		*gosub_scene subroutines f_stat_check_double "str" "con" "str" 2
		*if (stat_check)
			Despite you not using a skill, Yun Ge fails to overcome your defenses. When his next attacks land — a jab and another hook — they also stopped in their tracks by your unsurpassable guard. 
		*else
			Yun Ge smashes through your defense, his attack rattling you. You don't even get to react before a jab hits you right in the nose and another hook knocks you down.

			*gosub_scene subroutines reduce_health 6

			You shake it off and quickly get up, not willing to cease initiative towards Yun Ge.
	*selectable_if (mc_defensive_1_mastery >= 1)		#[i]Celestial Shell.[/i]
			*gosub_scene subroutines skill_exhaustion mc_defensive_1_cost fight_scene "defensive_1"
			*if (skill_shouting)
				"[b]Celestial Shell![/b]"
				
			Golden light encapsulates your whole body, forming a shell that protects you from all outside harm. 

			When Yun Ge's hook lands, it's as if he hits a wall of steel. His knuckles are immediately blooded and he has to cycle through his fingers one by one to make sure they still work. He doesn't even attempt to attack further.

			"What kind of Skill is this?!"

			You smirk and, after the barrier collapses, go on the offensive.
	*selectable_if (mc_defensive_2_mastery >= 1) #[i]Void Step.[/i]
			*comment				*if mc_defensive_2_mastery = "initial"
			*gosub_scene subroutines skill_exhaustion mc_defensive_2_cost fight_scene "defensive_2"
			*if (skill_shouting)
				"[b]Void Step![/b]"
				
			Just as his hook is about to land, you take a tiny step to the side: you [i]merge[/i] with the Void, your surroundings fading into nothingness. Replaced by the endless black. When you surface to the outside world again, you find yourself a good dozen feet away from the flabbergasted Yun Ge.

			"What kind of Skill is this?!"

			You smirk and go on the offensive.

*set fight_req 0
*if enemy_legbroken > 0
	*set fight_req -20

*label skill_attacks
*choice
	#Running Spin Kick.
		You run, gaining speed, before jumping up into the air. You spin two times around yourself, before releasing a kick towards Yun Ge.
		*gosub_scene subroutines f_stat_check "agi" "" 2
		*if (stat_check)
			Yun Ge stands frozen, unable to process your attack, and you hit him with ease… only for your kick to go through the empty air as Yun Ge splits into three identical figures. 
			
			*label find_real_yunge
			Confused, you focus on him, attempting to discern the real from the fake.
			
			*gosub_scene subroutines stat_check "per" 15
			*if (stat_check)
				You succeed, finding a minor detail — mostly caused by his incomplete understanding of the skill — that differentiates the original from his copies. Sadly, your momentum is already gone.
			*else
				You fail, your senses regarding all three as the original ones. 
				*set fight_difficulty +1
				
				[b]You cannot differentiate the original Yun Ge from his copies. The fight has become much harder.[/b]
				
			Yun Ge is the one who smirks now as he attacks you with new found vigor.
		*else
			Yun Ge easily evades your kick and retaliates with a hard punch into your gut. 
			
			*gosub_scene subroutines f_stat_check "con" "str" 2
			*if (stat_check)
				The firm muscles of your abdomen contain the damage. 
				
				Yun Ge rolls his eyes. 
				
				"Let's see if you can withstand this!"
				
				His body splits into three identical figures.
				*goto find_real_yunge
			*else
				You grunt as the fist forces you to bow down.
				*gosub_scene subroutines reduce_health 6
				*if mc_health < 0
					The pain soon overwhelms you and your vision goes black…
					*goto defeat
			
	*selectable_if (mc_offensive_1_mastery >= 1)		#[i]Heaven Crushing Palm.[/i]
			*gosub_scene subroutines skill_exhaustion mc_offensive_1_cost fight_scene "offensive_1"
			*if (skill_shouting)
				"[b]Heaven Crushing Palm![/b]"
				
			Your palm glows golden, the color of Heavens. It radiates an aura, a presence that makes  Yun Ge's eyes widen, his body tremble as he mumbles in an obvious display of panic.
			
			"Heaven… Heaven Crushing Palm…." 
			
			You push him down. 			Yun Ge squeals as the palm presses him down into the sand: that squeal soon turns into an agonized scream as the palm crushes his bones under its enormous weight. 
			
			When the Skill runs its due, the palm vanishes and you let go of him,
			*label skill_runs_out
			Yun Ge is revealed in an terribly injured state. His previously squeaky-clean, spotlessly white robe are drenched in crimson, his face bloodied and his face contorted in pain. He struggles to stand.
			
			"You… spoiled fucking bastard…" — he says, gasping and holding onto his rib as he speaks. He understands easily that for you to obtain such a skill, there was only one way: through your clan. An opportunity that he was never given.
			
			The envy courses through his veins, setting his willpower ablaze and numbing his injuries. He suddenly splits into three identical figures.
			
			*goto find_real_yunge
	*selectable_if (mc_offensive_2_mastery >= 1) 		#[i]Sixty-Four Earth Shaking Fists.[/i]
			*gosub_scene subroutines skill_exhaustion mc_offensive_2_cost fight_scene "offensive_2"
			*if (skill_shouting)
				"[b]Sixty-Four Earth Shaking Fists![/b]"
				
			You run up to him with your fists glowing red and punch him. Then you punch him again. And again. [i]Twelve[/i] again. Your hands move at an impossible for you speed as you rain punches everywhere on his body. If, at first, Yun Ge has tried to defend himself and even dodge, about half a dozen punches later he recognized the futility of such attempts: now he just hopes he would survive, cuddled on the ground, as your fists turn his flesh into mashed potatoes and his bones — into powder. 
			
			When the skill ends, he somehow finds the strength to push you off. You back away and take a good look at him:
			*goto skill_runs_out
			
	*selectable_if (mc_offensive_3_mastery >= 1) #[i]Extreme Demon Finger.[/i]
			*gosub_scene subroutines skill_exhaustion mc_offensive_3_cost fight_scene "offensive_3"
			*gosub_scene subroutines reputation_change 2 "kindness" "-"
			*if (skill_shouting)
				"[b]Extreme Demon Finger![/b]"
				
			Your finger glows red as you slash it towards Yun Ge's gut. For a brief second, he's bewildered at what is it you are trying to accomplish: he might not be the strongest Martial Artist, but he's body is still tempered way beyond the mortal means. 
			
			That bewilderment is soon to turn into unadulterated terror as your finger [i]pierces[/i] into his stomach. You cut his flesh in a diagonal line, lacerating his abdomen with a horrible wound until you are forced to pull out due to the skill duration running its course.
			
			You step back and watch as the blood streams down, unclogging and unstopping in its pour. Yun Ge desperately latches onto it, keeping the tissue together with his hands, but such an attempt can barely be effective.
			
			"You… spoiled fucking bastard…"— he says, gasping as he speaks. He understands easily that for you to obtain such a skill, there was only one way: through your clan. An opportunity that he was never given.
			
			The envy courses through his veins, setting his willpower ablaze and numbing his injuries. He suddenly splits into three identical figures.
			
			*goto find_real_yunge
	*selectable_if (mc_offensive_4_mastery >= 1) #[i]Flesh Scorching Kicks.[/i]
			*gosub_scene subroutines skill_exhaustion mc_offensive_4_cost fight_scene "offensive_4"
			*if (skill_shouting)
				"[b]Flesh Scorching Kicks![/b]"
				
			Your leg glow with a auburn light as you kick towards Yun Ge. He blocks the first one only to immediately scream out in pain. The skin on his forearms is burnt away, the before healthy flesh now ruby-red, almost [i]boiling[/i]. You do not stop, do not give him an opportunity to gather his bearings and two more kicks: one at his side, which incinerates that part of his robe and leaves a nasty burn on his rib, and the other one straight at his face. It knocks him down and Yun Ge gets up, his left cheek is not far from the color of charcoal. 
			
			"You… spoiled fucking bastard…" — he says, gasping and holding onto his cheek as he speaks. He understands easily that for you to obtain such a skill, there was only one way: through your clan. An opportunity that he was never given.
			
			The envy courses through his veins, setting his willpower ablaze and numbing his injuries. He suddenly splits into three identical figures.
	#[i]Skills.[/i]
		*gosub_scene skill_menu skill_menu
		*goto skill_attacks

*set skill_used false

"[b]BONE-BREAKING PUNCH![/b]" — he shouts as he lunges, aiming at your chest.

*choice
	#Catch his hand.
		*gosub_scene subroutines f_stat_check "str" "" 3
		*if (stat_check)
			As his Skill-infused, Inner-Energy enhanced fist arrives close, you nonchalantly lift your hand and stop it before the punch connects.

			You tilt your head, questioningly. 

			"Was this supposed to be your hidden card?" — you ask him in a mocking tone.
			
			He doesn't respond. Just stares in a dumbfounded fashion at his fist. It's at this moment the difference between you becomes clear to him: someone who can halt a skill with such minimal effort is certainly not an opponent an Early-Houtian like him can face.
			
			You [i]lift[/i] him by his arm and throw him to the side, his weight but a formality for someone as physically strong as you. 
			
			When he gets up — and he does, because no one who's reached Top-10,000 across the Sect is weak — he's fully consumed by madness. By the desire not to win, but to [i]not lose[/i].
			
			"I REFUSE! REFUSE! REFUSE!"
		*else
			This is at least Middle-Grade Skill, thrown by a guy who's strong enough to enter the Rankings of the entire Sect. Hoping to simply [i]catch[/i] it is a fool's dream, to put it nicely.
			
			Yun Ge's fist bends your palm to an extent it isn't supposed to bend: the bones in your hand fracturing into pieces, just as the name of the skill has promised.
			*gosub_scene subroutines add_injury 8
			
			Your painful scream is interrupted by 			a wrecking strike that sends you flying across the Arena.
			*gosub_scene subroutines add_injury 7
			*label bone_breaking_hits
			Your mouth soon fills with sand as you try to breathe while lying on the ground filled with yellow grains. 
			
			*gosub_scene subroutines reduce_health_return 8 fight_scene
			
			You spit it out, alongside the blood that rushes from the insides of your chest and return back to your feet.
			
			"Still not done?" — Yun Ge asks and you notice that he pants, utilization of the Skill taking its toll on him — "Then let me finish this!" 
			
	#Lean backwards.
		*gosub_scene subroutines f_stat_check "agi" "" 2
		*if (stat_check)
			Your body tilts backwards, your upper part almost touching the ground as it bends in a straight, relative to your upright legs, angle. The punch goes wide, the gust of air it produces is the only thing that hits you.
			
			When you rise, you use your palm to attack his chin from downwards, sending him flying across the Arena. He stands up — of course he does, because no one who's reached Top-10,000 across the Sect is weak — he's fully consumed by madness. By the desire not to win, but to [i]not lose[/i].
			
			"I REFUSE! REFUSE! REFUSE!"
		*else
			You are not fast enough to dodge his fist: 			a wrecking strike sends you flying across the Arena. 
			*goto bone_breaking_hits
	#Let it hit you.
		*gosub_scene subroutines f_stat_check_crit "con" "str" 3 2
		*if (crit_stat_check)
			The punch hits you, yet he's the one who's hurt. His fist bends in an angle it isn't supposed to bend, your tougher than metal flesh fracturing his hand in multiple places. He screams in anguish and holds on to his broken wrist, incapable of defending against your punch that staggers him to the ground.
			
			*label bone_breaking_nothit
			
			He stands up — of course he does, because no one who's reached Top-10,000 across the Sect is weak — he's fully consumed by madness. By the desire not to win, but to [i]not lose[/i].
			
			"I REFUSE! REFUSE! REFUSE!"
		*elseif (stat_check)
			The punch hits you and fails to even force a single step out of you. Your flesh is as tough as metal and even a Middle-Grade Skill specifically designed to break bones is incapable of overrunning your defense.
			
			You punch him in return, staggering him to the ground.
			*goto bone_breaking_nothit
		*else
			You might have miscalculated. This is a MIddle-Grade Skill specifically designed to break bones: what on Earth possessed you to think that taking on it with your body alone is a good idea?
			
			*gosub_scene subroutines add_injury 7
			A wrecking strike sends you flying across the Arena, one of your ribs refusing to remain whole underneath such force.
			*goto bone_breaking_hits

"[b]NINE SHOOTING FISTS[/b]"

Yun Ge roots himself in place, punching the empty space in front of him. For every blow, a large transparent fist materializes into existence —  and then soars towards you, roaring with force of the leaking Inner Energy.

One comes at your gut, the other at your face, the third — underneath your chin.

*choice
	#Try to evade them.
		*gosub_scene subroutines f_stat_check "agi" "agi" 3 2
		*if (stat_check)
			You evade the first punch, tilt your body out of the second's way and roll forwards to avoid the third. However, as you look up from your prone position, you see three more fists flying towards you, even faster than their predecessors.
			
			You quickly get back on your feet and [i]flip over[/i] the first punch. Then, you lean your torso back at an impossible angle, your back touching the floor full of sand, to evade the second and jump above the third. 
		
			You don't dare to entertain the idea that this over, however: you remember Yun Ge yelling about nine punches and when you turn to him, you realize he wasn't lying. Three more fists rush at you, these ones glowing dangerously red.
			
			Somehow, in an unprecedented feat of agility, you manage to weave your way in-between them and reach the now exhausted Yun Ge.
			*goto victory
		*else
			You try to evade the punches, but are not fast enough to avoid them.
			
			The first fist catches you in the stomach, bending you in half. The second strikes you at the cheek and, before you can even process the hit, the third one comes from underneath your jaw, lifting you up in the air with its power before you topple down
			
			You don't even get an opportunity to react as another series of fists you. You curl up, doing your best to protect yourself, but the punches rain down with a horrific force.
			
			*gosub_scene subroutines reduce_health 10
			*if mc_health <= 0
				Your vision goes black, your mind losing consciousness.
				*goto defeat
			*else
				Even an attack from what looks like a High-Grade Skill is not enough to keep you down. You stand up and reach the now exhausted Yun Ge.
				*goto victory
	*selectable_if (mc_footwork_1_mastery >= 1)		#[i]Gale Stream.[/i]
			*if (skill_shouting)
				"[b]Gale Stream![/b]"
	
			You can [i]feel[/i] the wind around you. You breathe it in, gaining its power and support. 
			
			You become lighter. As light as the air itself. When the fists come near, you simply move out of the way: there is no pressure, no tension as you evade the fists. The remaining six punches can't even touch the helm of your clothes as you weave in-between them.
			
			Yun Ge, exhausted and spent, watches you aghast. This was his ultimate skill — and it spectacularly fails. 
			*goto victory
	*selectable_if (mc_footwork_2_mastery >= 1)		#[i]Lightning Flicker.[/i]
			*if (skill_shouting)
				"[b]Lightning Flicker![/b]"
				
			Lightning explodes from underneath your feet: with a thunderous rumble, you cut through the air, leaving sparkling bolts in your path. 
			
			The fists can't even touch the helm of your clothes as you travel dozens of feet in an instant, weaving your way in-between the punches. All nine of them helplessly pass you by as you reach the exhausted and spent Yun Ge. He watches you aghast, his ultimate skill having spectacularly failed. 
			*goto victory


*label victory
*set mc_sect_ranking 9981
*set characters_12_opinion 50
You palm his face, put your leg behind his and trip him up. He falls, you mount him and start pummeling him on the ground. 

He can't defend himself — his strength evaporated after using that skill — and soon his limbs go limp.

"Please… No more… No more…" — Yun Ge begs, mumbling words between your attacks. 

*choice
	#Stop.
		*label let_yunge_go
		
		You decide that he has had enough — there is no need to injure him beyond the needed measure as is this just an arena match. You let out a breath and push yourself off him. You turn around to face the tribunes, finished with the fight. Yet, before you manage to take a step, you are yanked by your
		*if mc_hair_length = "bald"
			robe
		*else
			hair
		back to the ground.
		
		Yun Ge climbs on top you, his hands joined together above his head.
		
		"Fucking die!"
		
		"[b]HEART-STOPPING STRIKE![/b]"
		
		He brings them down, right at where your heart is supposed to be.
		
		*gosub_scene subroutines f_stat_check "con" "str" 3
		
		*if (stat_check)
			It harmlessly slides off your chest.
			
			"Wh-what?" — Yun Ge utters, dumbfounded.
			
			You turn him over and grasp his throat, he doesn't even bother to put up a resistance.
			*label finisher_choice
			
			*choice
				#Choke him out.
					You squeeze your palms until the light in his eyes dims and he falls asleep. He's certainly not a threat now, yet even a Houtian cannot remain long without oxygen: if you were to keep pressing a little longer, he might die…
					
					*gosub yangbohai_appears
					*choice
						#Snap his neck.
							*gosub_scene subroutines reputation_change 5 "kindness" "-"
							You disregard both his decree and your own gut: instead of listening to your sense of danger, you decide to follow through on your murderous impulse.
							
							Why? You can't say for sure. Maybe it's anger you feel at Yun Ge, maybe it's the pride and arrogance that doesn't allow you to submit: maybe it's both and maybe it's neither.
							
							Fact is, you directly go against the old man's words and snap Yun Ge's neck.
							
							*goto yangbohai_slap
						#Step back.
							*goto yes_senior
				#Let him go.
					You sigh and let him go after you notice the realization of complete defeat inside his pupils. He doesn't dare look at you, his expression filled with shame.
					
					"I'm sorry…" — he apologizes — "I just… I couldn't lose…"
					
					You just shake your head and lend him a hand.
					
					"Get up." 
					
					He takes it, but even after finding his footing he still doesn't meet your eyes. Instead, he bows and clasps his hands.
					
					"It was a good fight. Farewell, Senior ${polite_address}, I hope Heavens would favor you in the future." 
					
					*goto peaceful_ending
				#Put your fingers through his eyes.
					*gosub_scene subroutines reputation_change 10 "kindness" "-"
					This deceitful, honorless bastard deserves a good lesson: it's only your duty, as his new Senior ${polite_address}, to correct his shameful behaviour.
					
					You grin maniacally as you put you thumbs inside his eyes. 
					
					"AAGH!"
					
					You disregard his cries of misery, pushing deeper and deeper, scrambling his retina and leaving him permanently blind. 
					
					You already have achieved your goal — his cecity won't let him forget this day — but it's just so temping to press further, to break the bone guarding his brain…
					
					*gosub yangbohai_appears
					*choice
						#Push deeper.
							*gosub_scene subroutines reputation_change 5 "kindness" "-"
							You disregard both his decree and your own gut: instead of listening to your sense of danger, you decide to follow through on your murderous impulse.

							Why? You can't say for sure. Maybe it's anger you feel at Yun Ge, maybe it's the pride and arrogance that doesn't allow you to submit: maybe it's both and maybe it's neither.

							Fact is, you directly go against the old man's words and and press your fingers into Yun Ge's skull until they touch his brain.
							
							*goto yangbohai_slap
						#Step back.
							*goto yes_senior

		*else
			The strike knocks out the oxygen inside your lungs: then, you feel a stream of warm energy enter your body, guided to your heart. In a blink, the heart halts its beating, frozen by the foreign power. 
			
			*gosub_scene subroutines reduce_health 7
			*if mc_health <= 0 
				*goto defeat
			*else
				Through the sheer will, you awaken with a gasp, your heart finding its rhythm once again. Angered, you turn Yun Ge over and put your hand on his throat. 
				*goto finisher_choice
				
			
		
		
	#Continue beating him.
		*gosub_scene subroutines reputation_change 5 "kindness" "-"
		"No… I beg you… Please… Enough…"
		
		His speech becomes slurred, unrecognizable and he doesn't seem to be able to take much more of your punishment: just refuses to lose his consciousness. 
		
		*choice
			#Beat him to death.
				*gosub_scene subroutines reputation_change 5 "kindness" "-"
				You wish not to stop, continuing on hitting him instead. At some point, he already has lost his awareness and any threat he posed you: yet you couldn't care less. His face soon becomes mangled, mutilated and even your knuckles start to hurt from the prolonged beating you leash out.
				
				*gosub yangbohai_appears
				*choice
					#Disregard his words.
						*gosub_scene subroutines reputation_change 5 "kindness" "-"
						You disregard both his decree and your own gut: instead of listening to your sense of danger, you decide to follow through on your murderous impulse.

						Why? You can't say for sure. Maybe it's anger you feel at Yun Ge, maybe it's the pride and arrogance that doesn't allow you to submit: maybe it's both and maybe it's neither.

						Fact is, you directly go against the old man's words and and continue your rampage until Yun Ge is no longer present amongst the living..

						*goto yangbohai_slap
					#Step back.
						*goto yes_senior
					
			#Let him go.
				*goto let_yunge_go
		
		


*label defeat
You consciousness fades, your vision darkens…
*page_break Defeat

You are defeated. You can try and challenge him again another time.
*set fight_scene "none"
*set fight_sect_arena "none"
*goto_scene free_roam
*page_break End



*label yangbohai_appears
"[b]ENOUGH![/b]" — deafening shout causes you to cover your ears. It's not a skill, it's not a spell, merely a simple yell, yet your burst eardrums suffer just the same. When the booming sound ends and you expose your ears to the outside once again, your hands are covered in blood.

You look up and see a giant in the sky. A hunky, stout old man way above seven feet in height floats in the air with the same casualness others walk on earth. His shoulders are wide, planted so far across each other three grown men could've easily fit inside that distance. He's densely packed with thick muscles and throbbing red veins that pulsate with each and every breath. The old man boasts a whiter than snow goatee and a bald head without a trace of a hair strand.

He watches you, expecting total and complete compliance. Expecting you to [i]obey[/i] without question and you easily understand why: just the presence he carries induces uncontrollable shiver of terror. You match your gaze with his and almost immediately are drowned in his [i]bloodthirsty[/i] aura. 

[i]He may kill you…

[i]He will kill you…

[i]Kill you….

[i]KILL YOU!

[i]KILL KILL KILL!

You wrestle with your instinctual sense of fear, command it to remain dormant, but your hands still shake despite your best attempts. 

You don't know who this is: yet realize that this is not someone whom you can afford to provoke.
*return

*label yangbohai_slap
*gosub_scene subroutines prestige_change 5 "+"

For a second, there is silence. Absolute quiet brought about by your recklessness. Even the usually rowdy and loud observes do not utter a word, transfixed and stupefied.  

The silence is broken by the bald man. You expected many things from him: anger, disappointment, sadness for the death of a disciple — what you haven't expected is laughter. 

The man cackles and you get the feeling that everyone else in the arena has begun to cackle too: there's an itch to join in inside of even you…

The laughter stops. The man lands, his weight creating a crater on the ground. He cranks his neck and fixes you with a murderous glint. 

"It seems that I, Yang Bohai, have not massacred enough in recent times if a random disciple dares to be so insolent before me."

His steps are slow, steady and, most of all, heavy as he walks towards you.

You, instead, are anything but composed.

YANG BOHAI?!

Of course you know who Yang Bohai is. One of the three Shangtians of the Yang Clan, the undisputed number two of the Heavenly Ascension Sect, its Elder of Battle — the War Crazed Monarch, a true Demon through and through!

*choice
	#Face him stoically.
		You do not flinch as he comes close, his hot breath blowing onto you from the above.
		
		"What's your name? I will spare your family in consideration of your bravery."
		
		"Wu ${mc_name}." 
		
		*label yangbohai_learns_name
		
		"Wu ${mc_name}? Why does it sound familiar…" — he starts to ponder, forgetting about you entirely. You wonder whether or not you could make a run for it, but your speculations are doomed for failure as Yang Bohai comes out of his deep thinking process — "Ah! You are that kid whom Birdy Rin has been bugging me about. Something about you being talented." 
		
		"Birdy Rin?"
		
		"Yes, yes, Elder Rin or whatever it is you little people call that girl." — replies Yang Bohai before continuing — "Hah, you know what? On her account I'll give you a chance to survive. Withstand a slap of mine and I'll let you go." 
	#"You can't do anything to me! I'm Wu ${mc_name}, child of Wu Chao!"
		Yang Bohai snorts.
		
		"Those capable of influencing my decisions can be counted on one hand." — he says — "You tiny Wu clan doesn't make the cut." 
		
		"But my father…"
		
		He raises his hand, interrupting you. 
		
		"Wu Chao is a pathetic drunk that wets his pants when he hears my name." — jeers Yang Bohai — "If he comes for revenge, I will gladly reunite his with his ancestors." 
		
		He comes closer, his hot breath soon blowing onto you from the above. Yet, he stops an inch away.
		*goto yangbohai_learns_name
	#Beg him not to hurt you.
		*gosub_scene subroutines prestige_change 20 "-"
		*gosub_scene subroutines change_personality 5 "arrogant" "-"
		*gosub_scene subroutines stat_check "chr" 16
		*if mc_skill_persuasion >= 10
			His nose wrinkles as he spits.

			"Disgusting [i]worm.[/i] At least be brave enough to take responsibility for your own actions."

			"I wish not to stain my hands with your pathetic filth: get on your knees and I'll spare you." 
			*choice
				#Get on your knees.
					*gosub_scene subroutines change_personality 5 "arrogant" "-"
					You fall down, your knees scraped by the rough sand on the ground. You bow down to him three times, as the custom dictates.

					"I, Wu ${mc_name}, apologize for the offense I've caused." 

					You do not raise your head until Yang Bohai allows it.

					"Get out of my sight." 

					You quickly leave, afraid of aggravating him further.
					*goto leave_arena
				#Refuse to bow.
					It's one thing to beg — it's another matter all-together to whimper on the ground like a scared dog. 

					"No! I, Wu ${mc_name}, will not kneel to anyone!" — you refuse. 

					Yang Bohai snorts.

					"Then go and die." 
					
					He comes closer, his hot breath soon blowing onto you from the above. Yet, he stops an inch away.
					*goto yangbohai_learns_name
		*else
			"Disgusting [i]worm.[/i] At least be brave enough to take responsibility for your own actions." 			— his nose wrinkles as he spits — "I hate cowards like you the most. Tell me, which family has produced such a spineless dog?"
			
			"I'm Wu ${mc_name}…"
			
			"Doesn't matter — you'll die all the same." 
			
			He comes closer, his hot breath soon blowing onto you from the above. Yet, he stops an inch away.
		*goto yangbohai_learns_name
	
You find yourself paralyzed: you can't move, can't dodge and can't use any Skills.

Yang Bohai winds up his arm, his strike tardy but nevertheless just as [i]inescapable[/i]. You can feel its power, can feel the approaching death even through the distance: Yang Bohai is known to have blown up small mountains with punches and even one percent of such strength is insurmountable for the current you.

*page_break Receive The Slap
*gosub_scene subroutines reduce_true_health_return 15 fight_scene false
*if mc_health <= 0
	Your head [i]explodes[/i]. Bursts like a crushed watermelon. On the plus side, you don't experience an ounce of pain, the ordeal taking up barely an instance. On the negative, however, you're as dead as anyone can be. There is no bringing you back: only exceptional Xiantian that specialize in regeneration would be able to recover from such a blow.
	*goto_scene game_over
*else
	For a second, everything else ceases to exist: the burning, scorching pain becomes the center of your being. Although your skull withstands the blow, you are far from being safe and sound:
	*gosub_scene subroutines add_injury 2
	*gosub_scene subroutines add_injury 3
	*gosub_scene subroutines add_injury 5

	Your back hits the reinforced tribunes of the Arena, the bones in your spine snapping against the hardy surface. 
	*gosub_scene subroutines add_injury 6
	"You're still alive." — Yang Bohai exclaims — "I guess the Heavens do not wish you dead." 

	He crouches down next to you, cupping your chin with his hand and turning your face. Yang Bohai lifts you up by the collar, your feet dangling in the air.
	
	"Remember this next time you choose to disrespect your seniors." 
	
	He drops you and flies away.
	
	You do not possess such freedom of movement, having to wait instead for some sect workers to pick you up and carry you to the Infirmary.
	*set fight_scene "none"
	*if (eligible_achievements)
		*achieve slap_me_harder
	*goto_scene fr_infirmary
			
*label peaceful_ending
"[b]WAIT.[/b]"
A deafening shout causes you to cover your ears. It's not a skill, it's not a spell, merely a simple yell, yet your burst eardrums suffer just the same. When the booming sound ends and you expose your ears to the outside once again, your hands are covered in blood.

You look up and see a giant in the sky. A hunky, stout old man way above seven feet in height floats in the air with the same casualness others walk on earth. His shoulders are wide, planted so far across each other three grown men could've easily fit inside that distance. He's densely packed with thick muscles and throbbing red veins that pulsate with each and every breath. The old man boasts a whiter than snow goatee and a bald head without a trace of a hair strand.

He watches you, expecting total and complete compliance. Expecting you to [i]obey[/i] without question and you easily understand why: just the presence he carries induces uncontrollable shiver of terror. You match your gaze with his and almost immediately are drowned in his [i]bloodthirsty[/i] aura. 

[i]He may kill you…

[i]He will kill you…

[i]Kill you….

[i]KILL YOU!

[i]KILL KILL KILL!

You wrestle with your instinctual sense of fear, command it to remain dormant, but your hands still shake despite your best attempts. 

You know neither who he is nor what he wants with you.

*choice
	#"Yes, Senior?"
		*label yes_senior
		"What's your name?" — the man asks.
		
		"Wu ${mc_name}."
		
		"Wu ${mc_name}? Why does it sound familiar…" — he starts to ponder, forgetting about you entirely — "Ah! You are that kid whom Birdy Rin has been bugging me about. Something about you being talented." 
		
		"Birdy Rin?"
		
		"Yes, yes, Elder Rin or whatever it is you little people call that girl." — replies the old man before continuing — "Hah, you know what? You've impressed me. I'll be watching you with interest." 
		
		"I thank Senior for such honor. May I know his esteemed name?"
		
		"Yang Bohai."
		
		YANG BOHAI?!

		Of course you know who Yang Bohai is. One of the three Shangtians of the Yang Clan, the undisputed number two of the Heavenly Ascension Sect, its Elder of Battle — the Crazed War Demon! 
		
		You are not sure whether his attention is a good thing or not…
		
		Yang Bohai nods at you before he flies away. 
		*goto leave_arena
	#Wait quietly for him to speak.
		*goto yes_senior
	#"The fuck are you screaming for, baldy?"
		*goto yangbohai_slap





*label leave_arena
*gosub_scene subroutines clear_fight_vars
*set fight_sect_arena "none"
*gosub_scene subroutines give_exp 100 ""
*gosub_scene subroutines prestige_change 30 "+"
*page_break Leave The Arena
*goto_scene free_roam