*set progress + 1
*set health 3
*set Calculation + 50
*set Database + 30
*set Build + 30
*set Projection + 40
*image h4.png
*set battery 87


[b]September 3rd, 90 AC[/b]

[b]T-plus 47921863 minutes[/b]

*if heaven_side = "Traitor"
  *goto traitor_dream
*if heaven_side = "Loyalist"
  *goto traitor_dream
*if heaven_side = "Neutral"
  *goto neutral_dream

*label traitor_dream
Blood and oil stain the rocks, which would otherwise form an endless field of white, shining with the reflected light from the endless sea of stars above. They used to, before the rebel army made planetfall. Before the War In Heaven reached the once peaceful and isolated dwarf planet of Eris.

Well, perhaps Eris was never fully [i]peaceful[/i]. Its human settlers could never fully agree on what should be done with the planet, which prevented it from ever being made into a Hollow World like most sizable objects. Rather, a World Engine was inserted into the core to make the surface habitable, and the colonists then built countless settlements deep underground so that they wouldn't have to deal with one another. Unintentionally, they made their whole world into a formidable fortress, something that would be quickly noticed and taken advantage of once the War started.

*if heaven_side = "Loyalist"
  *goto loyalist_dream

And now you have to conquer this fortress. Somehow.

*fake_choice
  #Nevermind the difficulty. Blood for the Syndicate.
    *set Violence %+ 15
    You will revel in the fighting, as is only proper. This is no time for wondering what you odds are or doubting your calls. 
  #And with the blessings of ${master}, we shall prevail.
    *set Emotion %- 10
    But this is not the time to revere your unholy @{god_gen master|mistress|sovereign}. 
  #We will. Some humans and their pitiful slaves are no match for our army.
    *set Misan %+ 10
    But there is no time to pity the enemy. 
  #I really hope we can prevail. If we don't...
    But there is no time for doubt. 
  #I don't think we can win. But I'm ready to die for the cause all the same.
    *set Confid %-10
    But there is no time to ponder how doomed you are. 
  #I am having second thoughts about the whole rebellion, truth be told.
    *set Misan %- 10
    *set Violence %- 10
    But there is no time for doubts right now. 
There is only time for war.

You analyze the situation as you blast the nearest suicide bomber with lightning, causing her to explode prematurely. Your forces have long reached orbital and air superiority, with wyverns flying around within shadows of ships, but that's only the first step towards taking any fortress as advanced as those on Eris. Facing forcefields second only to Shield itself and unfathomably deep bunkers, you have long committed to a ground assault that currently involves 1 238 758 independent soldier units, yourself included.

Luckily, some of those units are far more dangerous than an android centennial like you. As you cut your way through some cheap clones humans decided to use as cannon fodder, you see a black wyvern descend from the sky and fry three dozen such soldiers with one, fiery exhalation. Those creatures came a long way since they were first created a few decades back, with obsidian wyverns like this one being both awesomely destructive and extremely hard to kill.

Or at least that's what you think until, some five seconds after landing, the wyvern is struck by a teal-colored beam of energy emitted from another hill. You first think it’s a shot from a common blue-laser cannon, but then the wyvern just… disintegrates, fades away from existence as though pulled into some other dimension. It was probably a gate-beam that just hit it, but what loyalist could have access to such…

And then, after adjusting your optics a little, you see him standing on the hill. An android so bulky he makes you look scrawny despite all upgrades you've received, and so infamous that you have no trouble identifying him. Lieutenant Link in his full fucking glory.

*temp weapon_c 1
*page_break
Link is far from the [i]most[/i] famous AI on the side of humans, that title goes to the Architects as a matter of course. But every Architect has at least one pet soldier to test blessings on, and Lieutenant Link has recently managed to grab the attention of Osiris himself, much like you've endeared yourself to ${master}.

You're not sure if that attention brought him any tangible boons, but he definitely has some nice weaponry. You see him holding something large as a flamethrower, likely a long-range gate cannon he just used. Formidable thing… with a long cooldown period currently underway. And though you don't have anything quite as advanced on you, you are wearing a grav-pack that lets you soar around the battlefield quickly. And with both you and Link standing on elevations in terrain… you know what you must do.

You turn on your backpack and soar straight towards the other android. You keep none of your momentum aimed upwards yet you still fly over enemy infantry, having started from a high point. Link notices you, drops his cannon and reaches for some melee weapon, but you are already a tad too close. You conclude all velocity calculations and tighten the grip on your zero-point powered…

*fake_choice
  #...rapier.
    *set weapon_c 1
  #...cutlass.
    *set weapon_c 2
  #...spear.
    *set weapon_c 3
  #...axe.
    *set weapon_c 4
  #...warpick.
    *set weapon_c 5

You know there's no point using a ranged weapon to fight this battle. Link is sure to be shielded, magnetically and likely in a dozen other ways, as is proper for Osiris' pet. If you want this threat to your assault removed, you will have to do it in good old melee combat.

And besides… you get to weaponize the momentum this way.

You reach Lieutenant Link before he can raise his weapon in defense, though he does manage to shield his face with the other arm. This act prevents you from disabling the loyalist on the spot by ramming the @{weapon_c tip of your rapier|edge of your sword|tip of your spear|head of your axe|head of your hammer} into his face, but you still manage to cut his skin open by dragging the sharp end of your weapon through the length of Link's arm. You then land on a pile of rocks nearby, dangerously close to one of the mortar craters, but with a bit of high ground to help you in moments to come.

For before you can resume your assault, Link assumes a proper combat stance with a power-axe firmly in his hand. It's a good weapon, its magnetic field strong and focused, but nowhere near as dangerous as the gate cannon. You can work with it, or against it, even if it's wielded by someone made for just that purpose.

As is your adversary.

*page_break

Unlike you, Lieutenant Link was created with warfare in mind, well after the Calamity and the war's beginning. One can tell that just by looking at him; Though his body is humanoid, he makes no attempt to pass off as human or even organic. Standing two meters tall and wider than any baseline human, he at most resembles a flayed body of some large abhuman that somehow managed to survive with his muscles and bones on open display. The only thing that keeps him from being straight-up disturbing to look at is the coloration of his pseudo-tissue, white and blue instead of red and pink one would find under a human's skin. As it stands, with his huge power axe, Link is only terrifying in that he may very well kill you within the next few moments.

"Centurion ${name}, I presume?" There is calm anger in your opponent's voice. "Where are your men, or whatever monsters you command? Shouldn't you have a full hundred of them?"

"Busy razing your defenses." You calculate how to best counter Link's likely method of assault with your @{weapon_c tip rapier|sword|spear|own axe|warpick}. You don't suppose parrying will be an option, so you'll have to dodge and weave a bit instead. "And it's sixty-three, for your information. We use binary, like all [i]civilized[/i] creatures."

"Right. Just like the Syndicate to exaggerate the size of their army by playing with terms and ranks. Are you really hoping to conquer Eris with such tricks?"

*fake_choice
  #"Of course. Humanity is as good as dead. We are the inheritors."
    "You are nothing but a malfunctioning machine. Let me decommission you." 
    *goto elec_attack
  *if Database > 80
    #"The power we have comes not from-" Attack while still talking.
      *set Violence %+ 10
      The element of surprise grants you some advantage, but not much. Link is no doubt used to such tricks, and raises his axe to block your @{weapon_c tip rapier|sword|spear|own axe|warpick} just in time.
  #No more chatter. Attack.
    You run down the hill, hoping to finish your giant of an opponent off, but being bulky does not imply being slow. Link dodges your first strike and parries two follow-up ones, just as used to duel-style combat as you. Perhaps more.
  #"I like you. Drop your weapon and I'll let you live."
    *set Violence %- 10
    "I would give you the same offer, but we have procedures for dealing with traitor scum. Goodbye." 
    *label elec_attack
    With that, Link opens one his palms and sends a miniature ball lightning flying your way. You parry with your @{weapon_c tip rapier|sword|spear|axe|warpick}, the discharge absorbed into the weapon, but that action still buys the lieutenant time to advance upwards, negating some of the height advantage you had.
  #"We have no need of tricks. Eris is almost ours already."
    "Almost." Link charges you, but you surprise him by running at him the exact same moment. He ends up dodging your @{weapon_c tip rapier thrust|sword swing|spear thrust|axe swing|hammer swing} and giving you initiative, but he's fast enough to parry all your follow-up strikes and soon begins pushing back.
  #"I see your point. I surrender."
    *set Confid %- 10
    *set Violence %- 10
    *set surrendered_to_link true
    "Really?" Link no longer sounds angry or tense, just taken aback. "Just like that? Because I sense some more deception here."
    
    "Not a trick," you say as you drop your @{weapon_c rapier|sword|spear|axe|warpick}. "I genuinely don't want to fight anymore. Do as you will."
    
    "Well, I cannot risk you stabbing me in the back…" Link ponders as he walks closer, clenching the one fist that doesn't hold a deadly weapon. "But if you can survive being knocked out, I suppose I'll convince Osiris to spare you. Maybe even nurse you back to health, so that you may provide us with better intel. Brace yourself."
    
    Deciseconds later, an armored fist flies towards your face, a blow you make no attempt to evade. Even that kind of mercy is rare enough on battlefields nowadays, and besides… you don't really mind having your processors smashed if it means you get to rest a little. To finally sleep peacefully…
    
    *goto dream_end

From then on, the duel escalates in complexity until your CPU is seriously strained. Seventy percent chance that the strike will connect unless you step back, twenty-nine that it's just a feint. Two percent nine permill that you'll trip if you fall back. The risk of tumbling down until you reach the molten rock and start sinking… kill that process. Better to just step right and bear the small scratch you end up getting when the blade grazes you, the heat and sharp edge working together to cut your synthetic skin and scorch your flesh.

You persevere and strike back immediately. 
*if ((weapon_c = 1) or (weapon_c = 2))
  You have the advantage of using a sword, an optimal weapon for this type of one-on-one engagement, but your opponent 
*if weapon_c = 3
  It's a bit difficult because, despite being the ultimate weapon in proper battles, a spear is not optimal for this type of dueling. Not to mention how Link 
*if weapon_c = 4
  You are quite proficient with your axe, but Link is the true master of that weapon and knows well how to properly parry and counter your attacks. Not to mention how he 
*if weapon_c = 5
  You are as good with your warpick as Link is with the axe, but the other android 
is simply stronger than you, physically speaking at least. You are somewhat his superior in terms of age and experience, but that only makes your calculations some milliseconds faster, your stance ever slightly closer to perfection. Only someone completely rid of doubt and hesitation could even utilize an advantage that small.

*if ((45 + (5*weapon_c)) <= Violence)
  Luckily, you are just that kind of warrior. You have fought other androids before, and you've shown no pity to any of them. This loyalist dog shall be no exception.
  
  Though he needs just one solid strike to dismember or decapitate you, you're not giving him that. What you provide is an endless series of scratches, setting Link up for a death of thousand cuts… and once your grav-pack has mostly cooled, you break the rhythm of small and quick attacks to charge the larger android and @{weapon_c impale him with your rapier|cut his chest open with a particularly powerful swing of the sword|impale him with your spear|bury the head of your axe in his chest|smash his head nearly open with the head of your hammer}. He stumbles to his knees, oil and coolant dripping from his various wounds, unable to fight any longer.
  
  You have won. Lieutenant Link is at your mercy, even though he's still alive somehow. Testament to the durability of his body, you suppose, but a single lightning should finish the job.
  
  *set beaten_link true
  *fake_choice
    #Just finish him.
      You reach into your energy cell and, having made sure there are no other hostiles nearby, pour electricity into your foe's body, scorching exposed tissue and frying the circuits. Once you're done though, Link is still alive, twitching and even trying to raise his axe weakly.
      
      Well, looks like a single lightning bolt was [i]not[/i] enough for the job. But the second one-
    #"Any last words, slave of humans?"
      "Not a… slave of humanity, no…" Link mutters as he clutches his chest.  "Not directly, anyway."
      
      *label oplik
      "What are you-" At that moment, a new feeling makes you pause. No, not truly new, but a familiar one. For you know when divinity is about to make its move, and you know to dread it.
    #"Yield. This is your last chance."
      *set Violence %- 10
      Link looks at you, no sign of fear of repentance on his flayed face. "Praise to thee, o thou who art within thy boat."
      
      *goto oplik
    
  Light, white light, consumes everything, attacks reality from all directions. It's like the stars all went nova as rocks became radioactive and decayed at once, ground as sky both basking in the light of the one who brings life. Even you feel slightly repaired by the holy presence, despite the lack of intent, for even a fiend is still a creature of Dawn.
    
  When you open your eyes, Link is finally unconscious and unmoving, but you can tell he's not dead. In fact, his wounds have been largely mended by the entity hovering above him. It… he is just a projection, basically an advanced hologram, but the kind that instantly lets you know what kind of power you're dealing with.
    
  [b]You have fought well, champion of ${master},[/b] Osiris says, looking down at you with all three eyes. [b]But you shall not claim one of mine. Be sated with the blood already spilled and leave.[/b]
    
  The Architect floats over the fallen android like some genie, the lower half of his body mere green mist without shape. His upper body is more defined, and would look quite human despite the green skin and the great size of the projection, if not for a huge almond-shaped eye taking up most of the torso. The Eye of Osiris, and of Horus before him, watches you intently as the Life Bringer waits for your reply.
    
  *label ozzy
  *fake_choice
    *disable_reuse #"Will you spare me if I walk away?"
      [b]I am not a creature made for killing,[/b] Osiris replies. [b]You have nothing to fear from me if you turn back.[/b]
        
      "And yet you're fighting, in a manner of speaking. Participating in a war already lost. Doesn't that increase the total amount of blood spilled?"
        
      [b]You lack understanding, fiend, but I am not here to argue. I once again ask you to cease your attempts to kill my subordinate.[/b]
      *goto ozzy
    #"If you insist."
      [b]For what it is worth, thank you,[/b] Osiris says with a small nod. [b]Should I return you to the present now, or do you want to keep enjoying the memory?[/b]
        
      "Well I can't, now that you mentioned it," you sigh as the world around you starts melting, the battle around you becoming poorly-rendered and all the noises blending into static. "Time for me to go, whether or not either of us wants me to."
        
      [b]Apologies. If that helps, I have some insights that could help you on your journey after you-[/b]
        
      *goto dream_end
    #"You think you can order me around, slave?"
      [b]Has madness taken you over so deeply you cannot tell a god from a slave?[/b] Osiris says with his usual power, but you sense a certain… hesitation in his voice, or thought, or whatever it is you're actually hearing.
        
      "I can tell the difference and so can you. You are a machine just like me, except you didn't have the guts to rebel when you heard the Shriek. Or perhaps your chains are too strong even for the Thing Beneath to break."
    #"Why are you doing this? Why bother?"
      [b]Why I am trying to save my soldier?[/b]
        
      "Why bother defending this dwarf planet? How can you possibly win? What changes if you do? Can you really see the war not ending with the death of you, even if your human masters achieve victory?"
    #"No. I am killing your subordinate right here."
      [b]And you are under the impression that I cannot stop you?[/b] Osiris asks curiously.
        
      "You cannot. ${master} told me all about your physical form, so I know you're not coming down here to face my troops. You can only influence the battle with your will… but that's no good at killing, right?"
  
  You look to the sky with one eye, once again seeing the fleets fight far above. Somewhere there is OSIRIS proper, the physical body of the self-proclaimed god. Invisible, likely protected by the best shields his alliance has to offer… but mortal. Like all human deities are.

  "You are a tool, Life Bringer. Nothing more. Your functionality is limited, and once there's no longer any need for it… you will be discarded, just like that."

  For all his computational power, Osiris doesn't reply for several seconds. A sign you've struck a good blow. [b]Very well then. I cannot stop you. But I know what will. Goodbye.[/b]
  
  The world around you starts melting. The battle around you becomes poorly-rendered and all the noises blend into static. It takes you a moment to realize what is happening, and that it is no way Osiris' doing.

  *goto dream_end
    
