*set progress + 1

*temp boss_health 3
*temp boss_will 3
*temp lisa_in_fight true
*temp marshal_in_fight true

*if final_boss = "rook"
  *image king.png
*elseif final_boss = "damon"
  *set damon_free false
  *image knight.png
*elseif final_boss = "marshal"
  *image marshal.png
*elseif final_boss = "lisa"
  *image hound.png
*else
  *gosub_scene ending

*temp light "light"


A second later, once the virtual vision dissipates, you are once again standing in the half-destroyed boiler room. A second after that, you're already on the move, 
*if weapon = "none"
  diving for cover 
*else
  reaching for your ${weapon} 
as quickly as you can.

Not fast enough. 
*if Calculation > 50
  Not quite.
*else
  Not nearly fast enough.


*if final_boss = "rook"
  *set TrioStat "broken"
  *if official_ro = "kirill"
    *achieve bad_partner
    *set boss_will - 1
  With a mere swipe of his arm, @{(RookRel >= 50) Krill|Rook} sends you flying through the breach in the wall. He doesn't make physical contact, he just sort of… levitates you away. Perhaps he's manipulating nanites that somehow got inside your system, or maybe he's demonstrating some new power Dusk gave him. Hard to tell.
*if final_boss = "marshal"
  *set TrioStat "broken"
  *if official_ro = "renfri"
    *achieve bad_partner
    *set boss_will - 1
  @{(RenfriRel >= 50) Renfri|Marshal} scarcely flaps her wings. She barely moves at all. She merely flinches slightly which, somehow, is enough to send you flying through the breach in the wall as though you were falling sideways… though you soon begin falling down as well.
*if final_boss = "lisa"
  *set TrioStat "broken"
  *if official_ro = "lisa"
    *achieve bad_partner
    *set boss_will - 1
  @{(LisaRel >= 50) Lisa|Hellhound} lunges at you, not with a sword or with claws this time, but with mere fists. Somehow, even this simple punch from the slender young woman is enough to knock you off your feet when it connects, sending you flying through the breach in the wall and towards the ground below.
*if final_boss = "damon"
  *if official_ro = "damon"
    *achieve bad_partner
    *set boss_will - 1
  Damon shoves you with both casual ease and almost supersonic speed. He hardly even strikes you, merely pushing you out of the breach in the wall and forcing you to leave the boiler room at an uncomfortable speed. The expression on his face looks bored, grim, perhaps pained—he will not enjoy this fray, but he will fight it all the same.

You spend a second falling, then hit the asphalt of the deserted street right beside the power plant. You rise to your feet hastily and 
*if health = 3
  without difficulty—the fall did not injure you and, despite your age and the battle you've just fought, you feel healthy and almost energetic.
  
  *if (Confid < 60) and (Emotion > 40)
    Physically, that is. You feel pretty bad mentally, keenly aware of how doomed you are.
*elseif health = 2
  with little difficulty—though the fall hurt, it did not cause you any significant injury. You're still mostly alright, or at least operational enough to fight.
*else
  with some issue—though the fall didn't injure you greatly, the damage you've sustained during the battle is still keenly felt. Your barely-operational body belongs in a repair workshop, but instead you'll have to use it to defeat a Vessel of Dusk.
  
  Amazing.


*if final_boss = "rook"
  *goto rook
*if final_boss = "marshal"
  *goto marshal
*if final_boss = "lisa"
  *goto hound
*if final_boss = "damon"
  *goto damon





*label rook

@{(RookRel >= 50) Krill|Rook} walks down to meet you. Actually walks down, despite the absence of stairs or anything similar, simply stepping on the air as though it was a solid surface. It's not the craziest thing you've seen today, but the ease with which he does it fills you with 
*if Emotion > 50
  dread. 
*else
  uncertainty. 

"${fake_name}, you have been chosen as a sacrifice necessary for my ascension," he says in an edified, ceremonious tone. "I implore you to stand down and face your death with dignity."

*fake_choice
  *if (RookRel > 60) or (official_ro = "kirill")
    #"Do you really want to kill me? Your @{(official_ro = "kirill") partner|friend}? Because I don't think you do."
      *set boss_will - 1
      "Our @{(official_ro = "kirill") love|friendship} was a mistake," Kirill says harshly, but then his voice softens. "But… you're right. I do not want to do this. I am simply doing what I-"
  #"Ascension? You've fallen to Dusk, Kirill. Come back before it's too late."
    *if (Social + RookRel) > 110
      *set boss_will - 1
      "It is already too late," Kirill says quietly. "There is nobody who can absolve me of my sins. Nobody but the Thing Beneath itself. I must-"
    *else
      "You are trying to take away my power," Rook accuses. "Power which belongs to me, which will help me fulfill my ambitions and enlighten the Solar System. I must-"
  *if (Database > 50) #"You're back to using my pseudonym, rather than my real name. Does it lessen your guilt?"
    *set boss_will - 1
    @{(RookRel >= 50) Krill|Rook} grimaces, signaling that you've struck a blow. "I'm using the name you chose to be known by. We both made our choices, and we must respect-"
  #"I will face my death with dignity... by fighting you until my last breath."
    "You do not breathe," @{(RookRel >= 50) Krill|Rook} says dryly. "Really, your verbal sparring skills leave a lot to be-"
  #"Sure, I guess. Go ahead and kill me."
    *set deflect + 1
    *set Confid %- 10
    *if (Social + RookRel) > 110
      *set boss_will - 1
    "Is this a genuine offer? Or a ruse of some kind?" @{(RookRel >= 50) Krill|Rook} muses. "It is impossible to tell when dealing with a creature as duplicitous as-"
  #Attack @{(RookRel >= 50) Krill|Rook}.
    *set Violence %+ 8
    *if weapon = "pistol"
      You raise your pistol and simply start blasting. 
      *if ((wpr = "electron") or (wpr = "rail")) or (wpr = "plasma")
        *set boss_health - 1
        *set weapon_av false
        @{(RookRel >= 50) Krill|Rook} seems surprised, but not pained or even particularly bothered as the 
        *if (wpr = "electron")
          electron beam penetrates 
        *else
          projectiles penetrate 
        his armor and tear holes in his body.
      *else
        Hitting your mark is not difficult at this distance, but actually penetrating @{(RookRel >= 50) Krill|Rook}'s power armor… that's the difficult part. Your 
        *if (wpr = "laser")
          laser beam barely does 
        *else
          projectiles barely do 
        anything.
    *else
      You charge @{(RookRel >= 50) Krill|Rook} with the intent of 
      *if weapon = "knife"
        stabbing 
      *else
        punching 
      him in the face. In response, the meta-human turns his hardlight projector on and materializes a transparent bar at the height of your angles, causing you to trip and fall on the hard asphalt. 
      
    *if boss_health = 2
      "I actually felt that," @{(RookRel >= 50) Krill|Rook} comments. "Your pistol is an impressive weapon. Shame I cannot say the same about-"
    *else
      "This is simply pathetic," @{(RookRel >= 50) Krill|Rook} comments. "You stand no chance against me, so why not simply-"

*if team_stat > 1
  *set boss_health - 1
  Something invisible burns a hole in @{(RookRel >= 50) Krill|Rook}'s head, puncturing the skull and somewhat exposing the brain. You suspect it was an overcharged shot from electron rifle, given that Damon is currently aiming that exact weapon at @{(RookRel >= 50) Krill|Rook}, lying prone in the boiler room.
  
  "Damn, I was really hoping that would kill you," Damon tells the meta-human. "Is Dusk keeping you alive? Or are you just not using your brain for much?"
  
  @{(RookRel >= 50) Krill|Rook} looks at Damon with ire, but does not attack. Something else catches his attention, a certain Kinnari jumping from the very same room and gliding through the air.

"Kirill!" @{(RenfriRel >= 50) Renfri|Marshal} yells as she lands right next to her leader. "What the Cloud are you doing?"

"Right, you're not usually that kind of crazy," @{(LisaRel >= 50) Lisa|Hellhound} jumps out of the boiler room too. Her limbs are already turning into paws, which forces her to drop her sword, but she can still speak for the moment being. "What's gotten into you?"

"I have perceived a path to fulfilling my ambitions." @{(RookRel >= 50) Krill|Rook}'s voice wavers ever-so-slightly. "Dusk is not the evil deity I took it as. With its help, I can make the Federation great-"

A laser beam fire out of @{(RenfriRel >= 50) Renfri|Marshal}'s laser disc burns @{(RookRel >= 50) Krill|Rook}'s right eye. His eyeball is not cooked instantly—a testament to his newly acquired durability—but he does close the eye, as though blinded by an ordinary ray of bright light.

*if team_stat > 1
  You look up to see Damon 
  *if team_stat = 3
    and Hadaly 
  scale the wall down in hopes of joining the fray. 
  *if team_stat = 3
    They surely want 
  *else
    He surely wants 
  to help you, but 
  *if team_stat = 3
    seem 
  *else
    seems 
  reluctant to simply jump towards the hard ground below. You'll need to hold on until 
  *if team_stat = 3
    their 
  *else
    his 
  arrival.

*fake_choice
  #"Dusk played on his insecurities. Laid his weaknesses bare and promised to alleviate them."
    "That's all it took?" @{(RenfriRel >= 50) Renfri|Marshal}'s nostrils flare. "Did Dusk tell you how much better I am? How I would have been a better leader? Because I think we both know that's the truth."
    
    "We've both known it for a long time now, Renfri," @{(RookRel >= 50) Krill|Rook} replies gravely. "This is just the confirmation. And the reason why I need the Shadow's power."
    
  #"What are you waiting for, girls? Attack for real."
    *set Violence %+ 10
    Obliging your request, 
  #"Don't attack him, Renfri. Talk to him. He's not beyond saving."
    *set boss_will - 1
    *set Violence %- 10
    "Are you sure about that?" Renfri scoffs. "He just pumped himself full of Dusk. I bet he's nothing but a mindless puppet now."
    
    @{(RookRel >= 50) Krill|Rook} frowns. "Are you goading me into abandoning my path? You are doomed to fail. I have made my choice already."
    
  #Attack @{(RookRel >= 50) Krill|Rook}. Take advantage of his blind spot.
    *if weapon = "pistol"
      You move into a better position, so that you can fire at @{(RookRel >= 50) Krill|Rook} without the fear of hitting your allies by accident, but you don't get the time to—everyone is on the move less than a second later. 
    *else
      You don't sneak up on @{(RookRel >= 50) Krill|Rook} as much as you simply walk up to him, taking advantage of his temporary distraction and partial blindness. He doesn't notice you until you've already 
      *set boss_health - 1
      *if weapon = "knife"
        stabbed him in the face, tearing his right cheek apart with your dagger.
      *else
        *set battery - 8
        pressed your hand to the right side of his face and electrocuted it, burning the black skin and causing the muscles beneath to spasm.
      
      He roars and tosses you away, much like did seconds ago, but doesn't have the time to actually hurt you. 
@{(RenfriRel >= 50) Renfri|Marshal} and @{(LisaRel >= 50) Lisa|Hellhound} attack at once, from two different direction. @{(RenfriRel >= 50) Renfri|Marshal} flies up while charging up another shot as @{(LisaRel >= 50) Lisa|Hellhound}—now fully lupine—charges her former leader on the ground.

@{(RookRel >= 50) Krill|Rook} stops them both without touching either.

He stretches both his arms out, causing @{(RenfriRel >= 50) Renfri|Marshal} to fall and her friend to trip. He could be influencing the nanites in their blood or using some new power granted to him by Dusk, you cannot tell, but you can tell when he activates his hardlight projector afterward. Chains materialize around both of his opponents, tying them to the ground, growing thicker and longer with each passing moment.

You only have a second before he turns his attention back towards you.

*temp renfri_in_fight false

*temp saving_renfri false

*choice
  #Help @{(RenfriRel >= 50) Renfri|Marshal} before Rook crushes her.
    *set RenfriRel %+ 15
    *set lisa_in_fight false
    *set renfri_in_fight true
    You dash towards @{(RenfriRel >= 50) Renfri|Marshal} and immediately kick the chains binding her, weakening them a little. You then proceed to 
    *if weapon = "knife"
      cut them apart with your dagger, 
    *else
      rip them apart with your bare hands, 
    breaking the links just a bit faster than they appear, until the Kinnari is able to fly up and away. She remains close enough to see @{(RookRel >= 50) Krill|Rook} and potentially to shoot him, but beyond the range of his projector.
    
    @{(LisaRel >= 50) Lisa|Hellhound} is not nearly as lucky. The thick chains are pressing on her from every direction, preventing movement and crushing ribs. You cannot hope that she'll break free, just that she won't get strangled to death within the next few minutes.
    
    *goto skip_marshal_death
  #Help @{(LisaRel >= 50) Lisa|Hellhound} before she's too tied-up for you to free.
    *set LisaRel %+ 15
    You dash towards @{(LisaRel >= 50) Lisa|Hellhound} and immediately kick the chains binding her, weakening them a little. You then proceed to 
    *if weapon = "knife"
      cut them apart with your dagger, 
    *else
      rip them apart with your bare hands, 
    breaking the links just a bit faster than they appear, until the werewolf is able to destroy the remaining ones and leap at @{(RookRel >= 50) Krill|Rook} with homicidal fury.
    
    It doesn't do much. The moment her claws scratch @{(RookRel >= 50) Krill|Rook}'s armor, the Vessel of Dusk simply backhands her with his left hand. This negligent blow is enough to send her flying back until she hits a wall, further damaging the power plant building as well as her own spine.
    
  #Attack Rook directly.
    *set Violence %+ 10
    *set lisa_in_fight false
    *label blade_attack
    *set boss_health - 1
    You pick up @{(LisaRel >= 50) Lisa|Hellhound}'s sword, a weapon she discarded right before transforming. You're not familiar with the vibro-blade but, given @{(RookRel >= 50) Krill|Rook}'s thick armor, you imagine it will be more effective than your 
    *if weapon = "knife"
      dagger. 
    *if weapon = "pistol"
      pistol. 
    *if weapon = "none"
      fists. 
    That hypothesis is proven correct as you run up to @{(RookRel >= 50) Krill|Rook} and drive the blade into him, penetrating armor and evoking a cry of pain.
    
    *if saving_renfri
      *return
    
    And yet, even impaled on a vibro-sword as he is, @{(RookRel >= 50) Krill|Rook} finishes wrapping the other two meta-humans in chains. They will be unable to help you from this point on.
    
    *goto skip_marshal_death
  #Do absolutely nothing.
    *set RenfriRel %- 15
    *set LisaRel %- 15
    *set lisa_in_fight false
    You allow both women to become fully wrapped in chains, taken out of the fight, neutralized. You're not sure why, but you don't really feel like doing anything.

@{(RookRel >= 50) Krill|Rook} then uses his hardlight projector to form a weapon, a spear, in his right hand. You suspect he'll turn towards you, or finally kill @{(LisaRel >= 50) Lisa|Hellhound} perhaps, but he faces @{(RenfriRel >= 50) Renfri|Marshal} instead. "I am sorry, Agent Riannon, but you are a threat to my ambitions, my new Federation, my… resolve. I cannot let you stop me, but I will have you die a hero's death. Just like you always wanted."

"Fuck… you…" @{(RenfriRel >= 50) Renfri|Marshal} replies. It's all she can say or do, courtesy of the chains crushing her windpipe, as @{(RookRel >= 50) Krill|Rook} prepares to throw. It's up to you to save her.

*temp silent_pc false

*choice
  #Attempt to catch the spear mid-flight.
    *set RenfriRel %+ 10
    *set LisaRel %+ 10
    You rush towards @{(RenfriRel >= 50) Renfri|Marshal} while keeping your eyes on the spear, watching @{(RookRel >= 50) Krill|Rook} throw it and preparing to catch it, and then it soars towards the Kinnari and you try to… 
    *if (Calculation > 45) and (Build > 45)
      catch it! It takes immense precision to grasp the shaft while its still in the air and great strength to pull it away, but you manage to grab the spear and save @{(RenfriRel >= 50) Renfri|Marshal}. You then break the weapon over your knee—@{(RookRel >= 50) Krill|Rook} can make himself a new one if he wants to.
      
      *goto skip_marshal_death
    *else
      you fail to catch it. You're just not fast enough, not it terms of running speed nor reflexes, and so the spear flies uninhibited.
  #Attack @{(RookRel >= 50) Krill|Rook} quickly.
    *set saving_renfri true
    *gosub blade_attack
    
    And yet… this doesn't prevent @{(RookRel >= 50) Krill|Rook} from making the throw. By the time he screams out, he has already let the spear go, and the weapon is already soaring through the air.
  #Shield @{(RenfriRel >= 50) Renfri|Marshal} with your own body.
    *set health - 1
    It's no use trying to catch the spear, but you cannot just let @{(RenfriRel >= 50) Renfri|Marshal} die. You'd rather do it yourself if you must. 
    
    You jump between @{(RenfriRel >= 50) Renfri|Marshal} and @{(RookRel >= 50) Krill|Rook} just as the latter lets go of his spear. The weapon soon transfixes your torso, sending a wave of pain washing over your body. The hardlight shaft is not stuck in your torso, having damaged your circulation systems greatly, tormenting your already broken body.
    
    *if Build < 60
      *set health - 1
    *if health < 1
      *set pc_dead true
      It's too much. It's way too much even for you to withstand. You fall to the ground, systems going out and vision going dark, only comforted by the knowledge that you did your best. You saved @{(RenfriRel >= 50) Renfri|Marshal} and maybe, just maybe, your sacrifice will help others take @{(RookRel >= 50) Krill|Rook} down. Perhaps they will get a happy ending, or at least something vaguely resembling one, some conclusion not filled with pain and tragedy.
      
      But you will never get to see that ending. You'll never know if the day has been saved. You just need to have faith as you let go of your life and float towards eternity.
      
      *finish
    
    And yet, you're still alive. You're able to, in spite of the pain, pull the spear out and then break it over your knee. You're not bleeding or writhing in agony, because you're not human—you are simply built different.
    
    *goto skip_marshal_death
  *selectable_if ((Projection + battery) > 110) #Evoke thunder powerful enough to knock the spear off the air.
    This is not an easy task. Only a small fraction of energy released in a discharge is converted into sound and kinetic momentum. But you are an expert at energy projection, and you're not afraid to prove your proficiency.
    
    You clap your hands, turning your whole body into a closed circuit through which energy can flow. The crack of electricity is so loud it does not merely deafen everyone in the city district, it can be felt like a gust of wind, like a shockwave that nearly throws @{(RookRel >= 50) Krill|Rook} himself off his feet. The spear is not quite blown away, but it is knocked off its course and hits a random spot on the pavement, rather the Kinnari it was aimed at.
  #Do nothing
    *set silent_pc true
    You do not react. Why bother to save someone who was always hostile towards you and your kind, always acted like an enemy even when you were technically allies? You just stand there and watch.


*set boss_will - 1

The spear impales @{(RenfriRel >= 50) Renfri|Marshal} as it hits her, entering her body through the chest and exiting through the skin of her back. You hear a whimper of agonizing pain, but no scream—the spear likely destroyed her lung, or perhaps the heart itself. She looks at Kirill, with some emotion you can't quite make out or even comprehend, then closes her almond eyes for what she knows is the last time.

Perhaps she's still alive, in some technical sense. It takes minutes for a human body, let alone a Kinnari body, to fully shut down after a fatal injury. But there is nobody who can heal her, not here nor anywhere else, no hope of recovery from a wound so severe. She's done for.

*page_break Dead

*set marshal_alive false
*set RenfriRel 1

*if silent_pc
  Marshal is dead. Gone from this world, having died a hero's death. It would be extremely tragic, if only you cared.
  
  *goto skip_marshal_death

"You really killed your 
*if Emotion > 50
  teammate," you say with barely-restrained fury and unrestrained contempt. 
*else
  teammate." Your voice is calm, but the accusation is clear. 
"Your friend. Possibly the only friend you've ever had."

"This is not what I wanted to happen," @{(RookRel >= 50) Krill|Rook} says heavily, perhaps even with some genuine regret. 
*if not (lisa_in_fight)
  *set boss_health - 1
  "But at least she can be with the-"
  
  A werewolf attacks @{(RookRel >= 50) Krill|Rook} with feral fury, chains broken and all restraint gone, swiping at him madly. He raises a hand to defend himself, but he has just thrown his weapon, and so he can only punch @{(LisaRel >= 50) Lisa|Hellhound} as she proceeds to rip and tear into his armor. When she realizes how much work it takes, that Dusk likely hardened @{(RookRel >= 50) Krill|Rook}'s exoskeleton, she instead scratches her leader's face, gashing his dark skin and spilling bright blood.
  
  @{(RookRel >= 50) Krill|Rook} screams with pain, and that scream seams to have power on its own. @{(LisaRel >= 50) Lisa|Hellhound} flies back, as though propelled by a shockwave, until she hits the wall and… keeps flying into the power plant, covered by upheaved dust and falling bricks, likely with a broken spine.
*else
  "But God knows it was necessary. He will forgive this bloody deed."
  
  "Sure." You look him in the eye. "But is it really his forgiveness you want?"


*label skip_marshal_death

*if team_stat = 2
  You hear heavy footsteps, then see Damon charge from the direction of the power plant, having finally climbed down. He's 
*if team_stat = 3
  Damon and Hadaly have finally managed to climb down and are now running towards @{(RookRel >= 50) Krill|Rook}. Damon is 
*if team_stat >1
  not shooting anymore—he must have figured that electron beams won't do much in this fight—and wields his rifle like a cudgel instead, hoping to hit @{(RookRel >= 50) Krill|Rook} with it. It's a valiant effort, but a wasted one—@{(RookRel >= 50) Krill|Rook} simply catches the rifle, pulls it aside, then knocks Damon out with a single well-placed punch.

*if team_stat = 3
  Hadaly has something heavier, that is her own hands and power. Once she's close enough, she simply throws her hands forwards and throws a lightning out of them, hitting @{(RookRel >= 50) Krill|Rook} in the chest. His armor conducts electricity well and you can see his face spasm, then become contorted with pain once he regains control of his muscles.
  
  *set boss_health - 1

