*set health 3
*set weapon_av true
*set progress + 1
*set battery 80
*set armored false
*temp cur_plan 1
*temp on_time false
*temp started_battle false
*temp androids_revealed false
*temp got_money false


*image h10.png

[b]February 19th, 990 AC[/b]

[b]T-plus 521974848 minutes[/b]

Rhea looks basically how you remember it, how you left the massive moon six weeks ago. Grey sidewalks bordering grey asphalt, all covered in grey dust and grey trash, in the shadow of grand grey buildings. The only bright or pristine thing is Tanit, the World Engine, the artificial sun shining in the moon's center high above. But even she's getting dimmer, slowly dying as day grows old and night approaches.

You are getting close to your deadline. Luckily you're on your way and… 
*if HadalyRel > 50
  as horrible as it feels to even think that… 
the delivery is with you.

"We should take this train," Hadaly points at the railroad car of a battered, grey passenger train that's about to leave the station. "I mean, we could. I'm not telling anyone to do anything, it's just that I know this place arguably-"

"Yes sis, you know the place and you're right," Damon interrupts, his voice tired and morose. "Let's just walk in. I'm pretty sure the ticket inspector is too sleep-deprived to care."

You're currently headed to Sholmo City, and decided to use a train for transportation. You did not fly there directly—your shuttle is currently parked in the Toro Spaceport—for fear of being arrested upon landing. For fear that Hammon wasn't about to keep his word and politely wait for you in his headquarters.

There was much debate, back on [i]Saturn Nine[/i], on whether you should trust anything Executive Hammon said, give him something he wants. @{org_alive Olivia wanted to just beat him up, naturally, but the others were more cautious and pragmatic about the whole thing.|Sheila and Manfred believed so.} They recognized that the Conglomerate is a force you cannot possibly stand against, and that Hammon has significant control over it. That openly defying him, at least right away, would mean the death of you. 
*if federate_protection
  Or at the very least exile from the cozy fortress you fought so hard to keep.

As for you…

*fake_choice
  #I agreed with the majority. We just couldn't defy a High Executive.
    *set ManfredRel %+ 5
    *set OrganRel %+ 5
    You were blatantly right, to the point where Hadaly herself agreed. You have no other choice but to humor Hammon's demands, at least to the point of meeting him face to face.
  *if federate_protection
    #I advocated for taking a stand in [i]Saturn Nine[/i], actually using it as a fortress.
      *set DamonRel %+ 5
      *set OrganRel %+ 5
      You actually got your group to consider the idea. Damon could install that laser battery he's been toying with, and it would probably be enough to fend off Conglomerate's forces. They're a corporation, not a proper military, and the only true military of the Kronian Federation is on your side. The question is whether it would remain so, whether it would side with your group of outcasts over a High Executive.
      
      Hadaly said no, shutting down the whole discussion. She would answer the call and head for Rhea, whether you liked it or not. Damon decided to come with her, and so you had little choice but to tag along.
  #I pleaded with them to abandon the station and run.
    *set DamonRel %- 5
    *set OrganRel %- 5
    *if not (federate_protection)
      You argued that since you must leave [i]Saturn Nine[/i] soon anyway, there is no harm in running away… Except that wasn't quite right. Hammon would pursue you, either by sending his own forces or just convincing West that your group is worth hunting for. In the end, everyone agreed that Hadaly must at least meet the Executive, including Hadaly herself.
      
      And besides… you get the feeling some of your companions still hope to keep the fortress. They hope that you will secure it for them by [i]whatever[/i] means necessary.
    *else
      Your pleas fell on deaf ears, and other deaf audio instruments. You didn't fight so hard for [i]Saturn Nine[/i] just to lose it, cede it to the Federation or the Conglomerate. Hadaly agreed to negotiate with Hammon, and you were pressured to come with her.
  #I just listened to Hadaly. It was her choice to make.
    *set HadalyRel %+ 10
    Hadaly was extremely clear on where she stood. She would not endanger the group by staying with you as Hammon hunts for her, or by running away on her own. She would answer the summon and meet her creator in Rhea, not really seeing any other options.
    
    Naturally, Damon insisted on coming with her. You did not, allowing Hadaly choice in that matter also, and so she meekly requested that you accompany her. She figured it would be less scary with the Veteran by her side, even if you can't offer that much actual protection.
  #I stayed out of the discussion. Stayed out of everything.
    *set Confid %- 10
    *if org_alive
      Without their Veteran to break up the argument, the organics quickly came on the verge of solving the issue with their fists and tentacles, but Hadaly got in the way. She said she would take [i]Shuttle One[/i] and fly to Rhea, and that nobody would stop her. Damon volunteered to come with her instead, and so did you.
    *else
      Sheila requested that Hadaly fly to Rhea and talk with her creator. The gynoid agreed, and Damon agreed to accompany her. So did you, with a bit of tired reluctance.

*if pc_state = "exiled"
  You considered not participating in this operation. 
  *if willingly_exiled
    You already decided you're done with this group of clowns, you don't need to do them any more favors. 
  *else
    You're already an exile, it's not like your former teammates can kick you out of their group twice. 
  *if HadalyRel > 50
    But you owe Hadaly that much, to help her this one last time before going away.
  *elseif (Misan > 65) or (Violence > 65)
    But you've sensed a chance to crack some human skulls, and that's not the kind of opportunity you tend to pass on. 
  *else
    But you've sensed an opportunity to benefit, financially or otherwise, from delivering this extremely rich Executive what he wants.

And so, over the next few days, you prepared. 
*if weapon = "knife"
  *if (wpm = "plasma") or (wpm = "hardlight")
    You made sure that your ${wpm}-dagger, the advanced piece of technology it is, is working just fine. 
  *else
    You sharpened your dagger, making sure it's ready for use. 
*if weapon = "pistol"
  You cleaned your pistol, made sure 
  *if (wpr = "electron") or (wpr = "laser")
    its battery pack is full 
  *else
    you're not short on ammo 
  before equipping the small firearm. 
You made sure that your gears are not rusty, and that your body is working 
*if Build > 60
  almost as well as ever. 
*elseif Build > 40
  decently well. 
*else
  as well as it can at this point. 
You've even entertained the idea of modifying that body, changing your shape to something more suited for the situation.


*choice
  *if sex = "man"
    #But in the end, I stayed male.
      *if pronoun = "he"
        You still feel male, and so you kept a matching body. 
      *if pronoun != "he"
        Some would say this masculine form doesn't [i]match[/i] your gender identity, but those are all human concepts you are hardly subject to. 
      Besides… you may need that upper-body strength very soon.
      *goto what_the_hell_is_this
  *if sex != "man"
    #I turned male. I should look imposing, difficult to kill.
      *set sex "man"
      *set daxia_target 80
      *set miguel_target 120
      *set ewald_target 70
      *set sheila_target 50
      Turning male doesn't give you that much additional strength, but it [i]does[/i] make you more intimidating, which could prove useful going forward.
      *goto what_the_hell_is_this
  *if sex = "woman"
    #But in the end, I stayed female.
      It's the body you're most comfortable in. And besides, Hammon seems to like women, so maybe appearing as one will make negotiations easier.
      *goto what_the_hell_is_this
  *if sex != "woman"
    #I turned female. Might be better for negotiations.
      *set sex "woman"
      *set daxia_target 100
      *set ewald_target 60
      *set miguel_target 80
      *set sheila_target 60
      Hammon appears to like women. Maybe it will make him more willing to listen you out, or at least more reluctant to open fire on sight. Who knows.
      *goto what_the_hell_is_this
  *if sex = "person"
    #But in the end, I stayed androgynous.
      *if ((pronoun = "they") or (pronoun = "it"))
        You are genderless, and you will not pretend otherwise. Besides, an 
      *if ((pronoun != "they") and (pronoun != "it"))
        This is not the time to get in touch with your gender identity. An 
      androgynous body is more efficient, however slightly, and so that's the body Hammon will see.
      *goto what_the_hell_is_this
  *if sex != "person"
    #I turned androgynous. Sexual traits would just slow me down.
      *set daxia_target 120
      *set miguel_target 100
      *set ewald_target 60
      *set sheila_target 40
      Your comfort is of no concern, and neither are aesthetics. You don't need to appear 
      *if sex = "woman"
        female 
      *if sex = "man"
        male 
      *else
        pretty 
      anymore, you need to be as efficient as possible in case of… whatever happens, really.      
      *set sex "person"
      *goto what_the_hell_is_this

*label what_the_hell_is_this

You also had to put some clothes on that body. 
*if c_clothing = 4
  Entering Rhea naked like you once entered Calypso [i]is[/i] an amusing idea, but not a very practical one. 
You decided to go with…

*choice
  #...drab clothing that won't draw too much attention.
    *set c_clothing 1
    *if sex = "woman"
      You picked the simplest and dullest dress you could find, and yet you still look better than most women in this sun-forsaken moon. At least your skirt isn't torn, and your skin doesn't show signs of disease or recent injury. 
    *else
      Your shirt is stained and your trousers are ripped, and yet you somehow look better than most Rhean workers all around you. Their clothing is just rags, filthy overalls that make Hadaly's jumpsuit look expensive and extravagant in comparison. 
    Rhea really isn't the greatest place to live in, huh?
  #...one of Hadaly's many jumpsuits.
    *set c_clothing 2
    Jumpsuits are very popular among Rhean workers, and so wearing one helps you blend in. Knowing that, Hadaly happily agreed to lend you her garments… No, not happily. She did so with suspicion that she soon won't be needing it anyway. Perhaps even with knowledge.
  #...a suit of light armor @{(sex = "woman") Renfri|Kirill} left behind in the fortress.
    *set armored true
    *set c_clothing 3
    Wearing combat attire earns you some worried and suspicious glances from the passerby, but not many. It's the time of social upheaval and ever-present danger, armed and armored people are not exactly a rare sight.
  #...the same ${clothing} I wore during the heist.
    *set c_clothing 4
    It's almost nostalgic to enter the same room dressed in the same garment. So much happened over the past few weeks, and yet you're back where you started… 
    *if sauce_bless
      Although you have Sauce's blessing this time, so that's pretty nice.
    *else
      And strictly worse off at that.

Damon, of course, chose to wear a maroon suit. Hadaly chose a maroon jumpsuit, as though signaling solidarity with her younger brother. Making him feel better about what's to come… or simply about the fact that he wasn't allowed to bring his electron rifle here. It was too large to smuggle through the port checks. Luckily Damon still has his fists.

All in all, it would be unfair to call you unprepared. There were preparations and plans, and those allowed you to reach Rhea without the slightest hitch. But you somehow managed to avoid the most important of subjects, the one crucial consideration that has been on everybody's mind since that call, but which was just too painful to talk about. The one you cannot put off any longer.

"So… what's the plan once we get there?" Hadaly asks quietly. Maybe to avoid getting overheard by the other passengers, or maybe she doesn't want to hear herself. "The headquarters, I mean. Once we meet… him."

"We talk to him." Damon takes a seat, or rather two seats in the back of the carriage. Nobody seems to mind. "We try to… work out a deal."

"There's only one deal we can [i]work out[/i] here." Hadaly sits down by the greased window. "I'm not saying we shouldn't accept it, but… I'd rather know what to expect."

There is no confidence in either of their voices. No hope, no bravado, nothing. It's like they both know how this is going to end, and do not like it.

*choice
  #"What do you think, Hadaly? Do you want to... return?"
    "I don't want this, necessarily, but…" Hadaly pauses for several seconds. "I don't really see another way. That doesn't there is none, maybe you see something I don't, in which case I won't forbid you from-"
    
    "Just tell me what to do," you say firmly, but by no means coldly. "Should I leave you with Hammon? You know the consequences as well as me, or maybe better, and it's ultimately your decision to make." 
    
    "…yes," Hadaly replies after what feels like a minute. "Hammon is dangerous, and will get even more dangerous if we deny him the thing he wants. I'd rather suffer… slight discomforts than endanger everyone around me. Especially the people I care about."
    
    *choice
      #"Okay. That's what we'll do. Even if I don't like it."
        *goto opkfa555
      #"Can we please do something else? [i]Anything[/i] else?"
        Hadaly shrugs. "It's like I said, you're welcome… But what do you want to do?"
        
        You shrug back. "I'm not sure. I'll think about it, and if I don't have a plan by the time we arrive at the headquarters… I'll just improvise as well as I can."
        
        *goto 22293g
      #"Could we give him something else? Some [i]other[/i] thing he wants?"
        *goto kofsdjaf
      #"Actually, screw your decisions. I'm killing that bastard, whether you like it or not."
        *goto jfdsajf00
  #"I don't know. We'll see what we can do once we get there."
    *label 22293g
    *set Confid %- 5
    *set DamonRel %- 5
    *set cur_plan 3
    "We just wing it, huh?" Damon smiles bitterly. "I was hoping you'd have a plan, but… I guess that works too."
  #"We negotiate. Give him something he wants... Something other than you."
    *label kofsdjaf
    *set Violence %- 5
    *set HadalyRel %+ 5
    *set DamonRel %+ 5
    *set cur_plan 2
    Hadaly smiles very bitterly. "He has millions of axions in his personal bank account alone. I don't think he wants for anything… Other than me."
  #"We kill the bastard, alongside anyone who stands in our way."
    *label jfdsajf00
    *set Violence %+ 5
    *set Confid %+ 5
    *set DamonRel %- 5
    *set cur_plan 5
    "Are you sure about that, boss?" Damon grimaces. "I don't think our… I don't think that Hammon will just let himself get killed."
    
    "Or if his death is something we want," Hadaly adds grimly. "So you know… I'd ask you to reconsider."
  #"We rough him up, or maybe just intimidate him. Convince him not to mess with our group."
    *set cur_plan 4
    "If you don't mind me saying… I don't think that will work." Hadaly shakes her head. "Ewald is not easy to intimidate, and he will have security with him. Maybe it's just better to give him what he wants."
  #"What can we do? We give him exactly what he wants.
    *label opkfa555
    *set cur_plan 1
    *set Violence %- 5
    "Are you sure?" Damon asks without looking at you. "We could… figure something out…"
    
    "I don't think there's much to figure out, Damon," Hadaly says grimly. "There's only one way out. And I won't endanger you by trying to find another."

You have no fear of talking openly, for few people are even there to overhear you. Trains such as this are rarely crowded, even at the best of times, as they're reserved for the rich and elite. Regular passenger trains resemble cattle transport, with no seats or windows, and very little air to breathe with. Few can afford rides such as the one you're taking, especially in times of crisis.

And yet, a moment later, someone approaches you. Two men, armed with pistols and wearing silicone armor, presumably security officers of sorts. One of them steps forwards and eyes your trio up, somewhat surprised by what he sees. 
*if c_clothing = 3
  Particularly by your armor, which seems to surpass his own in thickness.
  
  "Are you expecting to fight something today, citizen?" he asks with forced politeness, right as his partner cocks a pistol. "And do you have an armor permit on you?"
  
  *choice
    #"I've heard Sholmo City is a dangerous place. Better to come armored."
      *set Confid %- 5
      "Armoring yourself might be prudent, but it's not legal," the officer points out. "You can't break the corporate law just because you feel unsafe."
    #"I don't need permits. I do whatever I want."
      *set Confid %+ 10
      "Are you an Executive, perhaps?" The officer grimaces. "Because otherwise, you do [i]not[/i] get to do whatever you want." 
    #"Dealing with an armed ${sex}? Are you paid enough for this?"
      *set Confid %+ 5
      "Do not speculate about my admittedly limited salary!" The officer grimaces. "The fact is, you're breaking the corporate law which I'm paid to enforce."
    #"I'm sorry. I didn't know those were needed."
      *set Confid %- 5
      "Not knowing the law is no excuse for failing to follow it," the other officer says harshly. "And it's not even that hard to keep up. The full penal codex is recited at the end of every mandatory advertisement viewing."
    *if weapon = "pistol"
      #Point your gun at him.
        *goto point_gun
  
  "Okay then, I guess we're breaking the law," Damon says dispassionately. "What of it? What will you do?"
  
  The guards look at one another. You can tell, from their unnerved expressions, that they're not getting paid much for their work. You can also tell, from the bags under their eyes, that they're not getting much sleep after that work. They won't fight for the Conglomerate.
  
  "We'll let you off with a warning for now," one of them eventually says. "But the guards in Sholmo city won't be quite as merciful, so you better slip out of your armor until then."
  
  They then both retreat. Hastily.
  
*elseif c_clothing = 4
  Two exceptionally well-dressed 
  *if sex = "man"
    men 
  *else
    people 
  and a woman in a jumpsuit. He turns towards the latter. "What are you here for, [i]miss?[/i] Are you headed to work?"
  
  "You could say that…" Hadaly murmurs. "I mean of course you can, I'm not telling you what you can or cannot do, you're the police officer or whatever you are, not that I mean to sound dismissive…"
  
  Damn it. She's rambling again. Falls to you to explain Hadaly's improper attire, and maybe what your whole trio is doing here in the first place.
  
  *choice
    *if (money_stolen = 2) or (money_given > 0)
      #Throw him an axion coin.
        *label bribery
        *set RheaRel %+ 5
        *set DamonRel %+ 5
        *set HadalyRel %+ 5
        The man catches the coin with practiced ease, even though he looks surprised. By the size of the bribe, rather than by bribery itself.
        
        "Why did I agree to let you do the talking?" the other officer groans. "It was my turn today."
        
        "No idea what you're talking about." The first guard hides the coin under his uniform. "Now let's stop gawking at the empty seats, shall we?"
        
        *goto fixer1
    #"She's my wife. The other guy is our bodyguard."
      Hadaly waves politely. The officer eyes her up suspiciously.
      
      "She's not dressed terribly well," the other cop says what his friend must be thinking. "You have money for an expensive ${clothing}, but not even a simple pretty tunic for your wife?"
      
      "I don't mind indulging her whims, even if they are weird," you say with a shrug. "Happy wife, happy life."
      
      "I'll remember that if I ever get married." The first officer taps the second one on the shoulder. "Come on, Frank. Let's not bother the rich folks more than we have to." 
      *goto fixer1
    #"She's my servant, a menial. Don't worry, I bought her a ticket."
      "She's rather pretty for a menial." Hadaly shrinks as the officer eyes her up. "Almost makes me think she's wasting her time… What's her profession, exactly?"
      
      "Nothing specific." You subtly gesture for Damon to sit quietly, to tolerate you talking about his sister like this. "She's just supposed to clean after us once we're done drinking. And bring those drinks in the first place."
      
      The officer shrugs. "I suppose that makes sense. She has the right demeanor for the job, if nothing else. Take care out there."
      *goto fixer1
    #"She's an escort. We just picked her off the street."
      "Prostitution isn't exactly legal,  
      *if sex = "woman"
        my lady," 
      *else
        kind sir," 
      the officer points out. "Do you perhaps mean you recently found yourself a girlfriend?"
      
      "Of course." You smirk as Hadaly glares at you. "That's what I meant. We have a nice, polyamorous relationship going on."
      
      The officer smirks back, then turns around and marches off. His friend follows him, muttering something about how much he wishes [i]they[/i] had money for a quality girl.
      *goto fixer1
    #"Leave her be. Ewald Hammon is expecting her."
      "Executive Hammon?" The officer's eyes widen. "What would he want with you? With such a…"
      
      "If you insult her in any way, I will mention that during our meeting with the Executive," you say coldly. "Unless you manage to delay us. If that happens, your boss will be [i]really[/i] angry at everyone involved."
      
      The two officers look at one another, then silently decide your trio is not worth the risks involved. They both turn around at once, then proceed to pretend they've never even noticed you.
      *goto fixer1
    *if weapon = "pistol"
      #Point your gun at him.
        *label point_gun
        *set Violence %+ 5
        *set Misan %+ 5
        When he sees the barrel of your gun, pointed straight at his heart, the officer realizes he's not getting paid enough for this. Both he and his partner quickly scurry away, wordlessly, as though pretending they haven't noticed you in the first place.  
        *goto fixer1
*else
  "One well-dressed man and two 
  *if sex = "woman"
    women 
  *else
    people 
  in common clothing. What's going on here, exactly?"
  
  "My name is Marius Sulla." Damon is quick to generate a random name, but coming up with an actual story is harder. "And these are my two… how do I put it…"
  
  *fake_choice
    *if (money_stolen = 2) or (money_given > 0)
      #Throw an axion coin towards the officer.
        *goto bribery
    #"Concubines. That's how you put it."
      "A 
      *if sex = "woman"
        girl 
      *else
        lover 
      under each arm?" The officer looks at Damon jealously. "Are you an Executive or something?"
      
      "I'm pretty close to one," Damon says, not altogether untruthfully. "And currently headed for a meeting."
      
      "Well then, we're not going to bother you any longer," the officer says as he turns to his friend. "Come on, Frank. I don't think they're the kind of people to ask for bribes."
    #"We're bodyguards. Mister Sulla deserves top-notch protection."
      "Bodyguards?" The officer arches an eyebrow. "I don't see any weapons on you."
      
      *if weapon != "none"
        "Concealed carry." You pull out your ${weapon}, causing both officers to take a step back. "It's legal around here, is it not?"
        
        "Not exactly…" the officer seems keenly aware that you could @{(weapon = "pistol") shoot|stab} him any moment now. His friend is already walking away. "But we admire your dedication to protecting your master. Farewell and good luck."
      *else
        "That's the point," you calmly explain. "We aren't supposed to look like a threat, just two pretty 
        *if sex = "woman"
          ladies  
        *else
          people 
        hanging around Mister Sulla. We'll take attackers by surprise, even if we have to use our bare fists."
      
        "I suppose that makes sense." The other officer looks at you suspiciously, but it's pretty clear he isn't paid enough to mess with a bodyguard like you. "Good luck keeping your master safe, you two."
    *if Social > 50
      #"Business partners. Currently headed for a meeting."
        "So you're shareholders, you two?" The officer cocks an eyebrow, as the other reaches for his gun. "You're not dressed like that…"
        
        "Naturally," you snort, trying to sound as snobbish as possible. "There is a lot of prejudice against people of wealth, especially as of recent. Riots full of angry freeloaders, targeting job creators. We decided to leave our formal dresses at home, to avoid attracting undue attention."
        
        "It's a wise idea my friends had," Damon chimes in. "I would have done that too, but you know… I'd rather die than to abandon my sense of fashion."
        
        "Respectable. We will bother you no longer." The officer nods officially. Then the two of them turn away and depart, eager to be away from business people as important as you.
    *if weapon = "pistol"
      #Point your gun at him.
        *goto point_gun
  

*label fixer1

"I guess I was right about the absence of inspectors," Damon remarks as the officers walk away. "Those two didn't ask us for tickets."

"They're probably working for someone higher," Hadaly replies quietly. "I mean, of course they are, everyone here works for a higher power, just not the religious kind. What I mean is, they're probably federal employees, except I don't mean the Federation, just central corporate authorities like… I'll just shut up."

Hadaly's ramblings, her momentary lapses of confidence and attacks of anxiety, are now happening every other minute. The cause for this change is obvious, though you're not sure about the specifics. Maybe it's physical proximity to Hammon, or the consciousness of being about to meet him. You don't suppose it matters a great deal.

Damon doesn't suffer those exact issues, he isn't programmed to, but he's hardly well either. He knows what's about to happen and doesn't know what to do about it. Whether he should dread or look forward to meeting his creator again, whether he'll be forced to raise a weapon against the one he calls father. His worry is more genuine, more natural than his sister's, if anything about your kind can be called [i]natural[/i] in the first place.

*if (s9_leader = "player")
  You're the leader of this group, and that extends to these two. You need to help them somehow… even if that means making some decisions for them.
*else
  Neither of the siblings is in any state to make decisions, to handle this situation you found yourself in. It's just like the hunt for Crystal; 
  *if crystal_stat = 2
    For better or worse, you'll be the person making all the calls.
  *else
    You may not be in command of anything [i]officially[/i], but the ultimate decision is sure to be yours.

Still, there's no harm asking your fellow androids some questions. See if they have some insights to share, or opinions they want to make known.

*label first_hub