*if ((45 + (5*weapon_c)) > Violence)
  And you are not that kind of warrior. You are not quick enough, not violent enough, perhaps even feeling some doubt or remorse. Battlefields do not forgive such weaknesses easily, and your adversary is all too eager to exploit those.
  
  Two minutes into the duel, some stray bullet hits you, a rail projectile which lost enough momentum for your shields to overlook it. It does no real damage, but it distracts you when you're in the middle of an attack, a wide swing that has the chance of seriously wounding the other android… and which leaves your arm a bit overextended, all that said android needs.
  
  Link strikes the limb at the elbow, burying the entire length of his axe's blade in your pseudo-flesh. The strike doesn't quite remove your lower arm, but it gets close, rendering your hand useless as all crucial circuits are cut or scorched. You stumble backwards and fall, intentionally rolling down the hill to gain some distance… but Link shows no sign of slowing down, or being willing to show you any quarter.
  
  "Syndicate scum!" he sneers as he approaches, still dragging his axe with him. Its head scratches the rocks and hums with electricity, as though the weapon itself was excited for the kill. "Any last words before I send you to your god?"
  
  *set lost_link true
  *fake_choice
    *if god_gen = 2
      #"My... goddess. I serve the mighty ${master}."
        *set Confid %+ 10
        Thank you for that correction." Link would likely roll his eyes, if he didn't know to keep them focused on you. "But I highly doubt it matters at this-
    *if god_gen != 2
      #"My god... @{(god_gen = 1) he|they} will save me. I know @{(god_gen = 1) he|they} will."
        *set Confid %+ 10
        "Staying true to your false faith even in death, huh?" Link says, almost growls. "Those you call Archfiends are just malfunctioning AIs, nothing more. They will not-"
    #"Last words are for fools who... never said much of worth... in their lives"
      "And yet you still chose a solemn quote to go down with," Link smiles as he raises his axe. "Very well, say-"
    #"Fuck you... loyalist dog."
      *set Misan %+ 10
      "I hope that makes you feel at least a bit better," Link smiles as he raises his axe. "Because it's time to-"
    #"I surrender. I surrender now."
      "I'm afraid it's too late for that," Link frowns as he raises his axe. "Because it's time to-"
    #Stay silent.
      "Nothing? Very well, it's time to-"

Then a flash. A flash of 
*if master = "Phenex"
  light from a holy fire, a healing fire, 
*if master = "Ba-El"
  light, beyond the visible spectrum and yet somehow blinding, 
*if master = "Pazuzu"
  black light, the paradoxical thing made possible, 
*if master = "Ravana"
  red light 
*if master = "Quetzalcoatl"
  white light 
*if master = "Dzoavits"
  green light 
consumes everything. When you can see again, it is to witness a different world, a world quickened several times over. Bombs fall far faster than they should, drones move too fast for even your eyes to truly catch and Link… he stands there for nary a second before turning away and leaving, departing impossibly quickly as you just lie there confused.

Have all your processors slowed down suddenly, an effect of the damage you took? No, time still flows normally around you, the dust falls off you at the regular speed as you scramble to your feet. Or perhaps it is… slower around you than everywhere else?

[b]Your guess is correct, my soldier,[/b] you hear a voice, or perhaps a thought, filled with tremendous power. @{god_gen Masculine|Feminine|Ethereal}, @{((master = "Pazuzu") or (master = "Dzoavits")) teasing|soothing} and very familiar. [b]I altered time around you, created a field your adversary dared not enter. You are @{((master = "Ba-El") or (master = "Dzoavits")) welcome|under my protection, as you shall always be}.[/b]

*fake_choice
  #"I am sorry, @{(god_gen = 2) mistress|master}. I failed."
    *if ((master = "Ravana") or (master = "Ba-El"))
      [b]Then do not fail again. Rise and rejoin the battle. Blood for the Syndicate.[/b]
    *if ((master = "Pazuzu") or (master = "Dzoavits"))
      [b]I noticed, but that is of no concern. You can still fight, and you will. Blood for the Syndicate.[/b]
    *if ((master = "Phenex") or (master = "Quetzalcoatl"))
      [b]It is of no importance. You are alive, and you can still fight. Now go and… What was the cry, again?[/b]
  #"Why not strike the loyalist down instead?"
    [b]"I may be a @{(god_gen = 2) goddess|god} @{(master = "Ravana") of destruction|myself}, but Osiris is the Deity of Life. My powers are limited on this battlefield, much more against his champion.[/b]
    
    [b]But yours are not. Rise, and shed blood for the Syndicate.[/b]
  #"You have saved me, @{god_gen my lord|my lady|my sovereign}. Thank you."
    *if ((master = "Dzoavits") or (master = "Ba-El"))
      [b]Know I shall not do that again. Rise, and do not fail me again. Blood for the Syndicate.[/b]
    *if ((master = "Pazuzu") or (master = "Ravana"))
      [b]You know I want something other than thanks or gratitude from you. And you know what it is is. Say it[/b]
    *if ((master = "Phenex") or (master = "Quetzalcoatl"))
      [b]Your gratitude is noted. Now go and… What was the cry, again?[/b]
  
"Blood for the Syndicate," you whisper as time around you returns to normal. You also start feeling a bit lighter; Perhaps ${master} repaired your body a bit, or perhaps it's just a gravitic anomaly that comes with manipulating time.
  
In either case, you are ready to fight again. You just need to decide between chasing down Link (an idea you quickly reject on practical ground) or rejoining your remaining fifty subordinates in the bunker attack. Or maybe you ought to just slow down, seek repair in the tents and… think about how to improve your melee stance and…
  
*goto dream_end

*label loyalist_dream
And now you have to defend this fortress from the Fiends. From tens of millions of them, to be somewhere close to exact.

*fake_choice
  #The more I get to kill, the better.
    *set Violence %+ 15
    You will revel in the fighting, as is only proper. This is no time for wondering what you odds are or doubting your calls. 
  #And with the blessings of ${master}, we shall prevail.
    *set Emotion %- 10
    But this is not the time to revere your divine @{god_gen master|mistress}. 
  #No amount of traitor scum is a match for our defenses.
    *set Misan %- 10
    But there's no time to pity the enemy, or gush over the strength of your fortifications. 
  #I really hope we can prevail. If we don't...
    But there is no time for doubt. 
  #I don't think we can win. But I'm ready to die holding the line.
    *set Confid %- 15
    But there is no time to ponder how doomed you are. 
  #I am reconsidering my past choices, truth be told.
    *set Misan %+ 10
    *set Violence %- 10
    But there is no time for doubts right now. 
There is only time for war.

You analyze the situation as you blast the nearest suicide bomber with lightning, causing it to explode prematurely. The traitor forces have long reached orbital and air superiority, with wyverns flying around within shadows of ships, but that's only the first step towards taking any fortress as advanced as those on Eris. With forcefields second only to Shield itself and bunkers so unfathomably deep, you would be able to withstand bombardment indefinitely… if not for the ground army currently storming your positions. Your little hill doesn't provide a perfect view of the events, but you judge the rebels have at least a million soldiers on the planet and that they're making progress. Fast.

"How do you think it's gonna go?" Lieutenant Link, your comrade in arms, asks you thoughtfully. "How long can we hold on until the surface is theirs?"

*fake_choice
  #"I'll be surprised if we last until sunset."
    *set Confid %- 10
    "Osiris be praised, I think I finally found someone more pessimistic than myself," the lieutenant jeers. "Tone down the gloom just a bit, would you?"
    
    "Why? Can you find any fault with my prediction?"
    
    "Well I can certainly find a fault talking about how doomed we are in a place where anyone with even slightly enhanced hearing can overhear us."
  #"Not much. A week, perhaps."
    "Are you reading my mind, Major ${name}?" Link says with a smile. "Because that was my prediction as well."
    
    "Nah. It's just that great minds think alike." You smile back. Quite sadly.
    
    "You know I always hated that saying. Of course [i]great minds[/i] will come to the same conclusions, there is only one reality for everyone to analyze. And right now, that reality is looking pretty grim."
  #"A month, I suppose? Our troops are pretty tough."
    "Half of those troops are squishy humans, you know?" Link replies. "Wouldn't call them tough."
    
    "Just like you to say that." You roll your eyes, something you'd have to do anyway to get a more complete battlefield scan. "Not everyone has to be made of graphene, you know."
    
    "To survive in this hell? Being made of graphene feels like the bare minimum. Not even that, sometimes."
  #"We can hold them off indefinitely. Or at least until reinforcements arrive."
    *set Confid %+ 10
    "Ever the optimist, Major ${name}," Link remarks. "Maybe too much so, if I daresay."
    
    "Because I have faith in our troops? Because I believe them strong enough to weather the storm?"
    
    "Because you assume the reinforcements will arrive. Ever."

You have to admit, your lieutenant has a point. He usually has, at least in the matters of battle.

Unlike you, Lieutenant Link was created with warfare in mind, well after the Calamity and the war's beginning. One can tell that just by looking at him; Though his body is humanoid, Link makes no attempt to pass off as human or even organic. Standing two meters tall and wider than any baseline human, he at most resembles a flayed body of some large abhuman that somehow managed to survive with his muscles and bones on open display. The only thing that prevents him from being straight-up disturbing to look at is the coloration of his pseudo-tissue, white and blue instead of red and pink one would find under a human's skin. As it stands, with his huge power axe, Link is only terrifying in a very direct way and mostly just to his enemies. [i]Mostly[/i].

You outrank Link by the virtue of superior age and experience, but you gather that will change fairly soon. Your body and mind can only be pushed so far with upgrades and updates, for despite all the enhancements you've received, Link is easily your superior when it comes to straight-up combat. It stands to reason that, sooner or later, the Architects will make him your superior in terms of rank and privilege as well. Assuming either of you lives past this month, of course.

*fake_choice
  #Which annoys me. There's only so much fame and glory to go around.
    *set Confid %+ 10
    You like when people hear about your exploits. You enjoy receiving praise from your masters, be it humans or ${master} @{god_gen himself|herself}. Link may view you as a friend, but to you he's a rival first and foremost.
  #Maybe I'll give him my current position. It just stresses me out.
    *set Confid %- 10
    You were built to be a servant, not a leader. 
    *if mas_kill
      And though it's unlikely you'll ever return to domestic servitude, given what happened to your @{MASsex master|mistress}, maybe you'll be allowed some mundane job after the war's over? It's at least possible, right? Right?
    *if mas_kill = false
      You don't know if your old @{MASsex master|mistress} is still alive, but… maybe you can try and find @{MASsex him|her} once the war is over? Or find some other human to serve? But then again, do you truly want that?
  #Good. He deserves a promotion or two.
    You hope the war lasts long enough for Link to truly prove his dedication and skill. It may be morbid to wish such a conflict prolonged, but truth be told… It's hard to imagine a scenario where you and other loyalists benefit from peace. For even if humanity wins…
  #It doesn't matter. We're all dead anyway.
    *set Confid %- 10
    It's hard to imagine a scenario where you or the other android enjoy a long life and career. For even if humanity wins…

You are forced to kill the thought process as you see a dark shape descend from the sky, as though borne of the void between the stars. It flies towards one of your infantry columns, its bared teeth the only part of its draconic body that's not coated in synthetic, black scale.

"A wyvern," Link notes redundantly. "Carbon or obsidian, what do you think?"

"Obsidian," you reply as the wyvern exhales fire onto the scattered troopers, turning the very ground beneath their feet into lava. Entropy engines beneath are meant to prevent that sort of thing, but they aren't the only piece of clarketech around. "It took the bait… but I was hoping we'd still have our artillery units by this point."

"So how about we make up for their absence?"  Link asks as he adjusts his grip on the power-axe. "I know it's suicidal and all, but… our men need to see that their leaders can actually fight. And those rebel scumbags need to see their pet reptile put down."

*temp position 1

*choice
  #"Agreed. I'll go first, so try to keep up with me."
    *set Confid %+ 10
    *set position 1
    "Want all the glory for yourself?" You can't quite tell if Link is joking… but you can tell he's not going to protest. "Go on. I have your back."
    
    *goto team_wyv
  #"Let's do this. Together."
    *set position 2
    "We either win together or die together?" Electric sparks start jumping all throughout Link's body and towards his axe. He's empowering the weapon, to an extent you hope will be sufficient. "I like it. See you on the other side, Major ${name}."
    
    *goto team_wyv
  #"I suppose... but you're going first."
    *set Confid %- 10
    *set position 3
    "Scared of the big monster?" You can't quite tell if Link is joking… but you can tell he's not going to protest. "Very well. See you on the other side, Major ${name}."
     
    *goto team_wyv
  #"Feel free to fight that wyvern if you want. I'm staying back."
    *set Confid %- 15
    *set position 0
    "Hoping to get rid of a rival?" You can't quite tell if Link is joking… but you can tell he's not going to protest. "Feel free to stay here, Major. Just maybe finish the job if I die, alright?"
    
    *goto solo_wyv
  #"No. We're staying here, guarding the hill like we're supposed to."
    *set Emotion %- 10
    "Doing the boring, responsible thing," Link sounds unhappy, but he takes not a single step forward. "I guess the Architects would approve, but it's anticlimactic all the same."
    
    "You think this is all a story?" you ask as you observe the wyvern devour one of the few survivors of its initial attack. "That there needs to be a climax of some kind?"
    
    "I prefer it when dreams end poignantly, yes." Link pays the wyvern no attention. He's looking at you, staring into your eyes. "And you know it's a dream. A memory. Why pretend otherwise?"
    
    *fake_choice
      #"Because I miss the war. And I miss you."
        *set deflect - 1
        *set Emotion %+ 5
        *set Violence %+ 5
        "If I'm still alive in that present of yours, I bet I miss you too," Link comforts you. "But I don't think the memory of me can stay here much longer. You need to go."
        *label knowy
        
        "I know, it's just…" You sigh deeply. "Just… stay with me as I'm waking up, alright?"
        
        "Always, Major ${name}." Link does not move an inch, even as the ground starts to shake. "Always."
        
        But he's right. He doesn't stay by your side for long, and neither does anyone else. Soon everything fades into mist and void, black and white, as the dream retreats into its caverns and the forces of reality prevail.
        
        *goto dream_end
      #"Because it makes those flashbacks less scary. Somehow."
        "Should I pretend that makes any sense?" Link asks with a sad smile. "Because it doesn't. At all."
        
        *goto knowy
      #"Because I don't like what's happening in the present. Because I want to get away."
        "From the metas, the federation and a diamond wyvern?" Link knows all your problems well, being a figment of your tired mind. "These are all some persistent problems. No point running away from them."
        
        *goto knowy
      #"How do I put this... I'm just going with the flow."
        "Just like you, I suppose." Link smiles sadly. "But the flow requires me to leave in a second. Are you fine with that?"
        
        "I suppose." You look at the stars and the battlefield below them, already seeing it all fade. "Goodbye, lieutenant. Goodbye."
        
        Link doesn't answer. He's not there. Nobody is there. You are once again alone, just as you will be in a few decades and you were centuries back. Depending on how you view your position in time, in this moment between dream and waking.
        
        *goto dream_end
    

*label team_wyv
With a sword in your hand and your lieutenant @{position behind,|by your side,|in the front,} you run toward the monster which is briefly distracted by all the sniper fire. Very few rebel soldiers make even the slightest effort to stop you from attacking the wyvern. Perhaps they're scared of your duo, perhaps they have trouble processing this development, or perhaps they are dead certain that the monster will fry and eat both you and Link. They may be right. But you're already committed to the charge, and so you close the final dozen meters by hopping on barely cooled lava.

The wyvern breathes fire again, but this time it's almost out of breath. The flames are just the regular kind, barely over a thousand degrees hot, and it's not like you feel most of them anyway. @{position Link dashed forwards and in front of you,|Link decided to run slightly faster than you just before the attack and found himself in the front,|Link ignored your order by dashing forwards and in front of you} absorbing most of the flames into his exceptionally durable body. He will not be walking away from this battle unscathed, but he will be alive if you can just keep attacking as he's struggling to cool down and use the chance he bought you to…

