*temp goingup 0
*temp turf 0
[b]Chapter 1[/b]
*line_break
[b][i]Final Act: A Peculiar Party[/i][/b]

The days till Saturday pass by unspectacularly, and without any further nightly disturbances.

Not counting a tiny stray cat that seems to have taken note of the cafe being occupied again, and has shown up the past few nights.

*fake_choice
   #I wouldn't call the cat a disturbance. In fact we began feeding it.
      *set cat true
   #Yes. I hope it goes away soon.
But aside from that, nothing out of the ordinary (though you yet have to find a suitable definition of 'ordinary' for Cornucopia) happened.
*if ((gf_parent) or (gf_child))
   *line_break
   Hell's Bells, you remember when there had been people in your life sneering at changing pronouns 'cause it's 'so out of the oridinary'. They'd probably explode if they'd face Cornucopia.
   *line_break
   And talking about pronouns... 
   *line_break
   *gosub_scene sub_pronouns
   *goto gettingready
*else
   *line_break
   *gosub_scene sub_pronouns
   *goto gettingready
*label gettingready
You got the last few contracts in order, bought a washing machine and dryer, and even got a TV along the way.
*line_break
Of which $!{kid_firstname} intends to make good use while you're away.

But first...

"$!{kid_calling}, you look good enough." $!{kid_firstname} rolls ${kidtheir} eyes as you check your appearance in the bathroom mirror again.

"Oh, excuse me for being nervous," you harrumph. Then you sigh. "Do you really think this is ok?"
*line_break
You do a little turn. In combination with other items the ${outfit} is not too bad looking.

"$!{kid_calling}, really, you're fine."

"Oh, I hope," you say, just as the doorbell rings. "Well, there's the cab then." You pull $!{kid_firstname} into a hug. "Don't stay up to late, ${kid_nick}. I'll call you when I arrive. And you call me should something happen, alright?"

You let go of ${kidthem}, and ${kidthey} @{c_plur nod| nods}.

"Of course," ${kidthey} @{c_plur say| says}. "Now go and enjoy yourself."
*page_break Easier Said Than Done
Your heart sinks a little as the cab finally pulls up at the given address.

Sure, you had checked things beforehand to make sure you won't end up in some dark, lonely alley, but...
*line_break
No photograph and tourist information could have prepared you for seeing the thing in the flesh.

Or better in the glass and steel.

The [i]Magistrate's Palace[/i].
*line_break
An extremely misleading and absurdly cheeky name. It had been a gin palace, a drinking hall across a courthouse, decades and decades ago, had become a restaurant slash hotel, burned down and had been rebuilt into it's current shape.

They added a casino.

And the party is being held in one of the roof gardens slash penthouse hundreds of meters above the street.
*line_break
You lean back in the car seat for a moment and take a deep breath.

*fake_choice
   #Alright, this was a bad idea. This is really out of my league, and I should leave.
      *set rash %-5
      *set skulduggery %-5
      You gulp, fingers curling into the fabric of your ${outfit}.
      
      "Hey, you alright back there?" the driver asks.
      
      "I... Could you drive me back?"
      
      The driver just shrugs and reaches for the keys, just as someone knocks on he window.
      
      Mr Montgomery.
      
      Seems there's not much of a choice. You sigh and briefly roll your eyes. 
   #This is really intimidating, but I have come this far... Here goes nothing.
      *set rash %+5
      *set skulduggery %-5
      "Don't mind me saying, but you look really unwell," your driver says.
      
      "Stage fright, I guess." you grin askew and let out a small yelp as someone knocks on the window.
      
      Mr Montgomery.
      
      Well, as you said, here goes nothing. 
   #Oh Hell's Bells! Who do they think they're trying to fool? Well, they messed with the wrong person.
      *set rash %+5
      *set skulduggery %+5
      You pinch the bridge of your nose.
      
      "You alright?" your driver asks, giving you a slightly worried rear-mirror glance.
      
      "Yes, just gathering my thoughts," you say, brows furrowed darkly.
      
      "I could drive you back, if you..." before your driver can finish, someone knocks on the window.
      
      Mr Montgomery.
      
      You sigh and remind yourself not to shoot the messenger. 
   #I really don't like this. This is a trick. I'm angry... and leaving.
      *set rash %-5
      *set skulduggery %+5
      You frown darkly. "Get me back home," you mutter, earning a bemused rear-mirror glance from the driver.
      
      "You alright back there?"
      
      "Yes. I... I jus don't have time or patience for this bull-..."
      
      Before you can finish someone knocks on the window.
      
      Mr Montgomery.
      
      If this is a trick, they are at least thorough. 
"Nevermind," you tell your driver and pay your fee. "Keep the change. Good night."
*page_break And Clamber Out Of The Car.
"Glad you could make it," Mr Montgomery says as the cab drives off.

"So am I. ...I guess," you say, calming your nerves, and stare up at the looming building.
*line_break
Then you snap your attention back to Mr Montgomery. "Alright, out with it? What game are you playing here?"

Mr Montgomery blinks baffled, briefly greeting a couple heading up the stairs as they pass, before turning back to you. "What do you mean?"

"For starters, this is a little too creamy crème de la crème of high society by the looks of it." Your shoulders slump. "This is a prank, isn't it?"
*line_break
You run a hand over your face, as if to wipe the look of angry devastation and disappointed acceptance off. But Mr Montgomery looks back guiltily.

"Good gracious, no." He clears his throat. "Tem mentioned you said something about some bad experiences in the past, but... no. I swear on my kids' lives this is genuine."

You straighten your posture, but stay wary. "It's still very, very high society. I figured it'd be some kind of press event, given they could do without the mayor after inviting her..."

"That's quite rude to my main job," Mr Montgomery grumbles, but then looks positively embarrassed. "Wait. Hold on. I... I didn't tell you?"
*page_break "Tell me what?"
With a whimper Mr Montgomery bites his lips, before sighing exhausted. "What the party is about," he finally says, rubbing his neck.

"No, you just gave me a very fancy invitation, told me something about someone named Lesley, and..."

Mr Montgomery sighs again, tilting his head back and staring at the nightly sky for a moment. "I'm sorry. Well, yes," he then starts over, "It is a press event, but a rather special one." He looks back at you and smiles. "Come, we've been twiddling our thumbs out here long enough. I'll explain everything on the way up."
*line_break
He turns towards the stairs and waves you to follow.

You signal him to wait only a moment, as you fish out your phone and call $!{kid_firstname}, telling ${kidthem} that so far all's alright, but you give ${kidthem} the address and tell ${kidthem} to stay careful.

$!{kidthey} @{c_plur advise| advises} you to do the same. 
*line_break
You stash your phone away, take a deep breath and look around.

With the cab gone and everything (you do glance around for another cab for a moment)...

You huff briefly, lift your chin, and, ultimately, follow Mr Montgomery.
*page_break Into The Palace
Arching and looming dozens of meters above you, the main hall of the Palace is a cone-shaped dome that can make one dizzy.
*line_break
Everything glitters and gleams, a hypnotizing symphony of champagne marble and black coffee slate.

You stiffen briefly when you look up and see no railings anywhere on the higher levels, until you spot the smooth glass separating visitors of these floors from a very nasty encounter with the casino floor below.

"The Palace is a pretty new building as it is," Mr Montgomery begins in his best tourist guide voice as you weave your way past roulette tables and slot machines towards the elevators. "The old one burned down during Odium's reign. We took some cues from a similar building in a sister town for the new one's design."

"I hear so much about Cornucopia's sister towns," you respond, "And I've heard of none of them. Not the ones in Oregon or Nebraska or Indiana or the one a state over on the coast. Are they even all in the same reality?"

"It's complicated."

