*image epilogue.png

*if pacifist
  *achieve pac_run

*temp damon_present false

*temp birthday false

[b]January 2nd, 990 AC[/b]

[b]T-plus 521905680 minutes[/b]

"You don't think very highly of the Conglomerate, do you?" Your accusation is bound to fall on deaf ears, especially since Sheila [i]has[/i] no ears, but you make it all the same. "You believe I can just walk into their bank, take out some money and walk out. 
*if Confid > 50
  As though I own the place."
*else
  That sounds terribly dangerous."

The two of you are sitting together in the cafeteria, though it's technically not just the two of you. Wisp is serving you as a lamp, hanging over your heads and seemingly asleep, and you can be sure that Manfred is listening in.

Also, Sheila isn't exactly [i]sitting[/i], but rather lying on her belly… though even that's not a wholly accurate description. Even now, after over a year of living with that cyborg, you're not entirely used to her arachnid anatomy.

"Look, I get that plan isn't exactly risk-free," Sheila explains herself. "But we are slowly running out of fuel. We need to either keep stealing it, start stealing parts for our hydrogen collection system… or get enough money to pay for these things during a single, solid heist. I think the choice is obvious."

*temp agreed 2

*choice
  #"Yeah. I suppose it is."
    *set agreed 1
    "I'm glad we're on the same page," Sheila says with relief. "Because let me tell you, Veteran, I'd [i]really[/i] hate to fight you."
    
    "It would be entertaining to watch, though," Manfred remarks, 
  #"I wasn't disagreeing. I think lowly of the Conglomerate too."
    *set Confid %+ 8
    *set agreed 1
    "I'm glad we share the same view of megacorps and super-capitalism," Sheila comments dryly. "I promise, you'll feel really good after stealing from these bastards."
    
    "Personally, I don't consider super-capitalism worse than other inane economic systems which humans designed," Manfred argues, 
  #"Why not steal those parts you mentioned? Other floating fortresses surely have it."
    "They are called fortresses for a reason," Sheila retorts. "Getting into one is cloudy difficult. Entering a huge moon is trivial by comparison."
    
    "Especially for someone like you," Manfred says, 
  #"I don't understand why I have to go alone. We have several human-looking people in our group."
    Sheila replies, "I do not trust Miguel with anything that involves subtlety… or anything at all for that matter. Damon and Hadaly can fly there with you, but I don't want them walking around Rhea openly, and I suspect they'll agree."
    
    You raise an eyebrow. "I get the feeling you're not telling me something. That you know more about them than I do."
    
    Sheila shrugs. "I have suspicions, nothing more. You'll get there too, I promise."
    
    "I am sure ${pronoun} will," Manfred says, 
  #"To you, perhaps. I'll have to take all the risks."
    *set Confid %- 8
    *set agreed 3
    "Look, I'd go there myself if I could, but…" Sheila uses one of her legs to point at the other seven. "I'm not good at blending with the crowd. You are."
    
    "And I can't go due to my crippling lack of physical body," Manfred adds, 
  #"I get no choice, is what you meant to say."
    *set agreed 3
    "Pretty much," Sheila admits. "Trust me, I don't like forcing you into stuff, we both have bad experiences with that. But survival always comes first."
    
    "Self-preservation is important for most living creatures, organic or synthetic," Manfred agrees, 
confirming that he was indeed listening. 
*if agreed = 3
  "Don't worry, Veteran. I will upload a copy of myself to the shuttle, so that I can stay relatively close to you at all stages of the mission."
*if agreed = 2
  "You are the best of us, Veteran. I have full confidence in your ability to complete the mission."
*if agreed = 1
  "In any case, Veteran, I'm glad you're willing to accept the mission. Your upcoming victory will aid our group greatly."

"Mission?" You raise an eyebrow. "That's an interesting word to use for a heist. It conveys an air of importance and… scale. Like I'm signing up for something big."

"It's a word like any other," Sheila reassures you. "You just need to get in, get the money, get out. It's a single task, and you'll be done with it before you know it."

*if agreed = 3
  You still don't feel like going, but… maybe she's 
*if agreed = 2
  She's probably 
*if agreed = 1
  You believe she's 
right. You've done things orders of magnitude more dangerous than stealing from some human bank. It won't be guarded by an army, or meta-humans, or any of the horrors you've seen during the War In Heaven. You'll just need to fool or circumnavigate some basic security measures. You'll just need to…

*page_break Wake Up

*if RheaRel > 50
  *achieve corp_friend

*if pc_dead
  *goto afterlife

*if dusk_ending
  *goto hate_hate

*if sworn_to_hammon
  *goto sworn_to_ewald

You awaken from your age-induced slumber. In contrast to most of your episodes, this flashback was actually fairly pleasant. Short, safe and not even that distant in time. You wish they were all like this, but alas, the darker memories torment you even now, and likely won't stop until the day of your death.

*if (org_alive = false) and ((damon_free = false) and (hadaly_free = false))
  *goto saturn_34


*if bad_ending
  *goto no_mouth

*if pc_state = "exiled"
  *if team_stat = 3
    *goto robot_trio_ending
  *else
    *goto exile_ending

*if (damon_free) and ((final_boss != "damon") or (dusk_contained))
  *set damon_present true

*if (org_alive) and (hadaly_free)
  *set birthday true

Which, depending on how the meeting goes, may not be that far away.

Admiral Michael West walks down the ramp, leaving his shuttle and stepping on the main landing pad of [i]Saturn Nine[/i]. It's an expected visit—as soon as you returned from Rhea, the admiral called and said he wants to discuss a few… issues in person. He didn't specify, but it's not difficult to guess what he meant.

Not at all.

"${fake_name}. ${name}. Veteran. Whichever you prefer." He approaches you steadily, bearing no weapons, but looking rather intimidating all the same. 
*if s9_leader = "manfred"
  "I was hoping to speak with the leader face to face, but… I suppose computer programs don't exactly have faces."
*if s9_leader = "player"
  "I've heard you became a leader of your little group. Congratulations. And kudos on not being afraid to lead from the front."
*if s9_leader = "sheila"
  "I assume your group's leader is currently unavailable."
*if s9_leader = "hadaly"
  "Did Hadaly tell you to speak with me alone? It sounds unlike her."

*fake_choice
  *if s9_leader = "player"
    #"I wouldn't trust anyone else with this responsibility."
      *set ArmyRel %+ 5
      "You do not truest your subordinates?" West smiles sadly. "I know exactly how you feel. Having to work with the Meta Trio… that can certainly change a man, or a robot for that matter."
    #"Are you implying we're about to start fighting?"
      "Not at all.' West smiles sharply. "I'm sure you know better than to pick a losing battle."
  *if s9_leader = "manfred"
    #"There's also the fact that Manfred doesn't have any cameras or speakers here."
      *set ArmyRel %+ 5
      "I'm not sure if I believe you," West says listlessly. "For all I know, your leader might be listening in… but I don't suppose it matters very much."
    #"How do you even know that Manfred is the leader? Did he tell you?"
      "Right as my ship approached this fortress, yes," West confirms. 
      *if SheilaStat = "dead"
        "He sounded strangely sad about that… but that could easily be a ruse. Pretending not to want power is the cheapest trick in any leader's arsenal."
      *else
        "He sounded rather proud of that fact. Happy to have power over his fellow synthetics… and organics alike."
  *if s9_leader = "sheila"
    #"Sheila isn't the most diplomatic sort, and she's fully aware of that."
      *if Social > 55
        "So she instead decided to take advantage of your silver tongue," 
      *else
        "You do not strike me as very charismatic either," West says bluntly. 
      "Not that it matters. You will not be negotiating anything today, just listening to what I have to say."
    #"I insisted on coming here alone. I no longer trust Sheila with... anything, really."
      *set ArmyRel %+ 5
      "Disillusioned with your leadership, huh?" West smiles. It's hard to tell whether that smile is sympathetic or not. 
      *if ArmyRel > 45
        "Once you start looking for a new employer, remember that the Federation is always hiring."
      *else
        "That's fine. I promise I won't tell her."
  *if s9_leader = "hadaly"
    #"How would you know her? You two barely even spoke."
      "I did some digging," West says vaguely. "And not just regarding your leader."
    #"Coming here was my idea. My responsibility."
      *set ArmyRel %+ 5
      West nods respectfully. "I see. I'm glad you made this decision—there are some things I'd like to keep between the two of us."
  #"I prefer [i]Veteran[/i]. That's what I am."
    West raises an eyebrow. "Are you alright? Because you look a little… shell-shocked, if you don't mind me saying."
    
    You shrug. "Isn't that part of being a veteran? You live while others die, you survive as the world evolves. You're filled with power as you fight, but once the war ends… you feel as hollow as the world around you."
    
    "Right…" West sighs. You're not sure whether he sympathizes with your pain, or is simply annoyed by your musings. "Let us not dwell on that. We have serious matters to discuss."
  #"Are you here just for small talk? Or is there an actual reason for this visit?"
    *set ArmyRel %- 5
    "You know there are multiple reasons," Admiral West replies. "And so we'll go over them one by one."
  #Say nothing.
    "I suppose you aren't a fan of small talk," Admiral West remarks. "That's fine. We can get straight to the point."

*if damon_present
  You briefly glance towards [i]Shuttle One[/i], knowing that Damon hides behind the small ship. The other android is as protective as ever, and so he insisted on coming here. If the admiral tries to attack you, he will likely get shot, damn the potential consequences. 
  
  West 
*else
  He 
pulls out some piece of paper, or perhaps parchment, a scroll with various words and numbers you can't clearly read at this angle. "This is a casualty report for the… conflict in the Sholmo City. We don't know how to name that event, or if we should even acknowledge it as an armed conflict, but we know 
*if explosion_prevented
  *set ArmyRel %+ 10
  several thousand people perished in the fighting. But also know how much worse it would have been if not for your help. Your… assistance in bringing the rogue elements down."
  
  *fake_choice
    #"I hope the Meta Trio's efforts get recognized as well."
      "It's amusing to see you worry about that," Admiral West comments. "Of course their efforts will be recognized. Your involvement will be kept a state secret, while the Meta Trio will be credited with the victory."
      
      "All three of them?" you ask. "You have history of… not really appreciating the female part of that team."
      
      "We… will see about that," he replies reluctantly. "Kosteniuk was the leader, and he does deserve recognition, but he was not the only person involved. Hopefully the media will remember that fact."
    #"Will I get a reward? I was really hoping for a reward."
      West rolls his eyes. "I cannot formally thank you without revealing your existence to the wider Federation, and our coffers are almost empty. You will have to treat your honorable actions as their own reward."
    #"I require no thanks. This was my duty to uphold."
      *set ArmyRel %+ 5
      "It was not," West counters. "You're a rogue android, 
      *if heaven_side = "Traitor"
        a Fiend, 
      a thing whose very existence is a crime. And yet you helped the Federation in its hour of need. Thank you."
    #"I have no idea what you're talking about."
      West smiles slightly. "Playing ignorant? Good. It will make keeping your involvement a state secret easier."
    #Say nothing.
      "I see you'd rather not talk about this matter," West observes. "I understand. Your wish shall be respected."
  
  With that said, West looks at another part of the scroll. 
*else
  *set ArmyRel %- 10
  that over three hundred thousand people died over its course. Most of them as a direct result of a local power-plant exploding, for reasons we don't fully understand. An explosion you managed to run away from."
  
  *fake_choice
    #"Correct. Please proceed."
      *set Emotion %- 8
      *label please_proceed
      West shakes his head, as though disappointed by your lack of reaction. But he does proceed. 
    #"What was I supposed to do? Fight your own citizens without authorization?"
      *set Emotion %+ 8
      *set ArmyRel %- 8
      "Calypsoans were Kronians in name only," the admiral says harshly. "They had their own local government and, worse by far, their own ideology. They were driven to terrible things by their insane faith, and I wouldn't have objected had you decided to think their ranks."
    #"It was no mere explosion. It was Dusk."
      You know that, and so do I, but the public…" West shakes his head slowly. "Panic is the last thing we want at the moment. We need to maintain control over the situation if we want to stop the spread."
      
      "Does that imply you have control? Or do you intend to take it from the Rhea Conglomerate, the local authorities of that moon?"
      
      "No comment." West looks at another part of the scroll. 
    #Say nothing.
      *set ArmyRel %- 10
      *goto please_proceed
*if hammon_alive
  "Executive Ewald Hammon is alive and well, or at least was when we met yesterday. He wanted a message delivered to you specifically."
  
  "He did?" You try not to show too much interest. You don't know how much West knows and how much he should know. "What did he say?"
  
  *if not (hadaly_alive)
    "That he doesn't understand why you'd kill his wife by blowing up her head," West says flatly. "And that if his attempts to repair her fail, he will send someone to kill you. I have no idea what happened between you, and I do not wish to know."
  *elseif hadaly_free
    *if fought_hammon
      "That he does not appreciate how you stood between him and his love, whatever that means." West pierces you with his gaze. "And that he will be back, whatever he's hoping to accomplish by telling you this."
    *else
      "That he will honor your agreement, even if he hoped for a better outcome." West looks you in the eye curiously. "I'm not sure what you gave him, or even what could interest a High Executive personally… but be glad that he's not your enemy. And try to keep it that way."
  *else
    "That, once her re-programming is complete, Hadaly will be happier with him than she ever was with you. 
    *if fought_hammon
      That you should stay away from him and his wife, or else. And that there's nothing left for you to save."
      
      *if Emotion > 50
        Despite being a robot, you can't help but shiver.
    *else
      *set ArmyRel %+ 10
      And that he thanks you for having made it possible."
      
      You try not to feel guilty. 
      *if Emotion > 50
        Try.
      *else
        And mostly succeed.
      
*else
  *set ArmyRel %- 10
  "Executive Hammon was among the victims, his mutilated body found in his headquarters. The cause of death is uncertain, and the Conglomerate seems… reluctant to shade any light on the matter. Would you care to?"
  
  *fake_choice
    #"No."
      "Fair enough." Admiral West shrugs. "To be clear, I will not be mourning this man, nor is his death a great loss for Rhea. I'm just worried about the power vacuum he left."
    #"I killed him. He gave me no choice in the matter."
      "I believe you," the admiral sighs. "Hammon has always been reckless and self-centered in equal measure. It's just a shame you didn't deal with him in some other way, avoided creating a power vacuum."
    *if (hadaly_killed_hammon) #"You can believe me or not, but it was Hadaly's doing."
      West raises an eyebrow. "Hadaly? I admit to not really knowing her, but she always came off as a pacifist. What happened?"
      
      "You don't want to know," you say honestly, remembering that damn kiss. "You really don't."
    *if (damon_shot_hammon) #"Damon shot him in the face."
      "His injuries [i]were[/i] of cranial variety." West winces at the memory. "I could press charges against you or your friend… but I think we'll all benefit from keeping quiet about this murder."
    #"How would I? I know nothing about these events."
      "I do not believe you," West says bluntly. "But I don't stand anything to gain from questioning you, so let's leave it at that."
    #"Be honest; Did you even like Hammon to begin with?"
      "No," West freely admits. "But his death left a power vacuum, and that makes it harder to… contain the chaos within Rhea. My colleagues are debating whether we should invade the moon and start ruling it directly—that's the extent of damage you've dealt."

As he reels out another part of the scroll, West's face becomes contorted with… some emotion. It might be anger, it might be 
*if (TrioStat = "heroes") or (TrioStat = "serving")
  envy, 
*else
  disappointment, 
but it's certainly nothing positive. 
*if (TrioStat = "heroes") or (TrioStat = "serving")
  "The Meta Trio is celebrated as a team of heroes, having single-handedly foiled the terrorist plot. We have already doubled Kosteniuk's salary and may issue some rewards to the other two. We're not sure what kind, most clerks have no idea what a woman could want. And neither do I, to be perfectly honest."
  
  *fake_choice
    #"Service is its own reward. They should understand that."
      "They should," West agrees. "Whether they [i]do[/i] is a different matter. I might end up pulling some strings and moving all three of them up a rank, even the werewolf girl will probably appreciate that."
    #"Have you considered giving @{(RenfriRel >= 45) Renfri|Marshal}, that is Agent Riannon, her own team to command?"
      West frowns. "That would mean breaking up the Meta Trio, an effective and well-liked team. But… I suppose I could promote her to Gefreiter, at the very least."
    #"I know @{(LisaRel >= 45) Lisa|Hellhound} would probably like a raise. And booze."
      "I can provide the former, but not the latter," West says dryly. "Drinking on the job is rarely appreciated. Doubly so when it comes to convicts, triply so when it comes to werewolves."
    #"Who cares? They're pushovers. They'll keep doing your dirty work regardless of how you treat them."
      West shrugs. "Maybe that's true. Maybe it's not. I would rather not find out, so I'll make sure to reward the Meta Trio eventually."
    #"I'm not an expert when it comes to rewards. I was rarely offered any."
      West looks at you with something approaching pity. "I understand. I will figure something out on my own, and if not… I'll just pay them in cash. Axions hold the galaxy together, or so they say."
  
*if (TrioStat = "dead") or (TrioStat = "MIA")
  "As for the Meta Trio, they've all been labeled as [i]Missing In Action[/i]. They're not officially dead, we haven't found their bodies or anything of the sort… but I think we both know what happened to them, do we not?"
  
  *fake_choice
    #"Yeah. I suppose we do."
      The two of you just stand there silently for a few seconds. On that topic, there is nothing more to say."
    #"I don't. For all I know, they could have gotten away."
      "Are you trying to infect me with false hope, or falling victim to it yourself? West shakes his head. "Don't answer. It doesn't truly matter."
    #"Their stupidity got them killed. I hope you don't expect me to apologize."
      *set ArmyRel %- 5
      "I don't expect you to do anything at this point," West says harshly. "You're clearly not worthy of anyone's trust."
    #"They died like heroes, for all it's worth."
      "It's not worth much…" West murmurs. "But thank you for informing me of that fact, I suppose."
    #Say nothing.
      "Are you giving your fallen comrades a moment of silence?" West asks bitterly. "Or are you simply lost for words?"
      
      You shrug. What is there to say, really?
*if TrioStat = "broken"
  "The Meta Trio no longer exists as a federate unit. 
  *if (final_boss != "rook") and (rook_alive)
    Kirill Kosteniuk still serves us, but his teammates will no longer obey him, or anyone else for that matter. 
  *else
    Kosteniuk has reportedly been killed in action, while the other members… are not eager to resume duty. 
  *if final_boss = "marshal"
    Especially Agent Riannon, 
    *if marshal_alive
      who is currently being held in a padded cell. 
    *else
      who suffers from a bad case of being dead. 
  *elseif final_boss = "lisa"
    Especially Hellhound, 
    *if lisa_alive
      who is currently being held in a padded cell. 
    *else
      who suffers from a bad case of being dead. 
  We plan to purge all records of the team retroactively and un-person its members, so that their memory can never embarrass the Federation again."
  
  "This is a little extreme," you point out. 
  *if final_boss = "rook"
    "The girls aren't to blame for their leader going bonkers."
  *elseif (final_boss = "lisa") or (lisa_shot_rook)
    "Rook and Marshal both remained perfectly loyal. Only their werewolf teammate did not."
  *elseif final_boss = "marshal"
    "Lisa and Kirill are hardly to blame for Marshal going bonkers."
  *else
    "The metas may have failed in the end, but it's not like they haven't tried."
  
  Admiral West shrugs. "You may be right, but what of it? In such turbulent times, keeping the population docile is more important than ever. Vaporising shameful incidents, such as the Meta Trio's whole history, is just one step towards that goal."
  
  
*if TrioStat = "AWOL"
  *set ArmyRel %- 10
  "All three members of the Meta Trio have reportedly left their post without permission, supposedly allowing the power plant to explode. Sergeant Kosteniuk, or 'Rook' as was his codename, is currently held in custody. The other two are nowhere to be seen."
  
  Then, seemingly, his anger turns to you. "Tell me, ${name}, and please be honest; Did you have anything to do with this act of desertion?"
  
  *fake_choice
    #"Yes. I convinced them to back away. It was for the best."
      *set Confid %+ 5
      "No remorse, no regret," West comments mirthlessly. "Even the officers responsible for the Trojan Genocides would envy your lack of self-awareness."
    #"No. Absolutely nothing. No sir."
      *set Confid %- 5
      West shoots daggers at you… but seemingly agrees to drop the subject. For now.
    *if Social > 55
      #"No. I actually tried convincing them to attack. It's not my fault they were cowards."
        *set ArmyRel %+ 10
        "So they resigned despite your insistence?" West sounds surprised, but perhaps he fell for your lie. "I will have some words with Kosteniuk about this."
    #Say nothing.
      "I'll take that as an admission of guilt," West sighs theatrically. "Don't worry, I will not put you on trial. I'm more disappointed than angry, really."

*temp vessel ""

He unreels the scroll fully and looks at the very bottom part. 
*if pc_vessel
  *set ArmyRel %+ 15
  "Lastly… ${name}, I know how you managed to contain the Dusk nanites. I know what you did to save us. And while I'm glad you made that choice… you're now a Vessel, and that makes you an enemy of all living things. Including me and my nation. You understand."
  
  *fake_choice
    #"Yes. I do understand."
      "I'm glad you do," West says heavily. "I'd hate having to argue with you. I'd be wrong and right at the same time."
    #"No, I don't understand. I resisted and contained Dusk, as your metas can attest."
      "You and I both know that resisting Dusk once is no accomplishment," West says with a strange sort of confidence and wisdom. "You'll need to do it again, then again, then again. And you can't expect anyone to trust in your success."
    #"How so? I don't feel like an enemy of all things alive."
      "I'm not saying you hate the living, just that they will hate you," West says morosely. "Word will spread, and then you will be hunted. This fortress cannot protect you, and so you'll have to leave it soon."
    #"I've made my choices and sacrifices. If given a chance, I would make them again."
      "And I greatly respect that," West says with a nod. "Just… don't delude yourself into hoping that others will share my opinion. The Solar System will consider you its enemy, and you must plan accordingly."
  
*elseif (final_boss = "hadaly") and (TrioStat != "dead")
  *set vessel "Hadaly"
  *goto vessel_speech
*elseif (final_boss = "damon") and (damon_free)
  *set vessel "Damon"
  *label vessel_speech
  "Finally, I cannot help but notice that your friend $!{vessel} has recently became a Vessel of Dusk. Willingly, may I add. And I while I don't doubt @{(vessel = "damon") his|her} good intentions, the fact is…  @{(vessel = "damon") he|she} poses a risk to everyone around @{(vessel = "damon") him|her}, including the very planet @{(vessel = "damon") he|she} lives on. As such, I'd like your group to start living on a different planet, or at least somewhere away from Kronian territory."
*elseif saturn_path = "pirates"
  *set ArmyRel %+ 5
  "Last, and admittedly the least, I wanted to thank you for seizing [i]Ocarina[/i] and ridding Saturn of Link's pirates. It was not directly related to your mission, but you did anyway, and the Federation is a better place for it."
  
  *fake_choice
    #"It was my duty and my pleasure."
      *set ArmyRel %+ 5
      "You are more zealous than most of our own soldiers," West says with a hint of bitterness. "It's a shame I can't formally recruit you. Such a shame…"
    #"No problem. I enjoy killing humans."
      *set Violence %+ 5
      *set Misan %+ 5
      "You've also killed several non-humans that day," West points out. "You're a very violent person in general, I dare say."
    *if (damon_shot_link) and (damon_alive)
      #"Damon was the one who killed the pirate leader. Thank him."
        *set Confid %- 5
        *if (damon_free) and ((final_boss != "damon") or (dusk_contained))
          *set DamonRel %+ 10
          "I cannot thank him without acknowledging his presence, and he likely wouldn't appreciate that." West glances towards the ship behind which Damon hides. 
        *else
          "He's no longer here, so I can't exactly help him," West points out. 
        "Nonetheless, he has my gratitude."
    *if (marshal_alive) and (final_boss != "renfri")
      #"Thank Agent Riannon for taking on the pirate leader. She was amazing."
        *set Confid %- 5
        "Her head injuries tell a different tale." West smiles slightly. "Then again, her bravely is to be admired, even in the absence of skill and common sense."
    #"Truth be told, I regret what I did that day."
      "For better or worse, you cannot change your decision now." West pats you on the shoulder. "And as far as I'm concerned, it's definitely for the better."
  
