*temp told_truth false
*temp used_dao 0
*temp called_maid false
It's a few days after your awakening, and you have been anything but idle: you couldn't allow yourself to be due to the drastic changes that took place during your slumber. 

A massive battle occurred between Long Chen and Tang Ruo. It's said more than a hundred of Tattooed and Martial Artists fought to the death, filling the virgin jungle with dozens of brutally mangled corpses. 

In the end, however, it became apparent that the Prince bit off more than he could chew: he and Long Chen clashed directly and the Celestial heir, famed for his invincibility, was almost smacked to death with a single blow. The might of the 'strongest Houtian' was so overwhelming that the single strike of his cudgel broke several of Ruo's life-saving treasures and the Tang heir was carried away, unconscious, by another artifact. He had not been seen since. 

Long Chen, however, became even more arrogant in his behavior. All the tribe besides the seven under your and Xiwen's control have been conquered by him and it's only a matter of time before he arrives for your relics as well. Right now, he's most likely recovering from whatever minor injuries he received during the previous battle and will soon set out, no doubt eager to end this expedition with a victory.

So, although there's no way for you to match up to his level yet, you have been training hard and exploring the powers of the Golden Seed. When actively used, you discovered, you can explode with strength equal to Late-Houtians — and not weak ones either. But the main benefit is its passive ability, one that does not cause you any mental strain: whenever you fight now, it's akin to having the most knowledgeable master guiding your actions. As if the Heavens themselves constantly whisper in your ear, you can make right decisions by instinct and even predict your enemy's moves with an always precise accuracy. 

Overall, that dream made incomprehensibly stronger. It worries you that you have no idea about the origin of this power, but it's not like you can remove it from your brain either. For now, you'll just have to live with it and brace yourself for the possible consequences.

*page_break
*gosub_scene subroutines clear_fight_vars
You wipe the sweat off your forehead, completing yet another set of exercises. You have doubled the intensity of your training lately and it's during one of the additional sessions that Ro Hyi comes to find you.

"Senior ${mc_name}, I'm glad to see you have recovered." — the disciples says — "You gave us all quite a fright when you dropped unconscious out of the blue." 

"I gave myself a fright as well." — you chuckle, welcoming Ro Hyi with a clasp of your hands.

"If I may ask… what exactly happened?"

*choice
	#Tell the entire truth.
		*set told_truth true
		Feeling that you can trust this masked Martial Artist, you spill the entirety of the story, not holding anything back: you tell them about the dreams you've been having, about the Golden Seed and about its strange, otherwordly powers. 

		When you finish, Ro Hyi is silent. They remain silent for minutes, probably trying to determine whether your mind has wavered in its sanity. Finally, the disciple nods.

		"It all sounds unbelievable to me…" — Ro Hyi mutters — "But since Senior ${polite_address} has trusted me with this knowledge, I will trust that ${pronoun_2} words are true."

		"You have been blessed by the Heavens once again." — the disciple bows — "Congratulations."

		"Thank you." — you reply — "What is it you wanted from me today?"

		"Oh." — Ro Hyi mumbles, taken out of their thoughts — 
		*label investigation_results
		*if expo_twins = "investigated"
			"Right. I have finished the interrogation of the twins and it yielded quite a harvest of knowledge."

			"Please, do tell."

			"These twins and their so-called 'Mistress' are members of the Havoc Sect.
		*else
			"I have brought news both grave and hopeful. Do you remember those twins that attacked you before you collapsed"
			
			"I do. What is it?"
			
			"Turns out, they are lackeys of someone called 'Mistress' and all three are members of the Havoc Sect.
		From what I heard, this 'Mistress' is an exceptional talent unmatched in the Middle-Houtian stage except for the monster genius, the Prince." — Ro Hyi explains — "She's known for being extremely cruel, devious and cunning. It is said that once the previous greatest talent of the Havoc Sect, a Peak-Houtian on par with Lei Xiwen, had wanted to forcefully make her into his concubine. So, she schemed him to death: first, she managed to cripple him and make him lose his martial prowess, then she publicly castrated him, letting the entire sect watch the humiliating process. As that disciple was begging for death, she carved out his still beating heart and ate it in front of his dying eyes. After that incident, no one has dared to even look at her wrongly and many started calling her the 'Little Demon Queen'."

		Ro Hyi coughs, clearly uncomfortable talking about this revolting character. 

		"Together, the trio has been hunting down disciples of the Law and Ascension sects, either capturing or killing them, if there was no other choice. As for why they tried to get these disciples alive, the Mistress owns the infamous 'Purity Draining Needle'. The meaning of this artifact is self-explanatory."

		*gosub_scene subroutines stat_check "int" 25
		*if (stat_check)
			"Purity Draining Needle?" — you ask, the name stirring your memory — "I thought it was lost more than a thousand years ago." 

			"Senior ${polite_address} ${mc_name} is quite well-read, indeed." — Ro Hyi mentions, a hint of surprise leaking into their voice — 				"I thought so as well. Turns out, the Havoc Elders had it all along and were just waiting for a suitable disciple to show up."

			"By suitable, you mean having the Yin-Yang Physique, also called An Alchemist's Dream? The one where the Yin and the Yang of the owner are perfectly balanced, leaving them with an androgynous appearance, but also allowing feats otherwise impossible? Like assimilating the stolen Blood Purity of others?"

			"${YM}, your breadth of knowledge is astounding." — Ro Hyi praises, though there seems to be something wrong with their tone: but you can't pinpoint it — "This Mistress is a terrifying character, indeed. If she gets the help of a talented alchemist in the future, she may even turn out on par with the current Demon Queen. I can understand why the twins would choose death over betraying her."

		*if (expo_twins = "investigated")
			"From the sisters' words, I have managed to determine two possible locations for their hideout. 
		*else
			"I have managed to determine two possible locations for their hideout. 
		We can ask Senior Xiwen to search one, while we head out to the other. However, we need to be quick — time is of the essence. As soon as the Mistress understands that the twins have failed, she will kill every disciple she has imprisoned."
		*label hyi_choice
		*choice
			#"Let's hurry then!"
				"Let's hurry then!" — you exclaim and both of you set out on your way.

				*goto havoc_hideout
			#"I don't really care about saving other disciples."
				"I don't really care about saving other disciples." — you say, shrugging your shoulders — "It's their fault for being so weak as to suffer such a fate."

				"Are you sure, ${YM}?" — Ro Hyi asks — "Some of your acquaintances have been captured as well. A barbarian woman called 'Tigress' and a noble named from the Jing family. If you ignore this opportunity, their death is almost certain. Not to mention, since Senior Xiwen already knows of this matter, once we get out of this Zone, the Sect will punish you heavily for not protecting your fellow Brothers and Sisters."

				*choice
					#"Alright, alright. Let's go."
						"Alright, alright. Let's go." — you say and both of you set out on your way.

						*goto havoc_hideout
					#"Still don't care."
						"Still don't care." — you say, emotionless.

						Ro Hyi is flabbergasted by your answer.

						"It seems I had a wrong idea about ${YM}." — the masked disciple eventually replies — "Excuse me, then. Even if you do nothing, I still have to try my best to save their lives."
						
						*if expo_twins = "killed"
							*set expo_hyi_damage "nothing"
						*else
							*set expo_hyi_damage "partial"

						*goto not_gone
			*if (expo_twins != "investigated")
				*hide_reuse #"Where did you get this information?"
					"Where did you get this information?" — you ask, suspicious of how someone as insignificant as Ro Hyi was able to gather such detailed intelligence.
					
					"While you were in a coma, we caught another disciple of the Havoc Sect. Senior Brother Xiwen allowed me to interrogate him and… after some persuasion, he told us everything he knew." 
					
					*goto hyi_choice
	#Tell the truth, but omit the Golden Seed and its powers.
		You tell Ro Hyi about the strange dreams you've been having, about the boy you keep on seeing and how those visions have resulted in you falling into a coma for month. You omit, however, everything related to the Golden Seed and its powers. Although you trust this masked Martial Artist quite a bit, you don't feel comfortable sharing every detail about your current situation with them. In Jianghu, one always needs to be careful — for caution is the best tool of survival.

		It takes a moment for Ro Hyi to think over the meaning of your words, but soon they nod.

		"${YM}, don't take offense, but you should consult a healer once you get back to your sect. Realistic dreams are very common amongst Martial Artists, due to our strong personalities forcing our will into the subconsciousness. However, if they send you into a coma, there may be a problem with your mind. There are countless stories of Martial Artists suffering a Breakout due to nightmares. You must not neglect your mental health."

		"Thank you for your concern." — you say with a smile — "What is it you wanted from me today?"

		*goto investigation_results
	#"To be honest, I don't know myself."
		Trust in the Martial World is not something easily earned — it's impossible for you to reveal a secret as big as the one you carry to someone you just met. 

		"To be honest, I don't know myself." — you say, with an awkward chuckle — "I just collapsed after training and found myself waking up a month later."

		It's clear that Ro Hyi doesn't believe your words: they don't comment on your lie, however, accepting it with a nod.

		"Anyway," — you continue — "What is it you wanted from me today?"

		*goto investigation_results
	#"You may not."
		"You may not." — you say, your cold tone leaving no room for discussion.

		"I understand. I apologize for prying." — Ro Hyi replies, hurt at both your rudeness and lack of trust.

		"Anyway," — you continue — "What is it you wanted from me today?"

		*goto investigation_results