You should have expected that answer.
*page_break Into The Elevator You Go
"So," he begins as the doors close, "Anything you want to know? It's going to be a bit of a ride."

You look at him warily. There are some questions on your mind, but you doubt you'll have time for all of them, no matter how long going up will take.

*label goingup_int
*choice
   *hide_reuse #Ask him about the @{(goingup =0) party. First things first| party}.
      *if (goingup =0)
         *set goingup +1
         *set elev_party true
         *goto party_elev
      *else
         *set goingup +1
         *goto party_elev_short
   *hide_reuse #Ask about the fire and Odium.
      *if (goingup =0)
         *set goingup +1
         *set elev_fire true
         *goto fire_elev
      *else
         *set goingup +1
         *goto fire_elev_short

*label party_elev
"First things first: What [i]is[/i] this party about?" You ask, crossing your arms. "It's fancy, some press event, and you got me here to level the field for this Lesley. Now the details, if you please.

"It's mid-April. Next TV season is around the corner -don't know how that was handled where you come from-, so this is a little get-together of producers, writers, sponsors and the press."

"You mean there'll be presentations?"

"No, those already happened. This is more... -How did @{(rival_gender = "male") Mr| Mrs} Haggerty put it?- New Year's Eve for entertainment media."

"Sounds a little dire... Who?"

@{(rival_gender = "male") "Frank| "Fay} Haggerty. Our host tonight."

You nod quickly. "Media Mogul?"

"Sponsor. Big one. $!{rivthey}'s the head of one of CoCi's richest families and the money behind a lot of shows. And one of the judges on Cooking Cornucopia."

*if (day2visit = "city")
   "Oh, I heard of that one," you say.
   
   Mr Montgomery's face lightens up. "Oh?"
   
   "Yes, it was described to me as Cutthroat Kitchen meets The Great British Bake Off."
   
   "Hah!" Mr Montgomery smiles broadly at you. "Can't say that's not accurate. But 
*if (day2visit != "city")
   "A cooking show?" You ask.
   
   "[i]The[/i] cooking show in CoCi." Mr Montgomery beams brightly. "But 
@{(rival_gender = "male") Mr| Mrs} Haggerty can explain it better. Huh... Come to think of it, the new producer should be here too. They should be able to explain it best."

"New producer?" You wonder. "If the show's so popular, what..."

"Maternal leave."

"Oh."
*page_break That's A Little Surprising.
"Personally I wish her all the best," Mr Montgomery continues. "Can't wait to see who follows her."

"Shouldn't that have been announced yet?"

Your companion tilts his head a bit abashed. "My other job got a bit in the way with the announcements and looking things up. It happens."

You smile a little, 
*goto elev_interlude

*label party_elev_short
"I should have asked before, but what [i]is[/i] this party about? What can I expect? Aside from this Lesley."

"It's a little get-together of producers, sponsors and the press. It's mid-April now, and -I dunno how it was where you come from- here the new TV seasons start mid-May."

"Aha?" That does... not mean much to you.

"Yes. The presentations are over and this... -How did @{(rival_gender = "male") Mr| Mrs} Haggerty put it?- This is a bit of New Year's Eve for entertainment media.

@{(rival_gender = "male") "Mr| "Mrs} Haggerty?"

@{(rival_gender = "male") "Frank| "Fay} Haggerty. Our host tonight. Pretty important sponsor for a couple of shows."

You smile a little, 
*goto elev_interlude

*label fire_elev
"What do you mean 'Odium burned this building down'?" You say, cocking your head. "From all I heard so far, I was under the impression Odium was this mysterious, shadowy figure in the background."

"They were. The building burned down as a result of a battle against Odium's Crawlers."

You search your memory. 
*if (know_coci_gloom_ian)
   Had Mr Rattray said anything? 
*if (day2visit = "aporia")
   Had there been anything in that short movie at APORIA? 
Have you stumbled over the term before? Try as you want, you can't think of anything.
*line_break
So you simply greet that statement with a blank look.

Mr Montgomery rolls his shoulders. "Odium's... lackeys."

"Ah." You nod knowingly. After all, what be any villain without henchfolk?

"During Odium's reign they attacked an old abandoned -granted, almost everything in the area had been abandoned back then- theatre not too far from here. Where the 'Le Paon D'or' restaurant's now."

That sounds peculiar. "What business had this Odium with an abandoned theatre?"

"It had been a hideout to a villainess named Glimmer. Maybe she had done something..." Mr Montgomery shakes his head. "We never found out."

"Is she dead?"

"Coma. FreezeFrame got her out before the building collapsed."

"The name means nothing to me. Another hero I presume?"

Mr Montgomery breaks into a laugh. "Good gracious," he cackles, "Oh, he'd have some choice words for you if you'd call him that."

"Villain then?"

"Technically. But Above and Below know he's more of a hero, and he [i]hates[/i] that notion." Mr Montgomery chuckles for a moment, before it fades into a sigh. "But yeah, he got Glimmer out. I know Vivacity, and Fog and Gaslight -the latter you met: Miss Misra, she's working with Joshua-" you nod and your companion continues, "Well, I know these three investigated back in the day. If I'm not mistaken Fog, Emma Burke actually, is working with Ian from time to time, visiting Glimmer, even now."

*page_break There's A Surprise.
"You mean Mr Rattray? @{(know_coci_gloom_ian) He didn't strike me as too keen on even talking about the whole Gloom and Odium thing| What does he have to do..}. I mean I heard him getting called 'CoCi's top historian' but..."

"Ian is someone who can't sit still till he has answers," Mr Montgomery elaborates. "Sure if you ask him he'll say his goal's to uncover CoCi's origins, but truth be told, he spends more time trying to find who Odium was. I can understand him," there's an odd ton in his voice at this.

"So he hopes this Glimmer will wake up?"

A nod. "It's odd. The doctor's say she should have been awake for years now. Even taking into account that the help we could provide back then was far from optimal, vitakinetic help or not... It's odd."
*line_break
There's an air of finality in Mr Montgomery's voice, and he falls silent.

So do you, until you 
*goto elev_interlude

*label fire_elev_short
"What do you mean 'Odium burned this building down'?" You say, cocking your head. "I though Odium was this mysterious, shadowy figure in the background."

"They were. The fire was the result of a battle against their lackeys."

"I see." Not that it makes that much sense. "Why did they attack a casino?"

Mr Montgomery shrugs. "They attacked an abandoned theatre a bit down the streets. The entire street was ablaze as a result."

That doesn't really answer anything. "And why..."

"Oh, if only we'd know. Glimmer might know, but she's been in a coma since. You should talk to Ian if you want to know more. He and Emma Burke are amongst those that hope she'll wake up the most."

"Ian? As in Mr Rattray?"

"The same. Believe it or not, but he is determined -much to his own dismay I think- to find out who Odium was."

You're about to comment on that, 
*goto elev_interlude

*label elev_interlude
*if (goingup =1)
   look at the display. "Still a bit to go?"
   
   "A little bit. It's a very high building by CoCi's standards. 74 floors, 310 meters from bottom to roof. The InSpire stands at 330 meters.
   
   "In...Spire?"
   
   "Our nickname for the APORIA building."
   
   "That's... cheesy."
   
   "I know. We love it." Mr Montgomery grins broadly. "Well, do you have another question maybe?"
   
   *goto goingup_int
*else
   just as the elevator's chime indicates your arrival.
   
   "Well, there we are," Mr Montgomery says.
   
   *goto haggerty_party

*label haggerty_party
The elevator opens into a short, brightly lit corridor of dark stone, the security guards at the doors across the hall nearly blending into the matte slate.
*line_break
They nod at Mr Montgomery, while you show your invitation, gathering your courage.