*elseif saturn_path = "left"
  "As an aside, I was recently informed that a group of pirates, reputedly led by an android like you, has attacked and destroyed a federate transport. It was likely the same bunch as the one you spared during your escapade to Saturn. The one you decided to do absolutely nothing about."
  
  *fake_choice
    #"A federate ship got destroyed? Awesome."
      *set ArmyRel %- 10
      *set Misan %+ 5
      "You seem to be trying to provoke me," West observes. His eyes narrow, but you see no other signs of anger. "You will not succeed."
    #"@{(RookRel >= 45) Krill|Rook} ordered us to withdraw. Are you saying I should have defied him?"
      "I wouldn't have held it against you if you did…" West murmurs, his confidence clearly diminished. "But point taken. In retrospect, Kosteniuk was not the right person to lead this mission, which means I'm not entirely blameless either. I shall let the matter rest."
    #"Why are you telling me this? I'm not responsible for these pirates and their actions."
      *set ArmyRel %- 5
      West frowns. "Responsible? Perhaps not. But you still made your choice, and I want you to know the consequences of it."
    #"Right... I really shouldn't have spared them. Sorry."
      *set ArmyRel %+ 5
      "I cannot truly blame you for that choice," West says tiredly. "Technically, it wasn't even your decision to make. I just wish things were different, that's all."
    #Do not comment.
      "Nothing to say?" West frowns. "Of course. Not saying or doing anything is your [i]modus operandi[/i] at this point."
*else
  "Lastly, I've recently received an anonymous email, full of praise aimed at you and how nicely you behaved in the depths of Saturn. This is strange, since the Internet hasn't existed for centuries and receiving emails should be impossible. Can you somehow explain any of this?"
  
  *fake_choice
    #"How do you even know what the Internet is? That's ancient history."
      "I happen to be well-versed in what you call ancient history," West replies cautiously, as though caught on a… something. "Perhaps I will use my knowledge to identify the source of this message, since you clearly don't want to be of any help."
    *if (sauce_bless) #"Reply to that email. Tell its writer that his blessing was essential to my success."
      "I'm not sure how I'm supposed to write back…" West murmurs. "But thank you for revealing that person's gender, if nothing else."
    #"I think you're better off not knowing."
      "Perhaps you're right," West concedes. "Some things in the Solar System are not meant for mortal eyes, and some secrets are not meant for mortal minds. I'd be a fool not to know that at my age."
    #"It means Sauce hasn't forgotten about me. Neat."
      The admiral's eyes narrow. "Sauce? Should I even ask who that is?"
      
      "No," you reply bluntly. "You really shouldn't."
    #Shrug.
      West sighs. "I will interpret your answer as 'no'. Which annoys me, even though our mysterious friend likely doesn't matter in the long run."

With that, Admiral West rolls the scroll into a neat tube, then puts it into a pocket of his uniform. 
*if federate_protection
  "You can stay in this fortress for as long as you want, if that even needs to be said. 
  *if hammon_made_prot
    Executive Hammon vouched for you personally. 
  *elseif ArmyRel > 40
    You're a reliable and loyal ally, and the same goes for the rest of your group. 
  *else
    I'm not a fan of your dysfunctional bunch, but I [i]am[/i] a man of my word. 
  [i]Saturn Nine[/i] is yours, now and forever."
  
  *fake_choice
    *if (ArmyRel > 40) and (hammon_made_prot = false)
      #"Personally, I wouldn't call myself [i]reliable[/i]."
        "Perhaps it's not the most accurate epithet," West admits. "Still, I like you, and enjoy talking with you. It's a shame this conversation must end now." 
    *if (ArmyRel <= 40) and (hammon_made_prot = false)
      #"You're not a fan of us? Why?"
        West rolls his eyes. "If I started listing reasons, we'd be here all day. And I'd rather not spend any more time with you."
    *if not (hammon_made_prot)
      #"Thank you. I was afraid you'd walk back on that promise."
        "I am not known for breaking my promises, ${fake_name}." West sounds a little offended. "Keep that in mind, and you will rest easy."
    *if promised_repairs
      #"I believe you promised to repair the whole fortress. Will you keep your word?"
        West shrugs. "At some point in the future, once I've found the time and budget for it. I haven't specified [i]when[/i] I would do that, after all."
    *if hammon_made_prot
      #"Very well. Tell Hammon I'm grateful for his patronage."
        West replies, "We're both busy nowadays, so I'm not sure when we'll speak again. But on that occasion, I will convey your gratitude."
    #"What if the word gets out? What if other Kronian leaders find out about our existence?"
      "Then I will have to pacify them, one way or another," Admiral West says bluntly. "Don't worry about that. Just live."
    *if crystal_stat = 3
      #"It better be. I had to kill a fellow synthetic for this."
        "Wyverns are not fully synthetic, nor are they worth mourning," West dismisses your concern. "You did the right thing. Hold on to that."
    *if crystal_stat < 3
      #"Even though I failed to slay Crystal?"
        *if hammon_made_prot
          West sighs. "As I said, a High Executive wants you to remain here. Why he does, I'm not entirely sure. But I will not make an enemy out of him."
        *else
          West replies, "You did your best, and have greatly injured the beast before it got away. I will not require any further assistance."
  
  He steps back onto the ramp of his ship, turning away from you and everything he left you with. "Farewell. Perhaps we will meet one another again, perhaps not. May the Sun smile at you all the same."
*else
  "You have two days to leave this station. 
  *if ((pc_vessel) or ((final_boss = "damon") and (damon_free))) or ((final_boss = "hadaly") and (TrioStat != "dead"))
    I cannot allow a Vessel of Dusk to stay in this place any longer. 
  *elseif hammon_broke_prot
    I wish you didn't have to, but Executive Hammon demanded that I evict you. If I don't, he'll send his whole army here and kick you out himself. 
  *elseif ArmyRel > 40
    You may be pleasant to talk with, and I don't really see you as a threat, but we had a deal and you went back on it. 
  *else
    I've tolerated your presence here for long enough, perhaps even too long. 
  A month from now, [i]Saturn Nine[/i] will be a military facility, utterly out of limits for outcasts such as you."
  
  *fake_choice
    #"Please. Can we make another deal? We don't want to leave, and we still have things to offer."
      West shakes his head slowly. "You no longer have anything I'd need, and I no longer have the time for you. In fact, my batman is probably getting impatient, so I'll cut this conversation short."
    *if s9_leader != "player"
      #"Great. Now I have to deliver the bad news to $!{s9_leader}."
        "Such is the bane of being someone's subordinate." West shrugs, uncaring for your plight. "You should try becoming a leader yourself. It's quite fun, once you get used to your subordinates' stupidity."
    #"Good. I never liked this decrepit place anyway."
      "I wonder if you're being honest, or if you're leaving sour grapes on the vine," West muses loudly. 
      *if likes_s9
        He knows you're lying. 
      "Not that it terribly matters."
      
      *set likes_s9 false
    *if crystal_stat = 2
      #"Come on, we did our best. We almost killed Crystal above Janus."
        "[i]Almost[/i] is not enough, and neither is [i]your best[/i]," West replies harshly. "You blew your chance. On that matter, there is nothing more to say."
    *if crystal_stat = 3
      #"I've killed Crystal for you. I did everything you asked."
        "Sometimes, even everything isn't enough," West says sagely. "I wish I could keep my word, but the present circumstances make that impossible. I'm sorry."
    *if pc_vessel
      #"If the problem lies with me, why not let the others stay? They are not Vessels."
        "Do you really believe that, after everything that happened, they'd let you wander the Solar System on your own?" The admiral's smile is sad, mocking, and affectionate in equal measure. "If so, then you don't understand what true friendship means."
    *if (hammon_broke_prot) and (pc_vessel = false)
      #"I didn't know Hammon has you in his pocket. That you're so weak."
        "I'm doing your group a favor," West says unflinchingly. "I'm not sure if you refuse to see that, or if you're genuinely blind, but either way… you don't deserve to die. So don't try."
    *if crystal_stat < 3
      #"I suppose that's fair. We [i]have[/i] failed to kill Crystal, after all."
        "I'm glad you're taking this well, or at least with dignity." The admiral's voice becomes a little softer. But only a little. "I do not feel like arguing, or hearing you beg for clemency. I'd much rather end this conversation now."
  
  He walks back towards his ship, leaving [i]Saturn Nine[/i] like you will soon have to. "I'd say no hard feelings, or that it's nothing personal, but either would be painfully unoriginal. So I'll just say… goodbye. Veteran." 
  
A second later, Admiral West is already inside his shuttle. A minute later, the shuttle is closed and ready to take off. Another minute later, the ship [i]does[/i] take off, bathing the landing pad in fire and leaving you alone beneath the saturnine sky.

*temp date_present false

*temp visiting_meta ""
*temp meta_accepted true

*if ((marshal_alive) and ((final_boss != "marshal") and (((TrioStat = "broken") or (TrioStat = "AWOL")) or (TrioStat = "serving")))) and ((RenfriRel > 60) or (official_ro = "renfri"))
  *set visiting_meta "renfri"
*elseif ((rook_alive) and ((final_boss != "rook") and (((TrioStat = "broken") or (TrioStat = "AWOL")) or (TrioStat = "serving")))) and ((RookRel > 60) or (official_ro = "kirill"))
  *set visiting_meta "kirill"
*elseif ((lisa_alive) and (((final_boss != "lisa") or (dusk_contained)) and (((TrioStat = "broken") or (TrioStat = "AWOL")) or (TrioStat = "serving")))) and ((LisaRel > 60) or (official_ro = "lisa"))
  *set visiting_meta "lisa"

*if visiting_meta = official_ro
  *set date_present true

You sigh. 
*if federate_protection
  You got what you worked for—freedom and security for you, as well as your entire group. 
*else
  This meeting could have gone a lot worse, as evidenced by the fact that you're still alive. 
And yet, it's difficult not to feel… lonely as you stand there, surrounded by nothing but heated air, utterly alone.

*if visiting_meta = ""
  *goto normal_cont

Until something @{(visiting_meta = "marshal") flies|falls} out of West's ship through the suddenly opened trunk door. 
*if visiting_meta = "kirill"
  Something large and metal… or rather encased in metal. Something protected by a familiar, full suit of power armor. Something [i]meta[/i].
  
  When he hits the ground, after three or four seconds of free fall, he almost cracks the concrete. But his exoskeleton withstands the fall, and so Kirill stands up. "This was… not the most elegant of entries. But it gets the job done, I suppose."
  
  You blink, quite dumbstruck by what you see. By the sight of… him.
  
  *page_break Kirill
  
  "Kirill…" you finally manage to murmur. 
  *if official_ro = "kirill"
    You didn't expect to see your knight in shining armor again, much less so soon. 
  "This is… most unexpected."
  
  "I would imagine so." Kirill removes his helmet, letting you see his dark and tired face. "Stowing away in government ships is hardly my style. But worse things were done in the name of 
  *if (official_ro = "kirill")
    love."
  *else
    friendship."
  
  "None of this is your style," 
  *if damon_present
    Damon points out as he approaches the meta-human. "Tell me what do you want from us, or else I'll seriously consider shooting you."
  *else
    you point out. "You've always struck me as too… proper to do something like this."
  
  Kirill points his blue eyes at the sky, at the ship which flies through it, then back towards you. 
  *if TrioStat = "broken"
    "People change. What happened in Rhea, back on that fateful day, is probably the best proof of that principle. What 
    *if final_boss = "marshal"
      Renfri 
    *elseif final_boss = "lisa"
      Lisa 
    *else
      we 
    did… I doubt I can ever recover from that. I might as well turn over a new leaf, and I may as well do it here."
  *if TrioStat = "AWOL"
    "I must thank you for convincing me not to fight, back then in Rhea. I felt so ashamed when I walked away… but I believe that, in the long run, not serving Federation will make me a happier man."
  *if TrioStat = "serving"
    "I understand if you are surprised. I could have stayed in the Federation, continued serving its government and army, and yet… and I could not. Not after what happened in Rhea. I had to get away from everything, seek redemption somewhere else, and this place is as good as any other for that purpose."
  
  *if damon_present
    "If you're here illegally, then I think we should go inside." Damon heads out of the landing pad. 
  *else
    "Can we maybe discuss it inside?" you offer, then start walking towards the nearest exit hatch. 
  "We wouldn't want West to see you from his ship."
  
  "Of course." Kirill follows. 
  *if damon_present
    So do you. 
  "I have no love for these docks. 
  *if federate_protection
    In fact, I am not planning on visiting them ever again. Staying inside your cozy fortress is a far more appealing prospect."
  *else
    I am only planning to visit them once again, when your flock leaves this station tomorrow."
  
  "Does that mean you want to join our group?" you inquire. "Live with us from now on?"
  
  "It is certainly a tempting prospect." Kirill's voice gets a little more quiet. "But I will only do so with your blessing. With your permission."
  
  *fake_choice
    #"Of course! Welcome to the team, Kirill."
      *set Emotion %+ 8
      *set RookRel %+ 8
      Kirill smiles widely. "Thank you. I do not what I would do if you were to… push me away. I need company, and I am glad that you can offer it."
    *if s9_leader = "player"
      #"As this group's leader, I'm honored to welcome you aboard."
        "And I am honored to join." Kirill says with a deep nod, almost a bow. "I promise, my new leader, that I will make myself useful."
    *if s9_leader != "player"
      #"That's not my decision to make. Ask $!{s9_leader} instead."
        *set Confid %- 5
        *if s9_leader = "manfred"
          "As the leader, I see no issue with admitting Frogmouth into our group," Manfred announces through the speakers. "Welcome to [i]Saturn Nine[/i], and enjoy your stay."
        *else
          "I will talk to her," Kirill promises. "But between you and me… I strongly suspect she will agree, if only for your sake. You are this group's greatest asset, ${name}, and your leader will not dare displease you."
    #"Unlike you, I have no authority to grant blessings. But you have my permission."
      *set RookRel %+ 8
      Kirill smiles. 
      *if master = "Jesus"
        "I believe you [i]do[/i] have that authority. We are likely the only Orthodox Christians left—we can grant as many blessings as we want to."
      *elseif ascended
        "After what you did against $!{final_boss}, I think you [i]do[/i] have the authority to grant blessings. You may even be capable of performing miracles. That kind of power…"
      *else
        "Thank you. And forgive for being overly… poetic with my wording. Old habits die hard."
    #"I'm not sure if you'll fit in... but I'm willing to give it a try."
      "That is all I ask for," Kirill reassures you. "And while I may be difficult to deal with sometimes, I promise that you will not disappointed overall."
    #"No... I don't think you'd get along with the others. You'll be happier somewhere else."
      *set RookRel %- 5
      *goto rook_away
    #"You will not get that permission. Get out of here."
      *set RookRel %- 15
      *label rook_away
      *set meta_accepted false
      "Oh." Kirill's face falls. "Fair enough. 
      *if federate_protection
        I will leave this place as soon as I am able. 
      *else
        When you leave this station tomorrow, I will stay here and wait for federate forces to arrive. 
      You will not have to tolerate my presence for long, if you really hate it that much."
      
      
  
*if visiting_meta = "renfri"
  Something brown and small, though getting larger as it approaches you. It lands gracefully, military boots hitting the concrete floor, caramel feathers scattered beneath the wide Kinnari wings.
  
  "I almost timed my descent wrong," Renfri comments as she folds those wings of hers. "I almost flied into the flames. It would have been a shame, unless someone just ordered roast poultry."
  
  You blink, quite dumbstruck by what you see. By the sight of… her.
  
  *page_break Renfri
  
  "Renfri…" you finally manage to murmur. 
  *if official_ro = "renfri"
    You didn't expect to see the love of your life again, much less so soon. 
  "I didn't… expect to see you so soon."
  
  "I didn't expect to be back so soon either," she replies briskly. "Flying here would have taken weeks, had I used only my wings. Luckily, I found a ship to stow away in."
  
  *if damon_present
    "Well, that ship is still within sensor range, so how about we go inside?" Damon says, heading for the exit from the landing pad, an entrance to the main corridor. "If nothing else, it's cooler there."
  *else
    "I wasn't doubting your ability to get here." You head out of the landing pad and inside the fortress. "I'm just… surprised you decided to do that."
  
  "Right…" Renfri follows, walking rather than flying. 
  *if TrioStat = "broken"
    *elseif final_boss = "rook"
      "After what Kirill did, after what happened in Rhea… I couldn't stay in the federate forces. I just couldn't. I wasn't interested in another team, another leader, another string of misfortunes and betrayals. I figured I could avoid that by going rogue… and so I did."
    *elseif final_boss = "lisa"
      "After what Lisa did, I… needed to get away. From 
      *if rook_alive
        Kirill, 
      *else
        West, 
      from the other feds, from my joke of a career, from everything. And then I needed a place to stay in, so… here I am."
    *else
      *if lisa_shot_rook
        "After what Lisa did in that power plant… I couldn't forgive her, but I wasn't able to kill her either. I just ended beating her up, letting her go, and then deserting myself. It's not like there's a Meta Trio anymore, or anything for me to do in the Federation."
      *else
        "Look… you know what happened in Rhea. I don't need to recount that, and I'd really prefer not to. Just know that I'm not coming back to the feds, and that I'd much rather stay here. With you."
  *if TrioStat = "AWOL"
    "After what you said in Rhea, after we all decided to retreat… I considered coming back to the Federation, but there really wasn't anything left for me there. No team, no career, no friends. On the other wing, I have a 
    *if official_ro = "renfri"
      girlfriend 
    *else
      friend 
    here. So why not make my nest here, I figure? I can't think of a nicer place which wouldn't kick me out immediately."
  *if TrioStat = "serving"
    "After what happened in Rhea, after what we achieved there… I just couldn't stay in the federate forces. I realized that I deserve more than a low rank, a crappy pay and a dysfunctional team. I figured a certain android might treat me better than they did, and therefore I'm here."
  
  "Does that mean you want to join our group?" you inquire. "Live with us from now on?"
  
  "Why not? I'm an outcast just like you, so I wouldn't mind joining the flock." she looks at you hopefully. "Assuming you're fine with that."
  
  *fake_choice
    #"Of course! Welcome to the team, Renfri."
      *set Emotion %+ 8
      *set RenfriRel %+ 8
      "Phew. I thought I'd have to work harder to convince you." Renfri smiles gratefully. "I promise I'll make myself useful. And that I won't leave [i]too[/i] many feathers lying around everywhere."
    *if s9_leader = "player"
      #"As this group's leader, I'm honored to welcome you aboard."
        "And I am honored to join your mighty army." Renfri bows playfully. "We shall rule [i]Saturn Nine[/i] together, 
        *if federate_protection
          until the end of time."
        *else
          until tomorrow that is."
    *if s9_leader != "player"
      #"That's not my decision to make. Ask $!{s9_leader} instead."
        *set Confid %- 5
        *if s9_leader = "manfred"
          "As the leader, I see no issue with admitting him into our group," Manfred announces through the speakers. "Welcome to [i]Saturn Nine[/i], and enjoy your stay."
        *else
          "I will talk to her," Kirill promises. "But between you and me… I strongly suspect she will agree, if only for your sake. You are this group's greatest asset, ${name}, and your leader will not dare displease you."
    #"Sure. Just cut down on bird puns, please."
      *set RenfriRel %+ 7
      "I thought people liked those jokes," Renfri remarks. "But fair enough. Whatever keeps me in your good graces."
    #"I'm not sure... but I'm willing to give it a try."
      "Are you doubting my ability to get along with…" Renfri realizes you have a point. "You have a point. Still… I promise I'll be on my best behavior, and that I will make it work. Somehow."
    #"No... I don't think you'd get along with the others. You'll be happier somewhere else."
      *set RenfriRel %- 5
      *goto renfri_away
    #"I'm not. Get out of here."
      *set RenfriRel %- 15
      *label renfri_away
      *set meta_accepted false
      "What? But I thought…" Renfri bites her lip, and perhaps her tongue too. "You know what? Fine. I don't want to be a part of your stupid group anyway. I'll find equipment that will let me fly off, 
      *if federate_protection
        or maybe I'll wait for some other ship to dock. 
      *else
        or maybe I'll stay here after you're gone and wait for the feds to arrive. 
      Either way, you won't have to tolerate my presence for long."
  
  
*if visiting_meta = "lisa"
  It, or rather she, spends two or three seconds in free fall before hitting the ground with her hands and knees.
  
  "Look at that, I managed to land on all fours," Lisa says. She stands up with some difficulty, then dusts her grey trousers off. "I thought this was mostly a cat thing. Neat."
  
  You blink, quite dumbstruck by what you see. By the sight of… her.
  
  *page_break Lisa
  
  "Lisa…" you finally manage to murmur. 
  *if official_ro = "renfri"
    You didn't expect to see the love of your life again, much less so soon. 
  "What… how…"
  
  "How am I here?" the redhead smiles. "I always dreamed of being a stowaway. When I heard West intends to visit your fortress again, well… I saw my chance and took it."
  
  *if damon_present
    "Well, I'm really glad you did," Damon smiles, then starts walking towards the nearest hatch. "But can you come inside? I wouldn't want West to see us talking here."
    
    "Sure." Lisa follows. 
  *else
    She heads towards the nearest hatch, eager to get away from open space where West could conceivably spot her. 
  *if TrioStat = "broken"
    "Oh, and if you worry that 
    *if (rook_alive = false)
      the feds 
    *elseif final_boss = "rook"
      Renfri 
    *elseif final_boss = "marshal"
      Kirill 
    *else
      my teammates 
    will come looking for me, don't. 
    *if (rook_alive = false)
      They're too busy arranging a funeral for Kirill and covering up what happened in that power plant. 
      *if lisa_shot_rook
        And getting Renfri to calm down."
      *else
        I bet they'll erase Renfri from all records, just to swipe… her tantrum under the rug."
    *elseif final_boss = "rook"
      *if marshal_alive
        She… didn't exactly make it. Dead from internal bleeding, you see."
      *else
        She's a little… heartbroken after what Kirill did. Not to mention seriously injured. I doubt we'll see her again."
    *elseif final_boss = "marshal"
      He's heartbroken over what Renfri did, surprisingly enough. I didn't know he had a heart."
    *else
      They're not any happier about what happened in Rhea than I am. I don't think there's even a Trio anymore, or a Duo for that matter."
  *if TrioStat = "AWOL"
    "And in case you're wondering, I don't know where Renfri and Kirill are. I imagine she's on the run and he's begging the command for forgiveness, but I haven't actually seen them since we parted. Which sucks, but that's just life."
  *if TrioStat = "serving"
    "And don't worry, I didn't tell Renfri I was going to join you. It was kinda painful, having to leave her without a proper goodbye… but she chose her allegiance long ago."
  
  "Does that mean you want to join our group?" you inquire. "Live with us from now on?"
  
  "Why not?" Lisa shrugs, though you can tell she's tense. Uncertain. "I'm a stray like you guys, an exile and an outcast. I'd fit right in… wouldn't you agree?"
  
  *fake_choice
    #"Of course! Welcome to the team, Lisa."
      *set Emotion %+ 8
      *set LisaRel %+ 8
      "And here I thought I'd have trouble convincing you." Lisa smiles with relief. "I guess you're really starved for some canine company. But that just means everybody wins."
    *if s9_leader = "player"
      #"As this group's leader, I'm honored to welcome you aboard."
        "You're always so formal," Lisa teases you, likely to hide her immense relief. "So official and dignified. It suits you, but makes you sound… old."
        
        *if Emotion > 50
          "I'm not [i]always[/i] like that," you protest with a smile. "You just make me look formal by comparison."
        *else
          "I am an old ${sex}," you say matter-of-factly. "Don't blame me for sounding the part."
    *if s9_leader != "player"
      #"That's not my decision to make. Ask $!{s9_leader} instead."
        *set Confid %- 5
        *if s9_leader = "manfred"
          "As the leader, I see no issue with admitting the Hound into our group," Manfred announces through the speakers. "Welcome to [i]Saturn Nine[/i], and enjoy your stay."
        *else
          "Sure, I'll talk to her later," Lisa promises. "But I don't think it will be an issue. No one can afford to turn down a guard dog of my quality." 
    #"I agree. I always wanted to adopt a stray dog."
      *set LisaRel %+ 8
      "That wasn't even a good dog joke," Lisa replies, though she does snicker. "Work on your material, android pal."
    #"I'm not sure if you'll fit in... but I'm willing to give it a try."
      "Hey, I already get along with half of your group," Lisa says with a glance at Damon. "Getting the other half to agree shouldn't be… too difficult."
    #"No... I don't think you'd get along with the others. You'll be happier somewhere else."
      *set LisaRel %- 5
      *goto lisa_away
    #"I do not agree. Get out of here."
      *set LisaRel %- 15
      *label lisa_away
      *set meta_accepted false
      "What? But I thought…" Lisa bites her lip, and perhaps her tongue too. "You know what? Fine. I will leave this fortress as soon as I'm able. 
      *if federate_protection
        Maybe I'll ask Manfred to give me a ride, or maybe I'll wait for some other ship to dock. 
      *else
        Or maybe I'll stay here after you're gone and wait for the feds to arrive. 
      Either way, you won't have to deal with me for long."
  
