*page_break
*label new_day
*gosub_scene subroutines heal_injuries_weekly 1
*set expo_date +1
*temp letter_arrogant 0
*temp letter_friendly 0
*temp letter_neutral 0
*temp goshan_asked 0
*temp expo_tribemap false

*label expo_free
*if expo_date = 1
	The first thing you decide to do, is find Goshan to inquire him about the other tribes in the vicinity.
	
	He is in the Tribe Hall, reading some kind of an ancient book. Hearing you approach, he closes it and sets the tome aside. 

	*label goshan_questions
	*if goshan_asked = 0
		"Greetings, Apostle." — he says — "How can I be of service?" 
	*else
		"Anything else?"
	*choice
		*hide_reuse #"Tell me about the tribes nearby."
			*set expo_tribemap true
			*set goshan_asked+1
			"Tell me about the tribes nearby."

			Goshan nods and stands up.

			"Please, give me a minute." 

			He walks over to another room and returns soon after, holding an old, yellowed out map. Goshan plasters it on the floor and gets on his knees.

			"There are three tribes near us." — he says, his palm moving to the north of the map — "First one, is Deadly Serpent Tribe. They possess numbers about equal with us, but their warriors are not suited for open battles. They prefer the darkness of the night, sneaking through the bushes and stabbing their enemies in the back, instead of facing them head-on. Whenever we faced them in the past, we always came out on top."

			"Second is the Rushing Bull Tribe, an exact opposite to the Serpents. They are dumb brutes, very strong and aggressive, but lacking in any sort of smarts or subtlety. They also numbers lower than ours by a hundred or two, their savage nature taking its toll."

			"The last one would be, I believe, the most difficult one to conquer. Arrogant Tiger Tribe has the fewest members, merely a hundred, but each one of them is a Tattooed Warrior wielding inhuman power. Individually, they may not be as strong as Kuku was before your battle, but they are not far off either."

			"You should proceed with cautions. We have encountered the a few times recently and the outcomes… were always disastrous."

			*page_break
			*goto goshan_questions
		*hide_reuse #"Can you tell me more about this world?"
			*set goshan_asked +1
			"Can you tell me more about this world?"

			"I can," — Goshan replies — "But there's not much to tell."

			"Our ancestors were brought into this world thousands of years ago. The scriptures say, they were the most devoted followers of the Volcano God, which is why they were tasked with the mission of such great importance — to protect the sleeping God and prepare for his inevitable rise." 

			"To achieve that, generations have been raised on nothing but war alone. Men, women, children, elderly: everyone fights, honing their skills in battle, hoping that  they would the ones to take part in the Ascension, that they would the ones to help wake the Volcano God and return our people into the main world."

			"Main world…" — you mutter — "What do you know of it?" 

			"Not a lot." — Goshan says, his eyes glowing with excitement — "Except for its name. [i]Celestial Empire[/i]! So prideful and majestic!"
			*page_break
			*goto goshan_questions
		*hide_reuse #"Can you tell me more about the relics?"
			*set goshan_asked +1
			"These relics you've mentioned before… can you tell me more?"

			"When our people first got here, the Volcano God divided us into twenty tribes. For each tribe, he assigned a tribe leader — a Goshan, a Sacrificial Warrior and a Protector, a beast of unmeasurable power. The protectors watch over us, making sure we stick to the divine rules, but their main goal is to protect the pieces of the sacred relic. They keep it safe, waiting for the outsiders to come and unite the fragments into a key that will unseal the Volcano God." 

			"The scriptures say, after you, by one way or another, conquer a tribe, the Protector must give you the relic as well. They also say, if you manage to kill or subdue the holy one of the the tribe, the fragment, by right, is yours as well." 

			*page_break
			*goto goshan_questions
		#"That's all."
			*goto new_day

*elsif expo_date = 2
	*goto_scene expedition_YF_arrives

*elsif expo_date = 3
	There are three tribes — tribe of the Deadly Serpent, of the Rushing Bull and of the Invisible Tiger — nearby. You should deal with them, before you can look to expand your tribe further. 
	
	From what you know, the Rushing Bull Tribe should be easiest for you to tackle, so it's only natural for it to serve as your first target.
	
	You gather a few of the hunters of your own settlement, trusting them with an important mission: scout the surroundings of the Rushing Bull Tribe and return back with all the valuable information that they can gain.
	
	*page_break
	*goto_scene expedition_free
*elsif expo_date = 4
	*goto_scene expedition_first_training
*elsif expo_date = 5
	*if (lushu_alive)
		*goto_scene expedition_lushu_first
	*else
		*goto new_day
