*temp level_string ""
*temp grade_name ""
*if not (char_create_complete) 
	You must complete Character Creation in order to unlock this page. 
*else
	*goto statpage_opened
	
*label statpage_opened
*choice
	#Check Info.
		*goto statpage_info
	#Special.
		*choice
			#Tattoos.
				*goto tattoos_menu_show
			*if (mc_level >= 1)
				#Inner Energy Infusion.
					*if (not (energy_infusion))
						You rouse the dormant Inner Energy inside of you, fusing it with your flesh. A wave of power washes over, as every part of your body works beyond its normal limits.

						[b]All physical attributes increased by 10%. You will constantly spend Inner Energy until Infusion is toggled off.[/b]
						*set energy_infusion true
					*else
						You stop infusing Inner Energy into body.

						*set energy_infusion false
					*goto statpage_opened
			#Go back.
				*goto statpage_opened
	#Check Attributes.
		*label statpage_attributes
		*temp str_lvl ""
		*temp str_exp ""
		*temp agi_lvl ""
		*temp agi_exp ""
		*temp con_lvl ""
		*temp con_exp ""
		*temp end_lvl ""
		*temp end_exp ""
		*temp vit_lvl ""
		*temp vit_exp ""
		*temp per_lvl ""
		*temp per_exp ""
		*temp int_lvl ""
		*temp int_exp ""
		*temp chr_lvl ""
		*temp chr_exp ""
		*temp exp_left 0
		*if mc_level = 0
			[b]Current Martial Level:[/b] Mortal.
		*else
			*if mc_level = 1
				*set level_string "Early"
			*elsif mc_level = 2
				*set level_string "Middle"
			*elsif mc_level = 3
				*set level_string "Late"
			*elsif mc_level = 4
				*set level_string "Peak"
			[b]Current Martial Level:[/b] ${level_string}-Houtian.
		*line_break
		*gosub format_atr "str"
		*gosub format_atr "agi"
		*gosub format_atr "con"
		*gosub format_atr "vit"
		*gosub format_atr "per"
		*gosub format_atr "int"
		*gosub format_atr "chr"
		*gosub exp_until_increase "str"
		[b]Strength:[/b] ${mc_str} ([i]${str_lvl}[/i]) (${exp_left - mc_str_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "agi"
		[b]Agility:[/b] ${mc_agi} ([i]${agi_lvl}[/i]) (${exp_left - mc_agi_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "con"
		[b]Constitution:[/b] ${mc_con} ([i]${con_lvl}[/i]) (${exp_left - mc_con_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "vit"
		[b]Vitality:[/b] ${mc_vit} ([i]${vit_lvl}[/i]) (${exp_left - mc_vit_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "per"
		[b]Perception:[/b] ${mc_per} ([i]${per_lvl}[/i]) (${exp_left - mc_per_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "int"
		[b]Intelligence:[/b] ${mc_int} ([i]${int_lvl}[/i]) (${exp_left - mc_int_exp} EXP needed)
		*line_break
		*gosub exp_until_increase "chr"
		[b]Charisma:[/b] ${mc_chr} ([i]${chr_lvl}[/i]) (${exp_left - mc_chr_exp} EXP needed)
		*line_break
		*page_break Go Back
		*goto statpage_opened
	*if (not_under_construction) 
		#Check Personality.
			*label personality_opened
			[b]PERSONALITY:[/b]
			*stat_chart
				opposed_pair mc_pers_arrogant 
					Arrogant
					Humble
				opposed_pair mc_pers_elitist
					Elitist
					Equalitarian
				opposed_pair mc_pers_egoistical
					Egotistiical
					Selfless
				opposed_pair mc_pers_ruthless
					Ruthless
					Honorable
				opposed_pair mc_pers_manipulative
					Cunning
					Blunt
				opposed_pair mc_pers_impulsive
					Impulsive
					Rational
				opposed_pair mc_pers_violent
					Violent
					Irenic
				opposed_pair mc_pers_indulgent
					Indulgent
					Austere
			*choice
				#Explanation of personality stats.
					[b]Arrogance[/b]: Belief in your unabashed superiority over others, whether deserved or unfounded. 

					[b]Elitism[/b]: Belief that nobles are inherently better than commoners due to their divine blood.

					[b]Egoism[/b]: Valueness of yourself as someone whose wishes and desires are more important than the wants of others.

					[b]Ruthlessness[/b]: Willingness to use dirty tricks and despicable means to achieve your goals.

					[b]Cunningness[/b]: Willingness to lie and cheat in order to find success. 

					[b]Impulsiveness[/b]: Proneness to being overwhelmed by your own emotions, sacrificing rationality in favor of basic instincts.

					[b]Violence[/b]: Proneness to solving conflicts with your fists instead of words. 

					[b]Indulgence[/b]: Engagement in various debaucheries such as drinking and gambling.

					*page_break Go Back
					*goto personality_opened
				#Go back.
					*goto statpage_opened
	#Check Martial Arts.
		*label martskills_opened
		Which category do you wish to browse?
		*temp comp_level ""
		*choice
			#Offensive.
				*label offensive_opened
				*choice
					#Heaven Crushing Palm.
						[b]Martial Art:[/b] Heaven Crushing Palm.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						Developed by the Palm Crushing Celestial herself, this art has been the core technique of the Wu Clan since the start of the Martial Era. Wielded by the countless geniuses and prodigies, the Art has undergone countless enhancements and modifications and could be regarded as one the strongest Arts in the world — if your clan hadn't lost the original version two thousand years ago. All that remains now is a Top-Grade copy that can still hold its own in the Jianghu, but falls short against the real Transcendent Skills.

						Unleashes a Palm Strike with enough Inner Energy to bend metal and shatter bones to dust.

						[b]Comprehension:[/b]
						*gosub format_comprehension "offensive_1"


						*page_break Go Back
						*goto offensive_opened																
					#Sixty-Four Earth-Shattering Fists.
						[b]Martial Art:[/b] Sixty-Four Earth-Shattering Fists.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						A technique created by the son of the Wu Clan's Progenitor, Wu Huang, who has managed to reach the realm of Shangtian in merely three hundred years. An ambitious man, he has tried to replicate his mother's skill and even improve upon it. He wasn't as talented as he believed himself to be, however, and the result, although far from disappointing, could quite reach the [i]Transcendent[/i] standards.

						Allows the Martial Artist to punch up to sixty-four times in the time it takes them to to perform a single attack. 

						[b]Comprehension:[/b]
						*gosub format_comprehension "offensive_2"
						*page_break Go Back
						*goto offensive_opened
					#Extreme Demon Finger.
						[b]Martial Art:[/b] Extreme Demon Finger.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						Although Wu Clan specializes in the bare-handed techniques, not all of its expert had shared the same dislike towards weapons: one of them, a disgruntled Shangtian-level powerhouse, even developed an Art that combines both a finger and a blade into a single entity. The result turned out to be an utter success, a skill mighty enough that it could've become the Wu Clan's signature instead of the Heavenly Crushing Palm — if not for its atrocious and vicious requirement. The expert who developed it had no conception of the Sword Path, so he had took this knowledge from others. Took, in this case, meaning carved out their hearts and drained their blood.

						Imbues one of the Martial Artist's finger with sharpness akin to a keen blade — flesh can be sliced as if paper.

						This Skill is considered to be an [b]evil[/b] technique. Be careful on using it in public if you want to keep your reputation.

						[b]Comprehension:[/b]
						*gosub format_comprehension "offensive_3"
						*page_break Go Back
						*goto offensive_opened
					#Flesh Scorching Kicks.
						[b]Martial Art:[/b] Flesh Scorching Kicks.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						One of the very few techniques developed by someone below the Shangtian, conceptualized and performed by a Houtian instead. Wu Chao, who was often called the 'Last Hope of the Wu' before his eventual descent into debauchery, was an absolute genius during his prime and managed to create a skill that can be considered to be on par with the best of Top-Grade Arts.

						Infuses Martial Artist's legs with the power of fire, while also releasing a dozen of kicks in a span of a second.

						[b]Comprehension:[/b]
						*gosub format_comprehension "offensive_4"
						*page_break Go Back
						*goto offensive_opened
					#Go back.
						*goto martskills_opened					
			#Defensive.
				*label defensive_opened
				*choice
					#Celestial Shell.
						[b]Martial Art:[/b] Celestial Shell.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						Another technique of the Palm Crushing Celestial that had, during her travels of the Martial World, saved her life dozens of time. A near impenetrable barrier of golden light, this skill can only be broken through with an overwhelming force or a similarly terrifying Art.

						[b]Comprehension:[/b]
						*gosub format_comprehension "defensive_1"


						*page_break Go Back
						*goto defensive_opened																
					#Void Step.
						[b]Martial Art:[/b] Void Step.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						An incomplete technique found in the Living God's belongings. It is not known what the full version is capable of, as even this variant delves into the incomprehensible power of space and makes the user almost uncatchable for their enemies.

						Void Step Art can instantly relocate you out of the harm's way, but you will be left defenseless if your opponent a space-locking Art/artifact. Void Step also requires you to gather special Void Treasures to further your comprehension.

						[b]Comprehension:[/b]
						*gosub format_comprehension "defensive_2"
						*page_break Go Back
						*goto defensive_opened
					#Go back.
						*goto martskills_opened
			#Movement.
				*label footwork_opened
				*choice
					#Gale Stream.
						[b]Martial Art:[/b] Gale Stream.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						Infuses your body with the power of the wind, allowing you to at high-speeds for a relatively long amount of time.

						[b]Comprehension:[/b]
						*gosub format_comprehension "footwork_1"


						*page_break Go Back
						*goto footwork_opened																
					#Lightning Flicker.
						[b]Martial Art:[/b] Lightning Flicker.
						*line_break
						[b]Grade:[/b] [i]TOP.[/i]
						*line_break
						[b]Description:[/b]

						Infuses your body with the power of lightning, allowing you to erupt with a short, but huge burst of instant acceleration. 

						[b]Comprehension:[/b]
						*gosub format_comprehension "footwork_2"
						*page_break Go Back
						*goto footwork_opened
					#Go back.
						*goto martskills_opened
			#Supportive.
				*label supportive_opened
				*choice
					*if (mc_supportive_1)
						#Aura Perception.
							[b]Martial Art:[/b] Aura Perception.
							*line_break
							*gosub get_grade_name mc_supportive_1_grade
							[b]Grade:[/b] [i]${grade_name}[/i]
							*line_break
							[b]Description:[/b]

							One of the most common Skills in the world, utilized by almost every Martial Artist. 

							Allows the practitioner to perceive and analyze the aura of other Martial Artists, emitted by the concentration of Inner Energy inside their bodies. This can be used to gather a rough estimate of someone's strength. 

							*if mc_supportive_1_grade = 1
								A low-grade version only works on the people of the same level as the user, only shows the general power-level of the target, cannot avoid any aura-obscuring defenses and cannot gather any information about Skills in the employ of the target.
							*elsif mc_supportive_1_grade = 2
								A middle-grade version only works on the people of the same level as the user, cannot avoid any aura-obscuring defenses, cannot gather any information about Skills in the employ of the target, but can provide a more detailed explanation of their attributes.
							*elsif mc_supportive_1_grade = 3
								A high-grade version only works on the people of the same level as the user, can attempt to pierce through aura-obscuring defenses and provide a more detailed explanation of the target's attributes, but cannot gather any information about Skills in their employ.
							*elsif mc_supportive_1_grade = 4
								A top-grade version works on all practitioners of the same [i]realm[/i] as the user, can pierce most aura-obscuring defenses with ease, can gather information about the target's most used Skill and provides a more detailed explanation of their attributes.

								[b]Comprehension:[/b]
								*gosub format_comprehension "supportive_1"
					*if (mc_supportive_2)
						#Energy Concealment.
							[b]Martial Art:[/b] Energy Concealment.
							*line_break
							*gosub get_grade_name mc_supportive_2_grade
							[b]Grade:[/b] [i]${grade_name}[/i]
							*line_break
							[b]Description:[/b]

							Allows the practitioner to temporarily suppress the emissions of their Inner Energy, rendering them as mere mortals in the eyes of other Martial Artists. 

							Can be broken through by higher Martial Levels, High-Grade Aura Perception and completely useless in front of higher Martial Realms.

							[b]Comprehension:[/b]
							*gosub format_comprehension "supportive_2"
					*if (mc_supportive_3)
						#Cosmic Field.
							[b]Martial Art:[/b] Cosmic Field.
							*line_break
							*gosub get_grade_name mc_supportive_3_grade
							[b]Grade:[/b] [i]${grade_name}[/i]
							*line_break
							[b]Description:[/b]

							Allows the practitioner to toggle on a gravity field around their body, rendering most projectiles — like arrows, throwing knifes and even some Skills — useless. 

							[b]Comprehension:[/b]
							*gosub format_comprehension "supportive_3"
					#Go back.
						*goto martskills_opened
				*goto supportive_opened
			#Go back.
				*goto statpage_opened
	#Check Talents.
		*label traits_opened
		You possess the following Talents:
		*gosub_scene cslib_menu build_array_filter "mc_trait" "name" true "conditions" "trait_check_statpage"
		*temp n cslib_ret
		*if n > 0
			*temp cost mc_trait[n]["cost"]
			*temp description "trait_${n}"
			*gosub_scene descriptions {description}
			*page_break Go Back.
			*goto traits_opened
		*else
			*goto statpage_opened
	#Characters.
		*label characters_opened
		*temp n 1
		*label opinion_loop
		*temp all_opinion round((characters[n]["opinion"] - 0.5))
		*if all_opinion <= 100
			*stat_chart
				percent all_opinion ${characters[n]} Relationship
		*if n < characters_count
			*set n+1
			*goto opinion_loop
		*gosub_scene cslib_menu build_array_filter "characters" "" true "conditions" "characters_check"
		*temp n cslib_ret
		*if n > 0
			*temp opinion round((characters[n]["opinion"] - 0.5))
			*temp status characters[n]["status"]
			*temp description "character_${n}"
			*gosub_scene descriptions {description}

			*stat_chart
				percent opinion Opinion of you

			[b]				Relationship Status:[/b] ${status}
			*page_break Return
			*goto characters_opened
		*else
			*goto statpage_opened
	#Settings.
		*label settings
		*choice
			#Change Difficulty.
				The game can get quite challenging and maybe even frustrating (especially if you die later on), so it may be wise for you to choose an easier setting and be comfortable. On the other hand, challenge can be quite [i]fun[/i] and you will never die with a single wrong choice, so keep that in mind too.
				*choice
					#Mortal Talent. (Recommended, Achievements Unlocked)
						*set difficulty 1
					#Earth Talent. (x2 EXP)
						*set difficulty 2
						*set eligible_achievements false
					#Heavenly Talent. (x4 EXP)
						*set difficulty 4
						*set eligible_achievements false
					#Overlord-level Talent. (x10 EXP, Cheat Mode)
						*set difficulty 10
						*set eligible_achievements false
			#Change Stat Display.
				There are two ways you Attributes can be displayed: as a percentile bar or a as a number. Which setting would you like to use?
				*choice
					#Percentile Bar
						*set stat_display 1
					#Numbers
						*set stat_display 2
			#Toggle Stat Check/Health Change Texts
				*choice
					*if (show_check_text)
						#Disable Stat Check Text
							*set show_check_text false
						*if (show_check_text_req)
							#Disable Stat Check Requirement Text
								*set show_check_text_req false
						*else
							#Enable Stat Check Requirement Text
								*set show_check_text_req true
					*else
						#Enable Stat Check Text
							*set show_check_text true
					*if (show_health_text)
						#Disable Health Change Text
							*set show_health_text false
					*else
						#Enable Health Change Text
							*set show_health_text true
			*selectable_if (not_under_construction) #Tooltip.
				Tooltip allows you to see what attributes certain choices will check to determine the success of your actions (won't take effect until you go to the next page).
				*choice
					#Enable Tooltip
						*set tooltip true
					#Disable Tooltip
						*set tooltip false
			#Toggle Skill-Name shouting.
				*if (skill_shouting)
					*set skill_shouting false
					You have turned off skill-name shouting.
				*else
					*set skill_shouting true
					You have turned on skill-name shouting.
				*goto settings
			#Toggle Monthly Review
				*choice
					*if (monthly_review)
						#Disable Monthly Review
							*set monthly_review false
					*else
						#Enable Monthly Review
							*set monthly_review true
			#Go back.
				*goto statpage_opened
		*goto settings
				
*label statpage_info	
[b]STATUS:[/b]
*stat_chart
	percent round(((mc_health/mc_health_total)*100)) Health (${mc_health}|${mc_health_total})
*if mc_stamina_total > 0
	*stat_chart
		percent round((mc_stamina/mc_stamina_total)*100) Inner Energy

[b]INJURIES:[/b]
*temp i 0
*temp amount_injuries 0
*temp inj_string ""
*label injury_loop
*set i +1
*if (injuries[i])
	*set inj_string "injury_${i}"
	*set amount_injuries +1
	*gosub_scene descriptions {inj_string}
*if i != injuries_count
	*goto injury_loop
*if amount_injuries = 0
	You are uninjured.

[b]Name[/b]: ${mc_surname} ${mc_name}
*line_break
[b]True Age[/b]: ${mc_age}
*line_break
[b]Martial Level[/b]:
*temp level_string ""
*if mc_level = 0
	Mortal
*else
	*if mc_level = 1
		*set level_string "Early"
	*elsif mc_level = 2
		*set level_string "Middle"
	*elsif mc_level = 3
		*set level_string "Late"
	*elsif mc_level = 4
		*set level_string "Peak"
	*temp power_level ((mc_str+mc_agi)+(mc_con+mc_end))+mc_vit
	${level_string}-Houtian (Power Level: [b]${power_level}[/b])
*line_break
*if (mc_sect_position != "none")
	[b]Sect Position:[/b] $!{mc_sect_position} Disciple.
*line_break
[b]Contribution Points:[/b] ${mc_sect_points}

[b]GOAL:[/b]
*line_break
*if mc_goal = 1
	[i]Become the most powerful and revered practitioner of Martial Arts in the world. 
*elsif mc_goal = 2
	[i]Restore Wu Clan to greatness.
*elseif mc_goal = 3
	[i]Achieve justice and fairness for the common folk.
*elseif mc_goal = 4
	[i]Keep the current societal order.
*elseif mc_goal = 5
	[i]Attain absolute personal freedom.
*elseif mc_goal = 6
	[i]Pursue pleasures of the flesh.
*elseif mc_goal = 0
	[i]You don't have any particular goal.

[b]Prestige:[/b]
*temp prestige_string
*if mc_prestige < 100
	*set prestige_string "Unknown"
*elseif mc_prestige < 200
	*set prestige_string "Noted"
*elseif mc_prestige < 300
	*set prestige_string "Prominent"
*elseif mc_prestige < 400
	*set prestige_string "Renowned"
*elseif mc_prestige < 500
	*set prestige_string "Exalted"
*else
	*set prestige_string "Legendary"
${prestige_string} (${mc_prestige})
*line_break
[b]Reputation:[/b]
*line_break
*if mc_reputation_honor = 50
	People view you as [b][i]neither[/i][/b] honorable nor unscrupulous.
*elseif mc_reputation_honor < 10
	You are the most [i][b]despicable[/b][/i] ${pronoun_4} in the Celestial Empire and beyond. Your word means nothing, your promises are empty air.
*elseif mc_reputation_honor < 20
	You are a completely [i][b]shameless[/b][/i] bastard. You can break your word without blinking an eye and almost no one in the Celestial Empire trusts you. 
*elseif mc_reputation_honor < 30
	You are [i][b]treacherous[/b][/i]. Although not completely unprincipled, you are known to have went back on your promises many a time. Most people wouldn't put their trust in you.
*elseif mc_reputation_honor < 40
	You are [i][b]untrustworthy[/b][/i]. Perhaps you you've broken a few promises or said words that you decided not to back up with actions: but many would hesitate to confide in you.
*elseif mc_reputation_honor < 50
	You are [i][b]shady[/b][/i]. People've heard some dishonorable things about you and some of them wouldn't trust you based on your word alone.
*elseif mc_reputation_honor < 60
	You are [i][b]honest[/b][/i]. People know that you speak the truth far more often than not.
*elseif mc_reputation_honor < 70
	You are [i][b]sincere[/b][/i]. You've made good on several promises and gained an honorable reputation.
*elseif mc_reputation_honor < 80
	People know you to be someone who's [i][b]frank[/b][/i] and always follows up on his words. Most would easily trust you.
*elseif mc_reputation_honor < 90
	You are as [i][b]straightforward[/b][/i] as they come, your mouth knowing no lies. 
*elseif mc_reputation_honor >= 90
	You are simply [i][b]genuine[/b][/i]. Your word is the absolute truth: even the most paranoid would trust you based on it alone.
*line_break
*if mc_reputation_kindness = 50
	People view you as [b][i]neither[/b][/i] good nor evil.
*elseif mc_reputation_kindness < 10
	You are a [i][b]paragon of sin[/b][/i]. Every evil, diabolical act imaginable — you've done it and probably laughed in the process. Ordinary folk would avoid you like a plague, while various heroes will try and hunt you down. 
*elseif mc_reputation_kindness < 20
	You are a [i][b]vile creature[/b][/i], committing atrocities wherever you go. Most people both fear you with bone-chilling shivers and hate you with a burning passion.  
*elseif mc_reputation_kindness < 30
	You are a [i][b]wicked[/b][/i] ${pronoun_4}. You've done some depraved, contemptible things, but still remain outside the realm of true evil.
*elseif mc_reputation_kindness < 40
	You are [i][b]immoral[/b][/i]. Slowly, but steadily your human values get corrupted and you step further and further onto the demonic path. 
*elseif mc_reputation_kindness < 50
	People know to you be [i][b]foul[/b][/i], a ${pronoun_4} of questionable morals. It remains to be seen whether or not you'll become a true demon. 
*elseif mc_reputation_kindness < 60
	People know you to be a [i][b]decent[/b][/i] ${pronoun_4}. You help out whenever you can and haven't done much evil.
*elseif mc_reputation_kindness < 70
	You are [i][b]good-natured[/b][/i]. Your compassionate actions have caused people to have a good attitude towards you.
*elseif mc_reputation_kindness < 80
	You are [i][b]benevolent[/b][/i], known for your kindness towards others. People are drawn towards you. 
*elseif mc_reputation_kindness < 90
	You are [i][b]magnanimous[/b][/i], your selflessness knows no bounds. People have an overwhelming amount of respect for you.
*elseif mc_reputation_kindness >= 90
	You are a [i][b]paragon of virtue[/b][/i]. A true hero, the best ${pronoun_4} of your generation. People admire you.

*temp sexname
*temp facialname ""
*temp hairname ""
*if mc_hair_length = "bald"
	*set hairname "You are bald."
*elseif mc_hair_length = "buzz-cut"
	*set hairname "Your ${mc_hair_color} ${mc_hair_style} hair is clipped shortly in a buzz-cut style."
*elseif mc_hair_length = "short"
	*set hairname "You have short ${mc_hair_color} ${mc_hair_style} hair that barely reaches your brows."
*elseif mc_hair_length = "medium-length"
	*set hairname "Your ${mc_hair_color} ${mc_hair_style} hair flows freely, reaching the bottom of your chin."
*elsif mc_hair_length = "long"
	*set hairname "Your ${mc_hair_color} ${mc_hair_style} hair flows freely, reaching past your shoulders."
*temp eyename
*if mc_eye_left = mc_eye_right
	*if mc_eye_left = "blue"
		*set eyename "Your eyes are as blue as the sea,"
	*elsif mc_eye_left = "green"
		*set eyename "Your eyes are a pair of bright green emeralds,"
	*elsif mc_eye_left = "hazel"
		*set eyename "Your eyes are of hazel color, a curious mix of green and brown,"
	*elsif mc_eye_left = "brown"
		*set eyename "Your eyes are a pair of brown chestnuts,"
	*elsif mc_eye_left = "black"
		*set eyename "Your eyes are as black as the abyss,"
	*else
		*set eyename "You eyes are a pair of extremely rare ${mc_eye_left},"
*else
	*set eyename "You eyes are differently colored, with your left pupil being ${mc_eye_left} and your right — ${mc_eye_right},"
*temp skinname ""
*if mc_skintone = "pale"
	*set skinname "while your skin is pale, almost as white as the purest marble."
*elsif mc_skintone = "porcelain"
	*set skinname "while your skin is fair and porcelain."
*elsif mc_skintone = "beige"
	*set skinname "while your skin is sandy-beige and with a slight tan."
*elsif mc_skintone = "bronze"
	*set skinname "while your skin is bronzed and has a healthy glow."
*elsif mc_skintone = "chocolate"
	*set skinname "while your skin is dark brown, resembling a bar of chocolate."
*elsif mc_skintone = "ebony"
	*set skinname  "while your skin is ebony, resembling the endless darkness."
*temp heightname ""
*if mc_height = 1
	*set heightname "very short"
*elsif mc_height = 2
	*set heightname "short"
*elsif mc_height = 3
	*set heightname "neither tall nor short"
*elsif mc_height = 4
	*set heightname "tall"
*elsif mc_height = 5
	*set heightname "very tall"
*temp bodyname ""
*if mc_bodytype = "muscular"
	*set bodyname "You are built like a mountain, with big bulging muscles that your clothes struggle to contain. You are as solid as rock, with wide shoulders, veiny forearms and large hands."
*elsif mc_bodytype = "lean"
	*set bodyname "Your body is well-proportioned and lean. Your muscles are clearly defined, but hidden underneath a layer of clothes. Your back has an ideal V-shape, with wide shoulders and narrow hips."
*elsif mc_bodytype = "skinny"
	*set bodyname "You are built like a twig, thin and wispy. Your shoulders and hips are narrow, hands are small and wrists are slim."
*elsif mc_bodytype = "chunky"
	*set bodyname "You are built like a bear that regularly takes part in feasts. You are barrel-chested, with hips almost wide as your shoulders. You are a carrying a solid chunk of muscle hidden underneath the softness of your belly."
*if mc_sex = 0
	*set sexname "man"
	*if mc_hair_facial != "clean-shaven"
		*set facialname "You also have a ${mc_hair_facial}."
*else
	*set sexname "woman"
	*if mc_bodytype = "lean"
		*set bodyname "Your body is well-proportioned and lean. Your muscles are clearly defined, but hidden underneath a layer of clothes. You have a perfect hourglass figure."
[b]Appearance:[/b]
*line_break
You are a ${heightname} ${sexname}. ${bodyname} ${hairname} ${eyename} ${skinname} ${facialname}
*if (mc_trait_3)
	*line_break
	[i]You possess an otherworldly beauty.

*if fight_sect_arena = "none"
	[b]Equipment:[/b]
	*line_break
	*set amount_injuries 0
	*if mc_equipped_robe > 0
		*temp equipped_robe equipment[mc_equipped_robe]["name"]
		[i]${equipped_robe}[/i]
		*set amount_injuries +1
		*line_break
	*if amount_injuries = 0
		You don't have any items equipped.
*else
	Equipment is prohibited during matches in the Arena.

[b]Gold:[/b] ${mc_gold} coins.
*line_break
[b]Free EXP:[/b] ${mc_exp} EXP

*goto statpage_opened

*label tattoos_menu_show
*choice
	*if (mc_tattoo_dragon = 1)
		#Dragon Tattoo. 
			A tattoo that fully covers your left sleeve, depicting a large, winged, fire-breathing dragon. 

			Dragons are known for their terrifying physical might and the tattoo of one will give you some of their strength: for the cost of [b]10[/b] Inner Energy, you can temporarily raise all of your physical attributes by [b]3[/b].

			When in need, you can ignite the tattoo, destroying it forever, but gaining a short burst of infinite, endless power in return.

			*choice
				*selectable_if (mc_stamina >= 10) #Activate.
					*set mc_stamina -10
					You send your Inner Energy into the Tattoo — and the dragon responds. It shudders, moving on your sleeve, and growls slightly.

					You feel invigorated, with power coursing through your veins.

					*set mc_tattoo_dragon 2
					*goto tattoos_menu_show
				#Ignite.
					You send your Inner Energy into the tattoo — and the drawn dragon comes alive. It roars furiously and exhales, it's a breath a flame that covers up your arm. 

					You feel invincible. Unstoppable. 

					You feel [i]divine[/i].

					*set mc_tattoo_dragon 3
					*goto tattoos_menu_show
				#Go back.
					*goto tattoos_menu_show
	*if (mc_tattoo_turtle = 1)
		#Turtle Tattoo.
			A tattoo of a turtle shell on your back.

			Tortoises are known for their impenetrable defenses: for the cost of [b]10[/b] Inner Energy, you can reduce the next incoming damage by [b]2[/b]. 

			When in need, you can ignite the tattoo, destroying it forever, but gaining an impenetrable defense in return.

			*choice
				*selectable_if (mc_stamina >= 10) #Activate.
					*set mc_stamina -10
					You send your Inner Energy into the Tattoo — and the shell responds. It glows with green light and spreads its warmth across your back.

					*set mc_tattoo_turtle 2
					*goto tattoos_menu_show
			#Ignite.
				You send your Inner Energy into the tattoo — and the shell expands, covering your body whole. It glows with intense green light, emitting a sense of impenetrable unwieldiness. 

				*set mc_tattoo_turtle 3
				*goto tattoos_menu_show
			#Go back.
				*goto tattoos_menu_show
	*if (mc_tattoo_phoenix = 1)
		#Phoenix Tattoo.
			A tattoo of phoenix's wings on your chest.

			Phoenixes are mythical beasts of healing and rebirth: for the cost of [b]10[/b] Inner Energy, doubles the effect of your regeneration.

			When you are near death, the tattoo will ignite by itself: it will be destroyed forever, but you will be resurrected at full health.

			*choice
				*selectable_if (mc_stamina >= 10) #Activate.
					*set mc_stamina -10
					You send your Inner Energy into the Tattoo — and the phoenix responds. It spreads its wings and flops them, sending its vitality into your flesh.

					*set mc_tattoo_phoenix 1
					*goto tattoos_menu_show
				#Go back.
					*goto tattoos_menu_show
	#Go back.
		*goto statpage_opened
*label format_atr
*params atr
*temp string_lvl "${atr}_lvl"
*temp string_exp "${atr}_exp"
*set {string_exp} mc[atr]
*if mc[atr] >= (10 + (10*mc_level))
	*set {string_lvl} "PEAK GENIUS"
*elsif mc[atr] >= (8 + (10*mc_level))
	*set {string_lvl} "GENIUS"
*elseif mc[atr] >= (5 + (10*mc_level))
	*set {string_lvl} "TALENTED"
*elseif mc[atr] >= (3 + (10*mc_level))
	*set {string_lvl} "MEDIOCRE"
*else
	*set {string_lvl} "MEAGER"

*return

*label format_comprehension
*params skill
*temp current_level {"mc_${skill}_mastery"}
*set level_string ""
*if current_level = 0
	*set level_string "Not comprehended."
*elsif current_level = 1
	*gosub_scene cslib_string find skill "supportive"
	*if cslib_ret > 0
		*set level_string "Comprehended."
	*else
		*set level_string "Initial Success."
*elsif current_level = 2
	*set level_string "Small Success."
*elsif current_level = 3
	*set level_string "Large Success."
*elsif current_level = 4
	*set level_string "Perfection."
[b]${level_string}[/b]
*return

*label get_grade_name
*params grade
*if grade = 1
	*set grade_name "LOW"
*elsif grade = 2
	*set grade_name "MIDDLE"
*elsif grade = 3
	*set grade_name "HIGH"
*elsif grade = 4
	*set grade_name "TOP"
*return

*label exp_until_increase
*params atr
*set exp_left 50+(mc[atr]*10)
*return