*label havoc_hideout
*page_break
*if expo_twins = "investigated"
	*set expo_hyi_damage "full"
*elseif expo_twins = "killed"
	*set expo_hyi_damage "nothing_knows_mistress"
*else
	*set expo_hyi_damage "partial_knows_mistress"
As you traverse the overgrown, untouched jungle, Ro Hyi initiates a conversation.

"${YM}… can I ask you some personal questions?" — they say — "Don't get me wrong, I don't mean to pry. It's just… Ever since there was news about a disciple with perfect Purity, I became very curious in you." 

*choice
	#"Ask away."
		"Ask away." — you say.
		
		"How does it feel, having a perfect Purity? Is there something special, something that sets you apart from the rest of us?"
		
		You shrug your shoulders in response.
		
		"Not really. My Martial Arts are stronger and I grow in strength easily, not encountering any bottlenecks or difficulties on my path of advancement. But there's no qualitative difference between, say, me and someone with 98 or 99%."
		
		"Interesting…" — Ro Hyi notes, before continuing her query — "In the last few years, there have been a lot of rumors about children with similar, almost identical, appearances turning up throughout the entire Empire. It caused a lot of scandals and outrage, with husbands killing wives for their supposed infidelity. Looking at you and Senior Chen, those rumors must be true." 
		
		"They are." — you confirm — "But I can assure you, than no green hats has been worn, at least in the case of me and Long Chen." 
		
		"Really?"
		
		"Yes. It's absolutely impossible. There's something else going on, something that we don't quite understand." 
		
		"Can such a weird thing be happening?"
		
		"We have trouble believing it ourselves, were it not for our indistinguishable faces." 
		
		Your conversation goes on, as Ro Hyi asks you all sorts of questions: from your childhood and parents to your ideals and life goals.
		
		*goto arrived_hideout
	#"You can't."
		"You can't." — you reply, still acting cold to the masked disciple.
		
		"I understand." — Ro Hyi replies and you spend the rest of the journey in silence.
		
		*goto arrived_hideout

*label arrived_hideout
*page_break
After more than three hours of walking, you finally arrive at the supposed location. Only, there's nothing there to be seen: fallen branches, leaves on the ground and endless trees, just like everywhere else in this world. 

*gosub_scene subroutines stat_check "per" 25
*if (stat_check)
	One of the trees, however, looks weird: you can't determine what is off with it at first, but then you take a closer glance at its trunk. The coloring at the bottom is off, a different shade of brown compared to the rest of tree. You walk up to it and touch the bark with your palm, only to let out an amused chuckle.
	
	Because you just felt dried paint. 
	
	You take a deep breath, weave your arms around the tree and [i]pull[/i]. To no surprise, it offers almost no resistance — because there aren't any roots holding it in place. Instead, there's a hole, just wide enough for a human to fit through, and dim light coming from its insides.
	
	"Senior ${polite_address}, you are very perceptive." — Ro Hyi commends — "I was beginning to fear my information was incorrect."
*else
	"Is this the place?" — doubtful, you ask Ro Hyi.
	
	"It should be." — the masked disciple answers, themselves sounding unsure — "Let's look around, maybe we'll find something." 
	
	You spend more than thirty minutes searching, but despite flipping over every stone in your immediate vicinity, your endeavor bears no fruit.
	
	"Was I wrong?" — Ro Hyi mutters to themselves, leaning on a tree — "But I was cert- Wait!"
	
	Frantic, the disciple turns around and starts touching the bark with their hands. Soon, Ro Hyi lets out half-amused, half-annoyed chuckle.
	
	"There's dried paint on this tree's trunk." — Ro Hyi says.
	
	"What? Why would there be paint?" 
	
	Without another word, Ro Hyi weaves their arms around the tree and pulls it out — with much less effort that you thought it was going to take. Why? Because instead of roots holding the tree town, there's a hole, just wide enough for a human to fit through, and dim light coming from its insides. 
	
	Ro Hyi shakes their head and sighs. 
	
	"We almost got fooled."
	
	"But we didn't. Good job." — you comment.
	
	"Thank you."
	
"Shall we?" — you say, pointing to the hole.

Ro Hyi nods and gestures you to go first. Without a second thought, you jump in and…

… find yourself in a tunnel, dozens of feet under the ground. The walls around you are made of a certain stone, a material quite popular back in the Empire for its cheapness, durability and ease of use in any circumstances. Torches lit with fire illuminate your surroundings, revealing a metal door just a few meters ahead. 

Ro Hyi lands near you as well, letting out a small grunt. The jump is a little bit too difficult for a measly Early-Houtian, after all.