"Well," Mr Montgomery says with a sly grin as the guards open the door to the penthouse, "Hope you'll enjoy yourself."
*page_break Here Goes Nothing
Oh my...

Your heart drops a little bit as you step into the luxurious penthouse. You had mused what it would look like, and you take some pride in having come close.
*line_break
Everything is glass and steel and huge windows, black and white wood and leather and mood lighting.
*line_break
You're not entirely certain, but you think the entire living part of your cafe might fit in here.

And it's crowded.
*line_break
All around you (and in the large garden outside, too) people are standing and lounging around in small groups, doing bits of smalltalk, some exchanging numbers by the looks of it.
*line_break
Next to you, Mr Montgomery's scanning the crowd, while you... Seconds ago you had felt ready for this.

Now you feel entirely out of place, bit like a fish on a bicycle.

*fake_choice
   #Hell's Bell, yeah...
      *set ruff %+5
   #Naw, I'm fine.
      *set ruff %-5
[i]At least you are a pretty fish...[/i]

You move away from the door, rocking on your heels a little, as Mr Montgomery gasps happily.
*line_break
*set met_lesley true
*set lesley_name "Lesley Arcs"
"Ah, there we go," he says and waves at someone across the crowd, before guiding you over to a small couch to the side.

"$!{parent_address} $!{lastname}," Mr Montgomery begins as you reach it, "allow me to introduce you to my favorite rival, Mx Lesley Arcs."

The person getting up from their seat is a small wiry one, with short, frizzy ginger hair. They smile brilliantly at you, if a little slyly.

"Favorite rival?" you wonder.

Mx Arcs and Mr Montgomery chuckle in unison.

"I think I told you Lesley works for the Chronicler? Can't not have a bit of rivalry what with me working for the Gazette."

"It's not much of a rivalry, actually," Mx Arcs says, cocking their head with a grin. "That'd require Art to be on my level."

"Hah, that'd be a long way down," Mr Montgomery retorts.
*page_break Adorable...
Mx Arcs shakes their head with an amused smirk, before turning to you again. "But business now. Art mentioned that you are the new owner of the Timeless?"

You nod. "I gathered the disappearance of the former owner had been major news for years," you say.

"Indeed," Mx Arcs say. "But I believed Art filled you in on the whole affair already."

You gesture vaguely. "Kinda sorta."

This prompts Mx Arcs to quirk a brow at Mr Montgomery. "Art, really? You could have filled..." Now the quirked brow is directed at you. "Her? Him? Them? Em? '$!{parent_address}' can mean a lot of things. Mind if I ask what's it for you?"

You blink a little baffled. "Umm, it's ${them}, err, ${they}, you know what I mean." You manage, and Mx Arcs smiles.

"Today, or...?"

Again you blink. @{gf_parent "Today| "Everyday}."

"Precious. Oh, for yours truly it's a ${lesleythey}-day today." As you nod your acknowledgment, Mx Arcs turns back to Mr Montgomery.

"As I was saying, Art. You could have filled ${them} in on the whole thing."

Mr Montgomery shrugs softly and apologizing.

"Anyway," Mx Arcs says, flipping ${lesleytheir} hair back. "About the interview..."

"Didn't you just want to fill me in?" you ask baffled.

"We'll do that along the way. We have work to do."

"Wait, what? Here and now?" you ask, maybe a little too loud and a little too scandalized.

Mx Arcs raises an unimpressed brow at the heads your outburst has turned, before looking cooly at you. "Why, did you think Art brought you here just for an introduction and the get-together?"

*fake_choice
   #Ah well, let's get this over with then. Not that I feel well...
      *set ruff %+5
      *set uncon %-5
      You sigh 
   #Truth be told, I might enjoy this.
      *set ruff %-5
      *set uncon %+5
      You shrug at Mx Arcs 
   #I guess I'll let those two surprise me. What's the worse that could happen?
      *set ruff %-5
      *set uncon %-5
      You shrug at Mx Arcs 
   #Eesh, let's just do this. But you do know all these options sound kinda creepy and sexual?
      *set ruff %+5
      *set uncon %+5
      [i]Now that you say it... I apologize.[/i]
      
      [i]Anyway...[/i]
      
      You give both of them a long, cold look, shrug 
and sit down, waiting for the duo to begin.

Not that anything actually comes of it.

"Art?" A voice (an oddly familiar one at that) calls from somewhere nearby. "Arthur Montgomery?"
*line_break
You and your companions look towards the speaker.

It's Mrs Lane. You had not expected to run into the lady from the train, of all people, here.

She's weaving her way through the crowd towards the couch, eyes wide in surprise as you and your two reporters rise to your feet.

"I don't believe it!" Mrs Lane exclaims, beaming at Mr Montgomery. "I didn't expect to run into you here."

She's rather giddy, while Mr Montgomery looks at you and Mx Arcs rather helplessly.
*line_break
You decide to lend a hand by introducing (re-introducing) Mrs Lane to Mr Montgomery.

Not that it seems to ring any bell.

"Gracious, Art, it's been ages!" Mrs Lane continues unperturbed, holding her arms out for a friendly embrace.

Mr Montgomery, however, seems completely at a loss now, and a little close to panic. "My deepest apologies Mrs Lane, but I really don't remember you at all."

Mrs Lane looks pretty hurt at that, getting Mr Montgomery to wince embarrassed.

"Art, what did you [i]do[/i]?" Mx Arcs chimes in, looking rather scandalized and frazzled at ${lesleytheir} colleague.
*page_break Uh-Oh...
The sense of a nearing panic grows stronger. "Nothing. I... I..."

"Oh goodness gracious..." Mrs Lane suddenly groans abashed and buries her face in her hands. "Oh good heavens, I'm so sorry Art," she says, looking up embarrassed. "I just realized the last time you saw me was probably when my ID said 'Phillip Hart'. I'm sorry."

Mr Montgomery blinks. "Oh." Then begins to smile broadly. "Ohh! Hey!" Now he holds his arms open for an embrace which Mrs Lane gladly takes, "Good Heavens. How are you... Jenny? Is Jenny right?"

"Absolutely!"

Mr Montgomery laughs. "How's life been treating you?"

"Oh, not too bad," Mrs Lane says, letting go and grinning. "Got married," she wiggles her hand, "got a child, and recently got hired by the station. That's why we moved back here."

"The station? Do you mean C2-RBN?" Mx Arcs asks, and Mrs Lane's grin spreads.

"The very same."

"My congratulations, " says Mr Montgomery, "To everything. What's the new job?"

Mrs Lane puffs her chest a little, all giddy now. "Oh nothing big, Art. Just, ah, being the new brain behind Cooking Cornucopia."
*page_break Now There's A Surprise
"That's unexpected," Mr Montgomery says, eyes wide in surprise (though that might be a leftover from everything that happened up till now), as he waves Mrs Lane to take a seat. "Congratulations."

Mrs Lane sits (as does the rest of your group) and waves him off. "Don't cheer till the ratings are in, Art. Lulu did an amazing job, and Helen's a blessing. But it still hinges on me and how well I do my job in the end." She lets out a long sigh, folds her hands in her lap and looks at you with a smile. "Heh, meeting Art was surprising enough," she says. "But seeing you here... How are you?"

"All things considered?"

"Oh, that sounds dire."

You laugh. "Overwhelmed, rather." You tell her about the cafe, and Mrs Lane whistles through her teeth.

"I only heard about it. It was after my time," she says. "But aside from that whole ordeal with Odium and the former owner, I only heard good things."

"Oh, I heard about that, too," you say, glancing at Mx Arcs and Mr Montgomery. "That Mr Audley was Odium."

"Or that this Odium abducted him, for whatever reason," Mrs Lane adds.
*page_break Alright, That's A New One.
After everything that happened so far, you had gone and read up on your little cafe's history, but that theory is one you hadn't come across yet.
*line_break
You're about to ask, when Mrs Lane looks a little flummoxed at Mr Montgomery, who's been gazing at her just as bewildered.