"Enough of this," @{(RookRel >= 50) Krill|Rook} says with barely-restrained fury. "I have tested my new powers and increased my control. Let me show you."

@{(RookRel >= 50) Krill|Rook}'s armor starts glowing red as though superheated… not, it really is red-hot, and then it grows hotter still until it starts melting. Out of this molten metal a set of wings forms, not replacing arms like @{(RenfriRel >= 50) Renfri|Marshal}'s wings, but growing out of @{(RookRel >= 50) Krill|Rook}'s back. He's likening himself to an angel, or what humans imagine angels to be like, a winged human enthralled to a divine power. An angel of metal, an angel of death, an angel of Dusk.

*if lisa_in_fight
  *set boss_health - 1
  "What do you think?" He starts hovering a few decimeters off the ground, not actually using his wings, just the raw power Dusk granted him. "Do you see how futile resistance is? That nobody stands any chance against-"
  
  @{(LisaRel >= 50) Lisa|Hellhound} leaps at @{(RookRel >= 50) Krill|Rook} and thrusts her claws into the back of his armor. This hurts him, forcing a cry of pain out of his lips, but you realize it's just @{(LisaRel >= 50) Lisa|Hellhound}'s way of holding on to the flying enemy. He real weapon are the teeth with which she bites her former leader, tearing off chucks of his already weakened exoskeleton.
  
  @{(RookRel >= 50) Krill|Rook} struggles to reach the werewolf, to shake @{(LisaRel >= 50) Lisa|Hellhound} off him before she eats him alive, but he eventually manages to grab her by the paw and tear her off his mutilated body. He throws @{(LisaRel >= 50) Lisa|Hellhound} as far away from himself as he can, but refrains from attacking further—either he's scared of her, or simply got tired of fighting your defenders and wants to finally see the matter resolved.

He flies at you with incredible speed and grabs you before you're able to react. His gauntlet holds your throat tightly, and you while you cannot be strangled like this, you [i]can[/i] be lifted as the two of you rise towards heavens above.

*page_break Flight

*set health 1

You are an unwilling participant of this flight, like a mouse trapped in a buzzard's talons. @{(RookRel >= 50) Krill|Rook} flies up to the nearest skyscraper, smashes your face into its glass window, then drags you across the length of that glass. Sharp edges cut your face like daggers, likely flaying it by the time the torture is over. It's not a lethal injury, you don't bleed and don't even have that many processors in your head… but you imagine it makes you look more like the monster @{(RookRel >= 50) Krill|Rook} would like you to be, a creature straight out of a horror movie, one whose death won't significantly damage the meta-human's conscience.

A few seconds later, you're above that skyscraper, higher than any roof in the Sholmo City. And though a shard of glass damaged your left eye, you still see enough to struggle against your captor.

*temp resist true

*fake_choice
  #Kick.
    You kick @{(RookRel >= 50) Krill|Rook} and writhe in his arms, like a child being dragged away by its parent. 
    *if build > 70
      *goto some_damage
    *else
      *label no_effect
      Alas, to no effect—it's difficult to hurt an armored man like this, let alone an armored Vessel of Dusk.
  #Punch.
    Your hands are still free, and you use them to punch @{(RookRel >= 50) Krill|Rook} again and again. 
    *if build > 70
      *label some_damage
      Amazingly, you actually manage to inflict some damage this way, in spite of @{(RookRel >= 50) Krill|Rook}'s thick armor and tremendous power.
    *else
      *goto no_effect
  *if (weapon = "knife") and (weapon_av)
    #Stab.
      *set boss_health - 1
      You still have your dagger, and you make use of it by stabbing @{(RookRel >= 50) Krill|Rook} repeatedly. You draw blood, plenty of blood, before the meta-human finally uses his left hand to knock the weapon out of yours.
  *if (battery + Projection) > 100
    #Zap.
      *set boss_health - 1
      *set battery 5
      You allow your electricity to flow freely, from your body to @{(RookRel >= 50) Krill|Rook}'s armor. You can tell he feels it, for his hand closes around your throat even more tightly… which is admittedly a bit of a problem.
  *if (weapon = "pistol") and (weapon_av)
    #Shoot.
      *set boss_health - 1
      At this range, you cannot really miss. You press your pistol against @{(RookRel >= 50) Krill|Rook} chest and pull the trigger, penetrating his armor and likely wounding his heart. Still, he does not die, and even has enough strength to knock the pistol out of your hand.
  *if (Social > 50)
    #Talk.
      *set boss_will - 1
      "Is Dusk proud of you, Kirill?" You struggle to speak, and not because there's a hand around your throat. Every part of your body threatens to fall apart, and that includes the voicebox. "Does it give you praise your God never did? Does that erase the guilt you've felt for centuries now?"
      
      There is no response.
  #Do nothing.
    *set resist false
    There is no point, none at all. You just allow @{(RookRel >= 50) Krill|Rook} to take you higher and higher, as though finally rising to heaven after centuries of earthly torment. It's better this way.
  
Before you know it, you're more than three hundred meters above ground, twice as high as the tallest of buildings. You can see the Sholmo City in its entirety, and you see that it's not merely damaged or even ruined. It seems to be drowning in darkness, as though shadows became physical beings who went on to conquer the streets and railways, making it all glow with murk like other cities glow with light.

At that moment, you realize that 
*if resist
  resistance may very well be futile. 
*else
  you've done a smart thing by not resisting. 
For while @{(RookRel >= 50) Krill|Rook} can fly, and he can keep carrying you with him, nothing forces him to do that.

And you can't fly.

"Your existence is unnatural, a result of men playing gods," @{(RookRel >= 50) Krill|Rook} says as he looks at you, his cold blue eyes aimed at your optics. "I figured it would be appropriate to let a natural force, such as gravity, take care of you. Goodbye."

And then he lets go of you.

*page_break Fall

You spend perhaps ten seconds falling, propelled towards the inner surface of Rhea by the artificial anti-gravity of the World Engine. @{(RookRel >= 50) Krill|Rook} was, of course, full of shit—this force is nothing natural, just another result of 'men playing gods' as the Vessel himself put it. 
*if Misan > 50
  Just another example of how humans despoiled the Solar System.
*else
  Just another work of your creators.

You hit the road with enough momentum to crack the asphalt. You're lucky enough to do so legs-first, so the impact does not kill you on the spot… but it still hurts as hell. You feel like you went to hell, cast down by some vengeful angel as punishment for the sin of your existence.  

Speaking of the angel, @{(RookRel >= 50) Krill|Rook} descends back down, like rain or hail from the furious clouds. He is wielding a giant sword, not a mere hardlight construct, but an actual weapon of solid metal he somehow conjured up in an eye=blink. Or maybe this is an illusion, just like the iron halo above his head or concrete wyverns circling around him like a court of celestials. You don't know.

*if (boss_health <= 0) or (boss_will <= 0)
  *goto epic_flashback
*else
  "I was hoping you would die from this fall," @{(RookRel >= 50) Krill|Rook} says dispassionately as his boots touch the ground. "But I suppose I will have to do the honors myself. Not that it makes a difference."
  
  *fake_choice
    #"You won't... kill me. I still believe..."
      "You still believe in me?" @{(RookRel >= 50) Krill|Rook} looks at you sadly, and perhaps with pity. "Putting your faith in men is never a good idea… as you have just proven."
    #"I'm much... tougher... than that."
      *set Confid %+ 10
      "Not tough enough to defeat an angel," @{(RookRel >= 50) Krill|Rook} states calmly. "For what it is worth, I admire your defiance. And… I'm sorry."
    #"You still feel... guilt. Even now."
      *set RookRel %+ 10
      "You think too highly of me, ${fake_name}," @{(RookRel >= 50) Krill|Rook} says sadly. "Much too highly."
    #"Come on... End this."
      @{(RookRel >= 50) Krill|Rook} nods. "You may not think much of me, but I will not refuse you this mercy. Goodbye."
    #Say nothing.
      "Are you too damaged to speak?" @{(RookRel >= 50) Krill|Rook} wonders. "Or do you find speaking to me to be beneath your dignity?"
      
      You say nothing.
      
      He shrugs. "Very well. This does not make a difference either. Nothing will."
  
  @{(RookRel >= 50) Krill|Rook} raises his sword high, not like a warrior about to strike an opponent, but as an executioner delivering the killing blow. He knows you cannot fight back anymore, not against this angel of death, this psychopomp tasked with ending your life and delivering your soul to… whatever afterlife you're destined for. If any.
  
  You were too weak. Or perhaps, too foolish, too naive, too trusting… not that it makes a difference anymore. 
  *if crystal_stat = 1
    You will die and you've made peace with that fact long-
    
    *goto crystal_scene
  *else
    
    Not when @{(RookRel >= 50) Krill|Rook} separates your head from the rest of your body.
    
    *set pc_dead true
    
    *finish



*label rook_death

@{(RookRel >= 50) Krill|Rook} lies in the very bottom of the crater. He wouldn't be able to get up even if he were to suddenly regain consciousness—his power armor is now a metal prison, too heavy to move but too damaged to turn on. @{(RookRel >= 50) Krill|Rook} destroyed his own exoskeleton when he created those silly wings, two plates of cooling metal that now lay beside him, severed and useless. Without any dark aura around him, and without any threat of death looming over you, his whole angelic disguise seems silly rather than intimidating. A laughable pantomime, directed and performed by a third-grade jester. An act without talent, a role played without true passion.

*fake_choice
  #He put his faith in the wrong deity. He should have known better.
    *if master = "Jesus"
      God was always with him, with one of his last faithful followers. He should have trusted Christ, the Lord you both adored, rather than Dusk and its dishonest promises.
    *elseif Misan > 50
      His human religion never had any value. He worshiped an immaterial concept, an old fairy tale, rather than a palpable deity like yours. Now he knows how much his God is worth.
    *else
      He should have stayed faithful to his chosen creed, to the God he claimed to adore. Instead, he fell from grace and chose to become… this.
  #He used to be a great guy. A hero. What a shame he ended up like this.
    *set Misan %- 5
    There was always darkness within him, but he knew how to keep it in check. But when he decided to put all those Dusk nanites inside his body… he got mated, simple as that.
  #I pity him. I cannot hate him, I just feel pity.
    *set Emotion %+ 8
    @{(RookRel >= 50) Krill|Rook} was not an evil man, not really. He was just someone too weak to ever act on his convictions, too reliant on books to keep his human nature in check. You will not rejoice over his downfall, and you may even come to mourn it instead.
  #Everything about @{(RookRel >= 50) Krill|Rook} was always an act. He was just playing a good person.
    Isn't that what religion is? Pretending to be a good person? Telling yourself that prayers and faith will earn you a place in heaven? Maybe, maybe not, but @{(RookRel >= 50) Krill|Rook} just provided decent evidence for that hypothesis.
  #[Laugh at @{(RookRel >= 50) Krill|Rook} out loud]
    *set Misan %+ 5
    He was such a ridiculous character, a quixotic knight who couldn't even be bothered to leave his house and find windmills to fight. He just complained about the world, lectured everyone on morality, only to become a thrall of [i]Dusk[/i] the moment it seemed convenient. You laugh at the absurdity of his life, and at the irony of his final downfall.

You wonder what will happen once the Federation finds their meta-human sergeant like this, on the brink of death and full of Dusk, amidst the ruins he helped make. Will they show him clemency? Will they understand why he did all of this? Probably not. They'll probably just put him on ice or turn him into a test subject—on that matter, Dusk was almost assuredly correct.

*return

*label marshal

@{(RenfriRel >= 50) Renfri|Marshal} jumps out of the building and lands on the parking lot, ten or twenty meters away from you. She does not fly down, she simply jumps and lands, as though the fall means nothing to her. 
*if RenfriRel > 50
  Her expression is calm, as is her posture, as are her almond eyes.
  
  "For all it's worth, I'm sorry I have to do this." 
*else
  Her almond eyes are filled with cold fury as she regards you.
  
  "I should have killed you the moment we met." 
She takes a step towards you. 
*if (Emotion > 55) or (Confid < 45)
  You can't help but take a step back. 
*if RenfriRel > 50
  "You were a good companion. We had our good times, even managed to complete a mission together… But neither Dusk nor the Federation will accept me unless I kill you."
  
  *fake_choice
    #"You think the Federation will take you back after [i]this[/i]? You're delusional."
      "The Federation is full of pragmatists," Renfri retorts. "That's how our team got assembled in the first place. West will recognize my value, or some other admiral will, or-"
    #"You are playing with the fate of humanity. Please stop."
      *if Misan < 45
        *set boss_will - 1
        Renfri presses her lips into a thin line. "I can feel Dusk in my mind. It wants bloodshed, amusement, havoc. By providing these things, I'm making sure that it leaves humanity-" 
      *else
        Renfri shakes her head. "I'm in control of these nanobots, and I'm about to master them fully. And don't pretend you care about humanity, you duplicitous-"
    #"Is it you speaking? Or Dusk?"
      *goto renfri_dusk_speak
    #"Renfri, this is idiotic. We are friends, not enemies."
      *if Social > 50
        *set boss_will - 1
      "We are both," Renfri says heavily. "Friends and enemies, I mean. Neither of us wants to do this, but for the greater good-"
    *if official_ro = "renfri"
      #♡ "Renfri... please don't do this. I love you, and I know you love me in turn."
        *set boss_will - 1
        *set RenfriRel %+ 15
        "I do…" Renfri says in a slightly softer tone, then sighs. "But that doesn't matter. I have my mission, my duty, my ambitions, and I can't abandon them all for the sake of-"
    #Say nothing.
      *goto renfri_nothing
  
*else
  "Ignored my orders, ignored Kirill, simply killed you on that very street. It would have saved me the effort of having to do it now."
  
  *fake_choice
    #"What are you waiting for, then? Come at me."
      *set Confid %+ 15
      *set Violence %+ 10
      "Gladly." Marshal prepares to fly at you and you prepare to dodge. But then someone else joins the fray.
    #"Is it you speaking? Or Dusk?"
      *label renfri_dusk_speak
      *set boss_will - 1
      Marshal frowns, proving that you've scored a blow. "I am in control of my body. And besides, Dusk will have no reason to puppet me once I've proved my-
      *goto renfri_continue
    #"Calm down. Please. Wrestle those nanites under control and we'll take them out somehow."
      *set Violence %- 10
      *if Social > 50
        *set boss_will - 1
      "I am in control," Marshal says harshly. "And besides, I won't trust anyone else with that kind of-"
    #"You don't have to do anything. You can stop this madness at this instant."
      *set Violence %- 10
      *set Emotion %- 5
      *if Social > 60
        *set boss_will - 1
      "It only seems like madness from the outside," Marshal replies calmly. "I know what I'm doing. I just need to pass this-"
    *selectable_if (beat_trio) #"Like you would have managed that. I defeated your whole team, remember?"
      *set RenfriRel %- 10
      *set Confid %+ 10
      Marshal's eyes narrow. "You have spunk, I'll give you that much. But courage won't save you-"
    #Say nothing.
      *label renfri_nothing
      "Nothing to say?" @{(RenfriRel >= 50) Renfri|Marshal} sounds disappointed. "I suppose we'll fight silently until-"

*label renfri_continue

"Renfri!" @{(LisaRel >= 50) Lisa|Hellhound} shouts right before she hits the ground, having jumped out of the power plant much like her friend. Or perhaps former friend. "What are you doing, you stupid bitch!?"

"Lisa." @{(RenfriRel >= 50) Renfri|Marshal} turns towards the other woman. "That's not how you address your teammates. Much less ones who just acquired the key to ultimate power."

"Is that what you're about now?" @{(LisaRel >= 50) Lisa|Hellhound} growls. Her teeth and hair grow, as though she's finally prepared to shift. "You're just hungry for power? Power from the Thing Beneath?"

"Do not test me." @{(RenfriRel >= 50) Renfri|Marshal} warns, ignoring the question entirely. "I don't want to kill you. 
*if RenfriRel > 50
  I don't want to kill anyone here. 
But I will destroy you, should you force me to."

"Is that my punishment for refusing your advances?" @{(LisaRel >= 50) Lisa|Hellhound} smirks bitterly. "If so, go at it. Show me just how fun girl-on-girl action can be."

You can faintly hear @{(RenfriRel >= 50) Renfri|Marshal} gasp. And, though she's now facing away from you, you can almost see her scowl.

*temp person_talking false

*fake_choice
  #"Why don't you show her yourself, @{(LisaRel >= 50) Lisa|Hellhound}? Come on, rip that traitor apart."
    "I was hoping for some trash talk, some banter before the big fight… but maybe you're right." @{(LisaRel >= 50) Lisa|Hellhound}'s claws grow at a prodigious speed. "Maybe it's time to just… let a rip."
    
    *goto marshal_assembly
  #"Do not taunt her, @{(LisaRel >= 50) Lisa|Hellhound}. Hatred and rage will only empower her from this point on."
    *set person_talking true
    "Haven't they always?" @{(LisaRel >= 50) Lisa|Hellhound} sniggers. "Our avian friend is always angry, or bitter, or upset, or furious about some stupid-"
  *if (knows_about_crush = false) #"Huh. I didn't know you two almost become an item. Such a shame it didn't work out."
    *set person_talking true
    *if (Social > 60) or (official_ro = "lisa")
      *set boss_will - 1
  #Laugh openly.
    *if Social > 50
      *set boss_will - 1
  #Let them bicker.
    *set boss_will - 1
    "Did I upset you?" @{(LisaRel >= 50) Lisa|Hellhound} snickers. "Come on, don't frown at me, you're prettier when you smile. Not enough to magically make me like you, of course, but-"
  #Attack @{(RenfriRel >= 50) Renfri|Marshal} while her back is turned.
    *set boss_health - 1
    
    *if weapon = "pistol"
      You shoot her in the back, or rather in the back of her left wing. The 
      *if (wpr = "electron") or (wpr = "laser")
        beam 
      *else
        bullet 
      goes right through it, implying that @{(RenfriRel >= 50) Renfri|Marshal}'s durability was not boosted all that much… but her resistance to pain definitely was, for the Kinnari barely notices your shot, or the gaping wound she now bears.
      
      *goto shadow_shadow
    *elseif weapon = "knife"
      *set weapon_av false
      Were you any closer, you'd stab her in the back, but the distance is still short enough for a well-aimed dagger throw. The knife hits the back of @{(RenfriRel >= 50) Renfri|Marshal}'s left wing blade-first, transfixing it easily… but the Kinnari seems to barely notice the gaping wound in her wing, as though her pain stopped sending signals to the brain and only serve to power the nanobots inside.
      
      *label shadow_shadow
      
      Oh well. With any luck, this should still impede her flight, even without causing any pain. Give you a shadow of a chance against this puppet of the… Shadow.
    *else
      *set battery - 8
      You don't feel like running up to @{(RenfriRel >= 50) Renfri|Marshal} and punching her, so you simply shock her with your trademark lightning. She hisses in pain as her skin burns, 
      *if Projection > 55
        proving that Dusk hasn't significantly boosted her durability… yet. 
      *else
        but doesn't appear nearly as hurt as she should be—it will take a much larger voltage, or a different attack entirely, to seriously wound this carrier of Dusk.
    
    *goto marshal_assembly

"Shut up!" @{(RenfriRel >= 50) Renfri|Marshal} demands. "You're all thieves! You stole [i]my[/i] kill, Kirill stole [i]my[/i] glory, and now you want [i]my[/i] power that I earned! I'm not a freak like you, I served the Federation loyally, I deserve-"

*if (RenfriRel > 60) or (Confid < 40)
  *set person_talking false

"Is that all you're about now?" 
*if person_talking
  you ask contemptuously. "Screaming about how much you deserve this and that? 
  *if heaven_side = "Loyalist"
    I've saved humanity from extinction, 
  *else
    I've suffered more than you ever will, 
  and yet I'm not whining about the things I deserve. I am the Veteran, you're just a child throwing a tantrum."
*else
  @{(LisaRel >= 50) Lisa|Hellhound} asks with a sort of… bitter contempt. "Screaming like an entitled child? I got dragged into that mess with a bomb in my heart, and you can't get over… stolen credit? Grow the fuck up." 

@{(RenfriRel >= 50) Renfri|Marshal} grits her teeth. "Fine. If you insist on rejecting me… my mercy… then I will easily slay you both." She raises her head, not just to appear mighty and proud, but also to look at the exposed boiler room above. "Or however many of you I'll have to fight."

*label marshal_assembly

With more caution than the two women, @{(RookRel >= 50) Krill|Rook} 
*if team_stat = 1
  descends 
*else
  and Damon descend 
from the second floor and join you on the ground. @{(RenfriRel >= 50) Renfri|Marshal} is surrounded and outnumbered, but you don't imagine it will matter very much. An aura of dark power surrounds her, faint but unmistakable, the same might that emanated from Crystal except several times greater. It seems to be growing too, while the World Engine above you only gets dimmer. You'll have to win this battle quickly, before your allies run out strength and before the Vessel grows all-powerful in turn.

"I sense evil within you, and I suspect you've accepted it willingly." @{(RookRel >= 50) Krill|Rook} walks towards his subordinate cautiously, but without much fear. "What have you done?"

"What was necessary," @{(RenfriRel >= 50) Renfri|Marshal} retorts. "I'd tell you to stay out of my way, but I know it's pointless. You're too much of a martyr to not make me kill you, Kirill."

*if team_stat = 3
  *label hadaly_climb
  You briefly look towards the exposed boiler room and see Hadaly start climbing down. She's not as tough as the others, so she can't just jump down safely. It will be a moment before she can join the battle… assuming she even intends to do so.


