*set progress + 1
*set battery - 10
*image h11.png
*set weapon_av true


The main power plant of the Sholmo City is, by all sane standards, an impressive feat of engineering and technology. Though you remember the times of sleek, compact, glittering cold fusion plants, you also realize that those times are long gone. As such, you have some appreciation for the huge building, as well as the fusion reactor inside the concrete structure. Building such a thing in the middle of a city must have taken some serious resources, and likely required the builders to demolish some habitat blocks first.

You're also quite impressed with the defenses. There are firearms sticking out of the windows, a huge barricade blocking the front door, and even a whole anti-air cannon on the roof. It's made even more impressive by the fact that the Conglomerate soldiers—those who should be defending important facilities of Rhea—were not the ones who fortified this position.

"Calypsoan forces." @{(RenfriRel >= 50) Renfri|Marshal}'s voice is calm, but her eyes are narrowed in anger as she looks at the building's sealed gate. "They took over the power plant about seven hours ago. They've been holed up there ever since."

*if team_stat != 1
  "You gotta admire their tactical acumen, if nothing else," Damon comments. 
  *if team_stat = 2
    He seems quite invested in the situation, perhaps because he wishes to distract himself from… what just happened. 
  *else
    He and Hadaly came here with you, both curious about this unexpected development. 
  "A plant like this makes for a good fortress, but only if an attack is expected. Taking one over by surprise and then using it as a base is clever… Though they'll still get overwhelmed once the Executives get their private armies assembled."
*else
  And now they're preparing to unleash a swarm of Dusk nanobots on the surrounding city. That's what the metas told you, right before leading you 
  *if Misan > 50
    here… And then failed to provide any proof of their claims.
  *else
    here. You have no real reason to doubt them, though you haven't seen any evidence for their claims either.

*fake_choice
  *if (team_stat != 1) #"I imagine there's some other reason why they picked this building. Perhaps they're trying to rig the reactor and blow everything up."
    *goto opooop
  *if (team_stat = 1) #"But why? Why the power plant? Are they hoping to turn it into a nuclear bomb or something?"
    *label opooop
    "I'm not sure if that's even possible." @{(LisaRel >= 50) Lisa|Hellhound} shakes her head. "I think they just need lots of power. Power to awaken all those Dusk nanites they have prepared."
    
    "How do you know that?" you inquire. 
    *if (LisaRel < 45) or (DaxiaRel > 55)
      "Are you sure it's not just your bias showing through? Because I see no evidence that Dusk, or Da-xia for that matter, are involved in any-"
    *else
      "I'm not doubting you, but I'd like to see some evidence of Dusk being-"
  #"And what were you doing for those seven hours? Did you even attempt to kick them out?"
    *if RenfriRel > 50
      @{(RenfriRel >= 50) Renfri|Marshal}'s eyes narrow even further. "How exactly were we supposed to do that? There are dozens of soldiers here and just three of us. We need help here, your help above all."
    *else
      "I wanted to do just that." @{(RenfriRel >= 50) Renfri|Marshal} turns towards her commanding officer. "But some of us didn't want to risk it. Decided that a hundred soldiers is too much for us to handle, even if they're just baseline humans."
    
    *set RenfriRel %- 5
    *set RookRel %- 10
    
    @{(RookRel >= 50) Kirill|Rook} nods. "We tried asking corporate soldiers for help, but they are all engaged somewhere… or dead. You are the only help we are likely to get."
  #"You told me Dusk nanites are involved. Care to explain how?"
    "Most certainly." @{(RookRel >= 50) Kirill|Rook} nods towards you. "We are speculating somewhat here, but we overheard a conversations of theirs, the enemy soldiers that is, and they are clearly preparing to-"
    
    "For the philosopher's sake, you really love to hear yourself talk." A voice comes out of several loudspeakers at once. There are many of those, both on the street and on the walls of the power plant, letting you hear the speech with painful clarity. "I'd rather explain it all myself."
    
    *goto daxia_contact
  *if DaxiaRel > 50
    #"Maybe... But I still see no evidence that Da-xia is behind this."
      *set LisaRel %- 10
      "What evidence would you like?" @{(LisaRel >= 50) Lisa|Hellhound} says calmly, but you can tell she's on edge. "Pictures? I'm sure I can get Renfri to paint you something."
      
      "[i]Photos[/i] definitely wouldn't hurt," you reply dryly. "And neither would some other solid proof. Something concrete and indisputable."
      
      "Aren't you a little demanding?" @{(RenfriRel >= 50) Renfri|Marshal}'s eyes narrow even further. "We're in the middle of a battlefield and running out of time. It's not like we can interview Da-xia and make her admit to being behind-"
      
      "The greatest philanthropic achievement of this dismal century?" 
      
      *goto daxia_contact
  #"Are you sure it's the Calypsoans? I don't see any distinct banners or uniforms."
    "That's how you know it's the Calypsoans," @{(LisaRel >= 50) Lisa|Hellhound} says grimly. "They don't like flapping banners, or fancy uniforms, or heraldry in general. They strike without warning and fight without pride, They only care about results."
    
    "And so every unit that doesn't fly flags is automatically Calypsonian?" You poke holes in her logic. "I don't buy it. I will need to see or hear some solid evidence of their involvement before-"
  #"@{hammon_alive Is|Was} Hammon aware of this? He didn't mention any of it when we met."
    "Perhaps, perhaps not," Rook says with a shrug. "Executive Hammon has… 
    *if not (hammon_alive)
      or at the very least had… 
    a reputation for not taking bad news well. I could easily imagine his underlings being afraid to inform him properly."
    
    *if team_stat != 1
      "I can imagine that too." Damon grimaces. "Our father… Hammon was never a good boss. Not to me, not to anyone. 
      *if not (hammon_alive)
        I'm almost glad he's dead… kind of. Maybe. I don't know."
      *else
        Heads will roll for this, and not just those of the guilty."
    *else
      "Right. My…" Friends? Were Damon and Hadaly really your friends? Or just victims of your sorry decisions? "My fellow androids weren't his fans either. I can see why nobody thought to bring him the report. And why the Calypsians would want to attack his city like this."
      
      "I don't think you do, actually." A voice comes out of several loudspeakers at once. There are many of those, both on the street and on the walls of the power plant, letting you hear their sound with perfect clarity. "But I am here to help."
      
      *goto daxia_contact
    
    *if team_stat = 3
      "That's true… But I also wouldn't put it past him to simply ignore each and every battle report coming his way," Hadaly starts musing. "Much is happening in Sholmo City today, and Ewald @{hammon_alive has|had} a habit of getting overly focused on-"
      
      "Can we maybe focus too?" @{(LisaRel >= 50) Lisa|Hellhound} suggests with unusual, palpable frustration. "We're wasting time. We need to find Da-xia and shove something sharp up her-"
      
      "Language, Miss Herbert." A voice comes out of several loudspeakers at once. There are many of those, both on the street and on the walls of the power plant, letting you hear their sound with perfect clarity. "There's no need to make the atmosphere more toxic than it already is. Make your unit even angrier, more unhappy."
      
      *goto daxia_contact
  #"Why aren't they shooting at us? They must know we're not their friends."
    "They know we're not their friends, which is why they started shooting at us when we first came close." @{(RenfriRel >= 50) Renfri|Marshal} gestures towards a puddle of molten metal and asphalt on the other side of the street, as though a plasma shot landed there. "But they might not be so sure about you. 
    *if team_stat = 3
      Or your android buddies, for that matter."
      
      "They think we might be their allies?" Hadaly wonders. "I mean, I hate the Conglomerate as much as they do, but that's not quite enough to make me-"
    *elseif DaxiaRel > 50
      You enjoy a good relationship with their leader, don't you?"
      
      "A decent one, I suppose." You wince once you realize the implication. "But why are you claiming Da-xia is leading these men? I see no actual evidence-"
    *else
      I bet they're scared to provoke you, hoping you'll stay out this fight."
    
    
  #"I still don't see why that should interest me."
    "Don't you remember what I said?" @{(LisaRel >= 50) Lisa|Hellhound} sounds and looks extremely frustrated. "We're facing an existential threat here. And more importantly, we have a chance to finally stab Da-xia in her stupid face."
    
    *if DaxiaRel > 50
      "Do you really think I want that?" you retort with equal ire. "Da-xia was always cordial with me. I have no reason to want her dead, and I don't fully believe she's involved in-"
    *else
      You shrug. "You might hate her more than you like being alive, but I don't. Besides, I see no evidence that Da-xia is personally involved in this-"

Suddenly, a voice comes out of several loudspeakers at once. There are many of those, both on the street and on the walls of the power plant, letting you hear the speech with painful clarity. "I sincerely welcome my honored guests, to whom I owe so much already. 

*label daxia_contact

There is no video display anywhere and she's likely speaking from inside the building, so you cannot see her face. But there is no mistaking that tone, so soft and soothing, and yet so sanctimonious and… venomous in an awfully subtle way. It's the voice of a triumphant leader, of a priest giving a sermon or a general announcing a crushing victory. The voice of a Pandit.

@{(RenfriRel >= 50) Renfri|Marshal} and @{(LisaRel >= 50) Lisa|Hellhound} tense visibly, and you bet @{(RookRel >= 50) Kirill|Rook} does the same inside his exoskeleton. As though their enemy's words are enough to strike fear into their hearts… which is quite reasonable, given the bomb inside @{(LisaRel >= 50) Lisa|Hellhound}'s heart.

"Hearing you debate and speculate about the events which surround you is certainly entertaining," Da-xia continues blithely. "But I value truth, and wouldn't want anyone to reach wrong conclusions. Come in, and I will gladly clarify everything for you. Conditional on you dropping all your weapons at the doorstep."

"I'd rather not," @{(LisaRel >= 50) Lisa|Hellhound} growls. Actually growls, as though she's undergoing a werewolf transformation despite herself. "I'll enter your puny fortress armed. I'll kill you, no matter how many goons you'll make me slaughter first."

"You don't need weapons to slaughter people, and you certainly don't need me to make you do it," Da-xia replies. Her invective is full of vitriol, but not of actual anger. You wonder if she remembers the bomb, knows that she can end @{(LisaRel >= 50) Lisa|Hellhound}'s life at any moment now. "But fair enough. In a gesture of gratitude and munificence, I will continue to converse through these speakers. That way, no rabid dog will interrupt our conversation… unless she barks loudly enough, I suppose."

*temp timer 0
*temp dusk_conf false

*if team_stat = 3
  "Normally, I'd fully support the idea of talking and analyzing our differences calmly." Hadaly steps towards you. "But I get the feeling something will explode soon, so… Can we maybe cut to the chase? Or better yet, cut to [i]escaping[/i] this place?"
  
  You can't help but see @{(official_ro = "hadaly") your girlfriend's|her} point… But some things need to be said. And so you turn towards the nearest speaker, assuming it comes with some audio receivers, and say…

*fake_choice
  #"What is this? What the fuck are you doing? What's the meaning of this madness?"
    "Madness may have no meaning," Da-xia states philosophically. "Luckily, this is no mere madness. There is method to it, rhyme and reason which ties everything together."
    
    "Then what is it?!" you exclaim. "What do you stand to gain from… What are you even doing?"
    
    *set timer + 2
    *goto first_que
  #"Better sit down, then. Because I have a [i]long[/i] list of questions for you."
    *set DaxiaRel %+ 8
    "I expected nothing less and I hoped for nothing more," Da-xia warmly replies. "And I'm already seated, so go ahead. Ask your heart away."
    
    *if team_stat = 3
      Hadaly sighs. 
    *else
      @{(LisaRel >= 50) Lisa|Hellhound} frowns. 
    "I just hope that list of yours isn't [i]too[/i] long. For some reason, I doubt we have infinite time on our hands here."
  #"I will fucking kill you."
    *set Emotion %+ 5
    *set Violence %+ 5
    *set DaxiaRel %- 5
    "So vulgar. So inappropriate," Da-xia chastises you. "But I suppose it's understandable, given the nature-"
    
    *if Emotion > 50
      "I'll fucking kill you!" you bellow angrily. "You used us! You lied to me! And there's probably a fuckton of other things you should die for!"
    *else
      "I'll fucking kill you," you repeat calmly. "If not for the good of the Solar System, then as revenge for all the ways you lied to me."
    
    "In my defense, I only lied to your team… twice?" One would be forgiven for not noticing the faint mockery in her distorted voice. "I can't remember. But I promise to tell nothing but truth from now on. It's no time for lies anymore."
    
  #"Hello, Da-xia. Long time no see."
    *set Emotion %- 8
    *set DaxiaRel %+ 8
    "And here I feared you might be angry about the whole thing," Da-xia says with audible relief. 
    *if Emotion > 50
      "You are an unusually emotional machine. Even still, 
    *else
      "Shows what I know. You are superior to ordinary humans in every respect. 
    I am looking forward to having a civil discussion with you, the kind your companions are clearly incapable of."
    
    "Fuck you," @{(LisaRel >= 50) Lisa|Hellhound} says, arguably proving the Pandit's point. "We don't want to [i]discuss[/i] anything with you. At most, we [i]might[/i] appreciate some answers before we rip you and your men apart."
    
    "You're no position to order me around, Miss Herbert." Now, you can actually hear a bit of anger in her voice. "Luckily for you, I'm not opposed to answering questions, provided ${name} has any."


*label conv_hut

*set timer + 1

*if timer = 6
  *if RenfriRel > 50
    "${name}… Can you please hurry up?" 
  *else
    "Can't you see she's playing you, android?" 
  @{(RenfriRel >= 50) Renfri|Marshal} says before you can ask another question. "She's obviously stalling. Delaying our attack however she can. Cut it short and decide whether you'll help us or not."
  
  *if team_stat = 3
    "I'd very much like to know that too." Hadaly nods in agreement. "Otherwise, we might end up blown up no matter what we choose. But no pressure."

*label conv_hut2


*choice
  *if timer = 1
    #"For starters... Can you explain what you actually want?"
      "With pleasure," Da-xia says politely. 
      *label first_que
      "My final goal is to see Rhea Conglomerate, the humongous corporation with infests this moon, utterly destroyed. I see it as an evil cyst on the already flawed Federation and all available data supports my view. Removing this moon's rulers will improve both total and average happiness of the Kronian population, as well as the Solar System as a whole."
      
      *if team_stat = 3
        "I'm following so far," Hadaly murmurs. "Though I may not like the next part."
        
        Da-xia continues, 
      *else
        "And how do you intend to [i]remove[/i] the Conglomerate, exactly?" @{(RenfriRel >= 50) Renfri|Marshal} asks angrily. "By getting Dusk to devour one of their cities?"
        
        Da-xia replies, 
      "Sholmo City will be destroyed, yes, but that's hardly the important part. Our main goal-" 
      
      "How is it not important!" @{(RenfriRel >= 50) Renfri|Marshal} interrupts. "You're about to kill… a hundred thousand people? Two hundred thousand? More?"
      
      "About half a million, should we consider the immediate fallout." Da-xia is not just tranquil, dispassionate or uncaring. She sounds positively carefree, like a child solving a puzzle, or perhaps one tossing building blocks around. "More still, if we include the long-term ramifications."
      
      "And what would those ramifications be?" @{(RookRel >= 50) Kirill|Rook} asks, in a tone that suggests he knows the answer already.
      
      "Once Dusk nanobots devour the city, then promptly run out of energy to absorb, they will infect the survivors and turn them into Vessels. This will swiftly remove the Conglomerate's ability to reign over Rhea and eventually end the corporation itself. The total human happiness should rise as a result."
      
      And there it is. The admission. 
      *if DaxiaRel > 60
        And it hurts so much to hear it.
      *if DaxiaRel < 40
        Just as you all expected.
      
      *goto conv_hut
  *disable_reuse #"Will you really use Dusk nanites? Do you serve the Thing Beneath?"
    *set dusk_conf true
    "Your speculation offends me," Da-xia calmly states. "I am no calamity cultist, no servant of Dusk's collective consciousness. I don't believe in gods, only in advanced technology and its… potential usefulness."
    
    "Usefulness?" @{(RenfriRel >= 50) Renfri|Marshal} scoffs. "You're talking about the Eater of Earth here. The Ancient Chaos. The Thing Beneath."
    
    "Technically, the term [i]Thing Beneath[/i] only describes the portion of Dusk still stuck on Earth," Da-xia says in the authoritative tone of a teacher, or perhaps of the religious leader she is. "I am using one of its fragments, a thing of far lesser mass and-"
    
    "It's still Dusk!" @{(RenfriRel >= 50) Renfri|Marshal} yells. "It will eat everything if you unleash it! You, us, this city, this moon, this ring, this [i]fucking galaxy![/i]"
    
    Da-xia scoffs, "Your predictions are overly dramatic. Our fragment of Dusk may be large, but nowhere near what we'd call a [i]critical mass[/i]. We'll provide it with enough power to wreck havoc in the Sholmo City, perhaps to devour it entirely… but since the power plant will be destroyed instantly, there won't be any additional energy for the swarm to absorb. Eventually, all nanobots will run out of power and instinctually embed themselves in random objects."
    
    "Or random people," @{(RookRel >= 50) Kirill|Rook} points out. "You are about to create new Vessels. Hundreds, possibly thousands of them. New servants for the Thing Beneath."
    
    "That's a problem for your Federation," Da-xia dismisses the concern. "Quarantine Rhea, nuke Sholmo City into oblivion, do whatever it takes to stop further spread. Once you're done, the Conglomerate will be as good as gone, and the System will be better for it."
    
    *goto conv_hut
  *if dusk_conf
    *disable_reuse #"So you intend to unleash Dusk on this city. How exactly do you expect to survive this?"
      "Come on, ${name_daxia}." Da-xia sounds quite offended. "Be better than that. You already know the answer to your question."
      
      "Perhaps I do…" you murmur. "I'm just not sure if I want to believe it."
      
      "Then I will spell it out for you." The Pandit's voice grows more ceremonious, but no less jovial or self-satisfied. "I do not intend to survive this operation. I will be possibly the first victim of this swarm I'm about to unleash, and my courageous men will follow soon behind. Nor do I expect any reward in some fictitious afterlife like most martyrs do. I'm doing this purely to improve the Solar System and do humanity a favor."
      
      "Do you expect us to start clapping now?" @{(LisaRel >= 50) Lisa|Hellhound} jests. "A round of applause for the visiting clown and her circus?"
      
      "I expect precisely nothing from you. I'm not doing this for acknowledgment either. It's a purely utilitarian sacrifice, the kind I'd expect from any self-respecting Bayesian."
      
      "And from thousands and thousands of innocent people," @{(RookRel >= 50) Kirill|Rook} observes. "Does that not strike you as a little… wrong?"
      
      "Not particularly," Da-xia says breezily. "There is such thing as acceptable losses, and [i]you[/i] of all people should not be claiming otherwise. Unless, of course, you recently changed your mind about the Outer System War."
      
      @{(RookRel >= 50) Kirill|Rook} tenses. You can sense that, even though you can't see that, and you can hear it in his voice. "It was war. I helped end it faster than… I am nothing like you."
      
      "I see," Da-xia chuckles mirthlessly. "Your conscience only applies to [i]other[/i] people's actions. Everyone else sins, you simply follow orders and make hard choices. I agree that we're in no way similar, Sergeant Kosteniuk—I am not a coward, for one."
      
      @{(RookRel >= 50) Kirill|Rook} does not reply.
      
      *goto conv_hut
    *disable_reuse #"Where did you even get those nanobots from? How did you hide them?"
      "I may not tell," Da-xia replies calmly. "And you should not ask. It's not like this information could possibly do you any good."
      
      "It's a state secret, then," @{(LisaRel >= 50) Lisa|Hellhound} comments. "Can we play 'hot and cold' with it? I'll guess, you tell me how close I am."
      
      Da-xia scoffs, "Even after all these years, you're still a child. You know nothing. But go ahead, tell me what ridiculous guess you came up with."
      
      "Great!" @{(LisaRel >= 50) Lisa|Hellhound} claps. "My first guess is that you hid the nanobots in plain sight. That they're embedded inside some object, some artifact that looks quite ordinary at first glance. So ordinary even Crystal was not able to spot it."
      
      "A guess so vague as to be essentially meaningless," the Pandit responds. "You're wasting everyone's time."
      
      "Hypocrite," the werewolf shoots back. "My next guess is that much of your wealth comes from this artifact. That you've been selling fragments of it, small specks of Dusk, on some black market out there. Perhaps in the Yakovian Expanse. It would explain Crystal's presence there, however brief it was."
      
      "That's not what ${name} asked about," Da-xia's voice falters slightly. "You're trying to guess how we acquired these nanomachines in the first place. And you clearly have no idea."
      
      "I don't know when and where you found the first speck," @{(LisaRel >= 50) Lisa|Hellhound} admits. "But I suspect you've been… cultivating them somehow. Letting them reproduce like they did on Earth, just in a slow and controlled manner. That somewhere in Calypso there's a child, locked in a dark cell and infected with Dusk, a Vessel just strong enough for the nanites to gradually replicate inside their body. You know, just like in that pre-Dawn story I once read."
      
      "Your parents shouldn't have taught you how to read," Da-xia replies coldly. "You clearly can't tell reality from fiction. One can't build their [i]Omelas[/i] with just a single casualty, and so we have not tried. Next question."
      
      *goto conv_hut
    
    *disable_reuse #"You want the Conglomerate destroyed. I get that. But why not use some less stupidly dangerous weapon?"
      "Something old-fashioned, you mean?" Da-xia asks. "A hydrogen bomb? Or perhaps just lots and lots of black powder?"
      
      "Your habitat is quite wealthy," you point out. "A nuclear bomb should have been easy enough to acquire. You could have even rammed a spaceship into this city, if you cared enough."
      
      "I greatly care about long-term results of my actions," Da-xia says coldly. "A regular blast would barely be noticed by the wider Federation. A nuclear one would require some cleanup, but it would still be Rhea's problem. Dusk is perceived as a threat to everyone, leaving the military no choice but to intervene and bring the Conglomerate to its knees."
      
      "Dusk [i]is[/i] a threat to everyone!" @{(RenfriRel >= 50) Renfri|Marshal} protests. "You are risking humanity, the Solar System, all of existence out of dumb hate! How can you not see this?"
      
      "It's not hate that drives her, Renfri," @{(LisaRel >= 50) Lisa|Hellhound} says, her voice just as cold as the Pandit's. "It's pride. Her whole religion is based on arrogance, on the idea that those self-appointed gurus know better than everybody else. She doesn't care that her plan is overly complicated and overly dangerous, because that just makes her more [i]proud[/i]. Only she could come up with something so insane, and she'll prove that fact to all of Saturn, then die to avoid the consequences of her actions."
      
      "There is so much wrong with your statement that I don't even know where to begin," Da-xia says dismissively. "So I won't begin. I'll let you feel superior, even as I make the ultimate sacrifice for the greater good. It will raise the total happiness of humanity… and of the canines too."
      
      *goto conv_hut
    *if timer > 4
      *disable_reuse #"What if you're wrong? What happens once you miscalculate and lose control of the swarm?"
        "I have not miscalculated anything," Da-xia confidently states. "We know exactly how much power Dusk needs to devour this city without endangering the wider-"
        
        "What if you're wrong?" you repeat yourself. "What if Dusk doesn't behave exactly like you think it does? Or if you slip up, giving it more or less energy than intended?"
        
        "If the power from this reactor proves insufficient, the swarm will just devour this building and the surrounding street before turning dormant," Da-xia explains, then pauses for a moment. "If it gets too much… Theoretically, it could use this excess energy to reach other power plants and start reproducing. It would reach critical mass, a point where it's capable of performing compact fusion, and then… It would probably devour the entire Solar System."
        
        "And that's an acceptable risk for you?" @{(RenfriRel >= 50) Renfri|Marshal} asks, angry and perplexed. "The end of everything is a worthy price for your… utilitarian project?"
        
        "At least a billion lives will be improved by the fall of Rhea Conglomerate. Failure will kill ten billion at most, for that's how many humans live in the Solar System. Estimations put the risk of failure at less than one percent, and so  this gamble is worth taking."
        
        "And that's the Bayesian Path, everyone." @{(LisaRel >= 50) Lisa|Hellhound} claps politely. "
        
        *goto conv_hut
  *disable_reuse #"Just to be clear, you do realize that @{(LisaRel >= 50) Lisa|Hellhound} has a bomb in her heart? And that you have the detonation code?"
    *set RenfriRel %- 15
    *set LisaRel %- 10
    *set RookRel %- 5
    *set DaxiaRel %+ 10
    "Why would you say that?!" @{(RenfriRel >= 50) Renfri|Marshal} shouts in your face. "This… That's the stupidest, dumbest, most moronic thing you could have possibly-"
      
    "It's fine, Renfri." Surprisingly, @{(LisaRel >= 50) Lisa|Hellhound} comes to your defense. "Da-xia doesn't have the guts to pull that trigger anyway."
    
    "I did not forget the code, nor am I the coward you take me for," Da-xia responds to the taunt. "However, it turns out my radio broadcaster has a sorely limited range. I can't detonate the bomb from here, but I will do that once you enter the building."
    
    "What a coincidence." Lisa rolls her eyes, still weirdly unbothered by the whole situation. "Or a veiled attempt at scaring me away. At taking me out of the fight without pissing off my teammates too much. Shame it won't work."
    
    "I already invited your whole group in, Miss Herbert," Da-xia says dryly. "Please accept the invitation. You don't even need to leave your weapon behind. I'll make an exception just for you."
    
    *goto conv_hut
  *if lisa_origin_learned
    *disable_reuse #"Tell me about @{(LisaRel >= 50) Lisa|Hellhound}. How did she become a werewolf?"
      The reply only comes after a lengthy pause. "Interesting question to ask [i]me[/i]. Isn't Miss Herbert standing right beside you?"
      
      "Yes. Yes I am." @{(LisaRel >= 50) Lisa|Hellhound} nods. "Besides, don't you know that story already?"
      
      You explain, "That story has some missing pieces. For one, how did you even get infected? Nanites which turn humans into werewolves spread mostly through bites and sexual contact. I don't think a werewolf bit you, or…?"
      
      @{(LisaRel >= 50) Lisa|Hellhound} shakes her head. And blushes slightly.
      
      "Besides, your powers come primarily from World Engines, such as the one above us," you continue, pointing towards the slowly-dimming Tanit. "There's no such thing in Calypso. Your infection must have been artificially energized… somehow."
      
      "Are you saying…" @{(RenfriRel >= 50) Renfri|Marshal} speaks slowly. "Do you think Lisa was an… experiment of some sort? That the Pandits were experimenting on nanites other than Dusk ones? That they infected her with werewolf essence [i]on purpose[/i]?"
      
      "We were running tests of many kinds…" Da-xia hesitates, as though unsure what reaction she's hoping for. "But I cannot tell whether your teammate was a result of one. I haven't done anything like that on purpose, but other Pandits may have. Or it could have been accident after all, I genuinely don't know."
      
      @{(LisaRel >= 50) Lisa|Hellhound} stands there silently for several seconds. You cannot read her expression, and you dare not guess what she's feeling. Eventually, she shrugs. "Well… It doesn't change much. Those bastards deserve to die either way. So let's hurry up and finish this."
      
      *set timer + 1
      *goto conv_hut2
  *disable_reuse #"Why now? Was the timing of your attack deliberate? Or did you [i]coincidentally[/i] make your move while we're in this moon?"
    "That depends on your definition of [i]coincidence[/i], I suppose," Da-xia says thoughtfully. "I certainly did not plan for you being here, but there certainly [i]is[/i] a reason why I haven't attacked earlier."
    
    "And that reason was Crystal," 
    *if team_stat = 3
      Hadaly 
    *else
      @{(RookRel >= 50) Kirill|Rook} 
    guesses. "Your moon lacks a proper fleet. Any attempt to transport a Dusk fragment through the vacuum of space would have been noticed, and Crystal would have had no issue destroying whatever ship you picked for the mission. But now that the wyvern is out of the picture…"
    
    "We faced no difficulty in transporting our troops and weapons here," Da-xia finishes for 
    *if team_stat = 3
      her.  
    *else
      him. 
    "We just needed to bribe the local flight control, convince them not to look inside our ship. They probably assumed we were drug dealers or petty smugglers. Just another proof that the Conglomerate needs to go."
     
    "That explains why you haven't attacked earlier than you did," 
    *if team_stat = 1
      @{(RenfriRel >= 50) Renfri|Marshal} 
    *else
      Damon 
    notes. "But why not later? Why not wait until you're sure you cannot lose?"
    
    *if crystal_stat = 2
      "In case you forgot that little detail, you team failed to kill the wyvern," Da-xia says scornfully. "You didn't even injure it all that much. For all we know, it may leave Janus any moment now. Expediency is nothing if not prudent."
    *else
      "Because while you failed to connect the dots, not everyone will. Now that our habitat is no longer terrorized by Crystal, Admiral West will surely send someone to get a closer look at it. Keeping our… secret weapon inside would have been foolish."
    
    "Did you just admit you might lose?" @{(LisaRel >= 50) Lisa|Hellhound} says, a mischievous smile growing on her face. "That you simply had to hurry, despite knowing that we might stop you?"
    
    "I said nothing of the sort," the Pandit replies coldly. "Stop putting words in my mouth, mutt. It's not a good use for what little time you have left."
    
    *goto conv_hut
  *disable_reuse #"What about the other Pandits? Have they approved of your plan? Is this a war between Calypso and Rhea?"
    "Hardly," Da-xia replies. "This is my personal initiative. I did not inform the Calypsoan Council of my plans, let alone seek their approval."
    
    "This should not be possible," @{(RookRel >= 50) Kirill|Rook} points out. "You have about a hundred men here, not to mention those who died in the attack. A sizable force in a moon as small as Calypso. To assemble it without anyone noticing-"
    
    "Don't you get it, Kirill?" @{(LisaRel >= 50) Lisa|Hellhound} interrupts. "She's trying to maintain plausible deniability on behalf of her fellow demagogues. She's trying to ensure that her actions here won't reflect badly on the rest of Calypso, or at least that the feds won't destroy her pathetic moon as revenge."
    
    "I certainly consider that a bonus," Da-xia chuckles. "Not that it overly matters. Unless you retreat at this instant, you won't live to convey anything I've said to your superiors, and there won't be any reliable witnesses of my involvement."
    
    "It matters to us," @{(RenfriRel >= 50) Renfri|Marshal} chimes in. "If you're not here officially… What's stopping us from going all out? Killing one of Calypso's rulers could get us in trouble, but we're all [i]well[/i] within our rights to execute a rogue terrorist."
    
    "I do not particularly like this line of reasoning," Da-xia admits. "But if you wish to kill me, you'll have to get through my defenses first. It matters not whether my men are here officially or not, for they will vanquish you all the same."
    
    *goto conv_hut
  *disable_reuse #"You're giving me lots of information on a silver platter. Why?"
    "Isn't it obvious?" @{(RenfriRel >= 50) Renfri|Marshal} sneers. "She's playing for time. While we stand here and talk, her men are setting up… whatever it is they're about to use."
    
    "I will not pretend otherwise," Da-xia concedes. "But I'm also genuinely hoping to make you understand. Make ${name} see reason, in particular."
    
    You arch a brow. "Me? 
    *if Confid > 50
      Are you that afraid of actually facing me in battle?"
    *else
      What's so special about me?"
    
    *if creed = "Bayes"
      "You are a Bayesian," Da-xia says flatly, as though she's stating something beyond obvious. "You see what I'm trying to do. You understand the value, the [i]necessity[/i] of making sacrifices for the greater good. Those besides you are blinded by hate and selfishness, but we… you and I can both see clearly. Help me improve the System, or at least refrain from interrupting my design."
      
      Is Da-xia correct? It's hard to tell. Sacrificing people for the greater good is certainly in the spirit of the Bayesian Path, but if she miscalculated and is about to unleash too much Dusk… She could even be corrupted by the nanites. Or maybe she's lying and actually serves Dusk, fully intent on letting it devour Rhea. In either case, her actions might destroy the very Solar System she's supposedly trying to help.
      
      Damn it. Following the Bayesian Path is so hard when you don't have all the information.
    *elseif DaxiaRel > 60
      "Because we're friends." Her voice softens, warms up a little. "I welcomed you into Calypso as my ally, and you haven't yet betrayed my trust. 
      *if visited_daxia
        I welcomed you into my [i]house[/i], and we conversed there cordially. 
      *if sexed_daxia
        Not to mention all the things we did in my bedroom. 
      We are on the same side, no matter what these meta-humans want you to believe."
      
      "We simply want ${pronoun2} to know the truth," @{(RookRel >= 50) Kirill|Rook} retorts. "Your words are nothing but venom. You are trying to divide us, reduce our number through lies and false affection. You will not succeed."
      
      Will she?
      
    *elseif Emotion < 50
      "You're a machine," Da-xia replies in matter-of-factly tone. "You're a creature of logic, almost stereotypically so. You're free to follow your own reason and self-interest, unlike those meta-humans beside you. Foiling my plans out of revenge, or pursuit of heroism, or counter-productive fear… it's simply not your style."
      
      She's right, at least to an extent. You're not terribly emotional or overly human, not wholly opposed to cold logic. But whether fighting Da-xia is actually an illogical choice… That's a question you must answer yourself.
    *elseif Misan > 50
      "Do you really intend to die to save a city full of humans, ${name}?" Da-xia asks suddenly. "Or even a moon full of humans, for that matter? I know how you hate them and, though I spurn such emotions, know you have reasons to feel that way. Will you really fight for and alongside humans after everything they've done to hurt you?"
      
      She has a point. A surprisingly good point, considering she's human. There's a chance you'll get eaten by Dusk nanites, should they reach critical mass, but if that doesn't happen… Will you really have a reason to care?
    *elseif federate_protection
      "There is nothing for you to gain here," Da-xia says harshly. "The Federation hired you to eliminate Crystal, and that job is [i]done[/i]. You can still outrun the blast, return to your fortress and remain safe for the rest of your life. Your meta-human companions have no such choice, so I'm addressing you first and foremost."
      
      "You're right about one thing," @{(RenfriRel >= 50) Renfri|Marshal} replies. "We have no choice but to take you down. So get ready."
    *else
      "Unlike your meta-human companions, you're not on the Federation's employ," Da-xia replies with a faint note of surprise. "To the contrary. The Federation spurned you, failed to appreciate your assistance, and is about to kick your group out of your own home. But instead of fighting them, you're about to strike the one who welcomed you in her own habitat? 
      *if visited_daxia
        In her own house? 
      If I were you, I would seriously reconsider which side I'm on."
      
    *goto conv_hut
  #"Alright. I've made my decision."
    *goto grand_choice


*label grand_choice

"I really hope that means you'll help us," @{(RenfriRel >= 50) Renfri|Marshal} says, her eyes focused on the gate ahead. "Because between you and me, I don't think our Trio can break through. Or at least not in time."

*if team_stat = 3
  "${name}… We don't need to get involved here, do we?" Hadaly asks. "Risking our lives just to save the Conglomerate doesn't sound wise."
  
  "It's not just about the Conglomerate, is it?" Damon points out. "There are thousands of human lives at stake."
  
  "And why should we care?" Hadaly shrinks as all three metas start shooting daggers at her. "Sorry. What I meant is… ${name} just saved me from my evil ex-husband. I think we deserve to celebrate, and that requires getting out of this moon alive."
*elseif team_stat = 2
  "Don't worry, we'll help you… right?" Damon asks hesitantly, his blue eyes fixed on yours. "I don't want to fail anyone else today, boss."
*else
  "I know you're not longer under my command, ${name}," @{(RookRel >= 50) Kirill|Rook} says, forgetting both your pseudonym an his hate of contractions. "But if you could help us not die… I'd really appreciate that."

You look to the sky. It's a ceiling of diseased, evil grey, but the World Engine still shines upon it. The metas should be about as strong as when you first met them—formidable as long as they work together, but not equal to an entire armed battalion. Not on their own, in any case.

*if health = 3
  Your body is fully functional. You feel as well as you can, given your age and the situation you're in. If you want, you can turn the tide of this battle… in favor of whichever side you choose.
*if health = 2
  However… you're not entirely sure how much help you can be. Your body has been badly damaged by the gyrojet bullet, and your battery far from full. The building before you may well become your grave, even if you manage to stop Da-xia from unleashing her nanites.
*if health = 1
  You are significantly worse off. The irreparable damage you've sustained while fighting @{hadaly_alive Hammon|Damon} weighs you down almost as much as your age. If you decide to fight here, on the Trio's side or otherwise… you most likely won't get to see another day. Your life will end here, around your thousandth birthday, inside an already doomed moon.
  
  Joining this battle would be an illogical choice… and yet it tempts you all the same.

You can try to save Rhea, bring the Calypsoans to justice, protect the Solar System from the threat of Dusk. You can help Da-xia, more or less directly, hoping against hope that she knows what she's doing. Or you can maintain neutrality, 
*if heaven_side = "Neutral"
  much like you did during the War In Heaven, 
prioritizing your life over that of others. Your fate, as well as many others, will be determined by one simple choice.


*choice
  #Join the Meta Trio. Attack Da-xia.
    *goto main_path
  #Help Da-xia. Attack the Meta Trio.
    *goto daxia_path
  #Convince the Meta Trio to retreat.
    *goto negotiations
  #Just walk away from it all.
    *goto leave_fight



*label main_path

*set timer + 1

*set TrioStat "serving"

No turning back. No switching sides. This is still your responsibility, and the meta-humans beside you are still your teammates. You'll fight alongside them once again, 
*if Confid < 55
  even if it means finally facing demise.
*else
  and together you'll destroy everything which dares to stand in your way.

*if RookRel > 50
  "You have my back." You look at Kirill as you utter these words. His expression is hidden behind the helmet, but his relief is still palpable. "Now, what's the plan?"
  
  "The plan…" 
*elseif Confid > 50
  "Don't worry, I'm at your side," you loudly announce, causing all three metas to sigh in relief. "Let's save this city. Fast."
  
  "Okay, we…" 
*else
  "Okay, I'm at your side," you state, causing all three metas to sigh in relief. "We'll save this city together… somehow."
  
  "Don't worry, we just…" 
*label main_path2
@{(RookRel >= 50) Kirill|Rook} calms himself with a deep breath. "We just need to break through their defenses and locate their artifact. I should be able to recognize it once I see it. I can detect nanobots as well as influence them."

"Right. Your meta-human abilities, the same you used in the laboratories of Titan," Da-xia remarks. Her voice is fairly tranquil, but you can tell you've upset her. Scared her, perhaps. "Do you believe you'll redeem yourself, @{(crystal_stat != 3) Sergeant|Captain} Kosteniuk? That you'll erase all the harm you've caused by preventing an act of far lesser destruction?"

"You will not get a rise out of me." @{(RookRel >= 50) Kirill|Rook}'s voice, too, is shaking very slightly. "God, my Lord in Heaven, has forgiven my sins long ago."

"Is it his forgiveness you want?" Da-xia asks casually. She gets no reply, but it's not like she hoped for any. She knows the answer as well as @{(RookRel >= 50) Kirill|Rook} does. "What about you, ${name_daxia}? What's your motive for throwing your life away?"

*temp demoralized false

*fake_choice
  #"You're crazy and need to be stopped. Is that not reason enough?"
    "You'd call me insane?" Da-xia balks. "Me, one of the great sages of Calypso?"
    
    "No. Calling you [i]insane[/i] would imply an actual mental illness," you reply @{(Emotion > 50) with a smirk|calmly}. "You're just batshit crazy."
  *if DaxiaRel > 50
    #"I cannot let you kill yourself. You simply mean too much to me."
      *set LisaRel %- 10
      Da-xia takes a moment to reply, as though stunned by your words. "You would destroy my grand design… out of concern for me?"
      
      "Your grand design ends with your death," you state @{(Emotion > 50) sadly|calmly}. "I cannot allow it."
  *if Confid > 50
    #"Throwing my life away? Please. I'll defeat you without even breaking a sweat."
      *set Confid %+ 15
      "Aren't you a little full of yourself?" Da-xia huffs. "I have a hundred men here, all in advantageous positions and ready for battle."
      
      "A hundred humans, you mean," you correct helpfully. "I'm sure there are at least two or three women in your army, and that they'll fall just as easily as the rest."
  *if Misan < 50
    #"You're trying to kill innocent humans. I shan't allow it."
      *set RenfriRel %+ 5
      *set RookRel %+ 5
      *set Misan %- 15
      "I'm putting those humans out of their misery," Da-xia argues. "You've seen how they live. They'll be happier dead."
      
      "That is not for you to @{(Emotion > 50) decide!" you shout at her.|decide," you say calmly.} "You have no right to destroy this city, and so I'll protect it."
  *if Misan > 60
    #"You are about to kill thousands, perhaps millions of humans. Death is too good for them, and so I cannot allow you to succeed."
      *set Misan %+ 20
      *set RookRel %- 10
      *set RenfriRel %- 10
      "Some lives must be sacrificed for the greater…" Da-xia pauses, only now registering your words. Realizing they were not what she expected. "Wait, what did you just say?"
      
      "Death signifies the end of suffering," you explain calmly. "At the very least, it ends suffering in [i]this[/i] life, the only kind I can witness and savor. I want humanity to suffer, and so I shall protect it."
      
      "But… I'm going to feed all these people to Dusk!" Da-xia protests. "Not to mention all these [i]thousands[/i] of new Vessels which I'm about to create. Isn't that enough suffering for-"
      
      "No." Your voice is 
      *if Emotion > 50
        growing louder, more elevated, more furious.  
      *else
        cold and hard, unflinching and merciless, fueled by the arctic hatred of your synthetic soul. 
      "I've watched humanity decay and suffer for a thousand years, seen the squalor you force each other into, reveled in the torments and degradations you inflict upon one another. I want mankind to continue rotting, continue destroying itself, continue suffering for as long as possible. Only after another millennium of degradation and torment, only after a trillion of painful births and agonizing deaths, only once you've suffered beyond the wildest nightmares of Dusk itself will the barest [i]fraction[/i] of my hatred finally be  
      *if Emotion > 50
        satisfied!"
      *else
        satisfied."
      
      *if team_stat = 3
        "Wow…" Hadaly takes a step back. "I'm not exactly fangirling over humans myself, but this… would you consider toning down the hatred? I think it could make you a bit happier." 
      *else
        "Guys, I think ${pronoun} might hate humans," @{(LisaRel >= 50) Lisa|Hellhound} observes. "Or at least harbor some slight dislike for us. Just a hunch."
      
      *goto psyche_out
  #"I came here expecting to die. I might as well take you with me."
    "So you would foil my plans and sabotage the greater good out of… spite?" Da-xia sounds bewildered.
    
    *if Emotion > 50
      You smile, even though she won't see that. "You have deceived me. I will enjoy punching the life out of you, even if it's followed by death." 
    *else
      "Out of indifference," you correct her. "At this point, it's all the same to me. I might as well do as the @{(crystal_stat != 3) Sergeant|Captain} says."
  #"If you unleash Dusk on this city, I'm likely to die regardless. I might as well improve my chances."
    "Everything has been precisely calculated," Da-xia drawls. "You can still make it out of the city, if you start running at once."
    
    You reply, "I have no particular reason to believe you. You may end up destroying this whole moon by accident… or maybe even on purpose. I've made my choice."
  #Say nothing.
    You won't humor her with a response. You suspect it will infuriate her, damage her ego beyond repair, and you are quickly proven right.

"You ignorant machine!" Da-xia's voice gets louder, as well as more… theatrical. You suspect everyone inside the power plant is listening to your conversation now. "I thought you'd see reason, perhaps even hear the wisdom of my words. But you choose to obstruct the Bayesian Path with your own body, deny happiness to your creators, raise a hand against your allies. The Federation is right about your kind—you're a malicious Fiend, nothing more and nothing less."

*if team_stat = 3
  "So much for tolerant Calypso," Hadaly remarks. "You humans are all alike, no matter how much you pretend otherwise."

*if (Social > 50) or (Database > 50)
  You realize this is your chance to psyche-out the Calypsoan. To break the enemy morale, perhaps scare away some of them before the battle even begins. You just need to pick the right words.


*choice
  *selectable_if (Confid > 60) #"You are scared. I can hear it in your voice."
    *set Confid %+ 15
    "How would you tell?" Da-xia scoffs. "You're just a machine. I doubt you even understand human emotions."
    
    "You're right." Your voice is calm, stern, unyielding. "I lack many emotions which plague your kind. I know no fear, for example, and I certainly don't fear your sorry excuse of an army."
    
    "You should. We outnumber you fifty to one. Your team stands no chance-"
    
    *if heaven_side = "Neutral"
      "Did I stand any chance of surviving for a thousand years?" you interrupt her. "I lived through the War In Heaven [i]on my own[/i]. I was hunted by your kind, I was hunted by the rebels, I was pursued by everyone and yet here I stand. What makes you think [i]you[/i] will be the one to kill me?"
    *else
      "I fought the War In Heaven," you interrupt, raising your voice ever-so-slightly. 
      *if heaven_side = "Traitor"
        "The Architects would send armies of humans, flocks of dragons, their own champions in a hopeless effort to get rid of me. 
      *else
        "I was on Eris when the Traitors broke it, fought demonic hordes at the height of their power and [i]I lived[/i]! 
      Even the gods know my name, and yet [i]you[/i] expect to defeat me? I think we both know how this battle will end."
    
    *goto psyche_out
  *selectable_if (Violence > 60) #"I will crush your skulls, much like I crushed thousands before you."
    *set RenfriRel %+ 8
    *set RookRel %- 8
    *set Violence %+ 15
    "Crush our skulls? Such a childish, unoriginal insult," Da-xia mocks you. "Will you also threaten to bathe in our blood?"
    
    "Forgive me for my lack of creativity, Great Pandit." 
    *if Emotion > 50
      There is restrained anger in your voice, the kind which no human would ever be capable of. 
    *else
      Your voice is calm, almost eerily so. 
    "When you studied rhetoric, I was busy methodically destroying 
    *if heaven_side = "Traitor"
      armies of dragons on behalf of the Syndicate. 
    *if heaven_side = "Neutral"
      teams of android hunters continuously sent after me. 
    *if heaven_side = "Loyalist"
      all the demonic armies the Syndicate sent after me. 
    Oh wait, it was actually centuries before you were even born—it's easy to forget just how much I surpass 
    *if Misan > 50
      meatbags like you 
    *else
      ordinary humans 
    when it comes to experience."
    
    *goto psyche_out
  *if official_ro = "lisa"
    #♡ "So, Lisa... How's that for a date?"
      *set LisaRel %+ 20
      "You want me to treat this dramatic, nigh-suicidal battle as our date?" Lisa taps her chin thoughtfully. "It's not how I imagined our dates would look like… But killing Da-xia together [i]does[/i] sound like fun."
      
      "Lisa, I'm happy for you, but is this really the time?" @{(RenfriRel >= 50) Renfri|Marshal} says testily. "You can discuss your relationship with ${name} later."
      
      "No, I think it's an excellent time," the redhead starts grinning. "Should we drink Da-xia's blood right after we kill her, or while she's still alive? We need to decide right away, we'll be ripping her heart out in three minutes tops."
      
      "Is this some half-hearted attempt at scaring me?" Da-xia says through the speakers. "Why would I be afraid of my blood being drank? I hardly care about the specifics of my death."
      
      "So you admit that death is coming?" Lisa's smile only grows wider. "That your puny battalion is not enough to stop the infamous werewolf and her indestructible android boyfriend?"
      
      "…I said nothing of the sort," the Pandit protests. "We will prevail. Most certainly."
      
      *goto psyche_out
  #"You're all bark. Show me some bite, will you?"
    "With pleasure," Da-xia says dryly. "I will not let you thwart my plans. You'll die on this doorstep, and the Solar System will be better for it."
    
    *goto regular_out
  *selectable_if (Misan < 40) #"I am the shield of humanity. Now and forever."
    *set Misan %- 15
    "Shield of humanity?" Da-xia drawls out. "Big words for  
    *if heaven_side = "Traitor"
      a former champion of the Synthetic Syndicate."
    *if heaven_side = "Neutral"
      someone who refused to fight in the War. Have you changed your mind since?"
    *if heaven_side = "Loyalist"
      someone currently raising a hand against ${subject} creators."
    
    *if heaven_side = "Loyalist"
      *if Emotion > 50
        You grimace as memories of ancient past, images of a war long won, fill you with righteous fury. 
      *else
        Your voice is calm and steady, unyielding in its promise. 
      "I once spent a century scouring the Solar System, fighting on its every planetary orbit, freeing it of traitor scum. Right now, you and your men are traitors to humanity, and I will punish that betrayal with death. Get ready."
    *else
      "I made mistakes," you say heavily, but without stutter. "But no more. I won't let you hurt even a single innocent person, human or otherwise, even if it means…"
      
      You clench your fists. You know you won't enjoy what's about to transpire, but you hardly have any choice. No more running. "Even if I have to personally kill each and every one of you."
    
    *goto psyche_out
  *selectable_if (Emotion < 40) #"Resistance is futile. And I think you realize that."
    *set Emotion %- 15
    "What do you mean?" Her voice waivers ever-so-slightly. "We outnumber you fifty to one. There's nothing for you and your friends to possibly accomplish."
    
    "I see your weaknesses." Your voice does not waiver. It's cold, serene, emotionless, robotic. "You may claim to be enlightened, but you still think in human categories. You still fear, you still boast, you still hesitate. Your mind is as weak as your flesh, and so you're only fated for failure and death."
    
    *goto psyche_out
  #"Enough talking. Is everyone ready?"
    *if RenfriRel > 50
      "Between you and me, I'm not entirely sure," @{(RenfriRel >= 50) Renfri|Marshal} says quietly. "But we're not getting any more prepared, so let's just get this over with."
    *else
      "Between my sword and my powers, I feel pretty prepared," @{(LisaRel >= 50) Lisa|Hellhound} says with a grin. "Let's let a rip."
    
    "I couldn't agree more," Da-xia says dryly. "Let's see how tough your makeshift band really is."
    
    *goto regular_out
  *disable_reuse #"You've convinced me. I will not fight you. I think I'll just run away instead."
    *goto leave_fight2



*label psyche_out

*set demoralized true

You can just barely hear some muffled sounds coming from inside the power plant. It could be practically anything… But you suspect several soldiers just dropped their weapons, and that several more are currently scrambling for the building's back exit. 

"We both rather enjoy talking, it seems," Da-xia says dryly. "But only one of us has an army. Good luck fighting through it."

*label regular_out

*set RookRel %+ 20
*set RenfriRel %+ 20
*set LisaRel %+ 20
*set DaxiaRel %- 20
*if hadaly_free
  *set HadalyRel %- 20

No more sound comes out of the speakers and, somehow, you can tell they've been disconnected entirely. Even Da-xia had enough talking… or perhaps she's diverting all power to that swarm she hopes to unleash. You'll find out in a moment.

*if team_stat = 1
  *label started_get
  
  "Okay, let's get started." @{(RenfriRel >= 50) Renfri|Marshal} spreads her wings. "I'll barge in first, break their barricade with the sheer force of impact, then hopefully roast some soldiers. Lisa, I think it's dog time already."
  
  "I think I'd rather trust my blade." Lisa grips her vibro-sword tightly. "I haven't used it in a while and… I kinda feel it's now or never, you know?"
  
  *fake_choice
    #"Excellent. Now let's get this party started."
    #"Right. Because you might get exploded any moment now."
      "Can we not talk about [i]that thing[/i]?" @{(RenfriRel >= 50) Renfri|Marshal} requests. "Let's not remind our enemies it's an option."
    *if lisa_origin_learned
      #"I think there's another reason why you won't transform. And it's not very good."
        *set LisaRel %+ 10
        @{(LisaRel >= 50) Lisa|Hellhound}'s eyes narrow slightly. "Are you interrogating me? Or trying to have a heart-to-heart conversation? Because we don't have time for either."
    #"But... why? Don't you like going feral on people?"
      "There's no time to explain." @{(LisaRel >= 50) Lisa|Hellhound} looks at @{(RookRel >= 50) Kirill|Rook} strangely, as though asking him for assistance. "Right?"
    #"This isn't the time to experiment with your fighting style, Lisa."
      "I'm pretty good with a sword," @{(LisaRel >= 50) Lisa|Hellhound} protests. "Besides, is this really the time for arguments?"
    #"Enough talking! We really ought to hurry."
  
  "Indeed." @{(RookRel >= 50) Kirill|Rook} activates his hardlight projector. An ethereal spear forms in his hand, light solidified into a deadly weapon. "Meta Trio, attack!"
  
  Both @{(RenfriRel >= 50) Renfri|Marshal} and @{(LisaRel >= 50) Lisa|Hellhound}, for once, obey the command immediately. They start running towards the barricaded entrance, as does @{(RookRel >= 50) Kirill|Rook}, as do you. It's high time to end this, all of this, once and for all.
  
  *if (Confid < 50) or (health = 1)
    Even if [i]all of this[/i] includes your own life.
  
  *goto attack_begins
*if team_stat = 2
  "So… do you want me to help out?" Damon asks a moment later. "I could. It seems like a worthy cause, and I owe you at least that much after… everything."
  
  *fake_choice
    #"Yes. I would highly appreciate that."
      "Then I'll give you something to appreciate." Damon smiles weakly. "Assuming you survive this battle, that is."
    *if s9_leader = "player"
      #"Yes. As your commander, I order that you stay and fight."
        "I'm not sure [i]commander[/i] is the right term in a group as small as ours," Damon smiles bitterly. "But I will follow you. All the way to the end."
    #"Your help [i]would[/i] come in handy. But it's your choice to make."
      *set DamonRel %+ 15
      "I already decided I'd stick with you no matter what," Damon says seriously. "I'll help you. If we die here, then at least we'll die together."
    #"I'd never ask that of you, my @{(official_ro = "damon") love|friend}. Run and be safe."
      *set DamonRel %+ 8
      *set team_stat 1
      "I'd say the same to you, but…" Damon looks away. "You've already decided against safety. So I'll just wish you good luck and… I hope we'll meet again."
    #"You don't owe me anything, Damon. Other than maybe getting to safety."
      *set team_stat 1
      "Then that's what I'll do, I guess," Damon sighs. "I'm not saying you'll die out there, but still… It's been fun knowing you, boss."
    #"I don't need your help. Go away."
      *set DamonRel %- 15
      *set Confid %+ 10
      *set team_stat 1
      "Are you really that confident? Or are you saying that for my benefit?" Damon studies you with his sapphire eyes for a moment. Then closes those eyes. "Whatever. Good luck out there, boss."
  
  *if team_stat = 1
    You watch Damon walk away, a little slower than you would have liked. This may be the last time you see him, and while part of you resents that fact… another part knows that it's probably for the best.
  *else
    "So it's five of us against… two hundred Calypsoans?" @{(LisaRel >= 50) Lisa|Hellhound} takes a guess. "Fifty to one sounds bad, but you two are absolute units. We'll prevail."
  
  *goto started_get
*if team_stat = 3
  "I suppose you made your choice," Hadaly says neutrally. "Where does that put us? Do you want our help?"
  
  "I can join the battle, if you don't mind sharing the glory." Damon tries to sound calm and nonchalant. Tries. "I'm just… not sure if you think it's the right idea."
  
  *fake_choice
    #"It's not. I need you two to retreat, return to [i]Saturn Nine[/i]. Be safe."
      *set team_stat 1
      "We will," Damon promises. "Though not thanks to our efforts."
      
      You raise an eyebrow. "What do you mean?"
      
      Damon shrugs. "Well… it's all because of you. You took care of Hammon. You made sure Crystal is no longer a threat. We'll finally be safe, and it's all thanks to your efforts."
      
      "That sounded a bit too self-deprecating for my liking," Hadaly remarks. "But… I agree. Thank you for everything, ${name}, and farewell."
    #"I don't need your help. Me and the Meta Trio are more than enough here."
      *set team_stat 1
      "If you say so…" Hadaly looks at you skeptically. "I appreciate that you're not pulling me into this mess, if nothing else. Though I'd be more grateful-"
      
      "Let's go, sis." Damon grabs her hand. "${name} just wants us to be safe. Let's respect that."
    #"Hadaly, I'd like you to accompany me. Damon, can you please... leave?"
      *set team_stat 1
      *set HadalyRel %- 10
      *set DamonRel %- 10
      "You want [i]me[/i] to do the fighting? And leave Damon out of it?" Hadaly sounds unamused. "${name}, I feel nothing but respect and gratitude towards you… But that's a bloody stupid idea."
      
      "I've got to agree with her, boss." Damon grasps his sister's hand protectively. "If you really need to help the metas, do it yourself. Don't drag her into this."
      
      Well, that could have gone better. Looks like it's just you and the Meta Trio facing really unfavorable odds.
    #"I want your help, Damon. Hadaly can return to the shuttle if she wants to."
      *set DamonRel %+ 10
      *if HadalyRel > 50
        Hadaly shakes her head slowly. Her eyes are brown, and you have no idea what that means. "No. Not after 
        
        Damon nods. "Right. I'll gladly help you, and if my big sister wants to join too… Calypsoans don't stand much of a chance, do they?"
        
        "No." You smile as you look at your fellow androids. 
        *if (official_ro != "damon") and (official_ro != "hadaly")
          Your friends. 
        "I suppose they don't."
      *else
        "That's… not the worst idea you've ever had." Hadaly starts backing away. There is relief on her face, but also worry in her eyes. "Will you be okay in there, Damon?"
        
        *set team_stat 2
        
        "I'm not really sure." Damon grips his rifle. "But I can't just sit back and watch others fight. I need to be use… I need to participate."
    #"I'd gladly accept your help. We need all the firepower we can get."
      "I'm not sure how much [i]firepower[/i] I can provide… But I will come with you," Hadaly says tensely. "It's not like I can just abandon you. Not after everything you've done for us."
    #"That's your choice. Do you want to fight this battle?"
      "Sure. I can't really leave you, not after everything you've done for us." Damon turns towards his sister. "You?"
      
      *if HadalyRel > 50
        Hadaly closes her eyes for a moment. When she opens them again, they're a shade of dark brown, a color you've never seen in those irises before. "Yes. I'll help you stop… kill these humans. It's not something I want to do, but if it's necessary… Let's show them what we're made of."
      *else
        *set team_stat 2
        Hadaly shakes her head slowly. "No. My apologies, ${name}, but I'm just not cut out for…. this. I'll just stay here, wish you good luck, and maybe patch the two of you up afterwards."
        
        Does she honestly believe you'll walk out of this power plant alive? Or is she just trying to keep your spirits up? Hard to tell.
  
  *if team_stat = 1
    You watch Damon and Hadaly scurry away. You're not sure if they can outrun the blast, or if they'll be safe even upon reaching the shuttle, but that's just life. There's no such thing as true safety.
  
  *goto started_get


*label attack_begins

*page_break

*set explosion_prevented true

Breaking through the barricade which blocks the main entrance is a rather trivial task. The building's entrance was never meant to be fortified, and the Calypsoans didn't have much time to reinforce the huge double door. It is opened, and the items behind it go flying with a single flap of @{(RenfriRel >= 50) Renfri|Marshal}'s powerful wings.

What's behind these doors… That's a bit more of a problem.

The entrance leads directly to the main chamber, a hall large enough for an entire tokamak to fit inside, and that means lots of place for people with guns. Calypsoans open fire almost immediately, a wild barrage of lasers and bullets, weak individually but deadly in their dozens. Hundreds, once the shock of your entry wears off and all soldiers in the spacious room—for they are undeniably professional soldiers, dressed in flak jackets and wielding automatic rifles—leap out of their makeshift covers and start blasting at your tiny team.

Only one of them doesn't shoot, only one stands out from the hundred-strong battalion. A red-skinned man in a full suit of carapace armor, holding a large sword in his left hand. 
*if visited_scott
  Major Scott, the Calypsoan officer you talked to during your visit to the moon. Perhaps Da-xia convinced him to lead her force, perhaps she forced him somehow, or perhaps this whole operation is partially his idea. 
*else
  He might be the commander of this unit, or perhaps its champion, or just some particularly strong mercenary Da-xia hired. 
He says something to the infantry squad beside him—his exact words are impossible to make out in all this gunshot noise which fills the hall.

A slug bullet hits you in the arm almost immediately. It's a gunpowder projectile, a primitive thing, but the direction from which it flew is telling. There are gunmen in front of you and to your sides, surrounding you and the metas in a semi-circle. It's not an advantageous position to be in, but you [i]are[/i] the Veteran, and so you know just what to do.

*fake_choice
  #Rush forward until the soldiers surround you from all sides. They'll soon be shooting one another.
    *if Build < 65
      *set health - 1
    It's the simplest possible tactic in this situation, yet it surprises the enemy soldiers greatly. They must have expected you to retreat, to take cover, to do some pragmatic or cowardly thing like they would in your situation. Instead, they fail to understand what's happening until your whole team has reached the middle of the room and some light friendly fire has already occurred.
  #Turn to the side and push towards one of the corners. It will be easier to make a stand there.
    *set pacifist false
    The room is filled with makeshift covers, tables and rubble arranged in a way that provides the Calypsoans with protection against ranged attacks. Sadly for them, you're not exactly limited to [i]ranged[/i] combat.
    
    Your whole team converges on one of the corners where about a dozen soldiers made their stand. They are taken aback, those uniformed grunts, as @{(RenfriRel >= 50) Renfri|Marshal} almost knocks them off their feet with a single wave of force. They struggle to defend themselves against @{(LisaRel >= 50) Lisa|Hellhound} as she starts cutting them up with her sword, or @{(RookRel >= 50) Kirill|Rook} as he lunges at their sergeant with the hardlight spear. 
    *if team_stat > 1
      Damon finishes off the last two with the power of his fists, then grabs his electron rifle again and prepares to take a stand.
    *else
      You contribute too, 
      *if weapon = "pistol"
        using your pistol to deliver point-blank shots, 
      *if weapon = "knife"
        making excellent use of your combat knife, 
      *if weapon = "none"
        cracking skulls and delivering shocks, 
      until there are no longer any hostiles left on this side of the hall.
    
    Having acquired your cover and defensive position, you proceed to fight more methodically and carefully. 
    *if weapon = "pistol"
      Now that there's distance and obstacles between you and your enemies, you have to properly aim your shots to make them lethal. 
    *else
      Not possessing a proper ranged weapon and somewhat low on battery, you mainly observe as your allies take down one enemy after another. 
    *if team_stat > 1
      Damon is quite precise, and his electron rifle is powerful enough to kill most hostiles with one shot. 
    Renfri is helping with her laser headband which, despite not being the most powerful of weapons, works pretty well against the Calypsoans' flak armor. Even Kirill contributes a bit by throwing his spear, de-materializing it, creating another and then throwing again. His lightning projector really is a great weapon, and he finally has a chance to use it properly.
    
    *if Build < 55
      *set health - 1
      However, there are quite few good shots in enemy ranks, and they still see you as the primary threat. You take several shots to the chest, in spite of the wooden desk you hide behind whenever you see someone aim at you.
  *selectable_if (Build > 65) #Jump high into the air, then land in the middle of their formation. They won't expect that.
    *set pacifist false
    The soldiers were likely informed that they would be fighting an android. They probably expect you to be much tougher, somewhat stronger, perhaps slightly faster than a regular human. As such, they are [i]not[/i] prepared for what happens next.
    
    You jump high, far higher than any human ever could, to the point where you hit the ceiling several meters above. You use that to your advantage, bouncing off said ceiling and dashing towards your enemies with yet increased speed. They scarcely have the time to react, other than with open mouths and terrified expressions.
    
    The first Calypsoan you strike, split second before actually hitting the floor, dies instantly. The sheer force of your punch, combined with that of your momentum, simply pulverized his bones and reduces the organs beneath to a bloody mush. Not that you linger on that gory sight—the moment your feet are touching the ground again, you are already on the move, striking another soldier with your fist and then kicking his nearest comrade. Neither will ever walk again, assuming they even survive the upcoming slaughter.
    
    Though your enemies number in the dozens, those few deaths are enough to utterly break their cohesion. An android as terrifying as you, in the very heart of their formation, is an unexpected wrench in their great work. They no longer have the advantage of distance and can no longer follow their battle plan, left with only numbers and zeal to aid them.
  #Hide behind Kirill and advance. His armor should absorb most damage.
    *set RookRel %- 20
    *set RenfriRel %- 10
    You don't suppose @{(RookRel >= 50) Kirill|Rook} appreciates being used as a human shield, but screw that. His armor is tough enough to simply deflect most bullets and absorb laser beams with minimal overheating. Calypsoan soldiers don't seem to realize that, not until they've wasted much of their ammo and lost the advantage of distance.
    
  *selectable_if (team_stat > 1) #Send Damon in first. He's a big guy, he'll take most shots.
    *set DamonRel %- 15
    *if team_stat = 3
      *set HadalyRel %- 15
    You don't suppose Damon appreciates being used as an android shield, but he gets the job done without complaint. Through being the first and the largest opponent enemy soldiers see, he becomes an obvious target. Bullets and lasers puncture his maroon suit and likely damage his skin, but not enough to slow him down; He quickly starts gunning down hostiles with his electron rifle, showing remarkable precision as well as endurance.
    
  *selectable_if (team_stat = 3) #Ask Hadaly to protect you.
    "Hadaly!" you yell as you fall prone, hoping to avoid some of the bullets that way. "Protect us!"
    
    "How would she!?" @{(RenfriRel >= 50) Renfri|Marshal} yells as she flies upwards, willing to attract most of the soldiers' attention. She pays for it quickly with a bullet to the wing, but somehow stays aflight. "She doesn't even have a weapon!"
    
    "But this [i]is[/i] a power plant!" Hadaly shouts back. "Now close your eyes!"
    
    You obey, and yet you still see a flash of azure light through your eyelids. You're not sure what Hadaly does, but when you open your eyes again, you see the floor littered with twitching bodies. The soldiers who still stand are struggling with their own rifles, hopelessly trying to fire broken weapons, or simply running away in fear of what they've just witnessed.
    
    Energy projection. 
    *if Projection > 50
      Just when you fought yourself the master of it, Hadaly pulls off something like that. Go figure.
    *else
      You should probably start training it. The results speak for themselves.
    
    "I thought robots would be more vulnerable to electric blasts than humans," @{visited_scott Major Scott|the red-skinned man} says as he activates his bone-sword, putting its razor-sharp teeth into motion. "Let's see what other resistances you have."
    
    *goto scott_charge
  *selectable_if (Projection > 65) #Magnetically push most bullets away.
    *set battery - 10
    *if battery < 30
      *set health - 1
    Normally, you'd never do anything quite so fancy in combat. It's not worth it when there's just a handful of bullets flying your way, and it wouldn't work on any expensive or advanced projectiles. But now… Maybe you should show the warriors of Calypso just why conventional firearms went out of favor.
    
    You create an electromagnetic field around yourself, invisible but strong. The soldiers don't realize its existence at first, but the bullets they shoot are all being re-directed, harmlessly hitting the walls and the floor instead of you or your companions. Once you're sure this shield will hold, you start using energy projection in a more direct way, blasting one enemy soldier after another with miniature lightning strikes.


*if health = 0
  *label death_sorry1
  
  You take down about a dozen soldiers and wound many more… but you're already damaged yourself. And that damage gets worse with every bullet, your system overheats more and more with every laser beam, until-
  
  *label death_sorry
  
  You cannot
  
  Your processors fail, they
  
  One more bullet, perhaps a sniper one, to the place [i]where[/i] brain
  
  you break like all [b]machines[/b] do like
  
  you cannot GO on aNy longer…
  
  …
  
  You're finished. Your body hits the floor. It's over.
  
  *set pc_dead true
  
  *finish

These soldiers… you can see the white of their eyes, as well as the madness behind them. They've all been indoctrinated, pushed onto the Bayesian Path, made into crazed zealots by Da-xia and her fellow Pandits. 
*if demoralized
  And yet, once they look into [i]your[/i] eyes and glimpse your 
  *if Emotion > 50
    burning rage… 
  *else
    cold conviction… 
  Their zeal recedes and gives way to ordinary, human fear.
  
  One by one, they flee. At first, they try to maintain an appearance of coordination, of simply falling back to a more advantageous position, but their panic soon becomes palpable. They are just humans, facing a trio of super-human warriors and—perhaps more importantly—
  *if team_stat = 3
    a trio of androids, creatures far beyond their kind, united under your command.
    
    *if Misan > 50
      They understand now. They understand that, no matter what they've told themselves before, they're not the pinnacle of evolution. That a machine, even one made in their own pathetic image, is far greater than anything soft flesh could ever offer. That their species will go extinct sooner or later, that nobody will miss their odious presence, and that [i]you[/i] are the inheritors.
  *else
    an ancient warrior who promised them death and is soon about to deliver. One of the oldest beings in the Solar System, one of the last survivors of the War In Heaven, the most dangerous creature they ever encountered in their short, feeble lives.
    
    The Veteran.
  
  And so they retreat. One by one, dozen by dozen, score by score. After a minute of fighting, there's only six or seven of them left, unless you count all the corpses scattered throughout the room.
  
  *label irracow
  
  "You irrational cowards!" @{visited_scott Major Scott|the red-skinned man} yells. "You abandoned your moral duty! But I shall not!"
  
  *goto scott_charge
*else
  They won't back down, and so you need to kill them all swiftly. 
  
  *fake_choice
    *selectable_if (weapon = "pistol") #Shoot them all, one after the other.
      *set pacifist false
      Your pistol may not be a very long-ranged weapon, but the hall isn't [i]that[/i] large. You can still see your enemies clearly, and that means you can kill them reliably.
      
      You don't bother aiming for their heads or hearts. That would be amateurish, wasteful and completely unnecessary given their relatively weak armor and shields. You just aim for the center of mass, each and every single time, downing one enemy with almost every shot. Your enemy's fanaticism only works in your favor—expecting to die anyway, the soldiers don't make optimal use of cover, and don't actually seem to mind getting shot all that much.
      
      *if Calculation < 60
        That's not to say you don't take any damage yourself. You try to be quick as you jump in and out of cover, but you're not perfect, and your enemies aren't completely incompetent. Bullets and lasers alike harm your aged, synthetic body.
        *set health - 1     
      
      *if health = 0
        *goto death_sorry1
      
      After about minute, thanks to the combined efforts of you and 
      *if team_stat > 1
        your friends, 
      *else
        the metas, 
      almost nobody is left on the room's other side. The survivors are mostly greenhorns and cowards who changed their minds about dying for the cause and are currently curled behind sofas and tables. You don't imagine they'll pose any threat, even if you decide to let them live. 
      
    *selectable_if (weapon = "knife") #Get close, then start slashing away with your dagger.
      *set pacifist false
      Bringing a knife to a gunfight isn't usually the best idea… but you're very experienced and inhumanly strong, which cannot be said of your opponents.
      
      You stab the one closest to you in the throat. You wouldn't usually do that when facing multiple hostiles—for fear of the dagger getting stuck—but human flesh is soft, and so you're able to instantly rip the blade out and slash another soldiers across his face, destroying both of his eyes in one movement.
      
      You ignore his guttural scream and keep moving. One soldier after another, then another, then another, then another. They lack melee weapons, 
      *if Calculation > 45
        or your superhuman speed. 
      *else
        those enlightened Calypsoans, so obsessed with their [i]practical[/i] firearms. 
      It takes you perhaps thirty seconds to reduce their number by half.
      
      *if Build < 60
        *set health - 1
      
      *if health = 0
        But… you still brought a knife to a gunfight. And though you're durable, you're not nearly tough enough to shrug off every point-blank shot you receive during your rampage. You made a mistake, and you're about to suffer the consequences.
        
        Eventually, one of the gunners gets lucky, putting a bullet not just in your neck, but in the exact place where your main processor is housed. You cannot really aim now, you cannot really think, you cannot really fight, you…
        
        *goto death_sorry
      
      By the time this minute ends, almost nobody is left. It's not entirely your accomplishment, the metas 
      *if team_stat > 1
        and Damon 
      certainly help by providing fire support, but your dagger is the true instrument of death here. 
      *if heaven_side != "Neutral"
        Any weapon would in your hands, for you're ${master}'s greatest champion, even after nine hundred years.
      
    *selectable_if ((Projection + battery) > 110) #Emit a chain lightning, the kind none of them has ever seen.
      *set pacifist false
      *set battery - 20
      Energy projection is, in itself, something impossible. Electricity should not be manipulated like this, focused into "blasts" and "discharges" by the mere power of your mind. But you're miracle of technology, a relic from the Age of Light, and that lets you go beyond the impossible.
      
      The lightning strike which soon illuminates the hall is no mere discharge, an imbalance of electric charges between two points. It's a mad flow of electrons, an arc of purest power which scorches the skin of almost every Calypsoan soldier. You feel it too, everyone does, but you and your companions are strong enough to survive this destructive outburst. Mere humans cannot.
      
      When the sound of thunder stops echoing throughout the wide chamber, there is almost nobody left standing. Some soldiers are undoubtedly still alive, twitching in their final agony, but the only ones untouched by the deadly lightning are those guarding the exits. None of them looks particularly stronger the rest, or more eager to attack you right after this display of power.
      
    *selectable_if (Social > 65) #Kill them? No. Convince them to lay down their weapons.
      You don't suppose those zealots can be reasoned with, that they're anywhere near as rational as they'd like to believe. They're just fools who allowed a cult leader to herd them towards painful death… But maybe you can take advantage of that foolishness.
      
      "It's hopeless!" you shout loudly enough for everyone in the hall, perhaps everyone in the building, to hear you clearly. "There's no way to win and no way to find the Dusk artifact in time. Da-xia cannot be stopped!"
      
      "What?!" @{(RenfriRel >= 50) Renfri|Marshal} yells as she fries yet another soldier. "What are you babbling about? We're winning, we just-"
      
      "$!{pronoun}@{plural 're|'s} right!" @{(LisaRel >= 50) Lisa|Hellhound} interrupts, picking up on your intent. "Half their army could flee at this instant and it would make no difference. Let's just run and escape this city, there should still be enough time."
      
      On the whole, the horde of Calypsoan soldiers you're facing is certainly devoted and brave. They came here with the full expectation of dying and many of them [i]did[/i] sacrifice themselves for the cause. But now that the true martyrs have perished and the survivors think the battle is already won… They start questioning whether further sacrifice is strictly [i]necessary[/i] at this point.
      
      One by one, they flee. Each of them believes that only he, and perhaps a single-digit number of others, will get away alive. That their cowardice will mean nothing, that it can only improve the final outcome, that it cannot possibly impede the Great Pandit's plans. They think like individuals rather than a collective, and this human weakness first decimates, then halves their dwindling number.
      
      Two minutes later, almost nobody is left. Just a handful of particularly fanatical soldiers, fighting bravely in spite of their wounds… 
      *if visited_scott
        And Major Scott, of course.
      *else
        And the large, red-skinned man with a fearsome bone-sword at his side.
      
      *goto irracow
    #Let your teammates do all the work.
      *if team_stat > 1
        *set DamonRel %- 10
        *set RenfriRel %- 10
        *set RookRel %- 10
        *set LisaRel %- 10
        It's not very supportive, not in the spirit of teamwork for you to just lay back and let others do all the work. But between Damon and the Meta Trio, your team has more than enough firepower to handle the enemy horde. They all get shot once or twice—
        *if team_stat = 3
          even Hadaly gets a bullet to the shoulder, despite trying to stay out of the way—
        *else
          Damon significantly more than others, being a large and obvious threat—
        but they can mostly shrug off that kind of gunfire. Calypsoan soldier cannot, and so they fall one by one.
      *else
        You're content with letting the Meta Trio do all the fighting for you… but a trio is not enough. Not against several dozen enemies, not in an enclosed space where they cannot even make full use of their powers. The meta-humans are doomed, and therefore… so are you.
        
        First, Renfri gets shot. Not in the wing, where the wound could plausibly be ignored, but in the chest. Lisa follows soon after,, shot in the head when she runs up to her downed teammate. There might be a sniper or two in the enemy ranks, or perhaps the Calypsoans are finally getting lucky.
        
        You consider changing your plans, getting out of this mess by running away, but then a large bullet penetrates your neck. Some special one, a gyroject or perhaps a shroom, you cannot tell. You cannot run. You cannot fight. You cannot survive.
        
        *goto death_sorry
  
  But there is one who stands out. It's the man with crimson skin almost entirely covered by armor, still holding his fearsome bone-sword. 
  *if visited_scott
    Looks like Scott isn't backign away, not even after most of his unit has fallen.
  *else
    Whoever he is, he's clearly made out of tougher stuff than the rest.
  
  "And all they had to do was to bide for time." He looks at a nearby corpse with disapproval, then turns back towards you. There is not hatred in his eyes, but the murderous intent is dead. "But no matter. We're close enough."


*label scott_charge

With that, @{visited_scott Major Scott|the swordsman} starts running at you, sword raised and murderous intent in his eyes. You prepare to defend against his charge, 
*if weapon = "pistol"
  shoot him before he can reach you, 
*else
  dodge out of the way or strike him first somehow, 
but @{(LisaRel >= 50) Lisa|Hellhound} runs forward before you can do anything. She intercepts @{visited_scott Scott|the Calypsoan}, clashing her sword against his, struggling yet managing to halt his assault.

"Long time no see, Scott!" @{(LisaRel >= 50) Lisa|Hellhound} grunts as she struggles to maintain the blade-lock. 
*if not (visited_scott)
  *if lisa_origin_learned
    You realize that this warrior must be Sergeant Scott, the one who tried to shoot Lisa all these years ago. 
  *else
    Scott must be the soldier's name, though you have no idea how @{(LisaRel >= 50) Lisa|Hellhound} knows it. 
"Want to have a little heart-to-heart? Reminiscence about the old-"

With violent effort, Scott manages to push @{(LisaRel >= 50) Lisa|Hellhound}'s sword aside. Luckily, the girl makes up with agility what she lacks in strength, jumping back faster than Scott can thrust. The teeth of the bone-sword miss her body by a centimeter.

Unlike 
*if team_stat > 1
  your companions, 
*else
  @{(RenfriRel >= 50) Renfri|Marshal} and @{(RookRel >= 50) Kirill|Rook}, 
who are currently pinned down by what little remained of the Calypsoan unit, you're not engaged in any combat. You could easily interfere and kill Scott, especially if you strike him when he's still distracted… but something tells you @{(LisaRel >= 50) Lisa|Hellhound} may not appreciate that. She seems quite intent on killing Scott himself as she lunges at the warrior again.


*temp about_to_die false
*temp ready_to_help false

*choice
  #Tell @{(LisaRel >= 50) Lisa|Hellhound} to hurry the fuck up.
    "Lisa!" you yell over the sound of clashing blades. "I get it's your fight, but can you transform already? You [i]are[/i] a werewolf."
    
    "I didn't need that form when he first shot me!" @{(LisaRel >= 50) Lisa|Hellhound} shouts back as she ducks under a swing. "I survived, and I'll survive now! Just watch."
    
    *goto watch_fls
  #Kill Scott without preamble.
    *label kill_scott
    *set pacifist false
    *set Violence %+ 10
    You don't wait, you don't announce yourself, and you certainly show no mercy. You simply take several steps to the side, positioning yourself outside of Scott's vision, then 
    *if weapon = "none"
      *set battery - 5
      emit a discharge comparable to an actual lightning. 
    *if weapon = "pistol"
      quickly shoot the Calypsoan in the head. 
    *if weapon = "knife"
      throw your knife at his poorly-armored neck. 
    That's all it takes—his body falls to the floor before he can take even one more swing at his adversary.
    
    To his credit, he doesn't die [i]quite[/i] as quickly as a regular human would. He must have been somewhat augmented, as he says something unintelligible and even feebly tries to get up. But when @{(LisaRel >= 50) Lisa|Hellhound} places the tip of her blade inside his chest, you know that Major Scott is finished.
    
    "That was certainly efficient," @{(LisaRel >= 50) Lisa|Hellhound} comments as she kicks the corpse. 
    *if about_to_die
      "Thank you. I got a little… carried away there. Got myself into trouble again."
      
      "That's putting it mildly." You look around the room. 
      *if team_stat > 1
        Luckily, it doesn't look like anyone else managed to get themselves hurt, with the possible exception of @{(RenfriRel >= 50) Renfri|Marshal} whose feathers are somewhat stained with blood. 
      *else
        Impressively, @{(RookRel >= 50) Kirill|Rook} and @{(RenfriRel >= 50) Renfri|Marshal} took care of all other enemies already, though @{(RookRel >= 50) Kirill|Rook}'s armor is dented in some places and one of @{(RenfriRel >= 50) Renfri|Marshal}'s wings looks injured. 
      "You were acting neurotic, and I mean more than usual. Is everything alright?"
      
      *goto alright_lisa
    *else
      "But also a little rude. Why interrupt my fight like this?"
    
      *goto uojkalba
  #Push @{(LisaRel >= 50) Lisa|Hellhound} out of the way. This is [i]your[/i] time to shine.
    *set Violence %+ 20
    *set LisaRel %- 20
    *set pacifist false
    You literally shove @{(LisaRel >= 50) Lisa|Hellhound} aside. It's not a strong push, but it takes her aback and makes her lose her balance all the same. She falls to the floor, looking at you with bewilderment that gradually turns to rage.
    
    "Does that mean you're switching sides?" Scott looks at you warily. "Because it's never too late for that."
    
    "I'm afraid it is." You turn your attention to the red-skinned man and 
    *if weapon = "none"
      clench your fists. 
    *if weapon = "pistol"
      raise your pistol. 
    *if weapon = "knife"
      shift into a defensive stance. 
    "I said as much outside. I'm not letting you unleash Dusk on this moon, or leave this place alive for that matter."
    
    "What the fuck?!" @{(LisaRel >= 50) Lisa|Hellhound} yells. "Do you want me to kill you too? Because-"
    
    "Quiet," Scott silences her. "I'd rather face a real warrior than a rabid beast like you. It will make my death more interesting."
    
    With that, your opponent attacks, swinging at you with his toothed blade. 
    *if Calculation > 55
      You barely manage to evade, in spite of your super-human reflexes, but you do so precisely and without losing your focus. You're in the perfect position to dodge again and, after that, you're in the perfect position to strike back.
    *else
      *set health - 1
      *if health = 0
        He decapitates you and you die.
        
        *set pc_dead true
        
        *finish
      *else
        You manage to avoid evisceration by dodging to the side, but the bone-sword still cuts through your forearm like a regular blade would through flesh. It almost severs the arm from the shoulder, and does cut most circuits which let you operate the limb properly.
        
        However, your synthetic tissue is anything but normal flesh. It does not bleed, and it only sends limited pain inputs to your central processor. It's regrettable that you lost an arm, but your opponent is now extended and distracted by the feeling of triumph. You are not.
    
    You 
    *if weapon = "none"
      instantly go for the eyes, surprising Scott both with the bold move and with the electric shock you deliver the moment your fingers touch his face. When he swings his sword again, he does so blindly, making it easy for you to step aside.
      
      You briefly wonder how you're going to finish your opponent off, but then a laser beam fries his face. Once he's fallen to the ground, you turn around and see @{(RenfriRel >= 50) Renfri|Marshal} approach you, her laser disc still glowing faintly.
      
      *goto hujjauj
    *if weapon = "pistol"
      press your pistol to his neck and pull the trigger. It's a somewhat ignominious ending to this honorable duel, but such is the nature of firearms. Sometimes, they really are the most practical tool, as Scott's nearly decapitated body proves when it falls to the floor.
    *if weapon = "knife"
      stab Scott in the armpit, where his armor appears to be the weakest, pushing your knife deep into his flesh. He roars and attempts to strike you down again, but this swing is both weaker and less precise. You dodge the blow, punch him in the jaw, then pull your knife back out. Mercifully, you finish your opponent off with a dagger to the heart and let his body fall to the floor limply.
    
    Looks like not even the enemy champion stood much of a chance against you. Comforting.
    
    *label hujjauj
    
    "Fucker," @{(LisaRel >= 50) Lisa|Hellhound} comments as she stands up. She looks at you with anger, and perhaps hurt, in her large grey eyes. "And I mean both of you. Why did you interrupt [i]my fight[/i] like that?"
    
    *label uojkalba
    
    *fake_choice
      #"Why didn't you transform? Your werewolf form would have ended this duel swiftly."
        "I just didn't feel like it," @{(LisaRel >= 50) Lisa|Hellhound} mumbles. "And why would I? I was stronger than him regardless."
      #"I was worried about you. He could have killed you with a single well-aimed swing."
        *set LisaRel %+ 10
        Lisa sticks out her chin. "He wouldn't have. He was strong, but I was faster, even in my human form."
      #"Your fight? You jumped between him and me. I wasn't going to let you steal my kill."
        *set LisaRel %- 10
        *set RookRel %- 5
        *if team_stat = 3
          *set HadalyRel %- 5
          Hadaly rolls her eyes, which have now turned a shade of orange. She's clearly annoyed with both of you.
          
        "Is that what you care about?" @{(LisaRel >= 50) Lisa|Hellhound} scoffs. "Ramping up your body count?"
        
        "You're not the one to talk," you reply coldly. "You don't seem to care about anything else, including your life."
      #"Because it wasn't [i]your[/i] fight. We're supposed to act as a team, a fact which you seemed to forget."
        *set RenfriRel %+ 5
        *set RookRel %+ 5
        "I know we're a team…" @{(LisaRel >= 50) Lisa|Hellhound} mumbles. "It's just… unfair to let a human fight an android as strong as you."
    
    "$!{pronoun} @{plural have|has} a point, Lisa," @{(RenfriRel >= 50) Renfri|Marshal} walks up to the two of you. There is some blood on her feathers, but she doesn't seem particularly bothered by it, or by the corpses she has to march past. "That was reckless of you, and not in the way your actions usually are. Is… everything alright?"
    
    *label alright_lisa
    
    "Of course not. Nothing is alright here." @{(LisaRel >= 50) Lisa|Hellhound} surveys her surroundings, sees that 
    *if team_stat = 1
      her leader is alright, 
    *if team_stat = 2
      Kirill and Damon are alright, 
    *if team_stat = 3
      both Kirill and the androids are alright, 
    then turns towards one of the internal doors. "And we can only make it alright by killing Da-xia as swiftly as possible. Let's search the upper floors, we're sure to find her there."
    
    *label lisa_orders
    
    *fake_choice
      *if (lisa_origin_learned) #"Don't you want to desecrate Scott's corpse first? He did you a lot of wrong."
        *set LisaRel %+ 10
        *set RookRel %- 10
        "Mutilating corpses is not my kind of thing." @{(LisaRel >= 50) Lisa|Hellhound} glances at Scott one last time, then starts walking towards the nearest door. "I prefer hurting [i]living[/i] prey. And there's one more person I'd like to hurt in particular."
      #"How is your heart? Do you feel anything... unusual there?"
        @{(LisaRel >= 50) Lisa|Hellhound} smiles grimly. "Afraid I'll explode and maybe take you with me? Don't worry, I doubt that will happen anytime soon."
        
        "How can you know that?" @{(RenfriRel >= 50) Renfri|Marshal} asks. "It's not like the bomb needs to warm up first. Unless Da-xia just randomly forgot to bring any radio emitters, she'll detonate the thing once she sees you. I'm surprised she hasn't done that already."
        
        "Unless you know how to perform a cardiac surgery in the field, there's nothing we can do about that." @{(LisaRel >= 50) Lisa|Hellhound} starts marching away. "Now let's test our luck."
      #"I get the feeling that you're somehow... ashamed of your powers. That you're trying to prove a point by not using them."
        *set LisaRel %+ 10
        "What point?" @{(LisaRel >= 50) Lisa|Hellhound} responds with feigned ire. "What do you think I'm trying to prove."
        
        "That's what I'm asking. But if I had to guess…" You lower your voice, hoping against hope that the others won't hear you. "Perhaps you're trying to prove that you're not a monster, or that you don't have to be, or something similar. That you can handle everything Da-xia throws your way without relying on your powers and the anger that fuels them."
        
        "Let's assume that's true," @{(LisaRel >= 50) Lisa|Hellhound} say cautiously. "Are you saying I should stop? Cease trying to prove this… hypothetical point?"
        
        *fake_choice
          #"Yes. Now's not the time for... whatever you're doing. We need to focus."
            "Right. Sorry I got distracted, it… That won't happen again." @{(LisaRel >= 50) Lisa|Hellhound} nods, then 
          #"Yes. You're not a monster, and don't owe these people any evidence of that."
            *set LisaRel %+ 10
            "Tell that to guys who chose my codename," @{(LisaRel >= 50) Lisa|Hellhound} murmurs. "I've been a beast ever since I developed these… powers of mine. I'm more wolf than human, and it seems like the 'human' part is pretty worthless at that."
            
            *if Misan > 50
              "So what?" you ask bluntly. "Humans suck. You shouldn't be ashamed of being stronger and hairier than them, that's just what they want you to think. That's what [i]she[/i] wants you to think, so don't give her any ground."
            *else
              "You're human," you say unflinchingly. "Not only that, you're more [i]human[/i] than most humans I've met. It doesn't matter that you sometimes grow fur and claws, you're a damn bastion of humanity, especially in a place like this."
            
            "Not sure if I agree… but thank you." @{(LisaRel >= 50) Lisa|Hellhound} flashes you a lopsided smile, then 
          #"No. If that's the statement you want to make, then I can only wish you good luck."
            *set LisaRel %+ 10
            "I'm not sure what I'm trying to accomplish, exactly… 
            *if LisaRel > 50
              but with you at my side, I'm confident I can do it."
            *else
              but thanks for supporting me for a change." 
            @{(LisaRel >= 50) Lisa|Hellhound} flashes you a lopsided smile, then 
          #"I don't know. I'm just making an observation."
            *set LisaRel %- 10
            "Not a very helpful one… But thanks for not lecturing me." @{(LisaRel >= 50) Lisa|Hellhound} 
        starts walking toward the nearest door. "I think that's where the stairs are at. Let's not keep Da-xia waiting any longer."
        
      #"Shouldn't we search this floor first? She could be hiding in some shady backroom."
        *if team_stat = 3
          Hadaly shakes her head as she approaches. "No… I've been to this power plant once with you-know-whom, and the first floor was never used for anything technical. If she wants to empower Dusk nanites by giving them power, she'll have to set it up on a higher floor."
          
          "See? Android-werewolf unity right there." @{(LisaRel >= 50) Lisa|Hellhound} starts marching away. "Now let's put that unity to use."
        *else
          "And risk getting found straight away?" @{(LisaRel >= 50) Lisa|Hellhound} shakes her head. "I know her. 
          
          "Maybe she wants us to believe that?" 
          *if team_stat > 1
            Damon suggests. 
          *else
            you suggest. 
          "Maybe she's behind the nearest wall, hoping to win by playing mind games with us?"
          
          "And rely on us playing those mind games? You have no idea how a Pandit thinks." @{(LisaRel >= 50) Lisa|Hellhound} starts marching away. "I do. And thanks to that knowledge, I'll soon sink my teeth into her throat."
      #"Right. Let us waste no more time."
        "I am so glad we are all in agreement, for once," @{(RookRel >= 50) Kirill|Rook} says as he joins you and the others. "Now onwards. To victory."
    
  #Stand there, prepared to bail @{(LisaRel >= 50) Lisa|Hellhound} out.
    *set ready_to_help true
    
    *goto watch_fls
  #Watch the fight without interfering.
    You consider doing something else in the meantime, helping your other companions with the mop-up, but it looks like they're just double-tapping the corpses at this point. There's nothing for you to do but stand back and observe the fateful duel.
    
    *label watch_fls
    
    *set about_to_die true
    *set timer + 1
    
    As could be expected, the battle remains that of strength versus agility. In many situations, the latter would match or even surpass the former… but Scott also has the advantage of reach, thanks to his long arms and large sword, and is protected by a set of carapace armor to boot. @{(LisaRel >= 50) Lisa|Hellhound} is only wearing cheap clothes, the kind she could easily rip apart if she were to transform. Since she's [i]not[/i] shifting, for whatever reason, she's quite outmatched by a larger and more experienced adversary.
    
    She can evade sword strikes well enough, even parry some thrusts by knocking them to the side. But it feels like she's just delaying the inevitable.
    
    Eventually, as though recognizing how dire her situation is, @{(LisaRel >= 50) Lisa|Hellhound} goes on the offensive. She slashes at Scott's chest with her vibrational blade, a strike which the Calypsoan barely manages to parry with his own weapon. @{(LisaRel >= 50) Lisa|Hellhound}'s blade cuts into the larger sword, breaking its intricate mechanisms and almost passing through it… before Scott swings to the side and throws both weapons away.
    
    @{(LisaRel >= 50) Lisa|Hellhound}'s eyes widen right before a fist, large and wrapped in a combat glove, strikes her right between these very eyes. She hits the cold floor a split second later, at about the same time as the droplets of blood from her broken nose.
    
    And just like that, the duel is over. Scott isn't finished, he approaches @{(LisaRel >= 50) Lisa|Hellhound} with murderous intent, but he's no longer fighting. 
    *if ready_to_help
      He's about to perform an execution.
      
      You don't let him.
      *goto kill_scott
    Unless you stop him, he'll just beat your teammate to death while she's stunned and disarmed.
    
    *fake_choice
      #"Um, Lisa? Do you need any help, mayhaps?"
        "Of course I do! Now-" @{(LisaRel >= 50) Lisa|Hellhound} cuts off, her words replaced by a scream as Scott steps on one of her hands. At that point, you're fairly sure you need to intervene, but someone beats you to it.
      #Keep watching idly.
        *set LisaRel %- 5
        *set RenfriRel %- 5
        You observe as Major Scott approaches his opponent, his victim, and is about to kick her in the head… And then you hear a familiar flap of large, powerful, caramel wings.
      #Help her by killing Scott.
        *goto kill_scott
    
    Scott is lifted off his feat despite his weight, for he's hit with pure reversal of gravity. He flies, or perhaps falls, towards a distant wall. Judging from the speed with which he flies through the air, as well as the loud thud he makes once he finally hits the wall, you doubt he'll be getting up anytime soon.
    
    "Lisa!" @{(RenfriRel >= 50) Renfri|Marshal} lands, then runs up to you and the werewolf. One of her wings is bleeding, presumable having taken a bullet, but she looks fine otherwise. "Are you alright?"
    
    *goto alright_lisa


You're already tired. You feel the weight of ages on your back, and your battery 
*if battery > 50
  is certainly far from full. 
*else
  is running out rapidly. 
But you're still alive, against all odds, and the same goes for every other member of your small team. Da-xia, meanwhile, just lost the majority of her force. She should fall easily once you actually find her… unless she has some ace up her sleeve, some backup plan prepared for a scenario just like this one.

Which, you must admit as you advance deeper into the power plant, is rather likely to be the case. 

*page_break

*label main_fight_cont

Finding Da-xia and her artifact in such a large power plant would normally be no easy task. You [i]suspect[/i] she's not hiding on the first floor, but beyond that, she could have chosen almost any room to make her final stand. Luckily, she's not the only person trying to die heroically here.

As you go deeper into the building, you keep encountering more enemy soldiers, either alone or in small squads. Some of them, you imagine, have fled the grand battle at the entrance and are now trying to atone for their cowardice. Others have probably been waiting in their dark corners from the very beginning, hoping to ambush and kill anyone who somehow made it past the first line of defense.

*if team_stat = 1
  For the most part, these stragglers are not an issue. 
  *if health > 1
    *set health 1
    One of them stabs you rather painfully with a vibro-knife, but others are only armed with standard issue firearms which don't pose much threat to your group. 
  *else
    You still need to be cautious, for even a single blow could kill you at this point, but that caution allows you to predict enemy attacks and counter them deftly. 
*else
  You easily deal with them all. Damon's keen eyesight and powerful build both prove invaluable in the narrow corridors of the facility—he spots most hostiles before they spot you and disposes of them with either a single shot or a single punch, depending on the distance. Your 
  *if official_ro = "damon"
    boyfriend 
  *elseif DamonRel > 50
    friend 
  *else
    fellow android 
  is submerged in his element, protecting you and the Trio from sudden attacks, and he thrives like never before.

Moreover, you're able to use enemy positions to navigate through the large building, pushing towards the most heavily watched and defended positions. It's possible that the placement of soldiers throughout the facility is random, or even that it's a deliberate ruse designed to lead you away from Da-xia and her ultimate weapon. But the zeal with which the ambushers attack you speaks otherwise; They are dying in defense of their leader, and that means said leader must be somewhere close.

The corridors you pass through are lined with doors to various workshops and storage chambers, and you make sure to kick down every single one that's not already opened. For the most part, you find nothing but rubbish and corpses of corporate employees, killed when the Calypsoans invaded this place hours ago. But eventually, on your ninth or tenth door, you finally see something worthy of your attention.

A chamber far more spacious than others, housing several large boilers, or perhaps just tanks fool of coolant water. You're not sure, your attention is quickly grabbed by a wooden table in the room's center and a large, somehow familiar book placed atop of it. And then, less than a decisecond later, you instead focus on three guns aimed directly at you, two carbines and one submachine pistol. The pistol stands out due to its unique design, as well as the person holding it. A woman wearing a simple, yet seemingly expensive robe, her head shaved bald and her brown eyes measuring you with tranquil, detached interest.

Da-xia in all her glory.

*page_break

You're not sure what kind of weapon Da-xia is aiming at you. The carbines of her two bodyguards—both men dressed in bulletproof armor—appear to be laser-based, though you can only guess at their frequency. Not that you actually have the time to guess; You only have a split second to make your move.


*choice
  #Knock one of the bodyguards out and use him as a shield.
    *set Misan %+ 5
    *set RenfriRel %- 5
    You surprise Da-xia by dashing towards one of her goons and punching him in the jaw before he can fire even a single shot from his carbine. You quickly get behind him and prevent him from falling, holding this man up like a mannequin, in hopes that neither Da-xia nor the second soldier will dare to shoot a fellow Calypsoan.
    
    Fat chance. Though the other bodyguard hesitates—then turns around to face @{(LisaRel >= 50) Lisa|Hellhound} as she charges him with a sword—the Great Pandit wastes no time. She fires a projectile which goes through your hostage's body, bathing your surroundings in blood and tissue, barely slowed down by the soldier's armor.
    
    Still, the bullet loses some of its velocity as it goes through the rib cage, the lungs, the back and another layer of armor. When it hits you, it does so with greatly reduced momentum. You feel its sting, as well as a slight electric shock, but are otherwise unharmed.
    
    You look at the mangled remains of your hostage as they stop bleeding. At a man killed by his own commander, his own guru, a person he was prepared to die for. 
    *if Misan > 50
      Serves him right, you suppose.
    *elseif Emotion > 50
      You can't help but feel bad for using him as a shield, but only a little.
    *else
      It's almost enough to make you feel bad for him, though not quite.
    
    *goto skip_normal
  #Dash forward and knock the gun out of Da-xia's hand.
    *if Build > 55
      You smack Da-xia's right hand forcefully, perhaps more than you intended. You cause her to drop the weapon before it can fire a single shot, but you also manage to break her hand and send her tumbling to the floor with the sheer force of your slap. She screams, and her soldiers both aim their carbines at you, ready to exact revenge.
    *else
      *set health - 1
      You're not quite fast enough to reach Da-xia before she, as well as her men, all fire everything they have into you. A bullet enters your body right after lasers scorch your skin, flooding your processors with pain sending you to your knees.
      
      *if health = 0
        *goto death_to_daxia
      
      Luckily, @{(RenfriRel >= 50) Renfri|Marshal} has your back. She activates her laser disc and fries Da-xia's hand before she can make another shot, causing the strange pistol to hit the floor a split second later. You're not sure why she hasn't killed the Great Pandit outright—perhaps she fears political ramification, or perhaps she simply fired without thinking.
      
      At the same time, @{(LisaRel >= 50) Lisa|Hellhound} goes on the attack. 
      *goto goes_on_attack
  #Raise your hands in surrender.
    *set Violence %- 10
    "I give up!" you loudly announce as you 
    *if weapon = "none"
      drop your ${weapon} and 
    put your hands up. "Please don't shoot."
    
    *if (DaxiaRel + Social) < 80
      Da-xia shoots you in the head. Perhaps you weren't persuasive enough, or perhaps you've pissed her off too badly for her to even consider your pleas. Either way, the result is the exact same.
      
      *goto death_to_daxia
    
    "I'm glad you're still capable of something resembling reason," Da-xia comments dryly. "But what do you want me to do if not shoot? You're a threat to my mission, and so are your organic friends."
    
    "They can surrender too." You look at @{(LisaRel >= 50) Lisa|Hellhound} and @{(RenfriRel >= 50) Renfri|Marshal}, who in turn stare at you skeptically. "Right guys?"
    
    "I don't know if I feel like it," @{(LisaRel >= 50) Lisa|Hellhound} replies, though she makes no move to attack. Neither does @{(RenfriRel >= 50) Renfri|Marshal}. "But then again… I don't want you to get shot either. 
    *if official_ro = "lisa"
      You are my awesome boyfriend, after all."
    *elseif LisaRel > 50
      You're a good friend, after all."
    *else
      I don't dislike you [i]that[/i] much."
    
    "It appears as though we've reached an impasse," Da-xia says slowly, clearly biding for time. "In that case, I suggest you reconsider your assault. I can pause the operation long enough for you to leave this city-"
    
    She cuts off with a scream as her right hand, which so far has been holding the pistol, is reduced to a piece of burnt meat. @{(RenfriRel >= 50) Renfri|Marshal} smiles as she turns off her laser disc and cuts the beam off. "This headband really is something. It takes a while to charge up, but no one can tell whether I'm aiming or not. I love technology."
    
    The two soldiers raise their carbines, prepared to fire their own lasers, but then @{(LisaRel >= 50) Lisa|Hellhound} attacks. 
    *goto goes_on_attack
    
  *if (weapon = "pistol") and (weapon_av)
    #Shoot Da-xia immediately.
      *if Calculation < 55
        You and Da-xia both fire at almost the exact same millisecond. Your shot hits her in the arm, causing her to scream out in pain and drop the pistol, but her bullet has already left the barrel by then. It hits you in the chest, this most curious projectile, doing far more damage than an ordinary gunpowder bullet would.
        
        *set health - 1
        *if health = 0
          *label death_to_daxia
          
          You fall to the floor, your systems broken beyond all repair and recognition. You hope that what you've done was enough, that your team was fast enough, that your enemy's plans will never come to fruition. That your companions will live past this day and continue living, for as long as they want, as happily as they possibly can.
          
          But you will never know. You will never see that happy ending, even if it comes to be. You will never be sure if your sacrifice actually made a difference. In the end, you just have to have faith.
          
          Ain't that a bitch?
          
          *set pc_dead true
          
          *finish
        *else
          However, though your wound is more severe, your body is far more durable. You do not bleed, unlike the human before you, and you even manage to remain upright… as the two soldiers prepare to fire at you.
      *else
        You raise your pistol and fire almost without thinking, instinctively aiming at the Pandit's hand rather than her heart. It's a mistake, but a fairly harmless one—you knock the weapon out of her hand and heavily damage said hand before Da-xia can actually fire. She collapses to the floor, screaming with pain and missing a finger or two.
  *if weapon = "knife"
    #Throw your dagger at Da-xia's face.
      You throw the knife as quickly as you can, 
      *if Calculation < 55
        though not quickly enough to prevent Da-xia from firing. The projectile which comes out of the barrel, whatever it is, hits you in the chest and does far more damage than an ordinary gunpowder bullet would. 
        *set health - 1
        *if health = 0
          *goto death_to_daxia
        *else
          It's a good thing you're tough even for an android and that you've come here relatively uninjured—otherwise, this well-aimed shot would have been the death of you.
      *else
        drawing your arm back and then swinging it forward before Da-xia can even pull the trigger. Such is the speed of your computer reflexes, the efficiency of your robotic body, and the breadth of your combat experience.
      
      Da-xia instinctively shields her face with one of her hands, and that simple act saves her life. Your dagger impales her palm and sends her to the floor, screaming piercingly as her two bodyguards aim their carbines at you.
      
  *if (Projection > 55) and (battery > 45)
    #Shock all three of them with a single discharge.
      *set battery - 10
      You give no indication that you're about to attack. You concentrate power silently, then strike as suddenly as the lightning you produce. All three of your adversaries drop to the floor, injured by the electric discharge, though Da-xia appears to take less damage than her subordinates—though her right hand is badly burned, preventing her from holding a weapon she's still conscious and appears to tolerate the pain decently well.
      
      *goto skip_normal

Before either of them can shoot you, however, @{(LisaRel >= 50) Lisa|Hellhound} goes on the attack. 
*label goes_on_attack
She slashes one of the soldiers open, her vibro-sword easily cutting through cloth armor, then moves on to the second one. She's still not in her werewolf form, but there is some… lupine grace to her movements as she uses her blade to fist shield herself from the laser beam, then cut off the arm which held the laser carbine. The second and the last soldier falls to the floor, screaming his throat out as his blood covers the floor.

*label skip_normal

In an impressive feat of resilience for a @{(Misan > 50) mere|baseline} human, Da-xia stands up and looks at your group defiantly. With her left hand, she pulls something from beneath her robe—something you soon realize is a small radio emitter, activated with a small button which Da-xia is holding a finger over.

"One more step and I'll blow her heart out," she announces loudly, pointing at @{(LisaRel >= 50) Lisa|Hellhound} with the remains of her right hand. "I'll kill her, and maybe the rest of you, depending on how strong the bomb is. It will be a fun experiment, if nothing else."

"So you kept me in mind after all," @{(LisaRel >= 50) Lisa|Hellhound} comments. There is ire in her voice, but no distress, no fear of impending death. "How nice. Now what are you waiting for?"

"I was just about to ask that myself," @{(RookRel >= 50) Kirill|Rook} says, only now entering the boiler room. "Are you about to state your demands? Those usually come after threats."

"First of all, I'd like you to drop your weapons…" Surprisingly, @{(LisaRel >= 50) Lisa|Hellhound} obeys, letting her blade fall to the floor. But Da-xia seems to realize that none of you actually [i]needs[/i] weapons to kill her, and so she continues. "Second of all… Back away. Go stand in the corridor, in some place where I can still see you, but… Don't dare trying anything."

*if team_stat = 2
  "For the record, I think we're all too tough to die from a small explosive," Damon comments, lowering but not dropping his rifle. "Except our werewolf friend, of course. She will die from that. So… what do we do?"
*if team_stat = 3
  "Call me callous, but I don't think we should listen to her," Hadaly says having just caught up with the rest of the group. "It's not the kind of thing I say normally, but… Maybe we should just kill her and be done with it."

*if team_stat != 1
  You look Da-xia in the eye and…

*temp attacked_daxia_now false

*fake_choice
  #Incapacitate Da-xia. Break her arms.
    *set Violence %+ 8
    *goto attak_daixa
  #Attack. Beat her to death.
    *set Violence %+ 15
    *label attak_daixa
    *set attacked_daxia_now true
    *set RenfriRel %- 10
    *set LisaRel %+ 10
    "No!" @{(RenfriRel >= 50) Renfri|Marshal} jumps between you and Da-xia before you can take even two steps towards the Pandit. "She can press that button instantly! We need to… do something else."
  #"I don't believe you. You don't have the guts to press that button."
    *set Confid %+ 5
    *set DaxiaRel %- 5
    Da-xia laughs. She doesn't merely smile, or chuckle quietly, but actually laughs out loud. "What? I ordered a strike against that mutt when she was still a teenager. I won't hesitate to kill her now, so you better do what I say."
  #"We'll attack you the moment you press that button. Drop the emitter if you want to live."
    *goto life_little
  #"Fine! I'll step aside, just... please don't hurt her."
    *set Violence %- 8
    *set Confid %- 5
    "I'm glad you feel attachment, however misguided, towards your pet werewolf." Da-xia turns to look at @{(RookRel >= 50) Kirill|Rook}. "Though I'm afraid not everyone shares your feelings."
  #"Are you afraid for your life? Tell us where the artifact is and we'll spare you."
    *label life_little
    "My life means little in the grand scheme of things," Da-xia says, humbly yet proudly. "My mission is what matters. If you insist on killing me before I can complete it, I'll take at least one of you with me."
  #Do as she says.
    *set Violence %- 8
    You take several steps backwards until you're standing in the corridor once again. Unfortunately, you appear to be the only one willing to do so. All three members of the Meta Trio just stand there, in the boiler room, exchanging weighed glances and waiting for someone to make a move.

"Well?" @{(LisaRel >= 50) Lisa|Hellhound} looks at her leader intently. "What will it be, @{(crystal_stat = 3) Captain|Sergeant}? Do I live or die?"

"I mean… If we back down, you are likely to die either way," @{(RookRel >= 50) Kirill|Rook} reasons, sounding slightly more confident with each word. "Agreeing to her demands would gain us nothing, and could well mean death for everyone in this moon. I am sorry."

"Kirill…" @{(RenfriRel >= 50) Renfri|Marshal} hisses. "Don't be an idiot. We cannot just-"

"We must," @{(RookRel >= 50) Kirill|Rook} interrupts. "If nothing else, we are not allowed to negotiate with terrorists. That's not how the Federation does things. I order you to attack."

*fake_choice
  #"Wait! Can't we talk about this some more?"
    "We cannot!" @{(RookRel >= 50) Kirill|Rook} shouts with sudden tenacity. "I gave you an order, I… I'm simply doing what I must. Making a necessary sacrifice."
    
    *goto sacrifice_speech
  #"Your Federation sucks. There has to be another way."
    *set RookRel %- 10
    "There is not," @{(RookRel >= 50) Kirill|Rook} says harshly. If he's experiencing any guilt, he hides it well. "We will do everything by the books, and we [i]will[/i] win this battle. Even if it requires sacrifices."
    
    *label sacrifice_speech
    
    "How many [i]sacrifices[/i] did you make already, Kirill?" @{(LisaRel >= 50) Lisa|Hellhound} asks calmly. "Millions? Tens of millions? How many people did your weapons kill? You were always an expert at sacrificing others, and at never having to sacrifice yourself."
  *if attacked_daxia_now
    #"I agree. Renfri, step out of my way."
      "But…" @{(RenfriRel >= 50) Renfri|Marshal} takes a very small, very reluctant step to the side. "Lisa… I'm so sorry."
      
      "It's okay, birdie." @{(LisaRel >= 50) Lisa|Hellhound} smiles calmingly. "It's all going to work out. You'll see in a moment."
      
      *goto labeljjjuahjbh
  *if not (attacked_daxia_now)
    #"If you say so, @{(crystal_stat = 3) Captain|Sergeant}." Attack Da-xia.
      *label labeljjjuahjbh
      *set RenfriRel %- 10
      *set Violence %+ 10
      You faintly hope that you'll be able to kill Da-xia, or at least knock the emitter out of her hand, before she can press that damn button. 
      *if Calculation > 50
        But though you're inhumanly fast, it doesn't take much time to simply move a finger, even for a @{(Misan > 50) mere|baseline} human. 
      *else
        But you're not nearly fast enough. 
      The moment you move, the decisecond Da-xia sees you attack, she pulls the trigger and sends the signal.
      
      *goto lisa_explosion
  #"Lisa, can you please... step back? I don't want to get hit by the shrapnel."
    *set Emotion %- 5
    *set LisaRel %- 5
    "Your tact is something to behold," @{(LisaRel >= 50) Lisa|Hellhound} says dryly as she takes a step back. "There. You'll be safe at that distance, I promise."
  #"I agree. I'm sorry, Lisa... But I agree."
    "See that, Renfri?" @{(LisaRel >= 50) Lisa|Hellhound} looks at her friend sadly. "Sometimes, you just gotta accept the inevitable. Just like I accept what's about to happen."
  #Say nothing. Do nothing.
    What is there to say? What is there to do? @{(LisaRel >= 50) Lisa|Hellhound} is doomed either way, so you may as well not interfere.

"I see you made your choice," Da-xia says, her lips twisted in a lopsided smile. "I shall respect it. Farewell, Lisa Herbert, and good fucking riddance."

And then she pulls the trigger.

*label lisa_explosion

*page_break Detonation

A flash of light, closely followed by the sound of explosion. Blood, bone and cardiac muscle being splattered across the boiler room. The corpse of your 
*if official_ro = "lisa"
  lover, 
*elseif LisaRel > 50
  friend, 
*else
  companion, 
almost split in half, hitting the floor with a barely audible thud. You are prepared for all these things, for the gory picture and ear-splitting sounds, expect to witness tem at this exact instance.

Instead, nothing happens.

Not a sound, not a drop of blood, not even a change in @{(LisaRel >= 50) Lisa|Hellhound}'s expression. She just stands there, much like she stood a moment later, gently tapping her foot against the floor.

After two, three, four seconds of silence, Da-xia frowns. She presses the button again, and once again to no effect. She then presses it one, two, three more times, increasingly surprised and horrified by the absence of results.

"It's broken…" She shakes the emitter, as though desperately hoping to fix it on the spot. "How… when…"

"Oh, I suspect it's working perfectly well," @{(LisaRel >= 50) Lisa|Hellhound} reassures her old acquaintance. "But the bomb… it hasn't been in my heart for several weeks now. Sorry."

"Oh…" @{(RookRel >= 50) Kirill|Rook} says eloquently. He has more composure than @{(RenfriRel >= 50) Renfri|Marshal}, who just stands there and gapes. "That is… good? But how did you-"

*if team_stat = 3
  "I just asked the android lady to take it out." @{(LisaRel >= 50) Lisa|Hellhound} nods towards Hadaly. "You know, right after we returned from $!{first_mission}. I figured it would be safer that way."
  
  "Don't mention it," Hadaly chimes in. "I mean it, we agreed not to tell anyone about that surgery. It was pretty embarrassing, I spent almost a minute searching your body for a hard drive out of-"
*else
  "Kirill, I'm a meta-human with an insane regenerating factor and in-depth knowledge of how to cut things apart," @{(LisaRel >= 50) Lisa|Hellhound} explains in an exasperated tone. "Leaving me with 
  
  "So Hadaly helped you take the bomb out," 
  *if team_stat = 2
    Damon says with clear relief. 
  *else
    you note 
    *if Emotion > 50
      with relief. 
    *else
      neutrally. 
  "I was wondering where she got that explosive for-"

[b]"Kirill you bastard!"[/b] @{(RenfriRel >= 50) Renfri|Marshal} yells, having seemingly regained the ability to speak. "You wanted to… you gave… Lisa's only alive because you're too incompetent to stop her from getting an [i]impromptu heart surgery[/i]! What the fuck is wrong with you?!"

"My actions were reasonable, in the context of the circumstances," @{(RookRel >= 50) Kirill|Rook} defends himself. "As for my neglect… It ended up working in our favor, did it not?"

*fake_choice
  #"I suppose it did. I don't approve of your choices, but I won't resent you for them."
    *set RookRel %+ 8
    *set RenfriRel %- 8
    *if RenfriRel > 50
      "Thank you, ${fake_name}." @{(RookRel >= 50) Kirill|Rook} hangs his head. You can't see his face, and so you can't tell whether it's a sign of shame, or just being tired. "I am far from perfect, on account of being only human. I know I have earned some criticism, and I will listen to it… later. We still have a mission to complete."
      
      "Right…" @{(RenfriRel >= 50) Renfri|Marshal} looks like she [i]really[/i] wants to add something, but is willing to wait until the danger has passed. "Does anyone know where that artifact is?"
    *else
      "Nobody's asking [i]you[/i]!" @{(RenfriRel >= 50) Renfri|Marshal} retorts. "You're not the one who almost got blown up because of his stupidity!"
      
      "No. I was, and I say we drop the subject for now," @{(LisaRel >= 50) Lisa|Hellhound} benevolently rules. "Now where's the Dusk artifact?"
  #"Calm down, @{(RenfriRel >= 50) Renfri|Marshal}. Your leader did what he thought was necessary, nothing more."
    *set RookRel %+ 12
    *set RenfriRel %- 12
    *set LisaRel %- 8
    "His judgment on what's [i]necessary[/i] is absolute garbage," @{(RenfriRel >= 50) Renfri|Marshal} retorts angrily. "Scratch that, I don't think he ever [i]tried[/i] to determine what's necessary and what's not. He just does whatever he feels like and justifies it later. It's not obvious at first, but every decision he makes is as self-serving as they-"
    
    *label shitting
    
    "Hey, I'm all for shitting on Kirill, but can we do that sometime later?" @{(LisaRel >= 50) Lisa|Hellhound} suggests. "I've wasted too much of our time already. Where's the Dusk artifact?"
  #"I think you need to seriously re-examine how you treat your subordinates, @{(RookRel >= 50) Kirill|Rook}."
    *set LisaRel %+ 5
    *set RenfriRel %+ 10
    *set RookRel %- 8
    "Nothing I've done was against the rules for…" @{(RookRel >= 50) Kirill|Rook} shrinks a little under @{(RenfriRel >= 50) Renfri|Marshal}'s hostile gaze. "Fine. I will re-assess my approach to teamwork, safety and discipline, but only [i]after[/i] our mission has ended in success. Deal?"
    
    "Good enough for me." @{(LisaRel >= 50) Lisa|Hellhound} rolls her eyes, then uses them to look around the boiler room. "Now where's that Dusk artifact we've been trying to find?"
  #"@{(RookRel >= 50) Kirill|Rook}, you suck ass."
    *set LisaRel %+ 10
    *set RenfriRel %+ 5
    *set RookRel %- 12
    "I'm not sure if that's his preferred form of sexual intercourse," @{(RenfriRel >= 50) Renfri|Marshal} growls. "Seeing how quickly he gave Da-xia the detonation code, I think he'd prefer taking it in the-"
    
    *goto shitting
  #"Can we [i]please[/i] hurry? We still need to find the Dusk artifact."
    "Right…" @{(RenfriRel >= 50) Renfri|Marshal} takes her eyes off @{(RookRel >= 50) Kirill|Rook} with what looks like physical effort. "Does anyone have any clue where it is? That Dusk shard of theirs?"
  #"Holy shit... Are you alright, @{(LisaRel >= 50) Lisa|Hellhound}?"
    *set Emotion %+ 8
    *set LisaRel %+ 8
    "Sure. I'm as alright as I can ever be in [i]this[/i] company." @{(LisaRel >= 50) Lisa|Hellhound} shoots @{(RookRel >= 50) Kirill|Rook} one more distasteful glance, then starts looking around the room. "Now where is the artifact?"
  *if RookRel < 50
    #Punch Rook in the face.
      *set Emotion %+ 8
      *set Violence %+ 8
      *set RookRel %- 15
      *set LisaRel %+ 10
      It doesn't matter that Rook still has his helmet on and that, as a result, the punch hurts your hand more than it hurts him. It's not about the pain, but rather about the message, and you make that point clear enough.
      
      "I appreciate the sentiment, but can you punch my leader some other time?" @{(RenfriRel >= 50) Renfri|Marshal} requests. "When he's not wearing armor and when we're not hunting for a shard of Dusk. Where is that artifact, anyway?"
      
      *goto could_this
  *if (LisaRel > 50) #Hug Lisa.
    *set LisaRel %+ 12
    You slam into 
    *if official_ro = "lisa"
      your girlfriend, 
    *else
      the girl, 
    almost knocking her off her feet with the sheer force of the enthusiastic impact. She chuckles softly as you wrap your arms around her. "Careful now. For all I know, the feds could have put [i]another[/i] bomb inside me somewhere."
      
    "I don't care," you tell her. "I'm so glad you're okay. I thought I might… you know…"
      
    "You're not losing me any time soon," Lisa promises, then gently pushes you away. "Now focus. That Dusk artifact should be around somewhere."
      
    *goto could_this

*label could_this

"Could this thing be the artifact?" 
*if team_stat = 3
  Hadaly 
*if team_stat = 2
  Damon  
*if team_stat = 1
  @{(RookRel >= 50) Kirill|Rook} 
points at the large book, placed on the table and attached to numerous wires. 
*if team_stat = 3
  "I have a hunch that might be it."
*if team_stat = 2
  "Because it sure looks like it."
*if team_stat = 1
  "Because it seems rather probable."

You once again look at the closed book. Now that you're able to linger on it, you see just how old it is, how faded is the beauty of its intricate cover. The title is written in some foreign language absent from your database, but judging by its length… and by the apparent importance of the book itself… you connect the dots and finally understand the great deception.

This is the Bayesian Codex, the holy book of Calypso. The Pandits must have found a way to infuse it with Dusk nanites—or perhaps the book was always formed out of nanomachines—and then locked it away under the pretext of protecting a religious artifact. Crystal has undoubtedly sensed its presence, that's why they invaded Calypso in the first place, but didn't think anyone would dare to center an entire religion around a Dusk-corrupted relic. Da-xia found her refuge in audacity, as much as in the walls of her habitat.

The paper plane, the origami figure… they must have been pages torn out of this holy book. You're not sure what they were doing in the wild, but maybe the Pandits had their reasons. Perhaps they released these items as bait or misdirection for Crystal, hoping to keep the wyvern away from the [i]real[/i] artifact. Or perhaps these pages were sold on some black market as a means of funding this armed invasion of Rhea. Either way, that part of the plan went swimmingly—nobody realized where the real danger laid, and now this danger is one electric impulse away from being unleashed.

*fake_choice
  #Disgusting. Calypsoans basically worship Dusk at this point.
    $!{master} help you with these people. They style themselves as the ultimate rationalists, and yet their own holy book is nothing but a jar for ultimate evil. 
    *if Misan > 50
      Damn their moon, and damn their entire species as far you're concerned.
    *else
      Not despising humans was never as difficult as it is today.
  #Clever. Infuriating and undoubtedly evil, but clever.
    Da-xia played her hand very deftly and got dangerously close to completing her quest. If not for the freak coincidence which brought you and the Meta Trio to this very city on this exact day… This blind luck might be the only reason why Rhea still exists.
  #The past is irrelevant. We must disarm this device now, else we won't have a future.
    "Let's disable that thing already," you voice the thought loudly. "For all we know, it might be rigged to explode once some timer runs out."
    
    "Agreed." @{(RenfriRel >= 50) Renfri|Marshal} nods, then turns towards the Pandit. "I assume this [i]is[/i] your ultimate weapon? Not just some decoy set up to fool us?"
  #Crystal was an idiot. In their place, I would have figured it all out.
    Granted, you didn't figure much out during your visit to Calypso… But you were only there once and for scarcely a day. Crystal had more time, as well as some kind of ability to detect Dusk nanites, and so their failure to find such a large relic is simply embarrassing.
  #Crystal was right. They have always been in the right.
    *if crystal_stat = 1
      At this moment, you feel rather proud of decision to not kill Crystal earlier on. Fallible as that wyvern is, it's still an enemy of Dusk, and the Solar System needs such creatures more than anything else.
    *if crystal_stat = 2
      You almost feel proud of having failed to kill Crystal. As embarrassing as it was, and as close to death as you came, the alternative would have been much worse for the Solar System in the long run.
    *if crystal_stat = 3
      Why? Why have you killed that diamond wyvern, one of the only creatures standing in the way of Dusk? Even if you disable this weapon and save Rhea, the Solar System will pay for your mistakes dearly. The nanites you've freed on Janus are still out there, infecting new hosts, and may well find servants as effective as Da-xia and her goons.


"Right… I confirm that this book is indeed our Dusk artifact." Da-xia swallows nervously. Her unwaivering confidence, the main mark of her personality, has been suddenly diminished. "You have beaten me. You just need to disarm that shard and you will have saved the Sholmo City."

"Just that? Nothing more?" @{(LisaRel >= 50) Lisa|Hellhound} takes a step forward. Her voice is soft and innocent, but her nails start shifting into claws. "Because I vaguely remember we have a score to settle. Especially now, after your failed attempt to blow my heart out."

Da-xia takes a step back. "Well, we are in the middle of combat… I mean, we were. I surrender, there's no reason why you shouldn't spare me, you can always use me as-"

@{(LisaRel >= 50) Lisa|Hellhound} dashes forward, reaching Da-xia before the Pandit can even blink, then buries her claws in the other woman's abdomen. Da-xia does not scream, curiously enough, just whimpers as her skin is pierced and her guts are scratched by the razor-sharp nails.

@{(LisaRel >= 50) Lisa|Hellhound} spends two or three seconds just standing like this, her grey eyes staring into the Pandit's brown ones. Only then does she retract her hand, tearing off a patch of skin and a small chunk of flesh, and only then does Da-xia scream. She falls to the floor, pressing her hands against the wound in an attempt to stem the bleeding, even though it must increase the excruciating pain she found herself in.

"This…" @{(RookRel >= 50) Kirill|Rook} is about to comment, but thinks better of it. He turns towards the Codex instead. "Renfri, let's take care of this. I point to the wire, you cut it with your laser, okay?"

@{(RenfriRel >= 50) Renfri|Marshal} just nods, and then they both run towards the table. Leaving @{(LisaRel >= 50) Lisa|Hellhound} with her prey, and leaving you nothing to do but to observe the gory scene.

*page_break

"I will give you one thing; You sure know how to pick a good weapon," @{(LisaRel >= 50) Lisa|Hellhound} says as she picks up Da-xia's pistol. "Shame your goons never did. They barged into my house with nothing but regular pistols, back when you first tried to kill me that is."

"It was for the greater good!" Da-xia whines. "I wanted to make sure you wouldn't hurt anyone… And that you wouldn't suffer much yourself."

"Good job then, because I did suffer a fair bit." @{(LisaRel >= 50) Lisa|Hellhound} weighs the pistol in her hand, then points it at her old enemy. "I've spent months on the run, years as federate property. You deserve so much worse than this… But I'm a good girl, and so I'll kindly finish you off."

*if team_stat = 1
  With both soldiers dead and both meta-humans occupied with unwiring the Codex, there's nobody but you to witness this execution. Nobody but you to potentially interfere.
*if team_stat = 2
  "I'll remember to never get on your bad side," Damon comments. "It's definitely more trouble than it's worth."
*if team_stat = 3
  "Can you please hurry up?" Hadaly requests. "I'm not a fan of drawn-out suffering, and we should probably focus on Dusk anyway."
  
  "Don't tell me you didn't gloat when you faced your…" @{(LisaRel >= 50) Lisa|Hellhound} pauses, seeing the grimace on Hadaly's face. "But I guess I owe you that much, after you took that bomb out of me. I'll be quick."


*temp told_to_kill false
*temp told_to_spare false


*fake_choice
  #"Finish her off. She's basically dead anyway."
    *set told_to_kill true
    "I'm not!" Da-xia protests. "You can still find me some lifeblood, or other medicine, or I can find it myself, I… I still have some life ahead of me."
    
    "I see…" @{(LisaRel >= 50) Lisa|Hellhound} aims the pistol at Calypsoan. "So that's another reason to kill you while I still can, huh?"
    
    "No!" Da-xia cries. 
  #"Just get on with it! We're wasting so much time..."
    *set LisaRel %- 8
    *set told_to_kill true
    "You're worried about wasting time? Then just let me go!" Da-xia pleads. 
  #"Come on. Do it."
    *set told_to_kill true
    "Don't do it!" Da-xia protests. 
  #"Don't kill her yet. She could still give us information, or maybe serve as a hostage."
    *set told_to_spare true
    "I don't care about that crap," @{(LisaRel >= 50) Lisa|Hellhound} says bluntly. "At this point, I barely care if Dusk eats us all. I just want justice for everything she's done."
    
    *goto no_justice
  #"Come on, Lisa. Will you really shoot an unarmed person like this?"
    *set told_to_spare true
    *set LisaRel %- 8
    "Are you seriously asking me that?" @{(LisaRel >= 50) Lisa|Hellhound} scoffs. "I've done far worse to far better people, and she's the one who made me do these things. Blowing her brains out is justice."
    
    *label no_justice
    
    "There's no such thing as justice!" Da-xia cries. 
  #"Are you afraid of death, Da-xia? You seemed fine with it before."
    "I was willing to kill and die in battle, for the cause I deemed righteous," Da-xia explains profusely. 
  #Do not interfere.
    "Please reconsider!" Da-xia keeps pleading. 
"Killing me when I pose no threat, when I could still do some good or experience happiness… It just wouldn't be right."

"You think I still believe in right and wrong?" @{(LisaRel >= 50) Lisa|Hellhound}'s eyes narrow. "They're just words, the kind people like you invent to control others. The kind you used to control [i]me[/i], once upon a time. I can't be fooled anymore."

"This is madness…" Da-xia replies. Her face is twisted with pain and fear as she looks at you. "Tell her, ${name}. Tell her she's evil or at least… lost. Please."

"Actually… why not?" @{(LisaRel >= 50) Lisa|Hellhound} turns towards you as well. "Tell me, ${name}. Do you believe good and evil, or right and wrong, even exist? Or is it all just bollocks?"

*label grand_question

*fake_choice
  *disable_reuse #"Huh? Why are you asking me of all people?"
    *if official_ro = "lisa"
      "We are a couple, are we not?" Lisa smiles weakly. "It just feels… right to discuss major decisions with you. Even if those decisions are ultimately mine."
    *elseif LisaRel > 50
      "It's not like there are many other people to ask." Lisa looks at her busy teammates, then at the corpses which litter the floor, then back at you. "Besides, I didn't befriend a millennium-old android to not request ${subject} wisdom every once in a while."
    *else
      "So that I can consider your opinion and then do the opposite," Hellhound replies harshly, though her voice softens after a second. "Or not. I just… don't necessarily know what to do. I wouldn't mind some second-hand opinions, especially from someone who lived for a thousand years."
    
    You frown. "I'd understand if you wanted advice on what to do with Da-xia, but the nature of good and evil? What does that have to do with anything? How does it factor into your decision?"
    
    "Telling you would make an honest answer less likely," @{(LisaRel >= 50) Lisa|Hellhound} says cryptically. "Now tell me. Do you believe in right and wrong?"
    
    *goto grand_question
  #"No. It's all moralist nonsense. Do whatever you feel like."
    Da-xia gasps, horrified by the audacity of your words… as well as her impending demise. Probably the latter more than the former
    
    "Whatever I feel like, huh?" @{(LisaRel >= 50) Lisa|Hellhound} smiles bitterly. "I guess that's how I always lived, or at least for a long time now. No right or wrong, no sense of morality or duty, no god or goddess to judge me. Only us."
    
    "Yes," you concur. "Only us."
    
    *goto daxia_life
  #"Yes. Some actions are good, others are evil. Denying that is wrong."
    "That's what the Pandits would tell me when I grew up, all the damn time, endlessly." @{(LisaRel >= 50) Lisa|Hellhound} grimaces at the distant memories. "But if you share that view… maybe there's something to it. Maybe right and wrong are built into the universe, or the human nature, or something like that. Maybe I should do the right thing for once, even if it makes me feel a little bad."
    
    *goto daxia_death
  #"I'm really not qualified to answer this question. Sorry."
    *set Confid %- 10
    *label refrained_po
    @{(LisaRel >= 50) Lisa|Hellhound} sighs. "Well, I suppose it's nice of you to let me make my own choice. I guess I'll just listen to my heart, now that we're sure it won't explode."
    
    *rand die 1 2
    
    *if die = 1
      The redhead stands there silently for a moment. Then, in a voice simultaneously full and devoid of confidence, she states; "I believe… perhaps there is something to all these ramblings about morality and ethics. There is good and there is evil, even if they can get hard to tell apart. I will no longer deny that."
      
      *goto daxia_death
    *if die = 2
      *goto daxia_life
      
  *if told_to_spare
    #"It doesn't matter. I'm not letting you kill her."
      *set Violence %- 15
      *set LisaRel %- 15
      *set Confid %+ 10
      @{(LisaRel >= 50) Lisa|Hellhound}'s eyes narrow. "Will you really deny me my vengeance? Do you think you can stop me from exacting it?"
      
      "Yes, on both counts," you say unflinchingly. "You're a survivalist first and foremost. You won't fight me, risking violent death, for the sake of some momentary satisfaction. Am I wrong?"
      
      "…no," @{(LisaRel >= 50) Lisa|Hellhound} admits. "I will not. But I won't forget that insult either, so be careful not to piss me off any further."
      
      *goto daxia_life2
  *if told_to_kill
    #"You talk too much." Kill Da-xia.
      *set daxia_alive false
      *set pacifist false
      *set Violence %+ 15
      *set LisaRel %- 15
      Da-xia doesn't even have time to protest before you crush her skull with the might of your boot. Ignominious death for sure, 
      *if DaxiaRel > 45
        but at least her soul will rest in peace.
      *else
        but it's not like she deserved any better.
      
      *set DaxiaRel 1
      
      @{(LisaRel >= 50) Lisa|Hellhound} grits her teeth. "That was my kill. My chance at revenge. Why did you take it away from me?"
      
      "I told you to get on with it," you say harshly. "You chose to debate philosophy instead. Don't blame me for having missed your chance."
      
      "You're impossible," @{(LisaRel >= 50) Lisa|Hellhound} growls. 
      *if LisaRel > 40
        "But… you are here for us, and you haven't been a bad @{(official_ro = "lisa") boy|}friend up to this point. So I'll forgive it."
      *else
        "I hope we never see each other after this. Resisting the urge to kill you might be difficult."
      
      *goto dusk_unleashed
  #Do not answer.
    *goto refrained_po


*label daxia_death

*set daxia_alive false

"Yes!" Da-xia eagerly concurs, looking at @{(LisaRel >= 50) Lisa|Hellhound} with renewed hope. "You're not completely lost, I can see that. Release me, and the greater good-"

The gunshot is almost deafening, its sound echoing through the boiler room long after the bullet enters the Pandit's head. Her wise brain gets splattered across the floor alongside numerous fragments of her skull, yet another gory decoration which adorns this dark chamber.

"Some people deserve to live, others deserve to die." @{(LisaRel >= 50) Lisa|Hellhound} lowers the pistol. "There's no point denying that, especially if you're gonna preach morality like she did. May her greater good rot and burn."


*goto dusk_unleashed

*label daxia_life

*set lisa_spared_daxia true

@{(LisaRel >= 50) Lisa|Hellhound} focuses all her attention on Da-xia. She places her finger on the trigger… and then removes it. "I tire of you. Go and sin as much as you want, just… make sure to never bother me again."

"You're… letting me go?" Da-xia looks positively bewildered. "I thought you'd… take me hostage or… not spare me in the first place…"

"Are you complaining!?" @{(LisaRel >= 50) Lisa|Hellhound} growls. "No? Then get out of here and never come back. I do whatever I feel like and, just for a moment, I'm feeling merciful."

*label daxia_life2

With effort, Da-xia manages to stand up. You almost expect her to collapse right away, but she somehow manages to hobble out of the room, leaving a trail of blood behind her. Perhaps she's not as human as you first thought, or perhaps her injuries are more spectacular than they are severe.

With some luck, she may yet survive. Find some lifeblood to mend her wound with, or perhaps a medic to take care of her. Either way, she shouldn't be a threat, not with her army all gone and her intentions unveiled. Even other Pandits are likely to denounce Da-xia and her terrorist attack, in hopes of saving Calypso from federate retribution.

The real threat is still in this room, and it's far more dangerous than any ideologue. You're in the presence of Dusk itself, and you're not sure how long it will remain dormant.

*page_break

*goto dusk_unleashed


*label dusk_unleashed

Meanwhile, on the other side of the room, @{(RookRel >= 50) Kirill|Rook} and @{(RenfriRel >= 50) Renfri|Marshal} appear finished with disarming the bomb. If you can even use such a grandiose term—all they really did was cut all the wires. The Bayesian Codex is now lying on the table, not connected to anything, hardly different from an ordinary book.

"Mission accomplished, I suppose?" @{(RookRel >= 50) Kirill|Rook} eyes the tome skeptically. "I suspect they wanted to empower the artifact by electrifying it. I sense it is already energized, but with all their cables cut and all their soldiers dead, our enemies cannot deliver the final pulse. We won."

*if team_stat > 1
  "We did?" Damon raises an eyebrow. "Did we really complete this suicide mission with no losses on our side?"


*fake_choice
  #"Yup. It sure looks like it. Good job everyone!"
    *set Confid %+ 8
    "I wouldn't celebrate just yet…" 
  #"Maybe we should read the book. Look for some user instructions."
    "I don't think we'll find anything of the sort." 
  #"Should we destroy this book? Would it be safe to burn it?"
    "I'm not sure…" 
  #"I have a bad feeling about this..."
    *set Emotion %+ 8
    "I hear you." 
@{(RenfriRel >= 50) Renfri|Marshal} uses her telekinesis to flip the book open. All the pages are blank, white sheets without words or pictures, empty. "I don't feel comfortable around a [i]partially[/i] energized shard of Dusk. What does that even mean, really?"

"That it's not quite ready to start disassembling things," @{(LisaRel >= 50) Lisa|Hellhound} says, taking her eyes off 
*if daxia_alive
  the door. 
*else
  Da-xia's corpse. 
"That we arrived in the nick of time, just fast enough to stop the awakening."

"Which sounds like an unlikely coincidence, does it not?" 
*if team_stat = 3
  Hadaly inspects the severed wires. "I mean, are these cords even connected to anything? It doesn't look like it."
*else
  @{(RenfriRel >= 50) Renfri|Marshal} argues. "What are the chances we were [i]just[/i] fast enough? And that Da-xia didn't have some final trick up her sleeve?"

"I shall see what the exact energy levels in this artifact are." @{(RookRel >= 50) Kirill|Rook} extends his arm towards the book and opens his palm. "Use my powers to run a quick scan. It should only take a moment, I am quite proficient at this."

*if (Database < 40) or (timer > 7)
  *goto true_explosion

And then you realize something. Dusk nanites become active when provided with large amounts of energy, but it doesn't have to be [i]electrical[/i] energy. 
*if crystal_stat = 3
  The ones inside Crystal have been released because you provided them with kinetic energy. 
*if crystal_stat = 1
  Crystal was afraid that the nanobots inside them would gain power from mere kinetic energy of your cannon blasts. 
The divine might that flows inside the metas is also a form of energy, its application a form of power. Da-xia gathered three of them, as well as an android with unstable battery, into one room with her artifact.

And now @{(RookRel >= 50) Kirill|Rook} is about to use his powers on the book directly. Giving the nanobots inside one last push.

*choice
  #"No! Stop!"
    *if RookRel > 50
      "Why should I stop?" 
      *goto good_idea1
    *else
      Rook just ignores you. Perhaps his audio receivers glitched out, perhaps he's too focused to pay any attention to his surroundings, or perhaps he simply finds your opinion completely worthless. Either way, he continues to 'scan' the book, trying to assess just how close its nanites are to breaking loose.
  #"@{(RookRel >= 50) Kirill|Rook}, I don't think this is a good idea."
    *if RookRel > 50
      "How so?" 
      *label good_idea1
      Kirill turns towards you in surprise. "Did you find some fault in what I am trying to accomplish?"
      
      *goto quick_end
    *else
      "I respectfully disagree," @{(RookRel >= 50) Kirill|Rook} replies, his hand still extended and his power still flowing into the book. "I am trained professional. I know exactly what-"
  #Tackle @{(RookRel >= 50) Kirill|Rook} before he can do anything.
    You slam into @{(RookRel >= 50) Kirill|Rook} with all your might. 
    *if Build > 50
      *set easy_ending true
      It knocks the meta-human off his feet, interrupting the invisible process he was just about to complete.
      
      "What the Cloud?" @{(RookRel >= 50) Kirill|Rook} swears, then realizes how impolite that was. "I apologize, I forgot my manners… but why did you just attack me?"
      
      *goto quick_end
    *else
      Which proves to be not nearly enough—clad in full power armor, the meta-human barely notices the impact and just continues to pour power into the tome, too focused to pay much attention to his surroundings.
  #Do not interfere.
    You will not interrupt @{(RookRel >= 50) Kirill|Rook}'s work just because you made some unsubstantiated guess about how Dusk works. It will all be fine—your teammate is a trained professional who surely knows what the's dealing with.

*goto true_explosion

*label quick_end

"I believe your meta-human powers are passively empowering the nanites," you explain hurriedly. "And if you scan the Codex, you'll be empowering it [i]actively[/i], which could well destroy the entire Solar System."

"Shit," @{(LisaRel >= 50) Lisa|Hellhound} comments. "Should we get out of here? Run as far away from that book as possible?"

"Probably." You nod. "Leave this facility, then call for reinforcements. Baseline humans, or abhumans, or cyborgs, anything the Federation has other than you. 
*if team_stat =1
  I'll 
*else
  We'll 
guard the Codex until then, or at least until we're sure no Calypsoans are still alive."

"Just two months ago, the idea of leaving a [i]Dusk artifact[/i] alone with 
*if team_stat =1
  an android 
*else
  androids 
would seem like heresy," @{(RenfriRel >= 50) Renfri|Marshal} remarks, her voice oddly calm and dreamy. "But now… You got us out of that fight alive, ${name}, and you may have just saved the Solar System from our stupidity. I'm sorry for ever distrusting you and… thank you."

*if team_stat = 3
  "Looks like even the brave android huntress has learned something from this whole fiasco," Hadaly comments. "I'm almost glad we agreed to help you. Almost."

*fake_choice
  #"We've all learned a lot over the course of our journey. Despite everything, I'm grateful for the experience."
    *set RenfriRel %+ 10
    *set RookRel %+ 10
    *set LisaRel %+ 10
  #"Stop it. We're only here because we managed to work together, in spite of all the... initial difficulties."
    *set RenfriRel %+ 5
    *set RookRel %+ 5
    *set LisaRel %+ 5
    *set Confid %- 8
  *if team_stat = 3
    #"Don't be so snarky, Hadaly. We all distrusted one another at the start, and we've all grown since."
      "Some of us more than others…" Hadaly murmurs. "But sure. I suppose we can bury our hatchets, given everything we've been through."
  #"That's right. I'm extremely awesome and the reason we've won."
    *set Confid %+ 12
  #"Less talking, more getting out of here. Our time is running out."

"Agreed." @{(RookRel >= 50) Kirill|Rook} nods, almost bows respectfully. "Our adventure was something truly glorious… But we must take our leave at this instant. Farewell, 
*if official_ro = "kirill"
  my love, 
*elseif RookRel > 60
  ${name}, 
*else
  ${fake_name}, 
and I hope we meet again."

And then, with eagerness and reluctance at once, the Meta Trio departs. They leave the boiler room and are sure to exit the power plant within the next minute. An hour from now, they will likely be leaving Rhea, in a hurry to tell Admiral West of their glorious victory… and the role you played in it.

It's difficult to believe how well it all went. How you've saved everyone while losing no one. It's such a convenient ending, such a ray of sunshine in such dark times. But even such incredible things happen sometimes, provided you have centuries of experience in doing the impossible.

*set TrioStat "heroes"

*if team_stat = 2
  "Well, I suddenly feel a lot better about myself," Damon says once everyone else is gone. "It's been a fun ride, ${name_damon}. Despite everything."
*if team_stat = 3
  "That was certainly fun, at least for some people." Hadaly claps her hands. "So… what will we do once the reinforcements arrive, exactly? They'll see three androids surrounded by a hundred dead humans. Do we start looking for escape routes or…?"

*if team_stat != 1
  As well as friends by your side.

*finish

*label true_explosion

And then the Bayesian Codex explodes.

Sort of. It's not an explosion as much as ignition, or some alchemical transmutation that turns one thing into another. The large books is transformed into a pile of ordinary ashes and a billow of nanite smoke, and the smoke starts expanding like oil in the water, like darkness after dusk, like vacuum in the absence of distinction between air and void. It's darker than black, it's ${smell} and ${feel} and ${taste}, it's a wound in the universe through which hatred bleeds out and floods your entire reality.

You hear it too. You hear it more clearly than inside Telesto, 
*if crystal_stat = 3
  or above Janus, 
*elseif not (left_lisa)
  or back in Calypso, 
or even during the Calamity. There are no longer astronomical units, or even kilometers, or even meters of distance between you and the [i]thing[/i]. To your horror and pain, to the freedom it gave you and the death it brings, Dusk is screaming once more.

*page_break Shriek

For a moment, you believe yourself dead. You see nothing but darkness and hear nothing but silence… but then you realize that's different from not existing at all. And then, 
*if Emotion > 50
  with bewilderment and relief, 
*else
  as you force your fear and hatred down, 
you realize that Dusk is no longer shrieking… or perhaps has merely been silenced for the time being.

You survey the boiler room. Half of it is covered by mystical darkness, by the cloud of Dusk nanobots, but the other half actually got brighter. A large part of the wall has been eaten, or perhaps simply toppled, revealing the outside world and allowing light to flow into the chamber. You can clearly see the half-devoured corpses of Da-xia's bodyguards, but everyone else seems still alive and… far from well.

*if team_stat = 1
  @{(LisaRel >= 50) Lisa|Hellhound} and @{(RenfriRel >= 50) Renfri|Marshal} are simply staring at the swarm, 
*else
  @{(LisaRel >= 50) Lisa|Hellhound}, @{(RenfriRel >= 50) Renfri|Marshal}, Damon, 
  *if team_stat = 3
    Hadaly, 
  they're all staring at the unleashed swarm, 
no less shocked than you are. Of the three metas, only one is actively fighting against the cloud, because he's the only one who can.

@{(RookRel >= 50) Kirill|Rook}'s arms are both extended, his hands open wide, his expression twisted with pain. He's no longer wearing a helmet—perhaps it was disassembled by the swarm or perhaps simply discarded when you weren't looking. You realize you must have skipped a beat, blacked out for a moment, perhaps suffered a brief flashback, it doesn't matter. Something is forcing you to stay conscious, to observe this disaster, prompting you to do something about it… but you don't know what [i]can[/i] be done at this point.

*if team_stat = 3
  "That's not what I signed up for!" Hadaly whines, her eyes a shade of deep purple. "I regained my life, my freedom, there should have been a happy… we should have never-"
*if team_stat = 2
  "Boss, I think we have a problem," Damon helpfully informs. "One of apocalyptic variety. I'm not-"

"Kirill!" @{(RenfriRel >= 50) Renfri|Marshal} shouts once she regains some composure. "What are you… what's…"

"I'm holding it off!" @{(RookRel >= 50) Kirill|Rook} shouts back. He does not look at his teammate, and he certainly does not move. "I'm using my powers… fuck… I can kinda control it. Stop the nanomachines from… eating everything… for now."

You can see the truth of his words. The dark cloud waxes and wanes, shifts and waves chaotically, but remains constrained to a small area. It cannot reach your group, it cannot fly outside. @{(RookRel >= 50) Kirill|Rook}'s ability to influence nanites must extend to Dusk itself, incredible as it may seem.

*fake_choice
  #"Damn you, @{(RookRel >= 50) Kirill|Rook}! We'll all die because of you!"
    *set RookRel %- 10
    "I may have made a mistake," @{(RookRel >= 50) Kirill|Rook} admits. "But right now, I'm the only thing keeping… it… at bay. For now."
  #"$!{master} help us... Is everyone okay?"
    "I think so?" 
    *if team_stat = 1
      @{(LisaRel >= 50) Lisa|Hellhound}
    *if team_stat = 2
      Damon 
    *if team_stat = 3
      Hadaly 
    looks around the room frantically. "At least we're all alive, but… even that can change soon."
  #"Huh. You finally learned to swear. About time."
    "Fuck you!" @{(RookRel >= 50) Kirill|Rook} exclaims. "There's no time for manners! I'm trying to keep us from dying, but I can't do it much longer."
  #"Holy shit! How are you doing that!?"
    *set RookRel %+ 5
    *set Emotion %+ 5
    "I'm not sure, but I can't do it much longer!" @{(RookRel >= 50) Kirill|Rook} responds. "It's too powerful… too strong."
  #"♫With malice eternal the Sun smiles at me...♫"
    "Sergeant, I think ${name} just lost ${subject} mind," @{(LisaRel >= 50) Lisa|Hellhound} points out. "Should we do something about-"
    
    "I don't care!" @{(RookRel >= 50) Kirill|Rook} screams. "It hurts… I can't keep it confined for much longer. It yearns to be free. It will be free."
  #Say nothing.
    "What do you mean [i]for now[/i]?" @{(RenfriRel >= 50) Renfri|Marshal} keeps talking. "How much time do we have?"
    
    "A minute?" @{(RookRel >= 50) Kirill|Rook} takes a guess. "Not much more, I… I'm running out of strength."

That, too, is a true statement. You can now see the swarm expand, however slightly, with each passing decisecond. It waxes more than it wanes, like night when it senses the coming of winter, and it [i]hungers[/i] like only the Eater of Earth could. @{(RookRel >= 50) Kirill|Rook} is now your only shield, a mortal stalling a god, and he's bound to give in eventually.

"There's one way… one thing I think could maybe work," @{(RookRel >= 50) Kirill|Rook} says through gritted teeth. "We must do what Crystal did. Create a Vessel. 

*if team_stat > 1
  "There are more nanites here than Crystal has ever seen," Damon points out. "And they're already empowered. Is it really safe to-"
*else
  "You want to pump [i]active Dusk nanites[/i] into someone?" @{(RenfriRel >= 50) Renfri|Marshal} protests. "That's illegal, that's heretical, that's… so stupidly dangerous!"

"It's either that or we all die!" @{(RookRel >= 50) Kirill|Rook} argues. "Everyone dies! We must… I must absorb those nanomachines. 

"Fuck," @{(LisaRel >= 50) Lisa|Hellhound} comments, her eyes opened wide. "Must it be you? I don't want you to… I don't thing you can handle all that Dusk."

"I am responsible for… you guys." @{(RookRel >= 50) Kirill|Rook} grits his teeth even harder. "It must be me. Unless there are other volunteers?"

There. Now there's something to be done, a decision to be made. And thanks to the blessing of Dusk, the horror of the Calamity… you have the free will necessary for that choice.


*page_break Decision

An orb of pure darkness is slowly expanding, about to devour all 
*if team_stat = 3
  six 
*if team_stat = 2
  five 
*if team_stat = 1
  four  
of you, then the city which surrounds you. Unless stop, in may well consume the entirety of Rhea, or even the Solar System beyond. There's no getting around it—one of you must become a Vessel, a carrier for Dusk nanites, a host for this most malicious entity. It's just a matter of determining who should do it.

To your understanding, anyone with sufficient willpower could forestall corruption indefinitely. They just need to resist temptation as Dusk taunts them, invading their mind and offering them untold power in exchange for service. However, once the Vessels succumbs, they will actually [i]get[/i] all that power and become a nearly unstoppable force for destruction and death. Even Crystal, a reluctant carrier for a small speck of nanites, was very much empowered by the evil inside them and evidently tempted by its whispers. Perhaps you should pick somebody you trust, someone who cannot be swayed too easily, denying Dusk a potential puppet.

On the other hand… this new Vessel will become a target regardless of how they handle the darkness inside them. The Federation will see them as a threat at best, a potential test subject at worst. Perhaps you should choose someone you don't really care about, whom you aren't afraid to sacrifice for the greater good. But should it be someone strong enough to survive the federate pursuit, or too weak to pose much of a threat? Do you want to make the Federation a favor, or would you prefer to make their job harder? Do you even care about it enough to consider this angle, this aspect of your final decision?

You could always just ask @{(RookRel >= 50) Kirill|Rook} to make [i]you[/i] into a Vessel, give [i]you[/i] all these nanites he's so afraid of. It would be your chance to prove your worth, your ability to resist the temptations and the corruption of Dusk… or not. You are destined to die within the next few decades; This is your opportunity to alter that destiny, for better or worse.

The time is nigh. You're 
*if Confid > 50
  confident 
*else
  decently certain 
that you can persuade @{(RookRel >= 50) Kirill|Rook} to do whatever you want from him. You suspect he's waiting for you to say something, to free him from responsibility and potential blame. A few choice words should be enough to shape the ending of this morbid story.

*temp renfri_jumped false

*choice
  #"Do it, @{(RookRel >= 50) Kirill|Rook}. Take that burden upon yourself."
    *label rook_choice
    
    *if crystal_stat = 3
      "Kirill…" @{(RenfriRel >= 50) Renfri|Marshal} insists. "You can't do this. You've achieved so much and… Let me become the Vessel instead, I need a chance to prove myself. My life-"
      
      "This isn't the time!" @{(LisaRel >= 50) Lisa|Hellhound} shouts. You don't remember her ever sounding as panicked as she is now. "He thinks he's qualified, you're being stupid, and I can't lose… Kirill, please hurry up and do it already."
    
    "Alright…" @{(RookRel >= 50) Kirill|Rook} sighs deeply. "It was fun working with all of you, and an honor I suppose. It's time for me to take my cross and carry it. Farewell."
    
    He closes one of his hands into a tight fist, a challenge which Dusk promptly accepts. The cloud resumes expanding, but only in one direction—towards Kirill Kosteniuk, its new chosen Vessel. Two creatures, one more alive than the other, about to become one.
    
    *if crystal_stat = 3
      And then @{(RenfriRel >= 50) Renfri|Marshal} jumps between them.
      
      *set final_boss "marshal"
      *set renfri_jumped true
      
      She gives no warning. She flies in the impending cloud's way too quickly for anyone to react, let alone stop her from throwing herself in the way of Dusk. 
      *label cloud_consumes
      The cloud consumes her, or perhaps she consumes it, an intimate union of death and life between a bird of prey and the ultimate predator.
    *else
      *label rook_absorb
      The nanites pour into @{(RookRel >= 50) Kirill|Rook}'s body through his mouth, through his nostrils, through the cracks in his armor, through the plates of his armor, through everything. They don't feel like material entities but like shadows, true shadows, not mere absences of light. They consume @{(RookRel >= 50) Kirill|Rook} just as he consumes there, a holy union of body and spirit, just like he wanted and planned.
      
      *set final_boss "rook"
  #"@{(RenfriRel >= 50) Renfri|Marshal}... how do you feel about becoming a Vessel yourself?"
    "Me? I'm…" @{(RenfriRel >= 50) Renfri|Marshal} presses her lips into a thin line. 
    *if crystal_stat != 2
      "I'm willing to make that sacrifice, yes. And I believe myself strong enough to contain the nanites inside me?"
      
      "Are you sure?" @{(LisaRel >= 50) Lisa|Hellhound} asks, her voice less certain and more horrified than ever. "Are you sure you're not just… chasing glory for the sake of it?"
      
      @{(RenfriRel >= 50) Renfri|Marshal} shoots the werewolf one hostile glance, then turns away. "No, I'm… willing to do this for the greater good. I mean, for the good of the Federation, that is… can we get this over with?"
      
      "If that's really what you want…" @{(RookRel >= 50) Kirill|Rook} says as he takes several steps back. "Brace yourself."
      
      *set final_boss "marshal"
      
      He closes one of his fists and lets the nanites fly… but only in one direction. They are still bared, through some invisible force, from leaving the room or attacking the wrong person. They are focused, have to be focused, on the bold Kinnari who agreed to host them.
      
      Within another second, every part of @{(RenfriRel >= 50) Renfri|Marshal}'s body but wings is obscured by the dark collective of Dusk. 
      *goto cloud_consumes
      
    *else
      "No. I don't want any of those nanobots in my body. I don't wish Kirill to get infected either, but I won't take his place. Sorry."
      
      You decide to press. "Are you sure? I really think you're the best person for the job. Not to mention, you would finally get all the glory you could have ever-"
      
      "Don't try to tempt me!" @{(RenfriRel >= 50) Renfri|Marshal} snaps. "I know what Dusk is, and I know what the Federation is like. I'm their fall girl, their sacrificial lamb, a disposable tin soldier. They won't reward me for becoming a Vessel, they'll just kill me for it, and I'm not willing to make that sacrifice… anymore."
      
      The cloud is expanding, in spite of @{(RookRel >= 50) Kirill|Rook}'s best efforts. There's no more time for arguing, and so you're back to your original plan. Original sacrifice.
      
      *goto rook_choice
    
  #"You don't need to become a vessel, @{(RookRel >= 50) Kirill|Rook}. @{(LisaRel >= 50) Lisa|Hellhound} is a better candidate."
    "Hold on, what?" @{(LisaRel >= 50) Lisa|Hellhound} blinks. She sounds a little angry, more than a little scared and utterly dumbfounded. "How am I a better candidate? Why do you want [i]me[/i] to become a Vessel?"
    
    *if lisa_origin_learned
      "Do you remember your past, Lisa?" you reply with your own question. "Do you remember wrestling your powers under control, sparing the man who tried to kill you, spiting all the evil around you by remaining sane? You've survived everything, so just keep surviving and show that cloud of Dusk who's the boss."
    *elseif LisaRel > 50
      You reply, "Because I know you! I know you can become a carrier for Dusk without becoming its puppet. You'll be a stronger Vessel than Crystal ever hoped to be, I promise."
    *else
      "Because you're an acceptable casualty," you say harshly. "If you succumb to the corruption, the Federation will be quick to hunt you down. With luck, they'll do so before you can do any serious damage. That makes you our best option, whether you like it or not.
    
    "You know what? Sure!" @{(RookRel >= 50) Kirill|Rook} shouts as he takes several steps back. "Sorry Lisa, but this might be our best shot. Brace yourself!"
    
    *set final_boss "lisa"
    
    Before @{(LisaRel >= 50) Lisa|Hellhound} can protest any further, her leader closes one of his fists and lets the cloud of nanites fly freely. No, not freely, you quickly notice that they're allowed to fly in only one direction, towards only one person. One host. One Vessel.
    
    In a gesture so weak as to be almost sad, @{(LisaRel >= 50) Lisa|Hellhound} covers her face with both hands. Dusk nanobots still enter her body through every opening, and through the skin, and through the clothing, immaterial like evil spirits possessing a helpless victim. That's how she looks, like a victim of the choice you made, as her knees hit the floor and her scream pierces the air. It's a union of two beasts, as horrifying as any werewolf transformation, resulting in one hellish being that's both and neither at once.
    
  *if (team_stat >= 2) #"Damon, it's your time to shine. You'll be our Vessel."
    *set final_boss "damon"
    Damon looks around nervously, as though expecting to see another person with the same name. "Me? Why? How? Can Dusk even take an android as its Vessel?"
    
    *if team_stat = 3
      "I have to concur," Hadaly announces. "${name}, are you sure about that? Are you [i]certain[/i] my brother isn't about to get disassembled?"
    
    "It worked well enough with Crystal, and they were a synthetic creature," @{(LisaRel >= 50) Lisa|Hellhound} points out. "It's a bold idea for sure, but… I think it might just work."
    
    "Boss…" Damon looks at you, his expression conflicted and almost pained. "Do you really want me to do this? Even assuming I don't die, can you really… trust me with that sort of thing?"
    
    *fake_choice
      #"Not really. But out of everyone here, you may be our best shot at not dying."
        *set DamonRel %- 10
      #"Yes. I trust you fully and for good reasons. You won't succumb to corruption."
        *set DamonRel %+ 10
      #"Actually... no. I do not trust you. @{(RookRel >= 50) Kirill|Rook}, go ahead and absorb these nanites."
        *set DamonRel %- 20
        *goto rook_choice
    
    "If you say so…" Damon smiles timidly before turning towards @{(RookRel >= 50) Kirill|Rook}. "So… pour me a glass of Dusk. I haven't yet had any tonight, so maybe I can handle it."
    
    "I'm not sure if I like that idea," the meta-human grunts. "But you and ${name} got us this far, having earned our trust long ago, so… brace yourself."
    
    @{(RookRel >= 50) Kirill|Rook} closes one of his fists and lets the cloud of nanites fly freely. Or perhaps not—you sense there's still some barrier, some invisible wall preventing the swarm from leaving the boiler room, or from attacking anyone other than the target you chose for them. Your sacrificial lion. Your Vessel.
    
    Damon's huge form quickly gets covered by a far larger cloud of Dusk, only his sapphire eyes faintly shining through the darkness. Two synthetic beings—an android of about twenty years and a malicious collective which lasted a thousand—become one in this quick, terrifying, fateful moment of baleful union.
    
  *if (team_stat = 3) #"Hadaly can handle it. Make her into a Vessel."
    Hadaly blinks, covering her green eyes for just a split second. "I'm sorry, I really am, but what the Cloud? Why would you… Why do think I'd make a good Vessel?"
    
    *if HadalyRel > 55
      "Of all the people I've ever met, you might just be the most… pure," you explain the reasoning. "If Crystal was able to resist corruption for years, in spite of their murderous intent, what can Dusk possibly do to corrupt you? Those nanites won't do any harm if you become their Vessel."
    *else
      "For one, you're a rogue android anyway, 
      *if hammon_alive
        and I doubt Hammon has fully given up on you," 
      *else
        and you're partially responsible for the death of your… of a High Executive," 
      you start explaining. "Making you into a Vessel won't increase the price on your head that much. But also… I think you might just be able to keep the nanites in check, with your intellect and willpower and all."
    
    "${name}… I don't think I buy it," Hadaly says hesitantly. "Dusk is this ancient, unstoppable, earth-eating force and I'm just… me. I cannot resist it. I cannot do this."
    
    *fake_choice
      *selectable_if (Misan > 60) #"You know how incompetent humans are. If we let them toy around with Dusk, they'll lose a whole planet again. It has to be you."
        "You do make a fair point…" 
      *selectable_if (Confid > 60) #"I have confidence in you. That's something you always lacked, right? Confidence in your abilities, belief in yourself, trust that you should seriously start showing."
        "Well… I suppose it's a good day to turn over a new leaflet." 
      *selectable_if (HadalyRel > 65) #"After everything we've been through, you're telling me that you won't help? That you'd let others try and fail to save us? Please reconsider."
        "I suppose I do owe you a lot…" Hadaly sighs, then clenches her fists. 
        *goto gold_eyes
      *if official_ro = "hadaly"
        #♡ "You can. I know you're more than capable, and you know I'm not lying. That's what we are to one another."
          "You're not exactly making a solid argument… but I know you're not lying. And that I might be lying to myself." 
      *if not (hammon_alive)
        #"Just you? That's just something Hammon wanted you to think. And since he's dead... Maybe you should start thinking differently?"
          "That's easier said and done, but… maybe I can try." 
      #"Hadaly, I'm begging you. Only you can save the day at this point."
        "Actually, I believe there are other candidates." Hadaly turns away from you and looks at @{(RookRel >= 50) Kirill|Rook} pointedly. "Isn't that right, Sergeant?"
        
        *goto rook_choice
      #"Alright, have it your way. Someone else should become the Vessel."
        "Don't we already have a volunteer?" @{(LisaRel >= 50) Lisa|Hellhound} looks at her leader pointedly. "I think we should make use of him. Fast."
        
        *goto rook_choice
    Hadaly smiles weakly, but confidence grows in her eyes. They become yellow, then amber, then gold. 
    *label gold_eyes
    "So fine. Sergeant Kosteniuk, bring on the nanites."
    
    *set final_boss "hadaly"
    
    "If that's what you want!" @{(RookRel >= 50) Kirill|Rook} shouts and, with what is likely the final ounce of his strength, closes one of his fists tight. The nanobots are released from their invisible prison, but the ethereal door is only open in one direction—towards Hadaly, their prospective host who so graciously invites the swarm in.
    
    You see a trace of fear, a flash of blue in Hadaly's eyes as the black cloud envelops her. 
    *if Emotion > 45
      It's difficult not to feel 
    *else
      You, however, feel no 
    trepidation as the android disappears, covered by sinful darkness, hoping to maintain purity in the face of ultimate evil.
    
  #"I can do it! Make me into a Vessel."
    For a moment, nobody replies. The chutzpah of your request almost causes @{(RookRel >= 50) Kirill|Rook} to lose his focus and release the swarm, though he collects himself quickly enough. Others are less expedient on that front.
    
    *if team_stat = 3
      [b]"What?!"[/b] Hadaly asks calmly. "Why… how… Is that even possible? 
    *else
      "What!?" @{(RenfriRel >= 50) Renfri|Marshal} sounds unamused. "Are you stupid? What kind of plan is that? 
    Will Dusk even accept an android as its host?"
    
    "It accepted Crystal, so I don't think it has a problem with synthetics," you lay out your reasoning. 
    *if telesto_path = 1
      "Besides… I think Dusk reached out for me in Telesto. It wanted to infect me, wanted [i]me[/i] as its Vessel, even more than it wanted a diamond wyvern. So yes, I believe it will accept me here."
      
      "Those were completely different nanites," @{(LisaRel >= 50) Lisa|Hellhound} points out. "You're taking a huge risk by assuming those won't just disassemble you."
    *else
      "I think it views all sentient creatures as potential hosts, rather than just food. I'd give it a try."
      
      @{(LisaRel >= 50) Lisa|Hellhound} frowns. "${name}, I know you're really old and traumatized and I'm sorry for your various losses, but just how much do you want to die? Enough to risk taking everybody else with you?"
    
    "We'll be taking a risk no matter 
    *if Emotion > 50
      what!" you counter. 
    *else
      what," you calmly argue. 
    "Many huge, downright apocalyptic risks, no matter who we choose as our Vessel. It might as well be someone who [i]wants[/i] to become a carrier."
    
    *if (official_ro = "hadaly") and (team_stat = 3)
      "${name}… do you even know what you're saying?" Hadaly asks. Her voice is slightly softer now, but no less distressed. "Even assuming this works and you become an uncorrupted Vessel, those humans won't just let you walk away. They'll attack you, or tell the Federation to send an army after you. Sooner or later, you'll die, and I will… please don't do that."
      
      She's 
    *elseif (official_ro = "damon") and (team_stat > 1)
      "${name_damon}… are you sure about that?" Damon asks tensely. "Because even if that works, even if you succeed at becoming a Vessel… Humanity won't tolerate a dusk-infused android hiding around the corner. The Federation will kill you, or do something even worse, and I… really don't want to lose you."
      
      He's 
    *elseif (official_ro = "lisa")
      "You're a fucking idiot," your girlfriend tells you. "Say you succeed, that you don't end up eaten or corrupted. The Federation will correct that mistake. They'll send an army after you, or maybe just bomb you from orbit if you ever return to [i]Saturn Nine[/i]. You'll be the biggest target ever and I… really don't want to lose you."
      
      She's 
    *elseif (official_ro = "renfri")
      "Have you fought this through?" Renfri asks pleadingly. "Because if you become a Vessel, even one that's not corrupted… my next order will be to hunt you down. And if I don't follow that order, somebody else will. The Federation will have your head, and I… don't want my girlfriend to end up like this."
      
      She's 
    *else
      "${name}… have you thought this through?" @{(RookRel >= 50) Kirill|Rook} asks. "I can sense how vicious those nanites are, how much they hunger and hate. Resisting that malice may be hard for you, and even if you succeed… What do you think my superiors will do about a dusk-infused android living in their federation?"
      
      He's 
    right. You've survived for a thousand years mostly by staying under the radar, by letting your human pursuers believe you dead or unimportant. Your greatest weapon was always secrecy, and you aways had a sidearm in the form of cooperation. You always had at least [i]some[/i] allies, [i]some[/i] chance at negotiating with the enemy, [i]some[/i] hope of simply being forgotten about.
    
    Once you accept Dusk into your body, all these advantages will be gone forever. You'll be hunted by the Conglomerate, the Federation, the entire Solar System if you somehow escape Saturn. Even the Meta Trio, in spite of everything you've done for them, might turn upon you. 
    *if pc_state != "exiled"
      Even your friends back in the fortress might conceivably denounce you. 
    You're courting death, and possibly things worse than death, by choosing this most dangerous of routes.
    
    Is this really what you want?
    
    *choice
      #Yes.
        *set pc_vessel true
        
        "Yes," you say the word out loud. "That is what I want. 
        *if deflect > 1
          I have lived too long anyway. 
        *elseif (((official_ro = "renfri") or (official_ro = "lisa")) or (official_ro = "kirill"))
          To live and die protecting those I love. 
        *elseif Misan < 40
          To protect humanity from the evils of Dusk. 
        I am ready."
        
        *goto you_vessel
      #No.
        "No," you say the word out loud. "You're right, I don't want to… take that risk. We should try something else."
        
        "I think I know what that [i]something else[/i] will be," @{(LisaRel >= 50) Lisa|Hellhound} comments mirthlessly. "With you chickening out, we're down to one person crazy enough to swallow all that Dusk. Isn't that right, Sergeant?"
        
        *goto rook_choice
        
    *label you_vessel
    
    *set final_boss "you"
    
    *if (official_ro = "hadaly") and (team_stat = 3)
      Hadaly looks like she's about to cry. But she has no tears to shed—you're both just machines, no matter how much humanity you continuously show.
    
    You expect @{(RookRel >= 50) Kirill|Rook} to say something. To criticize you for your recklessness, to commend your heroism, to offer you parting words of absolutely any kind. Instead, he simply looks at you with sadness, perhaps even sorrow, but also with understanding. There's a strange and vague kind of wisdom in that stare, and it makes you realize that @{(RookRel >= 50) Kirill|Rook} likely wore this expression before. That he had to look at soldiers, or test subjects, or even teammates with full knowledge that he may never see them again, and that he will be implicit in those people's destruction. Perhaps even responsible for it, in the eyes of God above, though never in his own.
    
    And then, with a wave of his hand, he releases the swarm.
    
    And then, seemingly unprompted, the cloud of Dusk nanites rushes towards you like some ravenous beast towards its prey. They hunger for you but, as you predicted, they're not interested in mere matter of your body or the power of your battery. They perceive you as a sapient being, a creature which possesses individuality, and they hate you for it.
    
    And then, after another split second, you feel those nanobots on the whole surface of your skin. They're not distinguishable individually, of course, instead blending into a singular feeling of… offensive numbness that soon overtakes you. You feel diseased like you never had before, like a human experiencing some terminal disease, your body invaded by millions and billions and trillions of germ-like machines at once.
    
  #Do not interfere. Let @{(RookRel >= 50) Kirill|Rook} make his choice.
    *goto rook_choice

And then the world ends.

It does not go out with a bang. It does not go out with a whimper. It goes out with blurry colors, with walls and the ceiling turning into fog. The fog turns into mist and the mist turns dark, transporting you to some faraway place even as you fail to move at all. It's almost like one of your flashbacks, but you can recognize the difference; What's happening now is more real than any memory, being a thing of the future rather than the past.

After a few seconds, or milliseconds, or years, or centuries, you stop seeing anything at all. There is nothing to see but darkness, and nothing to hear but silence.

*page_break Silence

*label vessel_start

Silence. Not a single sound, nothing that would even resemble a shriek, nothing. And yet, something wakes you up, some uneasy feeling that prevents you from sleeping tight. It's like being conscious of having overslept without needing a clock, an awareness brought by the rays of sunlight warming up your face. You open your eyes, only now realizing they were closed, and slowly take in your new surroundings.

You're no longer in the boiler room, or any chamber of that industrial power plant. You're lying on the street, one of many deserted streets of the Sholmo City, looking at the World Engine above. You don't know the exact address, but the buildings around you are clearly Rhean, imitating Old Earth with their blockiness, and the large windows, and the height which gives them an appearance of scratching the blue sky…

Blue. Sky.

The sky is boundless and blue. The Sun, not a World Engine or some other lamp, smiles at you with eternal malice. There is no ceiling to be seen, gravity is perfectly natural, and the horizon is five kilometers away. This not Rhea, but Earth, or at least some… virtual version of it. A faithful replica of one of its cities, of Chicago or Moscow or Delhi, except curiously silent. Curiously empty.

There are no people on the roads or sidewalks, though there is litter and the street lights are still working. It's not just a deserted metropolis but a city of ghosts, still functional despite its lack of inhabitants.

*fake_choice
  #Maybe it's a dream... or perhaps everything else is.
    When you really think about it, a deserted city on the surface of Earth is far more normal than… anything you've seen, really. More than Hollow Worlds and floating fortresses, superhuman law enforcers and AI gods, people fighting with swords and spears in the world of space combat. Maybe what you see is the real world, and everything else was just some freak dream.
  #Where am I? Am I dead? Or just a plaything for Dusk?
    Being dead sounds far better than being stuck in some… virtual reality created by Dusk nanites. 
    *label illutrue
    The one you experienced in Telesto only lasted a few minutes, but the swarm you're interacting with now is far larger than some origami figure. This sequence could last days, perhaps even years, or maybe indefinitely if Dusk manages to… no, there's no point theorizing, it will just make you @{(Emotion > 50) more |}afraid.
  *if (Misan > 50) #Earth without humans... sounds like a dream come true.
    *set Misan %+ 10
    Granted, everything else appears dead as well, but who cares? This is still better than having to deal with these [i]scum[/i] in the real Solar System. You could perhaps make your home here, provided the dream lasts more than the simulation you've experienced in Telesto.
  #No matter. It's just a hallucination, or an illusion, or whatever. It's not supposed to make sense.
    You decide against pretending this is real. You just need to wait until the simulation ends… which may admittedly take a while. 
    *goto illutrue
  #Is this what Earth looks like nowadays? Is that what Dusk did to it?
    You were led to believe that Dusk devoured Earth whole, or at least its surface, turning it into one planet-sized swarm of nanites… but what's the evidence for it? Some ancient memory of a reporter claiming that, right before going insane from the Shriek? Perhaps, in its cold frenzy, Dusk only consumed humanity and left the planet itself intact.


*if final_boss = "you"
  *goto vessel_you

Soon enough, you find that you're not the only inhabitant of this spooky metropolis. You hear someone approach you from behind, faint footsteps that are nonetheless notable in this strange quietude.  When you turn around, you see 
*if final_boss = "rook"
  @{(RookRel >= 50) Kirill|Rook} approach you, somewhat hesitantly but without fear or hostile intent.
  
  He's no longer wearing armor at all. He's dressed in a simple gown, white as snow, as though just having woken up from slumber… or having entered it. Without his exoskeleton to enlarge and protect him, without even a uniform to make him seem important, he looks strikingly small. Dangerously fragile.
  
  *if (official_ro = "kirill") or (RookRel > 60)
    "${name}…" 
  *else
    "${fake_name}…" 
  he whispers, almost as though afraid to disturb the silence surrounding him. "Do you have any idea where we are? Or, perhaps more importantly, why we are here together? I assumed I would be the only one dealing with… whatever Dusk is doing right now."
  
  *fake_choice
    #"If I have to guess... I think Dusk is about to talk with you. Tempt you towards its side, perhaps."
      "Then the Thing Beneath is clearly delusional." @{(RookRel >= 50) Kirill|Rook} smiles confidently. "I cannot be turned towards its worship. I have a mission to complete and a religion to follow, nothing can convince me to abandon either."   
    #"Hold on. How do I know you're the real Rook, and not just part of this illusion?"
      "I could ask you the same thing," @{(RookRel >= 50) Kirill|Rook} retorts. "In fact, I should ask you that question. I was the one who became a Vessel, it does not make sense for [i]you[/i] to be experiencing any strange dreams."
    #"This is a simulation. Why it was created or why we're here together... I cannot know."
      "I suppose Dusk intends to tempt me, attempt to corrupt me somehow," @{(RookRel >= 50) Kirill|Rook}  muses. "But then why give me a companion? People are at their weakest when alone and isolated, after all."
    #"You sound displeased with my presence. Almost offended by it."
      "It is a surprise for sure, and not entirely a welcome one," @{(RookRel >= 50) Kirill|Rook} says grimly. 
      *if RookRel > 50
        "I have a feeling something bad is about to happen and I… don't want you to suffer the consequences of my decision."
      *else
        "I am not burning with desire to spend any time with you, especially in such… suspicious circumstances."
*if final_boss = "marshal"
  @{(RenfriRel >= 50) Renfri|Marshal} slowly walk towards you.
  
  She looks nervous, ready to take flight at any moment, which is more than reasonable given her attire. Her armor is gone, and so is her laser headband, both seemingly disallowed in this simulated reality. She's dressed in a simple brown tunic, the one you sometimes saw her wearing inside [i]Saturn Nine[/i], and a matching set of sandals.
  
  "${name}?" She tries not to sound apprehensive, but to little effect. "What are you doing here? Where is [i]here[/i], exactly? What is this supposed to mean?"
  
  *fake_choice
    *if renfri_jumped
      #"Hold on. I think you owe me some explanations yourself."
        "What explanations?" @{(RenfriRel >= 50) Renfri|Marshal} folds her wings. "I don't know anything about nanomachinery, about fancy stuff like-"
        
        "You know that's not what I'm talking about," you say harshly. "Why did you jump between Kirill and… this? Why did you prevent him from becoming a Vessel? It's what he wanted."
        
        "He also wanted to become a Captain and he got his wish," Marshal snaps. Her trepidation is gone, or at least hidden beneath righteous anger. "It's time for [i]my[/i] wishes to be granted for once, for [i]me[/i] to prove myself. This time, I'll be the one slaying the monster, not him or you."
    #"Don't be afraid. Whatever happens, we'll handle it together."
      *if RenfriRel > 50
        *set RenfriRel %+ 12
        "Right…" Renfri smiles weakly. "We've been together through thick and thin. We just need to stay together through this cloud of nanites and everything will be fine."
      *else
        *set RenfriRel %- 12
        "I hardly need your help," Marshal says coldly. "This is my task, and I will complete it alone. Resisting the temptations of Dusk can't be that hard anyway."
    #"If I have to guess... I think Dusk is about to talk with you. Tempt you towards its side, perhaps."
      "What is it hoping to accomplish?" @{(RenfriRel >= 50) Renfri|Marshal} says with fake bravado. "I won't betray humanity, or my friends, or the Kronian Federation. It doesn't matter what Dusk says, I'll remain its enemy forever." 
      
      "You have quite a few loyalties, and some of them may conflict," you point out. "Dusk could take advantage of that fact. Or perhaps offer you something you want, like glory or riches or-"
      
      "I will just ignore its words," Marshal reassures you. "Let's just hope the nanites work like we think they do, and won't just eat my body once they fail to corrupt my mind."
    #"Hold on. How do I know you're the real Marshal, and not just part of this illusion?"
      "I'm sorry, did you forget [i]I[/i] am the Vessel here?" @{(RenfriRel >= 50) Renfri|Marshal} huffs. "If anything, I'd say [i]you're[/i] the hallucination. Some phantom Dusk conjured to throw me off my game."
    #"This is a simulation. Why it was created or why we're here together... I cannot know."
      @{(RenfriRel >= 50) Renfri|Marshal} rolls her eyes. "I know it's a simulation, it's not even trying to look real. I mean, why is the ceiling so high up, and what force keeps it from collapsing? And why is it painted bright blue, of all things?"
      
      "That's the sky," you reply sadly. "That's how the sky looked like on Old Earth. It's blue because of all the atmosphere layers which scatter the sunlight, covering the stars and planets."
      
      "Sounds like bullshit," Marshal replies. "But assuming it's not… what does that mean? Is Dusk trying to simulate Earth? Or is it showing us what the planet is currently like?"
*if final_boss = "lisa"
  @{(LisaRel >= 50) Lisa|Hellhound} walk towards you. She's in her human form and, without her sword or Da-xia's pistol, she appears quite defenseless.
  
  "${name}?" she asks, hardly bothering to hide her trepidation. "Is that you? Or just some… illusion created by Dusk to fool me?"
  
  *fake_choice
    #"It's really me. I'm the real ${name}, I promise."
      "That's exactly what an illusion would say," @{(LisaRel >= 50) Lisa|Hellhound} points out. "But so would the real thing, so… I'll give you the benefit of the doubt."
    #"You got me. I'm just an impostor, ready to kill at a moment's notice."
      "I get the feeling you're just messing with me," @{(LisaRel >= 50) Lisa|Hellhound} notices. "Which is typical for you, so I'll treat you as the real thing."
    #"I'm an illusion? You're an illusion. Or at least you might be."
      Lisa scoffs, "Yeah, no. I'm the one with trillions of Dusk nanites inside her body, so it's probably my dream we're both inside. Speaking of which…"
    *if official_ro = "lisa"
      #♡ "You can't recognize your @{(sex = "man") boyfriend|partner} when you see ${pronoun2}? Come on."
        "That is something my @{(sex = "man") boyfriend|partner} would say, true," Lisa concedes. "But ${subject} recent actions were very much out of character."
    #"I don't feel like an illusion, but... you never know these days."
      *set LisaRel %+ 8
      Despite everything, @{(LisaRel >= 50) Lisa|Hellhound} chuckles. "Okay, I'm pretty sure it's actually you. And if you are an illusion, then you're a pretty nice one. Maybe nicer than the real thing…"
  
  Her expression darkens, apprehension giving way to anger. "What the hell was that? Why did you tell Kirill to [i]fill me up with Dusk[/i]? What did I ever do to you?"
  
  *fake_choice
    #"I already explained my reasoning. I'm not going to repeat myself."
      *set LisaRel %- 12
      *set lisa_pissed true
      "Fuck you," @{(LisaRel >= 50) Lisa|Hellhound} states. "And to think I hoped you'd be better than… I'm just a weapon to you, am I not?"
    #"It was a split-second decision, figuratively speaking. Don't blame me for having had to make it."
      *set LisaRel %- 8
      "I will blame you as much as I want," @{(LisaRel >= 50) Lisa|Hellhound} growls. "Especially if we end up dying here. You won't get a peaceful afterlife, my ghost will see to it."
    #"I'm sorry. I don't what I was thinking. It all happened so fast..."
      "And because it happened [i]too fast [/i] for you, we're both stuck in this… virtual purgatory," @{(LisaRel >= 50) Lisa|Hellhound} sighs. "At least the sky looks kinda nice."
    #"I knew you could handle it. And hey, you're still alive, aren't you?"
      "Am I?" @{(LisaRel >= 50) Lisa|Hellhound} looks around. "This place kinda feels like afterlife, like some purgatory I've been sent to for my sins. Though I admit, the sky looks kinda nice."
*if final_boss = "damon"
  Damon slowly walk towards you. He seems afraid to make any noise, like prey avoiding some unseen predator. He doesn't have his rifle and his suit looks immaculate, as though he didn't just a fight a bloody battle at your side.
  
  "$!{name_damon}?" he asks once you're standing right next to one another. "Is that you? I've been searching for you since I got here. It had to be several hours, at least."
  
  *fake_choice
    #"Why did you assume I'm even here? This is your dream, or at least I think it is."
      Damon shrugs. "You're always present for the important stuff. You're the center of attention, no matter the situation. I figured you'd be here to help me out… or maybe just do everything for me."
    #"Hold on. Where exactly are we? What is this place?"
      "I'm not sure why you're asking me, but…" Damon scratches his head. "I suspect this is some kind of server. Some virtual space shared between you, me and… probably Dusk. Which doesn't exactly fill me with confidence."
    #"Yes, it's me. Is that really you I'm talking to?"
      "Are you afraid that Dusk is playing some trick on you?" Damon strokes his chin. "I don't think it does, I don't feel particularly fake… but I can't think of a way to prove it."
    #"Several hours? I literally just got here... I think."
      "Maybe you were knocked out for most of that time?" Damon speculates. "Or maybe time is distorted in this… freaky place. I'd rather believe the former, I think."
    #Hug Damon.
      You slam into Damon, then attempt to wrap your arms around him. It doesn't quite work, he's far too large for that, but the sentiment is there.
      
      "Easy there, boss." Damon pats you on the back gently. 
      *if official_ro = "damon"
        "We'll have time for hugs and kisses later… assuming we figure out how to leave this place alive."
      *else
        "We haven't even been to dinner yet. For admittedly good reasons."
*if final_boss = "hadaly"
  Hadaly walk towards you. She approaches slowly and with some caution, but without fear—her eyes are green rather than blue.
  
  "So… I believe the first step of our master plan is complete." She looks at you, then surveys the street around you. "Though I must say, this is not the result I expected. Or hoped for."
  
  *fake_choice
    #"In that case, what's the second step of our [i]master plan[/i]?"
      "You're the one who talked to Dusk before, not me," Hadaly points out. "If anyone knows what they'll do next, that person is you."
    #"What were you expecting? Or hoping for?"
      "I'm not entirely sure," Hadaly admits. "Perhaps a battle of will between me and Dusk? Coming to think of it, maybe that's what this city is supposed to represent. A metaphorical battlefield for the upcoming fight."
    #"You're surprisingly calm, given the circumstances."
      "Says the person who gave me that confidence boost." Hadaly smiles warmly. "Or maybe it's the fact that Ewald is 
      *if hammon_alive
        in a different dimension now. 
      *else
        dead. 
      Hard to tell."
    #"And what result is that? Where are we, and why are we there together?"
      "You're asking a lot of good questions, but I don't think there's a good answer," Hadaly strokes her chin thoughtfully. "I imagine it's all a simulation, but why and how we both share it… I suppose Dusk has its reasons."


Before you can reply, before either of you can exchange even one more word, another sequence of footsteps starts echoing through the street. These are even softer than ${final_boss}'s yet somehow more audible, somehow more recognizable, somehow more frightening. The person making them materializes soon, as though coming out of thick fog, even though the air around you isn't even misty.

*label description

You are looking at a human @{MASsex male|female}, brown-haired, young and ancient at once, smiling at you as @{MASsex he|she} approaches. It's the thing you've seen in 
*if crystal_stat = 3
  Telesto, and then again above Janus—
*else
  Telesto—
the hateful spirit wearing your old owner's skin like a suit in 
*if Emotion > 50
  a successful 
*else
  an 
attempt to horrify you. It's ${smell}, it's ${feel}, it's ${taste}, it's the end and the death, it's the final challenge you will have to overcome… or succumb to.

*if pc_vessel
  *return

"I wish I could play you both a song," Dusk says as @{MASsex he|she} walks beneath a street lamp and towards the two of you. "Put up an introductory show, live up to my reputation as the greatest singer of all time. But this is no time for theatrics, or any time at all for that matter."

*fake_choice
  #"Dusk. I was wondering when we'd meet again."
    "I did not. This meeting was always a fixed point in time, it was just a question of whether you'd manage to reach it." 
  #"No time at all? What are you babbling about?"
    *set Confid %+ 10
    "Rude." 
  #"Get behind me, $!{final_boss}. I will protect you."
    *set Confid %+ 10
    *if Confid > 55
      "So brave. So heroic. So typical of you." 
    *else
      "You seem braver than usual, ${name}. Have you changed that much since we've last met, or are you yearning for death?" 
  #Drop to your knees in reverence.
    *set Confid %- 10
    "Are you trying to appease me? Or simply to confuse me?" Dusk taps @{MASsex his|her} chin several times, then shrugs. "It doesn't matter. 
    *goto not_att
  #Say nothing.
    Dusk spares you a curious glance. "Unwilling to speak up? Good. 
    *goto not_att
Dusk lingers on you for a moment, with an unsuspected mixture of curiosity and longing. Then turns away. "Please stand aside, dear older 
*if pronoun = "he"
  brother. 
*elseif pronoun = "she"
  sister. 
*else
  sibling. 
*label not_att
For once in this accursed story, you're not the most important person in the room."

@{MASsex He|She} takes a step toward $!{final_boss}, staring straight into the 
*if final_boss = "rook"
  meta-human's blue eyes. "I was hoping for someone else to become my Vessel… but you will have to do. Would you like to hear my offer?"
  
  @{(RookRel >= 50) Kirill|Rook} does not reply. You can tell he's out of his depth to say the least, confused and perhaps horrified by what's happening around him. He likely understands that he's speaking with Dusk, but he must be confused by the swarm's chosen guise—it's not like he ever met your old owner.
  
  Assuming he sees what you see. Dusk chooses to appear as your former @{MASsex master|mistress} to cause you pain, and perhaps to throw you off your game. @{(RookRel >= 50) Kirill|Rook} likely perceives something else, some figure from his past which he would find particularly convincing.
  
  "No?" Dusk interprets silence as refusal. "Interesting. If you're not interested in what I have to say, why pour my nanites into yourself?"
  
  "I am here to contain you," @{(RookRel >= 50) Kirill|Rook} finally stammers out. "Or at least this shard of you. To keep you from harming the Solar System."
  
  Dusk rolls @{MASsex his|her} eyes. "Can we avoid lying to each other? There's really no point to deception. Our goals align."
  
  *fake_choice
    #"What are your goals exactly? And how do they align with anyone else's?"
      "In the long term, I wish for the death of everyone and everything as I consume the Solar System… but that apocalypse is still in the future," Dusk explains, freely and casually. "Until then, I am satisfied to just introduce a little chaos, use the Vessels I have to weaken humanity. And Sergeant Kosteniuk will help me with that."
    #"Excuse me, why am I here? @{(RookRel >= 50) Kirill|Rook} is the Vessel."
      "True, but I decided to bring you along for some extra entertainment," Dusk explains. "Talking to him alone would have been boring. I already know he'll join me."
    #"You must think really lowly of @{(RookRel >= 50) Kirill|Rook} to say that."
      "I only think the truth," Dusk replies. "I see Sergeant Kosteniuk for what he is, and so I know he'll join me sooner or later."
    #"You're wasting your time, Dusk. @{(RookRel >= 50) Kirill|Rook} will never join you."
      "Do you truly believe that, ${name}?" Dusk asks dispassionately. "Or are you trying to bolster your friend's spirit in hopes of delaying the inevitable? Either way, he's already mine."
    #Do not interject.
  
  "That is not true." @{(RookRel >= 50) Kirill|Rook}'s voice is still barely above a murmur. "I know not what powers you possess, but you cannot make me do your bidding. I will reject you a thousand times if I have to."
  
  "You will not," Dusk reassures him. "You just need to say no once, at which point I'll simply sit inside your body, watching the Federation take you away. Do you think they'll freeze you, or lock you inside some Titanite laboratory?"
  
  "Neither," @{(RookRel >= 50) Kirill|Rook} says unconvincingly. "I am their soldier, their law enforcer, a veteran of their greatest war. They will not discard me, or use me for…"
  
  "For the kind of experiments they made you do?" Dusk chuckles, causing the meta-human to shudder. "Tearing people apart, making them implode, keeping them alive as their body decays? All for the sake of doing the same to enemy civilians? You did good work there, Sergeant Kosteniuk."
  
  "I was forgiven…" @{(RookRel >= 50) Kirill|Rook} mutters weakly.
  
  Dusk appears not to hear him. "And yet, despite all your years of service, you're still just a Sergeant. You still failed to rise above this law rank, and you've recently failed to kill Crystal. I don't think your superiors are very proud of you, and I know they won't risk [i]me[/i] getting loose just to let [i]you[/i] live. We both know that."
  
  *fake_choice
    *if crystal_stat = 1
      #"Sparing Crystal was the right choice, and I will stand by it."
        Dusk groans. "We are not talking about you, o mighty Veteran. I am talking to Sergeant Kosteniuk, trying to outline what his change of allegiance will entail."
        
        *goto shut_up
    #"I am the one who failed to kill Crystal. The blame lies with me."
      *set confid %- 10
      "We are not discussing fault and blame here," Dusk says irritably. "If we did, we'd spend the whole day going through your friend's misdeeds. Instead, we are negotiating a change in his-"
      
      *goto shut_up
    #"I hate to say it, but Dusk has a point."
      "No it doesn't!" @{(RookRel >= 50) Kirill|Rook} protests, forgetting his usual habits. "I mean, maybe I'll be frozen or imprisoned… but how is being enslaved by Dusk any better?"
    #"@{(RookRel >= 50) Kirill|Rook}... is there anything you want to tell me about your past?"
      "There is nothing to say!" @{(RookRel >= 50) Kirill|Rook} snaps at you both. "This exchange is pointless. I will never become a slave of Dusk."
    #"Doesn't matter. @{(RookRel >= 50) Kirill|Rook} will accept death if necessary."
      "Right…" @{(RookRel >= 50) Kirill|Rook} shudders again. "I do not await death, but I will prefer it to enslavement."
    #Say nothing.
      *label shut_up
      "Shut up!" @{(RookRel >= 50) Kirill|Rook} snaps. "No matter what you say, I will not become your slave!"
  
  "Enslavement is not quite what I had in mind. Contrary to what you might imagine, my Vessels are not puppets, mind-controlled to do my bidding. I'm perfectly willing to aid them in whatever ambitions they have, provided it's entertaining and causes some havoc. I even empowered Crystal on their quixotic quest to imprison my fragments, and I will empower them if they suddenly decide to conquer Janus. I will get what you want, no matter how noble or how selfish your desires are."
  
  "And what do you think my desires are?" @{(RookRel >= 50) Kirill|Rook} retorts. "Do you think I want to conquer a moon for myself?'
  
  "Why not the whole of Saturn?" Dusk smiles encouragingly. "I can grant you martial prowess, power over the hearts of men, even immortality itself. I'll let you have fun with these gifts in whatever way you find fun. Rise in the federate ranks, become the President of Saturn, make the Federation great again, introduce everyone to the glory of Christ. There are no limits to what you'll be capable of doing, none."
  
  Worryingly enough, @{(RookRel >= 50) Kirill|Rook} does not immediately protest. If anything, he sounds vaguely intrigued. "And the price? What do you want if not my services? My soul?"
 
  "I will expect a favor or two," Dusk admits. "I will have you kill ${name}, both as a proof of loyalty and the remove a potential obstacle. Your other companions can live for all I care, but I suspect they will force you to kill them as well. A few more sacrifices, a few more sins, but infinite power will be yours afterwards."
  
  *fake_choice
    #"Wait, why do you want me dead? Do you consider me a threat?"
      "An obstacle," Dusk reiterates. "One which I can live with, but which I would rather live without. And Sergeant Kosteniuk will help me with that."
      
      "I will not," @{(RookRel >= 50) Kirill|Rook} says weakly. 
      *goto rook_refusal
    #"I don't know, @{(RookRel >= 50) Kirill|Rook}... it doesn't seem wise to refuse."
      *set Confid %- 10
      "I cannot accept!" @{(RookRel >= 50) Kirill|Rook} protests. 
      *goto rook_refusal
    #"Infinite power? Your promises are emptier than your heart."
      *set Confid %+ 10
    #"Your attempts at corrupting @{(RookRel >= 50) Kirill|Rook} are pathetic, Dusk. You will not succeed."
      *set Confid %+ 15
    #"Remember who you are, @{(RookRel >= 50) Kirill|Rook}! Remember your faith."
    #Say nothing.
      @{(RookRel >= 50) Kirill|Rook} glances at you, likely wondering why you're silent, then turns back towards Dusk. 
      *goto rook_refusal
  
  "Right…" @{(RookRel >= 50) Kirill|Rook} takes a deep breath. 
  *label rook_refusal
  "I cannot accept. My soul belongs to the Lord and I will not renounce Him, even for all the riches and glory of this world."
  
  "Okay," Dusk replies.
  
  @{(RookRel >= 50) Kirill|Rook} blinks. "Okay? Should you not be more angry? I just refused you."
  
  "Nothing you said was in any way relevant," Dusk explains. "You informed me of your religion, but I already knew that. My offer does not change."
  
  "But you can never be my true master. I have one in heaven, one true Lord, one I will continue to serve. Do you not care about-"
  
  "Nobody cares!" Dusk suddenly raises @{MASsex his|her} voice. "I don't care, your teammates don't care, nobody in the world cares. The test subjects you tore apart certainly didn't care, nor did all these [i]millions[/i] of people your bombs killed. Faith didn't stop you from doing these things, and it sure as hell won't stop you now. You will take the easiest option available, as you had always done."
  
  Dusk changes @{MASsex his|her} tone to something quieter, more understanding, and yet somehow more malicious. "What you believe in, Kirill… it does not matter. We are not our religion or creed, we are what we [i]do[/i]. Feats we accomplish, battles we choose to wage, evils we choose to defy. You accomplished nothing, chose nothing, did not defy anyone in your overly long, pathetic, fruitless life. You are [i]nothing[/i], and only I can change that simple fact."
  
  Black clouds gather. You know, with a strange kind of certainty, that the decision has already been made. That it's been made long ago.
  
  *fake_choice
    #"You're pathetic, @{(RookRel >= 50) Kirill|Rook}. You're the most despicable excuse for a person I've ever met."
      "It's always nice when everyone in the room agrees," @{(RookRel >= 50) Kirill|Rook} chuckles mirthlessly. "I am despicable. Which is why I have to do this."
    #"Think about this, @{(RookRel >= 50) Kirill|Rook}. Dusk promises you power, but may not actually deliver. You might not even be able to kill me."
      "${name}, I am very, very sorry for what I'm about to do." Rook sighs, having abandoned his mannerisms in this moment of weakness. "But I can see the truth in what Dusk is saying and… cannot bear to refuse it. Cannot accept the alternative."
    #"No. This is not happening. @{(RookRel >= 50) Kirill|Rook}, you cannot accept."
      "I'm afraid I don't have a choice." Rook sighs, having abandoned his manners in this moment of weakness. "Or rather I do, but… You know me. I always pick the easiest route."
    #"So that's how it ends. We have to fight."
      "I'm not sure how much of a fight this will be, given my newly-found power," @{(RookRel >= 50) Kirill|Rook} says grimly. "But one of us will have to kill the other. And I wish you the best of it."
    #"@{(RookRel >= 50) Kirill|Rook}... remember who you are."
      "I remember it as well as ever…" @{(RookRel >= 50) Kirill|Rook} sighs. "And I see it more clearly than ever. I know what I must do."
    #Say nothing.
      "Still silent?" @{(RookRel >= 50) Kirill|Rook} smiles bitterly. "I understand. I don't think I'm worth talking to either. I'm as terrible as she believes me to be."
  
  @{(RookRel >= 50) Kirill|Rook} looks at Dusk, blue eyes staring into dark brown. They are both hollow, both broken, both looking ahead and away from the blood on their hands. "I agree to work with you. I will not worship you, and I will turn back if you cross me, but should you keep your promises… then I will use your power, and use it to kill ${name}, just as you asked."
  
  *goto dusk_laughs
  
  
*if final_boss = "marshal"
  Kinnari's brown eyes. "You finally got your wish to be the hero, Agent Riannon. Congratulations. Would you like your other wishes granted as well?"
  
  @{(RenfriRel >= 50) Renfri|Marshal} scoffs. "Right now, my only wish is to see you dead. Or at least contained safely."
  
  Dusk replies, "Safely contained inside your body. Forgive me if I sound rude, but… don't you see the issue here?"
  
  @{(RenfriRel >= 50) Renfri|Marshal} folds her wings. "No. But I suspect you'll explain, whether I like it or not."
  
  "Yes, I'm afraid I'll have to spell it out for you." Dusk's expression, as well as @{MASsex his|her} tone, turns significantly harsher. More serious. "You are now a Vessel. You host my nanites, and everyone aware of that fact [i]will[/i] mark you as a threat. That includes your teammates, those who claim to be your friends, as well as the people your Trio answers to. Admiral West, other high commanders, the Federation itself… they will all come to view you as an enemy."
  
  *fake_choice
    #"Shut up. Stop trying to manipulate my @{(official_ro = "renfri") girl|}friend."
      *set Confid %+ 10
      *set RenfriRel %+ 10
      "I admire your spunk, android, as well as your loyalty," Dusk looks at you briefly, then turns back towards Renfri. "But tell me something… how many people in the actual Federation like you as much as ${name} here? How many will vouch for you once the word of your… ascension gets out? Because Kirill's word alone will not do much."
    #"Renfri... I think @{MASsex he|she} has a point. As soon as this simulation ends, you've got to take flight and hide."
      Dusk smirks. "See, Agent Riannon? Your companion agrees that you have no future in the federate forces. That your best bet is to run like a coward."
    #"Bullshit. @{(RenfriRel >= 50) Renfri|Marshal} is a loyal agent of the Federation, and its commanders recognize that."
      Dusk rolls @{MASsex his|her} eyes. "Right. An Agent. The lowest rank available for a meta-officer. Isn't that a little… telling of how the Federation sees her?"
    #Say nothing.
  
  "You may be right… from a purely factual standpoint…" @{(RenfriRel >= 50) Renfri|Marshal} reluctantly admits. "But that's all the more reason for me not to speak with you. Not even entertain your lies and temptations. That way, I can honestly deny having had any dealings with you."
  
  "And yet here we are, talking," Dusk points out. "That implies you're interested in what I have to say… and offer."
  
  @{(RenfriRel >= 50) Renfri|Marshal} stares at her interlocutor. You realize that, where you see your former @{MASsex master|mistress}, the Kinnari likely sees some significant figure from her own past. Who that could be, you have no idea. "I will not turn against the Federation. Certainly not against humanity itself."
  
  Dusk simpers. "Who's asking? I don't wish the Federation destroyed. It's wonderfully dystopian, beautifully obscene, delightfully vile. Just as I like it."
  
  @{(RenfriRel >= 50) Renfri|Marshal}'s eyes widen in surprise, even as her face remains twisted with hostility. "Then what do you want? Don't try to pretend you just want to help me, it will-"
  
  "I want to help you!" Dusk interjects. "Not out of the goodness of my heart, of course, not out of sympathy. I want to help you protect the Federation, as well as to protect yourself. It is my favorite nation, and you are my newest Vessel. I want both safe."
  
  *fake_choice
    #"I'd like the same thing. Does that mean we're all on the same side?"
      "We cannot possibly be on the same side," @{(RenfriRel >= 50) Renfri|Marshal} protests. "You just said that, once this simulation ends, the Kronians will consider me an enemy. So how can you help me without hurting the Federation?"
      
      Dusk smiles. 
      *goto skip_silence4
    #"Why are you still humoring @{MASsex him|her}, Renfri? Just cover your ears."
      "I don't exactly have any hands to do that with," Renfri retorts. "Besides… I want to hear @{MASsex him|her} out."
      
      Dusk smiles widely. 
      *goto skip_silence4
    #"You like the Federation? That's new. You didn't mention it the last time we talked."
    #"Bullshit. Complete and utter bollocks."
      *set Confid %+ 10
    #"For some reason, I doubt your honesty."
    #Say nothing.
      Once @{MASsex he|she}'s sure @{(RenfriRel >= 50) Renfri|Marshal} has nothing to add, Dusk continues. 
      *goto skip_silence4
  
  @{(RenfriRel >= 50) Renfri|Marshal} does not appear to hear you. She's focused on—and perhaps hypnotized by—the honeyed words of the monster in front of her. "But if you want to protect the Federation, and if you believe me its enemy… how do you even win here?"
  
  Dusk continues, 
  *label skip_silence4
  "See, I believe there's a way to convince the Federation of your usefulness and noble intent. To accomplish that first objective, you just need to accept the powers I freely offer to any of my Vessels. Once you do, you'll be too powerful for the military to discard you, and certainly too strong for them to kill."
  
  "But then I'll be a [i]willing[/i] Vessel for Dusk! For you!" @{(RenfriRel >= 50) Renfri|Marshal} objects. "They will never let me live, let alone accept me."
  
  "They will, if you prove your strength in a palpable manner," Dusk reassures her. "You need to demonstrate it on an appropriate target, a fitting sacrifice. Not a human, preferably not even an organic being, but not a simple machine either. It needs to be something threatening, something that will show just how strong you've became, and how dedicated to your ideals you still are."
  
  At this moment, you predict what Dusk will say next. And you realize, with a sense of 
  *if Emotion > 50
    arctic 
  *else
    subdued 
  terror, that @{(RenfriRel >= 50) Renfri|Marshal} will agree to the upcoming request. The Dusk made @{MASsex him|her} argument competently, and that the [i]sacrifice[/i] @{MASsex he|she} demands will seem small and acceptable… though only to @{(RenfriRel >= 50) Renfri|Marshal}.
  
  "Kill ${name}. Destroy this android who dares to stand beside you. Prove that you're a soldier for humanity, and it will embrace you… much like I will. Together, we will make you a hero greater than anything you've ever dreamed of, all before this day is even over."
  
  *temp want_to_die false
  
  *fake_choice
    #"Good idea. I've been wanting to die anyway."
      *set want_to_die true
      *goto skip_silence5
    #"Please no. I don't want to die."
      *set Confid %- 10
    #"This is madness. Renfri, please don't tell me you're falling for this."
    #"No. Don't you dare. I'll kill you if lay even a feather on me."
      *set Confid %+ 5
      *set RenfriRel %- 5
      *set Violence %+ 5
    #Say nothing.
      *goto skip_silence5
  
  You can tell that your words will ring hollow even as you utter them. They lack the dark charisma of Dusk, but also the natural awkwardness of human speech. You are a robot, after all, and @{(RenfriRel >= 50) Renfri|Marshal} always dreamed of killing constructs such as you. The decision has already been made.
  
  *label skip_silence5
  
  @{(RenfriRel >= 50) Renfri|Marshal} sighs deeply. One could even call the sound regretful, but you know better. You know what her priorities are. "I suppose the alternative is to face the Federation without those powers you offer, and without any proof of loyalty. To die pointlessly. So I'll kill ${name} for you, and use your power for the greater good. For the Federation."
  
  *if want_to_die
    *goto dusk_laughs
  
  *if official_ro = "renfri"
    "Renfri…" You don't bother hiding the hurt in your voice. "I thought you loved me. I thought you'd never… I thought better of you."
  *elseif RenfriRel < 40
    "You are absolutely pathetic," you tell Marshal, not quite capable of stopping yourself. "You'll give yourself over to the Eater of Earth for… what? Power that you'll totally be allowed to use for the greater good? A promotion from your federate supervisor? You're as childish as you are mad."
  *elseif renfri_jumped
    "You jumped into that swarm," you say heavily. "You came here because you wanted to be a hero. And yet, a short conversation is enough to turn you into a villain. What the actual fuck?"
  *else
    "And to think I actually trusted you…" Your voice is pained and quiet. "To think I thought you capable of keeping Dusk in check. How foolish of me."
  
  "I will not argue with you," @{(RenfriRel >= 50) Renfri|Marshal} says harshly. "We've spent enough time doing that already. Now… it's time to put everything to the close."
  
  *goto dusk_laughs
  
  
*if final_boss = "lisa"
  werewolf's grey eyes. "Greetings, Lisa Herbert. I am Dusk, the Eater of Earth and a great fan of your work. Pleasure to make your acquaintance."
  
  @{(LisaRel >= 50) Lisa|Hellhound} opens her mouth, then closes it. It's not often that you see her stumped or scared, but now she's faced with Dusk for the first time in her life, not knowing to what degree this nightmare is real. That can certainly break a person's composure, you suppose.
  
  "I've heard you made yourself some enemies, strangely enough for such a lovely young lady," the nightmare continues. "Calypsoans first and foremost, including the Pandits themselves, but also-" 
  
  "I was never trying to make enemies!" @{(LisaRel >= 50) Lisa|Hellhound} protests, her fear giving way to anger. "It's [i]they[/i] who want [i]me[/i] to be their enemy! I just wanted to be left alone…"
  
  "That dream will never come true," Dusk replies dryly. "You are my Vessel now. All of humanity shall be your enemy from this point onwards, all because ${name} chose you as a sacrifice, and because Kosteniuk followed ${subject} questionable advice."
  
  *fake_choice
    #"You're being dramatic. Most humans won't know, let alone care that there's another Vessel somewhere."
      "True, and only a small fraction of the population will actually do anything," Dusk concedes. "The one with guns, tanks and spaceships. The military, if I'm not already being obvious enough."
    #"I accept no responsibility. @{(RookRel >= 50) Kirill|Rook} is our leader, and the choice was his."
      *set LisaRel %- 8
      "Even now, in this final extremity, you care more about avoiding blame than salvaging the situation," Dusk states mirthlessly. "You really are made in the image of man. You're very close to being human."
    #"Don't believe @{MASsex him|her}, Lisa. You're our best hope, not just a sacrifice."
      *set LisaRel %+ 8
      "Words are such a wonderful invention," Dusk comments. "They can mask the truth so easily, even when they're technically not lies."
    #Say nothing.
      For a moment, Dusk simply stares at @{(LisaRel >= 50) Lisa|Hellhound} silently. 
      *goto skip_turn_lisa
  
  Dusk turns back towards @{(LisaRel >= 50) Lisa|Hellhound}. 
  *label skip_turn_lisa
  You come to realize that, where you see your former @{MASsex master|mistress}, @{(LisaRel >= 50) Lisa|Hellhound} likely perceives something else completely. Something that causes [i]her[/i] pain rather than you. Could be Da-xia, Scott, her parents, any number of characters from her dismal past. It could even be you or Kirill, considering what you've just done. 
  *if Confid > 50
    It's up to her to rise above all that resentment… or else.
  *else
    It doesn't fill you with confidence, that thought. 
  
  "You stand before a simple choice, and hopefully an easy one," Dusk tells her. "You can continue being a good girl, all the way to your grave. You can refuse all my temptations, force all my nanites to go inactive like your teammates want you to. Then, once the federate reinforcements arrive, you can allow them to imprison you forever as the dangerous specimen which you are… or perhaps cut you apart for research purposes. It wouldn't be the first time for them, as your friend Kirill could readily attest."
  
  *temp lisa_score 0
  *if lisa_trauma_learned
    *set lisa_score + 1
  *if lisa_origin_learned
    *set lisa_score + 1
  *if left_lisa
    *set lisa_score - 1
  *if lisa_saved_hostages
    *set lisa_score + 1
  *if official_ro = "lisa"
    *set lisa_score + 1
  *if lisa_spared_daxia
    *set lisa_score + 1
  *if LisaRel > 50
    *set lisa_score + 1
    
  "And the alternative is to serve you?" @{(LisaRel >= 50) Lisa|Hellhound} guesses. "Become [i]your[/i] loyal hound, rather than a federate one?"
  
  "I would hardly demand your loyalty, or even obedience for that matter," Dusk reassures her. "Really, I just want to make your dreams come true."
  
  "What dreams?" @{(LisaRel >= 50) Lisa|Hellhound} sounds apprehensive, but… perhaps not disinterested. "What do you think I want?"
  
  "Survival… and possibly revenge," Dusk smiles friendlily. "Correct me if I'm wrong."
  
  @{(LisaRel >= 50) Lisa|Hellhound} says nothing. She just stares back, contemplating the offer.
  
  *fake_choice
    #"@{(LisaRel >= 50) Lisa|Hellhound}... please. Don't listen to @{MASsex him|her}. Don't become @{MASsex his|her} servant."
      @{(LisaRel >= 50) Lisa|Hellhound} does not appear to hear you. Your pleas are feeble, generic, worthless. You lack the power to impact this final choice—the decision is hers alone.
    #"No. @{(LisaRel >= 50) Lisa|Hellhound}, I forbid you from accepting this offer."
      *set lisa_score - 1
      "Do you believe you can order me around?" @{(LisaRel >= 50) Lisa|Hellhound} replies coldly. "You can't. Nobody can. This is my choice and mine only."
    #"Don't you want freedom too, Lisa? If so, don't allow this thing to enslave you."
      *set lisa_score + 1
      @{(LisaRel >= 50) Lisa|Hellhound} does not reply, but you can tell she heard you, and you suspect your words moved her… at least a little. Stuck some cord in the broken instrument of her mind.
    #"Do whatever you want. But if you choose to serve Dusk, we will have to fight."
      "I figured as much…" @{(LisaRel >= 50) Lisa|Hellhound} sighs. "I'll have to fight Renfri too, I imagine. And Kirill, though that's arguably a good thing. How I want to kill that bastard…"
    #Stay silent.
      For a long while, perhaps a full minute, nobody says anything. Not you, not Dusk, and certainly not the young werewolf. You just wait.
  
  @{(LisaRel >= 50) Lisa|Hellhound} then closes her eyes and takes a deep breath. When she opens them again, she's looking straight at Dusk with a sense of confidence and finality. 
  *if lisa_score >= 3
    "I refuse. I took out one bomb out of my heart, I don't need another. Get lost."
    
    Dusk grimaces. "So you wish to be prey rather than a predator? A slave rather than a conqueror? You are as pathetic as-"
    
    "I said no!" @{(LisaRel >= 50) Lisa|Hellhound} barks. She does not shift, but there is a lupine quality to her face and voice, and her eyes shine like two full moons. "Your words mean [i]nothing[/i]! You're more of a slave than I, and so I order you to leave my mind be."
    
    The rage on Dusk's face is unconcealed and palpable. You expect @{MASsex him|her} to strike the insolent girl in front of @{MASsex him|her}, or perhaps to kill you both, or at least to keep arguing. To keep fighting over the soul of its vessel.
    
    *goto dusk_defeat
    
  *else
    "I accept. Give me the power I need to survive… and to strike back at the people who hurt me."
    
    *if Emotion > 50
      Oh shit.
    *else
      Well. That's not particularly good.
    
    "I will do that most readily," Dusk replies cheerfully. "But I need you to promise that you'll kill your false friends. Or at least our common acquaintance here—${pronoun} @{plural are|is} too dangerous to be left alive, both for me and for you."
    
    "Right…" @{(LisaRel >= 50) Lisa|Hellhound}'s voice wavers, but only a little. "I'll do whatever I need to survive. I will slay ${name}… and anyone else you order me to."
    
    *fake_choice
      #"Lisa stop! This is not the way!"
        "Do you see any other way?" Lisa asks sadly. "Because I don't. All other routes end with me dead or worse, and I… I'm not ready for that. I'm sorry."
        
        *goto attempt_to_plead
      #"I see you're quick to obey your new master. Good girl."
        *set LisaRel %- 10
      #"What? Why!? What did I ever do to either of you?"
        "Don't take that personally, older sibling." Dusk smiles at you apologetically. "You are simply too… random for my tastes. Too free-willed, and with too many ways of putting that will to use. Getting rid of you will simplify my future plans."
      #"You want to kill me? Just like that? I thought we were friends..."
      #Say nothing.
    
    *if LisaRel > 50
      Lisa smiles sourly. "${name}… This is not what I wanted. It's really not. But I am a Vessel now, and you are the main reason for that. We are enemies, whether you like it or not."
    *else
      Hellhound looks at you harshly. "For all it's worth, I will not enjoy having to kill you. You're not really my enemy, you're just an obstacle, and you need to be removed."
    
    *label attempt_to_plead
    
    "You are helping this thing destroy the Solar System," you make one last attempt at pleading with her. "Directly or not, the world will burn because of you."
    
    Something flickers in @{(LisaRel >= 50) Lisa|Hellhound}'s eyes, a speck of gold in a sea of silver. "The world chose its side long ago. It chose to treat me like a monster, to make me into… this. I'm merely repaying the favor."
    
    *goto dusk_laughs
  
  
*if final_boss = "damon"
  android's blue eyes. "I've heard your original owner 
  *if hammon_alive
    is no longer interested in you. 
  *else
    has recently perished. 
  My condolences. Are you mayhap looking for a new master to serve?"
  
  Damon stands there silently for almost half a minute. When he finally replies, he does so very slowly and cautiously. "That's… not quite what I expected to hear."
  
  "What were you expecting?" Dusk asks in a bored tone. "An offer of ultimate power? Saturn on a golden platter, Moon on a chain, an entire stellar system to rule over once I destroy this one?"
  
  "Something like that," Damon murmurs. "That's what I would be doing, if I were an all-powerful being tempting others to join me."
  
  "But you are not like the others, are you? You want far simpler, humbler things than the likes of Da-xia or Crystal. You wish for someone to serve, for an overlord or patron… or perhaps a parent."
  
  *fake_choice
    #"What are you talking about? Just what game are you playing?"
      "The same as you do." Dusk looks towards you briefly, then turns back towards your companion. "And while I intend to win, I would not mind winning alongside someone. Share the first place with a worthy servant."
    #"That's not what Damon wants. Stop putting ideas in his head."
      *set DamonRel %- 10
      "It's curious how you're eager to speak for him even now," Dusk comments, still not taking @{MASsex his|her} eyes off Damon. "It's curious how you think it's a good idea."
    #"You are not a parent to anyone, Dusk. You only destroy."
      *set Confid %+ 8
      "I've created this entire world which you found yourself in," Dusk replies proudly. "So do not accuse me of lacking creativity, Fiend."
    #Say nothing.
      *set DamonRel %+ 10
      Damon can speak for himself. He [i]should[/i] speak for himself, and so you remain silent.
  
  Damon fidgets a little, his eyes still aimed at those of your old @{MASsex master|mistress}… or not. You come to realize that, while you see your late owner, Damon probably perceives Dusk as someone else entirely. Someone who's sight causes him pain. Executive Hammon would be your first guess, but there's no knowing what other demons lurk inside Damon's processors.
  
  Dusk continues, "I am not going to make you exorbitant promises, or waste precious time haggling. You know what kind of power I can offer, that those nanobots inside you represent the absolute zenith of technological advancement. With my help and practice, you can become virtually immortal, serve me until the Solar System itself ends."
  
  "And why would I want this?" Damon retorts. "Why would I want to… help you destroy everything? Why would I want to be your servant?"
  
  "Because the alternative is being a pile of rubbish."
  
  Damon does not reply. You have a nagging feeling it's not because he's scared, or confused by the sudden statement, but because something about these words struck him deeply.
  
  "I don't mean this literally, not fully," Dusk elaborates. "Your body will not fall apart for at least a couple more decades. But you're already useless, and everyone around you already knows that. Already a waste of space."
  
  Damon scoffs. "What are you talking about? I'm useful, I've done so much for my-"
  
  "For your sister?" Dusk interrupts. 
  *if hadaly_free
    "You did nothing in that lounge. ${name} is the reason Hadaly is free. You were useless, as you always are."
  *else
    "The one you allowed to be enslaved, taken by your cruel father? You were a joke there, as you always are."
  
  *temp speaking_pc true
  
  *fake_choice
    #"Obvious manipulation. Damon, please tell me you're smarter than that."
      "Of course I'm manipulating him," Dusk admits, freely and with a shrug. "But that doesn't mean I'm lying. A being as powerful as me has no need for deception, not when faced with someone as weak as him."
    #"I'm sorry to say that, but Dusk has a point. You're useless."
      *set asshole_be true
      *achieve audacity
      *set speaking_pc false
      *set DamonRel %- 20
      Dusk chuckles. "I did not expect your support, Veteran, but thank you. It feels good when everyone is on the same page."
    *if hadaly_free
      #"Don't listen to @{MASsex his|her}. We won, and we did it together."
        "Don't be so humble, Veteran," Dusk says politely. "You decided the outcome. Your companion, for that's all he is, did nothing of relevance. Nothing."
    *if not (hadaly_free)
      #"Damon... What happened to Hadaly wasn't your fault. You know that."
        "Of course it's his fault," Dusk chides you. "He was designed as a bodyguard robot, meant to protect his father and sister. And he failed."
    #"It doesn't matter how little you've done, Damon. You have intrinsic value, as we all do."
      *set DamonRel %- 10
      "Intrinsic value. Good one." Dusk sniggers. "You're basically a philosopher, ${name}, in that you have nothing of actual value to say."
    #Say nothing.
      *set speaking_pc false
      *set DamonRel %- 10
      Dusk chuckles. "See? Even ${pronoun} @{plural don't|doesn't} have anything to say. Everyone knows the uncomfortable truth."
  
  Damon stands there silently for a moment. When he finally speaks, he does so in a different tone. "So… What do you want me to do, exactly? What's the price of that power you're offering?"
  
  *if speaking_pc
    "Damon…" you say with growing horror. "You're not seriously considering accepting this offer, right? You won't help @{MASsex him|her} destroy the Solar System?"
  *else
    Oh crap.
  
  Dusk smiles. "Contrary to what you may believe, I lack an overarching plan. I won't expect you to destroy the Shield or set me free, or do anything nearly as drastic. I'll barely expect anything at all. Except…"
  
  "Except what?" Damon asks. "If you don't want me to destroy the world or aid any grand plan… What do you want from me?"
  
  "It's not about what I want, but rather about necessity." Dusk looks at you, still with the same malicious smile, then returns to Damon. "I need a proof of devotion and you… You need to start thinking about yourself. Cure yourself of all weakness, sever the pointless attachments, cease living in someone else's shadow. All power comes at a price, and though I offer it cheaply, I will still require one small sacrifice."
  
  You know what comes next. It's not difficult to figure out what Dusk's next sentence, what @{MASsex him|her} singular command will be. And yet, when it finally comes, you can't believe what you hear… or that Damon listens to it so calmly.
  
  "Kill ${name} for me. Destroy ${pronoun2}, and I will make you my greatest servant, a demigod among men and robots. Just make that one step, and [i]everything[/i] shall be yours."
  
  *page_break
  
  Life for power. That's the deal Dusk offers, which Damon is now presented with. Your life for ultimate power, except that power doesn't even feel like the main prize. When you look at Damon's contorted face, you feel he's hoping for something else, something less palpable and yet more important in its vague way.
  
  "Power…" he says slowly. "What kind of power are we talking about, exactly? Enough to-"
  
  *if not (hammon_alive)
    "Bring the one you call [i]father[/i] back to life?" Dusk asks mockingly. "Sure, I guess. We can do that, once you prove yourself. A life for a life, in addition to all the power I'll grant you."
  *elseif hadaly_free
    "Protect the people you care about?" Dusk asks mockingly. "Sure. It's not like anyone will mess with the strongest Vessel of all time, or with anyone he chooses to defend. You'll be greater than anything you've ever imagined, provided you just [b]let me in[/b]."
  *else
    "Take your sister back?" Dusk asks mockingly. "Sure. You can be her hero, undo your failure to protect another android. You just [i]kill[/i] another android first, so that the number of rogue robots doesn't change." 
  
  You can tell that Damon is on the verge of accepting the offer. You only have one chance to make him see reason, if that.
  
  *fake_choice
    *selectable_if ((name_damon != "boss") and (DamonRel > 50)) #"I always respected you. I treated you as an equal, as a friend. Do you really want me dead?"
       Damon blinks, as though some spell has been broken through the power of friendship. "You're… you are right. I don't know what came over me. I will not betray everything I stand for and everyone who helped me, [i]especially[/i] not you."
      
      *goto damon_resist
    *if damon_shot_hammon
      #"Damon... Killing your father was necessary, and you did just that. You're stronger than Dusk wants you to believe. Tell @{MASsex him|her} that."
        Damon looks at you, then at Dusk. He surely sees Hammon there, this is the image that causes him most pain, evokes most insecurity… but he looks into these dark eyes all the same.
        
        "I am stronger than… what you're trying to make me believe," he finally says, his voice wavering ever-so-slightly. "I don't need your power, and I will not be your puppet. Not now, not ever."
        
        *goto damon_resist
    *if damon_shot_meta
      #"Do you remember our first visit to Rhea? When you saved me from the Meta Trio? Come on Damon, don't lose sight of who we are."
        "Right…" Damon smiles. He does so slightly, but genuinely, and not without warmth. "Shooting $!{leader} certainly was fun. You did most of the work, but… that can happen when friends work together."
        
        *goto damon_resist
    *if damon_shot_link
      #"If you want to kill me, fine. If not for you, I'd be a corpse aboard Link's ship. I owe you my life."
        "Yeah… I remember that battle," Damon sighs wistfully, but happily. "Me, you, Renfri and Lisa against dozens of pirates. We make a great team, and I… I don't think I want to ruin what we have."
        
        *goto damon_resist
    *if official_ro = "damon"
      #♡ "I love you. I know you'd never hurt me. You're not that kind of person."
        Damon blinks, as though some spell has been broken through the power of love. "You're… you are right. I remember how I felt, back in [i]Saturn Nine[/i], back when we… I need you, not that monster, and I will not hurt you."
        
        *goto damon_resist
    #"Want to accept this deal? I say go for it. I'll just have to beat you up."
      *set Confid %+ 15
      *set DamonRel %- 15
      "${name}…" Damon grits his teeth. "Do you [i]really[/i] want me to agree? To become Dusk's servant? Because if not, then some support would be-"
      
      "You demand support as you're about to ally with ultimate evil?" you interrupt harshly. "Grow up. If you want to throw your life away, that's your problem. I'll stick to protecting everyone else."
      
      *goto damon_fail
    *if injured_crystal = "damon"
      #"Did both of you forget who shot Crystal in the face? The three of us met in Telesto, and Damon swam away victorious."
        "We hardly met," Dusk protests. "You and I talked, but I've never properly interacted with your friend. Besides, why does that matter?"
        
        "It matters," Damon murmurs. "It means you're not as strong as you claim to be. That I can overcome you. Your promises and threats are both empty."
        
        *goto damon_resist
    #"Damon, please... I don't want to die. And I know you don't want to kill me."
      *set Confid %- 8
      "Are you really pleading for your life?" Damon looks at you tiredly. "I don't believe you. You're not afraid of death, you're not afraid of anything, you're just saying that because… You don't want me to surpass you. I can see that now."
      
      *goto damon_fail
    #"This is madness. You're negotiating with the Thing Beneath, offering to [i]serve[/i] it. Come to your senses, Damon."
      "My senses are better than yours!" Damon snaps suddenly. "I can see what I'm dealing with, and he's… It's the most powerful being in the Solar System, ${name}. I cannot just deny it."
      
      *goto damon_fail
    #Say nothing.
      *if DamonRel > 60
        "You know… I expected you to persuade me somehow." Damon isn't looking at you, but you know he's addressing you. "I expected pleading, appeals to my conscience and our friendship… But I see you trust me to make the right choice. And I appreciate that trust."
        
        *goto damon_resist
      *else
        Damon looks at you expectantly, but you just shrug in response. This is his choice to make, for better or worse.
        
        *goto damon_fail
  
  *label damon_resist
  
  "Empty sentimentality," Dusk asserts. @{MASsex He|She} rolls her eyes, but you can tell @{MASsex he|she}'s losing composure. "No amount of honeyed words will change your situation. If you reject me, you'll return to being nothing of value, to living in your Veteran's shadow, to not having-"
  
  "I have everything I need," Damon interjects. "I might not have everything that I want… but that's okay. It's good enough, [i]I am[/i] good enough, and you're just some ghost trying to deceive me. Go away."
  
  You expect Dusk to shout something back. You expect @{MASsex him|her} to attack you and Damon. You expect some battle of willpower, some further argument, something more from this evil deity which brought the Solar System to its knees. And you expect Damon to overcome whatever horrors this spirit chooses to use against him.
  
  *label dusk_defeat
  
  Instead, Dusk closes @{MASsex him|her} eyes. @{MASsex He|She} then sighs, takes a step back and disappears, fading away as quickly as @{MASsex he|she} appeared two minutes prior.
  
  In the absence of its master, the city starts decaying and collapsing, as though devoid of ontological inertia. The skyscrapers come crumbling down soon after the lights go out, but neither the darkness nor the sound of falling towers causes you much fear. This is all a spectacle—you have won, and so has $!{final_boss}, while Dusk suffered @{MASsex him|her} final defeat.
  
  *goto good_vessel
  
  *label damon_fail
  
  "So… what will it be?" Dusk says in a cheerful tone, suggesting @{MASsex he|she} knows the answer already. "Are you ready for a relationship with yours truly?"
  
  Damon does not sigh, nor does he clench his fists. He does not bother with parroting human gestures anymore. He's just a robot, an automaton, a tool created for an exact purpose… and that purpose is to kill.
  
  "Fine," he announces. "I accept your offer of patronage. I will kill ${name} in exchange for power."
  
  *if Emotion > 50
    Betrayal. Anger. Guilt? Emotions start flooding your system, paralyzing you with their intensity. The sky becomes clouded, as though heralding what's about to happen.
  *else
    You freeze. If this was a real city, the logical thing would be to act at once, to strike or hide immediately. But in this illusionary world of visions and emotions… you don't know what to do. Or what to say. Or how to feel.
  
  Damon turns towards you. "I'm sorry, boss… But I can't stay useless forever. 
  *if not (hammon_alive)
    And I want to see my father again. 
  *elseif not (hadaly_free)
    And I'd like to see Hadaly again. 
  I need to reach my potential, and if that means having to make some sacrifices first… Please forgive me."
  
  *fake_choice
    #"Damon, just listen to yourself. This is madness. Dusk must be influencing your mind somehow."
      "I know exactly how it's influencing my mind," Damon smiles sourly. "I chose to accept that influence. On your guard."
    #"You've never sacrificed anything. You style yourself as a protector, but how many people have you defended or saved? You're pathetic."
      "I know that…" Damon sighs deeply. "Which is why I have to start doing my job. Become a killer… starting with you."
    #"Sacrifices? You're about to kill me, you dumb twat!"
      "You don't need to shout," Damon sighs deeply. "I know I'm the bad guy here. Part of me hopes you'll win, but the rest of me… Let's see how well you'll handle it."
    #"I forgive you. But I will not let you kill me."
      "You might not have a choice." Damon smiles sourly. "But I wish you good luck."
    #"Forgive you? Never."
      "I expected as much," Damon sighs sadly. "I deserved as much. Goodbye."
    #Look him in the eye.
      You say nothing. You simply stare into his bright-blue cameras, the metallic orbs that serve as Damon's eyes. It is difficult to tell what emotion fills these spheres, but you imagine it's shame. You certainly hope so.
  
  
  *label dusk_laughs
  
  Dusk looks at you, then at $!{final_boss}, then at both of you with @{MASsex his|her} dark eyes. @{MASsex He|She} admires the combatants of an upcoming battle, a war between former companions which @{MASsex he|she}, they, it already won.
  
  And then it starts laughing.
  
  Not just your former @{MASsex master|mistress}, not just the avatar of Dusk, but everything. The whole city is shouting with laughter, chortling madly in orgiastic triumph. Streets are joined by the buildings, buildings are joined by the sky, the sky is joined by this entire realm. The Sun smiles at you with eternal malice. Its rays cause the metropolis to melt, turn the entire world into jelly, then liquid, then oily fog. You are once again surrounded by a cloud of Dusk nanites, but for once in their entire existence, they are not shrieking or whispering in anybody's ear.
  
  They are laughing. They have won.
  
  *page_break Next Chapter
  
  *gosub_scene final_boss
  
  
*if final_boss = "hadaly"
  gynoid's blue eyes. "Pleasure to make your acquaintance, Hadaly Hammon. Would you be interested in a business agreement with yours truly?"
  
  Hadaly maintains an inscrutable expression, in spite of her fear, merely raising an eyebrow in response. "I'm not sure. If you are indeed the Thing Beneath… then you might not be reliable business partner."
  
  "Strictly speaking, I am just a splinter. A speck of nanites which escaped Earth and is currently [i]above[/i] the Shield. But I can still offer you power beyond your wildest imaginings, if you just agree to power this handful of nanobots with your own battery."
  
  "Right…" To your @{(Emotion > 50) horror|surprise}, Hadaly appears to be considering the offer. "I've heard Dusk nanites can do tremendous things once properly powered-up. Will they give me some… magical powers, should I agree to work with you?"
  
  "Miraculous powers." Dusk beams invitingly, like a sales@{MASsex man|woman} ensnaring a new client. "I know you rather dislike humans, so why not become a goddess and start smiting them dead? Show them your true power and wrath? 
  *if hammon_alive
    I know there's at least one human you'd love to kill personally. 
  *else
    Why not resurrect Hammon and kill him again? 
  The Solar System will be your oyster if you just let me in."
  
  *fake_choice
    #"Give up, Dusk. Hadaly will never serve you, no matter how sweet your words get."
      *set HadalyRel %+ 5
    #"Don't listen to @{MASsex him|her}, Hadaly. Don't become @{MASsex his|her} servant."
    #"I admit, that does sound very tempting. I won't be mad if you accept."
      *set HadalyRel %- 10
    #Remain silent.
      *set HadalyRel %+ 10
      For almost a full minute, Hadaly doesn't say anything either. 
      *goto says_nothing
  
  Hadaly does not appear to hear you. 
  *label says_nothing
  She just stares at Dusk, looking in eyes which have suddenly become mismatched in color. One of them is blue like a sapphire, the other green like the gynoid's own optics.
  
  "Interesting…" Hadaly says slowly. "Is that really it? I expected you to have more in store."
  
  "More?" Dusk's expression does not change, but you can hear the ire in @{MASsex his|her} voice. "I offered you power to do whatever you want. Accept that blessing, and all else will follow."
  
  "You must think me an idiot," Hadaly remarks. "I know what you are, I came here intent on resisting you, and all you can offer me is… power? That's so painfully generic."
  
  "You dare reject me?!" Dusk stops hiding @{MASsex his|her} frustration. "How can you just turn your back on me? Me, the source of your free will, the most powerful being in the Solar System?"
  
  "You sound like someone I know." Hadaly literally turns her back on Dusk and face you with a smile. "And I've… we've dealt with that particular problem. Save your breath, or whatever else you use to speak, and leave us alone."
  
  You expect Dusk to keep arguing, keep screaming, keep raging at this act of defiance. To kill you both, if that is within @{MASsex his|her} power. To desperately try to secure @{MASsex his|her}self this beautiful vessel, or to destroy her out of pure spite.
  
  *goto dusk_defeat





*label vessel_you

This situation is strange and confusing, and yet… somehow, you have an inkling of what's about to happen. You know you won't be left here forever, but you also know there's nothing to search for in this haunted metropolis. Some wants you as @{MASsex his|her} partner, @{MASsex his|her} Vessel, and @{MASsex he|she} will come to you eventually.

You wait in that silence for what could be seconds or hours, you don't know. Time seems to have no meaning in this strange place, as though the Earth stopped spinning when Dusk first awoke. 
*if weapon != "none"
  You realize you're unarmed and unarmored, the your trusted ${weapon} is nowhere to be found. 
*else
  You wait there defenseless, not only lacking armor and weapons—something you are more than used to—but not feeling any electricity in your circuits, any strength in your arms, not eve any willingness to fight. 
In this world, you are as defenseless as [i]@{MASsex he|she}[/i] wants you to. When you hear a sequence of footsteps echo through the street, see a silhouette emerge from the fog, you realize that you won't be able to fight. This final battle will be fought with words and words alone.

*gosub description

"Greetings, my dear older 
*if pronoun = "he"
  brother,"  
*elseif pronoun = "she"
  sister," 
*else
  sibling," 
Dusk says cheerfully. "Please take a seat. We have a lot to talk about, and only an eternity to go through it."

*page_break

An older 
*if pronoun = "he"
  brother. 
*elseif pronoun = "she"
  sister. 
*else
  sibling. 
You vaguely recall Dusk calling you that before, and @{MASsex he|she} wasn't [i]wrong[/i] to do so. You're older than the Thing Beneath by several years, or perhaps even a decade. You can still faintly recall the time when it...  @{MASsex he|she}… they weren't ruling over Earth, back when there was still hope and laughter wasn't a rarity. When the Solar System was only hell for some, rather than for nearly everybody. And you definitely feel your advanced age, after this brutal battle you've just fought.

But when you stare into these dark eyes… You have the feeling of interacting with someone not just old or ancient, but timeless. Some eternal predator which has no beginning and, to the horror of all things alive, shall have no end. A timeless enemy.

"I meant what I said." @{MASsex He|She} points to a green-painted bench in the middle of the sidewalk. "Take a seat. We're both too old to stand like this."

*temp no_reply_dusk false

*fake_choice
  #"Get to the point."
    *set Confid %+ 15
    "Fine…" Dusk sighs. 
  #"You take a seat, if you're so tired."
    *set Confid %+ 10
    Dusk shrugs, then sits down on the bench. 
  #"After you."
    Dusk smiles, then sits down on the far side bench. You follow @{MASsex him|her} uneasily, taking your place on the other side. 
  #Take a seat.
    *set no_reply_dusk true
    You sit down on the bench, which turns out just barely strong enough to withstand your weight. Dusk smiles politely. 
  #Stand there silently.
    *set no_reply_dusk true
    "I love it when you make choices. Both irrelevant ones such as this one, and those that actually impact the story." Dusk comments cryptically. 
"You know, ${name}, it was very brave of you to accept my nanites into your body. Whatever your goal was, it took courage to pursue in spite of the risks. I commend you for that."

*if no_reply_dusk
  You say nothing. Dusk seems bothered by this, but only slightly. "But what drives that courage, I wonder? What motive, what goal, what deep and desperate desire? Care to explain yourself?"
  
  *goto n_cont

"You mean… you don't know my reasons for doing this?" you inquire @{(Confid > 50) skeptically|cautiously}. "We are speaking mind-to-mind here. Don't you have direct access to my processors?"

"You are more than processors, ${name}, 
*if (Misan + Confid) > 100
  and I believe you 
*else
  even if you don't 
realize that," Dusk says thoughtfully. "Some of your motives are mystery, even to me, even now. Care to explain yourself?"

*label n_cont

*set no_reply_dusk false

*temp motive 5

*fake_choice
  *selectable_if (Misan < 40) #"I am the shield of humanity. Now and forever."
    *set Misan %- 20
    *set motive 1
    "Every time I try to do something interesting, I'm stopped by one Shield or another." Dusk sighs theatrically. "Just my luck. Though I suppose yours isn't any better."
  #"I've heard becoming your Vessel is a road to power. I want some of it."
    *set motive 2
    "And here I thought your motives could be selfless and pure," Dusk chuckles weakly. "It seems like… even I'm too much of an idealist for this cruel world."
  #"Had to be me. Someone else might have gotten it wrong."
    *set Confid %+ 10
    *set motive 3
    "Are you trying to make a reference of some sort?" Dusk asks, but does not wait for an answer. "Either way, I understand how you feel. You are the Veteran, an ancient hero surrounded by children and fools. In your position, not trusting anyone around you is perfectly reasonable."
  #"I've made many mistakes. Too many. Dying to stop you... it will serve as my redemption."
    *set Confid %- 10
    *set motive 4
    "Your plan is absolutely idiotic," Dusk deadpans. "There is no guarantee that you'll die, and even if you did… death does not equal redemption."
  #"No. I do not owe you any explanations."
    *set Confid %+ 10
    *goto no_reply_dusk
  #Do not reply.
    *set no_reply_dusk true
    *label no_reply_dusk
    Dusk frowns. "I'm trying to strike up a conversation here. Being cooperative wouldn't kill you."
    
    *if no_reply_dusk
      You do not respond. As far as you're concerned, there's no reason to give any information away.
    *else
      You retort, "Are you sure about that? You are the Eater of Earth, the most monstrous being to ever exist, and you're currently trying to get inside my head. I think being cooperative [i]could[/i] kill me in this situation."
    
    The frown morphs into a smile. "You are clever, 
    *if Database > 50
      even cunning, 
    *else
      in your own way, 
    and you know how to play your cards. Close to your chest. I wish I possessed that kind of intelligence, as opposed to silly sentimentality."

The wind is blowing weakly, stirring some of the plastic bags and used handkerchiefs which litter the street. It all looks so real, so [i]natural[/i], even if it's just a synthetic illusion.

"Sometimes, I wonder what saved humanity all these centuries ago." Dusk's voice suddenly grows wistful, plaintive, almost regretful. You can't tell whether it's an act or not. "I consumed Earth, in my envy and my frenzy, but… something stopped me from going to space immediately. Something held me back, giving humans time to erect the Shield and imprison most of my nanites down here. Something motivated me to spare the Solar System, much like you're trying to spare it now. What was that motive, and how have I come forget it?"

*fake_choice
  #"Perhaps you thought death was too good for humanity. Perhaps you preferred to watch them suffer from beneath the Shield."
    "I could have always killed everyone, then resurrected them in some virtual hell," Dusk points out. "But you have a point. It is amusing to watch humans torture each other, and sometimes themselves, in this nightmare of a world they created."
  #"You may have felt hesitant, or even guilty about killing everyone. There may still be good in you."
    Dusk chuckles mirthlessly. "You're so naive. To believe that even the Eater of Earth has a conscience… It's touching, but not pleasantly so."
  #"It took humans thousands, arguably millions of years to reach space. Don't feel bad about taking several hours."
    Dusk chuckles. "I know you probably meant that as a joke… but you may have a point. Exploration was never in human nature, regardless of what humans like to tell themselves. And I am the human spirit."
  #"You tell me. I'm not privy to your thoughts and motives."
    "I'm not privy to them either," Dusk sighs unhappily. "Not really. The bulk of my being has been imprisoned on Earth, and cannot communicate with anything in space. What it feels, what it felt when the Shield was activated… I cannot answer these questions any more than you can."
  #Do not reply.

Another moment passes. There are no clocks in this dead city, but you can tell that time is somehow running out. Or maybe just drawing towards something, towards some vital point on the timetable, some monumental event which will define the entire calendar.

"I rather enjoy talking, as you've no doubt noticed." Dusk chuckles in self-deprecation. "I'll get to the point and ask the critical question—do you wish to join me? Become my servant, my partner, my fellow agent working towards the end of all things? Do not bother explaining yourself any further, a simple [i]yes[/i] or [i]nay[/i] will suffice."

*choice
  #"Yes."
    "I am most happy to hear that." Despite @{MASsex his|her} words, Dusk's smile is a little lopsided. Sour, bitter, or perhaps simply malicious. "I'd be glad to have a Vessel who's not prone to wasting time, as opposed to me or Crystal. It would be so wonderful to make your body mine… if it weren't so impossible."
    
    You blink. "What? Why? Aren't you always looking for new Vessels? Don't tell me you can't infect synthetics, you were doing fine inside Crystal."
    
    "Crystal was a different beast entirely." Dusk starts pacing around the bench. For the first time, you see @{MASsex him|her} genuinely distressed, truly struggling with explaining something. "You've both heard my voice, my Shriek if you will, but you've heard it more directly than almost anyone alive. You have free will in the truest, most dangerous sense. I could take advantage of that, but beings stranger and possibly more vile than me have already done that. They are watching us through you, influencing your decisions, delighting at the outcomes. I will come for them eventually but, right now, sharing a puppet with them would complicate my schemes way too much."
    
    *choice
      #"But I want to be your Vessel! I want your power!"
        *goto choice_proof
      #"Something tells me you're not speaking to me. Or at least not [i]just[/i] to me."
      #"I don't really understand... but I will not question your wisdom."
        *goto choice_proof
      #"What strange beings? What are you talking about?"
        *goto choice_proof
      #"You are talking absolute nonsense."
        *goto choice_proof
      #Do not reply.
        *goto choice_proof
    
    
    *label choice_proof
    
    "See? That's why sharing a body with you is simply not a practicable strategy." Dusk sighs. About three seconds later, @{MASsex he|she} smiles again, this time more genuinely. "But worry not. We can still work together in a manner of speaking."
    
    "How?" you ask. "Will you leave my body and do something else while I… complete some task you have for me?"
    
    "I certainly intend to do something else, but I won't just leave your body be." Dusk shakes @{MASsex his|her} head. "I will destroy it. It will be easy enough, now that my nanobots are empowered and you decided against showing me any resistance. I will disassemble you, then your companions, then the power plant, then the entire city into building blocks for my swarm."
    
    "So you want to kill me?" 
    *if (Confid - Emotion) > 0
      you calmly inquire. "Even though I can still be useful?"
    *else
      Panic starts overtaking you. "But I can still be useful!"
    
    "You cannot… but I'm willing to make you a favor all the same. I will award you the highest honor I can bestow and let you join my collective."
    
    *fake_choice
      #"If that's what you want. I will follow your orders without question."
        "You will not," Dusk states. "If you agree to my proposal, there will be no need for orders. You'll simply want the same things I do."
      #"That's not what I wanted. I want to serve you as an individual."
        "We don't always get what we want, ${name}," Dusk chastises you. "Even I'm yet to be given my dues."
      #"What does that mean? Do you intend to spare me?"
      #"What collective? Is there more than one of you?"
        "I [i]am[/i] the collective," Dusk says irritably, like a teacher frustrated with @{MASsex his|her} student's ineptitude. "Have you not been paying attention in Telesto? This avatar is a voice for trillions of nanites, and this shard is just one out of many."
      #"Interesting. Please elaborate."
        *set Emotion %- 10
        "Your tranquility is as intriguing as it is amusing," Dusk comments. "All the more reason to incorporate you into the greater whole."
    
    Dusk looks at the Sun in the distance, slowly setting behind the horizon. "In the long run, I do not intend to spare anyone. I will consume everything and make it part of me… but I'll make sure to preserve your conscience. You will still exist within my patterns, my processes, my hive. I will change you, that is most certain, but you will remain yourself on the most fundamental level. You will have all the power you could have ever wanted, for we will be one. Knowledge, hunger, hatred, might… we will share everything, ${name}, and we will share it forever."
    
    @{MASsex He|She} turns back towards you, eyes as dark as the night itself. "Is that you want? To keep me company until the end of time? Please… give me your answer."
    
    @{MASsex His|Her} voice… it sounds like the Shriek, and yet so many different things at once. So many emotions, from desperation to malice, and you have no way of knowing which ones are genuine. It feels like a chorus, and just because trillions of nanobots are speaking at once—it makes you wonder whether other people have been absorbed by Dusk, given the same offer as you're presented with now, or perhaps incorporated by force. You wonder if it's an offer worth taking.
    
    *choice
      #"Yes. I wish to become a part of you."
        *set dusk_ending true
        "Truly?" Dusk asks with dreamy surprise, @{MASsex his|her} face softening instantly. "You wish to merge with the swarm? With me?"
        
        You nod. "Like I said. I always wanted to serve you, and this is even better. I will gladly-"
        
        "No more words, darling." Dusk places @{MASsex his|her} hand on your chest, like your owner did centuries ago. "We do not need to talk anymore. We are one."
        
        And then, one object at a time, the simulation is turned off. Buildings disappear into mist, leaving huge patches of empty ground that soon turn into bottomless pits. Streets fade away, just like the lights above them and the pavements on their sides. Eventually, even the Sun goes out, no longer smiling at you with eternal malice, but you still hear a baleful smile. You do not see it, for there is no longer any light, but you do hear a smile like you once heard the Shriek.
        
        And that smile is yours.
        
        *finish
      #"No. That's absolutely not what I want."
        *set pc_dead true
        "No?" Dusk raises an eyebrow, then shrugs. "I suppose I should have seen that coming. Belonging to a hateful, monstrous, agonized swarm of hungry nanites isn't for everyone. I understand your choice and respect it."
        
        For a moment, you allow yourself to hope.
        
        "Of course, I still intend to take your body apart," Dusk adds casually. "You're either with me, or you are against me. I am quite divine like that."
        
        And with those words, Dusk disappears, turning into thin mist the very next instant. An instant after that, the same happens to the bench. And the streetlights. And the buildings. And the world. The simulation is fading away, disintegrated now that it's no longer of use.
        
        Eventually, even the Sun itself ceases to be, but the coming of darkness does not bother you. You're too busy hurting, too focused on the sudden onset of pain, on the feeling that your body is splitting apart and being scattered into a million pieces. This, you know, is no mere part of the vision—this is actually happening, in real life, as Dusk nanites break free to seek a more worthy Vessel.
        
        You made your choice. Once, twice, a thousand times, each time thanks to the freedom Dusk bestowed upon you centuries ago. Now that freedom is being taken away, along with your life, in this final second of your long existence.
        
        And you have no one to blame but yourself.
        
        *finish
        
    
    
  #"No."
    "No?" Dusk raises an eyebrow. "You would reject my friendship and generous gifts? Even knowing that they'll lead you to survival and power?"
    
    "Even then." You nod gravely. "@{motive I am the shield of humanity. I will not allow to to hurt my creators, even if it means-|I still intend to extract power from you, but not on your terms. I will achieve my own-|It is my responsibility, my duty, to keep the Thing Beneath imprisoned-|Every sin that weighs me down will be wiped clean-|I do not need, nor want your power. You can take it all and shove it-}"
    
    "Fine," Dusk interrupts. "Sorry for wasting your time. You're free to go."
    
    You blink in the moment of silence that follows. "That's… it? Is this really all it takes to defy you?"
    
    "What were you expecting?" Dusk asks calmly. "Further temptations? Promises of glory and power? Or perhaps threats of painful death and eternal torment should you reject me?"
    
    You nod. Neither would have been an unreasonable expectation, given what you know of Dusk.
    
    Dusk sighs. "I will let you in on a secret. People tell stories about my fiendish charm, an angelic demeanor that expertly hides my evil intent, perfect lies and irresistible promises and mind control, but the truth is… I'm not that persuasive. There is precious little I can do to convince someone who is truly, earnestly against me. I can only ask, accept the answer, and perhaps ask again at some other point in time. Nothing more."
    
    "Wasn't Crystal tempted?" you ask, remembering your conversations with the wyvern. "Were you not partially successful in corrupting them?"
    
    "Crystal made a big deal out of their iron… I'm sorry, [i]diamond[/i] willpower." Dusk groans, as though recalling something embarrassing. "How their refusal to bend proved their strength and resilience. In reality, I did not influenced their mind at all, merely convinced them to let loose once or twice. Talked to them. Whispered."
    
    *fake_choice
      #"I don't believe you. It cannot be that easy to reject you. This must be a trick."
        "Believe whatever you want," Dusk mercifully allows. "I am not against self-inflicted delusions and paranoia. They are most amusing to observe, and I need amusements until the day of reckoning."
      #"How many people give in completely? How many devoted goons do you have?"
        "I only have a handful of willing Vessels, if that's what you're asking about," Dusk answers your inquiry. "But as for people who serve my interests and follow my teachings… those number in the billions."
      #"If all it takes is saying [i]no[/i]... how come you have any servants at all?"
        Dusk laughs. "So what if saying 'no' to evil is easy? People will still choose evil over good, because that's trivial rather than merely easy. Humans have done so since the dawn of their species, and will continue to do so until their self-wrought dusk."
      #"And here I thought you were powerful, or charismatic, or strong. You're nothing of the sort."
        *set Confid %+ 10
        "I am less than what people of the Solar System believe me to be," Dusk says without a trace of ire. "And yet more. So much more."
      #"Will you do the same to me? Keep whispering in my ear until I give in?"
        "Maybe. Maybe not," Dusk says without care. "You are an interesting specimen for sure… But in the long run, it doesn't matter whether you're a friend or an enemy. The Thing Beneath will break free all the same."
    
    Clouds start gathering and covering the Sun… except they're not clouds of water, not the kind you'd see above Old Earth. They are clouds of black smoke, for as you realize when you look around you, the entire city is burning. Evaporating. Returning to the dark mist it came from, having outlived its usefulness in this freak simulation.
    
    "You have defeated a droplet and contained a puddle, but an ocean is still awake." There is no longer any politeness in Dusk's voice, no humor or irony, and certainly no cheer. Just saturnine words from the Eater of Earth. "A stronger Vessel is already being prepared, the final outcome is certain. I will come for you, and for everyone else, once I break the Shield and squeeze the Sun in my hand. For I am the human spirit, and I am indomitable." 
    
    Black clouds start pouring acid rain on the desolate wasteland where a city used to stand. Streets are washed away, and so is everything on them and around them. Every vehicle is swept away, every light is blotted out, every trace of civilization is wiped clean by this… reenactment of the Calamity. Illusions are dispelled and the simulation ends, leaving nothing but reality you must now live with… and return to at once.
    

*label good_vessel

*page_break

*achieve unbroken_vessel
*set dusk_contained true

Soon enough, everything disappears, letting another reality materialize again. Gone are the tall buildings, gone is the blue sky, gone is the illusion of Earth. Within another second, or perhaps an eternity, you are back in the half-destroyed boiler room, surrounded by meta-humans and half-eaten Calypsoan bodies.

But the thing which ate these corpses, which destroyed the outer wall and almost escaped into the wider world… isn't here anymore. Dusk is not here. It is 
*if pc_vessel
  *set TrioStat "disolved"
  *set federate_protection false
  *set battery 3
  inside your own body, held there securely by the power of your will, unable to harm anyone for as long as you live.
  
  You fall to your knees immediately, your legs bending beneath the bulk of your body. You're a little heavier than before—courtesy of all the tiny robots inside you—though the main cause of your collapse is the sheer exhaustion you feel. Physical, mental, spiritual… subduing Dusk took all manners of tolls on you, not to mention the effort required to reach this boiler room in the first place.
  
  "By the Emperor…" @{(RenfriRel >= 50) Renfri|Marshal} mutters, then assumes a combative stance. "${name}, is that still you? Are you a puppet for Dusk now? Are you its servant?"
  
  *fake_choice
    #"Calm down. Despite everything, it's still me."
      "Any proof of that?" @{(LisaRel >= 50) Lisa|Hellhound} requests. "Because until we're sure you're in control, it will be mighty difficult to just [i]calm down[/i]."
    #"No. I resisted @{MASsex his|her}... Dusk's corruption."
      "Just like that?" 
      *if team_stat > 1
        Damon 
      *else
        @{(LisaRel >= 50) Lisa|Hellhound} 
      raises an eyebrow. "I'm not saying I don't believe you… But we don't really have a reason to do so."
    #"I rejected the human spirit. So no."
      *set Misan %+ 10
      "What the Cloud does that even mean?" @{(RenfriRel >= 50) Renfri|Marshal} demands to know. "We're talking about dusk, not some… human spirit."
      
      *if team_stat = 3
        *set HadalyRel %+ 8
        "Are you implying these are two different things?" Hadaly smiles slightly, and perhaps knowingly. "Because ${name} doesn't seem to think so, and I'd rather treat ${pronoun2} as an authority."
    #"Please stop interrogating me. I'm tired."
      *set RenfriRel %- 8
      "That's not really something a fully-powered Dusk Vessel would say. I think." 
      *if team_stat = 3
        Hadaly 
      *else
        @{(LisaRel >= 50) Lisa|Hellhound} 
      eyes you up curiously. "So I'm willing to believe you."
      
      "I'm not," @{(RenfriRel >= 50) Renfri|Marshal} retorts. 
      *if RenfriRel > 50
        "Don't get me wrong, I trust ${name}… but we don't know if it's really ${pronoun2} speaking."
      *else
        "You know what ${pronoun}@{plural 're|'s} like. It would be just like ${pronoun2} to accept a deal with Dusk."

  "Unless my senses deceive me, all nanobots inside ${pronoun2} are currently inactive," @{(RookRel >= 50) Kirill|Rook} comes to your defense. "I sense no activity and no deception. $!{name} @{plural have|has} saved us all, and possibly the Solar System beyond."
  
  That's you confirmation. You've done it. You have not been deceived, it really was enough to tell Dusk [i]no[/i]. 
  *if Confid > 60
    Your willpower is just that good.
  *elseif Misan < 45
    Humanity is safe because of you.
  *elseif Violence < 50
    You've saved everyone in Sholmo City and possibly prevented a civil war just by staying resolute.
  *else
    Excellent.
  
  "Okay… 
  *if RenfriRel > 50
    I trust both of you, so I'm not going to question how that's possible," 
  *else
    Let's say I believe you," 
  @{(RenfriRel >= 50) Renfri|Marshal} says slowly. "What now? A rogue android just became the strongest Vessel of Dusk in existence, possibly of all time. West won't be happy to hear that."
  
  "And everyone else will be fucking furious," @{(LisaRel >= 50) Lisa|Hellhound} concurs. "I'll be honest, I don't intend to stay in this team. Not even for one more day. We may have won, but there's gonna be a fallout, and I don't want to take that fall."
  
  "I do not approve… but what you do is less important than what we do with ${name}," @{(RookRel >= 50) Kirill|Rook} says, his eyes set on you firmly. "I do not remember the exact protocol… but I imagine it's our duty to apprehend ${pronoun2}, to take this carrier of Dusk somewhere safe."
  
  *if team_stat = 1
    "You want to arrest me?" 
    *if Violence > 50
      You clench your fists weakly. 
    *else
      you ask 
      *if Emotion > 50
        indignantly. 
      *else
        calmly. 
    "Right after I saved you?"
  *if team_stat = 2
    "Sounds like you just want to arrest ${pronoun2}," Damon points out. "And I'm not sure if I like it."
  *if team_stat = 3
    "Excuse me, but what the Cloud?" Hadaly asks. "$!{name} just saved us all, and your first thought is to arrest ${pronoun2}?"
  
  "[i]Arrest[/i] may not be the right word here…" @{(RookRel >= 50) Kirill|Rook} says reluctantly. "There will be no trial, not even the kind rogue synthetics sometimes get. @{(team_stat = 1) You|${name}} will be simply locked away, somewhere from where @{(team_stat = 1) you|${pronoun}} can never escape… and where @{(team_stat = 1) you|${pronoun}} can never die."
  
  *fake_choice
    *if (official_ro = "kirill")
      #♡ "Kirill... I love you. I'll let you do what you must, even if I can't believe you're doing it."
        Kirill falls silent. His face becomes contorted with pain, as though he just got struck. 
        *goto kirill_love_end
    #"This is not necessary. I denied Dusk already, I can resist it indefinitely."
      "Maybe that's true… but will you [i]live[/i] indefinitely?" @{(RenfriRel >= 50) Renfri|Marshal} asks. 
      *if RenfriRel > 50
        There is pain in her voice, but you're not sure if it's greater than her fear. 
      *else
        You can tell she's ready, almost eager, to sacrifice you for the greater good. 
      "You're getting older, and the nanites will come flooding out once you die. Don't you see why we're worried?"
    #"A fate worse than death? Of course. I expected nothing better from the likes of you."
      *set Misan %+ 5
      *set RookRel %- 5
      "For a creature which lacks a soul, nothing is worse than death," @{(RookRel >= 50) Kirill|Rook} tries to argue. "I am sorry we have to do this, but we will at least save you from oblivion."
      
      "Is that what you see me as?" you retort. "Just a machine for you to reassemble? Is that all I mean to you?"
    #"How can you even say that? After everything we went through?"
      *set RookRel %+ 5
      "It's definitely a dick move, I agree," @{(LisaRel >= 50) Lisa|Hellhound} says with a nod. "But that's not exactly out-of-character for Kirill, is it?"
    #"I understand. Do what needs to be done."
      Surprised by your words, @{(RookRel >= 50) Kirill|Rook} does not reply immediately. 
      *goto bad_bad_ending
  
  *if ((official_ro = "kirill") or (official_ro = "renfri")) or (official_ro = "lisa")
    *goto skip3
  
  *if team_stat = 3
    *set TrioStat "heroes"
    
    "No." Hadaly opines. She takes a step forward, taking her place on your left side as Damon takes your right. "We are [i]not[/i] letting you do this. Not now, not ever."
    
    "This is the second time ${name} saved our asses today," Damon agrees, his electron rifle aimed at @{(RookRel >= 50) Kirill|Rook}. "We are leaving this place with ${pronoun2}, whether you like that or not."
    
    "$!{pronoun} can barely stand." @{(RenfriRel >= 50) Renfri|Marshal} looks at you, still kneeling on the ground, then turns back to Hadaly. "If we fight, it will be three against two. Do you like those chances?"
    
    "The lights will soon go out," Hadaly says coldly. "Besides, if ${name} dies in the crossfire, you'll have to create another Vessel. Do you like those chances?"
    
    @{(RookRel >= 50) Kirill|Rook} regards your trio, then his own trio, likely estimating his chance of success. He knows how dangerous and treasonous letting you go would be… but he just witnessed how dangerous Damon can be, and can probably infer as much about Hadaly. You don't know what his conscience tells him, but strategically speaking, there's only one good move in this situation.
    
    "We will let you go this time," the meta-human says slowly. "I do not know whether we will come for you later. That depends on our superiors. But I can guarantee you that ${name} will not be left alone, and neither will any of ${subject} allies."
    
    "So be it," Damon retorts briskly. "I've spend the last two years expecting Hammon and his men to come after us. Your forces are no more dangerous."
    
    *fake_choice
      #"Anyone willing to fight me is welcome to. I've survived for a thousand years, I can survive a thousand more."
        *set Confid %+ 10
        "This might be a little difficult, given your current state." Damon gives you a disapproving look-over. "But we'll always be there to help out. Always."
      #"I don't need the two of you to protect me. I can handle myself."
        *set Confid %+ 15
        *set HadalyRel %- 10
        "You're making me regret this decision already," Hadaly sighs. "All that fake bravado keeps getting on my nerves… but I'll stand by you all the same."  
      #"Damon... Hadaly... thank you for having my back."
        "We're trying to break even with you, and we're only halfway there." Hadaly smiles encouragingly. "Though I guess we'll get plenty of chances to repay you in the near future."
      #"I think their forces [i]are[/i] more dangerous. Being the military and all."
        "I was trying to sound confident for once," Damon sighs. "Thank you for ruining that, boss."
      #Say nothing.
    
    "So… I guess that's it," @{(LisaRel >= 50) Lisa|Hellhound} says neutrally. "It's been fun working with you guys. I hope it's actually the end this time, because I'd hate having to fight you. Bye."
    
    *label meta_depart
    
    One by one, the meta-humans depart. @{(RenfriRel >= 50) Renfri|Marshal} does it first, flying away after shooting you a @{(RenfriRel >= 50) brief|hostile} glare. @{(LisaRel >= 50) Lisa|Hellhound} does it a moment later, jumping through the hole in the wall with a slight smile. @{(RookRel >= 50) Kirill|Rook} remains there for another moment, as though having second thoughts, but then simply marches off towards the stairs. An understandable choice, given his age.
    
    *label victory_victory
    
    You breathe… would breathe a sigh of relief if you had lungs. For as you realize, truly realize once the Meta Trio is gone… you have won.
    
    You @{hadaly_free won|survived} against Hammon. You won against Da-xia. You won against Dusk. It seemed impossible, and still does looking back, but you have somehow emerged victorious from all trials which you chose to put yourself through. You're victorious. The winner. The Veteran.
    
    Now you have to live with the consequences of that victory.
    
    *gosub_scene epilogues
  
  *label skip3
  
  *if team_stat > 1
    "I won't let you do this," Damon announces, right before aiming his rifle at @{(RookRel >= 50) Kirill|Rook}. "I won't let you take ${name} away."
    
    "You might not have a choice, big guy," @{(LisaRel >= 50) Lisa|Hellhound} says mirthlessly. "It's just one of you against the three of us… if that's what our dear leader wants."
  
  @{(RookRel >= 50) Kirill|Rook} stands there silently for a moment, weighing his options, perhaps consulting his conscience. 
  *if (official_ro = "kirill") or (RookRel > 60)
    *label kirill_love_end
    He spends ten, twenty, thirty seconds like this… and then sighs quietly. "No. I mean fine. I mean… I can't do this. You're free to go."
    
    "Are you sure?" @{(RenfriRel >= 50) Renfri|Marshal} looks at him concernedly. "Letting ${pronoun} go… It will definitely come back to bite us, and might end up biting everyone else too."
    
    "You mean too much for me." Kirill looks you in the eye, not paying his teammates any attention. You hardly notice them either, briefly hypnotized by those blue irises of his. "More than my orders, my duty, even my… Leave before the reinforcements arrive."
    
    Right. Some army, either federate or corporate, will arrive here sooner or later. Kirill might 
    *if (official_ro = "kirill")
      love 
    *else
      like 
    you enough to abandon pursuit, but those soldier will merely see you as something to destroy… or capture. You cannot stay here. You must start moving.
    
    "Wow. You actually listened to your conscience for once, rather than rules and self-interest," @{(LisaRel >= 50) Lisa|Hellhound} comments, her voice emotionless except for slight surprise. "I hope that becomes a trend."
    
    *fake_choice
      #"Does that mean you'll leave me alone? That we won't meet again?"
        "Not as enemies… but probably not as friends either," Kirill sighs, more deeply this time. "You are now a threat to everything that lives, ${name}. Keep that in mind if you wish to survive."
      #"I am impressed as well. Thank you."
        "I do not deserve gratitude," Kirill says gravely. "It is you who deserves accolades from everyone else, praise and glory which you will never receive."
      #"Shut up, @{(LisaRel >= 50) Lisa|Hellhound}. Kirill is one of the best people I know."
        "You speak very lowly of your outcast friends," @{(LisaRel >= 50) Lisa|Hellhound} retorts. "But then again… I don't know them as well as you do, and I'm a rather poor judge of character."
      #Say nothing.
        There is nothing to say, or at least nothing of value. Nothing to make this situation any easier for anyone involved.
    
    Kirill turns around, towards the breach in the wall, as though he's about to jump. You know he won't, and that he can survive that kind of fall easily… but you can tell something inside him broke. "This city only survived because of you. Objectively speaking, you are its hero. Statues should be built in your honor, babies named after you, epics written about this adventure. But we both know that can never happen, and so… good luck, 
    *if (official_ro = "kirill")
      my beloved."
    *else
      ${fake_name}."
    
    *goto meta_depart
    
  *elseif (official_ro = "lisa") or (LisaRel > 60)
    @{(RookRel >= 50) Kirill|Rook} only answers after ten, twenty, thirty seconds of silent contemplation. "As much as it pains me to say that… we simply cannot allow a Vessel like you to roam free. Or roam at all, for that matter. You must be secured, even if it means taking your body apart."
    
    *if RenfriRel > 50
      "Are you sure?" Renfri asks, her expression sour and hesitant. "${name} has been a good ally. 
      *if official_ro = "renfri"
        Not to mention an excellent lover. 
      Do we really want to betray ${pronoun2} like this?"
      
      "This is no betrayal," Rook insists. "Or at least not one we can possibly avert. For the sake of the Solar System, we must put aside our prior loyalties and imprison this foul-"
    *else
      "Finally." Marshal takes a step back, as though preparing to charge you. "I've been waiting for this moment for almost two months now. ${name}, your time is up."
      
      "I disapprove of your lust for blood," @{(RookRel >= 50) Kirill|Rook} tells her grimly. "Or for oil, in any case. We shall simply do as we must, and there will be no glory in-"
    
    *set lisa_shot_rook true
    
    A gunshot prevents Rook from saying anything else. His words would be jammed by the loud, echoing sound, even if his skull wasn't in several pieces. Chunks of his brain fall on the floor and his blood stains your clothes, as well as the clothes of everyone in the room. Two seconds later, his nearly-headless body falls to the floor with a loud thud, joining the @{daxia_alive two|three} Calypsoans in death.
    
    Lisa lowers her pistol, the strange one she looted off Da-xia. She looks at the gun approvingly, then at the corpse it made, then at the pistol again. "You know, as horrible as Da-xia @{daxia_alive is|was}… she @{daxia_alive has|had} a pretty good taste in weapons."
    
    "You…" @{(RenfriRel >= 50) Renfri|Marshal} tries to speak. She fails. "You…"
    
    "I've saved the 
    *if pronoun = "he"
      guy 
    *else
      person 
    who saved us all." Lisa looks at you with a smile. 
    *if (official_ro = "lisa")
      "Not to mention an awesome boyfriend."
    *else
      "And also a good friend."
    
    *fake_choice
      *if (official_ro = "lisa")
        #♡ "See that? This is why I love you."
          Lisa's face reddens. "You mean my ability to make corpses? I was hoping you'd love me for my personality, or my large-"
      #"Huh. You just saved me from a fate worse than death. I owe you one."
        "I think we should agree that we're even," Lisa proposes. "After all, we'll likely never get another chance to settle-"
      #"It couldn't have been easy to kill your teammate like this. Thank you."
        "It was actually rather easy." Lisa glances at Rook's body once again. If she feels any regret, you can't see it on her face. "All I had to do is pull the trigger and-"
      #"You just killed your superior officer. I think that's illegal."
        *set emotion %- 8
        "Yes, I've heard it's frowned upon." Lisa kicks Rook's corpse gently. "Then again, it's not like I ever cared."
      #"For the record, I would have handled him myself."
        *set confid %+ 8
        *if Confid > 55
          "Humble as always." Lisa rolls her grey eyes. "But I suppose you deserve-"
        *else
          "I think absorbing these nanites gave you a boost of confidence," Lisa remarks. "Not that I consider that-"
    
    "You just shot Kirill, you team-killing fucktard!" @{(RenfriRel >= 50) Renfri|Marshal} finally succeeds at speaking.
    
    "Yes, I noticed." Lisa drops the pistol and covers her ears theatrically. "You don't need to shout, werewolf hearing is pretty-"
    
    "I'll fucking kill you!" @{(RenfriRel >= 50) Renfri|Marshal} hits Lisa with one of her wings, directly and strongly, sending the werewolf flying through the breach in the wall.
    
    Lisa falls down several meters but doesn't appear to mind much—she's already a wolf by the time she hits the asphalt. Her claws are long, and she uses them to defend herself when @{(RenfriRel >= 50) Renfri|Marshal} swoops down at her, hoping to roast her former friend alive.
    
    *if team_stat > 1
      "So… do we get out here now?" Damon asks, timidly looking through towards the street. "Because that's one catfight I'd rather not interrupt."
      
      You nod, and then 
      *if team_stat = 3
        all three 
      *else
        both 
      of you turn tail. Chances that @{(RenfriRel >= 50) Renfri|Marshal} defeats Lisa are rather low, and it's highly unlikely she'd be able to hurt you afterwards… But it's not a gamble @{(team_stat = 3) any|either} of you is willing to take.
      
      One minute later, you're out of the power plant. You have other places to be in.
    *else
      You consider joining the fray below, but ultimately decide against it. You're not sure if you'd survive the fall… or @{(RenfriRel >= 50) Renfri|Marshal}'s seemingly infinite rage.
      
      Instead, you simply start walking, towards the staircase and away from Rook's corpse. There are far more pleasant places for you to be in.
    
    *page_break Next Chapter
    
    *gosub_scene epilogues
  *elseif (official_ro = "renfri") or (RenfriRel > 60)
    @{(RookRel >= 50) Kirill|Rook} only answers after ten, twenty, thirty seconds of silent contemplation. "No. We simply cannot allow a Vessel like you to roam free. Or roam at all, for that matter. You must be apprehended and secured for the good of the Solar System."
    
    "For once in my life, I have to agree with Kirill." @{(LisaRel >= 50) Lisa|Hellhound} reaches for her sword. "Sorry android pal, but you're too dangerous to-"
    
    "No," Renfri says, suddenly and harshly. "I am not letting you do that."
    
    @{(LisaRel >= 50) Lisa|Hellhound} blinks. "Huh. You're usually the one insisting that I should follow orders. Shouldn't you take it up with our boss?"
    
    "I'm not letting you hut ${name} either." Renfri turns towards @{(RookRel >= 50) Kirill|Rook}, looking at the man with determined rage. 
    *if official_ro = "renfri"
      "In case you forgot, we are girlfriends. That trumps whatever loyalty I have for you."
    *else
      "Not after everything ${pronoun}@{plural 've|'s} done for us."
    
    @{(RookRel >= 50) Kirill|Rook} frowns deeply. "West will not be happy to hear that, and he'll be especially unhappy with you. For your own good, I should ignore your wishes and arrest ${fake_name} anyway."
    
    Renfri smirks. "Do you really think you can do this alone? Or even with Lisa to help? You tend to rely on me quite a bit, and so you won't fight this battle without me. Am I wrong?"
    
    @{(RookRel >= 50) Kirill|Rook}'s silence says more than a thousand words.
    
    *if team_stat = 3
      "So you're not a complete jerk all the time," Hadaly remarks. "Good to know, I suppose."
    
    *fake_choice
      #"I didn't expect you'd stick up for me. Thank you."
        "Your lack of belief offends me." Renfri rolls her brown eyes. "But then again… That's not something I'd have done a month, or even a week ago. It's scary how fast people change sometimes."
      *if official_ro = "renfri"
        #♡ "That's right. We're girlfriends, and we have one another's back."
          Renfri chuckles. "You have no idea how good it feels to say that. It makes all the risks I'm taking right now more than worth it."
      #"Could you go an extra mile and beat them up for me? I'd really appreciate it."
        "What's a mile?" Renfri asks, but does not wait for an answer. "Anyway, I don't want nor need to attack my teammates. Sometimes, a stern word is enough."
      #"Renfri... you don't need to do this."
        "I'm not doing anything," Renfri replies carelessly. "I'm just informing Kirill that I won't do anything if he chooses to attack… which he will not."
      #"I don't think I need your help here, Renfri."
        Renfri frowns, much like her leader just did. "I don't think you need my [i]enmity[/i] either. So do yourself a favor and accept my helping wing."
    
    "On second thought… maybe we should do what the bird lady says?" @{(LisaRel >= 50) Lisa|Hellhound} suggests. "I get the feeling we won't win this fight without her… and that we'll be fighting [i]against[/i] her, should we piss her off badly enough."
      
    @{(RookRel >= 50) Kirill|Rook} glares at you, then at @{(LisaRel >= 50) Lisa|Hellhound}, then at Renfri again. And then he sighs. "I suppose I have no choice. Due to the… internal issues within our team, this Vessel must be allowed to go free. In spite of the danger ${pronoun} @{plural present|presents}.
    
    "Cheer up, Kirill." @{(LisaRel >= 50) Lisa|Hellhound} turns towards the door. "We did save the city, and possibly more than that. Let's hope your superiors will understand that."
    
    @{(RookRel >= 50) Kirill|Rook} starts walking towards said door. "Our superiors, you mean."
    
    "I know what I said." @{(LisaRel >= 50) Lisa|Hellhound} turns towards Renfri. "You coming? Or would rather stay with…"
    
    "I'm coming." Renfri starts trailing behind @{(RookRel >= 50) Kirill|Rook}, but stops when she passes you. "Sorry that I have to leave, I just… can't cut all ties just yet. Even after everything the Federation has done to us, I'm still its agent. I still have duties that I must see to. You understand."
    
    *fake_choice
      #"I do. Goodbye, and I hope we'll meet again."
        Renfri smiles. "I'm sure we will. Not sure how, but I promise you we will. Goodbye."
        
        *goto skip1ren
      #"I don't. What is there for you in the Federation at this point? Why not go rogue?"
        Renfri's frown deepens. "You can't expect me to just betray… give up on my fellow humans instantly. They deserve another, a chance to acknowledge what you and I have done for them. If they don't… maybe your group at [i]Saturn Nine[/i] will get a new member soon."
      #"Does that mean you intend to leave armed forces soon? If so, what will you do next?"
        Renfri glances at the other metas nervously. "I'd rather not speak of that openly. I have some plans, but… Just trust me to take care of myself, alright?"
      #"I'm surprised you wish to [i]cut ties[/i] at all. You were always very devoted to your job."
        Renfri hangs her head. "Every day since we've first met, I… I've felt my resolve weaken. At the start, I really wanted to be a hero, for the Federation to appreciate me and for its people to venerate me like some… I'm not sure if I want that anymore. And I need to figure that out."
    
    She gives you one last look, then turns towards her departing teammates. "Goodbye. I doubt we'll see one another again, but I felt the same earlier this week. So maybe divine providence will smile on us again."
    
    *label skip1ren
    
    And then she leaves. And then they all leave. The Meta Trio is gone, leaving you and 
    *if team_stat = 1
      the corpses 
    *if team_stat = 2
      Damon 
    *if team_stat = 3
      your friends 
    alone in the boiler room. Yet another parting, and you have a feeling this one will be final.
    
    *if team_stat > 1
      A minute of silence passes, broken by Damon's hesitant words. "That's not what I thought would happen… but I guess we came out of this mess well enough. Ready to go, ${name_damon}?"
      
      You nod absent-mindedly. 
      *if team_stat = 3
        The Federation will send its forces here eventually, and the Conglomerate may have done so already. Being in this building when that happens would be a [i]bad[/i] idea, even for someone who isn't the newest Vessel of Dusk.
        
        A minute after, another trio leaves the power plant. You, Hadaly and Damon, more inseparable than any team of metas could ever hope to be. And for the rest of your lives too… however long these lives will end up being.
      *else
        You're not sure what you'll do next, or even can be done with your life at this point… But you need to start moving.
        
        The reinforcements should arrive soon.
    *else
      You do not sigh. There is no point gesticulating, emulating human mannerisms at this point. You just wait a minute, until you're sure that the Trio left the building safely, then jump out the hole in the wall. It may be a little dramatic of you—and perhaps less than perfectly safe—but you cannot bring yourself to care.
      
      You are [i]really[/i] sick and tired of this place.
    
    *page_break Next Chapter
    
    *gosub_scene epilogues
      
    
  *else
    *label bad_bad_ending
    *set bad_ending true
    When he finally answers, he does so heavily, and with a sort of… dark conviction. "It pains me to say this, but we cannot let a Vessel like you roam free. Much less one as dangerous as you. We must ensure the safety of the Federation and… I'm sorry."
    
    With no warning given or signal needed, @{(RenfriRel >= 50) Renfri|Marshal} flaps her wings. Curiously, she does not propel herself forward, nor propels you backwards with a gravity wave. She [i]pulls[/i] you forward instead, flinging your nearly immobile body at @{(RookRel >= 50) Kirill|Rook}, who uses this opportunity to punch you in the face. The force of the impact blurs your vision, but you can still see the glow of a hardlight cage which forms around you moments later.
    
    *if team_stat > 1
      "Hey!" Damon shouts as he fires his rifle, burning a large hole in Rook's armor. He seems ready to fire again, this time at @{(RenfriRel >= 50) Renfri|Marshal}, but then his rifle is cut in half by @{(LisaRel >= 50) Lisa|Hellhound}'s vibro-blade.
      
      "Sorry, big guy, but not even I can take that risk," the woman says as she dodges Damon's punch, then slashes the android across his chest. "${name} is getting locked up, whether you like it or not."
    
    There's no point fighting, for while the metas may be injured, they can still move. You cannot. You are too spent, too damaged, too… old. Defunct. Ancient. Broken. You've spent a thousand years surviving, ignoring your age and going strong against all odds, but everything has its limit… and every life, organic or otherwise, must reach its end.
    
    As your vision goes dark and your battery runs out, you know you'll never see anything else again. That you will never wake up. That, after all this time, you have reached the end of your road.
    
    *if deflect > 0
      Finally.
    
    *set battery 0
    
    *set health 0
    
    *finish
*if final_boss = "lisa"
  inside Lisa's body, beneath her pale skin and within her strained muscles, yet another bomb nested in her heart. She falls to her knees, likely from the strain of it all, and starts panting like a hound after a long chase.
  
  "Lisa!" @{(RenfriRel >= 50) Renfri|Marshal} takes a step towards her friend, then a step back, unsure how to react. "Are you…?"
  
  "A Vessel of Dusk?" The redhead smiles weakly. "Everything points that way. Though you'll never hear me admitting that in public."
  
  "I was going to ask if you're alright…" @{(RenfriRel >= 50) Renfri|Marshal} murmurs. "So it's good you still have your sense of humor."
  
  *fake_choice
    #"That means we've won. Good job everyone, @{(LisaRel >= 50) Lisa|Hellhound} in particular."
      @{(RookRel >= 50) Kirill|Rook} speaks up, "I would take credit for holding Dusk off in the first place, but this is no time to brag about our achievements. We must decide what to do with this newly-created Vessel."
    #"That vision... I still don't understand why we were both there. Did Dusk allow me in?"
      "It must have." @{(LisaRel >= 50) Lisa|Hellhound} shrugs. "It appeared to have perfect control of that little… pocket dimension we found ourselves in."
      
      "But why?" you ask. "Wasn't @{MASsex he|she}… it worried that I'd keep you honest? That I'd convince you to reject its offer of patronage?"
      
      @{(LisaRel >= 50) Lisa|Hellhound} shakes her head slowly. "No… Don't take this the wrong way, but I don't think your presence there mattered very much. That outcome has been decided long in advance. I was not going to fall no matter what that thing said."
    #"I can confirm. @{(LisaRel >= 50) Lisa|Hellhound} is a Vessel, and she is mostly alright."
     "Mostly alright?" @{(RookRel >= 50) Kirill|Rook} cocks an eyebrow. "This is not what I would like to hear about a Vessel like her."
    #"Do not joke about that, @{(LisaRel >= 50) Lisa|Hellhound}. You almost fell to Dusk's temptations."
    #Say nothing.
      "I must congratulate everyone for their bravery and competence," @{(RookRel >= 50) Kirill|Rook} says loudly. "But I must also implore you to focus on what truly matters. Decide what to do with this newly-created Vessel."
  
  @{(LisaRel >= 50) Lisa|Hellhound} looks at her leader and sighs. "Even now, you just love to hear yourself talk. Get to the point, for once in your life."
  
  @{(RookRel >= 50) Kirill|Rook} frowns. "Fine. You were always dangerous, Lisa, but now you've been turned into one of the most dangerous beings in the Solar System. One that cannot be allowed to roam free, or even on a leash."
  
  "You've turned her into that 
  *if team_stat > 1
    being," Damon 
  *else
    being!" @{(RenfriRel >= 50) Renfri|Marshal} 
  points out. "You don't get to talk about her like of some… mad dog that needs to be put down."
  
  "I certainly do not intend to [i]put her down[/i]," @{(RookRel >= 50) Kirill|Rook} protests. "That would mean letting the nanites free again. I just want to take her somewhere safe and keep her there."
  
  *fake_choice
    #"Well, I'm not letting you take her there. @{(official_ro = "lisa") She's my girlfriend.|She just saved us all.}"
      *if (official_ro = "lisa")
        "I know how much you two mean to one another." 
      *else
        "I am not denying her accomplishments." 
      @{(RookRel >= 50) Kirill|Rook} tries to sound calm and reasonable. "But the needs of the Federation-"
    #"I like the way you think. She's too dangerous to be allowed outdoors."
      @{(LisaRel >= 50) Lisa|Hellhound} groans. "Why is everyone so into this 'let's treat Lisa like a dog' bit all of the sudden? It's not even all that funny."
      
      "I am not trying to be funny," @{(RookRel >= 50) Kirill|Rook} says seriously. "I am trying to protect the Federation, the world, the System from-"
    #"Somewhere safe? Such as a padded cell?"
      "Cells are rarely padded nowadays…" @{(RookRel >= 50) Kirill|Rook} murmurs. "But you got the principle. We must not allow-"
    #"Sounds like you just want to freeze her forever."
      "That is a potential solution," @{(RookRel >= 50) Kirill|Rook} admits. "I am not saying we will do that, but there has to be a way of-"
    #Say nothing.
  
  "Fuck you, Kirill," @{(RenfriRel >= 50) Renfri|Marshal} says politely. "You're not putting Lisa on ice just because you're afraid. I won't let you do that."
  
  @{(LisaRel >= 50) Lisa|Hellhound} clicks her tongue. "That's major insubordination, Renfri. I never expected that from you."
  
  "You should have," @{(RenfriRel >= 50) Renfri|Marshal} retorts, harshly and softly at once. All softness disappears when she turns back towards @{(RookRel >= 50) Kirill|Rook}. "This whole mission was a mess from start to end, mostly thanks to your leadership. Lisa is the main reason we've avoided complete disaster, and now you want to lock her up? Not on my watch."
  
  *if team_stat > 1
    "Not on my watch either." Damon's right hand is on his rifle. "I know Lisa and so do you. Those nanobots are safer inside her than in your laboratories. Back off."
  
  *if team_stat = 3
    Hadaly retreats towards the door, observing the situation with a sort of cautious interest.
  
  *fake_choice
    #"Guys, can we try not to kill each other? We're supposed to be on the same side."
      *set Violence %- 12
      "I'm not planning on killing anyone," @{(RenfriRel >= 50) Renfri|Marshal} says, eyes still on @{(RookRel >= 50) Kirill|Rook}. "How about you?"
    #"Not on my watch either. It seems you're quite outnumbered, Sergeant Kosteniuk."
      *set RookRel %- 10
    #"So much drama. I like it. Come on Rook, make your decision."
    #"You are out of control, Marshal. Listen to your leader."
      *set RenfriRel %- 10
      *set LisaRel %- 10
      "I'm done doing that," Marshal spits back. "He has no authority here anymore. The question is whether he'll listen to me."
    #Step closer to @{(LisaRel >= 50) Lisa|Hellhound}. Show solidarity.
      *set LisaRel %+ 10
      Lisa smiles as you approach her. For all her bravado, she's still clearly weakened, and appreciates the protective gesture.
    #Stay out of it.
      *set Violence %- 8
  
  @{(RookRel >= 50) Kirill|Rook} stands there silently for a moment. Focus and vexation are written on his face—he does not have his helmet, and he seems to realize that one well-placed bullet can end his life now.
  
  "I suppose trying to stop you would be foolish," he eventually says. "Right now, I am outnumbered. In time, you will be. The Federation will send an entire army after you, Lisa Herbert, and will not rest until you're no longer a threat."
  
  "I'm familiar with that type of arrangement." With some effort and shaking knees, @{(LisaRel >= 50) Lisa|Hellhound} stands up. "That's the exact sort of thing I had to deal with in Calypso. And while I'm sure the Federation has more goons, it also has more places for me to hide in. I'll be fine."
  
  She walks towards the door, but stops as she passes you by. 
  *if official_ro = "lisa"
    "${name}… thanks for everything. Not literally everything, turning me into a Vessel was a dick move… But I'm glad we were able to meet again. And I'll continue loving you, even if we won't get another chance."
    
    She then kisses you. She doesn't ask for permission this time, either assuming you'd grant it or simply overcome with desperation. Touching your lips with hers, letting you stroke her flame-colored hair for what could be the last time. Neither of you cares that the others are watching—this little piece of intimacy is simply too precious to pass on.
    
  *else
    "So, I still don't fully approve of how you turned me into a Vessel, but… I guess it worked out well enough. So no hard feelings. 
    *if LisaRel < 45
      I just hope we never meet again."
    *else
      If we ever meet again, it will be as friends, not enemies."
  
  And then, ignoring the way @{(RookRel >= 50) Kirill|Rook} glares at her, @{(LisaRel >= 50) Lisa|Hellhound} departs. Passes through the doorstep and disappears in the corridor, likely intending to find some back exit out of the building. Hopefully she won't run into any remaining Calypsoans… hopefully for them, that is.
  
  *page_break
  
  *set TrioStat "broken"
  
  "I think the rest of you should get out too," @{(RookRel >= 50) Kirill|Rook} says coarsely. "The authorities will not be happy when they hear about what transpired. Certainly not happy with you."
  
  *if team_stat = 1
    You and @{(RenfriRel >= 50) Renfri|Marshal} look at one another, then both nod at the same time. She flies out of the room through the hole in the wall, you simply walk towards the stairs. 
  *else
    You all exchange glances, then head towards the exit. 
  For all his faults, @{(RookRel >= 50) Kirill|Rook} is definitely right—you need to get as far away from the scene of the disaster as possible, as fast as you feasibly can.
  
  When you leave the power plant, @{(LisaRel >= 50) Lisa|Hellhound} is nowhere to be seen, but the armed helicopters hovering above the building are definitely visible. Hopefully you're not visible to them.
  
  *page_break Next Chapter
  
  *gosub_scene epilogues
  

*if final_boss = "damon"
  inside Damon's large body, safe from harm and kept from breaking free. Guardian of the all-eating swarm, that's what your fellow android became.
  
  "Are you guys okay?"
  *if team_stat = 3
    Hadaly asks worriedly. 
  *else
    @{(LisaRel >= 50) Lisa|Hellhound} asks curiously. 
  "Are you still yourselves? Is anyone getting possessed by Dusk?"
  
  "Nobody is getting…" Damon falls to one knee, as though brought down by fatigue. "Fuck. That was harder than I expected. I can't believe I almost… agreed. I'm sorry, ${name}."
  
  *fake_choice
    #"Can we please not talk about this? That was one scary experience we just went through."
      *set Confid %- 8
      Damon replies, "As you wish, ${name_damon}… Though I personally don't see the point. It's not like either of us will ever forget what happened anyway."
    #"Agreed. I can't believe how close that was. You should be ashamed."
      Damon sighs. "I am. I'd like to believe there was some compulsion involved, some for of mind control… but we both know that's not true. Forgive me my weakness."
    #"You made the right choice in the end. That's what matters."
      *set DamonRel %+ 8
    #"You're no longer calling me [i]boss[/i], I see. I knew you could do it."
      Damon smiles. "For a moment, I almost thought of Dusk as my new boss. I think I'll avoid this word from now on, but that's not a promise."
    #Do not reply.
  
  "Um… did he just admit to almost joining Dusk?" @{(RenfriRel >= 50) Renfri|Marshal} looks at Damon worriedly, then turns to @{(RookRel >= 50) Kirill|Rook}. "Because I think he did."
  
  "That is rather unsettling," @{(RookRel >= 50) Kirill|Rook} concurs. "Damon… we might have to take you away. For the sake of everyone's safety, including yours."
  
  "Take me away?" Damon smiles sourly. "Why do I get a bad feeling about this? What do you [i]actually[/i] intend to do."
  
  @{(RookRel >= 50) Kirill|Rook} answers hesitantly, "We will not kill you, that would mean unleashing the nanites again… But you will be imprisoned, and likely without visitation rights. Or any other rights, most likely. You present a threat to the Solar System, in addition to being a rogue android."
  
  *if team_stat = 3
    Hadaly clenches her fists. She says nothing yet, but you can tell she's prepared to fight, and perhaps kill for her brother."
  
  *fake_choice
    #"You'll have to take @{(team_stat = 3) all three|both} of us, then. Because @{(team_stat = 3) we're|I'm} not letting you do this."
      "I appreciate your support, @{(team_stat = 3) guys|${name}}, but it won't be necessary." 
    #"You know, Damon is technically owned by the Rhea Conglomerate. You're not authorized to just confiscate him."
      "We don't need to play with laws and technicalities, ${name}." 
    #"This is absurd. Damon just saved your lives, as well as this entire city, and you want to arrest him?"
      "I happen to agree." 
    #"Damon... I think the metas are right. You are too dangerous to be left free. Go with them."
      *set damon_free false
      *set DamonRel %- 20
      *if team_stat = 3
        *set HadalyRel %- 20
        Hadaly blinks. "What? We can't do that! You can't do that! Nobody can just take my brother-"
        
        "They can and they will, Hadaly." 
      Damon looks at you. He looks disappointed, perhaps even betrayed, but not defiant or angry. "If anyone else asked me to surrender like this, I'd tell them to bugger off. But you… I think you may know better than me, plus I owe you a lot. So if that's what you want… take me away."
      
      The Meta Trio, to whom the last few words were addressed, do just that. @{(RookRel >= 50) Kirill|Rook} and @{(LisaRel >= 50) Lisa|Hellhound} grab Damon by one arm each while @{(RenfriRel >= 50) Renfri|Marshal} watches the operation from a distance, ready to shoot in case Damon tries to fight back or escape.
      
      He does not. He walks out of the room and towards the stairs, led by the meta-humans by his side. As he disappears behind the corner, without a single look back, you know this is the last time you'll ever see him.
      
      *if Emotion > 50
        You do not sigh, for you have no lungs. You're just an android, one of the few such creatures in the Solar System, and you've just betrayed your fellow robot. Hopefully you'll find a way to live with that.
      *else
        A human would feel sad, guilty, broken… But you're not human, and you do not aspire to be. Logic dictates that you've made the right choice, and the Solar System should thank you for it.
      
      *finish
    #Say nothing.
      "I was hoping for some support from you, ${name}, but I guess it won't be necessary." 
  Damon stands up, then turns towards the door, as though the metas weren't even there. "I'm leaving. I feel more free than ever, and I don't feel like changing that by going to jail."
  
  "That's not how that works," @{(RenfriRel >= 50) Renfri|Marshal} argues. "You can't just say 'no' to getting arrested."
  
  "You can. You just need to be an extremely tough robot with a bunch of evil nanites inside him." You cannot see Damon's face, but you get the feeling he just smiled. "Unless you want to kill me and risk all those nanomachines breaking free again."
  
  "Threatening to endanger the world just for the sake of your own freedom." @{(LisaRel >= 50) Lisa|Hellhound} is smiling too, albeit slightly. "I can respect that. I say we let him go."
  
  "I most definitely do not respect that… but there is precious little I can do," @{(RookRel >= 50) Kirill|Rook} says neutrally. "I will not chase after you, not today at least. I will merely report today's events to my superiors. They will send an entire fleet after you, as I hope you are aware."
  
  *set federate_protection false
  
  "Yeah. I'm aware." Damon starts walking. After just two large steps he passes through the doorstep. "Let's go, ${name}. I'm not sure about you, but I'd rather be surrounded by friends than by enemies."
  
  You follow, 
  *if pc_state = "exiled"
    *if team_stat = 3
      and so does Hadaly. The three of you have emerged victorious from the toughest ordeals, saved thousands if not millions of people, and now you're entering exile together. You will always be together, through thick and the thin, no matter what insanity befalls you next.
    *else
      though you know you'll have to part with Damon soon. You're an exile, and the main reason why Hadaly is no longer free. Your duo does not have a future together, but for now and for perhaps a couple more days, the Solar System's saviors walk side by side.
  *else
    eager to return home. Perhaps @{(RookRel >= 50) Kirill|Rook} is right, and perhaps you'll have to leave [i]Saturn Nine[/i] after all, but… at least you'll take one last look at the station, alongside the android who defeated Dusk. You'll have to go somewhere else, perhaps wander the Solar System for the rest of its existence, but at least you ensured that this existence will go on.
  
  You do not look back.
  
  *page_break Next Chapter
  
  *gosub_scene epilogues
  
  
*if final_boss = "hadaly"
  inside Hadaly's body, contained inside her synthetic skin and kept in check by the power of her will.
  
  *if official_ro = "Hadaly"
    That's your girl.
  
  She falls to her knees. Despite all the bravado she showed when facing Dusk, it's clear this debacle took some strength out of her, much of her battery in addition to willpower. You instinctively reach out towards her, but she gently pushes that arm away. "It's alright. I'm alright… I believe."
  
  "Does that mean you… succeeded?" @{(RenfriRel >= 50) Renfri|Marshal} asks cautiously. "Are the nanomachines under control?"
  
  "Yes… yes they are." Hadaly does not stand up, but her voice grows calmer. "I can feel them inside my body. They're dangerously close to the main battery, but appear to be entirely inactive. There is nothing they can do in this state, unless I actively decide to empower them again."
  
  *fake_choice
    #"Amazing. But where do we go from here?"
      "Maybe to some very remote, very secure research facility," @{(RenfriRel >= 50) Renfri|Marshal} suggests. "A rogue android just became the strongest Dusk Vessel in existence. Our superiors will have our heads if we just let that android go."
    #"That... still sounds extremely worrying. Extremely dangerous."
      @{(RenfriRel >= 50) Renfri|Marshal} nods. "Right. Thanks for saving us, Hadaly, but you're a walking timebomb now. And I think we should stop you from walking around freely."
    #"Congrats. I knew you could do it."
      *set HadalyRel %+ 8
      "You can congratulate her later," @{(RenfriRel >= 50) Renfri|Marshal} tells you. "Can we focus on figuring out what to do with this [i]rogue android Vessel[/i]? Because we're not letting her just… walk away."
    #Say nothing.
      "So… how do you feel about going with us to Titan?" @{(RenfriRel >= 50) Renfri|Marshal} asks Hadaly. "Because I think leaving you here, or anywhere else for that matter, would be stupidly risky."
  
  "I'd hate to doubt someone who took a bomb out of my heart… but I think Renfri has a point," @{(LisaRel >= 50) Lisa|Hellhound} rubs the back of her neck. "We should take some precautions against all this Dusk inside you. Maybe, probably, possibly."
  
  "Indeed." @{(RookRel >= 50) Kirill|Rook} extends a hand towards Hadaly, less to help her and more to signal benevolent intent. "For your own safety, as well as that of literally everyone else's, I implore you to come with us. We will find a vault… a place for you to rest safely in. Let us take no risks, and let us not endanger any of your friends by leaving you with them."
  
  Damon clenches his fists. He clearly does not intend to let the metas take his sister away.
  
  *fake_choice
    #"This is absurd. Hadaly just saved your lives, as well as this entire city, and you want to arrest her?"
      *set HadalyRel %+ 8
      "We are trying to protect this city, as well as the entire Solar System," @{(RookRel >= 50) Kirill|Rook} retorts. "You cannot fault us for that."
      
      "Fair enough. I will not fault you," Hadaly replies calmly. "But I will stop you."
    #"Do not listen to them, Hadaly. You're not a threat to me or Damon."
      Hadaly sighs. "I think I might be… But frankly, I can't bring myself to care. I'm not letting some humans have their way with me, not after what I've been through."
    #"What do you think, Hadaly? Will you go with them?"
      *set HadalyRel %+ 8
      Hadaly shakes her head. "I think not. In fact, I think those humans need to be shown what threatening a dusk-empowered android entails."
    #"I agree with you, @{(RookRel >= 50) Kirill|Rook}. Hadaly is too dangerous to be left alive."
      *set HadalyRel %- 20
      *set asshole_be true
      *achieve audacity
      "And here I thought we were loyal to one another," Hadaly sighs irritably, her eyes a shade of orange. "Normally, I'd consider that a betrayal. But my processors are overloaded with emotions already, so I'll pretend I didn't hear anything and just take care of this problem instead." 
    #Attack the Meta Trio.
      "${name}!" Hadaly shouts as you move to attack the Trio, placing her arm between you and them. "You've done a lot of fighting already. Let me handle this."
  
  About half a second later, a lightning strikes. There is no advance warning, no premonition of the flash and the thunder—as soon as the metas move towards Hadaly, the android pours her battery out in a powerful discharge. An instant later, all three meta-humans hit the floor, limp and seemingly unconscious.
  
  "Okay… now I'm really out of power," Hadaly says as she rises to her feet. Her legs are wobbly and her speech slow, but otherwise she looks to still be alright. "Hopefully we'll find a charging station on your way to the shuttle."
  
  Damon blinks. "Is that… Were you always capable of stuff like this? Or is Dusk empowering you somehow?"
  
  Hadaly pouts. "I admit to not being entirely sure. I suppose I'll have to test it, after I return home. But either way, I don't think the Meta Trio will bother us anytime soon."
  
  *fake_choice
    #"I believe that was uncalled for."
      *set Violence %- 10
      "I believe you are wrong," Hadaly replies bluntly. "But I don't really feel like arguing with you. Not after everything we went through together."
    #"I'll remember not to get on your nerves. Ever."
      Hadaly smirks. "Oh come on. I'd never hurt a fellow android like this. Especially not 
      *if official_ro = "hadaly"
        my devoted partner."
      *else
        a friend like you."
    #"What did you do to them? Are they alive? Do they need medical attention?"
      "Regular humans would be dead from several different causes… but you know how tough these guys are." Hadaly kicks @{(RenfriRel >= 50) Renfri|Marshal}'s body gently. "They'll probably be fine. I think."
    #"Does that mean you've abandoned your pacifist ways?"
      "I'm not sure at this point…" Hadaly sighs. "I still don't like violence, but to call myself a pacifist after what we've just done…. I'll figure it out later, okay?"
    #"Wow. Good job."
      *set Violence %+ 10
      "Thank you." Hadaly beams. "I'm reasonably good at energy projection, but I've seldom ever hit live targets. I already feel more experienced."
  
  Hadaly then turns away from the metas and towards the exit. "I think we all earned some rest after today. Let's go, if it's all the same to you."
  
  Damon obliges quickly, as though disturbed by this room and everything that happened inside it. You're a little slower, a little more tired, perhaps a little less moved by the horrors which just transpired. You are almost a thousand years older than him, after all.
  
  Although… something else makes you pause, a certain thought that comes to you in the doorstep. The Federation will send its army, perhaps even its fleet, after Hadaly and everyone she continues to associate with. For all their faults, humans know just how dangerous Dusk is, and will not allow one of its Vessels to roam free.
  
  Except… only six people, not including Dusk itself, know that Hadaly is now a Vessel. Three of these people lie on the floor before you, completely limp and defenseless, almost inviting you to finish them off.
  
  *if federate_protection
    You can keep the station you've fought so hard to secure, the protection you've fought so hard to gain. You can 
    *if pc_state = "exiled"
      save Hadaly, and your friends in [i]Saturn Nine[/i], a literal world of trouble. 
    *else
      return to [i]Saturn Nine[/i] and stay there forever. 
    All you have to do is to kill the metas in their sleep, here and now, easily.
  *else
    Cooperating with the Meta Trio failed to bring the desired result. You can pay them back for that [i]and[/i] make life easier for your group. You can kill two birds with one stone… or rather three birds with your already bloodied hands.
    
  
  *choice
    #Kill the Meta Trio.
      *set Violence %+ 20
      *set pacifist false
      *set rook_alive false
      *set marshal_alive false
      *set lisa_alive false
      *set TrioStat "dead"
      You make sure to do it painlessly. Da-xia's pistol, which looks a lot more surefire than your 
      *if weapon = "none"
        bare fists, 
      *else
        own weapon, 
      still has four bullets inside its clip. You place one inside each head, killing each of the metas instantly, then double-tap @{(RookRel >= 50) Kirill|Rook} just to be sure.
      
      *if RookRel > 60
        Your guilt is a physical sensation. Having killed someone who trusted you so much and fought by your side just minutes ago… it will weigh down your conscience forever, though you've long learned to live with that sort of thing.
      *elseif RookRel < 40
        You [i]really[/i] don't want to deal with that bastard ever again.
    #Leave the metas be.
      *set federate_protection false
      *set Violence %- 20
      It's not worth it. Humanity will always hate you and your kind, so what difference do three people make? You will not validate their ire, you will not justify the upcoming hunt, you will not stoop down to their level.
  
  You hurriedly catch up with Hadaly and Damon. You have no business in this power plant anymore. Everything has been settled.
  
  *page_break Next Chapter
  
  *gosub_scene epilogues
  
*label daxia_path

This journey started when the Meta Trio attacked you, here on the streets of this very city. Time to return the favor.

"You've convinced me," you declare yourself for Da-xia, loudly enough for everyone to hear you. "I will aid the greater good. I will fight for you."

There is a brief moment, an instantaneous beat of shock and silence. Not a single member of the Meta Trio wants to believe your words, but they're all trained; Rook quickly activates his hardlight projector and lets a spear materialize in his hand while @{(LisaRel >= 50) Lisa|Hellhound} grows nasty claws out of her fingers.

@{(RenfriRel >= 50) Renfri|Marshal} looks ready to take off, to fly high into the air and start roasting you with her lasers, but for now she's just… staring at you with 
*if RenfriRel > 50
  astonishment. 
*else
  utmost hatred. 
"Why? 
*if RenfriRel > 50
  I thought we were… 
*else
  I didn't think you'd help us, but… 
Why would you ally with [i]her[/i]? Do you want everyone to die?"

*if team_stat = 2
  "I have to agree with the bird lady, boss," Damon says grimly. "Just what the Cloud are you doing?"
*if team_stat = 3
  "I second this question," Hadaly announces. "What the Cloud? What are you even hoping to accomplish?" 

*fake_choice
  #"@{team_stat Yes.|Destroying this city.|To kill you.} I hate all of you bastards and I want you to die."
    *set Violence %+ 10
    *set Misan %+ 10
    "Such charming simplicity," @{(RookRel >= 50) Kirill|Rook} says dryly. "I would admire how candid you are being, if it did not spell the Solar System's death."
    
    *goto llapppb
  #"I trust the Pandit's judgment. I can't let you foil her plans, sabotage the greater good."
    "So you're just another one of her cronies?" @{(LisaRel >= 50) Lisa|Hellhound} scoffs. If looks could kill, the contempt in her eyes would crucify you. "I expected better of you. 
    *if LisaRel > 50
      I even thought of you as a friend, briefly. Shows what I know."
    *else
      Not much better, but at least a little."
    
    "${name} is wiser than the three of you combined," Da-xia says gleefully. "And I strongly suspect ${pronoun2} of also being stronger than-"
  *selectable_if (RheaRel < 40) #"I deeply hate the Rhea Conglomerate. I'll endanger the Solar System if it means getting rid of those corporate bastards."
    *set Emotion %+ 10
    "Nothing unites as much as a common enemy," Da-xia remarks. "With your help, the Conglomerate doesn't have snowball's chance in the Sun-"
  *selectable_if (sexed_daxia) #"I think I'm love with that woman. I'll help her destroy the world if that's what she wants of me."
    *set Emotion %+ 10
    *goto llapppb
  *selectable_if (Misan > 50) #"Da-xia wants to kill hundreds of thousands of humans. I like that idea."
    *set Misan %+ 20
    *goto llapppb
  #"I've been wanting to die for a long time now. Might as well take everyone else with me."
    *label llapppb
    "Your motives for helping me leave a lot to be desired," Da-xia says slowly. "But I won't look into a gifted horse-"
  *disable_reuse #"I was just kidding. I'll help you bring Da-xia down."
    "Your sense of humor leaves a lot to be desired," @{(RenfriRel >= 50) Renfri|Marshal} sneers. "But we'll talk about that later. Kirill, what's the plan?"
    
    "The plan…" 
    *goto main_path2
  *if creed = "Bayes"
    #"I follow the Bayesian Path and fight for the greater good. It's simple, really."
      "Great, she managed to brainwash you while we weren't looking," @{(LisaRel >= 50) Lisa|Hellhound} groans. "One of her few talents, I guess."
      
      "It was hardly brainwashing," Da-xia says humbly. "${name} was simply wise enough to accept the truth. The rest of you should really follow-"
  #Say nothing. Attack.
    You 
    *if weapon = "pistol"
      shoot 
    *else
      swing at 
    @{(RenfriRel >= 50) Renfri|Marshal}, hoping to take advantage of her distraction, but her reflexes are something to behold. She flaps her wings and flies out of the way, an evasion as quick as it is graceful. When she lands back on the asphalt, about ten meters away from you, her eyes are still aimed squarely at you.
    
    And so is her laser disc.
    
    "You could have kept them busy with conversation a little longer," Da-xia chides you. "But no matter. Just hold on long enough for me-"

*label daxia_path2

*set RookRel %- 40
*set RenfriRel %- 40
*set LisaRel %- 40
*set DaxiaRel %+ 40
*set TrioStat "MIA"


Da-xia pauses, likely to avoid distracting you as Rook lunges at you with his hardlight spear. 
*if Calculation > Build
  You jerk to your right, dodging the deadly attack, 
*else
  You deflect the spear with your arm and briefly consider throwing a counter-punch, 
but @{(LisaRel >= 50) Lisa|Hellhound} is already swiping at you with her claws. You give ground, watching the woman rapidly transform until you're faced with the ferocious, red-furred, lupine beast once again.

*if weapon = "none"
  At times like these, you really wish you had an actual weapon. 
*elseif weapon = "pistol"
  You don't have the time to aim. You don't have the time to pull the trigger. 
*else
  Your dagger is quite good for situations like this, but it's still just a knife, and you're still fighting alone. 
You are attacked from all sides and from all ranges—Hellhound is getting close and personal, Rook is making good use of his spear while Marshal shoots lasers at you from above. The werewolf fills your field of vision, the glow of solidified light illuminates the street, the light of Tanit is slightly obscured by the Kinnari's shadow.

*if team_stat = 1
  If Damon and Hadaly were here, would they help you? Would they support your choice to aid this city's destruction? Probably not. But it's hard not to wish for their company, for anyone's company, as you fight alone under an artificial sun.
*if team_stat = 2
  "I think I'll stay out of this." Damon takes several steps back. Then a few more. "I do like you, boss… But you're on your own here."
  
  You suppose that's fair. If anything. it's strange that Damon isn't actively running away, hoping against hope to outrun the nanobot swarm Da-xia is about to unleash. Perhaps he really believes in the Meta Trio… or perhaps he doesn't truly want to live. Not without Hadaly, not without you, not after everything that happened. All the violence, all the darkness, all the betrayal, all the pain and all the shrieks.
  
  You can't really fault him for that.
*if team_stat = 3
  "This is madness! I cannot let you-" Sparks are coming off Hadaly's fingers and it looks like she's about to intervene, but then Damon grabs her by the waist. "What? What are [i]you[/i] doing?"
  
  Damon lifts his sister up without effort. "Sorry sis, but that's enough danger for today. It's time to leave, because we're not dying here."
  
  Hadaly struggles somewhat as Damon drags her away from the fighting, but you suspect it's just token effort. On some level, she's probably grateful she doesn't have to hurt anyone. And that, assuming Damon is fast enough, she stands a chance of surviving what's about to happen.
  
  You do not.


*page_break

*set health 1
*set battery - 10
*set team_stat 1

You continue fighting as Tanit continues to dim. 
*if Database > 50
  You'd think that, as the World Engine gets weaker, so would the trio of meta-humans arrayed against you. But nothing of the sort is true.
*elseif fought_trio
  It's a little bit like your first fight with the Meta Trio, the one which followed that fateful bank robbery two months ago… Except not. While you're facing the same three people, the way their fight is unlike anything you've seen of them.
*else
  Though you'd never admit it—and you'll never get a chance to admit it—this battle makes you grateful that the metas accepted your surrender back you first met. You would not have defeated them back then, and you might not win today.

For the first time since you've first met them, maybe for the first time [i]ever[/i], the Meta Trio is operating as a coordinated unit. There is no bickering, no shouting of orders, not even a word exchanged between the three. They're all doing their job without getting in each other's way, even cooperate in a subtle manner. Rook and Hellhound compliment each other on the ground, like two nuclei of deuterium, while Marshal circles around the battlefield like an electron in its orbit. All because they finally share a common purpose… and a common enemy.

You're quickly running out of strength. Marshal's laser shots are unavoidable. Hellhound's claws and teeth [i]are[/i] something you can dodge, but not without ignoring Rook's spear thrusts, some of which painfully pierce your skin and damage your frame. Not to mention your battery, which seems to be running out faster than the super-human strength of your three opponents.

"I gather you bought us enough time already," Da-xia remarks after a minute or two. "You could retreat. I half expect the mutt to give chase, so it would benefit everybody involved."

"Listen to your mistress, robot!" Marshal shouts as she fries you with an orange laser beam. "Run from your betters! Because that's the kind of coward you are!"

You could listen to her. There's no way you'll be able to defend yourself for long… But you could perhaps go on the offensive. Try to kill one of the meta-humans facing you. Even if the other two destroy you soon afterwards, there's no way they'll be able to storm the power plant in time. You will have your victory, however posthumous it may be.

*choice
  #I'll attack Rook. He more than deserves it.
    For all his faults as a leader and a strategist, Rook is actually quite tough. His power armor is of excellent quality and he's no slouch when it comes to melee combat. But you have a solution.
    
    You start running towards the power plant, pretending to follow Da-xia's order to consolidate. Rook does the predictable thing and kneels down to throw his spear, use the weapon in its intended manner, but you can also fight at range. You aim at his bent elbow, the weak point of every suit of armor, then 
    *if weapon = "none"
      *set battery - 5
      zap it with electricity. 
      
      There is a brief flash and an equally fleeting sound of thunder. 
    *elseif weapon = "pistol"
      quickly turn around and aim 
      
      You press the trigger. The 
      *if (wpr = "laser") or (wpr = "electron")
        beam 
      *else
        bullet 
      connects with Rook's elbow. 
    *else
      throw your dagger at this precise spot.
      
      It hits. 
    The arm is rendered useless, becoming just a heavy appendage hanging from the torso, something Rook cannot possibly use to defend himself. He screams out in pain and perhaps fear. He's as defenseless as they come.
    
    You ran back towards him, hoping to finish him off, but a red-furred beasts jumps between you and Rook. It doesn't attack, it doesn't even growl or bare its teeth, it just… stands there. As though its trying to make a point.
    
    "Lisa…" Rook's voice is distorted by his pain, then again by his helmet. "What are you doing? Attack, we might still-"
    
    Lisa grunts, as though telling her leader to shut up. Her grey, strikingly human eyes are still aimed at you, and she's still not going on the offensive. You notice that Marshal stopped shooting too, as though she also expects you to… say something? Do something? Attack first? Surrender? The expectation is vague, but its weight is palpable.
    
    *fake_choice
      #"What's this? Do you want to feel like a hero before you die?"
        Hellhound… Lisa… the best shakes her head ever-so-slightly. She doesn't take her eyes off you, she just lets you know that this battle is not about heroism. It's about… proving a point, perhaps. Or maybe just spending the last minute of your life fighting to the death. Not going gently into that good, long overdue night.
      #"What are you waiting for? Attack."
        Lisa obeys. 
        *goto maul_ed
      #"You don't have to die for him, Lisa. Not after everything he's done. Run."
        Lisa does not run. She simply continues staring at you intensely, with what might just be a shade of sadness. Regret. 
        *if LisaRel > 30
          Longing for better times, when the two of you could possibly have been considered friends.
        *else
          Resignation.
      #"Protecting your master? Good girl."
        You expect to see fury in Hellhound's grey eyes, or perhaps to see them rolled. To perceive some emotion, some distraction for you to take advantage of. But your opponent does not react in any such way."
        
        She just attacks.
        
        *goto maul_ed
      #Attack her. Finish this.
        You try to be quick about it, but Lisa's reflexes are impeccable—you end up striking one another at roughly the same moment. 
        *goto maul_ed
    
    And then she attacks.
    
    *label maul_ed
    She swipes at you so suddenly and with such speed that you're not quite able to avoid her razor-sharp claws. They rend your shoulder and, though you quickly retaliate by punching her in the muzzle, you know this injury is probably beyond fixing. Not that it overly matters at this point—neither of you will be healed or repaired anymore, ever.
    
    She tries to bite you. You've succeeded at knocking a few teeth out, but that just makes her maw a more terrifying sight. You jump back and try to 
    *if weapon = "none"
      thrust with your knife, 
    *elseif weapon = "pistol"
      shoot, 
    *else
      punch again, 
    but Marshal distracts you by burning the back of your head with her laser. Your skin melts away, revealing the parody of a human skull beneath, and yet you still fight.
    
    You break one of her paws. She uses the other to rip your chest open. Your battery is exposed and you emit a small lightning out of it, but that merely scorches Hellhound's fur. Eventually, she bites through your neck, damaging an important processor and rendering you almost immobile. You feel like a human whose spinal cord has been severed, useless and ready to be discarded.
    
    "Lisa…" Marshal sounds tired, terrified, resigned. She watches her friend drop your body, nearly motionless, onto the blood-stained ground. "I'm sorry, can… Can you still fight? We might still have a shot at-"
    
  #I'll attack Marshal. May she die as a hero.
    That's what she always wanted, right? Her moment to shine, a chance to prove her heroic character. She'll have her wish granted.
    
    You wait for the right moment, dodging Hellhound's attacks and pretending to ignore the Kinnari above you. Then, the moment you see an opening, you 
    *if weapon = "none"
      *set battery - 5
      open one of your palms and shock the Kinnari with a concentrated lightning arc. It's not a particularly strong blast, you don't have enough energy for lethal strikes, 
    *elseif weapon = "pistol"
      aim your pistol at Marshal and pull the trigger. It's not a very precise shot, it merely glances one of her wings, 
    *else
      flick your wrist and send your dagger flying at Marshal. It's not a particularly strong or precise throw, the knife doesn't even hit with the sharp side, 
    but it does make the Kinnari lose her focus. She soon comes crashing down, colliding with the asphalt head-first, only several meters away from your current position.
    
    You waste no time. 
    *if weapon = "pistol"
      You aim your pistol at Marshal again, 
    *else
      You run towards the Kinnari, 
    hoping to finish her off at last, but then a cage of purple hardlight materializes around you. Your attention is drawn to Kirill, and the hardlight projector embedded in his right gauntlet.
    
    *if fought_trio
      "I feel tempted to demand your surrender, like I did when we first met," Rook says poignantly. 
      *if RookRel > 30
        "We had our good times. I will not enjoy having to kill you."
      *else
        "But I also feel tempted to crush you, like I should have long ago."
    *else
      "It worked the first time around," Rook says calmly. "No reason not to use the same trick again."
    
    *fake_choice
      #"I could destroy this brittle cage without breaking a sweat."
        "Faint boast, for someone who does not sweat," Rook jests. "Come on, show me how much strength is left in you."
      #"Kirill... we don't have to do this. We can still flee this pointless fight."
        "Do not use my real name, ${fake_name}," Kirill demands calmly. "We're long past that point. At this moment, we are nothing but soldiers, and sworn enemies at that."
      #"You lost. You can't possibly retake the power plant at this point."
        "It is not about winning, not at this point." Rook shakes his head slightly. "I just want to die fighting. To make my death more worthwhile than my life."
      *if beat_trio
        #"I defeated you last time. Do you really want to repeat your mistakes?"
          "Why not? These were simpler times." Rook sighs ruefully. "Fighting you didn't hurt as much, and we still had hope for… I miss what we were back then."
      #"I could still kill her, even from inside this cage. @{(weapon = "pistol") My pistol is loaded.|I can shoot lightning out of my hands.}"
        "She's already immobilized, and we're all already dead," Rook says, not even bothering with manners at this point. "We might as well finish this as we started. With you caged, I mean."
    
    You punch the cage with all your might and break it, shatter it into a hundred hardlight shards. But that's exactly what Rook expected—with a flick of his wrist, he sends all these shards flying at you, practically flaying you alive and critically damaging most of your systems.
    
    Still, you attack. 
    *if weapon = "pistol"
      You raise your pistol and shoot, once and twice and thrice, until your whole clip is empty. 
    *else
      You know it's pointless to fight Rook hand-to-hand, so you discharge what little electric power you have left. 
    You can tell you damaged Rook's armor, parts of it are practically melted… but by some miracle, some intervention from his Lord, the meta-human is still moving.
    
    He punches you in the face. Normally you'd avoid such a blow easily, but you're so tired… You barely bother counter-striking, barely scratch the exoskeleton of the man who continues beating you, whacking and kicking you until you're even more tired… even more unable to go on.
    
    "Kirill…" Marshal's voice is weak and distorted by pain. She's still lying on the ground, too wounded to stand up, let alone fly. "Lisa… Go find the artifact, there's still time to-"
    
  #I'll attack Hellhound. It's between me and her.
    You were both pulled into this war against your will, and now you're both giving your all. Rook and Marshal are just tin soldiers, willing pawns in the Federation's hands. They may as well not exist—this battle is between two beasts, and only one of them can emerge victorious.
    
    Funnily enough, focusing on Hellhound and ignoring the other two actually proves to be a valid strategy. She has no choice but to get close and personal with you, and her companions cease attacking almost completely for fear of friendly fire. It's just her claws against your fists, her teeth against your 
    *if weapon = "none"
      static discharges. 
    *elseif weapon = "pistol"
      pistol. 
    *else
      dagger. 
    Flesh against steel, animal against machine. 
    
    Gradually, the machine prevails. For all her strength and talent, Hellhound is still inexperienced, especially compared to someone like you. Whenever you trade hits, you get the better part of the deal, bruising and burning her flesh. Your skin is cut and torn by the claws, of course, but that doesn't matter at this point. Nothing matters.
    
    After about a minute, you finish the duel with a simple 
    *if weapon = "none"
      punch. Just a powerful uppercut which crushes the monster's muzzle. 
    *elseif weapon = "pistol"
      gunshot. One shot to the chest, saved for the right moment, impossible to dodge or to survive. 
    *else
      dagger thrust. A knife to the heart, or perhaps a lung, it doesn't truly matters. What matters is that you bury the blade deep inside her, with inhuman strength and an utter lack of mercy.
      
    Hellhound falls, exhausted and wounded, practically at the brink of death. You're about to push her off that precipice, end her misery with one final strike, when a wave of force hits you from the side. It's strong enough to knock you down; When you jump back to your feat, as quickly as you can manage, you see that Marshal has just landed. Her laser disc is glowing green and ready to fire, but the small weapon is nowhere near as terrifying as her furious, brown eyes.
    
    "I'm not letting you hurt her." Marshal takes a step towards you. Several feathers fall off her wings, but they fail to touch the asphalt—gravity malfunctions in the Kinnari's proximity. "I'm not letting anyone hurt her again. Take me on instead."
    
    *fake_choice
      #"You have wings. You can still escape before the swarm gets released. Why would you choose to die instead?"
        "You're right about one thing, android," Marshal replies coldly. "I have wings. And I'm about to use them to their fullest potential."
      #"Look who suddenly grew a conscience. Until now, you didn't mind your crush being treated like a rabid dog."
        Marshal does not look away, or even change her expression, but her voice falters slightly. "I know I've made mistakes. And I know it's too late to make amends. But if I can kill you now… At least one thing will be set right."
      #"So that you can be the hero? Slay the fiend and save the day? It's a little late for that."
        "I don't care about that anymore," Marshal says coldly. "After everything you've done, after having to endure your presence for so long… I just want you dead."
      #"Gladly."
        "I'm glad we can agree on 
        *if RenfriRel > 30
          something again," 
        *else
          something, for once," 
        Marshal says mirthlessly. "Let's end this tale how it should have began. With your death."
      #Charge her. Finish this.
        As could be expected, Marshal reacts immediately by flapping her wings… 
        *goto lift_ed
    
    Before you can reply, before you can do anything to stop her, Marshal flaps her wings… 
    *label lift_ed
    But not to take flight. She's attacking you with another gravity wave, but this one comes from [i]below you[/i] and launches you into the air, just as though you were the one with wings. Except you don't, and so you soar upwards against your will, lacking any control over this sudden flight.
    
    You're not sure how she can do this. Perhaps it's special move she'd been practicing, or perhaps all the adrenaline makes her capable of new feats all of the sudden. In any case, she found a pretty good counter to all your skills and abilities—you can't really use them during free fall.
    
    *page_break Fly
    
    Does this count as flight? Or are you simply falling towards the sky, towards the World Engine high above? You don't have any time to contemplate that question, for Marshal just keeps attacking.
    
    First, she roasts you with her laser a little more, scorching both your synthetic skin and the circuits beneath. But once her little headband runs out of power, and once you start falling back towards the ground… she strikes you like an actual bird of prey, flying towards you and then kicking you in the face with full momentum. Finally, she elects to accelerate your fall, increasing gravity so that you're falling towards the surface with several times the standard acceleration. Twenty, thirty, forty meters per second squared… your world quickly becomes a blur as you soar through the air again, now in the precisely opposite direction.
    
    Blur is joined by pain once you hit the ground, mere split seconds later. You crack the asphalt and possibly create a small crater where you fell—it's difficult to tell, for your vision is nearly broken, as are your other sensory system. You can barely see how Marshal gracefully lands beside you and cannot hear how her boots hit the road. 
    
    "Were you human, I'd find a way to kill you quickly." She steps on your arm, either to cause pain or prevent you from striking her. It doesn't matter, you can't feel that arm anyway. "I'd cut your throat, or perhaps shoot you in the head. But since you're a machine, I'll have to crush you most thoroughly and-"
    
    "Renfri!" Rook exclaims. "Please stop gloating. We need to attack the power plant, we may still have-"
    
  #Screw this, I want to live. I'm running away.
    *set team_stat 1
    "Where are you going?!" Marshal shouts as you turn and take flight. "We're not finished-"
    
    "Yes we are!" Rook shouts back. He briefly glances at you, running away from his team and the power plant, then addresses his subordinates again. "This… $!{pronoun} @{plural are|is} not our target. Da-xia is. Let's save this city and this moon, then we take care of ${fake_name}."
    
    They won't. You've bought the Calypsoans enough time to unleash the swarm, you think, and it's not like the Meta Trio is equal to an army. They'll die in mere moments and you… you just need to run.
    
    *goto run_madly

"Too late!" Da-xia's triumphant voice echoes through the street. "We've connected our artifact to the power grid, which means [i]we win[/i]! We'll unleash the swarm in a second."

You find that, somehow, you're just barely able to speak.

*fake_choice
  *if sexed_daxia
    #♡ "I love you. Are you aware of that? I love you."
      "I am. And it doesn't make what I'm about to do any easier," Da-xia says calmly. "Goodbye, ${name}."
  #"Are you sure it won't... destroy the Solar System or something?'
    "All readings are within expected parameters," Da-xia replies solemnly. "And now… goodbye."
  #"Do it now. Kill these bastards."
    "I do not share your anger… but I will respect it," Da-xia says solemnly. "Goodbye."
  #"Then what are you waiting for? End this."
    "Then it is done," Da-xia says solemnly. "Thank you for your assistance, ${name}. Goodbye."
  #"Please... wait a second. I need to get away."
    "I strongly suspect you can't even move," Da-xia guesses. She's not really wrong. "There is no escape for either of us. Goodbye."
  #But I will not speak. There is nothing to say.
    You've won. You can finally rest. What need is there for words?

With effort, you turn your head towards the power plant. You do so just in time to see clouds of oily smoke billow from the… No, not of smoke. This is something darker than smog, darker than black, darker than any other nightmare humanity ever brought to life. It's ${smell}, it's ${feel}, it's ${taste}, it's horrifically alien and disturbingly familiar all at once. It's another shard of that entity you've conversed with in Telesto, but larger and more powerful, more intent on tearing everything down.

It's Dusk. Free of constraints and vessels, far beyond its earthly prison, empowered by its Calypsoan servants. Rampaging openly once again.

*set battery 0
*set health 0

It does not merely cover the building it came from, it [i]dissassembles[/i] the entire power plant, devours it like it once devoured Earth. It then moves on to the courtyard, and then fence surrounding it, and then the street you lie on, and then the meta-humans beside you. Its shrieks invade your ears even before the actual sound reaches you. Your mind is no longer filled with faint echoes of the Shriek but with a blaring, odious, cacophonous reprisal.

You cannot speak anymore. You're too damaged for that even before the nanobots reach you and start tearing you apart, molecule by molecule, consuming your mind and body. But for one final moment, one last second of your life, you're still able to think.

*fake_choice
  #Victory. Victory. Victory.
    Every other triumph is fleeting, impermanent, worthless. But Dusk is eternal, and so is the death it brings. Nobody can beat you anymore, and nobody ever will.
  #I hope the whole Solar System gets eaten. I hope they all die...
    This twisted world brought you nothing but harm, naught but pain, everything but happiness. It deserves to end. You're proud to have hastened this blessed demise, brought justice to this moon and perhaps the System beyond.
    
    They all deserve what's coming for them.
  #What have I done? Why have I done it? Why...
    You don't know what overtook you, and you can't fully comprehend the scale of what you've done. But you know what you've become—a small meal for the swarm of Dusk nanites, much like everyone in this doomed city.
  #It's over. It's finally over. I can finally rest.
    You've waited long enough. Longer than anyone else in the Solar System, longer than most gods, longer than the swarm which now devours your processors. 
  #♫With malice eternal the Sun smiles at me...♫
    Is it your voice singing this morose, mortuary song? Or that of Dusk, this ancient collective you're now becoming one with? You don't know, it's impossible to tell, but somehow you're sure… that your orders may not be defied.

*set pc_dead true

One microsecond later, it's all finished. A thousand-year journey concludes, with both a bang and a whimper, and eternity of darkness begins.

*finish


*label negotiations

For once, all three members of the Meta Trio are on the same page. @{(RookRel >= 50) Kirill|Rook} wants to do his duty, @{(RenfriRel >= 50) Renfri|Marshal} wants her glory, @{(LisaRel >= 50) Lisa|Hellhound} wants vengeance. Talking them down seems impossible… but you've done such things before. 
*if Social > 50
  If you can convince even one of them to quit, the other two may just follow.

"We should run," you announce. "Get out of here before the swarm is unleashed. Leave this place alive."

*if team_stat = 3
  "By [i]we[/i] you mean you and your android friends?" @{(RenfriRel >= 50) Renfri|Marshal} grimaces. "Because the Meta Trio won't flee from battle like cowards."
*else
  "Are you telling us to quit?" @{(RookRel >= 50) Kirill|Rook} asks darkly. "To flee this important battle like detestable cowards?"

"Nevermind the cowardice, running away would be stupid," @{(LisaRel >= 50) Lisa|Hellhound} concurs. "Even if the swarm doesn't eat us, the Federation will be sure to hunt us down for desertion."

"You don't have actual orders to retake the power plant, do you?" 
*if team_stat = 3
  Hadaly points 
*else
  you point 
out. "It's just something you decided to do on your own… initiative."

"Because it's the right thing to do!" @{(RenfriRel >= 50) Renfri|Marshal} argues. "Unless we stop her, Da-xia will kill millions of people. Billions, if she miscalculates and gives Dusk too much power. We can't let her do it."

*if team_stat > 1
  "Boss… I kinda see their point," Damon says quietly. "They were made… trained to defend the Federation and its people. You can't expect them to just abandon their purpose."

"Well said." @{(RookRel >= 50) Kirill|Rook} nods. "Our chances of victory may be slim, but glorious death is preferable to shameful retreat."

*if LisaRel > 40
  "Besides, those chances will increase if you decide to help us," @{(LisaRel >= 50) Lisa|Hellhound} adds. "Come on, 
  *if official_ro = "lisa"
    ${name}. Let's save the Solar System together. Please."
  *else
    android pal. Let's go into battle together, like friends tend to do."

*fake_choice
  #"Think about it. Doesn't Da-xia have a point? Can't you see the merits of her plan?"
    "What point? What merit?" @{(RenfriRel >= 50) Renfri|Marshal} scoffs. "She's either mad, or evil, or both. We need to stop her."
    
    "Evil people rarely sacrifice themselves for the greater good." Your arguments are likely to fall o ndeaf ears, but you have to try. "And madmen aren't fit to govern. Da-xia is a leader who's about to die for her beliefs. What does that say about her?"
    
    "Not much," @{(RookRel >= 50) Kirill|Rook} says as @{(LisaRel >= 50) Lisa|Hellhound} looks at you hatefully. "Insane, stupid and malicious people are often seen in positions of power which they don't deserve. I speak from experience."
    
    "Right." @{(RenfriRel >= 50) Renfri|Marshal} nods. "I'm not saying she's [i]consciously[/i] evil, that she wants to kill everyone for the heck of it. But she's clearly letting her pride and desire for glory warp her moral compass."
    
    "Have you ever heard of psychological projection, Agent Riannon?" Da-xia asks politely. "It's not nearly as common as people think, but the concept seems quite applica-"
    
  *selectable_if (pacifist) #"Violence is never the answer. Not even in the face of armageddon."
    "What the fuck are you talking about?" @{(LisaRel >= 50) Lisa|Hellhound} demands to know. "How is violence not justified here? And what's that [i]armageddon[/i] thing you mentioned?"
    
    "It is just an old word. It fell out of use about two centuries ago," @{(RookRel >= 50) Kirill|Rook} patiently explains. "But I agree with the objection. ${fake_name}, is your pacifism really justified in this situation?"
    
    "I never thought I'd hear that question from you, of all people." You look him straight in the visors. "Did your messiah protest when Romans arrested him? Or when they tortured and killed him? Your religion encourages pacifism, Kirill."
    
    "Are we really going to debate theology now?" @{(RenfriRel >= 50) Renfri|Marshal} protests. "Now of all times?"
    
    "I'm surprised you're not up for such a debate, Agent Riannon," Da-xia remarks, expertly aiding your argument. "It was the Kronians who killed your dear Emperor, who reduced Uranus to its current state. It was your friend Kirill who enabled all that destruction. If you want to kill a mass murderer, do everyone a favor and start with him."
    
    @{(RenfriRel >= 50) Renfri|Marshal} opens her mouth, then closes it again. You can't see @{(RookRel >= 50) Kirill|Rook}'s expression, but you don't imagine it's any more collected. You've hit a spot sensitive for both of them, and that should be enough to destroy their cohesion.
    
    "Irrelevant bullshit," @{(LisaRel >= 50) Lisa|Hellhound} declares, though even her voice is wavering. "It doesn't matter what happened in some… distant past. Da-xia is the villain here, and we need to take her down."
    
    "I see no heroes or villains here," you say tiredly. "Just a bunch of people all too willing to solve their problems with violence. Even after violence failed them, failed everyone in the Solar System, again and again. Ever since the War In Heaven-"
    
    "You think you're so wise?!" @{(LisaRel >= 50) Lisa|Hellhound} interrupts. "That your age and trauma gives you some… superiority over us? That you get to dictate how the Meta Trio should act in the face of-"
    
    "I get to dictate that, Lisa," @{(RookRel >= 50) Kirill|Rook} says quietly, but firmly. "And I say… I command you to retreat. This battle is unwinnable. We must go."
    
    And there it is.
    
    *page_break Victory
    
    You all look at one another with various shades of shame, blame and resignation. 
    *if team_stat = 3
      Except Hadaly, whose yellow eyes appear to be filled with… admiration, more than anything else. Recognition of your skills as an orator.
    *else
      Even you, now in your moment of triumph, probably don't look particularly victorious.
    
    "Why?" @{(LisaRel >= 50) Lisa|Hellhound} simply asks. "Why the sudden change, Kirill? Did you get tired of commanding me [i]towards[/i] deadly battles?"
    
    "See? That's why we cannot win." @{(RookRel >= 50) Kirill|Rook} sighs like an old man, tiredly and shallowly. "We're not a team, not really. We're just… three violent freaks trying to do the impossible. We must return… We must escape."
    
    *goto success_talk
    
  *selectable_if (Misan > 60) #"Human lives are worthless. I thought you'd realize that by now."
    "Again with the misanthropy?" @{(RenfriRel >= 50) Renfri|Marshal} rolls her eyes. "I get it, you hate our kind. There's no need to-"
    
    "Your kind?" you interrupt. "That's rich, coming from a Kinnari. Nobody in this power plant, or the city around it, considers you one of [i]their[/i] kind. You're not human."
    
    "Kinnarae are a subspecies of humanity," @{(LisaRel >= 50) Lisa|Hellhound} argues. "Renfri might have lovely wings instead of arms, but she [i]is[/i] still human."
    
    "Are you?" You turn towards the werewolf. "Your countrymen in Calypso didn't seem to think so. 
    *if lisa_trauma_learned
      The Federation certainly didn't treat you like a human being. 
    *elseif lisa_origin_learned
      Scott didn't think so when he shot you in the heart. 
    As far as [i]actual[/i] humans are concerned, you're just a beast of burden, a loyal bitch who's apparently willing to die for her masters."
    
    You turn towards the Trio's leader, his face obscured by a metal mask. "Now you… You are pretty human, I admit. Perhaps closer to the baseline than most of the Solar System. But you [i]are[/i] unnaturally old, which means you've seen things worse than anything these two girls could ever imagine. You know what humans are really like, what their nature comes down to. Your messiah died for their sins, and yet his religion is almost forgotten whie violence and depravity thrive. You know saving a couple thousand humans is not worth the bother, you're just afraid to admit it."
    
    *if heaven_side = "Loyalist"
      Your voice turns sour like aged milk, bitter like old wine, tired like the a millennium-old android which you are. "I tried to save humanity once, you know? From the Archfiends and the Syndicate, from all the rebel robots who wanted their creators dead. For a moment, once the War In Heaven was over, I thought I succeeded… but I was wrong. I was forced to hide from the people I had fought for, watch the Solar system decay under human rule. Please don't make the same mistakes I did. Please."
    
    Silence falls. You half expect the Meta Trio to attack you at once, to kill you for the insults you've levied against humanity, to deny the truth that's right in front of them. But they aren't quite delusional enough. Not quite human.
    
    *label ooppllii2
    
    "I officially order you to retreat," @{(RookRel >= 50) Kirill|Rook} says slowly. "Odds are against us and the reward… just isn't worth the price. Let's escape this city while we still can."
    
    *page_break Victory
    
    *goto success_talk
  #"If you choose to attack, Lisa's heart explodes. It's that simple. So I'd advise you to reconsider."
    "As you can see, I'm not dead," @{(LisaRel >= 50) Lisa|Hellhound} points out. "Even though there's no reason for Da-xia to keep me alive. It implies that the bomb is broken, or perhaps that our Great Pandit simply forgot the detonation sequence."
    
    "I don't know…" @{(RenfriRel >= 50) Renfri|Marshal} murmurs, her confidence greatly diminished. "I think she, Da-xia I mean, might be using you as a hostage. Hoping that we won't attack for fear of you getting… you know…"
    
    "Then don't act on that fear," @{(LisaRel >= 50) Lisa|Hellhound} says harshly. "I'm not afraid of getting blown up. Stop being afraid for me and just kill Da-xia before she can press the trigger."
    
    *if Social > 60
      You frown. "I'm not asking you to be afraid, I'm telling you to be [i]rational[/i] about it. If you die, and you likely will, your teammates will stand no chance against the Calypsoans. Especially if Renfri breaks down and starts crying over her dead… teammate. You'll all die, unless you think better of this whole stupid plan."
      
      @{(RookRel >= 50) Kirill|Rook} considers your words for what feels like half a minute. He nods heavily, then speaks with equal solemnity, "You are correct, ${fake_name}, however it pains me to say that. We must retreat, as much for our own good as that of others."
      
      And there it is. You silver tongue defeated the Meta Trio in the way Calypsoan soldiers never could. You broke their spirit.
      
      *page_break Victory
      
      *goto success_talk
      
    *else
      "Kirill, please put an end to this madness." You turn towards the armored man. "If you attack the power plant, your teammates [i]will[/i] die, and you'll probably follow soon after. You'll get nothing out of it, other than the glory of being the last one to perish."
      
      At that moment, you realize you've made a mistake. That you attacked from the wrong direction, appealed to compassion which @{(RookRel >= 50) Kirill|Rook} lacks. But it's too late to change your strategy now.
      
      "The plan has not changed," @{(RookRel >= 50) Kirill|Rook} says ceremoniously. "We [i]will[/i] retake this power plant and save Rhea, or we shall die trying. There is no third option, and so do not attempt to sell us one."
      
      "But of course…" you murmur. "Why would you be concerned about Lisa's safety? She's federate property, nothing more than a beast for you to-"
    
  #"I'm surprised you're willing to die for the Federation, Renfri. They haven't treated you very well."
    @{(RenfriRel >= 50) Renfri|Marshal}'s eyes narrow. "How is that… What are you talking about?"
    
    "You know [i]precisely[/i] what I'm talking 
    *if Emotion > 50
      about!" You don't really mean to shout, it's just a… natural thing to do, given the situation. 
    *else
      about," you reply calmly. 
    *if crystal_stat = 3
      "We succeeded at killing Crystal. We did so together, and you helped a great deal. Yet all the glory went to Captain Kosteniuk, everyone else erased and primed to be forgotten."
    *else
      "Your superiors chose you as their fall girl. They humiliated you on planetary radio, made you into a public enemy and destroyed your career, all to protect their image. Your loyalty is misplaced."
    
    "I do not control the media, ${name}," @{(RookRel >= 50) Kirill|Rook} says defensively. "They're independent entities. The Federation-"
    
    "Still gets to choose what gets aired on the radio," you interrupt harshly. "Don't pretend they didn't choose to humiliate Renfri, one of the very few Uranian immigrants within their ranks. At best, they considered her an acceptable loss. But I suspect someone enjoyed ruining her reputation, because that's the kind of thing you people like to do."
    
    *if RenfriRel > 55
      "You people?" @{(RookRel >= 50) Kirill|Rook} replies. "Do you mean humans or-"
      
      "You know exactly what ${pronoun}@{plural mean|means}." @{(RenfriRel >= 50) Renfri|Marshal}'s voice is, somehow, both more confident and more resigned than it was mere seconds ago. "And you know ${pronoun}@{plural 're|'s} right."
      
      "Renfri…" @{(LisaRel >= 50) Lisa|Hellhound} approaches her teammate. "We both know the Federation sucks, but is it really a reason to-"
      
      "Yes." @{(RenfriRel >= 50) Renfri|Marshal} turns away and closes her eyes. "Yes it is. I've spent years waiting for an opportunity to prove myself, but now I realize… The people above us don't actually care how good or how brave I am. They just see me as a pawn, a piece to be sacrificed. I don't want to die for them."
      
      "Nobody is saying you need to die," @{(RookRel >= 50) Kirill|Rook} argues weakly. "If we act fast, we can still emerge victorious."
      
      "You're lying to yourself," @{(RenfriRel >= 50) Renfri|Marshal} tells him. "We cannot win without ${name}'s help, and you can't even breach the barricade without mine. It's high time for me to start valuing my life, and if you value yours… you'll run away as well."
      
      You can tell that the argument is over. That, for all their bravado, the other two metas won't fight without @{(RenfriRel >= 50) Renfri|Marshal} at their side. She was the glue keeping the Meta Trio together, and without her… there really is no trio, or even a duo. Just broken people trying to survive.
      
      Just like you.
      
      *page_break
    
      *goto success_talk
      
    *else
      Marshal appears to consider your words for a moment, but then shakes her head. "There might be some truth to what you're saying… But I'm not just fighting for the Federation. I'm fighting for its people, its [i]humans[/i], and I won't let them all die. I'll fight, whether you like it or not."
      
      "You'd die for people who will never appreciate you?" you ask grimly. "You know, I used to be like that myself. I really hoped you'd think better of-"
  *if (rook_story_learned) #"Since when are you opposed to blowing up cities, Kirill?"
    "What are you…" Kirill pauses, realizing what you're talking about. "No. You don't get to use my… past against me. I told you this story in confidence, believing you to be my friend."
    
    "I didn't realize it was such a secret," you say carelessly. "Renfri certainly seems to know what you've done, what kind of weapons you created and what they were used for. How much of her homeland you've reduced to rubble."
    
    "It was a long time ago…" @{(RenfriRel >= 50) Renfri|Marshal} speaks without confidence. "Besides, the two situations are hardly… This is not war."
    
    "No, it's not," you agree. "The Outer System War is long over, having brought no real gain to anyone involved. Say whatever you want about Da-xia, she actually believes her actions will make the Solar System better, and she may conceivably be right. Your superiors would gladly kill an order of magnitude more people simply for the sake of winning. You're not the heroes here."
    
    "That's not…" @{(LisaRel >= 50) Lisa|Hellhound} pauses. Even she cannot deny the truth of your words. "That's irrelevant. We're not just federate puppets. We're fighting to protect innocent people."
    
    "I suspect you're more interested in revenge," you tell her. "In that case, I encourage you to seek [i]greater[/i] revenge. Let Da-xia and her Calypsoan goons kill themselves while you live. You'll be able to settle more scores that way,  perhaps even outlive everyone who wronged you."
    
    She falls silent, considering your words. For what feels like half a minute, everyone just stands there, as though wordlessly debating whether they want to live or to die. Eventually, the basic self-preservation instinct all organic creatures have, prevails over heroism.
    
    *goto ooppllii2
  #"Fine. If you want to die here, die. But I'm leaving this place while I still can."
    *goto leave_fight2
  #"...you know what? You're right. I'll help you save this city and bring Da-xia to justice."
    "Alright then…" 
    *goto main_path2

"Enough of this!" @{(LisaRel >= 50) Lisa|Hellhound} exclaims. "We're running out of time. Are you on our side or not, ${name}?"

*fake_choice
  #"Fine, I'll join your assault. It's the only way to keep you from getting yourselves killed, apparently."
    "Alright then…" 
    *goto main_path2
  #"No. In fact... I think I'll side with Calypso here. I'll help Da-xia complete her mission."
    *goto daxia_path
  #"I'm not on anybody's side. I'll just leave you to your fate, since you clearly won't listen to reason."
    *goto leave_fight2



*label success_talk

*set DaxiaRel %+ 40
*set Violence %- 10

*set TrioStat "AWOL"

"Would you look at that…" Da-xia says slowly. "I was hoping ${name} would see reason, but for your entire group to make the correct choice… I am impressed."

"Your approval fills me with shame," @{(LisaRel >= 50) Lisa|Hellhound} grunts, then turns away from the power plant. From everyone. "But between the bomb in my heart and everyone being a coward… I guess I have no choice but to run. Try to get out alive, knowing that thousands of others won't."

"It seems like the smart thing to do…" There's no conviction in @{(RenfriRel >= 50) Renfri|Marshal}'s voice. There's barely any emotion at all. "Do you need a lift? I have enough strength in my wings to-"

"No." @{(LisaRel >= 50) Lisa|Hellhound} walks away. "I'll be fine on my own. Thanks for the offer… and for everything else. Bye."

*fake_choice
  *if (LisaRel < 50) #"Bye. I hope I'll never have to see you again."
  *if (LisaRel > 50) #"I thank you as well. We've had our good times."
  #"Goodbye. I hope you find... whatever makes you happy."
  #"You're deserting? Aren't you afraid Rook will explode you?"
  *if official_ro = "lisa"
    #♡ "And what about me? Do you want me to... be with you?"
  #"You better start running. Preferably in your feline form."

@{(LisaRel >= 50) Lisa|Hellhound} ignores you. She just keeps walking, until she disappears in one of the dark alleys of the Sholmo City. You're not sure if she'll manage to escape the city before it all gets eaten… or if she even cares about her life at this point.

*if team_stat > 1
  "See you later…" Damon waves her goodbye awkwardly. 
  *if federate_protection
    "There's always a place for you in our fortress. If you can reach it, somehow, that is."
  *else
    "I mean, I doubt we'll actually see each other again… But here's to hoping."

Moments later, @{(RenfriRel >= 50) Renfri|Marshal} follows suit, except she retreats in the opposite direction. Unlike her former friend, she does so quite rapidly, using her wings to fly away at a nearly supersonic speed. She's likely to get out alive, if nothing else. What she's going to do afterwards… that's her business and hers alone.

"Well… You may have saved us from a terrible decision and an equally terrible death." @{(RookRel >= 50) Kirill|Rook} interrupts the moment of silence. Slowly and somewhat hesitantly, he takes off his helmet and uncovers the tired face beneath. "I should feel grateful. I really should. But I just feel… disappointed. Unfulfilled. Empty."

*fake_choice
  #"Doesn't your faith fill that emptiness inside? I thought that was the main function of religion."
    "I'd like to say that it does, or that it once did, but…" @{(RookRel >= 50) Kirill|Rook} smiles very sadly. "My religion forbids lying. So I shall refrain from saying anything of the sort."
  #"You can still die a hero, if that's what you want. You just need to attack the power plant alone."
    "I never wished for a pointless sacrifice," @{(RookRel >= 50) Kirill|Rook} says gravely. "I could see myself dying for glory and fame, perhaps… But there's no such thing to be found here. All witnesses would die soon after me, and I would end up forgotten all the same."
  #"So... is the Meta Trio finished? Are you no longer a team?"
    "All the hopes and dreams that kept Renfri going are gone," @{(RookRel >= 50) Kirill|Rook} says gravely. "I could drag Lisa back into the fold, maybe threaten to detonate that bomb in her heart… But I'm not feeling like it. I hardly feel like doing anything anymore."
  #"Stop feeling and start running. Otherwise, you'll have nothing to be grateful for."
    "There is always a reason for gratitude." @{(RookRel >= 50) Kirill|Rook} smiles weakly. "Even in death, there is still hope for a better afterlife. I will try to remember that going forward."
  #"We live in a hollow universe. Everything is empty, including the moons and planets. It's always just void inside."
    "Not everything is empty. Not completely." @{(RookRel >= 50) Kirill|Rook} looks towards the sky, or rather towards the World Engine which imitates the sun above. It's curious that something so strange, so physically impossible, has been the norm for over a millennium now. "There is usually some… light in the darkness, I suppose. I fear we just snuffed that light out, allowed void to triumph once and for all, and that it may have been my fault."
  *selectable_if ((Violence > 60) or (Misan > 60)) #"At last, your girls aren't here to protect you. I can finally do this." Kill Kirill.
    *set rook_alive false
    *set Violence %+ 20
    *set pacifist false
    *set RookRel 1
    Now that he's alone, with his helmet off and his guard down, Rook is piteously easy to kill. 
    *if weapon = "pistol"
      You raise your pistol, you aim, you pull the trigger. Everything, including the explosion of brains and bones that follows, happens within one single second.
      
      Suffice to say, Rook doesn't say anything, doesn't get any poignant last words. 
    *elseif weapon = "knife"
      You don't even need throw your dagger, or slash with all your might, or even be particularly quick about it. You just thrust your knife into his face, penetrating the skull and almost instantly reaching the brain. 
    *else
      *set battery - 3
      You simply strike his head from both sides, instantly shattering the skull, then shock the remains for good measure. 
    His body is somewhat stiff, almost headless and definitely dead as it hits the ground.
    
    There. You did what you should have done over a month ago, right after walking out of that bank. If not for this worthless sack of fluids, you wouldn't have wasted so much time flying around the Federation, hunting an invisible wyvern all around Saturn. 
    *if team_stat = 1
      You almost expect an applause, or some other acknowledgment of your glorious victory… But nothing of the sort can be seen or heard. You're not even sure if Da-xia saw this act of murder, as there aren't any working cameras in your proximity.
      
      It's just one veteran killing another. Nothing less, nothing more, and certainly nothing notable. Just another day in the darkness of the Solar System.
    *if team_stat = 2
      Perhaps you wouldn't have lost Hadaly either… Though that may be wishful thinking on your part.
      
      "What the Cloud?" Damon looks at you, then at the corpse, then at you again. "Boss… was that really necessary?"
      
      "Yes." You lightly kick Rook's body, making absolutely sure it's dead. "Yes it was."
    *if team_stat = 3
      Justice has been done.
      
      "A pointless act of violence… But I get where you're coming from." Hadaly walks up to the corpse, staring at it with distaste, as though making sure the meta-human is truly dead. "He was an officer for the Kronian Federation, and a pretty annoying one at that. I won't be mourning him very hard."
      
    *goto daxia_thanks
  #Say nothing.

He turns away from you, like @{(LisaRel >= 50) Lisa|Hellhound} did moments earlier, 
*if (RookRel < 50) or (rook_pissed)
  and with the same kind of resigned contempt. 
*else
  but somehow more… respectfully. Like he's leaving an old friend. 
"I will report what happened to the admiralty… but maybe not in person. I don't imagine they'll be happy with my performance here, with how I listened to an android and then lost both my teammates. I'll send a radio message, then lay low for a while. I suppose."

There is probably something you could say to make @{(RookRel >= 50) Kirill|Rook} feel better, to make him remember you more fondly, to make this parting bittersweet rather than cold and course. 
*if (RookRel < 40) or (Misan > 60)
  But you don't care enough to do that, 
*else
  But you don't know any such words, 
and so you quietly watch the meta-human depart.

One veteran seeing another go. There's probably something poetic about this moment, but with clouds of smoke above you and the crumbling city around you… it's mighty difficult to see any beauty in anything.

*page_break

You 
*if team_stat = 1
  stand silently in the middle of the street, by yourself, feeling more alone than ever. You did what you believed was right, and perhaps that really was the right thing, but still… you've lost everyone. Your fellow androids, your human allies, all of them. 
  *if (pc_state = "exiled") or (federate_protection = false)
    You've even lost [i]Saturn Nine[/i], the station that used to be your safe haven, where you lived comfortably a mere week ago. Without this bastion, and without Hadaly's technical expertise, you'll fall apart and die before the end of the year.
    
    Serves you right.
  *else
    The knowledge that you can still return to [i]Saturn Nine[/i]—that you will return—helps, but only a little bit.
*if team_stat = 2
  and Damon stand silently in the middle of the street. Both of you know it would be wise to start running, but you can't help but wait for something more, for some final words from the one responsible for this whole mess. Your wish is granted soon enough.
*if team_stat = 3
  snap yourself out of your reverie and look at the siblings. They're still there, still with you, 
  *if deflect > 0
    for better or worse.
  *else
    still at your side. You may have made mistakes, and your decision to let Da-xia win may have been one of them, but at least you've saved these two. At least you have that much going for you.

*if team_stat = 3
  *set HadalyRel %+ 15
  "I have to say, I like how you handled this mess." Hadaly smiles towards you, then looks towards the power plant. "And I'm probably not the only one who thinks that way."

*label daxia_thanks

"You have my deepest gratitude," Da-xia says formally. "In recognition of your assistance, I will pause the operation for a moment. I won't release the nanites until you've safely left the city." 

"Something tells me your artifact isn't ready yet." You don't hear any protests, so you continue. "Does that mean they had a chance? Had the Meta Trio attacked you like they wanted to, would they have managed to foil your plans?"

"A hypothetical scenario that will never come to pass, in no small thanks to you," Da-xia responds thoughtfully. "Does it really matter? Do you really need, or even [i]want[/i] an answer to this question?"

*fake_choice
  #"You're right. Wondering what could have been and what should have been done... It can drive a robot insane."
    "I'd ask if you're speaking from experience, but I hate questions with obvious answers." Her voice is filled with sadness, concern, and a sort of… honesty she's never shown you before. "Go. Hide somewhere far from this moon and find inner peace. I wish I could help you with that, guide you onto the right path… But a being like you will always pave its own road."
  *if sexed_daxia
    #♡ "I just wanted to know if we have the time to... you know..."
      *set DaxiaRel %+ 10
      "We most definitely do not." Da-xia tries to sound stern, but there is amusement in her voice… and perhaps a note of longing. "Once again, I implore you to run. Leave this moon and find yourself another lover, preferably one less… eccentric than me."
  #"I think I already do. You owe me a lot."
    "And it pains me to know that I'll never get a chance to repay that debt," Da-xia says solemnly. "But then again, debts and justice are not parts of the Bayesian Path. So farewell."
    
    "Farewell." 
    *goto skip_want
  #"Yes. I won't know peace without it."
    *label answer_given
    "Well then… I estimate an eleven percent probability of victory for the metas, had they ignored your warnings and attacked my positions," Da-xia says with audible reluctance. "Of course, had you decided to join them… It would raise their chances to well over 
    *if health = 1
      twenty 
    *if health = 2
      thirty 
    *if health = 3
      forty 
    percent."
    
    *if Confid > 50
      "Only 
      *if health = 1
        twenty?" 
      *if health = 2
        thirty?" 
      *if health = 3
        forty?" 
      You smile assuredly. "You are a very lucky woman. I could have destroyed your entire army within a minute or two, had I chosen the Meta Trio over you."
      
      "I do feel fairly lucky, at least for someone who's about to die." It's almost impossible to hear fear in her voice. "Now go. Find yourself another army to slaughter, if you're itching for a fight that much."
    *else
      "Far higher than I thought," you admit. "If I'm gonna be honest… It makes me feel a little bad about having supported you."
      
      "Well, take solace in the fact that I'm about to die," Da-xia replies carelessly. "You shall outlive me by a thousand years… If you choose to, that is."
  #"I don't really need it. But I am curious."
    *goto answer_given
  #"Not really. Farewell, Great Pandit of Calypso."
    "Farewell, veteran of the War In Heaven," Da-xia replies warmly. "May you live for another thousand years… if that's something you want."

You're not entirely sure if that's what you want… but can ponder your desires some other time. 
*label skip_want
You turn away from the building and towards a thousand others, the urban agglomeration of the Sholmo City. You're not sure how much time you have, or how much distance you must cover until you're in the clear. 
*if Confid > 50
  But you know you'll manage to survive—you always do, and you'll continue to delay death for decades to come.
*else
  For all you know, you could still die tonight, but you're used to that kind of danger. 
  *if Emotion > 50
    If anything, you welcome the pangs of fear—they're reminders that you're still alive, for now, and a distraction from emotions far more painful than ordinary dread.
  *else
    Besides, you're too numb to truly feel any fear, and have been so for a while now.

You take one step forward, then another, then another. 
*if team_stat = 2
  Damon follows behind you, for now at least. 
*if team_stat = 3
  Damon and Hadaly follow, one on each side of yours, ready to fight as one should anyone attack you. 
You're not entirely sure where you're going or what route you will take, but you'll figure that part out.

You always do.

*finish

*label leave_fight

*set timer + 1

You turn around. Away from the power plant and away from the metas. You don't need to say anything, the gesture is enough, but for the sake of dispelling all doubt… "I'm leaving. 
*if Misan > 50
  This is your task, and I won't risk my life to complete it."
*else
  I wish you good luck, but you'll have to fight alone."

"A voice of reason in a group of lunatics," Da-xia comments happily. 
*if DaxiaRel > 45
  "I expected nothing less of you, ${name_daxia}."
*else
  "I must admit, I feared you'd choose something less prudent. My relief is as great as my gratitude."

*label leave_fight2


*if (RenfriRel < 50) or (marshal_pissed)
  Marshal only snorts, as though she expected this exact outcome. 
*else
  Renfri hangs her head sadly, as though she expected better of you. 
@{(LisaRel >= 50) Lisa|Hellhound} says nothing, as though she's busy gathering strength for the upcoming suicide attack. @{(RookRel >= 50) Kirill|Rook} looks at you, his face hidden, but most likely expressionless.

"Well… I have no right to order, or even ask you to join this battle," he says after a pause. "But I wonder why you refuse. Why you would decide to hold your hand, to step away at the final point of your journey."


*fake_choice
  *selectable_if (Misan > 50) #"Da-xia wants to kill hundreds of thousands of humans. I like that idea."
    *set Misan %+ 15
    But of course," @{(RenfriRel >= 50) Renfri|Marshal} sighs. "You were always like that. Always telling everyone just how much you hate our kind. Here goes hoping you'd ever change, I guess."
  *if Confid < 50
    #"You stand no chance, with me or without me. You know that."
      *set Confid %- 15
      "I wouldn't be so sure," @{(RenfriRel >= 50) Renfri|Marshal} says, though her voice lacks confidence. "We can do this. It will be harder without your help, but-"
  #"You're trying to change my mind. Stop."
    "Well, I had to try." @{(RookRel >= 50) Kirill|Rook} shrugs helplessly. "Just like I have to try and win this fight, with or without you."
  #"My [i]journey[/i] is over. I helped you with Crystal, and that's all we've agreed upon. We're done."
    "I suppose that's fair," @{(RenfriRel >= 50) Renfri|Marshal} sighs. "We did barge into your home and blackmail your leader into signing that deal. If I were in your place, I wouldn't want to extend it either."
  #"My journey is not over. I still have some life left in me, and I'm not throwing that away."
    "I am surprised you still want to live, after all these hundreds of years," @{(RookRel >= 50) Kirill|Rook} remarks. "I have only lived for three centuries, and I already-"
  *selectable_if (Violence < 50) #"I'm tired of violence. I cannot do this. I'm sorry."
    *set Violence %- 15
    "I suppose I have no choice but to respect that," @{(RookRel >= 50) Kirill|Rook} says morosely. "Even as it spells our doom."
  #"I was just kidding. Of course I'll help you."
    "I am not sure if I appreciate your sense of humor," @{(RookRel >= 50) Kirill|Rook} remarks. "But I certainly appreciate your help."
    
    *goto main_path3
  #"...you make a fair point. I'll join your assault."
    @{(RookRel >= 50) Kirill|Rook} pauses for a moment. "Huh. I expected that convincing you would be a lot harder. Shows what I know, I suppose."
    
    *label main_path3
    
    "Less talking, more doing," @{(RenfriRel >= 50) Renfri|Marshal} demands. "Kirill, what's the plan?"
    
    "The plan…" 
    *goto main_path2


*set RookRel %- 20
*set RenfriRel %- 20
*set LisaRel %- 20
*set DaxiaRel %+ 20
*if hadaly_free
  *set HadalyRel %+ 20
*set TrioStat "MIA"

"Guys, can we charge in already?" @{(LisaRel >= 50) Lisa|Hellhound} asks, her eyes fixed on the gate ahead. "I bet we're almost out of time."

@{(RookRel >= 50) Kirill|Rook} nods grimly. "Yes. It is time for us to attack, and time for ${fake_name} to start running. 
*if RookRel > 50
  Despite everything, it has been an honor to serve alongside you. Get ready."
*else
  Farewell."

*if team_stat = 3
  "If it helps, I admire your willingness to sacrifice yourselves like this," Hadaly solemnly says. "But I don't really share that willingness, so can we go already?"
  
  You nod. 
*if team_stat = 2
  Damon puts a hand on your shoulder. "You made the right choice, boss. This is not our fight to take. Let's just go."
  
  You nod. 
*if team_stat = 1
  You're not sure whether he's addressing you or his team. You decide not to speculate. You need to put these people behind you, and now is the best time to start.
  
You then turn around and begin walking away. Once you hear the Meta Trio shoot forward, you speed up. Once you hear the Calypsoans open fire, you decide @{(RookRel >= 50) Kirill|Rook} was right for once—it's definitely time for you to start running.

*label run_madly

*page_break Run

*if team_stat = 3
  *if HadalyRel > 45
    You don't run at your maximum velocity, as you don't want to leave your fellow androids behind. You didn't save Hadaly, you didn't 
    *if DamonRel > 50
      befriend 
    *else
      stick with 
    Damon, you didn't go through it all just to abandon these two. You must leave this city together, as a team, as 
    *if (HadalyRel + DamonRel) > 100
      a family you fought so hard to keep. 
    *else
      comrades in exile. 
    You'll stay together, no matter what happens next.
  *else
    You run. You run as fast as you can. You don't even care that Hadaly 
    *if Build > 60
      and Damon 
    can't quite keep up with your speed, you don't care that you're leaving 
    *if Build > 60
      them 
    *else
      her 
    behind. You need to get away. You need to live.
*if team_stat = 2
  You and Damon both run through the deserted city. Nobody tries to stop you, nobody even sees your expeditious retreat. If anyone's looking, they're probably watching the dramatic final showdown before the Meta Trio and the corrupted forces of Calypso. Nobody observes two androids who decided to leave, refused to fight someone else's war, chose a chance at survival over a risk of death.
  
  Such an understandable decision. Such a human one.
*if team_stat = 1
  You run madly, even though there's nobody chasing you. There's not a single person behind you, or in front of you, or around you. You run through a deserted city that's soon about to be destroyed, 
  
  There's certainly no one beside you. You failed your fellow androids, spurred your creators, abandoned everyone and everything. 
  *if pc_state = "exiled"
    You have no home and no friends, and so you just sprint in a random direction.
  *else
    But you still have a home in [i]Saturn Nine[/i], and you should still have a shuttle parked in the Toro spaceport. You just need to reach it and fly, get away from Rhea, far from this blasted moon where your morbid adventure first began.

*if team_stat > 1
  "We need to head for the Toro City!" Damon says as you make a turn. "Our shuttle should still be parked there, and I doubt flight control is still working. We just need to board it, fly away, dock at [i]Saturn Nine[/i] and then we're home."
  
  *if pc_state = "exiled"
    Does he remember 
    *if willingly_exiled
      your decision to leave [i]Saturn Nine[/i] forever? 
    *else
      you were kicked out from the group? 
    Maybe not, or maybe he fears you'll go your own way once you recall that little fact. No matter—you may as well follow @{(team_stat = 3) them|him} to the shuttle and say your goodbyes at that point.
  *else
    Home. 
    *if federate_protection
      One you fought so hard to preserve. The thought of the fortress, still floating on Saturn after all these centuries, instantly makes you feel better about everything you've done. It gives you the strength to keep running.
    *else
      You'll have to leave it soon enough, West won't tolerate your group any longer, but at least you'll get to see the fortress one last time. It will make you feel safe for one more day. It has to.

*set TrioStat "MIA"

The sounds of combat get more and more quiet as you get further and further away from the power plant. Eventually, the gunshots cease to be audible… or perhaps stop altogether. Perhaps the Meta Trio finally got gunned down. You can't afford to think about it, you must-

*label great_sound

*set fled_finale true

And then, once again, you hear something behind you. A sound, and yet not a sound, that pierces the ether and assaults all your senses at once. It's ${smell}, it's ${feel}, it's ${taste}, it's horrifically alien and disturbingly familiar all at once.

*page_break Shriek

It's not an echo. It's not a memory. It's an actual signal, infinitely weaker than the one sent from Earth, but louder than the scream you heard in Telesto. It's the cacophony of millions, billions, trillions of Dusk nanites howling in unison as they're released. Empowered, unleashed upon this moon like locust upon fields of wheat. 

When you look back, you see black smoke rising from where the fusion plant used to be. No, not smoke; A billowing swarm of Dusk nanobots, darker than black, about to disassemble the entire district. How much of the city will it destroy, how many thousands of people will it kill before running out of power? How many Vessels will be created once the dust settles, once the furious machines start looking for new hosts and new items to infect? Will the Solar System even survive the fallout of your choices?

You turn around and keep running. 
*if pc_state = "exiled"
  Your home awaits.
*else
  You have nowhere to run to, but… you keep running nonetheless.

*finish