*elseif expo_date = 6
	*temp letter_greetings "[i]"
	*temp letter_body1 "[i]"
	*temp letter_body2 "[i]"
	*temp letter_farewell "[i]"
	*temp letter_part 0
	The scouting party you've sent out to gather intelligence on the Rushing Bull Tribe has returned, without losses and bearing good news.
	
	The Rushing Bull Tribe seems to be true to its name: their members are reckless and straightforward, lacking vigilance. The five scouts have managed to not just establish the exact numbers of the tribe, they even found out the tribe leader's identity. 
	
	There are eleven Tattooed Warriors in the tribe — the rest of the warriors are of no concern to you, for Mortals can hardly hurt you even in big crowds. Similar to you, another Martial Artist have taken control of the natives, a man named
	*if (characters_10_alive)
		*set leader_name "Fu Bing"
		Fu Bing. He's a member of your sect and you've met him before, during the entry tournament.
	*else
		*set leader_name "Cho Chun"
		Cho Chun, a member of your sect but someone whom you've not interacted with before.
	
	Since you are fellow disciples, you could try and settle the matter peacefully. A letter with the situation clearly explained should be enough. After all, apart from Tang Ruo, hardly anyone from the Heavenly Ascension Sect would go against you. 
	
	Then again, there are always more… violent approaches.
	*label bulltribe_approach
	*choice
		*hide_reuse #Send a letter.
			Settling on a diplomatic approach, you take out a scroll from your spatial ring and start writing…
			*label compose_letter
			${letter_greetings}
			
			${letter_body1}
			${letter_body2}
			
			${letter_farewell}
			*if letter_part = 0
				*choice
					#[i]Greetings, Martial Brother Bing,[/i]
						*set letter_friendly +1
						*set letter_greetings  &"Greetings, Martial Brother Bing,"
					#[i]${leader_name},[/i]
						*set letter_neutral +1
						*set letter_greetings &leader_name
					#[i]Listen up, dog,[/i]
						*set letter_arrogant +1
						*set letter_greetings &"Listen up, dog,"
				*set letter_part +1
				*goto compose_letter
			*elseif letter_part = 1
				*choice
					#[i]I won't waste ink on a trash like you.[/i]
						*set letter_arrogant +1
						*set letter_body1 &"I won't waste ink on a trash like you."
					#[i]I'll cut straight to the point.[/i]
						*set letter_neutral +1
						*set letter_body1 &"I'll cut straight to the point."
					#[i]It's good meeting you again. I've heard about your impressive accomplishment, conquering a whole tribe in such a short amount of time, and applaud you for it.[/i]
						*set letter_friendly +1
						*set letter_body1 &"It's good meeting you again. I've heard about your impressive accomplishment, conquering a whole tribe in such a short amount of time, and applaud you for it."
				*set letter_part +1
				*goto compose_letter
			*elseif letter_part = 2
				*choice
					#[i]We both know the goal of this Zone, so what would it take for you to relinquish your key fragment into my possession? I'm open to negotiation.[/i]
						*set letter_neutral +1
						*set letter_body2 &"We both know the goal of this Zone, so what would it take for you to relinquish your key fragment into my possession? I'm open to negotiation."
					#[i]I'm giving you one day to surrender the tribe to me, before I come and beat you senseless.[/i]
						*set letter_arrogant +1
						*set letter_body2 &"I'm giving you one day to surrender the tribe to me, before I come and beat you senseless."
					#[i]The goal of this Zone is clear and to achieve it, we must work together. Junior Brother, how about joining with me? I'll lead us to victory and will ensure that you get your share of the reward.[/i]
						*set letter_friendly +1
						*set letter_body2 &"The goal of this Zone is clear and to achieve it, we must work together. Junior Brother, how about joining with me? I'll lead us to victory and will ensure that you get your share of the reward."
				*set letter_part +1
				*goto compose_letter
			*elseif letter_part = 3
				*choice
					#[i]Sincerely, your Senior ${polite_address} ${mc_name}.[/i]
						*set letter_friendly +1
						*set letter_farewell &"Sincerely, your Senior ${polite_address} ${mc_name}."
					#[i]${mc_surname} ${mc_name}.[/i]
						*set letter_neutral +1
						*set letter_farewell &"${mc_surname} ${mc_name}."
					#[i]Your Grandpa, Big ${mc_name}.[/i]
						*set letter_arrogant +1
						*set letter_farewell &"Your Grandpa, Big ${mc_name}"
				
				${letter_greetings}

				${letter_body1}
				${letter_body2}

				${letter_farewell}[/i]
				
				Do you want to sent this letter?
				*choice
					#Yes.
						You put the letter into a special envelope and seal it with a drop of your blood — confirming this way its authenticity. Then, you call for one of the scouts and hand him the paper, as well as the instructions on what to do with them. 
						
						Now you'll have wait for the ${leader_name}'s response.
						
						*goto bull_letter_response
					#No, rewrite.
						*set letter_part 0
						*set letter_greetings ""
						*set letter_farewell ""
						*set letter_body1 ""
						*set letter_body2 ""
						*goto compose_letter
		#Prepare your warriors for a frontal assault.
			A frontal, direct assault is the most guaranteed to have success: your numbers are higher and you yourself are much stronger than ${leader_name}. The chance of failure is low, but, on the other hand, there's a high probability of some of your warriors dying during the battle. 
			
			*choice
				#Proceed
					*goto_scene expedition_rushing_bull assault
				#Do something else.
					*goto bulltribe_approach
		*hide_reuse #Infiltrate the Rushing Bull tribe.
			*comment *if (no_energy_concealment)
			*comment Since the tribe is lead by another Martial Artist, it would be pointless to infiltrate it without the Energy Concealment technique — you'd be sensed as soon as you step foot into the tribe.
			*comment You'll have to find another way.
			*comment 				*goto bulltribe_approach
			Infiltrating the tribe on your own carries a great risk. If you're found out, you'll be alone, surrounded by enemies — no matter how strong you are, fighting against a dozen Houtian-level opponents would be almost suicidal.
			
			On the other hand, it also holds potential for the best outcome: you could overtake the tribe, or steal their key fragment at the very least, without risking your own warriors. They would be better saved for more important and more difficult battles.
			
			*if (expo_yuanfang)
				Yuan Fang won't be much of help in this matter either: his giant, miscolored body is far too attention grabbing.
			
			*choice
				#Proceed.
					*goto_scene expedition_rushing_bull sneak
				#Do something else.
					*goto bulltribe_approach