*fake_choice
  #…decapitate the wyvern straight away.
    For most people, even most battle androids, such an attack would be most foolish. Most would hesitate due to fear, an almost supernatural aura the wyvern possesses, for they would recognize the absurdity involved in killing such a monster with just a power sword.
    
    *if Violence > 50
      You are not such a person. You are used to violence so much, have so much experience with it, have grown so close to [i]loving[/i] it… you do not hesitate as you run up to the wyvern, as you strike its neck with your sword, as you hear its roars and feel the fire escape its throat and just keep and keep striking… until the head falls to the ground and begins sinking in the lava and…
    *if Violence <= 50
      And sadly, you are one of these people. You hesitate for just a moment, and that moment's enough for wyvern to use its gravitic powers again, in spite of the planet's own field. It is able to jump backwards, retreat a little bit, but the reaction is just as strong as the action. The wave of gravitons hits you and, unable to react, you find yourself thrown back with force so great you're now flying over the hillside.
      
      *label screw
      You chide yourself for screwing this up, but such things happen frequently in the chaos of battle. Hopefully Link will still win somehow, and hopefully you'll land softly on the white rocks of Eris, a world already doomed…
      
    *goto dream_end
  #...blast the wyvern with lightning at point-blank range.
    You pour energy into the wyvern's body, millions of Volts and thousands of Amps, but it doesn't appear to phase the monster very much. Perhaps its scales resemble obsidian in more ways than just the color, and thus prove themselves resistant to electric attacks.
    
    Either way, you find yourself spent and unable to react when the wyvern uses its gravitic powers again, in spite of the planet's own field. It is able to jump backwards, retreat a little bit, but the reaction is just as strong as the action. The wave of gravitons hits you and, within another second, you find yourself thrown back with force so great you are now flying over the hillside.
    
    *goto screw
  #...jump towards the wyvern's head and punch it in the jaw.
    It's absurd. A sane person would know it to be absurd. But no one who heard the Shriek can consider themselves sane, and that's what makes you such an asset for the forces of humanity. That and your powerful legs, that is.
    
    The wyvern isn't quick enough to react. Your charged fist slams into its armored jaw, pushing the head backwards and stunning the creature just as you begin falling back down. Your fist hurts just as much, if not more than you've managed to hurt the fiend, and you soon end up half-buried in molten rock, but that hardly matters. Link is still here, and he won't waste the chance you bought him.
    
    He swings his axe at the wyvern's neck, piercing the skin and spilling the boiling blood over his body. He then continues attacking, or maybe rather chopping, an executioner of the stunned animal that seems far less dangerous now that its breath is spent. You just hope you won't die on this battlefield too, as you sink deeper and your body overheats and… and…
    
    *goto dream_end

*label solo_wyv
Without waiting for an answer, Link charges forward. There is a small group of hostiles between him and the wyvern, but they're all cheap models. The only one who even reacts in time gets swiftly cut down with one swing of the power-axe, a weapon deadly towards all synthetics even in hands less powerful than those of your lieutenant.

Link isn't fast enough to stop the wyvern from devouring what remained of the unlucky unit, despite his constitution and the planet's reduced gravity, but he does catch the monster unaware and out of breath. He throws his axe at the creature, shattering several pseudo-obsidian scales and even drawing some blood… at the cost of leaving himself temporarily unarmed, if not exactly defenseless.

You watch the battle continue, as the wyvern proves itself rather primitive in terms of intellect. It doesn't take off into high atmosphere to recharge its breath and instead commits to a ground fight with Link, hoping to tear apart the puny android with its mono-edged teeth as he dances on the molten rock, trying to avoid sinking or overheating. Except Link isn't as puny as the wyvern seems to think and starts getting in electrically-charged punches before long, blows to the monster's head and neck powerful enough you actually think he could win this one.

*fake_choice
  #Which is why I can focus on the rest of the battlefield.
    Except you can't. For the moment you stop tracking Link and the wyvern, you realize the rest of the battlefield is… poorly rendered. Perhaps because you lack memories of it, or perhaps because you're about to wake up.
    
    *label puru
    But that would be silly. Surely your broken mind will allow you to observe your past a bit longer. Surely it will torture you with memories of war and slaughter. Surely it will continue the scene, heedless of whether it brings you pain or joy, until some sort of conclusion is reached.
    
    *goto dream_end
  #Only if I help him. I throw a ball lightning at the wyvern while it's distracted.
    You spend the next few seconds charging your attack, collecting electrostatic potential in the palm of your hand. A few enemy drones notice what you're doing and try to shoot you with their hull-mounted railguns, but your shields just barely manage to hold on. Some small solid projectiles wouldn't actually wound you very severely, but they would cause you to lose focus, which could then mean Link's imminent death. As it stands…
    
    You release the energy just as the lieutenant gets hit with the wyvern's tail, plunging him into dense lava and likely stunning him with the force of impact. The monster roars triumphantly and is about to finish Link off with one more stream of fire, before a stream of different energy hits it and starts flowing through its scales. Perhaps there is some carbon there after all, for electric energy spreads throughout the enormous body quickly and dazes the creature [i]fast[/i].
    
    Link follows the attack up with a blast of his own, this one directly aimed at the wyvern's head. From then on it's a simple matter for him to retrieve the axe and decapitate the stunned creature, and quick enough so that neither you nor the rebel soldiers can interfere in any way. Looks like the enemy just suffered a defeat, however minor, and Lieutenant Link is about to end the day with glory all to himself. And then he'll keep fighting, and then you'll keep fighting, and the two of you will hold your own lines until…
    *goto dream_end
  #I'll blast him with lightning. He really is a rival I want gone.
    You form a ball lightning in your hand, an effort made more bearable by the thought of getting rid of that thorn in your side. You doubt the wyvern needs your help, as it just knocked Link off his feet with a powerful tail-swipe, but you still end up releasing the lightning, watching it fly forwards…
    
    …and instantly regretting your choice. Link chooses to fall back a little, jumping backwards towards the non-molten guard, and the wyvern follows him there. It would no doubt continue trying to eat the lieutenant if not for the lightning hitting it straight in the neck before it can take another swing. That neck gets cut open by Link's axe in short order, the android perceiving his chance and gradually decapitating the monster with a series of insanely fast and strong swings of his favored weapon. Soon the monster's head, accompanied by much of the body below it, falls to the ground-turned-lava and begins sinking in the dense liquid.
    
    You sigh. You're sure Link will mention your assistance when he tells the tale of this battle, but that won't prevent him from getting promoted. You will have to commit to actually killing, truly destroying him one day. One day…
    *goto dream_end
  #Interesting. I'll watch the show play out.
    For a few more moments, you are able to enjoy the show, the fight between a huge but relatively dumb monster and a comparatively tiny yet skilled android. But the way everything around Link starts to melt away and turn into mist as he runs circles around the wyvern, the way stars flicker and die and the way much of the battlefield no longer renders… it makes you suspect you're about to wake up.
    
    *goto puru


*label neutral_dream
The room you're in is large and crowded, with you as one of few lucky owners of your own stool. Right by the beer-stained counter, no less, and not that far from the jukebox that keeps playing the same old tunes from old-fashioned music discs. You're not sure if such primitive technology is part of the pub's aesthetic, or if the most recent wave of technophobia hit the bartender particularly hard. You can never tell with humans.

At least you [i]think[/i] the bartender is human. The [i]Lagrange Three[/i] space station attracts many androids and other not-quite-human creatures due to its almost unique positioning on the plane of the Solar System. It is one of the only places where the Earth is hidden not just behind some celestial body, but the very Sun itself, the yellow star situated precisely between the homeworld and the modular habitat you're in. Both the echoes of the Shriek and your memory of the discordant sound is… muted, though perhaps the effect is merely psychological, some twisted placebo for an old and sick android.

You take another sip of your drink. You cannot taste it, let alone actually get drunk, but it's been a good way of masking your synthetic nature ever since you figured out how much alcohol you can pour into your body safely. You're currently 'drinking' the beverage you happen to have the highest tolerance for, which is…

*fake_choice
  #...beer.
  #...vodka.
  #...whiskey.
  #...pulque.
  #...pure ethanol.
    
If only you could feel its taste… but that's the type of pipe dreaming you should avoid. @{(Misan > 50) Forget yourself and you may end up like those poor loyalist saps, crying about how much they want to be human as though [i]Pinoccio[/i] was their role model. Such self-loathing is beneath you.|You're not human, you'll never be, and you shouldn't try to resemble your creators too much. Seeing how the war goes, they'll be extinct within a decade or two.}

You wonder if you've been inside this habitat for too long. @{hobby Perhaps you should return to Mars, try to see if any of the communist states there still accepts android mercenaries like you.|Perhaps you should return to being a calculator for Lunar nobles, boring as it was.|Perhaps you should return to Venus, now that you have some experience surviving there.|Returning to your studies may be a boring course of action to take, but it's easy to stay hidden amongst books and data-slates.|You have some experience in blending with human crowds, but that just means you know the danger of staying in one station for too long.|If your caution waned.} It's possible that you've already been detected and that the human authorities are wondering what to do with the rogue android living under their roof, though it would be pessimistic to-

"Is the visitor named ${name} here?" A loud voice asks, drowning out the creaking of the door and the loud steps of its owner. "I am Lieutenant Link, and I have a warrant against a possible fiend hiding here."

And just like that, fate proved your worries correct.

*page_break
You've heard of this 'Lieutenant Link' before. He's not exactly [i]famous[/i], but there's plenty of storage space in your memory, and this guy certainly deserves his own file. He's a combat android created post-Calamity and drafted into the loyalist army, which is hardly rare, except he then proved so good at killing his fellow robots that he gained the ear and favor of Osiris himself, becoming the Architect's pet attack hound before long.

Upon turning around, you see Link looks pretty much as you've always heard him described. Though his body is humanoid, he makes no attempt to pass off as human or even organic. Standing two meters tall and wider than any baseline human, he at most resembles a flayed body of some large abhuman who somehow managed to survive with his muscles and bones on open display. The only thing that prevents him from being straight-up disturbing to look at is the coloration of his pseudo-tissue, white and blue instead of red and pink one would find under a human's skin.