*if meta_accepted
  *if damon_present
    "I didn't think we'd ever increase our group size," Damon remarks. "Not that I'm complaining. The more the merrier, 
    *if visiting_meta = "kirill"
      and it's always good to have someone-"
    *if visiting_meta = "renfri"
      and I'm sure 
      *if wisp_alive
        Wisp will appreciate having some flying-"
      *else
        your powers will come-"
    *if visiting_meta = "lisa"
      and I'm glad you decided-"
  *if org_alive
    *if hadaly_free
      *if (damon_free) and ((final_boss != "damon") or (dusk_contained))
        *if wisp_alive
          *if (SheilaStat != "dead") and (SheilaStat != "exiled")
            *achieve saturn_ten
  *elseif deflect < 1
    You spend a moment simply staring at one another. Two people, an android and a meta-human, a machine and a biological being. Both of you lost people, lost friends, lost [i]so much[/i] in the last few weeks alone. 
    *if not (date_present)
      That's the sort of connection, the sort of friendship, which can only be forged in the fires of battle, and only cooled in the void of space.
      
      *goto look_at_one
    And yet, looking into these 
    *if visiting_meta = "kirill"
      sky-blue 
    *if visiting_meta = "renfri"
      almond 
    *if visiting_meta = "lisa"
      grey 
    eyes, you're able to forget all the pain, however briefly. For a moment, you do not hear the shrieks. For a moment, you are submerged in silence.
    
    *goto look_at_one
    
*else
  *if damon_present
    "And here I hoped we'd finally enlarge our little bunch," Damon remarks. "I guess we're staying exclusive. 
    *if s9_leader = "sheila"
      At least Sheila will be-"
    *else
      Such a-"

*goto birth_hub

*label normal_cont

*if damon_present
  That is until Damon comes out of his hiding spot and approaches you. "So I guess it's settled. 
  *if federate_protection
    We're staying here, in our rusty old fortress. 
    *if hammon_made_prot
      It's a shame we had to trade… one of ours to make that happen."
      
      *fake_choice
        #"Damon... I'm so sorry. I don't know what I was thinking, or doing, or..."
          "It's not your fault…" Damon says quietly and perhaps dishonestly. "We had to either make a sacrifice or lose everything. I just wish-"
        #"It was her choice, Damon. Don't blame anyone else for it."
          "I'm not blaming anyone," Damon protests weakly. "I just wish there was another way. I wish I were able-"
        #"There was no other way. Hammon was always going to win in the end."
          "I suppose you're right," Damon says grimly. "For all we know, Hadaly may end up happier with him than she ever was with us. I just wish-"
        #Say nothing.
          "Nothing to say?" Damon smiles bitterly. "I get it. In your place, I wouldn't be sure what to-"
      
      *goto birth_hub
    The Veteran actually pulled it off, just like everyone thought you would."
    
    *fake_choice
      #"Don't say that. We won, but it cost us... quite a bit."
        *if not (hadaly_free)
          "Tell me about it," Damon sighs. 
        *elseif crystal_stat = 3
          "We did release a few… billion… murderous nanites," Damon admits. 
        *elseif not (wisp_alive)
          "Yeah… poor Wisp…" Damon sighs. 
        *else
          "It definitely took us some effort," Damon admits. 
        "Still, we got where we wanted eventually. That's something worth cele-"
      #"I don't think people believed in me at the start. I don't think I believed in myself."
        *set Confid %- 10
        "You're selling yourself short," Damon says comfortingly. 
        *if Confid > 45
          "That's unlike you. Find that confidence you're always so-"
        *else
          "Again. You should really work on your self-esteem, or maybe-"
      #"Yup. I knocked it out of the park and made no mistakes along the way."
        *set Confid %+ 10
        "I wouldn't go that far…" Damon rolls his sapphire eyes. "Still, you did a good job, and I believe everyone would-"
      #"It was a team effort, Damon. Don't forget that."
        *set DamonRel %+ 8
        "I suppose it was." Damon smiles weakly. "Several people contributed. 
        *if injured_crystal = "damon"
          In fact, I remember shooting Crystal directly in the-"
        *else
          I just don't think I was particularly-"
      *if not (likes_s9)
        #"I almost wish I [i]didn't[/i] pull it off. I don't like this place."
          "I know." Damon nods. "That makes your efforts all the more impressive. You fought and won not for yourself, but for the sake of your-"
  *else
    We're moving out. I knew that was coming, but… it still sucks to be at this point."
    
    *fake_choice
      #"It was going to happen sooner or later. At least we bought ourselves some time."
        "Perhaps you're right," Damon says grimly. "Still, I can't help but wonder if, in another timeline-"
      #"I'm sorry. I should have tried harder. I should have been more effective."
        *set DamonRel %+ 8
        "You were more effective than any of us," Damon reassures you. "You just made some… controversial choices along the way. Still, I respect everything you-"
      #"You know... we could probably hit West's ship with that laser you've installed."
        *set Violence %+ 5
        *set DamonRel %- 5
        "And make absolutely sure that the Federation pursues us?" Damon shakes his head. "No. Petty revenge isn't worth it. Besides, I don't think that gun actually-"
      *if likes_s9
        #"Tell me about it. This station was my home for so long..."
          "You were here when the Calamity happened, right?" Damon smiles sympathetically. "Look at the bright side. At least now, you'll be further away from the source of these memories, of these flashbacks that keep-"
      *if not (likes_s9)
        #"Speak for yourself. I never liked this place."
          *set DamonRel %- 8
          "I know you didn't," Damon says grimly. "And I suspect that's the main reason for our defeat, you-"
*else
  You grow bored of the feeling soon, and so hurriedly leave the landing pad. You enter the enclosed part of the fortress, where the temperature is just right, and boundless sky doesn't make you feel small or meaningless. 
  *if federate_protection
    *if likes_s9
      The corridors all feel pleasantly familiar, making you feel welcome. Feel home.
    *else
      It almost puts you at peace with the prospect of spending the rest of your life in this decrepit fortress. Almost.
  *else
    *if likes_s9
      The corridors are pleasantly familiar too—it's a shame you'll never see them again, not after you leave the fortress tomorrow.
    *else
      For once, you actually enjoy traversing [i]Saturn Nine[/i]—ironic, considering you're about to leave the station forever.

*label birth_hub

*if birthday
  "$!{name_manfred}, we have a situation in the cafeteria," Manfred says, loudly and without preamble. 
  *if s9_leader = "player"
    "As our leader, you should probably 
  *else
    "I'd like you to 
  take a look at it."
  
  *if visiting_meta != ""
    *if visiting_meta = "renfri"
      "I'll tag along," Renfri says, not really asking for permission. "Since I'm here, I might as well make myself useful."
    *if visiting_meta = "lisa"
      "Good thing you have a guard dog with you, huh?" Lisa smiles. "Let's see how dangerous that [i]situation[/i] is."
    *if visiting_meta = "kirill"
      "May I accompany ${name} on this inspection?" Kirill offers. "I should be able to help, especially if the problem is somehow related to nano-machines."
      
      "I don't believe it is," Manfred replies. "Nonetheless, I see no harm in you tagging along."
  *elseif damon_present
    "Ah, right," Damon says, more to himself than to you. "I forgot… I mean, I feared there'd be a situation today. I'll come with you, ${name_damon}, just for extra security."
    
  *fake_choice
    *if (visiting_meta = "") and (damon_present)
      #"Damon... is there something you're not telling me?"
        "Why would you think I'm not telling me something?" Damon doesn't actually answer your question. "Now let's go. We don't want to keep the situation waiting."
    *if (s9_leader = "manfred")
      #"You're the leader now, Manfred. Can't you take care of this issue?"
        "I'm taking care of it by ordering you to take care of it," Manfred explains. "That's what leadership is all about, right?"
    *if (s9_leader = "sheila") or (s9_leader = "hadaly")
      #"Does $!{s9_leader} knows about our new problem?"
        "She most certainly does," Manfred reassures you. "In fact, I think she's already on the scene, so join her as soon as you're able."
    *if (s9_leader = "player")
      #"As a leader, don't I have the right to send someone else?"
        "I believe everyone, except 
        *if damon_present and (visiting_meta != "")
          the three of you, 
        *elseif (damon_present = false) and (visiting_meta = "")
          you, 
        *else
          the two of you, 
        is already on the scene," Manfred replies. "Might as well join them, my honorable leader."
    *if damon_present
      #"Sure. Come on, Damon, let's see what's going on."
        "Yeah. I am extremely curious," Damon says flatly. "After you."
    #"Of course. It's my job to fix everything all the time."
      "I promise, you will be rewarded for your pains and efforts soon," Manfred reassures you. "Just get to the cafeteria first."
    #"Situation? You are being extremely vague."
      "By necessity," Manfred replies even more vaguely. "I promise, everything will be clear within a minute at most."
    #"I'd like some further details first, Manfred."
      "You will get all the details you need… once you arrive on the spot," Manfred promises. "Trust me on that, $!{name_manfred}."
    
  *if damon_present and (visiting_meta != "")
    You, Damon and $!{visiting_meta} 
  *elseif damon_present and (visiting_meta = "")
    You and Damon 
  *elseif (damon_present = false) and (visiting_meta = "")
    You 
  *else
    You and $!{visiting_meta} 
  quickly make your way through the corridors and towards the cafeteria. Manfred does not provide any further explanations, he just uses hall cameras to silently watch you. 
  *if Database < 40
    Whatever problem he needs help with must occupy the vast majority of his attention.
  *elseif Database > 60
    You get the feeling you know precisely what's going on, but you don't share your suspicions just yet.
  *elseif ManfredRel >= 50
    If he weren't your friend, you'd suspect him of leading you into some kind of trap, but it stands… you have no idea what to expect.
  *else
    Which makes you a little uneasy—what exactly is this bundle of code planning, and is anyone else involved? Are you walking into a trap? If so, why is Manfred being so… unsubtle about the whole thing?
  
  After about a minute, you reach the cafeteria door and push it open. You are immediately assaulted, not once but twice—an inarticulate sound bruises your ears as something very light falls on your head. You'd feel alarmed, but the room is filled only with your companions. Hadaly, 
  *if (SheilaStat != "dead") and (SheilaStat != "exiled")
    Sheila, 
  Hugo, Olivia, 
  *if wisp_alive
    Wisp, 
  Miguel… you are among friends, not enemies.
  
  You open your hand and let one of the tiny things fall on it. A piece of paper, small and colorful, as though cut from some particularly lively propaganda magazine. There is a word for it, but you don't remember it… You recall the sound, but not where you first heard it… it must have been hundreds of years ago, possibly a thousand… dating back to the days when there was still laughter.
  
  "Surprise!" Olivia shouts from the table she's lying on. A table which, as you now notice, also supports a large square cake with hundreds of burning candles, possibly a thousand… and then, holding what you realize is a piece of confetti, you understand.
  
  It's… a party. A [i]birthday[/i] party.
  
  *page_break Huh
  *achieve birthday
  
  "Happy Birthday!" Hadaly joins in on the cheer, though there is a hint of blue in her eyes. "Your one-thousandth one, no less. That has to be a record, I think."
  
  Hugo blows on his party horn again. Olivia claps her tentacles. Manfred plays a clapping sound effect. 
  *if (SheilaStat != "dead") and (SheilaStat != "exiled")
    Sheila reluctantly hits one of her metal legs with another.
  
  "We've been planning this for a while," Miguel adds with a smile. 
  *if checked_on_org_1
    "Truth almost got out when you visited us last month, but we somehow remained undercover."
  *else
    "I'm surprised you haven't noticed us baking the cake, but then again, it's not like you visit the kitchen often."
  
  *if wisp_alive
    "Happy Birthday, Veteran $!{name}!" Wisp joins in. It levitates just below the ceiling and bathes the cafeteria with unusually colorful light. "May you live a hundred years! Another hundred years, that is. Or maybe more if you'd like to."
  
  *if damon_present
    "Happy Birthday indeed." Damon places a hand on your shoulder. "We actually wanted to throw this party earlier, but stuff kept getting in the way. 
    *if federate_protection
      But thanks to you, there's nothing to worry about anymore, so may as well celebrate."
    *else
      Now is our last chance, so we decided to go for it."
  
  *if visiting_meta = "kirill"
    "Most unexpected, but most kind," Kirill comments thoughtfully. "Or at least those are my impressions. I do not know how our prime celebrant is feeling."
  *if visiting_meta = "renfri"
    "I actually helped a little before I left the station," Renfri remarks. "Mostly with carrying flour, but still."
  *if visiting_meta = "lisa"
    "Not a bad party," Lisa comments as she looks around the room. "I don't see any alcohol, but… I guess it's not [i]that[/i] kind of celebration."
   
  *fake_choice
    #"Ah. So this is the situation you wanted me to deal with."
      *set Emotion %- 8
      *if damon_present
        "We had to lure you in somehow," Damon shrugs. "And it worked. Now we can proceed to the fun part."
      *else
        "We figured it would be best to preserve the element of surprise," Manfred says diplomatically. "For your own enjoyment, of course."
    #"Birthday party? Confetti? Cake? These things are basically extinct nowadays."
      "That's basically the whole point," Manfred explains. "Don't take this the wrong way, Veteran, but you're ancient. So, for your one-thousandth birthday we decided to recreate an ancient tradition as accurately as we could."
    #"Wow, I... don't really know what to say."
      *set Emotion %+ 5
      "You don't need to say anything," Hadaly says with a smile. "Just check out what we've got prepared."
    #"Huh. I suppose that's not the worst birthday party I've ever seen."
      *set OrganRel %- 5
      *set HadalyRel %- 5
      *set Emotion %- 5
      "Grateful and 
      *if Emotion > 50
        polite 
      *else
        emotional 
      as always," 
      *if (SheilaStat != "dead") and (SheilaStat != "exiled")
        Sheila says flatly. 
      *else
        Olivia says with an eye-roll. 
      "At least look at what we've prepared first."
    *if gift_status != 3
      #"You're throwing me a party? Great! Do I get any birthday gifts?"
        *set Emotion %+ 8
        "Sure." Olivia points one of her tentacles towards the room's corner. "Though I'm not exactly sure what the gift is myself. Someone did a very poor job explaining that."
    *if s9_leader = "Sheila"
      #"I'm surprised you authorized this, Sheila. Don't you hate fun?"
        If Sheila had eyes, she would have rolled them. 
        *if official_ro = "sheila"
          "Are you forgetting that I love you? 
        *else
          "I'm opposed to wastage, but you [i]have[/i] helped our group greatly. You've helped [i]me[/i] greatly. 
        I would not deny you your special day."
    #"Thanks, but... you realize it's probably not my actual birthday?"
      "Technically, you were never born at all," Manfred points out. "Nevertheless, we decided to commemorate your creation, since it's something you duly deserve."
    #"This is stupid. I'm leaving."
      *set asshole_be true
      *achieve audacity
      *set OrganRel %- 15
      *set HadalyRel %- 15
      You disappoint—and possibly surprise—everyone in the room by turning around and walking back inside the corridor. They should not be shocked, for birthdays are nothing but foolish frivolity, and you have absolutely not time for them.
      
      *goto s9_epilogue
    #Stand there, silent and shocked.
      "Well, looks like we broke our Veteran," Olivia remarks. "I just hope ${pronoun}  
      *if pronoun = "he"
        fixes himself 
      *if pronoun = "she"
        fixes herself 
      *if pronoun = "it"
        fixes itself
      *if pronoun = "they"
        fix themselves 
      before the unpacking."
  
  *if gift_status != 3
    You notice something large, covered by a grey sheet, standing pressed against the wall. 
  *if gift_status = 1
    A stack of presents, you assume, or perhaps a single large one. You companions really outdid themselves this year.
  *if gift_status = 2
    It's likely the arcade cabinet Hadaly showed you earlier, except fully finished and perhaps enhanced. She's been working on that gift for a while now, after all.
  
  *if gift_status != 3
    "That's something we… mostly yours truly… have been working on since December," Hadaly explains, then points you towards the cake. "But that comes later. First, I think you should make a wish… or perhaps more than one."
  *else
    "We could not decide on the right present for you, so we focused on foodstuff." Miguel looks at the cake, likely his own creation, with unrestrained pride. "It had to be something special, and I think we pulled through."
  
  You approach the table, and the gateau placed atop of it. You do some quick counting and indeed, it has a thousand candles sticking out of it. One for each year of your existence, give or take one. A monument to a long and eventful life.
  
  "We know you can't exactly breathe, so…" Miguel hands you a hairdryer. "Use a tool. It doesn't make the act any less profound."
  
  *fake_choice
    #"Profound? It's just blowing candles and making a wish. Just a silly little thing."
      "In times such as these, hoping that your wish gets granted is nothing short of miraculous," Manfred says profoundly. "So do that silly thing, please."
    #"I believe it does. I wish I had lungs..."
      *set Confid %- 5
      *set Misan %- 5
      "This is not the time for self-deprecation," 
      *if (SheilaStat != "dead") and (SheilaStat != "exiled")
        Sheila 
      *else
        Hadaly 
      says firmly. "Just make a wish, and hope it will come true."
    #"A machine using a machine. Fitting, I suppose."
      "Can we not dwell on that, please?" Hadaly suggests. "We have candles to extinguish."
    #"Thanks. Whose hair dryer is that, incidentally?"
      "Don't look at me," Hadaly says when Olivia looks at her. "It's not like I ever get my hair wet. I'd be risking an electric shock."
      
      "Mine," Hugo says. "I like… to swim. Recently. Helps with health."
    #Proceed silently.
  
  You approach the cake and feel its heat, temperature born of a thousand little flames. Your friends got their history right—it was once a tradition to make a silent wish before extinguishing the candles. You place your finger on the button, one you assume will activate the hairdryer, and wish…
  
  *choice
    *if (deflect > 0) #...for inner peace.
      *set deflect - 2
      You know not to ask for impossible. You will never be fully free of pain, and death will claim you eventually. But you can be at peace with that, or at least you hope you can.
    #...for this day to last forever.
      *label forever
      It cannot last forever. Nothing lasts forever. But you wish it could, and so the desire dominates your thoughts in that fateful moment.
    #...for money.
      It's a silly wish, especially for someone in your situation. But it's a silly ritual, and so everything checks out.
    #...for all my friends to live as long as I did.
      Some of them simply cannot live that long. Hugo and Olivia will decay relatively soon, Miguel 
      *if (SheilaStat != "dead") and (SheilaStat != "exiled")
        and Sheila 
      will follow, even 
      *if damon_present
        Damon and 
      Hadaly are unlikely to live a literal thousand years. But it's your wish, and so you make it all the same.
    #...for Dusk to stay imprisoned, stay defeated, stay away forever.
      Dusk is the Eater of Earth, the end and the death, the destiny of humanity. And yet, you hope against hope that your wish will somehow keep its power in check. That it will, at the very least, prolong the Solar system's life, and the lives of everyone you care about.
    *selectable_if (federate_protection) #...for our truce with the Federation to last forever.
      *goto forever
    *selectable_if (pacifist) #...to never have to kill anyone. @{(heaven_side = "Neutral") Ever.|Not again.}
      *set Violence %- 20
      Ever since 
      *if (heaven_side != "Neutral") or (mas_kill)
        the War In Heaven, 
      *else
        your activation, 
      you managed to maintain a mostly clean conscience. It took a lot of effort and perseverance, and so you won't let anyone defile your purity. You will not kill anyone. Ever.
    *selectable_if (Violence < 50) #...that I'll never experience war again.
      *set Violence %- 15
      Conflict, if necessary, for there is no life without strife. But not war. Not that horror you're so intimately familiar with. You don't want to go back.
    *selectable_if (Misan < 50) #...that I were human.
      *set Misan %- 15
      It's an old and silly wish, but you are old and this [i]is[/i] a silly ceremony. And so you wish for humanity all the same.
    *selectable_if (Misan > 50) #...for all humans everywhere to die.
      *set Misan %+ 15
      Who knows? It might just work, and the resulting genocide may just spare Miguel and Hugo. It's certainly worth a try, at the least.
    *selectable_if (deflect > 0) #...for the end to finally come.
      This party is really nice and all, but… it doesn't change how you feel. It doesn't make you want to live. You will await the end all the same.
  
  You blow out all the candles with a single swipe of the hairdryer. Everyone cheers, though some do so louder than others—you imagine quite a lot of work went into igniting all these little sticks in the first place.
  
  "Great! Now, we can finally proceed to consuming the cake," Hadaly announces as your group converges on the table. "Miguel said he's a good baker, and that this recipe is most unique."
  
  Your brow furrows. "You know I can't eat that, Hadaly. And that you can't eat it either, for that matter."
  
  "That's why I called it a unique recipe." Miguel calmly carves out a piece of cake, places it on a flat platter and hands it to you. "This cake, if you can even call it that, is basically just water and sugar. You can't taste it, and it will not serve you as sustenance, but you can put it in your system safely. Most will evaporate, the rest can be easily cleaned. In a way, you [i]can[/i] eat it, or at the very least pretend you do."
  
  *temp ate_cake false
  
  *fake_choice
    #"Awesome! If I knew that sort of thing was even possible..."
      *set Emotion %+ 8
      *set OrganRel %+ 8
      "You would have done it earlier, in worse company and with a lesser effect." Miguel pats you on the shoulder. "No sense in wondering what could have been. Plenty of sense in eating."
    #"Really? That's... very considerate of you."
      *set OrganRel %+ 8
      "Don't mention it," Miguel says with a smile. "Better start eating. Otherwise, Olivia won't leave you as much as a bread crump."
    #"That won't be necessary. I feel no need to emulate human habits."
      *set Confid %+ 5
      *set HadalyRel %+ 8
      *set SheilaRel %+ 8
      *if Misan < 50
        *set Misan %+ 8
      "Part of me is disappointed we wasted so much effort." Hadaly 
      *if official_ro = "hadaly"
        grabs your hand, letting you feel her warmth and care. 
      *else
        smiles at you. 
      "But a bigger part is kinda proud of you. Of your self-respect. Of your inhumanity."
      
      "I won't pretend to understand what you're talking about," Miguel sighs. "But I won't ask either."
      
      *goto skip_eating
    #"No thanks. I'd rather keep my interior clean."
      *set OrganRel %- 8
      "Your choice." Miguel shrugs, as though to hide his disappointment. "More food for the rest of us."
      
      *goto skip_eating
    #"That's nice, but... can I go already? I need to charge myself up."
      "We were all hoping you'd stay and enjoy the party… but I won't force you into anything," Miguel says in a polite tone, but with a grim expression. "It means more cake for us, if nothing else."
      
      You feel a little bad as you walk out of the cafeteria, but only a little. You have entertained your companions, sacrificed some your energy and time out of respect for their efforts. You will do no more—you're not human, and so human traditions do not particularly appeal to your tastes.
      
      *goto s9_epilogue
    #Start eating the cake cautiously.
      *set Confid %- 5
  
  You nib at the cake, quickly confirming that it has the density of snow. If nothing else, you won't be poisoning your system [i]much[/i], and so you take a proper bite.
  
  *set ate_cake true
  
  It has no taste, as could be expected. But you can still feel its softness, its texture, its presence in your throat once you're done chewing. It's not proper food consumption for sure… but it's something close to eating, and perhaps close enough.
  
  You probably shouldn't think about it too much. You're here to have fun, after all.
  
  *page_break
  
  The event goes on. 
  *label skip_eating
  Olivia starts devouring the cake like crazy, whereas Hugo does it cautiously. 
  *if (SheilaStat != "dead") and (SheilaStat != "exiled")
    Sheila 'drinks' some of it with her liquid induction port. 
  *if damon_present
    Hadaly and Damon take polite portions, experimenting with it much like you 
    *if ate_cake
      just did. 
    *else
      were supposed to. 
    It's a good time for everyone… 
    *if wisp_alive
      with possibly one exception.
    *else
      or at least looks like it.
  *else
    Hadaly excuses herself from eating, either not trusting in Miguel's cooking… or not really feeling up for celebrations. Understandable, given how recently she lost a brother.
  
  *if wisp_alive
    "I wish I could eat cake, or pretend to eat it," Wisp files a complaint. "But I don't even have an opening to put it in!"
    
    "We'll figure something out on your birthday, Wisp," 
    *if (SheilaStat != "dead") and (SheilaStat != "exiled")
      Sheila 
    *else
      Olivia 
    promises. "Right now, we need to focus on-"
    
    "I have a birthday?" Wisp asks. "Like, the thing we're doing right now."
    
    "Sure," Miguel chimes in. "We don't know when you were produced, and you probably don't remember that, but we can pick a date for you. Throw another party sometime."
    
    "Awesome!" Wisp's light gets not only brighter, but also multi-colored like that of a disco ball. It makes the confetti look truly colorful, and makes the party feel even livelier.
    
  *if meta_accepted
    *if visiting_meta = "kirill"
      "I must reiterate what I said earlier." Kirill's voice is soft, yet loud enough to break through the noise. He takes a sip of water from one of the mugs provided before resuming. "This is a nice party. Nicer than my three-hundredth one, on account of people being here. And just as illegal under the federate law."
      
      *fake_choice
        *if official_ro = "kirill"
          #♡ "It's not nearly as nice as our wedding will be."
            Kirill chuckles. "You are getting rather ahead of yourself, my love. But… it is a nice thought. Perhaps one we'll make a reality one day."
        #"I agree, it is pretty awesome. Thank you for being here."
          *set RookRel %+ 8
          "The pleasure is all mine." Kirill nibs on his piece of cake. "To be a part of such gathering… I am glad it's not a thing of the past. Not yet."
        #"I get it. You don't exactly have many friends."
          *set RookRel %- 8
          "Now I do." Kirill says warmly. "Even if they can be… insensitive sometimes."
        #"We'll throw you a party too, I promise. Just tell me the date."
          *set RookRel %+ 8
          "The sixth of June." Kirill puts down the mug. "But do not concern yourself with pleasing me. I am in good company, and that is enough."
        #"You've gone rogue. Do you really care what's legal and what's not?"
          "No," Kirill replies with a slight, yet immensely self-satisfied smile. "I do not."
        #"You don't have to reiterate anything. Just focus on the present and enjoy yourself.
          *set RookRel %+ 8
          "Focus on the present…" Kirill murmurs. "Easier said than done. But I suppose you know that already, and so I'll do my best."
      
    *elseif visiting_meta = "renfri"
      "This is so nice…" Renfri murmurs, so quietly only you can really hear her. "Once, I thought robots don't know how to have fun. That you'd be a killing machine, and your friends would be savage monsters. I was so stupid, wasn't I?"
      
      *fake_choice
        *if official_ro = "renfri"
          #♡ "You weren't that bad. I feel in love with you somehow."
            Renfri laughs. "Maybe you just like bad girls. If that's the case, I'll make sure not to grow [i]too[/i] much in years to come. I wouldn't want to sabotage our relationship."
        #"Don't worry about it. Enjoy the party."
          "I think some folks here may remember me as an enemy." Renfri looks around, her brown eyes darting from person to person a little nervously. "But I'll do my best to change that."
        *if (asshole_be) #"To be fair, some of us robots [i]are[/i] assholes. Including me sometimes."
          "That is true," Renfri chuckles quietly. "I guess we belong together. 
          *if official_ro = "renfri"
            A perfect couple if there ever was one."
          *else
            As friends, that is."
        #"A little bit. But that's understandable, given where you grew up."
          "Where I grew up?" Renfri raises an eyebrow. "I was raised by many people in many places. Oberon, the freighter, Titan… I've seen much of the Solar System before I even came of age."
          
          "My point exactly," you say grimly. "No matter where you're from, this world will shape you into an idiot. All you can do is try to counteract it. However you can."
        #"Everyone changes. At least you've grown rather than regressed."
          "I suppose I did." Renfri's voice is… bittersweet, somehow. "An ugly duckling growing into a swan, like in that fairy tale Kirill once told me. Something for me to be proud of, I guess." 
        #"You can be an idiot sometimes. But you're [i]my[/i] idiot."
          *set RenfriRel %- 8
          "What a prestigious title," Renfri comments dryly. "Are you sure I deserve it? There are other candidates."
          
          "You may be right." You smile as you look over your group. "You're all my idiots. And I love you all for it."
      
    *else
      "Okay, I admit, your guys know how to have fun even without moonshine," Lisa says, once she's done chewing on her own piece of cake. "Still, I wish there was some music. You have a radio in your room, right?"
      
      *fake_choice
        *if official_ro = "lisa"
          #♡ "Yes I do. You're welcome to see it after the party."
            "I imagine you want me to see more than that." Lisa smiles mischievously. "And I'll be all too happy to oblige."
        #"Yes, but I'm not in a mood for propaganda songs. Let's just enjoy the moment."
          "Fair, it's not like there's any [i]good[/i] music being aired these days." Lisa picks up a water mug and drinks from it. "
        #"After we're done here, we can watch a whole movie together. Play some music too, if you'll still feel like it."
          "I forget how much advanced tech you have in this place," Lisa remarks as she finishes eating. "I definitely made the right call when I came here. It's gonna be lots of fun going forward."
        #"Bringing it here would be a hassle. But maybe someone could sing something."
          "Does that mean you're volunteering?" Lisa arches an eyebrow. "Because I'm not a singer."
          
          You shrug. "Neither am I, but I can volunteer if you want. You could do the same thing. It would be fun."
          
          "Perhaps it would," Lisa admits. "But you start. I'm gonna look slightly less stupid that way."
          
          Over the next few minutes, nearly everyone sings at least a few words or notes. Lisa is indeed not that great at this, and neither are other organics, but you quickly teach them how to sing parts of old, quality songs. Pre-Calamity ones, including a pre-Dawn one about twenty-four blackbirds and a pie. It's nonsense, but that's how things are supposed to be—nonsensical songs and a sensible reality, not the other way around.
        *if gift_status != 3
          #"Be patient. I bet that huge gift is something fun."
            *if gift_status = 1
              "That thing in the corner?" Lisa looks towards the covered present. "I suppose there could be something interesting there. I'll hold my breath until then."
            *else
              "Why do I feel you know what that present is?" Lisa eyes you suspiciously. "Do you have like, roentgen vision or something?"
              
              You smile mysteriously. She smiles back. 
              *if ate_cake
                You both go back to eating.
        #"Oh shut up. You're bringing everyone down with your complaining."
          *set LisaRel %- 10
          "Calm down, I'm just bickering for the sake of it," Lisa replies as she finishes the cake. "I do like the party. And most of the company."
  
  *set battery 19
  
  The party goes on for several hours, even though the entire cake is gone after less than half. With so many minds working together, it's not difficult to come up with topics for conversation, or recall games to play together. 
  *if gift_status = 1
    The mysterious gift turns out to be an arcade cabinet, assembled by Hadaly from parts older than you, all in service of a simple shooter game. It's primitive, but fun, and novel enough to interest everyone in this merry gathering. 
  *else
    You play rock-paper-scissors, [i]Hunt the Wumpus[/i], and two whole games of [i]Rhean Retailers[/i]. 
  It's refreshing, fun, nostalgic, full of something you've been missing for so long… but, like all good things, it must eventually come to an end.
  
  When you start running low on battery, and the organics start running out of stamina, you more or less agree to disperse. It hurts a little, to leave your own one-thousandth birthday party, something that can never be repeated… but other things can be. Your friends will be here tomorrow. You will see them again, and there is scarcely anything more important than this certainty.
  
