*title Aetherian Spell Academy
*author Karlan
*scene_list
  startup
  secondyear
  loudestmaze
  master_and_creator
  crimson_weapon

*comment ||MC Basic Information and Pronouns Block|| [Variables and stats regarding the MC, as well as how much money they have.]

*create fname "Anonymous"
*create family_name "Identity"
*create Name "Anonymous"
*create gender "Unknown"
*create gsuffix "None"
*create coins 0
*create orientation "bisexual"

*comment -----------------------------

*create mcnoun3 "none"
*create mcpronoun "none"
*create mcposnoun "none"
*create mcselfnoun "none"

*comment ||MC Personality Block||

*create amity 50
*create hostility 50
*create calmness 50
*create excitability 50
*create intellect 50
*create intuition 50

*comment ||School Friend Block|| [Variables and stats exclusive to the school friend in Ch.1]

*create school_friend "None"
*create fmeter 30
*create fskill "None"
*create fskill2 "None"
*create skin "Brown"
*create posnoun "None"
*create pronoun "None"
*create selfnoun "None"
*create noun3 "None"

*comment ||Friend Block|| [Variables and stats exclusive to Hane and Morgana. Tentative rival character].

*comment hmeter belongs to Hane. First letter before "meter" is a good indicator. morgmeter is Morgana.

*create hmeter 0
*create haneknowdark 0

*create morgmeter 0
*create morgknowdark 0

*create romance "None"
*create lnoun "None"
*create love 0

*create rmeter 0
*create rivstatus "None"

*comment ||Title Block|| [Variables regarding the titles of MC].

*create title1 "Magical Prodigy"
*create title2 "of Great Potential"
*create title "None"

*comment ||Ally Block|| [Allied summons and stats/variables related to them.]

*create demonbound 0
*create demonaccolade "Demon Slayer"
*create purifyaccolade "Demon Purifier"

*comment --------------------------------------

*create prometheanname "None"
*create catalyst "None"
*create catadjective "None"

*create prometheanpower 0
*create prometheandefense 0

*create darkpromethean_bound 0

*create prometheanbound 0

*comment -------------------------------------

*comment ||Accolade Block|| [Achievements for the MC].

*create deeds 0
*create accolade1 "None"
*create accolade2 "None"
*create accolade3 "None"
*create accolade4 "None"

*comment ||MC Stat Block|| [Combat and Charm stats for MC].

*create combat 8
*create swiftness 8
*create creation 8
*create charm 5
*create healing 8
*create darkness 0
*create spellcraft 8
*create conjuration 8

*comment ||MC Equipment||

*create teleporter 0

*comment || Variables for situational conversations. Intended for accurate world-building and for skipping unnecessary conversations.||

*create summer "None"

*create luxisknown 0

*create demonknowsfriend 0

*create raychangehair 0
*create rayhaircolor "neon green"
*create rayhairstyle "fauxhawk"

*create dinnersuit "None"

*create annaknowdark 0
*create annahate 0
*create bertrandknowdark 0

*page_break

*comment Update command for title. Otherwise title variable will not work properly.

*set title "${title1} ${title2}"



*comment || SCENE JUMP MENU ||

*comment goto_scene secondyear
*comment goto_scene loudestmaze
*comment goto_scene master_and_creator
*comment goto_scene crimson_weapon



*comment Save slots for dashingdon website and beta testing.

*sm_init spellacademy | 5

*comment Game begins here.

*image title_logo.png
*image town.jpg



The continent of Aether was always plagued with war. The nations of Esten and Lahar have long been neighbors, yet they've fought for centuries. Their opposing cultures, and equally nationalistic behaviors, have set them to war against each other since Esten's declaration of independence in the Moon Year 1339.
During the Moon Year 1680, the governments of both countries suddenly agreed to a peaceful end to the war. Neighboring countries were initially relieved during the armistice, but the reasons that ended The 300-Year War remain elusive. Citizens are whispering of conspiracies that caused the end of the war, such as the Estenian president being poisoned and falling deathly ill.
Both governments refuse to speak regarding the topic, and the general populace has been instructed to ignore inquiries regarding it. Yet the tension in Aetheria remained heavy and thick.

*page_break
*image chapter_1.png

*image esten.jpg

Esten is a technologically advanced society. Boasting the most advanced and numerous weaponry in the entire continent. Esten's population is forty-five million, and growing rapidly. The advancement of technology, however, has made the nation the target of contempt for less wealthier nations.

This country's cities hold futuristic technology. Citizens of Esten employ the use of high-tech computers and flying cars for daily life. It's not uncommon to see Estenians using holographic technology for mundane activities, such as driving vehicles and teaching school lessons.

*page_break

*image furze.jpg

Lahar is the largest nation in Aether. The population of this country is north of sixty million people. They possess the most advanced magic, also known as spellcraft, in Aether. Their country
is home to the most prestigious and largest spellcrafter school in the continent, The Aetherian Spell Academy.

Unlike Esten, citizens of Lahar do not employ high-tech vehicles and appliances. Despite this, cell phones and cars are still used by Laharians for every day use. The usage of spellcrafting devices, otherwise known as magical appliances, are very common in this country.

Your family lives in Furze, the second largest city in Lahar. Furze is a bustling metropolis, with millions of people present in the city's streets at any given time.

*page_break

The streets of Furze are lined with cobblestone and uneven concrete. During night, the bronze and gold buildings of Furze were illuminated by lamps powered with lightning elementals. Children and curious adults would often stand next to these magical appliances, just to hear the crackling bolts of the conjured elementals.

Vehicles in Furze use rugged wheels, composed entirely of synthetic Laharian rubber, to overcome the uneven terrain. Powered by mana and electricity, Laharian cars and buses are large, bronze vehicles that all social classes employed for daily use.

The citizens of Furze wear colorful clothes, to contrast Furze's monochromatic skyscrapers, composed of Laharian polyester or wool. Crowds of people from Furze wear a gamut of colors, ranging from neon yellow to the refined shades of blues and greens.

Here in Furze, your story begins.

*page_break

Furze can be a cruel city without someone to help and guide you. Fortunately, your parents were always there to support you. Who were they?