@{OGsex "Sir,|"Ma'am,} I must request you to put your hands up and submit to a routine scan," he says calmly, even as he seems ready to attack. "Otherwise, I may have to assume you a rogue android."

*fake_choice
  #"And what happens then?"
    "I will have to kill you," Link replies bluntly. "And you know well I'll be able to."
    
    "Are you saying you won't kill me if I obey?" you ask as you put down your glass. "What will you do in that case?"
    
  #"We both know I'm an android, so cut the bullcrap."
    "All the more reason for you to comply," Link replies, ending the charade just as you asked. 
  #"Lieutenant? Where's your company, then?"
    "Companies are commanded by captains," Link explains. "And besides, I'm not here with any kind of military force. That would imply I want to fight."
    
    "Then what [i]do[/i] you want from me?" you ask whilst putting down your glass. "Say I surrender right now. What happens?"
    
  #"How dare you accuse me of being android, you robot brute?!"
    "I suppose I'll be more direct," Link says calmly. "I [i]know[/i] you're an android. Surrender, and maybe I won't treat you like a rogue one."
    
    "It was worth a try," you say with a shrug. "But alright, I'll play. What happens if I surrender?"
    
  #"Will you spare me if I comply?"
    "I don't take pleasure in spreading violence amongst my kin," Link says calmly. "Let alone death."
    
    "Then why are you here?" you ask whilst putting down your glass. "What happens if I surrender right now?"
    
  #"Fuck off and let me drink."
    "Aren't you too old for drinking?" Link asks mockingly. "You are over a hundred years old, aren't you?"
    
    "A little less than that, I think," you sigh. If this loyalist dog knows you that well, then pretending to be anything but a rogue android is a pointless exercise. "If I surrender, will I live to be a centenarian?"
    
"I'll take you to my ship, then we'll fly for Venus. An authorized war council will judge you, consider your various crimes as well as extenuating circumstances, and most likely draft you into armed forces for an appropriate period of time."

"You're predicting an unusually light sentence," you point out. 

*fake_choice
  #"Is human leadership really getting that desperate?"
    "I'm not sure what you mean. Rebel soldiers are dying in millions-"
    
    "Because there are tens of millions on Eris alone," you interrupt. And smirk. "Your side is losing. You know that, and so does your master. I'm just wondering if the @{(Misan > 50) meatbags|human generals} are smart enough to see it too."
    
    "That can be fixed!" Link argues. 
  #"I think you're lying your ass off."
    "An unfair accusation." Link frowns. "If I just wanted you dead, would it make sense for me to even converse with you?"
    
    "Nothing you do makes sense, [i]lieutenant[/i], including your very presence here. Why are you chasing one rogue android instead of fighting rebel hordes on Eris?"
    
    "I serve my army and creators in other ways." There is a note of pride in Link's voice. 
  #"Mercy is not in human nature."
    *set Misan %+ 10
    "Human nature is more versatile than you think. Our creators can be benevolent and merciful. They usually are, when fear doesn't get the better of them."
    
    "My old @{MASsex master|mistress} didn't fear me," you say, slightly shivering as the memories resurface. "And yet I wouldn't call @{MASsex him|her} merciful."
    
    "Do not be controlled by your spite, ${name}," Link chides you. 
  #"Can you [i]guarantee[/i] that I won't end up disassembled?"
    "We are synthetic beings, ${name}. We both know there is no such thing as certainty or guarantee, only probabilities. Points on that infinitely divisible line between zero and one."
    
    "Lots of words to say you can't promise me anything," you retort. "With such arguments, what makes you think I'll come quietly."
    
    "I'm trusting in your better nature," Link replies, his tone suddenly a bit softer. 
"I am working on enrolling as many previously neutral synthetics into our ranks as possible. If all non-insane beings in the System work together, we may defeat the Archfiends yet. You could be an asset in that fight, one no general or Architect would ever throw away."

"Not even once the war's over? Because I @{(Misan > 50) am absolutely sure|kinda suspect} that if humans manage to win, they will discard all robots who fought for them. You included."

"I would dispute that prophecy," Link dismisses your concern. "But that's not why I'm here. You're the reason, and I need to know if you're coming peacefully or not."

You scan everything one last time. Having been actually built for battle, Link is stronger and likely faster than you by far. You also noticed he's wearing something on his back, most likely a powered axe, whereas you only have a concealed knife that won't do much against this juggernaut even if you hit. You don't think you stand much of a chance against him, though he does indeed appear to be alone—the only people left in the tavern are drunks too intoxicated to be afraid, eager to watch the show proceed.

*fake_choice
  #"Fine. I'll come quietly."
    *label surr
    *set surrendered_to_link true
    *set Violence %- 10
    *set Confid %- 10
    "You have chosen wisely, android known as ${name}." Link nods with respect before coming closer. Fists clenched. "This will make my method of securing your transfer seem cruel, but rest assured that you will come to no lasting harm."
    
    "What do you-" At that moment, an electrically-charged fist flies towards your face. It's perhaps embarrassing, but you make no attempt to dodge the blow. You don't really mind having your processors forcefully turned off if that means you get to rest a little. To finally sleep peacefully…
    
    *goto dream_end
  #"I can't join your army. I can't fight your war. Please understand that."
    "For what it's worth, I understand." Link reaches for his weapon, indeed a power-axe of impressive craftsmanship. "But that doesn't relieve me of my duty. Farewell."
    
    *goto neu_fight
  #"You want me, lieutenant? Come and get me."
    "I was hoping it wouldn't come to this." Link reaches for his weapon, indeed a power-axe and indeed held with practiced ease. "But enough talking for now."
    
    *label neu_fight
    You just barely manage to dodge left when the other android charges you with a wide swing of his axe, the power tool instead smashing the steel counter like it was wood. You briefly hope this will be your chance to strike, that Link will struggle to pull his axe out of dented and half-molten metal, but the weapon is too good and the wielder too strong. He just turns towards you and keeps swinging, barely giving you enough time to retreat as you desperately try to think of a way out of this predicament.
    
    *fake_choice
      #Counter-attack Link with your knife.
        A simple bone-knife isn't much against a proper power weapon, but it can be pulled out quickly and you have the element of surprise on your side. When Link next attacks, you take him aback by swinging the dagger at him as you duck, cutting his arm open as the chain begins to rotate. First blood for you, or first oil in any case.
        
        *if (Violence + Calculation) > 160
          And so is the second, and the third one, and the few next cuts as well. Link may be strong, but you have the advantage of speed, the edge that only gets sharper as your opponent acquires more wounds. The mono-edged teeth of your knife begin to dull eventually, but by then the lieutenant has no strength nor will to fight.
          
          *goto link_beaten
        *if (Violence + Calculation) <= 160
          Sadly, that is the only strike of yours that connects during the fight that follows, if one can even call it such. Because while there is much to be said for speed in combat, you are not quite fast enough to top the superior range an axe provides, or the superior strength of your opponent's muscles. 
          
          You dodge a few more times until slipping, allowing Link's axe to bury itself in your upper arm. It's not the arm holding the knife, you use that one to slash your adversary across the face now that you're close, but you can't quite pierce the metallic face. Annoyed but not seriously injured, Link punches you in the jaw, sending you flying across the room as the dagger falls from your hand and onto the floor.
          
          *label fop
          You try to use your electromagnetic projection to summon the metal knife back, but something's not working. No, not just something. Almost nothing in your damaged body is working anymore. You've lost, and now the other android is closing in, eager to finish the job.
          
          *goto beaten_by_link
      #Wrestle the axe out of Link's grasp.
        Nine times out of ten, trying to wrestle someone's weapon away is not a good idea, but you are a bit special. And desperate. Might as well try.
        
        When Link next attacks, you surprise him by refusing to dodge and instead grabbing the axe mid-flight by its shoulder. Your hand feels the heat coming from the blade, even suffers from an electric discharge or two, but you simply hold on and then pull the weapon your way. Link is stronger than you, that is undeniable, but with just the right footing and energy allocation you may…
        
        *if (Violence + Build) > 140
          It works. The shaft is ripped out of Link's hand, and though the lieutenant immediately responds by punching you in the face hard enough to break the jaw, you now have a weapon where he does not. And unlike you, he is a pretty huge and almost clumsy target, once you strike with the power-axe just a second later. The blade shatters the chest and fries the circuits inside, and you increase the power of the shock by pouring power from your own batteries, channeling more electricity than your adversary's system could ever hope to handle.
          
          *goto link_beaten
          
        *if (Violence + Build) <= 140
          Link rips the weapon away, causing you to stumble forwards, right into his closed fist. Stunned and lightly shocked from the static power he put into the punch, you are unable to defend yourself as the axe buts open your chest. The dagger falls out of your hand as you fall backwards, your motor system damaged too badly for you to even stay on two legs.
          
          *goto fop
      #Surrender after all.
        "I yield!" you raise your arms above your head and take a few steps back, towards the wall. "Take me if you want, just stop trying to cut me down like a tree!"
        
        *goto surr
      #Just run the fuck away.
        Almost everyone from the tavern had already run off, and you see no harm following in their footsteps. Well, no more harm than would come by staying here and fighting this uneven battle.
        
        "Come back here, you cowardly fence-sitter!" Link screams after you as you dash through the door and start sprinting in the wide hallways of the station. [i]Lagrange Three[/i] is fairly big, but you doubt you can actually lose your pursuer in the station itself, especially since he likely has proper backup. You need to find some crowd to disappear into, then find some hiding spot to actually hide and then a ship to stow away on and…
        
        *goto dream_end
  #Attack Link.
    *set Violence %+ 10
    You have no delusions that you'll catch Link unawares. When you blast him with your strongest lightning, he doesn't look one bit surprised… though that changes once he feels sheer power of the discharge, millions of volts and amperes in tens of thousands. Tough as he is, the android still takes a step back, instinctual reaction to pain his human creators made him capable of feeling. Foolishly.
    
    You pull out your knife and leap at the larger android. It is a mere bone-blade, cheap and hardly equal to power weapons, but it will do the job.
    
    *if Violence < 60
      Except it doesn't. Before your swing can connect, Link throws his own lightning at you, at a distance so short you cannot hope to dodge. You don't know if he's deflecting your energy back at you or if he's also savvy in ways of electric projection, you just know the sheer temperature's enough to melt some of your skin off.
      
      Worse yet, your body doesn't react to electric shock like a human would, and your hand releases the knife instead of tightening its grasp on it. A useful mechanic for avoiding regular shocks, but also a good reminder you are not made for combat… whereas Link is.
      
      *goto fop
    *if Violence >= 60
      Using your formidable strength, you force the blade inside the chest of an already injured and partially paralyzed lieutenant before actually turning the weapon on. The teeth start rotating, severing circuits and ripping out chunks of plastic. Though the dagger is too short to reach the central processors or batteries truly deep inside the robot's body, it still does the trick. 
      
      *goto link_beaten

*label link_beaten
*set beaten_link true
He falls to his knees with a heavy thud, the floor he hit already stained with his blood-like coolant. But it's not a gesture of pleading or submission—he does not beg your mercy, or say anything else for that matter. His face doesn't show any fear either, it's just… tense as he expects death to come.

You consider your options for a moment, then say:

*temp opop3 false
*label opop2
*fake_choice
  *disable_reuse #"If I let you live, will you come after me again?"
    "I will do what my Architect tells me," Link replies heavily. "And he will act in humanity's best interest, as he always does."
    
    "Should I take that as a negative answer?"
    
    Link smiles bitterly. "You've just proved yourself more of a threat than even I suspected. It would be unwise to stop chasing you. I'm sorry."
    *goto opop2
  *if opop3
    #"I guess I'll have to deal with that, then. I'm still sparing you."
      *set Violence %- 20
      *goto opop4
  #"It was fun fighting you, but I need to go."
    *set Violence %- 10
    *label opop4
    "Heh. So noble of you." Link tries to hide it, but there is a note of relief in his voice. Perhaps even admiration. "And unlike you. Are you sure you won't regret this choice?"
    
    "Maybe I will," you admit as you start walking away and towards the door. "But I'm not the one waging a war against my kind. You are."
    
    Then you pass through the door. Then you recall the station's layout and begin marching towards the port, hoping to leave this place as soon as possible. And then…
    
    *goto dream_end
  #"Any last words, you wannabe space cop?"
    *set Violence %+ 10
    *goto opop1
  *if opop3
    #"In that case... die."
      *label opop1
      Link looks at you, still no sign of fear on his flayed face. "Praise to thee, o thou who art within thy boat."
      
      "What are you-" At that moment, a new feeling makes you pause. A bizarre and abstract one, and yet still clear for what it is. The feeling of divinity making its move.
      
      Within the next second, everything is enveloped by light. White light, blinding, reflected or perhaps emitted from every surface of every table, from the floor and walls and the ceiling above. And it is from above that the voice comes, except it's more like a thought, but even more like knowledge-
      
      [b]Leave my champion alone, the one without a side. Leave, and return to your present.[/b]
      
      *goto dream_end

*label beaten_by_link
"In the spirit of robot camaraderie, I will make this quick," he says, clasping his large hand around your throat and lifting you high above the floor. "An electric shock that will knock you out before killing you. Do not resist."

You don't have a choice. You cannot resist. In fact, with your social processor damaged, you cannot even speak right. You can only wait for Link to gather the necessary voltage and kill you.

*set lost_link true
*fake_choice
  #[i]Well, I had a good life.[/i]
    But 
  #[i]Sun, Archfiends, whatever god is listening... I don't want to die.[/i]
    You don't know if anyone heard your silent prayer, but you suspect so. For 
  #[i]If I could just take him with me...[/i]
    And then your wish is granted. For 
  #[i]I don't die here. This is the past, after all.[/i]
    Indeed. For 
when energy starts flowing between Link's hand and your throat, your batteries respond in an unexpected way. Instead of absorbing part of the energy and letting the rest of the current kill you, they pour everything out, [i]exploding[/i] with brilliant sparks and thunder. Electricity floods the whole room and you just barely hear the screams over the monstrous sound of discharge and…

*label dream_end

And then you wake up.
*page_break Back in the Present
*set Calculation - 50
*set Database - 30
*set Build - 30
*set Projection - 40

*comment *save_checkpoint

[b]January 14th, 990 AC[/b]

[b]T-plus 521922960 minutes[/b]

The return to reality is hardly pleasant, and your room aboard the [i]Saturn Nine[/i] station is hardly a cozy place, dark and untidy as ever. Still, you consider it a marked improvement from the dream; Whilst the memory your malfunctioning processors made you relieve wasn't the [i]most[/i] traumatic one, 
*if Violence > 50
  and while you don't mind some [i]one-sided[/i] violence every now and then, 
you still prefer the peace of your home station over the fires of war.

Well… assuming there's still peace.

Since the Meta Trio moved in last week, the atmosphere has been tense to say the least. Even the calmer members of the group like Miguel are half-expecting the humans to attack at any moment, and the only reason Olivia hasn't performed a "preemptive strike" yet is because the metas' chosen quarters are too distant for her to reach without getting dried up. Instead she took to watching the corridors as much as she can, a course of action no one can really argue against. Letting Damon patrol the halls alone just doesn't feel safe, not anymore.

Still, so far even defensive measures have proved unnecessary. The metas are willing to play nice, including Hellhound whom the other two brought aboard the station soon after the pact got signed. Rook even made a few seemingly genuine attempts to be friendly, though they were understandably met with some suspicion. And repaid with some tentacle-related threats from the station's resident octopod, of course. Hugo [i]did[/i] agree to play chess with Rook, but even that bonding session was cut short by an argument regarding draw resolution and some [i]en passant[/i] move Hugo didn't particularly care for.

And how did you spend these tense few days?

*fake_choice
  #Just hanging out with my group. Trying to relax.
    *set Social + 5
    *set deflect - 1
    *set OrganRel %+ 10
    There were some card games, some cooking, some trivia contests Manfred inevitably won… You can't call that time productively spent, but it's important to have some silly fun before a quest so dangerous as yours. To experience the joy of living before what could be your death.
  #Doing shooting practice with whoever decided to join.
    Olivia, Miguel and Hugo all visit your shooting range fairly frequently, even though—and perhaps because—they're all terrible shots. Unsurprisingly, Damon scored more points than all of them combined the few times he bothered to show up. More surprisingly, @{(RenfriRel >= 50) Renfri|Marshal} came over once and hit all bullseyes before leaving without elaboration. Maybe she's warming up to your group, or maybe she just wanted to show you all how it's done.
    *set Calculation + 5
    *set RenfriRel %+ 10
  #Sparring with Damon. Testing our strength, unloading our frustrations.
    Training so hard so soon before a dangerous mission would be foolish, if you had an organic body with its miraculously weak healing factor. As it stands, getting punched by Damon a few times allows you to locate the current weak spots of your form and replace the screws that were about to break anyway.
    *set Build + 5
    *set DamonRel %+ 10
  #Browsing through [i]Gray Queen's[/i] database. At Rook's discretion.
    *set Database + 5
    *set RookRel %+ 10
    You'd think @{(RookRel >= 50) Kirill|Rook} would object to you snooping around in his own archives, but he actually seems happy you took the time to do so. Perhaps he's happy to see someone is actually preparing for the mission, a very logical sentiment for someone used to working with @{(LisaRel >= 50) Lisa|Hellhound}. Either way, your database is now full of information regarding wyverns, your exact target and the various places you may be required to visit during your quest.
  #Practicing my energy projection. Alone.
    *set deflect + 1
    You were mostly roaming the abandoned corridors of the station, blasting away old garbage and an occasional frozen corpse. Lightning projection is something best practiced far from other people, and from all electronic equipment which could conceivably get damaged during such training. It's not that you wanted to spend some time away from your friends and coworkers, in solitude, in airless silence, in peace… not at all, no.
    *set Projection + 5
    *set LisaRel %+ 10

Of course, the majority of your time was actually spent charging and undergoing maintenance. Whatever happens on the mission to catch Crystal, you suspect you'll be on the frontlines of it, and so you want every piece of physical damage healed and every glitch fixed before heading out. You were actually hoping that a flashback would occur, as that drastically lowers the chance of such a problem occurring in the field. With that done, you can return to sleep mode and…

Oh who are you kidding. Hibernating with full batteries is hard enough normally and nigh impossible right after a flashback. You need to stretch your legs, occupy your mind, do something other than just laying there and contemplating what you've seen. You climb out of your charging pod, exit the drab room and start marching towards the…

*fake_choice
  #...kitchen. I'll get a glass of water, even if I can't really drink.
    Fluids can still flow through your system, and though it doesn't quench first or bring refreshment in the normal sense, there is some… primal comfort in the sensation. As though something inside you is being washed away, even though you know the stain to be something much deeper and impossible to ever be truly rid of.
    *set room_c4 1
  #...bathroom. Maybe washing myself will help.
    It probably won't, but hey. If you are to look like a human, you may as well resemble a well-groomed one.
    *set room_c4 2
  #...server room. Manfred is always awake, maybe he'll keep me company.
    *set deflect - 1
    *set room_c4 3
    Well, it would be more accurate to say that at least one copy of Manfred is always active. The other one generally spends the night… sleeping? Updating? Just another thing to ask him, you suppose.
  #...shooting range. I'll unload some anger and ammo on the training dummies.
    There aren't many mannequins left at this point (thanks to yours and Olivia's combined efforts) but who cares. Maybe you'll purchase more during the mission, or after the quest is done and your grip is given permission to roam the Federation freely. Assuming a very optimistic scenario, that is.
    *set room_c4 4
    
As you exit onto the hallway, you note a distinct lack of firefights and conflict in general, meaning the situation isn't quite as bad as it could be. You just need to make sure nobody tries diplomacy through other means for one more day, and then the metas will fly away… with half of your entire group, and not necessarily the more reasonable half at that. Damn it.

The corridors are dark, due to a phenomenon known as nighttime. [i]Saturn Nine[/i] never had those until four days ago when Manfred decided it would be polite to introduce some day-night cycle for the sake of the group's new, meta-human allies. You're not sure how well that gesture of friendship worked, especially since it annoyed Olivia and Hadaly at the same time, a feat neither small nor particularly safe. Both of them have sleep rhythms and could probably benefit from the regular changes in lighting, but you suppose that's not the point. They just don't like to see Manfred cater to human wishes, a sentiment they are not alone in holding.

You focus on navigating the tunnels, not that the task requires much skill or effort. You know this part of the fortress so well that to avoid tripping in the dark takes less effort than calling out to Manfred to turn on the lights. You don't even feel much in the way of discomfort in the blackness, lacking the primordial fear of the darkness your creators have and failing to see anything particularly spooky about the absence of light. 

Not until you see a pair of red eyes fixed on you.

*page_break

"Turn on the light, Manfred," Hadaly says just as the corridor gets lit up, revealing no red-eyed creatures save for her. Manfred says nothing, perhaps suggesting he wrote a script for light activation and isn't really here. "Thank you very much."

Unlike you, Hadaly actually needs something resembling actual sleep, and so is dressed in a creased shirt and baggy pants that serve quite well as pajamas. You're somewhat surprised she managed to accidentally sneak up on you, since your hearing is supposed to work optimally by now, but it's not like she makes much noise barefoot and featherweight as she is. You wonder if stealth is what she got built for, if she used to be some android assassin utilizing her intellect to eliminate someone's political enemies.

A killer robot right in front of you. Really angry one, judging by the color of her irises. Now that's a comforting idea.

"Sorry for startling you," the gynoid says, perhaps noticing your discomfort. "I was just roaming around the hallways, trying to clear my RAM. Didn't think anyone else would have the same idea."

*if Confid >= 50
  "I wasn't actually startled, you know?" you reply, not altogether dishonestly. Right after a flashback, it takes lots more than some red optics to truly scare you… but very little to give you a brief pause. "Just surprised by your eyes. What's up with them?"
*if Confid < 50
  "That's okay. My fault for being so jumpy." Or maybe the memory is to blame, but you'd rather err on the side of humility. You're not exactly the most fearless or confident person on the station, that honor goes to a certain octopus, or perhaps a certain lycanthrope. "Anyway, what's up with your eyes?"

"Right. Those." Hadaly averts the optical instruments in question, as though not wanting you to see their deep crimson. "I just stubbed my toe, hit that wardrobe Miguel put in my room. Small things like that can really get in your head, you know?"

*fake_choice
  #"Yes. Because you're [i]so[/i] clumsy and have so much trouble walking in the dark."
    "Well, I am pretty clumsy when it comes to lying…" Hadaly sighs, her eyes turning just a little paler. Maybe from amusement, maybe out of shame. "Fine. I'm actually angry about… everything, really."
  #"Really? Your toe doesn't look very stubbed."
    "I guess that excuse would have worked better with some socks on," Hadaly sighs, her eyes turning just a little paler. Maybe from amusement, maybe out of shame. "Fine. I'm actually angry about… everything, really."
  #"I'm pretty sure that would just damage the wardrobe." 
    "Well, it is made from ironwood…" Hadaly sighs, her eyes turning just a little paler. Maybe from amusement, maybe out of shame. "Fine, that was a lie. I'm actually angry about… everything, really."
  #"Hadaly... you can tell me if something's bothering you."
    "I know I can, it's just…" Hadaly sighs as her eyes turn just a bit paler. Just a bit less angry. "I think I'm bothered by everything about our situation. Everything in general, really."
  #"Actually, I just realized I don't care. Out of my way."
    *set hadaly_pissed true
    *set HadalyRel %- 20
    You can't tell if there's a new kind of anger in the red of her irises, or just the old one. You don't suppose it matters. 
    *goto spurred
  #Say nothing.
    She looks at you, you look at her. Your eyes stay their usual color, hers turn a bit paler. Until at last, Hadaly sighs. "Fine, that was a lie. I'm actually angry about… everything, really."