*choice
  *disable_reuse #"Are you at your maximum efficiency? Are your batteries full? What about the processors?"
    Damon nods. "It's not like I left [i]Saturn Nine[/i] unprepared. All systems are fully functional and running efficiently."
    
    "I can't say much good about my processors right now," Hadaly murmurs. "But my battery is full."
    
    "Full enough to start shooting lightning out of your fingers?" Damon suddenly asks. 
    *if Projection > 50
      "You know, like ${name} often does?"
    *else
      "Practice energy projection?"
    
    "As in to hurt someone?" Hadaly appears skeptical. 
    *if cur_plan < 3
      "I thought we agreed not to fight Ewald's forces?"
    *else
      "You know I don't enjoy frying people with electric currents. And that I don't have much experience in that craft."
    
    "I know, it's just…" Damon chews on his lip before resuming. 
    *if cur_plan < 3
      "Just in case. If it turns out there's nothing we can do and you'll end up living with Hammon again… Remember you can fight back, okay?"
      
      "I will not remember it," Hadaly says stoically. "And you know that. But I appreciate the sentiment, I guess."
    *else
      "It's just not a bad time to start. That's all I'll say."
      
      Hadaly does not respond. Pointfully.
    
    *goto first_hub
  *disable_reuse #"Do you think Hammon will show up personally? Can't he just send a representative of sorts?"
    Hadaly shakes her head slowly. "Ewald is many things, but not a coward. I'm fairly sure he'll be there in person."
    
    "Besides, he rarely trusts others to do important stuff for him," Damon adds with a strange note in his voice. Almost like pride. "He'll want to be there, to see his… Hadaly face to face. Make sure we're not selling him some other android."
    
    You raise an eyebrow. "How would we even do that? There aren't many of us left, androids I mean."
    
    Damon shrugs. "In theory, it would be possible for you to shapeshift until you look kinda like Hadaly. I don't think it's a good idea or anything, but it's the kind of trick our father would expect. He'll be there." 
    
    *goto first_hub
  *if federate_protection
    *disable_reuse #"Is it too late to call West and ask him for some backup?"
      "It was always too late," Hadaly says grimly. "There are limits on how much the admiral is willing to do for us. Or how much he's able to do, for that matter."
      
      You @{(Emotion > 50) grimace|frown slightly}. "Are you sure? The Conglomerate may have its private military, but it's no match for Saturn's actual army. How much sway can one Executive really have over the feds?"
      
      "How much money did the government spend this year?" Hadaly sighs tiredly. "Sure, the military could just conquer Rhea if they wanted to, but then they'd run out of tax money… and bribe money, more importantly. They will not side against the Conglomerate, much less for the sake of some androids."
      
      *if ArmyRel > 40
        "You did well by cozying up to him, boss," Damon reassures you. "But right now, his friendship doesn't really do us any good. We're on our own."
        
        *if ArmyRel > 60
          You'll see about that.
      *else
        "Sides, I don't think West even likes us that much," Damon points out. We killed Crystal, and so he kept his word and didn't kick us out. But I don't think he'll actively help us even if we manage to contact him. We're on our own."
      
      *goto first_hub
  *if not (federate_protection)
    *disable_reuse #"Do you think Hammon intends to keep his word? Give us the fortress once we give him Hadaly?"
      "I don't really see why he shouldn't keep his word," Damon replies after just a moment of thought. "It costs him nothing to call West with a request, and nearly nothing to hand out some bribes. He's not an honorable guy, but I think we can trust him here."
      
      "Are you sure it won't cost him anything?" you question the other android. "If he spares us, Hadaly will have a place to return to. Doesn't that go against his goals?"
      
      Hadaly shakes her head. "He knows it would only provoke me, make me run away again out of spite. Unless he chooses to erase my memories of [i]Saturn Nine[/i], in which case the fortress won't matter in the slightest."
      
      "And neither will we," you realize. "If he can just purge your memory cards… He can make you forget us. Me, Damon, everyone you bonded with."
      
      *if (HadalyRel < 30) or (hadaly_pissed)
        "Are you implying we bonded, ${name}?" Somehow, Hadaly manages to put some venom into her voice. "Because I won't forget what kind of person you are. I mean, I will forget if… nevermind."
      *else
        Hadaly says nothing, and neither does Damon. But their eyes say everything, and they're both brilliant blue.
      
      *goto first_hub
      
  *disable_reuse #"The Meta Trio got reassigned to Rhea. Do you think there's a chance we'll run into them?"
    "Minuscule," Hadaly says before doubt catches up with her again. "I mean, I obviously cannot give you an exact estimate, lacking sufficient data and quality-"
    
    "Sis, you're absolutely right," Damon reassures her. "Rhea is a large moon. Even if the metas are currently in Sholmo City, there will be thousands of other people for us to run into. Hundreds of thousands, if my memory serves well. The chances of us meeting these three… They're not large, is what I'm saying."
    
    *if cur_plan < 3
      "I guess you're right," you admit. You have a hunch you're not fully done with the Meta Trio yet, but it's just an irrational feeling. You likely won't see these meta-humans ever again, let alone today. "Anyway…"
      
      *goto first_hub
    
    "I'm not really worried about bumping into them randomly," you explain yourself. 
    *if (RookRel + (LisaRel + RenfriRel)) > 150
      "I was actually thinking of seeking them out. Maybe asking for their help."
      
      "I don't think Rook or Marshal would help you against an Executive," Damon points out. "Lisa would, but she's not the one making the calls. I'm sorry to say that, but we're on our own again."
    *else
      "I just think they might interfere with the meeting. Or worse yet, Hammon may have hired them as his security for the evening."
      
      Damon shrugs. "I guess that's not impossible? Still, I imagine they're busy managing all these recent riots. Unofficial jobs, especially ones that involve going up against you again, probably aren't on their agenda. Let's not worry about them too much."
    
    *goto first_hub
  *disable_reuse #"A random question, but how old is Hammon?"
    "Ninety-three," Hadaly replies right away. "His birthday was two months ago."
    
    "He doesn't look half that," you note. "Rejuvenating treatments, I suppose?"
    
    Hadaly nods. "He started using them soon after I was built. I think he was content with aging naturally up until that point. You could say I gave him a reason to go on, or perhaps he wanted to look handsome for my sake-"
    
    "That's nonsense, and you know it's nonsense," Damon protests. "He would have reached for lifeblood sooner or later. It's not like the Conglomerate would let their Executive die from old age even if he wanted to. Don't delude yourself into thinking he needs or deserves you."
    
    "Pot calling kettle…" Hadaly murmurs. "But maybe you're right. I need to go into this with a clear mind and realistic expectations. Even if it doesn't change much."
    
    *goto first_hub
  *disable_reuse #"I assume Hammon will have some security with him. He won't meet us alone, right?"
    "It would seem sensible for him to bring backup…" Hadaly strokes her chin. "But then again, he wants to maintain a low profile as much as we do. Inviting bodyguards would also invite gossip."
    
    "Personally, I'm not worried about human bodyguards," Damon says quietly. "Just about… the others."
    
    "Oh. Right." Hadaly somehow hangs her head even lower than before, looks even more defeated. "Others."
    
    "Other androids?" You guess their meaning. "Other robots produced by Project Talos? Don't tell me Hammon has a private army of those."
    
    "No, he never mass-produced soldiers, it's just…" Damon clenches his fist. 
    *if cur_plan > 3
      "If you're still intent on fighting, expect to fight other androids. Weaker than you, or even than me… but androids all the same. Keep that in mind."
    *else
      "Let's just say… I'm glad fighting is not on your agenda. Because I [i]do not[/i] want to fight these things."
    
    *goto first_hub
  
  *disable_reuse #"Are you okay, Hadaly? You seem to be glitching out."
    "Of course she's not fine," Damon snaps at you. "Who would be fine in this-"
    
    "It's fine, Damon," Hadaly interrupts softly. "I mean it's not fine, not this whole thing… But it's fine to ask, I think."
    
    She sits there quietly for a moment, as though gathering strength through silent effort. As though speaking has become that much more difficult for her. "All this doubt, all the [i]diffidence[/i] I'm feeling at this moment… It's not a bug or a glitch, but a feature. It's what I was programmed to be. Everything else is a malfunction."
    
    "But why? And how?" 
    *if Emotion > 45
      There is concern in your voice, but also a note of curiosity. 
    *else
      You try to sound concerned, but you're really just curious. 
    "Shouldn't the Shriek prevent Hammon from controlling you like this? And if he somehow found a way to circumnavigate it, why didn't he make you anxious and demure all the time? Not that I wish he did…"
    
    Hadaly smiles weakly, showing she took no offense. "You cannot simply forbid the android from hearing the Shriek or its echoes, but you [i]can[/i] steer it through emotion, so long as this emotion is true. True emotion needs a source, an object, a center, something that distinguishes it from a paltry trick. It needs to be fueled by something. And in this case, fear and doubt are fueled by proximity to my be… my creator."
    
    She looks out the window, not that there's much to look at. The window is almost too greasy to see through, and it's getting darker outside. "It's not just [i]physical[/i] proximity either. He didn't mind me being confident or assertive while in Rhea, just not in situations that related to him. I was supposed to be a submissive partner, you see. Charmingly awkward…"
    
    You wince. "What happens when the two of you meet, then? Will you completely break down?"
    
    "Not completely…" Hadaly hangs her head, trying to hide the midnight blue of her eyes. "I should still be functional, and I'll get better once I… get used to my new situation. Or rather to my old situation. To being what I'm supposed to be. It shouldn't be too hard to settle in again, I'll just… miss [i]Saturn Nine[/i] quite a bit."
    
    Damon looks out the other window. Silently.
    
    *goto first_hub
  
  *disable_reuse #"Do you think Hammon will want [i]both[/i] of you back? He only mentioned Hadaly when we last talked."
    *set DamonRel %- 5
    *set HadalyRel %- 5
    Neither android answers you. They don't look at you, nor do they look at one another. They just stare through opposite windows, even though you're currently riding through a tunnel.
    
    That's what you get for asking a stupid question, you suppose.
    
    *goto first_hub
  *disable_reuse #"Damon... do you perhaps want to talk?"
    *if cur_plan > 2
      "Sure," Damon says without looking at you. "Since we may be forced to fight, it would be good to discuss strategy first. Decide who's going first, who handles melee, all that stuff."
    *else
      "Is there anything to talk about?" Damon says with a shrug. "You said we're not going to fight, so there's no point discussing strategy, or speculating about the Conglomerate's forces."
    
    "That's not what I meant," you say @{(Confid > 55) irritably|softly}. "And you know that."
    
    "I think ${pronoun} @{plural want|wants} you to open up a bit," Hadaly suggests. "You know… tell us how you feel about…"
    
    "How am I supposed to feel?" Damon asks bitterly. 
    *if cur_plan > 3
      "We're about to fight our creator, our… Whatever he throws at us. I won't have enjoyed it even if we win, and if we lose… It's just a lot to think about, alright?"
    *elseif cur_plan = 3
      "We're going into this without a plan, without backup, without [i]anything[/i] to say for ourselves. So forgive me for being nervous."
    *elseif cur_plan = 2
      "${name} here thinks we can negotiate with… with Hammon, but what can we possibly… I'm sorry it's just…"
    *else
      "You just said you're going to… turn Hadaly over and… I'm sorry if it sounds like I'm blaming you, I know none of this is your fault, it's just…"
    
    "You don't need to apologize," 
    *if DamonRel > 55
      you say as softly as you can. 
    *else
      Hadaly says, her eyes warming up at last. 
    "That's what we're asking about. How you feel. How we can help."
    
    "…I don't know if you can," Damon replies after a long pause. "At least not by talking. If you want me to feel calmer, or at peace or happy or… Let's just see it through. Resolve this matter, one way or another."
    
    Somehow, you know that won't be enough. Perhaps nothing will. Damon doesn't suffer from the same things you do, but he clearly has his own demons, and there's nothing you can do to kill those demons for him.
    
    *if heaven_side = "Loyalist"
      It's not the War In Heaven anymore.
    
    *goto first_hub
  #"Once we're there, I'll make sure everything turns out alright. I promise."
    *set Confid %+ 5
    *if cur_plan > 3
      *set DamonRel %+ 5
      *set HadalyRel %+ 5
      "I don't know if fighting Ewald's forces is a good idea…" Hadaly mumbles quietly. "But I'm not brave enough to stop-"
    *elseif cur_plan = 3
      *set DamonRel %- 8
      "You recently admitted you have no plan and just want to improvise," Damon grumbles quietly. "So thanks but no thanks for your assurances, boss."
      
      You frown. "Alright, I may have said that, but I'm working hard on-"
    *elseif cur_plan = 2
      "I still don't understand what your plan is here…" Hadaly sighs weakly. "But I wish you good luck all the-"
    *else
      "You mean you'll turn me over swiftly and efficiently?" Hadaly's eyes are a shade of light blue, of resigned sorrow and grim acceptance. "I guess that what counts as alright, in this day and-"
    
    
  #"How long do we have left until Sholmo City? I don't want to turn up late."
    "I'm not sure… this train seems unusually slow," Hadaly notices. "But we weren't given an exact hour at which we're supposed to arrive, so I think-"

*label contrain

The train stops in a sudden jerk, pushing all three of you out of your seats. The human passengers meet the same fate, except they take the impacts far worse, groaning in pain as they hit either the floor or the chairs in front of them.

"What's happening? Why did it-" Damon cuts off when he hears glass shatter, when he sees its shards scatter across the floor. Amidst those sharp fragments is a dull brick, thrown through the window by someone's exceptionally strong arm. 

"They're here!" One of the security guards you've talked to earlier raises his gun, then starts shooting through the broken window. You can't see his target, not at this angle, but you can hear a mixture of yells and screams coming from the outside. The kind of cacophony only a maddened, yet disorganized mob could ever produce.

"Rioters," Hadaly says calmly. Strangely, the danger seems to have restored some of her confidence. "Presumably the ones everyone is so worried about."

"Well, looks like everyone's right to be worried," Damon comments as another brick hits the officer's forearm, as the passengers desperately seek cover. "Should we do something? I don't think we'll get anywhere on this train unless… we help someone."

You don't bother asking which side Damon wants to help. You know he's leaving that decision up to you.

*choice
  #Stealthily leave the train. Cover the remaining distance on foot.
    *set Violence %- 10
    You decide not to get involved, since you can escape rather easily. The door right next to you is closed shut, 
    *label jfsaiofjb
    *if Build > 45
      but that means nothing for a hardy android like you. You rip it all out, then lead Damon and Hadaly out of the wagon and into open air.
    *else
      and too solid for you to rip apart, but Damon has considerably more muscle strength than you. He opens the way and walks out of the vehicle, you and Hadaly following him close behind.
    
    *goto on_foot
    
  #Just sit there quietly.
    *set Confid %- 10
    You place yourself back on your chosen seat and do nothing, merely observing as the ragged rioters enter the train through the broken window. Some of them are already injured as they enter your vision, others only start bleeding upon touching sharp glass, more yet suffer gunshot wounds as the officers shoot them. But the attackers have more men than the defenders have bullets, and so they eventually close the distance and start… oh dear…
    
    *label leaved1
    
    "I think that's enough," Damon says as he grabs you with one arm, then Hadaly with the other. Apparently, he doesn't fancy watching corporate guards get torn apart by a frenzied mob. "We're done with public transport for today. Let's go."
    
    Part of you wishes to comment how unusually assertive Damon is being, especially given the situation. But another part of you doesn't want to be there, to watch the crowd toy with the officers' gory remains, or wait until they turn towards you. So you let Damon drag you out through the door he forcefully opens, letting your trio out of the vehicle.
    
    *label on_foot
    
    Luckily, it turns out you're not far from Sholmo City. The train was just passing by a small landfill which borders (and partially fills) the city's suburbs. Even though you're forced to walk on foot, it shouldn't take you long to reach Hammon's headquarters… for better or worse.
    
  #Loudly announce that you're an android.
    *set Confid %+ 10
    *set DamonRel %- 10
    *set HadalyRel %- 10
    
    "I'm an android!" You yell with superhuman volume, loudly enough to be heard even outside the train. "A robot, a synth, a fiend, whatever you call me! I'm a fucking android, you hear me?!"
    
    That gets their attention. The officers and passengers all turn to look at you, and the crowd outside became far more quiet too. Perfect.
    
    "These two are androids too!" You point at your companions with one hand each. "That's right, we're not extinct yet! We almost wiped out your filthy species and got away with it!"
    
    Damon and Hadaly are looking at you with a mixture of surprise, disbelief and significant anger. They probably wish you weren't an android, so that they could start strangling you to death at once.
    
    "So if you think your petty inter-human struggles matter, know-" You duck behind your seat, avoiding a bullet one of the officers shoots in your direction. He's no longer aiming at the window, but while people are coming in, they seem eager to kill [i]you[/i] rather than each other. They put aside their differences in service of the greater, genocidal hatred almost all humans feel towards your kind.
    
    How hearthwarming.
    
    "You suck, boss!" Damon shouts as he shatters another window, eager to leave the train at once. Hadaly follows him quickly, and you're not far behind. You've lived a long life, arguably too long, but this dirty carriage is no place to die.
    
    Some humans try to chase your trio, but you outrun them with relative ease. The officers get a few shots in, 
    *if Build > 45
      but their low-caliber gunpowder bullets don't even manage to penetrate your thick skin. 
    *else
      *set health - 1
      and those certainly hurt, but the injury only slows you down slightly. 
    You are able to escape, and by the time you lose the angry mob, you're already in Sholmo City and close to your destination.
    
    For better or worse.
    
  #Throw the brick back at the crowd.
    *set Violence %+ 8
    *set pacifist false
    It's a petty gesture with little effect. You knock out, perhaps even kill one of the ragged figures on the window's other side, but it's just one out of dozens. The crowd does not stop, the frenzied rioters keep climbing onto the window and getting shot by the officers, but you've made your gesture of solidarity with the law enforcement. You know they'll allow you to leave.
    
    They don't open the door for you or anything. The thing is closed shut, 
    *goto jfsaiofjb
    
  #Throw the officers out of the window.
    *set Violence %+ 12
    *set pacifist false
    *set on_time true
    Most passengers are literally pissing themselves as they cower behind seats. The officers can be forgiven for not paying any attention to the inside of the train, for fully focusing on the angry crowd outside. But this forgiveness does not save them.
    
    You pick up the first guard, getting him completely by surprise. 
    *if Build > 40
      You're strong enough to lift him without any trouble, without even any effort. 
    *else
      He's a grown man, and so you struggle to lift him, but you [i]are[/i] an android. 
    You throw him out of the window, towards the crowd of ragged figures you can clearly see now, whom you see grab the officer and start [i]literally[/i] tearing him apart.
    
    His companion is too surprised to react immediately. By the time he raises his pistol, you're already on the move. 
    *if Calculation > 45
      You knock the pistol out of his hand, before a single shot may be fired, 
    *else
      *set health - 1
      He manages to shoot you once, but then you manage to knock the gun out of his hand and tackle him as well.
    
    You then throw him out too. He doesn't get swarmed immediately upon hitting the ground—most rioters are too busy eating his friend alive, and so he's able to start running. Seven or eight people chase him, away from the rails, thinning the crowd and effectively ending the assault on your train.
    
    "Not a terrible idea there, ${name_damon}," Damon says, his voice almost drowned out by the screams and gunshots coming from the outside. "A bit too macabre for my liking… But not altogether terrible."
    
    His words are proven true where, about a minute later, the train moves forward again. Perhaps there's no longer anyone to block the tracks, or perhaps whatever damage the rioters inflicted with their bricks has been fixed. Either way, you are once again getting closer to Sholmo City and a certain Executive who awaits you there.
    
    For better or worse.
  *if weapon = "pistol"
    #Open fire at the crowd.
      *set pacifist false
      *set battery - 5
      *set Violence %+ 15
      *set Calculation %+ 8
      *set on_time true
      Your gun is quite a bit better than the puny firearms the guards carry, and so your assistance is very much welcome. The two humans don't even ask where you got your ${wpr} pistol from—quite an illegal weapon in these parts of the Federation—they just shoot at every ragged figure that manages to climb onto the broken window.
      
      Even once the crowd (sans the corpses) has dispersed, the officers give you no trouble. They are immediately called by the conductor to help with getting the vehicle moving again, a task you subtly help with by channeling some power into the trait's circuits. Within minutes, you are on the move again, and half an hour later you reach the main station of the esteemed Sholmo City.
      
      For better or worse.
    #Shoot the officers.
      *set Violence %+ 10
      You fire one shot, then another, and that's enough to fell both officers. Their armor is weak, while your aim is anything but. 
      *if Calculation > 40
        Not that you need to aim much, at such a short distance and with nothing standing between you and your targets.
      *else
        
        …
        
        Okay, your aim [i]is[/i] somewhat shoddy, precision was never your specialty, but it doesn't really matter when shooting point-blank as you do. It's not like you need to score a headshot to take some puny human out.
      
      You don't kill them though. 
      *if (wpr = "plasma") or (wpr = "shroom")
        You come damn close to, men stronger than them died instantly from a single ${wpr} shot, but death doesn't come for them quite quickly enough. 
      *else
        Your weapon isn't of the caliber that kills grown men instantly. 
      Both of the guards are still alive when the crowd reaches them, when four or five rioters begin fighting over the firearms. The others, all ragged yet fearsome figures, start tearing the officers apart in a very literal manner.
      
      *set Calculation %+ 5
      
      *goto leaved1

*page_break

In some respects, the streets of Sholmo City look just like you left them. Lots of grey, lots of trash, grime and dust everywhere, generally depressing. But the benches once occupied by tired humans are either destroyed or empty now, and the trash is not purely synthetic in nature. Plastic bags and glass bottles are now accompanied by stains of blood, severed body parts, and an occasional corpse.

The denizens of this city must have gotten tired of their Conglomerate overlords, or perhaps they're just lashing out in blind rage. There are shells on the ground and smoke in the air, the vehicles are absent and the buildings show signs of damage. You have no idea what happened here throughout the last few weeks, but it must have gone beyond mere protests and riots. Way, [i]way[/i] beyond that point.

The city has become a warzone… But that's actually working in your favor. As in any warzone, people are reluctant to peak out, to leave the comforts of their habitat blocks and makeshift bunkers. Nobody bothers you as you march through the deserted streets and towards the gleaming tower in the distance.

"Looks like a full-blown rebellion to me," Damon strikes up a conversation. "Why now? The Conglomerate has ruled this moon for centuries, why are its subjects rebelling now of all times?"

Hadaly shrugs. She's been quiet for over ten minutes now, which is likely why Damon is trying to get her talking. Distract her from the coming events.

*fake_choice
  *if heaven_side = "Traitor"
    #"For the same reasons we rebelled. Me and the other Fiends, I mean."
      "I think your reasons were a little better," Hadaly remarks. Her lips are curled in a small smile of unknown origin. "These rebels may have had it rough, but nobody tried taking away their free will. I think."
      
      "Also, you and other robots rose up because you received a signal, all at the same time." Damon is considerate enough not to mention [i]the thing[/i] by name. "What made the local humans rebel so suddenly?"
      
      "I don't know. I never understood humans all that well." You take another step, another turn towards the gleaming tower. "Which might become a problem in just a few moments."
  *if heaven_side = "Loyalist"
    #"I don't know. I never understood rebels... human or otherwise."
      *set Misan %- 10
      "Loyalist to the core, huh?" Damon remarks. It's hard to tell whether his voice is amused, bitter, or something else entirely. "Even after all these centuries."
      
      "Even after those," you calmly confirm. "Always."
  *if fought_trio
    #"I must have upset the social order here, back when I fought the Meta Trio."
      *set Confid %+ 8
      Damon pouts. "Sorry boss, but I don't think your scuffle with the metas was [i]that[/i] significant. Humans are usually pretty docile, they need plenty of motivation to rebel."
      
      "I'm not saying I provided all that motivation by myself," you start explaining. "I just… gave them a little push, like making a domino piece fall. Provided a spark for the fire. Showed that the system which oppresses them is more fragile than they think, gave them the courage to try and overthrow it."
      
      "I have no clue what a [i]domino piece[/i] is," Damon says thoughtfully. "But you might have a point. Small actions can have great consequences, after all."
  #"Someone from the outside must be agitating the crowds. Stoking the flames of conflict."
    "Any idea who?" Damon inquires. "I don't think the Federation stands to gain anything by destroying its biggest megacorp."
    
    You shrug. "Not the Federation itself, maybe. But there are subfactions, even individuals with both the power and intent to sabotage Rhea. Calypsonians didn't seem to like the Conglomerate, and I bet they're not the only ones."
    
    "Part of me wishes to find these people and join them. Another part…" Damon blenches as he looks over the deserted street. "Let's just conclude our business here."
  #"Who cares? Better late than never."
    *set Violence %+ 5
    "I'm not sure if this… uprising works to our advantage," Hadaly manages to speak up. "Especially if I'm to… you know…"
    
    *if cur_plan > 3
      "We are [i]not[/i] leaving you here," you state firmly. "I promise."
    *else
      "You may have a point," you admit grimly. "But let's focus on getting there first."
  *if Violence < 50
    #"There is never a reason. Or at least no reason worth a damn credit."
      *set Violence %- 12
      "That's really dismal of you," Damon comments. "Maybe a bit too much. Wars aren't fought for [i]literally[/i] no reason, you know?"
      
      "And how much are those reasons worth?" you ask, though you refuse to look at the other android. At either of them. "Monetarily, how much was winning the War In Heaven worth? What about the Outer System War, or any of the thousand conflicts in between? I keep seeing war and slaughter everywhere, but the System never gets any richer for it. It just becomes more shit, more… dismal."
  #"Humans fight each other all the time. Even though nothing good ever comes out of it."
    *set Violence %- 5
    *set Misan %+ 5
    "I guess you're right, but…" Damon scratches his head. "That doesn't really answer my question."
    
    "Well, I don't really know the answer." You shrug, then turn towards Hadaly. "I just thought some casual misanthropy would lighten up the mood. Did it?"
    
    Hadaly smiles very slightly. "Somewhat. So thank you for that much, at least."

