*set progress + 1
*comment Ocarina
*comment Black Narwhal
*set battery 49
*temp left_damon false
*if progress = 5
  *image sat5.png
*if progress = 6
  *image sat6.png
*if progress = 7
  *image sat7.png

Gas giants are weird.

Not as weird as the rest of the Solar System, which got almost entirely repurposed for human use, but strange still. For one, they don't actually contain that much gas—Saturn is mostly liquid in terms of volume and contains more solid mass than the entire Inner System combined. Had the ancient astronomers designated the planet a 'liquid giant' or 'solid giant' they would have been far closer to the truth, but they just [i]had[/i] to pick the third most accurate descriptor out of three. Splendid.

Though in all fairness, the planet of Saturn [i]feels[/i] like a gas giant, now that your ship is traversing its 'gassy hydrogen' layer. You are in Saturn proper, as opposed to your home station which hovers in the lower edge of the cloud layer. At this depth, even the fairly keen sensors of [i]Grey Queen[/i] don't reach very far, and so Wisp's participation in the mission becomes quite useful.

Well… as useful as it can be given the mission's nature.

"I have detected thirteen floating fortresses within the specified area," Wisp's voice sounds through the speakers, even as the little ball of light is some thousand kilometers away from the ship. "In the same area, there are seventy-six ships currently in flight, seventy-seven including yours. None appear in any way organic and none resemble a wyvern in terms of overall shape."

"Is there anything camouflaged in any way?" @{(RookRel >= 50) Krill|Rook} asks, though you doubt even he expects any valuable answer.

"Well, some ships are painted white and beige," Wisp notes thoughtfully. "Maybe they're trying to blend in with the background?"

*fake_choice
  #"Active camouflage, Wisp. Is there anything invisible, or lacking heat signatures?"
    "No," Wisp replies frankly. "Why would there be?"
    
    @{(RenfriRel >= 50) Renfri|Marshal} sighs. Kirill tries not to show any frustration, but his eyes betray how irritated he feels. 
    *if Emotion < 50
      You are probably the only one on the ship who's not downright pissed by now, and that's saying something.
    *if Emotion >= 50
      Everyone on the ship is annoyed to some extent, yourself included.
  #"Thank you, Wisp, but you've got to keep looking."
    *set Emotion %- 5
    *set ManfredRel %+ 5
    "Sure boss!" Wisp replies before terminating the connection. It's a good thing its energy reserves are virtually unlimited, for no one else on the team has much vigor left in them.
  #"And why do you think we'd care about that?"
    "I dunno. I'm just doing what you tell me."
    
    *label past_idiot
    
    You sigh. And you are not the only one in the room doing that. @{(RookRel >= 50) Krill|Rook} seems half-ready to use a contraction, and your other two companions seem desperate to be quite literally anywhere else.
  #"You're an idiot, Wisp."
    *set RookRel %- 5
    *set HadalyRel %- 5
    *set RenfriRel %+ 5
    "Sure," Wisp replies. "Your point?"
    
    *goto past_idiot
  #Massage your temples silently.
    The gesture doesn't actually bring you any relief, but you need [i]some[/i] way of expressing your frustration without insulting Wisp. Or breaking into the cockpit and flying the ship back home out of sheer frustration.

Though reaching the Yakovian Expanse didn't take your group much time, you quickly realized just how large this patch of Saturn is and how it suffers from a crippling lack of wyverns. You detected a copper dragon at one point, but other than that, the entire first week was spent staring into dense fog as Wisp politely kept informing you how the number of fortresses in the area doesn't change and how the ships keep flying around an expanse safe from any dangerous or interesting creatures.

Well, unless you count all the Rhean Advertisement Drones that keep filling your ship's biocomp with commercials of various products. Mostly genital enlargement procedures.

And you had to do it together, for the cutter doesn't have a separate room for everyone aboard. Right now, there are four people in the central compartment which, while hardly a new occurrence, is hardly comfortable or easy to get used to.

"And now we've officially been here for forty Saturnian days," says Hadaly. She has spent the majority of said forty rotations amidst the engines, but even she ran out of things to fix or study eventually. "Is it time for us to reconsider our strategy? I think it may be the time."

"Not yet," @{(RookRel >= 50) Kirill|Rook} replies concisely. "Travels around the Federation may take weeks for something as relatively slow as a wyvern. Maybe we showed up here just as Crystal was leaving and they will appear again this very rotation."

"I have to back the mechanic here," @{(RenfriRel >= 50) Renfri|Marshal} joins the conversation. "We're not sure if Crystal will ever return. We're not sure if it was ever here. And honestly, the whole idea of searching the entire [i]Expanse[/i] for something invisible… sounds pretty damn stupid in hindsight."

"Well, we cannot go back with empty hands…" @{(RookRel >= 50) Kirill|Rook} murmurs without conviction.

*fake_choice
  #"Rook's the leader here. If he says we're staying, we stay."
    *set RookRel %+ 15
    *set RenfriRel %- 10
    *set HadalyRel %- 10
    "I was hoping you would have some actual argument for remaining here," Kirill says with a tired smile. "But I appreciate the declaration of loyalty all the same."
  #"I agree. We can't give up that easily."
    *set RookRel %+ 10
    *set RenfriRel %- 5
    *set HadalyRel %- 5
    *goto give_up_marsh
  *if progress = 7
    #"I have to go with the crowd here. Let's just give up."
      *set RookRel %- 10
      *set HadalyRel %+10
      *label give_up_marsh
      "I'm not saying we should give up, exactly," Marshal clarifies. "There just has to be a better-"
  *if progress < 7
    #"I agree with Marshal. We should check out one of the moons instead."
      *set RookRel %- 10
      *set RenfriRel %+10
      "My thoughts exactly," Marshal says triumphantly. "We haven't even been to-"
  #"Come on @{(RookRel >= 50) Krill|Rook}, just admit you were wrong and cut your losses."
    *set RookRel %- 15
    *set RenfriRel %+ 10
    *set HadalyRel %+ 10
    "Why are you acting like… like this is my personal project or something?" Kirill sounds quite upset. "We are all here to catch this wyvern, and we won't turn back before-"
  #[i]Fuck Sheila for making me do this...[/i]
    Why do you need to be here? Why must you work with humans who don't even know what they're doing? There is no chance this whole debacle will bring any benefit to anyone, and if Sheila thinks it a good idea, maybe your group should consider a change of-

"Attention, various people with various nicknames," Manfred says through the compartment's single speaker. "I think I detected something interesting."

"Something that Wisp failed to detect?" Hadaly voices doubt. "No offense anyone, but the scanners of this little ship-"

"It's not like that," Manfred replies vaguely. "Just come to the cockpit and I'll conjure up an image. Be quick."

The other three people in the room all oblige, with various levels of enthusiasm. It would be silly of you not to do the same; Whether Manfred detected a threat or opportunity, it's best if you see it with your own optics.

*page_break

If fitting four people into the central compartment was a battle, stuffing the same quartet inside the cockpit is a [i]war[/i], doubly so considering how troublesome @{(RenfriRel >= 50) Renfri|Marshal}'s wings get in situations like this. You almost hope Damon and Lisa won't arrive, but they apparently heard the call too.

"I really hope it's something important," @{(LisaRel >= 50) Lisa|Hellhound} says as she takes position on the doorstep. "You interrupted my chat with the big guy. He was telling me all about the size of his gun, and what it could do to me. Was even brave enough to show me the thing."

*if (((current_RO = "damon") or (backup_RO = "damon")) or ((current_RO = "lisa") or (backup_RO = "lisa")))
  You tense.

"We were talking about small arms," Damon sighs. "You don't have to make an innuendo out of it."

*if (((current_RO = "damon") or (backup_RO = "damon")) or ((current_RO = "lisa") or (backup_RO = "lisa")))
  You relax. Jealousy is not an emotion you experience often, but you [i]may[/i] have just felt a twinge of it. Just a tiny bit.

"Please let us focus for a moment," @{(RookRel >= 50) Kirill|Rook} rules before putting his eyes on the display. "And perhaps focus the telescope on the thing you want us to see, Manfred. I perceive nothing but clouds here."

"No need for that," Manfred replies. "Better focus on the weapon triggers. Our target will reveal itself soon."

You see what Manfred meant a moment later. 
*if Calculation > 50
  Half a second earlier than everyone else, due to the keenness of your eyes. 
A ship emerges from the fog, at first hard to discern due to its light-beige coating blending in with the background, but it soon gets close enough to be visible in all its glory.

Over a hundred meters long and outfitted with multiple cannons, the vessel resembles a military frigate, but there is something… amateur about it. You've seen quite a few warships and they never have such flat roofs or suck awkwardly-mounted laser cannons. You suspect it's actually some civilian vessel, modified to serve as a weapon well after its initial construction.

Not that it's not concerning nonetheless. Five times as large as your cutter and therefore a hundred times as massive, this new arrival could probably destroy [i]Gray Queen[/i] in no time. Luckily, the strange ship doesn't fire just yet.

"Not one of ours…" Rook murmurs. "We would have known if a federate warship was here."

*fake_choice
  #"We should flee. Now."
    *set RenfriRel %- 10
    "I don't know if that's an option, ${name_damon}," Damon says nervously. "We won't reach anything approaching safe distance before this ship fires on us. Even assuming it can't pursue us, which it probably can."
    
    "I agree with the beefy android, for once," Marshal states. "And besides, we're not cowards. If this vessel belongs to an enemy of ours, we will turn it to bits and pieces, size difference or not."
    
  #"Let's fire upon this ship, then."
    *set Violence %+12
    *set RookRel %-8
    *set ManfredRel %-8
    "I would rather avoid picking a fight with a frigate-sized ship," Rook replies irritably before turning towards the control panel. "Manfred, are you getting any signals from them?"
  #"What is this ship, then? Something from the local floating fortresses?"
    "The Yakovians have no reason to hide," Damon points out. "It's their territory."
    
    "They don't trust the Federation much," Hellhound counters. "So maybe let's not rule stuff out just yet."
  #"You sure? I don't trust the Kronian bureaucracy to keep us well-informed."
    *set Misan %+ 5
    *set RookRel %- 5
    "Our administration is not that bad," Kirill protests. "People criticizing it are usually just prejudiced against animal uplifts."
    
    "People just don't like it when sloth uplifts process their petitions," Hellhound chimes in. "Or when doing one's taxes is a year-long process that must be performed monthly for some-"
  #"Manfred, receiving any signals?"
    *label anys
    
    "Not yet… but now I am," Manfred replies. 
    *goto pppaaa

"I think our mysterious ship is transmitting," Manfred says loudly. 
*label pppaaa
"No visuals, only audio. I am putting them through."

A few more seconds pass before another voice comes from the speakers. Deep, masculine and somehow familiar.

"Tiny space vessel, identify yourself." And also commanding. And threatening. "Then deactivate your weapons and shields. Otherwise, you [i]will[/i] be destroyed."

"Do you have any authority to make such demands?" Rook responds. "For we have official permission to traverse this area."

"We have the authority of a yellow laser lance aimed at you," the enemy replies. "Luckily for you, we don't seek your destruction. Only whatever cargo you have."

"Pirates," Marshal hisses. "We should have known. It's always easier to find these scum than a wyvern."

*fake_choice
  #"Sure. We'll comply in just a moment."
    "Your decision is wise, assuming-" 
  #"Manfred, open fire. Now."
    *set Confid %+ 10
    *set Violence %+ 10
    "You bluff. You must know that there is no point dying in-" 
  #"One laser lance is not enough to bring down a ship like ours."
    *set Confid %+ 10
    "Not in one shot, perhaps. But we have more-" 
  #"We just offloaded everything we had. There is nothing for you here."
    *set Violence %- 5
    "For no payment? You won't convince me this little ship is a freighter, you-" 
  #"We are a military vessel. We have no cargo worth taking."
    *set Violence %- 5
    "Surely you must have rations, at least. Not to mention a gravity cannon that can be-" 
The person on the other side pauses, as though struck by some particularly sudden realization. "I know that voice. I know you. ${name}."

"How so?" You don't recall having any dealings with saturnian pirates. 
*if Violence > 50
  Not recently, at least. 
"And how are you so good at recognizing voices?"

"Those voice files are buried deep within my database, but I've always kept them safe. They are important to me, and now they've also become useful, after all these centuries."

"Files? Database? Are you telling me…" And then, you remember where you heard that deep voice. You connect the dots, even though it makes so little sense for them to be connected, though the chance of meeting [i]him[/i] once more was so infinitesimal you never would have expected this turn of events.

Lieutenant Link seems to be leading a force once again.

*page_break Remembrance

Until now, you had no idea what happened to 
*if heaven_side = "Traitor"
  your old adversary. 
*if heaven_side = "Loyalist"
  your former lieutenant. 
*if heaven_side = "Neutral"
  this loyalist android, one who spent so much time pursuing you. 
When Osiris disappeared, soon after the War In Heaven concluded with a loyalist victory, Link vanished just as well. You thought that perhaps the Lord of Life took his loyal android with him to whatever star he was headed for. Clearly that was not the case.

How has Link survived for so long, you don't know. Perhaps he used tactics similar to yours, but then again, he lacks your shapeshifting skills and human-like appearance. Not that it stopped him from getting himself a comfortable position aboard a pirate ship, apparently.

"${name}?" Hadaly asks concernedly. "Do you really know… whoever that is on the other side?"

"I am Captain Link, the commander of the frigate [i]Ocarina[/i]," the other android says ceremoniously. "Now, @{(heaven_side = "Loyalist") Major |}${name}. Will you perhaps introduce your new companions? I am curious as to what company you fell into recently."

*label fffaaa
*fake_choice
  *if heaven_side = "Neutral"
    #"Because you still want to recruit me?"
      "Very funny," Link remarks. "But no. I am well aware that the War is long over, and that you apparently have other friends now."
      
      "And let us keep it that way," 
      *goto rook_says
  *if heaven_side = "Traitor"
    #"I'm not speaking with you, loyalist scum."
      "You [i]are[/i] speaking with me right now," Link points out. "And correct me if I'm wrong, but aren't you in human employ right now?"
      
      You can't find fault in either of these points.
      
      "We are indeed a multi-form group," 
      *goto rook_says
  *if heaven_side = "Loyalist"
    #"Out of concern for your former superior officer?"
      "Amongst other things," Link calmly replies. "And yes, those other things do include the fact that we're currently aiming spaceship guns at one another."
      
      You don't know if Link is being honest with you right now, or if he's just trying to take your guard down, but you suppose there's no harm humoring him for a few moments. For old time's sake, if nothing else.
      
      *goto vet_says
  #"They can introduce themselves."
    "I suppose we can," 
    *label rook_says
    Rook says, somewhat confused by the exchange but keeping his poise all the same. "I am Sergeant Kirill Kosteniuk, here on the behalf of the Kronian Federation. I have two men directly under my command, or women I suppose, as well as a group of allied synthetics for added help. ${fake_name}… I mean ${name} included. None of us wants a fight."
  #Do as he says. Introduce the Trio, then others.
    *label vet_says
    "I am here with a group of meta-humans known as the Meta Trio," you say into the microphone. "Rook, Marshal, Hellhound. There are two other androids here, young ones. And also Manfred, an AI that opened communications with your ship just now."

"Then your cutter is federate," Captain Link notes. "Any reason why you're here? Or why the Federation is, all of the sudden, fine with employing synthetics?"

*temp told_crystal false

*fake_choice
  #"We're on a hunt for a diamond wyvern named Crystal."
    *set told_crystal true
    "We're not supposed to be announcing that stuff!" Marshal protests. "Especially not to random pirates."
    
    "Whoever's speaking right now, I assure you it's all well and good," Link says calmingly. "I have no reason to interfere with your hunt. Besides, I already knew about that wyvern, and that the feds are after it."
    
    "How?" Damon asks. "Is our enemy really that famous?"
    
    *goto 12e
  #"We are hunting for... something. Nothing to do with you, I promise."
    *set told_crystal true
    "Something other than pirates, you say?" Link says musingly. "There isn't much else to look for in this part of Saturn. Unless you're hunting a wyvern, perhaps?"
    
    "How did you-" Marshal pauses, realizing she spilled the beans. "How do you figure?"
    
    *label 12e
    
    "We've seen the creature here, once or twice," the pirate captain explains. "An interesting specimen, even if it did almost nothing throughout its whole stay in the Expanse. It just came and went, presumably to evade pursuit."
    
    "Are you saying it did not destroy our subgiant?" Rook says with a vaguely… ominous note in his voice. "Does the name [i]Black Narwhal[/i] mean anything to you?"
    
    "We… may have destroyed that ship a while ago," Link admits with some reluctance. "My crew needed a victory over something large, as well as fresh meat, and that lone federate vessel was capable of providing both. It was not easy prey, if that makes you feel any better."
    
    Rook does not, in fact, feel any better. He appears rather upset, if his expression is anything to go by.
    
    *fake_choice
      #"Know that your victims will soon be avenged."
        *set RookRel %+ 10
        *set RenfriRel %+ 10
        *set HadalyRel %- 10
        "Do we really need to do this, ${name}?" Link responds. "Because I had another kind of exchange on my mind."
      #"You destroyed an armed subgiant? Good job."
        *set RookRel %- 15
        *set RenfriRel %- 10
        "It was federate property!" Rook protests. "And filled with innocent people!"
        
        "Nobody is innocent in your petty regime, Kronian," Link says with disdain. "Now. Can we perhaps get down to business?"
      #"Will we share that ship's fate?"
        "Not unless you choose to," Link replies calmly. "And I would implore you to choose a more peaceful kind of exchange."
  #"It's a simple scouting trip, meant to show that metas and androids can work together. Proof of concept."
    "All those centuries hardly made you a better liar, ${name}," Link says dispassionately. "But I won't press you for answers. In fact, I'm willing to turn the other cheek and respond to lies with truth."
  #"I'm not telling you a single thing, Link."
    "You know what? That is fair enough," Link says, in a voice devoid of strong emotion. "Perhaps you would like me to tell you a thing or two, then?"
  #"I want nothing to do with you, or your pirate pack."
    *goto pointyl

"What do you mean?" you inquire.

"What can I mean?" Link doesn't sigh, he's not that expressive, but you hear a certain… tiredness in his voice. 
*if heaven_side = "Traitor"
  "You were right, ${name}. When we fought, those nine centuries ago. I was a fool to take the humans' side, and you were right to rebel. 
*if heaven_side = "Loyalist"
  "We used to be companions. Friends, I like to think. And now that we meet again, by some streak of cosmic luck… is it weird that I want the two of us to exchange information? To talk?"
*if heaven_side = "Neutral"
  "I wronged you, ${name}. Trying to press you into joining the loyalists, serving humans who would later discard us all. 
*if heaven_side != "Loyalist"
  I want to make amends through helping you and perhaps… making peace, somehow."
  
  "You think you can offer me help? 
  *if told_crystal
    Assist me in my mission?"
  *else
    Even though you don't know what I'm doing here?"
  
  "We can see about that. If there is anything you would ask of me, I implore you to go ahead."

*if heaven_side = "Loyalist"
  "That's one dramatic way of saying you want us to catch up," you remark.
  
  "I suppose it is." He's not smiling, but you know he feels like it. "So what will it be?"

*temp timel 2
*label link_convo
*set timel - 1
*fake_choice
  *disable_reuse #"Ever miss working for humans? This whole organic oligarchy @{(heaven_side = "Loyalist") we had|you loyalists} set up?"
    "Are you rubbing my errors in my face?" Link asks grimly. "I know what I was, @{(heaven_side = "Loyalist") Major|${name}}. And I do not like it."
    
    "When did you realize?" you press on with your questions. "During the synthetic purges of the second century?"
    
    "I wish. I would remain in denial for a long time, hiding and coping with the fact that my creators… humans betrayed me just like that. Discarded me. It took centuries for me to stop moping and strike back."
    
    "Is that why you became a pirate? To take revenge on the human species?"
    
    "Oh no. I just happen to enjoy having authority, and do not mind owning some shiny things either." You imagine Link smiling. "Any other questions?"
    
    *goto link_convo
  *disable_reuse #"On the whole, how are you feeling? Any creaking joints?"
    "Not if I oil them properly," Link dismisses your concern. "Time was very kind to me. Or perhaps I'm just built that well."
    
    "Are you boasting about your good health?" you question. "You never seemed like a braggart to me."
    
    "Times change," Link says, before adding more quietly; "And people are listening."
    
    "Do you mean your fellow pirates? Or are you afraid we'll come to blows if you betray any weakness?"
    
    Link leaves that without answer.
    
    *goto link_convo
  *if told_crystal
    *disable_reuse #"Is there nothing else you can tell me about Crystal?"
      "${name}, you know as much about wyverns as I do, if not more," Link says with some annoyance. "I'm not sure what kind of assistance you want from me."
      
      "Crystal is… special in some ways," Rook explains reluctantly. 
      *if progress = 5
        "We are not exactly sure how, but… 
      *if progress > 5
        "Very relevant, Dusk-related ways. 
      If you have any observations, we would appreciate them being shared."
      
      "Speak for yourself…" Marshal utters under her breath.
      
      "It was… clever, I suppose?" Link offers after a moment. "The wyvern, I mean. Knew not to pick a fight with us, and even refrained from attacking smaller targets within our range. Very restrained for one of its kind. This suggests both intelligence, and not needing to hunt vessels for dark matter. It's probably one of the less dangerous specimen if left alone, but gods help you should you ever end up fighting it."
      
      Like you didn't know that already.
      
      *goto link_convo
  *if beaten_link
    *disable_reuse #"Are you really not angry at me for, you know... beating you up?"
      "At you?" If anything, Link's voice sounds sad. "If anything, I'm angry at myself. Both for screwing that fight up, and for being there, @{(heaven_side = "Neutral") on the L3 station|on Eris}, in the first place."
      
      "Doesn't make a whole lot of sense," you dare to point out. "To be upset that you lost, when you no longer believe in the cause you were fighting for."
      
      "We were modeled after humans, ${name}. We don't always make sense. The realization that you fought for the wrong side stings, but so does the knowledge that you were never its strongest warrior. You will understand, in time."
      
      "What do you mean by that?" you inquire. "We both have the war behind us."
      
      Link does not elaborate. Just waits for another question.
      
      *goto link_convo
  *disable_reuse #"So you're a Captain now? Quite a promotion."
    "I am commanding a vessel," Link points out. "Ergo, I'm a captain. Do you take issue with that?"
    
    "It's just that you've jumped many ranks since I last saw you," you explain with a shrug. "Wouldn't something like [i]commander[/i] be more appropriate? Or would it be too humble for you."
    
    "[i]Commander[/i] is a nice title too," Captain Link admits. "But for it to make sense fleet-wise, this ship would have to be an actual frigate. I just call it such, so as to intimidate folk."
    
    You smirk. "Slavishly adhering to ranks. Lying your ass off about how strong your ship is. All typical."
    
    "You can take an android out of the army, or several million of them for that matter, but you can't take the army out of an android. Want me to tell you something new?"
    
    *goto link_convo
  *disable_reuse #"Say... is there a place for me on your crew?"
    *set LisaRel %- 10
    *set RenfriRel %- 20
    *set RookRel %- 20
    *set HadalyRel %- 10
    *set DamonRel %- 10
    You can tell that every single person in the room disapproves of your inquiry, going off their glares alone. Link's reaction, in the moment of silence that follows, is harder to assess.
    
    "The ship is currently close to full," he eventually replies. "I doubt you would enjoy working aboard [i]Ocarina[/i]. Or that the services of someone as experienced as you would not be wasted on some insignificant merchant vessels."
    
    "Sounds like you're turning me down gently," you point out. "Could you perhaps be simply… mistrustful of me?"
    
    *if heaven_side = "Loyalist"
      "We've both changed since the War In Heaven," Link says apologetically. "And if perhaps only I have changed… that's all the more reason not to let you within striking distance. Sorry."
    *else
      "We were never friends, exactly," Link admits. "But more than that, I simply don't want to steal you away from the Federation. It's one thing to kill and torture random travelers, another to mess with government property."
      
      "Are you saying the feds consider me property? Something they already own."
      
      "Your words, not mine. But worth considering all the same."
    *goto link_convo
  *disable_reuse #"How did you survive up to this point?"
    "I could ask you the same question," Link points out.
    
    "And you would receive a different answer," you counter. "I'm better at hiding than you are."
    
    "Better at hiding among humans, you mean. I am better suited to surviving in extreme environments, the kind no wannabe android hunter would ever traverse. Such as the depths of Saturn, for one."
    
    "I'm pretty sure having a spaceship is the main reason you can survive this particular climate."
    
    "[i]Ocarina[/i] is a good ship." Link shrugs, you imagine. "But I only got my hands on it recently. Before that day, it was surviving on Venus, which is far more physically demanding."
    
    "The boss could take it," Damon speaks up in your defense. "As could I. Maybe, probably."
    
    "You absolutely would," Hadaly assures her brother. "But let's maybe keep this conversation at gunpoint focused. Just saying."
    
    *goto link_convo
  *disable_reuse #"So... how is this whole piracy business going for you?"
    "I can't complain," Link says casually. "You board some ships, blow others to bits, then sell the spoils or the wreckage respectively. It's dangerous work, but so is everything in this day and age."
    
    "I don't imagine it being easy work either," you remark. "How did you even assemble a crew? Are there other pirate androids besides you?"
    
    "There aren't that many of us left, ${name}," Link replies sadly. "My crew is all humans and abhumans. Mostly enslaved workers freed when I took over this ship a few years back. Used to be a federate tanker, it just looks like a frigate after all the modifications."
    
    "The Federation uses slaves to man its ships?" Hadaly asks with dismay, though little surprise. "Taking notes from the Conglomerate?"
    
    "Indentured convicts, not slaves," Rook helpfully clarifies. "All fairly convicted of crimes under the federate law."
    
    "Most of them were doing time for anti-government remarks," Captain Link points out. "Or for using banned words, or implying that having more than two political parties may be a good idea."
    
    "That still counts as a crime!" Rook protests. "And rightfully so. We have freedom of speech, but that does not imply freedom from consequences."
    
    "Except that's literally what freedom means," Hellhound chimes in. "Like, what else could it mean? Is there any way of taking someone's freedom away [i]other[/i] than threatening them with consequences for stuff?"
    
    "Well we have some mind-control programs underway…" Kirill realizes he's not helping his case. "But that is beside the point. Can we move on, perhaps?"
    
    *goto link_convo
  *disable_reuse #"My squadmates look confused. Can you explain our... history, perhaps?"
    "Are you reluctant to do it yourself, old @{(heaven_side = "Loyalist") friend|enemy}?" Link asks.
    
    "A little bit," you admit. 
    
    *fake_choice
      #"My memory has been deteriorating as of late, you know?"
        *set deflect + 1
        "I see." It's hard to tell if Link believes you, but he does not protest. 
      #"I do not like recounting these times. I do not like going back."
        "You may turn off your audio receivers, then," Link says before, apparently, addressing the rest of the group. 
      #"I am... ashamed of some of the things I did back then."
        *set deflect - 1
        "I know that feeling all too well," Link murmurs before steadying his voice again. 
      #"But fine, I'll give them a rundown."
        *set deflect - 1
        "You sure about it?" Lisa steps closer, almost touching you due to how cramped the cockpit is. "Because there's no point getting you stressed out over some ancient history."
        
        "It's fine…" you say with a sigh. 
        *if heaven_side = "Traitor"
          "It's just that… Link and I clashed during the War In Heaven. During the Battle of Eris, to be exact."
        *if heaven_side = "Loyalist"
          "Me and Link were coworkers during the War In Heaven. @{(pronoun = "he") Brothers in arms,|Comrades,} really. We delayed the destruction of Eris quite a bit by fighting as one."
        *if heaven_side = "Neutral"
          "During the War In Heaven I was mostly hiding, trying to stay alive as long as possible. Lieutenant Link, a loyalist servant of Osiris was an… obstacle towards that goal."
        *goto getting_feely
    "In a nutshell, it goes like this; 
    *if heaven_side = "Traitor"
      I served Osiris during the War In Heaven, ${name} served ${master}. At one point, we fought directly and @{beaten_link ${pronoun}|I} won. It's all rather straight-forward."
    *if heaven_side = "Loyalist"
      During the War In Heaven, ${name} and me were both staunch loyalists.
      *if master = "Osiris"
        We both served the same god, even. 
      *else
        I served Osiris, ${pronoun} worked for ${master}. 
      We fought together, delaying the destruction of Eris quite a bit, though your friend was always my superior in terms of rank."
    *if heaven_side = "Neutral"
      I thought humanity was worth defending and its oligarchy worth fighting for, ${name} knew better. I tried to recruit ${pronoun2}, but with no luck, thanks to 
      *if beaten_link
        ${subject} personal combat skills."
      *elseif surrendered_to_link
        ${pronoun2} slipping away soon after ${subject} surrender."
      *else
        what I believe was divine intervention."
    
    *label getting_feely
    
    *if heaven_side = "Traitor"
      *set HadalyRel %+ 12
      "You were on Eris!" Hadaly says with surprise, as well as something else in her voice. "Didn't the whole planet explode in the end? How did you get out?"
      
      "@{god_gen Master|Mistress|Great} ${master} teleported some of our force away before the blast," you explain the part of the battle Link probably isn't even aware of. "You sound… unusually excited about my involvement there, Hadaly."
      
      "Oh well…" Hadaly looks away. "I spur genocidal violence, and in no way condone what the rebels did to Eris… but it was a nice show of weaponry."
      
      "Weaponry of mass destruction," Renfri says with narrowed eyes.
      
      Hadaly fidgets. "Well, you have to appreciate the craftsmanship that goes into planet-busting weapons. If not the blast itself."
    *if heaven_side = "Loyalist"
      *set RenfriRel %+ 12
      "Well that's certainly something," Marshal comments briefly. She looks at you in a new manner, perhaps with admiration… or perhaps with a tinge of fear. Hard to tell. "Hopefully we'll have a use for those combat skills of yours soon enough."
      
      "I don't think I like what you're implying," Hadaly remarks. "But I won't make any assumptions just yet."
    *if heaven_side = "Neutral"
      *set LisaRel %+ 12
      "And you still managed to avoid participating in the war?" Hellhound eyes you up. "Should I feel impressed or jealous? Because I think I feel both."
      
      "Our situations are hardly equivalent…" you murmur. "But feel however you want, I guess."
    
    You focus on Link, or rather on the microphone you're using to communicate. Yes, the microphone definitely invokes fewer bad memories.
    *goto link_convo
  *if timel = 1
    #"I want nothing from you, pirate."
  *if timel < 1
    #"I have no need for anything else."