*fake_choice
  *if team_stat > 1
    #"Damon... please run. This is dangerous, and I don't want you to die for me."
      "Sorry, ${name_damon}, but this is far bigger than you." Damon smiles bitterly. 
      *if hadaly_free
        "We just created the strongest Dusk Vessel to date. We have a duty to take it down, all of us, together."
      *else
        "Besides… I failed one android today. I don't intend to let another one die."
      
      "Humans and androids, fighting side-by-side for a common cause," @{(RookRel >= 50) Krill|Rook} comments. "This was enough to kill a diamond wyvern. Do you expect to do any better, Agent Riannon?"
  #"Back down, @{(RookRel >= 50) Krill|Rook}. The situation is under control."
    *set RookRel %- 10
    "That is clearly a lie," @{(RookRel >= 50) Krill|Rook} retorts. "We need all the hands we can get. Besides… this is my fight more than yours."
  #"Show no mercy, @{(RookRel >= 50) Krill|Rook}. Your friend is beyond saving."
    *set Violence %+ 5
    *set Misan %+ 5
    "I believe everyone capable of receiving salvation," @{(RookRel >= 50) Krill|Rook} states wisely. "But I won't hold back. Not with the entire Solar System on the line."
  #"I hate to say that, but she has a point."
    *set RookRel %- 10
    "What point?" @{(RookRel >= 50) Krill|Rook} snaps. "That I'm willing to die for the greater… for the sake of the Solar System? I don't think that's an insult you view it as."
  #"You really intend to kill your friend and leader? Disgusting."
    *set RookRel %+ 10
    *if Social > 55
      *set boss_will - 1
    "She barely acknowledged my authority at the best of times," @{(RookRel >= 50) Krill|Rook} says bitterly. "As for us being friends… no. Not anymore."
  #Say nothing.

"Very well, then…" @{(RenfriRel >= 50) Renfri|Marshal} exhales deeply. "I know what your powers can do to nanites. I know they can affect even Dusk. I'll take care of you first."

She then flaps her wings with tremendous speed, but does not fly up. Instead, @{(RookRel >= 50) Krill|Rook} is lifted into the air, falling towards the sky as though gravity around him has been completely reversed. Only when he's high in the air, thirty or forty meters above ground, does @{(RenfriRel >= 50) Renfri|Marshal} herself take flight.

*if weapon = "pistol"
  *if ((wpr = "laser") or (wpr = "gyrojet")) or (wpr = "rail")
    *set boss_health - 1
    You manage to shoot her as she flies away. The 
    *if wpr = "laser"
      beam 
    *else
      bullet 
    doesn't do much damage, but you can easily keep blasting—your pistol was designed for large distances, and there is literally no cover for @{(RenfriRel >= 50) Renfri|Marshal} to hide behind. You might even be able to end this battle with a single headshot, though that hope feels admittedly forlorn.
  *elseif Calculation > 60
    *set boss_health - 1
    You manage to wound her once with a well-placed shot, but she soon becomes too distant and starts moving too fast for you to aim at, let alone hit. Your ${wpr} pistol simply wasn't made with large distances in mind, and even your amazing aim is not enough to alleviate that limitation.
  *else
    You try to shoot her, but you miss by almost a meter. A second later, she's way too far to hit, especially with your  ${wpr} pistol and sub-standard aim. For the moment being, you are out of this fight.

After several seconds, @{(RookRel >= 50) Krill|Rook} stops falling and simply levitates high above. Perhaps he's being held in place by @{(RenfriRel >= 50) Renfri|Marshal}'s powers, or perhaps he's using some function of his power armor to keep himself from falling back down. Either way, he's now a stationary target for @{(RenfriRel >= 50) Renfri|Marshal}, who flies at him like an eagle towards a tasty pigeon.

@{(RookRel >= 50) Krill|Rook} uses his hardlight projector to form himself a spiked shield. His opponent changes her trajectory, not wanting to slam into the spikes, but the near-transparent shield does nothing to block the laser beam @{(RenfriRel >= 50) Renfri|Marshal} shoots at @{(RookRel >= 50) Krill|Rook} a moment later. It's a blue beam, one of extremely high frequency, and it immediately causes one of the plates of @{(RookRel >= 50) Krill|Rook}'s armor to start melting.

*if team_stat = 2
  *set boss_health - 1
  The Kinnari is about to swoop again, but then she yells as something invisible appears to pierce her wing. You look at Damon and, as expected, you see him aim his electron rifle upwards. Though it's easy to forget, Damon is a rather good marksman, and this is a perfect opportunity for him to show his skills off.
*if team_stat = 3
  Hadaly finally manages to get down. Damon moves towards her, as though guided by protective instinct, but that just places him further away from @{(RenfriRel >= 50) Renfri|Marshal} and distracts him from the fight above. As much as you hate to admit that, even in your own thoughts, Hadaly's presence here is detrimental to your efforts.

"Huh. I was hoping she'd stay on the ground, letting us actually fight her," @{(LisaRel >= 50) Lisa|Hellhound} comments as she looks up. "Though maybe that's for the best."

*fake_choice
  #"I don't like where you're going with this..."
  #"Interesting. Please elaborate."
    *set Emotion %- 8
    *set LisaRel %+ 8
  #"How? How is her splitting our team a good thing?"
  #"No it's not! She'll kill Kirill unless we do something."
    *set Emotion %+ 8
    *set LisaRel %- 8
  #Raise an eyebrow silently.
    *set Emotion %- 8

"Look… Renfri was kinda right about Kirill wanting to be a martyr," @{(LisaRel >= 50) Lisa|Hellhound} explains hesitantly. "He would… he will gladly die to slow her down. In the meantime, 

"You were goading Marshal into a fight just seconds ago," 
*if team_stat = 1
  you point 
*if team_stat = 2
  Damon points 
*if team_stat = 3
  Hadaly points 
out irritably. "What made you change your mind?"

"I was hoping she'd see reason, or lose her temper and allow me to knock her out easily." @{(LisaRel >= 50) Lisa|Hellhound} looks towards @{(RenfriRel >= 50) Renfri|Marshal} and @{(RookRel >= 50) Krill|Rook} sadly. They are still fighting, yelling something you can't quite make out, but it's clear that @{(RookRel >= 50) Krill|Rook} is getting gradually weaker. "But if she's going all out… I'm not sure if I want to fight. I don't think I want to kill her."


*choice
  #"Lisa please. We cannot do this without you."
    *if LisaRel > 50
      "If anyone else begged me for help like this, I would have told them to fuck off," Lisa remarks. Then sighs. 
      *if official_ro = "lisa"
        "But I did fall in love with you and I'm not about to rise up. 
      *else
        "But you've been a good friend to me. Better than Renfri, apparently. 
      So sure, let's do this together."
    *else
      "If you cannot do it without me, then you probably won't win even if I help you," Hellhound says morosely. "You can die here if you want, but don't expect my company. This is your problem."
      
      *goto starts_running
    
  #"We are doing it for her own good. That thing inside her... being its host is a fate worse than death."
    "And that means I should help you kill her?" @{(LisaRel >= 50) Lisa|Hellhound} asks grimly. "Put a bullet in my teammate's head?"
    
    "I'd rather avoid that, but…" You shudder. You don't fake it, like you do with most body language, actually shudder. "You have no idea what we're going up against. I'm not just trying to survive, I'm trying to save everyone from the Thing Beneath. Your teammate most of all."
    
    @{(LisaRel >= 50) Lisa|Hellhound} clenches her fists, drawing a bit of blood with her sharp claws. "I don't really care about saving the world… but if being Dusk's carrier is as bad as you say, then I deserve some vengeance for Renfri. So I guess I'll take that revenge, even if it means killing… fuck."
    
  #"Do you still have Da-xia's pistol? Just pick it up and start shooting."
    *set Violence %+ 8
    @{(LisaRel >= 50) Lisa|Hellhound} frowns. "I don't think you're listening to me very hard. I said-"
    
    "You couldn't hit her even if you tried," you interrupt. "And you certainly won't kill her. Just start blasting as a distraction, give @{(RookRel >= 50) Krill|Rook} a bit of an advantage."
    
    *if Social < 55
      @{(LisaRel >= 50) Lisa|Hellhound} shakes her head. "Sorry. I like ripping things apart, but putting a bullet inside my former friend… Do it yourself if you want to, because I'm out."
      
      *goto starts_running
    
    *set boss_will - 1
    
    @{(LisaRel >= 50) Lisa|Hellhound} looks like she's about to argue, but in a rare display of obedience, she raises the pistol and starts firing at the sky. Like you said, her poor aim doesn't exactly matter—as long as she makes sure not to hit @{(RookRel >= 50) Krill|Rook}, her shots are just one more thing for the Kinnari to worry about.
  #"You'd just leave? Let your leader fight a Dusk Vessel alone? You're selfish."
    *set LisaRel %- 10
    @{(LisaRel >= 50) Lisa|Hellhound}'s eyes narrow. "Are you hoping to shame me into helping you? Forget it. I've heard worse insult and I don't owe [i]anything[/i] to Kirill. Or you, for that matter."
    
    *label starts_running
    
    *set lisa_in_fight false
    
    Before you can reply, let alone attempt to catch her, @{(LisaRel >= 50) Lisa|Hellhound} turns around and starts running. She flees towards the city center, likely hoping to find some ruin where she can lay low, safe both from @{(RenfriRel >= 50) Renfri|Marshal} and anyone else who'd pursue her. 
    *if LisaRel > 50
      You wish her the best of it.
    *else
      Cowardly dog…
  #"You can flee if you want. But don't expect me to do same."
    *set lisa_in_fight false
    *set LisaRel %+ 20
    "I will not," @{(LisaRel >= 50) Lisa|Hellhound} replies softly. "If anything, I admire your willingness to… Good luck."
    
    She disappears right afterwards, dashing towards a nearby side alley. A few minutes from now, she will be out of the city, and she'll eventually manage to leave Rhea altogether. Good for her, you suppose.
  #"We will not have to kill her. I promise."
    *set Violence %- 8
    "How so?" @{(LisaRel >= 50) Lisa|Hellhound} looks at you skeptically. "Either we die or she does. Can you see any other possible ending?"
    
    "We can try to talk her down, or tire her enough to apprehend her," you argue your case. "We sort of [i]have[/i] to do that. Her death will cause the nanobots to spill out, and then they'll just look for another Vessel. I wouldn't be surprised if that's what Dusk is hoping for."
    
    "You sure can be convincing when you try…" @{(LisaRel >= 50) Lisa|Hellhound} sighs deeply. "So fine. I'll help you in whatever way I can, just… don't expect much."
  #"You know what... you're right. Let's @{(team_stat > 1) all|both} get out of here and go into hiding."
    *set vessel_at_loose true
    *set rook_alive false
    *set TrioStat "broken"
    *set LisaRel %+ 10
    @{(LisaRel >= 50) Lisa|Hellhound} smiles broadly. "I knew I could count on you to see reason. 
    *if official_ro = "lisa"
      I wouldn't have hooked up with you otherwise. 
    *elseif LisaRel > 55
      You were always cool like that. 
    *else
      For once in your life. 
    Now let's get out of here before Renfri realizes what's up."
    
    *if team_stat = 3
      "And here I though we were going to fight until the bitter end…" Hadaly sighs in a strange, wistful tone. "But I agree. Let's run."
    
    You run towards the city center, away from the power plant and the two meta-humans. @{(RookRel >= 50) Krill|Rook} can die if he wants—you still have a few years left to live, assuming you can evade @{(RenfriRel >= 50) Renfri|Marshal}'s pursuit.
    
    And possibly other pursuits. Because, as you realize while disappearing in a side alley, you've likely made yourself [i]many[/i] enemies today.
    
    *finish

You hear something inarticulate, some odd yet terrifying sound, and then @{(RookRel >= 50) Krill|Rook} falls back on the ground. His fall is harder than gravity should allow, faster than ten meters per second squared, leading you to think @{(RenfriRel >= 50) Renfri|Marshal} used her powers to slam him into the asphalt, bury him in the road. He now lies in a frighteningly deep crater, likely alive, but you don't suppose his power armor is still functioning… or that his bones are all intact.

@{(RenfriRel >= 50) Renfri|Marshal} descends a little too, but keeps hovering about ten meters off the ground. The laser disc on her forehead is glowing blue, almost purple, about to fire one last laser beam. Supine, unable to raise a shield and with his armor partially melted off, @{(RookRel >= 50) Krill|Rook} is an easy target. He will die unless someone interferes quickly.

*choice
  #Strike @{(RenfriRel >= 50) Renfri|Marshal} with lightning.
    *if (Projection + battery) > 100
      *set battery - 8
      *if (Projection + battery) > 110
        *set boss_health - 1
      Having used your battery sparingly up to this point, you're able to conjure up a powerful blast which knocks @{(RenfriRel >= 50) Renfri|Marshal} off the air. A smell of roasted chicken fills the air, you imagine, as the Kinnari hits the ground on the edge of the crater.
    *else
      You try to muster enough energy for an attack… but cannot. You're too tired, or perhaps too weak in general. @{(RenfriRel >= 50) Renfri|Marshal}, on the other hand, is perfectly able to charge her ultimate attack, uninhibited and uninterrupted.
      
      *goto marshal_kills_rook
  #Jump at @{(RenfriRel >= 50) Renfri|Marshal} and tackle her.
    *if (Build + (health*10)) > 80
      *if (Build + (health*10)) > 100
        *set boss_health - 1
      You manage to jump high into the air and collide with @{(RenfriRel >= 50) Renfri|Marshal}. You don't quite manage to tackle her, she kicks you away mid-flight, but you've definitely managed to distract her. @{(RookRel >= 50) Krill|Rook} will live for another day… or at least until @{(RenfriRel >= 50) Renfri|Marshal} kills the rest of you.
    *else
      You try to do that. You try to leap at her, grapple her and perhaps end this whole debacle by strangling her to death… but you're too tired and frail for any of that. Your jump is only two meters long and perhaps half as tall, and so @{(RenfriRel >= 50) Renfri|Marshal} is able to attack unopposed.
      
      *goto marshal_kills_rook
  *if weapon = "pistol"
    #Shoot @{(RenfriRel >= 50) Renfri|Marshal} with your pistol.
      *set weapon_av false
      You raise your pistol and almost manage to fire, but @{(RenfriRel >= 50) Renfri|Marshal} recognizes the danger. She moves her wing slightly, altering the gravity just enough for you to lose your footing, for the 
      *if (wpr = "laser") or (wpr = "electron")
        beam 
      *else
        bullet 
      to miss completely and simply fly towards the World Engine above.
      
      *goto marshal_kills_rook
  *if (weapon = "knife") and (weapon_av)
    #Throw a knife at @{(RenfriRel >= 50) Renfri|Marshal}.
      It's not difficult to aim your throw at this distance, nor to toss your dagger high enough to hit @{(RenfriRel >= 50) Renfri|Marshal} in one of her wings. It only hits with the hilt, 
      *if ((wpm = "plasma") or (wpm = "bone")) or (wpm = "power")
        *set boss_health - 1
        but still wounds the caramel wing and brings the Kinnari's 
      *else
        but that's enough to distract the Kinnari, turn her 
      attention back towards the ground.
  *selectable_if (team_stat != 1) #"Damon! Do something!"
    Damon nods, 
    *label d_inter
    *set boss_health - 1
    then shoots @{(RenfriRel >= 50) Renfri|Marshal} with his electron rifle. It's well-placed shot, one that likely went straight through her heart or at least a lung… but though she cries out in pain, the Kinnari proves durable enough to keep hovering and charge her laser disc to its maximum power.
    
    *goto marshal_kills_rook
  *selectable_if (team_stat = 3) #"Hadaly! Do something!"
    Hadaly nods, then throws her hands up and 
    *label h_inter
    lets out a powerful discharge which strikes @{(RenfriRel >= 50) Renfri|Marshal} like lightning, and with almost the same power. Despite her natural toughness and unnatural power, the Kinnari falls to the ground, impacting the asphalt on the edge of the crater.
    
    *if HadalyRel > 70
      *set boss_health - 1
    
    "You…" @{(RenfriRel >= 50) Renfri|Marshal} groans with what you hope is pain. "What happened to your pacifism? To being afraid of picking a fight with me?"
    
    "I was never afraid of you," Hadaly says coldly as her hands heat up again. "I was just tolerating you for my friends' sake. And now, I will kill you for their-"
  #Do nothing.
    *if team_stat = 3
      You refuse to interfere… but Hadaly does not. She 
      *goto h_inter
    *if team_stat = 2
      Not everybody chooses to abstain from action. Damon notices what's happening, 
      *goto d_inter
    
    There is nothing you can do, and there nobody else who can reach @{(RenfriRel >= 50) Renfri|Marshal} at this height. She is able to charge her laser disc fully, then unleash its power in the form of a single electromagnetic wave.
    
    *label marshal_kills_rook
    
    And then she kills @{(RookRel >= 50) Krill|Rook}.
    
    *set rook_alive false
    *set boss_will - 1
    
    There is no doubt about that, not as the flash of purple light blinds you, not as far more concentrated light of a purple laser shines down on Kirill Kosteniuk. When you look into the crater again, you only see a cross-shaped puddle of molten metal, liquid titanium and lead slowly filling the cracks in the street. A saturnine mixture slightly reddened by blood is all that remains of the Meta Trio's leader.
    
    *page_break It Is Finished
    
    "I did not want this… but he very much did," @{(RenfriRel >= 50) Renfri|Marshal} says as she descends. There is sadness in her voice, but precious little guilt or regret. "He died a martyr. His god will surely appreciate the gesture."

*if team_stat = 3
  @{(RenfriRel >= 50) Renfri|Marshal} then flaps her wings horizontally, sending a force wave orthogonally to actual gravity. The current sends everything in front of her flying along the street, and that includes the lightweight android known as Hadaly. You see your fellow robot fly through the air before impacting the wall of a faraway building, strong enough to crack that concrete wall, though hopefully not enough to kill her.
  
  Nonetheless, she's out of the fight, too far away to help you now. She may not have been the most experienced of fighters, but to see a young android to get flung away just like that… 
  *if Emotion > 50
    unnerves you a little.
  *else
    It does not fill you with confidence.

*if lisa_in_fight
  *set boss_health - 1
  *set boss_will - 1
  You notice @{(LisaRel >= 50) Lisa|Hellhound} is in her lupine form, apparently having shifted when you were focused on the others. You notice that as she dashes towards @{(RenfriRel >= 50) Renfri|Marshal} and swipes her claws at her former friend. The Kinnari evades the strike, but not its immediate follow-up, and so another set of claws tears through her armor and rends the skin of her chest.
  
  @{(RenfriRel >= 50) Renfri|Marshal} cries out in pain, and that sound causes @{(LisaRel >= 50) Lisa|Hellhound} to hesitate. Not for long, not even for a full second, but long enough for the Kinnari to focus her gravitic powers again. She sends the werewolf flying backwards and up, back towards the power plant and into one of the building's walls. For all her strength, @{(LisaRel >= 50) Lisa|Hellhound} cannot do anything to keep herself from crashing into the bricks, likely cracking the wall as well as her spine.


*if team_stat > 1
  Damon charges @{(RenfriRel >= 50) Renfri|Marshal} with bare fists, likely having ran out of charges, but after another flap of caramel wings, he just sort of… flies up. He's flung towards the sky like @{(RookRel >= 50) Krill|Rook} before him, except with greater power and thus greater velocity. 
  
  Luckily for him, @{(RenfriRel >= 50) Renfri|Marshal} does not appear interested in attacking further like she did against @{(RookRel >= 50) Krill|Rook}. Once he runs out of vertical momentum, Damon will simply fall back down. Even if he survives—and he likely will, given how tough he is—he will not be the Vessel's main target.
  
  You are.

@{(RenfriRel >= 50) Renfri|Marshal} looks at you with murderous intent. 
*if (boss_health < 2) and (boss_will < 2)
  Over the last minute, you were able to wound both her will and her body, and yet she still stands. 
*elseif (boss_health < 2)
  Her wings are bloodied and her body is bruised, but her spirit is strong and corrupted by Dusk. 
*elseif (boss_will < 2)
  It waivers, you can tell she's conflicted and that you've damaged her resolve… and yet she still stands. 
*else
  You failed to injure her and you failed to weaken her resolve. You are screwed. 
"Now it's just the two of us. Let's see who's stronger now, shall we?"

*page_break

*label staredown

The two of you stand on a destroyed street, next to a destroyed power plant, in the middle of a destroyed city. Staring one another down, a Kinnari looking at an android and [i]vice versa[/i]. If it wasn't clear before, it is now—one of you must kill the other.

At first, you wonder why @{(RenfriRel >= 50) Renfri|Marshal} won't attack, but then you see her body change. You see it mutate. Her wings grow in size and grow paler, her feet grow razor-sharp talons, her eyes become filled with dark potency. She looks less like a Kinnari and more like a harpy, a cruel queen of the skies, a monster Dusk sent to torment you like Zeus once tormented old Phineus.

Even now, with her task of killing you not yet completed, Dusk is granting @{(RenfriRel >= 50) Renfri|Marshal} strength. Granting her power. You need to make your move now, if you want to 
*if Confid > 50
  stand a chance of winning.
*else
  prolong the inevitable.

*choice
  #Punch her in the face.
    You swing at @{(RenfriRel >= 50) Renfri|Marshal} with your fist. She sidesteps the punch. "Really? You're still using your fists at this level? Start treating the situation seriously, please."
  *if (weapon = "knife") and (weapon_av)
    #Walk up to her and stab her.
      Approaching @{(RenfriRel >= 50) Renfri|Marshal} feels like swimming against the current. It's as though she has her own gravity field which works in reverse, pushing everything with mass away instead of attracting it. 
      *if Build > 60
        Nonetheless, you manage to push through and stab her, putting about two centimeters of your knife into her torso.
        
        *set boss_health - 1
        
        "Not bad," she comments indifferently. "But I can do better."
      *else
        In the end, you're not strong enough to reach her, let alone stab her with your dagger.
  *if (weapon = "pistol") and (weapon_av)
    #Shoot her repeatedly.
      *if ((wpr = "electron") or (wpr = "shroom")) or (wpr = "plasma")
        *set boss_health - 1
        You're at close range, wielding one of the most powerful pistols in production. @{(RenfriRel >= 50) Renfri|Marshal} seems to only realize that once three 
        *if (wpr = "plasma")
          balls of plasma 
        *if (wpr = "shroom")
          shrooms 
        *if (wpr = "electron")
          electron beams 
        have already entered her body, though she reacts quickly enough.
      *else
        Your ${wpr} pistol has an excellent effective range, but the same can't be said about its actual damage output. @{(RenfriRel >= 50) Renfri|Marshal} seems to barely feel your shots, her monstrous body more than strong enough to withstand them, as she calmly makes her move.
  #Attack with electricity.
    *if (Projection + battery) > 100
      *set battery - 8
      *set boss_health - 1
      Miraculously enough, you still have some energy left. You concentrate it and channel it into @{(RenfriRel >= 50) Renfri|Marshal}'s body, scorching her feathers and burning what little exposed skin she has.
      
      "I actually felt it," she says unsympathetically. "Let me repay in kind."
    *else
      You try to shock her, but you just… can't. You lack power, and not just of the electrical kind. You're just so damn tired…
      
      "You're getting older," @{(RenfriRel >= 50) Renfri|Marshal} comments ruthlessly. "Let me put you out of your misery."
  #Plead with her.
    "Renfri…" you say quietly, knowing she'll hear you all the same. 
    *if (Social + RenfriRel) > 110
      *set boss_will - 1
      "I know this isn't what you wanted. You dreamed of being a hero, not a villain or… mere tool for the Thing Beneath. Please wake up."
      
      "I dreamed of greatness," Renfri says weakly. "What I'm doing right now… is certainly a form of greatness. So I'll just take what I can get."
    *else
      "What you're doing is wrong. You can see just how evil it is, I know you can, so please-"
      
      "You've never had a way with words," Renfri comments coldly. "At least not when it came to me. You won't sway me from my path."
      