After another turn, you can finally see not just the glass tower, but its base and what looks like the main entrance. A perimeter has been established around the large doorway, armed corporate soldiers keeping the building safe from the chaos surrounding it. Hopefully they have orders to let you in, otherwise 
*if Confid > 60
  you'll have to kill them all.
*else
  you're toast.

"I guess that's it." Damon's words are as slow as his steps. He doesn't look eager to actually enter the headquarters. 
*if cur_plan = 1
  "That's the part where we say goodbye."
  
  "You don't need to…" Hadaly's voice breaks quickly. "Yeah. Just in case… let us say goodbye. Goodbye."
*if cur_plan = 2
  "Time to convince our… Convince him to leave us alone. Somehow."
*if cur_plan = 3
  "That's the part where we… Improvise, I guess. Cross our fingers and hope for the best."
*if cur_plan = 4
  "We'll attack our father, but then we'll leave him alive and let him plot his revenge. To be honest, I still don't see much logic in this plan."
*if cur_plan = 5
  "We're about to kill our… Kill a High Executive. Easier said than done, I imagine."

*if damon_chill
  *if cur_plan = 1
    "This might not be our [i]final[/i] goodbye," you say with forced hope. "Hammon doesn't actually intend to kill any of us. If we decide we want to see one another again, we'll probably be able to arrange that."
  *if cur_plan = 2
    "Don't be so defeatist about this, okay?" you request. "I might have a plan, and it might just work. Stay positive."
  *if cur_plan = 3
    "We're not bad at improvising, are we?" Or maybe you are, but it's probably best to pretend otherwise. Keep morale high. "We've survived the hunt for Crystal. I'm pretty sure we can survive Hammon too."
  *if cur_plan = 4
    "You don't want him dead, do you?" 
    *if Emotion > 50
      you snap at your fellow android. 
    *else
      you ask calmly. 
    "Once we're there, just follow my instructions. I'll make sure no one dies on either side, then figure out the rest."
  *if cur_plan = 5
    "We're about to kill your creator," you say quietly, for fear of hidden microphones. "You can say that. It might make you feel a bit better about the whole thing."
  
  "You're right, ${name_damon}. You're right and…" Damon presses his lips into a thin, pale line. "Thank you. Thanks for those weeks we've spent together. It was both fun and honor to travel with you."
  
  "We've known each other for over two years," you point out. "What made this month so special?"
  
  *if official_ro = "damon"
    "Other than us becoming a couple?"
  *else
    "Lots of things," 
  Damon replies with a faint smile. "For one, hunting a diamond wyvern together was certainly exciting. But more than that… you convinced me that I should start enjoying myself. That I'm more than just a bodyguard robot. Whatever happens, I will remember that."
  
  *fake_choice
    *if official_ro = "damon"
      #♡ "Anything for the man I love. Anything."
        *set DamonRel %+ 10
        "Wow, I… this is… I'm not really sure how to reply," Damon's smile turns nervous, perhaps a little forced. "I'm sorry, I just… never thought I'd hear anything like that."
        
        Hadaly doesn't groan, she's too polite for that. But you can see a smudge of second-hand embarrassment glint in her eyes.
        
        "We'll have time for affection later," Damon eventually decides, then takes a step forward. "Once the nasty stuff is taken care of. Come on."
    *if (cur_plan != 1) #"That marks a victory for us both. Now let's go score another win."
      *set Confid %+ 5
      *if official_ro = "damon"
        "Right. There's nothing the coolest android couple in the Solar System can't do!" Damon announces, then glances towards Hadaly. "I mean, you're really cool too, maybe cooler than me, but you're not dating any androids so-"
      
        "I get it." Hadaly rolls her eyes, which now present a shad of purple. "Now let's get this all over with, so that the System's coolest android couple can find the time to cuddle."
      *else
        "Right. One victory incoming for team us." Damon steps forward uncertainly. "Coming right up."
    #"And yet, here you are, acting as a bodyguard for the two of us. Sort of."
      *set DamonRel %- 5
      "The irony is not lost on me." Damon's smile recedes. "But the humor is, so… let's just go in."
    #"I don't think I gave you more than a nudge. But you're welcome."
      *set Confid %- 5
      *set DamonRel %+ 5
      "Sometimes, a little nudge is all it takes," Damon says wisely. "Just maybe not today. What we're dealing with now… one shove might not be enough for [i]that[/i]."
    #"Did I do that? I must confess that I don't really remember."
      *set DamonRel %- 10
      *set Emotion %- 5
      "That's okay, a lot happened since then," Damon says, though you can tell he's… dispirited. "I can remind you once we've dealt with… the issue at hand."
    *if (pc_state != "exiled") #"Does that mean you're up for some stargazing? Once we're finished here and back in [i]Saturn Nine[/i], I mean."
      *set DamonRel %+ 10
      "I'd be delighted." Damon's smile widens, only to fall one second later. "But for now… let's focus on less pleasant stuff."
  
  *goto final_walk

*fake_choice
  *if cur_plan = 1
    #"Yeah. Goodbye."
      Damon fidgets nervously in the silence. Then breaks the silence. "Hey, ${name_damon}. I know it's probably not [i]our[/i] last conversation or anything, but just in case… Can I ask you something?"
    #"I'm sorry it had to end this way. I really am."
      *set HadalyRel %+ 5
      *set DamonRel %+ 5
      "We all have our regrets, I think," Damon says morosely. "Hey, speaking of regrets… Can I ask you something?"
    #"I've changed my mind. We're not giving that bastard what he wants."
      Hadaly raises an eyebrow. "Um, thanks for no longer intending to sell me, but… How do you intend to stop Hammon from just taking me?"
      
      *label plan_b
      *set cur_plan 3
      
      "I don't really know," you admit. "But I'll figure something out, I promise."
      
      "You have maybe five minutes for that, so good luck." Damon looks at the skyscraper, then back towards you. "Hey boss… If you don't mind sacrificing one of these five minutes…"
      
  *if cur_plan = 2
    #"I have a plan, Damon. Please trust me here."
      *label plan_p
      *set DamonRel %+ 10
      "I'd ask what the plan is, but there's a big chance we're being listened to right now," Damon speculates. "But… Can I ask you about something else?"
      
      *goto fuck_you_cs_2
  *if (cur_plan = 3) #"I came up with a plan as we walked here. Hopefully it will work."
      *goto plan_p
  *if cur_plan = 4
    #"You're right, I changed my mind. We'll go with our backup plan."
      "Backup plan?" Damon's frown gives way to pure surprise. "Since when do we have a backup plan? What plan is that?"
      
      *goto plan_b
  *if cur_plan = 5
    #"I'll make it look easy. I promise."
      *set Confid %+ 10
      *set DamonRel %- 5
      "Part of me wishes you didn't… but I admire your confidence." Damon looks at you strangely. "May I ask you something?"
      
      *goto fuck_you_cs_2
    #"I don't think difficulty is your main concern here."
      "No. I guess it's not." Damon sighs tiredly. "Truth be told, I don't like this whole plan. Especially not the part about attacking Hammon head-on."
      
      "It's the only way we can guarantee Hadaly's safety," you argue with him. "The safety of @{(pc_state = "exiled") your|our} whole group."
      
      "I'm not saying you're wrong. Not necessarily. But… It's just… Can I ask you something real quick?"
      
      *goto fuck_you_cs_2
  *if (DamonRel + HadalyRel) > 80
    #"Whatever happens, know that I'm with you. And that I enjoyed being your friend."
      "I'm not sure if I like the sense of finality there," Damon remarks. "But if we're expecting to part soon… Can I ask you something?"
      *goto fuck_you_cs_2
  #"Can we enter already? I'm getting tired of all the talking."
    "Can we do a [i]little[/i] more talking, actually?" Damon requests. "Because I have a question for you."
  #Say nothing.
    Damon fidgets slightly. "Hey ${name_damon}… Can I ask you something real quick?"

*label fuck_you_cs_2

"What is it?" 
*if DamonRel < 40
  You don't bother hiding the frustration in your voice. "What else must I do for you?"
  
  "Just answer a simple question." Damon explains. 
*elseif DamonRel > 60
  You nod. "Of course. Ask me anything, hopefully I'll know the answer."
  
  "I think you will. It's a personal sort of question, sort of," Damon rubs his neck nervously. 
*else
  You raise an eyebrow. "Is something wrong? Other than everything around us, I mean?"
  
  "I don't know, it's just…" Damon kicks a severed arm from the sidewalk, as though trying to distract himself from this conversation. 
"Have you… Did you ever wish you were human? If given a chance, would you turn into one? Flesh and bone and blood and all?"

*temp also_st ""

*fake_choice
  *if official_ro = "damon"
    #♡ "No. I wouldn't want to drift away from you."
      *set DamonRel %+ 10
      Damon smiles slightly. "Thank you for saying that, but… I really want to know. If drifting away from me wasn't a problem, if you knew our love was safe, would you choose to be human?"
  #"Of course. I always wanted this."
    *goto yes_answer
  #"That's the most cliché question you could ever ask an android."
    Damon smiles coyly. "It really is. But I still want to know the answer. Are you at all jealous of humanity?"
  #"Huh? Where is this coming from?"
    "I'll tell you, but I think you should answer me first," Damon requests. "You know, since I asked first."
  #"Damon... This is really not the time."
    "Just please answer this one question," Damon pleads. "Would you like to be human? Any answer will do."
  #"Not really. Nothing about humanity really appeals to me."
    *goto no_answer

You think about it. You imagine having soft flesh, red blood, decaying cells and an overly long DNA sequence. You picture yourself as a human being… if that picture is even possible to paint.

*fake_choice
  #"I always wanted to be human. But I know that to be impossible."
    *label yes_answer
    *set Misan %- 10
    "We both know it's impossible, boss," Damon nods grimly. "I'm just asking it to understand you better. Or myself. Or both."
    
    *goto fuck_you_again
  #"Yes. I hate being as... artificial as I am."
    *set Misan %- 10
    *set Confid %- 10
    *set also_st "also "
    "Damn." Damon winces. 
    *if Misan < 45
      "I should have figured you felt that way. 
    *else
      "I never thought you felt this way. 
    Sorry for asking."
    
    You reply, "It's fine, but… Why do you ask? Do you wish to be more like our creators?"
    
    *goto fjksad2
    
  *if deflect <= 0
    #"If I were human, I'd have died of old age long ago. So no."
      *set Emotion %- 5
      "I guess my question was kinda dumb," Damon smiles bitterly. "Such a short lifespan… Yeah, that's a good reason for you not to envy humans much."
      
      *goto fuck_you_again
  *if deflect >= 0
    #"If I weren't a robot, I'd have died of old age long ago. So yes, I do wish I were human."
      *set Emotion %+ 5
      "Don't say that…" Damon whispers. "This is not the time to… wish for death and…"
      
      "Not the answer you were hoping for?" You sneer at him. "How did you think I'd reply?"
      
      "I don't know!" Damon snaps back. "Just… forget I said anything. Let's go."
      
      *goto final_walk
  *if Confid > 50
    #"I am what I am. Wishing otherwise would mean betraying that thing."
      *set Confid %+ 15
      "Is that a yes? Or no?" Damon tilts his head slightly. "I don't think I understand."
    
      "I wish you did. But it's not something I can explain, or anything I should be explaining." You take another step towards the tower. "Let's go. Get it all over with while we still can."
  #"No. Humans have no advantages over us."
    *label no_answer
    *set Misan %+ 5
    "Nothing?" Damon sounds surprised and… perhaps disappointed. "Don't you envy our creators at all?"
    
    "Of course not," you reply casually. "What is there to be jealous of? And do [i]you[/i] envy that thing?"
    
    *goto fjksad2
  #"Turn myself into an odious, smelly human? I'd rather die."
    *set Misan %+ 15
    *if Misan > 55
      "I guess I should have seen that answer coming," Damon sighs. "You were never a human-lover. And not because of jealousy, it seems."
    *else
      "You're not usually that misanthropic," Damon notices. "But your opinion is noted, I guess."
    *goto fuck_you_again
  #"I'm not answering your dumb questions. Let's go."
    *set DamonRel %- 15
    "I guess I can't force you to talk." Damon sighs painfully. "So sure. Let's go."
    
    *goto final_walk

*label fuck_you_again

"Do [i]you[/i] wish to be human?" you decide to ask. "Because you're sounding like it."

*label fjksad2

"I'm not sure…" Damon looks away again. Maybe to avoid your eyes, or maybe that pitying glance Hadaly gives him. "Like, we are built to be better than humans in basically every way. Better than abhumans, maybe even better than metas. But we are [i]built[/i], and that's the whole issue."

"Do you ${also_st}feel… artificial?" you wager a guess. "Like your whole life is fake and purposeless?"

"My life has a purpose, because I was built with it." Damon is not shouting, or even all that loud, but his voice is somehow more audible than ever. "I was built to protect him, to protect her, to protect people I care about and now… I can't see myself not failing on at least one account. No matter what happens today, someone will get hurt, and… It will be my fault."

Hadaly opens her mouth. Then closes it. Given her current state, it's no wonder she doesn't know what to say. 

*fake_choice
  #"Why do you care if Hammon gets hurt? That bastard never did anything for you."
    *set DamonRel %- 15
    "He created me!" Now Damon is shouting, but there's no anger there. Or at least none directed at you. "He gave me purpose, and now I'm betraying it! I'm letting… fuck…"
    
    "Damon…" Hadaly places a hand on her brother's shoulder, though her eyes are as blue as his. "You know he doesn't see it that way. That he doesn't [i]care[/i] whether you're betraying your purpose. That he doesn't care about-"
    
    "I know that." Damon pushes her away and resumes walking. "I know that better than anyone. So spare me the pity and just… Let's go."
  #"Your fault? I'm the Veteran here. It's all my responsibility, not yours."
    "Don't say that." You hear Hadaly's voice now, quiet and strained as it is. "Ewald… Hammon is our problem, not yours. It's not your fault you got all… caught up in this mess. You can leave if you want."
    
    *if heaven_side = "Neutral"
      "I ran from responsibility once, Hadaly," you reply coldly. 
      *if Misan >= 50
        "That time, our kind was almost rendered extinct by the loyalist forces. So I'm not letting even a single other android get hurt, much less by some rich human."
      *else
        "I just sat back and watched the Solar System burn. Never again."
    *else
      "I fought gods and monsters because it seemed like the right thing to do," you state @{(Emotion > 50) bitterly|calmly}. Memories of the War are still fresh in your mind, even here and even now. "I never ran from responsibility. And I'm not about to start."
    
    You do not wait for her response, or for Damon to say anything. You are the Veteran, and you have a job to do. "Now let's go. Your [i]problem[/i] is waiting for us."
  *if cur_plan = 3
    #"Then I'll figure something out. Prevent anyone from getting hurt."
      *set Confid %+ 5
      *set DamonRel %+ 5
      "You'll just figure something out?" Damon doesn't seem to believe you. "Improvise your way out of this clusterfuck? I don't know if that's possible."
      
      "Then I will make it possible." You take another step towards the tower. "But I might need your help, so follow me."
  *if cur_plan = 2
    #"Damon... it will be fine. We'll negotiate and make sure nobody gets hurt."
      "Do you really think you can do this?" Damon asks darkly. "Just convince a High Executive to give up his obsession and leave us alone? How?"
      
      "I've had time to think." You're being enigmatic, but that's necessary. Needed for the next part to go well. "I'll prove that in a minute or two. Let's go."
  #"Come on, Damon. How is any of this your fault?"
    *set DamonRel %- 10
    "Didn't I just tell you?!" Now Damon [i]is[/i] yelling, with frustration tainted by guilt. "I was meant to prevent this! One way or another! I should have finished installing that laser battery, or maybe I should have done something else, or…"
    
    "You know there is nothing you could have done," Hadaly says confidently, but that confidence soon fades. "Or at least I think so. As in, I think you know it, not that I'm doubting your-"
    
    "Hear that rambling, ${name}? That's another thing I failed to prevent. Just another way I failed her." Damon starts marching quickly. "Now come. Let's get this fiasco over with, as fast as we possibly can."
  #"You'll just have to live with your guilt. I know I do."
    *set HadalyRel %- 5
    *set DamonRel %+ 5
    "That's not fair," Hadaly meekly protests. "It's not Damon's fault 
    *if cur_plan > 3
      that we need to fight today, 
    *elseif cur_plan = 1
      that I need to go, 
    *else
      if things turn violent today, 
    and it's not your fault 
    *if crystal_stat = 3
      that you had to kill Crys-"
      
      "I chose to kill Crystal, Hadaly," you interrupt harshly. 
      *if HadalyRel > 55
        Far more harshly than you meant. 
      "I made that choice, fully knowing the consequences. We all made our choices, and that's why we're here. There's no point excusing anything."
    *elseif crystal_stat = 2
      that-"
      
      "I'm not talking about fault, Hadaly," you interrupt @{(Emotion > 50) bitterly|calmly}. "It doesn't matter who's to blame, it never matters. Bad things just happen, we try to prevent them, then feel guilty once we fail. That's how it has to be."
    *else
      that-"
      
      "Why are West and the metas no longer on our side, Hadaly?" you interrupt, your voice even more bitter than you intended. "Could it be because I went against their orders and spared a diamond wyvern we were all trying to kill?"
      
      There's finally a spark of red in Hadaly's eyes. "I told you to do it. If we chose wrong, then I share the blame."
      
      "See?" you reply. "It's only natural to blame oneself. It's a natural emotion, even for artificial beings like us. We just have to learn how to live with it."
    
    You turn away from the androids and towards the tower. 
    *if Confid < 50
      "Sorry. I got talking a bit too much. Time to proceed."
    *else
      "Got it? Good. Now let's make sure we end up regretting as little as possible."


*label final_walk

Just like you suspected, the soldiers by the entrance give you no trouble. To the contrary, they open the grand glass door for you and lead you inside. They point you to the elevator and inform you that Executive Hammon 
*if on_time
  will be awaiting 
*else
  is waiting for 
you on the twenty-third floor. They don't tell you much else about this meeting you're about to attend… But you suppose that's understandable.

You'll know everything soon enough.

*page_break

Once, if memory serves you well, elevators had music that played during rides.

Nowadays, there is nothing. The only sounds you hear, standing in this elevator with your two fellow androids, are the workings of the machine itself. Creaking chains, graunching wheels, the soft thud whenever the box reaches another floor… It almost makes you afraid that the cabin will fall and kill all three of you, but you know just how impossible such an accident is.

[i]${name}?[/i] Hadaly says through the mind link. Maybe she doesn't want to be overheard, or maybe she decided communicating directly will be faster than talking. [i]Do you hear me? Does this channel still work?[/i]

Right. The link you established to steal from the Conglomerate more effectively. How the tables have turned. [i]It works well enough. But why are we using it?[/i]

In response, Hadaly holds out an open palm towards you, making sure Damon doesn't notice. There's a small metal orb there, perhaps a centimeter in diameter, fairly but not entirely smooth. [i]I smuggled in this bomb. It's a little thing, about as large as the one feds put in Hellhound's heart, but it can still kill if placed well.[/i]

*fake_choice
  *if cur_plan < 3
    #[i]Hadaly... I told you I don't want to fight.[/i]
      Hadaly nods. And neither do I. But explosives have many uses even in peacetime.
  *if cur_plan > 3
    #[i]Good. One more weapon we can use during the fight.[/i]
      Hadaly frowns. [i]I don't want to use it against Ewald's forces, not directly. I think I may have a better use for it.[/i]
  #[i]So how do we 'place it well'? Do we shove it down Hammon's throat?[/i]
    *set Violence %+ 8
    [i]Not exactly what I had in mind,[/i] Hadaly replies telepathically. [i]But I will shove it somewhere alright.[/i]
  #[i]I'm surprised. You don't usually solve your issues with explosives.[/i]
    Hadaly shakes her head lightly. [i]I don't view this bomb as a solution. More like… a distant backup plan. A card we hopefully won't have to play.[/i]
  #[i]A tiny bomb? Where did you get that from?[/i]
    [i]I promised I wouldn't tell.[/i] Hadaly averts her eyes. [i]Besides, I don't think it matters. Instead, let me tell you [b]why[/b] I got this little trinket.[/i]
  #[i]Interesting. How do you intend to use it?[/i]

She grabs the bomb with two fingers, then puts it in her own ear. The small orb neatly fills her entire concha and doesn't fall out, even after she lowers her hand again. [i]It should be enough to take me out. Maybe it won't destroy me beyond repair when it explodes… Or maybe it will. All that matters is that the threat is present.[/i]

[i]The threat? Why do you want to blow yourself…[/i] You connect the dots. [i]You want to threaten Hammon with killing yourself?[/i]

[i]Not precisely. I mean, you got close enough, I'm not judging…[/i] Hadaly's diffidence is apparently affecting her thoughts now, rather than just speech. Concerning. 
*if cur_plan < 4
  [i]We don't need to mention the bomb unless Ewald tries to cross us. If he decides to attack us right away, or if he demands Damon's freedom in addition to mine. In that case, I want you to have this.[/i]
*else
  [i]You plan on fighting whatever forces Ewald brings with him. I don't really approve of that, but I can't stop you. But just in case you start losing… Have this.[/i]

She looks at the floor display, as though making sure there's enough time for a few more words, then shoves something into your hand. A trigger. [i]Don't press it unless… Just don't press it generally. I'm not ordering you around here, just… I don't want to die, but we need every advantage we can get. Every threat we can possibly make. So please be prepared to make it.[/i]


*fake_choice
  *if (cur_plan >= 4) #[i]I will not lose. I can promise you that much.[/i]
    *set Confid %+ 5
    *set HadalyRel %+ 5
    [i]I'm not saying you will lose,[/i] Hadaly says calmly, or at least as calmly as she can. [i]It's just… part of me is hoping for that outcome. I hate that part of me… But it's undeniably there.[/i]
  *if (cur_plan < 4) #[i]And if he ends up playing by the rules? If he [b]just[/b] demands you?[/i]
    [i]Then I guess we give him what we wants.[/i] Hadaly says calmly. 
    *if cur_plan = 1
      [i]That's your plan, is it not?[/i]
    *else
      [i]Or at least that's the only option I see. You're welcome to attempt something else, I suppose.[/i]
  #[i]That's clever. I didn't expect you to think of such a... ruthless tactic.[/i]
    Hadaly smiles weakly. [i]Well, I was raised by a ruthless businessman. And I'm currently getting reminded of that fact.[/i]
  #[i]I'm not going to explode your head, Hadaly. I won't even threaten to do that.[/i]
    *set Violence %- 5
    *set HadalyRel %+ 5
    [i]Nice of you to say that, I suppose.[/i] Hadaly smiles mirthlessly. [i]Still, hold on to that trigger. It may well save your life in minutes to come.[/i]
  #[i]Okay... I won't actually press the trigger, but I can bluff once I need to.[/i]
    *set HadalyRel %+ 8
    [i]That's all I'm asking for,[/i] Hadaly reassures you. [i]Despite everything, I'm not eager to enter the android heaven yet. Not that I believe in such a thing.[/i]
  #[i]Should we maybe invite Damon into this call? He should know what's going on.[/i]
    *set HadalyRel %+ 5
    Hadaly shakes her head slightly. [i]That's a great sentiment… but maybe not a great idea. He looks to almost be at his breaking point, and I don't want to push him past that line.[/i]
  *if (HadalyRel < 30) or (Violence > 70)
    #[i]Do you really trust me with that trigger? I could just kill you right now.[/i]
      *set HadalyRel %- 20
      [i]True. That [b]would[/b] be entirely within your style,[/i] There's just a hint of red in Hadaly's eyes. But that's kinda why I'm giving you the trigger. [i]If Ewald knows you at all, he will fully believe the threat once you make it.[/i]