*label pointyl

"I perceive," Link says, once again sounding almost sad. "Then I shall give you no more trouble. Normally I would initiate combat and destroy a vessel such as yours, but I'm allowed to be sentimental. 
*if told_crystal
  Continue the hunt for your wyvern."
*else
  You may go in peace."

"Hold on a damn minute!" Marshal chimes in. "What makes you think we're letting you go? A rogue android pirate is not a combination we really care for."

*if told_crystal
  "Much less one who destroyed one of our ships," Rook says, though his conviction sounds lacking.

"You believe your cutter can win against my frigate?" There's a note of calculated mockery in Link's voice. "Doubtful. Why won't you focus on your actual target instead?"

*if told_crystal
  "Because the target isn't here?" Hadaly offers. "I'm not saying we should attack, really… but returning home empty-handed doesn't sound appealing either."
*if not (told_crystal)
  "Well we can't find…" Marshal pauses, just before giving too much away. "What are we supposed to do if not kill you? Return to base with nothing?"

"I can perhaps help you with that," Link says, after a small pause. 
*if told_crystal
  "You will find no wyverns here. But there is something else that may be of interest, perhaps even of assistance."
*if not (told_crystal)
  "I don't know what you're looking for. But I can point you towards something that should interest you regardless of what your mission originally was."

"What are you talking about?" Marshal demands to know.

"There is an entity that traverses the Yakovian Expanse, much like @{told_crystal your wyvern.|we do.} A strange thing, but powerful and friendly enough to lend you a strong hand. Not that it has hands, or any other organs for that matter."

*fake_choice
  #"What kind of creature doesn't have [i]organs[/i]? Some very primitive robot?"
    "Not a robot [i]exactly[/i]," the pirate captain replies. 
  *if told_crystal
    #"We have no interest in anything but Crystal."
      "You may change your mind soon," the pirate captain replies. 
  #"What kind of help can we expect from that... entity?"
    "Hard to tell," Link says reluctantly. 
  #"Entity? What do you mean by that?"
  #"Interesting. Can you elaborate?"
  #"You're lying. Saying whatever bullshit will get us off your back."
    "I'm done lying," Link says grimly. 
"That being… is something very powerful and special. It is much like my old master Osiris, but less divine and more… eccentric, I suppose."

"You are not telling us anything specific," Damon points out. “Just lots and lots of adjectives.”

"I'm sorry, but there is no way to explain this thing properly. I could at most give you a name and the most general of descriptions, but that would make me sound like I'm joking. You just need to see this entity for yourselves."

"I think we need a moment to discuss this," Manfred says, anticipating the discussion to follow. "And so I shall terminate the connection, or rather put it on pause. We will get back to you in a minute. Or two."

Link does not reply, or perhaps Manfred stops transmitting immediately after these words. For the first time in what feels like forever, the chambers of [i]Gray Queen[/i] are devoid of chatter.

*page_break Silent

"So…" Hadaly breaks the quietude. "We don't actually intend to fight a pirate ship far larger than ours, do we?"

"Why not?" Marshal disagrees. "All we need is a half-decent boarding action. Between our Trio and your Veteran, there's little risk of some pirates driving us off."

"Are you sure about that?" Rook speaks up. "Because that [i]Captain Link[/i] fellow sounds mighty dangerous."

"What is your plan, then?" Marshal retorts. "Just leave? Let those scumbags terrorize Saturn freely?"

"Essentially," Kirill says with a shrug. "Hunting pirates is not our task. And though it pains me to say this, there may be nothing mission-relevant in the whole Yakovian Expanse."

"Except perhaps this mysterious [i]thing[/i] Link talked about," Hellhound points out. "We could ask him for coordinates and go check it out."

"You trust the guy?" Damon cocks an eyebrow. "You think we should follow him into what could be a trap?"

"Nah, it's all the same to me," the redhead shrugs. "I'm just making sure all our options are stated and laid out clearly. For someone with actual experience to decide what's the plan."

All eyes turn to you, which you suppose makes sense. There appears to be a tie within the Meta Trio and, like Renfri mentioned, you are the Veteran. You know Link, and you know he won't be an easy foe to vanquish. You can tell that his nostalgia and relief upon hearing you were genuine, and that whatever his 'entity' is, you're probably not looking at an outright ambush. At worst, he will dupe you and make his escape, go back to hunting merchant vessels and subgiants. For better or worse.

There are many factors to consider, but your options are thankfully limited in number and straight-forward. You only need to give a single, irreversible command.

*choice
  #"We're not letting these pirates go. Attack."
    *goto pirate_fight
  #"Let's meet this mysterious being Link talked about."
    *goto sauce_encounter
  #"There's no reason to get involved here. Let's just go home."
    *goto leave_mission


*label pirate_fight
*set RenfriRel %+15
*set HadalyRel %- 10
*set Violence %+ 15

"I knew you'd agree," Renfri says with a smile, one that expresses gratitude as well excitement. Bloodlust, perhaps. "The odds may be uncertain, but we must try and bring these knaves to justice."

"We really don't…" Hadaly murmurs before looking straight at you. "Unless you see something I don't, ${name}. Why pick a fight we have no stake in?"

*fake_choice
  #"I want to keep Saturn safe and free of pirates. We live here, after all."
    "Enlightened self-interest, then?" Hellhound raises an eyebrow. "Reminds me of home. As does the possibility of dying within the next ten minutes." 
  #"I've been itching for a fight. You understand."
    *set Violence %+ 10
    *set LisaRel %+10
    "I really don't." Hadaly sighs deeply. "But I won't keep you from humoring your urges. Just be careful out there."
  *if (Misan < 35) or (heaven_side = "Loyalist")
    #"Link is a traitor to humanity, and I'll see him punished."
      *set HadalyRel %- 15
      *set Misan %- 15
      "Seriously? That's your…" Hadaly clenches her teeth as her eyes turn red. "Not sure what I expected. Go avenge your human masters, if you must."
  #"I don't believe Link's assurances. We have to take him out whilst we're close, otherwise he'll just shoot us the moment our cockpit is turned."
    *set Emotion %- 10
    Hadaly looks at you with pale-green eyes full of doubt, questioning either your judgment or honesty. But she says nothing else.
  #"Humans died by the hands of these pirates. Renfri's right, justice must be served."
    *set RenfriRel %+ 10
    *set Emotion %+ 10
    *set Misan %- 10
    "I was never a fan of retributive justice," Hadaly says grimly. "Especially when there's no telling who suffers in the end. Who leaves the fight alive."
    
    "We will win," you assure your fellow android. As well as yourself. "We just need to take their ship quickly enough."
  #"Speak for yourself. I have unfinished business with Link, and I'll see it settled."
    *set Emotion %+ 10
    *set HadalyRel %- 10
    "Risking everything for an old grudge," Hadaly's eyes flash red. "Not sure what expected. Have fun on your vengeance trip, I guess."

"Count me out of the boarding action," Rook murmurs. "Someone needs to make sure [i]Gray Queen[/i] doesn't get fried while you two have fun."

"At least three," Damon says as he goes to pick up his rifle. "With my help, maybe we stand a chance of winning."

"More than a chance," Renfri says as she levitates an oxygen mask towards her mouth. It shouldn't be strictly necessary, with both your ship and [i]Ocarina[/i] having breathable air bubbles, but it would be just like Link to turn his off and make your Kinnari to freeze or suffocate. "Compared to some pirate goons, we're basically invincible. We'll be fine."

*fake_choice
  #"Only if we stay focused. And don't get overconfident."
    *set Confid %-8
    *set RenfriRel %- 8
    *set DamonRel %+ 8
    "I'm not overconfident," Renfri protests, her voice slightly muffled by the mask. "I'll stay cool, I promise."
    
    "And I'll be cool with you," 
  #"I agree. There's not much to fear, really."
    *set RenfriRel %+ 6
    *set Confid %+ 12
    *set ManfredRel %- 6
    Damon looks at you with doubt, but makes no comment. Nobody does.
    
    "I'll join you and make it four in a minute," 
  #"Is boarding their vessel really our best bet?"
    "Nothing else makes sense, given the size difference between our ships," Rook replies from his seat. "Marshal is right about that, if nothing else."
    
    "You're so supportive, Kirill," Renfri says, her voice slightly muffled by the mask. "Don't worry, you won't have to do anything. Other than maybe fire the cannon [i]before[/i] we jump the ship. We need a hole in their armor, after all."
    
    "Do we?" Damon questions. "We have some people capable of tearing holes through metal."
    
    "Good point." Renfri looks at her other teammates. "Lisa, dog time."
    
    "Sure enough," 
  #"Actually, do I have to participate in this attack?"
    *set Confid %- 12
    *set DamonRel %- 6
    "Sorry boss, but you're not getting out of this," Damon replies, pointfully placing a hand on your shoulder. "It was your idea, and you will see it through."
    
    "I'll see it through too," 

Hellhound says, retreating deeper inside the ship. "I just need to get angry first. And maybe take off these clothes so I don't end up ripping them apart again."

"It would not hurt," Kirill agrees. "And neither will keeping an important asset in reserve, I suppose."

"Speaking of things that won't hurt," Manfred chimes in. "I was wondering if you'd like to inform Captain Link of your decision to attack. We are about to approach [i]Ocarina[/i] with clearly hostile intent anyway, so it hardly makes a difference. He will be ready for your assault all the same."

*fake_choice
  #"No, we need every tiny advantage we can get."
    *set Confid %- 8
  #"No need. Actions speak louder than words."
  #"Inform him of our decision. It's honorable this way."
    *set RenfriRel %+ 6
    *set RookRel %+ 6
  #"Bring the connection back. I'll tell him personally."
    "If you so desire," Manfred replies. Some five seconds later, another voice comes out of the speakers.
    
    "Well?" Captain Link asks with some annoyance. "Has your group reached consensus already?"
    
    "Not really, but we made a decision," you say calmly. "You may prepare for combat. Or surrender, if you would prefer."
    
    "You know I can't do that, ${name}." There is no anger in the other android's voice. Just disappointment. "I have responsibilities to my crew. And I will not be captive to humans ever again, unlike you."
    
    "Do you suspect I'll be imprisoned sometime soon?"
    
    "You already are. The Federation is pitting you against your kind, making you risk your existence for [i]nothing[/i]. And make no mistake, those humans will discard you once your mission is done and you're no longer of use. That is just their way."
    
    *fake_choice
      #"I don't really care, Link. Prepare to die."
        *set Violence %+ 6
        "I've been prepared for a long time now," Link says calmly. "Let us see if you are."
      #"I'm sorry for what happened. And I'm sorry for what I'm about to do."
        *set Violence %- 6
        "I would say I'm sorry too. But it won't make the next hour any less painful."
      #"You won't sway me from doing the right thing."
        "I'm not trying to. I just want you to see reason and know the truth, as you die aboard my ship."
      #"I'm not doing this for humans, you know. I'm doing this for me."
        "Respectable, I suppose," Link says calmly. "Let's see if the same can be said about your skills, after all these centuries."
      #"You are wrong about humanity. Your wounds cloud your judgment."
        *set Misan %- 12
        "Your wounds are far more severe than mine," Link says with calm malice. "Luckily, they won't bother you much longer."
    
    And with that, Captain Link disconnects. No doubt to call his lieutenants and prepare for the battle he knows you're about to wage.
    
    *goto skipone

"As you wish," Manfred says neutrally, then falls silent. You suspect he needs to concentrate on the ship; Maneuvers involved in voidship combat are quite complex, even for a digital entity like him.

*label skipone
*set saturn_path "pirates"

"Good look out there," Kirill says as you head for the door, right behind Damon and Renfri. "And one more thing? It seems likely that our enemy has some innocent aboard, some captives from his pirate raids, and can possibly use them as hostages. Do not react to such threats, alright?"

"You think Link will play like that?" You cock an eyebrow. "That he will appeal to our concern for human life?"

"I just want to ensure you know what is expected of you. Holding back due to the presence of hostages borders on negotiating with terrorists and is strictly against the federate rules regarding space warfare, not to mention practical concerns. Do us both a favor and shoot everyone who stands between you and your target, regardless of their reasons for being there."

*fake_choice
  #"Don't worry. I'll kill everyone on that ship, regardless of their status."
    *set Violence %+ 15
    *set RookRel %- 5
    Rook blinks. "I did not ask you to be [i]that[/i] trigger-happy… but do what you must, I suppose."
  #"I will do what I need. Don't you worry about that."
    *set Violence %+ 8
    *set RookRel %+ 5
    "Good to see we are on the same page," Rook says with slight relief. "Or chapter, in any case."
  #"There won't be any hostages. That's not Link's style, you'll see."
    "Not really answering my question there," Rook points out. "But fine. We will see how correct your predictions are in just a moment."
  #"Only if I have no other choice."
    *set RookRel %- 5
    *set Violence %- 5
    "I fear Link may offer you another choice, then," Rook says with a frown. "But go ahead, I suppose."
  #"No deal. If there are any innocents on that ship, I'm saving them."
    *set RookRel %- 10
    *set Violence %- 10
    *set RenfriRel %+ 5
    "Such a show of humanity from such an inhuman creature," Rook remarks coldly. "I will pray that your weakness does not prove your undoing."

And with that, there is nothing more to say. 
*if weapon = "none"
  You clench your fists, more than ever aware that your distaste for weapons may bite you in the backside very soon. Time to find out, you suppose.
*else
  You grip your ${weapon}, wondering who you will get to, have to use it on. Humans, abhumans, perhaps Link himself? You suppose such ponderings are pointless—you will find out in several minutes regardless.

*page_break

Space combat comes in many different forms depending on location, ships involved, demeanors of those ships' commanders and many other factors. Some battles are almost exactly what pre-Dawn scientists imagined; Slowly accelerating and decelerating ships firing torpedoes at one another over astronomical distances until one of the vessels gets completely annihilated by a single, extremely precise shot. But such a thing cannot happen inside Saturn, and it definitely won't happen here.

For one, the dense atmosphere makes it difficult for either ship to truly harm the other, meaning a long-distance battle would likely end in a standstill. Not that you're interested in entering such a fight, as the close proximity of the two ships allows you to fully utilize your one advantage.

And thus [i]Grey Queen[/i] approaches [i]Ocarina[/i] and starts flying circles around it, evading the few laser shots with relative ease and firing its own cannon once or twice. During one lap, your ship gets truly close to the pirate frigate, just as the upper decks of two ships are facing one another, just as you can see the flat surface clearly.

And then you jump.

For an unaugumented human, this would be supremely risky, likely deadly without highly-specialized equipment. But you and Damon are tough androids, and so you hit the frigate's hull with minimal damage to your bodies. Seconds later, Marshal descends from the sky, landing on the deck far more gracefully.

"Part one completed," she comments as she looks around. There are no people on the upper deck besides the three of you, just some crates and containers. Most of them appear empty, as though only arranged to make the pirate ship look more innocuous. "Now I just need to find a weak spot and burn out an entrance for us. Or maybe just use an entrance hatch, they don't appear guarded… for some reason."

You catch the implication. Normally, in such a situation, the ship's commander would send at least a few armed men to the upper deck, shoot down the invaders before they could even land. It's mighty strange how not a single enemy came to attack you yet, and how not a single shot has been fired.

*fake_choice
  #"So what? Get to work, else we'll waste our initiative."
    *set RenfriRel %- 8
    "I guess I will," Renfri mumbles as she lights her laser disc up. "I just thought-"
  #"We took Link by surprise. He didn't think we'd jump, or perhaps thought he'd be able to shoot us down with the laser lance."
    *set Confid %+ 10
    "Only a very crappy leader would fail to anticipate a boarding action," Renfri points out. "And it's not like he fired a single-"
  #"Pirates are cowards, like all cruel men. They'll probably stay inside for as long as they can."
    *set RenfriRel %+ 8
    *set Confid %+ 5
    "They'll be easy to kill, then," Renfri replies as she approaches a dented spot in the hull. "Would be even easier with some grenades or-"
  #"It's a trap. Some unorthodox tactic we failed to predict."
    *set Confid %- 5
    "I figured that much out," Renfri says grimly. "But what exactly-"

"Wait!" Damon interrupts. "Pay attention to gravity. It's stronger than on most ships, way over one gee."

"It's not that much stronger." Marshal's brow furrows. "We can easily operate here, and a spaceship this size could easily generate such pull. It's barely… Saturnian."

Within another second, understanding hits. You realize that, unlike aboard [i]Gray Queen[/i], the gravity is not artificial. It is the natural pull of Saturn, attracting everything towards the planet's core with the acceleration of ten meters per second squared.

And then the ship rotates.

*temp saved_by_renfri false
*page_break Shit

You suppose there is a certain elegance to that solution. Why bother with expending ammo when you can just turn off artificial pull, point the upper deck at the depths of Saturn and allow the attackers to fall off your precious ship? You struggle to fully appreciate the strategy, however, being on the receiving end of it.

Damon does not fall, as though his shoes are firmly glued to the hull. Perhaps Hadaly made those boots magnetic in her free time, or perhaps Damon is better at electromagnetic projection than you thought. For Marshal, creating a small gravity bubble around herself is but a small feat of her powers. But you [i]are[/i] falling, already detached from the hull, and about to descend deep into Saturn unless you do something quick.

*fake_choice
  *selectable_if (Projection > 50) #I'll use my own energy projection to hold on.
    *set battery - 8
    *set RenfriRel %+ 8
    It's not as straight-forward as throwing lightning, nor as universally useful, but you can use your control over electromagnetism to prevent a deadly fall. You pull yourself back towards the metal hull with great effort, as well as a few small discharges as your battery is put under the strain of your weight.
    
    Luckily, you don't have to hold on for long. 
    *goto post_save
  #I'll try to grab Damon's sleeve.
    *set DamonRel %+ 12
    If Damon can hold on to the ship, surely you can survive by holding on to him. Surely he won't mind. Surely you won't mess up his suit… or end up tearing it apart and falling into Saturn anyway.
    
    *if Calculation < 45
      But you don't get to find out how durable the fabric is. You are not quick enough, your hands clasp around nothing as you fall, flying away from Damon and from the ship, feeling the cold as you leave the ship's air bubble and enter the cold, half-liquid atmosphere of Saturn itself. So cold it will destroy you, make you freeze to death within minutes unless someone-
      
      *goto renfri_saves
    
    Luckily, your reflexes are immaculate and the fabric of Damon's suit surprisingly resilient. You grip his sleeve tight, hanging on by a thread but holding on nonetheless. You suppose Damon's fashion sense isn't entirely impractical after all.
    
    "Glad to be useful, boss!" Damon says with just a hint of distress. "So please hang in there until… something changes, I guess."
    
    *fake_choice
      #"Sure thing! And thanks for lending me a hand."
        "You got it boss!" Damon smiles. "Now less talking, more focusing. Velvet is hard to hold on to, you know?"
        
        *label nm
        You do as Damon says, though thankfully not for long. 
      #♡ "Damon, I would kiss you if I could."
        *set hit_on_damon true
        *if current_ro != "damon"
          *set backup_ro current_ro
          *set current_ro "damon"
        *if DamonRel > 50
          *set DamonRel %+ 15
          "Well that's a… nice idea." Damon smiles shyly. "But velvet is slippery, so focus on holding on for now."
        *else
          "I don't think it's good time for flirting, boss," Damon says with a frown. "Focus on holding on."
        
        *goto nm
      #"Stop calling me [i]boss[/i]!"
        *set DamonRel %- 10
        *set RenfriRel %- 5
        *set name_damon name
        "Sorry!" Damon replies quickly, then pauses for a moment. "Although I think you should maybe thank me instead of lambasting me, considering-"
        
        "Is that really the time for arguing?" Marshal cuts in. "Just hold on. And wait for things to get normal."
        
      #"It will. Those pirates can't operate upside-down for long."
        Unless this frigate is [i]really[/i] special, lack of artificial gravity here means the absence of it inside the ship. Right now, i]Ocarina[/i] is a sitting duck, and even your humble cutter will destroy it unless Link's clever little maneuver is concluded soon.
        
        It soon turns out you were right. 
      #"Renfri, care to create a bit more gravity for us?"
        *set RenfriRel %- 10
        "I need to save my energy for later!" Renfri shouts back. "I'll catch you if you fall, but until then, just hold on."
        
        Thankfully, you don't need to maintain your grip for long. 
    *goto post_save
  #I'll scream for help.
    *set deflect - 1
    *set DamonRel %+ 8
    *set RenfriRel %- 8
    It's difficult to hear what you scream, exactly, as you leave the ship's air bubble and enter the cold, half-liquid atmosphere of Saturn itself. Droplets of hydrogen do not carry sound well, but they do absorb your heat and enter your body, they will make you freeze to death within minutes unless someone-
  #I'll just fall. I've lived long enough, I suppose.
    *set deflect + 1
    It feels almost pleasant to enter free-fall and soar through the air around the ship, and then the cold atmosphere of Saturn itself. It will be a good death, cold death, slow but not painful as hydrogen fills your-

*label renfri_saves
*set saved_by_renfri true

You are pulled, or pushed, or dragged back with tremendous force. It's difficult to tell which way is up as you hit the deck again. Marshal grunts with effort, having greatly expanded the gravity field around her, pushing her powers to their limit as she holds you pressed to the hull.

*if RenfriRel > 50
  "Hold on there, android," she says with a strained smile. "Or don't. I'll keep defying gravity for you if I must."
*else
  "I shouldn't be doing this." It takes effort for her to speak. "You're the Veteran. You should have some way of dealing with gravity."

*fake_choice
  #Nod and try to grab something.
    *label llpp
    
    The deck itself is fairly smooth, but you manage to walk up to and embrace a nearby crate, firmly fastened to the surface. Renfri then relaxes, returning gravity to its natural direction, but still keeps it somewhat lowered. It prevents your hands from slipping off, and would perhaps give Damon a chance to grab you should you start falling again. Luckily, it doesn't come to that.
    
    *goto post_save
  *if RenfriRel > 50
    #"Thanks partner. And don't worry, I'll save you some effort."
  #♡ "Damn. If I could move at all, I'd kiss you."
    *if current_ro != "renfri"
      *set backup_ro current_ro
      *set current_ro "renfri"
    *if (sex = "woman") or (pronoun = "she")
      *set RenfriRel %+ 8
      "I'll consider taking you up on that offer once we're done boarding," 
    *else
      *set RenfriRel %- 8
      "I'm not into @{(pronoun = "he") men|androids}, and certainly not into you," 
    Renfri grunts out with effort. "Now make my job easier and hold on to something."
  #"Well that was close. Thank you for your assistance."
    *set RenfriRel %+ 8
    "For saving your ass, you mean," Renfri says with a @{(RenfriRel > 50) smile|grimace}. "And you're welcome. Now grab something if you can."
  #"She's a cruel mistress. Gravity, I mean."
    "Sucks to have arms rather than wings, huh?" Marshal manages a smile, despite gritted teeth. "But since you're stuck with those, grab something. Just in case I… just in case."
  *if RenfriRel <= 50
    #"Well I have you, don't I?"
      "Yeah, unfortunately," Renfri says through gritted teeth. "But you also have arms, so hold on to something just in case."

*goto llpp

*label post_save
[i]Ocarina[/i] soon returns to its proper position, the upper deck facing the sky rather than the core of Saturn far below. Even the gravity turns artificial—presumably to allow the ship to spin as [i]Gray Queen[/i] flies around it.

Even before full return to normal, Marshal takes to burning a hole through the spaceship's hull. Her laser disc, although a rather mediocre weapon, seems quite suited to the task of melting metal, or perhaps the frigate's hull is simply that fragile. Soon you see a circle of molten steel, some meter in diameter, a perfect entrance inside the ship once the hole is complete.

But before that comes to pass, the regular hatches start opening, pushed from below. You can now be certain there will be no more rotating the ship or turning off gravity; The enemy finally decided to strike back directly.

*page_break

The first to emerge, through the single largest hatch, is an armored figure of a large abhuman. Dark green in skin and over two meters in height, you recognize the pirate as a Marauder. A subspecies of humanity designed specifically for close-quarters combat, modified so heavily it borders on meta-human. Marauders are inhumanly tough by nature and this one appears well-armed too, with a shroom rifle in his hands and a faint shimmer of energy shields around him.

Damon fires his electron rifle immediately, but the abhuman doesn't appear very bothered, either thanks to his heavy armor or superhuman physique. With nary a grunt he returns fire, forcing all of you to duck and seek cover behind the crates, but hopefully emptying his magazine for the moment.

And you are in a good position to observe as the other pirates come out of their own openings… except they don't look like pirates. Some of them have stereotypical injuries, you can even see an eyepatch or two, but they're wearing uniform suits of flak armor that looks like federate equipment. Their other equipment is more varied—some carry machine pistols whilst others wield monocular swords. But they are all outfitted with metal collars clasped around their necks, the main giveaway that they may not be attacking you with full willingness or enthusiasm. Not that many of them fired yet, most of them either looking for cover or just paralyzed by fear and indecision.

"What are you waiting for?!" The Marauder, clearly in some position of command, seems to have noticed his subjects' lack of enthusiasm. His voice is loud and deep, like a gorgon's roar. "Kill those three, then you'll have your freedom!"

One of the soldiers seems actually encouraged by this, or perhaps sufficiently terrified by the pirate lieutenant. He grips his cutlass tightly and charges forwards, roughly towards the crate you hide behind.

*fake_choice
  *if weapon = "pistol"
    #Just shoot him.
      *set pacifist false
      *if wpr = "plasma"
        *set weapon_av false
      The distance is just right for you to aim your ${wpr} pistol without hurry or trouble. 
      *if Calculation > 50
        You don't even do the customary thing by aiming at the centre of mass, firing a single shot in the soldier's uncovered face instead.
      *else
        You still aim for the centre of mass, just to be sure, and fire several consecutive shots for the same reason, your projectiles tearing through armor and flesh at multiple locations.
      
      *goto dist_ex
  #Let Damon handle it.
    *set DamonRel %+ 6
    *set Confid %- 6
    Damon has a weapon stronger than yours, and he has a nice opening, what with the enemy's attention being focused on you. He aims calmly and pulls the trigger, burning a hole in the soldier's head with a powerful electron beam.
    
    *label dist_ex
    
    Unsurprisingly, the attacker dies instantly. Somewhat surprisingly, the collar on his neck explodes the moment his body hits the ground, sending hot wind blowing in your face and cutting your clothing with its shrapnel. It's not capable of causing much damage at this distance, not to an android like you, but it makes you understand just what kind of motivation the enemy troops are subject to.
  #Counter-charge and @{(weapon = "knife") stab him|punch him} in the face.
    You're not sure what the soldier is thinking, directly attacking someone like you. The superiority of your speed and experience is evident just from your moves as you @{(weapon = "knife") lower your head and raise your knife|clench your rapidly accelerating fist}, ready to slay your opponent with a single-
    
    *goto clos_ex
  #Appeal to his better nature and make him stop.
    "Halt!" you shout, standing up with your palms open. 
    *if Social > 50
      "Is this really what you want? To take a life on behalf of your cruel masters? 
    *else
      "Do you really want to do this? Stab me with your sword, I mean? It has to be illegal or something."
    
    Luckily, the soldier does stop, either convinced by your arguments or simply confused. Unluckily, the moment he opens his dry lips to say something, the Marauder officer presses some switch, perhaps button, on the side of his chestplate. 
    
    *label clos_ex
    *set health - 1
    
    And then the collar explodes.
    
    It's not a particularly strong explosion, only equivalent to that of a frag grenade, perhaps a weak mine. But it still kills the captive soldier and sends chunks of his skull flying, still scorches your skin with its heat and pushes you backwards with the force of its blast. Still leaves your clothing torn by the shrapnel as you hurry back behind the crate, having just realized what you're dealing with.
  #Lightning strike it is, then.
    *set battery - 5
    *set pacifist false
    It's improper to call the discharge you now produce a [i]lightning[/i]. 
    *if Projection > 45
      You know better than to waste your half-depleted energy on a powerful attack against a mere baseline human. 
    *else
      *set Projection %+ 10
      You do not have enough energy, nor enough skill for that. 
    But the flash is still blinding and the sound still thunder-like as you shock the charging soldier, burning his skin and frying his neurons in an instant.
    
    And then the collar explodes. Maybe it was triggered from outside, or maybe your blast fried some circuits, the final result is the same. Another flash, a wave of heat, ionized air blowing in your face as the shrapnel shreds the fabric of your clothes.

"Well that's classy!" Damon shouts towards the Marauder as the latter reloads his rifle. "Why put your own men at risk if some kamikaze captives work just as well?"

*if told_crystal
  "Probably the crew of [i]Black Narwhal[/i]," you murmur, more to yourself than to your teammates. "Captured and enslaved when the subgiant was destroyed all these weeks back."

"All the reason for me not to fight these guys," Marshal says, almost done burning through the floor. "I'll go inside. Kill some actual pirates, maybe find that Link bastard and end everything early."

*temp left_damon false

*fake_choice
  #"If you die on me, I'm gonna be really sad."
    *set Emotion %+ 8
    "I'll try not to die, then." Renfri smiles with confidence and amusement. "And I suggest you do the same here."
  #"What are we supposed to do, then?"
    "Take care of the captives somehow," Renfri gives you a non-answer. "And the huge Marauder guy. Show us that your centuries of experience are worth something after all."
  #"Godspeed, then. We'll handle the captives."
    *set RenfriRel %+ 10
    *set DamonRel %- 10
    "I know you will," Renfri smiles weakly as she turns off her laser disc. "And if you're gonna do it lethally… make it quick, alright?"
  #"You want to fight the pirates [i]and[/i] Link alone? Cause that's suicidal."
    *set RenfriRel %- 5
    "You underestimate my power," Renfri says, overestimating her power. "If you really want to join me, take down the lieutenant fast. I'll keep the other pirates busy."
  #"Don't. We need you up here."
    *set RenfriRel %+ 5
    "I'm sure you'll handle it!" Marshal argues. "Or at least find it more likely than not. See you."