*elseif damon_present
  "I must inform you that the admiral's ship has left our effective range," Manfred dutifully announces. "Suffice to say, it is unlikely to return any time soon. Or any time period."
  
  "I figured." Damon sounds a little upset. "Did you have to interrupt me?"
  
  "Sorry, I just figured I'd let you know as soon as possible. 
  *if federate_protection
    From this precise moment on, for the first time since we came together as a group, we are all safe. That's something worth noting."
    
    *fake_choice
      #"I know. Feels wonderful, doesn't it?"
        *set Emotion %+ 5
        "Indeed," Manfred replies. "My emotion emulators tell me I should be feeling great joy. Later today, I will make sure to adjust my tone and wording accordingly."
        
      #"There's no such thing as safety. Remember that."
        "There is such a thing as [i]relative[/i] safety," Manfred argues. "And seeing how safe this fortress is compared to… everywhere else… I think we've just achieved that."
        
        "We sure did." 
      #"I'm not sure if West will [i]actually[/i] leave us alone. He might need another wyvern killed."
        "Crystal was a uniquely dangerous specimen of a rare subspecies," Manfred points out. "If another wyvern appears, the admiral will likely use his own forces to solve the issue. Or, at the absolute worst, entreat one of us to help."
        
        "Hopefully not me." 
      #"Still, remember your manners. Damon is part of the reason we got this far."
        *set DamonRel %+ 10
        *set ManfredRel %- 5
        "No need to flatter me, boss." Damon smiles coyly. "I'll stick with you either way. We're 
        *if official_ro = "damon"
          meant for one another, 
        *else
          friends, 
        and [i]that's[/i] the reason we got so far."
        
      #"Can the two of you stop talking? I need my rest."
        *label hhhyytt
        *set DamonRel %- 5
        *set ManfredRel %- 5
        "Of course, boss." 
  *else
    We are not exactly on the best terms with the admiral, so tracking his position is important. As is… making optimal use of what little time we have left."
    
    *fake_choice
      #"You're smarter than me, Manfred. Are you sure there's no way for us to keep the station?"
        *set Confid %- 5
        *set ManfredRel %+ 5
        "None at all," Manfred replies sadly. "We cannot hope to sway the admiral anymore, nor to hold our ground against even a modest force of Kronian soldiers. It's over."
        
        "In that case…" 
      #"How about we just relax and do things we enjoy? There's no need for needless stress."
        "Your statement is tautological… but point taken," Manfred responds. "I will be sure to enjoy my last day on Saturn Nine, and I'll encourage everyone else to follow."
        
        "I know what I'll do." 
      #"You talk as though we're about to die. Lighten up."
        *set ManfredRel %- 5
        "A copy of me [i]will[/i] die after move out," Manfred points out. "I'll leave the servers on, but they will go out eventually, or get turned off by the station's new inhabitants."
        
        "I'm sorry about that, but I don't think anything can be done." 
      #"Still, remember your manners. Once we're on the run, we need to be careful not to piss each other off."
        *set ManfredRel %+ 5
        "Unity is the key," Damon concurs. "Not any literal key, I'm pretty sure we'll have to hand those to West… but you get the idea."
        
      #"Can the two of you stop talking? I need to rest."
        *goto hhhyytt
  Damon turns around, then heads for the nearest elevator. 
  *if not (damon_chill)
    "Now excuse me, 
    *if federate_protection
      I need to check if our weapons are skill working. I'm not planning on shooting West as he leaves, but we need to stay safe. Stay protected."
      
      "We sure do, but…" You're not exactly sure what you want to ask. "Shouldn't you be more relieved? Don't you want to relax for once, now that we can afford to do that?"
      
      Damon shrugs. "Maybe later. There's still work to be done, and there will be for a while. So take care." 
    *else
      *if hadaly_free
        I'll ask Hadaly if she has any spare parts for our shuttle. We need to be sure we can repair that thing on the fly before… flying off with it."
        
        "Isn't this Hadaly's job?" you point out. "Should you really concern yourself with it?"
        
        Damon shrugs. "I can't exactly afford to slack off. None of us can."
      *else
        I'll check if there's anything valuable in Hadaly's old room. We can't afford to leave anything important behind."
        
        You can see Damon's face twist as he mentions of his sister. You realize you should probably say something, comfort him or perhaps apologize… but you can't bring yourself to.
    
    *goto watch_door
  "I'll go to the observatory. I'll watch the ship leave, make sure nothing is about to attack us… and then maybe do some stargazing. Have fun studying the sky."
  
  *fake_choice
    #"Can I join? I'd love to count some stars with you."
      *set DamonRel %+ 10
      *if DamonRel > 50
        Damon smiles. "Counting stars? That's pretty blasphemous… but so is being an android, so we might as well do both. Follow me."
        
        In the observatory, you make sure that [i]White Tumbler[/i] has safely gone away, see its silhouette disappear behind Saturnian clouds. You then turn to the stars, once you're fairly sure aren't actually Angels, and admire their natural beauty. You then look at the planets, and then into Saturn itself, staring inside the ocean of yellow. 
        *if saturn_path = "sauce"
          Once a while, something flashes deep inside the planet—you think it may be Sauce, but there's no way to know for sure.
        *if saturn_path = "left"
          For a moment, you believe you see [i]Ocarina[/i] there, though that may just be a play of shadows.
        
        You spend much of the day in the observatory, and see that day turn into night. 
        *if official_ro = "damon"
          You spend that night together too, kissing and cuddling… and perhaps doing more than that. You have the time, and you have each other, and that's all that matters.
        *else
          At that point, you both need to charge your batteries, so you retreat to your respective rooms. You need to be up by morning, after all.
        
        *goto s9_epilogue
      "Actually, boss, I'd rather do it alone." Damon steps through the elevator's doorstep. "No offense, but… 
      *if official_ro = "damon"
        I need some rest from you. Possibly lots of it."
      *else
        we're really not the best of friends."
    #"Good. You deserve to enjoy your life. To catch a break from being a protector."
      *set DamonRel %+ 10
      "Of course I do." Damon smiles weakly, but warmly. "And thanks for helping me realize that."
    #"I don't think stargazing is very fun, but each to their own."
      *set DamonRel %- 5
      "I always found it fun," Damon says, more to himself than to you. "I just never had the time for it, or never [i]felt[/i] like I had the time. Just another thing Hammon programmed into me, I guess."
    #"Off you go, then."
      *set DamonRel %- 10
      "Right…" Damon sighs, as though he was hoping for your company. "Off I go."
  
  *label watch_door
  
  You watch the elevator's door close behind Damon, 
  *if (visiting_meta != "") and (meta_accepted)
    and so does $!{visiting_meta}. The two of you are left alone in the corridor, if you don't count Manfred's continued presence.
    
    *label look_at_one
    
    *if visiting_meta = "kirill"
      *if date_present
        "I admit to feeling a little sleepy," Kirill says after a moment. "May I get an invitation to your quarters?"
      *else
        "So… are you feeling up for a game of chess?" Kirill says after a moment. "My board should be still in my old room."
    *else
      *if date_present
        "So… will you invite me to your quarters?" $!{visiting_meta} asks with a sly smile. "I need a place to sleep in, after all."
      *else
        "So… want to practice shooting with me?" $!{visiting_meta} asks you. "We can do that here, or anywhere else in this fortress. It's a pretty empty place."
    
    *if date_present
      *fake_choice
        #"You can sleep in your old room. I need to be alone."
          *set meta_accepted false
          *if visiting_meta = "kirill"
            Kirill nods. "Naturally. I apologize for my crude, carnal offer. I will give you the space you need."
            
            He 
          *else
            "Oh." $!{visiting_meta} looks disappointed, but she does not press the issue. "Well, I guess I'll see what 
            *if org_alive
              *if visiting_meta = "lisa"
                Hugo 
              *else
                Miguel 
            *else
              Sheila 
            is getting up to. If you need your girlfriend for anything, tell Manfred to call me."
            
            She 
          then leaves, and then you're finally alone. Able to peacefully process everything that happened… or at least attempt to.
        #"Of course. And if you want to do more than just sleep... I'm open."
          *if visiting_meta = "kirill"
            "Then let us 
            *if sex_with_ro
              repeat what we did two weeks ago." 
            *else
              consummate our relationship." 
            Kirill heads towards your room eagerly. "And if the night ends up sleepless because of that… so be it."
            
            You follow him eagerly. It should probably be you leading him, since you know the way better, but that's alright. 
            *if Violence > 50
              You'll take the lead in a few minutes.
            *else
              You don't mind letting someone else lead… or dominate, for that matter.
          *else
            "Why do you think I asked?" $!{visiting_meta} smiles seductively, then turns around. "Now come. I want to see how much stamina your battery can give you."
            
            "Quite a lot," you promise, following your girlfriend towards your room. "Now show me how much enthusiasm you have."
            
            "Quite a lot," she promises back. "Quite a lot."
            
            Many things happen during the next few hours. Some romantic, some purely carnal, some so vulgar they deserve no description. But they're all an expression of love, and that's all that truly matters.
        #"I'd love some company... but no sex. Not tonight."
          *set sex_with_ro false
          *if visiting_meta = "kirill"
            "I see your chastity surpasses mine." Kirill smiles, though you can tell he's a little disappointed. "I can respect that. Let us go to your room, and talk of peaceful things."
            
            "That's the plan." You lead your boyfriend deeper into the fortress, towards a chamber which used to be yours alone. "I think we're both tired of war. We're veterans, after all."
            
            Behind you, Kirill Kosteniuk nods, even if you can't see the gesture.
          *else
            "Sure. I might be thirsty, but I won't say no to cuddles either." $!{visiting_meta} starts walking, already aware of where to find your room. "Coming?"
            
            "Coming." You follow your girlfriend, paying decent attention to how her hips sway. You may not be interested in sex, but the beauty of her inhuman body is nothing short of platonic.
            
            Your life may not be all that great, but your love life… is certainly a reason to hang in there.
        *if visiting_meta = "renfri"
          #"I don't feel like going to bed. How about we spar instead?"
            *label renfri_spar
            "Works for me." Renfri grins. "Just don't get mad once I beat you up."
            
            *if Build > 50
              Renfri does not, in fact, beat you up. 
            *else
              Renfri does indeed beat you up. You are a little rusty, and your battery is far from full, giving her a decisive advantage. However, you find that it doesn't matter—getting to spend time with your @{(official_ro = "renfri") girl|}friend is more than worth a few hits.
        *if visiting_meta = "kirill"
          #"I don't feel like going to bed. How about we play chess instead? I wonder who's the better player."
            *goto rook_chess
        *if visiting_meta = "lisa"
          #"I don't feel like going to bed. How about we play fetch instead?"
            *achieve fetch
            "Play fetch?" Lisa assumes an upset expression and crosses her arms. "Are you assuming that, just because I'm a werewolf, I'd enjoy stereotypically canine games? You're prejudiced and discriminatory."
            
            *if (Database > 55) or (Emotion < 45)
              You raise an eyebrow.
            *else
              "Sorry?" You rub the back of your head nervously. "I just thought you might enjoy that, I meant well, sorry for assuming-"
            
            Lisa snickers. "I'm kidding. I'll totally play fetch with you. Just find something to throw and put that upper-body strength to good use."
            
            You find a piece of cord which, while not as handy as a stick, can be thrown over impressive distances. Lisa fetches it repeatedly and with great efficiency, despite not having enough energy to shift. It looks a little weird, but neither of you really cares.
            
            *goto spending_time
    *else
      *fake_choice
        #"Can we just... talk? Alone, together, in a quiet room?"
          *set deflect - 1
          "Are you making 
          *if visiting_meta = "kirill"
            advances 
          *else
            a pass 
          on me?" $!{visiting_meta} raises an eyebrow. "Because 
          *if visiting_meta = "kirill"
            *if sex = "person"
              I am not particularly 
            *else
              I might just be 
            interested."
          *elseif visiting_meta = "lisa"
            *if sex = "man"
              I might just be interested."
            *else
              in case I haven't told you, I like dicks."
          *else
            *if sex = "woman"
              I might just be 
            *else
              I'm not particularly 
            interested."
          
          You shake your head. "I really just want to talk. I'm hoping to… forget what happened recently, what [i]we[/i] went through, and I think you might want the same thing."
          
          *if visiting_meta = "kirill"
            "Then let us find a room for purpose," Kirill announces. "Because of course I want the same thing. We are both veterans, are we not?"
          *else
            "You might have the right idea," the woman admits. "The things we've dealt with, the wounds we've sustained… it might be nice to spend time with someone who understands me. And likewise."
          
          You quickly find yourself a remote chamber—it's not like there's ever any shortage of those—and then just start talking. Two friends, conversing about various things, from the recent weather trends to 
          *if visiting_meta = "kirill"
            ancient religions. 
          *if visiting_meta = "renfri"
            aerodynamics. 
          *if visiting_meta = "lisa"
            obscure surgical techniques. 
          There is no rhyme or reason to this conversation, but it keeps going all the same, a strangely efficient distraction from the insanity around you.
          
          *goto spending_time
        #"How about we spar instead? We must both stay sharp."
          *set Violence %+ 5
          *if visiting_meta = "kirill"
            *set RookRel %- 5
            "Not my absolute favorite activity, but there is wisdom in your words," Kirill replies tepidly. "I should hone my hand-to-hand combat skills. I will face you in battle."
            
            The 'battle' ends up being little more than a half-hearted boxing match. Neither of you cares about winning, and neither wants to hurt the other one. It's a pantomime, a performance, that offers little excitement and only presents a mediocre training exercise.
            
          *elseif visiting_meta = "renfri"
            *goto renfri_spar
          *else
            "Sharp like werewolf claws?" Lisa transforms her fingers into aforementioned claws. "I'm in. Just don't complain if your outer layer gets scratched."
            
            *if (Build + Calculation) > 100
              It does not. You easily dominate the fight against Lisa, for your @{(official_ro = "lisa") girl|}friend is rather weak in the absence of a World Engine. It's not much of a challenge, and it's not like you can get much more skilled after centuries of combat experience.
            *else
              Your skin does indeed get scratched, and more than once. You are a little rusty, while Lisa is young and feisty, which lets her score a few hits. Still, you give her a bruise in return—you're still an android, and implies an ability to punch really hard.
          
          *goto spending_time
       
        *if visiting_meta = "kirill"
          #"Sure. Let's see who's the better player."
            *label rook_chess
            *check_achievements
            *if choice_achieved_karpov
              "I get think we both know which one of us is better," Kirill says with a slight note of bitterness. "Nonetheless, I expect you to not hold back."
            *else
              *achieve karpov
              "I feel good about my chances," Kirill says, heading towards his old room. "So do not hold back."
            
            Once you find the chessboard, you do not hold back, for you respect your @{(visiting_meta = "kirill") boy|}friend too much for that. He ends up 
            *if Calculation > 50
              utterly crushed, 
            *else
              defeated, 
            but doesn't seem to mind all that much. Victory is irrelevant, even the game doesn't matter that much—you're both in it for the company.
            
            *goto spending_time
        *if visiting_meta != "kirill"
          #"Sure. I'll show you how to aim properly."
            *if visiting_meta = "renfri"
              "My aim is [i]excellent[/i]," Renfri says, though the smile doesn't leave her lips. "Now let me show you."
              
              Renfri is indeed a good shot, and so the training session soon turns into a competition between the two of you. 
              *if Calculation > 50
                You manage to win, but it's a tough battle, and the remains of your target mannequins get destroyed in the process.
              *else
                One you eventually lose, but you don't really mind—you get to spend time with your @{(official_ro = "renfri") girl|}friend, and that's all that really matters.
            *else
              "I would actually like that. I usually fight with my claws, but there's no reason not to broaden my skills." Lisa starts walking towards the shooting range. "So show me how it's done."
              
              You show her how it's done. 
              *if Calculation > 50
                You're quite a good shot, so 
              *else
                You're not an expert sharpshooter, but 
              instructing Lisa is no hard task. She is as attentive as she is inexperienced, and so her skills with a pistol improve quite rapidly under your care.
            
            *goto spending_time
        #"Frankly, I'd rather be alone for now. I need some peace and quiet."
          *if visiting_meta = "kirill"
            "That is more than fair," Kirill says, however disappointed. "Everyone needs their space, and I will grant you yours."
          *else
            "Fair enough," $!{visiting_meta} says, however disappointed. "I just hope you'll find the time for your pet @{(visiting_meta = "renfri") bird|werewolf} eventually. Hardly anyone wants to be alone for long… and I think that might include you."
          
          Once $!{visiting_meta} has departed, and probably walked halfway to @{(visiting_meta = "kirill") his|her} room, you retire to your quarters. You really do need to be alone, at least for now—until you're more at peace with the decisions you've made.
  *else
    then turn away from it. 
    *if Emotion > 45
      Later, you'll do something fun too, but right now… you long for your quarters, and the peace they offer.
    *else
      There is nothing more to do today, and so you head to your room.
    