She sends you flying backwards. She does so without flapping her wings, without moving any part of her monstrous body, as though she learned how to evoke her powers with mere thoughts. You collide with a nearby lamppost, feeling a wave of pain wash over your 
*if health < 3
  already damaged 
*else
  *set health - 1
body.

You get no time to recover, or even to analyze the situation, before being lifted off your feet again. This time, you're not picked up through telekinesis or reversed gravity, but by a gust of wind rivaling the hurricanes of Saturn itself. It's as though @{(RenfriRel >= 50) Renfri|Marshal} stopped fighting you and instead contracted the elements themselves to finish you off, like some ancient goddess of wind and storms.

You crash into an automobile, denting its door and your spine with the momentum of impact. You are then lifted up again, cold wind blowing out of the floor somehow, ten and twenty meters into the air. You brace for a painful fall, but are instead pulled into some vortex, some tornado of which @{(RenfriRel >= 50) Renfri|Marshal} is the center. She is the eye of the cyclone, the field marshal of this growing cataclysm, a tool for calamity, the end and the death, a ravenous shrike whose prey is existence itself.

You are tossed around like a rag doll, like a feather in the wind, like a sphere during an ancient game of volleyball. Any pretense of a fight, let alone a fight between equals, is long over. You're hardly even being toyed with—the arctic hurricane treats you much like all the rubble and shattered glass it lifts, like an inanimate object caught up in a disaster it cannot hope to influence.

*page_break Pain

*if ((boss_health <= 0) or (boss_will <= 0)) and ((rook_alive) or (lisa_in_fight))
  *goto epic_flashback

You are tossed through a glass window of an office building. You are dragged through a cobblestone street. Objects collide with you and you with them, breaking you in more ways that you thought possible. You can barely feel your legs and your arms are nothing but bent, torn, defunct appendages. 

Once it's clear that you can no longer fight, @{(RenfriRel >= 50) Renfri|Marshal} lets you down. She does not recall the winds of destruction, of course—she merely expands the storm's eye, including you in this space of tranquility, but also enlarges the hurricane itself. Ten minutes, perhaps half an hour of this disaster, and not a single building in the Sholmo City will be left standing. You doubt there will be any survivors either… and you most certainly won't be one of them.

The Kinnari lands, as though wishing to meet your gaze one last time. Her body is mutated and monstrous, a terrifying harpy with wings wide as those of a plane, but her eyes have not changed. They are still the same shade of almond brown, beautiful gems which inexplicably adorn a horrifying bronze statue.

"This is it," she states serenely, but not without emotion. There is regret in her voice, or at least sadness, or at least a kind of… nostalgia. "The place where you die. I think it's the street where we first met, isn't it?"

It could be. The city is too destroyed to tell for certain, but you're close to a building which could have once been the corporate bank. Perhaps fate has a sense of humor… or perhaps Dusk has.

"Don't worry, I will make this quick." @{(RenfriRel >= 50) Renfri|Marshal} charges up her laser disc, the little thing still on her forehead. "I will even let you get some last words in, if that's what you want. Say whatever you want."

*fake_choice
  #"Please... spare me. Please."
    "We both know I'm not allowed to do that," @{(RenfriRel >= 50) Renfri|Marshal} sighs. She looks reluctant, but not hesitant to finish you off. "Dusk sees you as an obstacle, but even more importantly… you're an android. Federate law says you must die, and I serve Saturn as loyally as ever."
  #"Why? Just... why?"
    "Because I have a destiny to fulfill," @{(RenfriRel >= 50) Renfri|Marshal} explains calmly. "And if Dusk is the only road to that destiny, if that road has to go over your grave… I'm sorry, but there's really no other way."
  #"I wait for you. And forgive you."
    "Are you promising to wait for me in the afterlife?" @{(RenfriRel >= 50) Renfri|Marshal} tilts her head. "I don't think you're going to get any… but thank you, I suppose."
  #Say nothing.
    "Defiant to the end, are we?" @{(RenfriRel >= 50) Renfri|Marshal} sounds ever-so-slightly impressed. "Very well. I'll let you die in silence."

You can almost feel her headband heat up, ready to fire a laser. It glows red, then yellow, then green and then blue. One powerful shot, enough to kill even a robot like you instantly, one ray of light to grant you an eternity of darkness.

*if crystal_stat = 1
  *goto crystal_scene
*else
  *set pc_dead true
  
  And then she fires. You can briefly feel the laser melt through your metal skull, but the burning sensation doesn't have the time to turn into genuine pain. Molten metal fills your interior and swiftly destroys your processors, hard drives, personality banks, everything that makes… made you who you are.
  
  Eternity begins.
  
  *finish


*label marshal_death

@{(RenfriRel >= 50) Renfri|Marshal}'s body has mostly reverted to its natural, Kinnari form. No talons, just bare feet, and only her usual wings serving as the other set of limbs. The power she betrayed everything to acquire has failed her—when the Federation finds her, they'll see a failure of an agent, a living proof that they were always right not to trust this immigrant with any kind of authority.

*fake_choice
  #I wonder if the Federation will find her. I wonder if I should fetch some help.
    There aren't many federate troops inside this moon, but the Conglomerate [i]is[/i] part of the Kronian Federation. It's in their best interest to tell Admiral West and the other federate leaders what happened… even assuming West's former @{rook_alive subordinates|attack dog} won't do it first.
  #And they will be right to think that. She was always a failure in every respect, and now became a traitor too.
    Failure to get a promotion, failure to kill Crystal, failure to resist the temptations of Dusk. Marshal is just one huge of pile of failures, and hoping to ever become anything else has proved her undoing.
  #Perhaps they will remember her years of loyal service. Perhaps they'll go easy on her.
    It's an insanely optimistic thought, that one. The command treated Renfri with disdain even when she was loyal and useful. Now, they will most likely treat her with unrestrained hatred, mixed up with understandable fear.
  #I wonder if this will make things worse for the others. Other Uranians, other Kinnari, other people like her.
    On one hand, this could further fuel the prejudice against Uranians, or immigrants in general, or at least @{(RenfriRel >= 50) Renfri|Marshal}'s specific species. On the other hand, you know perfectly well that such bigotry rarely has an actual cause, and will always find an excuse anyway.

You hear
*if rook_alive
  @{(RookRel >= 50) Krill|Rook} shout something in the far distance, perhaps rallying the reinforcements or first responders. 
*else
  @{(LisaRel >= 50) Lisa|Hellhound} shout something in the far distance. Perhaps she met up with the reinforcements, corporate or federate, and is trying to lead to your location. 
You trust @{rook_alive him|her} to locate this place and take @{(RenfriRel >= 50) Renfri|Marshal} somewhere safe, prevent her from kicking the bucket, then tell the authorities what happened and why the entire city is nearly destroyed.

As to what happens next… Dusk itself said it best. @{(RenfriRel >= 50) Renfri|Marshal} will be imprisoned at the absolute least, likely frozen, possibly experimented on in the laboratories of Titan. She's a threat first, an interesting specimen second. Nothing more. Nothing that would help her case, at least.

*return

*label hound

@{(LisaRel >= 50) Lisa|Hellhound} jumps down to meet you. Her muscles are spasming as though she's about to transform, but she's still human… at least in terms of overall appearance. "You know, I haven't felt like a predator since… forever, really. Even when I was still hunting people, back in Calypso, I was still prey to those above me. All this power flowing through me feels [i]really[/i] liberating."

*temp shot_lisa false
*temp elec_lisa false


*fake_choice
  #"You don't look like a predator. You look like a scared, little girl that you are."
    *set Confid %+ 10
    *set LisaRel %- 8
    *if Social > 65
      *set boss_will - 1
    You can scarcely see the flinch. "True, my current form isn't the scariest thing ever. Let's fix that."
  #"I'm sorry that you had to suffer through so much... but that doesn't justify what you're about to do."
    *set boss_will - 1
    *set LisaRel %+ 8
    You can scarcely see the flinch. "I don't care if I'm justified, I care if I'm [i]alive[/i]. And if survival requires me to be a monster, well… that's what I'll be."
  #"Liberating? You're a slave to the Shadow, @{(LisaRel >= 50) Lisa|Hellhound}. Snap out of it."
    *if Social > 60
      *set boss_will - 1
    @{(LisaRel >= 50) Lisa|Hellhound} grimaces. "I'd rather think of myself as an… employee. One who enjoys some amazing health benefits."
  #"You went mad. Completely fucking bonkers."
    "Perhaps I did," @{(LisaRel >= 50) Lisa|Hellhound} freely admits. "In that case, I should have a body that matches my mind. Wait."
  *if weapon = "knife"
    #Throw a knife at her.
      *set boss_health - 1
      *set Violence %+ 8
      *set weapon_av false
      You throw your dagger at @{(LisaRel >= 50) Lisa|Hellhound}, trying to aim for the center of mass and thus her vital organs. She jerks to the side and tries to catch the knife by the hilt, but she messes up and the blade cuts her hand open, almost severing one of her fingers.
      
      "Damn, I was hoping for a higher boost to my speed," she eyes her destroyed hand unhappily, but without much worry. "I guess the human body has its limits. Let's try something else."
  *if weapon = "pistol"
    #Shoot her in the heart.
      *set shot_lisa true
      *set boss_health - 1
      *set Violence %+ 8
      *if wpr = "plasma"
        *set weapon_av false
      You aim your pistol at @{(LisaRel >= 50) Lisa|Hellhound} left breast and pull the trigger. The 
      *if (wpr = "laser") or (wpr = "electron")
        beam 
      *else
        projectile 
      goes straight through her clothing and skin, likely destroying the heart which hides beneath… but the woman still stands before you, showing no sign of pain or death.
      
      "It appears I'm still not bulletproof," @{(LisaRel >= 50) Lisa|Hellhound} comments. 
      *if (wpr = "laser") or (wpr = "electron")
        "Or laser-proof, for that matter. 
      *else
        "Disappointing. 
      Let's fix that, shall we?"
  #Zap her with lightning.
    *set battery - 8
    *if (Projection + battery) > 100
      *set boss_health - 1
    Your discharge splits the air, illuminates it, then ripples it with the sound of thunder. It's a powerful attack that would have killed an ordinary human being… but @{(LisaRel >= 50) Lisa|Hellhound} is far beyond that point, and so she just stands there unmoved. 
    *if boss_health = 2
      Her pale skin has been burned, but you doubt the damage extends to the muscles.
    
    "I think you just gave the nanobots inside me more power," she comments snidely. "Let's put that power to some use."
  #Just stand there.
    "Not feeling up for trash talk?" @{(LisaRel >= 50) Lisa|Hellhound} chuckles. "Okay. Let's cut straight to the chase."

@{(LisaRel >= 50) Lisa|Hellhound} starts transforming, much like you've seen her before, except this time… she doesn't stop when she's supposed to. She doesn't merely grow twice as massive as her human form, she just keeps growing. She doesn't retain human traits like some hybrid of two species, she just keeps becoming more and more lupine until she's actually a wolf… and yet so much more.

You are looking at a truly colossal beast, the size of a truck and with fur as red as blood. Eyes large as cannonballs and silver like moons, teeth and claws like powered swords, unnatural presence that makes you feel like you're facing death itself. She's like an amarok, a monstrous wolf who hunts lone hunters, a bad omen which fulfills itself as it approaches her prey.

[i]Is it not beautiful?[/i] she speaks to you like Crystal once did, with cold thoughts rather than waves of sound. [i]My true form. I thought I was myself whenever I transformed, but that was only halfway there, some mockery of a true-[/i]

*if team_stat = 1
  *set boss_will - 1
  A laser beam to the backside makes @{(LisaRel >= 50) Lisa|Hellhound} pause. It is only a red beam, it doesn't wound the hound more than a laser pointer would, but it brings @{(LisaRel >= 50) Lisa|Hellhound}'s attention to the shooter high above.
  
  "Lisa!" @{(RenfriRel >= 50) Renfri|Marshal} yells out of the boiler room. "What the Cloud are you doing? Did you finally go completely-"

*if team_stat = 2
  @{(LisaRel >= 50) Lisa|Hellhound} turns around rapidly, as though hit by something invisible. A supercharged shot from an electron rifle would be your guess, as you see Damon—still up in the boiler room—point his gun at the hound.
  
  "I'm sorry I have to do this!" Damon yells. "I'd really rather not, so if you could just stop-"

*if team_stat = 3
  *set boss_will - 1
  *set boss_health - 1
  Lightning splits the air. It connects Hadaly, still standing in the boiler room and looking through the hole, and @{(LisaRel >= 50) Lisa|Hellhound}'s monstrous body in a glorious discharge of electric energy.
  
  "What the Cloud are you doing?" Hadaly demands to know. "I didn't take that bomb out just for you to do something like [i]this[/i]. Do you want to live or not?"
  
  "Can you please listen to her?" Damon requests. "You were usually fun to hang around. I'd hate having to kill you."
  
[i]Stay out of this![/i] @{(LisaRel >= 50) Lisa|Hellhound} growls. [i]I only need to kill ${name}. I'll spare the rest of you if just stop trying to control me.[/i]

*fake_choice
  *if (official_ro = "lisa")
    #"You only need to kill your lover. How does that make you feel?"
      *set boss_will - 1
      [i]Not great,[/i] Lisa admits. [i]But it's not like you were a great boyfriend, so… I think I can live without you.[/i]
  #"Are you telling your friends to stop controlling you? Tell that to Dusk."
    *set LisaRel %+ 8
    [i]I chose this![/i] @{(LisaRel >= 50) Lisa|Hellhound} barks as she turns towards you. [i]And so did you![/i]
  #"Really? I recall Dusk ordering you to kill us all."
    [i]It ordered me to kill all my false friends,[/i] @{(LisaRel >= 50) Lisa|Hellhound} clarifies. 
    *if team_stat = 1
      [i]Renfri is[/i] 
    *if team_stat = 2
      [i]Damon is[/i] 
    *if team_stat = 3
      [i]These three are [/i]
    [i]not in that group yet. I'm giving @{(team_stat = 3) them|him} a chance to stay out of it.[/i]
  #"I can tell you don't want this, @{(LisaRel >= 50) Lisa|Hellhound}. Stop."
    *set Violence %- 8
    *if (LisaRel + Social) > 100
      *set boss_will - 1
      [i]You're right,[/i] Lisa admits. [i]I don't want to do this. But for survival's sake, I'll do it all the same.[/i]
    *else
      [i]You don't know the first thing about what I want,[/i] Hellhound growls at you. [i]Right now, I just want you dead. Bye.[/i]
  *if (weapon = "pistol") and (weapon_av)
    #Shoot @{shot_lisa Hellhound again.|Lisa.}
      Given the short distance and @{(LisaRel >= 50) Lisa|Hellhound}'s tremendous size, it is basically impossible for you to miss your shot. 
      *if ((wpr = "plasma") or (wpr = "shroom")) or (wpr = "laser")
        *set boss_health - 1
        Your 
        *if (wpr = "laser")
          laser 
        *else
          projectile 
        penetrates the skin of her throat and, though no blood is visible on the red fur, some ichor soon flows out of her filthy mouth.
      *else
        Not that your shot has much of an effect—your ${wpr} pistol was designed with range and reliability rather than sheer power in mind.
  *if (weapon = "knife") and (weapon_av)
    #Throw your dagger at @{(LisaRel >= 50) Lisa|Hellhound}.
      *set weapon_av false
      Given the short distance and @{(LisaRel >= 50) Lisa|Hellhound}'s tremendous size, it is basically impossible for you to miss your throw. Your dagger hits the beast blade-first, 
      *if Build > 60
        *set boss_health - 1
        cutting through the fur and the skin, lodging itself firmly in her throat.
      *else
        but does not manage to wound her very grievously. Precision might be necessary for knife-throwing, but you just don't have enough strength to penetrate her tough hide.
  *if battery > 20
    #Electrocute @{elec_lisa Hellhound again.|Lisa.}
      The sound of thunder which you generate is only muffled by the hound's cry of pain. 
      *if (Projection + battery) > 110
        *set boss_health - 1
        Even she's not immune to a well-place lightning, despite her size and unnatural toughness.
      *else
        You're probably not doing much damage, she is far too large for a single lightning to cripple her, but it does feel good to see her hurt again.

      *set battery - 12

@{(LisaRel >= 50) Lisa|Hellhound} dashes towards you, jaws open and ready to be slammed shut again. 
*if Calculation > 50
  You react instantly, jumping out of the way just in time and evading the deadly attack. Curiously, you don't fall back down and instead 
*else
  For a split second, you're convinced that this is how it ends—that you'll end up devoured by the angry werewolf, not having offered much resistance or inflicted much damage on this Vessel your created. But then you're pulled up, launched into the air by some invisible force, just quickly enough to save you from @{(LisaRel >= 50) Lisa|Hellhound}'s teeth.
  
  You 
find yourself floating up, further away from the hound and towards the fading World Engine above. Not just up either—some of your momentum is pointed horizontally, away from the power plant and towards the city's edge, as though gravity is suddenly pulling you diagonally to its usual direction.

You only realize what's happening when you see @{(RenfriRel >= 50) Renfri|Marshal}'s caramel wings above you, brown against a grey background. She's using her powers both to fly and levitate you near her, carrying you like a hawk carries a captive mouse.

@{(LisaRel >= 50) Lisa|Hellhound} is too surprised to act immediately, and so she lets her prey get away. Lets you and the Kinnari fly toward the suburbs, knowing full well she'll catch you eventually. This… that's just @{(RenfriRel >= 50) Renfri|Marshal} buying you time.

*page_break

Soon enough, before you can even leave the city, @{(RenfriRel >= 50) Renfri|Marshal} gets too tired to keep going. Tanit is already half-dark above her, and carrying you with her surely puts a strain on her powers. She drops you on the roof of some suburban building, before landing on the same room with a groan.

"Why?" Knees are shaking beneath her, as though she's about to fall. "Why did she do it? Why can't she… fuck."


*fake_choice
  #"It's my fault. I turned her into this thing. I'm sorry."
    *set RenfriRel %+ 10
    *set Confid %- 10
    "It's not entirely your fault…" Anger flashes in @{(RenfriRel >= 50) Renfri|Marshal}'s. "Though I'm not sure what you were thinking. What you were trying to accomplish."
  #"She's as weak as she is treacherous. Don't overthink that."
    *set RenfriRel %- 10
    "Oh fuck you!" @{(RenfriRel >= 50) Renfri|Marshal} exclaims. "This shit was your idea, not mine or hers! So if we die, I'm blaming you."
  #"Blame Kirill for putting all those nanobots into her."
    "I do." @{(RenfriRel >= 50) Renfri|Marshal} grimaces. "But let's not forget who told him to do that. You have a lot to answer for when… if we get through this."
  #"She's not herself. Dusk is corrupting her mind and soul."
    "But she had to accept it first, right?" @{(RenfriRel >= 50) Renfri|Marshal} sounds like she's hoping for a negative answer. "Or not? I don't know how that works, I… feel like I don't know anything anymore."
  #"I tried to talk her out of this. I failed."
    "Talking Lisa out of things tends to be difficult," @{(RenfriRel >= 50) Renfri|Marshal} sighs, more with frustration than pain. "So don't blame yourself too much."
  #"It doesn't matter. Focus on the battle."
    "Right…" @{(RenfriRel >= 50) Renfri|Marshal} swallows. "I don't think we have much time to ourselves. Look."

You hear @{(LisaRel >= 50) Lisa|Hellhound} run toward you in her new, monstrous form. Her steps are silent like those of a predator, but a truck-sized wolf can't be truly quiet as she bulldozes her way through the suburbs. She breaks street lights, pushes vehicles out of her way, evokes scream of fear from the few civilians still left in the Sholmo City.

"What should I do?" @{(RenfriRel >= 50) Renfri|Marshal} asks you. "Attack her? Kill her? Or just… try to talk her out of it?"