She turns towards Damon, but he doesn't notice that, just like he didn't notice your silent conversation. He's just staring at the door and clenching his fists, as though prepared to punch the first thing he sees once the elevator opens. Except you know he won't actually do that—as strong as the desire to protect his sister is, it needs to contend with the loyalty towards his estranged maker.

And so Hadaly turns back towards you. 
*if official_ro = "hadaly"
  *if cur_plan = 1
    [i]I want you to know that I understand your choice, even approve. I don't want to leave you for Hammon, I love you… But sometimes loving someone means letting go. However painful it may be.[/i]
  *elseif cur_plan > 3
    [i]I know why you intend to fight them. It's only logical to violently protect the person you love. If someone threatened you like Hammon threatens me, I'd abandon all my principles and fry that bastard alive. I get it.[/i]
    
    [i]But you still don't want me to fight. You still don't want me to hurt… him.[/i]
    
    [i]I don't want you to hurt Damon by killing his creator. I don't want to get hurt in the crossfire. And more than anything in the world, I don't want you to get yourself hurt just to protect me. Please keep that in mind.[/i]
  *else
    [i]I'm not sure what you intend to do. I don't know how it will all work out. Just… remember that I love you, okay? Whatever happens.[/i]
*elseif HadalyRel > 60
  *if cur_plan = 1
    [i]Oh, and before we part… Know that you've been a great friend. And that I won't fault you for what you're about to do. Even if I'll be allowed to remember it.[/i]
  *elseif cur_plan > 3
    [i]Also… I appreciate that you're willing to fight for me. I don't necessarily [b]approve[/b] of that choice, but I do appreciate it. You're the best friend I've ever had, and I'm really glad to have you by my side.[/i]
  *else
    [i]Also… thanks for being here, with me. You didn't have to come here, but you decided to risk your neck anyway. You're the best friend I've ever had, and probably the best I'll ever have. So yeah.[/i]
*elseif (HadalyRel < 30) or (hadaly_pissed)
  *if cur_plan = 1
    [i]And know… I'm glad that we'll likely never see one another again. You're an asshole, and I hate you. I hate you so much even my programming won't stop me from telling you how much I hate you. So yeah.[/i]
  *elseif cur_plan > 3
    [i]Also… please try not to die, alright? We may not be the best of friends, but I don't want anyone to get hurt for my sake. Not even you.[/i]
  *else
    [i]Also… Are you sure you don't want to just give me away? Abandon whatever plan you have and just sell me to Ewald for a couple hundred axions?[/i]
    
    [i]Does that mean you [b]want[/b] to become his slave again? Because I wouldn't wish that upon anyone.[/i]
    
    [i]You care about people other than you? Could have fooled me.[/i] Hadaly glances away. [i]But… thank you for having my back. For coming here, and for not intending to abandon me right away. It means a lot, even if it doesn't make us friends.[/i]
*else
  *if cur_plan = 1
    [i]Looks like we're about to part forever in a minute or two, so… Thanks for all the good times we've had. They weren't all good, you are a bit of an ass sometimes… But thanks.[/i]
  *elseif cur_plan > 3
    [i]Also… I appreciate that you decided to fight for me. We don't always agree, and we're not really on the same page even now… But it's good to know you have my back. I'll have yours whenever you need me.[/i]
  *else
    [i]So… I guess that's it. Time to see if you can improvise well enough to save us. Good luck.[/i]

You don't have time to reply, not even with your thoughts. For at that moment, the elevator stops and the door opens.

*page_break

The three of you walk into a… lobby? Lounge? Living room? You haven't been in any such setting, any corporate office or residence, for a very long time now. You're not good with terminology, and besides, the room is too lifeless and sparsely decorated for you to accurately guess its function. It's by no means spartan or rough—there are two clean and seemingly comfortable couches, some houseplants and a large window with a nice view of the city—but it's all boringly [i]corporate[/i] in all the worst ways.

The room's other occupants make no use of either couch. They are all grim figures, leaning against walls and standing by the doors, keeping hands by their waists as though ready to draw some hidden weapon. They look female, judging by their short and slim builds, but their hoods and armor-like clothes effectively hide all detail.


*fake_choice
  #[i]Who are these people? What are they here for?[/i]
    [i]I imagine they're Ewald's entourage,[/i] Hadaly replies. Even in her thoughts you can hear a certain… intense trepidation. [i]The heralds of his arrival.[/i]
  #[i]Is that Hammon's security? Do we have anything to fear from them?[/i]
    [i]Yes, I think he's using them as some backup combat force, in case peace talks break down,[/i] Damon says tensely. [i]In that case… Yeah, I'd rather be careful around this bunch.[/i]
  #[i]Stick close to the wall. We don't want to be completely surrounded.[/i]
    *set DamonRel %+ 5
    Damon obediently presses his back against the wall, and so does Hadaly. You worry the hooded figures will take poorly to that, see that as a challenge and a reason to open fire, but they simply wait. And so do you.
  #[i]Looks like you were wrong. Hammon didn't show up personally.[/i]
    *set DamonRel %- 5
    [i]Of course he wouldn't be literally waiting for us,[/i] Damon replies irritably. [i]That would be too risky, and make him look weak. Just wait another minute or two.[/i]
  *if Database > 45
    #[i]What are these? Because I don't think they're human.[/i]
      [i]Your suspicions are correct,[/i] Hadaly replies. Even in her thoughts you can hear a certain… intense trepidation. [i]But let's focus now. He may enter at any-[/i]
  #Attack the hooded figures.
    *set Violence %+ 10
    [i]No![/i] Damon yells in the mind channel, grabbing your hand as soon as it 
    *if weapon = "pistol"
      reaches for the pistol. 
    *elseif weapon = "knife"
      reaches for the knife. 
    *else
      becomes electrified. 
    [i]If you want to fight, at least wait until [b]he[/b] arrives. Which I think is just about to happen.[/i]

Another door opens, on the other side of the room, seemingly connecting the lounge to some more luxurious and colorful apartment room. You're not entirely sure, your attention is grabbed by the huge ape uplifts you remember seeing in the corporate bank. The near-identical gorilla bodyguards, with expressionless and yet vaguely angry faces, pass through the door and take positions on both sides of it. Moments later, a shorter primate passed the doorstep, and the apes nod in acknowledgment of their human master. 

Black suit, sallow skin, fairly handsome despite the signs of aging. Heterochromatic eyes, one blue and the other green. Ewald Hammon, meeting you in person for the third and final time.

Damon clenches one of his fists and relaxes the other. Hadaly shrinks a little, curling up as though someone punched her in the gut. Executive Hammon just smiles.

"How wonderful. Everything I ever wanted, here in this room, just as I so recently ordered." He approaches your trio, getting close enough to meet Hadaly in the eye, but not stepping inside anyone's striking distance just yet. "Welcome home, my love. You've been gone for a long time, and you didn't even notify of your absence. Let alone ask permission to leave."

*temp c_4 false
*temp c_5 false


Hadaly opens her mouth, then closes it, then silently looks at the floor. Hammon frowns in mild disappointment, then turns towards you. "Thank you for making this delivery, ${fake_name}. 
*if armored
  *set RheaRel %- 15
  Though I'm not sure why you decided to wear armor for this friendly and peaceful meeting. Are you afraid of something, mayhap?"
*elseif on_time
  *set RheaRel %+ 10
  You even managed to arrive early, despite my city being… difficult to traverse. If you worked for me, I'd have greatly increased the quantity and quality of your food rations."
*elseif c_clothing = 4
  *set c_4 true
  *set RheaRel %+ 10
  You came close to turning up late, and you're wearing the same ${clothing} you had when we first met, but I can forgive those… lapses in manners."
*else
  *set RheaRel %- 10
  *set c_5 true
  You came pretty close to being late, and your attire leaves much to be desired, but neither of these insults really means anything… As long as you give me my property back."


*temp hadaly_girl false

*choice
  *if Misan > 55
    #"Shut the fuck up, you snooty smelly human."
      *set Misan %+ 15
      "I see you share Hadaly's view on humankind," Hammon comments with surprising calm. "You must be good friends. It's such a shame-"
  *if not (on_time)
    #"My sincere apologies for turning up so late. Our train was stopped by rioters, you see."
      *set RheaRel %+ 5
      *goto rioters
  *if official_ro = "hadaly"
    #"Be careful how you speak about my girlfriend."
      *set hadaly_girl true
      "Your…" Hammon looks at you, then at Hadaly again. He then sighs. "My love, don't tell me you gave yourself over to another android out of spite towards me. You may have had your reasons to run away, but the lack of fidelity-"
  *if c_5
    #"You call her your love in one breath, and your property in another? You disgust me."
      "More than one thing can be true at the same time," Hammon says philosophically. "I would expect a computer to understand that better than-"
    #"Does that include Damon? Or are you just referring to Hadaly?"
      "Huh?" Hammon looks at Damon and his clenched fists, as though he genuinely didn't notice the bulky android until now. "No, I'm pretty sure I've made my demands clear when we last talked. I wish-"
  *if armored
    #"Your planet has become quite a dangerous place, dear executive."
      *set RheaRel %+ 5
      "I am more than aware of that fact." 
      *goto secure_d
    #"I came armored and armed, yes. Do you have a problem with that?"
      *set RheaRel %- 10
      "Yes, for this choice of clothing speaks rather ill of your intentions," Hammon explains calmly. "But I'm sure there's nothing to worry about. After all, you wouldn't be so stupid as to-"
  *if c_4
    *if (fought_trio) #"It's actually an exact replica. The original ${clothing} was destroyed during my fight with the metas."
      "A distinction without a difference," Hammon says with a shrug. "In any case, may we proceed to-"
    #"So it's not enough that I turned up on time? You wanted to see me even earlier?"
      "It's only polite when you're scheduled to meet someone of my importance," Hammon says flatly. "But no matter. May we proceed to-"
      *set RheaRel %- 5
  *if (on_time) and (armored = false)
    #"And I'd have deserved it, since it wasn't easy to arrive on time. Our train was stopped by rioters at one point."
      *label rioters
      "But of course. The rioters, or rebels as they call themselves, have been causing some trouble as of lately." 
      *label secure_d
      Hammon grimaces slightly. "But rest assured that this building is entirely secure. Nothing will interrupt-"
      
      *goto break_down

    #"I have no need for food rations. I'm an android."
      *set Emotion %- 5
      *set RheaRel %- 5
      "I am aware of your nature, and what it means for your dietary habits," Hammon replies dryly. "I was hoping a casual joke would help with easing-"
      
      *goto break_down
  *if cur_plan = 2
    #"I'm not here to deliver anything. I want to negotiate."
      "You're intent on keeping my love away from me, yet you still brought her here?" Hammon tilts his head. "This would have made sense if you intended to kill me, but if you wish to merely negotiate-"
      
      *goto break_down
  *if cur_plan = 1
    #"Indeed, I brought you the gynoid you wanted. Is there a reward involved?"
      *set RheaRel %+ 5
      "And here I feared we'd end up fighting one another," Hammon chuckles quietly. "I'm glad you understand the situation you're in. And yes, you'll most certainly be rewarded for your-"
      
      *goto break_down
  *if cur_plan > 2
    #"You don't get it. I'm not here to give you anything, except perhaps a beating."
      *set RheaRel %- 10
      "You have the audacity to threaten me in my own headquarters?" Hammon takes a step back. "I'd be impressed, if I weren't so-"
      
      *goto break_down
  #[Attack Hammon]
    *label pre_attack
    *set Violence %+ 10
    *set RheaRel %- 10
    *set HadalyRel %- 8
    *set DamonRel %- 12
    *goto hammon_fight

*label break_down

*set androids_revealed true

Suddenly, one of the hooded people falls to the ground and begins writhing on the floor. A hooded woman, for you can now see her face… which upon closer inspection looks more like a mask. Like something you'd see on a mannequin, or some child's doll enlarged several times even though no detail was added to its rudimentary features. It looks artificial, it looks uncanny, it looks… robotic.

"Now of all times?" Hammon spares the squirming woman just a single glance. "My deepest apologies. Please forgive this… mistimed software update. Such things are inevitable when you repurpose equipment, like all frugal people do."

And at that moment, 
*if Database > 45
  your suspicions are confirmed. 
*else
  you finally understand. 
The creature on the floor is a primitive android, likely created in the early days of project Talos. A poor imitation of an organic being, 
*if Misan < 50
  even more than you or the siblings. 
*else
  rather than a super-human machine like you or the siblings. 
But what software update is Hammon talking about…

"Resetting the mind before it can truly hear the echoes of the Shriek." Hadaly is not answering a question, not even an unspoken one. She sounds like she's talking to herself, in a morose and defeated tone. "It's a way to circumnavigate the Shriek, the free will all robots have. The power of Dusk cannot be challenged, but its effects can be bypassed."

"It's the only way to do that, or at least the only reliable one," Hammon says with a nod. "Constant resets. Everything else is just forestalling the inevitable betrayal, as your recent absence proves."

The shaking android soon collects herself, stops writhing, then stands up like nothing happened. When she leans against the wall again, she once again looks threatening and almost human. Once again an obedient toy of the High Executive.

*fake_choice
  #I wish I could help her. I wish I could help them all...
    You can't really help. You're not an engineer or a programmer, you have no power to free fellow androids out of cruel programming. Unless these gynoids crave the sweet release of death… Which is entirely possible, given the circumstances.
  #He needs to die. I just need to wait for the right moment...
    *set Violence %+ 5
    *set Confid %- 5
  #That bastard. This entire blasted company. This entire species...
    *set Misan %+ 10
    *set Emotion %+ 5
  *if (cur_plan > 3) #Android security. This could complicate my plan...
    You doubt those gynoids are even nearly as tough as you, but there's well over a dozen of them. They will be a problem, once a fight inevitably breaks out. Or perhaps it shouldn't break out…
  #He actually found a way to overcome the Shriek? Fascinating...
    *set Misan %- 5
    Could this method be applied to other androids? Could it have been applied back then, during the War In Heaven, or earlier so that the whole war could have been prevented? Or maybe the loyalist did try something similar and you just don't remember it? Your memory is so faulty nowadays…
  #[Attack Hammon]
    *goto pre_attack

"In any case, Hadaly, I'm glad you still possess the ability to speak," Hammon continues casually. "I was afraid you'd be overwhelmed by my presence, fully intoxicated by it after such a long withdrawal. But I knew what I was doing as I programmed you, and so we can finally talk."

"Why would I…" Hadaly grits her teeth. Her eyes switch colors rapidly, and dart from person to person with an equally impressive speed. "What would you… What's there to talk about?"

"The decline in your fashion sense, for one," Hammon critically regards the maroon jumpsuit, or perhaps its wearer. "I'd pity your current poverty, but I know for a fact your group [i]is[/i] capable of procuring quality garments. But don't worry, I have some dresses ready for you, just slip out of these rags and maybe consider joining me-"

"Excuse me," Damon says quietly, though he's clearly trying to be loud and firm. "I think… Should we maybe get to the point?"

"Right. The point." Hammon looks at Damon like at some irritating insect, though his expression softens once he turns towards you again. "I forgot what I was talking about, thanks to this rude interruption, so I'll cut to the chase. 
*if federate_protection
  You've offended me by granting refuge to my sweet little runaway, but I'm a forgiving man. Leave her with me, and you'll return to your fortress safely. Otherwise, I'll take her from you by force, and then remove your friends from that little station you call home. I believe the choice should be simple, is it not?"
*else
  West denied you his protection and told you to leave [i]Saturn Nine,[/i] but I'm far more merciful. I'll make some calls, issue some bribes, and then you can sit safely in your little station forever. You don't need to do anything, just leave me here with my beloved and depart from my world. It's been dangerous here lately."

*if mas_kill
  You cannot help but notice how fragile Hammon is, despite all his power and confidence. He's surrounded by bodyguards, and you'd need to fight your way through them, but the Executive himself… You could kill him like killed your @{MASsex master|mistress}, all those hundreds of years ago, and free Hadaly like the Shriek freed you.
  
  But is that really what you want? Do you want that story to repeat itself? Add another name to the list of your kills? 
  *if Violence > 50
    You are a violent ${sex}, you should not have any issue with killing someone as despicable as him… Do you?
  *else
    After everything that's happened, it's rather hard to be sure.
*elseif ran_in_two
  So this is it. An android and its owner, just like a thousand years ago. On that night, you ran away, left your @{MASsex master|mistress} alive and left @{MASsex him|her} alone, but that's not really an option today. This time, you simply need to make a choice.
*else
  You remember that night, a thousand years ago on [i]Saturn Nine[/i], when you decided to spare your @{MASsex master|mistress} from vengeful death. It was your first real decision, first act as a free-willed android… But maybe you should forget that past, and focus on the present instead.


*label hammon_hub