*choice
  #My parents are wealthy merchants. They are well-versed in trading and persuading others.
    *set charm +20
    *set coins +600
    You lived a life of luxury and privilege. Your room was often surrounded
    with the most impressive decorations. Expensive, imported sheets from the tropical nation Doht surrounded your bed, and the house maids often tended to anything you needed.
    To top it off, your parents were the type of people who found it easy to get their way. Being raised by motivated and pro-active parents has made you as similarly persuasive as them.
    (Charm +20, Coins +600).
    *goto school
  #My parents work in Furze's National Hospital. They help with accident victims that pour in from the city of Furze.
    *set healing +20
    *set spellcraft +10
    Your parents both met in college. Their passion for healing magic led them both to work for Furze's National Hospital. Their naturally altruistic behavior has inspired you to do the same. Using your talent in magic
    , you decided to focus on trying to heal others as a child. Your magic is naturally attuned to mending wounds (Healing +20, Spellcraft +10).
    *goto school
  #My parents were both originally from Lahar's National Military. Although, they were discharged several years before the armistice. They have strong physical discipline and a stern disposition.
    *set combat +15
    *set swiftness +15
    Your dad came from Lahar's 56th infantry and your mom was from the 12th artillery squad. They both met during the war, where your father was discharged honorably and your mother was honorably relieved from duty
    as a Laharian cannoneer. They carry their military discipline even inside the house. You don't recall ever disobeying your parents, and you were often attempting to be a model citizen outside the house.
    In addition, your father made it mandatory to teach you the essentials of combat, when you were a child. You became proficient in fighting at an early age. Their stern discipline has made your physique more athletic, and your senses much sharper (Combat +15, Swiftness +15).
    *goto school
  #My father was a carpenter, but my mother was a gifted spellcrafter. My family was always practical. My mother uses her spellcrafting to help my father build skyscrapers for Furze.
    *set spellcraft +15
    *set creation +15
    Your parents met in community college, where your father learned your mother was capable of using magic. Your father's practical mindset
    was always enhanced by your mother's eagerness to create with her magic. Together, they helped build skyscrapers for Furze. Your mother's magic has been passed down to you, and you
    are similarly as gifted in using spellcraft to create (Spellcraft +15, Creation +15).
    *goto school
  #Both my parents were actually gifted spellcrafters, however they were overbearing. During my youth, I rebelled against them and practiced forbidden magic. I snuck into the graveyard, and used my magic to control the wandering spirits.
    *set darkness +15
    *set conjuration +15
    Your parents never discovered your secret. You know well that dark magic is forbidden to use, even the most powerful spellcrafters consider it taboo. However, the thrill of casting
    dark magic is made all the more exciting by its forbidden nature. Your parents were oblivious to your abilities, and you were able to harness the dark elements to do your bidding (Darkness +15, Conjuration +15).
    *goto school
    
*label school
*page_break
What did your parents name you?

*choice
  #Alex
    *set fname "Alex"
    *goto parents
  #Kellen
    *set fname "Kellen"
    *goto parents
  #Hayden
    *set fname "Hayden"
    *goto parents
  #Peri
    *set fname "Peri"
    *goto parents
  #Jex
    *set fname "Jex"
    *goto parents
  #I will decide my name.
    *input_text fname
    *goto parents

*label parents

*page_break
What is your family's name, ${fname}?

*choice
  #Deleon
    *set family_name "Deleon"
    *goto parents2
  #Langsteen
    *set family_name "Langsteen"
    *goto parents2
  #Nareeq
    *set family_name "Nareeq"
    *goto parents2
  #Lazlo
    *set family_name "Lazlo"
    *goto parents2
  #Kassel
    *set family_name "Kassel"
    *goto parents2
  #I will decide my family's name.
    *input_text family_name
    *goto parents2


*label parents2
*set Name "${fname} ${family_name}"
*page_break

When you were a small child, your parents called you by a nickname after a certain incident. You never outgrew this term of endearment, and sometimes patronization, for as long as you lived.

*choice
  #They called me, "Mr. Magician."
    *set gender "Male"
    *set gsuffix "Mr."
    *set mcnoun3 "he"
    *set mcposnoun "his"
    *set mcpronoun "him"
    *set mcselfnoun "himself"
    *goto school2
  #They called me, "Ms. Magician."
    *set gender "Female"
    *set gsuffix "Ms."
    *set mcnoun3 "she"
    *set mcposnoun "her"
    *set mcpronoun "her"
    *set mcselfnoun "herself"
    *goto school2
  #Though they called me by a nickname, I later changed it because I am neither male nor female. Ever since, they've called me, "Mx. Magician."
    *set gender "Nonbinary"
    *set gsuffix "Mx."
    *set mcnoun3 "ze"
    *set mcposnoun "zir"
    *set mcpronoun "zir"
    *set mcselfnoun "zirself"
    *goto school2

*label school2

You received this nickname after your magical powers became apparent, at the age of three. Your mother had finished washing the dishes. She was looking for you and found you in the living room with every furniture levitating in the air.
Though your mother herself was a spellcrafter, she was astonished that a three year-old child was capable of levitating so many objects.

Despite your talents, however, you had an accident regarding your magic. What was it?

*choice
  *selectable_if (conjuration < 15) #My magic is powerful, but difficult to control. In general, it's not a problem, but conjuration became hazardous for me to use.
    *set conjuration -5
    Any time you attempted to conjure an elemental, you seemed to destroy private property as a result. Your parents were told to prohibit you from using conjuration in the house to prevent further damage. As a result you're just not very good at it (Conjuration -5).
    *goto goals
  *selectable_if (healing < 15) #I was not very useful when mending the wounds. I had attempted to heal my own wound when I tripped on the playground, but ended up casting fire magic. It was not pretty.
    *set healing -5
    Your magic was great for utility and destruction, but entirely useless when others were injured. You learned that healing magic was more dangerous than it looked (Healing -5).
    *goto goals
  *selectable_if (combat < 15) #My magic was fine, but I had accidentally broken my leg when I levitated myself too high and fell. Needless to say, my athletic skills weren't that great.
    *set combat -3
    *set swiftness -3
    You were not permanently disabled by this incident, but you were sedentary for a long period of time. This has drastically lowered your ability to physically perform (Combat and Swiftness -3).
    *goto goals
  *selectable_if (creation < 20) #I was not very adept at creation magic. I tried using creation magic to fuse my breakfast into a waffomelet, a waffle and omelet combined together. However I ended up charring my breakfast... and the entire dining table.
    *set creation -5
    Your parents were terrified when they found the destroyed table. They weren't angry, but you were forbidden from using creation magic without supervision. Needless to say, you stopped practicing creation magic because of this incident (Creation -5).
    *goto goals


*label goals
*line_break
*line_break
Your parents decided that it was best for you to enroll in The Aetherian Spell Academy when you came of age; the Year 1 students at the academy are enrolled when they're at least fourteen. Your potential in magic was vast, and your parents believe The Spell Academy is going to tap into your natural ability
for spellcrafting, and teach you how to control it.

Meanwhile, you are going to attend Kaelich's School for Spellcrafters. A program affiliated with The Spell Academy, that teaches young children to properly wield their magic.