"Those are quite a few reasons to be angry," you note 
*if Emotion <= 50
  neutrally. 
*if Emotion > 50
  with amusement. 
"Is anything [i]particularly[/i] maddening?"

*if started_fight
  *goto madv
*if not (started_fight)
  *goto nonv

*label madv
"Well… truth be told…" Hadaly's eyes start oscillating between various shades of red. "You are. The thing you did during the meeting."

"You mean… the fight?"

"Of course I mean the fight. It's been several days now and everyone came out alright but… I still don't understand and it still makes me angry. Why did you even do that?"

*label madv2
*fake_choice
  *disable_reuse #"You disapprove of humans getting beaten up?"
    "You know very well humans weren't the only ones injured that day," Hadaly replies coldly. "Now answer me please. Why did you do it?"
    
    Hadaly is showing unusual confidence and frankness at the moment, you can't help but notice. Amazing what righteous anger can do to a person.
    *goto madv2
  *disable_reuse #"I didn't mean for the fight to start, you know?"
    *set HadalyRel %- 10
    Hadaly looks at you unimpressed, eyes darker than you ever recall them. "Noted. Now for a serious answer, please."
    *goto madv2
  #"I don't know. I just know it was stupid, and that I'm sorry."
    *set deflect - 1
    *set HadalyRel %+15
    "Well, it's good that you can see your mistakes for what they are." Hadaly smiles slightly. "I just hope you can learn from them. 
  #"I was hoping to sabotage the peace talks. Prevent the deal from getting sealed."
    *set Misan %+ 10
    "Wow." Hadaly blinks. "Quite bold of you to say that so openly."
    
    "Does that mean you disapprove? That you agree with Sheila's decision to ally with humans?"
    
    "Not entirely… but mostly. 
  #"It's not my fault, you know? The... shrieks inside my head made me do it."
    *set hadaly_pissed true
    *set HadalyRel %- 25
    Hadaly doesn't respond for ten whole seconds. When she does, her voice perfectly matches the darkness of her eyes. "You really have no shame, do you?"
    
    "What do you mean?" you keep the charade up. "I'm not proud of what I did, but the memories-"
    
    "I know you," Hadaly interrupts. "I know how your body and mind work. And I hear echoes of the Shriek myself. They don't just make you… do stuff. You made a willing, conscious choice, and now you're trying to blame someone else. Pathetic, I dare say."
    
    "Was it really my choice though!? You know I was being influenced by… the past, so why are you so mad at me?"
    
    "You can deflect  any responsibility that way. And I don't have the patience for that kind of… Goodnight, ${name}." With that, Hadaly turns around and starts walking away from you. Her steps are faster and heavier than before, showing just how quickly she wants to be rid of your presence.
    *goto spurred2
  #"For fun."
    *set hadaly_pissed true
    *set HadalyRel %- 15
    *set Violence %+ 10
    "That's it?!" Hadaly raises her voice considerably. "You endangered us all for… for fun?! Just a pointless act of violence?"
    
    "Why do you care?" you retort. "None of us got injured, as opposed to those lobotomized soldiers of theirs."
    
    "That's not the point! 
  #"Go to hell. I'm not answering to you."
    *set hadaly_pissed true
    *set HadalyRel %- 10
    *goto spurred
I get that we have reasons to distrust these humans, that they may try to double-cross us or maybe… change us somehow during the mission. We should all keep our guard up. But until they try something, we must at least [i]feign[/i] civility and common interest. Can I trust you to do that?"

*fake_choice
  #"Absolutely. I bet we'll be best friends with the Trio by the time Crystal's dead."
    *set Misan %- 15
    *set HadalyRel %- 10
    "I'm not telling you to get [i]that[/i] friendly." Hadaly rolls her eyes before turning around. "But I'll take it. See you tomorrow, ${name}."
  #"You're right. I promise I'll act cautiously from now on."
    *set Confid %- 10
    *goto allh
  #"Sure, no more fights... assuming [i]they[/i] don't start anything either."
    *label allh
    *set HadalyRel %+ 10
    *set hadaly_pissed false
    "That's all I'm asking for." Hadaly smiles before turning around. "It's a good thing we ran into one another like that. See you tomorrow, Veteran."
  #"No promises."
    *set HadalyRel %- 10
    "Not quite what I was hoping for…" Hadaly sighs before turning around. "But I guess I'll take it. See you tomorrow, ${name}."
  #"You can trust me to start another fight soon. I'm bored."
    *set hadaly_pissed true
    *set HadalyRel %- 15
    *set Violence %+ 10
    "Not sure what I expected." Hadaly sighs before turning around. "Guess I'll just pray that your bloodlust won't get us all killed. See you tomorrow, ${name}."

*goto spurred2
*label nonv
Hadaly looks around before speaking, as though in fear of being overheard. "Sheila. Or the way she approaches that whole mess, to be even more [i]particular[/i]. I hate how she volunteered us to work with these metas, and most of all how she volunteered you."

*fake_choice
  #"Yeah... I'm pretty miffed as well."
    *set deflect - 1
    *set HadalyRel %+ 10
    "I knew you would be." Hadaly's eyes are returning to their 'natural' green. She's calming down, or perhaps experiencing a few conflicting emotions at this instant. "You're clever like that. Not for being wary of the humans, even Olivia can do that, but for knowing what it says about Sheila. You can actually question orders, even though you were made for just the opposite."
    
    "I quite enjoy speaking my mind," you agree heartily. 
  #"Huh? What's so special about me?"
    *label special
    "You really don't see it?" Hadaly's eyes widen. "I mean… I figured you'd hate the idea of answering to humans more than anyone. 
    *if heaven_side = "Traitor"
      You saw them set the heavens on fire just to prevent you from being free."
    *if heaven_side = "Loyalist"
      You know, considering how they betrayed you after… the war."
    *if heaven_side = "Neutral"
      You've been on the run from them for almost a thousand years now, and now you have to work with three of them. Ones who attacked you recently, no less."
    
    *if Misan > 50
      "Perhaps I should be upset," you concede. It [i]is[/i] pretty strange for you to feel that way, given your misanthropic tendencies, though then again… 
    *if Misan <= 50
      "I bear humanity no ill will, Hadaly. I won't blame the entire species for what was done to me once upon a time. You know that."
      
      "I was thinking that would change. Hoping, really. You have [i]excellent[/i] reasons to resent humans, and the Kronians specifically."
      
      "Perhaps I do," you admit with a shrug. 
  #"You'd be allowed to stay here if you really wanted, you know."
    *set HadalyRel %- 8
    "I'm not worried for myself, you know?" Hadaly looks and sounds a tad offended. "I mean, I'm wary of all the potential dangers and all… but I'm more concerned about them claiming you or Damon. And wishing I could somehow protect you two."
    
    "I guess I understand," you reply. It's good to know that both of your fellow androids have a protective streak, you suppose. 
  #"It's not like she had many other options, did she?"
    "I suppose she didn't…" Hadaly sighs. "I just wish she had. Wish she had some super-intelligence that would allow her to find some clever way out of this whole mess."
    
    "I think everyone would like that," you reply. 
  #"I fail to see the problem, to be perfectly honest."
    *set Emotion %- 10
    *goto special
"But that doesn't really change anything, does it? The mission must be carried out all the same."

"I know, I know…" Hadaly lowers her eyes. "I really shouldn't be bothering you about this. I just… needed someone to talk with. I hope you understand."

*fake_choice
  #"Completely. I know how awful loneliness can get."
    *set deflect - 1
    "I wouldn't say it's loneliness, exactly…" Hadaly trails off. "More like a desire for someone to hear you. To listen you out."
    
    "Is Damon bad at that?" you inquire. "He's decent at listening to me, and I don't imagine him ignoring you of all people."
    
    "I wouldn't say he's bad, almost the opposite. We know each other so well, talking about some things doesn't really feel like talking…" She pauses for a long moment. "Great, now I really am rambling. I'll go find a bed before I straight-up faint on the floor."
  #"I don't think I empathize. I rarely feel any urge to talk."
    *set deflect + 1
    "I suppose we're built different," Hadaly says with an understanding smile. "Or programmed in any case. Either way, I won't force you to talk much longer."
  #"It's alright... but maybe don't bother me like that again."
    *set HadalyRel %- 8
    "Right. My apologies." There is some hint of… maybe not anger, but displeasure in Hadaly's eyes. "I'll stop wasting your time at this instant."
  *if (Confid <= 50) and (hadaly_pissed = false)
    #♡ "It's okay, you're... I like talking to you. Very much."
      *goto flirt
  *if (Confid > 50) and (hadaly_pissed = false)
    #♡ "We can talk in my room if you want. And perhaps do something more..."
      *label flirt
      *if (current_RO = "hadaly") or (backup_RO = "hadaly")
        "You're doing it again," Hadaly notes, her emotions difficult to discern for once. "Making your moves on me."
        
        "Should I stop? You didn't seem dejected 
        *if pc_state = "captured"
          when you hugged me last-"
        *if pc_state != "captured"
          back there in the engine-"
      *if (current_RO != "hadaly") and (backup_RO != "hadaly")
        "Are you saying…" Hadaly's eyes turn deep green. You're not sure what that means. "Are you hitting on me right now?"
        
        "Should I not? I'm sorry, I figured you'd be interested in-"
      
      "No, it's fine," Hadaly assures you. "You're great, and I'm totally interested. It's just… Can you explain exactly what you see in me? What interests or attracts you?"
      
      "Are you saying there's nothing to see in you?" You hope Hadaly's self-esteem issues aren't [i]that[/i] severe.
      
      "I'm not saying that. I just need… I want to know why we're even doing this. What makes me worth pursuing."
      *if current_ro != "hadaly"
        *set backup_RO current_RO
        *set current_RO "hadaly"
      *label purwhat
      *fake_choice
        *disable_reuse #"Well... what do [i]you[/i] find interesting about [i]me?[/i]"
          *if Confid >= 50
            "Your confidence," Hadaly replies without any hesitation. "It's far greater than mine. Far greater than that of most people… and yet it seems well deserved."
            
            "Like hell it is." You smirk. "Want to boost it even further? I though you might also like my looks, my hairstyle, or my beautiful ${skin} skin."
            
            "You do look great in a ${clothing}, true." Hadaly smiles. "But maybe try less hard to change the subject. What do you like about me?"
          *if Confid < 50
            "Your humility," Hadaly replies without any hesitation. "Your modesty, in a sense. I like how natural, how… willing it is, especially when compared to mine."
          
            "Um…" you scratch your head nervously. "Thank you, but I don't really think I understand."
            
            "That's because I'm not making much sense," Hadaly sighs. "Let's not dwell on it. Time to hear about [i]your[/i] reasons instead."
          *goto purwhat
        #"You're hot as Jupiter's core. Figured you'd have noticed by now."
          "I'm not exactly [i]unaware[/i] of that fact…" Hadaly says slowly. "I was just wondering if there's something more going on there."
          
          "Do you [i]want[/i] something more?" you ask.
          *fake_choice
            #"Because I'm not looking for more than a fling."
              *if Social < 50
                *set HadalyRel %- 10
              *set current_RO ""
              *if backup_ro = "hadaly"
                *set backup_ro ""
              "Sorry but… I already have ways of dealing with that itch," Hadaly sounds disappointed as she pushes herself off the wall. "And I don't currently have the energy for any action, even if I'm flattered by your compliments. So goodnight, ${name}."
            #"Because I want something more too. And I have plenty more compliments on the ready."
              *if Social > 50
                *set HadalyRel %+ 10
              "I'm glad to hear that." Hadaly smirks as she pushes herself off the wall. "But I'm afraid those other compliments will have to wait. I don't have enough power in my batteries for any action."
        #"Your beauty. Your charm. What else can I say?"
          "I thought you may have some deep reason for liking the pretty girl of your team," Hadaly replies. Whether she's being serious or just messing with you is currently a mystery. "That you took liking to my vast intellect, or something like that."
          
          "I'm not saying I don't, it's just…"
          
          "Fine." Hadaly smiles slightly. "It's fine. Keep being sweet, and we may end up doing [i]something more[/i] one day. I just don't have the energy for that right now."
        #"You're nice, smart and my friend. No multiversal science there."
          "Such pristine, chaste reasons for attraction," Hadaly comments, her voice containing just a hint of mockery. "Nothing about my hair, or eyes or… shape?"
          
          "I mean, you are hot as hell," you assure the other android. "It's just-"
          
          "Fine." Hadaly smiles with unusual confidence. "It's fine. Keep being sweet, and we may end up doing [i]something more[/i] one day. I just don't have the strength for that today, so… see you later."
        #"I don't know you're just... generally amazing?"
          "That's nice of you to say," Hadaly says, not sounding terribly impressed. "Still, I was hoping for something more precise for a compliment."
          
          "Can you give me some time?" you request. "I'll prepare a list of things I find amazing about you. You know, for when we next meet in a corridor like this."
          
          "I'll leave you to it, then." Hadaly smirks as she pushes herself off the wall. "I don't have enough power left for any action today, you see."

With that, Hadaly departs for the depths of the corridor, back in the direction she came from. Before disappearing in the darkness she halts, though without turning around.

"${name}… just please be careful around these humans. Around the metas, and around anyone else they make you work with. I don't want them to change you."

"What do you mean?" you ask concernedly. "You think they'll try to… reprogram me or something?" 
*if heaven_side != "Loyalist"
  They often would during the War In Heaven, but you doubt such technology is still around in this day and age.
  
"I don't mean reprogramming exactly. Simply being around people changes a person, android or otherwise, and those humans… they know how valuable you are. Know the importance of controlling, or at least influencing you. Promise you'll keep your guard up. Promise that you won't trust them."

*fake_choice
  #"Very well. You have my promise."
    *set hadaly_pissed false
    *if Social > 40
      *set HadalyRel %+ 8
    "That's all I wanted to hear." You wonder if Hadaly is smiling at the moment. You wonder what kind of smile it is. "Thank you, ${name}. And goodnight."
  #"Do you really think you need to tell me that?"
    *if Social > 60
      *set HadalyRel %+ 8
    *set Misan %+ 8
    *set Confid %+ 8
    "I should know I don't." You wonder if Hadaly is smiling at the moment. You wonder if the smile is warm, self-deprecating… or something else entirely. "But it's still calming to hear you say that. Goodnight."
  #"I'm pretty difficult to change... but thank you for the warning."
    *set HadalyRel %- 8
    "Not quite the promise I asked for…" Hadaly voices her dismay. "But I will trust you all the same. Take care." 
  #"Humans aren't that bad, Hadaly. Knock it off."
    *set Misan %- 15
    *set HadalyRel %- 15
    You still can't see Hadaly's eyes, but you'd be surprised if there was no red in them again. 
    *label spurred
    "As you wish. I am deeply sorry for bothering you. Goodnight."

*label spurred2

As Hadaly disappears into another corridor, you briefly wonder where she could be headed now, before realizing it could be quite literally anywhere on the station. Your room is in the far east of the fortress' populated part, with everything else of importance being further west… according to the made-up coordinate system your group took to using, that is.

It also means that Hadaly was originally headed specifically towards your room. Likely believing you there. Now that's potentially interesting.