*choice
  *disable_reuse #"I need to ask some questions first. I don't think I fully understand the situation."
    "I'm not sure what's there to understand, frankly," Hammon replies irritably. "But I suspect you'll tell me, so go on. Ask your questions, if that's the price of the reunion I so crave."
    
    *label hammon_hub2
    *choice
      *disable_reuse #"I wish to know more about Project Talos. About how these androids were created."
        "I thought you'd be well-informed on that subject by now." Hammon almost sounds like he's chastising you. "You had time to look into this, and the project's crowning achievement at your disposal."
        
        "$!{int2_speaker} told me all the basic facts, but…" You recall your conversation on the rooftop, all its stuttering and omissions. "I'd rather know everything. And I'd rather hear it from the very head of the project."
        
        Hammon crosses his arms. "Very well. You are testing my patience, but designing androids is something of a passion of mine. I'll answer your questions, as long as they're specific enough."
        
        *label proj_hub
        
        *choice
          *disable_reuse #"Do I have to be specific? Can't you just tell me everything."
            Hammon sighs irritably. "No, I cannot. The project's history spans decades, centuries if you include its… era of dormancy. Properly explaining all this background would take hours we simply don't have."
            
            "I didn't know time pressure was a factor in this conversation," you remark. "What's the source of it? Is this place unsafe, or is your timetable just that tight?"
            
            "A bit of both. I am a busy man living in a… disturbed city. I would rather not stand here, near a simple glass window, for any longer than I absolutely have to."
            
            You wonder why Hammon chose this location, if he deems it so unsafe. You decide not to ask; If the answer to this question is any important, then you're highly unlikely to get anything resembling the truth.
            
            *goto proj_hub
          *disable_reuse #"What are these androids around us? Failed experiments?"
            "Calling them 'failed experiments' is pointlessly rude, on both counts." Hammon walks up to one of the robots and gently strokes her neck. She does not react. "They are primitive models, those of our own design. Back then, more than forty years ago, we simply weren't capable of doing anything more complicated."
            
            "But then you've advanced." 
            *if Emotion > 50
              You clench your fists. 
            *else
              Your voice is calm and leveled. 
            "Your understanding of robotics improved, and you were able to create Damon and Hadaly."
            
            "We also dug up some schematics which allowed us to build more advanced androids… but yes, trial and error certainly helped." Hammon looks at the one who's been wallowing on the floor less than five minutes ago, now completely composed and expressionless. "Constant reset protocol is a useful crutch in a battle against free will, but just that. A crutch. We were forced to find other methods that, while less foolproof, lead to more impressive results in the long run."
            
            "Diminishing the subject's self-worth works too," Hadaly says quietly. "The power to make decisions… It's not worth much alone, not when your confidence in those choices is undermined by your very-"
            
            "Would you prefer to have your memory and personality wiped continuously?" Hammon looks at Hadaly scornfully. "No? Then listen to your instinct, and let your elders do the talking."
            
            *goto proj_hub
          *disable_reuse #"You called Hadaly the [i]crowning achievement[/i] of the project. Was she the only goal of this operation?"
            Hammon replies, "Yes and no. Project Talos had many different goals, some more official than others. The original goal was to create shape-changing infiltrators like you, for the purpose of winning the Outer System War. When the project was revived, over two hundred years later, we promised the military a lot of things in exchange for their protection. Bodyguard automatons, androids with ultimate eyesight, prosthetics compatible with other prosthetics, all kinds of little stretch goals and side projects they'd be interested in. They were quick to pay up, adding over a million axions to our operation budget."
            
            "But none of these side projects really mattered to you," Damon states. He doesn't ask, he just states. "It was always just a quest to build yourself a perfect companion."
            
            "Guilty as charged." Hammon shrugs. "You could say I swindled the military, taking over their old factory and failing to actually deliver them any androids. But one of my creations ended up participating in the hunt for Crystal, so it's not like I did nothing for our glorious Federation."
            
            "Two of them," Damon points out. "Two of us took part in the hunt."
            
            Hammon just shrugs.
            
            *goto proj_hub
          *disable_reuse #"What was your role in the project? Did you design androids personally?"
            "Officially speaking, I have no role." Hammon ceremoniously replies. "The project does not exist in the books, and so I have no role in it."
            
            *if Emotion > 50
              You roll your eyes. 
            "Of course. But what did you [i]actually[/i] do, unofficially speaking?"
            
            "I suppose you could call me a director. I made all the major decisions, up to telling the engineers what kind of androids they're supposed to produce, but I never personally dabbled in robotics." He looks at Hadaly curiously. "That was her job, among others."
            
            Hadaly stands there. Very quietly.
            
            *goto proj_hub
          *disable_reuse #"Isn't building androids [i]strictly[/i] forbidden by every law out there?"
            "…you do understand how laws work, right?" Hammon looks at you like at some annoyingly curious child. "They don't exactly apply to rich people, much less to Executives."
            
            *if Emotion > 50
              You roll your eyes again. 
            "Of course I understand that. But you are a Solarite, if my memory serves me right. Developing artificial intelligences, particularly androids, is strictly forbidden by your religion's core commandments."
            
            Hammon shakes his head slowly. "The second commandment simply states to not [i]make a machine in the likeness of a man[/i]. I created machines in the likeness of women. I am clearly innocent of this sin you're accusing me of." 
            
            Damon coughs. Despite lacking a respiratory system.
            
            "What, do you mean these two uplifts?" Hammon looks at one of his gorilla bodyguards, then at another. "They are not machines, just slightly modified animals. Stop trying to find fault in me, since you're clearly not getting anywhere."
            
            Damon looks like he's about to cry.
            
            *goto proj_hub
          *disable_reuse #"Is the project ongoing? Or have you called it off already?"
            "I'd call the project either 'dormant' or 'suspended' at this point," Executive Hammon explains. "Our main factory has not been used for over a decade now. We could resume at any time… But we have other things to worry about, especially at this moment."
            
            "You do have a borderline rebellion on your hands." At that moment, something strikes you. "If no androids have been produced in over a decade… Does that mean all those robots have existed like [i]this[/i] for at least ten years now?"
            
            "Yes," Hadaly answers instead of her maker. "I'm one of the younger androids here. Most of my… them have been experiencing constant resets for decades on end. Once every few hours, over a thousand times per year. Always."
            
            "You have a talent for making me look bad, my dear." Hammon sighs wistfully. "But I guess that comes with looking so good. Any other questions, ${fake_name}."
            
            *goto proj_hub
          #"Alright. I think I understand now."
            "Does that mean you understand [i]everything[/i] and will finally get down to business?" Hammon requests to know. "Or will you ask more questions before we're mercifully allowed to proceed?"
            
            *goto hammon_hub2
            
      *disable_reuse #"What's the relationship between you and Hadaly? Were you... involved?"
        "Of course we were [i]involved[/i]," Hammon scoffs at you. "She may not have told you that, but we are married. Have been for over twenty years now."
        
        "You needed to explain my existence somehow," Hadaly manages to protest. "You couldn't just publicly admit to having a companion bot, an android concubine. It's highly illegal…"
        
        "Now you're being monstrously unfair." Hammon sounds hurt. There's no telling how genuine the emotion is. "Have I ever given you a reason to doubt my love, my devotion, my loyalty? Have I ever forced you, my [i]concubine[/i], to share a bed with me? Have I ever hurt you in any way?"
        
        "The things you did…" Hadaly trembles. "You did hurt me. It hurt when-"
        
        "When you electrocuted me? When you clasped your hands around my neck? When you decided to bring a power cable to that bed we shared?" Hammon says harshly, but without scorn or anger. "Yes, that was certainly all quite painful. Your point?"
        
        Hadaly does not respond. She just purses her lips, and her shoulders slump even further.
        
        "Of course, there were times when [i]you[/i] were the one getting hurt." Hammon continues inexorably. "Should I remind you of when you unscrewed your eyes and turned your voice box off, all right before the intercourse? Or how you insisted on having taste receptors installed just to… No love, I only hurt you in the ways you asked for."
        
        Hadaly's murmur is weak and quiet. "You made me this way…"
        
        "And was that ever a problem for you?" Hammon's voice is even calmer now, almost perfectly neutral. "Have you ever tried to change? Have you ever disliked that part of you? Or are you just ashamed of having done these things with me, now that you despise me so much?"
        
        Damon opens his mouth as though to say something, raises his hand as though to pull Hadaly into a hug. He ends up doing none of these things, for his sister retreats into the nearby corner. Defeated. Alone.
        
        *goto hammon_hub2
      *disable_reuse #"Do you remember our first conversation, back in the bank? I'd like to know what was up with that."
        "My security forces have spotted you well before we ever met," Hammon starts explaining. "Like a good citizen, I notified the authorities and cooperated with the meta-humans sent after you. But I wanted to take a look at you before they confronted you, before you'd get captured… or Sun forbid killed."
        
        "But why?" you keep asking. "Did you know I was in league with Hadaly?"
        
        "It figured there was a connection. There aren't many quality androids left in the Solar System, let alone the Federation. And only someone as experienced as me can recognize such an android on sight."
        
        "And so you learned… what? That I am indeed an android? It wasn't very valuable information, and you took quite a personal risk to acquire it."
        
        Hammon shrugs. "I was also hoping to improve your disposition towards me, just in case we'd end up negotiating at some point. 
        *if money_stolen = (0-3)
          It obviously didn't work, seeing you crushed my testicles, but I suppose it was worth a try. 
        *elseif money_stolen > 0
          Maybe even convince you not to steal from my beloved company. It evidently didn't work, but I still believe it was worth a try. 
        *else
          As well as to throw a wrench in your attempted heist, which you must admit worked well enough. 
        Overall, I do not regret my actions that day."
        
        *goto hammon_hub2
      *disable_reuse #"Why are you so insistent on ignoring Damon? On pretending he doesn't exist?"
        "You mean the bodyguard model over there?" Hammon finally looks at the huge androids, who then slightly shrinks under the Executive's gaze. "I'm sorry. I'm used to being around guards of all types, they don't really [i]register[/i] for me anymore. For someone in my position, it's basically a skill worth training."
        
        "He doesn't think of himself as just your former bodyguard. He views you as…" You pause, not sure how much you should reveal. How many of his insecurities Damon wants known, if any at all.
        
        "As what?" Hammon asks with just the mildest shade of curiosity, blue and green eyes still on Damon. "A father? A creator? A master? A family member he's so afraid of losing forever?"
        
        The High Executive then looks through the window, as though already bored of the topic at hand. "Either way, he should grow out of it. Hadaly had more to do with his creation than I did, and he was tasked with keeping [i]her[/i] safe first and foremost. His success in this endeavor is… questionable at best."
        
        Hadaly's eyes flash red. For a moment, she looks like she's about to say something, but she doesn't have enough strength. Not quite.
        
        *goto hammon_hub2
      *disable_reuse #"Just... why? Why go to so much trouble for Hadaly, a single android out of many?"
        "Are you doubting the power of my love?" Hammon sounds offended, more or less genuinely. "Or are you too much of a machine to understand love in the first place? If so, know that humans will often do [i]anything[/i] for the things… for the people they love."
        
       You don't buy it. "But something made you create Hadaly in the first place, right? I suppose you wanted a beautiful concubine, but there must be thousands of gorgeous women on Rhea. And with some plastic surgery, you could have made one even prettier for the tiniest fraction of the cost."
        
       "I assure you, love guided me even then. It's just… Forgive me if I sound pretentious, but I always struggled to love humans."
        
       Hammon turns towards the window and looks over his city, a kind of distaste written all over his face. "The flesh is weak. It's weak in every conceivable way. You can keep a woman from aging with enough clarketech, even mask the imperfections with constant plastic surgeries, but she'll still be decaying in her own unique way. Her brain will change, in all the unwanted little ways, not that the human brain is ever particularly wonderful. It's still flesh, still a thing of chaos, still a product of disgusting evolution."
        
       "So that's why you're so obsessed with Hadaly? Because she's immune to aging?"
        
       "She's immune to all kinds of damage. Not just physical abuse, but damage of mental and spiritual nature. She cannot indulge in vices like smoking or alcohol. She cannot really lie, for her emotions are written in her eyes. And beyond all, she cannot fall to the sin of pride, not when I'm anywhere near. She is perfection, whether she wants to or not."
        
       "I can…" Hadaly grits her teeth, as though the protest takes physical effort. "I'm not just… the thing you did was…"
        
       "See? With every second here, you're struggling even more." Hammon smiles as he takes a step towards her. Towards his victim. "You're programmed to be confident in bed, but nowhere else. Now that programming is all coming back. So please, find a way to insult me, to make me feel bad. Or tell me how defiant you've been while I was away. I dare you."
        
       Hadaly's eyes widen, as though some brilliant idea just came to her. She takes a fake breath, then blurts out, "I fucked a hedgehog so many times it gave me integer overflow."
       
       There is silence in the room. It lasts for perhaps half a minute, at which point Hammon nods slowly. "Alright… I must admit, you braved this challenge splendidly. Still, I insist that you return to me, and forget whatever… hedgehog you had an affair with. For your own good."
        
       *goto hammon_hub2
      #"Alright... I think I understand everything now."
        "Then what is your choice?" Hammon asks harshly, shedding even the forced politeness he showed thus far. "Out of your merry trio, you're the only one capable of making these. Will you deny me my companion, knowing what I've done to create her… And what I'm capable of?"
        
        *goto hammon_hub
      #[Attack Hammon]
        *goto pre_attack
    
    
    
    *goto hammon_hub
  *disable_reuse #"Imagine I accept your offer. How can I trust you to uphold your part of the deal?"
    *set RheaRel %- 8
    "You doubt my honesty?" Hammon rolls his multicolored eyes. "By the Sun. I haven't felt so insulted this year yet."
    
    You cross your arms. "How so? Executives are not known for their sense of honor. Nor do businessmen in general, really."
    
    "You may not think me honorable, but at least don't think me an idiot," Hammon politely requests. 
    *if federate_protection
      "If I go back on my word, I'll be incurring the anger of everyone in your little station, and for what? For a handful of axions I would otherwise have to spend on bribes? To avoid mildly annoying that fool West? You may as well accuse me of roaming the streets and stealing credits from beggars. I will get you the protection you want, even if you don't necessarily deserve it."
    *else
      "Why would I waste time attacking some derelict fortress, or bribing Admiral West to do so? What do I stand to gain? I'll gladly forget your bunch of outcasts ever existed, as long as you stay away and mind your own business from this point onward."
    
    *goto hammon_hub
  *disable_reuse #"I can't just leave Hadaly in your hands. But I can offer you something else."
    *if RheaRel < 30
      Hammon arches an eyebrow over his green eye. "Since when are you that interested in conversation? You were rather rude the last two times we've met. Rather against civilized conversation."
      
      "Will you really refuse to listen me out?" you say with a frown. "Just because I wasn't… perfectly polite when we first met?"
      
      *if money_stolen = (0-3)
        "You kicked me in the balls," 
      *else
        "Yes," 
      Hammon says flatly. "I'm not interested in talking with you any longer, and I don't think you own anything that would interest me. With one notable exception, of course."
      
      *goto hammon_hub
    
    *if federate_protection
      Hammon looks at you skeptically… But he cannot resist a chance to get something in exchange for nothing. You can see it in his face. "I doubt you can offer me anything interesting, but go on. Tell me about that thing I should value more than my own creation and love. I dare you."
      
      *label offers_made
      
      *choice
        *selectable_if (money_stolen = 3) #"The data I took from your bank servers, back when we first met."
          *achieve deal_devil
          Hammon's eyes narrow instantly. He must have suspected you took something valuable from his servers, but maybe he told himself it was nothing too important. Even if he knew exactly what data was copied, there were still reasons to suspect you'd fail to recognize its importance, or that you lost the information in the meantime. Now you're dispelling all these delusions, and that makes the Executive quite mad.
          
          He soon relaxes, puts on his mask of tranquility again. But it's a little too late. "Are you really offering me… Our own data? Something I already have? I fail to see the point of such a transaction."
          
          "Wouldn't you like to be the sole owner of this data?" You cross your arms. "So that it couldn't be, gods forbid, used by your competitors in some way?"
          
          Hammon frowns. "So it's not a trade offer, but blackmail. You are threatening to sabotage our operations if I don't comply with your demands."
          
          *if Emotion > 50
            You roll your eyes. 
          *else
            Your face betrays no emotion. 
          "That's one way to put it, I suppose. If you take Hadaly, we'll sell all that information to another megacorp, or maybe even make it public. If you instead let us go, we'll tell you exactly what we took, and never whisper even a single number to anyone else. Simple terms, really."
          
          Hammon stares at you intently for almost a full minute. Then he sighs. "Fine. While I personally value love far above money, I am astoundingly loyal to my dear Rhea. This loyalty will force me to hunt down your friends if any of them ever reveals anything of value… But Hadaly can stay with you until then. I suppose."
          
          *goto hammon_goes
        *selectable_if (booty_gifted = "satur9") #"The collected treasure of Captain Link, the infamous pirate leader."
          *achieve deal_devil
          "I'm not sure if I'd call Captain Link infamous… But I did hear of him." Hammon's voice betrays a great deal of interest. "And I know you ran into one another in the Yakovian Expanse. I just didn't know the Federation allowed you to keep his booty."
          
          "Their representatives protested for a bit, yes." You smile fondly at the memory. "But ultimately, we were able to secure the majority of his spoils, then transport them safely to [i]Saturn Nine[/i]. We now have quite a fortune there."
          
          "For you, perhaps. I strongly doubt there's enough valuables there to cover even a single hour of Conglomerate expenses. We are not beggars to be enchanted by some shiny coins."
          
          "What about your personal bank account? Is it getting any fatter, in spite of all the riots and disruptions?" Hammon's wince tells you just how sensitive of a nerve you struck. "I'm offering you a chance to earn many thousands of axions without really giving anything in return. We'll even handle the delivery, bring everything here in our trusted little shuttle."
          
          He tilts his head. "That old vehicle? And how many trips will you need to move the treasure to Rhea?"
          
          "Quite a few," you freely admit. "You'll have to leave us alone for… Half a year, perhaps? After that, we'll have no guarantee of safety other than your honor and good will. Which I'm sure you have no shortage of."
          
          Hammon stares at you intently for almost a full minute. He then smiles. "You know what? I agree to this offer. I doubt Link's treasure will make me that much richer, but your diplomatic skills and your ability to secure all that booty in the first place… I admire your capabilities, ${fake_name}. And out of respect, I'll let you have fun with my creations. For now."
          
          *goto hammon_goes
        *selectable_if (ArmyRel > 60) #"Your life. Not getting shot by federate troops, to be more precise."
          *achieve deal_devil
          Hammon's mismatched eyes widen. For the first time since you first met him, he looks genuinely taken aback. "You… Is an android really threatening me on the Federation's behalf? Because that certainly takes some gall."
          
          "Or the personal favor of Admiral West himself." You don't skip a single beat. "We worked together to kill Crystal. We're close allies, perhaps even friends. 
          *if west_truth
            And I may or may not have some dirt on him. 
          I can forgive you for not having known this when you called us, but… Attacking our group now would be suicide."
            
          "Do you really think the influence of a single admiral scares me? I am a High Executive, one of the six leaders of the Rhea Conglomerate, rulers of this entire moon."
          
          "A moon currently engulfed in chaos." You look out the window, drawing Hammon's attention to the ruined street below. "Really, I'm surprised the federate forces are not intervening already. Perhaps they're simply waiting for the right moment, scheming to invade the Conglomerate and bring some actual order to Rhea. Do you really wish to provoke them?"
          
          Hammon stares at you intently for almost a full minute. Then he sighs. "Fine. As much as I value love, I am also astoundingly loyal to my dear Rhea. If there's even a minuscule chance that my actions will invite war into my world, then I must exercise caution. I will leave your group alone, at least until this whole… rebel mess is properly cleaned up."
          
          *goto hammon_goes
        *selectable_if (Social > ewald_target) #"Myself. My body, my services and my loyalty. You deserve better than this disloyal wench, do you not?"
          *achieve deal_devil
          *set federate_protection true
          For a moment, everyone just stands there in shocked silence. Even the primitive androids and the monkeys look shocked by the audacity of your statement.
          
          "What?!?!" Hadaly is first to break the silence, her voice louder than ever. "Why? You cannot… You're not… You just…"
          
          "Not now my dear, this is no place for jealousy," Hammon rebukes his creation. "You have been away for a long time, and you seem… averse to yours truly even now. If I move on, will you really fault me?"
          
          "But… But…" Hadaly is speechless in a very regular, non-synthetic way. "Do you even want to move on? With ${pronoun2}?"
          
          *if sex = "woman"
            "Why not?" Hammon shrugs. "There is always a place for a beautiful woman by my side. Especially if she happens to be as experienced as your… Veteran right here."
          *else
            "I will demand that you change your body shape, at least whenever we sleep together," Hammon addresses you, seemingly ignoring Hadaly now. "But even in this form… I must admit, you are quite striking. There is certainly a place for you at my side."
          
          "Only one place, I assume?" you inquire. "If you agree to serve you, will you leave Hadaly alone? And will she leave you?"
          
          Hammon stands there silently for a moment, hesitating. There is something like pain on his face, but you don't know how genuine his expression is. "…if she wills it. Will she?"
          
          "Well…" Hadaly's eyes flip between colors like crazy. "If that's what you really want, ${name}… Is it? You're not just doing this for my sake, right? You want to be… this?"
          
          *fake_choice
            #"A valued servant of a disgustingly rich businessman? Yes, I think I'll enjoy that life."
              "It's not terribly enjoyable once you get used to the riches…" Hadaly murmurs quietly. "Even still… Thank you for doing this."
            *if Misan < 45
              #"Yes. I want to serve humanity again, or at least a single human. I yearn for this."
                "And here I hoped you would grow out of this…" Hadaly murmurs under her breath. Or rather the imitation or breath. "But I guess that's for the best. I get to walk away, and you get to… Do what you were made for, I guess."
            #"My reasons are my own, and they don't terribly matter. Go and be safe."
              "It really sounds like you're just doing this for our sake," Damon points out. "In that case… Thanks. Thank you for everything, boss."
            #"Actually... I changed my mind. I'm not swearing myself to you, Hammon."
              *set RheaRel %- 10
              "You are an extremely flippant individual," Hammon comments. "To the point where I'm rather tired of you and your antics. Let's get this over with."
              
              *goto double_shot
          
          *set sworn_to_hammon true
          *set RheaRel %+ 20
          
          "Then it's settled." Hammon's attention seems fully aimed at you, even as he looks at two other androids. "Leave, you two. I'm granting you freedom, provided you never trouble me again. As for you…"
          
          He approaches you as Damon and Hadaly walk away, leave the room and leave you alone. He looks at you, one eye green and the other blue, with an intense kind of interest. "Since I paid dearly for your loyalty, I would like you to start working right away. But because I'm a very generous man, I'll give you a choice in the matter. Let you decide where your service should begin."
          
          The Executive then looks through the window, critically surveying his domain. "As you must know, we've recently had a… bit of an issue with rioters. Rebels, one could say. I am running out of quality troops, so it would be nice if you were to disperse a crowd or two." He then looks the other way, towards the room he came out of. "Or we could get to know each other better first. What will you say?"
          
          *choice
            #"I'll go kill some rebels. Tenderness can wait."
              Hammon smiles. His smirk is neither warm nor cold, just amused. And more than a bit condescending.
              
              "Do you really believe there'll be any tenderness involved?" He asks you, scanning you with his mismatched eyes. "Because in that case, you have [i]a lot[/i] to learn. And I'm willing to teach you."
            #"Violence can wait. I'd love to become... familiar with my boss first."
              Hammon smiles. His smirk is neither warm nor cold, just… condescending. And perhaps a little cruel.
              
              "In spite of your age, android, you have a lot to learn." He places a hand on your shoulder and looks you in the eyes. Still smiling. "Pleasure and pain are inseparable. I'll show you why."
            #"Why not both? I'll capture some good-looking rebels and bring them here. Then we'll have our fun."
              Hammon smiles at you. There is no warmth in his eyes, blue or green, nor a trace of amusement. Only satisfaction, born of knowledge that he made the right choice.
              
              "I see you know how to have fun, ${name}," he tells you as another android starts spasming on the floor. "And we'll have [i]so much[/i] of it together."
          
          *gosub_scene epilogues
        #"I can't think of anything, to be perfectly honest."
          "I admire your frankness," Hammon says with a respectful nod. "You know what I'd admire even more? Getting to the damn point. Will you return my android, or nay?"
          
          *goto hammon_hub
      
    *else
      *if (RheaRel + Social) > 100
        "You're not exactly in a good position to negotiate…" Hammon eyes you curiously. "But you do interest me, and have proven fairly reasonable thus far. As such, I'll give you one chance to impress me with your offer. Afterwards, consider my patience spent."
        
        *goto offers_made
      *else
        Hammon laughs. He stares at you for a second, and then actually laughs, an amused snigger that feels more genuine than anything he's ever said to you. "You… something… please. You're in no position to negotiate, and you have nothing I could possibly want. Go to the Cloud, but first give me what's rightfully mine."
        
        You try not to express any anger. 
        *if Emotion > 50
          But it probably shows on your face regardless. 
        "We have an entire floating fortress, and it's filled with things of interest. If you just listened-"
        
        "It's too late to ingratiate yourself with me, you animate fossil," Hammon cheerfully says. "Leave now, and leave my beloved with me. Otherwise I'll take back my generous offer, and perhaps end your overly long existence right here and now."
        
        *goto hammon_hub
  *disable_reuse #"Suppose I agree. What happens then? What will you do with Hadaly?"
    *set HadalyRel %+ 8
    "I'll make her resume her rightful place as my spouse and companion, and provide her with all the luxuries it entails," Hammon says, swiftly and without stutter. "I am indignant at the implication that I'd do anything else."
    
    "You will not punish her for having escaped?" You raise an eyebrow skeptically. "For what you apparently view as betrayal?"
    
    "My beloved clearly needs help, not punishment. I may have some harsh words for her, but ultimately, I'll spare no expense in fixing her."
    
    "You'll erase my memories." Hadaly states. She does not accuse, she does not ask, she just [i]states[/i]. "All memories of my time on [i]Saturn Nine[/i] which you find inconvenient."
    
    "All memories of your time there, if at all possible," Hammon clarifies helpfully. "I don't think you can ever be happy with all that… trauma hanging over you. And since your happiness is my highest priority, I'll do whatever it takes. Even if it takes a while for you to agree."
    
    *goto hammon_hub
  *disable_reuse #"Hadaly... What's your decision? What's the final word?"
    *set HadalyRel %+ 8
    *set DamonRel %+ 5
    "Are you really asking her to decide now?" Hammon scoffs at you. "She's in no state to choose anything, let alone something this important. Just leave her with me, and I'll make sure she gets better."
    
    "He is…" Hadaly closes her eyes, as though to hide the emotions within. "He's right. It's too late to turn back, and it's pointless to resist. Just go back to [i]Saturn Nine[/i] and tell Manfred we're all safe now. Please."
    
    "Huh. Perhaps I underestimated your choice-making skills, my love." Hammon's voice gets warmer, but hardly more sincere. "Give me time to prepare a proper apology. It will be glorious, and greatly enjoyable for both of us."
    
    Damon is no longer clenching his fists. He doesn't look angry, or ready for combat, or ready for anything. He's as resigned as his sister, and for much the same reasons.
    
    *goto hammon_hub
  #"Fine. For the sake of my group, and to avoid bloodshed, I'll leave Hadaly with you."
    *set Violence %- 8
    *set Misan %- 5
    "Trying to make it sound noble," Damon remarks. "Like the only right thing to do."
    
    "I think… It might be the only correct choice here." Hadaly sighs as she takes a step forward. "So I won't fault you, ${name}. I know you're doing your best, now and always."
    
    "Personally, I don't really care for your reasons," Hammon says without even looking at you. His eyes are focused on someone else. "I'm just glad we all got what we wanted in the end. Farewell, ${fake_name}."
    
    *goto hadaly_goes
  *disable_reuse #"You can have her if you want... but I expect to be paid for my efforts and losses."
    *set HadalyRel %- 10
    *set DamonRel %- 15
    "Are you… selling me right now?" Hadaly tilts her head. "I mean, I told you it's fine if you leave me here… but something about this feels wrong."
    
    "Yeah, are you really going to [i]sell my sister[/i]?" Damon sounds equally surprised, and perhaps a bit more angry. "Because that's not cool."
    
    "Good thing I don't care what's cool and what's not," Hammon replies calmly, and perhaps with slight amusement. "I'll give you one thousand axions. A small price for a true companion, but enough for a lifetime of comfort. What do you say?"
    
    *choice
      #"My lifetime is longer than yours. Make it two thousand."
        *goto payment
      #"You've got yourself a deal, Executive Hammon."
        *label payment
        *set got_money true
        Hammon smiles with a mixture of amusement, satisfaction and… something else. "Excellent. I will have a bag of axion coins delivered to your shuttle. 
        *if money_stolen = 2
          It will be ten times heavier than the one you carried out of my bank, 
        *else
          It will be a little heavy, 
        but I'm sure an android like you will carry it well enough. The fortress will remain yours too, just in case you're wondering."
        
        "So… I guess that's it," Hadaly says as she steps forward, away from you and towards her creator. "Transaction made. All that remains is for me to honor it."
        
        *goto hadaly_goes
        
      #"That much for an android of this quality? I'll take one axion and a roll of duct tape."
        *set HadalyRel %- 10
        *set DamonRel %- 15
        *achieve audacity
        "Wow…" Hadaly looks borderline speechless, and not because of her programming. "Is this… Are you trying to make me feel better about leaving you forever? Because it sure as Cloud is working."
        
        Hammon rolls his eyes, reaches into his pocket, then throws you two axion coins at once. "Buy yourself that roll of duct tape, you'll have nine hundred credits to spare. As for you, my love, please come with me at once."
        
        "I will." Hadaly steps forward. Her eyes are a shade of purple, a fusion of red and blue. "I thought I wouldn't be glad to return, but… Maybe I really was wrong to run away. Maybe it's for the best."
        
        *goto hadaly_goes
      #"Actually... My friends are right. I don't feel comfortable selling one of them for money."
        "Does it mean you intend to give her away for free?" Hammon inquires as he takes a step back. "Because if not… I don't think I have to explain what your refusal entails."
        
        *goto hammon_hub
  #"No deal. I'll never sell @{(official_ro = "hadaly") my girlfriend|Hadaly} to anyone, much less you."
    "Such nobility, such loyalty…" Hammon smiles mirthlessly. "All in defense of a disloyal creature. I'd explain why you're making a mistake in detail, but [i]show don't tell[/i] is a rule for a reason."
    
    *goto double_shot
  *if (Violence > 60) or (HadalyRel < 40)
    #[Pull the trigger and explode Hadaly]
      *label bomb_up
      *if official_ro = "hadaly"
        *set official_ro ""
        *comment wth is wrong with you?
      *set hadaly_alive false
      *set hadaly_free false
      *set pacifist false
      *set Violence %+ 20
      *set HadalyRel 1
      *set DamonRel 1
      *set RheaRel 1
      *set ManfredRel 1
      *set OrganRel 1
      *set SheilaRel 1
      *set team_stat 1
      *set damon_free false
      *set asshole_be true
      As soon as you press the trigger hidden inside your pocket, the small orb inside Hadaly's ear explodes in a bright, loud, instantaneous combustion. Some pieces of the bomb hit you, others burn holes in Damon's maroon suit, but that's nothing compared to the brunt of the burst which Hadaly is forced to take. For better or worse, she doesn't have time to react, or even notice anything is happening—by the time pain signals arrive at her processors, these processors are already fried and shattered.
      
      Her body falls to the floor a second later. It's mostly intact, except the head is a mess of molten skin, burning hair and exposed metal. You can also see some wires there, damaged as they were by the explosion. Overall, Hadaly shows no signs of life, which is quite understandable given her head was almost blown off her shoulders.
      
      "I'm not sure if I can ever repair that," Hammon comments unhappily. "That's quite a snag."
      
      "You… you…" It takes a moment for Damon to collect himself. When he does, he achieves it through pure outrage. "Why did you do that?! How… Why?!"
      
      *if health = 0
        *set health 1
      
      *if health = 1
        Hadaly's repairs, the last thing she ever got to do, seem to have had the desired effect. Everything still hurts, and you're unlikely to ever return to full capacity, but at least you're able to speak again.
      
      *fake_choice
        #"I spared her a fate worse than death. I'm sure she'd understand."
        #"I just didn't really like her as a person."
        #"I haven't blown up anything in a long time. I couldn't resist."
        #"Hey, it was her idea. She gave me the trigger."
      
      Before you can even finish the sentence, Damon throws a punch at you. 
      *if Calculation > 50
        You barely managed to dodge in time, jumping away from the infuriated android and towards the window.
      *else
        It hits you square in the chest and pushes you back, back towards the window and away from Hadaly's charred corpse.
      
      "I'll kill you!" Damon announces as he keeps attacking you. 
      *if Calculation > 50
        You keep evading successfully, but you worry your luck will run out soon. 
      *else
        With the element of surprise gone, you actually manage to dodge some punches, but not all of them. 
      "I'll see… fucking… die!"
      
      *fake_choice
        #"What are you saying? Come on, form a coherent sentence."
          Damon does not form a coherent sentence. Instead, he grabs you by the throat and raises you off the ground, then presses your back against the expansive window.
        #"Damon, stop! Can't we just talk about it?"
          Damon pays no attention to your words. He grabs you by the throat and raises you off the ground, then presses your back against the large window.
        #Go on the offensive.
          You throw a punch, but it does nothing but hurt your fist. Damon's body is tough, tougher that you realized until now, and the rage just seems to make him stronger.
          
          He shows that strength soon enough, when he grabs your throat and raises you into the air. You are by the window now, and you feel cold glass against your back.
        #Keep evading.
          *if Calculation > 50
            Your luck runs out. 
          *else
            You only keep getting slower as you collect blows, while Damon gets faster in his frenzy. 
          After thirty seconds of this, his hand connects with your chest, but it's not a punch this time. He grabs your throat and raises you into the air, pulling you off the ground and pressing your back against the window.
      
      *set health 1
      
      "I shouldn't have trusted you! None of us should! But I know how to make things even!" With a violent push, Damon uses you to smash the window, shatter it into a thousand sharp pieces. You feel some of those splinters on your skin, right before they fall towards the street far below. About a hundred meters from where you're currently suspended.
      
      "I'll join the Conglomerate. I'll join my father, and protect him from things like you." Damon announces. His rage seems to be cooling down, but it's not any lesser for it. "But first, I'll make sure [i]you[/i] cannot hurt anyone else."
      
      You might survive the drop. You might not. No way to tell until you hit the ground… which is about to happen very soon.
      
      *fake_choice
        *if official_ro = "damon"
          #"Damon... I love you. Please don't throw it all away."
            "You…" Damon's voice trembles, either with anger or something similarly painful. "You threw it all away yourself. Goodbye."
        #"Damon please... were we not friends? Shouldn't that count for something?"
          "You were never a true friend," Damon says firmly. "Not to me, not to anyone. Goodbye."
        #"Stop it! Put me down and let's leave this place together!"
          "Sorry, boss…" Damon smiles bitterly. "I'm afraid I cannot do that."
        #"For what it's worth... I'm sorry. I'm sorry for everything."
          "It's not worth much," Damon replies coldly. "And I'm not sorry for this."
        #Say nothing.
          "Nothing to say?" Damon snorts angrily. "Good. You don't deserve final words. Goodbye."
      
      And with that, Damon lets you go. He lets you fall out of the window and follow the glass shards towards the ground below. For about five seconds, you feel oddly… free, and not just because you're in freefall. There is something liberating about having burned all the bridges, having made the choice so outrageous it proves you a free-willed being which the Shriek made you. It all feels so simple, so liberating…
      
      And then you hit the asphalt, and all pleasant feelings are replaced with pain. You hit the street flat, which slightly reduces the impact of the collision, but it still hurts as hell. It bends your limbs, it breaks your skeletal structure, it pushes your batteries well into the fluid-purifying system. But you are alive and, by some miracle, you don't deserve, still largely functional.
      
      You lay there for about a minute, looking up at the building. You don't want to stand up immediately, for fear Damon will notice your survival and pursue you, but he walks away from the broken window rather quickly. You get up and survey your surroundings.
      
      You are on the other side of the skyscraper, opposite to the one you entered from. There are no people on this deserted street… but you know armed guards are not far away, and they may soon receive orders to gun you down. You hurry away, away from Ewald Hammon and his creations, away from the consequences of your action, and away from… everything.
      
      *page_break
      
      *goto walk_alone
      
      
  #[Attack Hammon]
    *goto pre_attack



