It's dawn, and you sit cross-legged with your eyes closes. You inhale and exhale the rich air around you, as usual practicing your breathing technique. However, ever since you came into this Danger Zone, you've been noticing strange happenings after each session: instead of simply calming your nerves and steadying your mind, every meditation leaves you feeling stronger and stronger than before. It's a minute increase, one unnoticeable by a naked eye, but how could you, someone who's entire life revolves around perfecting your body, not notice the changes?

*gosub_scene subroutines give_exp 20 "str"
*gosub_scene subroutines give_exp 20 "agi"
*gosub_scene subroutines give_exp 20 "con"
*gosub_scene subroutines give_exp 20 "vit"

This time, you do your best to focus your senses on the strange environment around you, trying your to best to understand what makes it so special…

*gosub_scene subroutines stat_check "per" 25
*if (stat_check)
	Suddenly, you eyes go wide. Success! 
	
	It's just a tinge of a feeling, a hint of familiarity, but you manage to discern something that you've already experienced before: the same sensation that appeared when you touched the tribe's relic. The same insanely pure Inner Energy present inside that stone, existed in the air as well! 
	
	Granted, the quantity, and quality, of it was incomparable to the what was inside the rock — but so what? If this little bit could empower you already, wouldn't the relic grant you an even greater boon?
	
	Almost mad with desire, you rummage your spatial ring in search of the
	*if expo_xiwen = "minion"
		stone and bring it out.
		
		Before you do anything else, however, you hold yourself back. You don't really know what this weird energy [i]is[/i] and what exactly it can do. In small amounts, it doesn't appear to cause you any harm, but what if you absorbed a much bigger chunk? What would happen? If there is one thing to know about the Martial World, it's that great rewards always come with great risks.
		
		You remember Lei Xiwen, who's now present in your tribe. If there is one person who would know about the nature of these stones and this energy, it would be him. His master is, after all, considered to be the most knowledgeable man in the entire Empire.
		
		Maybe it's worth it to reveal this secret and ask him for help?
		*label what_to_do
		*choice
			*if expo_xiwen = "minion" 
				*hide_reuse #Ask Xiwen for help.
					When you let Xiwen inspect the sacred relics, 
					*label xiwen_confused
					he can only look at them with blatant confusion in his eyes. He fiddles with the rocks, and even uses a few investigative Arts to gain some insight, but in the end can only shake his head.

					*set history &"xiwen_knows_stones|"

					"I don't feel anything. They seem like ordinary stones to me." — he says, furrowing his brows — "But… if you want, I can ask my Master. He's bound to know something." 

					"How are you going to do that?" — you question — "All means of long-distance contact are ineffective in the Danger Zones. Especially with the outside."

					Lei Xiwen, however, just smiles mysteriously.

					"They are. But my Master has his ways. After all, if he says he's the second most knowledgeable about Danger Zones man in the world, no one will dare claim to be number one." 

					"It will take a few weeks, however." — Lei Xiwen continues — "Maybe longer. This Zone is very strange." 

					"I see. Thank you for your help."

					"Don't mention it." — the young man waves his hand — "I'm happy to be of assistance. For the time being, however, I recommend you wait and don't do anything. Caution is the best way to survive, after all." 

					*if expo_xiwen = "owner"
						"However… since I've inconvenienced you with my arrival, I will leave the stone in your care. The final decision is yours." 

					*page_break
					*goto what_to_do
			#Proceed on your own.
				Throwing caution to the wind, you 
				*label use_stone
				put your hand on the magical stone and feel the warmth inside. Your instincts scream at you, yell with all the power of your senses to grasp this energy, to swallow it whole — but the question of 'how' still remains. These rocks can't be broken, you've tried, and you don't possess any means of extracting the energy through the hardy shell.
				
				The only thing you manage to come up with is keep on practicing your breathing techniques, only now also holding the relic in your hand. And it works: perhaps far from the most optimal solution, but the air you absorb grows much, much richer. 
				
				*gosub_scene subroutines increase_atr "str" false
				*gosub_scene subroutines increase_atr "agi" false
				*gosub_scene subroutines increase_atr "con" false
				*gosub_scene subroutines increase_atr "per" false
				*gosub_scene subroutines increase_atr "vit" false

				*set history &"used_stone|"
				
				When you end your session, your body feels utterly exhausted: your muscles are tired, you are covered in sweat, and even your mind exists in a groggy, half-awake state. But the results seem to be more than worth it. 
				
				*goto return_to_tribe
			#Forget it. This is too dangerous.
				*label forget_it
				Not daring to take the risk, you put the stone back in your spatial ring. Another day, perhaps?
				
				*goto return_to_tribe
	*else
		stone, only to realize you've already given it up to Lei Xiwen. 
		
		You can try asking him to borrow it for a time, but without a good explanation he's not likely to agree.
		*label asking_xiwen
		*choice
			*hide_reuse #Ask Xiwen for the stone.
				"You need the relic?" — Xiwen questions after you make your request — "What for?"
				
				*choice
					#Can't you just trust me?"
						"Can't you just trust me?" — you say. 
						
						Xiwen looks at you, his eyes trying to find the answer you refuse to say aloud in your firm expression.
						
						*if characters_15_opinion >= 60
							"Fine." — he relents and hands the relic over to you — "Don't let me down."
						*else
							"I apologize," — he shakes his head — "But I can't."
							
							*goto asking_xiwen
					#Step forward and smile cutely, "Please?"
						You step forward, mere inches before his face — close enough for the both of you to feel each other breaths. Your mouth forms a cute, endearing grin and you gently tug at his robe.
						
						Your approach startles him and he looks away, unable to hold your gaze. He tries to get an answer out, but only ends up stammering unintelligible words. So, instead of speaking, he hands the relic over to you and walks away in a flustered hurry.
						
						After a chuckle, you return to your meditation spot and
						*goto use_stone
					#Tell him the truth.
						After explaining everything you know about the stones, Xiwen looks just as excited as you did a few minutes ago. 
						
						"Let me try." — he says, bringing out the stone. However, after almost an hour of trying,
						*goto xiwen_confused
			#Forget it.
				*goto forget_it
*else
	Sadly, your attempt proves to be futile. Your meditation is also spoiled, because you just can't help but feel that you have missed out on an enormous opportunity.
	
	*goto return_to_tribe

*label return_to_tribe
*page_break
*goto_scene expedition_free