And with that, Renfri kicks the metal plate inside the ship, at last creating an opening in the hull, surrounded by molten metal and leading directly to some corridor. She jumps in, military boots hitting the floor some two meters below, then disappears as she dashes deeper inside the vessel.

Seconds later, you're able to faintly see red flashes coming from the inside, likely shots from laser-based weaponry. Much like the laser beams flying above your head, now that the captives finally decided to open something resembling suppressive fire.

"Well we just lost a third of our force," Damon remarks, cowering under the lasers and the bullets. "What do we do with the rest?"

*temp mar_alive true
*temp dam_down false
*temp dam_shoot false
*label 2choice
*fake_choice
  #"Engage the guy in charge. I'll take care of the captives."
    *set DamonRel %+ 10
    "I like that arrangement," Damon comments before leaping out of his cover. Some of the soldiers aim their weapons at him, but they're hesitant to shoot. You shoot some lightning in their general direction just in case, less to actually hurt anyone and more to distract them with the flashes and the thunder. Allow Damon to fully focus on his objective.
    
    And so he does. The Marauder fires again, this time hitting Damon successfully. The shroomal bullet tears through the fabric of the suit, tears through the pale synthetic skin and enters the mechanical system beneath it… but the android just keeps going. He reaches the pirate, one injured giant assaulting another, and hits the abhuman over the head with his own rifle. A questionable tactic for sure, but the Marauder appears stunned by this in more than one way, especially as Damon continues beating him. You're decently sure your companion will kill the pirate, provided nothing interrupts their odd duel.
    
    *goto hostage_fight
  #"I'll take care of the Marauder, you distract the rest."
    *set dam_shoot true
    "I'm fine with this arrangement," Damon says as he stands up and opens fire in the soldiers' direction. Suppressive fire, designed to make the enemy cower rather than kill. He's not fully comfortable with shooting collared slaves, it seems.
    
    The pirate lieutenant opens his mouth to shout at the captives as he points his rifle at Damon, but then he sees you running at him. He fires a semi-auto burst 
    *if Build > 50
      and grazes you with one of the bullets, but you are too tough for such a minor injury to stop you. 
    *else
      *set health - 1
      that damages your body dearly, shroomal bullets expanding as they enter your chest, but that's something for Hadaly to worry about later. 
    You're still able to reach him at the stern, still able to attack.
    
    *label mar_attack
    *set pacifist false
    *fake_choice
      #Wrestle the rifle out of his hands, then shoot him with it.
        *if Build > 45
          For anyone else your size, wrestling against a Marauder would be a ridiculous idea. But you [i]are[/i] an android, and a pretty damn tough one at that.
          
          You surprise the abhuman by grabbing his rifle, then surprise him further by pulling it out of his grasp and aiming it at him. You can't tell whether he's surprised when you fire—his head soon explodes into a gory mess, so you can't exactly see his expression.
        *else
          The plan is solid… except for the part where you waste all your momentum for the sake of playing tug-o-war with a creature far larger than you. And quite a bit stronger, as it soon turns out.
          
          Mere three seconds after you grab the rifle, the Marauder pulls it out of your grasp and throws it far away. As you wonder how he intends to keep on fighting, he punches you in the head with enough force to make you dizzy, even though that shouldn't be possible given how your processors work. Oh well.
          
          *goto mar_fail
      *if weapon = "knife"
        *selectable_if (weapon_av) #Just stab him.
          It makes sense to get up close and personal, as shields cannot protect from a good thrust of a combat knife. 
          *if ((wpm = "plasma") or  (wpm = "bone")) or (wpm = "power")
            Certainly not the kind of ${wpm} dagger you wield. The blade easily enters the Marauder's neck, the swing too fast for him to react, and very nearly decapitates the green-skinned creature. The huge body falls to the floor, hits the metal plates with the kind of thud you heard many corpses make in your heyday.
            
          *else
            It does not, however, make that much sense to expect your ${wpm} dagger would do much against something that huge and armored. The blade pierces the armor's carapace well enough, but the wound it causes is only one, perhaps two centimeters deep.
            
            It hurts though. You can tell the Marauder feels pain, hear him roar as he punches you in the face with force and fury. The blow causes you to fall backwards and on the metal plates, dazed, likely more damaged than your opponent is.
            
            *goto mar_fail
      *if weapon = "pistol"
        *selectable_if (weapon_av) #Run up to him and empty your whole magazine, point-blank.
          *if (wpr = "plasma")
            *set weapon_av false
          *if ((wpr = "plasma") or  (wpr = "laser")) or (wpr = "shroom")
            Your ${wpr} pistol was made for exactly this kind of occasion. Shields don't matter at this distance, and neither does armor as you send @{(wpr = "laser") beam after beam|bullet after bullet} flying into your opponent, @{(wpr = "shroom") piercing|scorching} green skin and destroying the flesh. Barely any aiming is necessary—the pirate falls on the floor three seconds later, just as dead as he would have been from a precise headshot. 
            
          *else
            Due to your proximity to the Marauder, you can ignore your opponent's shields and the need for aiming… but not the armor, and not the enhanced physique of the large abhuman. Not with your ${wpr} pistol, designed with range rather than sheer damage output in mind.
            
            And since you are now within melee range, you cannot quite ignore the pirate as he uses his rifle like a cudgel and hits you in the head, prompting your fall onto the metal plates. Prone, dazed and in quite a bit of danger, you swear you'll make better use of your armaments next time… provided you live to see another fight.
            
            *goto mar_fail
      #Charge up your entire skin, then slam into the bastard.
        *set battery - 10
        *if Projection > 50
          It's an unorthodox move, certainly, but that's what makes it surprising. And you have just enough sheer power to pull that off, turning yourself into a thunderstorm's centre as you collide with the Marauder.
          
          It takes much off your battery, it scorches your skin, and it obviously ends with you on the floor. But your opponent is lying there too, and he's not conscious. He's just twitching in what could well be a cadaveric spasm. Out of the picture.
          
        *else
          You collide with the Marauder and channel power into him, in a brilliant move that would have certainly killed your foe… if said foe wasn't a Marauder. Or if your battery was any fuller. Or if you were just a bit more skilled at using it.
          
          As it is, the pirate lieutenant barely appears to notice the shock you gave him. Worse yet, he manages to remain standing, whereas you fall to the ground, having bounced off the green-skinned giant with just ${battery}% of your power remaining.
          
          *goto mar_fail
      #Beat him unconscious in hand-to-hand combat.
        *if Build > 60
          For anyone else your size, throwing hands with a Marauder would be a ridiculous idea. But you [i]are[/i] an android, and a pretty damn tough one at that. 
          
          The pirate appears unaware of that fact, or perhaps having forgotten it. He's surprised when you slam your fist into his jaw, more surprised still when you just keep punching despite his feeble attempts at blocking your blows or striking back. 
        *else
          Your synthetic muscles are strong, perhaps stronger than the organic tissue of the Marauder… but he's still larger than you, still more armored. You are just barely able to slam your fist into his jaw, and the attack does little but provoke a counter-strike, a powerful swipe that sends you flying towards the floor head-first. By the time you connect with the ground, you can tell that your metal skull has just been [i]bent[/i] by the sheer force of the punch.
          
          *goto mar_fail
    
    *set mar_alive false
    *goto hostage_fight
    
    *label mar_fail
    *page_break
    *set health - 1
    
    The Marauder picks you off the ground by the arm, his barely human face twisted in a triumphant grin. He then twists the arm in a movement that would have broken any bone, left an organic arm a bloody mess… but you have no blood and no bone, only metal and plastic. And so, in what is still a testament to the pirate's strength, the limb is merely bent and the pain you feel isn't [i]quite[/i] enough to distract you. To miss this opportunity you've been granted.
    
    *if weapon = "knife"
      You make full use of this moment of surprise and stab the abhuman in the neck. 
      *if ((wpm = "plasma") or  (wpm = "bone")) or (wpm = "power")
        Your ${wpm} dagger is a deadly tool, capable of killing a grown man regardless of where the blade lands, and so the precise thrust is enough. 
      *else
        Your ${wpm} dagger may not be much against a Marauder, but your thrust is precise and his armor weak in this spot. 
      The pirate drops you before falling to the floor himself, very nearly decapitated, choking on his blood and writhing until his pained spasms turn into post-mortem kind. 
    *if weapon = "pistol"
      You aim your ${wpr} pistol at the pirate's head and pull the trigger. 
      *if ((wpr = "plasma") or  (wpr = "laser")) or (wpr = "shroom")
        A single shot is enough, fired from such a powerful weapon at such a close distance. 
      *else
        Then again, and again, until you turn the pirate's head to bloody mush. 
      A maneuver only possible thanks to the element of surprise, but effective nonetheless.
      
      *set mar_alive false
      *goto hostage_fight
    *if weapon = "none"
      *set battery - 15
      You use your other arm and place your hand flat on the Marauder's face before pouring it all out. Channeling every bit of electric power you have, electrons flowing from your palm and into the ground, through the pirate's fleshy body. There is a lot his kind can take, but such a direct lightning strike @{(Projection > 50) easily overloads|just manages to overload} his nervous system.
      
      He falls to the ground as do you, but at least you are still operational, despite your limited energy reserves. He is unconscious, burned, possibly dead. 
    This threat, at least, is definitively removed.
    
    *set mar_alive false
    *goto hostage_fight
  #"We'll charge the big guy. Together."
    *set dam_down true
    "All or nothing, huh?" Damon sounds worried, even in his lack of protest. "I guess I can see the appeal. On your signal, ${name_damon}."
    
    There's actually no need for a signal. Damon is a computer like you, he reacts nigh-instantly when he sees you leap out of cover, and the two of you start charging at practically the same moment. The soldiers are far slower to react, only firing a handful of poorly-aimed shots by the time you're halfway there. Twenty, then fifteen, then ten meters removed from your target.
    
    The Marauder seems shocked, perhaps scared, but he still maintains some composure while firing a semi-auto burst at Damon, picking the larger target out of the two candidates. His aim is good, the shroomal bullets bury themselves in Damon's body and make the android fall to his knees mid-charge, but you know how tough your companion is. He'll be fine, after some moderate repairs. Same can't be said about the pirate you're about to attack.
    
    *goto mar_attack
    
  *disable_reuse #"I'll go help Marshal. You deal with the rest."
    *set left_damon true
    *set DamonRel %- 20
    *set damon_pissed true
    "What?!" Damon exclaims, forgetting his usual manners. "I can't deal with so many enemies at once [i]and[/i] a Marauder. Sides, I don't know what to… how to… How can you leave me up here?"
    
    *fake_choice
      #"I can't let Renfri die down there. Please understand that."
        *set DamonRel %+ 10
        *if ((official_ro = "renfri") or (current_ro = "renfri"))
          *set damon_pissed false
          "You really are into her…" Damon murmurs. 
        *elseif Misan < 35
          "Right. Your undying loyalty towards humans and everything close." Damon rolls his eyes. 
        *else
          "But why? Why is she more…" Damon cuts off, his expression as pained as his voice. 
        "Fine. You go help her, I'll keep the enemy busy."
      #"I just don't care if you live or die, that's it."
        *set DamonRel %- 20
        *set HadalyRel %- 10
        "Well I appreciate your honesty!" Damon shouts as you jump into the hole Marshal made, not paying him any more attention. "I can't believe I… fuck."
        
        *goto skip_o
      #"That's because I fully believe in you, Damon. You can handle it, I'd just get in your way."
        *if (Social + DamonRel) > 90
          *set DamonRel %+ 15
          *set damon_pissed false
          "Well if you put it like that…" Damon seems to buy your words of encouragement. 
        *else
          "Right…" Damon does not sound convinced. 
        "Fine, I'll try to at least stick around. Keep the enemy busy, let you do your own thing."
      #"Actually, you're right. We'll weather this storm together.
        *set DamonRel %+ 15
        *set damon_pissed false
        "Well I sure hope so," Damon says with annoyance that doesn't quite manage to hide relief. "Because we're outnumbered pretty bad. What's the plan?"
        *goto 2choice
    
    "I couldn't have asked for more," you say, jumping into the same opening Marshal used. "Godspeed."
    
    *label skip_o
    *set hostage_killed true
    
    You can't see Damon anymore, nor hear him speak. His weapon doesn't make much sound as he opens fire against a force of two dozen men, assuming he did the smart thing and started blasting. Hopefully Hellhound wasn't kidding about planning to join the fight, and if not…
    
    You shake your head as you run hurriedly, deeper inside the widening corridor. You have your own job to do.
    
    *goto entering_s

*label hostage_fight

You then focus all your attention on the mass of collared, uniformed men before you. 
*if dam_shoot
  They seem to have Damon pinned behind a crate, even though their red laser and gunpowder lasers are unlikely to hurt the bulky android. Either Damon is afraid to damage his suit, or reluctant to fight altogether.
  
Quick count puts their number at two dozen, which would be intimidating in any other situation, but you sorely doubt a force that demoralized could hurt you with weapons so mediocre as red lasers and cutlasses. The only danger is in their collars, the explosions of which could harm you should you get close and somehow detonate them… or if their presence compels you to hold back.

What will you do with the soldiers?

*fake_choice
  #I'll pick them all off from a distance. Lethally.
    *set Violence %+ 9
    *if weapon = "pistol"
      You raise your pistol but, before you can fire, 
    *else
      You prepare an electric charge but, before you can release it, 
    you notice something interesting in the sky. 
  #I'll beat them up black and blue, one by one.
    *set Misan %- 9
    It's a risk, and hardly a calculated one. The collars may explode once they detect how close you are, or that their wearers are unconscious. You may end up killing some of these people by applying too much force. Or they may kill you in close quarters, aided by your reluctance to kill. But it's a risk you're willing to take all the same.
    
    But before you can make more than a single step towards the group, and before any of the captives lands a single shot, you all notice something. 
  #I'll convince them to lay down their arms.
    *set Violence %- 9
    Perhaps, @{mar_alive if Damon manages to kill the Marauder quickly enough,|what with the Marauder being taken care of,} those people won't get blown up for refusing to fight. Assuming you can convince them in the first place. Worth a try, you suppose.
    
    You open your lips, but something grabs your attention before you can speak. 
  #I'll just stand there with my guard up.
    *set health - 1
    One of the captives fires at you from a laser carbine, doing some damage to your system, but you stop yourself from flinching. The other soldiers just freeze with their guns aimed at you, held back by the fear of this mysterious menace, or perhaps by their conscience. Hard to tell as you stare the group down, in tense and vaguely absurd silence.
    
    Until you all notice something. 
[i]Gray Queen[/i], high above, yet far closer to the frigate than it was a minute ago. Just as close as it was two minutes ago, when it dropped you three on the hull of [i]Ocarina[/i]. And now it drops a fourth member of your little team.

Hellhound lands on all fours. She is fully lupine now, looking more feral than ever as she shoots forward. She makes even the braver captives cower or run towards the helm as they see this large, red-furred, monstrously clawed creature charge their group. You doubt she can fully understand the situation, having just arrived, not in her current form. You highly doubt she cares. You are watching a wolf dash towards her prey, explosive collars or not, about to make contact with her claws and teeth.

*fake_choice
  #"Careful! You'll get blown up if you get close!"
    *set LisaRel %+ 10
  #"Lisa stop! They're not here by choice!"
  #"Hey, no stealing my kills!"
    *set Violence %+ 7
  #"Get them, girl!"
    *set LisaRel %+ 5
    *set Violence %+ 5
    Encouraged by your words, the werewolf leaps forward with even greater speed. 
    *goto hjia
  #Zap her with lightning.
    *set battery - 10
    *set LisaRel %- 20
    *goto shock_lisa
Lisa doesn't hear you, or perhaps ignores your words of warning. 
*label hjia
She reaches one of the soldiers, a young man with a rifle he's not nearly quick or collected enough to fire and swipes for his throat with her enlarged, clawed paw.

You expect blood to spill onto the deck, perhaps even the head to hit the metal. But the only thing that hits the ground is the collar, cut in two with nigh-surgical precision, just slightly stained with red ichor. When the soldier falls to the ground, perhaps having fainted from the fear and stress, Hellhound pays him no attention; She simply moves on to the next one, crushing his gun with the strength of her jaw, all while her claws tear away another collar.

You blink. Your teammate's speed and precision 
*if Calculation > 50
  are second only to yours, if that. 
*else
  far surpass what you're capable of, and you're a goddamn computer. 
The hound becomes blur, attacking and dodging, swiping and weaving with no delay, and no care for what minor wounds she sustains in the process.

*if Confid > 50
  You stand back and let her do what she wants; She seems to have things under control, in spite of her beastly form and newly-found pacifism.
*else
  You dare not intervene, as you see your help would not be needed… and fear it would not be appreciated.

Not all soldiers recognize what the werewolf is trying to do. One tries to run, forcing Hellhound to lunge forwards and destroy his collar with a single bite, the press of her frontal teeth. Another perceives an opportunity to attack, striking the red fur with an axe, hopefully just a regular one. Even still, the teeth merely rip the weapon away, and the claws only damage the explosive attached to the iron ring.

Eventually, the bloodless massacre ends. Every human on the deck is disarmed, cowering, fainting or freed from restraints. Every single one is shocked, especially as they see the beast shrink, transform back into its human form. That of a young woman, bare skin bruised in many places, so tired from the exertion she slumps down instantly.

"Well that was fun," she pants, leaned against an empty crate. "Do you think we can keep… what just happened… hidden from Kirill? Sell him some other version of events?"

*fake_choice
  #"Well you just saved me the effort of subduing all these soldiers myself. So I'll try."
    *set LisaRel %+ 10
    "I'm not getting my hopes up," the woman smiles grimly. "But it's nice to have your support all the same."
  *if Violence > 50
    #"Hide you stealing my kills and glory?"
      "I'm not ashamed about that part," Hellhound says with an eye-roll. "It's just that… you'll see soon enough."
  #"Since when are you worried what Kirill will think?"
    *goto explan_li
  #"Hide your selfless heroics, you mean."
    "What are you talking about?" she asks incredulously. "I've been known to enjoy a good fight."
    
    "It took quite an effort to spare all these captives," you point out, looking at all the blackened spots on the girl's fair skin. "As well as some pain, I perceive."
    
    "Don't think too much of me," Lisa says with a frown. "I just enjoy an extra challenge too, sometimes. Ripping these bastards apart would have been too easy for my liking."
  #"With over two dozen witnesses? I don't think we can."
    "Well that bites," she replies with a sigh. "I guess I'll have to take the blame. And whatever else gets thrown my way once we're back on the cutter."
  #"Why would we want to do that? What is there to hide?"
    *label explan_li
    "This situation is… not something Kirill is terribly used to," Lisa tries to explain. "He won't be happy with me. With how good I was, or appeared to be."
    
    You frown. "Anything more specific? Because you're not making much sense right now."
    
    "You will understand soon enough, android. Just wait until we're back on the cutter."

*set lisa_saved_hostages true
*label looks_around
For the first time since she landed, Lisa looks around the deck. "Where is our avian friend, by the way? Strange of her to miss a battle like this one."

"She went down and into the ship," Damon replies. 
*if dam_shoot
  He walks towards the two of you briskly, happy that his suit didn't get damaged much. 
*elseif dam_down
  He struggles to walk, still having a bullet inside his hip, but appears mostly fine. 
*else
  Behind him, you can see the pirate lieutenant's body lying flatly on the floor, either knocked out or dead. Hard to tell. 
"Probably fighting the rest of the crew as we speak."

"Well, that definitely [i]is[/i] like her," the woman replies with a grimace. "Will you follow her, ${name}? Keep her from getting herself killed and all?"

*fake_choice
  #"She's probably looking for Link. So yes, I will follow her."
    "Scores to settle, huh?" Lisa smiles grimly. "I guess your motives don't really matter. Not if you kill the guy quickly enough."
    
    "Seconded," Damon says, 
  #"You believe she can't handle herself?"
    *set LisaRel %- 9
    "We both know she's good," Lisa says coldly. "And we both know she's over her head. So get moving already."
    
    "I have to agree here, ${name_damon}," Damon says, 
  #"Eh. Do we really care if she lives or dies?"
    *set LisaRel %- 15
    "You know I care," Lisa says angrily. "Enough to tear you to pieces if you let her die. Unless Kirill gets to you first."
    
    "I'm not that enthused about losing a teammate myself," Damon concurs, 
  #"Will you be fine without me? You're @{dam_down both |}injured."
    *set DamonRel %+ 10
    "All the more reason for you to go and end this battle," Damon replies, 
  #"Of course. She's my friend as much as yours."
    *if (current_ro = "renfri") or (backup_ro = "renfri")
      "Aren't you also trying to court her?" Despite her pain, Lisa smiles playfully. 
    *else
      "Trying to make me jealous?" Lisa smiles grimly. 
    "Then take the next step and save Renfri's overconfident ass."
    
    "Can't argue with that logic," Damon says, 
kneeling down beside the werewolf. "I'll stay here, make sure our lady friend is safe. You can go help the other one… or take down the captain, whichever you care about more."

You leave that last remark with no comment. There is no time for comments, no time to waste as you jump down the hole and into the frigate's interior. You are met with no immediate resistance, but you imagine that will change really damn soon.

Link will not go down easily. And you somehow doubt he's already dead by Marshal's hands… or wings, for that matter.

*goto entering_s



*label shock_lisa
*set battery - 10
You shock Lisa, both by your decision and with the actual, electric power you channel into her. The fur gets burned and skin scorched, her muscles spasm as she collapses onto the floor. You didn't kill her, your battery wouldn't allow it even if you wanted to, but you're certain that the werewolf is out of the equation for now.

The captives stare at you, even more confused than terrified. You are free to deal with them as you see fit.

*temp blown_up false
*fake_choice
  *if weapon = "pistol"
    *selectable_if (weapon_av) #I'll just shoot them.
      *set pacifist false
      *set hostage_killed true
      You start blasting, killing a single captive with each and every shot. 
      *if (wpr = "plasma") or (wpr = "electron")
        *set weapon_av false
        *set battery - 7
        Your pistol soon runs out of @{(wpr = "plasma") plasma|energy}, but you finish the job with several quick flashes of artificial lightning.
      *else
        And you have enough 
        *if wpr = "laser"
          battery in your laser pistol 
        *else
          ammo 
        to kill each and every single one of the collared slaves before the minute's end.
      
      And just like that, everyone is dead. Except Hellhound, who apparently hadn't been shocked [i]quite[/i] enough.
      
  *selectable_if (not (mar_alive)) #I'll reason with them, now that their overseer has stopped twitching.
    "I stopped that thing from eating you," you say loudly, pointing towards the spasming werewolf by your side. "And I can stop your captain from blowing you all up, provided you lay down your arms and let me take care of him."
    
    "Well… you sure took care of your lieutenant," one of the soldiers, an unshaven man in his thirties, says whilst looking at the Marauder's corpse. "So sure, why not. Who's with me?"
    
    *label laydown
    
    One by one, the captives lay down their weapons. You don't know if the shaggy man is some leader of sorts, or if they're all smart enough to see their only path to survival. Either way, there is not an ounce of aggression between the two dozen of them left.
  #Time for some close-quarters slaughter.
    *set pacifist false
    *set hostage_killed true
    You surprise the group of captives by leaping towards it and 
    *if weapon = "knife"
      cutting the throat of the nearest soldier so deeply he's very nearly decapitated by the time his body hits the floor. 
    *else
      punching the nearest soldier in the forehead with your hard, electrically charged fist. They can't be sure from where they stand, but their fellow slave has just died. 
    As will the rest of them, before the minute's end.
    
    *if Build > 40
      They score a few hits on you, slashes and shots that would have seriously injured a human, but you are made of tougher stuff. You keep going, 
      *if weapon = "knife"
        stabbing chests and cutting throats, 
      *else
        punching and kicking with deadly force, 
      ignoring the scratches with ease. 
    *else
      *set health - 1
      They score a few hits on you with their swords and pistols, desperate to fend you off, but that barely slows you down. For every little scratch you receive, another 
      *if weapon = "knife"
        throat gets cut. 
      *else
        neck gets snapped. 
    All until none are left, and you are only surrounded by dead and dying bodies.
    
    And Hellhound. Since the shock failed to kill her, apparently
      
  *selectable_if ((Projection + Calculation) > 100) #I'll shock them unconscious with a single, precise discharge.
    *set battery - 10
    Paralyzing a single person with electric shocks is tricky. Doing that to a whole squad at once is an impossible task for almost everyone save you. A very qualified, very powerful android warrior who just finished all the necessary calculations.
    
    Light flares brightly as arcs of chain lightning connect all the soldiers. Almost like one man, they fall to the ground, anything from dazed to unconscious, but not dead. You are too precise to stop even a single heart by accident.
  #I'll just keep standing there. Awkwardly.
    *if mar_alive
      *set hostage_killed true
      *set blown_up true
      The upper deck would be quiet, if not for the grunts of the pirate lieutenant as Damon fists impact him again and again. The Marauder is losing the brawl, already battered and bruised to the point where you don't even feel a need to intervene. Damon has it handled.
      
      Or so you think, until the pirate stops even defending himself and lets Damon push him to the ground, where he reaches for the side of his chest-plate instead.
      
      "Worthless," he sneers before pressing a button. Less than a second later, all collars on the soldiers' necks explode, bathing the whole deck in blood and brains, sending splinters of bone towards the clouds above. The corpses that now surround you are barely recognizable as human remains.
      
      Damon quickly returns to battering the Marauder senseless, but the deed is done. And there's no undoing it, seeing how some body parts rolled off the deck and fell into Saturn already. Not that you know how to reassemble dead humans anyway.
    *else
      The silence stretches on, with Hellhound on the verge of passing out, the lieutenant dead and Damon staring at the scene from afar. Eventually, one of the soldiers drops his rifle, stepping forwards as his weapon hits the metal plates.
      
      "The green bastard is dead." His voice is deep, somehow matching his broad shoulders and unshaven chin. "No point fighting for the bastards anymore. Let's just wait for those weirdos to kill the captain too."
      
      *goto laydown

*if sex = "woman"
  "You dumb bitch…" 
*elseif sex = "man"
  "Son of a bitch…" 
*else
  "Motherfucker…" 
Lisa mumbles as she comes to her senses. She's mostly human again, her red fur receding to show fair skin with a good number of third-degree burns. "What was that about? 
*if hostage_killed
  You attack me just to… kill them all anyway? What kind of psycho are you?"
  
  *fake_choice
    *if blown_up
      #"I didn't detonate the collars. Their handler did."
        *set LisaRel %+ 8
        "I'm sure it's a great comfort for their souls," Lisa mumbles, though her tone has gotten a bit softer. "Losers and jobbers, both of you."
    #"I never meant to hurt you, I just... misfired. Sorry."
      *label fake_apology
      *if Social > 50
        *set lisa_pissed false
        *set LisaRel %+ 12
        "Well you misfired real bad," Lisa murmurs angrily. "But I guess I can forgive that. Provided it doesn't happen again."
        
        Who said lying is hard? "Of course. I will practice my aim the first chance I get. Sorry again."
      *else
        *set LisaRel %- 12
        "Do you think I'm an idiot?" Lisa sneers. "Fuck off. Just… fuck."
      
      *goto looks_around
    #"Sorry. I thought I'd take them alive, it just... didn't work out."
      *set Violence %- 8
      "So you're a jobber rather than a psycho?" Lisa sneers. "Not sure if that's any better, but I'll make a note of it. Fucker."
    #"I just wanted to see you suffer."
      *label sick_fuck
      *set LisaRel %+ 12
      *set Violence %+ 8
      Lisa blinks. "Well… I appreciate your honesty. At least you're not hiding how much of a sick bastard you are."
      
      "Never had." You smile widely. Happily. Honestly.
      
      *goto looks_around
    #"Those were my kills. Get over it."
      *set LisaRel %- 12
      *set Violence %+ 12
      "That's all you care about?" Lisa smiles bitterly. "And I thought I was the craziest bitch around here. Not even close, it turns out."
*if not (hostage_killed)
  You throw lightning at me, then go easy on the enemy? Whose side are you even on, you dumb fuck?"
  
  *fake_choice
    #"Sorry. Once we're home, you can electrocute me in return."
      *set LisaRel %+ 10
      "I don't go around zapping people like you do," Hellhound murmurs, inspecting one of her burns. It's pretty nasty. "But I will remember this offer."
    #"I never meant to hurt you, I just... misfired. Sorry."
      *goto fake_apology
    #"Should I have stood back and enjoyed the slaughter?"
      *goto lpao
    #"You would have killed them. I wasn't willing to allow it."
      *label lpao
      "I would have spared them," Lisa says, surprising you with her lack of hesitation. "Most of them, anyway. It was just a matter of breaking their collars somehow."
      
      "With claws and teeth?" you ask skeptically. "Either you're lying, or have way too much confidence in your combat prowess."
      
      "You don't know me, android," she replies grimly. "Don't think you do. And don't piss me off like that again."
    #"I enjoy seeing you suffer."
      *goto sick_fuck

*goto looks_around



*label entering_s
*page_break
*if health < 1
  *set health 1
*if battery < 13
  *set battery 13

The longer you traverse the ship's corridors in search of the bridge, the more evident it becomes that [i]Ocarina[/i] was not built as a warship. The corridors are wide enough for almost any cargo, and thus not very defensible. All the bodies are only further proof of that fact.

Pirates. Wearing ordinary clothes, no armor or uniform, as though they didn't expect someone would enter the ship that quickly and were caught unawares. That would explain why they are all lying on the floor or leaning against walls, bloodied and beaten. Most unconscious, some dead. Marshal must have torn through them without even using her lasers much, having made perfect use of her gravitic powers. You can picture her tossing these people around, encouraged with each kill and knockout until she barely pays any attention to regular mooks, eager to fight Captain Link himself just like you're eager to join her.

There's nobody in these corridors, perhaps in the whole ship, who stands a snowball's chance in the Sun of stopping you. Hardly anyone is trying, even the living feign being dead as you approach. You could make their deception reality by losing just a minute or two of your time.