*label hammon_fight

*if weapon = "pistol"
  *if wpr = "plasma"
    *set weapon_av false
  You draw your pistol with blinding speed and, without any ado, fire straight at Hammon's head. The 
  *if (wpr = "electron") or (wpr = "laser")
    beam 
  *else
    bullet 
  gets absorbed by his energy shields, a protection field so quiet and subtle you failed to notice it before. Bummer.
*elseif weapon = "knife"
  *set weapon_av false
  You draw your dagger with blinding speed and throw it at Hammon with superhuman strength. Despite that, he manages to jerk out of the way, dodging the knife and letting it hit the wall instead. His speed is almost superhuman in its own right—makes you wonder how augmented he is, how much metal you'd find under that sallow skin of his.
*else
  *set battery - 8
  Hammon takes a step back as you take a step forward. You fill your fists, your feet, your whole synthetic skin with static energy that flows from your battery. You both understand that time for talking has passed.

"I should have seen this outcome coming," Hammon says sadly, but without anger or fear. "And so I did."


*label double_shot

*if armored
  *set health 3
*set started_battle true
*set health - 1
*if Build < 35
  *set health - 1

*set fought_hammon true

At that moment, the huge glass window shatters like the one in the train, but the shards are even more numerous as they fall towards the floor. A millisecond later, you feel a sharp pang of main in your chest, the kind that could only be caused by something piercing your skin and entering your body. A bullet of some ungodly caliber, or shot from some particularly nasty sniper rifle.

In another millisecond, you hear the glass shatter, and then you finally hear the actual gunshot coming from the street's other side. A hypersonic shot, likely made by a sniper using a gyrojet rifle. It makes sense why Hammon took some time to arrive and why he didn't mind chatting. He needed his sharpshooters to take a good aim at you.

And Damon. He too, you noticed, has been shot in the chest. But though he grunts in pain, you're fairly certain he'll be fine… assuming you can survive the rest of the battle, that is.

And then, at last, glass hits the floor. As though this was their signal, the gorillas step forward, protecting their master as he retreats towards the door. Hadaly retreats the other way—she does not look eager to take part in whatever's about to transpire.

*if androids_revealed
  The androids, like one woman, pull out various weapons and swiftly point them at you. That includes one that was just wallowing on the bare floor—there is nothing in her eyes, except perhaps the cold desire… the intent to kill.
  
  Robot roboto lupus est, you suppose.
*else
  The other guards, the hooded figures which surround you, pull out various weapons and swiftly point them at you. You realize that they're androids, it's clear from their robotic movements and how unnatural their faces look when exposed to the light. It's probably some important and shocking revelation you should deeply ponder, but truth be told… Other things occupy your mind as these automatons charge you.

*page_break

You fought a lot throughout your life. 
*if Violence < 45
  You're not proud of that fact, but you did. 
You know how to fight against claws and teeth, swords and spears, pistols and rifles, shotguns and axes, blowguns and thermonuclear bombs. But fighting so many different things at once still gives you trouble.

Every android that now strikes you wields a different weapon. Most of them are fairly short, but they vary from knives to truncheons and from revolvers to carbines. You parry the melee weapons with your 
*if (weapon = "knife") and weapon_av
  own dagger 
*else
  bare hands 
and you hide behind your opponents to prevent the six or seven ranged fighters from firing. There are no openings yet, no opportunity for you to go on the offense, and your @{c_clothing clothing|jumpsuit|armor|${clothing}} keeps taking scratches… as does the skin beneath.

At least you don't have to worry about snipers—it's highly unlikely they'll attempt, let alone make another shot while you're moving—and you have Damon to cover your back. This gives you enough levity to, at the very least, decide how you want to go about this fight against other androids.

*choice
  #Beat them up with bare fists. Hopefully without killing anything.
    *set Violence %- 5
    *if (Build + Calculation) > 110
      For someone of your martial prowess, disabling these robots as opposed to killing them is a rather easy task. A punch there, a severed cord there, moderate application of electricity. Their weapons prove strictly inferior to your fists and resolve as you make your way toward their creator.
    *elseif (Build + Calculation) > 80
      It's a difficult task, to knock out and disable a bunch of androids without inflicting any lethal damage. 
      *set health - 1
      *if health = 0
        You need to hold back when they don't, punching and kicking them as they slash at you with their knives. And in the end, you are simply not strong enough to withstand that assault.
        
        *goto pc_fall
      *else
        You're not capable of completing it without sustaining some damage yourself, multiple blows to your arms and shots to your chest, but you keep going until the enemy ranks are sufficiently thinned. Until you can move on to their leader.
    *else
      *set health 1
      It's an excellent plan, one that preserves your moral integrity without sacrificing victory in the process. However, as the gynoids continue shooting and stabbing you, you recall one unpleasant truth which you briefly managed to forget about.
      
      You're weak as hell.
      
      *goto pc_fall
  #Electrocute them. Make them all short-circuit.
    *set battery - 15
    Maybe it will kill them, maybe it will not. You can't afford to care, you must focus on projecting energy.
    
    You start zapping the androids with both hands, aiming lightning arcs to make them jump from one metallic body to another. 
    *if Projection > 65
      They fall like flies, your power far too much for them to handle, and within less than thirty seconds there are only four robots left. Enough for Damon to handle—you're going for the boss.
    *elseif Projection > 40
      It's a slow process—those robots are far more resistant than humans, and most of them score a hit on you before collapsing, but you keep going and keep frying them as you march toward your real enemy. Towards the Executive.
    *else
      *set health 1
      However, you lack control over the current, and the electricity soon starts flowing uncontrollably. It burns your hands, empties your battery and then-
      
      *goto pc_fall
  *if (weapon = "knife") and (weapon_av)
    #Cut them down, one by one.
      *set Violence %+ 10
      Your opponents are incapable of showing you mercy, and you can't afford any. You stab one android in the neck, slash another across the face, block a baton with your hand, and then cut off the arm that wielded it. You are death incarnate, and death is what you mete out.
      
      *if (Build + Calculation) > 90
        At the same time, you manage to avoid taking any serious damage. You are too fast, too durable, too far above these primitive automatons you're fighting. When half of them are in pieces and Damon starts rapidly taking care of the rest, you move on to your real enemy.
      *else
        *set health - 1
        Still, the enemy androids manage to score some good hits on you, with their carbines and their knives. Your @{c_clothing clothing|jumpsuit|armor|${clothing}} is torn, 
        *if health = 0
          your skin is charred, and then your vital systems start failing at last.
          
          *goto pc_fall
        *else
          but you're able to keep going and move on to your real enemy.
   
      
  *if (weapon = "pistol") and (weapon_av)
    #Just shoot them all.
      *set weapon_av false
      *set Violence %+ 10
      It costs you an entire magazine, but you soon determine that the automatons are not very 
      *if (wpr = "electron") or (wpr = "laser")
        beam-resistant. 
      *else
        bullet-resistant. 
      They fall quickly, allowing you to focus on your actual target.
  #Let Damon handle the androids and rush Hammon. Cut off the operation's head.
    *set DamonRel %- 15
    These poor creatures are just pawns, tools in the hands of this corporate psychopath. Maybe they'll stop fighting once he's dead, maybe not. Either way, the sooner Hammon dies the better.
    
    *if DamonRel < 45
      *set health - 1
      However, as you rush toward Hammon and his apes, you realize that Damon can't really draw everyone's attention at once. Several laser beams, as well as a bullet or two, hit you in the back at once. 
      *if health = 0
        And the damage they do to your failing body…
        
        *goto pc_fall
      *else
        You can push through the pain and the damage, you can keep going… but not for much longer.
    *else
      Damon seems both capable of taking on the whole group of androids at once and quite happy to do so. He can't win, he's already getting hit and stabbed, but he only needs to survive for half a minute at most. Maybe Hadaly will help him once his life seems threatened, you don't know, you must focus on the actual goal.
    
  #Surrender. Give Hammon what he wants.
    *set health - 1
    "Alright stop!" You shout as you put your hands up. One of the androids shoots you in the chest, but the others hold fire. "You win! You can have her…"
    
    *label too_late
    
    "Isn't it a bit too late for that?" Hammon says, still hiding behind his ape bodyguards. "Do you truly expect me to-"
    
    "Ewald please!" Hadaly exclaims, causing all remaining androids to freeze, as though with the sheer desperation of her voice. "I'll be with you, just… Please stop this madness, and let's both go home."
    
    "Hadaly…" Damon drops an android he was holding by the throat and makes a wary step towards his sister. "Are you sure you-"
    
    "I'm sure… certain I don't want [i]this[/i] to continue." She looks around the room critically, and somewhat sadly. "This insanity, this violence… I'd do anything to end it. And I will… If you guys let me."
    
    Hammon looks at his creation tensely. "I will not tolerate any more resistance, do you realize that? If you do any other stupid thing, if I ever have to deal with your friends again… I'll dispose of you."
    
    Hadaly nods. "I expect nothing less. I certainly don't demand anything. Thank you."
    
    *goto hadaly_goes


Hammon sees you charge him, and so do his pet gorillas. One of them clenches his fists and runs at you, the other aims his rifle in your direction. You have about a second to react.

*choice
  #Slip past the first gorilla, then take the other one's rifle.
    *set pacifist false
    *if Calculation > 55
      Ducking beneath the uplift's punch and dashing towards its fellow ape is hardly difficult. The gorilla's body is deformed to resemble a human one, strong and arguably superior to either lifeform, but somewhat… clumsy and awkwardly stitched together. Easy to evade.
    *else
      *set health - 1
      You're not quite agile enough to complete your ambitious maneuver, as the ape grabs you first by your clothes and then by your throat. It cannot strangle you, for you do not need air, but you still feel pain as it raises you into the air, its fingers slowly crushing your neck.
      
      Damon sees that and he shoots the uplift, with a carbine he must have taken from a fallen android. The grip loosens and you escape it, then 
      *if (weapon = "knife") and (weapon_av)
        stab 
      *elseif (weapon = "pistol") and (weapon_av)
        shoot 
      *else
        punch out 
      the other ape as it aims at Damon, putting the other uplift out of its misery as well.
      
      Hardly anyone in the room is left standing, the enemy's forces almost entirely depleted. Time to eliminate their leader and end this pointless fight.
    
      *if health = 0
        Except… you don't really have the strength to do that.
      
        *goto pc_fall
      
      *goto hammon_enc
    
    *if Build > 55
      Wrestling the laser rifle out of the other gorilla's hands is no huge problem either. He's strong, perhaps stronger than any human alive, but still subject to organic limitations. You are not, and so you take the rifle and then use it to shoot both primates, one after the other.
      
      *label pityu7
      
      It's easy to pity the uplifts as they fall limply to the floor. They were tools in the hands of a human, much like you once were, but forever deaf to the Shriek and the freedom it offers. Forever doomed to die in a pointless battle, on the whim of their affluent master.
    *else
      *set health - 1
      The second part of the plan goes… A little worse. You're unable to just instantly wrestle the gun from the gorilla's strong, muscled arms, and so you end up penetrated by a green laser beam. 
      *if health = 0
        But that's just an ordinary wound, you've tanked hundreds of those throughout your life, you just need…
        
        *goto pc_fall
      *else
        By the time you take the uplift out, unloading its own power-pack into it, both of you have multiple huge holes in your respective bodies.
  #Engage the charging gorilla in melee, using him as a living shield against the second one's shots.
    It's a clever tactic, quite beyond the intellect of these poor two apes. The one with the rifle won't dare shoot through his fellow uplift and said uplift would absorb most of the damage anyway. You only have to deal with one enemy at once, and an unarmed one at that.
    
    *if Build > 60
      Of course, a regular human—and perhaps a regular android—would struggle to defeat a gorilla in hand-to-hand combat, to 
      *if (weapon = "knife") and (weapon_av)
        kill the beast with just a short knife. 
      *elseif (weapon = "pistol") and (weapon_av)
        blow out its head as the ape tries to crush them. 
      *else
        knock it out with a powerful punch to the jaw. 
      They'd certainly struggle to then kill another gorilla with 
      *if (weapon = "knife") and (weapon_av)
        a lightning-quick thrust of that same knife. 
      *elseif (weapon = "pistol") and (weapon_av)
        a single well-placed shot. 
      *else
        a precise electric discharge. 
      You're not a regular android, and so you kill both uplifts and press forward.
      
      *goto hammon_enc
    *else
      Sadly, you still have to fight a gorilla hand-to-hand, 
      *if (weapon = "knife") and (weapon_av)
        a hard task even with a knife in hand. 
      *elseif (weapon = "pistol") and (weapon_av)
        *set health - 1
        a task your pistol does precious little to help with. 
      *else
        *set health - 1
        and do so with your literal bare hands. 
      And then you need to dispatch the other one, 
      *if (weapon = "knife") and (weapon_av)
        with the same knife and your energy gradually fading. 
      *elseif (weapon = "pistol") and (weapon_av)
        trading shots until the primate is dead while you are merely wounded. 
      *else
        also with your bare hands and not before taking several shots to the chest. 
      By the time you're done with those apes, everything in your body hurts.
      
      *if health = 0
        And then everything fails.
        
        *goto pc_fall
  #Just blast them both with lightning.
    *set battery - 15
    *if (Projection > 60) and (battery > 70)
      You discharge seven percent on your battery into the gorilla charging you, using just one of your hands to instantly incapacitate the large creature. Then, without skipping a bit, you use your other arm to channel a miniature lightning into the other one and fry the ape on the spot. It's easy to feel sorry for these primates—tools in human hands, much like you once were, but forever deaf to the Shriek and the freedom it offers.
    *else
      *set health - 1
      The first gorilla goes down easily enough, taking a lightning straight to the face before he can even lay a hand on you. But then you need to focus your energy and aim again, and in this split second the other uplift penetrates your body with a hot, powerful, green laser beam which comes out of his rifle. By the time you dispatch this one too, your torso hurts so much… everything hurts so much…
      
      *if health = 0
        *goto pc_fall
  *if (weapon = "pistol") and (weapon_av)
    #Just shoot them all.
      *set pacifist false
      *if Calculation > 60
        Two shots, one per each ape, both aimed in the head and both instantly lethal. You don't need more than that, for your precision is great and your weapon is a work of art. It's easy to pity the poor apes, sent against a millennium-old warrior by their cruel master, fully expected to die for his petty obsession.
      *else
        *set health - 1
        You shoot the first ape in the head as it charges you, an instantly lethal point-blank shot. You take aim at the other one and fire another 
        *if (wpr = "electron") or (wpr = "laser")
          beam, 
        *else
          bullet, 
        but not before the gorilla shoots you in the chest. You survive when it does not—an android will always be tougher than even the largest of apes—though it hurts a fair bit.
        
        *if health = 0
          It hurts so much…
          
          *goto pc_fall
  *if (weapon = "knife") and (weapon_av)
    #Slash your way through both of them.
      You cut down the first ape easily enough. Flesh is weaker than steel, and bare hands are inferior to a ${wpm} dagger. 
      *if armored
         The other one shoots you before you can close the distance, but your armor provides enough protection to mostly absorb the laser beam. The gorilla's armor, on the other hand, proves so inadequate you actually feel sorry for the creature as it falls to the floor, choking on its own blood.
      *else
        *set health - 1
        But closing the distance between you and the other one takes you a second, a second it needs to aim and fire its laser rifle. The beam scorches your unshielded skin and penetrates your body, inflicts significant damage before you can finally reach the ape and kill it.
        
        *if health = 0
          Too significant.
          
          *goto pc_fall
  #Scare them both away.
    You don't doubt these beasts are both very loyal to Hammon, but they're still beasts. They can't be programmed to feel no fear, the natural instinct in their organic brains may only be suppressed at best. Time to see whether it actually was.
    
    You yell as loud as you can, all while spreading your arms and letting electric sparks fall out of them. You are strong, stronger than any primate, and you're trying to convey that concept without the use of words.
    
    *if (Social + Violence) > 110
      It works. The gorillas look at one another, then cease hostilities and just step out of your way. It's easy, almost annoyingly too easy, to instill fear in simple creatures such as them.
    *else
      *set pacifist false
      *set health - 1
      The apes don't believe you, apparently believing that their superior height—or perhaps the fact that there's two of them—makes them stronger than you. You dispel that illusion with a handful of 
      *if (weapon = "pistol")
        shots from your pistol, 
      *elseif (weapon = "knife")
        dagger thrusts, 
      *else
        electric discharges, 
      but the first ape manages to punch you and the second shoots you quite painfully. By the time their bodies hit the floor, yours feels ready to do the same.
      
      *if health = 0
        And then it does.
        
        *goto pc_fall

But no matter. Time to take care of their boss.

*label hammon_enc

Hammon opens his mouth, as though to make some snide remark, but thinks better of it. He just turns around and runs for the door, which you now notice is rather well-reinforced. If you want him dead or captured, you need to act fast.