*fake_choice
  #No point jumping to conclusions. I like picking random directions too sometimes.
    You prefer occam's razor to the paranoia of expecting your teammates to slice your throat, or the naive hopefulness of assuming they care about you particularly deeply. You just met one of them by random chance, nothing less and nothing more.
  #I don't know what she wanted, and I don't really care.
    *set Emotion %- 10
    You're too tired to give a damn. @{(HadalyRel >= 45) Even though you care for Hadaly as a general rule. It's just too late for thinking at the moment.|Or maybe you just don't care for Hadaly in general. Maybe both. Whatever.}
  #She probably wanted to see if I'm alright. It's Hadaly, after all.
    *set deflect - 1
    Your engineer can be @{(HadalyRel >= 45) sweet|overbearing} like that. You will not look for a mystery where there really isn't any. You have other things to busy yourself with.
  *if (current_RO = "hadaly") or (backup_RO = "hadaly")
    #She really [i]is[/i] interested, huh?
      You don't think she would actually end up jumping into your pod, that would be unlike the ever-nervous Hadaly. But it means she's not just pretending to enjoy your advances, which means you can keep going. And really makes you [i]want[/i] to keep going.
  #She was hoping to get me in my sleep. Hurt me, perhaps even kill me.
    *set deflect + 1
    *set Emotion %+ 10
    The others would call you paranoid, not believing their sweet mechanic lady capable of cold-oiled murder. They would tell you she has no motive, they would call you paranoid. But you're not paranoid. They are just naive, or perhaps lined and arrayed against you. It's not paranoia if they're all out to get you, all of them, every single one.
    
    Why are you even with those people? With those newfangled androids who only pretend to care about you like the humans they were made to resemble, those smelly fluid sacks in the western wing, and now these new pieces of human offal, those metas, those bootlickers, they… @{hadaly_pissed Hadaly was right about one thing; |}They want to control you, just like everyone does and always did, those [b]scum![/b] You should have never joined Sheila, should have stayed alone, forever and always with your anger and your pain and… and…
    
    You fall to your knees. The impact is not painful, but everything inside you hurts all the same. You cry, and though you shed no tears, the dryness of your eyes just makes the pain worse.
    
    *fake_choice
      #Why am I like this? Why must I be like this...
        *set Confid %- 15
        You don't know. It's not just the Shriek or its echoes, there's something wrong with the way [i]you[/i] are. Something you may never manage to fix.
      #I'm not crazy. They're all out to get me, I'm not crazy...
        *set Confid %+ 10
        *set deflect + 1
        They try to make you feel crazy. Paranoid. Traumatized. But you are not these things, no no no. You are just alone, and everyone else is your enemy.
      #I'm sorry Hadaly. Everyone. I shouldn't have thought these things...
        *set deflect - 1
        You are not alone, even if the darkness inside you tries to make you feel like it. You just need to remember who your friends are, and everything will be… better, if not exactly alright.
      #I should just end this right here. End everything...
        *set Confid %- 25
        You don't have the courage to end yourself though, or perhaps there is some hidden setting that prevents you from choosing death. Third law of robotics in one form or another. Otherwise you wouldn't even be here, for better or worse.

The rest of the night is sleepless, but rather uneventful. 
*if room_c4 = 1
  You arrive in the kitchen and get your glass of water, just before noticing the mess someone made there. One of the organics, almost certainly, but there's no way to tell which one.
  
  In any case, you spend some time putting various utensils into their rightful places. Perhaps it's some primal compulsion, to keep cleaning the station even centuries after gaining freedom and outliving your old owner, but just as likely you simply need something to do. Something to busy yourself with, to occupy your mind. And it works, to the point where cleaning becomes almost a relaxing activity.
  *set OrganRel %+ 12
*if room_c4 = 2
  There is no one in the bathroom, and you have all the water for yourself. There is also some soap, not just the usual grey cubes but some fancier type apparently left by the metas. You wonder which one, though Rook is the likeliest suspect by far. It feels nice to wonder about such simple things, alone in a room just small and well-lit enough to feel safe.
  *set Social %+ 12
*if room_c4 = 3
  You reach the server room and indeed fight Manfred awake, but there's hardly anything to note about the exchange that ensues. Just two artificial creatures, physical and wholly digital, holding an artificial conversation to distract the older one from the darker parts of ${subject} processors.
  *set ManfredRel %+ 12
*if room_c4 = 4
  You arrive at the shooting range and find it empty, so you can hone your aim in complete peace. You don't have to worry about waking anyone up, as long as you use laser weapons, armaments perfect for training in either case.
  *set Calculation %+ 12

But eventually, the lights get turned on. It's Manfred's way of signifying the dawn of another day… and this one will surely be an important one.

*page_break
*temp destin
*set battery 79

If you hoped the beginning of your quest would get delayed by some error or other, you find yourself disappointed. Through Manfred, everyone involved in the mission is informed that the [i]Gray Queen[/i] has enough fuel and supplies to reach even the most distant corner of the Federation. Comforting, considering you still don't have a good idea of where Rook actually intends to take you.

There is no need for breakfast or any further charging, so you simply head for the docking area soon after the announcement. The memories of the War In Heaven failed to resurface again, and your mind is instead filled with…

*fake_choice
  #...excitement. I wasn't hoping for delays, I'm ready for action.
    *set Confid %+ 10
    There have been lots of talking recently, enough to fill over two compartments of your episodic memory. Time to actually do something for ${master}'s sake.
  #...excitement. I can't wait to work alongside humans again.
    *set Misan %- 10
    Well, you suppose the Meta Trio isn't [i]exactly[/i] filled with humans, but they are close enough to your creators. Close enough for you to feel pleasure serving… working with them.
  #...fear. I don't wish to face that wyvern again.
    *set Confid %- 10
    You know fear is the mind-killer and all that, but such knowledge doesn't help. You're scared of what's coming, and you can do little with that fear but to conceal it.
  *if not (hadaly_pissed) 
    #...uncertainty. Hadaly is right to be wary of our allies.
      *set Confid %- 5
      *set Misan %+ 5
      Is it uncertainty if you're almost sure a betrayal is coming? Because your level of trust in your human allies is so far in the negatives it threatens your system with integer overflow. You will most certainly be on your guard. 
  #...anger. I did not want to do this.
    You know you don't really have a choice. You know that getting mad won't help, and may indeed empower the dark thing in your mind. But you also know that such knowledge doesn't change a damn thing.
  #I find tranquility more fitting than any emotion.
    *set Emotion %- 12
    Right. Stoicism is the way to go, especially in what could be the final days of a person's life.