"What?" She frowns mildly, raising a curious brow in response.

"Mhn? Oh, emm, nothing." Mr Montgomery clears his throat. "Just admiring your memory. I mean, it's been over twenty years, and you pick me out of this crowd like it's nothing while I stand there at a complete loss. And usually I've had the better memory."

By chance you catch Mx Arcs' eye and ${lesleythey} @{lesplur give| gives} you a knowing, and very dead-pan look. You mirror it.

Mrs Lane laughs. "Memory, shamory, Art. If @{(rival_gender = "male") Mr| Mrs} Haggerty hadn't mentioned you and pointed you out I would have been just as oblivious. I heard you got married too? My congratulations."

"Thank you."

You lean back, watching the two chat away merrily, until you notice Mx Arcs typing away on ${lesleytheir} tablet. "Already writing up an article?" you ask.

"Without the interview having happened yet? Do you think I write for [i]Covering Cornucopia[/i]?"

You smirk and observe Mx Arcs for a moment, before you sit back on the couch, not really knowing what to do with yourself.
*page_break Then Mrs Lane Rises.
"Alright, I have to leave you now," Mrs Lane says. "I'm here for business reasons, after all." She adjusts her outfit a little and bids you farewell, asking you to say 'Hello' to $!{kid_firstname} from her.

Just as she vanishes into the crowd, Mx Arcs and Mr Montgomery turn to you eagerly.
*line_break
"Well then..." Mr Montgomery begins.

"Tell us a bit about yourself," Mx Arcs finishes, twirling ${lesleytheir} tablet pen.

You take a deep breath. You've been through dozens of job interviews, this should not be that much different. Just... more personal maybe. "My name's $!{parent_firstname} $!{lastname}. I'm...
*fake_choice
   #36...
      *set parent_age 36
   #37...
      *set parent_age 37
   #38...
      *set parent_age 38
   #39...
      *set parent_age 39
   #40...
      *set parent_age 40
   #41...
      *set parent_age 41
   #42...
      *set parent_age 42
   #43...
      *set parent_age 43
   #44...
      *set parent_age 44
   #45...
      *set parent_age 45
   #46...
      *set parent_age 46
   #47...
      *set parent_age 47
   #48...
      *set parent_age 48
I'm ${parent_age} years old and have a ${parent_calling}, $!{kid_firstname}. $!{kidthey}@{c_plur 're|'s} ${kid_age} now."

Mx Arcs scribbles away on ${lesleytheir} tablet, while you begin to talk about your life and family, until you reach ${weird_nickname}.
*goto early_life

*label early_life
You fall silent for a moment, 
*if (married)
   scanning the crowd for Mrs Lane. You remember her daughter and her husband, and for a moment there's a slight pang of @{(spouse = "bad") jealousy| nostalgia} in your chest.
   
*if (married = false)
   leaning back and staring at the ceiling.
   
"$!{parent_address} $!{lastname}?" Mx Arcs pulls you from your thoughts, and you whip your head towards ${lesleythem} a little to fast.

"Ow..." You rub your neck, blinking at Mx Arcs a little accusingly.

$!{lesleythey} @{lesplur venture| ventures} on unimpressed. "You fell silent, what happened?"

With a frown you look ${lesleythem}. "Nothing... just... 
*if (married)
   just remembering my marriage."
   
   Your two companions exchange an odd glance, before looking at you again.
   *line_break
   Again you frown, and figure you might as well tell them. After all, this is heading towards you becoming the new owner of a cafe, so...
   *line_break
   Another deep breath. "I was married. My ${spouseis} 
   *goto more_married
*if (married = false)
   just remembering my family..."
   
   "That doesn't sound like you're too fond of them," Mr Montgomery says. You shake your head.
   
   "Some are okay. Mostly cousins several times removed. But the big chunk? They're right bastards..." Again you shake your head and figure you might as well tell them.
   
   *goto kid_life