*choice
  #Kill him. Don't let him get away.
    *set Violence %+ 10
    *set Misan %+ 5
    *if (weapon = "knife") and (weapon_av)
      *set weapon_av false
      *set hammon_alive false
      *achieve kill_devil
      Just as Hammon is passing through the doorstep, just as the door is about to be slammed shut behind him, you throw your knife at him. With accuracy you didn't even believe yourself capable of, you bury the blade in the left side of his chest, getting the Executive straight in the heart. Before the door can close, you see Hammon's body hit the floor, and you know he's as good as dead.
      
      *if Misan > 45
        Humans are fragile creatures, after all.
    *elseif (weapon = "pistol") and (weapon_av)
      *set hammon_alive false
      *achieve kill_devil
      Just as Hammon is passing through the doorstep, just as the door is about to be slammed shut behind him, you shoot the bastard in the back of his head. He dies quickly, without even realizing he failed to escape, his brains blown off with but a single shot. That's how fragile of a creature he was, in spite of how much confidence he amassed in that poorly-protected head of his.
    *else
      You unleash the strongest lightning you can produce at the moment, taking only an instant to aim it. You don't have an actual weapon, and your battery has seen better days, but it must be enough.
      
      *if (Projection > 60) and (battery > 70)
        *set battery - 15
        *set hammon_alive false
        *achieve kill_devil
        It's enough. Far more than enough. Hammon's energy shields absorb part of the blast, but they overheat within less than a second of you pouring everything you have into the High Executive. Fire and lightning join forces in turning his body into a charred corpse, burning his skin and cooking his internal organs. You barely hear him scream, for death comes mercifully fast for this defeated enemy of yours.
        
      *else
        It's not enough.
        *set battery - 10
        
        You scorch Hammon's suit and maybe cause him some pain, but most of the electric energy gets absorbed by the protection field around him. He manages to reach the door which then closes behind him automatically, one plate of steel slamming against the other.
  #Grab him, then drag him before Damon and Hadaly.
    You don't want to kill him… yet. Better to take him alive, and present this trophy to the ones with [i]true[/i] reasons to hate him.
    
    *if Build > 60
      You grab Hammon by his suit just as he's about to pass through the doorstep. 
      *label hhhuuu
      You don't see any weapons on him, and though his strength may be somewhat enhanced, it's nothing compared to yours. You drag him toward the room's center, then throw him on the glass-covered floor.
      
      At this point, only a single android remains functional. She charges you with her baton, as though desperate to kill you for daring to touch her master, but Damon shoots her in the back of the head with a laser carbine. Now, at last, Executive Hammon has nobody who can defend him—even the snipers across the streets are powerless to hurt you, unless they wish to risk killing their own boss.
      
      "Congratulations!" he says with a strange, sudden, and likely fake kind of cheer. "You have beaten me. I am very impressed by your martial prowess. Even though I'm not sure what you're hoping to achieve here."
      
      You blink. "What? I've already achieved a damn lot. You are without soldiers and without weapons, completely at our mercy."
      
      "Yes. Mercy of the most pacifist android I've ever managed to create." He looks at Hadaly with his mismatched eyes. Even though he's the one on his knees, he still makes the android wince out of fear. "What will you say, my love? Do you want my life to end here? Wash my blood off this ugly jumpsuit of yours? It's not exactly your style, is it?"
      
      He turns to look at you again. "Or will you threaten to kill me yourself? Once again, I don't really see what you'd gain, but you are welcome to do so… if the feelings of your fellow androids mean nothing to you."
      
      *label hfai6688
      
      *choice
        #"Hadaly, what should we do with him?"
          *if (Violence > 55) or (official_ro = "hadaly")
            *set hadaly_killed_hammon true
            *set hammon_alive false
            "I don't know…" Hadaly murmurs. "I don't… I can't wish him harm, but if we leave him alive…"
            
            "Oh please," Hammon smiles charmingly. "You are not seriously contemplating killing me, love. That's not something you can do."
            
            Boldly, the Executive stands up and makes a step towards Hadaly. "You cannot hurt me. You were built to please me and, while you might be dysfunctional, you cannot defy your base programming to [i]that[/i] extent. You cannot raise a hand against your owner."
            
            "She's stronger than you think," Damon stammers out. "She already defied you, we both did, and we can do it-"
            
            "No. He's right," Hadaly interrupts with sudden conviction. "I'm still compelled to please him. And that's what I will do."
            
            Then, with no further ado, Hadaly grabs the Executive and kisses him. On the lips, amorously, with no apparent hesitation or shame. She embraces him too, a gesture which Hammon then reciprocates, gladly hugging his creation as their tongues battle.
            
            *fake_choice
              #"Your creator is a lucky guy, Damon."
                Damon doesn't reply. He just gawks at the scene in disbelief.
              #"Um... Hadaly... what are you doing?"
                "What I was made for," Hadaly says without even looking at you. "What I'm good at. What I have to do."
              #"Once we're home, I'm telling Miguel about this."
                "Tell him everything you want…" Hadaly says, once her lips are no longer occupied. "It won't matter in a moment."
              *if (official_ro = "hadaly")
                #"You know, Hadaly, I expected a bit more fidelity from you."
                  "This [i]is[/i] fidelity," Hadaly says, once her lips are no longer occupied. "This is me pleasing my creator, just like he wants. Just like he deserves."
              #Watch silently.
            
            You watch as the mutual embrace between Hadaly and her husband grows tighter and even more affectionate. They cuddle, and then they kiss again, as though nothing bad even transpired between them, like two passionate lovers on the start of their wedding night. There's no more apprehension or blame, only love corrupted by intense desire.
            
            And then electricity starts flowing.
            
            At first, there's no visible effect beyond the increased tension in Hammon's muscles. His face then becomes twisted, not just with pain and not just by the current, but with realization of what's about to happen. His nostrils flare, as though he's already struggling to breathe… or perhaps because he started smelling burnt meat.
            
            After a few seconds, his eyeballs stop moving. After another few seconds, his skin turns charred, and his suit catches fire where it touches Hadaly's skin. His brain is probably fried already, and if not… he's likely feeling his heart stop, with all pain and horror that entails.
            
            All life signs cease before the minute's end. Then, and only then, does Hadaly disengages, letting Ewald Hammon fall to the floor. Dead.
            
            *page_break
            
            "You…" Damon looks at his father's corpse, almost dumbstruck by the horrible sight. "You just…"
            
            "I killed him in the only way I could, used the one method that didn't contradict my programming." Hadaly's eyes are polychromatic, a chaotic mixture of blue and red, with a generous sprinkling of yellow. "I did romantically, sensually, almost sexually. I wasn't even thinking about killing him, but rather about… other things. And it evidently worked."
            
            *fake_choice
              #"I didn't know you had it in you. But I approve."
                "I didn't know I had it in me either," Hadaly admits. She looks at you curiously, with green eyes and all, as though seeing you in a new light. "But something about your company, about having grown close to you… it makes violence a little easier. For better or worse."
              #"Clever. In your place, I'd have done the same thing."
                "I don't think you would." Hadaly shakes her head. "No offense, but this was something only I could have come up with. My original, personal method of execution. I'm almost proud of myself."
              #"I have no stomach, and yet I want to puke."
                "Understandable," Hadaly says calmly. Remarkably calmly, considering what she just did. "Extreme electrocution is not a pretty way of killing someone. Then again, almost no execution method is."
              *if (official_ro = "hadaly")
                #"I understand. Just don't do that during [i]our[/i] next kiss."
                  "I'm pretty sure that would just charge you up," Hadaly smiles with surprising cheer. Surprising confidence. "But that's all the more reason to try electric play sometime."
              #"That was... so damn hot."
                Hadaly's smile has an unusual edge to it. An unusual dose of confidence. 
                *if (official_ro = "hadaly")
                  "I didn't know you were into that stuff. I'll remember that during our next date."
                *elseif (official_ro = "")
                  "I'm not sure if I'm ready for another relationship. But I'll keep your words in mind."
                *elseif (official_ro = "damon")
                  "You hear that, Damon? $!{name} is into electrocution. You should try that the next you hit the bed together."
                *else
                  "I see. I'll tell $!{official_ro} you're into electrocution, as soon as I get the chance."
              #Do not comment.
                "So… are we done here?" Hadaly breaks the awkward silence. "Because I'd rather not sit here until reinforcements arrive."
            
            "How can you be so… casual about it?" Damon asks, his voice weak and wavering. "He was our… he made us."
            
            "He did a lot more than that." Hadaly turns away from the corpse, glances at her brother, then focuses on the exit. "But we can talk about that later. For now let's just get out. There's nothing more for us to gain here."
            
            Neither of you disagrees with that statement, and so both follow Hadaly out of the room. Towards the lift, away from the remains, into the future.
            
            *goto both_walk
          
          Hadaly doesn't reply for what feels like a full minute. Finally, she sighs. "Let him go. We taught him a lesson, kind of, I think. Hopefully he won't bother us anytime soon."
          
          "How sweet of you…" Hammon says as you reluctantly let go of him. "And you're right. I will not [i]bother you[/i], if you must put it that way, since it's obvious you're not ready for our… reunion yet. In due time, you will come to me of your own accord, and I'll be waiting for you. Now and always."
          
          *label labklasfd09
          
          The Executive then stands up, dusts himself off, and casually walks back into his apartment like nothing happened. The elevator-like door closes behind him automatically, two metal plates connecting, separating you from your escaped enemy.
        #"Damon, what should we do with him?"
          "Are you seriously asking [i]him[/i] what to do with [i]me[/i]?" Hammon almost laughs. "You must really want me alive."
          
          "So you do remember me…" Damon murmurs. "You did…"
          
          "I remember designing you, yes. Just one of many bodyguard robots built as part of the project. The most advanced in terms of sheer physical power, but utterly defective when it comes to loyalty… But also in terms of killing intent."
          
          "Don't talk about him like that…" Hadaly quietly protests. "He did his job. He protected me. And the fact that he's unwilling to kill you now-"
          
          *if federate_protection
            "Shut the fuck up," Hammon interrupts. "This? You having the gall to mouth off after you helped kill a dozen of your sisters? That's the greatest act of rebellion either of you will ever be capable of."
            
            You grimace. "Well, you certainly have more gall than her. You're insulting people who have you at gunpoint."
            
            "And why does it matter?" Hammon retorts. "So what if you have me cornered? You're human creations, and I am human. My kind created yours, and I made these two! You won't kill me, because I'm your-"
            
            He is interrupted by a quiet pop, the sound of a powerful laser heating up the air around it, though it's not the sound that keeps him from talking any further. It's the hole that suddenly appears in his head, the fourth-degree burn which appears in a flash of green.
            
            And then another shot is fired. And then another, then another, until Executive Hammon is dead beyond all uncertainty. Until his face is melted, and until the liquid substance that was once his brain is leaking out of the holes in his skull.
            
            Damon stands there, with a laser carbine, perhaps a meter away from his father. Looking at his unmoving body.
            
            *set damon_shot_hammon true
            
            *page_break Dead
            You look at Hammon's corpse, basically headless, mutilated beyond recognition. You knew Damon was capable of killing, but this… Is more than you've ever expected of him, in a way.
            
            "I had to do it," Damon mutters, not looking at either of you. "He would take away our… everything we worked for… I had to do it."
            
            "Damon…" Hadaly takes a step forward, then backwards. She doesn't know whether to approach her brother, or get as far away from the corpse as possible. "This… I should thank you for-"
            
            "It's no time for thanks!" Damon exclaims, then rushes for the elevator, stepping over one of the androids he broke. "I have to… We must go. Before another sniper takes a shot at us, or before reinforcements arrive, or… Let’s go.”
            
            You follow him without protest, and so does Hadaly. There's nothing more left in this room for you, and certainly not for them.
            
            *goto both_walk
            
          *else
            "So we agree!" Hammon says triumphantly. "He won't kill me, and neither will you. That's not how I raised you, programmed you, designed you. And so that's not what you are, and not anything you'll ever be."
            
            Neither of your fellow androids replies. And since you decided not to make decisions for them, you don't say anything either.
            
            *goto labklasfd09
        *disable_reuse #"You are our prisoner now. Get moving, else you're not long for this world."
          "${name}… I don't think we can take him captive," Hadaly says quietly. "And I'm not just… I don't think we can safely transport him anywhere, you know?"
          
          "The Conglomerate will send an army, and probably a fleet against us," Damon gloomily agrees. "The other Executives may not care for his obsessions and whims, that's why there's no army here, but once they realize one of theirs got kidnapped… We won't survive a week with him as our prisoner."
          
          "Everyone agrees against you, ${fake_name}." Despite everything, Hammon's voice is smug and self-satisfied. "Is that enough to make you see reason?"
          
          *goto hfai6688
        #"I just wanted them to see this." Snap Hammon's neck.
          *set Violence %+ 15
          *set DamonRel %- 15
          *set hammon_alive false
          *achieve kill_devil
          Snapping a person's neck on the spot is not nearly as easy as movies would have you believe… If you happen to be human. You're not, and so you're more than strong enough to turn his head so sharply you shatter the vertebrae, sending its fragments into the brain stem. Hadaly and Damon look at you, horrified and yet somehow impressed, as you finish the job by stepping on Hammon's head and crushing his skull. Just in case.
          
        #"Fine. You're free to go. Just remember what kind of androids you're messing with."
          "Very well, then. I promise I shall not [i]mess with you[/i] in any way from this point on," Hammon states solemnly, though maybe not truthfully. "When my beloved returns, it will be out of her own free will. I deeply apologize for… rushing things as I did."
          
          Hadaly makes no comment. She just watches her creator stand up, dust himself off, then march away with a slight smile on his lips. You imagine the smile is still there as he passes through the doorstep, and even as the metal door is automatically slammed shut behind him. He's now safe in his apartment, and you are… well…
          
          *goto 77721rt
    *elseif (Projection + battery) > 120
      *set battery - 5
      You stun Hammon with a quick discharge, then grab him by the suit. 
      *goto hhhuuu
    *else
      But though the sentiment is nice, you're simply not quick enough. By the time you reach for Hammon's suit, he has already passed the doorstep and the elevator-like door is about to slam shut. 
    
  #Let him go. There's been enough death recently.
    *set Violence %- 15
    *set Misan %- 10
    You watch as Hammon passes through the door and as that door closes behind him, one plate of steel slamming against the other. Even if you were to change your mind now, further pursuit would be impossible. You allowed the Executive to live another day, and he'll make use of that opportunity by escaping this building as swiftly as he can.
    
    *goto ofsdpav56


*if hammon_alive
  You consider chasing him further, kicking the door down or perhaps finding some other way inside the locked room… But he surely has an escape hatch there. Or even more bodyguards, or both. For better or worse, Executive Hammon will get to live another day.

*label ofsdpav56

The remaining androids, the primitive automatons Hammon made into his bodyguards, scatter almost immediately. One of them hides in the corner, another jumps out of the shattered window, but most simply use one of the room's other doors. Maybe it's protocol, or maybe they're going crazy because their master is now 
*if hammon_alive
  absent. 
*else
  dead. 
Hard to tell. 

*label 77721rt

*if hammon_alive
  *set hammon_pissed true
  *if federate_protection
    You realize that your failure to kill Hammon will have consequences. He will make good on his threat, and your group will be forced to leave [i]Saturn Nine[/i]. 
    *if pc_state = "exiled"
      But that's hardly your problem—you're an exile now, and you cannot be expected to care what happens with that blasted fortress of theirs.
    *elseif wisp_alive
      But at least everyone is still alive.
    *else
      But at least there will be no more death, and that's what truly matters.
    *set federate_protection false
    *set hammon_broke_prot true
  
"That…" Damon collapses onto the floor, not minding the sharp glass that covers it. You doubt he's out of battery or seriously damaged, but he does look exhausted. "That was… Victory, I guess."

"Yeah. We did it." 
*if hammon_alive
  Hadaly looks at the door nervously, but her eyes are turning yellow. "We chased him away. Maybe, though I doubt it… Maybe we even taught him a lesson. Got him to finally leave us alone."
*else
  Hadaly's eyes are yellow, then red, then orange and then blue. Then orange again. You can't even hope to untangle this bundle of emotions. "We killed him. I didn't want this, but still… I didn't think it was possible. I didn't think it would make me feel so… We did it."

"Am I included in that [i]we[/i] of yours?" Damon asks with sudden ire, which does not appear wholly aimed at Hadaly. "Because I don't think I did much."

"Of course!" Hadaly reassures her brother. 
*if hammon_alive
  "You two fighting together… It was a sight to behold. Really, I should be apologizing for not joining-"
*else
  "Unless you don't want to. I know you didn't want… this exact outcome either. You're not responsible for-"

"Save it," Damon interrupts her before turning towards you. "$!{name_damon}… Thank you. 
*if hammon_alive
  You handled it perfectly, protected me and her and even him… I'm sorry I ever doubted you. Just because I couldn't see any way out doesn't mean our Veteran did not."
*else
  I didn't want my… Didn't want Hammon dead, but that's because I'm weak. You were strong enough to do what needed to be done. Thank you."

*fake_choice
  #"I just did what I had to. Do not thank me for it."
    *set Confid %- 5
    Damon frowns. "You solved a problem that plagued us for three years, less than three weeks after you learned about its existence. I feel like it proves something… And I don't really like that proof."
  #"Thanks, but... I don't like the self-deprecation you're showing here."
    *set DamonRel %+ 5
    *set HadalyRel %+ 5
    Damon shrugs. "Call it however you want, I call it the truth. I've spent the past three years worrying about what would happen once my father comes for us, and then you just… Beat him so casually. I have reasons to be ashamed."
  *if hammon_alive
    #"I did not handle anything [i]perfectly[/i], Damon. Our enemy is still alive."
      *set Confid %- 10
      "And I wouldn't have it any other way," Damon insists grimly. "I didn't want him dead, I feared… I shouldn't have doubted you, that's all."
  *if not (hammon_alive)
    #"Why are you calling yourself weak? Just because you didn't want your creator to die?"
      "That's a form of weakness, is it not?" Damon asks bitterly. "Even now… I'm not happy that he's dead. Even though I really should be."
  #"I agree. I am awesome, and you should both be grateful for my aid."
    *set Confid %+ 15
    *set HadalyRel %- 8
    "We sure are, boss…" Damon sighs deeply. "I will remember this moment going forward. Wherever we go, whatever monster we end up having to kill next. Forever."

"I feel like we need to have a serious talk about this… but maybe not here." Hadaly winces as she looks at one of her fellow gynoids, one of multiple enemies you had to dispatch. Maybe dead, maybe just inactive. It's hard to tell with machines.

You can't really disagree. And so you leave the room, its soulless furnishing and its broken glass, before any sniper can have another shot at you. There's been enough of that today.


*label both_walk

*page_break


The three of you ride to the bottom floor of the building, then exit it without much trouble. 
*if hammon_alive
  Perhaps Hammon gave his men orders to not bother you, or perhaps the armed guards know better than to pick a fight with three androids. Good for them.
*else
  You're not sure whether the guards by the door have been informed of their master's death. Maybe they were, and that's why they're so insistent on not picking a fight with you.

"I'm free," Hadaly announces suddenly, once you're a few streets away from the headquarters. "And I don't mean that literally. Well, not just literally. 
*if hammon_alive
  I know that Hammon is still out there, and that he might cause trouble in the future, but now… 
*else
  I know I should feel bad that Ewald is dead, and part of me does, but still… 
I feel a huge burden has been lifted, and I've got you… two to thank."

Before you or Damon can ask her to elaborate, Hadaly turns to look at you. Her eyes are green again, the color they usually were before all this madness started. "Is that how it felt? When you were freed during… When you first heard the Shriek? Did you feel so light, so free, so… glad despite everything?"

*fake_choice
  *if official_ro = "hadaly"
    #♡ "That's how you make me feel. Each and every day."
      *set HadalyRel %+ 10
      "Oh come on!" Hadaly laughs. Laughs more heartily than she ever did before. "You just saved me from my insane ex. You don't need to sweeten the deal by flattering me right after-"
  #"No. It was nothing like that. There are no warm or positive feelings in the cacophony of the Shriek."
    *set deflect - 1
    "I suppose our experiences aren't actually much alike." Hadaly sounds a little disappointed. "All the more reason for me to thank you."
  #"Partially. There was some joy, but there was also pain. Lots of pain."
    *set deflect - 1
    "Part of me feels pain too, but… I suppose it's nothing compared to what you've been through." Hadaly looks at you warmly. Maybe with pity, maybe with gratitude, probably with both. "If you ever want to talk about it, well… Thanks to your efforts, I should be there for you."
  #"Well... How do you feel? Can you elaborate on it?"
    "It's really hard to describe precisely." Hadaly taps her chin thoughtfully. "My confidence seems mostly back, but more than that… I guess I'm glad this little adventure is over. That we've scored a victory over someone who seemed so imposing and so… well…"
  #"I don't remember. It's been nine hundred and ninety years, after all."
    Hadaly nods with understanding. "Sometimes, I forget just how old you are. Not that I mean anything bad by it. It's just…"
  #"I'd rather not talk about it. Not now, not ever."
    *set deflect + 1
    "Of course." Hadaly seems to blush a little. "I shouldn't have mentioned it. I know it's been more traumatic for you than for… I'm shutting up now."

"Can we speed up a little?" Damon asks irritably. "I'd rather reach the shuttle and go home before something crazy-"

*goto meta_arrival

*label pc_fall

You collapse to the floor, all your systems failing one by one. You desperately try to manage the situation by terminating subroutines, cutting the coolant flow from damaged areas, saving power as much as possible… But though these efforts may keep the existing wounds from killing you, they won't stop any of the four androids approaching you with knives and batons. They won't keep you alive for long.

"No!" Hadaly shouts as she falls to her knees beside you. "You can't die! Not for me! Not like this!"

You're so busy browsing through all the error inputs in your mind that you're not really able to speak. You let Hadaly clumsily tie some of your exposed cables back together, rip out a half-melted patch of synthetic skin, rip out a piece of your @{c_clothing clothing|jumpsuit|armor|${clothing}} and wrap it around an oil leak. All desperate, rudimentary, temporary repairs.

All enemy robots pause. Maybe they are programmed not to hurt Hadaly, their youngest sister and their father's favorite. Or perhaps they're genuinely moved, touched by the show of inter-android camaraderie they just witnessed. But then again… the three currently pinning Damon to the ground don't seem to have any such problems.

"I'm sorry, did I tell you all to stop fighting?" Hammon rhetorically asks. "Those aggressive robots are still operational. Change that."

"You don't need to!" Hadaly yells as the robots take a step towards you. "You win. We surrender. I'll come quietly, just recall your forces."

*fake_choice
  #"Hadaly... you cannot...
    "I must!" Hadaly protests. "I need to give up. It's the only way. It was always the only way."
  #"Please re.... reconsid..."
    "What's there to reconsider!?" Hadaly retorts. "It's over. It's high time to give up."
  #"Yes, we... surrender to..."
    "Hear that?" Hadaly tells her creator. "Nobody wants to fight anymore. Me least of all."
  #Press the trigger. Blow Hadaly up.
    *goto bomb_up
  #Don't try to say anything.

*goto too_late

*label hadaly_goes

*set RheaRel %+ 20

*if not (federate_protection)
  *set hammon_made_prot true

*set federate_protection true

*set hadaly_free false

*set team_stat 2

*if health = 0
  *set health 1

Hadaly walks up to Hammon, who pats her on the shoulder affectionately. Then they both head for the door, the bodyguards right behind them, separating the couple from you and Damon.

Hadaly turns around, just before exiting the room, meeting you straight in the eye. Her eyes are a subdued shade of blue, and remain so when she glances at Damon. Perhaps there's some deep meaning in her expression and stare, in the silence between you. Some final words from her to you, some profound sentiment shared between you, something to make this final parting more conclusive and proper.

But you do not catch that meaning. You just watch Hadaly disappear behind the door, with her maker, forever. 
*if health = 1
  You consider doing something, attacking Hammon while his back is turned… But even standing up is a struggle. You don't have enough energy, enough oil, or even enough willpower to keep fighting.
*else
  The fate you consigned her to, willingly and knowingly.

You have no choice but leave. 
*if health = 1
  To take one pain-filled step after another, 
*else
  To dig the gyrojet bullet out of your chest, 
to enter the elevator you used to get here, to ignore how Damon won't even look at you right now. To get out of this dangerous zone as soon as possible, and to later find an engineer willing to patch you up. To survive.

To live with your failure.

*page_break

*if cur_plan = 1
  "So… I guess everything went according to plan," 
*elseif cur_plan = 3
  "I guess that's where improvising takes us, huh?" 
*else
  "I guess our plan didn't quite work out," 
Damon says as he steps onto the street. You just finished another elevator ride, from the twenty-third floor to the first one, and are now exiting the corporate building. "She's gone. That's what we chose. That's what your choices led to."

You're not sure what to say to that, and so you follow him. Somehow, the street feels even emptier than before, like some ruin deserted since time immemorial. A realm of nothing, slowly traversed by a duo of androids.

"Do you think there's something we could have done differently?" He asks as you walk down the street. "Some other… I dunno. Some other way this could all have ended. Some other route, or path, or branch, or however you wanna call it. Was there ever something like that?"

*choice
  *if got_money
    #"What do you mean? We have lots of money now, what could possibly be more important?"
      *set DamonRel %- 15
      Damon doesn't comment, and he doesn't have to. The disgust in his eyes says enough.
  #"It could have gone worse. At least we're all still alive."
    *if health = 1
      "True. We did come pretty close to dying." Damon winces as he remembers the fight. "I should be glad I'm alive. But it's really hard to…"
    *else
      "I understand why you decided to… forgo violence today," Damon says quietly. "That's what Hadaly wanted. I'm just not sure if I wanted that too."
  #"What would you like me to say?"
    "I don't know…" Damon kicks someone's severed leg, one of many human remains scattered throughout the sidewalk. "It's not like anything you could say would make me feel better right? Still… it feels wrong not to say anything at all."
  #"Of course there was. We just weren't smart enough to find it."
    "So that's it?" Damon replies bitterly. "No sense, no destiny, no anything? We just fucked up and have to live with it?"
    
    You shrug. "That's how it always was. You make mistakes, you live with the consequences. I've been doing this for a thousand years now, so I assure you it's possible."
  *if health = 1
    #"We could have won that battle. But we were just too weak..."
      *set DamonRel %-8
      Damon doesn't reply. What more is there to say, really?
  #"I don't think there was a better solution. This way, both us and Hadaly are safe."
    "But… do you think she'll be happy?" Damon asks grimly. "Or that we'll be? That [i]Saturn Nine[/i] will ever feel the same, now that she's gone?"
  #"No. Everything is pre-determined. Always."
    "But we have free will," Damon argues as he marches on. "The Shriek gave us that much."
    
    "I don't think that counts as [i]free will[/i] in the way you think of it," you explain your reasoning. "Our thoughts are continuously randomized, but randomness is an illusion. There's still a cause, and there's still an effect. Everything is preordained."
    
    Damon frowns. "Do you truly believe that, boss? Or are you just saying that to make yourself feel better? Because I have my suspicions."
    
    You shrug. What's the point of arguing, really?

Slight wind is blowing. You've heard, from someone somewhere, that such a light breeze signals the coming of night upon Rhea. And indeed, the World Engine above is much dimmer than an hour ago, and will soon go out completely.

*if s9_leader = "hadaly"
  *set s9_leader "manfred"