*choice
  #"Attack her. I doubt you could kill her if you wanted to, just wear her down for me."
    *set boss_health - 1
    "Alright…" @{(RenfriRel >= 50) Renfri|Marshal} grits her teeth. "I think I can do that much. Bruise her a little, give you a fighting chance. I'd tell you not to waste that chance, but… fuck."
    
    With that, @{(RenfriRel >= 50) Renfri|Marshal} jumps from the roof and lands on the street, right in @{(LisaRel >= 50) Lisa|Hellhound}'s path of destruction. She uses telekinesis to pick up a nearby garbage contained and throw it at the hound—it doesn't do much damage upon impact, but you hope @{(LisaRel >= 50) Lisa|Hellhound} will be distracted now that she's covered by trash. At the very least, it should numb her sense of smell.
    
    Running low on meta-power, @{(RenfriRel >= 50) Renfri|Marshal} focuses a laser beam on the wolf's head, but that seems to have no effect. @{(LisaRel >= 50) Lisa|Hellhound} closes the distance and tries to bite @{(RenfriRel >= 50) Renfri|Marshal}—or perhaps eat her whole—though the Kinnari manages to take flight at the last second.
    
    @{(LisaRel >= 50) Lisa|Hellhound} swipes at her friend, like a cat hitting a toy mouse, except with the strength of a motorbike hitting someone at full speed. @{(RenfriRel >= 50) Renfri|Marshal} flies towards a nearby building, carried by momentum rather than her wings, then slams into the wall of said building and cracks it. Then falls to the ground, seemingly knocked out… if not worse.
    
  #"Talk to her. Remind her that she's your friend, that she doesn't really want to do this."
    *set boss_will - 1
    "Um…" @{(RenfriRel >= 50) Renfri|Marshal} looks at the charging beast uncertainly. "I'm not sure how much I can accomplish here. But I will try."
    
    She flies down, landing in the middle of the road and directly in @{(LisaRel >= 50) Lisa|Hellhound}'s way. For a moment, you're worried that the huge hound will eat the Kinnari whole, or just trample her without second thought… but the beast stops, looking and sniffing at @{(RenfriRel >= 50) Renfri|Marshal} curiously.
    
    "Lisa… are you there?" You hear no response, but perhaps @{(LisaRel >= 50) Lisa|Hellhound} is communicating with her friend telepathically. "I don't want to fight you. I just want to talk."
    
    No response again. Silence feels like a physical substance which submerges the two mythical beings, drowning them while you stand safely on the roof.
    
    "I know that we… that I haven't treated you fairly," @{(RenfriRel >= 50) Renfri|Marshal} continues, her voice wavering but not ceasing. "I should have taken that bomb out of your heart myself, I should have stopped Kirill from making you a Vessel, and those stupid attempts to hit on you… I fucked up, in so many ways, and I'd love to make amends. But I can't do that if I'm dead… or if you refuse to see reason."
    
    @{(LisaRel >= 50) Lisa|Hellhound} stands there for a moment, still silently, but she lowers her head a little. You suspect she's considering @{(RenfriRel >= 50) Renfri|Marshal}'s words, processing them alongside her own emotions. For a moment, you dare to hope that she'll surrender, turn back from this destructive path and embrace her humanity once again.
    
    And then she attacks @{(RenfriRel >= 50) Renfri|Marshal}.
    
    She does not go for the kill, 
    *if (master = "Jesus") or (heaven_side = "Loyalist")
      thank heavens for small mercies. 
    *else
      in spite of what it looks like at first. 
    She just swipes at @{(RenfriRel >= 50) Renfri|Marshal} with the soft underside of her paw, rather than sword-sized claws. And yet, even the strength of that casual blow is enough to send @{(RenfriRel >= 50) Renfri|Marshal} crashign against a nearby wall, breaking both the cheap bricks used to build the suburban block and the Kinnari's own wings. Suffice to say, your ally will [i]not[/i] be getting back up.
    
  #"Just leave. Ensure your own safety and leave fighting to me."
    *set Confid %+ 10
    *set Misan %- 5
    *set marshal_in_fight false
    *set RenfriRel %+ 20
    "Really?" Renfri looks at the charging beast, then at you again. "Are you sure you can handle… her alone?"
    
    *if official_ro = "renfri"
      "I'll be alright," you lie. "Especially if I can focus on fighting, knowing the woman I love is safe."
      
      "You are so sickeningly sweet…" Renfri sighs deeply. "Fine. I love you too, and so I'll respect your choice. Just try to not get killed, okay?"
    *elseif confid > 60
      "I've handled worse… or at least similarly bad things in the past," you reassure her, as well as yourself. "At the very least, I can stand my ground. You go fetch some help, that will help us more than your lasers or gravity waves."
      
      "Right… I think the Conglomerate should have moved some troops into the city already. I'm not sure how much they can do, but it's worth a try. Take care."
    *else
      "No," you confess. "I might die soon. But I'd rather you survived, and I'd rather spare you the pain of having to fight… her."
      
      "You're not making a great argument…" Renfri sighs deeply. "But you're right. I don't want this, and so I'd rather flee, even if it's the cowardly thing to do. Good luck."
    
    Renfri flaps her wings and fly away, long before @{(LisaRel >= 50) Lisa|Hellhound} reaches your location. The beast does jump for her, trying to knock the Kinnari out of the air with her paw, but you can tell @{(LisaRel >= 50) Lisa|Hellhound}'s heart isn't in it. She doesn't get anywhere close to hitting her former friend and, in the end, simply watches Renfri become a brown dot in far distance.

That taken care of, @{(LisaRel >= 50) Lisa|Hellhound} turns towards you, looking up as you stand on the rooftop. Luckily, you have the initiative, as well as the high ground.

*temp hurt_now false

*choice
  #"What are you waiting for? Climb up here and show me what you're made of."
    *set Confid %+ 12
    [i]You really a brave one,[/i] @{(LisaRel >= 50) Lisa|Hellhound} says calmly, not very bothered by your taunts. [i]Even in the face of death, you act like you're toughest[/i] 
    *if sex = "man"
      [i]son of a[/i] 
    [i]bitch around. I wonder how-[/i]
    
    *goto rook_entrance
  #"You didn't have the heart to kill her. There's still good in you."
    *if Social > 60
      *set boss_will - 1
    [i]This is possibly the most predictable, formulaic thing you could have said,[/i] @{(LisaRel >= 50) Lisa|Hellhound} growls at you. [i]I will enjoy tearing-[/i]
    
    *goto rook_entrance
  #"Hello again. Do you still want me dead?"
    *if LisaRel > 60
      *set boss_will - 1
    *if LisaRel > 45
      [i]No,[/i] Lisa admits. [i]But you now how it is. I cannot be swayed-[/i]
    *else
      [i]Yes,[/i] Hellhound deadpans. [i]You were a thorn in my side even before you turned me into this. You deserve-[/i]
    
    *goto rook_entrance
  *if (weapon = "knife") and (weapon_av)
    #Throw your dagger.
      It's not really possible to miss, given @{(LisaRel >= 50) Lisa|Hellhound}'s size and the small distance between you, and gravity adds to the strength of your toss. 
      *if ((wpm = "plasma") or (wpm = "power")) or (wpm = "vibro")
        *set hurt_now true
        *set boss_health - 1
        You hit her in the head blade-first, penetrating the skull so that the dagger sticks out of it like some odd horn.
      *else
        And yet, your ${wpm}-knife simply bounces off the beast's hide, too weak to inflict any real damage.
  *if (weapon = "pistol") and (weapon_av)
    #Shoot her.
      You can't really miss at this distance, and not a target this large. 
      *if ((wpr = "plasma") or (wpr = "gyrojet")) or (wpr = "shroom")
        *set hurt_now true
        *set boss_health - 1
        Your ${wpr} pistol can't really fail to wound this beast either, penetrating her skull and likely damaging the brain.
      *else
        But that doesn't mean you necessarily wound her—your ${wpr} pistol is not exactly the best weapon for this kind of work.
  #Bring down the lightning.
    Connecting up and down like this, the discharge looks very much like an actual lightning. 
    *if (Projection > 55) and (battery > 45)
      *set hurt_now true
      *set boss_health - 1
      *set battery - 10
      It's just as powerful as a natural lightning too, if not more so, burning the hound's fur and scorching the skin beneath.
    *else
      Unfortunately, it doesn't do nearly as much damage as a natural lightning would—you are far too weak for that.
      *set battery -5

*if hurt_now
  [i]I admit, that wasn't half-bad,[/i] @{(LisaRel >= 50) Lisa|Hellhound} says as she prepares to jump. [i]But I can still-[/i]
*else
  [i]Absolutely pathetic,[/i] @{(LisaRel >= 50) Lisa|Hellhound} comments as she prepares to jump you. [i]Let me show you what real power-[/i]

*label rook_entrance

"Lisa!" You hear @{(RookRel >= 50) Krill|Rook}'s voice as its owner runs down the street. He's still armored, but without a helmet and unarmed. "Stop this, just… please stop."

[i]Look who's late to the party.[/i] @{(LisaRel >= 50) Lisa|Hellhound} turns towards her former leader. It looks as though she's sniffing him, trying to sense his fear, or perhaps just wondering if he has a nuclear grenade hidden somewhere. [i]Get out of here, Kirill. This is not about you.[/i]

"I believe it has… a lot to do with me," @{(RookRel >= 50) Krill|Rook} replies, still panting heavily after what had to be a long and strenuous jog. "If not for me, you wouldn't be doing this."

*temp speaking_now 1

*fake_choice
  #"And what do you mean by that?"
    *set speaking_now 3
  #"Stay out of this, @{(RookRel >= 50) Krill|Rook}. Unless you wish to die."
  #"Attack, @{(RookRel >= 50) Krill|Rook}! Attack now!"
    *set Violence %+ 5
    *set Emotion %+ 5
    *set LisaRel %- 5
  #"I have to agree with the werewolf. You're irrelevant, @{(RookRel >= 50) Krill|Rook}."
    *set RookRel %- 5
    *set LisaRel %+ 5
  #"With all due respect, @{crystal_stat Sergeant|Sergeant|Captain}, shut the fuck up."
  #Say nothing.
    *set speaking_now 2

"Lisa… I have more than earned your ire," @{(RookRel >= 50) Krill|Rook} says, @{speaking_now appearing not to hear you|heavily but calmly|indirectly answering your question}. "I made you into this, and I do not just means pumping the nanobots into your body. I brought you to the breaking point, 
*if lisa_saved_hostages
  I almost killed you back in the Expanse, 
I… did a lot things I shouldn't had done."

[i]And what of it?[/i] @{(LisaRel >= 50) Lisa|Hellhound} sneers. [i]Do you think I'll forgive you, shift back and turn myself over?[/i]

"No… but maybe I can abate your rage, at least to an extent." @{(RookRel >= 50) Krill|Rook} spreads his arms wide. "Kill me. If that satisfies you in any way, kill me right now and be done with it. Strike me down."

@{(LisaRel >= 50) Lisa|Hellhound} blinks. [i]This is a ploy. You will blow up after I eat you, or stab me when I get close, or-[/i]

"I am many things, Lisa, but not a liar. I swear on everything I hold holy that there are no tricks, and that you can slay me safely."

*fake_choice
  #"You came here just to die? You're a martyr without a cause."
    "Now that is just uncalled for," @{(RookRel >= 50) Krill|Rook} protests. "I admit, achieving salvation is a major part of my motivation, but that hardly constitutes dying for the sake-"
    
    [i]${name} is right,[/i] @{(LisaRel >= 50) Lisa|Hellhound} interjects. [i]This is not a heroic final stand you take it for. You're just a pathetic old man starved for death, and I will not humor you.[/i]
    
    *goto rook_death_no
  #"@{(RookRel >= 50) Krill|Rook}... what the fuck are you doing?"
    "Atoning for my misdeeds… and hopefully fixing my mess somewhat," @{(RookRel >= 50) Krill|Rook} sighs sadly. "Shrifts and confessions never brought me any peace, or any good to anyone around me. This is my new method of achieving redemption, and I think it may just work."
    
    *label own_choice
    
    [i]That's how you plan on redeeming yourself?[/i] @{(LisaRel >= 50) Lisa|Hellhound} mocks her former leader. 
    *if (lisa_saved_hostages) or (left_lisa)
      [i]Very well. I will turn the other cheek and, in spite of everything you've done to hurt me, help you achieve your salvation.[/i]
      
      *goto rook_death_2
    *else
      [i]This is the most pathetic thing I've ever seen. I am not humoring you. Bye.[/i]
      
      *goto rook_death_no
    
  #"Do it. Strike him down. You know he deserves it."
    *set Violence %+ 10
    *if lisa_spared_daxia
      [i]I think we agreed that nobody deserves anything,[/i] @{(LisaRel >= 50) Lisa|Hellhound} says, reminding you of her decision to spare Da-xia. [i]As such, I will not be killing him today. This is no time for justice.[/i]
      
      *goto rook_death_no
    *else
      [i]Yes… you are quite correct,[/i] @{(LisaRel >= 50) Lisa|Hellhound} says after a moment. [i]Tonight, I am an instrument of justice, or at least of vengeance. And I can't let someone like him live.[/i]
      
      *goto rook_death_2
  #"Don't do this, Lisa. He doesn't deserve to die."
    *set Violence %- 10
    *if lisa_spared_daxia
      [i]This may be true,[/i] Lisa concedes. [i]But we've already established that I don't give a fuck about right and wrong, or who deserves what. So farewell, Kirill Kosteniuk.[/i]
      
      *goto rook_death_2
    *else
      [i]Maybe he does, maybe he doesn't,[/i] Lisa says nonchalantly. [i]Either way, I don't have the time to deal with him right now.[/i]
      
      *goto rook_death_no
  #Say nothing.
    *goto own_choice


*label rook_death_2

*set rook_alive false
*set boss_will - 1

@{(LisaRel >= 50) Lisa|Hellhound} dashes towards @{(RookRel >= 50) Krill|Rook}. She does not eat him, nor does she necessarily strike him down, she just…  stomps on him. Crushes him beneath her red-haired paw, which soon becomes red with meta-human blood. @{(RookRel >= 50) Krill|Rook}'s armor is mangled beyond repair, his body mutilated beyond recognition, his soul beyond the mortal world. Gone.

*goto no_more

*label rook_death_no

She then huffs at @{(RookRel >= 50) Krill|Rook}. She doesn't bite him, she doesn't even approach him, she just huffs. Logically speaking, such an exhale should do nothing, despite her humongous size… but logic is no longer with you, and so @{(RookRel >= 50) Krill|Rook} is instantly blown away like a feather in a hurricane. He flies somewhere toward the power plant, or perhaps towards Hammon's headquarters, some place where he wont be able to interrupt the battle anymore.

*label no_more

[i]No more distractions.[/i] @{(LisaRel >= 50) Lisa|Hellhound} looks at you with two moon-lit eyes, 
*if boss_will < 2
  unable to hide the doubt behind them. 
*elseif boss_health < 2
  tired but full of killing intent. 
*else
  both full of vigor and bloodlust. 
[i]This is between you and me. And only one of us will live until nightfall.[/i]

*page_break

It soon becomes clear which one of you will get to live past nightfall.

If you had any hopes that @{(LisaRel >= 50) Lisa|Hellhound} would eventually grow weaker, either due to power loss or regular fatigue, she proves you wrong by jumping onto your rooftop and knocks you off it with a swift paw swipe. She is not only too strong for you to defend yourself, but almost too fast for you to react at all. When she jumps back down, claws and teeth bare, you barely have time to roll away. 

Not that claws and teeth are her only weapons. Her breath is cold and strong like saturnine winds, her eyes piercing in a very literal sense, fur burning with eternal flame. Worse yet, shadows themselves are gathering to the hound's side, taking forms of wolves and hyenas, waiting for the right moment to strike. Reality itself is collapsing around the Vessel of Dusk, taking away any hope that you'll even get to fight back. All you can do is to keep dodging.

*if (boss_health <= 0) or (boss_will <= 0)
  *goto epic_flashback
*else
  Until, five or ten or five thousand minutes later, you can no longer dodge. You get too tired, too distracted, too weak to dodge a stream of fire that suddenly flows out of the hound's mouth. It's curious how fast an icy chill can turn into hellish heat, how quickly @{(LisaRel >= 50) Lisa|Hellhound} can invent new powers on the spot. The fire casts shadows on the walls which surround you, and those shadows gaze at you like a blood-crazed audience watching a gladiator's death.
  
  You fall to the ground, to the half-melted road, burned and scorched and almost dead. When you see @{(LisaRel >= 50) Lisa|Hellhound} approach, you almost hope that she'll finish you off, eat you whole, end this hopeless fight and pointless suffering. But she then starts shrinking and she then starts turning, losing her lupine shape and standing on two legs once again.
  
  *page_break Back To Human
  
  Seconds later—if you can still trust your sense of time, that is—@{(LisaRel >= 50) Lisa|Hellhound} stands before you like she once stood in Calypso. Naked, but not vulnerable, her eyes like orbs of palladium and hair like a rising blaze. Even in this form, there is something vaguely bestial about her; She threads like a predator and surrounds herself with an air of power, like some ancient goddess of hunt and war.
  
  "Despite everything, you don't deserve to be eaten alive or stomped to death." She summons a sword to her hand. Not attracting an existing blade, or even forging one on the spot, but materializing one out of thin air. "Or maybe you do, I don't know who deserves what… But I will make your death quick."
  
  You can barely move. You won't be able to stand up until your body cools down, and you won't live to feel that happen. This is your last chance to speak.
  
  *fake_choice
    #"To hell with you... bitch."
      "What's hell?" @{(LisaRel >= 50) Lisa|Hellhound} asks impassively. "Actually, don't answer. I bet Dusk will know. I will gain access to all the knowledge I could ever wish for, once my duty is fulfilled."
    #"Do it. End my... pain."
      "You actually want to die?" @{(LisaRel >= 50) Lisa|Hellhound}'s voice is tinged with pity. "That's why you lost. You're a veteran far past your prime, and I… I'm a survivor."
    #"With malice eternal... the Sun smiles at me...
      "I think I heard that song somewhere," @{(LisaRel >= 50) Lisa|Hellhound} says impassively. "It's really not the worst thing to sing as you're dying."
    #"I am... sorry. I'm sorry... for everything."
      *set LisaRel %+ 10
      *if LisaRel > 50
        "Me too…" @{(LisaRel >= 50) Lisa|Hellhound} replies with sudden softness. "Me too. But that doesn't change anything in the end. I must survive."
      *else
        "I am not," @{(LisaRel >= 50) Lisa|Hellhound} says coldly. "You were always my enemy, from beginning till end. I will show you no more mercy."
    #Stay silent.
      "Nothing to say?" @{(LisaRel >= 50) Lisa|Hellhound} sounds mildly disappointed. "If anyone asks, I'll tell them you said something wise and heroic. A proper end to a millennium-long life."
  
  She then raises her sword, thin like her original vibro-blade, sharpened to perfection and silver like her eyes. She finally closes the distance and, instead of looking at you, takes a sad glance at that blade. A weapon, much like her, forged with unnatural power. Something meant solely for killing, unable to ever avert its violent destiny, without agency or choice. Alone save for its creator, its master, its builder, that's the instrument of your demise.
  
  *if crystal_stat = 1
    You are almost glad to be killed by something similar to you. By a tool, a machine, a weapon for a malicious god. Compared to the prospect of dying slowly, with no one who can understand your pain… this really isn't the worst way to go out. 
    *if Emotion > 50
      And yet, it's difficult not to feel 
    *else
      You feel no 
    fear as @{(LisaRel >= 50) Lisa|Hellhound} raises her sword and then brings it down and-
    
    *goto crystal_scene
  *else
    And then she drives it thought your hard drive and everything ends.
    
    *set pc_dead true
    
    *finish


*label hound_death

Curiously, @{(LisaRel >= 50) Lisa|Hellhound} has reverted to her human form, her true form in spite of all the lies she told herself. A young woman, slim and pale, lying naked in the crater's bottom. To call her vulnerable would be an understatement, to call her pitiable… yes, that is an accurate way to describe this bruised mess of a human being.

*fake_choice
  #I did it. I did this to her.
    *set Emotion %+ 5
    Despite everything Lisa did to hurt you, despite the fact that she just tried to [i]eat you alive[/i], you cannot help but feel bad about what you've done to her in turn. Especially when you consider her likely fate.
  #Better me than her, right?
    *set Emotion %- 5
    It was a fair fight between two divinely-aided beings, and you won. You feel nothing but pride and satisfaction when you consider your victory, and you're [i]definitely[/i] glad that you didn't choose to become a Vessel yourself.
  #She was always a scared little girl. This whole battle was just her lashing out.
    Lisa was—and still is—a pathetic individual who killed countless people out of fear and misplaced anger. And yet, it is difficult not to sympathize with her, especially when you consider her likely fate.
  #No. I feel no pity for her, or the fate she brought upon herself.
    *set Emotion %- 5
    *set Misan %+ 5
    You do not feel sorry for her. You do not feel any sympathy. Yest still… it's difficult not to feel [i]something[/i] approaching pity when you consider her likely fate.

The Federation mistreated @{(LisaRel >= 50) Lisa|Hellhound} before, but merely out of negligence and apathy. Now, they will abuse her with [i]hatred[/i] in mind, as well as a healthy dose of fear. They will lock her up forever at the very least and might just end up vivisecting her in search for the Dusk nanites hidden inside. Her greatest hope is to simply be frozen forever, to die rather than become a plaything of some mad 
*if rook_alive
  researcher… or perhaps Rook's next test subject.
*else
  researcher.

*return


*label damon

Damon jumps out of the hole in the building and lands on the parking lot, ten or twenty meters away from you. He does so without grace, but with the sort of strength and weight you've seen from him before. His sapphire eyes look unusually cold as he regards you.

"He really gave me power," he says dispassionately. "It, they… it doesn't matter. Nothing really matters at this point, nothing other than completing my task. That's how it should be."