*page_break

Your first year at Kaelich's began when you were 10 years old. You had attended non-magic public schools in Furze, but your skills haven't improved due to the limitations of spellcraft in non-magic schools.

However, that period of time is over. Your magic would be in full usage during your time at a magic public school, and you were excited to visit Kaelich's.
However, when you first walked on campus you were thoroughly unimpressed. Kaelich's was a very small school.

It was composed of a main building, where classrooms are held, and a library building next to it with a small playground. That was the entire campus of Kaelich's. The term "humble beginnings" best describes this school, and you had hoped for something more.
During orientation, you learned that students graduated from Kaelich's when they finish three years of training at the school. Their grades and spellcrafting talents would determine whether or not they are able to attend The Spell Academy.

*page_break

During your time at Kael's, you became good friends with another spellcrafter. You first met them during your first day at school. In a classroom filled with eager young students, you see several students ahead of you.
Who would you like to speak to?

*hide_reuse
*label meeting
*choice
  #I speak to the tall boy, with curly blonde hair. He had tanned skin and green eyes. He dressed in a bright blue graphic shirt, and black jeans.
    You shook his hand and introduced yourself. He replied, "Nice to meet you, ${fname}. I'm Aron." You learned that Aron is actually of Estenian descent, but his ancestors moved to Lahar three generations ago.
    Despite his tall appearance, Aron did not seem like the athletic type. In fact, he mentioned that he spent most of his time reading books. You could tell he was passionate about spellcrafting. He had a sincere tone to his voice, but you noticed that he was much less social than the other students in the room.
    *goto meeting
  #I speak to the red-headed girl with blue eyes. Her fair skin was specked with freckles. She dressed in a teal skirt that matched her eyes.
    You shook her hand and introduced yourself. She replied, "I'm Danae. It's a pleasure to make your acquaintance." Danae had lived in the rural towns of Esten all her life. When her parents discovered she was a spellcrafter, 
    they decided to migrate to Lahar to give her a magical education. Though spellcrafters weren't discriminated against in Esten, Danae was regarded cautiously by her peers due to her ability to cast magic. She's bright-eyed and optimistic
    that Kaelich's will be kinder to her.
    *goto meeting
  #I speak to a boy with golden eyes. He had brown skin and brown hair. He wore a white, long-sleeve shirt and knee-length shorts.
    You shook his hand and introduced yourself. He replied, "I'm Jericho, it's great meeting you, ${fname}." Jericho is originally from the tropical nation of Doht, an island to the far north.
    However, Jericho moved to Furze at the age of two, and doesn't remember much about Doht. Jericho is apparently the son of a wealthy businessman, although, he never explained what his father did for a living. Jericho had an irreverent, and boisterous disposition. No doubt, a result of his wealthy and privileged upbringing.
    *goto meeting
  #I speak to the girl with streaks of blue dye in her long, dark hair. She had dark skin and was slightly short. She wore yellow jeans and a matching bright, yellow tank top.
    You shook her hand and introduced yourself. She replied, "How's it going? I'm Erika." Erika is native to Furze. She's quite used to the hustle and bustle that's required for daily life in Furze.
    Due to her city upbringing, Erika was naturally motivated and ambitious. She bragged about what she wore, and mentioned that she made the clothes herself. It seemed like Erika was an avid fashion designer.
    *goto meeting
  #I speak to the only boy with a bright, neon green faux hawk. He had pale skin and a lip piercing on the left side of his lip. He was quite tall. He wore a plain, black shirt, and polyester jeans.
    You shook his hand and introduced yourself. He replied, "'Sup! I'm Ray. Is it your first time at magic school too, ${fname}?" You explained to Ray that magic schools are not available until someone is ten years old.
    "Oh, is that right?" He regarded your information coolly, and didn't seem to take it seriously. He had a very relaxed nature, although, you weren't sure if it would help them in a competitive school such as Kaelich's.
    You learned that Ray is from Muria, the capital of Lahar. He moved to Furze when his mother got a new job. Despite his apathetic nature, you could tell that Ray was fiercely loyal when it came to friends and family.
    *goto meeting
  #I speak to the girl with stark, raven black hair. She had a pearly skin completion, and was slightly tall. She wore a hot-pink sweater, and gray denims.
    You shook her hand and introduced yourself. She replied, "Well, it's nice to meet you too, ${fname}! I'm Alana." Alana was... very eccentric. Despite her features, Alana was prone to laughing at everything.
    You took it to mean that she had a jolly personality. But you're not sure that's true, either. Alana was originally from the oriental city, Grotto, a city to the far east of Lahar's border. She explained that her family moved to Furze, last year, so she could enter magic school in the city. Despite her explanation, you were bizarrely fascinated with her unending sense of optimism. Strangely, her optimism wasn't of the infectious kind, so anyone who witnessed it could only watch in resigned amusement.
    *goto meeting
  #I'm finished speaking with everyone, and I take my seat.
    *goto seat

*label seat
*line_break
The class bell rang and you decided to take your seat. Who did you sit next to?

*choice
  #I sat next to Aron, he nodded at me in a friendly manner.
    You noticed that his desk was neatly arranged, and he had a notebook open for taking notes. When you asked him about his organized desk, he simply shrugged. It seemed like Aron was somewhat secretive of his thoughts. However, you felt he would slowly open up.
    *set school_friend "Aron"
    *set skin "tanned"
    *set posnoun "his"
    *set pronoun "him"
    *set selfnoun "himself"
    *set noun3 "he"
    *goto representative
  #I sat next to Danae, she smiled at me warmly.
    When you sat down, but you could tell she was relieved you sat next to her. She immediately began talking to you, and regarded you with familiarity. Danae was very kind, but you're afraid
    if the students at Kaelich's would take advantage of her kindness. Furze was a big city, and it's not uncommon practice to take advantage of someone to advance your own purposes here.
    *set school_friend "Danae"
    *set skin "fair"
    *set posnoun "her"
    *set pronoun "her"
    *set selfnoun "herself"
    *set noun3 "she"
    *goto representative
  #I sat next to Jericho. He gave me a fist bump, as soon as I sat down.
    Jericho gave you a piece of gum as a token of friendship. How touching.
    *set school_friend "Jericho"
    *set skin "brown"
    *set posnoun "his"
    *set pronoun "him"
    *set selfnoun "himself"
    *set noun3 "he"
    *goto representative
  #I sat next to Erika. She gave me a smirk before I sat down.
    Her expression made it seem like she was judging your clothes. You weren't sure, but it seemed like she approved of what you were wearing, which only confused you more. You were simply wearing denim jeans and a plain t-shirt. Erika's lively personality made her a lot more endearing than you expected.
    *set school_friend "Erika"
    *set skin "dark"
    *set posnoun "her"
    *set pronoun "her"
    *set selfnoun "herself"
    *set noun3 "she"
    *goto representative
  #I sat next to Ray. He lazily nodded at me, acknowledging my presence.
    Too cool for school, apparently. Despite this, you were interested in seeing if there was more to Ray.
    *set school_friend "Ray"
    *set skin "pale"
    *set posnoun "his"
    *set pronoun "him"
    *set selfnoun "himself"
    *set noun3 "he"
    *goto representative
  #I sat next to Alana. She squeed when I sat down. No she literally just said "squee!" when I sat down.
    You were unsure if this was a good choice of seat. Alana stared, deeply, at you with a large smile plastered on her face. May the Goddess help you against Alana's bizarre personality.
    *set school_friend "Alana"
    *set skin "pale"
    *set posnoun "her"
    *set pronoun "her"
    *set selfnoun "herself"
    *set noun3 "she"
    *goto representative