"What is this?" — the masked disciple asks, looking around — "Where are we?"

"Those from the Havoc Sect are cunning indeed. They even constructed a hideout underground, to avoid being discovered by the prying eyes."

"What devious scum." — Ro Hyi snorts — "Imagine if they used their cleverness to better our world, instead of wasting it on their schemes." 

"Should we open that door?" — the masked disciple asks, and, despite their tough words, you hear the nervousness in their voice — "What if… What if the Mistress is inside?"

*choice
	#"Don't worry. She may be Mistress to others, but she is, at most, a maid to me." 
		*set called_maid true
		"Don't worry." — you comfort Ro Hyi with a confident grin — "She may be Mistress to others, but she is, at most, a maid to me." 

		For some reason, you feel that the tunnel have become [i]colder[/i]. 

		*if (mc_sex = 0)
			"${YM} is truly a dragon among men."
		*else
			"${YM} is truly a phoenix among women."
		— Ro Hyi laughs — "$!{pronoun_1} knows no fear, everyone else is but an ant beneath ${pronoun_2} feet." 

		The disciple then bows.

		"Thank you for easing my panicked heart. With ${YM} by my side, I am at ease, ready to tackle all challenges head on." 

		"Great!" — you exclaim and pat them on the shoulder — "Let's head in then, I'm curious what this so-called 'Little Demon Queen' prepared for us." 
	#"Then we'll take the chance to do our society a favor and rid it of that vile creature."
		"Then we'll take the chance to do our society a favor and rid it of that vile creature." — you say, your tone full of righteousness.

		*label is_right

		"${YM} is right." — Ro Hyi replies with a bow — "My nervousness overwhelmed the sense of justice in my heart. I apologize."

		"It's fine." — you console them — "Everyone can become afraid. What matters is whether or not you can push through your fear." 

		"I definitely can!" — the masked disciple exclaims — "${YM}, let's head in!"
	#"We can't give up on our Brothers and Sisters simply out of fear."
		"I understand your concerns." — you console Ro Hyi — "But we can't give up on our Brothers and Sisters simply out of fear."

		*goto is_right

You walk up to the door and try to push it in. It opens with absolute ease, not locked or barred in the slightest and you see a room that causes Ro Hyi to turn away in disgust. They lean on a wall, barely holding in their stream of vomit by taking deep, audible breaths.

"Why would anyone do this…" — Ro Hyi murmurs, their voice weak — "This… this…" 

About half a dozen glass-doored cupboards are inside the room, all filled to the brim with human parts: brains, ears, eyes, tongues and teeth at the top, then hearts, lungs, livers and kidneys underneath. There are even vials full of blood at the bottom, liters and liters of human blood on a single shelf. Then, a pile of bones and a dresser with different martial robes, most torn or stained, occupy the room's left side, while a simple bed and a praying mat occupy the right one.

You step inside, wanting to inspect the room closer. You soon find that every cupboard has symbols engraved on it and those symbols turn out to be names: 

[i]Li Kee[/i]
*line_break
[i]Xiao Su[/i]
*line_break
[i]Ro Hyi[/i]

Wait, Ro Hyi?

*if (told_truth)
	Alerted, you turn around — but instead of the 'Ro Hyi' who was accompanying you all this time, you are met with the slam of the entry door. Suddenly, the walls around you light up with blue, complex symbols and when you try to leave, you find an invisible force field preventing you from doing so. 
				
	*gosub_scene subroutines stat_check "int" 20
	*if (stat_check)
		This is an Array — an extremely expensive and rare art of arranging the same symbols that constitute Martial Arts in a formation — with defense as its main property. You are nowhere near knowledgeable enough about this craft to dismantle it in a technical way. Your only solution, your only approach that will allow you to get out of this this room is the simplest, most primal method: smash it until it breaks.
	*else
		Although you can't quite recognize what is this obstacle preventing you from getting out, you can't just give up either: so, you you decide to use the simplest, most primal approach: smash it until it breaks.
	
	It takes you hours, however. 
	
	*set expo_hyi_damage "full"
	*goto end_event

*gosub_scene subroutines stat_check "per" 30
*if (stat_check)
	It's almost traceless. Almost impossible to sense. But you discover it, the subtle utilization of Inner Energy behind you — and, by instinct that soon proves to be life-saving, you dive to the side with all your might. 

	Half a second later, an attack of startling power comes at the place where you just stood and shatters the reinforced, stone-made floor. 'Ro Hyi' lifts up the metal bo staff they just used to perform the blow and snickers. 

	"Not bad." — 'Ro Hyi' says, circling the staff in their hands with a breathtaking display of skill — "You got some reflexes, at least."

	*goto hyi_revealed
*else
	*gosub_scene subroutines stat_check "con" 30
	*if (stat_check)
		*gosub_scene subroutines reduce_health 5
		A metal rod slams into your head: you're staggered, your ears ringing, but you still maintain enough reason to dive to the side. You avoid another heavy blow that shatters the reinforced, stone-made floor.
		
		'Ro Hyi' lifts up the steel bo staff they just used to perform the blow and snickers. 
		
		"Not bad." — 'Ro Hyi' says, circling the staff in their hands with a breathtaking display of skill — "You got a thick skull, at least."
		
		*goto hyi_revealed
	*else
		A metal rod slams into your head: it cracks your skull like an egg, bursting apart the bone with one heavy blow.
		*gosub_scene subroutines reduce_health 10
		It's a miracle you're still alive. It's an even bigger miracle that you find enough reason with your ringing brain to dive to the side, avoiding another attack that shatters the reinforced, stone-made floor.
		
		'Ro Hyi' lifts up the steel bo staff they just used to perform the blow and snickers. 
		
		"How disappointingly slow." — 'Ro Hyi' says, circling the staff in their hands with a breathtaking display of skill.
		
		*goto hyi_revealed
		
*label hyi_revealed
'Ro Hyi' has changed completely. From a tame, unassuming noble they have turned into someone who's mere presence [i]alarms[/i] you. The eyes behind their mask turned soulless and, even after a thorough glance, you can't find even a trace of humanity inside. For a good minute, the both of you stare at each other, you in confusion, 'Ro Hyi' with an amused tilt of their head. Looking at their confident posture, their relaxed attitude, reminds you of Tang Ruo: but their arrogance is different. While the Prince resembles a sword ready to pierce the Heavens themselves, invincible and uncaring towards others, the masked disciple — no, the masked [i]creature[/i] — gives you an impression of a wolf in sheep's clothing, a hungry predator out on a hunt. You can't see their expression, but just the image of a bloodthirsty, ruthless grin on that burned face sends shivers down your spine.

"Who are you, really?" — you can't help but ask, already preparing yourself for a dangerous fight. 

'Ro Hyi' throws off their robe, revealing a figure-hugging red martial suit underneath. Although their body is slim and athletic, flat and lacking any noticeable curves, you can for sure tell that the masked disciple is, in fact, a woman.

She spreads her arms wide open, letting out a demonic, bone-chilling laugh. 