*elseif expo_date = 7
	*goto_scene expedition_first_dream
*elseif expo_date = 8
	*goto_scene expedition_xiwen_arrival
*elseif expo_date = 9
	*if expo_xiwen = "captured"
		*goto_scene expedition_captured
	*else
		*goto_scene expedition_new_tribes
*elseif expo_date = 10
	*goto_scene expedition_meditation
*elseif expo_date = 11
	*goto_scene expedition_disturbance
*elseif expo_date = 12
	*if (expo_disciples)
		*goto_scene expedition_disciples_clash
	*else
		*goto new_day
*elseif expo_date = 13
	*if (expo_disciples)
		*goto_scene expedition_second_dream
	*else
		*goto new_day
*elseif expo_date = 14
	*if (expo_disciples)
		*goto_scene expedition_hyi_fight
	*else
		*goto new_day
*elseif expo_date = 15
	*goto expedition_third_dream
*elseif expo_date = 16
	*goto expedition_save_tigress
*else
	*label end_game
	[b]You've reached the limit of the current demo. Thanks for playing![/b]

	[b]Big thanks to all my patrons for their support. Especially:
	*line_break
	[i]fakethan[/i]
	*line_break
	[i]Meryllias[/i]
	*line_break
	[i]TheCycleBeginsAnew[/i]
	*line_break
	[i]Zedboredom[/i]
	*line_break
	[i]LordRaijin[/i]
	*line_break
	[i]Bax0R TaLp[/i]
	*line_break
	[i]darklight668[/i]
	*line_break
	[i]Saisho[/i]
	*line_break
	[i]0roxson0[/i]
	*line_break
	[i]Emily[/i]
	*line_break
	[i]SMacPhaidin[/i]
	*line_break
	[i]sometimes lol[/i]
	*line_break
	[i]Clayton[/i]
	*line_break
	[i]CJ[/i]
	*line_break
	[i]Chan Nguk Lan[/i]
	*line_break
	[i]Blank[/i]
	*line_break
	[i]Blanky[/i]
	*line_break
	[i]Age[/i]
	*line_break
	[i]Crispy Bacon[/i]
	*line_break
	[i]Glenda[/i]
	*line_break
	[i]Maximilian[/i]
	*line_break
	[i]Saisho[/i]
	*line_break
	[i]Tau Katungi[/i]
	*line_break
	[i]TechNote[/i]
	*line_break
	[i]Thrill[/i]
	*ending
*goto new_day
			