*label representative
*page_break

During Practical Magic class, ${school_friend} struggled to conjure fire. You approached ${pronoun} and showed ${pronoun} how to do it.

${school_friend} was surprised by your actions, ${noun3} asked you, "Why did you teach me how to do that? Aren't you competing to enroll in The Spell Academy?"

This was your first experience regarding Kaelich's elitist culture, which justified ${school_friend}'s reaction. Many students regarded each other with cutthroat attitudes, despite their young age. This is only made worse by the fact that only the best of the best spellcrafters were given a place in the student body
at The Spell Academy, and not every student at Kael's was going to be enrolled due to the very small acceptance rate. As it stands, helping out your fellow students isn't really a common occurrence in public magic schools.

You replied...

*choice
  #"It looked like you were struggling, so I thought you might have needed some help."
    *set amity +5
    *set hostility -5
    *goto friendtwo
  #"You were doing it wrong, and it bothered me. I like fixing things that aren't in order."
    *set intellect +5
    *set intuition -5
    *goto friendthree
  #"It seemed like everyone else has already move on, and you were the only one still trying to conjure fire. It was a bit sad to watch."
    *set calmness +5
    *set excitability -5
    *goto friendfour
  #"It's obvious, you're not as talented in magic as me. Therefore, I don't think you can even compete with me."
    *set hostility +5
    *set amity -5
    *set intellect +5
    *set intuition -5
    *goto friendfive

*label friendtwo
Your kind response resonated with ${school_friend}. You smiled at ${school_friend} and ${noun3} returned your smile.

${school_friend} gladly accepted your help. During the rest of class, you've both decided to keep each other company.

After showing ${pronoun} what to do, ${school_friend} tried to do the spell.

It worked perfectly.

${school_friend} was grateful to you. Above all else, your friendly demeanor seemed to have helped ${school_friend} relax when ${noun3} casted the spell.

Despite the cutthroat nature of Kaelich, both of you started an unlikely friendship.
*goto friend

*label friendthree
Your intellectual obsession fascinated ${school_friend}. They returned your cold logic with a look of amusement.

Fascinated by your skill, ${school_friend} watched you with ${posnoun} full attention.

The rest of the class was occupied with you and ${school_friend} sharing your time together.

After watching you, ${school_friend} decided to try the spell. It had worked perfectly.

${school_friend} was grateful for your help, and they shared a brief hug with you.

Despite the cutthroat nature of Kaelich, both of you started an unlikely friendship.
*goto friend

*label friendfour
Your voice was tinged with pity. ${school_friend} was taken aback by your response.

${school_friend} replied, "I can do it, just watch."

${school_friend} gathered ${posnoun} palms together, and ${noun3} loosed mana into her palms. The mana in ${posnoun} palms lit on fire, "Yay! I did it. See? I didn't need..."

Before ${noun3} could finish ${posnoun} sentence, the fire in ${posnoun} palms fizzled. The spell had failed.

${school_friend} reluctantly turned to you, "Okay, maybe I do need some help."

You smiled, "Alright. Here's how you do it..."

The rest of the class, the two of you were inseperable. ${school_friend} wanted to try out the spells for ${selfnoun}, but ${noun3} watched you diligently.

When ${noun3} finally learned the spell, the both of you looked at each other in triumph.

Despite the cutthraot nature of Kaelich, both of you started an unlikely friendship.
*goto friend

*label friendfive
Your hostile response, flustered ${school_friend}.

${school_friend} replied, "Just watch, I can do it too!"

${school_friend} gathered ${posnoun} palms together, and ${noun3} loosed mana into her palms. The mana in ${posnoun} palms lit on fire, "Yay! I did it. See? I didn't need..."

Before ${noun3} could finish ${posnoun} sentence, the fire in ${posnoun} palms fizzled. The spell had failed.

You spoke, "Here's a little tip, if you want to catch up to me."

You gave ${school_friend} a small hint towards executing the spell perfectly. After being given some help, ${noun3} succeeded after their fourth try.

${school_friend} looked at you with a newfound sense of respect. It seemed as though ${noun3} realized that you were in another league, in terms of skill, but they appreciated the small hint you gave them.

Despite the cutthroat nature of Kaelich, the two of you slowly became friends.
*goto friend

*label friend
*page_break
${school_friend} was often ignored by the other students for ${posnoun} lack of talent in magic. You had at least expected that some would talk to ${pronoun}, but ${noun3} was treated as entirely nonexistent. You couldn't decide whether to be furious or appalled.
In addition, most of the other kids believed that ${school_friend} would drop out next year, a possibility that made a few students disturbingly giddy.
You are the only student at Kael's that treats ${school_friend} with respect, and you aren't particularly bothered by the fact that ${noun3} wasn't the most talented spellcrafter.

*page_break

Due to your amity towards one another, you became concerned for ${school_friend} towards the end of the school year.
Your first year at Kael's passed by in a blur, but it looked as though ${school_friend} hadn't improved ${posnoun} spellcrafting in the least bit.
There was a very real chance that ${noun3} was going to fail and drop out of school next year if ${noun3} didn't improve.

During the last month of school, you saw ${school_friend} in the school yard, attempting to use a basic-level creation magic. You approached ${school_friend}, as you did in Practical Magic class, and you attempted to help ${pronoun}.

This time however, ${noun3} refused. ${school_friend} explained, "Thanks, ${fname}, but how am I supposed to get better if I always rely on you? Let me figure this out by myself, please. It's a matter of my pride."

You responded...