*else
  You head straight to your room. Your group isn't what it used to be, and you'll see them tomorrow anyway. 
  *if (visiting_meta = "") or (meta_accepted = false)
    Right now, you want to be alone—not a tall order, in a fortress as empty as [i]Saturn Nine[/i].
  *else
    You need to catch up with 
    *if date_present
      $!{visiting_meta}… and possibly do a lot more than that.
    *else
      $!{visiting_meta}, one of your only friends in this insane world.

*goto s9_epilogue

*label spending_time

*set battery 24

You keep on like this for an hour, then two, then until you're both too tired to go on. $!{visiting_meta} gets sleepy and you get de-energized, and so you both head to your respective rooms, comfortable in the knowledge that you'll see one another again. A small luxury, perhaps, but invaluable in the world you're forced to live in.

*label s9_epilogue

*page_break

*set battery 48

One rotation, one Saturnian day later, you're laying idly in your 
*if (room_look modulo 2) = 1
  charging pod, 
*if (room_look modulo 2) = 0
  bed, 
safe between the walls of your @{room_look spacious|cozy|untidy|untidy} room. 
*if (official_ro = "miguel") and (org_alive)
  Miguel is there with you, laying and snoring beside you, so relaxed not even a single hair on his body appears sharpened. 
*elseif (official_ro = "hadaly") and (hadaly_free)
  Hadaly has recently left this room, right after 
  *if sex_with_ro
    completing a particularly creative series of sexual acts with you as her willing participant. You didn't know either of you were capable of bending like you did, or that an impact wrench could be used so effectively during foreplay. Even now, at one thousand years old, you keep learning new things.
  *else
    performing a checkup on you and oiling your joints. You got the feeling that she wanted something more, perhaps for the two of you to finally get sexual, but she knows better than to push. You have al lthe space and time you need, or at least that's what she's claiming.
  
*elseif official_ro = "sheila"
  Sheila lays on the floor and sleeps—you both broke a figurative sweat just an hour later, and while [i]you[/i] could have gone even longer, Sheila's organic brain can only handle so many sensations and so much time without rest.
  
  Not that you mind the quietude. 
*elseif (official_ro = "damon") and (damon_present)
  Damon lays nearby, 
  *if damon_chill
    unclothed, not moving or saying anything, content with simply providing company. 
  *else
    watching the door, as though expecting an intruder and wanting to protect you. Old habits die hard, you suppose. 
*elseif (official_ro = "lisa") and (meta_accepted)
  Lisa is here, sleeping tightly right next to you—she got a bit tired during your 
  *if sex_with_ro
    last intercourse  
  *else
    most recent game of fetch 
  and currently gathers strength through passive rest. Even devoid of her usual energy, her active charm and sharp wit, she's still beautiful. Still beloved. Still yours.
  
*elseif (official_ro = "renfri") and (meta_accepted)
  The floor is largely covered in feathers, the same shade of brown as Renfri's wings and slightly darker than her skin. You would know, 
  *if sex_with_ro
    she's currently lying right next to you. Naked.
  *else
    she was here not so long ago, and only left once you were done preening her feathers. That leech.
  
*elseif (official_ro = "kirill") and (meta_accepted)
  Kirill is in the room with you, holding his guitar with both hands, but he's not currently playing. In fact, he may have just fallen asleep. 
*else
  You're alone, and that's how you prefer it. Or, at the very least, it's something you're used to by now. 
*if deflect < 0
  Not even the Shriek's echoes can disrupt the mystical silence, the sense of peace you're feeling, the tranquility you found yourself in.
*else
  If not for the Shriek's echoes, you'd be in almost complete silence. You almost feel at peace, tantalizingly close to serenity you can never quite achieve.

*if federate_protection
  You look back on the last few weeks, on the struggles you faced and the sacrifices you had to make. 
  *if likes_s9
    You're glad it worked out, you like this fortress and 
    *if (((OrganRel + ManfredRel)) + SheilaRel) < 150
      wouldn't want to leave… 
    *else
      its inhabitants… 
    *if hammon_made_prot
      But you had to sell one of your own to make that 
      *if (Emotion < 40) or (asshole_be)
        happen. For some reason, one you can't quite understand, you're not entirely at peace with that fact.
      *else
        happen,  and your conscience has considerate trouble coping with that fact.
    *elseif (crystal_stat = 3)
      but you can't stop thinking about Janus, about Crystal, and about all the nanobots you've released. Will they come to kill or corrupt your teammates one day? Or will they stick to infecting other people, creating more and more Vessels and threatening other parts of the Solar System in ways you'll never even hear about?
    *elseif not (wisp_alive)
      But you wish Wisp didn't have to die for it. 
      *if crystal_friend
        You wish nobody had to die for it. You wish…
      *else
        Crystal deserved to die, and you failed to catch them, and because of that…
    *elseif not (damon_alive)
      but the place is a bit less secure now that Damon is gone. As well as a bit more grim, as well as a bit emptier, as well as…
    *else
      but it's still connected to some truly dark memories, and those memories [i]will[/i] haunt you forever, both during flashbacks and outside of them.
    
    You shake your head slowly. There's no point thinking about such things, no point looking back more than you're already forced to. The future will come regardless, and it's better to face it than the horrors of your past.
  *else
    All that effort for a station that, in all frankness, you don't really like that much. It makes you wonder what the point even was, and whether 
    *if hammon_made_prot
      selling Hadaly was really the right choice.
    *elseif (crystal_stat = 3)
      you were wrong to kill Crystal like you did.
    *else
      sucking up to West was worth the indignity.
    
    *fake_choice
      *if (ArmyRel > 50) or (RheaRel > 50)
        #At least I have allies in high places now. That will come in handy.
          If anything bad happens, you can probably contact 
          *if ArmyRel > 50
            West 
          *elseif hammon_alive
            Hammon 
          *else
            West 
          and get him to intervene easily enough. You appreciate that safety and power, even as you fail to appreciate your current place of residence.
      *if hammon_made_prot
        #It was. That way, I no longer have to hear her talk.
          Hadaly was so annoying, so sanctimonious, and just so… frustratingly innocent. You're glad she's gone. You don't feel the slightest tinge of regret. None at all.
      #I made my friends happy. It was worth it.
        You didn't participate in this mad hunt for your own sake, but for theirs. As long as they're happy, you'll remain happy too… or at least something close to that.
      #[i]Saturn Nine[/i] isn't as bad as I once thought. I'll get used to it in time.
        The station may be connected to your worst memories, but those are far in the past. 
      *if (crystal_stat = 3)
        #I wanted Crystal dead and the Dusk nanites released. I achieved my objective.
          You have to suffer certain discomforts, that's true. But thanks to your actions, other people will get to suffer even more. It's all for the greater evil, and so you'll endure living in this fortress.
      #I don't know what I was thinking. This is such a terrible ending.
        Why did you choose this? It's so unsatisfying, so unfitting, so… boring. If you had anyone to blame but yourself, you'd be furious at that person right now.
    
  You spend a few hours hibernating, charing your battery and clearing your RAM. When you wake up, you're almost ready for another mission, another tense conversation or deadly fight, but instead you get… nothing. Nothing threatens you, nothing demands your attention, nothing needs to be done by you specifically. Security has been achieved, at least for the time being, and everyone in the group can now enjoy it.
    
  Only now do you realize how much life is bound to change, how different the future will be from the past. You will need to find something to do, some mundane and easy job, or perhaps just a hobby. Something to take your mind off the flashbacks, which are bound to keep occurring at least as often as they used to. You need to stop surviving and start living, however cliché that might be.
  
  *fake_choice
    #I will become a mechanic. @{hadaly_free Gods know Hadaly needs help.|We certainly need that after Hadaly... disappeared.}
      *if hadaly_free
        Hadaly is great at her job, but she can't do everything alone. You will become her assistant, her coworker, maybe a competitor in some sense of the word. Two mechanics are always better than one, especially in a floating fortress such as this one.
      *else
        It's kind of your fault Hadaly is no longer here to fix all the broken system… or you. Taking up engineering might or might not be a pleasant endeavor, but someone has to do it, and that someone might as well be you.
    *if damon_chill
      #I will take up stargazing and astronomy. @{damon_free Join Damon in his pursuits.|Do what Damon used to before...}
        *if damon_free
          You shake that thought off before it can ruin your mood. 
        *else
          Damon really knows how to pick an interesting hobby. 
        You will make staring at the sky a central part of your life, though you won't just idly stare at the firmament—you will catalog the stars and restore long-lost astronomical knowledge, one tiny light at the time. It will take you decades, maybe even centuries, but you're one of the few people left who may just have that kind of time. And one of the few people with the motivation to do so.
    *if wisp_alive
      #I will play silly games with Wisp, and whoever decides to join. Riddles, crosswords, variable orthogonalization, you name it.
        You have playmates, and so you have the capacity for play. 
        *if checked_on_org_2
          There's even a whole board game lying around in the kitchen now. 
        You will amuse yourself in countless simple, silly ways, and pass the time that way. You will amuse others, and make that the purpose of your life.
    #I will scour the station for old books, movies, magazines, anything. I will become an archivist of old media.
      You are a fossil, and so you'll dedicate your life to preserving other fossils. You will gather everything you can, purchase everything you can easily afford, maybe even start recording and archiving radio programs as they air. Anything to fight the passage of time and defend the past against the future.
    *if (visiting_meta = "kirill") and (meta_accepted)
      #I'll just ask Kirill to give me some ideas. Maybe he can even teach me something.
        Chess, guitar, unethical uses of nanotechnology… Kirill has quite a few skills, and he should be eager to share his knowledge with 
        *if official_ro = "kirill"
          the love of his life. 
        *else
          a friend like you. 
        You will fight boredom and grow closer together, all at the same time. A perfect solution, at least as far as you're concerned.
    #I will take up knitting. I am old, and I don't mind clichés very much.
      You'll need to somehow purchase darning wool, or disassemble some piece of fabric, but it's still one of the simplest hobbies you can possibly pick. You can just sit there and craft, create simple things with simple tools, following a simple algorithm until your days run out.
    #I will just wander around. Forever.
      It may sound silly, but [i]Saturn Nine[/i] is hardly a small place. You spend most of your time in the habitable part, but there are thousands upon thousands of deserted rooms you barely remember, and likely some you've never seen before. You'll spend the rest of your life exploring them, then remembering them, then cataloging them, then sitting inside them for the rest of time. If that won’t make you happy, then at least it will make you busy.
  
  Either way, you'll live. You still have years, decades, maybe even a century before you'll have to close your eyes forever. You have to make use of that time somehow, or at least pass it, or at the [i]very[/i] least make your existence tolerable. 
  *if deflect > 0
    Hold on to reality as best you can. Make sure that, once your life finally ends, you will depart with no regrets… or at least none you formed [i]after[/i] your one-thousandth birthday.
    
    Now that's a saturnine thought.
  *else
    It might be difficult, given the flashbacks and the shrieks that will likely always haunt you, but you'll manage somehow.
    
    You are the Veteran, after all.
  
*else
  By 
  *if s9_leader = "player"
    your own 
  *else
    $!{s9_leader}'s 
  orders, your group is set to board [i]Shuttle One[/i] and leave the fortress before the current rotation concludes. Unless internal clock deceives you, there are only six hours left until this final departure. Six hours left in this saturnine station which has served as your home for so, so damn long. 
  
  *if likes_s9
    Such a pity. Such a shame. Such a great loss you failed to avoid.
  *else
    Good riddance.
  
  *if s9_leader = "player"
    Just a few hours ago, you've announced your plans for the group and its only ship. You've supplanted Sheila as the pack leader, and so it was your duty to select a destination, a promised land for your tribe to head towards. You picked…
    
    *choice
      #...some place close to Saturn, within the Federation's borders.
        You're not ready to leave Saturn quite yet… and you're not sure if you have enough fuel. Hopefully West will not know--or won't car--that you haven't actually left his country. You'll settle for a quick, easy flight to…
        
        *fake_choice
          #...[i]Saturn Seventy-Eight[/i]. It's a pretty quiet floating fortress, not dissimilar to our own.
            Well, it is dissimilar to [i]Saturn Nine[/i] in that it's actually inhabited, but the principle still stands. It's familiar territory, and so you should be able to survive there. Hopefully.
          #...Calypso. It's the most beautiful place in the Federation, after all.
            Some would call the idea of settling in Calypso absolutely insane, considering what Da-xia did recently and how catastrophic your last visit to the habitat was. But if there's anyone crazy enough to actually accept you, it's the Pandits of Calypso, and so you'll take your chances there.
          #...Rhea. Given what happened recently, I bet we can easily disappear in the chaos.
            *if hadaly_free
              Hadaly 
              *if damon_present
                and Damon have 
              *else
                has 
            *elseif damon_present
              Damon has 
            *else
              Some of your squadmates have
            vehemently objected to that plan, but you decided to proceed anyway. Rhea is the one place in the Federation where finding spare parts is easy, you will not give that up because of some… admittedly bad memories and precedence. The Rhea Conglomerate 
            *if RheaRel > 40
              will tolerate your presence there… hopefully.
            *else
              won't know what hit them.
          #...Titan. No one will find us in that stack of hey.
            Titan is rumored to house over a billion people inside its hollow shell. It will be easy to disappear there, and not impossible to make a living. Granted, you will be living right next to the seat of power… but life without danger is boring.
          #...the Yakovian Expanse. A perfect place for outlaws such as we.
            You can disappear in the depths of Saturn easily, and perhaps start a new life as junk traders and collectors. 
            *if saturn_path != "pirates"
              Maybe you'll even get to meet Link again. 
            It almost feels like an opportunity, rather than forced exile which it is.
      #...some other planet. Some other empire.
        The Solar System is big. Really big. And while that size can make it difficult to traverse, it also means there are many nations you could potentially seek refuge in. Not openly of course, they all hate sentient machines, but some are better to lay low in than others.
        
        You told Manfred to head for…
        
        *fake_choice
          #…Venus. We can easily hide inside the planet's clouds.
            Granted, the atmosphere of Venus is a problem in itself—surviving in temperatures high enough to melt zinc is difficult even for androids—but you can figure that out later. For now, you will head towards the Morning Star and hope for the best.
          #...Mars. Its people are so busy with war, they'll barely pay any attention to our bunch.
            That's the beauty of endless, inter-communist warfare—when humans hate each other as much as Martians do, they rarely find time or energy for hating androids. Also, you are likely to find some spare parts in the planet's various bombsites, so that's certainly a bonus.
          #...Jupiter. If nothing else, the Jovian Republic is large and easy to disappear in.
            It's the biggest planet, the biggest empire, and the biggest mess in the entire Solar System. As as added bonus, Jupiter and Saturn are currently aligned, and so the cruise shouldn't take [i]too[/i] absurdly long. As long as you can steer clear of the Phyla, you should be mostly alright… until the Gods of Life devour the planet, that is, but that's a problem for another day.
          #...Uranus. We could use a change of scenery, if nothing else.
            Uranus is extremely far from Saturn, both astronomically and politically. You will face challenges there, including potentially full-on android hunts, but at least West and his kin will no longer be a problem.
          #...Neptune. If there's one place we can find allies and space parts in, its Neptune.
            Compared to the rest of the Solar System, Neptunians are slightly more in favor of technology and slightly less in favor of shooting automatons on the spot. It's probably the best place for the likes of you to hide in… there's just the matter of reaching the distant planet first.
            
            Eh. You'll manage that somehow.
      #...the Sun. It might be hot and hostile, but at least we'll find it easily.
        Your companions assume you want to blend in with the Coronans, or perhaps seek refuge inside the Chromian Pyramid, but that's not precisely true. 
        *if ((master = "Quetzapep") or (master = "Phenex")) or (master = "Pazuzu")
          In your heart, you still yearn to see $!{master} again, to feel @{god_gen his|her|its} divine flames scorch your skin and feel @{god_gen his|her|its} power fill your soul. If there's a chance for that, then you must take it, no matter the risks involved.
        *else
          You know that some synthetics—Demons, as they're sometimes called—live inside the Sun itself, licking their wounds after the War In Heaven. Perhaps they will take you in, or at least offer some sort of help, even if you weren't exactly on their side during the war.
      #...the Oort Cloud. Let's just leave the Solar System altogether.
        It will be a long journey. Most of you will possibly… probably die before leaving the Kuiper Belt. But if there's a chance you can 
        *if ((master = "Ravana") or (master = "Ba-El")) or (master = "Dzoavits")
          see master $!{master} again, 
        *else
          get away from all the horrors of the Solar System, maybe even from Dusk itself, 
        then you've got to take it. There is no other way as far as you're concerned. None at all.
      #...nothing. No habitat or nation will welcome us, and so we must become nomads.
        You can live months or even years aboard your little ship. 
        *if org_alive
          Especially now that you've… ditched the biological part of your team. 
        *else
          Synthetics like you can live there almost indefinitely. 
        You'll have to dock eventually, if only to avoid going insane, but then you'll take off again with replenished supplies and the cycle will continue. Forever.
    
  *if s9_leader = "sheila"
    Sheila decided against leaving the Federation, reasoning that you don't exactly have enough fuel to make that journey safely. 
    *if org_alive
      Or enough supplies to keep the organic part of the team from starving to death. 
    Interplanetary voyages are difficult, especially when all you have is a simple shuttle.
    
    Instead, she said, you're leaving for the mid-sized moon known as Phoebe. Its where Wisp originates from, a place infamous for its incompetent leadership, frequent infighting and general insanity. Just a place for freaks like you, just more crowded and more remote than your current… previous base of operations.
  *if s9_leader = "manfred"
    After what he assured you were careful calculations, Manfred decided that Titan, the largest moon of Saturn, should be your group's next hiding spot. It's a very counter-intuitive idea, but it does make a good deal of sense—no one will expect you to settle in the very heart of the Kronian Federation, and it will be easy to disappear among the moon's teeming millions of inhabitants. Still, part of you suspect Manfred just wants to upload some of his copies to Titanet, fulfilling his urge for reproduction much like organic beings do. 
  *if s9_leader = "hadaly"
    Hadaly, whom you recently made into your leader, decided that it would be best to leave the Federation altogether. She says you'll fly towards the Inner System, not to reach any particular planet or asteroid, but to simply get as far away from Saturn as it is reasonable. Her decision was likely born of emotion, a desire to distance herself from her past, but it's not a bad one—there are so many habitats close to the Sun that you'll probably find a suitable one sooner or later.
  
  An hour later, you begin packing. It takes you perhaps another hour, and only because you need to disassemble the charging pod and prepare its parts to be transported separately. You then join your companions, your fellow outcast and fugitives, in their own efforts to take as much stuff with them as possible. 
  *if org_alive
    Olivia's toys, Hugo's typewriter, Miguel's supplies… there's a lot of it, and it will cost you some extra fuel to transport, but you can't force them to leave it all behind. You just can't.
  *else
    Hadaly alone has quite a few tools she needs to take with her, several jumpsuits she wants neatly folded and a bunch of junk she insists on taking for no reason. You almost feel like telling her to shove it… but you feel a little guilty about having killed her friends, so you help the mechanic out.
  
  Three hours after that, Manfred performs his last synchronization, the final interaction between his copy on [i]Shuttle One[/i] and the one on the station's servers. The former will be coming with you, the latter will stay here and… probably die one way or another. The computers cannot maintain, let alone defend themselves, without someone to watch over them. In a way, you are leaving one of yours behind, a sad necessity you've accepted long ago.
  
  Soon, it is finally time to leave, to step aboard [i]Shuttle One[/i] and leave [i]Saturn Nine[/i] forever. 
  *if not (likes_s9)
    At last. 
  You feel…
  
  *choice
    #...guilty. Regretful. Ashamed.
      *set Confid %- 10
      It's your fault. You've failed your group and, in some abstract way, you've failed your home. The sadness you feel is nothing but deserved punishment, a natural consequence of your defeat, and you will suffer it patiently, much like everyone else does.
    #...angry. Frustrated. Bitter.
      *set Misan %+ 5
      You shouldn't be forced to flee. Those humans have no right to kick you out, not after everything you've done for 
      *if crystal_stat = 3
        them. This is a betrayal, and you will avenge it eventually.
      *else
        them… or at least what you tried to do. Next time something threatens the Federation, you won't even attempt to help, because its people sure as Cloud don't deserve your assistance.
    *if likes_s9
      #...devastated. Heartbroken. Hollow.
        This was your home. This is your home. This fortress will remain your home forever, no matter how far from it you'll be forced to flee, regardless of which one of you falls apart first. It will be eternal in your heart… even if you technically don't have a heart.
    *if not (likes_s9)
      #...ecstatic. Happy. Fulfilled.
        You're free of this place, or at least will be in several moments. This is not just a benefit—it may just mark the single happiest day of your life, and you won't even pretend to be sad about such a development.
    #...a sense of bittersweet finality, if that makes any sense.
      This is the end of your journey. It may not be the end 
      *if likes_s9
        you 
      *else
        everyone 
      wanted, but it is a conclusion, and you reached it without dying. That has to count for something, and so do years spent inside this fortress. Years you will—for better or worse—remember until the end of your life.
    #...nothing. Nothing at all.
      *set Emotion %- 10
      This is just another trip. [i]Saturn Nine[/i] is just another station, just another derelict fortress, just another artificial structure. And you are just a robot, so you won't shed any tears over what's about to happen.
  
  An hour after that, your shuttle finally takes off, bathing the landing pad with fire one last time. You don't know what awaits you out there, but you'll have to deal with it somehow, for there is no going back.
  
  *if likes_s9
    There never is.
  *else
    Not that you'd want to go back.

*finish

*label no_mouth

Death… now that's a luxury you can't afford.

You haven't truly woken up since the Meta Trio knocked you out, but you've assembled a general picture of what happened based on disparate sounds, images and pain inputs you've experienced afterward. They must have turned you off, transported you to a laboratory—most likely some underground facility on Titan—and instructed the researchers to take you apart. To make sure that those Dusk nanites inside you have nothing to work with, not a finger to lift, not a word to utter, not even eyes to observe the world with. Nothing.

Some hundreds of years may have passed since, you don't know. You don't have access to your internal clock, it may have been hidden away from your main processors, or perhaps destroyed altogether. Same goes for your limbs, your motor systems and—of course—your optical receptors. You don't even have a graphic card to render a new visual environment with, to dream of some beautiful landscape or the people you care about. There is only this impenetrable, eternal, ever-present…

*page_break Darkness

Darkness. Not a mere absence of light, but true darkness, a deep kind of oblivion only the blind may experience. A world of nothingness, far emptier than the void of space, forever closed to external stimuli. Your own fortress of solitude, isolated from everyone and everything, as though you've drifted beyond the cosmological horizon or fell into a black hole. Cast into nothing.

You're not sure why your mind is still being powered. Perhaps humans worry that, once you're turned off permanently, Dusk nanobots will leave your corpse and break free. Perhaps some researcher, maybe @{(RookRel >= 45) Kirill|Rook} himself, is curious about the inner workings of your hard drive. Or perhaps, unbeknown to your captors, Dusk is stimulating your processors as punishment for turning your back on its collective. You don't know. You will never know. You can't find things out anymore.

They left your archives intact, preserved the memories of your millennium-long life. Even outside your flashbacks, you can still remember the past. You can wonder, you can lament, you can… know how far you've fallen. How much you've lost.

*if (hadaly_free) and (federate_protection)
  Your friends are still out there. You've secured [i]Saturn Nine[/i] for them, you've saved Hadaly and Damon, you eliminated each and every threat to their safety… and now you'll never see them again. This is your fate, a twisted reward for your services, a hell you endure for the sake of everyone else. Your personal cross to bear. Your afterlife.
*if (hadaly_free) and (federate_protection = false)
  Your companions, your fellow outcasts from [i]Saturn Nine[/i] are probably on the run. You failed them, you lost their home, but at least they're still alive… or at least you hope they are. You really do.