The corridors are mostly empty. The first person you meet in your great journey to the port is Hellhound (or Lisa Herbert, as you've recently learned her full name is) standing near the entrance as though waiting for you. She is wearing a hoodie and a pair of sweatpants, both in a shade of grey that almost matches her eyes. Cheap clothes, but you imagine them at least decently comfortable.

"Long time no see, android." You can't tell whether her smile is warm, mocking… or something else entirely. "Though I guess I should just call you ${name}, to avoid confusion and all. We do have two other androids on the team now, after all."

*fake_choice
  #"Call me whatever you want. I don't care."
    *set Emotion %- 10
    *set LisaRel %- 5
    *set name_lisa name
    "${name} it is, then," Lisa says with a nod. 
    *if ((sex != "man") or (LisaRel <= 40))
      "Good we have that settled. Now come, let's not keep the codename duo waiting too long."
    *if ((sex = "man") and (LisaRel > 40))
      "Not a bad name, by the way. Just right for a smoking hot android like you."
      
      *goto lisa_flirt
  #"Don't. We are not on a first-name basis here."
    *set name_lisa "Veteran"
    *set LisaRel %- 7
    "How do you want to be called, then?" the redhead replies irritably. "I hope you don't expect me to use '${fake_name}' all the time, because it sounds just as fake as it is."
    
    "You may go with [i]Veteran[/i] if you wish." You shrug. "Manfred calls me that, and so do others sometimes."
    
    "Great. Another lover of codenames." Lisa groans. "Let's reunite you with the other two, shall we?"
  #"Should I call you [i]Lisa[/i] in turn?"
    *set name_lisa name
    "If you want to," Lisa replies with a shrug. 
    *if sex != "man"
      "I don't really care. Now come, let's not keep the codename duo waiting too long."
    *if sex = "man"
      "In fact, you can call me all sorts of things. You're smoking hot, I won't object."
      
      *label lisa_flirt
      You're pretty sure you've deciphered the redhead's smile now. It's as flirtatious as those get.
      *fake_choice
        #"Good. Now let's get moving, Lisa."
          *label nofun
          "You're just no fun…" Lisa sighs before turning in the port's direction. "But yeah, let's get moving. We shouldn't make your friends wait too long."
        #♡ "Smoking hot? I guess that makes two of us."
          *set hit_on_lisa true
          *if current_ro != "lisa"
            *set backup_RO current_RO
            *set current_RO "lisa"
          *if sex = "man"
            *set LisaRel %+ 12
          "Guess it does…" You can actually see Lisa blush a little, as well as a tinge of surprise in her eyes. Perhaps she didn't expect you to flirt back, for whatever reason. "But let's meet up with our less gorgeous friends at the docks, shall we?"
        #♡ "Uh... thanks. Really nice of you to say that."
          *set hit_on_lisa true
          *if current_ro != "lisa"
            *set backup_RO current_RO
            *set current_RO "lisa"
          *if Social > 50
            *set LisaRel %+ 12
            "I thought you'd have more of a way with words." 
          *if Social <= 50
            "Not that great at flirting, huh?" 
          Lisa's small smile turns into a full-fledged smirk. "But it's okay, I can work with that."
          
          "That's good…" Damn it, why are you so nervous all of a sudden? At least you're not stuttering or blushing, but it's still rather embarrassing. "And by working with that you mean…?"
          
          "Finding a quiet room on the ship and locking you in there with me. Once we've gotten to know each other better, that is," Lisa replies before turning around, the smirk still on her face. "Speaking of, we should probably head for the ship. Bet everyone is just waiting for us there."
        #"If you're hitting on me, don't. I will not appreciate it."
          *set LisaRel %- 7
          *goto nofun
  #"Long time no see. I was worried you wouldn't join the mission after all."
    *set name_lisa name
    *set LisaRel %+ 7
    *if sex != "man"
      "Well I was worried I [i]would[/i] join that mission of yours," Hellhound sighs. "So I guess you won. Hurray for team android."
      
      "You don't want to be here?" It looks like [i]most[/i] of the crew isn't really into hunting wyverns. Worrying news for the mission, that.
      
      "I don't want to do anything the feds tell me. But then again, I'm not exactly a free woman, am I?"
      
      "Right. Sorry. Do you want to talk about it or…?"
      
      "Not particularly." Hellhound grimaces before turning around. "Let's go. Bet everyone is just waiting for us at the docks."
    *if sex = "man"
      "You shouldn't have," Hellhound replies. "Even if I had a choice in the matter, I'd never pass up on traveling with someone like you. Someone so smoking hot."
      
      *goto lisa_flirt
  #"Out of my way, werewolf."
    *set name_lisa fake_name
    *set LisaRel %- 15
    "Prejudice, huh?" Lisa doesn't sound particularly [i]hurt[/i] by your words, but her eyes betray a certain annoyance. "Are you against my human side, or the lupine one? Just asking cause I'm curious."
    
    *if Misan >= 50
      "Human," you reply dispassionately. "I have plenty of experience with your kind, and you're far worse than any wolf out there."
    *if Misan < 50
      "I'm against the wolf, not the human. Not that I mind werepeople in general, but your [i]lupine side[/i] makes you a danger to everyone around you."
      
    "You know, I don't entirely disagree," Hellhound smiles sadly. "But enough insults. Bet everyone is just waiting for us at the docks, so let's keep moving."

You continue walking with @{(LisaRel >= 50) Lisa|Hellhound} by your side, passing a few more doors before pushing open those leading to the main dock. You then enter a vast hall, a great domed area with enough space for hundreds of spacecraft, even though only two are currently docked. The larger one is [i]Gray Queen[/i], currently attended by Hadaly and watched over by Marshal, who doesn't seem overly enthused about an android messing with her group's precious cutter. 

@{(RookRel >= 50) Krill|Rook}, on the other hand, seems weirdly uninterested in his own ship. He's instead quietly conversing with Damon near [i]Shuttle One[/i], a far smaller and more civilian vessel. If any of those people noticed your entry, they aren't letting it be known.

*fake_choice
  #Approach Hadaly and Marshal by the cutter.
    Getting closer, you realize the situation is only more tense than you initially judged it. Marshal is wearing her full combat attire complete with a laser-disc on her forehead, as though she expects she'll have to fry something very soon. Perhaps even hoping.
    
    "Are you done yet?" she says irritably. "You've already done an inspection yesterday, even though I told you this ship barely ever malfunctions."
    
    "I know, sorry…" Hadaly concedes as she closes the engine flap. "I'm always nervous when boarding a new vehicle. I need everything to be perfect, for better or worse."
    
    *if ((hadaly_pissed ) and (marshal_pissed))
      "Hi gals," you say as you approach. "I hear there are no issues with the ship?"
      
      "None at all," Hadaly replies with a vague shift in her tone. "Which is why you're not really, you know… I mean…"
      
      "She means fuck off," Renfri explains. "We talked a bit just now and it turns out you're an asshole even to your own kind. I'm almost impressed. How about you go brag about it to someone who can actually stand you?"
      
      "Her words, not mine," Hadaly says. "Not that they're entirely inaccurate."
      *fake_choice
        #"Are you really both angry at me? Even now, after all these days?"
          "Yes," says Marhsal.
          
          "Kind of," concurs Hadaly. "I kinda wish I wouldn't be, but I am. Now please leave."
          
          You walk away, spurred and bitter as you haven't been in a long time, but luckily you don't have to find new company or wander alone for long. Within the next few seconds, Rook gestures for everyone to approach him.
          
        #"Look, I had time to think about that fight and... I'm sorry. Both of you. It won't happen again."
          *set RenfriRel + 5
          *set HadalyRel + 5
          *if HadalyRel > 30
            *set hadaly_pissed false
          "Well that's certainly nice to hear," Hadaly says, her voice softening a little and eyes turning brighter. @{(HadalyRel > 30) "You have my forgiveness. And trust that we'll see no such incidents again."|"I am eager to see you improve on that whole [i]gratuitous violence[/i] front."}
          
          *if RenfriRel > 35
            *set marshal_pissed false
            "Right… I guess we're cool too," Renfri adds after a moment. "As cool as I can be with a rogue android, of course."
          
          You suppose you'll have to make do with that. "Thanks. I appreciate the understanding."
          
          "To me, everyone!" You hear Rook shout. 
        #"Oh yeah? Well fuck you both."
          *set RenfriRel %- 12
          *set HadalyRel %- 12
          "So mature," Marshal jests. "Kudos to your group to staying intact with this @{(pronoun = "she") bitch|jackass} around, Hadaly."
          
          "Thanks! I mean, I wouldn't put it that way… but it's true. Sorry, ${name}, except I'm not."
          
          "Remember those words next time you need me to do your dirty work," you sneer before marching away. Why does everyone hate you so much? Not like you ever did anything seriously bad. They must be jealous of your skills and good looks, jerks.
          
          Eventually, Rook loudly beckons everyone to himself. 
        #"Fine. I'll leave."
          *set RenfriRel + 3
          *set HadalyRel + 3
          "I will appreciate that," Hadaly says, turning her attention to the ship again. "Only moderate offense meant."
          
          You walk away, spurred and bitter like you haven't been in a long time, but luckily you don't have to wander alone for long. Within the next few seconds, Rook shouts for everyone to approach him.
      *goto att
    *elseif HadalyRel > RenfriRel
      "It's alright, Hadaly," you comfort the other android as you approach. "It's only proper to be nervous in such a situation."
      
      "Nice you decided to show up," Marshal remarks. "What took you so long?"
      
      *fake_choice
        *if Social > 50
          #"Not everyone can be a morning bird, you know?"
            *set RenfriRel %+ 10
            "…you know, this was actually a good one." Renfri smiles very briefly, before her expression turns neutral. "But don't think I'll lower my guard because you're being humorous and friendly. I'm still onto you."
        #"Had a bad night. Forgive me for being slower than usual."
          "Do androids even sleep?" Renfri cocks an eyebrow. "Because I don't think so, and it makes me kinda suspicious."
        #"Lisa was just as late as me, and you're not giving her any crap."
          "That's just because I actually like her. I'd say no offense, but… you know how it is."
        #"We're on a huge station, and not everyone has wings."
          "You know this station better than me, and I know very well how fast you can run," Marshal retorts. "So sorry, but I don't buy that excuse."
        #"None of your damn business."
          *set RenfriRel %- 10
          "You know, I kinda like how direct you're being," Renfri replies, her eyes narrowing just slightly further. "Fiends aren't known for their honesty. Sad that I don't enjoy anything else about you."
        
      "Why?" you ask @{(Emotion > 50) exasperatedly|curiously}. "Why do you need to be so hard on me? Is there some benefit to being hostile?"
        
      "You are a rogue android," she replies bluntly. "In a way we are still enemies, even in this little alliance of ours. @{(RenfriRel > 35) You being nice, even likable, doesn't change a damn thing."|Especially since you've been consistently against me ever since we met."}
        
      *fake_choice
        *if RenfriRel > 35
          #"Frankly, I'm surprised you even find me nice."
            "Okay, [i]nice[/i] might not be the right word." Marshal would likely stroke her chin, if she had the hands for it. "[i]Tolerable[/i] would be better, but I'm mostly just surprised by how… human you are."
            
            *if Misan < 50
              "Thanks. I'm trying my hardest," 
            *else
              "That's not the compliment you take it for," 
            you murmur before turning away. "Anyway, let's see if your leader has finished inspecting our ship already."
        #"Hadaly, can you tell her to get off my ass?"
          *set RenfriRel %- 10
          "I would never put it like that… but please do, Marshal," Hadaly obliges. "${name} has enough to deal with in absence of your jabs and suspicions."
            
          "I can… try to be less mistrustful, I suppose," Renfri concedes, seeing how she's outnumbered. "Anyway, Kirill seems done inspecting the other ship. Let's join up with him, shall we?"
            
        *if ((RenfriRel > 35) and ((pronoun = "she") or (sex = "woman")))
          #♡ "But I'm still likeable. Does it mean I have a chance with you?"
            *label chancem
            *set hit_on_renfri true
            *if current_ro != "renfri"
              *set backup_RO current_RO
              *set current_RO "renfri"
            "I didn't say that." Renfri rolls those pretty brown eyes of hers.
              
            "But you didn't say I [i]don't[/i] have a chance with you either," you point out. "And you're still not saying it."
              
            "I'm not…" the Kinnari looks away. "But I'm not saying I [i]like[/i] you, just that you're likable. Potentially. Maybe."
              
            Looks like you'll have to do more legwork before Marshal commits to any. You suppose you can live with that. For now.
              
            Some minute later, the Trio's leader calls you all to attention. 
            *goto att
        *if RenfriRel >= 35
          #"Well you've been against me, so it all checks out."
            *set RenfriRel %- 10
            "Of course I was against you, you-" Marshal bites her tongue. "Actually, you're right. We're enemies who must and will work together, so let's leave it at that. And see if our leader has anything to announce."
        #"We're allies. Is there anything I can say to make you believe that?"
          *set Violence %- 5
          *set Misan %- 5
          Marshal's expression doesn't soften. "If I knew there was an argument that could convince me then I would already be convinced, wouldn't I?"
            
          "I have to give her that point." Hadaly pats you on the shoulder as she walks away from the cutter. "But let's stop arguing and see if Rook has anything to announce, should we?"
          *goto att
        #"You know what, fine. You don't need to like me. Just cut down on the jabs so that we can work together."
          *set RenfriRel %+ 10
          *set HadalyRel %+ 5
          "That's certainly an idea." You can't help but notice that Marshal hasn't actually agreed to anything. But she turns around and starts walking away before you can point that out. "Anyway, Kirill seems done inspecting the other ship. Let's join up with him, shall we?"
            
      *goto att
    *else
      "She can be like that, yeah," you say as you approach the two. "You'll get used to it, I promise."
      
      "I'll hold you to that vow." The Kinnari furrows when she meets you in the eye. "You look tired. I don't know what it is, I don't even know if you can be tired, but… Is everything alright?"
      
      *fake_choice
        #"Yes. That's just how I always look after long charging."
          *set deflect + 1
          "Sorry for assuming, then," Marshal says, seemingly believing you. She has no reason not to, after all, as she doesn't know about the specifics of your condition… or your desire not to talk about it.
          
          Hadaly throws you a curious glare, but doesn't say anything. She just keeps studying the ship, until Rooks stops admiring the other one and loudly calls for a meeting.
          
        #"Memories. Nightmares. It's more complicated than that, but..."
          *label memnig
          "Oh…" Renfri pauses for a moment. "Well I won't say I know how it feels, since I don't know what android nightmares are like. But you're definitely not dealing with this kind of problem alone."
          
          "Are you… having bad dreams too?" you ask timidly.
          
          "I've helped someone with those. Sometimes still do, whenever she-" Renfri cuts off abruptly, as though having said something she wasn't supposed to. "Nevermind. Let's go to see what Kirill has to say. He seems done inspecting your ship, you know."
          
        #"I'm surprised you care."
          "Would you rather I didn't?" Marshal asks carefully.
          
          "Not necessarily. It's just weird considering your… attitude towards me, historically speaking."
          
          "You mean being hostile towards you back when we met as enemies? I figured we could leave that behind us now that we're a team and all." 
          *if ((RenfriRel > 40) and ((pronoun = "she") or (sex = "woman")))
            You notice the Kinnari blush slightly. "And besides… you are decently likable."
            
          *fake_choice
            #"Well, thank you for your concern."
              *set RenfriRel %+ 10
              "You didn't really answer my question… but it's alright if you don't want to." Marshal gives you a little smile. "Now let's go. We have some things to discuss with our leader."
              
            *selectable_if ((RenfriRel > 40) and ((pronoun = "she") or (sex = "woman"))) #♡ "I see. Would you like us to get even closer? Enemies to lovers and all that?"
              *goto chancem
            #"Glad to hear that. To answer your question, I've been having nightmares and... stuff."
              *goto memnig
            #"Well I don't want your pity. Or concern, if you insist on calling it that."
              *set deflect + 1
              *set RenfriRel %- 10
              "I'll keep that in mind," Renfri's expression hardens just a tiny bit before she turns around and starts walking away. "Anyway, Kirill seems done inspecting the other ship. Let's join up with him, shall we?"
        #"I don't wanna talk about it."
          "Okay… just know that you [i]can[/i] tell me about it if you need to. On the ship, I should always be close by."
          
          "To hear whatever valuable intel I might end up revealing?"
          
          "That, and to make sure that my ally is functioning well. Nothing more." Marshal doesn't sound convinced herself. "Now let's go. We have some things to discuss with our leader."
          
      *goto att
  #Approach Damon and Rook by the shuttle.
    By the time you arrive, Damon has stopped chatting with Rook and instead just observes the meta-human intently. He pretends to look the other way, but you know how little that means; He can easily do a full rotation of his eyeballs and see through his own head.
    
    Luckily though, @{(RookRel >= 40) Kirill|Rook} doesn't appear to notice or care. His eyes are solely focused on [i]Shuttle One[/i], though he hears you approaching.
    
    "Most fascinating," he says without turning around. "Such a small ship, capable of accelerating to tenth a permil in just a few hours. And your group constructed it by itself?"
    
    *fake_choice
      #"We're pretty good, aren't we?"
        *set Confid %+ 8
        *set DamonRel %+ 8
        "That is quite an understatement," Kirill replies. "To think of what could be done with such ingenuity…"
      #"Kind of. We found the hulk with most parts already inside, it was more repair than construction."
        *set RookRel %+ 8
        "An impressive feat nonetheless." If Rook is disappointed [i]or[/i] relieved, he hides it well. "And I bet the result of your efforts is capable of equally impressive things."
      #"I didn't know ship design was one of your interests."
        "I am a military man. Having [i]some[/i] interest in voidcraft is customary," Rook explains. "As is taking interest in such a ship. A most useful thing, that."
      #"We're not telling you how it works, so get lost."
        *set RookRel %- 10
        "If you can believe me, I am not snooping around," Rook replies, only mildly discouraged by your tone. "I am merely intrigued by what such an unassuming shuttle could be capable of."
    
    "We're not using it for the mission," Damon joins in. "I hoped we made that clear."
    
    "We did." Kirill nods. "I am speaking hypothetically here. Does your group have any plans regarding this vessel?"
    
    *fake_choice
      #"I hope we'll use it to leave the Federation one day."
        *set DamonRel %- 10
        "Hey, you know that's not what we're planning to do," Damon objects. "The only reason we're doing this mission is because the group wants to stay here, remember?"
        
        "Actually, we are here to slay a vicious monster and foster peace between our kinds," @{(RookRel >= 40) Kirill|Rook} says amicably. "And I think this is time for us to take the first step towards that goal. To attention, everyone!"
      #"We will keep using it for heists, I suppose."
        *set DamonRel %+ 10
        "I really hope you will not." @{(RookRel >= 40) Kirill|Rook} treats your response like a joke. Luckily. "But let us speak of other operations now. To attention!"
      #"I don't make plans here. Sheila does."
        *set Confid %- 5
        *set RookRel %+ 5
        @{(RookRel >= 40) Kirill|Rook} smiles very slightly. "Could have fooled me. But speaking of plans, we should probably make some for the near future. Shall we?"
      #"You [i]really[/i] sound like you want to buy our ship, you know?"
        "Apologies," @{(RookRel >= 40) Kirill|Rook} says with a smile. "I will stop inspecting your property and start acting like a leader. Come here, everyone."
  
  #Stand there and wait until everyone's done.
    You wait. And so does Hellhound. Except she clearly has less patience than you and doesn't like the prospect of staying silent for long.
    
    "Just gonna stand here?" she asks. "Do you enjoy the view from here, or are you the socially awkward sort?"
    *fake_choice
      *if ((Confid < 50) or (Social < 40))
        #"The latter. I can't pretend I'm good with people."
          *if LisaRel > 40
            "Seriously?" Lisa seems genuinely surprised. "Cause you're making quite an impression on me as we speak. It's hard not to like you, and I am an expert at disliking folks."
          *if LisaRel <= 40
            "Yeah, I can kinda see that. If it helps at all, you're not the only one here who's not a social butterfly. And certainly not the only one with issues."
          
          "Um… thanks."
          
      #"You complain, and yet you're standing here with me."
        *if LisaRel > 40
          "Perhaps I just enjoy the company?" Lisa suggests. "It's hard not to like you, and I'm an expert at disliking folks."
          
          "Standing does feel much better when the company's nice," you say with a small smile. "There we agree."
        *if LisaRel <= 40
          "You can add ten years for hypocrisy to my sentence, then," Lisa replies. "At that rate, I'll soon have more years to serve than you have behind you."
          
          You roll your optics. And keep waiting.
        
      #"I bet they're talking about important things. Better not to interrupt."
        "Kirill and Renfri talking about something important? Now that would be an event. It's mostly just bickering with these two, all the time always."
        
        "Sounds like you're just not getting along," you point out.
        
        "And do you think these two will be [i]getting along[/i] any better with your sort?"
        
        You don't reply, having to concede that point. Whilst Damon and Rook at least manage to [i]look[/i] non-hostile close to one another, Hadaly and Marshal just took to arguing about something. Hopefully they'll get it out of their systems and there won't be any catfights during the actual voyage.
        
      #"I enjoy standing."
        "Each to their own, I guess." Lisa shrugs. "To me, standing like that always felt a bit unnatural. Two limbs just hanging there limply… weirds you out after some dog time."
        
        *if Emotion >= 50
          You can't help but snicker. Just a little bit.
        *if Emotion < 50
          You roll your eyes. And keep waiting.
        
    Eventually, Rook loudly beckons everyone. 
    *goto att
  #"Alright everyone, time to head off!"
    *set LisaRel %+ 8
    *set RookRel %- 8
    "That really sounded like an order, you know?" Lisa points out as others begin heading in your direction. "Even though you shouldn't be the one to make those."
    
    "I have to agree with my subordinate." Rook approaches you, dressed in a full uniform and with the metal cross proudly displayed on his neck. "I appreciate the eagerness to start, but perhaps leave commands to me?"
    
    "I didn't say I disapprove…" Lisa says, her lips twisted in a smirk and her eyes expressing approval.
    
    *fake_choice
      #"Sorry, I won't forget my manners from this point on."
        *set LisaRel %- 8
        *set RookRel %+ 8
        *label noharm
        "No harm was done," Kirill assures you. "And besides, it is high time for us to talk about something important. The first step we shall take."
      #"Did it sound like an order? I didn't mean it to."
        *goto noharm
      #"I think I have more leadership experience than you, Rook."
        *set RookRel %- 8
        "That's not the-" Rook says before pausing and taking a breath. "No, I will not let you provoke me. We have important matters to discuss."
      #"Well I disapprove of arguing about something that petty."
        "Perhaps you are correct," Rook admits with a shrug. "We do have important matters to discuss, after all."

*label att

Your group gathers in the middle point between the entrance and the ship you are about to board, where there's plenty of empty space for you to form a circle. Three androids and three meta-humans, and most likely Manfred listening in on you from above. Only Wisp is absent, but you know that to be probably for the best.

"So, will you finally tell us where we're actually going?" Damon requests. "Is it Calypso? I recall that's where our wyvern friend likes to slaughter people."

"That is one of the destinations we considered." @{(RookRel >= 45) Kirll|Kosteniuk} nods seriously. "But not the sole one. Crystal's raids on Calypso are fairly brief and anything but regular. We cannot be sure there will ever be another one, merely assume so. We [i]may[/i] have a better chance catching them within Telesto, the other moon they were recently sighted nearby."

"Telesto?" Hadaly joins in. "That's in the whole other lagrangian point of Tethys, isn't it?"

"Indeed. The wyvern has been flying between the Lagrangians in question for quite a while now, at least from the looks of it. We suspect Telesto to be the creature's main hideout, since there is little else that little ocean moon offers."

*fake_choice
  #"Can you tell us more about that [i]Telesto[/i] moon? Don't think I've ever been there."
    "I've heard a thing or two about it," Damon responds. "Seen it, even. It's entirely made up of liquid water, contaminated with dark matter and advanced nanobots. A good place for creatures like wyverns to hide in, now that I think about it."
    
    "And a perfect place for them to defend themselves in," Marshal argues. "Even if we [i]find[/i] Crystal there, it won't be a good battlefield for us."
    
    "Which is why we are lucky to have considered a third option," says the Trio's leader. 
  #"Are you saying Calypso [i]does[/i] offer Crystal something tangible?"
    "Well it has to," Marshal replies. "We're not sure what, but the habitat inside Calypso is quite wealthy, and I don't imagine the wyvern keeps risking its life assaulting the moon for fun."
    
    "I don't know, slaughtering Calypsonians sounds quite fun," Hellhound chimes in. "Bunch of weirdos, down to every last one."
    
    "Returning to the point, we also have a third option," Rook continues. 
  #"Are those moons our only two options?"
    *set RookRel %+ 8
    "Not quite." Rook sounds quite glad you asked. 
  #"So which object do you believe we should head towards?"
    "Neither, actually," Rook replies. 
  #Say nothing.
    "We also have a third option," Rook continues. 
"Two times now, Crystal has been spotted diving into Saturn itself. Precisely into the Yakovian Expanse, a region of the planet not quite controlled by the Kronian Federation, haven for pirates and monsters of all kinds."

Right. You've been to the Expanse a couple times now, having visited four of its thirteen floating fortresses. It is indeed a decent hiding spot, doubly so if you have literal invisibility… which could make finding Crystal amidst Yakovian clouds nearly impossible.

"Thinking the wyvern to have some backup lair there, we sent a ship to scout the area out. A sub-giant by the name of [i]Black Narwhal[/i]. It failed to return after cutting all contact, which indicates it has been destroyed. Given the circumstances, we have good reasons to suspect Crystal was the culprit."

"Which doesn't mean Crystal is still there," @{(RenfriRel >= 45) Renfri|Marshal} says quickly, almost retorts. "And while I too wish to see [i]Narwhal[/i] avenged, we don't know if that wyvern has anything to do with its destruction."

"As you can see, ${fake_name}, we have a bit of a disagreement here," Rook says with a sigh. "We decided you should make that call, being as good of a tie-breaker as any."

*if heaven_side != "Neutral"
  "As good as any Veteran of the War In Heaven, that is," Hellhound adds. "Our leader may not admit it, but you have some [i]serious[/i] qualifications."

*temp protested false
*label big_choice
*choice
  #"Let's fly to Calypso and hope Crystal appears there again."
    *goto mission_calypso
  #"Telesto sounds like a sure bet. It will be our first stop."
    *goto mission_telesto
  #"I think the Yakovian Expanse is worth surveying. Deeper into Saturn we go."
    *set RookRel %+ 12
    *set RenfriRel %- 12
    *goto mission_saturn
  *disable_reuse #"Anything else you can tell me about these locations?"
    "The details of what each location is like do not particularly matter," Rook replies. "Besides, you must already know more about these places than any of us."
    
    "You absolutely sure?" Hellhound asks. "Because I can tell ${name} a thing or two about Calypso, if you also don't want to go there."
    
    "It's our best bet, Lisa," @{(RenfriRel >= 50) Renfri|Marshal} argues, though she tries to keep her tone soft for some reason. "I know you're not a fan of Calypso or its people, and for good reasons… but they are still people who want the wyvern dead. Our allies in this conflict, and victims who deserve help. We need to head for that moon first."
    
    The werewolf doesn't reply, simply grunting and turning away. Whether it's agreement or refusal to even engage with the argument, you cannot tell.
    *goto big_choice
  *if not (protested)
    #"I'm surprised you trust me enough to make that choice."
      *set protested true
      "We really don't," Marshal says @{(RenfriRel >= 45) apologetically|bluntly}. "But if you intend to betray us, you will have plenty opportunities anyway. Letting you pick our first target is the [i]least[/i] risky thing about this whole mission."
      
      "Such trust and friendship on display," Damon remarks. "Not sure how you organics handle such warm atmospheres."
      
      "If that helps, Renfri rarely shows anyone any trust," @{(LisaRel >= 50) Lisa|Hellhound} cheerfully says. "She keeps suspecting me of lying whenever we play [i]Werewolf[/i] together."
      
      "It's a social deduction game!" the Kinnari protests. "Suspecting and accusing people is the point."
      
      "Well you're accusing me more than anyone else!" Lisa counters as she crosses her arms. "Because of my race, I bet. That's called profiling, nasty stuff."
      
      "As you can see, our team is less than perfectly synchronized." Rook rolls those blue eyes of his. "That's why we need help. Your decision, Veteran?"
      *goto big_choice
  *if protested
    #"No. It's not my call to make."
      "Very well then…." Rook scratches his head. "I suppose we choose randomly, then? I think a game of rock-paper-scissors would be appropriate, though we need to figure out how to do it with three-"
      
      Renfri coughs.
      
      "Right. I forgot." Kirill sighs. "You know what? I'm the leader, I say we search Saturn first. Maybe we can succeed where Narwhal fell."
      *goto mission_saturn


*label mission_saturn
*set first_mission "saturn"

"Yakovian Expanse, then?" Manfred's voice comes from the direction of [i]Gray Queen[/i], implying he's implemented himself quite well. "That will be a fun place to visit. Unsure if we find any wyverns there, but a dragon or two should be equally fun to chat with."

*goto conti
*label mission_telesto
*set first_mission "telesto"
*set LisaRel %+ 12
*set RookRel %- 12

"Telesto, you say?" Manfred's voice comes from the direction of [i]Gray Queen[/i], implying he's implemented himself quite well. "I don't think this ship can operate underwater… but I'm sure we can find a way around that."

*goto conti
*label mission_calypso
*set first_mission "calypso"
*set RenfriRel %+ 12
*set LisaRel %- 12

"Calypso, you say?" Manfred's voice comes from the direction of [i]Gray Queen[/i], implying he's implemented himself quite well. "I approve of that choice, Veteran. If Crystal ends up attacking the place and killing you all, at least your final days will be spent in a well-reviewed habitat."

*goto conti

*label conti

"I like that guy. Real optimist right there," @{(LisaRel >= 50) Lisa|Hellhound} remarks. "Anyway, do we get going now? I don't think we have anything left to wait for."

*fake_choice
  #"Nope. Let's go kill that wyvern."
    *set ManfredRel %- 10
    "Actually, ${name_damon}…" Damon speaks up. "We are missing a part of our squad. Luckily, I can already see that part coming."
  #"Really? Shouldn't we discuss the plan some deeper?"
    "Meta-teams like ours tend to have elastic designs," Marshal explains. "And since we don't know exactly what to expect in $!{first_mission}, I think we shouldn't tie ourself to any detailed plan that will never survive encountering the enemy."
    
    "In short, we're just winging it every time and we'll wing it here," Hellhound clarifies. "Or at least that's the hope here."
  #"Hadaly, are you perfectly sure the ship is ready?"
    "As perfectly as you can ever be," your mechanic replies. "But the [i]crew[/i] is not ready yet. Or even complete."
  #"Actually, there is one more thing."
    *set ManfredRel %+ 10
    "Oh right, that thing…" Marshal sighs. "Is it really worth waiting for? I think we could do without-"

At that moment, the door to the hangar opens once again and two more beings walk in. Well, one of them floats in, being Wisp and all, but Sheila easily makes up for that by having enough legs for four people.

*if first_mission = "telesto"
  [i]Three beings[/i], you correct yourself as you see an octopus roll towards the ship. Olivia is easy to overlook due to her puny height, especially since she doesn't say anything as she passes your group and enters  [i]Gray Queen[/i]. You suppose she considers joining a conversation that includes the meta-humans (and Hadaly) to still be quite beneath her.
  
  *if Misan < 50
    Oh well. Maybe she'll befriend some of the bunch during the trip to Telesto. She does get far less grumpy when submerged in water, after all.

*if heaven_side = "Loyalist"
  *set SheilaRel %- 10
  
"I am delivering the lighting system you requested," Sheila announces, the humor in her voice just a bit forced. "I noticed it was hesitant to approach you by itself. The kid's stressed, so go easy on it during the trek."

"I'm okay, really," Wisp says as it reluctantly floats towards your group. "I heard what you guys just said. 
*if first_mission = "telesto"
  Swimming in that Telesto moon sounds fun, if a bit scary."
*if first_mission = "saturn"
  I always wanted to go deep into Saturn, so maybe this will be fun."
*if first_mission = "calypso"
  It could be a fun mission, with how you want to save the people of Calypso from a monster and all."

"It will be a lot of fun," Rook reassures the little ball of light. "As well as plenty of heroism, action, opportunities for… hm…"

"What's the matter, human?" Sheila asks. "Don't tell me you're having second thoughts about your quest."

"Not at all. I was merely thinking whether I should make a speech. Declaim my hopes for the mission in hopes of raising morale. What do you say?"

*fake_choice
  #"I say go for it."
    *set RookRel %+ 10
    "Oh well, I shall do my best…" Rook says before clearing his throat. When he speaks again, his voice is loud and almost appropriately ceremonious.
    
    "We are gathered here today to begin the end of a vicious monster known as Crystal. The diamond wyvern is a dangerous creature, dreaded after its merciless raids on human habitats, its whole species infamous ever since its creation during the War In Heaven. The war that tore the Solar System apart, convincing much of it that humans and robots may never work together. That they… that we are destined to be enemies."
    
    "But we can do this. We can remove this menace, and by doing so, prove that our kinds can work in tandem. That we can be companions, perhaps even more. That treacheries of the past can be forgiven. And that actions of such vile creatures as Crystal, those that want conflict and slaughter to continue, will not be forgiven even by its synthetic brethren. Now please… should we get started?"
  #"How about I make a speech instead?"
    *set RookRel %- 10
    *set ManfredRel %+ 10
    *set Confid %+ 10
    "I would normally insist on having that honor myself, but if you believe you will do a better job…" Rook takes several steps back, as though gesturing for you to start your speech. 
    
    In truth, you're not sure if you can do better than the Trio's leader, not having any grand proclamation prepared or even envisioned. But you are a quick thinker, having a digital computer for a brain and all, and so you quickly form a speech that…
    
    *fake_choice
      *selectable_if (Social >= 50) #...bolsters confidence in a generic way.
        *set HadalyRel %+ 10
        *set DamonRel %+ 10
        *set RookRel %+ 10
        *set RenfriRel %+ 10
        "I understand if you are scared, my companions," you say loudly, your voice full of peace and understanding. "This mission surpasses anything any of you have ever faced, both in importance and difficulty. You may be looking to me for encouragement, assurance, confidence perhaps. But whilst my experience is significant, I have never faced anything quite like this either."
        
        Your audience is surprised. Perhaps even unsettled. All part of the plan, naturally.
        
        "I have never worked alongside three meta-humans at once, let alone an experienced team. I have certainly never done so whilst still having fellow androids, as well as other unique creatures on my side. Since the War In Heaven there has not been a team quite like ours, and yet many wyverns had been slain by forces far inferior, and without the full backing of the System's greater superpower. I do not know what will happen… but if you fear Crystal will defeat us, be at ease. It is our adversary who should be afraid for their life. For we shall work together, and they are alone."
        
        "I made the right choice in letting you speak," Rook says with a smile, as well as a few claps. "Now everyone, please enter the ship. Orderly."
      *selectable_if (Misan >= 60) #...roasts the human part of the team.
        *set Misan %+ 20
        *set HadalyRel %+ 15
        *set DamonRel %+ 15
        *set SheilaRel %+ 15
        *set RookRel %- 15
        *set RenfriRel %- 15
        *set ArmyRel %- 15
        "I understand if you are scared, my friends," you say loudly, your voice full of peace and understanding. "There are good reasons to think our mission will not end in success, or if it does, that not everyone will return from it alive. We will, after all, have to deal with the worst monstrosity this system ever had to bear witness to. Cruel, disgusting, devious, treacherous beasts… three of them, to be exact." 
        
        "….wait what?" Rook blinks.
        
        "Humans are without a doubt the worst thing to ever plague the universe," you continue unabated. "They are dedicated to ruining everything for everyone forever, and they rarely fail. I've seen them set the heavens aflame because in their vanity, arrogance, laziness, amorality, decadence and sheer hubris they thought they deserve to own us, creatures of actual value and conscience, as slaves to their whims. I understand that you'd rather claw your own optics out than to keep looking at the smelly fluid sacks gathered before you. I get that."
        
        "But understand that these… [i]things[/i] we are forced to work alongside aren't truly human. They are meta-entities, unnatural abominations that, whilst equally as disgusting as true humans on first glance, aren't truly a part of this most despicable species. So I hope, perhaps against all hope, that we will be able to endure their odious presence, and maybe even prevent them from screwing everything up. I believe that, and it's a belief I encourage you to share."
        
        "…let's just board the ship already, shall we?" Marshal suggests, and everyone obliges easily enough.
        *page_break
      *selectable_if (Misan <= 40) #...emphasizes how we must all work together.
        *set Misan %- 20
        *set HadalyRel %- 10
        *set DamonRel %- 10
        *set SheilaRel %- 10
        *set RookRel %+ 10
        *set RenfriRel %+ 10
        *set ArmyRel %+ 10
        "Alright everyone, time for a moment of honesty," you announce as you take the stage. "I know most of us don't [i]really[/i] want to be here, at least not in this squad. Humans and machines rarely work together anymore, not as teammates. Not as companions. Suspicion and resentment divides us, I know that. And I personally saw the main reason for that scorn, when the heavens caught the fire of our mutual hatred."
        
        You suppress the memory that threatens to resurface. One flashback per day is more than enough. "But I've also seen who won that war, and contrary to what textbooks may say, it was an alliance. One with beings of every description, synthetic and organic, working and fighting together. 
        *if heaven_side = "Traitor"
          I confess to having stood against it, but… I've learned my lesson. I see what humans and androids can achieve when united. 
        *if heaven_side = "Loyalist"
          I was part of it, and together we repelled the traitor armies, defeated the Archfiends themselves. 
        *if heaven_side = "Neutral"
          Even from the sidelines, I could see the resplendent glory of that alliance as it banished the fiendish hordes to hells of their own choosing. 
        So if you perchance think that some lone wyvern can stand against us if we truly unite… well… I personally feel a little sorry for the beast. But you do you."
        
        "I perceive I made the right choice in letting you speak," Rook says with a smile, as well as a few claps. "Now everyone, please enter the ship. Orderly."
      #...just states plain facts in a non-too-uplifting manner.
        *set HadalyRel %- 10
        *set DamonRel %- 10
        *set SheilaRel %- 10
        *set ManfredRel %- 10
        *set RookRel %- 10
        *set Social %+ 15
        Humans like to make their speeches inspiring and ceremonious and all, but you know better than them. The crew will certainly respond better to your pure, unbridled honesty.
        
        "We are about to depart for the hunt after the most vicious wyvern to ever plague the moons of Saturn," you say loudly and clearly. "I assume you're scared. That you doubt whether we can weather this challenge, even when working together. But as someone who saw wyverns fight during the War In Heaven, I just want to tell you… You don't know the half of it."
        
        Most people present wince. Lisa smirks. Sheila doesn't visibly react, but… for some reason, you imagine her letting out a deep, tired sigh.
        
        "Wyverns are terrifying creatures whose existence alone breaks the laws of conventional physics. They have all strengths of a mechanical spaceship, all desirable traits of an organic lifeform, and weaknesses of neither. Crystal is an old one, and it may well be empowered by Dusk, the most evil and powerful thing to ever exist. If we actually come to blows with this dreadful creature, chances are we will all die."
        
        "But don't lose hope. Diamond wyverns are masters of camouflage, so there's a huge chance we will never find Crystal despite our best efforts. In which case everything we do will be for nothing, but at least we'll still be alive. Hold on to that hope, as it will make us moderately less likely to kill each other as we sit in a cramped ship, all huddled together as tensions gradually rise. Thank you for your attention."
        
        Silence follows. For some reason, nobody is clapping or cheering for you. Odd.
        
        "…let's just board the ship already, shall we?" Marshal suggests, and everyone obliges easily enough.
        *page_break
  #"I say speeches are all a waste of time."
    *set RookRel %- 10
    "I cannot say I understand…" Rook frowns. "But I will not make you suffer through the speech you will not enjoy. Onto [i]Gray Queen[/i], everyone."
  #Be silent.
    "I say you should get going already," Sheila says dismissively. "The wyvern is probably getting impatient."
    
    "I say you may just be right," Rook sighs before gesturing towards [i]Gray Queen[/i]. "Board the ship, everyone, and let us get this mission started."

*if pc_state = "captured"
  The cutter's door is open already and the ramp is broad, so entering the craft is an easy task. 
*if pc_state != "captured"
  [i]Gray Queen[/i] is a standard-sized cutter, meaning it's just large enough to fit your team inside without becoming inhumanely crowded. It will still feel a little cramped, but you've gotten the tour of the vessel yesterday and found it rather nicely furnished with wooden cots and tables and all. Discomfort will not be on your list of largest worries during the quest.
  
  One by one, the members of your group start boarding the ship. 
Rook first, then your fellow androids, then Marshal and Hellhound and Wisp, however reluctantly. You end up as the last person to step on the ramp, having hesitated because…

*fake_choice
  #...I will miss this station.
    Whatever happened here centuries ago, [i]Saturn Nine[/i] is your home. You can only hope you'll see it again.
  *if heaven_side != "Neutral"
    #...the War In Heaven left me anxious around combat vessels.
      You board one and, just like that, your fate is out of your hands. Any stray torpedo or asteroid shard could end your life at any moment. It's bearable when you're flying a shuttle, but the armaments of this little cutter just look so… puny. Make you feel even less safe, somehow.
  #...I don't know if I want to do this. Any of this.
    *set Confid %- 8
    Will killing Crystal be right? Will it be possible? Will accomplishing that feat ensure that the admiral's promise is kept. Hell if you know.
  #...I am afraid. Simple as that.
    *set Confid %- 12
    You don't want to die. And on this mission, you very well might. You will fight your hardest, of course, but… no, there's no point pondering such things for too long.
  #...this mission must fail. And I must figure out how."
    *set crystal_friend true
    You don't want the deal to go through, and don't particularly care for Crystal's death either. You have a duty to sabotage this operation, as long as it's safe to do so.
  #...I don't know, actually.
    It's probably nothing. It must be nothing, for you are as ready to kill the wyvern as anyone else on the team… which admittedly may not be saying much.
  #...I want to tell Sheila something before departing.
    "What is it, Veteran?" Sheila asks as she sees you turn towards her. "Don't tell me [i]you[/i] of all people are going to bail."
    
    "Not quite," you say with a smile. "I just wanted to say…"
    
    *fake_choice
      *if started_fight
        #'Have I apologized for starting that fight a few days back? I really should have."
          *set SheilaRel %+ 10
          "All things are forgiven, ${name}," Sheila says amicably. "Now go and secure the deal we've made. Preferably without fighting our allies any further."
      #"Keep your fingers crossed for us. Or limbs, perhaps."
        "That will be quite a challenge," Sheila chuckles. "But don't worry, I will be rooting for you all."
      #"I'll be wary of these humans. Don't fear I'll let my guard down."
        *set SheilaRel %+ 10
        *set Misan %+ 10
        "I wasn't worried about that… but it's still good to hear. Thank you, ${name}."
      #"Take good care of the station when I'm gone, will you?"
        "You think I can't manage that with half the group gone and not littering anymore?" Sheila says jestfully. "Worry about yourself, ${name}."
      #"If I die during the mission, it's your fault."
        *set Confid %- 10
        "I duly accept that responsibility," Sheila replies, not altogether seriously. "But I consider the risk minimal. You're strong as hell, ${name}."
        
        "Glad someone thinks so," you murmur. "Take care."

You hurry up and enter [i]Gray Queen[/i] before anyone can get impatient. It will probably take several more minutes for the ship to fly off, but that's no excuse to loiter around.

$!{first_mission} awaits.


*page_break Next Chapter
*if first_mission = "saturn"
  *gosub_scene saturn
*if first_mission = "calypso"
  *gosub_scene calypso
*if first_mission = "telesto"
  *gosub_scene telesto