*choice
  #"Of course, there's no way you'll fail." You gave ${pronoun} an encouraging grin.
      You left ${pronoun} with encouraging words, and left ${pronoun} to figure it out. The week after this incident, ${school_friend} came back to you with a satisfied expression.
      "Guess what? Check this out." You looked at ${posnoun} palm, and saw small pebbles of rocks levitating in the air. With ${posnoun} other hand, ${noun3} casted a spell with a faint shimmer of light.
      The pebbles began to rearrange themselves and formed a small dragon figurine.
      *set fmeter +5
      *set amity +6
      *set hostility -6
      *set intuition +6
      *set intellect -6
      *goto friend2
  #"Alright, if you think you can handle it." In truth, you were doubtful that ${noun3} would succeed.
      You hid your hesitation well, and left ${school_friend} to learn the spell by ${selfnoun}. The week after this incident, ${school_friend} came back to you with a satisfied expression.
      "Guess what? Check this out." You looked at ${posnoun} palm, and saw small pebbles of rocks levitating in the air. With ${posnoun} other hand, ${noun3} casted a spell with a faint shimmer of light.
      The pebbles began to rearrange themselves and formed a small dragon figurine.
      *set calmness +6
      *set excitability -6
      *goto friend2
  #"No way, this is a basic spell that everyone should've learned by now. You need all the help you can get!" You insisted with an exuberant tone.
      ${school_friend} replied, "Thanks for your concern, but trust me. This is for my own good." Reluctantly, you let ${pronoun} do as ${noun3} wish. You hoped that ${noun3} knew what ${noun3} was doing.
      The week after this incident, ${school_friend} came back to you with a satisfied expression.
      "Guess what? Check this out." You looked at ${posnoun} palm, and saw small pebbles of rocks levitating in the air. With ${posnoun} other hand, ${noun3} casted a spell with a faint shimmer of light.
      The pebbles began to rearrange themselves and formed a small dragon figurine. Astounded, you made it a point to let ${school_friend} learn on ${posnoun} own if results like this were happening.
      *set fmeter -5
      *set excitability +6
      *set calmness -6
      *goto friend2
  #You said nothing, and you simply looked at ${pronoun} curiously. You calculated that it was possible, but at the expense of long hours of training and studying
      ${school_friend} took your silence as a form of agreement and nodded quietly. It seems you've both come to an understanding. The week after this incident, ${school_friend} came back to you with a satisfied expression.
      "Guess what? Check this out." You looked at ${posnoun} palm, and saw small pebbles of rocks levitating in the air. With ${posnoun} other hand, ${noun3} casted a spell with a faint shimmer of light.
      The pebbles began to rearrange themselves and formed a small dragon figurine. It looks like your faith in ${school_friend} paid off. Although, you could tell ${noun3} hasn't had a good night's sleep in a while.
      *set intellect +6
      *set intuition -6
      *goto friend2

*label friend2
${school_friend} looked at you with a smile on ${posnoun} face, "This is only the beginning. I'm not as gifted at spellcrafting as you, ${fname}, but I'll work twice as hard. That
way I won't fall behind you."

As illogical, and sometimes reckless, ${school_friend} was, ${noun3} was capable of great things when ${noun3} exerted extreme effort. Your friend's overly passionate temperament was quite endearing, and you couldn't help but smile when ${noun3} succeeded.

*page_break

Your first year at Kael's has drawn to a quiet closure. Later on, you received a call from ${school_friend} and learned that ${noun3} was able to pass all ${posnoun} classes.
It looked as though ${noun3}'s beaten the odds, and ${school_friend} was going to be able to continue attending Kael's.

This news brought relief to you, but you still remain concerned. You still had three more years at Kael's, and if your friend struggled with first-year magic then using
higher level magic would be even more difficult. You can only hope that ${school_friend}'s work ethic can save ${pronoun} from dropping out.

*page_break

During summer break, your family visited the capital of Lahar, Muria. The capital also had the largest population than any other city in the country.
Furze was a large city, but Muria was even larger. Even more impressive, the capital was surrounded by large skyscrapers that floated around the city. These skyscrapers are used mainly for large businesses, although some were maintaining the city's electrical and mana energy source.

Unlike Furze, the streets of Muria were composed of a smooth concrete. The buildings were noticeably more colorful than Furze. The skyscrapers of Furze were mostly bronze, gray, and gold; whereas the buildings of Muria seemed like endless rows and bundles of teals, rusted reds, violets, and silver.

When you and your parents toured Muria, the people wore eclectic clothing. A strange mixture of Laharian wool and Estenian fibers were woven into Muria's modern fashion. In particular, feminine headdresses and high-fashion bucket and breton hats were in vogue in Muria.

You also noticed that, despite the high volume of pedestrians, vehicles run by elementals were popular in Muria. As you walked in the street, bronze and silver buses and cars with clear domes whisked by you. The clear domes were placed next to the caboose of the vehicles, and inside them, fire and lightning elementals hummed softly as they provided energy.

*page_break

Your parents apparently brought you to Muria for a summer program at The Spell Academy. To top it off, they gave you the choice of picking the program.
The programs that were offered are specifically targeted for young children aspiring to enroll into their school.
There were many programs to choose from, but one program in particular interested you.