*label kid_life
You take a deep breath, hold it for a moment and exhale.
*page_break
"You see... $!{kid_firstname} 
*if ((((((((((((((family_origin =6) or (family_origin =7)) or (family_origin =8)) or (family_origin =9)) or (family_origin =10)) or (family_origin =11)) or (family_origin =12)) or (family_origin =13)) or (family_origin =14)) or (family_origin =19)) or (family_origin =20)) or (family_origin =21)) or (family_origin =22)) or (family_origin =23))
   @{((((family_origin =12) or (family_origin =13)) or (family_origin =14)) or (family_origin =23)) was artificially conceived| wasn't planned}."
   *goto kid_life1
*if (adopted)
   adopted."
   
   *goto kid_life1
*if (family_origin =15)
   was...
   
   *choice
      #adopted."
         *set adopted true
         *goto kid_life1
      #not planned."
         I...
         *choice
            *if (((gender_parent = "female") or (gender_parent = "trans man")) or (gender_parent = "other")) #still have good contact with the one who got me pregnant, though."
               *set family_origin 6
               *set gender_p 1
               *goto kid_life1
            *if (((gender_parent = "male") or (gender_parent = "trans woman")) or (gender_parent = "other")) #still have good contact with the one I caused that to, though."
               *set family_origin 9
               *set gender_p 2
               *goto kid_life1
            *if (((gender_parent = "female") or (gender_parent = "trans man")) or (gender_parent = "other")) #don't have contact with the one who got me pregnant, though."
               *set family_origin 7
               *set gender_p 1
               *goto kid_life1
            *if (((gender_parent = "male") or (gender_parent = "trans woman")) or (gender_parent = "other")) #don't have contact with the one I caused that to, though."
               *set family_origin 10
               *set gender_p 2
               *goto kid_life1
            *if (((gender_parent = "female") or (gender_parent = "trans man")) or (gender_parent = "other")) #don't even know the name of whoever got me pregnant, though."
               *set family_origin 8
               *set gender_p 1
               *goto kid_life1
            *if (((gender_parent = "male") or (gender_parent = "trans woman")) or (gender_parent = "other")) #don't even know the name of whoever I caused that to. They just dropped $!{kid_firstname} off and went away."
               *set family_origin 11
               *set gender_p 2
               *goto kid_life1
      #artificially conceived."
         And...
         *choice
            #I'm still in good contact with ${kidtheir} other parent."
               *set family_origin 12
               *goto kid_life1
            #...well, I don't have contact with ${kidtheir} other parent."
               *set family_origin 13
               *goto kid_life1
            #I must admit, I don't even know ${kidtheir} other parent."
               *set family_origin 14
               *goto kid_life1

*label kid_life1
The look of surprise on your companion's faces could easily win olympic gold for how perfectly in synch it is.

"My family was outraged. I would never be able of being a single parent, they said," you continue. "I still decided to raise the child. It's my life, isn't it? Not whatever they had planned for my future." You sigh a little. "I did good, though I think. I couldn't be prouder of $!{kid_firstname}."
*line_break
Another sigh follows. 
*if ((((((family_origin =6) or (family_origin =9)) or (family_origin =12)) or (family_origin =19)) or (family_origin =21)) or (family_origin =23))
   "There's still contact with $!{kid_firstname}'s other parent. $!{spousetheir} family has been immensely supportive of us."
   
   "While your family hasn't?" Mr Montgomery asks.
   
   *goto more_solo
*if (((((family_origin =7) or (family_origin =10)) or (family_origin =13)) or (family_origin =20)) or (family_origin =22))
   "There's no contact with $!{kid_firstname}'s other parent, even though I know ${spousethem}. Sometimes I wish there'd been, maybe ${spousethey}'d have been supportive."
   
   "Your family hasn't been?" Mr Montgomery asks.
   
   *goto more_solo
*if ((family_origin =8) or (family_origin =11))
   "And I don't even know the name of $!{kid_firstname}'s other @{(family_origin =8) parent| parent. They just dropped $!{kid_firstname} off}. I always said I'd look into it if ${kidthey}'d want to know, but..." You lay your head back a bit and, once again, fall silent.
   
   *goto kid_life_important
*if (family_origin =14)
   "And I don't even know $!{kid_firstname}'s other parent. I always said I'd look into it if ${kidthey}'d want to know, but..." You lay your head back a bit and, once again, fall silent.
   
   *goto kid_life_important
*if (adopted)
   "I don't even know anything about $!{kid_firstname}'s biological parents. I mean I told $!{kid_firstname} I can look into things..." You fall silent, biting your lips for a moment.
   
   *goto kid_life_important

*label kid_life_important
"Allow me the question," Mx Arcs says, sitting up straighter, "This won't go into the article, at least in my paper..." Mr Montgomery sends ${lesleythem} a dark look upon that, "But do [i]you[/i] want to know @{adopted them| the other parent}?"
*line_break
You blink and look at the two. You had thought about this before, so...

*fake_choice
   #Yes, I'd love to.
      *set wantstoknow true
      "Yes, I'd love to," you say. "@{adopted I mean| Not even for a relationship, but}... There 
   #No, I don't care.
      "No, I don't care," you say. "Though... sometimes there 
have been days when I could have used someone's support."

"Your family did not provide any?" Mr Montgomery asks.

*goto more_solo

*label more_married
was 
*if (spouse = "bad")
   a complete asshole. 
   *if (family_origin =1)
      @{(rude >55) You can't imagine how happy| I know it's cruel to say, but} I am that ${spousethey} died."
      *page_break
      You're shaking with anger, till you 
      *goto onwiththeshow
   *if (family_origin =2)
      @{(rude >55) The| As crude as it may sound, but the} divorce was one of the best decision I ever made.
      *page_break
      You're shaking with anger, till you 
      *goto onwiththeshow
   *if (family_origin =3)
      @{(rude >55) Taking| As crude as it may sound, but taking} $!{kid_firstname} and leaving that... that..." you're shaking a little, "It was the best decision I ever made."
      *page_break
      You're shaking with anger, till you 
      *goto onwiththeshow
   *if (family_origin =16)
      @{(rude >55) Taking| As crude as it may sound, but the day} ${spousethey} vanished..." you're shaking a little, "It was one of the best days..."
      *page_break
      You're shaking with anger, till you 
      *goto onwiththeshow
*if (spouse = "good")
   one of the best things to ever happen to me. 
   *if (family_origin =4)
      But then ${spousethey} died. I... You can imag-...I..."
      *page_break
      You're shaking, till you 
      *goto onwiththeshow
   *if (family_origin =5)
      But it didn't work out in the end. We got a divorce, I took $!{kid_firstname} and..."
      *page_break
      You're shaking, till you 
      *goto onwiththeshow
   *if (family_origin =17)
      But then ${spousethey} just... vanished, and..."
      *page_break
      You're shaking, till you 
      *goto onwiththeshow

*label more_solo
You laugh bitterly. "As I said, my family, at least most of them, are right bastards. And I meant it." You huff angrily. "They said I could never handle things on my own. I proved them wrong... That was, until I lost my job."
*line_break
Fists clenched and jaw set you stare at the ground, shaking, remembering all the things, all those little things that had been done to you since.
*page_break
And then you 
*goto onwiththeshow

*label onwiththeshow
catch Mx Arcs' eyes. $!{lesleythey}@{lesplur 're|'s} smiling kindly. "You don't have to go into detail."

Mr Montgomery agrees. "We'll put this down as 'time of hardship'."

"Thank you," you say, adjusting your outfit a little."

"So, just out of curiousity, though," Mr Montgomery continues after you've been able to take a deep breath. "What you dubbed ${weird_nickname}, when did it happen?"

"Five, almost six years ago," you say. "$!{kid_firstname} and I, we've been traveling around the country when our hometown stopped being an option."

Your companions nod, and you do notice their fingers twitching with the desire to write it down.

"But this 'time of hardship' ended... how?" Mx Arcs asks. "How did you end up here?"

You exhale heavily and a little clueless, and tell them about the letter. "It was... unsettling to say the least. I mean, at the start I suspected some real bizarre practical 'joke'. Truth be told, I believed this party to still be part of it."

Mr Montgomery nods. "Tem mentioned you said something like that," he smiles a bit awkward, "I hope your concerns are gone by now?"

"Mr Montgomery," you say, "If you had to deal with the sheer vileness I had to endure from my oh-so-dear 
*if (spouse = "bad")
   *if (ownfamily = "good")
      @{(spousefamily = "bad") ${spouseis} and ${spousetheir} family| ${spouseis}}, 
   *if (ownfamily = "bad")
      @{(spousefamily = "bad") ${spouseis}, ${spousetheir} family| ${spouseis}} [i]and[/i] @{(spousefamily = "bad") my own| my own family}, 
*if (spouse = "good")
   *if (ownfamily = "good")
      family-in-law, 
   *if (ownfamily = "bad")
      family and in-laws, 
*if ((spouse != "good") and (spouse != "bad"))
   family, 
you'd grow very wary." You sigh deeply. "But I admit, I'm getting used to the idea that this is not a trick, as odd as the past few days... Hell's Bells, past few weeks, have been."

You lean back and ponder for a moment. "Once bitten, twice shy..." you murmur.

"But now that you are the genuine and rightful owner of the Timeless," Mx Arcs continues after another pause, "what are your plans now?"
*page_break There It Is.
There it is.

The question you've been dreading.
*line_break
Truth be told, last week you'd not have talked to anyone but close friends about your past. But now?

Now that it's steadily sinking in that, no, this is not a joke, someone [i]did[/i] buy you a cafe to run and a home to live in, now the future is becoming the more pressing question.

Your past and even the letter feel like a sidenote in your life. And the truth is...

"I don't know," you admit, shoulders slumping. "Get $!{kid_firstname} signed up for school and get the cafe running I guess." You smile a little. "And to be honest, this article might help with the latter."

Your companions smile with a bit of pride, and Mx Arcs gets up. "Let's take a break with this first, I'm starving."

Mr Montgomery suddenly looks very worried at ${lesleythem}. "Lesley, tell me you have eaten today."

Mx Arcs shrugs. "Naw, that's why I'll be plundering the buffet now." Mr Montgomery glowers at his colleague, and Mx Arcs shrugs again. "But hey, I slept, thanks for asking."

And before Mr Montgomery can get another word in, ${lesleythey} @{lesplur have| has} wandered off.
 
Leaving Mr Montgomery to frown deeply.

*fake_choice
   #Ask him about it. This sounded worrying.
      *set disin %-2
      "That sounds terribly unhealthy," you say. @{lesplur "Are| "Is} ${lesleythey} alright?"
      
      Mr Montgomery clicks his tongue. 
   #Don't ask him, none of my business.
      *set disin %+2
      "Y'know," Mr Montgomery frowns after a moment of silently and darkly observing his companion. 
"Some people, Tem included, will tell you I get a bit of a tunnel-vision when I'm on a story or a case. But Lesley? Lesley is that several times over." He briefly looks back at the buffet table. "That technomancy turf war will do ${lesleythem} in, I fear."

"Technomancy...Turf war?" 
*if ((day2museum_power1 = "tech") or (day2museum_power2 = "tech"))
   Hold up, hadn't the young man at the museum said something about that? @{(disin <40) Yes, yes he had| You're not entirely certain, but it certainly rings a bell at least}.
   *line_break
   "I think I've heard about that. Something at Hart's Station and the TC-D or somesuch."
   
   Mr Montgomery blinks surprised and nods. "Yes, exactly."
   
   "But that's all I know," you say and Mr Montgomery looks at you. 