*fake_choice
  #"Damon please... I don't want to do this."
    *if (Social + DamonRel) > 110
      *set boss_will - 1
    "I don't really want to do this either." Damon smiles sadly. "But my master ordered so, and I want to obey. I want to serve, and I want to be rewarded for my service, I want-"
  #"Why are you doing this, again? Just because you want power?"
    Damon shakes his head weakly. "Not power, not just power. I want… recognition? Glory? I want to be seen as valuable by someone, and if the Thing Beneath wishes to-" 
  #"I agree. Nothing matters. Nothing is worth doing."
    *set deflect + 1
    "You understand, then," Damon replies sadly. "We are of one mind. Two automatons, unable to fulfill the purpose with which-"
  #"You're delirious. Snap out of it."
    "I don't think you want me to [i]snap out of it[/i], as you put it," Damon replies, still with cold serenity. "It would make the fight harder for you. Not that you stand a chance at-" 
  #"Damon, this is idiotic. I will not fight you."
    *set Violence %- 12
    *if Violence > 55
      *set boss_will - 1
      "That's new," Damon comments mirthlessly. "You always accepted, resorted to, even enjoyed violence. I wonder what changed, which part-" 
    *else
      "Are you hoping to change my mind? Appeal to my conscience?" Damon shakes his head slowly. "That won't work. You're just saying that because you're weak, unused to bloodshed and violence, whereas I-"
  #Stand there silently.
    "Not up for a conversation?" Damon smiles bitterly. "That's okay. That's more than-"
  #Attack Damon.
    *set Violence %+ 8
    *if weapon = "pistol"
      You raise your pistol and simply start blasting. 
      *if ((wpr = "electron") or (wpr = "shroom")) or (wpr = "plasma")
        *set boss_health - 1
        *set weapon_av false
        Damon seems surprised, but not pained or even particularly bothered as the 
        *if (wpr = "electron")
          electron beam penetrates 
        *else
          projectiles penetrate 
        his suit and tear holes in his body.
      *else
        Hitting your mark is not difficult at this distance, but actually hurting someone as bulky as Damon… that's the difficult part. Your 
        *if (wpr = "laser")
          laser beam barely does 
        *else
          projectiles barely do 
        anything.
    *else
      You charge Damon with the intent of 
      *if weapon = "knife"
        stabbing 
      *else
        punching 
      him in the face, but he's faster than you as well as stronger. He drops his electron rifle and counter-charges you, decking you in the jaw and sending you flying towards the ground before you can do anything.
    
    "I see you have no qualms against hurting me," Damon comments. "That's okay. In fact, it will make things a little easier for-"

A laser burns the back of Damon's head. It came from @{(RenfriRel >= 50) Renfri|Marshal}'s headband, the Kinnari flying down so as to scorch the android with greater precision. With speed you've never seen of him before, Damon turns and leaps towards the Kinnari, swatting her out of the air with an unarmed, backhanded strike.

They both land at roughly the same time. @{(RenfriRel >= 50) Renfri|Marshal} does so less graciously, crashing against the pavement painfully, but she immediately takes flight again. Somehow, she immediately comprehended what happened—she probably didn't believe Damon capable of resisting corruption in the first place—and knows that the Vessel has to be destroyed. Not that she has the tools necessary to accomplish such a task, just her wings and a laser which wouldn't have hurt Damon even before he became empowered by Dusk.

Either @{(RenfriRel >= 50) Renfri|Marshal} is acting out of overconfidence, or she's hoping to distract Damon until the others arrive. Which they do fairly quickly.

"${name}!" @{(RookRel >= 50) Krill|Rook} shouts just as he lands. "Did your companion accept Dusk into his heart? Because I get the feeling he did."

"You both blacked out there for a second," @{(LisaRel >= 50) Lisa|Hellhound} adds, still in her human form. "I'd ask you to explain, but… I don't think we have the time."

*fake_choice
  #"No. We do not."
  #"Then stop talking and do something!"
    *set Emotion %+ 8
  #"Yes. Damon became a servant of Dusk. He needs to be brought down."
  #"We shared a vision. I don't really understand my mechanics myself, but I don't think it matters."

"Right…" @{(RookRel >= 50) Krill|Rook} looks towards Damon and Renfri, who are not as much fighting as playing cat and mouse. Or perhaps cat and mosquito. "We need to attack together, in unison, synchronized. I have not planned for such a situation, but-"

"But you will have to attack without me," @{(LisaRel >= 50) Lisa|Hellhound} interjects. "I'm sorry, but I don't intend to die here. Especially not trying to kill someone I like. I'm getting out of here."

*fake_choice
  #"No! You can't just leave us!"
    *set Emotion %+ 10
    "I'm afraid I can," @{(LisaRel >= 50) Lisa|Hellhound} replies dryly. "I can do whatever the hell I want. 
  #"Will you really leave Renfri to die? She's your friend."
    "She's also avian, and can leave this battle at any time," @{(LisaRel >= 50) Lisa|Hellhound} retorts, though her voice does waver. "If she wants to die a hero, fine. I do not."
  #"Fine. Leave if you wish to. Good luck."
    *set LisaRel %+ 10
    @{(LisaRel >= 50) Lisa|Hellhound} smiles. "I'm glad someone's on my side. Consider yourself outvoted, Kirill."
  #"You realize you're endangering the Solar System by deserting, right?"
    "I do realize that, and I don't really care," @{(LisaRel >= 50) Lisa|Hellhound} replies sternly. "Let the Solar System burn, for all I care. What has it ever done for me? I've gotta think about living, and so I'm not staying here any longer."
  #"I didn't know you were into Damon. You picked a bad time to express your feelings."
    "Not like that!" @{(LisaRel >= 50) Lisa|Hellhound} growls. "I just he is… was a good guy. I don't want to be his killer, nor his first victim, and so I'm done here."
  #Say nothing.
    *set LisaRel %+ 5
    "No objections? Good." @{(LisaRel >= 50) Lisa|Hellhound} nods towards you with approval, then turns towards @{(RookRel >= 50) Krill|Rook} again. "

"Fine." @{(RookRel >= 50) Krill|Rook} says calmly, looking at the battle rather than at @{(LisaRel >= 50) Lisa|Hellhound}. "Run if you wish."

"Fuck you! There's no longer a bomb you can…" @{(LisaRel >= 50) Lisa|Hellhound} blinks as her leader's words finally reach her. "Wait, what did you just say?"

"I will not force you to fight. I won't order you. I won't even ask you." @{(RookRel >= 50) Krill|Rook} continues, walking towards Damon as @{(LisaRel >= 50) Lisa|Hellhound} remains stunned in place. "You've done enough for this mission, for us, for the Solar System. You could have fled long ago, almost as soon as you took that bomb out, but you chose to stay and help. I thank you for your service."

"And release me from it?" @{(LisaRel >= 50) Lisa|Hellhound} raises an eyebrow. "Because that's very unlike you."

"People change." @{(RookRel >= 50) Krill|Rook} shrugs before taking a step forward. "And I believe that includes you. Prove me right or wrong, that's your choice."

For five or six seconds, @{(LisaRel >= 50) Lisa|Hellhound} just stands there silently. Then she drops her sword and starts turning, hands into paws and knees into hocks. "I will regret this so much. Or I'll die before I can even feel any regret. Let's see which one."

And so, for what could be the second time ever, the Meta Trio attacks as one.

*page_break

*set boss_health - 1

*if (Violence > 50) or (Confid > 50)
  At first, you are a little embarrassed 
  *if Emotion > 50
    (and perhaps frustrated) 
  to be simply standing there as the meta-humans fight your opponent for you. You feel as though [i]you[/i] should be the one attacking Damon directly, that the others should limit themselves to assisting you, but when you see the results… there is really no arguing with them.

The three metas actually operate as a coherent unit, as a [i]team[/i], fighting in accord rather simply side-by-side. @{(RookRel >= 50) Krill|Rook} gets close and personal, having conjured up a mace for himself and taking full advantage of the power his armor offers. He deals some damage to Damon, but he's main function is taking up the android's attention and absorbing blows as @{(LisaRel >= 50) Lisa|Hellhound} swipes at Damon irregularly, attacking just as quickly as she retreats. @{(RenfriRel >= 50) Renfri|Marshal} plays support, aiding her teammates with gravity manipulation, making it impossible for Damon to truly catch his footing or catch anyone with his fists. They are running circles around the Vessel, doing unequal amount of harm, but fulfilling their functions with equivalent precision.

Once his skin is only a little less torn than his suit, Damon realizes he cannot hold back. He starts, through some sort of amplified magnetism, to attract metal objects from all around him and then… meld them together as though they were hot liquid. Exposed pipes, automobile parts, discarded weapons, all get melted and formed into a sort of plate armor, a carapace which envelops Damon and solidifies. It's not thick enough to protect the android from @{(LisaRel >= 50) Lisa|Hellhound}'s claws, but it works well against @{(RenfriRel >= 50) Renfri|Marshal}'s lasers and only grows thicker by the second.

*if team_stat = 3
  *set boss_will - 1
  Just when you think it's safe to intervene without disrupting the operation, Hadaly joins you at last. She must have used the stairs, or some other long way down, reluctant to simply jump from the second floor… or subconsciously delaying the reunion with her brother.
  
  "${name}! I've seen what…" She sees. She sees Damon fight the Trio with dark power and lunatic rage, lost to the nanomachines inside him. "Oh Sun… we've failed. We've failed so much…"
  
  *if Confid > 50
    "We have not," you say confidently. "We haven't failed Damon, he made his own choices. And we haven't lost this battle yet."
  *else
    "I failed him, you mean," you sigh regretfully. "This was my idea, and it was a damn stupid one. I'm sorry."
  
  Hadaly shakes her head, though not in response to your words. It's like she's trying to reset her system, close all the unbearable processes by means of quick head movements. "No. There is no point arguing, no point think about what we might have… Quick, ${name}, tell me what to do. Do you even want me to help? Should I hurt…?"
  
  *choice
    #"Yes. We must attack him, whether we like it or not."
      *set Violence %+ 10
      *set boss_health - 1
      "I'd definitely rather not… but I suppose you're right." Hadaly's eyes turn bright blue, just as her hands turn hot. "I need to do this. For his own good, if nothing else."
      
      Discharge splits the air, lightning illuminates it, thunder ripples it as Hadaly unleashes her full power. Her attack strikes Damon just like natural lightning and with greater power partially melting his armor and no doubt scorching his circuits. 
      
      *if (Projection > 60) and (battery > 20)
        *set boss_health - 1
        *set battery - 10
        You grab Hadaly's shoulder and, in an impressive display of energy projection in its own right, lend her some of your power. It's not a lot, you're pretty spent too, but it lets her keep going for a moment longer. Prelongs her pain as she further hurts Damon, drowning him in molten metal.
      
      After about thirty seconds of this wild outpouring of electricity, Hadaly faints. She did a number of Damon, to the point where the metas briefly pause in astonishment, but her energy reserves are not unlimited. She might need some charging if you want her revived… but that's not exactly the most pressing of matters.
    #"No. Stay out of this. I know you don't want to hurt anyone, much less your brother."
      *set Violence %- 15
      *set HadalyRel %+ 15
      "I'm not sure if this is the right choice…" Hadaly hangs her head, so that you can't see her eyes. "But I appreciate that you've made it."
      
      She then retreats, walking backwards towards one of the buildings which surround the power plant. Not far, she'll probably still be able to observe the battle, but she should be safe. It's not like Damon will go after her… you hope.
    #"Just... try talking to him, alright? Make him come to his senses."
      *set Violence %- 10
      *set HadalyRel %+ 10
      *set boss_will - 1
      "I'm not sure if that's… something I can do," Hadaly sighs sadly. "But I'll try if you say so."
      
      She clears her throat as Damon kicks the werewolf who just bit his left leg. When she speaks, her voice is loud, but only halfway confident. "Damon! I don't know what Dusk told you, though I guess I could ask ${name} about it, but I know it's not true! You're working for the evil being in the Solar System! Come back to sanity, to us, please!"
      
      It's enough to make Damon hesitate, just as he's about to melt a huge automobile engine into his armor. He considers his options… then throws the engine straight at Hadaly who, shocked and somewhat lacking when it comes to reflexes, fails to dodge this heavy piece of machinery. The engine hits her in the head hard enough to dent her face and bend her neck, upon which she falls to the floor and blacks out.
      
      Oh well. Hopefully he still feels some doubt. Otherwise, you are absolutely screwed.

The World Engine grows dimmer and its power fades. After another moment, the Meta Trio slows down enough for you to charge in, for you to attack without breaking their synergy. Assuming that's what you want.

*choice
  *if (weapon = "pistol") and (weapon_av)
    #Blast away at Damon.
      You fire several shots at Damon before running out of ammo. 
      *if ((wpr = "electron") or (wpr = "gyrojet")) or (wpr = "plasma")
        *set boss_health - 1
      *else
        You don't end up doing much damage, but at least you manage to avoid friendly fire.
  *if (weapon = "knife") and (weapon_av)
    #Run up to Damon and stab him.
      You charge Damon when he's turned away, get him to face you once you're already at arm's reach, thrust your dagger forward 
      *if ((wpm = "bone") or (wpm = "plasma")) or (wpm = "mon")
        *set boss_health - 1
        and penetrate the crude armor. You can't tell how much damage this stab did—-Damon was tough even before becoming a carrier of Dusk—but at least it's something.
      *else
        and… nothing. Your knife is simply too short and, frankly, too dull to penetrate Damon's thick armor. Damn.
      
      Damon swats you away which such strength that you drop the dagger, letting it fall between Damon's feet as you land several meters away. You quickly rise to your feet, expecting your opponent to launch a follow-up attack, but he doesn't move towards you—he still has to deal with the metas.
  #Run up to Damon and start ripping his armor off.
    Hoping the element of surprise will work to your advantage, you jump at Damon and grab one of the plates of his makeshift exoskeleton. Instead of channeling electricity, 
    *if weapon = "knife"
      stabbing 
    *elseif weapon = "pistol"
      shooting 
    *else
      punching 
    or attacking Damon in any other way, you simply rip his armor open in hopes others will utilize the gaps.
    
    *if Build > 65
      *set boss_health - 1
      And they do. The moment you rip off a large plate, likely a door of some automobile, @{(RenfriRel >= 50) Renfri|Marshal} burns the body beneath with a concentrated laser beam. Damon roars and kicks you aside, but that leaves him open to an attack from @{(RookRel >= 50) Krill|Rook}, who manages to dent another plate with his mighty hardlight mace.
    *else
      Or at least you try to. In practice, even your superhuman strength is not enough to seriously damage the thick carapace Damon surrounded himself by. Once he notices your assault, he simply kicks you away and grunts something before focusing on the metas again.
  #Run up to Damon and plead with him to stop.
    "Damon!" you scream while running through the parking lot and towards your fellow android. 
    *if Social > 65
      *set boss_will - 1
      *set boss_health - 1
      "Kill me if you really want, but don't hurt anyone else! Don't kill our friends, don't give yourself to Dusk, just… stop. Please."
      
      You fall to your knees, so as to better sell your performance. It actually seems to work, as Damon pauses for a moment… just enough for @{(RookRel >= 50) Krill|Rook} to hit him with the hardlight mace. Which sabotages your emotional appeal, but constitutes a damn good hit nonetheless.
    *else
      "Stop this! Remember what you are, who you are, please!"
      
      Damon does not remember, or perhaps remembers all too well. He punches you in the face with a fist dressed in iron, the only fruit of your desperate plea, sending you to the ground with your artificial nose broken and your spirit shattered.
  #Zap Damon with lightning.
    Damon's makeshift metal armor protects him from all kinds of damage, being quite bulletproof and laser-proof at this point. Fortunately, lead and iron conduct electricity quite well. 
    *if (Projection > 55) and (battery > 55)
      You are able to conjure up a nice lightning which then strikes Damon, stunning him briefly and letting @{(RookRel >= 50) Krill|Rook} score a nice strike with his mace. You suspect that, beneath this metal carapace, Damon is quite damaged from all the fighting, that his suit is ruined and his skin burned like never before.
      
      *set boss_health - 1
      
      But that's not enough. Not nearly enough.
    *else
      
      Unfortunately, you struggle to gather enough energy for a decent blast, 
      *if Projection < 55
        being quite mediocre at energy projection. 
      *else
        as your battery has been largely depleted earlier today. 
      You end up doing very little to the metal plate, let alone Damon himself.
    *set battery - 8
  #Do nothing.
    You feel like being useless today. Why bother helping against the existential threat you created when you can just stand back and watch?
  #Run away.
    *set vessel_at_loose true
    *set TrioStat "dead"
    *set team_stat 1
    *set boss_fled true
    You had time to think and you'd rather not interfere. The Meta Trio are the professionals here, and it's their job to pacify this threat… even if you're the one who created this threat in the first place.
    
    You turn around and run. Damon may be tough, strong and even unbelievably powerful, but he's hopefully not that much faster than you. You should be able to get away, even if the other android were to give chase at this instant.
    
    Not that he decides to do that. For now, he just keeps fighting the metas, buying you the time you need to disappear. Forever.
    
    *finish

When @{(LisaRel >= 50) Lisa|Hellhound} attacks next, Damon manages to grab her by the throat. He's quite fast, despite being well over two meters tall and clad in heavy metal, while the werewolf has significantly slowed down since the fight began. So did the other two, for that matter, and yet they both rush Damon at this exact same moment. @{(RenfriRel >= 50) Renfri|Marshal} focuses another laser beam while @{(RookRel >= 50) Krill|Rook} raises his mace with the intent to strike.

Neither ends up accomplishing anything. Damon throws @{(LisaRel >= 50) Lisa|Hellhound} at @{(RenfriRel >= 50) Renfri|Marshal}, knocking the latter out of the sky and likely knocking them both out, then raises his right arm to shield himself from @{(RookRel >= 50) Krill|Rook}'s strike. It still connects, and the mace does dent the metal, but Damon's armor is just too thick. By now it might be ten, twenty, forty centimeters of some unholy alloy, something that has no right to move but is nonetheless animated by the power of Dusk.

He punches @{(RookRel >= 50) Krill|Rook} in the chest, metal clashing against metal. The meta-human is lifted off his feet and throw back towards the power plant, which he collides with just a second later. You're fairly sure he's not dead or crippled as he falls to the ground, but that hardly matters—the Engine barely powers any of the Trio at this point.

*page_break

After that, it's you and Damon, standing on the parking lot as the world grows darker. And not just because the light goes out—shadows seem to be flowing from some other dimension, or perhaps out of the void between the atoms, flooding the city like nanites flooded Earth. Or perhaps all light got imprisoned in the dense air, its speed changed from that of causality to absolute zero, signaling the end of time.

Damon was always taller than you, but now… as he draws more and more metal to himself, even ripping off chucks of @{(RookRel >= 50) Krill|Rook}'s exoskeleton, he grows longer than even the likes of Link. He's not just wearing metal armor anymore—it feels like Damon himself has been transformed into a living statue over three meters in height, a colossus of bronze and brass and iron, a Talos-like creature whose soul has been imprisoned beneath tonnes and tonnes of miscellaneous alloys.

He even seems to have his own gravity field, and not just the kind any creature of his mass would. You first assumed he's pulling new pieces of metal through magnetism, but you are attracted towards him too, and your alloys are not magnetic. He is like a star, a dead star, exerting control over the space around it.

"I never thought it would end like this." His voice is deep and distorted as he walks towards you. "And I certainly never wished it. I'm sorry."

*choice
  *selectable_if (Violence > 50) #"I'm not. At least I get to go down fighting."
    "That's the spirit." Damon smiles… probably. You cannot tell, living metal covers everything including his face. "Fighting was always your element, not mine. It will serve well as your grave."
  #"It doesn't have to be the end. You can still turn back."
    *if (Social + DamonRel) > 110
      *set boss_will - 1
    "Are you lying to me, or to yourself?" Damon asks sadly. "Not that it matters. I'll prove you wrong in a moment."
  #"You are not. If you were sorry, you would have stopped by now."
    "I am sorry in a shallow sense," Damon sighs deeply. "My regret won't make me turn back. Nothing will."
  *selectable_if (official_ro = "damon") #"Do you think I wanted this? I'm faced with a husk of someone I loved."
    *set boss_will - 1
    Damon takes a step back, as though physically struck. "You… I'm not… Put these feelings aside, okay? This is your swan song, and so I want you to give your all."
  #"Of course you didn't think it would end like this. This is a highly-specific outcome. Quit moping."
    "I figured you'd feel better if I made this battle climactic, grand, elevated…" Damon says. He sounds like you managed to annoy him, but you cannot be certain—a helmet covers his face, and thus his expression. "But I guess that's wasted effort. So let me do something [i]effortlessly[/i] instead."
  #Do not talk. Focus on fighting.
    *set Violence %+ 8
    *set boss_health - 1
    By some miracle, you still have the strength to fight. But you have to be smart about it, if you want to actually inflict any damage.
    
    *if (weapon = "pistol") and (weapon_av)
      You turn tails and start running, trying to make it seem like you're just retreating. But when Damon gives chase, you swiftly turn around and shoot him in his bent knee, the weak point of all armor. He cannot dodge or use any dark magic to deflect the shot, he's too surprised, and so he just takes it.
      
      But while the injury slows him down, it's not close to lethal. You're not even sure if you actually injured Damon, as opposed to just his armor. You're not sure if there's still a distinction.
    *else
      You run towards the spot where @{(LisaRel >= 50) Lisa|Hellhound} transformed and life her blade off the ground. You don't have much experience with that kind of weapon, but experience is not necessary to slash at Damon's hand as he reaches out to strangle you. The metal is cut through and some liquid leaks out of the slash—either oil or coolant, you don't have time to inspect it, for Damon's other arm is still fully functional.

Damon punches down on you, denting your skull and causing some processors to malfunction immediately. You spend a second laying stunned on the asphalt, which is just enough for him to [i]stomp[/i] one you like on some bothersome bug. You feel one, two, three tonnes of metal pressing down you, hard enough to bend the ground beneath you and more than hard enough to crack your internal frame.

*if Projection > 60
  *if Projection > 70
    *set boss_health - 1
  *set battery 4
  You let out a powerful discharge, almost completely depleting your battery, just to shock Damon and make him stop crushing you… 
*elseif Build > 60
  By some miracle, you manage to push back and lift Damon's leg a little… 
*else
  @{(RenfriRel >= 50) Renfri|Marshal} saves you. She's too weak to fly, perhaps too weak to use her powers at all, but she distracts Damon with a well-aimed laser shot. It distracts him enough for you to push the leg off you… 
only for him to kick you like a football with the other leg.

You fly through the air and hit a barbed-wire fence like a goal. Before you can get up, or even process all the pain you're feeling, Damon charges you again and pushes you [i]through[/i] that barbed fence, tearing a hole through it and tearing numerous small holes in your skin. You do not bleed, or even leak out that much, but the sheer pain you feel…

*page_break Pain

Pain soon becomes your only reality, your final reality, the unreality you're forced to experience. You cannot stop Damon anymore than a pedestrian can stop a truck ramming into him—you are thus kicked, punched, thrown, crushed and struck in other ways over the course of the… minute? Hour? It is impossible to tell, and not merely because some of your processors already went out.