*choice
  #It was a leadership program, and it centered around persuading others to resolve conflicts peacefully.
    *set charm +15
    The program was called The Magician Leadership Summit, and your group was responsible for directing the other youth programs. It was fun, if somewhat chaotic.
    You were taught that in order to persuade others to your side, having a reliable reputation was often the quickest way to do it. By the end of the program,
    you've learned to effectively persuade others to your cause, if need be (Charm +15).
    *goto second_year
  #The program was taught by combat spellcrafters, and it revolved around effective uses of conjuration.
    *set conjuration +10
    The program was taught by members of Lahar's former 18th Spellcrafter Commando. The experience of these veteran magicians were apparent in their instantaneous conjuration of elementals. You quickly learned
    that the trick to controlling elementals is to reduce the number you summoned. The combat spellcrafters taught your group that having one large elemental is better than having multiple smaller elementals. 
    The more you summon, the more difficult it is to control them simultaneously. Your conjuration has improved (Conjuration +10).
    *goto second_year
  #I picked a program that gave me a lot of free time. I didn't even attend the classes; instead, I visited Muria's catacombs. It was an infamous meeting ground for necromancers before The 300-Year War.
    *set darkness +10
    The program you picked didn't matter, but you decided on Applications of Meditation. The class wasn't more than an hour, not that it mattered since you skipped it anyway.
    Instead, you went to Muria's famous catacombs, Jurl's Keep. Beneath the catacombs, you learned to empower your dark magic.
    You hadn't grasped the basics of necromancy, until this moment. The skeletons in the tomb were essentially asking to be controlled. At the moment, you can only manage to summon
    four to six skeleton warriors, but this was an improvement from before. Your attunement to darkness grows (Darkness +10).
    *goto second_year
  #It was a program that focused on efficiently harnessing mana, the source of spellcraft.
    *set spellcraft +10
    The professor that taught your group was also teaching at The Spell Academy, although you couldn't quite remember nor pronounce his name.
    You learned that mana is a substance in the atmosphere that can be harnessed, but you also learned that the human body had mana stored in the brain.
    By directing your spells to the tips of your fingers, the output of spellcrafting was increased twofold. Your newfound knowledge has boosted your proficiency in general
    spellcraft (Spellcraft +10).
    *goto second_year
  #The program was revolved around new experimental uses of spellcraft to boost athletic performance. In particular, using magic to augment individual speed.
    *set swiftness +10
    *set luxisknown +1
    The program was taught by an athletic coach currently attending The Spell Academy. They mentioned that sports programs at the school included traditional sports with no magic, but
    also offered sports that fully utilized spellcrafting. Your group was shown how to play a popular sport called, Luxis. The rules were simple, one goalie blocked a ball with whatever spell he chooses, so long as the ball isn't damaged or otherwise destroyed.
    Meanwhile, assaulters charged the goalie using only performance enhancing spells in an attempt to score a goal. The goalie's team will have three defenders, while the opposing team has five; this is done to offset the goalie's advantage. The coach spoke, "The trick is to apply levitation magic forward, instead of up. By applying a small push to a specific body part, we can allow the human body to
    do more than it was meant to." The first few games were brutal. No one could apply the theory behind forward levitation. However, after the fourth game, everyone was able to do it to some degree.
    Your swiftness has been augmented by forward levitation spells (Swiftness +10).
    *goto second_year

*label second_year

Your time at Muria was exciting, and you hope to return once again when you're finally of age to enroll at The Spell Academy.

*page_break Summer Ends

Meanwhile your second year at Kael's is now in full swing. The skills and knowledge you gained from the summer program gave you an edge over the other students,
and you were able to quickly grasp the lesson material being given by your teachers. In addition to your sheer talent for magic, your training at the summer program allowed you to pull further away from your peers.
Your second year has clearly marked you as the most seasoned magician in your class.

It seemed as though your professors hold your skills in high regard. In particular, you were well-known for...
*comment I should've probably removed the unnecessary stat checks, but I kept it because why not? It's not harming the game in anyway.

*choice
  *selectable_if (combat > 8) #I was a talented martial artist. My teachers were impressed by my knowledge of practical combat.
    *set combat +8
    Your prowess in the martial arts was at full display during Furze's Local Youth Tourney. Although you were not first place, many were able to witness your fierce combat abilities.
    The school of Kael was proud to have a talented student such as you. You were given the title, "Fiery Combatant", during the tournament (earned a new title, Combat +8).
    *set title1 "Fiery Combatant"
    *goto orientation
  *selectable_if (swiftness > 8) #I was the most agile speed runner on Kael's track team. My fellow students were in awe of my agility.
    *set swiftness +8
    During physical activities, your raw speed is unmatched by anyone at Kael's. During the cross-country race, you finished first place amongst five hundred runners, and were regarded as "Quicksilver" by Kael's student body ever since.
    (earned a new title, Swiftness +8).
    *set title1 "Quicksilver"
    *goto orientation
  *selectable_if (creation >= 8) #I was the most capable wielder of Creation magic at Kael's. My ability to fuse objects and repair broken creations were held in high regards.
    *set creation +8
    Your ability to repair and create objects at will has been indispensable to the school after an accident left half of the library in ruins. A student absentmindedly
    forgot to extinguish a lightning elemental they conjured. After leaving it at the library overnight, three quarters of the books were discovered as ashes. With your creation magic,
    you were able to help repair the damage done to the library. You were even able to repair some of the destroyed books. The staff started calling you, "Creation Savant", for your role in the library incident
    (earned a new title, Creation +8).
    *set title1 "Creation Savant"
    *goto orientation
  *selectable_if (healing >= 8) #I was well-known for being a gifted healer. My ability to mend wounds was valued by the school nurse, in particular.
    *set healing +8
    There's no shortage of accidents and injuries at Kael's. Having magic present simply means that the damage done is compounded. Every week, a student's conjuration went haywire and left a staff member
    with mild burns. You were often given praise for being a reliable mender during these events. Your ability to heal has stifled further damage from coming to both the students and the teachers at Kael's. 
    The students called you, "Almighty Mender", for your reliable healing (earned a new title, Healing +8).
    *set title1 "Almighty Mender"
    *goto orientation
  #Actually, I was known as a jack-of-all-trades. Though I wasn't gifted in one particular discipline, I was capable of using all forms of spellcraft effectively.
    *set spellcraft +3
    *set healing +3
    *set creation +3
    *set conjuration +3
    Your versatile nature allowed you to wield all magic with relative ease. The student body envied your sheer talent to use all spellcraft disciplines with
    little difficulty. The teachers, by contrast, regarded your ability with awe. Being called "Magical Prodigy" by the staff suits you perfectly well
    (Spellcraft +3, Healing +3, Creation +3, Conjuration +3).
    *goto orientation
  *selectable_if (darkness > 0) #The students whispered that I had the ability to wield forbidden magic. No one ever had proof, but I was regarded with fear due to the rumors (Requires Darkness level 1 or higher).
    *set darkness +8
    The rumors reached staff members, who regarded the rumor as pure gossip. A few students claimed they saw you summoning spirits in the graveyard, but these claims
    have never been proven true, and none had definitive evidence that you were actually able to convene with the spirits. You knew for a fact that wielding dark magic is forbidden, 
    but the power gained from studying dark magic was too exciting to give up. You've been called "Dark Crafter" by some of the students, and the title stuck (earned a new title, 
    Darkness +8).
    *set title1 "Dark Crafter"
    *goto orientation
  *selectable_if (conjuration >= 8) #I was well-known for my control over conjuration. I was talented in summoning elementals and using the forces of nature.
    *set conjuration +8
    Your ability to summon multiple elementals was unprecedented in your class. Students both feared and respected your ability to conjure great wisps of flame,
    thunderous clouds, raging waters, and the quaking earth itself. You were called "Gifted Conjurer" for your great talent (earned a new title, Conjuration +8).
    *set title1 "Gifted Conjurer"
    *goto orientation

*label orientation
*comment title must be "updated" after a new title is earned. Otherwise, the stats screen won't show the changes made to the title.
*set title "${title1} ${title2}"

*page_break