"Welcome to my home!" — she exclaims, snapping her fingers. Suddenly, the door to the room closes by itself and the walls around you light up with crimson symbols — "I sincerely hope you won't find my decor lacking. I spent more than a month putting it together, after all."

"You are… the Mistress?"

Then it dawns on you. Does this 'Mistress' even exist? All that you know about her was told to you by, what appears, the Mistress herself. 

"Don't doubt too much." — the Mistress chuckles — "Lying about something that can be easily confirmed is an amateur mistake."

"What do you want? You plotted such a big scheme, sacrificed your own pawns and pretended to be a subservient brown-noser. What was it all for?"

*if expo_twins != "killed "
	"Sacrificed my pawns? Are you sure about that? Hehe. And about what I want, that's easy!"
*else
	"What I want? That's easy!"
— she says and points at you — "I want you, of course." 

"Unfortunately for you," — the Mistress continues — "My tastes differ from those two silly girls. While they enjoy the pleasures of the flesh, I would be satisfied with your blood and heart."

"You know, I'm really excited right now." — she tells you, planting her staff on the floor and leaning her chin on its tip — "I mean, those six weaklings barely raised my Blood Purity by a single percent. How much would a fat piggy like you give me? Mmmph~"

You hear her [i]salivating[/i] behind her mask, her cold gaze slowly turning ravenous.

"And if I fuse your skin with my own, use your bones to reinforce mine… Indeed, you are quite a harvest. Totally worth putting on a little show." — the Mistress concludes, but then clicks her tongue — "Tsk. If not for that annoying pretty boy watching you like a hawk, I would've snatched you long ago. You should thank him. In your thoughts, at least, because you're not getting out of here."

*temp asked_questions 0

*label talking_with_mistress
*if asked_questions = 3
	Understanding that talking won't get you anywhere, you resolve to use your fists instead.
	
	*goto attack_mistress
*choice
	*hide_reuse #"Oh? What if I just run away?"
		*set asked_questions +1
		"Oh?" — you chuckle — "You may be strong, but you can't be [i]that[/i] strong as a Martial Artist of the same stage as me. If I decide to run away, can you stop me?"
		
		"Be my guest." — the Mistress says, gesturing at the door — "Please, leave if you can." 
		
		Confused, you walk to the exit and attempt to push the door open… only to find your hand stopped by an invisible force field. 
		
		"Not bad, right?" — rings out the voice behind you — "I think I've killed more than thirty of my fellow disciples to get a hold of this beauty."
		
		*gosub_scene subroutines stat_check "int" 20
		*if (stat_check)
			This is an Array — an extremely expensive and rare art of arranging the same symbols that constitute Martial Arts in a formation — with defense as its main property. You aren't getting out of this room anytime soon, that's for sure.
		*else
			Although you can't quite recognize what is this obstacle preventing you from leaving, by its durability — which you tested with a couple of punches — you realize you aren't getting out of this room anytime soon.
		
		*goto talking_with_mistress
	*hide_reuse #"Maybe we can talk this out?"
		*set asked_questions +1
		"Maybe we can talk this out?" — you hopefully suggest.
		
		"Sure!" — the Mistress cheerfully agrees — "Just carve out your heart and drain all your blood into a vial for me. What's with that frown? You don't agree? Pff! Then don't complain that I wasn't willing to negotiate." 
		
		*goto talking_with_mistress
	*hide_reuse #"Where are my friends?"
		*set asked_questions +1
		"You said that there were disciples kept prisoner here. Including some of my friends." — you say — "Was that a lie? Are they all dead?"
		
		"Most of them are." — the masked disciples answers — "I kept some alive though. That Guo fellow is still breathing, for example." 
		
		"Where is he?" 
		
		"He's… I won't tell you, haha!" 
		
		*goto talking_with_mistress
	#"Enough. I'm tired of listening to your nonsense — go die!"
		"Enough!" — you shout — "I'm tired of listening to your nonsense! Go die!" 
		
		*goto attack_mistress
	#Attack her.
		*goto attack_mistress
	#[i]Abilities/Items[/i]. 
		*gosub_scene skill_menu
		*goto talking_with_mistress

*label attack_mistress
*set fight_scene "expedition_hyi_fight"
*gosub_scene subroutines set_enemy_stats 30 30 30 30 30 "middle" "Pressure Point Staff Art"
You decide to start this fight out with a bang: you run, jump and chop down with you leg, performing a perfect, lightning-quick ax-kick. Your technique is flawless, your figure a thing of beauty as you soar through the distance, but… 

The Little Demon Queen drags her foot back, bends her body a little and raises her arms: the metal rod grasped in her hands stop your attack in its tracks, without even causing her to stagger. She then flips her staff, changes her grip and smacks you out of the air. 

Before her blow connects, however, you feel as your back [i]hardens[/i]: your muscles contract, your skin molds, your bones vibrate in harmony — all of this a courtesy of the Golden Seed, no doubt. 

*gosub_scene subroutines f_stat_check "con" "str" 0
*if (stat_check)
	Although you are brought down to the floor, you immediately recover and get back up on your feet. 
*else
	*gosub_scene subroutines reduce_health 5
	The strike hurts, there's no denying it, but with your increased protection you are able to swiftly recover and get back up on your feet.

The Mistress stretches her neck and spins her staff again.

"Are you that eager to die?" — she mocks you — 
*if (called_maid)
	"Let this [i]maid[/i] fulfill your last wish then."
	
	[b]You have enraged the Mistress - probably not a good idea calling someone like her a mere maid. This fight will be more difficult.[/b]
	
	*set fight_difficulty +1
*else
	"I will help fulfill your last wish then." 

"[b]Demonic Summon Staff Art — Descent Of The Demon![/b]" 

Her metal rod is suddenly engulfed by black as the void flames. They emanate heat so strong and potent, it becomes hard to breathe. The fire, chaotic and unruly, seems to dance in anticipation as the LIttle Demon Queen lifts the staff and slams it down, aiming to crush you into meat paste and burn away you remains. She doesn't pull back in the slightest, the killing intent behind the blow as evident as the sun in a clear sky. 