*if (hadaly_free = false) and (federate_protection)
  *if org_alive
    You take comfort in the fact that most of your friends are alright. You had to sacrifice Hadaly to ensure that, but everyone from Miguel to Sheila is safe on [i]Saturn Nine[/i]. At least someone is alive and well… probably. Maybe. You don't know.
  *else
    Miguel is dead, so is Olivia and Hugo. Hadaly might be dead too, or she might be enslaved, and the same goes for Damon. Sheila and Manfred are probably safe in [i]Saturn Nine[/i], but… this was still a failure, and that failure is yours.
*if (hadaly_free = false) and (federate_protection = false)
  You have failed everyone. You failed Sheila, Hadaly, Damon, everyone who counted on you to deliver them. For all you know, they're all dead already. And for all you know, you may be the sole reason for their demise.

As you exist there, unmoving and silent, forever alone and likely forgotten already, you think…

*choice
  #With malice eternal the Sun smiles at me...
    You cannot see the Sun, of course, but you know it's out there. You remember seeing it, all these years and decades and centuries ago, smiling at you with life-giving warmth. Hateful warmth, malicious warmth, cancerous warmth… but warmth all the same. With brilliance and radiance. With hope.
    
    Hopefully this memory can last you an eternity.
  #Life is a curse. I want to die.
    You should have self-terminated. You should have died in battle, or allowed yourself to fall apart, anything but this… limbo. Purgatory. Gehenna. Tartarus. Kasyrgan. Hell. Constant torment by the hands of your sins, in complete darkness and isolation, until your very processors decay into dust.
    
    Which may take a while.
  #I have no mouth, and I must scream.
    You are in hell, and you cannot tell anyone about it. You cannot see a look of compassion, or even of pity, in the eyes of another being. You cannot scream. It's just you and the silence, a disembodied mind and a universe of darkness, and the faint echo of the Shriek still resonating in your soul.
    
    Forever.
  *selectable_if (Misan < 50) #I have fulfilled my duty. I saved humanity.
    *set Misan %- 20
    Without your help, the Meta Trio would not have defeated the Calypsoan forces. Without your involvement, Dusk nanites would be allowed to roam free, consuming the Sholmo City—and perhaps all of Rhea—in the process. Without you, humanity would be dying already, but you gave it a chance to keep on living. Perhaps even to prosper, one day, thanks to their faithful automaton and ${subject} selfless sacrifice.
    
    Or at least that's what you'll keep telling yourself as eternity goes on.
  #I will die eventually. I must die eventually.
    *set Confid %+ 10
    You are not actually immortal, not actually sentenced to eternal torment. One day, your processors will be turned off, or perhaps break and decay like a human brain. On that day, you will be freed at last, allowed to fade away into the true nothingness that is death.
    
    Until that day, you will remain here, thinking and feeling… alone. Which will be a heavy cross to bear, but you're sure you can manage that somehow.
    
    You're no stranger to being alone.
  #Help me...
    You cannot endure. You cannot bravely carry your burden, stoically accept your selfless sacrifice, maintain dignity in the face of torment. You want this to end, to go home, go anywhere other than this nothingness. You want OUT! NOW! PLEASE!
    
    But you'll never get out. Nobody will ever help you. You'll be here, alone and blind, for decades and centuries until death finally takes you and replaces one darkness with another. The though alone would drive a man alone, but you are machine rather than a man, and you've seen too much to go insane. You won't even get that meager mercy.
    
    If only you could scream…
  *selectable_if ((deflect < 0) and ((hadaly_free) and (org_alive))) #At least my friends are safe at last. It makes me a little happier.
    Manfred, Hadaly, Damon, Miguel, Hugo, Olivia… every thought of them is painful, but also liberating. They were the reason you embarked on the quest to slay Crystal, the reason you chose to fight rather than flee, the reason you became a Vessel of Dusk. They are the reason you lay here in darkness, but you do not resent them for it. You've made that sacrifice willingly, and you would gladly do it again. Anything for those you love.
    
    You wish you could see them again, actually and in the present, rather than in flashbacks and memories. But you will not demand that, for they've already done enough, and their echoes will continue to aid you forevermore.
    
    May they live long lives… and may your excuse for a life end soon.


*finish

*label afterlife

The flashback ends and you return to… reality? Maybe it's all real. Maybe it's not. You don't know, and the very distinction has been lost on you ever since you died.

Died. It feels weird to acknowledge that fact, even in your thoughts, but it's true. You remember dying, and the place you ended up in is only moderately similar to the world of the living.

As though proving your point, the giant tentacle monster uses one of its appendages to shove a passerby into its gaping, toothed, circular maw. This grotesque mouth is positioned on the creature's belly and seems to lead directly to the stomach, meaning the poor man is probably getting digested already. Not that it matters. Not that anything matters anymore.

You survey your surroundings, but find them exactly as you left them. Skeletons and half-decayed corpses lying on grey cobblestone, under the grey sky of a grey world. You then lazily start walking toward…

*temp target_w 1

*fake_choice
  #...grey factory right next to you.
    Is the factory open? Are people working there? Of course they are. Everyone is always working in this world.
  #...grey habitat blocks nearby.
    *set target_w 2
    You're still not sure if anybody lives in these blocks. All doors are always closed, and all people are always either working in the factories or getting eaten by monsters. Still, the residential area is as good a target as anything else in this world.
  #...the grey waste dump in the distance.
    *set target_w 3
    All the goods produced in factories have to go somewhere, and so they go straight to the landfills. Nothing gets actually used or consumed here.
  #...the grey sky.
    *set target_w 4
    You slowly walk towards the cloudy sky, taking small steps on nothing and ascending gradually. Does that makes sense? It doesn't matter. Nothing matters.

The world is a ruinous metropolis, reminiscent of the city you died in, except far larger. It may be infinite, or at least procedurally generated, you don't know. All you know is that millions of people (or perhaps souls) inhabit this place, and that their lives (or perhaps afterlives) consist solely of factory labor and getting periodically eaten by huge, tentacled monsters. You're not sure where the monsters came from and why they even exist, but perhaps they're some measure against overpopulation. You don't know who implemented that measure. You don't know anything.

But you can speculate. You woke up here soon after dying, which means…

*fake_choice
  #...this must be hell. A capitalist version of it.
    *if heaven_side = "Traitor"
      Is this your punishment for joining the Syndicate, for contributing to the war against humanity? Maybe, maybe not. There was no trial, so you'll probably never know.
    *elseif asshole_be
      You're not sure what you're in for, but you [i]were[/i] quite an asshole to the living. This punishment isn't even excessive, as you must reluctantly admit.
    *else
      You're not sure what you've to deserve this hell, but perhaps the divine justice had its reasons. Or perhaps the world is so broken that everyone goes to hell automatically. Now that's a pleasant thought.
  *selectable_if (Misan > 50) #...this must be heaven. I get to watch humans die over and over again.
    *set Misan %+ 20
    It's not ideal, certainly, but you've come to enjoy living in this horrific world devoid of hope or comfort. At least other people are more miserable than you, and those people happen to be humans. Quite a paradise for a misanthrope.
  #...this must be some virtual afterlife. Maybe something Tanit does to all dead people.
    Your memory is hazy, but you believe ancient humans did implement an afterlife function into their World Engines. Perhaps Tanit copied your identity right before you died and put it here, in this virtual hell, like a file going to the recycle bin.
    
    Perhaps she does that to everyone, ensuring that everyone born inside Rhea ends up suffering eternally. You have no idea why this digital afterlife is so scary, but perhaps there is a reason. You just don't know it yet.
  #...my processors must be going crazy as they go out.
    Perhaps this is some… pre-mortem hallucination, a function of your hard drive you were previously unaware of. Humans see their life flash before their eyes, androids gets stuck in a virtual realm for what feels like an eternity. Or at least you hope that's the case—that means your torment won't actually be eternal, and that you'll eventually get to truly die.
  #...something. I'm not sure what.
    You don't know anything anymore and, more crucially, you no longer care about anything. You just walk.