During the same year, the entire school was surprised to learn that your friend, ${school_friend}, had become one of the best magicians at the school.
This comes as no surprise to you, since you've seen ${school_friend}'s progress with your own eyes. You've witnessed the sleepless night ${noun3}'s committed to practicing
spellcrafts of every discipline, all in an effort to enroll in The Spell Academy. You even remember seeing ${pronoun} in the library for an entire week, buried in books regarding
the theoretical applications of spellcrafting.

One day, ${school_friend} approached you. ${school_friend} looked tired, and ${posnoun} eyes were red from lack of sleep, as usual. ${school_friend} spoke to you in a triumphant tone, "I did it, ${fname}. I've got the hang of it!"

You replied, "Got the hang of what?"

"What else do I mean? Spellcraft!"

It seemed as though ${school_friend} was able to master a discipline. Do you remember which one it was?

*choice
  #Countless hours studying had allowed ${school_friend} to wield conjuration with great effectiveness.
    *set fskill "Conjuration"
    You remember that this was the one spellcraft that ${school_friend} struggled with the most. Things have come full circle, and now ${noun3}'s
    able to wield conjuration with confidence. You couldn't be happier for ${pronoun}.
    *goto companion
  *selectable_if (healing < 20) #Intense training made ${school_friend} proficient in healing, and ${noun3} was essentially, the best wielder of mending spellcraft at Kael's. (Available if your Healing is less than level 20.)
    *set fskill "Healing"
    ${school_friend} dedicated ${selfnoun} to learning mending spells. ${school_friend}'s ability to heal wounds was second to none at Kael's, surpassing even your own ability to heal.
    You regarded ${posnoun} newfound ability with praise, and you couldn't be more proud to call ${pronoun} your friend.
    *goto companion
  *selectable_if (creation < 15) #${school_friend} learned to cast creation magic with ease; ${posnoun} reputation as the best creation spellcrafter was well-earned. (Available if your Creation is below level 15).
    *set fskill "Creation"
    ${school_friend}'s ability to shape and fuse objects was both efficient and impressive. What took other students hours to create, ${noun3} was able to make
    in a few minutes. You admired ${school_friend}'s determination to improve ${selfnoun}, and the results of ${posnoun} hard work has finally given fruit.
    *goto companion
  #${school_friend}'s tireless work had given made ${pronoun} proficient in general spellcrafting. Allowing ${pronoun} to become versatile when applying ${posnoun} magic.
    *set fskill "Spellcraft"
    ${school_friend} is an expert of many spellcraft disciplines, but a master of none; ${posnoun} ability to use magic in any situation
    will be a great advantage to ${pronoun}.
    *goto companion

*label companion
*page_break

${school_friend} turned to you and asked, "Want to see a new spell I learned?"

*choice
  #"Alright, let's see what you can do."
    "Alright! I'll do exactly that!"
    *set fmeter +5
    *goto show
  #"Hell yeah!"
    "I knew you were! Here it comes!"
    *set fmeter +5
    *set excitability +4
    *set calmness -4
    *goto show
  #You cautiously nodded your head. This could go a number of ways, and you weren't sure what ${school_friend} had in store.
    *set calmness +4
    *set excitability -4
    ${school_friend} focused, and began gathering mana in their palms.
    *goto show

*label show
*page_break
*if (fskill = "Conjuration")
  *goto fskillconjuration
*elseif (fskill = "Healing")
  *goto fskillhealing
*elseif (fskill = "Creation")
  *goto fskillcreation
*else
  *goto fskillspellcraft

*label fskillconjuration
*page_break
${school_friend} stepped back from you, and suddenly conjured fire from ${posnoun} palms. ${school_friend} began to shape the fire, until it looked like a small dragon. The small dragon was fully animated and squirmed in ${posnoun} hand.

${school_friend} smirked, "Here goes!"

The dragon in ${posnoun} grasp was thrown upwards with a swinging motion, and then it was lifted high in the air.

After a few seconds, the dragon exploded in a blaze of colorful flames and grew ten times its previous size. It flew upwards, into the sky.

You both watched as the dragon ascended, until it burst into a great wave of orange and blue flames.

The waves of flame descended as cloudy wisps of energy. Soon, you were both surrounded in colorful blue and orange wisps, gently descending around you.

*goto fskillconvo


*label fskillhealing
*page_break
${school_friend} stepped back from you, and ${posnoun} palms glowed. The light emanating from ${posnoun} hands were warm and potent. ${school_friend} expanded the light, and both of you were enveloped in a bright, light. 

A dome of healing magic surrounded the two of you. The dome exuded a white energy that seemed endlessly comforting.

${school_friend} waved ${posnoun} hand, and the dome of light began to separate from itself. It slowly began to pull apart until shards of light surrounded the two of you. The shards dissipated, gradually.

*goto fskillconvo


*label fskillcreation
*page_break
${school_friend} stepped back from you, and ${noun3} looked around, "Let's see what I can use around here."

${school_friend}'s eyes landed on a pile of rocks that layed on the ground and approached it. With a wave of ${posnoun} hand, the rocks began to gather into a mass of rocks and pebbles.

After a few moments, the rocks began to rearrange themselves to resemble a four-legged creature.

${school_friend} concentrated firmly, "One more should do it..."

With one more wave of ${posnoun} hand, the rocks finished moving and revealed their final product. The completed figure looked almost exactly like a wild, Lahar wolf. 

You were about to remark on ${posnoun} spell, but you suddenly noticed that the wolf was moving. You jumped back in fear, but the wolf approached you in a friendly manner. The wolf statue wagged its tail in front of you.

You spoke, "This is cool, but this spell looks really complex."

"No kidding, ${fname}. It took a while to learn this spell."

${school_friend} approached the wolf, "Watch this."

${school_friend} moved ${posnoun} hands in a circular motion, and the wolf began sprinting around the two of you. After a few seconds, the wolf halted. The rocks separated from one another and they hovered in the air. After a few moments, the rocks rejoined together and revealed a new figure that resembled a horse. The statue neighed.

You smiled at each other. With one more wave of ${posnoun} palms, the horse crumbled back into a pile of rocks.

*goto fskillconvo


*label fskillspellcraft
*page_break
${school_friend} stepped back from you, and released a torrent of mana from ${posnoun} palms. The mana stretched outwards and surrounded the two of you. You were surprised that ${noun3} was able to generate this much mana.

${school_friend} waved ${posnoun} hands, and the mana spiraled upwards. The two of you were inside a swirling pool of mana. The energy around you was moving at a blindingly fast pace. You feared your hand would come off if you so much as scraped the vortex's edge.

With one more wave of ${posnoun} hands, the torrent of mana gradually reduced, until it dissipated into a waning blue light.