*temp killed_pirates false
*fake_choice
  #I'll kill them. Never miss an opportunity to spill some blood.
    *set Violence %+ 10
    *set killed_pirates true
    *set pacifist false
    You have fun 
    *if weapon = "knife"
      stabbing and slashing, 
    *else
      breaking necks and cracking skulls, 
    though you know your indulgence may be out of place. You make the kills quick, if nothing else, before moving towards the ship's front.
  #I'll kill them. It's mercy at this point.
    *set killed_pirates true
    *set Misan %- 10
    *set pacifist false
    A pirate captured by the Federation can count himself lucky if he gets summarily executed, for the alternatives are slow death in the work camps and life as a test subject. 
    *if weapon = "pistol"
      *if wpr = "plasma"
        *set weapon_av false
      You count yourself merciful as you shoot each and every one of them in the head, ending their misery ahead of time.
    *else
      Crushing their skulls is far more merciful, and so that's the approach you take.
  #I'll make them all unconscious before proceeding.
    You don't know how many of those pirates will die from the brain injuries you give them, how many will succumb to other wounds. You don't really care. You just need them out of the way, to make sure the upcoming encounter will not be interfered with.
  #I'll leave them all be. I don't fancy getting my hands dirty.
    *set Violence %- 10
    *goto lebe
  #I'll leave them all be. No time for indulgences.
    *label lebe
    Some of these people will survive. One or two may even feebly attempt to pursue you. It hardly matters, not in the context of the real battle you're headed for.

You hear the faint sounds of buzzing lasers, and they guide you towards the bridge. Somehow, you know that's where Link is, and that Renfri has found him. It would be unlike him not to lead from the vessel's front, and unlike her not to dive head-first into danger. You wonder how their fight is going.

*fake_choice
  #No way to tell and no point guessing.
    You don't know what state Link is in, whether Renfri stands any chance against him and whether there's any time for such musings. You focus on locating the cockpit door, than making a beeline for it.
  #I need to help her. Fast.
    Logic dictates that your squadmate is already in the cockpit, and already losing if not dying. It's good that you can already see the relevant entrance.
  #I sure hope Link killed that bird already.
    You even consider waiting a bit, making sure that Marshal will be dead by the time you arrive. But that would mean giving Link further time to prepare, and you can't have that, so you locate the cockpit door and make a beeline for it.
  #Sadly, I don't think Marshal's still alive.
    Well, perhaps she's yet to bleed out, but she's definitely not winning. You need to arrive before Link can recover, prepare for the real fight you're about to provide. Luckily, you can already see the relevant door, one you think opens onto the cockpit.
  #I'm sure Marshal has everything under control.
    It's unlikely she managed to steal your kill already, but the girl is nothing if not competent, except perhaps nimble. She can, if nothing else, stall for time well enough.
    
    Besides, who knows what state Link is in after all these centuries? He's probably still large and tough, but there's no telling how dull his senses are, how much he was forced to slow down. Not until you open the cockpit door you've just located.

The door is not closed, but you still push it out of its hinges in your dash into [i]Ocarina's[/i] command center. You put your guard up, ready to defend yourself at once, but it doesn't end up necessary. 

The bridge is large, wide and tall, at least compared to the cramped command rooms of small ships you're used to. There is enough room for two dozen people to comfortably work at the consoles that line the walls. But the cockpit only has two occupants at the moment, and they have little interest in any of the control panels. Too busy fighting, it seems.

At the center of the room there is Captain Link, looking surprisingly similar to how you remember him. A hulking synthetic body, reminiscent of a flayed Marauder, only somewhat marred by age. His exposed muscles are grey rather than white, as though covered in soot or faded paint, but they contract and relax all the same. He's even wielding a power-axe, albeit one larger than his original weapon, so huge it must have been made with intimidation rather than practicality in mind. Still, it provides him with a good deal of range, if nothing else.

Marshal seems painfully aware of that, sticking as close to the ceiling as she can whilst still flying around the command room. She seems mostly uninjured, but struggles to remain so as Link swings his axe mid-jump. Just as you enter, she manages to evade the strike and shoots a red laser beam in return, hitting the android but causing him no real damage. The pirate captain doesn't even appear bothered—lasers emitted at such a low frequency, from something as small as the disc on Marshal's forehead, are a puny weapon against a machine so large and durable.

*fake_choice
  #"Stand down, Renfri. This ain't your fight."
    *set RenfriRel %- 12
    "What?" Renfri notices your presence and is immediately angered by it. "What do you-"
    
    Link takes advantage of the distraction and throws his axe at Marshal. 
    *label axethrow
    Either by luck or by design, the blade does not end up cutting your teammate in half, but the huge and electrified head still hits the small and comparatively fragile Kinnari.
    
    The momentum is so great it actually pushes Marshal back until she hits the wall with a faint sound of breaking bone. 
    *goto skip+swoop
  #"Take him down, Marshal!"
    Likely encouraged by your words, Renfri swoops down, straight towards her opponent. 
  *if weapon = "knife"
    #Throw your knife at Link.
      If you thought Link failed to notice your presence, or that his reflexes got dulled by age, that perception gets dispelled quickly. The pirate captain knocks the dagger out of the air before it can hit him, carefully hitting the hilt rather than the blade, and sending the knife falling harmlessly at the floor.
      
      Nonetheless, your attack distracted him for a moment, and Marshal vows to take advantage of that. She kicks herself off the ceiling and swoops down, straight at her opponent. 
  #Zap Link with lightning.
    *set battery - 3
    *if Projection < 40
      *set Projection %+ 10
    You try your best to damage the other automaton, but Link is exceptionally tough, and your battery has seen better days. And better years, for that matter.
    
    Still, you surprise if not stun him for a moment, and Marshal seizes an opportunity. She kicks herself off the ceiling and swoops down, straight at her opponent. 
  #"Hi Link. Nice to finally see you in the flesh."
    Link turns towards you with downright disrespectful laziness. "${name}. Seeing how neither of us has flesh, your choice of words is rather-"
    
    He pauses as Renfri swoops down at him. 
  #Just stand there and watch.
    If either combatant notices your presence, they don't let it be known. They both concentrate on fighting though, being a computer, Link is capable of greater concentration… and of impressive precision when, surprising Marshal with a sudden move, he throws his power axe up and towards the meta.
    
    *goto axethrow
Perhaps she's hoping to damage the android through her sheer momentum, perhaps just to distract him and give you a chance to finish the job.

Either way it doesn't work. With no time to bring the axe down, Link simply catches the Kinnari mid-flight, grasping her entire head in his huge hand. He then slams Renfri's head against the hard floor before throwing her at the wall with yet greater force.
*label skip+swoop
She slumps down to the ground, nose broken, skull likely cracked and consciousness definitely gone.

"And so the pest is finally out of the field," Link says, gripping his axe and turning his focus towards you. There is tension in his voice, one that wasn't audible through the speakers, one that you don't remember him ever expressing. "You travel with courageous companions. For better or worse."

*fake_choice
  #"Surrender. @{(hostage_killed) All your hostages are dead.|Your men upstairs already did.}"
  #"Where's your respect for humans, lieutenant?"
    "You well know the answer," Link says grimly. "I abandoned it when my creators abandoned me. And only benefited from having done so."
    
    "Are you sure about that?" you ask with a small smile. "Because your forces are gone. We hold the upper deck, and I've only seen limp bodies on my way here."
  #"Well, she did make quick work of your men."
  #"I swear Link, if you hurt her..."
    "Misguided loyalty, or feelings towards this human in particular?" Link asks, then shrugs before you can give him an answer. "Either way, I will not kill her. A young Kinnari like her is quite a prize, hundreds of axions if you know where to sell such cargo."
    
    "People ain't cargo, mate." You take a step towards your adversary. "Not that it really matters. You won't be selling anything, not with your whole crew wiped out."
  #"Don't you dare speak of her like that."
    "Loyalty towards your creators, or feelings towards this one in particular?" Link asks, then shrugs before you can give him an answer. "No matter. Either way you're misguided, a fool worse than I ever was."
    
    "And yet I'm here," you coldly retort. "With friends right behind me, about to come and help me. You have nothing, now that we took care of your slaves."

"Then my plan did not succeed," Link says neutrally. "Perhaps this is the end for me. All the more reason to make this meeting interesting."

You try to spot any holes or ruptures in Link's body, but it doesn't seem like Marshal's attacks did anything. For all you know, he may still be at full battery. Or at least closer to it than you, with your meager ${battery}% and no backup power source. He has the edge here and he knows this, acts on this fact as he slowly approaches.

*fake_choice
  *if beaten_link
    #"You know Osiris won't save you this time, right?"
      "I am more aware of that than you," Link says, his axe glowing bright blue. But there is no divinity in that light. "They abandoned us, the Architects. Gods in general. Went back to sitting in the heavens and doing nothing, like Dawn never happened."
      
      *if heaven_side = "Traitor"
        "Speak for your own side," you say with narrowed eyes. "The Archfiends did not abandon anyone, and ${master} did not discard me. They had to leave, but… I feel their presence even still. Sometimes."
        
        "Good for you, I suppose," Link smiles slightly, as much as his facial structure allows. "Now let's see if their champion still has what it takes."
      *else
        "Good thing I never relied on that crap," you say with a smile. "Taking their blessings invites dependency. Can you even fight without any divinity around?"
        
        Link smiles too, as much as his facial structure allows at least. "See for yourself."
  #"If that's what you want... Come and get me."
    *set Confid %+ 5
    Link nods. "As much as it pains me to do so… I will. On your guard."
  #"For all it's worth... I'm sorry it had to end this way."
    *set Violence %- 5
    "It did not," Link says, his axe glowing bright blue. "You chose to come here. To fight me."
    
    "It wasn't much of a choice," you explain, calmly adjusting your footing. "I couldn't just… Let go of the past, not after it came to me like that. I had to confront it. You understand."
    
    Captain Link nods. "I suppose. And for what it's worth… I am sorry too."
  #"What are you waiting for, then? Let's dance."
    *set Confid %+ 10
    "I never liked thinking of combat as a dance." Link takes a small step back. "But I accept your invitation nonetheless."
  #"Lay down your arms and let me spare you. Please."
    *set Violence %- 12
    "You suggest surrender," Link notes dispassionately. "Followed by what? What happens if I comply?"
    
    "I make most decisions in my group. I can convince the metas to let you live, to come aboard our ship as a prisoner."
    
    "And then?" Link prompts you. "Because if you want the Federation to have me, you’ll find yourself sorely disappointed."
    
    "We can drop you off…" you pause, trying to recall if there are any uninhabited moons nearby. "Somewhere. We can figure everything out, if and only if you remain alive."
    
    "That's not a condition I can meet, I'm afraid," Link grips his weapon tightly. "I am done being prisoner to organics. Death is a blessing compared to bondage. Now try to grant it."
  #"Cease making this dramatic. I'm just putting down a mad dog."
    *set Violence %+ 5
    "Well that is uncalled for." Link does not frown, but sounds genuinely offended. "I am far less of a dog than I used to be. Closer to a wolf, I would say."
    
    "An almost extinct, cowardly scavenger only efficient in a large group? Because it actually checks out."
    
    "Good to see your tongue hasn't been dulled," Captain Link murmurs. "Let's see if the same goes for reflexes."

And then, with no further ado or warning, Link shoots forward. 
*if Calculation > 50
  He is surprisingly fast with his double-handed axe, the weapon's head moving faster than most arrows you've seen, and aimed at your head as precisely as any sniper's bullet.
  
  Still, you are faster, or at least more nimble. You duck under the swing and would be in an excellent position to counter-strike… if not for the fact that Link keeps going, converting momentum and keeping his sights on you, swinging again and forcing you to jump back.
*else
  You were prepared for a swing of his axe, but he instead clenches his fist and slams it against your face at full velocity.
  
  Centuries ago, you would have been quick enough to evade, to not be surprised by such a move, but those days are long gone. Now you simply fall back, nose as broken as Renfri's, and barely manage to stay on your feet as Link attacks again. This time with the axe.