*label bull_letter_response
*set wrote_letter true
*page_break Wait...
*if letter_arrogant > 0
	*gosub_scene subroutines stat_check "prestige" (100*letter_arrogant)
	*if (stat_check)
		The reply arrives the next day, as the scout returns and presents you with another letter:
		
		[i]Greetings, Senior ${polite_address} ${mc_name}![/i]
		
		[i]You are a well-known and reputable figure of the sect, one of the leaders of the expedition. I will, of course, submit to your command and accept your guidance during this mission. The Rushing Bull Tribe is yours to do with as you please.[/i]
		
		[i]${leader_name}.[/i]
		
		*goto_scene expedition_rushing_bull peaceful
	*else
		The reply arrives the next day, only it's not the answer you've hoped for: the tribesman comes back beaten and bruised, limping and with a broken arm. He hands you a letter, before falling unconscious. 
		
		[i]You think I'm some dog you can order around? Fuck off![/i]
		
		One line is all it reads, but the attitude of your Martial brother is pretty clear.
		
		*label negative_bull_letter
		*choice
			#Tear the letter into shreds.
				In a fit of rage, you tear the letter into shreds. How does this punk dare act this way?! 
				
				You throw the pieces of paper to the side. It seems you'll need to teach someone a lesson.
				
				*goto bulltribe_approach
			#Laugh at the response.
				Seeing ${leader_name}'s response, you can't help but someone. You've been too low-key in the sect, it appears, if even a lowly disciple dares to refuse your request. 
				
				You'll need to rectify that.
				
				*goto bulltribe_approach
			#Calmly put the letter away.
				The result of the negotiations is unfortunate, but not unexpected. There's no need to get emotional over it, so you calmly put the letter away.
				
				*goto bulltribe_approach
*elsif ((letter_arrogant = 0) and (letter_neutral = 0))
	The reply arrives the next day, as the scout returns and presents you with another letter:
	
	[i]Greetings, ${polite_address} ${mc_name}![/i]
	
	[i]I'm pleased to hear your praise and am glad that you have reached out to settle this matter. As a junior, I will gladly relinquish command of the tribe to you in order to achieve our goal. I hope that when we meet again, Senior will give me some pointers over a cup of tea.[/i]
	
	[i]Appreciatively, ${leader_name}.[/i]
	*goto_scene expedition_rushing_bull peaceful
*else
	*if characters_10_opinion > 60
		The reply arrives the next day, as the scout returns and presents you with another letter:
		
		[i]Greetings, Senior ${polite_address} ${mc_name}![/i]
		
		[i]I'm pleased to hear from you again. As a junior, it's naturally my responsibility to aid you in accomplishing our sect's goal in this mission. Of course, I will relinquish control of the tribe to you.[/i]
		
		[i]Appreciatively, ${leader_name}.[/i]
		*goto_scene expedition_rushing_bull peaceful
	*elseif characters_10_opinion > 50
		The reply arrives the next day, as the scout returns and presents you with another letter:
		
		[i]Greetings, Senior ${polite_address} ${mc_name}![/i]
		
		[i]I'm glad to hear from you again. I'll be blunt with you: I spent a lot of effort taking control of this tribe and it will pain me greatly if my hard work was for naught. However, I understand the importance of our sect's mission and, if you're willing to compensate me with either gold or contribution points, I'll relinquish command of the tribe to you.[/i]
		
		[i]Appreciatively, ${leader_name}.[/i]
		*choice
			*selectable_if (mc_gold >= 10000) #Pay him 10,000 gold.
				*set mc_gold -10000
				You put your agreement into written words and the sect the scout to relay your answer.
				
				Your attempt at diplomacy have succeeded and unnecessary bloodshed has been avoided.
				*goto_scene expedition_rushing_bull peaceful
			*selectable_if (mc_sect_points >= 100) #Pay him 100 Points.
				*set mc_sect_points -100
				You put your agreement into written words and the sect the scout to relay your answer.				
				
				Your attempt at diplomacy have succeeded and unnecessary bloodshed has been avoided.
				*goto_scene expedition_rushing_bull peaceful
			#Refuse to compensate.
				You put your refusal into written words and send the scout to relay your answer. Shame that your attempt at diplomacy have failed — you'll have to figure out another way.
				
				*goto bulltribe_approach
	*else
		The reply arrives the next day, only it's not the answer you've hoped for:
		
		[i]Greetings, Senior ${polite_address} ${mc_name}![/i]
		
		[i]I'm glad to hear from you, but I, fear, I must offend you. I exerted a lot of effort  taking control of this tribe and it will be far too shameful for my hard work to go to waste. So, I must refuse your request.[/i]
		
		[i]As my senior, please forgive this junior his insolence.[/i]
		
		[i]Appreciatively, ${leader_name}.[/i]
		
		*goto negative_bull_letter


*goto new_day