*if ((day2museum_power1 != "tech") and (day2museum_power2 != "tech"))
   You scratch your cheek a little bewildered, waiting for an explanation.
   
   "Up in Hart's Station and the TC-D, Tesla-Coil-District." Mr Montgomery says. 
"Do you know about the districts in question?"

You shake your head.

"Alright then," your companion says and leans back, sorting his thoughts by the looks of it.
*page_break
"The two northernmost districts of CoCi are known as the Tesla-Coil-District and Hart's Station. Oh, and no, Jenny has nothing to do with the namesake, trust me, she has heard [i]all[/i] the jokes about it. Anyway... Hart's is to the west, where the docks and the freight depots are. Poorest district in town, just beyond the Thorn's-Gate-Cemetery in Old Town"

"Poor district?" you ask.

"You seem surprised."

"With what I've seen around the city so far..."

Mr Montgomery smiles lopsided. "$!{parent_address} $!{lastname}. While I think CoCi does better than some other cities, other realities even... I know we are far from an Utopia. We have poverty, homelessness and so forth. We try though."

"That [i]is[/i] more than some are even willing to do."

Mr Montgomery smiles a little grateful at you, and flexes his fingers after a moment.
*page_break "Where Was I?...
"Oh, yes," he goes. "So, yes, Hart's station would be that. Hard, grimy and rough. With a lot of the good things and a lot of the bad things one might expect in such part of town. And the TC-D... The Tesla-Coil-District is odd even by CoCi's standards.

*if ((day2museum_power1 = "tech") or (day2museum_power2 = "tech"))
   "I heard it's a gathering place of Chimerans."
   
   "It is indeed." Mr Montgomery nods sagely, 
*if ((day2museum_power1 != "tech") and (day2museum_power2 != "tech"))
   "And why?"
   
   "For one, it's a gathering place for Chimerans," Mr Montgomery answers, 
crossing his arms. "Mainly tech ones. CoCi never had a district that'd been 'just' Chimerans or anyone else, it's always mix and mingle, social standing not withstanding, as I said."

He looks a little awkward at that, before clearing his throat. "And then, maybe even more peculiar thing is... No one actually knows where its rings come from."

"Rings?"

Mr Montgomery briefly turns to respond to another guest greeting him, before he looks at you. "The TC-D is mostly underground. Spiraling rings going deep into the earth. That's what got it its name. We know about 15 rings, but there might be more. And everything beyond the seventh is off-limits to everyone who doesn't live or has business there or has a high enough clearing. We're not even certain if people from further down than the ninth ever ascend to the higher levels. We're not even certain if it's [i]people[/i] living down there."

You lean back and cock your head. "Now you're pulling my leg," you say, and look past him towards Mx Arcs, who is by now merrily chatting with... you think it's the marble guy from City Hall, but you might be wrong.

"Not remotely, $!{parent_address} $!{lastname}. But I had the same reaction when I heard about it for the first time. But the TC-D is what it is. Valentine -Heatstroke, you remember?- might be able to tell you more, she's there on a regular basis. Investigating some disappearances. And, Above and Below know it's likely connected to what's keeping Lesley awake."
*page_break And we're back on track.
"Oh?" It's a little surprising to hear that. Then again, a number of things have been surprising to find out just tonight.

"Yes. At least everything looks like it if you ask me."

You let out a soft sigh. "Mr Montgomery, I can't judge that. As I still have no idea what you are talking about. Not what Miss Heatstroke or Mx Arcs are doing, and certainly still not what that talk about a Technomancy turf war is about."

Mr Montgomery sits up a bit straighter and looks around. So do you.
*line_break
The party is still busy as anything, and Mx Arcs has moved over to chat with Mrs Lane and the group around her.

"Well, what do you want to know about first?" Mr Montgomery asks, catching you a little off guard.

"Umm..."

*label technoturfwar
*choice
   *hide_reuse #@{(turf =0) "What's with Heatstroke| "And how does Heatstroke figure into that}?"
      *if (turf =0)
         *set turf +1
         *set elev_tesla true
         *goto heat_tesla
      *else
         *set turf +1
         *goto heat_tesla_short
   *hide_reuse #@{(turf =0) "What's with Mx Arcs| "But how does Mx Arcs figure into that}?"
      *if (turf =0)
         *set turf +1
         *set elev_turf true
         *goto les_tesla
      *else
         *set turf +1
         *goto les_tesla_short

*label heat_tesla
"As I was saying," Mr Montgomery begins, "Valentine's been investigating irregular disappearances in the TC-D."

"Irregular compared to...?" You can't pinpoint what exactly it is, but something in Mr Montgomery's tone strikes you as off. "You sound..."

"Perplexed?"

"Yes."

"I am."

"You just sounded so certain that this is an easy case."

Mr Montgomery looks at you blankly for a moment, and shakes his head. "Did I? That wasn't my intention. You see," he rubs his chin in thought, "I'm certain the cases are connected. If it'll be easy is another question. Anyway." He stretches a little. "So, the TC-D is CoCi's shadier entertainment district. The lower you descend, the shadier it gets. When Valentine first mentioned she's looking into some disappearances, I admittedly didn't think much of it. People cross the wrong crowd in the TC-D, and they're gone. Most of them show up again."

"Alive?" you ask dryly.

Mr Montgomery gives an equally dry, short laugh. "Yes. Least they cross Scorn or the Jade Empress.

You are taking a shot in the dark here, but by the sound of this, you'd bet both of these are underworld kingpins.
*line_break
You voice your suspicion to Mr Montgomery.

"They are," he confirms. "At least we are certain it's them."

"I can't follow," you say with a sigh.

"Mhn? Oh. Oh, sorry. Alright, errr... With we I mean people who aren't buying that Scorn went completely legal after [i]Nightfall[/i] and what happened after. Just proving that he does have his hands on the wires is... impossible. Similar deal with Jade: No one's even certain she actually exists. If she's not just a name used by people to give more weight to their threats. And those that claim that they know that she's real aren't sure whether or not it is the same woman that crossed Scorn over ten years ago."

With a drawn out sigh Mr Montgomery leans back, briefly responding to another guest greeting him.
*line_break
"But forget about those two. Well, not forget, as you really ought to be careful should you ever go to the TC-D, but... they have nothing to do with Valentine's case. Errr... You see, Scorn, though let's say presumably Scorn, has his fingers in the affairs on the surface level and the third and fourth ring. Jade controls the fifth to eighth. But Valentine? She's following something on the even lower ones."
*page_break That's Worrying
"That's... worrying," you say, and Mr Montgomery nods.

"I trust Valentine to know what she's doing, but she's been rather secretive about it. She had recently contacted Tem and me to get access to a map of the lower rings -well, to the results of an attempt to make one- but all she told us was that she was looking into some disappearances," Mr Montgomery shakes his head. "I wish she'd finally talk to Ian again. He might know this stuff better."

You blink. "What do you mean, she doesn't talk to Mr Rattray?"

At this, Mr Montgomery looks at you alarmed. The expression quickly fades into sad embarrassment and he shakes his head. "Nothing. In any case, Valentine is certain that someone else but the usual suspects are behind these disappearances."

*goto turf_inter

*label les_tesla
*if (day2visit = "city")
   Mr Montgomery looks at you, lowering his voice. "Do you remember Miss Gotten?"
   
   "That thief Prestige fought?"
   
   Mr Montgomery nods bitterly.
   
   "How is he, by the way?"
   
   "Better, thanks for asking. Burrowing himself in his room, learning. School starts again soon, and he still has some things to catch up with." He 