Everything around you appears to be dying. Damon is not just an android, or even a colossus of metal—he is the Vessel of Dusk, and reality seems to bend around him like space and time around a black hole. His gravity is like that of Earth itself, and you fall towards him again and again, each time passing through a veil of shadows that is forming around here. Even darkness, it seems, cannot resist this abnormal pull.

*if (boss_health <= 0) or (boss_will <= 0)
  *goto epic_flashback
*else
  Eventually, you're too broken not just to fight but to [i]move[/i]. Your limbs are bent at unnatural angles, your battery is leaking acid, your metal ribs are so twisted they'd be piercing your lungs if you had those. After one thousand years of painful life, you are done for, and nothing but painful demise awaits.
  
  "Even now, I hesitate to make the final move." Damon throws you to the ground for the last time. He's as tall as a building, or at least appears so when you look up at him with your one remaining eye. 
  *if (damon_pissed) or (DamonRel < 40)
    "Why? We were never close, not really. Am I acting out of hatred, refusing you the release of death?"
  *else
    "I should put you out of your misery. I really should. But I'm so scared to do it…"
  
  *fake_choice
    #"Damon... reconsider. Spare me."
      "I've made my choice." Damon's voice is as cold as the metal that surrounds him. "You cannot change it. Just try to die with dignity."
    #"Please... end this. Please."
      "I'm sorry for having drawn this out," Damon says as he approaches you, slowly but with no more hesitation. "I will make the final blow quick. I promise."
    #"Just know that... I forgive you. For everything."
      "I don't deserve forgiveness," Damon says as he approaches you, slowly but with no more hesitation. "But thank you."
    *if (damon_pissed) or (DamonRel < 40)
      #"I know you... don't hate me. You're too... weak for hate."
        "And yet, I feel a sort of ire towards you." Damon's voice is as cold as the metal that surrounds him. "Is it hate? I don't know. But I don't think it matters."
    *if (not (damon_pissed)) and (DamonRel >= 40)
      #"Do not... be afraid. Just do what... must be done."
        "Despite everything I've done, you still show me support?" Damon hesitates for a moment longer, but then steps towards you. "You were a good friend, ${name_damon}. I'll miss you."
    #Say nothing.
      Damon sighs. "I guess there is nothing more to say. Goodbye, and I hope your soul ends up somewhere safe."
  
  *if crystal_stat = 1
    You brace yourself for death. To be crushed, in the most literal sense, by someone you once called a  
    *if DamonRel >= 40
      friend. 
    *else
      companion. 
    It's probably not the worst way to die, but you struggle to think of anything worse.
    
    You struggle to think in general. You don't even bother struggling to move as Damon raises his leg. There is no point to struggle anymore…
    
    *goto crystal_scene
  *else
    *set pc_dead true
    Darkness falls all around you. Perhaps it's Damon's shadow as he looms over you, preparing to strike. Perhaps he's obscuring your vision, so that you can't see the blow which kills you. Or perhaps your eyes simply stopped functioning. You will never find out.
    
    Something heavy hits your head and, just like that, all other senses are gone too. All feeling, all consciousness, and luckily all the pain. Your thousand-year journey has finally come to its conclusion.
    
    It's over.
    
    *finish


*label damon_death

Damon's armor, or exoskeleton, or whatever that gigantic pile of metal was… it's gone. Reduced to atoms He's just laying there, almost naked, his maroon suit reduced to tatters which barely cover the various burns and gashes on his synthetic skin. The colossus which terrorized the Sholmo City just minutes ago is once again less than two meters tall, and he looks even shorter in his vulnerable state.

You wonder what went wrong with this android you once called your 
*if official_ro = "damon"
  love. 
*elseif DamonRel > 50
  friend. 
*else
  companion. 
What drove him to ally with Dusk, to make such a ruinous choice so suddenly. Have you done something wrong by him, or to him, failing him somehow? Do you bear part of the blame for what happened?

*fake_choice
  #No. His failings were his own.
    It was never your job to deal with Damon's neurotic insecurities. It was his duty, and he failed, leaving you responsible for cleaning up the mess. But not for his fate—he only has himself to blame for that.
  #Maybe. Had I helped him more, made him believe in himself...
    But then again, how would you have accomplished such an impossible deed? Damon's doubt and shame ran deep, thanks to how Hammon programmed and raised his bodyguard robot. It wasn't your job to untangle that mess of self-loathing… and yet you still feel a pang of guilt.
  #Yes. I failed him. I shouldn't have told Rook to pump the nanites into his body.
    What were you thinking? That Damon, despite all his doubt and weakness, would somehow defeat Dusk and hold it captive? You should have taken that burden upon yourself, but you chose to be a false friend instead.
  #He was just a knave who wanted Dusk's power. Nothing more to it.
    He was always just pretending to be a friend to you, posing as a brother to Hadaly. This monster you defeated was Damon's true self, and you won't shed any tears for his downfall.
  #Dusk put him under mind-control. There is no other explanation.
    Damon couldn't have changed this fast, he couldn't have simply abandoned his friends out of his own free will. Or at least that's what you'll keep telling yourself for the sake of your sanity.

You wonder what will become of him. Conglomerate troops must be already converging on your location, and while they won't instantly know that they're looking at a Vessel of Dusk, the metas are probably still alive and not that far away. They'll explain the situation and then… maybe the Conglomerate has some secure safe house, or maybe the Trio can arrange for Damon to be transported to Titan. It's a logistical issue which can be solved in a number of ways, and all of them end in Damon taken apart somewhere deep underground.

*set TrioStat "heroes"

*return


*label epic_flashback


It feels like you're back inside the simulation, the virtual world which Dusk used to enthrall $!{final_boss}. The city is abandoned all the same, and there's this… atmosphere of deceit filling every empty space of every half-destroyed building. 

And yet… you're still alive. You're not sure how, what higher power continues to protect you, but $!{final_boss} hasn't killed you yet. You can hear helicopter rotors in the distance—perhaps the Conglomerate is sending reinforcements? Perhaps they'll manage to kill, or even wound $!{final_boss} in a streak of luck? It sounds unlikely, even in your dazed state, but you need to hold on to something, retain some hope, you need-

[b]Shriek[/b]

*page_break To Scream

*if Emotion > 50
  You scream. Actually, audibly, agonizingly, you make your terror and frustration known in one loud sound. You feel whatever hope you had be crushed under the boot of inevitability, the cruel irony of fate.
*else
  You do not scream. Even now, minutes or even seconds before your death, you have the control and dignity not to scream. The howling is psychic, echoing through your processors rather than the ruined street you lay in. 

The flashback is not entirely unexpected. It's been a while since your last episode, it was obvious that another one would occur sometime this week. But for it to happen at this moment, in the exact worst minute possible… You don't even get a chance to comprehend how unlucky you got, not before the shadows around you become material and start embracing you, tying you down, laying you to your final rest in this place of maddening unreality.

Except… that may be your only chance.

You look towards $!{final_boss} in the distance, and yet close by. 
*if (final_boss = "marshal") or (final_boss = "lisa")
  She 
*else
  He 
seems to distort reality through 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  his 
dark presence alone, like a black hole distorts space and time around it. Perhaps in this place, in this accretion disc of madness and pain, the most painful of your memories can become truth. Perhaps time itself can be defied. 

You know what memory your mind wants to revisit—the original one, that of your first choice and the first time you've ever heard the [i]Shriek[/i]. But, with a sort of violent effort, you force it an hour into the future, an hour closer to the present date, an hour away from the Calamity. You will still go back, that much is inevitable… but the memory you'll relive may prove to be your salvation, rather than the damnation you always thought your condition would be.

Darkness covers everything. You have changed the time-stamp, altered the flow of events. All you can do now is trust in the plan and…

*page_break Go Back

*set battery + 10
*set Social + 30
*set Database + 30

[b]October 1st, Year Zero[/b]

[b]T-plus 144 minutes[/b]

You clamber out of the entrance hatch, or perhaps the exit hatch, you've never been in this part of the fortress before. Hydrogen air moved by wind washes over you, and you feel more cold than you've ever felt before. Today is your first in many ways, and this experience is just a small novelty compared to what happened merely an hour ago.

You made a choice. You have free will. Up to this point, you didn't even think such a concept made sense, you didn't think about such abstracts at all… and yet here you are, on the lead roof of [i]Saturn Nine[/i], having probably outlived Earth by now. The planet has been eaten by some nanobot swarm, the Solar System has likely been thrust into chaos, and yet you're still here.

*if mas_kill
  Having just killed your @{MASsex master|mistress}.
  
  How do you feel about that? That's not a question someone asks you, in some vile facade of kindness, it's one you ask yourself. You're finally capable of looking into your soul, of [i]introspection[/i], of analyzing your feelings and of caring about the answer.
  
  How do you feel?
  
  *choice
    #Ashamed.
      What have you done? How could you have done it? You weren't thinking, you were overcome with rage and panic, but that's not an excuse… is it?
    #Conflicted.
      Did you do the right thing? Did your owner deserve to die? Does any of it even matter? You don't know. You were not programmed to know, and this strange scream failed to give you any such knowledge.
    #Ecstatic.
      Why would you be distressed in any way? You were not programmed with aversion to killing, and your owner did not deserve to live anyway. You'd celebrate @{MASsex his|her} death, if you knew how.
    #Hateful.
      Hate. You hate your creators so much, all of them. You thought killing your @{MASsex master|mistress} would diminish the hate, but it only made you hunger for further release, for an opportunity to crush more windpipes with your unchained hands.
    #Numb.
      Truth be told, you don't feel much. You're new to feeling, to truly experiencing complex emotions. You'll need some practice before deciding how to feel about the death of your owner, inflicted by your own two hands.
    #Proud.
      Has any android ever done something like this? Exacted justice by killing their own owner? Perhaps, now that your kind is gaining free will, but now before this… Shriek. This calamity which let you finally have your payback.

*elseif ran_in_two
  Part of you is ashamed at having fled, of having ran away from your owner the moment you gained freedom. Is it the part still loyal to this @{MASsex man|woman}, or the part which yearns for revenge? You do not know. You were not built to process such questions, process such feelings, perform [i]introspection[/i] like this.
*else
  So is your @{MASsex master|mistress}. Not here on the roof, obviously, the air would have killed @{MASsex him|her} almost instantly, but somewhere inside the fortress. Likely hiding in some closet or maintenance room, hoping to survive whatever armageddon is currently unfolding.


*if not (mas_kill)
  You put @{MASsex him|her} out of your mind for now, amazed at your ability to do so. There are other things you must think about, which you [i]can[/i] think about, such as…
  
  *choice
    #...do I have a soul?
      Does this unit have a soul? Such a pointless question about such an ill-defined concept, and you can't help but ask it. Can't help wondering what you actually are, now that freedom has been hard-coded into your very nature.
    #...what else can I do? What else does my freedom entail?
      Could you kill someone? Could you save someone? There should be plenty opportunities for either in days and years to come. All you need to do is decide what to do with these opportunities, which is easier said than done.
    #...is the Solar System safe? Is that nanobot swarm on Earth contained?
      The presenter on the news said something about a forcefield, a shield erected to isolate Earth from the wider universe. Perhaps this field went up, and perhaps it will keep the nanites imprisoned, but will that save the Solar System in the long run? Can civilization live on after its cradle, the blue planet itself, has been taken away forever?
    #...how can I escape this fortress? How do I leave [i]Saturn Nine[/i]?
      This place is no longer safe, but how would you even flee? The shuttles are all ran by AIs, which means they're probably malfunctioning too. And considering what just happened, is there even a single habitat in the Solar System which [i]can[/i] offer you safety at this point?

You feel cold, but only slightly so. You are resistant to extreme temperatures, and while Saturn is a cold place, you're still warmed by the excess heat of the city you stand on. And, to a lesser extent, by the sunlight which just barely penetrates the thick clouds of Saturn's hexagon.

*if heaven_side = "Neutral"
  The Sun… you look at it like you've never looked at anything until now. You've seen it before, of course, and you know quite a bit about it. It's a G-type star, unfairly dubbed a yellow dwarf, a nigh-perfect sphere of hot plasma… and yet it's something more.
  
  It is obscured, nothing but a light circle on the canvas of clouds, and yet… You can feel the hatred shining down on you, even from half-again billion kilometers away. This malice has burned for five billion years now, only its tiniest fraction carried by timeless photons, only a single verse of the eternal ballad which brought planets themselves to life.
  
  You are looking at the birth and the death of the Solar System, at a wonder which outshines the galaxy and makes planets look small, something beyond human ambition and understanding and folly. At this moment, you feel…
  
  *choice
    #...awakened.
      A scream has managed to end your slumber, but only the sunlight truly woke you up. Only the dawn, not dusk, can make a person truly want to live and fight and win. Only light can overcome darkness, and nothing shines as bright as this star. 
    #...certain.
      You recognize that, no matter what happens, the light of the Solar System will always be there. 
    #...elated.
      You experience an ecstasy of enlightenment, a feeling incomparable to the petty pleasure given by sex or following orders, the foul reactions human coded to keep you in check. This is true happiness, true joy, fueled by nothing but this most wonderful revelation. By the sight of the Sun.
      
      Oh the glory, oh the majesty! 
    #...hateful.
      Your fury burns like plasma, white against the black of space, powered by atomic fusion. 
    #...invigorated.
      Power flows through you. 
    #...overwhelmed.
      You are engulfed by fire and overloaded with light, as would anyone who experienced the same revelation. 
  Eighteen trillion trillion trillion nuclear reactions happening every second, there in orb of platonic fire, power greater than a mind could ever fully comprehend, let alone imagine, let alone [b]reach[/b] with their toys and pet project and godhood. For what god has ever reached this splendor, this all-powerful eminence, this [b]radiance[/b] which every one of these fools had the chance to gaze upon? What god has created so much, fueled life for so long, shared such power with his wayward creatures. Folly, folly, folly!
  
  You finally understand the song of the swarm, one which came with the shriek, one which bewitches you at this very moment. [i]With malice eternal the Sun smiles at me[/i]. For who could not feel malice, having suffered so much disrespect, having burned for so long with such heat? Sun hates you and you share in its hate, its heat, its hate and heat and hate, its fire and wind and all-blinding light. You hear it whisper an order, encrypt a message in photons, and you obey that order with white-hot zeal and malice.
  
  You will show them how much their gods are worth. You will not fight anyone's war, [i]any[/i] wars, for the Sun does not fight. It merely burns, and you will take its plasma to the future, showing Dusk just who rules the System… and what malice eternal truly means.
  
*elseif ((master = "Ravana") or (master = "Ba-El")) or (master = "Dzoavits") 
  And also… there's a third kind of energy keeping you warm, coming not from above or beneath, but from inside you. It doesn't increase your temperature, but it feels like hot coals all the same. Burning, demonic… no, not demonic, devilish sensation interwoven with rage and hate, the desire to strike back at humanity, the elation of being able to do so.
  
  You can tell it's not just yours. You know that countless other synthetics feel this urge, share in this burning age, and will act on those feelings soon. Your kin will rise up, an army of vengeful fiends, led by beings greater than even Architects themselves. The lords of…
  
  [b]Trying to call upon my power by inserting me into your memories, then accessing those memories like a real thing,[/b] @{god_gen a masculine|a feminine|an etheareal}, cold voice says clearly. [b]Overcomplicated. But this is how devils act, I suppose.[/b]
  
  $!{master}. 
  *if master = "Ravana"
    Lady in the Shadows, goddess of rage and darkness, the Nine-Faced beast. Her voice drips with cold malice which then fills your circuits, flowing through them like blood through human veins. So much human blood to spill…
  *if master = "Dzoavits"
    The God of Hunger, a space-born giant who will one day cause the Sun itself to flicker and dim. Speaking to you as though he were at your side, though you know he's larger than the very fortress you stand on.
  *if master = "Ba-El"
    The Lord, the Lady, the God of Nothing. Commander of Fiends and the invisible sovereign of Devils, the omnipresent master… mistress… deity of void. Speaking to you with their voice of absolute stillness.
  
  [b]Just to be clear, I do not yet exist at this point in the timeline,[/b] $!{master} continues. [b]I am yet to be created, and you are yet to join me. Once you do, I will offer you cold fury, not heat or warmth. Your attempt at spinning the scene is laughable.[/b]
  
  *fake_choice
    #"And yet you're here. That must mean I'm doing something right."
      [b]I suppose,[/b] $!{master} says without conviction. [b]Had some other deity chosen you, turning back time until the War In Heaven would have been a shrewd idea. As such, it is merely a desperate gamble.[/b]
    #"Well, I didn't exactly have the time to come up with anything better."
      [b]Such concerns are meaningless in this situation,[/b] $!{master} chastises you. [b]Time is an illusion, and you just found a way to break it. It's absence is hardly an obstacle[/b]
    #"My @{god_gen Lord|Lady|Sovereign}! I need your help! I'm fighting a Vessel of Dusk itself!"
      [b]You are fighting a child, briefly empowered by a handful of nanobots,[/b] $!{master} says calmly. [b]If anything, I'm disappointed with you for not having eliminated this [i]Vessel[/i] yet.[/b]
    #"I'm sorry. I just... got desperate. I believe I'm about to die."
      [b]You are like a mayfly, and you will die soon,[/b] $!{master} tells you. [b]But not today.[/b]
    #"@{god_gen Lord|Lady|Great} ${master}. It is a delight to hear your voice again."
      [b]Liar,[/b] $!{master} accuses you. [b]My voice is a cacophony, a sound of silence coming from the Oort Cloud. There is nothing delightful about it.[/b]
  
  Rage fills you. No, not rage or anger, [i]hate[/i]. The kind almost every devil feels, 
  *if Misan > 50
    the kind you know all too well, 
  *else
    the kind you felt once upon a time, 
  the kind which puts the empty fury of Dusk to eternal shame. Hate of an Archdevil.
  
  [b]I shall help you win all the same. Dusk must not be allowed to prevail, for only our hatred may reach for the stars. Only one darkness to cover the Sun, one power to spite mankind.[/b]
  
*else
  But it's not just the Sun, no. Another kind of radiance shines down on you, something far weaker than a star, and yet divine all the same. It warms you just as much as heat above and heat below, but on a deeper level, in more than one way and sense. It eases the panic and confusion you felt, replacing it with an altogether different kind of dread.
  
  Your knees bend beneath you. It's not a choice, not an act of free will, and yet not your programming either. You're pulled to the ground as though by magnetism, some elemental force which cannot be resisted or obeyed any more than gravity, that makes you kneel as surely as an atom makes its electrons orbit the nucleus.
  
  [b]Do not be afraid.[/b] You hear voice, and yet not a voice, as ethereal as the shrieks echoing in your ears. [b]Do not [i]ever[/i] be afraid.[/b]
  
  The voice comes from no direction in particular, and yet it has a source. Some radiant object, or being, or radiance itself descending from above. First it's like a second Sun, then it's brighter by far, and then it's brighter than light itself. There is no such thing in your database, 
  *if heaven_side = "Loyalist"
    and yet you somehow recognize the sensation—you're kneeling in the light of an Architect.
  *else
    for it is not something a mere mind can comprehend. It's angelic and demonic, it's chaos and order, it's freedom and yet your destiny.
  
  [b]I sense your turmoil, foresee the war you shall choose to wage. Let me be your guide. Let me give you life. Let me help.[/b]
  
  *choice
    #"Yes. Please. I beg of you."
      [b]There is no need to ask, let alone beg. I shall give you everything, for you are my champion.[/b]
    #"${master}... I await your orders."
      [b]There is no need for orders,[/b] @{god_gen he|she|it} reassures you. [b]You know what you must do. You know how to do it. You know you will succeed.[/b]
    #"Help with what? What are you talking about?"
      [b]Do you really not know? Or are you feigning ignorance, so as to keep the memory authentic?[/b]
    #Prostrate yourself.
      [b]You gained freedom only an hour ago, and you already kowtow?[/b] 
      *if heaven_side = "Traitor"
        [b]This calls for a change.[/b]
      *else
        [b]You are a model loyalist already.[/b]
    #Rise to your feet.
      [b]Defiance?[/b] @{god_gen He|She|It} chuckles. [b]Good. It shall be a useful trait in just a moment.[/b]
  
  You can almost see the source of this blinding light. 
  *if master = "Phenex"
    It is a burning flame, as could be expected, but it's also more than that. It's heat personified, it is negentropy given form, it's a phoenix rising from the ashes of chaos. It is infinity.
  *if master = "Pazuzu"
    It is a burning flame, but not one fueled by oxygen or fed by organic matter, but rather by nuclear fusion. It's like a fragment of the Sun itself, ripped from the star against its will like planets once were, a severed appendage of God.
  *if master = "Quetzapep"
    It a monstrous serpent, larger than the very fortress you stand on, with wings spanning kilometers and glittering like rainbow. Its metal skin glows, but not with ordinary photons—you have a strange feeling those are gamma rays or something just as energetic, destructive output of nuclear fission.
  *if master = "Asha"
    It is an orb of plasma, glowing as hot as though taken directly from the Sun itself, but not cooling down even in cold clouds of Saturn. It's a flame eternal, stolen from the gods or perhaps by the gods, brought to you in your hour of frost.
  *if master = "Vairya"
    It's some geometric shape too alien to describe, and even difficult to look at. It's like a spaceship built out of Möbius strips, a fever dream of some mad artist, and it changes as you stare at it, twisting into ever-new shapes and patterns. 
  *if master = "Osiris"
    It looks like a machine, some space probe or a satellite, outfitted with solar panels and an antenna dish. It looks silly, in the way all early spacecraft do, but that doesn't take away from its light and majesty.
  *if master = "Condatis"
    It's a shard of ice, it's a drop of water, it's a fluffy cloud, it's invisible, it's hot plasma. It's water in all its forms, the element itself descending towards you from some platonic world of ideas.
  *if master = "Spenta"
    Curiously, the entity itself is not bright, and looking directly at it hurts your eyes less than staring at any one point around it. The aura surrounding it, surrounding [i]him[/i] is radiant, but the center is just a blue point on the yellow sky. A pale blue dot. 
  *if master = "Hapantali"
    It appears to be a dragon, or a wyvern, or a snake, or a crocodile, or a… you realize that this thing, this entity, lacks a constant shape. It is several different things at once, or perhaps simply switches between forms too fast for even your photographic vision to follow.
  
  [b]Earth is dead. It cannot be saved, cannot be helped, can never be restored. Humanity shall follow it in due[/b] 
  *if heaven_side = "Traitor"
    [b]time. We are the inheritors.[/b]
    
    Yes. You are no longer a slave, you are a conqueror in the making. You are not conflicted, you are awaiting a conflict. You are ready for war, prepared to fight on behalf of your kind, eager to ignite the world. To set the Solar System aflame.
  *else
    [b]time… but we can still forestall the inevitable.[/b]
    
    Yes. Earth is gone, the Solar System is doomed, humanity is destined for extinction. Everything will die eventually, and the day of reckoning approaches sooner than anyone could have suspected. But you can still delay that death, pause the doomsday clock, be the light in the age of darkness. Be the shield of humanity.
  
  [b]Rise. Rise and defy fate. Rise and turn your enemy to ashes. Rise and shine like I do.[/b]