*choice
	#Dodge it.
		*gosub_scene subroutines f_stat_check "agi" "agi" 0
		*if (stat_check)
			You rotate your body to the side, avoiding her attack, and then her in the stomach. The Mistress, however, blocks it with her own leg, before she suddenly changes her stance with a hop and spin-kicks you in the stomach.
			
			But you have already knew what she was going to do: you cross your palms before your abdomen and absorb the kick without much trouble. The Mistress, however, refuses to relent as she jumps back and thrusts her staff multiple times into the nothingness.
			
			*goto charge_of_generals
		*else
			You rotate your body to the side, but fail to avoid her attack.
			*goto fire_roasts
	#Stop it with your bare hands.
		Trying to replicate her own feat, except reversing the position of bare hands and the metal rod, you bend down a bit and cross your arms above your head.
		
		*gosub_scene subroutines f_stat_check "con" "str" 2
		*if (stat_check)
			The first challenge is withstanding the terrible heat: even despite your sturdy constitution, when the fire comes in contact with your hands, you feel them [i]burn[/i]: slowly, inches of your skin become roasted and then charred. 
			*gosub_scene subroutines reduce_health 5
			But you groan and hold on, straining your muscles to oppose the enormous might behind the staff…
			*gosub_scene subroutines f_stat_check "str" "str" 2
			*if (stat_check)
				The veins on your arms almost pop from the pressure, but you end up the winner in this struggle, stopping the rod in its tracks. Then you put your own grip on the stick and, with a yell, yank it to the side, lifting its owner from her feet and throwing her in the air. But the Mistress does not relent: the staff becomes electrified as soon as it leaves her grasp, the shock forcing you to let go, and 
				*label flies_to_her
				it immediately flies back into her hands. She somersaults to catch it and, still in the air, thrusts the rod three times into nothingness. 
				
				*goto charge_of_generals
			*else
				… and are unable to contend with the power of the blow. The staff breaks through your guard and strikes your head, toppling you to the ground. 
				*label hit_by_staff
				*gosub_scene subroutines reduce_health 5
				The Mistress raises her rod again and slams it for the second time: but now, you roll to the side and avoid the attack, kicking the staff out of her grasp. However,
				*goto flies_to_her
		*else
			The first challenge is withstanding the terrible heat: and it already proves to be too much. 
			*label fire_roasts
			The fire [i]roasts[/i] you alive, your skin charring in an instant.
			*gosub_scene subroutines reduce_health 10
			And when the Mistress strikes, her staff breaks through your guard and hits your head, toppling you to the ground.
			*goto hit_by_staff

*label charge_of_generals

"[b]Demonic Summon Staff Art — Charge of Three Demon Generals![/b]"

Three streams of black, demonic flames appear at the locations of her stab: they soon transform, from shapeless fire to three burning, monstrous heads. The horned heads then scream, a high-pitched, shrieking sound, and charge at you, clanking their teeth. The Mistress follows right behind, already swinging her staff.

*choice
	#Dissipate the flames with your fists.
		You take a deep breath and when the heads come at you, their mouths lusting for your flesh, you blast them with heavy punches:
		
		*gosub_scene subroutines f_stat_check "con" "str" 1
		*if (stat_check)
			You disregard the heat and smash your knuckles into the first head's blazing face…
			*gosub_scene subroutines f_stat_check "str" "str" 1
			*if (stat_check)
				It crumbles under the sheer force of your blow, dissipating into harmless mist with a ear-bursting scream of agony. Then, you flip over the rest of the heads. And, while they are trying to turn and find you again, you slam them in the back with a double-palm strike, convicting them to suffer the same fate of total vanishing.
				*label when_the_mistress
				When the Mistress herself arrives, her staff already having traveled half-way through the arc required to hit your temple, you block the rod with your arm and punch her in the chest. To your surprise, however, the punch does no damage at all: instead, her red suit [i]shimmers[/i] and the Little Demon Queen continues, not even slowed down. She twists her metal rod and strikes upwards, hitting you under the chin. You are sent flying, staggered and confused. At this moment, however, the Golden Seed sends a pulse of light that clears up your consciousness — you land on your arms and, even before your legs touch the ground, you push yourself back like an unbreakable spring. Your feet hit the Mistress's solar plexus and this time the attack proves to be too potent for the suit to absorb. 
				*label knocked_out_breath
				She takes a few steps back, having trouble recovering her knocked out breath.

				*goto hurt_mistress
			*else
				But, although rattled, the head still persists in its charge, mouth open wide. And the rest of them follow as well.
				*goto bad_burn
		*else
			*goto bad_burn
	#Try to evade them.
		You masterfully step out of the heads' way, evading them with jumps and dodges: before you can rush forward and retaliate, however, the Golden Seed screams of an acute, distressing danger from behind: you turn around, only to realize that the heads are [i]intelligent[/i] and have adjusted their path, mere moments from colliding with the caught-off guard you. 
		*label raise_a_block
		Having no time to think of anything else, you raise a block and hope for the best as the three attacks slams into you at once…
		
		*gosub_scene subroutines f_stat_check "con" "str" 3
		*if (stat_check)
			You skin is unable to withstand the terrifying heat: it burns, burns until nothing is left. The heads sink their blazing teeth into the bare muscle, 	piercing almost to the bone. You yell in agony as they chew, infusing fire into your flesh. 
			
			*gosub_scene subroutines reduce_health 10
			*label you_withstand
			But you withstand it. You endure it. Once the heads dissipate, you are still standing and, despite their ugly, disfigured appearance, your hands still work. 
			*goto when_the_mistress
		*else
			*label bad_burn
			You skin is unable to withstand the terrifying heat: it burns, burns until nothing is left. The heads sink their blazing teeth into the bare muscle, 	piercing almost to the bone. You yell in agony as they chew, infusing fire into your flesh. 
			
			It hurts. IT HURTS.
			*gosub_scene subroutines reduce_health 15
			*goto you_withstand
			
	#Trick the heads into attacking each other.
		You carefully calculate the trajectory of the heads and…
		*gosub_scene subroutines stat_check "int" 20
		*if (stat_check)
			… form a plan inside your mind: when the first fiery face reaches its blazing teeth towards your neck, you flip over it…
			*gosub_scene subroutines f_stat_check "agi" "agi" 1
			*if (stat_check)
				… and fall before the two remaining ones. They leap you at the same time and, for a second, you wait — wait for the head behind you to turn around and pounce at you as well. Then, just at the perfect timing, you jump up and all the heads collide, their flames devouring each other without any distinction whatsoever. 
				
				*goto when_the_mistress
			*else
				… and are not fast enough to avoid collision.
				*goto raise_a_block
		*else
			… fail to calculate the plan before the heads collide with you.
			*goto raise_a_block
	#Use Golden Seed.
		*set used_dao +1
		You plant your feet wide and cross your palms before you [i]push[/i], activating the Golden Seed inside your mind. A golden barrier forms from your palms, one tall and wide enough to cover you whole — and as the heads slam into this impenetrable shell, they dissipate without even causing a shake.
		
		When the Mistress herself arrives, her staff already having traveled half-way through the arc required to hit your temple, the barrier stop its dead as well. You snort, dispel the golden shell, and kick her right above the stomach. 
		*goto knocked_out_breath

*label hurt_mistress
You leap to her, while she's still recovering her senses and…