*if (day2visit != "city")
   "You see," Mr Montgomery says, leaning towards you and lowering his voice. "Lesley is investigating Miss Gotten."
   
   "Who's that now?"
   
   "A burglar. As skilled as she's cocky. She doesn't seem to have powers, but she has so far managed to run rings around many heroes and villains alike." Mr Montgomery scrunches his nose up in a small pout, before he 
draws a long breath. "Anyway, Lesley is looking into who Miss Gotten is, and has found that she might have a connection to Hart's or the TC-D."

"Aha? And the turf war?"

"For a while now there's been a constant clash between two groups of tech-Chimerans: cyberpunk, in lack of a better word, ones and, well, steampunk ones. Former is lead by some shady individual calling himself the EMPeror, capital e-m-p, and the latter by a young woman going by 'Automatona'. Funnily enough one of our sister towns had to deal with someone of the same name, but it seems it's two people."

He scratches his chin for a moment. "Anyway... It'd appear as if these groups are at war with each other over which kind of tech-Chimeran is better."

Ah yes, the good old logic of war.

You ponder this for a moment, and then signal your companion to continue.

*goto turf_inter

*label heat_tesla_short
"Valentine is investigating some disappearances in the TC-D's lower circles," Mr Montgomery explains. "Some irregularities. You see, the TC-D is CoCi's shadier entertainment district. So, a missing person here or there, especially when they crossed the wrong crowd is unfortunately not that uncommon. But Valentine is certain that someone else but the usual suspects are behind these cases."

"And Miss Gotten and... these two others figure into it how?""

"I'm certain Miss Gotten is the eyes and ears of either of those, picking out targets to weaken the other side or to sort out weak links."
*page_break
*goto enter_haggerty

*label les_tesla_short
*if (day2visit = "city")
   Mr Montgomery looks at you, lowering his voice. "Do you remember Miss Gotten?"
   
   "That thief Prestige fought?"
   
   Mr Montgomery nods bitterly.
   
   "How is he, by the way?"
   
   "Better, thanks for asking. Burrowing himself in his room, learning. School starts again soon, and he still has some things to catch up with. As for Miss Gotten: Lesley's been 
*if (day2visit != "city")
   "You see," Mr Montgomery says, leaning towards you and lowering his voice. "Lesley is investigating Miss Gotten."
   
   "Who's that now?"
   
   "A burglar. As skilled as she's cocky. Lesley is 
looking into who Miss Gotten is, and has found that she might have a connection to Hart's or the TC-D."

"Aha? And the turf war?"

"Beside Scorn and Jade in the TC-D there's also someone calling himself the EMPeror on the lower circles. A self-proclaimed ruler of cyperpunk chimerans. And arch-nemesis of a villainess called Automatona, over in Hart's."

Mr Montgomery scratches his chin for a moment. "Automatona leads the, well, more steampunk-ish Chimerans, and it'd appear as if these groups are at war with each other over which kind of tech-Chimeran is better."

Ah yes, the good old logic of war.

"And given who it is who disappeared, I'm certain that Miss Gotten is the eyes and ears of either of those two, picking out targets to weaken the other side or to sort out weak links."
*page_break
*goto enter_haggerty

*label turf_inter
You lean back, chin on your chest in thought, pondering what you just learned. "This is all... confusing and concerning," you say, trying to make sense of things. "You think @{elev_tesla she| ${lesleythey}}'ll be alright?"

*if (elev_tesla)
   "I trust in Valentine's abilities. She's as headstrong as she's cocky, but she's not someone to rush into things without a second thought."
   
*if (elev_turf)
   "I trust Lesley to know what ${lesleythey}@{lesplur 're|'s} getting ${lesleyselves} into. I just wish Lesley would take things a little slower."
   
You nod slowly, and rub your chin. "I can't say I fully understand any of that,..."

*goto technoturfwar

*label enter_haggerty
"Nice theory, Art," Mx Arcs interrupts, slinking back into ${lesleytheir} seat with a plate, "But I had and dropped that idea of a connection a while back. I might pick it up again if I find any substantial evidence."

"Oh." Mr Montgomery looks a little disappointed, while Mx Arcs beams brightly at him.

"While there seems to be something about Miss Gotten that connects to Hart's and the TC-D, alas, it doesn't look as if she's involved in that clash."
*line_break
Mx Arcs gulps down a fancy and tiny feta canape, and eyes you and Mr Montgomery for a moment, whacking ${lesleytheir} finger. "No, no. These are two different things. I believe now that Miss Gotten has her hideout somewhere along the border between Hart's and the TC-D. Just need to find it."

Mr Montgomery knits his brows. "Lesley, I really hope you are not planning on investigating that on your own."

*if (day2visit = "city")
   Given how badly Prestige fared against this Miss Gotten, you doubt Mx Arcs would stand a chance.
   
"Oh never, Art," Mx Arcs responses. "Do you have time on Tuesday? Eight-fourty pm? Thorn's northern gate?"

Mr Montgomery sighs but ponders. "Lesley, I don't..."

"How did [i]you[/i] get into here?" A voice (another familiar one, and not in a good way) cuts Mr Montgomery off, and you whip your head around.
*page_break Oh Hell's Bells
Standing there like wrath-incarnated is that horrible @{(rival_gender = "male") man| woman} you had had the misfortune of meeting at the hairdresser on your first day in town.
*line_break
You worry a little for the glass in ${rivtheir} hand.

"You know each other?" Mr Montgomery blurts out, drawing all attention.

As pointless as that question is most of the times it's uttered, it doesn't fail to do one thing: Defuse the situation.

That horrible @{(rival_gender = "male") man| woman} looks at Mr Montgomery bewildered, the grip on ${rivtheir} glass relaxing. "I... had the misfortune of making this person's acquaintance."

@{((rude >55) and (rash >55)) "The feeling's mutual," you snarl| You just glower at ${rivthem}}.

That horrible @{(rival_gender = "male") man| woman} scrunches up ${rivtheir} nose: "If you wish to know, Mr Montgomery, they... Oh, what is it anyway? They? He? She? Em?"

The question catches you more off-guard than when Mx Arcs asked it. "Umm, '$!{they}'...?"

"Is that a question mark I hear, really? Tardy, tardy." That horrible @{(rival_gender = "male") man| woman} smirks at you for a moment, before looking back at Mr Montgomery. "If you wish to know, ${they} 
*if (rival_bottle_thrown)
   threw a bottle at me."
   
   Mr Montgomery looks at you alarmed.
   
   "$!{rivthey} had it coming," you harrumph, and next to you, Mx Arcs chuckles.
   
   "Sounds like you made as much of a positive impression on $!{parent_address} $!{lastname} as ${they} made on you, @{(rival_gender = "male") Frank| Fay}." $!{lesleythey} @{lesplur smile| smiles} slyly, and you wonder if...
*if (rival_will_remember = "one")
   @{p_plur are| is} quite a nuisance, but otherwise entirely... unremarkable."
   
   "And yet you are upset, @{(rival_gender = "male") Frank| Fay}." Mx Arcs smiles slyly. Well, good to know ${lesleythey}@{lesplur 're|'s} on your si-...
*if (rival_will_remember = "two")
   @{p_plur are| is} quite a nuisance, and an odd one at that. I admittedly haven't met anyone rude in such a polite manner before."
   
   "You sound impressed, @{(rival_gender = "male") Frank| Fay}." Mx Arcs smiles slyly. You don't really know what to make of tha-...
*if (rival_will_remember = "three")
   @{p_plur are| is} quite a nuisance, and a foul-mouthed one at that."
   
   "Yet you sound impressed, @{(rival_gender = "male") Frank| Fay}." Mx Arcs smiles slyly. You don't really know what to make of tha-...