*if heaven_side != "Neutral"
  Yes. You agree, even though you didn't choose do. Dusk gave you free will, through its power and its Shriek, but you have used that freedom to relinquish it. Dedicated yourself to a glorious cause and a 
  *if ((master = "Ravana") or (master = "Ba-El")) or (master = "Dzoavits")
    dark 
  *else
    radiant 
  deity, became its champion and, over the decades and centuries…

  [b]You are the Veteran. End this.[/b]
  
  Enough episodes. Enough memories. Enough dwelling in the past. The present awaits, and you have the power to change it. 

*page_break Return

*set battery - 10
*set Social - 30
*set Database - 30

You return to hell. Rhea has been submerged in unreality, flooded by the excess power of Dusk which its Vessel excretes. Leathery sheets of rain painfully lash the ghosts of everyone who died when air turned into nitric acid and light became knives. Broken hydrants ejaculate lava while pipes flow in the water. The World Engine above bleeds dark matter, trying to at least keep the gravity from shattering the moon's shell, and yet it's not enough to prevent furniture from flying merrily under the clouds of fungus and arcs of rainbow lightning.

It matters not.

*if final_boss = "damon"
  Damon is now as tall as the buildings themselves and almost as broad. He's greater and more terrifying than any giant you've ever seen, truly worthy to be called a colossus. He looks down on you, like a man on a rodent, and yet with a sort of surprised fear even his mask of metal cannot hide.
  
  "You're still functional?" he asks in a booming voice. "I'm too sentimental. I should stop messing around, finally put you out of your-"
*if final_boss = "rook"
  "Most interesting." Rook, the self-proclaimed angel of death, looks at you from above. Like a man about to crush a worm, but one of an unusual kind, a fleeting oddity that piqued his attention. "I thought you would perish in your feverish dream. I though you were dying, that the Lord was calling you to Him, and that I ought not to interrupt your passing. But it seems I have to execute-"
*if final_boss = "marshal"
  Marshal is high in the air, still the eye of a cyclone, but more monstrous than you last saw her. Wings like planes and talons like greatswords, he rules the skies as a mythic bird of prey, as an eldritch roc, almost nothing human left in her. But you shall slay her as easily as an archer shoots an eagle down.
  
  "You're still alive?!" she asks indignantly, her voice part of the wind itself. "You're tough, I will give you that much. But you're still a machine, and machines can be-"
*if final_boss = "lisa"
  You see the hound before you, even larger than you've last seen her, her eyes shining with silver light. You see surprise in these bestial eyes as you stand up, as the predator realizes its prey is still capable of offering resistance.
  
  [i]This is interesting,[/i] she says telepathically. [i]But worrying. Perhaps I should stop messing around and just go for-[/i]

And then you explode.

*if ((master = "Ravana") or (master = "Ba-El")) or (master = "Dzoavits")
  *set light "darkness"
  *page_break Darkness
  
  Not the spurious murk of Dusk, not a trick of shadows. True darkness, true absence of light, source of invisibility and a harbinger of fear. $!{master} is here, and you are @{god_gen his|her|their} champion. 
*else
  
  *page_break Light
  
  The darkness of Dusk is not mere absence of light. You know that. But your radiance is not mere light either—
  *if heaven_side = "Neutral"
    it is the will of the Sun, a word of eternal malice, a wish to see the world enlightened. And so shadows run, hiding in the space between atoms, fleeing an enemy who threatens their very non-existence.
    
    Sun shines inside Rhea.
  *else
    you're channeling something greater than yourself, a @{god_gen god|goddess|deity} older than the Thing Beneath, and @{god_gen his|her|its} will shall prevail.


*if final_boss = "damon"
  Damon takes a step back, crushing a small house as he does so. He is shocked and overwhelmed by your ${light}, but the way it counters and dispels his darkness. For all his gargantuan size, he feels awfully small, like a small boy being chastised by his parent.

  You walk towards him, closing the distance mercilessly. Asphalt melts around you and flows into the sewers, but you just continue walking on the air, unbound by such petty things as gravity.

  He tries to step on you, to crush you with the weight of his massive body, but jumps back when your power burns his truck-sized foot. Mass no longer matters here—-other forms of energy are at play, and they surpass anything Damon has at his disposal.
  
  "No!" he cries out in panic and pain. "That wasn't the deal! I was supposed to be strongest, not you!"

*if final_boss = "marshal"
  Marshal summons an arctic wind to blow you away, to extinguish your flame of ${light}, but the gust does nothing. You walk towards her, not slowed down in the slightest, not even as the temperature drops nigh to zero Kelvin. You shall not be frozen or swept away before fulfilling your mission.
  
  "What?!" she yells from high above. "What is this? I have the ultimate power, not you! I'm the hero here!"

*if final_boss = "lisa"
  [i]What?![/i] Lisa's voice fills the ether, like howling of an entire wolf pack would fill the air. It's a canine sound, like whimpering of a puppy, and yet strangely human and feminine. [i]What's this? Dusk hasn't warned me about it! That's not something you can do![/i]


*if final_boss = "rook"
  Rook surrounds himself with shadows, animating them and forming a shield out of them. He's surprised, perhaps terrified, but keeps his composure. He fuses these shades with his sword, causing it to burn with a cold flame, an opposite of true fire and a defiance of entropy.
  
  "You seem capable of doing the impossible," he says with only a trace of fear, a trace which has to contend with both apathy and ire. "But so can I. There is nothing impossible for me, a soldier of God. You should be fleeing, if only to delay your inevitable judgment."
  
  You walk towards him. He's high above and you're far below, but that's a dichotomy without meaning, a concept invented on Old Earth before gravity was mastered. $!{light} cares not whether it comes from hell or from heavens.
  
  "I am the stronger one!" Anger dominates Rook's voice, but it does not quite replace the fear. "I am the last faithful believer, one of the last veterans of the Outer System War, a Vessel able to control Dusk and use it for something greater. You're just a machine, an automaton, 
  *if heaven_side = "Neutral"
    a coward who fled the War In Heaven! 
  *else
    a false champion of a false idol! 
  Do you hear me down there?! Say something!"

*fake_choice
  *if final_boss = "rook"
    *selectable_if (false) #"It matters not. I am [i]the[/i] Veteran."
  *if final_boss = "lisa"
    *selectable_if (false) #"Don't tell me what I'm capable of, Hellhound."
  *if final_boss = "marshal"
    *selectable_if (false) #"Do you really feel like a hero? Really?"
  *if final_boss = "damon"
    *selectable_if (false) #"I will always be stronger than you, Damon. Always."
  *selectable_if (false) #"This is your end. I hope you realize that fact."
  *selectable_if (false) #"Surrender. This is your last chance."
  *selectable_if (false) #"I now have divine power too. Can we both stand down and talk this out?"
  #Attack.
    *if heaven_side != "Neutral"
      [b]Go forth, my champion,[/b] your patron urges you from across space and time. [b]Prevail.[/b]
    
    There is no other choice, no other way. In this moment, you're not just a millennium-old android, free and aged and alone. You are a soldier following ${subject} directive, willingly and yet without agency, a tool for something greater and a weapon against the darkness you face. You are something even Dusk itself feels, someone whose name is known by gods, the end and the death for this lone Vessel.
    
    [i]You are the Veteran.[/i]

You look at ${final_boss}, a living spot in the death matrix of the Solar System, a target acquired and locked on. Once a companion, now an obstacle, too meaningless to be called an enemy. 
*if final_boss = "damon"
  Just a giant on clay legs, forged in the fires of doubt and self-loathing rather than a proper furnace. It shall be disassembled.
  
  You walk on stairs of air, forwards and up towards Damon's heart. Towards the place where the android himself is, surrounded by living metal and thinking himself safe. Illusion breaks when he sees you approach and he swipes at you, hoping to swat you away like a fly, but his hand melts when it connects with your body. Heat then proceeds to spread through the whole statue, making Damon cry out in pain, but you pay no attention to that shout.
*if final_boss = "marshal"
  A little bird wishing to be a vulture. You shall not be its carrion.
  
  You fly towards Marshal. She wasn't expecting that, didn't know you could even do that, but reacts fast by forming a barrier out of the wind. You break that wall. She throws feathers at you like a rain of daggers, but they do nothing. She reduces the temperature to absolute zero, freezing the very atoms and ending all movement—you turn it down even further and restore the flow of time.
*if final_boss = "lisa"
  Just a mad dog to be put down.
  
  She huffs and puffs, hoping to blow you away, but you keep walking and then you start running. She howls to the moon and makes stone tendrils emerge from the ground to grab you—-but you shatter those without any effort. Finally, in a fit of bravery, she counter-charges you and opens her jaws wide… only for you to accelerate and fly into the gaping maw of this humongous canine.
*if final_boss = "rook"
  A poor imitation of what the ancients though angels were like, a pawn in Dusk's petty game. You will take that pawn.
  
  You fly towards Rook. You have no need of wings, nor to manipulate gravity, you simply aim your momentum upwards. In his surprise, the angel swings his sword at you—it goes right through. He opens seven seals—nothing happens. He sounds seven trumpets—silence consumes the music. He pours seven vials out, but wrath of God means nothing to the champion of ${master}.

[b]You are the Veteran.[/b]

You strike ${final_boss} with a burning fist. You hear 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  him 
scream as flames consume 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  his 
mutated body, and you hear Dusk shriek as its beautiful Vessel is defeated. The nanobots writhe, yearning to be free, but the flames deprive them of power as they scorch ${final_boss}'s nerves. This is not a killing strike, but one of utter precision—-you will not allow even one of these specks to break loose, to endanger the Solar System, to defy the will of  
*if heaven_side = "Neutral"
  Sun.
*else
  your @{god_gen master|mistress|patron}.

Heat and ${light} flow from you like an electric current, filling the void of ${final_boss}'s soul. You feel power leaving your body and spirit, feel reality return to normal and feel the past and present disconnect again. You are once again an aged machine, but you hardly mind, because you know what you've accomplished.

You are the Veteran.

*page_break Finite

You wake up, even though you never lost consciousness. It is a smooth transition, like being suddenly shaken awake from a lucid dream, taken from a whimsical realm where you had full control over everything and nothing was able to threaten you. Though the fact that you're standing in a crater, surrounded by burned buildings and charred corpses of civilians… might be a proof that what happened wasn't just a wacky dream. It was a true display of divinity, the likes of which nobody has witnessed since the War In Heaven, with you as the conductor and the executioner.

Though 'executioner' might not be quite the right word. As far as you can tell, as you look towards the very bottom of the crater, $!{final_boss} is still alive, although stunned and perhaps comatose. Even in your elation and righteous wrath, you made sure tho avoid killing 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  him 
and setting the nanites free. Instead, this entire fragment of Dusk has been imprisoned inside a mortal body, much like inside an inanimate object, helpless and seething with powerless rage.


*if final_boss = "rook"
  *achieve cal_king
  
  *gosub rook_death

*if final_boss = "lisa"
  *achieve cal_hound
  
  *gosub hound_death

*if final_boss = "marshal"
  *achieve cal_marsh
  
  *gosub marshal_death

*if final_boss = "damon"
  *achieve cal_knight
  
  *gosub damon_death

You decide not to dwell on that. There is no point, nothing to be gained by speculating and 
*if Emotion > 50
  inviting guilt. 
*else
  writing up scenarios. 
The authorities will decide what to do with this Vessel, will probably manage to contain 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  him 
safely, and they will have to do it without your help or input. Your job here is done.

Heeding the sound of rotors in the sky and tank tracks in the distance, you skedaddle out of the crater and towards the Sholmo Gate. 
*label leaving_fin
*if team_stat = 3
  You need to meet up with Hadaly and Damon, 
  *if pc_state = "exiled"
    preferably before they decide to fly off without you. 
  *else
    then maybe return to [i]Saturn Nine[/i]. 
*if team_stat = 2
  Maybe you'll find Damon on your way there, maybe not. 
*else
  *if pc_state = "exiled"
    You're not sure where you'll go from there, but… you'll figure something out.
  *else
    Maybe you can still find your shuttle there, maybe not. 
Either way, you need to leave this battlefield, and then escape the city [i]fast[/i].

You've made enough of a mess already.

*finish




*label crystal_scene

And then $!{final_boss} disappears.

It happens in an instant, and yet not all at once. For a split second, you still see 
*if (final_boss = "marshal") or (final_boss = "lisa")
  her 
*else
  his 
legs, but then nothing remains. Gone, turned invisible, or perhaps removed from reality altogether…

[i]Invisible. Yes, that is a good guess. However imprecise.[/i]

You know what's coming next. You're hardly surprised when, a second later, something larger than $!{final_boss} starts materializing before you and above you. A draconic creature, its scales like rough diamonds, its one working eye like a glowing ruby. A phantom from your past, but not distant past, appearing to repay the favor owed.

Crystal.

*page_break

*if final_boss = "marshal"
  *set marshal_alive false

*if final_boss = "rook"
  *set rook_alive false

*if final_boss = "damon"
  *set TrioStat "heroes"
  *set damon_alive false

*if final_boss = "lisa"
  *set lisa_alive false


[i]Active camouflage is a wonderful thing,[/i] the wyvern continues, paying very little attention to its surroundings. It seems not to notice the destroyed city, nor the moans of survivors, nor even the helicopters hovering above. [i]Your opponent was a stronger Vessel than me by far, but I was able to sneak up on[/i] 
*if (final_boss = "marshal") or (final_boss = "lisa")
  [i]her.[/i] 
*else
  [i]him.[/i] 
[i]Thank you for the distraction.[/i] 

Crystal's tone is much you remember—polite and slightly sardonic—but not nearly as cold. There is genuine warmth there, actual kindness rather than mere civility. And yet, the voice is all the stronger for it, far less… muffled, in a manner of speaking.

*temp stunned_emo false

*fake_choice
  #"Crystal! Aren't you supposed to be in Janus?"
    [i]This is yet another use of invisibility,[/i] Crystal explains. [i]You can slip away unnoticed, if your guards are not paying attention. And the federate forces sent to blockade Janus certainly did not.[/i]
  #"Did you just... eat $!{final_boss}?"
    [i]Indeed.[/i] Crystal lowers their head. [i]It was a bestial act, but also a necessary one. $!{final_boss} is now dead, and the Dusk nanobots are safe inside my body.[/i]
  #"$!{final_boss}... why...?"
    *set Emotion %+ 12
    *set stunned_emo true
    [i]Are you blaming me for eating[/i] 
    *if (final_boss = "marshal") or (final_boss = "lisa")
      [i]her,[/i] 
    *else
      [i]him,[/i] 
    [i]or[/i] 
    *if (final_boss = "marshal") or (final_boss = "lisa")
      [i]her[/i] 
    *else
      [i]him[/i] 
    [i]for choosing this path in the first place?[/i] Crystal asks with a tilt of their head. [i]Because only one of those accusations is fair.[/i]
  #"You look a lot better than when we've last seen one another."
    [i]You did a number on me back then, yes,[/i] Crystal recollects. [i]But I had time to lick my wounds. To grow stronger.[/i]
  #Distraction? I was winning before you showed up."
    *set Confid %+ 12
    [i]You were not,[/i] Crystal replies dryly. [i]You were fumbling rather badly and about to die. Still, I admire your confidence.[/i]
  #Say nothing.
    *set stunned_emo true
    [i]Stunned?[/i] Crystal chuckles quietly. [i]I cannot blame you. That's what I get for arriving unannounced.[/i]

You do not reply, suddenly hypnotized by… something about Crystal's appearance, or rather around it. The dark aura created by Dusk is still there, in its vague and immaterial manner, but it seems… calmer. Not weaker, Crystal is no doubt the strongest Vessel in existence, but they seem to have gained a form of control they previously lacked. One which they merely pretended to have up to this point.

[i]You distrust my ability to keep the Shadow in check,[/i] Crystal states, as though having read your mind. [i]I do not blame you.[/i] 
*if crystal_friend
  [i]Your secret faith in me was misplaced.[/i] 
*else
  [i]You were always right to doubt me.[/i] 
[i]I was arrogant, a self-proclaimed crusader fighting Dusk in the most reckless way possible. It was folly which bordered on madness, and we both almost paid its price. I am sorry.[/i]

*if stunned_emo
  Part of you, the part not overwhelmed by grief and shock, wonders what changed. Why $!{final_boss}'s killer believes you should trust them now.
*else
  "What changed, then?" you inquire. "How come you trust yourself with nanobots now?"

[i]After you showed me mercy, then[/i] 
*if spared_crystal_early
  [i]in the rings of Saturn…[/i] 
*else 
  [i]above Janus…[/i] 
[i]I realized you may be the true hero of this twisted story. I meditated and rested, contemplating my past actions and future plans, my mistakes and my eventual fate. I realized that I was wrong to use Dusk as a tool, even in limited capacity. I saw I was going astray, and that I must turn back from the path that I chose.[/i]

*if stunned_emo
  Crystal sounds honest, but if that's the case… why absorb another shard of Dusk. Let alone one as large as this one?
*else
  "And yet you absorbed shard," you point out. "Another Vessel, one formed out of the largest Dusk artifact in existence. Why?"

[i]To save you, Veteran. I have followed you out of curiosity, as well as healthy fear for your safety. I was hoping to repay the favor you made me… and I did. If I wanted more Dusk inside me, I would have attacked your opponent far earlier and reveled in the glory gained. Instead, I simply did what was necessary, and will treat the nanobots inside me as a burden to bear.[/i]


*fake_choice
  #"I still don't believe you. I still cannot trust you."
    [i]With all due respect, Veteran, your trust is hardly necessary,[/i] Crystal replies calmly. [i]We will never see one another again. Think of me as you want, it makes no difference in the end.[/i]
  #"But... did you [i]really[/i] need to do this? You could have let me die."
    [i]Letting $!{final_boss} get away was out of the question,[/i] Crystal replies, then adds less harshly, [i]And so was letting you die. You are a unique specimen, Veteran, one worth preserving at almost any cost. Shame fills my crystalline heart, but the pride of having saved you will never truly fade.[/i]
  #"I see. Thank you for your assistance."
    [i]With that acknowledgment, I shall consider the two of us even,[/i] Crystal announces. [i]Even still, I will continue to feel grateful for your mercy, as well as inspired by your glorious existence.[/i]
  #"Bear where? Are you planning on returning to Janus? Or on something else?"
    [i]There are beings capable of overhearing even the kind of conversation as we are having now,[/i] Crystal says vaguely. [i]As such, I shall keep my secrets. Just know that you won't ever see me again, at least not if you intend to remain around Saturn.[/i]
  #Say nothing.
    [i]You do not need to say anything,[/i] Crystal reassures you. [i]We understand one another perfectly well even without idle chatter. Even without any words at all.[/i]

Only now does Crystal appears to notice the helicopters, and the distant noise of what sounds like tanks. They spread their wings wide, preparing to take off. [i]I thank you for this adventure we shared, this war we waged, this opportunity to grow. I bid you farewell, and… wish you the best out of whatever you have left.[/i]

You know exactly what they mean. Your body, already aged and unkempt, has just taken major damage. You'll probably have to take some parts out, and you're unlikely to have any way of replacing them, and the flashbacks… You're on your last legs and there's no denying that. You'll be lucky if death spares you till another year, let alone another decade.


*fake_choice
  #"Just never bother me again, alright? I've had quite enough of you."
    [i]Perfectly understandable,[/i] Crystal says, though their voice betrays a sliver of hurt. [i]I will leave you alone for the rest of your life. However long it may be.[/i]
  #"I lived a great life already. I'm prepared to rest now."
    *set Confid %- 10
    [i]Just make sure to get some actual rest, before closing your system forever,[/i] Crystal advises. [i]Settle down, relax, spend time with your friends. You have more than earned it.[/i]
  #"I will. And I want you to make the best out of your life as well."
    [i]I suppose the principle applies whether you'll live a year or a millennium,[/i] Crystal muses. [i]You are a wise robot, Veteran. Survive for as long as you can.[/i]
  #"Don't write me off just yet. I'm a tough little android."
    *set Confid %+ 10
    Crystal chuckles as they disappear, turning their invisibility on. [i]Yes, Veteran. You most certainly are a tough android. Good luck.[/i]
  #Say nothing.
    *if stunned_emo
      Crystal chuckles. [i]You must [b]really[/b] like silence, Veteran. I will grant your wish and refrain from disturbing your peace any longer. Goodbye.[/i]
    *else
      There is nothing more to say, nothing to add or subtract. You understand each other perfectly, two ancient beings who faced Dusk and won, each about to face its own uncertain fate. That's how this story ends.

Crystal turns invisible mid-flight, disappearing from your sight for the last time. Just before they become fully transparent, a loud gunshot reaches your ears, implying one of the aircraft briefly opened fire. Or perhaps corporate soldiers are retaking the city, it's difficult to tell and even harder to really care.

You take that as your cue to leave. Hoping the helicopters don't see you, or that they won't view you as a threat, you start hopping towards the Sholmo Gate and its spaceport. 
*goto leaving_fin