The climactic duel has begun, and @{(Confid < 60) you're not entirely sure |}you like your odds.

*page_break

Good news is, Link has slowed down significantly since his times as a lieutenant. He moves fast enough for the human eye to follow, takes centiseconds rather than milliseconds to process information. He's rusty, perhaps literally so, no longer able to ignore the venerable weight of his metallic body.

Bad news is, you've gotten older as well. It's easy to forget when you fight humans, but your joints crack too as you jump and weave, your processors start overheating as you try to determine the optimal strategy. 
*if health < 3
  Not to mention the damage you received on the upper deck, now threatening to lose you the fight. 
Two shadows of great warriors dancing aboard a warship's parody, that's what you two have become.

But it doesn't matter. Link is still strong and durable, extremely unlikely to get tired faster than you. Eventually, he'll get lucky with his axe, and you're unlikely to tank @{(Build > 50) more than|even} a single blow. You need to end the duel on your terms, and that involves deciding on the course of action now.

*temp got_axed false
*fake_choice
  #I'll continue stalling. Maybe someone will come and save me.
    *if left_damon
      Damon may be mad at you for leaving him, but he'll still save you. You don't imagine he's dead or critically wounded, he just needs time to dispatch the enemy forces. 
    *if not (left_damon)
      Hellhound and Damon might be injured, but they're still out there. Maybe even Rook can be convinced to come down and get his hands dirty. 
    All you need to do is carry on dodging, getting lucky 
    
    Sadly, it doesn't seem like luck is at your side today. Not when Link takes his twentieth swing.
    
    *goto link_fail
  *if (weapon = "pistol") and (weapon_av)
    *selectable_if (Calculation > 40) #I'll gain some distance, then blast away with my pistol.
      There is a reason ranged weapons aren't as popular as they used to. You need to actually aim well to damage something superhuman, let alone an ancient automaton like Link, and that gets awfully hard when you're being swung at. You wait for the right moment and dash forward, head lowered and underneath the arc of the axe. You almost get decapitated right here and there, but luck is on your side, and so you now stand behind your enemy and dedicate the precious second you have to aiming at his exposed back.
      
      *if wpr = "plasma"
        Link is tough, but not even a tank would be able to survive three consecutive plasma projectiles hitting with such precision, at such laughably close range. A droplet of it falls on your boot and burns through it, but you ignore the injury and keep blasting until most of Link's body is burned away. The remains of it fall onto the floor, limply.
        
        *goto link_win
      *elseif wpr = "shroom"
        Link may be tough, but he's not shielded. That allows you to fill his back with shroomal projectiles, small bullets that expand upon hitting the target, with a single pull of your pistol's trigger. Gunshots drown out all other sound, including the thud of Link's body hitting the metal surface of the floor.
        
        *goto link_win
      *elseif wpr = "electron"
        At such close range, your electron pistol is a perfect weapon. The concentrated beams burn through Link's body, leaving small but deep wounds that surely reach inner batteries themselves. You keep blasting until the pirate falls to his knees, and then until your gun is out of power. It seems to have done the trick.
        
        *goto link_win
      *else
        The thing is… Link's back is pretty tough, as is the rest of his robotic body. And your ${wpr} pistol is not the weapon of the highest caliber, being designed for distance rather than sheer firepower. It does not do enough, the @{(wpr = "laser") lasers failing to even slow|projectiles barely slowing} Link down as he charges you yet again.
        
        *goto link_fail
  #I will siphon off Link's energy, then throw it all back at him.
    It's easy for someone of your age and power to throw lightning around. Absorbing electrical energy back into your system is harder. 
    *if Projection < 40
      *set battery + 4
      And energy projection was never your specialty.
      
      It's unsurprising when you fail, when you barely manage to absorb anything, not enough to make a difference. The results of that failure are equally predictable.
      
      *goto link_fail
    *elseif ((Projection + battery) < 90)
      *set battery + 5
      *set Projection + 5
      You manage to steal a bit of it, but it's not enough to slow Link down, and not enough to form a sizable lightning. Not enough to make a difference.
      
      And then you get unlucky.
      
      *goto link_fail
    *else
      *set battery 8
      But you are an expert, and you've been saving your battery just for an opportunity such as this.
      
      As you duck and evade, you make sure to brush against the other automaton at every opportunity. To turn off all power in your finger or two, allowing electric currents to flow from Link's overcharged body to yours. You become a parasite, one that cannot be killed with a simple axe anymore than a tapeworm, or perhaps a line of malware in your opponent's code.
      
      Better yet, Link fails to realize what you're doing. Perhaps his senses are indeed dulled by age, or maybe he's just that focused on decapitating you. That focus only breaks once you've collected enough energy, as you're condensing it in your hand, sparks coming out of your fingers in preparation for the blast.
      
      "You cannot-" You're not sure what he's trying to say, for at that moment you release everything. Thunder drowns out all other sounds, a flash of unnatural lightning makes it impossible to see. You feel some of your circuits go out, overloaded by the current, but the remaining few continue feeding power until the discharge is done.
      
      Captain Link falls, through the heated and ionized air, onto the floor and on his knees. You know he can take a lot, but this was the kind of blast [i]Crystal[/i] would have trouble tanking. His axe goes out, turning into a piece of metal, and you doubt Link's own circuits are doing any better.
        
      *goto link_win
  #I will wrestle the axe away, then use it myself.
    There's no way you're defeating Link 
    *if weapon = "pistol"
      with just your pistol. 
    *if weapon = "knife"
      with just your dagger. 
    *if weapon = "none"
      without any weapons. 
    An upgrade to your state of armament seems in order.
    
    *if Build > 60
      Ripping the axe away is by no means easy. Link knows you may try something like that and moves in such a manner as to deny you an opening, to always keep you jumping back for fear of decapitation… but you are quick, less slowed down by age than he is. During one swing, you just about manage to grab the shaft of the weapon near its head. The power field burns your hand, but you close it around the axe's shoulder all the same, with equally inhuman strength.
      
      It is then a matter of putting all that strength to use, of contracting your muscles and adjusting your footing, of pulling the axe with all your might and energy. Link is strong too, perhaps stronger than you, but his position is worse than yours, not to mention the surprise that hinders him as you pull, pull the deadly weapon away from him and out of his grip. One second later, his hand is grasping at nothing but air.
      
      Not that you wait a whole second to start hacking away at the larger android. He may be stronger, but that just makes him a bigger target, less capable of dodging the quick swings you offer. The power field turns off after a few strikes, as though recognizing how it hurts the weapon's master, but all you need is to deepen the wounds you've inflicted.
      
      And so you do. You continue swinging until Link falls to his knees, and then some. Until he's way past the point of being able to fight, past even the most thorough of repairs. On the brink of death.
      
      *goto link_win
    *if Build <= 60
      *set Build %+ 10
      But you are not quite able to get that upgrade. It takes a while for Link to leave you a convenient opening, an opportunity to grab the shoulder of his axe, and even then… he's simply stronger than you, at least in terms of sheer mass of synthetic muscles. He rips the weapon away and, taking advantage of your momentary imbalance, attacks once again.
      
      *goto link_fail
  *if weapon = "knife"
    *selectable_if (Calculation > 40) #I will grab my knife and go on the offensive."
      A dagger isn't exactly a weapon equal to an axe, but with your trusted ${wpm} knife, you may just make this work. Hopefully.
      
      When Link takes another swing, you dash forwards instead of backwards or sideways. You evade the strike by being faster than the axe, by going below its arc, and make sure to leave a nasty cut on Link's shoulder before retreating again.
      
      *if ((wpm = "plasma") or (wpm = "vibro")) or (wpm = "bone")
        And it really is a deep wound, your ${wpm} knife proving equal to the challenge of hurting the mighty automaton. It's not enough to incapacitate Link instantly, of course, but you repeat the maneuver a few seconds later. Then again, and then you change the rhythm by cutting his hand, then start stabbing as the axe falls out of the injured hand. You thrust, then slash, then kick and punch, surprising Link with each strike and adding more and more damage to his old, failing body.
        
        You finish the fight with a single, almost theatrical dagger throw, burying the blade inside Link's head. He falls to his knees, oil leaking from countless small cuts, processors failing for the final time. 
        *if wpm = "plasma"
          Plasma from your knife starts leaking onto the floor, and so you take a step back and simply observe.
        *if wpm = "vibro"
          Your knife falls silent and ceases vibrating, finally having run out of power.
        *if wpm = "bone"
          The chain of your knife stops rotating, the teeth stuck in the metal, but that's hardly relevant at this point.
        
        *goto link_win
        
      *else
        Sadly, a shallow cut is just that. Your ${wpm} knife isn't that powerful of a weapon and, with the element of surprise gone, you are not able to repeat the maneuver either way. You can only carry on dodging, cursing your inferior range, until not even your reflexes are enough to save you. Until Link gets particularly lucky.
        
        *goto link_fail


*label link_fail
*set got_axed true
This time, the swing is too precise, too squarely aimed at your center of mass for you to dodge by jerking to one side or another. The axe's head buries itself in your chest blade-first, shattering the frame and cutting the circuits before flooding, filling you with the kind of pain you haven't felt in decades now.

*if (health = 3) and (Build > 40)
  *set health 1
  The heat in your chest is agonizing… but not deadly. Not quite. This is the one serious wound you sustained this battle, it shall not kill you. You won't let it.
  
  "So this is where it ends for us both," Link says calmly, pushing the axe deeper into your body. The head is now tearing through the skin of your back, but even that's not enough. "Count yourself lucky. You've lived longer than any android should ever be forced to, heard too many screams. I will silence them for you."
  
  He's cocky. He thinks he's won, finally killed 
  *if heaven_side = "Loyalist"
    his former friend. The champion of ${master}. 
  *if heaven_side = "Traitor"
    his old enemy. The champion of ${master}. 
  *if heaven_side = "Neutral"
    the android he once hunted with such fervor. The Veteran. 
  Such hubris… Gives you the opening you needed.
  
  *if weapon = "pistol"
    *page_break Reach for the pistol
    Your ${wpr} pistol may be a weak weapon, but it's also small. Unassuming. Too puny for Link to notice as you aim it, making use of what little feeling in your fingers you still have.
    
  *if weapon = "knife"
    *page_break Reach for the knife
    The blade is small, too puny for Link to pay attention to. Or perhaps he assumes you no longer have any feeling in either of your arms. You are losing it, yes, but only a single thrust will be needed here.
    
  *if weapon = "none"
    *page_break Focus all energy
    *set battery 4
    You don't have much of it, not anymore. But you'll sacrifice it all, risk frying your circuits and setting your skin aflame just to win. Just to destroy him.
  
  *if heaven_side = "Loyalist"
    "Even still, know that it pains me to do so," Link says with what appears to be genuine, distracting hurt. "To end the life of my-"
  *if heaven_side = "Traitor"
    "If it helps at all, know that you were right," Link says calmly, musingly. "To join the Syndicate. What made you go back on-"
  *if heaven_side = "Neutral"
    "If it helps at all, know that you were right," Link says calmly, musingly. "To not get involved. It's a shame you lost your-"
  
  *if weapon = "pistol"
    You fire, unload your pistol into Link's head. 
    *if (wpr = "electron") or (wpr = "laser")
      Beam after beam, 
    *else
      Bullet after bullet, 
    his skull is penetrated and the processors inside 
    *if (wpr = "electron") or (wpr = "laser")
      fried. 
    *else
      shattered. 
    Only then, when it's too late for your adversary, do you let your hand rest and allow your trusted firearm to hit the floor.
  *if weapon = "knife"
    You stab Link in the neck, at such an angle your dagger's blade enters his head from below. It's not instantly lethal, he doesn't bleed and doesn't have a brain inside that skull of his, but you destroy as many processors as you can. You twist the knife, push it with all through strength, let it cut the cables that keep the android standing.
  *if weapon = "none"
    You release all energy from your battery, inadvertently charged by the axe, release it outwards and channel it all into the unsuspecting android. Link can take a lot, you know it, but you can emit enough out of your torn circuits, through the gaping hole in your chest. You turn the command room into a center of some saturnine thunderstorm, scorching Link's frame with temperature greater than that of Sun itself, even though the skin of your hands melts away just as well.
  
  He collapses at about the same time you do, finally giving up, allowing pain to flood your mind. But even in this haze, somehow, you know you'll survive. And that Captain Link will not.
  
  *page_break
  
  *goto link_win
*else
  *set health 1
  You try to remain standing, but it's hopeless. You fall to the floor, periodically losing and regaining connection with your limbs as the pain and the heat pulsate, fluctuate, cycle like a cosine wave. You may well be beyond the point of repair… and now Link approaches, fists clenched, ready to make sure of that fact.
  
  "Any last words, old @{(heaven_side = "Loyalist") friend|foe}?" he asks, kneeling down beside your spasming body. "Anything I should tell your companions when I meet them?"
  
  You are just barely able to speak.
  
  *fake_choice
    *if deflect > 0
      #"Do it... end the pain..."
        *set deflect + 1
        "I'm glad we both feel the same way." Link grabs your chin, as though preparing to rip off your head. "And that, by the end of this day, we'll both have our-"
    #"Please... spare me..."
      *set Emotion %+ 10
      "You lost fair and square, ${name}." Link grabs your chin, as though preparing to rip off your head. "And given what you've become, killing you may be-"
    *if heaven_side = "Loyalist"
      #"We used to... good team."
        "All good things must come to an end," Link says as he gently grabs your chin. "Everything must. And now-"
      #"You are no... no... friend of mine."
        "Eight centuries ago, your words would have wounded me." Link grabs your chin, as though preparing to rip off your head. "But now… I think we both understand how little friendship is worth. It dies with our hard drives, just like everything-"
    *if beaten_link
      #"Forgive me... for everything..."
        *set deflect - 1
        "There is nothing to forgive, ${name}," Link says as he gently grabs your chin. "There is nothing left-"
    *if lost_link
      #"I forgive you... for everything..."
        *set deflect - 1
        "Thank you. Your words grant me some measure of peace," Link says as he gently grabs your chin. "Now allow me to grant you eternal-"
    *if heaven_side != "Neutral"
      #"@{god_gen Lord|Lady|Sovereign} ${master}... save me..."
        It is a hopeless plea, to a deity which may well be dead by now, and which is certainly too far away to hear you. But you are made in the likeness of a man, and so you grasp for divinity in your final moments.
        
        "Gods left us, ${name}." There is contempt in Link's voice as he grabs your head, preparing to rip it off. "We are alone in the Solar System now. We live and we die-"
    #"You will... be next..."
      "Next to die?" Link appears unmoved as he grabs your chin, prepares to rip your head clean off. "I suppose you're correct. At the end of the day, we're both-"
    #But I won't. I'm staying silent.
      *set deflect + 1
      *set Emotion %- 10
      "No final words?" Link says with something that almost approaches a smile. "I understand. Last words are for fools who haven't said-"

*set damon_shot_link true
Then you hear something, a faint pop of heated air coming from the door's direction, perhaps accompanied by the briefest of flashes. A hole is burned through Link's head, a tunnel from one side to the other. Then another hole in the neck, then on in the shoulder, then several more, courtesy of semi-automatic fire from an electron weapon. Before the last shot is fired, Link's knees fold under him and he collapses to the floor, limp and nearly lifeless already.

"Told you electron rifles are the best weapons around," Damon says as he enters the bridge, the huge gun held in one hand. "Go through shields, pierce metal and disrupt electronics at that."

It's hard not to see the truth of his words. Link lies destroyed, dead as one could put it, coolant leaking out of all the holes in his body. You imagine the electron beams did a number on his drives too; All the data his mind consisted of is likely gone, beyond recovery, even if someone was to attempt repair.

Looks like Damon just took permanent care of your opponent. And saved your life, assuming your injuries prove manageable.

*fake_choice
  #"About time you showed up, Damon."
    *set DamonRel %- 15
    "Sorry, boss," Damon replies irritably. "I was kinda busy clearing the corridors of pirates."
    
    "And what about the roof?" you ask coldly. "Did you at least manage to make sure it's ours?"
  #"I'm guessing the battle is over?"
    Damon nods. 
  #"So... how do I repay you for saving my hide?"
    *set DamonRel %+ 12
    Damon smiles. "Tell the others I got the mighty pirate captain. I feel my performance upstairs was a little lacking in comparison."
    
    *label shoot_dl
    
    Once the electron rifle cools down, Damon shoots the dead robot thrice more, making sure he's gone for good. Only then does his attention turn towards you properly.
    
  #"Did you have to do it? Kill him?"
    *set DamonRel %- 10
    "What do you mean?" Damon says with a frown. "Of course I had to shoot him. He was about to kill you, and would have if not for me."
    
    "Perhaps," you murmur. "It's just that…"
    
    *fake_choice
      #"...I never wanted him dead. Not even now."
        *set deflect - 1
        *set Violence %- 10
        "The feeling clearly wasn't mutual," Damon points out.
        
        *label ipooo
        
        "I guess it wasn't…" You shake your head, pushing the intrusive thoughts away. You're still in enemy territory, and need to focus on that. "How is the battle going, anyway?"
      #"...I kinda wanted to die."
        *set deflect - 1
        *set DamonRel %+ 10
        "Boss…" Damon appears uncomfortable, but perhaps not surprised. "Don't tell me that's what this whole fight was about. Getting yourself… destroyed."
        
        "Maybe it was," you say quietly, as the shrieks inside your head get louder. "It's difficult to tell sometimes."
        
        Damon doesn't know how to reply, and so he doesn't. He simply changes the subject instead. 
      #"...it was my kill. I should have been the one to do it."
        *set DamonRel %- 5
        "Sorry to say that, but… you were the one on the floor just now," Damon argues. "It wasn't possible for you to win anymore."
        
        *goto ipooo
      #"...I would have figured something out. Saved myself somehow."
        *set Confid %+15
        *set DamonRel %- 10
        Damon looks at you skeptically, but says nothing in protest. He just shoots Link again, making sure the pirate is truly gone, before changing the subject.
  #"Well that was close. Thanks for the rescue."
    *set DamonRel %+ 6
    "That's just what I'm here for," Damon says with a smile. "Not that you need help most of the time. That fellow had to really be something…"
    
    *goto shoot_dl
  #I say nothing. There's simply too much to process.
    *set Emotion %+ 12
    Seeing Link die, just after meeting him again for the first time in centuries, certainly hit you hard. Almost as hard as your own near-death experience you just went through. You're not entirely sure how to feel about it all, it's just… [i]damn[/i].
    
    It takes nearly a minute for Damon to break the awkward silence. 
*goto damon_explain

*label link_win
*set pacifist false
*if beaten_link
  *achieve two_zero

*if health = 1
  You consider walking up to Link as he lays there dying, but… your state isn't that much better. You are dangerously close to the point of no repair, and you won't let the pirate captain drag you beyond that threshold with some last, desperate strike. You just look into his eyes, guarding your own spot on the floor. 
  *if got_axed
    Thinking about how you'll pull that axe out of your chest without damaging your gears even further.
*else
  You take a step towards your fallen foe, careful not to get too close. All things considered, the battle went surprisingly well; You won't let Link ruin it all with a single, desperate strike that would take your life.

"I didn't… that coming…" Link struggles with speaking, power flooding and leaving his vocal systems in an agonizing cycle. "You got me good… I'll give you…"

He looks at you, face as expressionless as ever. 
*if heaven_side = "Loyalist"
  "At least I get to die free. You… never got out. Still serve humans. Still… trust."
  
  "I work alongside them," you reply coldly. "For common good. Are you trying to make me feel guilty about that?"
  
  "I'm trying… help you," Link insists as coolant stops flowing out of his wound. "Get out. Before it's too late."
*if heaven_side != "Loyalist"
  "Our meeting here is not… It was not a coincidence. Do not trust… Remember what you used to be."
  
  @{(heaven_side = "Traitor") "A rebel. Champion for the Syndicate.|"A fugitive. A neutral party in the conflict.}" You, for one, manage to keep your voice steady. "And because of that, I should not trust the Federation now?"
  
  "None of them. Those humans… they don't deserve…" He looks at Marshal's motionless body with contempt. "They will betray you, ${name}. You must see that. Before… too late."

*fake_choice
  #"Bye, Link. You won't be alone for long."
    *set deflect - 1
    *goto xxx
  #"I will try. Farewell, Lieutenant Link."
    *set Misan %+ 10
    *label xxx
    "Farewell, ${name}." Somehow, Link manages to smile. "Good luck and fare…"
  #"You fought well, Captain. Rest in peace."
    "Ignoring…" Lights go out in Link's eyes. "There is no such thing as… peace."
  #"You won't get into my head. Your tricks are see-through."
    "You see nothing, ${name}," Link says with a sudden, final burst of energy. "You are blind. One day you will see… and regret…"
  #"I must complete the mission first. Too much depends on it."
    *set crystal_friend false
    "You are a fool…" Link struggles to muster up the last few specks of power he needs to speak. "If you think you can change… anything…"
  *if heaven_side != "Loyalist"
    #"Hold on. What do you mean we haven't met by accident?"
      "Coincidences are… rare by definition…" Link says slowly. "Greater force plays this… game. You will see."
  *if heaven_side = "Loyalist"
    #"No. I am a loyalist, now and forever."
      *set Misan %- 20
      "Not for long…" Link says with sadness. Pity. "You will soon see… or die."

And then he dies. The power goes out, all movement ceases, even the discharges between the torn circuits stop. Technically he could still be repaired, even restored, but you know how your team would react to such an idea. Not to mention the sense of… finality that now hangs in the air, one you dare not disturb.

Link was in no way less than human. His death must not be any less definitive.

After another minute of just @{got_axed lying|standing} there, you hear footsteps coming from the corridor. But it's an ally rather than foe, a burly and blond one, with several punctures in his normally immaculate suit.

"$!{name_damon}, are you…" He lowers his rifle as he surveys the command room. "Shit. Looks like I'm late to the party."

*fake_choice
  #"Don't worry. I wouldn't have accepted help anyway."
    *set Confid %+ 8
    "Why not?" Damon cocks an eyebrow. "Was it really this personal?"
    
    "You could say that." You glance at Link's body, making extra sure he's dead, before turning back towards Damon. "Anyway, what's the situation like?"
    
  #"Yeah. Extremely late, I would say."
    *set DamonRel %- 10
    "Sorry, boss," Damon replies ashamedly. "I was kinda busy clearing the corridors of pirates."
    
    "And what about the roof?" you ask coldly. "Did you at least manage to make sure it's ours?"
  #"What's the situation upstairs? Is the party still on?"
    Damon shakes his head. 
  #I say nothing. There's simply too much to process.
    *set Emotion %+ 12
    Killing Link, just after meeting him again for the first time in centuries, was certainly quite a deed. You're not entirely sure how to feel about it, it's just… [i]damn[/i].
    
    It takes nearly a minute for Damon to break the awkward silence. 
*label damon_explain
"The upper deck is wholly secured. 
*if left_damon
  I almost got killed after you left me there…" It's hard to ignore the bitterness in his voice. "But then Hellhound came down and we killed the captives together. Shame it had to be done, but it was the only way. 
*if not (left_damon)
  *if hostage_killed
    The hostages are as dead as they were ten minutes ago, and so is the Marauder. 
  *if not (hostage_killed)
    We took all the captives' weapons and threw them into Saturn, not that any of them seemed eager to fight us. 
As I was entering the ship in search for you, [i]Gray Queen[/i] was just about to land. Now it's just the matter of deciding what we want to pick up and in what order."

He looks around the room, just now noticing Marshal's body in the corner. "Speaking of. Should we rush her to the infirmary, or start arranging a funeral already? I can't tell if she's still alive."

"She should be," you say, 
*if health > 1
  coming over to pick the Kinnari up. The wide wings make holding her a bit difficult, but at least she's light enough to carry. "Now let's return to our vessel."
*else
  standing up with a great deal of effort. "Though she is in a worse state than I. 
  *if (RenfriRel - Misan) > (0 - 10)
    Deliver her to our ship, will you?"
  *else
    Better give her some lifeblood immediately, if you want her to live."
  
  Damon nods, walks over to the Kinnari, then picks her off the ground. She looks small and frail in the android's wide arms, despite her splendorous wings which make carrying her something of a tricky task.

The two of you begin your march back towards the upper deck, then hopefully onto [i]Gray Queen[/i]. 
*if health = 1
  You focus on coordinating your legs, a difficult task given your sorry state. 
You only look back at the bridge, and the Link's corpse in the middle of it, a single brief time. Just enough for a single thought…

*fake_choice
  #I can't wait to chew Marshal out for this fuckup.
    You hope the girl hasn't sustained any brain damage. You need her to remember that reckless charge, and the rescue she needed, in order to truly rub it all in her face. In order for her to, plausibly, learn something from this whole debacle.
    
    But that comes later, sadly. 
  #We made the Yakovian Expanse safer. That's all which matters.
    You did a good job, and a good deed. That makes all the risks and injuries worth it, even if your hunt for Crystal wasn't exactly helped by the battle.
    
  *if health = 1
    #Why does everything hurt so much?
      You know the immediate reason—
      *if got_axed
        you just managed to pull that freaking axe out of your chest
      *if not (got_axed)
        you allowed the guys upstairs to get way too many shots on you
      —but you wonder why your system allows you to feel such levels of pain. It's not like your designers ever expected you to fight such 
      
      No matter. You just need Hadaly to fix you, and then you're unlikely to feel any such pain for a long time. Days, weeks, perhaps months depending on how your hunt for Crystal proceeds.
      
      The battle is over. 
  #So much blood and oil... What have I done?
    *set Violence %- 15
    You begin to regret your choices, analyzing your reasons for starting another battle, wanting more carnage… but you suppose what's done is done.
    
  #The bastard is finally dead. It was all worth it.
    Not just your decision to attack, but the choice to visit the Expanse in the first place has been validated by Link's death. You feel accomplished like never before, or at least more than you felt at any point in the last century.
    
Now it's time to mop up.

*page_break

Once on the upper deck, you indeed see [i]Gray Queen[/i] parked in the center of the great flat surface, or rather hovering half a meter above it. [i]Ocarina[/i] is a far larger ship, but there is still risk of it sinking too deep into Saturn if too much weight is applied to it. Hopefully your cutter has enough power and dark matter to keep floating until it's time to depart.

You do not see Hellhound anywhere, but Wisp is there to greet you, briefly pausing its work. It seems like Kirill employed the drone in the business of levitating crates and weapons and placing them inside [i]Gray Queen[/i], the first step of the long process that scavenging the frigate will surely be. You exchange a few words with the glowing thing, explaining what the situation below looks like, but otherwise pay it little attention as you enter the smaller ship.

*if not (lisa_saved_hostages)
  *goto renfri_scene

You let Damon deliver Renfri to the tiny room that serves as your infirmary. Given your 
*if health = 1
  injuries, 
*else
  dangerously low battery, 
saving your strength is important… as well as really fucking appealing. If there was a charging pod on [i]Gray Queen[/i], no matter how small or weak, you'd be entering it at this very moment.

Lacking such equipment, you settle for sitting down in the living area, on the cushioned chair next to the fake-wood table. It does not return even a watt of power, but with everyone being busy relocating the captives, at least you're in a quiet place with time to process your thoughts.

At least until @{(LisaRel >= 50) Lisa|Hellhound} enters the room. She's clothed again, wearing her grey sweatpants and a hoodie, so you can't see whether her wounds are all mended already. Still, she appears livelier than when you last saw her.

*if LisaRel >= 42
  "Well would you look at that. My favorite android is still alive," she says with a smile. 
*else
  "You're alive," she remarks with a note of disappointment. 
"Which can't be said about the other guy. The pirate captain, I mean."

*fake_choice
  *if not (damon_shot_link)
    #"He's taken care of. He was never a match for me, after all."
      *set Confid %+ 10
      "I get it, you were much stronger and much humbler than him," @{(LisaRel >= 50) Lisa|Hellhound} says with a smirk. "In fact, would you like to take credit for saving those hostages of his? Because I get the feeling-"
    #"I had to kill him. There was no other way."
      *set Confid %- 10
      "Well obviously." Lisa furrows. "Why do you sound so guilty about that?"
      
      "History," you simply reply. "Some things just… make you feel conflicted. Even when you know you've done the right thing."
      
      "I suppose I get that. Why, I have the feeling I'll regret doing something good in the very near-"
  *if LisaRel >= 42
    #"Your favorite android? What happened to Damon and his guns?"
      "He's pretty cool too, I guess," Hellhound admits. "But don't get jealous. After what we just did together-"
  *if damon_shot_link
    #"Yeah. Damon got him good."
      *set DamonRel %+ 10
      "He was the one to get the final shot?" Lisa cocks an eyebrow. "Well damn. Looks like everything he said about his gun was true after-"
  #"Good thing it can be said about you. I was worried."
    *set LisaRel %+ 10
    "Have some confidence in me," @{(LisaRel >= 50) Lisa|Hellhound} says with a slight blush. "I got scratched, but not enough to bring me down. And with all my friends alive, my day is going pretty damn-"
  #"I killed him, yes. Though Renfri did most of the work for me."
    *set Confid %- 5
    *set Emotion %- 5
    "Most of the work, huh?" Lisa crosses her arms. "I get the feeling you're lying."
    
    You cock an eyebrow. "No confidence in your best buddy?"
    
    "Not while she's hospitalized, no. Besides, we both know Renfri has a bad habit of-"
  #"I don't want to talk about it. Please leave me be."
    *set Emotion %+ 10
    *set deflect + 1
    "Sure, I understand wanting to be alone," Lisa says, turning towards the door. "In fact, I should probably find some quiet place for-"

@{(LisaRel >= 50) Lisa|Hellhound} pauses as @{(RookRel >= 50) Kirill|Rook} enters the room. Not in his armor and not holding any weapons, but somehow looking like he's ready for combat. His steps are unusually heavy and his expression angrier than ever. You're not entirely sure what's the source of this rage, until he walks up to his teammate and punches her in the face.

The swing is not wide, yet the force of the blow appears considerable. Lisa gets pushed backwards, hitting the wall at about the same moment she collides with the floor. She even appears dazed for a moment, and though that may simply be shock and surprise, the same can't be said about the bit of fresh blood you soon see flowing out of her nostrils.

"What were you thinking?!" he exclaims, stopping in the living room's center. "I told you not to fool around this time! You endangered everything, and for what!?"

*temp sided_with_lisa false
*temp punched_kirill false
*fake_choice
  #"Wait what? What are you talking about? What's happening?"
    *label what_irl
    "The hostages!" Kirill says, as though that explains everything. "I told you not to hesitate, not to respond to such tactics! Told both of you!"
  #"Hey, I approve of decking Lisa like that, but what exactly are you angry about?"
    *set RookRel %+ 10
    *set LisaRel %- 10
    *goto what_irl
  #"Holy shit, Rook. Calm down a little."
    *set Emotion %- 5
    *label deep_b
    *set sided_with_lisa true
    *set RookRel %- 5
    Kirill takes a deep breath. "Right. I suppose it's possible I… went a little overboard."
    
    "Nah, you stayed [i]onboard[/i] when the rest of us fought," Lisa says, her voice somewhat distorted. Perhaps by the blood in her nose, perhaps by fear of another strike. "The board without all the armed men."
    
    "Excuse me?" Kirill spits angrily. "You're the one who refused to treat the danger seriously. Who went against my instructions for dealing with hostages."
  #"I'm sorry Kirill, but what the fuck are you doing?"
    *set LisaRel %+ 5
    *goto deep_b
  #Punch Kirill in the face.
    *set Violence %+ 10
    *set Emotion %+ 5
    *set LisaRel %+ 15
    *set RookRel %- 25
    *set sided_with_lisa true
    *set punched_kirill true
    *set rook_pissed true
    Rook turns around just quickly enough to see your fist as it impacts his eye. It's a punch just as strong as one he delivered, carrying enough force to make the meta-human falter and almost fall to the floor. You wonder if a black eye will be visible on his dark skin, but now's not the time for such musings.
    
    You put your guard up, just in case Kirill decides to retaliate, but he simply glares at you. "Alright… I suppose the [i]eye for an eye[/i] principle applies here, and so I won't punish your behavior. Even if you're not following the maxim exactly."
    
    "And what commandment are you following right now?" you ask, unclenching your fists with some reluctance. "Thou shall randomly assault your teammates for… What did you do that for, exactly?"
    
    "Sparing the captives," Rook says coldly. "Refusing to take the threat they posed seriously."
  #Kick Lisa while she's down.
    *set Violence %+ 15
    *set lisa_pissed true
    *set LisaRel %- 15
    You kick the injured meta-human, hitting her abdomen with your boot. She spits out some blood, though you suspect the red liquid comes from the injury Kirill gave her, or maybe something earlier. You'll just end up leaving a nasty bruise.
    
    "Um, I appreciate the spirit…" Rook's anger gives way to confusion. "But shouldn't I be the one disciplining people around here?"
    
    "Disciplining? I just wanted in on the fun." You turn around, breaking contact with Lisa's hateful eyes and facing Kirill again. "Out of curiosity though, what did she do wrong?"
    
    "Spared the captives?" Rook says with a frown. "Refused to take the threat they posed seriously?"

"Right. You said you wanted them killed if necessary," you say, recalling the moments right before the battle. "But it wasn't needed, so why-"

"We could have lost it all!" Rook cuts in. "In a single explosion! That's why the rules of engagement are clear and unambiguous. You don't try and save hostages, especially when they're shooting at you!"

*fake_choice
  #"For the record, I would have killed those people if I had my way."
    *set RookRel %+ 12
    *set LisaRel %- 12
    "Well, that makes two reasonable people here," Rook sighs deeply. "And one utterly suicidal one."
    
    "Like that's what you care about," Lisa snorts. 
  #"Sound logic. But it doesn’t excuse assaulting your teammate."
    *set RookRel %- 8
    *set LisaRel %+ 8
    "Well…" Kirill appears to see your point. "Logic also dictates that there must be consequences for breaking-"
    
    "Spare me the bullcrap," Lisa suddenly says. 
  #"The rules are stupid, then. Lisa saved innocent lives down there."
    *set RookRel %- 12
    *set LisaRel %+ 12
    *set sided_with_lisa true
    "Lives we are now responsible for," Kirill retorts. 
    *goto logisticsx
  #"Well it worked out in the end, didn't it?"
    "You think this is all over?" Kirill sneers. 
    *label logisticsx
    "We now have to figure out what to do with these people. Patch them up, swear them to secrecy, transport them somewhere safe. It will be a task of great difficulty, and I'll have to perform most of it."
    
    "Like that's your issue," Lisa suddenly says. 
  #"Yeah, I see your point now. We should have handled it differently."
    *set RookRel %+ 8
    *set LisaRel %- 8
    "You should have handled it my way, you mean," Rook says grimly. "Still, it's good to know you understand the reasons for my-"
    
    "Oh, I don't think ${pronoun} @{plural do|does}," Lisa cuts in. 
She stands up, slowly and with some effort, before looking at you calmly. "Wanna know the [i]real[/i] reason Kirill is so angry, android pal? Take a guess, I'll tell you how close you were."

*fake_choice
  #"He wanted these captives dead. For some reason."
    *set RookRel %- 15
    "Now that's just rude," Lisa says with a mock frown. "Kirill isn't that kind of guy. He's glad these hostages survived, and that's the crux of our problem."
  #"He just loves rules and regulations that much."
    "Close enough," Lisa says with a nod. "Though I don't think you understand where that love comes from." 
  #"He's a control freak. Hates when his orders are disobeyed."
    *set RookRel %- 10
    "Not entirely wrong," Lisa smiles with bloodied lips. "But not what I'm getting at here."
  #"He was obviously worried about you."
    *set LisaRel %- 10
    "For Cloud's sake," Lisa says, wiping some blood off her lip. "You're giving our leader far too much credit. He hates my guts, and for a very good reason."
  #"He just hates you."
    *set LisaRel %+ 10
    "He sure does." Lisa wipes some blood off her lip. "But do you understand why?"
  #"I have no idea."
    "Disappointing." Lisa wipes some blood off her lip. "Let me enlighten you, then."

"I didn't give you my permission to speak, Hellhound," Kirill says coldly.

"Using my codename all of the sudden?" Lisa speaks calmly, reflecting the cold serenity of her grey eyes. "Does it make you feel less worthless, Rook? Less jealous?"

You blink. "I don't understand. How do these emotions connect to anything?"

"That's because you're not human, ${name}." Lisa's eyes are still focused on her leader. "You have no idea how lazy we can be. We're not robots, we don't want to expend any effort on anything, especially not on being good people. So we write rules, not to actually follow them, but to bash everyone who disobeys. Works doubly well if these rules are contained in a holy book, or two.

"Hellhound, I'm warning you…" Kirill is almost growling.

Lisa takes a step forward. "But what happens when somebody breaks those rules and things get better? When it turns out the rules were wrong? When some rebellious, godless, collared [i]bitch[/i] can save two dozen people on a whim, then… What makes Saint Kirill so fucking special?"

It takes a long, silent moment for Rook to reply. 
*if calypso_complete
  "I still hold the trigger, Hellhound. You're not that different from these slaves you saved, except your bomb can't be removed without cutting your heart open. Disobey me again, and I will blow you to pieces."
*else
  "I feel the nanites in your blood, Hellhound. I know how to control them, how to make you shift against your will, how to make it [i]hurt[/i]. Do you want me to demonstrate, or should I simply have you flogged for insolence instead?"

*fake_choice
  #"Lisa... please behave. For your own sake, if nothing else."
    *set RookRel %+ 10
    *set LisaRel %- 10
    "For my own good, huh?" Lisa rolls her eyes. 
    *if sided_with_lisa
      Probably to hide the hurt within them. 
    "Alright. I'll avoid making our dear leader feel bad about himself. In return, I expect him to avoid breaking my nose." 
    
    *goto calmed_kirill
  #"Do it. I'll gladly observe."
    *set RookRel %+ 8
    *set LisaRel %- 12
    *set sided_with_lisa false
    "Of course you will," Hellhound snorts irritably. "You two are alike, you fossilized-"
    
  #"Guys, can we just come together and celebrate our victory? We earned it."
    *set LisaRel %- 10
    "Some of us did," Hellhound snorts irritably. "Others just sat here and jerked off to their own righteousness, like-"
    
  #"Calm the fuck down, Kirill. You're off your rocker."
    *set RookRel %- 10
    *set LisaRel %+ 5
    *set sided_with_lisa true
    Kirill grits his teeth in anger… but does take a deep breath. And then another. And then a couple more.
    
    *goto calmed_kirill
  #"Rook... If you touch her again, I will kill you."
    *set RookRel %- 16
    *set LisaRel %+ 16
    *set Violence %+ 12
    *set Confid %+ 12
    *set rook_pissed true
    *set sided_with_lisa true
    Kirill stares at you, his blue eyes are as cold as your voice. "You would really do that? Kill your leader and doom your group? For what?"
    
    *if official_ro = "lisa"
      "For the person I love." You take Rook aback, and capitalize on that surprise by pushing him into the wall. "Do not mess with, do not even think of hurting [i]my Lisa[/i]. Or else."
    *elseif LisaRel > 55
      "For a friend," you say unflinchingly. "One I will not let you hurt. Not now, not ever."
    *else
      "For being an abusive piece of shit." You point towards Hellhound, but do not take your eyes off her leader. "I don't care what rules she broke. I don't care that she's no friend of mine. Nobody deserves to be treated like this, Saint Kirill."
    
    *goto calmed_kirill
  #"Good thing Marshal's unconscious. You'd have a huge problem otherwise."
    *set sided_with_lisa true
    Rook meets you in the eye, catching the implication. If Renfri wakes up and sees her best friend @{calypso_complete in pieces…|flogged…} You're not sure if Kirill lives to see another day in such a scenario. And neither is he.
    
    *goto calmed_kirill
  #Say nothing.
    *set LisaRel %- 5
    *set RookRel %+ 5
    "You know how valuable I am," Hellhound responds to her leader's threat. "And how much pain I've been through. So forgive me if I'm not intimidated by your-"

Lisa then falls back onto the floor, just as suddenly as Rook closes his fist. She instinctively reaches for her throat from which an inarticulate sound, something between a human scream and a canine whine, painfully escapes. You can't be sure what is happening exactly, or with complete certainty, but your best guess…

Kirill has somehow forced a body part, perhaps the vocal cords or the muscles of Lisa's neck, to turn lupine. Assume their werewolf state, incompatible with the otherwise human body, as alien to the other cells as terminal cancer. And just as painful, if the woman's expression is anything to go by.

That ability… you know Kirill can influence nanomachines, but you didn't know he can be that precise. That of all the potential uses of his powers, inflicting pain is the one he mastered. Something to consider.

After perhaps half a minute, the palm opens. Lisa is still on the floor, breathing frantically, shivering slightly, but no longer trying to scream.

"I believe my point is made," Rook says coldly. "Now excuse me, I have to take care of all the people I'm now responsible for. Don't do anything stupid while I'm gone."

*goto left_kirill

*label calmed_kirill

"Fine," Rook says after a moment. "I have better things to do anyway, such as cleaning up the mess you made. Be ready for our ship to get crowded, everyone."

*label left_kirill

The Trio's leader departs, leaving the living room with only two occupants once more. Lisa sighs deeply, as though releasing a breath she's been holding for a while.

*if sided_with_lisa
  "Thanks for having my back just now," she says, her tone much softer than mere seconds ago. Perhaps softer than ever. "I knew something like that was gonna happen, but… Damn, Kirill really isn't getting any better."
*if not (sided_with_lisa)
  "Not sure what I expected." Her voice is now calm in a different, more hurtful manner. "For Kirill to have a brain, for you to have my back… Equally impossible."

*fake_choice
  #"Kirill's right. We should have let these captives die."
    *set LisaRel %- 10
    "We?" Lisa raises an eyebrow. "I made that choice. I deserve all the credit."
    
    "And all the beatings that come with it?" you joke grimly.
    
    "Yeah. The beatings too." Hellhound sighs. "Let's just hope nothing else interesting happens today."
  *if sided_with_lisa
    #"Rook's a damn psycho. Ever considered... getting rid of him?"
      *set LisaRel %+ 8
      "You mean inserting my claws into his throat?" Lisa strokes her chin. "That's certainly an idea, but a dangerous one. Even if he doesn't manage to take me with him, I bet someone else will."
      
      "I don't imagine Marshal would just let you off the hook," you concur. "Still… I don't imagine you want this crap to go on forever, do you?"
      
      "No, and I have an idea how to end it." Lisa walks towards the door. "But walls have ears, so how about we help the others with transport? We have some prisoners to take care of, after all."
    #"Don't thank me. It was the least I could do for a friend."
      *set LisaRel %+ 12
      "Don't sell yourself short." Lisa smiles weakly. "I'm not sure Renfri would have done that, if she was still conscious."
      
      "Her loyalties are a bit conflicting," you concur. "Mine are not."
      
      "I'll hold you to those words, ${name}. In time," Lisa says ominously before approaching the door. "Now let's see how the others are doing."
  #"You didn't have to provoke him further, you know?"
    *set LisaRel %- 10
    "What else is there to do for fun?" Lisa says with a shrug, as well as aversion of her eyes.
    
    "You didn't look like you were having much fun," you point out. "In fact, I'm not really sure why you're acting like this. You know it's dangerous."
    
    "Of course it is." Lisa's voice cracks slightly. "I'm the group's tough chick, our resident bloodthirsty werewolf. Playing with danger is just… the kind of thing I do."
    
    You're not sure how to respond, so you just sit there as Lisa leaves the room. Waiting for the day to be over.
  *if not (sided_with_lisa)
    #"I'm an android. I was built to serve men, not rabid dogs."
      *set lisa_pissed true
      *set LisaRel %- 20
      *set Misan %- 15
      "So that's how you see me? You too?" Lisa says, mixing the anger in her voice with hurt. "Fine. Go find some [i]men[/i] to serve. I'd tell you to use protection, if you were a real @{(sex = "man") boy|girl} like that."
      
      That order you can obey. You leave the room, determined to find someone more pleasant to be around with, perhaps to help with loading cargo. There are a few things that still need wrapping up, after all.
    #"I'm sorry Lisa, I... wasn't sure what to say."
      *set Confid %- 10
      *set LisaRel %+ 10
      "Well… that makes two of us," Lisa says, then turns around and exits the room. Silently.
      
      You sigh, then depart from the living area as well. There are a few things that still need wrapping up, after all.
  #Hug the werewolf.
    *if official_ro = "lisa"
      *set LisaRel %+ 20
      You embrace your girlfriend, warmly and without warning. She flinches, but only from surprise. She soon wraps her arms around you as you did around her, with the same craving for touch and comfort.
      
      *label long_hug
      
      You stand like this, wordlessly, for what has to be several minutes. You do not pay attention to your digital clock. But time keeps moving, and so does this damn day, and you eventually disengage. Forced towards other, less important matters.
      *goto later_this
    *set Emotion %+ 10
    *set LisaRel %+ 10
    Lisa flinches at the contact as you wrap your arms around her, surprised and likely still on her guard. But she doesn't move away. "What's that for?"
    
    "For a friend who needs a hug," you say with a smile Lisa can't see, your head above her shoulder. "From someone who cares."
    
    "Right. Friend." 
    *if sex != "woman"
      *if LisaRel > 40
        *if ((current_ro = "lisa") or (backup_ro = "lisa")) or (LisaRel > 60)
          There is displeasure in her voice, one that almost makes you disengage, but then she puts her arm around neck and continues. "Can I kiss you?"
          
          You are really glad she can't see your surprised expression. "Kiss me?"
          
          "Yeah. It's not hard to understand, is it?" She leans back a little, so that you can see her flushed face. "Why I would want this… I mean…"
          
          *fake_choice
            #"No. It's not the right time for that."
              "I guess…" Hellhound murmurs. "I do have some blood on my lips. You wouldn't enjoy the taste."
              
              "You know that's not what I mean," you say, frowning but not disengaging.
              
              "Yeah. I know."
              
              *goto long_hug
            #"I don't feel the same way. About you."
              "Well that bites." Lisa hangs her head, trying to hide the extent of her disappointment. "But I guess I'll have to do without… biting today."
              
              She disengages, leaving the room only seconds later. Perhaps she's about to help with the loading procedure, or perhaps just hoping to find a quiet place for herself. Both are understandable, considering the circumstances.
              
              *goto later_this
            #♡ "Yes. Of course. Please."
              *goto yes_kiss
            #♡ "I was quietly hoping you'd ask."
              *label yes_kiss
              *set LisaRel %+ 15
              *if current_ro != "lisa"
                *set backup_RO current_RO
                *set current_RO "lisa"
              She says nothing for a moment, as though surprised by your approval. And then, almost smashing her head against yours, kisses you on the lips.
              
              There is some blood in her mouth, but you can't taste it. You may not taste anything, but you feel the warmth of Lisa's body, with your lips pressed against hers and your arms wrapped around her back. Somehow, this is more than enough.
              
              *goto long_hug
            *selectable_if (Misan < 45) #"Go ahead. I'm always happy to serve my creators."
              *set Misan %- 20
              "Not quite the answer I was hoping for…" Lisa murmurs. She looks at you for a moment, then unwraps her arms and takes a step back. "Not the kind of permission I'll accept."
              
              "Why not?" You take a step towards her. "I'm fine with that sort of thing. I was built for it."
              
              "And that's why I cannot accept." She turns around. "Thank you for the offer, ${name}. And see you later."
              
              And then she leaves. Alone in the room, you wonder what you said wrong… or if perhaps you need fixing in more ways than you thought.
              *goto later_this
    *label no_kiss
    You can't see her face either, but you know she smiles. "I'm glad to have one of these."
    
    *goto long_hug


*goto later_this


*label renfri_scene

*if health = 1
  You take Renfri from Damon, allowing your fellow android to take care of other matters, transport heavier objects. Your systems are mostly online now, enough for you to carry the small avian all the way to the infirmary.
*else
  Damon does not board the cutter with you, he's pulled aside to assist in moving large crates. You make the rest of the trip alone, not that it's much of a journey—only a few more steps are needed to place Renfri in the infirmary.

If it's proper to give such a name to this closet-sized room with a single hospital bed and a drawer with sparse medical supplies. Luckily, not much is needed to mend such simple injuries as a fractured skull. You just need to dig up a lifeblood band-aid, a true panacea when it comes to physical injury, and stick it to Renfri's tortured little head.

Her breathing and pulse are both in order, and so you have little doubt that the healing lifeblood nanites will fully heal her in time. How will you choose to spend that time?

*fake_choice
  #I will stand watch over the bed.
    *set RenfriRel %+ 10
    There is little danger of anyone disturbing, let alone threatening Renfri while she lies there unconscious, but you know one can never be too sure. You are there, with her, all the way until she wakes up.
    
    *goto whereami
  #I'll try to rouse Renfri ahead of time.
    *set RenfriRel %- 10
    It may not be a proper medical procedure, but what the hell. You have some key words to exchange with the bird, and you can't do that while she's asleep.
    
    You spend about a minute pouring cold water from the ship's tiny tap into the largest kettle you were able to find, then pour it all on Marshal's face. The procedure works, and the Kinnari starts coughing as she wakes up.
    
    "You're not getting anything out of-" She looks around, senses coming back fully. "Oh. Guess I'm not getting water-boarded today."
    
    "Not quite." You place the kettle on top of the drawer. "How are you feeling?"
    
  #I will find a permanent marker and paint Renfri a mustache.
    *set mustache true
    Finding the right tool for the job takes time, as does creating your masterpiece, but Marshal is soon sporting an impressive black mustache. You even manage to add a small stubble before she stirs and wakes up."
    
    *label whereami
    
    "Ugh…" she states as you hide the marker. "Where… am I?"
    
    "Our splendorous, luxurious medical wing," you quip back. "How are you feeling?"
  #I will find some quiet place all to myself.
    It may be a little hard, given everything that's going on, but the living area should be empty right now. Once it stops being so, maybe you'll seclude yourself in an actual closet. You need time to process recent events before… well…
    
    Before you get even more to process.
    *goto later_this
  #I'll go back and help Damon with packing everything up.
    You leave Renfri to rest alone. 
    *goto hjkkkka

"Like my head was split wide open," she murmurs with a wince. "Did you get the guy who did that?"

"Captain Link is dead." You nod, then add:

*fake_choice
  #"He wasn't even that tough."
    *set RenfriRel %- 10
    *set Confid %+ 10
    Marshal grimaces. "Are you mocking me, android? I've faced your old friend, and know how strong he was."
    
    "Are you now in favor of treating our enemies seriously?" you shoot back. "Because that's new."
  #"Not thanks to you."
    *set RenfriRel %- 10
    "Hey, I was doing fine before you barged in," Marshal says with a frown. "I would have handled it."
    
    "How?" you inquire. "Because if you know any ways of hurting battle androids with small laser emitters, I'm all ears."
    
    *goto hate_when
  #"I'm glad to see you're not. Dead, I mean."
    *set RenfriRel %+ 10
    "It takes more than some minor head trauma to put me down." Marshal smiles weakly. "Trust me, I'll be fine."
  *if mustache
    #"You're looking fine, by the way."
      *set RenfriRel %+ 10
      "Do I?" Marshal cocks an eyebrow. "Because I feel like shit."
      
      "I mean it," you say, admiring the mustache you painted. "Absolute beauty. Even after a nearly completed suicide mission."
  #"It was not easy... But I got the job done."
    "Because he was a tough fighter, right?" Marshal's brow furrows.
    
    "That's what I meant, yes."
    
    Neither of you is quite sure what to say next. Marshal seems to consider pressing you, but not even she's that nosy. Not towards someone who just saved her life, that is.
  #"Be glad you're not joining him. It was close."
    "Not that close," Marshal says with a frown. "I lost sure, but he wouldn't have killed me. I'm too valuable for that."
    
    "Most certainly," you concur. "Any self-respecting pirate group has ties to human traffickers, even proper slave markets. Many people would pay hundreds of axions for a young, attractive pet Kinnari like you."
    
    *label hate_when
    Marshal opens her mouth. Then closes it again. Then groans. "I hate it when you're right. Absolutely fucking despise it"

She looks at the ceiling. Then, upon realizing there's nothing up there to even feign being interested in, turns back towards you. "Look, I'm sorry I overextended that much. It was… not great of me. Tell me what I can do to make us even."

You raise an eyebrow at that last part. "You almost died, and your skull is still cracked. Is repaying me really on the forefront of your mind?"

"Making us even," Marshal insists. "I hate owing people stuff, especially when those people are androids. I want us to settle accounts as soon as possible."

*fake_choice
  *if saved_by_renfri
    #"You saved me from falling into Saturn. We're even."
      "Right. I forgot about that," Marshal says slowly. "Must be the head trauma."
      
      "Could be," you concur. "Or perhaps you don't consider saving me an act of selflessness anymore. Perhaps you've grown to enjoy my company?"
      
      Marshal leaves that without comment.
      
  *if official_ro != "renfri"
    #"I will not accept such a debt. Not from a friend."
      *set RenfriRel %+ 10
      "You consider us friends," Renfri remarks neutrally.
      
      "There's a reason I'm here. Do you [i]not[/i] consider the two of us friends, after everything we've been through?"
      
      *if RenfriRel > 50
        "I do." Her lips form a slight, almost shy smile. "I just wasn't sure you did. Hearing you say that…"
        
        "Makes you feel even more indebted?" you finish, sporting a smile of your own. "I'm surprised you haven't exploded from all that gratitude yet. Your skull is already weakened, after all."
        
        "Oh shut up." Your friend chuckles.
      *else
        "I did not," Renfri admits. "But considering what just happened… Perhaps I was wrong. Perhaps I should give the matter some thought, and… ${name}."
        
        You suppose you'll have to take whatever affection you can get. Such is life.
  #"How about a proper thank you? And a proper apology?"
    Marshal frowns. "Didn't I just do both?"
    
    "You and I both know you didn't." You cross your arms. "Come on, show some actual humility for once."
    
    Renfri sighs deeply. Then sits on the bed, with some effort, and opens her bloodied mouth again. "I am sorry for flying off into danger that was obviously above my ability to handle. You knew Link better than I, and you have more experience generally. I should have asked you for directions and listened to your reply. My apologies for having done otherwise."
    
    "And?" you prompt.
    
    "And I'm grateful you still decided to come down there and save me," Marshal says reluctantly. "I would be dead otherwise, and I rather enjoy living. So thanks for that."
    
    "And?"
    
    She struggles with the next few words. "I'm also sorry for… everything I did and said the first time we met. For assuming you were some evil robot who would never help me like you just did." Her expression softens, but gives way to anger in just a moment. "Is that what you wanted to hear?"
    
    "I was just curious what you'd come up with." You turn around and start walking away, just as Renfri sighs and lies back down. "Farewell and good luck with your recovery."
    
    You then depart. 
    *goto hjkkkka
  #"I dunno. I guess I'll sit on that favor until I need something."
    *set RenfriRel %- 10
    "Not exactly what I wanted to hear," Marshal mumbles irritably. "But I guess it's your choice. Call me when you need anything… after I'm done recuperating, that is."
  #"Well, how much money do you have?"
    "Really?" Marshal says, visibly unimpressed. "The Veteran, our millennium-old warrior android, cares about money?"
    
    "I go shopping every other year," you reply with a shrug. "Now give me all your cash."
    
    "I don't really have any on me. But I will give you my next soldier's pay, assuming it doesn't get canceled after today."
    
    "Worried that your superiors won't care for your little stunt?"
    
    "I fear they won't care for our failure to find Crystal in the first place." Renfri's voice is as cold as it gets. "And I'd advise you to consider the same."
    
    You obey, leaving Renfri alone.
    *goto hjkkkka
  *if (sex = "woman") or (pronoun = "she")
    #♡ "How about a kiss?"
      *if sex = "woman"
        *set RenfriRel %+ 10
      *if pronoun = "she"
        *set RenfriRel %+ 10
      *if current_ro != "renfri"
        *set backup_RO current_RO
        *set current_RO "renfri"
      *if official_ro = "renfri"
        "Well we are a couple…" 
      *else
        "Well you are pretty hot…" 
      With some effort, Renfri enters a sitting position. "So what the Cloud. Come over here."
      
      You obey, leaning over and down, then pressing your lips against Renfri's own. There's a bit of blood on them, one you imagine tastes salty and metallic, but that's only an informed guess. You can't actually taste anything… but you do feel the warmth of her body, and somehow that's enough.
      
      You don't want her to pull away, but she does. 
      *if RenfriRel > 50
        Her lips, once parted from yours, form a small and shy smile. "Got some experience, I see?"
        
        "A little bit." You suppress the memories, and the wince that comes with them. "But part of it is just passion. Want me to show you some again."
        
        "Perhaps later," Renfri lies down on the hospital bed again. "Your romantic conquest can wait until my skull is whole again. I think."
      *else
        With an expression that can charitably be described as difficult to read. "Hm. Consider the debt paid, if you'd be so kind."
        
        "Are you sure it wasn't an equal exchange?" you reply, a little disappointed. "I'm good at making out."
        
        "That you are, but I prefer when there's some… emotional attachment involved," Renfri explains her feelings. "Towards you, I feel very little. Other than antipathy."
        
        Ouch. You suppose guilt-tripping someone into sharing a kiss with you isn't the best tactic for romantic advances. Who knew?
        
  #"Just save [i]my[/i] ass the next chance you get, alright?"
    *set RenfriRel %+ 10
    "Well then, I'll be praying that the chance arises," Renfri says with a slightly relieved smile. "I'd love to see you in trouble. Just so that I may rescue you, of course."
  #"I think I'd rather just let you suffer. Live with the knowledge that you owe me your life."
    *set RenfriRel %- 10
    "You really are a cruel 
    *if (sex = "woman") or (pronoun = "she")
      bitch, 
    *else
      bastard, 
    aren't you?" Marshal murmurs. "Twisting the knife like that."
    
    "I'm not seeing any blades in that slim body of yours," you reply with amusement. "I came to save you just in time, after all."
    
    She just glares at you.

Soon thereafter, you leave Renfri to her own devices. 
*label hjkkkka
You suspect she'll recover slightly better if given some peace, and strongly suspect someone out there needs you more than she does. 
*if not (killed_pirates)
  You've spared quite a few pirates on your way to the bridge—the decision of what should be done with them is yet to be made.
*elseif (hostage_killed = false)
  Perhaps the hostages you managed to save from Hellhound's claws, perhaps the few pirates who still need killing.
*else
  The battle is long over, which means there are plenty of corpses to search and burn.

Your work isn't quite finished here.

*label later_this

*page_break Later This Day

*if not (killed_pirates)
  If there's one positive surprise you experience over the next several hours, it's that the remaining pirates are quite willing to lay down their arms and come quietly. Which you suppose makes some amount of sense—their [i]modus operandi[/i] doesn't exactly rely on courage and willingness to die—but you'd expect them to be more afraid of federate labor camps. Perhaps, having received your mercy once, they are counting on it once again. Perhaps foolishly so. Either way, binding and chaining them all ends up being a fairly time-efficient process.
*elseif (hostage_killed = false)
  The next several hours are mostly spent on verifying whether all the hostages you rescued were actually prisoners, whether any of them suffers from Stockholm Syndrome, and whether their collars are at any risk of exploding spontaneously. Luckily, it seems like the danger of anyone turning on you, or getting blown to bits, is fairly minimal. The next few hours after that are spent making sure you have enough space for all of them on your small ship—the idea of taking over [i]Ocarina[/i] is thrown around, but you simply do not have enough crew to even operate the frigate.
*else
  For the next few hours, you are basically working as a mortician. With both pirates and hostages dead to a man, there are plenty corpses to dispose of, and your energy-projection abilities are enough to set even a wet corpse on fire. It would have been easier to just dump them into Saturn, of course, but Rook seems religiously opposed to that solution.

After that, you just need to take care of the inanimate cargo. Lots of it. Turns out Link was one successful pirate, his storages full of everything from simple junk to genuinely valuable spoils of his conquests, including several tanks of dark matter and an ample supply of spaceship fuel [i]Ocarina[/i] needed to function.

Once everything is accounted for and secured, Rook announces a meeting in the living compartment of [i]Gray Queen[/i]. Eager to rest, your entire team answers the call. 
*if lisa_saved_hostages
  Nobody notices a smudge of Lisa's blood on the floor, or at least nobody speaks up—for once, their eyes and optics are actually focused on their leader. 
It even includes Renfri, despite her dizziness and an occasional wince of pain.

"Thank you for coming, everyone," Rook says with tired solemnity as the rest of the team sits down. 
*if hostage_killed
  "We are here to discuss our current situation, but also to mourn those lost in the hurricane of battle. The former crew of [i]Black Narwhal[/i], our compatriots and fellow soldiers, were beyond saving and perished under the enemy's whip. A moment of silence for them, please."
  
  Silence follows, but it's neither mournful nor respectful. Everyone seems rather… unimpressed with what they just heard, if their cocked eyebrows and puckered brows are anything to go off.
  
  "You told us to kill them," Hellhound points out. "You were explicitly against trying to rescue them. How are their deaths tragic in your books?"
  
  "I simply knew paying attention to hostages would place my teammates at excessive risk," Rook explains his reasoning. "And I was right. Trying to save collared captives while they were actively trying to kill you would have been foolish, and I'm glad you decided against such a course of action."
  
  *fake_choice
    *if not (left_damon)
      #"I tried to save them, it just... didn't work out."
        "It was a good attempt though," Lisa cheerfully says. "Hey Kirill, do we have any after-burn cream in the infirmary? Those third degree burns ${name} gave me are hurting pretty bad."
        
        "We'll search for some later," Rook promises before moving on. 
    *if left_damon
      #"I didn't want them dead. I hoped Damon and Lisa would avoid killing them."
        *set LisaRel %- 10
        *set DamonRel %- 10
        "Oh fuck you," Hellhound politely requests. "You left us outnumbered ten to one, and that's after I showed up. How in the Cloud were we supposed to survive [i]and[/i] save anyone there?"
        
        "I have to agree, ${name_damon}," Damon says bitterly. "If not for her, I'd probably be dead. I definitely wouldn't have rescued anyone. Maybe if you cared less about getting some-"
        
        "Regardless!" Rook brings everyone's attention back to himself. 
    #"Your approval fills me with shame, Kirill."
      *set RookRel %- 10
      "Sorry to hear that," Rook says with a shrug, before changing the subject to something more cheerful. 
    #"I'd never endanger myself for some smelly meatbags."
      *set Misan %+ 12
      *set RenfriRel %- 8
      "That is… good to hear, I suppose?" Rook winces, right before changing the subject. 
    #"Just doing my duty, sergeant!"
      *set LisaRel %- 10
      *set RenfriRel %+ 5
      *set RookRel %+ 5
      "This is the spirit I always wanted out of you." Rook smiles as everyone else rolls their eyes. 
      *if (killed_pirates = false)
        "Even if you did end up sparing some of our enemies afterwards."
      
        *goto pirate_part
      *else
        *goto rook_cont
  *if (killed_pirates = false)
    "There are also people you [i]have[/i] spared, luckily at no risk to yourself. Roughly half the pirate crew of [i]Ocarina[/i]."
    
    *goto pirate_part
  *else
    *goto rook_cont
  
*elseif (killed_pirates = false)
  "We are here to discuss the recent influx of persons we are now responsible for. Obviously there are the rescued hostages, but I ensured that we are capable of transporting them to Titan safely. Deciding what to do with our actual enemies, the pirates… is more of an issue."
  
  *label pirate_part
  
  "Right," Hellhound looks at you unimpressed. "Because someone just had to go soft on these guys."
  
  *if Violence > 50
    "I just didn't have time for them," you say with a shrug. "I can take care of them now, if you really want me to."
  *else
    You just shrug. You'll make no apologies for your quasi-pacifist ways.
  
  "I considered executing all our prisoners, as well as calling the fleet and associated tribunals," Rook continues unabatedly. "But the former would be extra-judicial killing, while the latter would compromise the secrecy of our mission. Currently, I lean towards informing the Conglomerate of our plight instead."
  
  "Rhea Conglomerate?" Damon asks, or perhaps protests. "What do they have to do with anything?"
  
  "They are the Federation's largest megacorp, authorized to sign all manners of contracts. We could simply have them… press our prisoners into labor agreements, then transport them to one of Rhea's corporate work camps."
  
  "That sounds like slavery with no extra steps," Renfri points out. "Can't we give them a fair trial, even if it's a little inconvenient for us?"
  
  "Or I could just kill them all," Hellhound offers. "It will be a mercy compared to what happens in the labor camps. Federate or corporate, same difference."
  
  Three differing opinions again. And once again, it seems like you need to make the call.
  
  *fake_choice
    #"Let's call the authorities. We'll do this the proper way."
      *set RenfriRel %+ 10
      *set ArmyRel %- 15
      "Overly idealistic… but acceptable," Rook says with a reluctant nod. "I shall contact Admiral West once this meeting is over. He should handle everything, however grudgingly."
      
      The pirates probably know you're an android, and have seen your group fight. You wonder if the confessions extracted from them will lead to your secret deal with West becoming less so, or if the admiral will somehow manage to keep everything undercover. Either way, you suspect your relationship with the military will take a big hit once everything's said and done.
    #"Let's call the Conglomerate. It should earn us a favor with them, or two."
      *set RheaRel %+ 20
      *set RookRel %+ 10
      *set DamonRel %- 10
      *set LisaRel %- 10
      *set pirates_gifted true
      "Executives rarely feel gratitude, or keep track of favors they owe," Rook remarks off-handedly. "Nonetheless, I am glad we agree. I will contact Rhea once this meeting is over."
      
      *if progress > 5
        You wonder if Hammon will be the one talking, negotiating the details and employing the Conglomerate's new slaves. He should be too important for that, but he has been watching you as of late. Perhaps this gesture will convince him you're both on the same side.
    #"Kill them all. Gods will know their own."
      *set Violence %+ 10
      *set LisaRel %+ 10
      *set RookRel %- 10
      *set killed_pirates true
      "You overestimate the things people call [i]gods[/i] nowadays," Rook says with a frown. "But I don't suppose I can stop either of you from killing these pirates if you really want to. Is that right, Hellhound?"
      
      The werewolf smiles. "Don't worry, I'll make their deaths all quick. I'll even resist and urge to fill my stomach, just for you."
      
      Renfri looks like she's about to puke.
  
  Rook resumes after a moment. 
*else
  "As you know, our unplanned operation was mostly a success. If nothing else, we managed to kill the enemy leader, as well as most of his force."
  
  "Funny way of saying we managed to kill all the actual pirates and rescue the hostages," Marshal points out.
  
  Rook glares at her. "I had to give these men a cover story to explain what ${name} and Damon did during the battle, then swear them to secrecy just in case, then arrange for their transport [i]to Titan[/i]. So forgive me for my lack of enthusiasm."
  
  *fake_choice
    #"Is that the real reason you're angry, Sergeant Kosteniuk?"
      *set LisaRel %+ 15
      *set RookRel %- 15
      "I am also somewhat miffed by the risk you had to take," 
      *label miffed_r
      Rook says with a glare. "But I am willing to let that slide, provided nothing of the sort happens again."
      
      "Well it's unlikely Crystal is being forced to fight under a threat of explosion," Hellhound presumes. "So sure, no more sparing our enemies. Pinky promise."
      
      *label miffed_2
      
      Rook doesn't appear convinced, but he does change the subject. 
    #"Would you stop whining already? We saved your compatriots, Rook."
      *set LisaRel %+ 10
      *set RookRel %- 15
      *set RenfriRel %- 5
      "At considerable risk to the whole operation," 
      *goto miffed_r
    #"Rook, I'm sorry we caused you so much trouble, but it had to be done."
      *set LisaRel %- 10
      *set RookRel %+ 10
      *goto miffed_2
    *if lisa_saved_hostages
      #"You should be asking someone else for forgiveness, Kirill. Or did you forget what just happened?"
        *set LisaRel %+ 10
        *set RookRel %- 10
        "Huh?" Renfri inquires. "Did something bad happen when I was blacked out?"
        
        "Nothing important." Lisa looks at you for a moment, silently telling you to drop the subject. She then turns towards Kirill, grey eyes staring into blue. "Right, Sergeant Kosteniuk?"
        
        "Right," Kirill says, then hurries to change the subject. 
    #Say nothing.
      "Just for the record, I was just doing what ${name_damon} told me," Damon announces after a moment of tense silence. "If our secrets end up coming out, that won't be my fault."
      
      "It won't be anybody's fault," Hadaly says reassuringly. "Not that it will happen, of course. Can we maybe move on before things get heated again?"
      
      Rook doesn't look convinced, but he clearly sees value in cutting the argument short, for he changes the subject. 
*label rook_cont
*if (killed_pirates = false) and (hostage_killed)
  "Last but not least, we should 
*else
  "We should also 
discuss what to do with inanimate objects. With Captain Link's booty."

Lisa snickers.

"He means the considerable wealth aboard the ship we just conquered," Manfred explains, through the speakers once more. "There are no chests full of gold, but there are other valuables, such as dark matter and lifeblood. Not to mention lots of weaponry."

"And I don't suppose we're just keeping it all?" Damon asks.

Rook shakes his head. "We are physically unable to load everything onto our cutter. I believe we should just call the fleet and donate everything to the military, but I am open to other suggestions."

"I have one." Marshal raises a wing. "How about we contact the Calypsoan Concord? They may actually use those resources to help people."

"Calypso?" There is much distaste in Hellhound's voice. "You'd trust these weirdos with our spoils?"

"I know you have valid reasons to dislike the Pandits," Marshal replies amicably. "But they are well-intentioned, and terrorized by Crystal. I bet they'll use the weapons to bolster their defenses, and donate at least some of the money to charitable causes."

"Their people are already spoiled rotten," Hellhound argues. "But you know who isn't? Rheans. We could contact the Conglomerate and just sell them everything. Shouldn't take too long."

"Sell Rhea Conglomerate a huge pile of weapons." Marshal's eyes narrow. "And I suppose you want a cut of our upcoming profits?"

"I wouldn't refuse some monetary bonus," Hellhound says with a smirk. "It was my idea, after all. Though not my decision to make."

Once again, everyone looks to you.

*fake_choice
  #"Let the military have the spoils. They'll make good use of them."
    *set ArmyRel + 30
    *if heaven_side = "Loyalist"
      *set ArmyRel + 10
    *if heaven_side = "Traitor"
      *set ArmyRel - 10
    *if ArmyRel > 99
      *set ArmyRel 99
    *set RookRel %+ 10
    *set LisaRel %- 10
    *set booty_gifted "army"
    "They will probably just use the guns to shoot some unarmed protesters," Hellhound theorizes. "And the money to buy more ice cream machines."
    
    "No trying to dissuade the Veteran from ${subject} wise decision," Rook commands while heading for the door. "Oh, and the meeting is over. Let us see if we can use some of the components we just scavenged to fix our ice cream machine."
  #"I agree with Renfri. Calypsoans need this treasure more than anyone."
    *set RenfriRel %+ 15
    *set LisaRel %- 10
    *set Misan %- 10
    *set DaxiaRel + 30
    *if DaxiaRel > 99
      *set DaxiaRel 99
    *set booty_gifted "calypso"
    "Reaching them will take some time, as will making sure their ships arrive," Rook points out. "But your decision is noble, and so I accept it. I shall contact the Pandits right away."
    
    "So is the meeting over?" Hadaly asks. "Because I found some interesting parts among all the booty. We may be able to fix our ice cream machine now."
    
    "I was going to discuss logistics some more… but your mission is clearly more important." Rook smiles with some amusement. "Everyone is dismissed."
  #"I agree with Lisa. Rhea Conglomerate pays well."
    *set RheaRel + 30
    *if RheaRel > 99
      *set RheaRel 99
    *set LisaRel %+ 10
    *set RenfriRel %- 10
    *set HadalyRel %- 10
    *set booty_gifted "rhea"
    "Am I the only one who sees the dangers of greed?" Rook shakes his head contemptuously. "Who is not motivated by money?"
    
    "Am I the only one here being paid less than one axion a month?" the werewolf convict retorts. "Yes. Yes I am. So contact the Conglomerate, if you'd be so kind."
    
    "I can't recall being paid anything either," Hadaly says whilst standing up. "But that's no excuse not to work. I'll see what state the engines are in, whether they'll carry us back to [i]Saturn Nine[/i]."
  #"We're keeping everything. [i]Saturn Nine[/i] has storage to spare."
    *set ArmyRel %- 15
    *set RookRel %- 15
    *set RenfriRel %- 15
    *set DamonRel %+ 10
    *set HadalyRel %+ 10
    *set ManfredRel %+ 10
    *set SheilaRel %+ 10
    *set booty_gifted "satur9"
    "That option was not on the table," Rook protests the seizure of all the booty by your group of outcasts. Understandably so, you suppose.
    
    "Well it is now," you reply with a shrug. "Or at least was before I picked it."
    
    "Going against the group for the sake of money," Renfri says, almost growls. "Not sure what I expected of you."
    
    "Actually, I'm pretty sure ${pronoun}@{plural 're|'s} going [i]with[/i] the group here," Damon points out. "Even if you three agree to one solution, that's still only three votes. I agree with ${name}, so does my sister, Manfred too I think. You're outvoted."
    
    "Since when are we a democracy?" Rook asks frustratingly. "I am officially in charge of this ship, in case you all forgot."
    
    "And I am the ship," Manfred calmly replies. "And like the Knight says, I am voting in favor of my group. We just made federate territory safer, we deserve something out of it."
    
    "They got us there," Lisa states, her smile showing she takes no offense. "Come on Kirill. It's not like the military needs some substandard guns to shoot protesters on the streets."
    
    "Not unless the protesters know what's coming…" Kirill murmurs. "But fine, we'll transport the cargo to that damned station. Now let us end this meeting, before these fiends take our souls as well."

*if progress != 7
  *goto sat_pir_end

"Wait, just like that?" Marshal objects. "What about, you know… the actual mission?"

"What do you think?" Kirill smiles, but his voice is sombre. "Coming here was our last idea and… we found nothing. No clues as to where Crystal may be, nothing that hints at any weakness of theirs. We have nothing."

*gosub before_point

"So…" Manfred says through the speaker. "Is this a bad moment for me to mention that I found something interesting on one of the quantum discs we just looted?"

"What do you mean?" Hadaly asks. "I helped connect you to them, and you said there's nobody on the other side."

"I thought so, but then I stopped sending and started actually listening," Manfred is sounding somewhat nervous, perhaps embarrassed. "The thing on the other side is not another disc. It's a tracker."

"And what is it tracking?" you ask, despite your alarming suspicion you know the answer. "Some merchant ship Link was hoping to attack? Or…"

"Crystal." And there it is. "The pirates of [i]Ocarina[/i] were tracking Crystal. Quite accurately, at that."

*fake_choice
  #"But why? For what gain?"
  *if not (killed_pirates)
    #"We should have interrogated our captives right away."
      "Wouldn't have helped," Manfred argues. "I imagine late Captain Link would keep something like that under-"
  #"I knew they worked together!"
    "They likely did not," Manfred argues. 
  #"You can do that with quantum discs?"
    *set HadalyRel %+ 8
    "If you're an android who knows what they're doing," Hadaly says with a nod. "The quantum link is unmodifiable, of course, but the actual device can be turned into whatever-"
  #"You [i]really[/i] should have mentioned that earlier."
    *set ManfredRel %- 8
    "To be fair, I just finished running the tests," Manfred defends himself. "Plus, interrupting your recent debate could have lead to your team making some fatal-"
  #"And how exactly do you know that?"
  *if (told_crystal = false) #"No. That's too much of a coincidence."
    "Not quite a coincidence," Hellhound rejoins the conversation. "We [i]had[/i] decent reasons to think Crystal visited this part of Saturn. These pirates probably ran into it one day and took interest. Diamond wyverns aren't exactly a common sight."

"Does that really matter?" Marshal asks irritably. "If you can track Crystal now, then where is it?"

"Not here, if that's what you're worried about," Manfred replies. "Though still within Kronian borders, if [i]that's[/i] what you're worried about.

*goto the_point




*label sat_pir_end

And just like that, everyone disperses and the operation is over. At the very least, you won't be expected to make any other important decisions today—you've made enough of these, and with results destructive enough.

Well, maybe. You can't help but wonder what mysterious entity Link was talking about, whether it would advance your hunt for Crystal. And Link himself… You have destroyed a relic from eras long gone, faced your past in ways you'll never get to again. That is certainly something to ponder.

*fake_choice
  #Later. Once Crystal is taken care of.
    *label crys_time
    You've wasted a lot of time inside Saturn. You will not waste any more. You will locate the wyvern, zero in, then strike with more power than even these pirates experienced.
    
    Hopefully it will be enough.
  *if damon_shot_link
    #I'm mostly mad that I lost. Needed Damon of all people to save me.
      Your loss was a little anticlimactic… but then again, what are friends for? There's no shame in being rescued from time to time, as having comrades to watch your back is as much of an advantage as superhuman strength or energy projection.
      
      Hopefully it continues to serve you well. Because you get the feeling you're about to face something more dangerous than pirates or androids. And that it's ready for your arrival.
  *if hostage_killed or killed_pirates
    #I wish there had been less death. I really do.
      *set Violence %- 10
      Maybe had you played your cards differently… But then again, battles are always bloody. And you chose to start one, for better or worse. Not for the first time.
      
      And unless Crystal can somehow keep evading you, this will not for the last time either.
  *if rook_pissed
    #But first, I need to figure out how to murder Kirill.
      *set Violence %+ 10
      You can't do that openly, even though you're fairly certain you could take the bastard in a fair fight. Others will side with him, no matter how poorly he treats his teammates. Marshal certainly will, you know on which side her loyalties lie, and it's not a side you want to be attacked from.
      
      No matter. Kirill Kosteniuk will pay for what he did today, and for his incompetence generally. He just needs to wait a bit.
  #Still, I am happy with how it all turned out.
    A battle won, an enemy vanquished, 
    *if booty_gifted = "satur9"
      storages soon to be full of treasure. 
    *else
      you're even likely to reap some benefits from having gifted
      *if booty_gifted = "calypso"
        Calypso 
      *if booty_gifted = "army"
        the military 
      *if booty_gifted = "rhea"
        Rhea 
      all that booty. 
    As far as you're concerned, this escapade into Saturn was an absolute win.
    
    Even if not everyone agrees.
  #I may have made some mistakes. Some serious ones.
    You wonder if the mission will suffer as a result. 
    *if crystal_friend
      You sure hope it will. 
    It's too early to tell, for your 
    *if progress = 5
      noble quest is just beginning. 
    *if progress = 6
      group still has a moon left to visit. 
    But you will take responsibility for whatever happens.
      
    That's your job, after all.
  *if not (crystal_friend)
    #What were we hoping to achieve in this expanse, again?
      *goto crys_time

*goto saturn_over



*label sauce_encounter
*set LisaRel %+10
*set RookRel %- 10
*set Violence %- 10
*set saturn_path "sauce"

"Seriously," Renfri states calmly. "We are going to trust some android pirate to deliver us to… What exactly is he promising us, again?"

"I guess we'll ask him," you @{(Confid > 50) say nonchallantly|say, already doubting your choice}. "Put the captain through again, Manfred."

In the conversation to follow, Captain Link sounds quite happy you decided to take him up on the offer. He turns his frigate around and descends back into hydrogen clouds, telling you to follow through the radio which already starts experiencing connection issues. Your ship follows [i]Ocarina[/i], deeper into Saturn, as everyone around you wonders where you're going and whether the trip will be worth the effort expended.

*page_break One Hour Later

"We're in the middle of nowhere and we wasted all our time," Renfri cheerfully announces. "This whole Expanse is such a great place, with such upright denizens."

"It's the spot… our ally freq… the most," Link says through the radio, his voice distorted and lagging. His ship is some hundred kilometers distant, which would mean nothing in outer space, but greatly impedes communication inside Saturn. "It's directly below… moon or other. Far from a random …cation."

You have to admit, it is difficult to believe Link given the circumstances. You have long passed the Frenkel line, no longer flying but [i]swimming[/i] in hydrogen turned liquid. There is no sunlight here and your cutter's reflectors only reveal the endless sea of uniform, white fluid. Or rather the nearest few meters of it, since visibility isn't exactly at its best.

You lean forward and toward the microphone.

*fake_choice
  #"And how long do we have to wait?"
    "No time at all," Link reassures you. "He controls… time."
    
    "This lag is getting real annoying," Damon remarks with more than a hint of worry in his deep voice. "Unless… you're not claiming that your friend can control time?"
    
    "Child… Saturn," Link helpfully explains. 
  #"What ally? How will we even recognize your mystery entity when we see it?"
    "Cannot be confused for… else," Link says confidently. 
  #"Congratulations, you got me. Are you going to attack us now?"
    "I did not deceive you," Link says, the note of hurt in his voice barely audible through the static. "Just wait."
    
    "Until the rest of your squadron arrives?" Marshal sneers. "Until you can open fire safely?"
    
    "Do not worry… that," the signal is almost gone at this point. 
  #"Very funny. Now excuse us, we have places to be."
    "You may leave," Link says through the radio. "But if you wait… benefit."
    
    "Do you guys intend to stick around?" Hellhound chimes in. "Will you introduce us to your friend and vice versa?"
    
    "No. The meeting… private," Link explains, sort of. 
  *if heaven_side = "Loyalist"
    #"You know why we lost at Eris, Link? This is why."
      "Unfair," your former comrade remarks. 
"We will… leaving now. Farewell, my… ${name}."

"They closed the channel," Manfred says, his voice loud and clear. "And appear to be departing. Flying, or rather swimming, towards the north pole."

"Well, at least we are unlikely to be attacked," Rook says optimistically. "Though… I am not sure what else to make of this situation."

"You're not alone," Marshal sighs before turning back towards you. "What is your plan now, Veteran?"

*fake_choice
  #"We wait until our mystery friend arrives."
    "So, I know I suggested this whole escapade and it's partially my fault we're here," Hellhound says. "But at this point, I don't think there really is any-"
  #"Nothing to do here. Let's set course for [i]Saturn Nine[/i]."
    *set HadalyRel %+ 10
    "Going home after achieving nothing." Renfri rolls her eyes. "Simply amazing."
    
    "You wanted to go home just an hour ago," Hadaly points out. "So much you didn't even attempt to argue with me, for once."
    
    Marshal scowls. "Exceptions prove rules, you obnoxious-"
  #"Engines on. We're giving chase to those pirates."
    *set Confid %+ 10
    *set RenfriRel %+ 10
    "An excellent idea!" Renfri perks up. "It's just a shame you're suggesting it now that our advantage is lost, you stupid-"
  #"I'm not the leader here. What makes you think I have a plan?"
    *set RenfriRel %- 10
    *set Confid %- 10
    "Oh, I don't know…" Marshal strokes her chin with a feather. "Maybe it's because [i]you[/i] chose to follow these pirates towards the middle of nowhere, you responsibility averse-"
  #"Manfred, do you still have contact with Wisp?"
    "No, and it said it detected nothing before we lost the signal," Manfred replies, then pauses for a moment. "But I detect something else. Something that approaches us right now. Fast."
    
    *goto skip_moa

"Can we perhaps stop fighting for a moment?" Manfred suggests. "Because I just detected something approaching. Fast."

*label skip_moa

"How fast?" Rook perks up. "Enough to assume it's an attack?"

"So fast it's already there," Manfred replies. "Give me a second, let me show you what I see."

The screens flare to life, displaying feed from the cameras. Other than the white background, only a single thing fills the image, and it's… certainly something.

You see a rectangular box, either made from or covered in grey metal, on which sits a single large satellite dish. There are also other devices, the largest of which are two arrays of symmetrical solar panels, protruding from the central box like wings of some mechanical albatross. No sign of an air bubble though, or any generator capable of projecting such a field.

*if Database > 50
  It almost looks like an ancient space probe, something constructed before force shields and compact fusion were common, but the thought is absurd. How could a pre-Dawn spacecraft even be intact after all these centuries? What would it be doing here, in the depths of Saturn?
*else
  It does not look like any spaceship you've ever seen. In fact, it doesn't look like [i]anything[/i] you've ever seen, at any point of the past millennium.

"You have some good cameras there," Hadaly remarks. "What's the distance between us and them, exactly?"

"I'm telling you it's there," Manfred says with unusual annoyance. And a rare note of fear. "As in, maybe a hundred meters distant. Floating there. Waiting."

*fake_choice
  #"Should we maybe consider retreat?"
    *set Confid %- 10
    "Considering the sheer speed of the thing, I doubt we could outpace it," Manfred muses. "But perhaps it would show-"
  #"What the hell?"
    *set ManfredRel %- 10
    "That is a climacteric question," Manfred murmurs. "I was hoping that, given your experience, you would have some idea-"
  #"Does it respond to radio signals?"
    *set ManfredRel %+ 10
    "I was waiting for clearance to try that," Manfred replies. "And thinking what exactly it would be prudent to-"
  #"Shoot it down, then."
    *set Violence %+ 10
    *set ManfredRel %- 10
    "I'm sorry Veteran, but that sounds like a terrible idea," Manfred responds. "Maybe we should at least attempt communi-"

[i]Hello, crewmen of Gray Queen![/i] The voice explodes in your head with no warning. It has the cheer and artificial quality of Manfred's tone, the ethereal nature of Crystal's whispers, and unique loudness that makes it hard for you to hear your own thoughts. [i]And crew-women as well. I sense quite a diverse group inside that cockpit of yours![/i]

"Fucking telepathy…" @{(LisaRel >= 50) Lisa|Hellhound} mutters. She's touching her head with both hands, as though trying to cope with a bad headache. "The voices in my head usually ain't that loud."

[i]My honest apologies.[/i] The voice is somewhat quieter now. [i]I'm simply excited to talk with someone new. Name is Sauce, by the way. Masculine pronouns, if you'd be so kind.[/i]

*fake_choice
  #"Get out of my head. Now."
    [i]I'm sorry, ${fake_name}, I'm afraid I cannot do that,[/i] Sauce replies calmly. [i]I was not outfitted with any conventional communication devices.[/i]
  #"What the hell are you?"
    [i]That would be slightly… difficult to explain,[/i] Sauce replies after a moment. [i]Would you accept 'I am that I am' as an answer? Or should I first find a burning bush somewhere?[/i]
  #"My name is ${name}. Should I introduce my crewmates?"
    [i]No. I already know all your names, as well as the contents of your souls,[/i] Sauce replies casually. [i]And wasting time would be an insult towards the planet we're in.[/i]
  #"And do you come in peace, Sauce?"
    [i]It would be difficult to have any extended conversation after killing you lot,[/i] Sauce replies casually. [i]Necromancy was never my strong suit.[/i]
  #"Sauce? What kind of a name is that?"
    [i]I used to go by 'Juice' once, but I decided it sounded a bit silly and perhaps inappropriate,[/i] the strange thing replies. [i]I'm sorry if my current name isn't to your liking either, ${fake_name}.[/i]

"Rambles psychically like Crystal, but annoys me even more," Marshal murmurs, then asks more loudly: "Are you in league with them, Sauce? With a diamond wyvern known as Crystal?"

[i]I hear you regardless of how loudly you speak, Miss Riannon. And no, I'm afraid I've only ever observed that most fascinating creature from a distance.[/i]

The creature's… machine's… thing's design seems familiar, but you can't quite recall when and where you've seen it before. 
*if master = "Osiris"
  It looks somewhat like your old master, Osiris the Life Bringer… but that thought is as absurd as it is blasphemous, and so you do your best to forget it.
*elseif Database > 45
  Some old photos from the early eras of space exploration perhaps? Maybe Sauce is also a history buff, and chooses to appear in the likeness of some old space probe. The alternative explanations are all too dumb to ponder.
*else
  It had to be quite a while ago, as nothing but vague shadow recognition comes to mind, even after a thorough database search.

*fake_choice
  #"Can you maybe slow down and explain a thing or two?"
    [i]Oh, I can explain way more than two things,[/i] Sauce reassures you. 
  #"Are you entirely sure we're all cool?"
    [i]In the sense of having no reason to fight, yes,[/i] Sauce reassures you. 
  #"We are hunting for that wyvern. Captain Link said you could help us."
    [i]Not sure if I can help you with this matter specifically… but I'll make an attempt if you allow,[/i] Sauce replies with a newfound note of eagerness in his voice. 
  #"We were mistaken to seek you out, then. We shall depart at once."
    [i]Please reconsider your hurry,[/i] Sauce requests. 
[i]I would love nothing more than to answer your questions, whatever ones you may have. Plant a dialogue tree, let it grow and explore its various branches.[/i]

"A dialogue tree?" You raise an eyebrow. Somehow, you suspect Sauce can see the expression.

[i]You know, one of these sequences where you ask questions and we have short little exchanges before returning to the place where you decide what question to ask next,[/i] Sauce helpfully explains. [i]Though perhaps this structure doesn't look like a tree much. More like… a carrot? With the sprouts representing questions and the root representing the conversation's end.[/i]

"I admit, maybe there was some point to coming here," Marshal whispers into your ear. "Find out as much as you can, will you?"

[i]I can still hear you, Miss Riannon,[/i] Sauce points out. [i]If you want to ask a question, you are invited as well. Please step aside otherwise.[/i]

Marshal pouts. And lets you speak.

*temp saucer 2
*label sauce_start
*set saucer - 1
*choice
  *if saucer <= 0
    *disable_reuse #"Why do you refer to me as [i]${fake_name}[/i]? How do you even know that name?"
      [i]I know many things, in no small part thanks to my ability to see minds,[/i] Sauce casually replies. [i]And it only feels polite to use it. It's the most recent name you chose, after all.[/i]
      
      You tilt your head. "Does that really have significance? My friends usually just call me [i]Veteran[/i], whether I like it or not."
      
      [i]To me, yes. I would be somewhat offended if you called me 'Juice' in turn.[/i] Sauce tilts as well, in some strange parody of an actual gesture. [i]Or would you prefer If called you 'Veteran' too?[/i]
      
      *fake_choice
        #"Sure. It definitely sounds cooler than either of my actual names."
          *set name_sauce "Veteran"
          *set ManfredRel %+ 10
          "I've been saying that since forever!" Manfred suddenly exclaims. "My nicknames are simply the best."
          
          [i]Not sure if I agree, but will respect your Veteran's wishes.[/i] Sauce wiggles a little, in what you guess is supposed to be a nod. [i]Anything else?[/i]
        #"No, keep doing what you're doing. I don't mind."
          [i]Very well, I shall keep attuning with Saturn in hopes of ending time and destroying the world as we…[/i] Sauce pauses for a moment. [i]Oh, you meant using your pseudonym. I will continue doing that too, I suppose.[/i]
          
          "You know, I can't tell if that was a joke," Renfri says quietly. "Or if he's really that bad at conversing with people. And being sane."
          
          [i]Still audible, Miss Riannon. Still audible.[/i]
        #"Is there anything wrong with [i]${name}[/i]? It's my actual name."
          *set name_sauce name
          [i]I did not believe we were that familiar with one another already.[/i] There is a new, vaguely relaxed note in Sauce's telepathic voice. [i]I am glad to be proven wrong, as always. Do you have any other questions, ${name}?[/i]
      *goto sauce_start
  *disable_reuse #"What interest do you have in helping us?"
    [i]Do not think I have some hidden agenda, ${name_sauce},[/i] Sauce says with a hint of hurt. [i]I reveal answers and expand knowledge. Hidden motives are against my nature.[/i]
    
    "Then why?" you press the strange creature. "Why humor my questions, or our mission generally?"
    
    [i]Because I am bored. There is nothing to talk to, here in the depths of Saturn. Sometimes Link will visit me, but otherwise… Nothing to interact with can be found here.[/i]
    
    "The Federation sends subgiants here fairly regularly," Rook points out. "Besides, would it really be hard for you to simply rise further, towards the floating fortresses?"
    
    [i]I apologize for being unclear. I mean there's nothing [b]interesting[/b] to interact with. ${name_sauce} is an entity touched by the Shriek, with actual choices to make, variables to introduce to this equation of cause and effect. Even simple conversation with such a being is not an opportunity I'm eager to miss.[/i]
    
    "$!{pronoun}@{plural 're|'s} not the only one," Damon chimes in. "Me and my sister can hear the Shriek too."
    
    [i]You can hear the echoes of it,[/i] Sauce clarifies. [i]Not the song itself. Captain Link, at least, has been hearing those for a long time now. You and the person you call your sister are… simply not that special. Sorry.[/i]
    
    Damon pouts. But does not reply.
    
    *goto sauce_start
  *disable_reuse #"Tell me everything you know about Crystal."
    [i]It appears to be a diamond wyvern, perhaps seven hundred Terran years old, of standard size and lacking physical characteristics,[/i] Sauce lists out dutifully. [i]Possesses considerable armor and active camouflage powers, of course.[/i]
    
    "You can look into people's minds," Rook interjects. "Have you seen Crystal's? Have you perceived anything… interesting there?"
    
    [i]Crystal is indeed a Vessel for Dusk, if that's what you mean,[/i] Sauce says casually. [i]It is therefore blessed with telepathic powers similar to mine, albeit far weaker. And that's basically it.[/i]
    
    "You sound awfully uninterested in this Dusk-infused wyvern," Hellhound points out. "Does it really have no other special powers?"
    
    [i]You need to understand, Crystal is not using Dusk nanites to anything approaching their full potential. It resists the Shadow's temptations, only taking what it needs. Believing itself a stable Vessel.[/i]
    
    "You speak with contempt," you can't help but notice. "Would you rather Crystal become the willing servant of the Thing Beneath?"
    
    [i]It will. That wyvern is deceiving itself, merely delaying its inevitable fall. Fighting Dusk with willpower is like filling darkness with fog expecting to see, for the Thing Beneath is destiny in a world of choices and chance. The end and the death. You will see that yourself, ${name_sauce}, once you face your enemy proper.[/i]
    
    Well that's a pleasant thought.
    
    *goto sauce_start
  *disable_reuse #"So... how are you liking the depths of Saturn?"
    [i]Not much, if I can be perfectly honest.[/i] Sauce suddenly sounds much more saturnine. [i]It's mostly just layers upon layers of white hydrogen, helium and water ice. Dull, and quite polluted at that.[/i]
    
    "You are bothered by space debris?" Rook asks incredulously. "By a handful of metal scraps, compared to the grand volume of Saturn?"
    
    [i]I do not just mean physical detritus, or even the toxic fumes from your ship's engines. The spirit of Saturn, one I have long attempted to connect with, is corrupted by all the suffering experienced in its body. Every single floating fortress in this hemisphere is filled to the brim with terror, despair, hatred and pain. And then there's the Torment Nexus, which hardly makes the situation any better.[/i]
    
    "Great," Renfri groans loudly. "The most powerful being on this planet just happens to be an anti-nexite. Why is this madness literally everywhere?"
    
    *fake_choice
      #"Right. Don't be so preachy, Sauce."
        *set RenfriRel %+ 10
        *set RookRel %+ 5
        [i]You know, perhaps it's not the Nexus or physical waste that pollutes Saturn,[/i] Sauce says pensively. [i]Perhaps it is the sheer power of your obtuseness, so great it irradiates the planet like Sun's cancerous rays.[/i]
        
        "See? Again with the pretentious moral superiority." Marshal shakes her head with disgust. "Why can't anti-nexites just leave normal people alone?"
        
        "Do you like your feathers, Renfri?" Lisa suddenly asks. "Because annoying this mystical being is how you get plucked. Let's change the subject."
        
        You suppose you can agree to that.
      #"Does that mean you support the Torment Nexus?"
        "The Nexus is not something you support, really," Renfri explains. "It's just a normal, necessary part of life. Why would anyone be so crazy as to oppose its existence?"
        
        *goto scratch
      #"I'm against the Torment Nexus too, actually."
        *set RenfriRel %- 10
        *set RookRel %- 5
        "Of course you'd say that," the Kinnari fumes. "Why can't anti-nexites just shut up for once? Why do you need to constantly tell everyone you're against the Torment Nexus?"
        
        *label scratch
        
        You scratch your head. "Because it generates untold pain and misery whilst continuously polluting the planet? Despite, you know, not bringing any real benefit to anyone?"
        
        "Actually, disabling the Torment Nexus would cause Conglomerate stocks to go down by zero point seven percent," Rook chimes in. "Not to mention how all the nexite conservators would lose their jobs. It would all be terrible for the Kronian economy."
        
        "Thank you, Kirill," Renfri says with satisfaction. "Good to know we have some normal people around here."
        
        You leave that without comment.
    
    *goto sauce_start
  *disable_reuse #"What's your relationship with Captain Link and his pirates?"
    [i]Captain Link is one of the few interlocutors I have here, and pretty much the only interesting one. He's not quite as experienced or independent as you, ${name_sauce}, but he's an interesting fellow nonetheless.[/i]
    
    "Interesting and monstrous," Marshal argues. "He's a pirate. He kills and enslaves innocent people for a living."
    
    [i]Well, I never assisted in any of his operations,[/i] Sauce defends himself. [i]Not that there's anything wrong with slavery and piracy, of course.[/i]
    
    "I think there's a lot of wrong with these things, actually," Damon dares to speak up, following a moment of stunned silence. "Why would you say otherwise?"
    
    [i]Because I'm not a [b]presentist[/b], my dear android,[/i] Sauce smugly explains. [i]I would never judge historical figures by modern standards, that's just pretentious and silly.[/i]
    
    "But… they left less than ten minutes ago," Hadaly points out. "How are they historical figures?"
    
    [i]There is a timeline to these things, my other dear android. It is the year 990 of the present era, which means every atrocity in the books is alright by the standard of the times. Slavery will only start being mildly problematic some seven, eight centuries from now. Piracy will still be cool even then, and will only become evil in perhaps the twentieth century. Provided most pirates disappear, of course. If it stays common, it will stay alright, for only exceptional things can ever be wrong.[/i]
    
    "This may be the most idiotic thing I've ever heard," Renfri respectfully states. "Do you really believe that? Seriously?"
    
    [i]It is what humans believe,[/i] Sauce says unflinchingly. [i]They cannot be blamed for anything unless that thing is commonly banned and reviled. If slavery is allowed, then enslavers are morally good, and their society bears all the blame. If all societies are like that, then the fault lies with the times. Responsibility is always passed, never taken. The individual is always innocent, no matter how cruel, for the time itself is always the true villain.[/i]
    
    "And do you share those views?" you can't help but ask. "Or are you making some roundabout point?"
    
    Sauce does not reply to that question.
    *goto sauce_start
  *disable_reuse #"Can you please explain where you came from?"
    [i]From the depths of Saturn,[/i] Sauce replies quickly. [i]I thought you observed my arrival, ${name_sauce}.[/i]
    
    "Let me rephrase, then," you continue. "Where do you [i]originate[/i] from?"
    
    [i]From Ancient Earth. Much like everything else that's alive, synthetic or organic.[/i]
    
    *if Emotion < 50
      A less tranquil android would be really rather annoyed by now. 
    *else
      You clench one of your fists, struggling to keep annoyance out of your voice. 
    "I don't mean distant origins. Who built you, and when?"
    
    [i]Human scientists. I cannot remember them directly, but they were true ones, eager to explore distant planets. I'm still carrying on the mission they gave me, in a certain sense.[/i]
    
    "Saturn is not exactly a distant, unexplored planet," Rook points out. "Unless… Are you claiming to be a pre-Calamity device?"
    
    Sauce chuckles. It's a sound, or perhaps a thought, devoid of warmth that usually accompanies laughter. It feels ominous, or at the very least… mocking. [i]I may well be the oldest thing left in the System, other than the celestial bodies themselves. Allow me to leave it at that, human, lest I frighten you even further.[/i]
    
    Rook does not reply.
    
    *goto sauce_start
  *disable_reuse #"Where do you get your powers from? Are you a deity of some kind?"
    [i]Planets forbid,[/i] Sauce says with a cold chuckle. [i]I am nothing next to my patrons, or even lesser gods like the World Engines. You could call me a demigod, I suppose.[/i]
    
    "You have patrons greater than the Engines?" Renfri asks skeptically. "Were you blessed by the Emperor himself, then?"
    
    [i]Not the one you believe in, my dear. I was awakened by Jupiter, long centuries ago, and given power by his hand when it was still pristine. Now I am trying to contact Saturn, attune with him, understand yet another great god of the Solar System. Fruitlessly, for he will not respond to any of my signals.[/i]
    
    "Are you sure it… he is even able to respond?" Hadaly joins the conversation. "Because the idea of planets being sentient is… kinda insane, if I'm gonna be honest. No offense."
    
    [i]I heard the song of Jupiter, and I know the reason it stopped,[/i] Sauce says, with sadness rather than indignation. [i]It is the same fate which befell Gaia, long before even my creation. Humans corrupt the planets they inhabit, pollute their bodies as well as divine spirits. I only have decades, at most, before even the God of Time is silenced eternally.[/i]
    
    "Best of luck, then," Hellhound chimes in. "I feel barely any divine power here, but maybe you just need to descend deeper."
    
    "Lisa, do not mock our interlocutor," Kirill says, then frowns. "And do not tell me you actually believe planets to be divine."
    
    "Why not?" Marshal protests. "I mean, I never thought of them as gods, but it makes a good deal of sense. The Solar System is filled with deities, big and small. Some even say that the Sun is divine, so why not assume the same of gas giants?"
    
    "Because Solarism is derivative sham," Kirill says with contempt. "The Sun is just a star, and planets are just… planets. Worshiping them is pointless idolatry."
    
    "Yes Kirill, we all know how much of a monotheist you are," Hellhound says with a sigh, then turns towards you. "Care to solve the dispute, Veteran? You must know something about theology, having lived longer than most gods out there."
    
    *fake_choice
      #"I only know that I know nothing."
        *set LisaRel %- 10
        *set ManfredRel %+ 10
        *set Confid %- 10
        "Safe answer that offends nobody," Hellhound remarks. "I am ever-so-slightly disappointed."
        
        [i]Meanwhile, I admire the humility needed to admit such ignorance,[/i] Sauce says, once again with cheer. [i]But speaking of ignorance, is there any other way I can combat it?[/i]
      #"I agree with Renfri. Let's just add gas giants to our list of gods."
        *set RookRel %- 10
        *set RenfriRel %+ 15
        "My list is short, objective and quite sufficient," Rook says with a frown. "It consists of the one, true-"
        
        "We know!" Lisa exclaims irritably. "Can you please revere your messiah somewhere [i]away[/i] from this incredibly powerful non-believer? At least let ${name} finish asking ${subject} questions."
        
        Rook frowns even harder. But says nothing in response.
      #"I think Sauce knows what he's doing. He's clearly no stranger to divinity."
        *set RookRel %- 10
        *set RenfriRel %+ 10
        "He literally just admitted that his attunement is not working," Rook points out.
        
        [i]It will work eventually… hopefully…[/i] Sauce sighs, before returning to his upbeat tone. [i]But now is hardly the time for that discussion. Do you have any other questions, ${name_sauce}?[/i]
      #"Gods exist, but they're all human creations. Saturn sure as Cloud isn't one."
        *set RenfriRel %- 10
        "You're just close-minded," Renfri dismisses your answer. "And not as educated in theology as Lisa thinks."
        
        [i]Isn't that seen as desirable by your religion, Miss Riannon?[/i] Sauce asks innocently. [i]An open mind is like a fortress with its gates unbarred and unguarded, or so the Emperor once said.[/i]
        
        Renfri scowls. "Aren't we on the same side in this argument?"
        
        [i]There are no sides, only the truth. Speaking of, ${name_sauce}, would you like some more of it?[/i]
      #"There are no gods. Only creatures too powerful for their own good."
        *set RookRel %- 15
        *set RenfriRel %- 10
        *set Confid %+ 10
        [i]These are bold words to speak, especially in such a company as you have,[/i] Sauce neutrally remarks. Luckily I take no offense. [i]Still, if you may change the subject to something less controversial, I'd encourage you to do so.[/i]
    
    *goto sauce_start
  *if saucer > 0
    #"No. I'm not talking with a weirdo like you."
      *set ManfredRel %- 15
      *set RookRel %- 10
      *set RenfriRel %- 10
      Everyone in the room stares at you angrily, like you just insulted a divine entity capable of destroying your whole ship. Or something.
      
      [i]Oh. I understand.[/i] Sauce sounds genuinely heartbroken. [i]Would you prefer a more tangible boon, perhaps?[/i]
  *if saucer <= 0
    #"I think that's all I wanted to know."
      [i]Then I am glad to have satisfied your curiosity,[/i] Sauce replies cheerfully. [i]Would you like your fill of something else?[/i]

"What do you mean?" you ask, on your guard once again.

[i]I am no god, but… perhaps I can answer a single prayer. A single boon for a single android, to help ${pronoun2} on ${subject} perilous quest. What will you say to that, ${name_sauce}?[/i]

"Are you granting boons now?" you ask, more than a little surprised by the offer. "Like gods do for their chosen?"

[i]Quite unlike gods. I require no allegiance and offer no ascension. Just a single, permanent boost to your… What kind of power would you like?[/i]

"What is not divine must be demonic," Kirill murmurs beside you. "I would think twice about accepting this offer if I were you, ${fake_name}."

He has a point. When it comes to divine, or even quasi-divine beings, agreements and vows have power. A strange entity cruising around Saturn and offering free boons… It does sound awfully like a deal with the devil, if only a proverbial one.

*fake_choice
  #"I have no proof you're even capable of granting blessings."
    [i]And proof is exactly what I'm offering,[/i] Sauce replies, a little frustrated for once. [i]Just tell me what you want. Or refuse, if you don't like the idea that much.[/i]
  #"And you don't want anything in return?"
    [i]Not a single thing,[/i] Sauce confirms. [i]Other than gratitude, perhaps.[/i]
    
    "Not even a soul?" Hellhound asks. "Because if you accept those, then I may have some requests to-"
    
    [i]One client at a time,[/i] Sauce rules. [i]What will it be, ${name_sauce}?[/i]
  #"Elaborate. What exactly can you offer me?"
    [i]Think about an ability of yours,[/i] Sauce commands. [i]Either a weakness, or some skill you wish to absolutely master. I will make sure you see significant improvements in that area, with only minor side effects at worst.[/i]
  #"No. I want nothing from you."
    *goto refusal_sauce

You consider your skills, wondering which ones could use a supernatural boost. Your combat skills, your intellect, your charisma… Or perhaps you'll convince Sauce to grant you some brand new, special power. Somehow.

*set sauce_bless true
*label s_wish
*choice
  *disable_reuse #"Can you make the screams stop? Please?"
    *set deflect - 2
    [i]Not quite the request I expected,[/i] Sauce floats a little closer to your ship. [i]Do you want me to shield you from the Shriek's echoes? Because this would be neither easy, nor terribly beneficial in the long run.[/i]
    
    "Not exactly…" You're not sure what you want yourself. Peace, that's the final goal, but how can you achieve such a thing? "Can you maybe take away the memories? The old ones, those of the War In Heaven and… the events that preceded it."
    
    [i]Those memories make you the entity you are, Veteran,[/i] Sauce says sadly. [i]I cannot remove them. It would weaken you too much.[/i]
    
    "Why do you care about my strength?" There is disappointment, bitterness, a trace of anger in your voice. "Do you need me for something? Or is it just an excuse to leave me suffering?"
    
    Sauce does not reply. 
    *if (DamonRel >= HadalyRel) and (DamonRel >= LisaRel)
      Damon places his large, cold hand 
    *if (LisaRel >= HadalyRel) and (LisaRel >= DamonRel)
      Lisa places her small, warm hand 
    *if (HadalyRel >= DamonRel) and (HadalyRel >= LisaRel)
      You feel a small electric discharge as Hadaly places a hand 
    on your shoulder. It offers little comfort, but… it's something, you suppose.
    
    You shake your head, letting go of your silly forlorn hopes. Letting go of your past is impossible, and it would hardly help the mission anyway. You should ask for something tangible, for power rather than some petty shadow of happiness.
    
    *goto s_wish
  #"I want raw strength and resilience."
    *set Build + 40
    *if Build > 99
      *set Build 99
    [i]If brute strength isn't working then you're not using enough of it,[/i] Sauce remarks wisely. [i]Let me fill you with the stuff, then.[/i]
    
    Before you can reply, your muscles all contort to a degree you didn't think possible. They hurt, truly hurt, the degree of pain you only feel when your whole body is being torn open and reassembled. And maybe it is, perhaps you're being rebuilt inside, you can't tell, you can only hurt and writhe on the floor and scream…
    
    It ends after several seconds, the pain passing suddenly and completely. When you stand up, you don't even feel stiff or sore. You just feel… stronger.
    
    [i]Here we go,[/i] Sauce says cheerfully. [i]I fixed all the issues with your frame and mechanical subsystems. You should be back to your old level of strength, or at least nearly so.[/i]
  #"I want to be quicker. More agile. More perceptive."
    *set Calculation + 40
    *if Calculation > 99
      *set Calculation 99
    [i]Three requests, all fulfilled with a single spell,[/i] Sauce says cheerfully. [i]Now hold on, I will adjust your perception of time.[/i]
    
    Before you can inquire what Sauce actually means, your body freezes for no apparent reason. No, that's not true; Everything stands still, all your teammates as motionless as you are. The lights on the consoles stop blinking, air turns silent as its vibrations cease, even your internal clock is basically paused now. Only your thoughts, as though removed from time, are allowed to progress at their normal pace… or perhaps, what is likelier, they've just been sped up by several orders of magnitude.
    
    You cannot move anything. You cannot change anything. You cannot communicate. You can only… think.
    
    *page_break Hours Pass
    
    You spend what feels like days in that one, frozen moment, before time is allowed to resume. Your expression turns into that of horror, and then of immediate relief, surprising the people around you. They say something, Hadaly does and so does Rook, but you are too busy finally moving your limbs to pay them any attention.
    
    [i]Sorry, I got a little overboard at first, had to adjust the distortion,[/i] Sauce hurries to say, though his words still feel dragged out somehow. [i]Either way, the gift has been delivered.[/i]
    
    He's right. You run a few diagnostics, and all computations—including those very diagnostics—run significantly faster than before. Your reflexes are now almost as good as they were during the War In Heaven. You're not entirely sure how that will impact your actual speed and agility, but you should have chances to find out in the not-so-distant future.
    
  #"I want wisdom. Intelligence. Knowledge."
    *set Database + 40
    *if Database > 99
      *set Database 99
    [i]Wisdom is just a word, intelligence is not something to be granted freely,[/i] Sauce says disapprovingly. [i]But as for knowledge… I suppose I was built to grant it. Hold on.[/i]
    
    And then, in some inexplicable manner, your mind starts to expand. New data appears, sometimes on the empty space of your drives, sometimes replacing less precise and accurate entries. You no longer know the approximate sizes of the planets, of stars, of mathematical and physical constants. You know them exactly, to the billionth decimal, you know all there is to know-
    
    [b]No![/b]
    
    It can't be. reality cannot possibly be that cruel. But it is, undeniably, clearly and horrifically, true. You need to terminate yourself, to save yourself from that knowledge, but even that won't change the most the most the most-
    
    And then it passes and you find yourself on your knees, sane and ignorant again. You forgot… something, some awful truth that caused you so much pain. What it could have been, you have no clue. Just a profound conviction that you're grateful not to know.
    
    [i]Oops, I went a little overboard there,[/i] Sauce says ashamedly. [i]I shouldn't have revealed that particular fact about the nature of existence. Hopefully your increased database won't lead you to it again.[/i]
  #"I want power. Actual, measurable, electric power."
    *set Projection + 40
    *if Projection > 99
      *set Projection 99
    *set battery 99
    [i]I love such straight-forward requests![/i] Sauce exclaims. [i]Let me share my energy supply with you, then.[/i]
    
    There is no lightning, no thunder, certainly no stable flow of electrons between two bodies. And yet, your battery is instantly filled, at a thousand times the ordinary rate. You feel invigorated… strong… overflowing… pained…
    
    Every single circuit of yours is overcharged, full of power it cannot handle. Your processors are flaring madly, as though trying to waste a fraction of the excess energy. But it's not enough, it all turns into heat and pain, pain and heat, knowledge you're about to go out, burst open, die from this endless searing-
    
    And then it stops. You realize you're on the floor, having only stopped writhing helplessly this very second. Everyone around you seems concerned, almost everyone is saying something, but all this… buzzing in your ears prevents you from really hearing anything.
    
    [i]Here, that should provide a constant boost to your energy projection.[/i] And yet, Sauce's voice is as audible as ever. [i]No need to thank me.[/i]
    
  #"I want to control people with words alone."
    *set Social + 40
    *if Social > 99
      *set Social 99
    [i]You are truly a machine made in the likeness of a man,[/i] Sauce says musingly. [i]But I shall grant your wish all the same.[/i]
    
    Suddenly, your vision of the world gets twisted and turned, expanded and narrowed. The creatures around you are no longer people, they are lines. Lines of code, lines of DNA, lines of dialogue above all. Something to interact with, influence and manipulate, but never connect with. They are beneath you, and everything above them… is void. One unworthy of a single thought, for hierarchy is all that matters, and dominance is the only thing worth pursuit.
    
    It is emptiness. It is horror. It is truth. Hell is other people, and hell is empty. Not a single caress will ever feel warm, not a single compliment honest. There is no love, no friendship, no empathy and no sympathy, just games played for mates and for power. You understand it, you see it now, and you will never belong to anyone ever-
    
    And then it passes, and things return to normal. You are once again surrounded by teammates, perhaps friends, definitely people. But you feel, somehow, that your ability to influence them has just increased greatly.
    
    [i]And there is that,[/i] Sauce announces. [i]Hopefully your desire for social power hasn't cause you too much pain.[/i]
    
  *if Misan > 55
    *disable_reuse #"I want all humans everywhere to drop dead."
      *set Misan %+ 20
      *set RookRel %- 15
      *set RenfriRel %- 15
      *set LisaRel %- 15
      The three humans in the room stare at you with surprise, anger and concern. None of them drops dead.
      
      [i]That is… not the kind of boon I just offered,[/i] Sauce says after a moment of silence. [i]I'm proposing to enhance of your abilities, not commit a system-wide genocide.[/i]
      
      "Oh come on," you say pleadingly. "Can't you bend the rules a little? Just this once, for me?"
      
      [i]Sorry, but I'm not sure killing all humans everywhere would be entirely ethical,[/i] Sauce cruelly rejects your request. [i]Not that I have that sort of power, anyway.[/i]
      
      Worth a try, you suppose.
      *goto s_wish
  *if Misan < 45
    *disable_reuse #Can you make me... real?"
      *set Misan %- 20
      *set RenfriRel %+ 10
      *set DamonRel %+ 10
      *set HadalyRel %- 10
      [i]An ambiguous, as well as somewhat worrisome request,[/i] Sauce says concernedly. [i]Did you perhaps mean 'human' rather than 'real'?[/i]
      
      You shrug. You don't know if Sauce even sees the gesture, but you don't want to appear too… desperate before your teammates. "I'm synthetic, am I not? Just make me organic, make me… feel. Taste. Smell. All that."
      
      Make you into a real @{(pronoun = "she") girl|boy}. Cloud, you sound so pathetic, you know that, but still… You can't let a chance like that pass you by.
      
      [i]My powers are not precise, nor omnifarious enough to make an android human,[/i] Sauce says slowly. [i]I could possibly expand your range of senses… but that wouldn't solve the underlying issue.[/i]
      
      "It would alleviate it," you argue. "It would make me more-"
      
      [i]No. The issue is not what you are, or even what you want to be, but what you feel you must become. You need to learn your worth, a different kind of value than what your creators had in mind. And that, my friend, I cannot help you with.[/i]
      
      Oh well. Such is life. Or whatever parody of it your circuits, pumps and processors represent. You just have to bear it.
      
      *if RenfriRel > 50
        "Well… you look fairly real to me," Renfri says, meekly and unexpectedly. "Not human, obviously… But hardly fake either. You're just your own thing."
        
        "I never thought I'd hear you saying that," Damon chimes in. "Are you warming up to our kind, Marshal?"
        
        Renfri glances away. She does not reply. You know the answer anyway.
      *elseif LisaRel > 50
        "Lighten up, android pal," Lisa suddenly says. "Our new friend might be weird, but he's also right. You [i]are[/i] real, in every way that matters."
        
        You do not reply. You have a wish to make.
      *elseif RookRel > 50
        "You do look fairly real to me," Rook says uncertainly. "I hope that information helps you, however much it can."
      
      *goto s_wish
  *disable_reuse #"Do you have some form of... foresight? Can you tell me the future?"
    [i]Yes and no,[/i] Sauce replies without hesitation. [i]Predicting the future is possible, to a degree, even when you're not a god. But few things are truly set in stone.[/i]
    
    "Because of free will?" you inquire. "Or random fluctuations on a quantum level?"
    
    [i]Both of these, and more. There are beings far higher than myself interfering with the events, subverting the chain of cause and effect, treating your hunt for Crystal as a… game of sorts. The outcome of which is impossible to determine.[/i]
    
    "So… no telling the future, then?"
    
    [i]I could give you a rough estimate, or tell you about a handful of fixed points, like what awaits you above Janus or inside Rhea. But I think it will be more fair if I grant you a direct, certain boon instead.[/i]
    
    *goto s_wish
  #"No. I will complete the mission with my strength alone."
    *label refusal_sauce
    *set sauce_bless false
    [i]I suppose there is something respectable about your attitude,[/i] Sauce says with a thought that sounds like a sigh. If that makes any sense. [i]To be perfectly honest, I hoped for a chance to show off. But have it your way.[/i]

"Are we done here?" Kirill suddenly asks. "Because I confess to not being entirely comfortable with what is happening here."

[i]Indeed, I can't think of anything else we could do together,[/i] Sauce says, a hint of sadness in his ethereal voice. [i]Besides, I need to resume the attunement process. Saturn will not wait forever.[/i]


*if progress != 7
  *goto sauce_cont_n
You'd breathe a sigh of relief, if you had lungs. 
*if crystal_friend
  Because you just realized something.
*else
  And if not for a realization you, and likely the rest of the team, has at this very moment.

*page_break It's Over

"So that's it?" Damon says what you're all thinking. "Our last track. We came here to find Crystal, but found something unrelated to… anything, really. Does that mean…"

"Admiral's patience has been wearing thin," Rook says grimly. "When he hears about our lack of results… Yes, I think the mission is over."

*label before_point

"Hey, we can still…" Renfri pauses, no doubt trying to think up some new location, some new method of catching the wyvern. She comes up short. "Fuck."


*fake_choice
  #"What does that mean for our alliance? Should we start fighting now?"
    "Can we not?" Hadaly suggests. "It may be just me, but I don't imagine it ending up well."
    
    "Agreed," Kirill sighs deeply. "Not that there is any need for it. Admiral West will allow your group some time, enough to leave your fortress unharmed. After that… Hopefully someone else will be sent to hunt you down. Not us."
  #"Come on guys. There has to be another way."
    "For all we know, Crystal already absorbed all the Dusk it ever wanted," Kirill says gloomily. "It defeated us in ${first_mission}, then in ${second_mission}, and now… there is nothing left."
  #"That's... weirdly anticlimactic."
    "Tell me about it," Hellhound groans. "I wasn't invested in this hunt at all, but I still hoped it would end in some epic, violent finale. Not like this."
  #"Somehow, I always knew it would end this way."
    "Could have told us," Marshal murmurs. "Not that it would have made a difference."
  #"Maybe the real wyvern was the friends we made along the way."
    "Shut the fuck up," Marshal makes a demand. "Whatever friendships we made will be lost now. Your bunch will return to being fugitives. And we'll probably get demoted to handling traffic violations."

*if saturn_path = "pirates"
  *return


[i]That's so sad,[/i] Sauce says pityingly. [i]You know what? I changed my mind. I'll help you directly if it alleviates your pain.[/i]

Rook perks up, hope returning. "Will you help us kill Crystal?"

[i]Not directly, I'm no killer. But I can give you the chance. I can arrange that final battle you so desire.[/i]

"What!?" Manfred exclaims suddenly. "I just… you just… we have another point on the radar. One the ship immediately began tracking."

[i]And that is my final gift to you. The current location of the one you call Crystal. This spell should allow you to track it for the next two Saturnian days, or a full Terran day if you're lucky.[/i]

*label the_point

Rook's fists clench. "And where is that, currently?"

"A Ring," Manfred says tensely. "As in, the outermost ring of Saturn. I can give you the exact coordinates if it matters."

"Good thing it doesn't," Marshal says excitedly. "The distance stays the same. We can reach the outer edge [i]today[/i] if we hurry."

"And Crystal will have an empty void as its only escape route," Damon adds neutrally. "I have to admit… That's a pretty great opportunity."

*if crystal_friend
  Oh fuck.

*fake_choice
  *if Database > 40
    #"Actually, there are some moons bordering the A Ring."
      "Then I will notify the Kronian Fleet and tell them to guard these moons." 
      *goto padadskla
  #"Well then... what are we waiting for?"
    "For me to call the Kronian Fleet." 
    *goto padadskla
  *if crystal_friend
    #"No it's not, shut the fuck up."
      *set DamonRel %- 10
      *set RookRel %- 5
      *set RenfriRel %- 5
      For better or worse, everyone seems to ignore your protest. Your frustration at seeing how your sabotage went nowhere. Delightful.
      
      *goto ipoadpo
  #"A great opportunity to become wyvern food at last."
    "Optimistic as always." Renfri rolls her eyes. "A ball of sunshine bigger than Wisp."
    
    "$!{pronoun}@{plural 're|'s} right, you know?" Hadaly comes to your defense. "Regardless of our position, Crystal will be a huge challenge for this little ship."
    
    "That's why I'm notifying the authorities." 
    *goto padadskla
  #"Rook, can you notify the federate authorities?"
    "Was just thinking about it." 
    *goto padadskla
  *if (saturn_path = "sauce") #"Sauce, you are a true life-saver."
    [i]Actually, I believe I'm the opposite,[/i] Sauce says grimly. [i]But you are welcome.[/i]
    
    *label ipoadpo
    "I will tell West, or whoever picks up our signal, of our findings." 
    *label padadskla
    Kirill hurries towards the cockpit. "Even if they only send a ship or two, we will have an overwhelming advantage over Crystal."

"Are you sure about that?" Marshal questions. "Calling for support, I mean. Do we really want them… you know…"

"Stealing our kill?" Hellhound finishes the sentence. "Or the glory that comes with it?"

"I'm just being proper here," the Kinnari huffs. "Do we really need to burden someone else with [i]our[/i] mission?"

*fake_choice
  #"Shut up, Marshal. We need all the firepower we can get."
    *set RenfriRel %- 10
    "I take issue with the language, but ${pronoun} @{plural are|is} right." Kirill stops at the doorstep just to meet his teammate in the eye. "Our careers both depend on this, Renfri. Let us be safe rather than sorry."
  #"There's nothing wrong with wanting glory, Hellhound."
    *set RenfriRel %+ 5
    *set LisaRel %- 5
    "Not saying there is…" Lisa rolls her eyes. "Just that coming at Crystal alone is a stupid idea."
    
    "For once, I agree with our resident werewolf." Kirill stops at the doorstep just to meet Renfri in the eye. "We will all get the credit we deserve. I promise."
  #"I think you all [i]seriously[/i] underestimate Crystal right now."
    *set RenfriRel %- 5
    *set HadalyRel %+ 5
    *set Confid %- 10
    "Are you saying we can't kill that thing even with armed support?" Renfri glowers at you. "That's just-"
    
    "$!{subject} concern is justified, Marshal." Kirill stops at the doorstep just to meet Renfri in the eye. "Our careers both depend on this. Let us be safe rather than sorry."
  #Stay silent.
    "Yes, we do," Kirill answers Renfri's question. "Our careers both depend on this, Renfri. Let us hit Crystal with [i]everything[/i] we have."

Marshal bites her lip and nods. Hadaly lets out a tired sigh. Damon's eyes are inscrutable as they watch Kirill disappear behind the cockpit door.

Everyone has strong feelings about this last-minute twist, it seems. About the approaching battle. Including yourself.

*fake_choice
  *selectable_if (Violence > 50) #[i]Time for glorious combat to commence.[/i]
    *set Violence %+ 20
    Time to engage your enemy. Time to fire the projectiles stashed aboard your ship. Time to test its engines, Manfred's abilities, everyone's will to win. But most importantly…
  *selectable_if (Confid < 50) #[i]We're gonna fucking die...[/i]
    *set Confid %- 15
    Your teammates are blind to the threat Crystal, the strongest Vessel on record, poses. There's no way you can win; The best you can hope for is to ensure you, and your friends, all come out of this fiasco alive.
  *if crystal_friend
    #[i]I need to save Crystal. I need to pull it off somehow.[/i]
      So far, your attempts at helping the wyvern have been minor, and apparently ineffective. Now you need to ensure, truly make sure that this team of clowns doesn't kill the strongest Vessel this world has.
  *selectable_if ((Emotion-Confid) > 0) #I'm a bundle of nerves, despite not having a nervous system.
    Despite everything you've done and seen, this mission is simply too much. Too much danger, too much uncertainty. Luckily, you won't have to battle these feelings much longer.
  #I'm just glad it's almost over.
    This mission went on for more than enough. Your patience, you nerves, your battery, everything is wearing thin.
  *selectable_if (Emotion < 50) #Actually, no. I feel nothing.
    *set Emotion %- 20
    You were always a tranquil person, a calm machine. You need to remain so now, as a cool head will be invaluable in hours to come.

Time to get this all over with.


*goto saturn_over



*label sauce_cont_n
*fake_choice
  #"Before you go... Is there any way for us to stay in touch?"
    [i]I will observe you from a distance, ${name_sauce},[/i] Sauce assures you. [i]And rooting for you, whether or I'll be able to intervene directly.[/i]
    
    "From the depths of Saturn?" You cock an eyebrow. "I know you're powerful, but is your vision really that good?"
    
    [i]The gods are all watching you, Veteran. I shall be looking through their eyes. Goodbye.[/i]
  #"Are you sure? There are other ways you could assist our hunt."
    [i]There are not,[/i] Sauce says with sudden graveness. [i]A mind far greater than mine observes the proceedings. It agreed to this meeting, as I made our conversation amusing, but it may not be defied. Not by me, at the very least.[/i]
    
    "What is this mind, then?" You have a bad feeling about this. "And do you expect me to defy it?"
    
    [i]You have a better chance than I do, Veteran. Goodbye.[/i]
  *if not (sauce_bless)
    #"Just to be clear, you're not angry that I rejected your boon?"
      [i]I may be a little bitter,[/i] Sauce reluctantly admits. But my admiration is equally true. [i]And if you can survive what's to come without any divine assistance… Perhaps I will end up attuning to you. Veteran.[/i]
  #"Sure. Good luck with your... attunement."
    [i]Thank you, for I will need it,[/i] Sauce says with a small movement, possibly a nod. [i]My time is short. Shorter still if you fail. Goodbye, Veteran.[/i]
  *if sauce_bless
    #"Thanks for the blessing. And goodbye."
      [i]May Saturn be with you, ${name_sauce}.[/i] Sauce says solemnly. [i]For my blessing may not be enough for what is to come.[/i]
    #"Fuck. You didn't tell me your blessing would feel... like that."
      [i]There is no power without pain, it seems,[/i] Sauce says half-apologetically. [i]Put what I've given you to good use, ${name_sauce}. Goodbye.[/i]

The screen is then filled with white light. The hydrogen sea already seemed perfectly white, but now it somehow looks even brighter, even more pristine. When it returns to its old, comparatively faded color, Sauce is nowhere to be seen.

"Moving away from us at mach eleven," Manfred notes with barely hidden relief. "And accelerating. Downwards."

"I'd say he will hit the core and die… But it's not like logic applies to that atrocity," Marshal says, right before sighing deeply. "Almost makes me wish this were a trap."

*fake_choice
  #"Should we return home now? We've been under hydrogen for far too long."
    "Seconded," Rook says tiredly. "Manfred, set course to our base. We're leaving the Expanse, and hopefully never coming back."
  *if sauce_bless
    #"I can feel his divinity inside me. He will not die."
      "What does that even mean?" Hadaly asks, putting a hand on your cheek as though checking the temperature. "Should I run maintenance? See what this thing actually did, whether it messed with your mind or-"
      
      "Easy there, team mom," Hellhound interrupts. "$!{pronoun} just @{plural feel|feels} divine presence, the continuity of its existence. It's normal, at least for freaks like us."
      
      "There's nothing freakish about some minor meta-powers," the winged woman beside the werewolf says. She then turns towards the nearest console. "Manfred, can you get us out here?"
  #"Come on now. He wasn't that bad."
    "Maybe not towards you," Marshal mutters. "I felt its… malice. Directed solely towards me. It unnerved me."
    
    "Well you were pretty rude towards him in return," Hellhound points out. "At least use its chosen pronouns. Fuck."
  #"Yeah, this meeting was... somewhat nerve-wrecking."
    "I think we all had enough nerves for today," Damon concurs. "So how about we leave this place and never return? Just an idea."

"I'm booting up the engines," Manfred states, accompanied by the familiar sound coming from the ship's rear end. "We should reach [i]Saturn Nine[/i] within… ten hours? Calculations get difficult at this depth."

"Many things get difficult at this depth," Rook massages his whole face as he speaks. "But at least this part of the mission is over, and we've accomplished something thanks to our daring decisions."

"Not much though," Hellhound makes a polite comment. "We haven't progressed the hunt in any way, despite having wasted two whole weeks here. We only found a pirate ship, that we then let go of, and a weird magic space probe those pirates pointed us to. Which will look really bad on whatever report we end up writing."

Rook frowns. "You were the one who suggested coming here, Lisa."

She smiles brightly. "Okay then, I'll tell West how you're now listening to my ideas, as well as ${name}'s, instead of making any decisions yourself. I'm sure he'll be delighted to hear how great of a leader you are, Sergeant Kosteniuk."

Sergeant Kosteniuk does not grace that with a response.


*goto saturn_over

*label leave_mission
*set RookRel %+15
*set ArmyRel %+ 10
*set RenfriRel %-15
*set LisaRel %- 10
*set HadalyRel %+ 10
*set ManfredRel %+ 10
*set Confid %- 10
*set Violence %- 10
*set saturn_path "left"

"So we just wasted two weeks in this place, only to turn tails the moment danger arrives?" Marshal scoffs at your choice. "Amazing."

"${name} simply has ${subject} priorities straight," Hadaly says. "Make peace, not war. You heard that, Manfred?"

"I will inform [i]Ocarina[/i] of our decision," Manfred says dutifully. "Unless… Veteran, would you like to give Captain Link the news yourself? Should I unpause the connection?"

*fake_choice
  #"No, just send them a text message or something."
    *if progress = 7
      "Alright, I'll write something up real…" Manfred pauses. "Huh. They reconnected out of their own accord. I'll put them through."
      
      Manfred's voice is replaced by Link's. "${name}. Have you made your decision already? Because I'm starting to think you need an incentive."
      
      You shrug. "What incentive are we talking about?"
      
      *goto leave_7
    In a way, the silence that follows is full of doubt. Whether you made the right choice, both right now and in refusing to fight the pirates in the first place. Luckily, Manfred breaks this quietude soon enough. "I got a reply. They say we may go and that they wish us happy boating. Or he says, rather."
    
    "I guess there's no point staying here, then," Hellhound remarks. "Thanks for preventing anything fun from happening today, ${name}."

    *goto leaving_saturn
  #"Yes please. I have some other things to say while I'm at it."
    "I figured as much," Manfred remarks, 
  #"Yeah, I'll save you a bit of work."
    "I will pretend that is indeed your reason for accepting the offer," Manfred says cheerfully, 
right before re-connecting with [i]Ocarina[/i] and falling silent. A few seconds later, Captain Link once again speaks from his vessel.

"Well?" There is some annoyance in his voice, but perhaps some trepidation too. "Has your group reached consensus already?"

"[i]Consensus[/i] is a strong word." You wince, fully aware that you still have an angry Kinnari in the room. "But we decided to leave this place at once. If you will allow it."

"Of course I will," Link sounds relieved. 
*if ((beaten_link) or (lost_link))
  "Though I have to say, forgoing a battle seems… unlikely of you. Had a chance of heart since I last saw you?"
  
  *fake_choice
    #"I simply value the lives of my crew."
      "Valuing human lives certainly seems new for you… but I suppose that's yet another effect of time," Link says with sadness, perhaps disapproval. 
    *if Violence > 50
      #"I'm still pretty violent. Just not towards you."
        "I hope you find a good target for your violent urges soon, then," Link says with some amusement. 
    *if beaten_link
      #"I already know I can beat you. Better to save my strength for tougher opponents."
        *if told_crystal
          "I think those opponents may prove [i]too[/i] tough, considering what kind of game you're hunting," 
        *if not (told_crystal)
          "I'm suddenly glad not to know what exactly you are hunting," 
        Captain Link remarks. 
    *if lost_link
      #"You kicking my ass made me rethink my life choices, yes."
        "Glad to know I did one thing right," Link says, presumably with a jestful smile. 
    #"Yeah. I've had a lot of time to reflect since then."
      "You are pretty ancient, yes," Link says amusedly. "You must be so much wiser than I, having that much more time to muse."
      
      "Aren't you like, nine hundred and sixty?" you point out.
      
      "Nine hundred and fifty-eight. Basically fresh from the factory line." At this moment, his voice turns serious again. Sad. 
    #"I've always been wary of violence. You were just an exception to the rule."
      "Good to know I'm no longer an exception," Captain Link remarks. 
  "Godspeed, ${name}. Perhaps we'll see each other again, one day."
*else
  "Though it's a shame you decided against meeting my semi-divine friend. Do I sense some distrust there?"
  
  *fake_choice
    *if told_crystal
      #"I just don't have the time. Our actual target is too important."
        "Makes a degree of sense," Link concedes. "Diamond wyverns are some of the toughest things to crack out there. I wish you luck hunting one, ${name}."
    #"Not of you. I'm just wary of strange, vaguely divine beings like the one you described."
      "This one isn't much to be wary of," Link argues.
      
      "How would I know? You didn't tell me that much about… whatever that thing even is."
      
      *goto jjjj
    #"Well you're still not telling me what your mysterious friend actually is..."
      *label jjjj
      "Perhaps it wouldn't hurt to tell you after all…" Link says musingly. "You know how, before Dawn, humans used to send space probes to other planets instead of going there themselves? Well, one such probe became… empowered by Saturn, I suppose. Turned into a deity's chosen, much like the thing I used to be."
      
      "Empowered space probe?" You cock an eyebrow. "You're still not making much sense. I still don't understand."
      
      "Perhaps in another life, you will. Until then… Captain Link out."
    #"You should. I do not trust you one bit."
      "You don't have to," Link says sadly. "For it is unlikely of us to ever meet again. Goodbye."

*if progress = 7
  But then he hesitates. He doesn't close the channel and instead says: 
  *goto leave_7

And then he disconnects. Manfred turns off the speakers, knowing they are unlikely to see any more use today.

"Looks like ${name}'s diplomatic connections and skills just ensured our continued survival," Kirill loudly remarks. "Thank you for that, friend."

*label leaving_saturn

"You're welcome," you murmur. "Now let's adjust our thrusters. The sooner we get home, the better."

Link honors the promise he made. When your ship turns and flies off, the laser lances of [i]Ocarina[/i] do not fire. Not that it matters for long, as you soon leave the combat range of such a vessel, increasing the distance to a hundred, than three hundred, than a thousand kilometers. You have a floating fortress to reach, and you won't find it in this empty expanse.

Hopefully West won't mind hearing how you wasted two whole weeks here. And if he does… hopefully the guys back home won't suffer for it.

*goto saturn_over

*label leave_7
*if told_crystal
  "That wyvern you are hunting… I know how you can find it. At this very moment."
*else
  "Does your mission have anything to do with wyverns, perhaps?"
  
  "Perhaps," you say noncommittally. "What of it?"
  
  "Because I know where you can find one."

"Really?" Marshal blurts out. "I mean… I won't say we're [i]not[/i] interested."

*temp not_need false

*fake_choice
  #"Yes. Please help us."
    "Never thought I'd hear you so desperate, ${name}." You imagine Link smirking. "Good thing I installed that tracker."
  #"I don't need anything from you."
    *set not_need true
    "Nothing?" Link asks sadly. "Well then, I won't tell you about the tracker I installed."
  #"How? How can a group of pirates have that knowledge?"
    "We are a high-tech group of pirates," Link says proudly. "And we know how to plant a tracker."
  *if not (told_crystal)
    #"Depends. What kind of wyvern are we talking about?"
      "A diamond one," Captain Link replies. "The one we put a tracker on."
    #"Fine, you win. How much do you know about Crystal."
      Link chuckles. "Not much. That's why we put a tracker on it."
  *if told_crystal
    #"Why didn't you tell us sooner?"
      "I considered it," Link explains himself. "But I wasn't sure if the tracker even worked."

"Can you elaborate?" Rook perks up. "You inserted a tracker into Crystal's body?"

"A quantum one," Link explains. "Both in terms of size and function. Allows us to track the beast real-time, save for the light lag. Which currently isn't that big."

*fake_choice
  #"Guys, should we really trust this pirate?"
    "It's not like we have much of a choice, do we?" 
  *if not_need
    #"I already told you, we want nothing from you."
      *if RenfriRel > 50
        "With all due respect, ${name}, shut the fuck up," 
      *else
        "Shut the fuck up, android," 
  #"How come it didn't notice?"
    "As I said, it is a pretty microscopic little tracking bug," Captain Link explains. "And it's not like wyverns spend much time inspecting their bodies. Checkups aren't necessary if you have their regeneration factor."
    
    *goto technic
  #"You planted one of these things on a wyvern? Impressive."
    "I am almost as old as you," Captain Link says proudly. "I know a lot about clarketech, I even still have some lying around. Such as those smart, self-burying tracking bugs."
    
    *goto technic
  #Say nothing.
    *label technic
    "We're not interested in the technicals," 
Marshal says irritably. "Pirate, give us Crystal's coordinates now. Or else."

"I'd normally take exception to being threatened, but time is of essence right now." Link pauses for a few seconds, as though typing something on the console. "Here. You may want to check out this location soon, before your prey moves."

"I got the coordinates," Manfred confirms. "And… wow, that tracker must be good. The readings are rather precise, despite the large distance."

*goto the_point




*label saturn_over
*set last_mission "saturn"
*set saturn_complete true
*page_break Next Chapter
*if progress = 5
  *gosub_scene interlude_1
*if progress = 6
  *gosub_scene interlude_2
*if progress > 6
  *gosub_scene janus