*page_break Hold Up A Second!
You spin around and stare at Mx Arcs wide-eyed.
*line_break
"What did you just call @{(rival_gender = "male") him? I mean, 'Frank' is a common name, but you| her? You} don't mean to tell me this is..."

@{(rival_gender = "male") "Frank| "Fay} Haggerty," that horrible person interrupts, "Yes. And now tell me what you are doing here."
*if (rival_gender = "male")
   *set rival_name "Frank Haggerty"
*if (rival_gender = "female")
   *set rival_name "Fay Haggerty"

"I should explain this," Mr Montgomery says, standing up. "I believe I told you about the invitation..."

He continues explaining the whys and wherefores to Haggerty, while you frown.
*line_break
As if the evening had not been stressful enough. You groan and rub your forehead. Just your luck, isn't it?

"Are you alright?" Mx Arcs asks, and you look at ${lesleythem} bleary-eyed.

"Not really." You sigh. "I think I should go."

"With all due respect," Haggerty then almost growls at Mr Montgomery, making you look up, "But I don't know why you try. I don't believe this person is fit to get that shoddy old hovel into shape at all."

The attack on your person would have been one thing here. But then you see how heartbroken Mr Montgomery looks at that (My, the Timeless must mean more to him than he lets on) and that's definitely too much.

"Excuse you?!" You jump up and raise your chin in defiance. "What's wrong with you?"
*page_break Around You Several Heads Turn
Haggerty gives you a scrutinizing look, and raises ${rivtheir} chin, mirroring your move. "Running a business isn't for the faint of heart, my dear. And you don't strike me as capable of running a cafe. Especially not one that comes with this much baggage."

@{(rival_gender = "male") "Mr| "Mrs} Haggerty," Mr Montgomery says before you can do anything (especially anything you might genuinely regret), "I understand you and $!{parent_address} $!{lastname} had not the most favorable of first impressions of each other, but I do trust in $!{parent_address} $!{lastname}'s abilities to get the Timeless back into shape."

Somehow this is not as reassuring as it might have been intended to be, but it's still nice.

"And on what basis, Mr Montgomery?" Haggerty retorts. "Do you know ${their} cooking or anything?"

"No, but neither do you, or am I mistaken?"

Haggerty harrumphs. And for a moment you wonder how this would play out if Mr Montgomery would not be the mayor's husband. "Mr Montgomery, I believe you've forgotten that I'm the head of several businessess [i]and[/i] a judge on Cooking Cornucopia," ${rivthey} then says and turns to walk off, but not without giving you a nasty last glance. "I know a failure when I see one."

Alright, that does it!

*fake_choice
   #Call Haggerty out.
      *set skulduggery %-5
      *set rival %+5
   #Get Haggerty's attention and call ${rivthem} out.
      *set skulduggery %+5
      *achieve toast1
      You quickly look around, and grab a piece of bread from Mx Arcs' plate.
      
      And hurl it at Haggerty's head.
      
"Listen here, 
*if (rude >55)
   @{(rival_gender = "male") Mister| Missy}!"
   *line_break
*if (rude <=55)
   you..." You manage to bite back an insult.
   *line_break
The immediate area around you falls @{(rude <=55) silent nevertheless| silent}.
*line_break
*if (ruff<=45)
   "I might not be some world-class cook or some business mogul," you soldier on, "but I can tell you one thing: Someone bought me that cafe, asking me to run in. I don't know who, but I do know that they must have trust in my abilities and believe in me. Hell knows I've went through some shit in live, and that I didn't trust this whole thing at first. But you know what?" By now you have marched forward and are pretty much nose to nose with Haggerty. "I will gladly take this chance and make the best of it. And I will make you eat. Your. Words."
   
   *goto eatyourwords
*elseif (ruff >55)
   "I'm no great cook, sure," you say bravely, "but someone bought me that cafe, and they trust in what I can do! I endured a lot of shit in my live, enough to not trust all of this at first. But you know what? I [i]will[/i] take this chance. I'll show you what I can do!"
   
   *goto eatyourwords
*else
   "I'm no world-class cook or anything, sure," you state bravely. "But Hell knows, someone out there trusts in me enough to have bought me that cafe. I've been through some nasty stuff, hell, I didn't even believe all of this to be true. But you know what? I am not going to disappoint whoever got me the Timeless. And I'll show [i]you[/i] what I can do!"
   
   *goto eatyourwords
*label eatyourwords
"You'd have to physically force me to get into that hovel," Haggerty responses unfazed, "or eat your food. Also don't threaten me at my own party."

Your blood is boiling. All eyes on you, your chest heaving and your body shaking, you don't know how to respond to that.

"Got nothing to say? Thought so." Haggerty smirks and turns away. "Be glad you are here as Mr Montgomery's guest. Otherwise I..."

While you can guess how that sentence was meant to end, Haggerty doesn't get that far.
*line_break
Because hearing ${rivtheir} tone, watching ${rivthem} sashay away like that, causes the entire mixture inside you to explode.
*page_break "I'll join the show then!"
"I'll join the show then!" You shout.

If the party had fallen silent before, they now reached a state of negative sound.

Haggerty stops. And turns slowly. "Pardon?"

"I said I'll join the show. You are a judge on there, remember?" You glare daggers at ${rivthem}. "I don't know how Cooking Cornucopia works, but I know enough about such shows to know I'm good enough to get on one. Maybe not this season or the next..."

"Why not?" a voice interrupts and throws you off your game. At least Haggerty doesn't do any better by the looks of it.
*line_break
You turn and look at Mrs Lane, who looks at you like innocence made solid.

You cock your head at her. "Err, what?"

"Three contestants dropped out on short notice. There's a couple of months between the initial picking and the beginning of the show, so most runner-ups won't be available anymore now."

"And as we already limit CoCo to 20 initial entries per season," a woman in a mint-green evening dress chimes in, "There should be a spot for you."

You open your mouth to respond.

You close your mouth.
*line_break
"I..." you finally manage, as Mr Montgomery steps up, claps his hands and beams brightly.

"Why, that is an amazing idea. Don't you agree, @{(rival_gender = "male") Mr| Mrs} Haggerty? Seeing how much both, the show and the cafe mean to many people, this would certainly have an incredible effect on... many things."

You look from Mr Montgomery (who is sporting a smile that says 'We can both play the [i]I'm rich and influential[/i]-card, but remember who [i]I[/i] am) to Haggerty, and again you slightly worry for ${rivtheir} glass.

Then Haggerty turns to you, and flashes you the falsest smile you've ever seen. "Why, yes, Mr Montgomery. But, of course, this would require $!{parent_address} $!{lastname} here to be up to the challenge."
*page_break ...
The rest of the evening passes by in a bit of a blur until you find yourself stretched out on your bed, staring at the ceiling.

"$!{kid_calling}?" You turn your head to find $!{kid_firstname} standing in the door, 
*if (whattheheck_counter =7)
   hugging @{(day2visit = "city") Henny| Henny to her chest and} 
*if (day2visit = "city")
   @{(whattheheck_counter =7) and| hugging} Gertrude to ${kidtheir} chest and
rubbing sleep from ${kidtheir} eyes.

"Hey ${kid_nick}," you say and sit up. "Did I wake you?"

$!{kid_firstname} nods. "How was the party?"

You smile at ${kidthem} askew. "Well..."

To that, your ${parent_calling} wrinkles ${kidtheir} nose and looks at you funnily. "$!{kid_calling}, I know that face," ${kidthey} @{c_plur mutter| mutters}. "What did you [i]do[/i]?"

*set contest_entered true
You let out a defeated sigh. "I... guess I joined a cooking show."
*finish Onto Chapter 2 Act 1: Hairy, Hairy, Quite Contrary