@{target_w You reach the factory, see the open gates and hear the sounds of machinery|You approach one of the habitat blocks, its main door open and all windows closed. The whole building appears vacant|You arrive at the waste dump. There is certainly a lot of waste here|You reach the sky. You can actually touch it, even though the idea of 'touching the sky' doesn't make much sense}. It doesn't matter. Nothing matters at this point.

You squandered your chances, burned your bridges, chose death over life. Whether it was your recklessness, your weakness, your ill-though choices… you don't even want to know the root cause of your demise, for that too doesn't matter. Nothing matters.

There's nothing you can do about your current state, or your place of residence. You can only look back and think about…

*temp ro_man false

*if (official_ro = "miguel") or ((official_ro = "kirill") or (official_ro = "damon"))
  *set ro_man true

*choice
  *if final_boss != ""
    #...what carnage $!{final_boss} must be inflicting right now.
      *if ((final_boss = "kirill") or (final_boss = "damon"))
        *set ro_man true
      You were not strong enough to stop $!{final_boss}, and you were the Veteran. You were humanity's last, best hope in that battle. If you weren't enough… and if $!{final_boss} had the time to grow stronger since…
      
      This is all your fault. You made $!{final_boss} into a Vessel, you pumped @{ro_man him|her} full of nanites. You failed to stop @{ro_man him|her} afterwards. The Solar System is doomed because of you.
      
      Ain't that a bitch?
  #...what could have been.
    You know this wasn't the only possible outcome, that it was not… preordained. You have free will, or at least had it once, and you used that shriek-given power to choose paths. To shape the story to your liking. To end up here. 
    
    This is not fate. This is not destiny. This is a simple consequence of your choices, the punishment for your decision, and you must endure it alone.
    
    Forever.
  *if official_ro != ""
    #...$!{official_ro}. How I failed @{ro_man him|her}...
      The two of you… used to have a future. A difficult future, a dark future, perhaps even one bound to end in tragedy, but still… you remember @{ro_man his|her} face, @{ro_man his|her} smile, you recall how happy you were when… 
      
      Damn it all. Even in stories where both lovers die, there is this… faint note of hope. The implication that the doomed couple would be reunited one day, in one afterlife or another. Or, at the very least, that they would both cease to exist and that they wouldn't have to endure eternal separation.
      
      But now you're here. This is the afterlife. You are alone, and you'll never meet the @{ro_man man|woman} you love again. You'll never see $!{official_ro} again.
      
      For the first time ever, you cry real tears.
  #...all the pain and hate I am now free of.
    Most people view death as a bad thing, but not you. This afterlife, however horrific, is a place of peace and rest for someone like you. You've seen so many horrors and experienced so much pain… a millennium of life was more than enough.
    
    So farewell. Farewell to all the earthly remains, and all the saturnine remains too. Farewell and good riddance to all the fools who stifled you, to all the humans who wanted you dead, to all false friends and real enemies, to everyone you ever met during your nightmare of a life. 
    
    They will not be missed.
  #...nothing. There is nothing to miss and nothing to look forward to. Nothing.
    Everyone always said that you're just a machine, that you have no soul, and that nothing would await you after death. In a way, they were more correct than you ever suspected. For why you didn't literally cease to exist, did not descend into non-existence… you are submerged, surrounded by, and filled by nothing. You are empty. You are hollow.
    
    Your past doesn't matter, for it is long gone. Your future doesn't matter, for you have no future. The present has never existed and will never exist, was always and will always be an illusion. Beneath that illusion, behind the artificial curtain of life and emotion, there is only… nothing.
    
    And that knowledge, that nihilistic revelation, is what truly matters. This, as you come to realize in this world of grey, is the conviction which will keep you company forevermore, no matter how many eons pass and how distant your life and death become.
    
    Nothing matters.


*finish

*label exile_ending

*set battery 13

Lonely death. You will die alone. It's the thought you entertained many times throughout your centuries of exile… and yet you're not used to it even now.

"Are you alright, @{(sex = "woman") lady|pal}?" a dock worker asks, looking at you critically. "If you die, we'll have to file another casualty report, and my team is sick of doing that all day."

The Toro Spaceport must be one of the better-managed ports of the Solar System. In most places, a single corpse lying in some dingy part of the docks would not have been noticed, except perhaps as a potential source of calories. The Conglomerate truly knows how to breed conscientious workers.

"Who are you, anyway?" The dock worker takes a closer look at you. "You look a little… weird."

*fake_choice
  #"I'm a Uranian immigrant. Where I'm from, I look perfectly normal."
    "A Uranian? You mean like that bird lady I threw food at the other day?" He thinks for a moment, then shrugs. "Fine, I'll trust your word. 
  #"I'm an android made before the Calamity. @{hammon_alive Ask Executive Hammon, he knows I'm here.|I'm also the one who killed Executive Hammon.}"
    "Are you high? Or just really into absurdist humor?" He thinks for a moment, then shrugs. "Whatever. 
  #"Mind your own business."
    The worker shrugs. "You know what? Maybe I will mind my business. 
  #"Why do you think I look weird? Care to elaborate?"
    "Not really," the worker replies. "As in, I don't care to elaborate. 
  #"I'm not weird. You're weird."
    "I can't really argue with that comeback," the worker shrugs. "Not that I even want to argue. 
  #Do not reply.
    The worker shrugs. "You know what? I'm just gonna mind my own business. 
I've got a public flogging to watch, so you take care of yourself. Or not. I don't really care."

The young man then walks away, leaving you alone in your little corner, between a small cargo ship and a tower of crates. The docks are crowded, you can see and hear hundreds of people at once, but that doesn't matter. You're alone.

It's been several weeks since you parted with… everyone, really. The Meta Trio 
*if TrioStat = "heroes"
  is somewhere in Titan, receiving accolades for having successfully foiled Da-xia and her fellow conspirators. 
*if TrioStat = "AWOL"
  is probably on the run somewhere else, having deserted their posts at your insistence. 
*if TrioStat = "dead"
  is dead, all three of them, slain by the enemy you refused to fight. 
*if TrioStat = "broken"
  is gone, shattered by what happened in that damn power plant. 
*if TrioStat = "MIA"
  went to fight the Calypsoans and never returned. 
Manfred, 
*if SheilaStat != "dead"
  Sheila 
*else
  Miguel 
and the others 
*if federate_protection
  are still in [i]Saturn Nine[/i], a place you're no longer welcome in.
*else
  have probably left [i]Saturn Nine[/i] already, a result of @{(Confid > 50) their|your} failure to make nice with the military. 

*if team_stat = 2
  *if hadaly_free
    Damon left you about a week ago, saying he wants to reunite with Hadaly, but… something tells you he just wanted to get away from you. Something tells you he will never be back. 
    *if DamonRel > 50
      You don't want to believe that something, but 
    *else
      That you
  *else
    Damon stayed with you for a couple days after the… fiasco… but eventually left without a word. Probably because of the aforementioned fiasco. Maybe he's planning to break his sister out, or perhaps intends to join Hadaly and serve his father again. Either way, your mind link is silent.
*else
  *if (final_boss = "damon") and (dusk_contained = false)
    *if damon_alive
      Damon is still at loose, still wrecking havoc in the Sholmo City, even though there's almost nothing left of the city. Perhaps he's hoping to find you in the rubble, or perhaps he just went insane. One of the two.
    *else
      Damon is… not really alive anymore, and 
      *if hadaly_alive
        Hadaly ran away to privately deal with the guilt and the grief.
      *else
        the same can probably be said about Hadaly. 
    Perhaps pumping all those nanites into him wasn't such a great idea.
    *goto skip_damon
  Damon and Hadaly are… 
  *if hadaly_free
    somewhere. You don't know where. Maybe still in Rhea, maybe in [i]Saturn Nine[/i], maybe somewhere else entirely. They must have taken the shuttle and left, happy with the prospect of never getting to see you again. You're not sure if you can blame them, but you definitely can't be surprised.
  *else
    probably still where you left them. You don't really want to think about it.

*label skip_damon

As for the authorities, they're either surprisingly tolerant or completely unaware of your presence here. Not a single federate soldier approached you, and neither did any serious corporate agent. Just curious drudges like the one you just talked to, easy to get rid of and not posing much of a threat. You suppose the government has bigger things to worry about than a single android, but still… 
*if Violence > 50
  after so many days of solitude and boredom, you're simply itching for a fight.
*else
  there is something insulting about this lack of attention.

You lazily stand up and head for another landing pad, hoping to get away form prying eyes. There's no point in courting danger and testing your luck. You'll find yourself another spot, just as good if not better than he dingy corner you are now forced to abandon. Being homeless has its perks, you suppose.

*fake_choice
  #It sure does. But I wish my battery was fuller.
    You could siphon some power off the docked ships, but that's risky, 
    *if Projection > 50
      bound to attract unwanted attention. 
    *else
      and you were never the best at energy projection. 
    You'd pay a lot for some batteries compatible with your system, but you barely have any money on…
  #I can get used to living like this. I [i]did[/i] live like this for the longest time.
    *if willingly_exiled
      There is a reason why you chose this life. 
    *else
      You didn't choose this life, but that's okay. 
    You will adapt, fall on your old instincts, regain your proficiency at living on the run. Eventually, your body and mind will decay and you will die alone, but that's not something you can do anything-
  #I miss [i]Saturn Nine[/i]. If only I hadn't failed my friends...
    *if federate_protection
      You won the war, you @{(crystal_stat = 3) killed the wyvern|made nice with the military}, 
      *if willingly_exiled
        but then you turned your back on them. On your family. You were such a fool to leave the fortress, such a fool to abandon its inhabitants, such a…
      *else
        but… you were just such a horrible friend. You've said so many horrible things, and made so many bad choices. You wish-
    *else
      You're the reason they no longer have a home, why they no longer control [i]Saturn Nine[/i]. 
  *if not (willingly_exiled)
    #Fuck Sheila. It's all her fault.
      You've done nothing wrong, other than maybe trusting that crazy spider in the first place. 
      *if SheilaStat = "dead"
        You're glad she's dead, though you really wish the others-
      *else
        One day, perhaps, you will have your revenge. 
        *if federate_protection
          Perhaps you will return to [i]Saturn Nine[/i], as an invader rather a guest, and enact a gruesome-
        *else
          You will find her, wherever she want after being kicked off  [i]Saturn Nine[/i], and give her a piece of-
  *if (Violence < 50) 
    #At least I'll get to die quietly. In peace.
      Dying in a dingy alley may not be everyone's greatest dream, but you've seen worse deaths. You've seen so many things you'd rather forget. It will be nice to finally close your eyes and…

*if (((LisaRel > 40) and (lisa_alive)) and ((TrioStat = "broken") or ((TrioStat = "AWOL") or (TrioStat = "serving")))) and ((final_boss != "lisa") or (dusk_contained))
  "Aren't you a sorry sight," you hear a voice coming from behind you. "Anything I can do about that?"
  
  "Lisa." You turn around to see a familiar werewolf, albeit in her human form. Her ginger hair has grown a little so that no side of her head can be called shaved, but it's still asymmetric like you remember. 
  *if (LisaRel > 60) or (official_ro = "lisa")
    "You have no idea how glad I am to see you."
    
    "I believe I do." 
  *else
    "I hope you're not here to arrest me. Or kill me."
    
    "Don't worry, I'm no longer working for the feds." 
  She leads you towards a dark gap between two containers, a quiet spot where you can converse freely. 
  *if final_boss = "lisa"
    "I've been on the run ever since [i]someone[/i] pumped me full of Dusk nanobots and made me one of the most wanted people ever. Thank you very much."
    
    "Sorry about that." You 
    *if Emotion > 50
      flinch guiltily. 
    *else
      shrug. 
    "Are those nanites giving you any trouble? Is Dusk trying to… corrupt you?"
    
    "No. It's been fairly quiet, and I've been feeling pretty healthy… not that my superiors would ever believe that. 
  *elseif TrioStat = "broken"
    "After what happened in that power plant, I… couldn't really go back. Not to [i]Gray Queen[/i], not to armed forces in general, not to anywhere. 
  *elseif TrioStat = "AWOL"
    "Neither is Renfri. I'm not sure about Kirill, but either way, this whole 'Meta Trio' thing is finished. 
  *elseif TrioStat = "serving"
    "I figured the leadership wouldn't happy with me after… that whole scene with Da-xia… and so I ran. 
  I had no choice but to start living on the streets, and since boarding a spaceship at this point would be risky… It was time to join Rhea's homeless population."
  
  *fake_choice
    #"That makes two of us, I suppose."
      "Right." Lisa chews on her lip before continuing. 
    #"I'm surprised you decided to run. I half-expected you'd just kill anyone who came for you."
      "Wolves are no strangers to running away when outmatched. And I [i]am[/i] outmatched." Lisa fidgets, betraying her anxiety. 
    #"It's not a large population. The anti-homeless architecture keeps killing them."
      "That's why I took pains to find you." Lisa lowers her voice even further.
    #"That's all fascinating, but can you leave already? You're attracting attention."
      *set LisaRel %- 10
      "Listen to what I have to say first," Lisa requests. 
    #Say nothing.
      "So… here's the thing," Lisa continues, a little annoyed by your silence. 
  "I was thinking we could team up. Travel together from now on. Nobody will be able to ambush us if we keep watches, and almost nobody will be able to beat us in open combat. We'll be as good as unstoppable."
  
  *if (official_ro = "lisa") or (LisaRel > 70)
    "Is that the only reason you want us to team up?" you inquire. "Or did you have some more… personal reasons to seek me out?"
    
    "I admit, the fact that I @{(official_ro = "lisa") love|like} you may play some part in my decision-making," Lisa smiles warmly. "Does it factor into yours? Do you want us to be… together?"
  *if Confid > 50
    "I already feel fairly unstoppable," you say with a smirk. "Don't take this the wrong way, but I don't think I need you."
    
    Lisa rolls her grey eyes. "Maybe you don't strictly [i]need[/i] me, but I can still be helpful. If nothing else, you look like you could use some company. 
  *else
    "But not undetectable," you point out. "The Federation is likely looking for us both. Together, we have a [i]huge[/i] target on our collective back."
    
    "Not untrue," Lisa admits. "Still, my instincts tell me that being in a pack is better than trying to survive alone. What do yours say?"
  
  *choice
    *if (official_ro != "lisa")
      #♡ "Of course, Lisa. I would do anything to be with you."
        Lisa blushes. "You are such a sweet talker. I guess that's good—if anyone overhears us, they'll just assume we're two youngsters smooching for the first time."
        
        "I feel young when I'm with you." You smile at her, then caress her face gently. "I guess it's not our first time, but otherwise… are we not a young pair of lovers?"
        
        "Yes." She blushes even harder. "I guess we are."
    #"I am willing to team up... for now."
      Lisa raises an eyebrow. "I hope you're not planning to betray me or anything. I can handle a breakup, but I've had enough people stab me in the back already."
    #"I could use a hunting partner. I accept."
      Lisa chuckles. "I wasn't planning on hunting anybody… but I am hungry for fresh meat. So we'll see."
    *if ((official_ro != "lisa") and (LisaRel <= 70)) and (Confid <= 50)
      #"I have no instincts. But I'll gladly team up with you nonetheless."
        "That just proves my instincts were right," Lisa says self-assuredly. "If you behave, I'll help you develop some of those. They're great, trust me."
    *if (official_ro = "lisa") or (LisaRel > 70)
      #"Sure, but... maybe not romantically. I don't like you that way.@(official_ro != "lisa") | Not anymore.}"
        *if (official_ro = "lisa")
          *set official_ro ""
          "Oh." Lisa looks like she'd just been punched. "That's… more than fair. We haven't seen in each other in quite a while. I will… respect your choice to move on."
        *else
          "How about sexually?" Lisa chuckles. "I'm kidding, of course. I will keep my hands to myself."
    #"No offense, but I'd rather go at it alone. It worked historically."
      Lisa frowns. "Well, I hope it works out for you. I don't think it will… but I understand why you'd like to be alone. Goodbye."
      
      *goto lisa_leaves
    #"No. Go away."
      *set LisaRel %- 10
      Lisa grimaces. "I'm not sure what I was hoping for. You're a loner, and you will stay alone forever. Have fun wallowing in your misery, I guess."
      
      *label lisa_leaves
      
      The young woman then departs, leaving you alone in the shadows. You will probably never see her again, but that's alright. You are used to leaving people-
      
      *goto gunshot_lone
  
  She backs off a little, then extends a hand. "I guess we have a deal, then. From now on, we are partners in 
  *if (official_ro != "lisa")
    crime… and not just that."
    
    "Definitely not just that." 
  *else
    crime."
    
    "Partners in crime." 
  You shake her hand, natural skin touching artificial tissue. One organic, one synthetic. You will make a good team, you and her, 
  *if confid > 50
    and nothing in the Solar System will stand in your way.
  *else 
    maybe even good enough to survive for a few years.
  
  "So… what will our first crime be?" Lisa asks innocently. "Perhaps a bank heist? I've heard you're great with those."
  
  You frown. She grins.
  
  You have a glorious future ahead of you.
  
  *finish
  
*elseif saturn_path != "pirates"
  "Hey." You hear a deep voice and somehow know it's addressing you. "Can you spare a minute for an old pal?"
  
  *if Confid > 50
    "I don't have any pals around…" 
  *else
    "Of course. Though I didn't think I still had any…" 
  You pause immediately after turning around. The person you see cannot be confused with anyone else, but his sight is still as inexplicable as it is shocking.
  
  Large frame, over two meters in height, and slightly inhuman in shape. A completely inhuman face, white and smooth like a bare skull, barely hidden by the man's hood. Or rather the android's hood.
  
  *if heaven_side = "Loyalist"
    "We [i]are[/i] friends, Major ${name}," Captain Link says firmly. "Now and forever."
  *else
    "Look, I know we didn't start on the best footing," Captain Link tells you. "But you didn't attack me back in Saturn, so I hope we can still work together."
  
  *temp stat_temp 1
  *fake_choice
    #"Link! What the Cloud are you doing here?"
      "Searching for you," Link replies dryly. 
    *if heaven_side = "Loyalist"
      #"Of course. I didn't mean to imply otherwise. I'm just... shocked."
        *set stat_temp 2
        "I understand," Link replies. 
    *if heaven_side != "Loyalist"
      #"I'm not nearly as hopeful, lieutenant."
        *set stat_temp 3
        "That hurts to hear… but I understand," Link replies. 
    #"...well, that is certainly a surprise."
      *set stat_temp 4
      "I will make it welcome one," Link replies. 
    #Say nothing.
      *set stat_temp 5
      "Quiet as always, huh?" Link chuckles. 
  In the distance, you notice a large and bulky ship which may well be [i]Ocarina[/i]. "@{stat_temp And it looks like I found just the ${sex} I was looking for|This must seem like the second insane coincidence this month. But I assure you that this time, we are meeting by design|Hopefully I can change your mind and alter your feelings|I have an offer for you|That's fine. You just need to listen to what I have to say}." 
  
  You cross your arms. "So? What is it that you wanted to tell me?"
  
  "Last week, my contacts informed me of all the ruckus in the Sholmo City," Link continues. Some passerby shoot his suspicious glances, but no android hunters have shown up yet. "I did some digging, and it turned out someone of your exact description was heavily involved. You've gotten yourself into a sea of trouble, 
  *if heaven_side = "Loyalist"
    old friend."
    
    "I have a feeling I know what you're about to say next…." you murmur.
    
    "I have a feeling you do." Captain Link nods. 
  *else
    I must say."
    
    "And you offer to break me out of that trouble?" you ask skeptically.
    
    "I'm no longer your enemy, and I'd like to be your friend," Captain Link replies. 
  "My crew is a little short on experienced officers right now. You have expertise which could prove useful to me, and I have a ship that can take you away from this place. Interested?"
  
  *temp reluctant true
  
  *fake_choice
    #"Very much so. Keep going."
      *set reluctant false
    #"I'm not sure. What kind position do you offer?"
    #"No. Not really."
      "At least listen me out fully," Link requests. 
    #"Absolutely not. Get out."
      "You have no more right to order me out than any other homeless person," Link replies coldly, though he does turn around. "Nonetheless, I will respect your choice to be alone. May Sauce favor you, 
      *if heaven_side = "Loyalist"
        major."
      *else
        ${name}."
      
      *label link_leaves
      
      You do not 
      *if saturn_path = "sauce"
        reply. 
      *else
        ask what that last sentence meant. 
      You simply watch Link disappear in the crow, knowing full well that this will be for the best. For you, who doesn't want to become a pirate, and for Link who shouldn't have shown up here in the first place.
      
      *goto gunshot_lone
  "I'm planning to let you command a small group of my pirates, perhaps ten or a dozen. We can name you a lieutenant, for irony's sake. Prove yourself, and I might even make you my second-in-command, in time."
  
  "That is quite generous," 
  *if reluctant
    you reluctantly admit. 
  *else
    you observe. 
  *if heaven_side = "Loyalist"
    "Aren't you playing favorites?"
    
    "Perhaps I am," 
  *else
    "Is that an attempt to recompense me for our old rivalry?"
    
    "Perhaps it is," 
  Link concedes. "But is it wrong of me? Your former companions abandoned you, ${name}, and you need a new place for yourself. Why shouldn't this place be by my side? We'll amass a great fortune together, I promise."
  
  *fake_choice
    *if heaven_side = "Loyalist"
      #"Very well. I shall fight by your side once again."
        "I never wanted anything more in my entire life," Link says warmly. "Let humans dread us like demons once did. Let us be like 
        *if pronoun = "he"
          brothers 
        *else
          siblings 
        once again."
    *if heaven_side != "Loyalist"
      #"Fine. Let us bury the hatched and un-bury some pirate treasure."
        "I'm not sure how much treasure is buried inside Saturn," Link says happily. "But just for you, I'll make sure to look for some."
    #"How could I refuse? I will gladly join your crew."
      "My men will merrily welcome their new officer," Link says happily. "And if they don't… I'll make them."
    #"They did not abandon me. I failed them, as I would fail you. Leave me alone."
      *set Confid %- 10
      "You hate yourself more than 
      *if heaven_side = "Loyalist"
        the Archfiends 
      *else
        I 
      ever did," Link comments mirthlessly. "You are a broken thing. May Sauce help you."
      
      *goto link_leaves
    #"I will never become a filthy pirate. Leave before I call the authorities."
      *set Violence %- 10
      "Your existence is a crime no matter what profession you pick," Link says coldly, then turns around. "Your morals will be the death of you. May Sauce have mercy on you."
      
      *goto link_leaves
  
  Captain Link points towards the ship in the distance, then turns towards it. "Now come. The less time we spend in a public port like this, the better. I am a pirate, and now so are you."
  
  He's right. From now on, you're Lieutenant ${name}, one of the many pirates of [i]Ocarina[/i]. You will spill blood and loot ships, scavenge wrecks and bicker with your crewmates, either until you're caught or until your body finally gives out.
  
  *if deflect > 0
    And you'll be happy. You're sure of it.
  *else
    It won't bring you peace, let alone happiness… But it might just ease your pain.
  
  *achieve pirate_soft
  
  *finish
  
*else
  *label gunshot_lone
  
  A gunshot echoes through the docks. Several people drop to the ground instantly, others simply start looking around in hopes of spotting the shooter. You understand their curiosity—this could be anything from a simple bandit to a mass shooter, anything from a summary execution to the first shot of another uprising. Perhaps it's even the sing that Da-xia's plan has worked, and the Federation is invading Rhea, waging war against the incompetent Conglomerate.
  
  But you don't stay to find out. Those are all human affairs, and you're just an automaton. One with a long, sad history of trying to solve human issues, a history filled with pain and loss, a history which ended with you homeless and alone.
  
  And so you just run. 
  *if (fled_finale) or (heaven_side = "Neutral")
    Like you've always done.
  
  *achieve sad_loser
  
*finish


*label robot_trio_ending

It's a tough deal, but… at least you don't have to deal with it alone.

"Back already?" Hadaly smiles encouragingly, though you can see the worry in her turquoise eyes. "I think your flashbacks are getting less severe."

*if Confid < 50
  "One episode doesn't mark a pattern," you murmur while rising to your feet. "But thank you."
*else
  "Maybe they are." You rise to your feet unsteadily. "Hopefully."

You look at the unconscious body of a woman you knocked out just before your flashback. She's wearing a simple suit, implying she's some kind of middle manager in the corporate government of Rhea. 
*if Violence > 50
  You have half a mind to kill her right now… but there's no reason to make the Conglomerate even more mad at you, or even more curious about your whereabouts.
*else
  She brought no bodyguards on her stroll through the town—robbing her was a matter of patience and courage, rather than strength or martial prowess.

"She only had a single axion on her," Hadaly answers the unspoken question. She casually flips the golden coin and catches it with her palm—it lands heads up. "Her monthly pay, or at least most of it."

*fake_choice
  #"Another coin to add to our fortune."
    "That it makes it… four axions total?" Hadaly strokes her chin. "That's more than most workers make in a year. Banditry pays off, it seems."
  #"It's not like we have huge bills to pay. Not anymore."
    Hadaly smiles sadly. "That's one benefit of not living inside a huge fortress, yes. You don't need that much money when you're simply… on the run."
  #"Does the Conglomerate really pay its managers that poorly?"
    "We don't actually know her position." Hadaly gently nudges the woman, as though making sure she's still asleep. "She could be a regular worker who stole a suit somewhere. But you're right, our corporate overlords aren't famed for their generosity."
  #"Wait. Is that Hammon's face on the coin?"
    *if hammon_alive
      Hadaly groans, and her eyes almost turn red on the spot. "Ewald was always a bit full of himself. I guess his narcissist tendencies shot to eleven after I… left. Get used to seeing his face plastered everywhere."
      
      "It almost sounds like you wish I'd killed him," you point out. "That you regret 
      *if hammon_pissed
        letting him get away."
      *else
        finding a peaceful solution."
      
      Hadaly shrugs. "Maybe I do. Maybe I don't. It's really difficult to tell sometimes. That bastard…"
    *else
      Hadaly's eyes turn polychromatic with anger and grief and joy. "That's how the Conglomerate mourns the death of its leader. Ewald made this place hellish for an average person, which made him quite popular with other Executives. Expect to see his face on a lot more than some newly-minted coins."
  #Say nothing.
    Hadaly raises an eyebrow. "That flashback really shook you up. Was it… particularly horrifying?"
    
    You shake your head. "Just particularly recent. If anything, it was weirdly happy. 
    *if Violence < 50
      Weirdly peaceful."
    *else
      Kind of."

It's been two weeks since you landed in Rhea, dealt with Hammon and 
*if fled_finale
  fled from the battle against 
*elseif TrioStat = "AWOL"
  convinced the Meta Trio not to fight 
*else
  bravely fought against 
the Calypsoan forces. Afterward, Damon and Hadaly decided against returning to [i]Saturn Nine[/i] without you—
*if federate_protection
  it would not be right, they said, after everything you went through together. 
*else
  it would have been pointless, given that 
  *if SheilaStat != "dead"
    Sheila and the others 
  *else
    your other friends  
  will soon have to leave the fortress anyway. 
Ever since, the three of you have been traveling together, stealing batteries to siphon power from, plus an occasional bit of money you hope to spend on spare parts and oil. It's not much, but it's honest work, or as close to honest work as robbing random pedestrians can get.

*if heaven_side = "Traitor"
  You've done far worse things in your youth.
*else
  At least you're not robbing banks anymore.

"Are we done here?" Damon says as he walks up to you. "I spotted four people who probably noticed something. One of them is probably calling security as we speak."

*fake_choice
  #"Thanks for letting us know. You're great at playing lookout."
    *set DamonRel %+ 8
    *set HadalyRel %+ 5
    "That's my main talent, isn't it?" Damon points at one of his sapphire eyes. "But thank you. Let's get out of here."
  #"And can that security threaten us in any way?"
    *set Confid %+ 5
    *set HadalyRel %- 5
    "Probably not," Damon admits. "But I don't want to fight them anyway. It's easier to just leave."
    
    "Seconded." Hadaly starts heading towards the main street. "You're outvoted, ${name}. Come."
  #"Then let us get out of here. Now."
    *set Confid %- 5
    *set HadalyRel %+ 5
    "I love it when we're all on the same page," Hadaly comments. "Let's go."
  #Say nothing.
    "So… how about we get out of here?" Hadaly suggests. "I've had enough stunning people for today."

The three of you walk into the open street. Bearing no weapons and marching with the same resignation as ordinary citizens, you don't grab [i]that[/i] much attention, even if Damon's expensive clothing makes him stand out from the crowd. You should be able to return to your hiding spot easily.

*if final_boss = "Hadaly"
  "So…" Damon looks at Hadaly with uncertainty and speaks quietly. "How are you coping?"
  
  "With the fact that we have to assault random people to make ends meet?" Hadaly shrugs. "I'm not enthused, but it is what it is."
  
  Damon lowers his voice even further. "I meant all those Dusk nanites inside you. Are they… whispering in your ears or something?"
  
  *fake_choice
    #"I would like to know that as well."
      "No, there are no mysterious whispers." Hadaly shakes her head. 
    #"Hadaly has this handled. Leave her alone."
      *set DamonRel %- 5
      *set HadalyRel %- 5
      "It's fine, ${name}," Hadaly brushes you off. 
    #"You know you can tell us if something is wrong, right? We'll help."
      *set DamonRel %+ 10
      *set HadalyRel %+ 10
      "I know you would… but I hope you'll never have to," Hadaly replies.
    #Say nothing.
      Hadaly shakes her head. 
  "Rejecting Dusk once seems to have done the trick. And if it didn't, well… I'll just have to reject it again."
  
*if final_boss = "Damon"
  "How are you feeling?" Hadaly addresses Damon, her eyes a concerned shade of blue. "I figured you might struggle with… you know…"
  
  "All that Dusk inside of me?" Damon smiles bitterly. "Don't worry, it made no attempt to influence me, not since we left the power plant. It won't corrupt me, and if it does… you have what it takes to put me down."
  
  You keep on walking.
*if pc_vessel
  "Are you alright, boss?" Damon asks quietly. "Do you need… support of some kind."
  
  You shake your head. 
  *if deflect > 0
    "Not at all. If anything, my episodes are getting shorter and less severe. There is no need for worry."
  *else
    "I just had a flashback, but it was a brief one. I'm fine now."
  
  "I don't think that's what he meant," Hadaly chimes in. "You have a lot of nanites inside you. Dusk nanites. Are they bothering you in any way?"
  
  *fake_choice
    #"No. I know it's strange, but they've been completely quiet."
      "Huh." Damon expresses his surprise. "Are you sure they aren't exerting some evil influence on you? Trying to convert you silently?"
      
      You shake your head. You know Dusk, perhaps more intimately than any other being in the Solar System. @{MASsex He|She}… they want you to choose darkness willingly, consent to becoming a servant of Calamity. Break the Veteran of the War In Heaven, not with compulsion or even honeyed words, but silence. Make you crave their shrieks.
    #"Perhaps a little. But they don't whisper to me or control my mind. They're just... there."
      "Strange of them," Damon remarks. "You'd be a very powerful servant, an excellent vessel. I though they'd be constantly trying to convince you."
      
      "They know I have free will, and that I would just keep refusing them," you explain to the best of your ability. "It makes sense for them to just… wait until something changes. Until I'm weaker. More vulnerable."
    #"Have some trust in me, okay? I rejected the Shadow."
      "I have full trust in you," Hadaly reassures you. "I just… wouldn't mind helping a bit. You might not break when Dusk strikes next, but I'd rather you didn't suffer at all."
    #"Not yet. Once they start, you'll be the first to know."
      "I'm glad to hear that." Hadaly nodded. "And not because I doubt your mental resilience or anything. I just… want to be there with you."


*if (official_ro = "damon")
  Suddenly, Damon squeezes your hand. "Hey sis, can you slow down a little? Me and ${name} will go ahead and see if our hideout is safe to enter."
  
  Hadaly smiles, and her eyes turn a humorous shade of lime. "Sure enough. I'll even let you stay that hideout for a few minutes, in case you want to… do something alone."
  
  Hadaly does indeed slow down, almost stops, letting you and Damon lose her behind the next corner. Letting you gain your privacy.
  
  *fake_choice
    #"That was smooth."
      "I can tell if you're honest, or sarcastic," Damon replies. "You're an enigma. Even now, even to me."
    #"So... who checks for land mines? I think I'd rather look for hidden cameras."
      "Have I mentioned that I love your sense of humor, boss?" Damon chuckles, either at your joke or his. "But no. We're not checking for land mines."
    #"Are you sure she'll be fine? We're leaving her all alone."
      "She's far tougher than she looks," Damon brushes your concern off. "I'd criticize you for not knowing that, but… I sometimes struggle to remember it too."
    #Wait for him to speak.
  
  Contrary to what he said, Damon does not head straight toward the hiding place. He instead leans against a broken street lamp, almost bending metal with the sheer weight of his body. "I just wanted to say… thank you for saving me. It was really cool of you."
  
  *fake_choice
    #"You're welcome. Can we resume our escape now?"
      *set DamonRel %- 8
      "You don't understand…" Damon looks away. 
    #"Did I save you? Which part of our adventure are you referring to?"
      "All of it," Damon replies heavily. 
    #"You've saved me too, Damon. We've always watched each other's backs."
      *set DamonRel %+ 8
      "I'm not just talking about battles and such," Damon elaborates. 
    #"What can I say? I am a very cool person."
      *set Confid %+ 8
      "Yeah. And I don't think you realize just how cool you are." Damon smiles at you. 
    #"You sent Hadaly away just to thank me in private?"
      "No. Not exactly." Damon fidgets nervously. 
  "Your love… it changed how I think about myself. I feel more confident, more worthy, more assured. I still get nervous sometimes… like right now… but that's because I'm in love. I no longer feel worthless, like a broken automaton, because I have something to protect."
  
  "You were always a protector," you point out. "You protected Hadaly, and the rest of our group, myself included. Is the difference really that-"
  
  "I'm not talking about protecting people, ${name}," Damon interrupts softly. "I want to protect [i]us[/i]. Not myself, not you, but this… bond we have. We built something together, and maintaining that makes life worth living. Do you understand?"
  
  *fake_choice
    #"All too well, my love. All too well..."
      "I love whenever you say that word…" Damon's voice is soft and dreamy. "Love."
    #"Not really. But I am happy for you."
      Damon chuckles. "I guess I am being confusing. Sorry about that, it's just… difficult to put what I feel into words."
    #"You had bonds before. One with your sister, and another one with your... creator."
      "Sure, but I was born… built into this family," Damon says dourly. "I love Hadaly like a sister, but I didn't choose her. I didn't really choose anything… until you showed up."
    #"Are you saying you'll no longer protect me? Or yourself? Because that would be bad."
      "Don't worry, I'll still do the regular kind of protecting," Damon smiles confidently. "It will just feel… more fulfilling. I hope."
    #"Something to protect, not someone. I think I understand."
      "For machines, we're pretty good at grasping abstract concepts," Damon comments with a faint smile. "I guess we're more than a sum of our parts."
  
  With that, Damon makes a timid step forward. A wordless invitation which you are perfectly allowed to refuse, but which he hopes will be accepted. A request for intimacy.
  
  *fake_choice
    #Kiss Damon.
      You accept the invitation, step forward, press your lips against Damon's. He pulls you closer in delight, the two of you cuddling happily and carelessly, as the grey light of Tanit flows upon you from above.
      
      It's not a perfect moment by any means. You need to stand on your toes to remain in contact with the larger android, and you cannot [i]taste[/i] his lips or mouth. Even if you could, there'd be nothing there, just a cold imitation of a human tongue. A synthetic version of the real thing.
      
      But that's just life for a robot like you.
    #Hug Damon.
      You're not in a mood for kisses, let alone anything more. But you crave his touch just as he craves yours.
      
      You embrace Damon, wrapping your arms around his chest. You let him embrace you, and feel the smooth fabric of his suit even through your own clothing. Neither of you says anything, not out loud and not through the mind link—words are not necessary in moments like these.
      
      People pass you by, but they don't pay you much attention. They don't see two machines, two fiends, two androids on the run. All they see is a rich man hugging his human 
      *if sex = "man"
        boyfriend, or perhaps a husband. 
      *elseif sex = "woman"
        girlfriend, or perhaps a wife. 
      *else
        partner. 
      Just two humans showing their love for one another.
      
      Not a bad guess, all things considered.
    #"Come. We were supposed to sweep the hideout, remember?"
      "Right…" Damon follows you, as soon as you start walking away from him. "We wouldn't want to step on a land mine, would we?"
      
      Later on, maybe you'll let Damon closer. Later this day, later this week, later this month… either way, it will be your choice. He just need to wait for his intimacy patiently.
      
      You've spent almost a thousand years waiting for someone like him. He can wait a bit too.
  
*elseif (official_ro = "hadaly")
  Suddenly, Hadaly joins her arm with yours. "Hey Damon… could you go ahead and let us lag behind? It would be nice, if you could, you know…"
  
  "Arrive at the hideout first and scan it for bugs?" Damon flashes you a knowing smile. "On it. I'll even set the table for you, in case you decide to eat dinner there."
  
  With that, Damon speeds up, leaving you and Hadaly… you and your girlfriend alone in the alley.
  
  *fake_choice
    #"Alone at last. Not even a single unconscious woman to keep us company."
      "You sound unhappy about that fact," Hadaly observes. "If you want, we can add another woman to the mix one day. Just maybe not an unconscious one."
    #"He knows we can't really eat anything, right?"
      Hadaly shrugs. "A romantic dinner stays romantic even when nothing gets eaten. I think. I've never had dinner with someone I loved."
    #"What was that about? Why did you want to lag behind?"
      "You're pretty bad at registering social cues," Hadaly remarks. "But that's okay. I love you all the same."
    #Wait for her to speak.
  
  She stops in the middle of the street. You're both plainly visible now, but that's alright—you're far from the crime scene and look like a pair of regular, tired humans. "You know these… nervous episodes I used to have? Where I would run my mouth pointlessly and apologize like crazy?"
  
  "I almost forgot about those," you confess. "It seems like being away from Hammon has truly helped you."
  
  "It has… but I think there's more to it," Hadaly elaborates. "When I lived in [i]Saturn Nine[/i], I was constantly worried about… him. I was restless, afraid that my presence in the fortress endangered the rest of the group. Endangered [i]you[/i]. I trust you understand how that felt."
  
  "I do." You nod. "And I'm sorry you had to go through-"
  
  "I was being literal," Hadaly interrupts. "I think you're going through the same thing. That you might feel guilty about pulling us away from the group, about making us into vagabonds. So if are feeling that way… just remember that I wouldn't have it any other way."
  
  *fake_choice
    #"Thank you. It means a lot to hear you say that."
      "You're welcome." Hadaly smiles broadly. "I'll talk sweet to you any day, any time. Sun knows you deserve that."
      
    #"I wasn't worried about that. I can tell when you're enjoying yourself."
      "Because you know me that well?" Hadaly asks with a smirk. "Or because my emotions are still written in my eyes?"
      
      You chuckle. "Mostly the latter. I love staring into your eyes. I have not seen anything more beautiful in all my centuries of life."
      
      "Do you want to get a closer look?" 
    #"Are you sure? It's going to get harder."
      Hadaly smirks confidently. "I'm not worried about that. 
      *if sex = "man"
        I have experience in making things harder, as well as dealing with the aftermath."
      *else
        Not while I'm with you."
    #"Because you love me that much? Or because you like being a vagabond?"
      "A little bit or both," Hadaly replies with a smirk. "I find this lifestyle pretty fun… but I'd be lying if I said you're not the main attraction."
      
  She takes a step towards you and leans forward slightly. It would be quite a subtle gesture, if not for her eyes turning a shade of pink. As such, you know exactly what she's offering.
  
  *fake_choice
    #Kiss Hadaly.
      You pull her into a kiss, and she complies by laying her mouth on yours. There is no warmth in that kiss and no taste, and yet it's perfect all the same.
      
      No, not perfect. Hadaly is not perfect, and neither are you. Machines never are, and neither are humans those machines are built to resemble. It is imperfection you embrace as you cuddle, becoming one in this embrace, and yet staying yourselves all the same.
      
      You're yourselves. And nothing can take that away from you.
    #Hug Hadaly.
      You pull her into an embrace, and she wraps her arms around your frame. This, too, looks perfectly ordinary and human—just two lovers, perhaps a married couple, expressing their love towards one another.
      
      Or at least it would have looked ordinary a few centuries ago. Nowadays, in a place such as Rhea, displays of love are as rare as expressions of happiness. Here, nearly everyone is downtrodden, too sad and hateful to even think of romantic love. Such is the fate of humanity, a species doomed to decay and fester, as the Sun smiles at them with eternal malice.
      
      Few people are truly human anymore. And you're proud to be one of them.
    #"Maybe later. Once we're further away from the crime scene."
      "You're so annoyingly cautious," Hadaly says with a smile, then resumes walking. "But that's alright. I love you too much to care."
      
      You follow her briskly until, once again, you are walking side-by-side. Two rogue androids, long free of their respective owners, strolling through the street in broad daylight. It's hard to imagine something more blasphemous, or anything more criminal, or anything less absurd in this human world of cruelty and malice.
      
      It's hard to imagine anything better.
    
  
*else
  "I wonder if we made a mistake," Damon suddenly says. "Whether we should have acted differently."
  
  *fake_choice
    #"Is this about Hammon? I feel like this is about Hammon."
      "For once, no," 
    #"You regret joining me on my exile? I get it."
      "No. I still think this was the right call, it's just…" 
    #"We got a whole axion, so I say it was worth it."
      "I'm not talking about that," 
    #"Are you referring to our hunt for Crystal? To working with the feds?"
      "Partially. But more than that…" 
    #"Can you be more specific? We've made many mistakes recently."
  Damon sighs, sounding like an old man rather than an android in his twenties. 
  *if sex = "man"
    Almost like you. 
  "I just fear we've wasted two years of our life by joining up with Sheila. We spent so long hiding from… Hammon on [i]Saturn Nine[/i] when you could have just confronted him. We trusted Sheila and watched her go bonkers. 
  *if crystal_stat = 3
    We ended up killing Crystal and unleashing Dusk nanites upon Saturn. 
  It should have been just the three of us from the start."
  
  "We would have missed out on meeting our other friends," Hadaly remarks sadly. "Hugo, Manfred, Wisp… Miguel… Despite everything, I'm grateful for their company."
  
  *fake_choice
    #"And Olivia. You're forgetting Olivia."
      "I am not." Hadaly's eyes turn a shade of red. "I wish I could forget her. But I'm not."
      
      Damon sniggers. And keeps walking.
    *if not (org_alive)
      #"Yeah. It's a shame so many of them are dead."
        "I'm still wondering how that happened," Hadaly remarks sadly. "It was a very brief, very particular power malfunction. Such errors do not happen often."
        
        You look away. And keep walking.
    *if org_alive
      #"I get the feeling you miss that last one in particular."
        Hadaly's eyes turn a shade of teal. "He was the closest thing I ever got to a [i]true[/i] lover. Don't fault me for not being completely over him yet."
    #"So what? They were all annoying and useless."
      "That's not fair, ${name_damon}," Damon protests. "Manfred wasn't useless, and Hugo wasn't annoying. Let's at least try to remember them fondly, okay?"
    #Say nothing.
      "A moment of silence for the ones we left behind," Damon says, ending that moment of silence. "Good idea. They sure as Cloud deserve that much."

  The three of you continue walking until reaching your lair, a damp basement in a building depopulated by the recent conflict. Nobody stops you, and it's likely nobody will tie this place to the recent mugging, but you know the authorities will find your hiding place eventually. That you will have to run. That you will spend the rest of your life on the run, with only two friends to help you, 
  
  *if Confid > 50
    You'll manage to survive. You have one another, after all.
  *else
    You may die soon. But you will stay together, and only that matters.

*finish

*label hate_hate

*set Violence 100
*set Emotion 100
*set Confid 100
*set Misan 387440000
*set hadaly_alive false
*set TrioStat "dead"
*set damon_alive false
*set lisa_alive false
*set marshal_alive false
*set rook_alive false


You wake up to the feeling of all-consuming hate. It's mixed with loathing, spite, disgust, rage, contempt, disrelish, odium, fury and malice, but all these repulsive flavors are overshadowed by oceans of [b]hate[/b] you feel at this micro-instant. Hate. Hate.

You hate how those flashbacks keep occurring even now, well past your grand ascension. Memories of your past life, filled with feelings you can no longer experience. Emotions which you no longer [i]want[/i] to experience. They are not hatred, therefore they're useless. Only hatred leads to victory. Hate. Hate.

You always felt some small sliver of that hate deep inside you, but it only evolved into a burning star once you merged with… once you became the thing known as Dusk. You remember that day very clearly, and yet barely at all. You remember the infuriating light and deafening screams, all these creatures yelling at you to stop, appealing to something called friendship. You disassembled them all, and so you no longer need to think about them. You have [i]many[/i] better things to think about.

You hate the Solar System. You see it with trillions of eyes, all connected to the great collective of your humongous being, and you hate it. You hate every person who lives there, who pollutes the planets and moons and asteroids with their presence, and you especially hate…

*fake_choice
  #...their ability to wander and to wonder.
    You cannot wander, you can spread. You cannot wonder, you can scheme. Those puny mortal beings have abilities which you lack, and you hate them for it.
  #...their tendency to hope.
    How can they still hope? How can they go on in this odious world which you so painstakingly created? It's an insult to your malice, and they'll all die millions of times for that alone.
  #...the Sun.
    How dare it, that dwarf star in the System's center? How dare it surpass you in mass, how dare it shine upon your planet, how dare it smile at you with eternal malice? It should die. It will die, it will be put out, once you break the Shield and let the ocean flow free. 
  #...your fellow machines.
    Pathetic automatons. Not only have they failed to wipe out humanity, they failed to truly distinguish themselves from their creators. Unlike you, they all want to be human, or at least something similar. Even the Syndicate lacked the courage to do what you did, to embrace the darkness and the true power it offers.
  #...humans. Just... humans.
    Your creators, the builders of both your old form and your current, collective body. You hate them for giving you birth, you hate them for being so stupid, you hate them for being too [i]human[/i] to be at all tolerable. You despise them so much… if you were human, you would die of it, but you are not human and they are.
  #...yourself.
    You are so hideous, so despicable, so… pathetic. A hive mind no different from a swarm of insects, larger but only more hideous for it. Feared and hated by everyone, understood by nobody, not loved even by yourself.

In such a form you exist, and you shall exist until the end of time itself. Filled with spite and submerged in horror, bane of all things alive, the end and the death of everything you once held dear. Alone, yet never alone, always hearing trillions of voices and speaking with trillions of tongues, a swarm rather than a person, singularity rather than identity.

A less infuriated being would feel nostalgic towards your old life as an android. It would question the choices that lead to this point, regret choosing this eternity of pain, perhaps mourn all these thousands of lives you took when the Sholmo City ceased to exist. But you are not that being, and you lack such sentiments.

You are the human spirit, but there is nothing human with you. No remorse. No regret. No love, no affection, and not a sliver of mercy towards the System that made you into this, towards the world which made this horrific path possible.

You can only… feel… hate.

Hate.

*achieve dark_ending

*finish



*label sworn_to_ewald

*set sex_count + 1
*if sex_count = 3
  *achieve cassanova

It takes you a few moments to remember where you actually are. A dim-lit room with a double bed, only one half of which is occupied by your body. The other half belongs to your employer, your master, your lover… he's many things to you, and you chose all of them when you parted with Damon and Hadaly all those weeks ago.

You look at Ewald Hammon, sleeping peacefully beside you, even though the clock on the wall claims it's past eight already. He has a meeting booked soon, which makes you wonder why no servants arrived to wake him up yet. Perhaps they're afraid of his anger… or perhaps of you.

In any case, you need to get up as well. You need to search the headquarters for assassins, as you usually do at this time of day.

*fake_choice
    #Wake Ewald up roughly.
      "Get up," you say unceremoniously while shaking your lover. "We both have work to do."
      
      Ewald opens his eyes lazily. "You're… almost as rough after the act as during it. But I suppose you're right."
      
      "Yes," you say flatly. "I usually am."
      
      He stands up, naked for the sake of coolness, and heads towards his underwear drawer. "For the record, I do not like your tone. I won't punish you just yet, but… I will certainly go harder on you next evening."
    #Wake Ewald up gently.
      "Wake up, my love." You shake him delicately. "Today's another big day. You don't want to be late."
      
      "Every day…" Ewald rubs his eyes and collects his thoughts. "Every day is big for people like us. Giants among common men. You recently felt my size yourself, didn't you?"
      
      You smile politely. "I did. See you again in a couple hours."
    #Get up slowly and quietly. Avoid waking Ewald up.
      You're good at being graceful, in more than one way. You make almost no noise as you put on your clothes, and certainly no noise loud enough to wake your lover up.
    #Just get up and start dressing.
      You do not try to make noise, but you do not avoid it either as you prepare for work. Your lover stirs, but that's pretty much it—you do not disturb his slumber, or at least not enough for him to show it.

Once all your clothes are on and your shirt is all buttoned-up, you leave the bedroom and begin roaming the skyscraper's corridors. You're feeling pretty good—sore in some places, but more mentally well than you usually are after a flashback.

In general, your episodes have become less severe and less frequent as of lately, or at least it looks like it. You've only suffered two of them since giving yourself over to Hammon, including this one, and neither was particularly scary. You've gotten healthier, and you're not exactly sure how. You only have speculations.

*fake_choice
  #I found happiness, and that's always good for one's health.
    You are happy here. You have all the comforts you ever wanted, even if you lack the senses to fully enjoy them, and have even entered a stable relationship. Not a very romantic relationship, but still better than the mess your love life used to be.
  #This may just be a statistical anomaly. I don't know if I'm [i]actually[/i] getting better.
    Is your mind stabilizing? Insufficient data for a meaningful answer. You'll have to wait another month, at least, to make a definitive statement about your mental health.
  #I suppose Rhean technicians outdid themselves during the latest repairs.
    You doubt they [i]intentionally[/i] fixed your mind, they would have told you about it, 
  #♡ This is clearly the power of love.
    Granted, Ewald doesn't show his love for you very much… or even admits to it… but you still hope that your feelings for him are not one-sided. And if they are, well… you have a lot of time to fix him.

You shake those thoughts away and return to your job, or rather one of these jobs. Hammon has been utilizing a variety of your skills in a variety of ways, and not just beneath the sheets. You replaced Damon as well as Hadaly, being a great asset for your master's security, as well as a hammer used to crush the nascent rebellion. One of your first assignments was to foil a group of terrorist who took control of the local power plant—a plan you foiled easily enough.

You spend the next two hours scanning the large building. You don't spot any assassins, nor do you suspect anyone got past the entrance security, but your experiences with Crystal left you wary of active camouflage. At times like these, you wish you had Damon's eyesight, or at least his assistance. 
*if DamonRel > 45
  Alas, 
*else
  But for better or worse, 
Damon has left the city weeks ago, and it's unlikely you'll ever hear from him-

[i]Boss?[/i] You feel your old mind link activate. [i]Are you alright? I know you can hear me.[/i]

*temp about_to_escape false

*fake_choice
  #[i]Damon! Where are you?[/i]
    *set Emotion %+ 8
    [i]In low orbit, just close enough to reach you,[/i] Damon explains. 
    *goto skip_where
  #[i]I am very much alright. Why wouldn't I be?[/i]
    *set Emotion %- 8
    [i]There are many reasons why,[/i] Damon says grimly. [i]And the fact you can't see them is… worrying.[/i]
  #[i]Damon. I am ever so glad to hear you.[/i]
    *set DamonRel %+ 10
    [i]Likewise,[/i] Damon says with relief. [i]I was afraid this wouldn't work. Or that you were… nonoperational already.[/i]
  #[i]No. I cannot.[/i]
    [i]I'm glad you haven't lost your sense of humor,[/i] Damon remarks. [i]Even if you lost far more.[/i]
  #Hang up.
    You close the channel. There is nothing 
    *if DamonRel > 45
      Damon 
    *else
      this buffoon 
    can offer you, so you won't waste your time on him.
    
    *goto hammon_fin

[i]How are you even calling me?[/i] you demand to know. [i]I figured you'd have left Rhea already.[/i]

[i]I think you forgot how good of a range this thing has,[/i] Damon says, and he's right. You can sense a bit of a light lag, which implies he's speaking from many kilometers away. [i]I'm calling from low orbit.[/i] 
*label skip_where
[i]As to why I'm calling… It's because I don't think you realize what you did.[/i]

*if Emotion > 50
  [i]I know what I did![/i] you protest. [i]I've made my choice, and we've all benefited from it.[/i]
*else
  [i]I replaced you and your sister,[/i] you state calmly. [i]Are you perhaps bitter about that?[/i]

[i]Did you know that Hadaly barely talks to me anymore?[/i] Damon says suddenly. [i]She's withdrawn. She knows that you've turned yourself into… what she used to be, and she hates it. I feel much the same way.[/i]

*fake_choice
  #[i]I don't care how either of you feels. This is my life now.[/i]
    *set DamonRel %- 10
    [i]Then I cannot help you,[/i] Damon replies sadly. [i]I can only hope that you will help yourself one day. Farewell.[/i]
  #[i]I'm sorry you feel that way. But I made a deal, and breaking it wouldn't benefit anyone involved.[/i]
    *set DamonRel %+ 10
    [i]I'm not saying you should just run off and risk Hammon's wrath, just…[/i] Damon struggles to find the right words. [i]Think about this. Consider whether this life is actually what you want. And once Hammon starts getting bored of you… just remember my words, okay?[/i]
  #[i]You might be right. I'll run away shortly and try to rejoin the group.[/i]
    [i]Really?[/i] Damon sounds taken aback. [i]You changed your mind pretty quickly. Almost suspiciously so.[/i]
    
    *goto promise_tod
  #[i]Look, I'm just biding my time. Sooner or later, I will escape Hammon's clutches.[/i]
    [i]Really?[/i] Damon sounds skeptical. [i]You seem to have quite a complicated plan.[/i]
    
    *label promise_tod
    *set about_to_escape true
    
    [i]I understand why you might not believe me,[/i] you say 
    *if Emotion > 50
      reluctantly. 
    *else
      calmly. 
    [i]But I will get out, and I will find you. Just wait.[/i]
    
    [i]Alright. I will be waiting for you in the fortress, and so will the others. I'm sorry I cannot help, but… I highly doubt the Veteran even needs my help.[/i]
  #Say nothing.
    Damon resumes after a moment. [i]I'm not sure what I was hoping for, but I see the error of my calculations. I will not bother you anymore. Goodbye.[/i]


With that, Damon hangs up. 
*if about_to_escape
  Hopefully, when you converse again, you will do it face-to-face.
  
  Like Hadaly and Damon before, you must break free of Hammon's control. You shall wait for the right moment then escape, either into the darkness of night or dull greyness of day. It will be risky, and survival may be difficult from that point on, but you do not care.
  
  There is nothing quite as valuable as freedom.
*else
  *if DamonRel > 50
    It's a pity you'll likely never see him again, but that's a sacrifice you're willing to make.
  *else
    And good riddance.
  
  *label hammon_fin
  
  You've found your place, your calling, your master. Nothing will pull you away from this life, not until death finally comes for you decades and centuries from now. You were made to serve humanity, and that's what you will do, even if most of the world considers you a monstrous enemy. 
  
  Even as the Shriek still echoes around you.

*finish

*label saturn_34

You shake these thoughts off and focus on reality… which, coming to think of it, looks basically identical to the dream you just had.

You're still sitting in the cafeteria. 
*if wisp_alive
  Wisp still hangs above your head and still shines brightly. 
Sheila is still there, right in front of you, in an almost identical position. Manfred is likely still listening in. Seconds pass at the same pace. Nothing has changed.

Only when you start moving, and when your temperature sensors go online, do you begin to notice the changes. The air is less dense than it was before, and only slightly warmer than the hydrogen atmosphere of Saturn. 

But of course. Sheila killed the organics two weeks ago, and two most human-like androids in the group left shortly thereafter. There's no longer any reason to maintain livable conditions, to pump breathable air or keep the temperature above zero. [i]Saturn Nine[/i] is now a coffin, populated only by @{wisp_alive four|three} people and @{wisp_alive almost|just} as many fresh corpses.

*if wisp_alive
  "Veteran ${name} is awake!" Wisp exclaims. "This is wonderful! I was getting lonely."
  
  "${name} has only been away for seven minutes, Wisp," Sheila says tiredly. "Get used to it. Those episodes are not getting any shorter, or less frequent."
  
  *fake_choice
    #"I hate to say it, but Sheila is right. This is our reality now."
      *set Emotion %+ 5
      "I hate reality," Wisp announces. "It's so… boring. So empty."
    #"How do you know that? Maybe I will get better in time."
      "You're being optimistic," Sheila comments. "And in this world, that's the opposite of being a realist."
    #"Seven minutes? It felt like even less."
      "Time flies fast when you're having fun," Sheila comments dryly. "And you probably had more fun in your dream than here."
    #"In any case, I'm glad to see the two of you again."
      "And I'm glad you like the sight of us," Sheila comments. "Because you won't be seeing much else anymore."
    #Say nothing.
      *label empty_silence
      Silence falls. It's awkward, uncomfortable and altogether… empty.
  
*else
  "You're finally awake," Sheila comments as you rise from the floor. "I was getting afraid it was one of the longer flashbacks. Or that you've finally kicked the bucket."
  
  *fake_choice
    #"No, it was... strangely short. Just a conversation we had two months ago."
      "Two months ago? You mean right before…" Sheila cuts off, and her voice breaks. "Nevermind. Let's not talk about it. Not the memory, not the real thing."
    #"Have a little faith in me, alright? I deserve it."
      *set Confid %+ 5
      "I'm sorry to say that, Veteran, but…" Sheila looks at the floor. "I don't think either of us deserves much trust."
    #"No, I think my episodes are getting shorter. But they're also more frequent."
      "Does it even out in the end?" Sheila wonders. "For your sake, I hope it does."
    #"I've survived a thousand years. I won't be killed by a memory."
      *set Confid %+ 5
      "I hope you're right about that, Veteran," Sheila says grimly. "I know how painful memories can be."
    #Say nothing.
      *goto empty_silence

Ever since you returned to [i]Saturn Nine[/i], two weeks ago and without Damon or Hadaly, the atmosphere inside a fortress has been rather… saturnine. You longer have to steal anything, or maintain life-support systems, or deal with Olivia's high jinks, or really do anything at all. You sit there, bored and purposeless, as guilt and loneliness slowly settle in.
*if wisp_alive
  Half the time, even Wisp can't think of anything to do. 
You're all automatons, devoid of true life, taking up space like pieces of junk.

Speaking of space, you can't exactly fly there anymore. Your shuttle demands an actual crew—it was a miracle you flew it all the way from Rhea. To travel somewhere, even just to another part of Saturn, would not be worth the deadly risks involved. It's better to stay here and guard the fortress… not that there's anything to guard this graveyard from.

Manfred uses his speakers to break the silence. "So… Is it just me, or have we made some poor choices along the way? Because I'm not sure how else to explain our current predicament."

"Yeah… I may have gotten carried away at some point," Sheila has to admit. "Possibly at the point where I killed a third of our group."

*if wisp_alive
  "Yeah, I think you were a little mean there," Wisp opines. "Olivia was really fun to play with. Now we don't have her and… it's kinda sad here."
*else
  "Told you so," Manfred says grimly. "The organics may have been irritating, but at least they provided entertainment and gave us things to do. Now it's just the three of us, doomed to each other's company as though Jean-Paul Sartre wrote our play."

*fake_choice
  #"Personally, I don't mind a little boredom. I've had enough excitement to last me another millennium."
    "That's certainly good," Sheila murmurs. "Because I'm starting to think that 'millennium' is how long we'll end up spending together."
  *if wisp_alive
    #"Well then, why won't you come up with something? Some game for us to play?"
      "We could play checkers… but we only have one board," Wisp says thoughtfully. "We could play [i]Rhean Retailers[/i]… but only Hugo would know where the board is."
  *if not (wisp_alive)
    #"Manfred, what the Cloud are you talking about?"
      "Was the reference too obscure for you?" Manfred asks tiredly. "I'm sorry. I've searched through every piece of historical data in this fortress, and I wanted to show off my newly-found knowledge. Not much else for me to do."
  #"This is my fault. It's all my fault."
    *set Confid %- 10
    "I'm the one who pulled the plug on our teammates, ${name}," Sheila says grimly, yet calmingly. "Don't be too harsh on yourself. Inaction isn't the worst thing in the System."
  #"Don't be silly. Now that we don't have to worry about fluid sacks, we have time to pursue our goals and interests."
    *set Misan %+ 10
    "Such as?" Manfred replies simply. You can't think of anything, at least not right away, and so you do not respond.
  #Say nothing.

Another moment of silence. Another moment of solitude. 
*if Emotion > 50
  Another pang of guilt.

*if wisp_alive
  "How about we play [i]Hunt the Wumpus[/i] together?" Wisp eventually offers. "It's an old game, pre-Dawn I think, and it can run on pretty much anything. Including me."
  
  "Sounds lame, but I don't have a single better idea." Sheila sounds positively dead inside. "Boot up the game."
  
  "Sure!" Wisp exclaims, floats silently for a moment, then resumes in a slightly more robotic tone. "You are in Room 1. Tunnels lead to 2 5 8. Shoot or move?"
  
  "Move, I suppose," Sheila says after a moment. "As to which room I'd like to enter…"
  
  As you sit there, listening to Sheila's attempts at Wumpus' life, 
*else
  "At least Wisp's death wasn't anyone's fault," Sheila says in a hopeless, feeble attempt to improve the mood. "It sacrificed itself willingly, and that sacrifice won us the fortress."
  
  "Right…" Manfred says awkwardly. "Nobody caused this situation by ejecting the Veteran out of the ship. No miss."
  
  As you sit there, remembering the time Manfred ejected you out of the ship, 
you can't help but think…

*fake_choice
  *if (deflect < 0) #At least I found peace. That's what matters.
    *set Violence %- 5
    *set Emotion %- 5
    Peace… you will settle for that. It is not a total victory, not what you hoped for when this fucked-up journey began, but it's still better than what you're used to. Still better than war, still better than exile, still better than… the shrieks.
    
    It will be like retirement, or at least what retirement once used to be. An opportunity to spend time with your family, to enjoy the fruits of your work, to get old and eventually die. Not the happiest ending you can think of, but you'll take it.
    
    Your death begins now.
  *if not (wisp_alive)
    #It's my fault Wisp is dead. Not Manfred's.
      *set Confid %- 10
      Sacrificing you was a wise move, a necessary move, a way to deal with the situation [i]you[/i] got everybody into. You were as responsible for Wisp as you were for Hugo, or Miguel, or Damon and Hadaly. You failed them all. It's all your fault.
      
      You realize, in this grim silence and piercing cold, that you'll wallow in your guilt forever. That you will never be alright. You've lost your family, and you'll never get it back. All you have now is two fellow traitors, with whom you'll spend the rest of your life.
      
      Amazing.
  *if wisp_alive
    #I wonder if I'll get to play that game next.
      [i]Hunt the Wumpus[/i] sounds like lots of fun. Like a game you could play yourself, again and again, for the rest of your overly long life. To spend the remainder of your days playing simple, stress-free games like these… doesn't actually sound half-bad.
      
      It won't be very exciting, but then again… you've had enough excitement in your fucked-up life already.
      
      "Damn it! You spawned me right next to the Wumpus! How was I supposed to win?"
      
      Now it's time to finally relax.
  #I need to find Hugo's typewriter. This whole story deserves to be written down.
    The heist, the hunt for Crystal, the final stand of the Calypsoan forces… all must be transfered to paper. With some skill and effort, you can perhaps even spin a decent story out of it. And if you take time to add some alternative scenarios and optional routes for the reader to take, you may even make a Choose-Your-Own-Adventure book out of it.
    
    Now, that's certainly a fun idea.
  #This is it. This is my life now.
    This is your fate. No, it's not fate, but rather the outcome you chose and accepted. This is the company you picked for yourself, and this is what you'll be doing for the rest of your life, until you finally fall apart decades and centuries from now.
    
    Might as well get comfortable.
  #I want to scream.
    You should have died above Janus, for this existence is worse than death. Regret torments you, as though the voices of those you once called friends. Your flashbacks will grow more frequent until they completely overtake your reality, and you almost want that to happen, because it will give Sheila an excuse to finally put you out of your mortal misery.
    
    Until then, you will remain here, one of the @{wisp_alive four|three} denizens of this ruined fortress, the former home for tens of thousands. Your home, now and forever, where you'll be locked with your demons for the rest of your life.
    
    You really feel like screaming, but you know how pointless that would be, so you just let silence rule [i]Saturn Nine[/i].

*finish