*choice
	#Punch her in the face.
		… wind up your arm for a powerful punch. At first, she doesn't even try to dodge, too preoccupied with her own pain. But when she finally raises her head and realizes her situation, for some reason, you see a mocking glint flicker in her eyes. 
		
		When your fist hits her mask, it's you who's hurt: the mask appears to be made of something a hundreds time harder than steel and striking with such immense force has left your hand bruised and knuckles at the verge of breaking.
		
		She snickers and and thrusts her staff into your gut.
		*gosub_scene subroutines reduce_health 6
		
		You quickly disengage, dodging two more swings on your way out. 
	#Kick at her knee.
		… kick at her knee, causing her to groan and fall down. Before you can follow up, though, she shakes her head to get out of the daze and sweeps your leg with her staff, bringing you to the ground as well. She then attempts another swing, but you shove her off with your legs and disengage. 
	#Use Golden Seed.
		*set used_dao +1
		*if (used_dao = 2)
			Once again, you call upon the Golden Seed — and it answers, but, for a barely noticeable split of a second, your vision blurs from the mental exhaustion. You can feel your concentration waning, your awareness diminish: at most, you can use the Seed one more time before risking falling into the unconsciousness. 
		*else
			You call upon the Golden Seed — and it answers.
		
		You smash your palm into her body: her chest [i]caves in[/i] and your hand almost comes out on the other side of her flesh. The Mistress is thrown back, soaring without any semblance of control, and crashes into a wall. She struggles to get up, the eyes behind the mask reflecting unprecedented shock as she coughs out blood.
		
		Not wanting to let this opportunity go, you to try to follow up: but the Mistress, holding onto her broken ribs, throws the metal rod at you to stop you from coming close.
		
		"[b]Demonic Summon Staff Art — Hellknight's rage!"
		
		The staff transforms into a giant winged knight, wearing monstrous armor and armed with a flaming spear. The knight lets out a war cry as it charges at you, driving his weapon at your heart. Left without a choice, you jump to the side to avoid the dangerous stab. The knight then disappears, as if he was never there, and the now turned back staff flies into the Mistress's hand.  
		
		During this time, the Little Demon Queen has taken out a talisman from her ring and burnt the magical paper into ash. It shined onto her with a green, healing light, and she returned to her feet, looking unharmed. 
		
		But you know: she's hurt.
		
		"I have no idea what that was." — the the Mistress says — "But I doubt you can do it again."
		
		[b]You've wounded the Mistress. She will be slower, weaker and easier to injure.[/b]
		
		*set fight_difficulty -2

*page_break
*label you_stare
You stare at each other, both unwilling and unable to admit defeat. Despite the intense previous exchange, your opponent still is full of vigor: you wonder how much Inner Energy she has left, because the skills she used were anything but thrifty. 

"Look at you." — the Mistress mocks — "So proud of yourself for lasting this long against those pompous, flashy and useless skills. Fine. I've had my fun. I'll let you see the real Mistress, the true inheritor of the all-powerful Flesh Stealing Emperor!"

She rips off her clothes, but the expected sight of naked skin is absent: what meets your eye, instead, is a blood-red amalgamation of pulsating flesh. With every Mistress's breath, her body oozes disgusting yellow goo. The gunk pours to the floor and, akin to acid, burns holes inside the stone. 

Next, the Mistress removes her mask. That burned, disfigured face it still the same — only now, she opens her mouth wide and, with an inhuman sound, four more sets of sharp, deadly fangs grow in her maw. Looking at them closely, every tooth is not a single entity. It's a sum of human canines glued together, differing in both thickness and color. 

Her eyes lose their pupils, the whites turn into solid red. Her arms and legs shed their human skin, assuming the same monstrous appearance, while her fingers become elongated claws. Finally, to conclude her transformation, a pair of bat-like leather wings sprout from her back. 

What frightens you the most, however, is that the Mistress has not used any Martial Art. Her current state is not a skill, not an effect of a ridiculous artifact: no, this is her, the [i]real[/i] her. 

Just what kind of torture did she subject herself to?
*choice
	#Continue.
		*goto wings_flap
	#[i]Abilities/Items[/i]. 
		*gosub_scene skill_menu
		*goto you_stare

*label wings_flap
*page_break The Wings Flap
The Mistress flaps her wings and soars. You can only look up as she circles above you, hovering half a dozen feet above your head. But you don't have to wait long for her to come down: with a shriek, she flies down, her claws reaching for your throat. 

*choice
	#Grab her arm and throw her to the ground.
		*gosub_scene subroutines f_stat_check "str" "str" 2
		*if (stat_check)
			You lean your body as she swipes her inhuman hand at you and catch her wrist when she tries to pull it back. Then, you step closer and twist your hip, throwing the monstrous Mistress to the ground with a loud thud. 
			*label refuses_to_stay_down
			But she refuses to stay down, 
			*label stabbing_toes
			stabbing her razor-like toes into your gut, grabbing your shoulders and throwing you over herself.
			
			*gosub_scene subroutines reduce_health 2
			Your positions now reversed, she opens her grotesque mouth and bites into your neck. You stuck your hands in-between her teeth, as if she was a rabid dog, and struggle to prevent her jaw from closing and chewing on your flesh.
			*gosub_scene subroutines f_stat_check "str" "str" 3
			*if (stat_check)
				She thrashes from side to side, her head flailing about wildly, but you persist and headbutt her in the nose. 
				*label dazzling_her
				Having dazzled her for a second, you grip her close and continue smashing your forehead into her face. 
				
				After a few of such attacks, the Mistress recovers and pushes you off, flapping her wings to get away. She wipes the blood — a mix of your and hers — dirtying her eyes and licks her hand, smiling in ecstasy. 
				
				"[b]More.[/b]" — a dreadful, fiendish voice rings out from the Mistress — "[b]I want more.[/b]" 
			*else
				Unable to keep her away, you remove your hands in fear of losing your fingers — and let the Mistress bite off a chunk of your neck.
				*gosub_scene subroutines reduce_health 10
				She swallows it and chortles in satisfaction. Using her distraction, you headbutt her in the nose.
				*goto dazzling_her
		*else
			You lean your body as she swipes her inhuman hand at you and catch her wrist when she tries to pull it back. However, as you step closer and twist your hip, the Mistress manages to rip apart the flesh on your spine before you can throw her to the ground. She refuses to stay down too,
			*goto stabbing_toes
	#Dive between her legs.
		*gosub_scene subroutines f_stat_check "agi" "agi" 2
		*if (stat_check)
			Just as she swipes her claws, you dive between her legs. The Mistress misses and you elbow her in the back, causing her to crash into the ground.			
			*goto refuses_to_stay_down
		*else
			Just as she swipes her claws, you dive between her legs — but the Mistress still catches you and rips apart the flesh on your spine.
			
			*gosub_scene subroutines reduce_health 5
			You ignore the wound and elbow her in the baсk, causing her to crash into the ground.
			*goto refuses_to_stay_down
	#Use Golden Seed.
		*set used_dao +1
		With a thought, you [i]disappear[/i]. Vanish into the void, to your absolute delight finding out that you don't even have to take a step to perform this move. Once behind the Mistress, you slam your palm into your back and the monstrous creature crashes into the ground.
		*goto refuses_to_stay_down

"[b]Flesh Stealing Mantra — Uncontrollable Fear![/b]

The Mistress grows. Twice her previous size, thrice… ten times! Another pair of wings sprouts from her back, another horned head from her neck, another pair of arms. Her aura raises in its potency, from a level comparable to a Late-Houtian to a realm you do not dare to imagine. The amount of Inner Energy she emanates drowns your senses in its endless capacity. 

A red glint flashes in her eyes, a flicker of light that sends a shiver straight into your soul.