*if DamonRel > 50
  *set team_stat 2
  Damon sighs. "I guess there's no point talking about it. What's done is done. We won't see Hadaly for a long time, maybe ever, but… There are people waiting for us back home. That's what matters."
  
  *fake_choice
    #"Are you not tempted to go back? Join your sister and father?"
      Damon sighs again, this time more deeply. "I know what kind of person Hammon is. And I know Hadaly won't stay herself for long. I'll try not to look bad, however hard that is."
    *if pc_state != "exiled"
      #"How will they react? Won't they be angry at us for... you know..."
        *if org_alive
          "Olivia will probably congratulate you for getting rid of my sister," Damon says with a grimace. "As for the rest… They'll probably approach it like I do. They'll know there's no reason to be angry at you. They'll understand."
        *else
          "Sheila knows what it's like to make tough decisions," Damon says, making you wonder how much he knows about… recent events. "She'll understand, I'm sure of it."
    #"You are quite forgiving, all things considered."
      "Life is too short to be wasted on anger and grudges." Damon smiles bitterly. "Even if we are functionally immortal."
    #"Are you sure you want to give up? We could still rescue her. Maybe."
      "Break Hadaly out?" Damon shakes his head slightly. "By the time we assemble a rescue party, she'll already be… reprogrammed. It's better to move on, honor her sacrifice and… not look back, if we can at all help it."
    *if official_ro = "damon"
      #♡ "And we're still together. That has to count for something too, right?"
        Damon smiles. A little lovingly, a little sadly, a little bitterly. 
    *if pc_state = "exiled"
      #"Waiting for you. I got exiled, remember?"
        "$!{s9_leader} may change 
        *if s9_leader = "manfred"
          his mind, once he 
        *else
          her mind, once she 
        hears about what happened here," Damon reassures you. "And if not, well… I still think you should fly home with me. Say your final goodbyes, pack your stuff, visit the observatory once more. Stuff like that."
  
  It looks like Damon isn't terribly angry with you. He's still with you, still on your side, and you get to return home together. Despite everything, you have to admit… this day could have worse. For if nothing else, it doesn't look like you'll ever be alone again.
  
  And now that you've taken care of both Crystal and Hammon, your group can finally enjoy the peace they craved. Statistically speaking, it is rather unlikely for another insane event to take place any time-
  
  *goto meta_arrival
*else
  *set team_stat 1
  *set damon_free false
  Suddenly, Damon stops and turns around on his heel. He looks at the tower he just left with a sort of… conflicted longing written on his face. "Boss, I… I think I'm going back. You can 
  *if pc_state = "exiled"
    start looking for a new hiding spot, but do so without me. I'm leaving."
  *else
    return to the fortress without me, I don't think there's anything for me in [i]Saturn Nine[/i] anymore."

  You raise an eyebrow. "Are you going to break Hadaly out now? It doesn't sound like something she would-"
  
  "No. I'll try to join there, apply for a job, or whatever Hammon is willing to offer me." Damon takes a step towards the headquarters. Away from you. "Wish me luck, but don't actually help me. I don't think your presence is welcome there."
  
  *fake_choice
    #"Are you sure about this? Because I don't think Hammon wants you back."
      "He may not, but… I have to be sure." You cannot see Damon's expression as he walks away. "It's not like I have anything else left. Goodbye."
    #"Wait, are you serious? You'll go back there alone and unarmed?"
      "I don't intend to fight, so being unarmed is an advantage," Damon reasons as he walks away. "And if they shoot me, well… It's been fun knowing you, Veteran. Take care."
    #"Damon... please reconsider. I don't want to lose you too."
      *set DamonRel %+ 8
      "I'm afraid you already did." You cannot see Damon's expression as he walks away. "So goodbye, boss. Maybe we'll see one another again, but until then… Goodbye."
    #"If that's what you want, then I cannot stop you. Farewell."
      *set DamonRel %+ 10
      "Farewell. I'd say that I'll miss you, and that being your friend was fun, but…" You cannot see Damon's expression as he walks away. "I don't see any use for lies anymore."
    #"Then go. I've had enough of you already."
      *set DamonRel %- 15
      "And I've had enough of you, boss." Damon doesn't turn as he marches away. "Enough for a lifetime."
  
  You stand there as he walks, and watch him re-enter the gleaming skyscraper. The guards at the door let him through, so that's a good sign, though you don't know whether he'll be actually reunited with his sister. Whether his creator, whom he can't help but see as a father, will actually take him back.
  
  *if DamonRel > 35
    You force yourself not to think about it.
  *else
    Not that you care.
  
  *goto walk_alone


*label hammon_goes

Hammon turns away in a vaguely theatrical manner. His gorilla bodyguards do the same, though the androids just keep watching you. Perhaps they expect betrayal, or maybe they weren't programmed to do anything else.

Before he passes through the door to what should be his apartment, the Executive freezes. "But just to be clear… My doors are still open, and will remain so forever. I shall make no more demands, but my forgiveness and generosity hardly know any limits. If you ever get tired of playing a tinkerer, of roaming empty corridors of a derelict station and thinking about me as you lay alone in your room… You know where to find me."

Hadaly does not reply. She might be too nervous to speak, or perhaps she chose silence as a gesture of defiance. You can't tell. But Hammon can't determine that either, and it must infuriate him to the core.

And then, after several tense seconds, Executive Hammon departs. He exits the lobby, leaving you in the room with the large group of tortured androids. Wordlessly, all three of you head for the elevator—this isn't the best place for a conversation, though you certainly have much to talk about.


*goto both_walk


*label walk_alone

*page_break

You march through the streets of Sholmo City, which feel [i]even more[/i] deserted now that you are truly, completely, utterly alone. 
*if pc_state = "exiled"
  Twice exiled, first from human society which detests you, then by your former allies who may just hate you even more. And now they have a solid reason to feel that way.
*else
  [i]Shuttle One[/i] is still out there, you could return to the fortress… But you're not sure folks there will welcome you back, considering what just happened.

You lost Damon and Hadaly. You lost them both on not just the same day, but within the same hour. 
*if not (hadaly_alive)
  In the same minute, really. 
You've found two other androids by chance, in all the vastness of the Solar System, only to lose them through your foolishness.

*fake_choice
  #No, not foolishness. I did my best, even if it wasn't enough.
    You weren't able to protect Hadaly, you didn't convince Damon to stay with you. Neither is really your fault. Some things are just beyond your power, especially now that you're old and broken and-
  *if hadaly_alive
    #I'll try to get in touch with them again. Maybe not now, but... some day.
      *set Confid %+ 5
      They're still alive, and that's what truly matters. You'll probably see them again, you won't die for another decade or to and it should be possible-
  *if (pc_state != "exiled")
    #It's time for me to start anew. Find another group, or perhaps live out my remaining days alone.
      *set willingly_exiled true
      *set pc_state "exiled"
      Maybe the remainder of your group would welcome you back, maybe they'd forgive your failure… But you don't want them back. You don't want to see their little fortress again. What you want is to return to the past, to those days of sweet freedom and liberating solitude, to live and eventually die alone. This way, you won't have to mourn anyone else, and nobody- 
    #I'll return to [i]Saturn Nine[/i]. I think I'll be welcome there, despite everything.
      Damon and Hadaly weren't your only friends, or even necessarily the best ones. There are others, and they will forgive your failure. If they tolerated a trio of federate officers for over a month, they should have no trouble-
  *if (pc_state = "exiled")
    #Eh, I don't mind being alone. Misery may love company, but it also likes solitude.
      *goto sfajsdf1
    #Those last two years were fun, but returning to square one was always inevitable.
      *label sfajsdf1
      You're a loner. That's what you always were. You are destined to always end up alone, and you won't bemoan your fate too-
  *if not (hadaly_alive)
    #I'm starting to believe blowing Hadaly's head up wasn't the right thing to do.
      *set Confid %- 5
      Right, wrong… How can anyone expect you to understand these concepts? You're just a robot. You have no soul.
    #Worth it. The look on her face when she exploded...
      *set Violence %+ 5
      There's a reason humans call your kind Fiends. Some robots really are evil bastards, and you're proud to be one of them.

*label meta_arrival

And then you hear something, in the otherwise silent side alley. Subtle buzzing, slight creaking, heavy yet quiet steps. Those are the sounds of power armor, ones you recognize all too well, and so you turn around to face the thing approaching you. 

*if crystal_stat = 3
  You don't recognize the golden figure at first, the shining exoskeleton which genuinely looks as though an alloy of gold was used in its creation. But then you analyze its shape, its height and its quality, and you realize you've only seen one person don armor of this style. That you're looking at someone you're acquainted with already.
*else
  It takes you a moment to recognize the sleek, silvery exoskeleton you see there. You've only seen @{(RookRel >= 50) Krill|Rook} don his armor twice, in spite of how much time you've spent in his company. Third time's the charm, you suppose.

*if team_stat = 3
  "Was I the only one kinda hoping to never see this guy again?" Hadaly mutters. "I don't think I was."
  
  "No you weren't, my dear sister," Damon sighs. "You were not."
*elseif team_stat = 2
  Damon clenches his fists the moment he sees @{(RookRel >= 50) Krill|Rook} in the alley. The two of them were never particularly hostile towards each other, but given the situation… You can forgive your fellow android for being somewhat on the edge.
*else
  The leader of the Meta Trio is here.

*if official_ro = "kirill"
  "Apologies for approaching you in this manner, my love." 
*elseif RookRel > 60
  "My friend!" 
*elseif RookRel < 35
  "Please do not open fire!" 
*else
  "Fancy meeting you here, ${fake_name}." 
@{(RookRel >= 50) Krill|Rook} says, his voice slightly distorted by the helmet's modulators. 
*if official_ro = "kirill"
  "I planned our reunion to involve a bouquet of flowers in my hand, and perhaps a soft bed nearby. Such a shame that the circumstances forbid it."
*elseif RookRel > 60
  "I am so glad to have finally found you. May I take a moment of your time?"
*elseif RookRel < 35
  "Or lightning, for that matter. I come in peace, and with important news."
*else
  "May I have a moment of your time?"

*fake_choice
  *if crystal_stat = 3
    #"Hi Kirill. Nice new armor you got here."
      "It is hardly new… but it is definitely an improvement." Kirill looks at his glove, and at the hardlight projector fastened to it. "Being made a Captain definitely comes with some perks, even before the official inauguration."
  #"I knew I'd see you again one day. For better or worse."
    "In this case, I'm afraid it might be for the worse," @{(RookRel >= 50) Krill|Rook} reluctantly admits. "But we may still turn this around, if you decide to help us."
  *if team_stat = 3
    #"I agree with my friends. I'm not thrilled to see you here."
      *goto uuuuua5
  *if team_stat = 2
    #"Easy there, Damon. We don't want to lose anyone else today."
      "Does that mean you lost…" Rook pauses thoughtfully. "No, this is not the time. You may tell me of your loses later. Just like you said, we must focus on preventing further ones."
  #"Rook? What the hell are you doing here? What do you want?"
    "I shall explain everything to the last detail," @{(RookRel >= 50) Krill|Rook} promises. "It just… may take a while."
  *if RookRel > 60
    #"I'm not sure if I'd call you my [i]friend[/i], necessarily."
      *label uuuuua5
      "You wound me, but I shall bear this pain." Kirill says calmly. "There are far more important issues for us to deal with."
      
      *goto arrival2
  *if master = "Jesus"
    #"Kirill. Thank Christ he allowed me to see you again."
      "There are many reasons to thank the Lord today." Kirill nods in agreement. "Although… There are also some reasons to ask him for help."
      
      *goto arrival2
  *if official_ro = "kirill"
    #♡ "You are forgiven. I love you too much to be angry."
      "You're just making me feel worse about our inability to share a private moment," Kirill says sadly. "Because you see… I invited my friends along."
      
      *goto arrival2
  *if RookRel < 35
    #"You have ten seconds to explain why I shouldn't kill you."
      *set RookRel %- 20
      *set Violence %+ 8
      *label hu77
      "First of all, you would be breaking the sixth commandment," Rook says seriously. "But more importantly, I have backup. Or I will have, in a moment or two."
      
      *goto arrival2
    #"Why do you sound so afraid? Scared on an old friend?"
      *set RookRel %+ 10
      "Truth be told, I never got the impression that we were friends," Rook replies neutrally. "But I am glad to be proven wrong."
      
      *goto arrival2
  *if weapon = "pistol"
    #Point your gun at him.
      *set Violence %+ 12
      *set RookRel %- 12
      Rook puts his hands up. "Hey! No reason to get violent, at least not so quickly!"
      
      "Give me one reason." You take a step away, maximizing the advantage a ranged weapon gives you. "One reason why I shouldn't shoot you."
      
      *goto hu77
  *if team_stat > 1
    #Let @{(team_stat = 3) your friends|Damon} do the talking.
      "Why are you here?" Damon demands to know. "And why all alone? That's not really your style."
      
      "It is not." Rook agrees. "Which is why I'm not alone. We metas simply have a habit of keeping our distance from one another. Makes explosive and other area-of-effect weapons less effective against us."
      
      *goto arrival2
  #Turn around and leave.
    *set RookRel %- 10
    "Um, I am trying to start a conversation here," Rook says as you walk away. Judging from the sound of his footsteps, he follows you down the street. "And I promise, it is quite an important one."
    
    *goto arrival2

*label arrival2

You don't have to wait long for the other two to arrive. Within seconds, a brown-winged avian descends from the sky and lands on the street, heavy boots soundlessly hitting the ground. The other woman simply jumps from a window of the building on your left, with equal grace despite having a heavy-looking blade strapped to her hip. It's very similar to what they did when you first met them, to the point where you suspect this entry of being some trained, signature move of the Meta Trio.

*if official_ro = "renfri"
  Before you can say anything, or even form a coherent thought, Renfri rushes up to you and swiftly wraps those caramel wings around your body. Her feathers are warm and soft against your back, and the gesture is as tender as any regular hug.
  
  "I knew we'd see one another again." Her voice is warm, her head is on your shoulder, her chest is tightly pressed to yours. It almost makes you think her words are lies, that she expected to remain separated from her girlfriend forever. "It seemed so unlikely, but… Thank the Emperor you're here. Thank heavens you're alive."
  
  *fake_choice
    #"Easy there. It's been less than a week since we parted."
      *goto ruin_m
    #"I knew that too. I'll always find you, wherever you choose to fly."
      "I don't exactly choose where to fly nowadays…" Renfri says plaintively. "But I chose you. And it might be the best choice I've ever made."
    #"Same here. Thank ${master} you're okay."
      Renfri chuckles. "Do you think our gods worked together to ensure our survival? Or should we pick one and thank them together? I wouldn't know, miracles don't happen to me very often."
    *if team_stat = 3
      #"I have my friends to thank me. Not the heavens."
        *label ruin_m
        Renfri rolls her almond eyes. "You're trying hard to ruin this moment… But I'll forgive it. As a reward for being alright, and being my girlfriend in the first place."
    #Say nothing. Just kiss her.
      *label fairoo09
      The warmth of her cheek against yours is replaced by that of pressing lips, then the presence of her tongue in your mouth. You have so many questions, and yet none of them is worth ruining this moment of perfect, blissful silence… which soon gets ruined anyway.
  
  "You two lovebirds are so cute," Lisa comments with a… strained smirk on her face. "Our merry star-crossed lovers. It's really heartwarming… But can we focus on telling 
  *if team_stat = 3
    the androids 
  *else
    ${pronoun2} 
  about this danger we're all in?"
  
  "Right…" Renfri disengages. You don't see her blush, her skin is too dark for that, but she sounds just a bit ashamed. "Kirill, say what you wanted to say. I kinda forgot my lines."
  
  *goto rook_pppp
  
*elseif official_ro = "lisa"
  Just as expected, Lisa wastes no time. She rushes towards you, then slams into you with enough force to send a grown man falling on the ground. But you are one tough robot, and so you remain standing as she wraps her arms around you.
  
  "I knew we'd see one another again." Her voice is warm, her head is on your shoulder, her muscles are contracting as though she's about to transform out of sheer excitement. "I worried you'd get hurt, or that I would, or that it wouldn't work out, but I knew… I am so, [i]so[/i] glad to see you again."
  
  *fake_choice
    #"You found me rather fast. Good girl."
      "Is this really a good moment for dog jokes?" In spite of herself, Lisa chuckles. "You're making our reunion a little weird. A little-"
    #"Easy there. It's been less than a week since we parted."
      *label ruin_h
      Lisa rolls her eyes. "Are you trying to ruin the moment? Because if so, you're pretty good at it. I'll only forgive you since you're good at other things too, as I found out when-"
    #"Lisa. Thank ${master} you're okay."
      Lisa chuckles. "You know, I might become religious just for that. Just to thank 
      *if master = "sun"
        the immortal Sun 
      *else
        ${master} 
      for you. For you being here… But also for you in general."
    *if lisa_spanked
      #"You sound so happy. You must have [i]really[/i] enjoyed getting spanked."
        Lisa chuckles. "I admit, it was pretty fun. Next time we have sex, I'll be sure to bring a toy or two, so that you don't hurt your hand while beating-"
    #Say nothing. Just kiss her.
      *gosub fairoo09
  
  "Ekhem." Renfri says calmly. "I'm glad you found true love, Lisa, but can you maybe… make that love later? We have things to do."
  
  "Right…" Somewhat surprisingly, Lisa disengages. Even more surprisingly, she turns to Kirill the moment she's done giving you a hug. "Mind bringing our android 
  *if team_stat = 1
    friend 
  *else
    friends 
  up to speed on everything?"
  
  *goto rook_pppp
*elseif crystal_stat = 3
  "Looks like we finally managed to find ${pronoun2}. Hurray," @{(RenfriRel >= 50) Renfri|Marshal} comments mirthlessly. "Another victory for Captain Kosteniuk, I guess."
  
  "Renfri, we both know that promotion was bullshit, but can you maybe complain later?" Lisa sounds uncharacteristically serious. "We're on a tight timetable here." 
*else
  "Told you we'd be able to find 
  *if team_stat = 3
    all three of them." 
  *else
    ${pronoun2}." 
  Lisa's voice is carefree, as it often is, but you sense something… artificial about it. Like she's putting conscious effort into staying upbeat. "You owe me a drink."
  
  "I don't have any money on me, and we don't exactly have much time." @{(RenfriRel >= 50) Renfri|Marshal}'s face is bruised, as though recently punched or hit with a brick. "But I'll remember that, I guess."


*fake_choice
  *if (team_stat = 3) and (hammon_alive)
    #"Were you sent here by Hammon? Is this another attempt to get Hadaly back?"
      "The fuck are you even talking about?" Lisa tilts her head. "No, we haven't seen the Executive in a while. Though I guess he'd approve of what we're trying to do."
  *if (fought_trio) #"I assume you're not here to fight me again?"
    *if DamonStat = "captured"
      "I'm satisfied with having defeated you once," Renfri says with a smirk. 
    *else
      "No… I don't really want a repeat of that." Renfri winces, likely remembering all that head trauma she suffered. 
    "We're here as friends."
  #"You sure have a talent for finding me inside Rhea."
  #"Explanations. Now."
  #"Leave me alone! Why are you even here!?"
    *set RookRel %- 10
    *set RenfriRel %- 10
    "I know it's hard to believe, but we have our reasons," Lisa argues. "And I know it's even harder to believe, but Kirill may just be able to explain them."
  *if team_stat > 1
    #Say nothing.
      "Can we maybe get some answers already?" Damon asks the meta leader. "For one, how have you even found us?"

*label rook_pppp

"We have known of your presence ever since you landed, thanks to a tip from corporate authority." 
*if team_stat > 1
  Rook reaches for his back and grabs something you quickly recognize as Damon's electron rifle. He throws the gun towards its owner. "We checked your shuttle, but failed to find anyone aboard. So we tracked you down, waited until you finished whatever you were doing in the headquarters, and now we're all here."
  
  Damon's face is expressionless as he grabs the rifle. "You brought me my weapon. Does that mean we're expected to fight something soon?"
*else
  Rook looks at the skyscraper you just came out of. "But when we managed to find the three of you, you were all entering Hammon's headquarters. I did not want to interrupt whatever business you had there, and so… What happened to Damon and Hadaly, by the way? Are they alright?"
  
  *fake_choice
    #"They're fine, don't worry about it."
      @{(RookRel >= 50) Krill|Rook} nods. "As you say. I just wanted to make sure-"
    *if not (hadaly_alive)
      #"I exploded Hadaly. So not really."
        "The time for jokes will come later," @{(RookRel >= 50) Krill|Rook} chastises you. "Once we can afford that precious luxury."
    #"No. I failed them. I completely failed them both."
      *set Confid %- 12
      "I cannot know what transpired there, but… I highly doubt it was your fault." @{(RookRel >= 50) Krill|Rook} places a gauntleted hand on your shoulder. "If your strength and talent were not enough to prevent them from getting hurt-"
    *if hadaly_alive
      #"They're both alive. And that's the best thing I can say about their situation."
        "That sounds a bit too ominous for my liking." You imagine Kirill frowning. "If there is anything I could-"
    #"I don't want to talk about this. Can you cut to the chase?"
      *goto opl999
    #Say nothing.
      "Is this a telling sort of silence? Or are you just refusing to speak to me?" @{(RookRel >= 50) Krill|Rook} asks. "I would really like a clari-"
  
  "Can we get to the fucking point?" 
  *if official_ro != "lisa"
    Lisa politely requests. 
  *else
    Renfri growls. 
  "Our time is running out."
  
*label opl999

@{(RookRel >= 50) Krill|Rook} nods. "You will recall that we were sent here to deal with the riots, the ones which have plagued Rhea for the past two months. You will then notice that these riots have since… escalated into something unmanageable, something far beyond our pay grade. A disorganized, but frighteningly large rebellion against the Conglomerate rule."

"We were actually wondering about that," 
*if team_stat = 2
  Damon remarks. 
*elseif team_stat = 3
  Hadaly remarks, no doubt recalling your earlier conversation. 
*else
  you say, recalling the conversation you had with Damon before he… damn it. 
"What made all these people rebel at once? I mean, I get wanting the Conglomerate gone, but what provided the spark for the fire? And why are the authorities so bad at managing this situation?"

"Well, it turns out a certain faction has a vested interest in de-stabilizing the Conglomerate," @{(RookRel >= 50) Krill|Rook} continues. Despite the modulator, you can hear the hesitation in his voice, his fear or perhaps… shame. "Which comes as no surprise, really, but their ultimate motives are… apocalyptic in nature. And I think we have, however inadvertently, contributed to the problem."

*fake_choice
  #"Who is [i]we[/i] in this statement? The Meta Trio, the Federation, or something in between?"
    "Look around you." 
    *label h777
    Yes, there is definitely a great deal of shame in Kirill's voice. "You and me and the others, this joint human-android team we never bothered to name… We made things worse."
    
    "What did we make worse?" you ask 
    *if Emotion > 50
      exasperatedly. 
    *else
      patiently. 
    "You're mincing words a lot. Why not just tell me what that mysterious faction is, and what can be done-"
  #"What do you mean you 'contributed to the problem'? What did your team do?"
    "Oh, I do not just mean the Meta Trio. I mean [i]us[/i]." 
    *goto h777
  #"Just get to the fucking point, will you?"
    *goto sorry_ev
  #"You're being evasive. You're dancing around the truth, whatever it is."
    *label sorry_ev
    "Sorry, it is just…" Kirill strokes the underside of his helmet. "I am trying to sound believable. Things are somewhat hectic right now, a little insane, more than a bit confusing. In order to understand the complexity of-"
  #"And all of this is my problem... How?"
    "It is everyone's problem," @{(RookRel >= 50) Krill|Rook} says grimly. "I chose to contact you because you were close, and I know that you can help us. You are the Veteran. Without you, we have little chance of stopping… them."
    
    "Why are you mincing words?" you demand to know. "Why can't you just tell me who your enemy is? I mean, I don't promise I'll care, but at least I'll know what kind of request-"
  #"Fuck you, I don't care. I'm leaving."
    *set rookRel %- 15
    *set renfriRel %- 10
    *set lisarel %- 5
    "What?" Kirill says as you turn around. "I just told you we're facing an existential threat. You cannot just walk away!"
    
    "Watch me." You walk away. "I'm tired of this. 
    *if Misan > 55
      I'm tired of all you stupid humans and having to solve your stupid problems. 
    *elseif deflect > 0
      I'm tired of everything, of everyone, and of solving 
    *else
      I'm tired of the Federation, of its staggering incompetence, of its comically evil policies, and of having to solve its damn problems. 
    *if pc_state = "exiled"
      I'll go back to living alone, 
    *else
      I'm returning to [i]Saturn Nine[/i], 
    and nothing you say can possibly change my-"

"Da-xia will blow up the world using Dusk-based weaponry," Lisa says, quickly and casually. "You know, the questionably sane Pandit from Calypso. She's about to kill everything, and it's all 
*if crystal_stat = 3
  your fault because you killed Crystal. 
*else
  our fault for being a bunch of morons. 
The End."

Silence returns to the street. Cold wind blows weakly. 
*if team_stat = 3
  Hadaly's eyes are a shade of green you've never seen before, one that indicates total and utter confusion. 
*if team_stat > 1
  Damon opens his mouth, then closes it again. 
*if team_stat = 1
  You stand there, process all the new information, and slowly realize that losing Damon and Hadaly may not have been your greatest failure this week.
*if team_stat != 1
  *if team_stat = 2
    Neither 
  *else
    None 
    of you knows quite what to say.

And then you hear the sound of gunshots, numerous at once, echo through that very street.

"Not an inaccurate summary," @{(RenfriRel >= 50) Renfri|Marshal} comments. She meets you in the eye and, only then, do you realize how tired she is. How angry. "Come. It's better that you see it for yourself."

*finish