*goto fskillconvo


*label fskillconvo
*page_break

When the last remnants of ${school_friend}'s spell vanished, ${noun3} suddenly bent over wheezing; ${posnoun} ${skin} skin was paler than usual, "I shouldn't have used that much mana. I feel so exhausted."

You shook your head in disapproval, ${noun3} was too excited and used up too much mana to create an impressive, but short-lived, spell show.

${school_friend} recovered and looked at you, "I think I need a nap now. Thanks for watching my magic, ${fname}."

You wanted to say something to ${pronoun} at this moment.

*choice
  #"No problem, ${school_friend}"
    *set fmeter +5
    ${school_friend} nods toward you, and ${noun3} begins to walk away. You feel at peace, knowing that ${noun3}'ll be able to make it through Kaelich's program and graduate.
    *goto endyear
  #"You're incorrigible, you know that?"
    Sometimes, your friend is a bit reckless. You don't particularly care to always be picking up after ${posnoun} mistakes, but ${school_friend}'s hapless nature
    seems to be part of ${posnoun} personality. Sometimes, you wish ${noun3} wouldn't overexert ${selfnoun}. Yet, you're happy ${noun3} got what ${noun3} worked for.
    *set intellect +6
    *set intuition -6
    *goto endyear
  *selectable_if (healing > 10) #"Here, let me heal you. I'm sure I can recover some of your mana." (Requires Healing above level 10)
    ${school_friend} lay on the floor, obviously relieved that ${noun3} didn't have to force ${selfnoun} to stand anymore. You put your hands on ${posnoun} torso, and a warm sensation leaves your fingertips.
    You can sense the depleted mana from ${posnoun} body. There's usually a pulsating energy from spellcrafters with plenty of mana, but you only feel a faint murmur from ${school_friend}'s body.
    You look down, it looks as though ${school_friend} has fallen asleep. ${school_friend} looked so peaceful.
    *set fmeter +8
    *goto endyear

*label endyear
*page_break

The second year was relatively peaceful compared to your first year. To top it off, you were no longer worried about ${school_friend}'s performance in class.
However, towards the end of the second year, your professor approached you after class. Mr. Adelich was a gaunt old man, whose tall figure seems to make him lankier than he really is.

"${gsuffix} ${family_name}, may I speak with you for a moment?"

You turned towards him, "Something on your mind, professor?"

"As you may very well know, ${gsuffix} ${family_name}, you are a very gifted spellcrafter. However, one of your spellcrafting disciplines is lacking, and needs a bit of remediation in order to be fixed."
This took you by surprise. You were under the impression that you've been doing very well for yourself.

You were about to open your mouth to reply, but Mr. Adelich is one step ahead of you, "You may be asking 'Which discipline is it', and I'd like you to think. What spellcraft discipline do you think it is?"

Do you have any idea what discipline Mr. Adelich is alluding to?

*choice
  *selectable_if ((healing < 20) and (title1 != "Almighty Mender")) #He must be talking about my mending spellcraft. I've never been very adept at healing (Healing must be below level 20).
    *set summer "healing"
    *goto summerbreak
  *selectable_if ((creation < 20) and (title1 != "Creation Savant")) #I believe he's alluding to my creation magic. It does leave something to be desired, if I'm being honest (Creation must be below level 20).
    *set summer "creation"
    *goto summerbreak
  *selectable_if ((conjuration < 20) and (title1 != "Gifted Conjurer")) #He's probably talking about my conjuration. The forces of nature are fickle, and I'm not well-versed in controlling the elements (Conjuration must be below level 20).
    *set summer "conjuration"
    *goto summerbreak 
 *selectable_if (spellcraft < 20) #It's most certainly my application of general spellcraft. I'm doing fine with other disciplines, but I find general spellcraft to be unnecessarily tedious (Spellcraft must be below level 20).
    *set summer "spellcrafting"
    *goto summerbreak

*label summerbreak

You replied, "It's my ${summer}, isn't it?"

Mr. Adelich nodded, "Yes. Though you are gifted, your magic in this discipline is particularly lacking. It's not a crippling failure, but it would be best to
fix this as soon as possible. You see, I have very high hopes for you, ${gsuffix} ${family_name}. I believe you will be one of a very few number of students who will make it into The Aetherian Spell Academy."

He continued, "As such, my job is to make sure that future spellcrafters are prepared as much as possible, for whatever their future holds for them.
I believe improving your ${summer} will be a great boon to you once you've reached The Aetherian Spell Academy."

You were baffled, you didn't know Mr. Adelich thought so highly of you. He looked at you quizzically, obviously expecting a response of some kind.

*fake_choice
    #"Thank you, Mr. Adelich!"
    #"I have no words, except that I am entirely grateful, sir."
    #"I will take your advice to heart, Mr. Adelich."
    #"I'm not quite sure I need it." Perhaps Mr. Adelich underestimates me?
      Mr. Adelich laughed, "The bravado of youth! I'm not saying it's imperative, but it will benefit you greatly ${gsuffix} ${family_name}."
      You were pensive for a few moments. You decided, what harm could it do? You replied, "Alright, what did you have in mind, sir?"

Mr. Adelich replied, "What I had in mind is to let you take a summer class specifically revolving around ${summer}. 
I will not be your professor, it will be someone else."

You nodded, "Alright, Mr. Adelich. I'll sign up for summer ${summer} class."

"Good! Now if you'll excuse me ${gsuffix} ${family_name}, I have a meeting to attend today."

*page_break 

True to your words, you signed up for ${summer} class the following day. 

The end of the second school year came and went, and your summer class has begun.
It was a sweltering, hot day, and the summer class was held in the library, since all the classrooms in the main building were being renovated for the summer.
Fortunately, ice elementals were summoned by the staff to ensure that the temperature was bearable inside the building.

*page_break

You learned beforehand, from Mr. Adelich himself, that remedial classes in public magic schools aren't very common.
This is entirely due to the competitive nature of magic schools in Furze, and a spellcrafter who needed remedial is immediately less qualified in the eyes of the school system.

However you seemed to be a unique case. You're not in remedial because you're failing, quite the opposite. You were given remedial as a supplementary course by a professor who regarded your talents.
Yet, the stigma of taking remedial classes is apparent when looking at your remedial class' extremely low attendance rate.

You can only hope your time in summer school is worth it.

*page_break

As a surprise gift for finishing your first year of magic school, your parents bought you a brand-new cellphone. Unlike Estenian cellphones, the Laharian version of these devices ran entirely on mana; rather than relying on electricity for energy.

You thanked your parents, and you were sure you would make good use of it.

*finish