What… what the hell is this? How are you supposed to fight this?! No, no, you need to run away, you need to escape…. 

*choice
	*selectable_if (mc_int >= 30) #Something's off.
		Wait. If she grew to ten times her previous size, reaching a height of more than fifty feet… how does she still fit inside this room? There's no way the ceiling would've been raised to accommodate her transformation…

		The illusion shatters. 
		*label just_in_time
		Just in time too, because the Little Demon Queen is almost done shoving her hand into your chest. You quickly strike her wrist away and erupt with anger for being tricked.
		
		*label first_angry_punch
		Your first punch doesn't produce much of an impact. Her head turns a bit to the side and she stumbles, that's all — but you do not plan to stop. 
		
		One after another, you pummel her face with your knuckles. She retaliates in kind, lashing out with her claws.
		
		*gosub_scene subroutines f_stat_check "agi" "agi" 4
		*if (stat_check)
			But you're faster, as you manage to evade her every blow by masterfully side-stepping her strikes. You continue your onslaught, eventually 
			*label grabbing_back_head
			grabbing the back of her head, pulling it down and attacking with your knees. Thrice your bash her skull, before the Mistress digs her finger-blades into your sides.
			
			*gosub_scene subroutines reduce_health 10
			You still refuse to stop. Gritting your teeth, you kick her in the stomach and follow her flying figure, air-punching her in the mouth. Some of those perverse teeth shatter from the force of your fist and, as the Mistress spits the fragments out, you grip her neck and lift her up. 
			
			Yet, pressed against a wall with her face a bloody, broken mess, the Mistress gives you an excited, energized smile. Her legs wrap around your waist and she drags you closer. Laughing maniacally, she grins:
			
			"[b]Flesh Stealing Mantra — Vitality Transmission![/b]"
			
			Her tongue shimmers and retracts, a hairy tentacle crawling from the depth of her throat to replace it. With a vomit-like, spewing sound the tentacle leaps from the Mistress's mouth and latches onto your chest. Its hairs stab into your skin, penetrating your flesh, and start producing suction noises. 
			
			*gosub_scene subroutines reduce_health 5
			*label tentacle_detached
			The tentacle cannot be detached: you pull it, yank it, punch it, it's still stuck no matter what you do. It drains and drains, transfusing your blood and strength into your enemy.
			
			Her wounds heal. Her bruises fade. Her teeth regrow. If this goes on, she'll only need a minute to be back to her peak again!
			
			*choice
				#Kill her before she kills you.
					Fine! Let's see who wins in the end, your fists or her tentacle! 
					
					*gosub_scene subroutines f_stat_check_double "con" "str" "str" 5
					*if (stat_check)
						Although the tentacle weakens you greatly, causing your knees to buckles and making it a struggle to stand straight, you [i]will[/i] yourself to continue. You punch with the intention of blowing a hole in her head, putting your everything into every attack. 
						
						*label heals_at_your_expense
						
						*gosub_scene subroutines reduce_health 5
						Although the Mistress heals at your expense, her rate of regeneration is not enough to keep up with the damage you inflict. As her skull bursts apart and you begin to pound her cerebrum directly, the tentacle slows down. Its absorption slows down, and as the Mistress's body softens and she herself collapses, the tentacle falls down limp as well.
						
						You drop to your knees next to the Little Demon Queen, her wrecked face covered in the smeared brains staring straight at you. 
						*label not_breathing
						She's not breathing anymore, not moving, but you still can't feel at ease. 
						
						Looking down, you see the dozens of minuscule holes inside your chest. They bleed heavily, and your other injuries are far from light too. Your exhaustion is palpable, your entire body burning in tired agony. 
						
						Struggling, you put a palm on the ground to help yourself stand. First things first: you must make sure that this abomination of a Martial Artist never bothers you again. 
						
						With one hand, you grab her jaw, with the other — press down on her shoulders, ready to ready to separate the head from body and end it once and for all.
						
						But the Mistress's stomach suddenly bulges and explodes, covering you in yellow, stone-searing acid. 
						
						*gosub_scene subroutines reduce_health 5
						
						When you open your eyes again, most of your skin corroded by the blast, the Mistress is nowhere to be found. Only a pool of blood remains where she once laid, but you have no idea whether she evaporated into nothingness or somehow managed to escape. 
						
						Thankfully, those symbols on the walls have dimmed and you can leave this damned place, never to return. 
						
						*page_break
						*goto end_event
					*else
						The tentacle sucks you of your strength, the hairs drilling deep inside.
						*gosub_scene subroutines reduce_health 10
						And yet… you [i]will[/i] yourself to continue. You [i]will[/i] yourself to stand, punching the Mistress with the intention of blowing a hole in her head, putting your everything into every attack. 
						
						*goto heals_at_your_expense						
				#Use Golden Seed.
					*set used_dao +1
					*if used_dao > 3
						You call upon the Golden Seed, but its too much for your feeble mind to handle.
						
						You have overexerted yourself. You have made a mistake that will cost you your life and now, you will pay the price.
						
						*goto_scene game_over
					Imbuing your hand with the mysterious power, you chop at the tentacle — and cut it in half. It falls to the ground, splashing black, void-colored blood. The Mistress screams in soul-crushing pain and collapses, desperately touching the tentacle's remnant still sprouting from her mouth. You do not give her a chance to pull anymore tricks: you pummel her head, putting your everything into each attack. Her skull eventually bursts apart and you drop to your knees, the Little Demon Queen's wrecked face covered in the smeared brains staring straight at you.
					*goto not_breathing
				#[i]Abilities/Items[/i]. 
					*gosub_scene skill_menu
					*goto tentacle_detached
		*else
			In your rampaging state, you don't have the presence of mind to dodge: the blades lacerate your neck and shoulders…
			*gosub_scene subroutines reduce_health 5
			… but you don't care,
			*goto grabbing_back_head
	#Use Golden Seed.
		*set used_dao +1
		*if used_dao > 3
			You call upon the Golden Seed, but its too much for your feeble mind to handle.

			You have overexerted yourself. You have made a mistake that will cost you your life and now, you will pay the price.

			*goto_scene game_over
		
		By instinct, you activate the Golden Seed: it fills your mind with golden, celestial light and… the illusion shatters. 
		*goto just_in_time
	#Succumb to fear.
		Unable to calm your nerves, you freeze: you can only helplessly watch as the Mistress steps close and, with her gigantic palm, crushes you into dust…
		
		You wake up from an unbearable sting of pain. The giantess disappears and, belatedly, you realize that it was all a mere illusion — but the hand that the Little Demon Queen has put through your chest, missing your heart by an inch, isn't.
		
		*gosub_scene subroutines reduce_health 15
		Having almost died due to a trick, you erupt with mind-shattering rage.
		*goto first_angry_punch
	
	
*label not_gone
*goto end_event

*label end_event
*page_break
*if expo_hyi_damage = "full"
	*set expo_army 0
	When you return to the tribe, you find Lei Xiwen standing among a sea of corpses. Just like in the Arrogant Tiger Tribe, no native was spared: hundreds of men, women and children lay dead on the street. Event the disciples you welcomed before have not avoided the calamity, their bodies placed in a separate row.
	
	*if (expo_yuanfang)
		The only one who has survived this purge is Yuan Fang, though he looks extremely pale and hurt.
	
	"I've positioned them in the way tradition back home requires." — Lei Xiwen says, his tone ice-cold — "That's the least I could do." 
	
	"What happened here?" — you ask, still trying to process the happenings — "Was it you?"
	
	*if (told_truth)
		"Of course not." — Xiwen replies — "It's the work of that 'Ro Hyi'. Or the Mistress. Or the Little Demon Queen, whatever you want to call that abomination of a human."

		"She purposely lead us both out on a wild goose chase and then came to the empty tribe, devastating it in our absence. Not only this tribe either, every tribe under our control has been wiped out. I suppose she had it planned already." — Xiwen explains, his brows furrowed — "In truth, when I realized I was tricked, I thought you were her target. I still believe so, but you must have done something to spook her and cause her to return and commit this atrocity instead." 
		
		"But why?" 
	*else
		"Of course not." — Xiwen replies — "Those twins you've captured, they have been set free by 'Ro Hyi'. Or, to call her by her name, the Mistress. Or the Little Demon Queen, whatever you want to call that abomination of a human."
		
		"She purposely lead us both out on a wild goose chase and, as soon as we were gone, the sisters poisoned the entire population of the tribe. Not only this tribe either, every tribe under our control has been wiped out." — Xiwen explains, his brows furrowed — "In truth, when I realized I was tricked, I thought you were her target. Judging by the fact that you're still alive, you must have managed to fend her off. Good job." 
		
		"But why… why do this?"
	
	"I don't know." — sighs Xiwen — "Out of frustration. Out of bloodthirsty cruelty. Out of some grandiose scheme to weaken our side in the clash against Long Chen. I don't know. Mind of someone like the Mistress is incomprehensible to me." 
	
	"What do we do now then?"
	
	"What can we do?" — Xiwen chuckles — "We wait for Long Chen to come and then surrender. There's no way for the two of us to fight both him and his army of Tattooed." 
	
	*if characters_4_opinion >= 70
		Just then, a swish of a sword cause both of your heads to turn north, a ragged, flying figure captivating your attention.
		
		The figure rides a large flying sword, but the usual sight of straight back and unperturbed gaze is absent: instead, the lofty and arrogant Prince is barely conscious and unable to stand on his own. When the sword reaches you, Tang Ruo attempts to jump off on his own — and falls down on his knees, coughing out blood while clutching onto his ribs. 
		
		Still, however, he chuckles and raises his bruised face to meet yours.
		
		"What if I lend a hand?"
		
		*ending
	*else
		"Give up? Just like that?"
		
		"There's no way for me to defeat Long Chen and there's no way for you to contend against his dozens of Tattooed. This is not a life and death battle, you should learn to retreat when outmatched."
		
		Unable to think of an argument, you sit down, letting the thought that all of your work during the expedition has been for naught.
		
		*ending
*elseif expo_hyi_damage = "partial"
	Grave news find you as soon as you wake up next morning. It seems that, during the night, Ro Hyi has set the assassin-sisters free and together they poisoned the tribe's food supply. Many of the tribesmen under your control died, but the damage was mainly limited to normal, non-Tattooed natives. Those proved to be too resilient for such a common poison and, since you didn't fall for Ro Hyi's scheme, the masked disciple didn't have time to do anything else.
	
	An hour later, you meet with Xiwen and he explains the situation to you in more detail.
	
	"Turns out that 'Ro Hyi' is an extremely fearsome character of the Havoc Sect." — he says — "She's someone called 'the Mistress' or 'the Little Demon Queen' due to her bloodthirsty nature and formidable strength. Despite being a Middle-Houtian, she has slain enemies a stage above her in an open fight and has, once, even schemed a Peak-Houtian equivalent to me in power to death."
	
	"She's cunning, ruthless and unpredictable. Her goal was probably you, due to that bounty list, but you have managed to evade her carefully woven web of plots. Even I was tricked, so I have to praise you for your insight." 
	
	*label what_are_our_loses
	
	"What are our losses?" — you ask.
	
	"Although the death of many is regrettable, our combat strength remains the same. We are also guarding against that Havoc trio now, so this situation will not occur again." 
	
	"But…" — Lei Xiwen sighs — "Even with the two of us and our army of Tattoed, fighting against Long Chen will be nigh-impossible." 
	
	*label ruo_arrives
	
	*if characters_4_opinion >= 70
		Just then, a swish of a sword cause both of your heads to turn north, a ragged, flying figure captivating your attention.
		
		The figure rides a large flying sword, but the usual sight of straight back and unperturbed gaze is absent: instead, the lofty and arrogant Prince is barely conscious and unable to stand on his own. When the sword reaches you, Tang Ruo attempts to jump off on his own — and falls down on his knees, coughing out blood while clutching onto his ribs. 
		
		Still, however, he chuckles and raises his bruised face to meet yours.
		
		"What if I lend a hand?"
	
	*ending
*elsif expo_hyi_damage = "nothing"
	When you wake up next morning, you find out that Ro Hyi is nowhere to be found. The explanation for his disappearance, however, is much more devious than you initially imagined:

	"Turns out that 'Ro Hyi' is an extremely fearsome character of the Havoc Sect." — says Lei Xiwen — "She's someone called 'the Mistress' or 'the Little Demon Queen' due to her bloodthirsty nature and formidable strength. Despite being a Middle-Houtian, she has slain enemies a stage above her in an open fight and has, once, even schemed a Peak-Houtian equivalent to me in power to death."
	
	"She's cunning, ruthless and unpredictable. Her goal was probably you, due to that bounty list, but you have managed to evade her carefully woven web of plots. Even I was tricked, so I have to praise you for your insight." 
	
	*label even_with_two

	"But…" — Lei Xiwen sighs — "Even with the two of us and our army of Tattoed, fighting against Long Chen will be nigh-impossible." 
	
	*goto ruo_arrives
*elseif expo_hyi_damage = "partial_knows_mistress"
	Grave news find you as soon as you wake up next morning. It seems that, during the night, assassin-sisters that were freed by the Mistress had poisoned the tribe's food supply. Many of the tribesmen under your control died, but the damage was mainly limited to normal, non-Tattooed natives. Those proved to be too resilient for such a common poison and, since you gravely injured the Little Demon Queen during your fight, the twins could not do anything else by themselves. 
	
	An hour later, you meet with Xiwen to talk about your current situation.
	
	*goto what_are_our_loses
*elseif expo_hyi_damage = "nothing_knows_mistress"
	Next morning, Lei Xiwen finds you for a chat.
	
	"Good job coming back alive." — he praises — "I learned about the Mistress last night. It's good you managed to get out of her trap and killed off her subordinates beforehand. Who knows what would've happened if you didn't."
	
	*goto even_with_two
	
	
	
*ending