*set progress + 1
*temp couple 3
*temp manfred_sleep false
*temp hadaly_goes true
*temp lisa_nice false
*temp dusk_told false
*temp hit_by_kid false
*temp lisa_helps true
*temp hiding false
*set weapon_av true
*temp learned_from ""
*temp terrorist false
*if progress = 5
  *image cal5.png
*if progress = 6
  *image cal6.png
*if progress = 7
  *image cal7.png
*set battery 69
*temp sat_watch false
*temp renfri_flew true
*temp hadaly_observes false
*temp visited_homeless true


*if Database > 50
  The moon of Calypso is well-known even to those who lack your vast database. 
*if Database <= 50
  Your database contains little information on non-rounded moons of Saturn, but even you know a thing or two about Calypso. 
It's not the largest or most populous of Saturn's satellites, being surpassed by over twenty moons in both categories, but it's particularly interesting in several ways. Its government is said to be more efficient and more… genuine than any other political body in the Federation. They subscribe to ancient ideas like nearly everyone else, but their ideology 
*if Database > 50
  comes from the Age of Light rather than preceding centuries. 
*if Database <= 50
  differs from the usual notions of corporatism and indirect democracy. 
You've never been to Calypso yourself, but you've heard people call it unusually peaceful, a remarkably happy place.

Of course, you imagine that some of that peace is gone after Crystal invaded the moon several times, but still… There is something pleasant about how you're headed somewhere known for being quiet and cozy.

Especially since [i]Gray Queen[/i] is currently anything but.

Though the cramped cutter is never really a quiet place, it has been [i]extraordinarily[/i] noisy for the past several hours. You are finally approaching Calypso after three rotations of travel, so the engines are loud as ever. At least they have an excuse of being inanimate; The same can't be said about your actual crewmates, who just keep talking and arguing even as discerning any particular conversation becomes difficult in the chatter. Only Wisp is silent for once, has been since you told it to start orbiting Calypso and looking out for Crystal. You suspect that's either because it lost contact with the ship or found some shiny piece of ice to chase.

*fake_choice
  *if progress = 5
    #We're all new to working together. It will get better in time.
      You will become a well-oiled machine after you bond over your first victory… assuming that victory ever comes, of course.
  *if progress = 7
    #This is our last chance to kill Crystal. I get why the tensions are high.
      If the wyvern fails to revisit Calypso sometime soon, your mission will fail in the most boring and anticlimactic way possible. You are as anxious as anyone to avoid that outcome. 
  #Those metas just can't help but bicker, huh?
    Granted, Manfred has also gotten a bit snarky recently, and your fellow androids have no problem arguing with one another… but that's different. Somehow.
  #Eh. I've heard worse noises in my life.
    You've witnessed explosions so large and loud they could be heard in the vacuum of space, however little sense that makes. Still, that doesn't mean you [i]enjoy[/i] your current predicament.
  #I will go insane here, won't I?
    Your calculations show a considerable risk of madness in current circumstances. Roughly 30% for each of the arguments underway, and it's cumulative.

From the small closet you're sitting in, having dressed yourself for the occasion, you can discern three separate arguments. Damon is talking to Hadaly in the engines, Rook's trying to reason with Hellhound in the passenger compartment, and you're pretty sure Marshal is bickering with Manfred in the cockpit. You could join one of the arguments if you want to defuse it… or if you're hungry for some verbal sparring yourself.

*fake_choice
  #I'll see what my fellow androids are on about.
    *goto d-h
  #I'll see what's happening in the cockpit.
    *goto m-m
  #I'll join Lisa and Kirill, whatever they're arguing about.
    *goto r-l
  #I want none of this. I just wait until we dock.
    You sit and… not quite relax, but try to remain calm as [i]Gray Queen[/i] approaches the moon. Slowly.
    
    *goto cal_ar

*label d-h
Damon and Hadaly arguing is not a common occurrence. Not because they never differ, but because they rarely differ [i]enough[/i] for Hadaly to stand her ground. As she's clearly doing right now.

"Look, I'm sorry, but you're really not making a persuasive argument here," she says. "I'm going out there, for better or worse."

"Then can you at least try to convince Rook that he should let me tag along?" Damon replies irritably.

"You know I'm not any good- Oh hey ${name}! Would you consider waiting a minute or two? Damon is being… well…"

"Understandably worried," Damon finishes for his sibling. "Concerned for my little sister. I don't think you can fault me for that."

"I'm not faulting you [i]per se[/i], but like… do you need to be the 'protective big brother' here? I'm older than you, and usually capable of taking care of myself."

*fake_choice
  #"Can you tell me what's the matter? Maybe I could help."
    "Only if you can make her see the value of safety," Damon groans. "Which doesn't appear possible."
    
    Hadaly ignores her brother and turns to you with explanations. "You know how we're about to visit Calypso? 
  *if progress != 7
    #"You're the older one? That's interesting. Care to tell me more about it?"
      "That's not the point," Hadaly replies irritably. "
  *if progress = 7
    #"Why are you arguing? Does it have something to do with your... creator?"
      "Kind of?" Hadaly winces, unhappy to hear her pursuer mentioned. "But not directly. 
  #"Can the two of you shut up? You're not the only ones on this ship."
    *set DamonRel %- 7
    *set HadalyRel %- 7
    "I will, once you help my brother see reason," Hadaly states. "
  #"I'll leave you two to it."
    *set DamonRel %- 5
    *set HadalyRel %- 5
    "Bye," Damon says quickly, annoyed at the interruption, before turning back towards his sister. "Anyway, I don't think you considered how quickly your eyes can change, and how it gives away your nature…"
    
    At that moment you close the door shut. You have better things to do than serve as a councilor for these two. Well, at this moment you can't do much more than wait… but that's still an improvement from participating in some sibling argument.
    *page_break
    *goto cal_ar
You see, we just talked to Sergeant Kosteniuk over in the next room and he insists that Damon should stay on the ship. We need someone guarding the vessel, and he's the most clearly robotic one between the three of us. So now he insists that I remain here as well and keep him company."

"You know that's not why I object. I'm just… not enthusiastic about you being surrounded by thousands of humans with only ${name} to help out in case something happens."

"Calypso is notable for being a safe habitat, Damon. It's united, away from the Conglomerate and largely free from crime. The only risk here is Crystal, but I don't think this ship provides adequate protection from them either."

*fake_choice
  #"I dunno, Damon has a point. What if someone sees your eyes change?"
    *set DamonRel %+ 5
    *set HadalyRel %- 5
    "They don't change color that much!" Hadaly protests as her irises get closer to scarlet. "Besides, I have no reason to meet anyone in the eye, so please tell my dear brother to get off my back."
  #"Rook ordered Damon to stay here? Sounds dumb."
    *set DamonRel %+ 8
    "The guy's an idiot, do real debate here," Damon remarks. "But that's not the point. Can you tell Hadaly we don't need any more androids in the field?"
    
    *goto dowith2
  #"Wait, what do you mean she'd [i]only[/i] have me as help? Am I not enough?"
    "That's not what I was getting at," Damon assures you. "The point is, everyone else around you will be human or meta-human, and that's always dangerous. Can you tell her that?"
    
    *goto dowith2
  #"Why do you want to go out anyway? I figured you'd be happy to watch the engines or something."
    *set HadalyRel %- 8
    "What, am I not allowed to enjoy tourism?" Hadaly crosses her arms.
    
    "Not saying that," you defend yourself. "But I don't remember you being in any hurry to see Rhea when we landed there. What changed?"
    
    "The location. Calypso is much nicer than that hollow dumping site, so how about you tell Damon I should [i]obviously[/i] be allowed to sightsee around it?"    
  *if progress != 7
    #"Wait, what does the Rhea Conglomerate have to do with anything?"
      "They're evil humans with guns, therefore dangerous." Damon is the one to reply, for some reason. "But that's not the point. Can you tell my sister that we don't need any more androids in the field?"
      
      *label dowith2
      "Can you tell him you won't tell me that?" Hadaly requests. "Because he's clearly not listening to me. When I tell him that."

*temp quiet false
*fake_choice
  #"Frankly Damon, I don't see why you're so worried. We'll be fine out there."
    *set DamonRel %- 8
    *set HadalyRel %+ 8
    "I really hope you're right, ${name_damon}," Damon replies grimly. "Otherwise… I'm not really sure what I'll do."
    
    *goto lplp
  #"If Hadaly wants to come with me and the Trio, she will. Deal with it."
    *set DamonRel %- 15
    *set HadalyRel %+ 15
    "I guess I'll have to," Damon says grimly. "Have fun out there, you two. The least you can do is to make the risk worth it."
    
    *label lplp
    *set hadaly_pissed false
    With that, Damon departs from the engine room, leaving it a little less cramped and with only the buzzing of machinery to fill the air. That and Hadaly's sigh.
    
    "Well, I hope Manfred keeps him good company here. I'd hate to see Damon leaving the ship against Rook's wishes just because he's that much of a big brother."
    
    *fake_choice
      *if (official_RO = "hadaly")
        #♡ "It will be fine. Now... Do I get a reward for helping you out?"
          *set HadalyRel %+ 10
          "Are you saying you wouldn't have helped me if not for your… hopes for a reward?" Hadaly says with a playful smile.
          
          "But of course I would," you reply with a mock bow. "Your humble servant is always at your disposal. $!{pronoun}@{plural 's|'re} just hoping for a gesture of your grace's approval."
          
          "I suppose I could spare one, in my magnanimity," she says before pulling herself towards you and pushing her lips against yours. It's a small kiss quickly planted and lasting just a moment, but there is still tremendous voltage in the contact, surpassed only by the emotion it stirs in you. And unlike the tinkle of electricity, the feeling does not fade once Hadaly steps back. If anything, you feel it get [i]stronger[/i].
          
          "How about we hit the cockpit now?" Hadaly suggests, her precious lips once again forming a small smile. "I want to see the landing maneuvers, and it's safer to watch them on the screens than from the upper deck."
      #"He's an adult. He won't do anything stupid."
        "I'm not sure if I agree," Hadaly replies with a bitter smile. "But as Damon's big sister, I admire your faith in him. Now let's go watch the landing… if you want to, that is."
      #"You're a saint for even humoring him, you know?"
        *set HadalyRel %- 5
        *set DamonRel %- 5
        "He's not that bad," Hadaly replies with a shrug. "And it gets even easier when I remember all the things we've been through before meeting you and Sheila. How many times he's stuck up for me."
        
        "Any chance you'll tell me about it?" you ask, fully knowing Hadaly's still unlikely to discuss her past in detail. @{(progress = 7) Especially considering what you've recently learned of that past…|}
        
        "Maybe later." Hadaly smiles, somewhat sadly. "For now, let's just go to the cockpit and enjoy watching the landing on the screens there. If you want to, that is."
      #"Since when do you care for what Rook wants?"
        "I don't. But letting him [i]know[/i] that is not a good idea, not until we're ready to betray him," Hadaly flashes you a smile which may be sinister just as easily as joking. "In the meantime, let's hit the cockpit. I want to see the landing maneuvers, and it's safer to watch them on the screens than from the upper deck."
      
    You follow Hadaly out of the room and through the full length of [i]Gray Queen[/i]. Behind, you can hear the engines hum louder than ever, doubling their efforts and confirming that landing is mere minutes away.
      
    *page_break
    *goto cal_ar
      
  #"I think Damon's right. Bringing you would endanger you [i]and[/i] the mission."
    *set DamonRel %+ 10
    *set HadalyRel %- 10
    "Endanger the mission?" Hadaly asks indignantly. "I get being worried about me, but where did you get that from? Is it just because of my eyes?"
    
    "Partially. But more than that, I'm worried Damon will insist on coming with you, and then we'll have a conflict with Rook. And an even more conspicuously-eyed android in our group."
    
    *goto plpl
  #"Sorry, I'm staying out of this."
    *set quiet true
    Hadaly deflates, having apparently expected your support. @{(HadalyRel < 40) For some reason. |}She opens her mouth as though to make another argument, but after a moment of silence she just sighs.
    
    *label plpl
    *set hadaly_goes false
    *set damon_pissed false
    "You know what, fine," she says eventually. "I'll stay here, if only to prevent a pile of synthetic muscle from coming after me. Have fun with your meta-human friends, ${name}."
    
    You watch Hadaly walk away and out of the room. You're not sure what she intends on doing now, having just left the engines behind, but you suspect it will be better not to bother her anytime soon.
    
    "Well, I guess that's the best outcome I could have hoped for," Damon sighs once his sister is out of her usual hearing range. "I hope you don't mind visiting Calypso in a group of four instead of five, ${name_damon}."
    
    *fake_choice
      #"Nah, she'd be useless in a fight anyway."
        "Actually, I wouldn't underestimate Hadaly like that," Damon replies. "Her core is really high-voltage, and she knows how to project all that energy out. She can be a real force for destruction when she wants to." 
        
        "And we just pissed her off," you remark. "You are very good at making me feel safe, you know that?"
        
        "I know, boss. I know."
        
        *page_break
        *goto cal_ar
      #"The smaller our group, the less threatened local authorities will feel."
        "That reasoning works too, I guess." Damon relaxes a little. "And makes Rook justified in not letting me out, I guess. I'd probably scare these people to death."
        
        "You actually agree with our human leader?" you note. 
        *if Misan >= 50
          "Don't tell me you're turning into a human lover."
        *if Misan < 50
          "Any chance you're becoming a human lover like me?"
        
        "Not a chance, boss." Damon smiles assuringly… but perhaps not honestly. "Not a chance."
        
        *page_break
        *goto cal_ar
      #"Actually, I do mind. Having Hadaly stay on the ship is a terrible idea."
        *set DamonRel %- 10
        "…wait what?" Damon stares at you with confusion.
        
        "What I said. Hadaly is smart as hell, and has some nice energy-projection abilities. Her eyes aren't exactly natural, but she can cover those with a pair of sunglasses. She would be great to have in the squad."
        
        "Makes sense, but… why didn't you take her side, in that case?"
        
        *fake_choice
          *if quiet
            #"I don't like taking sides, that's all."
              "I guess I can understand that," Damon replies. 
              *if heaven_side = "Neutral"
                "I mean, that's how you survived the War In Heaven itself, wasn't it?"
                
                "Yeah," you sigh. "And that's how I'll keep surviving. Now and forever."
              *if heaven_side != "Neutral"
                "It's not like you had much luck in conflict you did pick a side in… if you don't mind me saying."
              
              Hum of the engines is the only reply.
          #"Because I wanted to annoy her. And limit her autonomy while I was at it."
            *set DamonRel %- 15
            "You know ${name_damon}… sometimes I can't decide if you have a weird sense of humor, or if you're just an asshole."
            
            "Just an asshole," you say matter-of-factly. "I figured you'd start noticing it by now."
            
            "I think I just started, boss," Damon sighs. "I just did."
          #"Because I have your back. Always."
            *set DamonRel %+ 10
            "That's nice to hear, but…" Damon fidgets a little. "You know you don't need to agree with me on everything, right? We'll stay @{(official_RO = "damon") a couple|friends} even if we differ from time to time."
            
            "I know, it's just… hard not to think of relationships like of variables that need to be kept high. I feel as though every person I know can be reduced to a percentage of how much they like me, and I have to keep all the bars filled to at least fifty percent, or sixty or… I think I'm hard-coded to process social data like this."
            
            "You have some issues, ${name_damon}." Damon smiles grimly. "But we can get through them together. I happen to have your back too, after all."
            
            You can't help but smile.
          *if (official_RO != "hadaly")
            #"Hadaly is my friend and your sister. Two reasons to keep her away from danger."
              *set DamonRel %+ 15
              "Good to see we're on the same page," Damon smiles, though that expression soon fades. "I just hope she wasn't right about this ship being more dangerous than Calypso."
              
              "Calypso is full of humans," you note calmly. "A species far more dangerous than wyverns."
              
              "…be careful out there, ${name_damon}," Damon says, concern and worry back in his voice full-force. "Be careful."
              
              You simply nod in response.
          *if (official_RO = "hadaly")
            #"Hadaly is my girlfriend. I care about her safety just as much as you do."
              *set DamonRel %+ 15
              "Right…" Damon laughs nervously. "I forgot that. Hard to get used to my sister dating someone again, especially after we both got reminded of… the father. She must be really into you."
              
              "She definitely seems like she is," you smirk, but that expression soon fades. "Maybe a bit less now that I pissed her off, though."
              
              "I'm sure she'll let that slide," Damon assures you. "After you've come begging for her forgiveness on hands and knees, that is."
              
              Well that's certainly a thought.
      *if (official_RO = "damon")
        #♡ "I don't, but... could you recompense that with a kiss?"
          "Recompense?" Damon smiles as he takes a step forward and encircles you with his arms. "The pleasure is all mine."
          
          "You're not very creative when it comes to flirting." You respond with a smile of your own. "Luckily, you're also cute. And mine."
          
          And then you kiss. It's not the greatest smooch you've ever had, Damon's lack of experience is still showing and the engines buzz irritably in the background… but it hardly matters. You are about to face your final challenge of the quest, and if you have to bid farewell to the man you love before that last mission…
          
          You'll be damned if you don't do it well.
    *page_break
    *goto cal_ar

*label m-m
The closer to the ship's front you get the clearer it becomes that, indeed, Marshal is arguing about something with Manfred. You expect it will the easiest of all three fights to break up; After all, Manfred @{(ManfredRel <45) may be annoying, but he still |}is an amicable and polite computer program who's likely trying to deescalate already.

"Go fuck yourself, if you're even capable of that with those vestigial wings of yours." Manfred's cheerful voice flows out of the speakers.

"Go throw yourself out, you huge pile of junk code," Renfri retorts, her voice significantly fuller of rage and hate.

"Why so aggressive? I just did what you told me to, like a good AI. You ordered me to, and I quote [i]say that again and-[/i]"

"That was a threat! And sarcasm!"

"Ah, my apologies, I was led astray by the knowledge there's not a single threat you can actually fulfill," Manfred says before… not turning towards you, he still lacks a body, but you can somehow tell he's turning his attention to you now. "Greetings, Veteran. Could you tell Frogmouth here that I am innocent of all wrongdoings she accuses me of?"

*fake_choice
  #"Marshal, know that Manfred is innocent. Also fuck off."
    *set RenfriRel %- 10
    *set ManfredRel %+ 10
    "Oh come on!" Marshal exclaims. 
  #"And what are the accusations, exactly?"
    "I'm not even accusing him!" Marshal replies exasperatedly. 
  #"Frogmouth? Are you really using insults as nicknames now?"
    *set RenfriRel %+ 8
    *set ManfredRel %- 8
    "It's not an insult, strictly speaking," Manfred explains himself. "It's actually a name for a kind of bird currently thought extinct, but which once inhabited the areas of Earth that correspond to-"
    
    "No changing the subject!" Marshal tells the AI before turning towards you. 
  #"Nah, I think I'll leave you two to it."
    *label birdhead
    *set RenfriRel %- 5
    *set ManfredRel %- 5
    "Bye then Veteran!" Manfred says cheerfully before returning . "Anyway, I don't think you considered how light a bird's head must be for efficient flight, a fact that explains your complete lack of-"
    
    At that moment you close the door shut. You have better things to do than serve as a mediator for these two. Well, at this moment you can't do much more than wait… but that's still an improvement from participating in some sibling argument.
    *page_break
    *goto cal_ar
"All I'm trying to do is make sure that none of the malicious or ill-thought ideas he [i]may[/i] have ends up killing the rest of us."

"Funny way of saying you don't trust me, and that you're afraid to leave me alone with the Knight. Which is why you want me to temporarily die, just for your own peace of mind."

"Funny way of saying I want you to enter sleep mode," Marshal retorts. "I took a digital processing course at college, you know. I'm aware you can do that, and it won't bring you any harm."

*fake_choice
  #"Is that true, Manfred? [i]Can[/i] you fall asleep?"
    "It is technically possible, yes," Manfred reluctantly replies. "Redundant, idiotic and a very literal waste of my time… but possible, I suppose."
    
    "Not like you have much to do here anyway," Renfri says irritably, before turning towards you. 
  #"And what could Manfred potentially do, if he were to turn against us?"
    "Basically none," Manfred replies instead of Renfri. "Biocomputers do most things on this ship, annoyingly enough."
    
    "There are some… experimental functions he could plausibly get access to, if left alone with his boredom," Marshal explains, looking at you expectantly. 
  #"I agree with Renfri. You're being dramatic, Manfred."
    *set RenfriRel %+ 10
    *set ManfredRel %- 10
    "Maybe a little," Manfred reluctantly admits. "But you're not taking her side here, are you?"
    
    "It sure sounded like ${pronoun} @{plural are|is}," Renfri says before looking at you. 
  #"Why the mistrust, @{(RenfriRel >= 50) Renfri|Marshal}?"
    *set RenfriRel %- 10
    *set ManfredRel %+ 10
    "She just doesn't particularly care for our kind, Veteran," Manfred replies instead. "Somewhat understandable, given that the human brain runs on fallacies and prejudices."
    
    "If you end up breaking something here, even by accident, then I won't be the only member of the Trio with that prejudice," Renfri returns before turning towards you. 
"Please back me here, ${name}. @{(RenfriRel >45) I know you can understand my worries.|For once in your life.}@{(RenfriRel < 60) |You always do.}"

*fake_choice
  #"@{(RenfriRel >= 50) Renfri|Marshal} is right. Just take a nap, Manfred."
    *set RenfriRel %+ 15
    *set ManfredRel %- 15
    *goto turnoff
  #"Give it a rest, @{(RenfriRel >= 50) Renfri|Marshal}. We're all teammates here, not enemies."
    *set RenfriRel %- 15
    *set ManfredRel %+ 15
    "One does not preclude the other," Marshal rasps. "But if you're enemies, then I suppose I'm outnumbered. So have it your way."
    
    *goto turnon
  *if Social > 50
    #"Renfri... Do you think this argument improves your position in any way?"
      *set ManfredRel %+ 10
      "What do you mean?" Renfri furrows.
      
      "If Manfred ever decides to kill us all, he will probably choose to do it in the middle of space transit," you explain politely. "It makes little sense to be extra careful with him when we're [i]not[/i] on the ship. If anything, you're just daring him to plot his revenge for later whilst really inhibiting him in any way."
      
      "Excellent point, Veteran!" Manfred concurs. "Not that I'm actually planning any vengeance."
      
      "You know, I am aware you're taking his side… but you're right," Marshal sighs in defeat. "Let's leave the AI on while we're away and hope nothing bad comes out of it."
      
      *goto turnon
  #"Nah, you keep arguing. I'm staying out of this."
    *goto birdhead
      
*label turnoff
"Betrayed by my own kind," Manfred emits a sigh. "How tragic."

"We are two completely different beings, Manfred," you say with an eye-roll. "For example, you can go to sleep by executing a single command. Do it."

"I find it unnecessary… but I suppose I will abide by the democratic decision here. Goodnight." With that, Manfred falls silent. Which is the only indication he actually went to sleep, and not exactly a reliable one.

"Can you check if he actually did what he promised?" @{(RenfriRel >= 50) Renfri|Marshal} requests. "Would make me a little calmer."

"I could connect my antenna to the system, but… are you sure my word will change anything?"

@{(RenfriRel >= 50) "I trust you well enough by now," Renfri replies. "And it's not like it will hurt to let you do a quick check."|"Not really," Marshal admits. "But I'd feel stupid if I didn't at least try checking if that thing is actually asleep."}

*fake_choice
  #"Okay then. Give me a decasecond or two."
    *set RenfriRel %+ 10
    Marshal simply nods as you extend your antenna and plug it into the nearest port. You are immediately connected with the main steering biocomputer, but you force yourself to ignore the screaming brain and look for something less physical. It is like searching for grains of sand in a pile of stones, like trying to find an atom of silicon in the core of the Sun… but it is possible, and soon enough you connect with Manfred's binary presence.
    
    He's not sleeping. It is difficult to tell what he's doing exactly, which part of the code is being executed, but it's not the few lines responsible for deactivation. He's trying to fool Marshal, and something tells you he hopes you'll help, knowing you are watching.
    
    You could send him a signal. Or not.
    
    *fake_choice
      #"Yeah, he's sleeping alright."
        *set ManfredRel %+ 20
      #"No foolery, Manfred. Go to sleep like you promised."
        *set ManfredRel %- 15
        "That bastard," Renfri snarls. "Can you force him to actually turn asleep?"
        
        "No, but… he's doing it right now," you say as Manfred turns off, letting go of the processor's limited memory, the last executed command being that of "sleep" from the "time" library. The exact length of his nap seems to match his earlier words too. "Apparently he's given up."
      #Silently tell Manfred to turn off.
        *set ManfredRel %- 8
        You send the string telling Manfred to make good on his promise. You doubt he's happy about that, but he doesn't send anything back. He just turns off, letting go of the processor's limited memory, the last executed command being that of "sleep" from the "time" library. The exact length of his nap seems to match his earlier words too.
        
        "And?" Renfri prompts you when she sees you pull out your stick.
        
        "He's deep asleep," you reply, not specifying when the nap began for Manfred's sake. "You can rest assured he won't try anything in our absence. Or hunt wyverns assured in any case."
    
    "I see," the Kinnari says with some relief. "Thank you. And sorry for making you police your friend like this."
    
    *goto wel
  #"I trust Manfred. He wouldn't lie to us like this."
    *if Social < 50
      *set RenfriRel %- 10
    *set ManfredRel %+ 10
  #"I'm not feeling like digging through Manfred's code, to be honest."
    *set RenfriRel %- 10

"I suppose that's fair," the woman sighs. "The important thing is that we're on the same side. 
*if RenfriRel > 48 
  I don't know if you're backing me because we're @{(official_RO = "renfri") a couple|buddies} or because you care for the mission too, but… 
*if RenfriRel <= 48
  And while I want you to know that this doesn't change anything and that we're still not friends… 
thanks."

*label wel
"You're welcome," you say with a slight smile. "Now get ready for the landing. It may be a bit turbulent without our ship AI to help us."

Marshal does not comment on that last part.

*page_break
*goto cal_ar

*label turnon
"Thank you for seeing reason, Miss Frogmouth," Manfred tells the Kinnari as she leaves the room in frustration. He then turns towards you, or so to speak. "And to you, Veteran, for your support. Though I wouldn't have minded if you tried to get in her good graces by doing otherwise."

*fake_choice
  *if (official_RO = "renfri")
    #"I'm already in her good graces, I believe."
      "Not anymore you're not," Manfred comments cheerfully. "But I'm sure you can earn her forgiveness sometime. After some groveling, of course."
      
      You do not reply.
  *if (official_RO != "renfri")
    #"Are you implying I'm into her?"
      *if ((current_ro = "renfri") or (backup_ro = "renfri"))
        "Are you not? I believe I heard you making moves on her once or twice. In fact, I was considering offering advice…"
        
        "I think I just ruined whatever chances I may have had," you sigh quietly. "So thanks, but maybe don't bother. I'll find someone else, maybe."
        
        "Good luck with that, then," Manfred says cheerfully. "In the meantime, be ready for the landing. We're almost there."
      *if ((current_ro != "renfri") and (backup_ro != "renfri"))
        "I didn't mean that in a sexual or romantic sense," Manfred says chidingly. "I merely figured you may be interested in making allies among the organic part of our group."
        
        *label quipback
        "Like you were just doing?" you quip back.
        
        "Do as I say, not as I do. And besides, I am not the one in danger of being badly injured by a Kinnari with exceptionally strong legs and a laser disc on her forehead."
        
        You cannot deny the wisdom of these words.
  #"It's okay. I don't really care what she thinks of me."
    *set Emotion %- 5
    "Perhaps you shouldn't consider starting to care?" Manfred suggests. "It's not an immediate concern, but perhaps you should consider alleviating her anger in the near future."
    
    *goto quipback
  #"Never. We machines have to stick together."
    *set ManfredRel %+ 10
    *set Misan %+ 5
    "I wouldn't call myself that," Manfred muses loudly. "Machine is a physical system, like you or this ship. I am a digital entity, further from being a machine than even organic beings, who can consider themselves such under some definitions."
    
    "You know you're ruining what could have been a really nice moment?"
    
    "I am aware of that, Veteran. Now get ready for the landing."


*page_break

*goto cal_ar

*label r-l


The passenger room looks as comfy as ever, with its sleek sheets and the wooden coffee table. Given that there is actually a mug of the brown liquid on said table, you imagine it smells pretty nice too. It's just a shame it doesn't [i]sound[/i] half as pleasantly.

"What the fuck is even your problem?" Lisa politely asks Kirill, who is currently shooting daggers at her across the room. "I didn't say I'd pick a fight, or even act all that rude. I just won't be [i]polite[/i] either."

"Well maybe I need you to play nice for once!?" The Trio's leader snaps back. "I need Calypsoans to know that you're… under control. Safe."

"Under control?" Lisa sniggers. "How about you go ahead and put a shock collar on me, then? At least then there'll be a chance for something [i]fun[/i] to come out of this dumb trip."

"I'd consider it, but it would make them think you [i]need[/i] to be restrained. I want them to believe otherwise… even if it means believing falsely." Rook sighs before looking at you, as though only now noticing your presence. "Good to see you, ${fake_name}. I would ask you for support, but I see the battle I'm fighting is futile."

*fake_choice
  #"Could I maybe offer some help anyway?"
    *set RookRel %+ 8
    "I appreciate the offer, but… I am afraid making Hellhound see reason is beyond even your fiendish powers."
  *if (official_RO != "lisa")
    #"Why are you bothering our resident werewolf, exactly?"
      *set LisaRel %+ 6
      *label 1_5
      "I would not say I'm bothering her…" Kirill murmurs. "Just trying to make her see reason."
  *if (official_RO = "lisa")
    #"Tell me why you're bothering my girlfriend. Or else."
      *set LisaRel %+ 12
      *goto 1_5
  #"You're using contractions. Feels weird to hear."
    "My apologies," Rook sighs. "Contractions are considered very rude in my culture. I just cannot help but use them, as my subordinate here refuses to see reason."
  #"What are you twats bickering about?"
    *set RookRel %- 5
    *set LisaRel %- 5
    "I resent that phrasing," Kirill replies. "I am not bickering, merely trying to make Hellhound see reason."

"See reason?!" the werewolf objects. "Don't listen to him, ${name}. He just thinks I'll scare the natives, the ugly monster I am."

"Oh grow up. I just want you to show you mean no harm, and to mind some very basic manners."

"You've just been telling me to stay quiet unless spoken to, keep my eyes lowered, title the queen bitch herself as Great Pandit… Have you considered adjusting your demands yet?"

*fake_choice
  #"I don't understand. Why is it so important that she behaves?"
    *set LisaRel %+ 5
    *set RookRel %- 5
    "Lisa… Hellhound… She has a bit of a history with Calypso," Rook explains. "She went on a rampage here, back when she was unable to control her powers very well. A spree with multiple lethal casualties."
    
    "I mean, it was a long time ago…" If you didn't know better, you'd think Lisa is sounding guilty right now.
    
    "They still remember it. I talked to Da-xia through our radio connection and she certainly does, so you will need to play nice when we meet up with her. Do you agree, ${fake_name}?"
  #"Great Pandit? What kind of honorific is that?"
    *set LisaRel %+ 8
    "The title bore by the twenty-eight members of the Calypsoan ruling council," Rook explains dutifully. "Including one we are likely to meet in half an hour."
    
    "If you think it sounds stupid, you're not alone," Hellhound remarks. "People here are way into their sage-y titles, and Daxia is the most insufferable example of that."
    
    "It's [i]Da-xia[/i]. You know how it is pronounced as well as me."
    
    "But I care far less."
    
    "My point exactly."
  #"Do we really care if some Calypsoans get spooked?"
    *set RookRel %- 8
    *set LisaRel %+ 8
    "I know you may not care about scaring regular people," Rook replies with an eye-roll. "But it is vital that the authorities trust us, and preferably are fond of us too. So if you could please tell @{(official_RO = "lisa") your girlfriend|Lisa} that she should try not to antagonize those powerful and valuable allies of ours, that would be great."
  #"I don't get your point, Kirill. Lisa ain't that scary."
    *set RookRel %- 8
    *set LisaRel %- 8
    *set Confid %+ 8
    "Not to you perhaps, [i]Veteran[/i]," Rook shoots, almost shouts back. "But the people in this habitat are just… people. They will be scared of a werewolf, especially one who butchered some of them a few years back."
    
    "…wait what?" You blink. "What did you just say she did?"
    
    "Not the point! That point being, can you please tell @{(official_RO = "lisa") your girlfriend|her} she should [i]actively try[/i] not to cause panic?"

*fake_choice
  #"Bugger off. Lisa can transform in the middle of the habitat for all I care."
    *set RookRel %- 15
    *set LisaRel %+ 15
    @{(RookRel > 42) "I expected better from you, Veteran."|"Not sure why I expected better from you.}" Rook shakes his head disdainfully. "Such foolishness. I'll leave you two alone, so that you can discuss how you wish to sabotage the mission over morning coffee. Have fun."
    
    @{(RookRel > 42) Krill|Rook} indeed departs, leaving you alone with Lisa, who flashes you a smile the moment her leader is gone.
    
    "@{(Violence > 50) I knew|I didn't know} you'd be fine with me frightening the locals. Thanks for not being stuck-up like some of our fellow wyvern-hunters."
    
    "You're welcome. But please tell me…"
    
    *fake_choice
      #"...what's your story with this place, exactly?"
        "I can tell you what the story's [i]like[/i], if you wish," Lisa says with a grimace. "Grim, gory, and not something I want to talk about right now."
        
        "You mean you're not comfortable sharing right now?"
        
        "I mean there are a lot of people talking and listening all around us. And now the engines are getting louder too, which I guess means we're about to land."
        
        The next few minutes prove the meta-human right.
      #"...you don't actually intend to turn wolf in public, right?"
        "Nah, I won't scare anyone [i]on purpose[/i]. I just don't want to actively show anybody on this moon any respect either."
        
        "You don't want to show anyone respect, huh? Is that normal for you, or are there some concrete reasons for that?"
        
        "You'll see, @{(official_RO = "lisa") honey|android}," Lisa replies with a sudden, strange sadness. "You'll see."
      #"...will Kirill stay mad at me for long?"
        "If this guy held on to grudges, he would have yeeted me out of the airlock long ago," Lisa says assuringly. Kinda. "He'll forgive you. Now let's dress for the upcoming occasion, shall we?"
      #"...how long until the landing? I'm bored."
        "Trust me, I'm bored too," Lisa assures you. "But I don't think the arrival is far off."
        
        And indeed, it only takes a few more moments for engines to roar, heating up in preparation for a difficult maneuver. And you know it will only take a few more minutes for them to fall silent.
      *if (official_RO = "lisa")
        #♡ "Will I get a kiss as a reward?"
          *set LisaRel %+ 10
          "And here I thought you were helping me selflessly," Lisa replies with mock offense. "Turns out you just wanted a smacker."
          
          "And is there any problem with that?" You approach, grabbing your girlfriend by her shoulder and gently pulling her towards you.
          
          "There would be… if I wasn't selfish too. And into you." And with that, she initiates the kiss. As your lips connect with hers you get the strangest sensation of [i]tasting[/i] the woman you've embraced. It's nonsense, you don't really have a sense of taste and can't smell either… but somehow you still feel coffee on the lips, and on your tongue once it briefly touches hers.
          
          You spend a moment like this. Then spend another few moments just standing there, looking at one another, synthetic eyes locked into organic grey. You can tell that Lisa considers taking this further, that she wants it… but there is hardly any time for that.
          
          Your final mission approaches.
      
    *page_break
    *goto cal_ar
  #"Show her some trust, Kirill. I'm sure she'll behave, right Lisa?"
    *set lisa_nice true
    Lisa stares at you for a moment, as though trying to decide whether you're taking her side or not. "If you insist… I suppose I can be quiet and demure. No titles though, and I certainly won't give anyone my apologies."
    
    "I suppose that is good enough," @{(RookRel > 42) Krill|Rook} sighs, with relief instead of frustration for once. "Except you may be forced to answer a question or two, so let us go through the appropriate responses. Thank you for your assistance, ${fake_name}, but could you leave us alone for a moment?"
    
    "Sure thing," you say, heading back towards the door. Getting dismissed like that doesn't feel great, but that's just the price for trying to make the team work together instead of taking sides and escalating conflicts. The voice of reason and compromise is rarely sweet or melodic, and you can't expect people to react very positively to it.
    
    Hopefully your efforts will pay off soon.
    
    *page_break
    *goto cal_ar
  #"If Hellhound tries anything funny, I'll zap her with my lightning."
    *set lisa_nice true
    *set LisaRel %- 8
    *set Violence %+ 8
    "Not the type of support I was hoping for…" Rook sighs. "But I suppose a threat of pain will do, in absence of reason and repentance."
    
    "So I get the shocks but not the collar? Lame." Hellhound stands up and heads for the nearest door. "But fine, I accept your terms. Just be prepared to make good on your threats, should I change my mind."
    
    *label wolf_gone
    Once the werewolf is gone, Rook collapses onto one of the seats. He sighs once again, but this time with relief rather than frustration. "Thank you, Veteran. One more reason you deserve the title, I suppose."
    
    *fake_choice
      #"You know I just did that to piss her off, right?"
        "…in retrospect I should have figured." @{(RookRel > 45) Krill|Rook} somehow deflates even further. "Can I have your promise that you will not try to infuriate anyone whilst in Calypso?"
        
        "No," you reply after a great deal of contemplation. "You cannot."
        
        "Should have figured that one too." He stands up, grabs the mug of coffee and takes a sip from it, as though in hopes it will improve his mood. "Now get ready. We are landing in another quarter at most."
      #"Happy to help, though I think you're overreacting a bit."
        @{(RookRel > 45) Krill|Rook} looks at you skeptically. "Do you think I am overestimating how scared the Calypsoans will be, or underestimating Hellhound's ability to behave?"
        
        *if LisaRel < 42
          "The former. I get that Lisa can be difficult, but surely the people here are used to dangers worse than a leashed werewolf?"
          
          "Sounds like you are not very familiar with the Calypsoan way of life," Rook replies before standing up from his comfy chair. "But that will be amended in just a few moments. We are about to dock, after all."
        *if LisaRel >= 42
          "The latter. I know Lisa can be difficult, but she's quite clever and composed when she wants to."
          
          "And [i]only[/i] when she wants to," Rook replies before standing up from his comfy chair. "I suppose we will find you who is right within the next hour or two. We are about to dock, after all."
      #"You're welcome, but... do you think she'll [i]actually[/i] behave?"
        *set RookRel %+ 8
        "Realistically? No." Kirill sighs. "But if something bad happens, at least I can say I tried to rein her in."
        
        "Well that's unusually defeatist," you point out. "Especially for you. Any reason why you're [i]that[/i] pessimistic about our chances?"
        
        "You will see in time," Kirill simply replies. "And not that long of a time. We are about to land."
      *if (official_RO != "kirill")
        #♡ "Anything for the most handsome meta-human on the ship."
          *if Social > 50
            *set RookRel %+ 10
          *if current_ro != "kirill"
            *set backup_RO current_RO
            *set current_RO "kirill"
          *set hit_on_kirill true
          "Thank you very much…" @{(RookRel > 45) Krill|Rook} frowns. "Wait, am I not the only meta-human here who can be considered handsome? I think my teammates would be [i]pretty[/i], being women and all."
          
          "I keep my compliments honest," you joke. "But I'll oblige if you want me to call you the [i]prettiest[/i] person around. Anything for you, like I just said."
          
          "Good to know, I suppose." His frown turns to smile, but this new expression is short-lived too. Kirill's face becomes serious and almost blank as he turns towards the cockpit. "Now get ready. We are landing in another quarter at most." 
      *if (official_RO = "kirill")
        #♡ "Do I get a reward for helping you out?"
          "I do not think it's entirely ethical of me to offer such rewards," Kirill muses loudly. "We are already fraternizing. No point making our dynamic any stranger."
          
          "Makes sense." You step a bit closer. "How about you just kiss me for no reason, then?"
          
          "I can agree to that." Kirill's lips twist in a smile, just before touching yours as the distance between you is reduced to zero. It's a small kiss, a peck, something done with just a bit of interest and passion.
          
          If this was anyone else embracing you, perhaps you'd feel offended. But you know Kirill, you know the responsibility he bears, and you're now aware of yet another one of his worries. It's difficult to blame him for being distracted; The mission is important, perhaps more for him than anyone else on the ship.
          
          Still… he could make better use of his tongue sometime.
    *page_break
    *goto cal_ar
  #"Agreed. Lisa, can you promise you'll be an adult for once?"
    *set lisa_nice true
    *set RookRel %+ 15
    *set LisaRel %- 15
    Hellhound looks at you with distaste that borders on hatred, but she can recognize when she's outnumbered. @{((Emotion > 50) or (Violence > 50)) And she knows you're not quite as patient as her leader. |}"You know what? Fine, I'll be as demure and self-abasing as you'd like. My dignity is a fair price for getting the two of you pricks off my back."
    
    "Thank you for the understanding," Rook replies, not really minding the insult. "If we get through this outing without you offending or scaring anyone, I'll pay you your monthly wage as a bonus."
    
    "So like a tenth of an axion?" Lisa stands up and heads for the nearest door. "Better that than nothing, I guess. Bye."
    
    *goto wolf_gone
  #"You're the leader, Rook. You do it yourself."
    "Right. Apologies." @{(RookRel >= 50) Krill|Rook} sighs, before turning back towards his subordinate. "Anyway, they have heavy ordnance on Calypso, so if you do anything stupid…"
    
    At that moment you close the door shut, having just walked through it. You have better things to do than serve as a councilor for these two. 
    
    …well, at this moment you can't do much more than wait… but that's still an improvement from participating in some human argument. At least you are [i]somewhat[/i] closer to being in silence that way.
    *page_break
    *goto cal_ar

*label cal_ar
*set met_daxia true
The process of landing inside a habitat is rarely easy. The Calypsoan authorities know you approach and are at least vaguely on your side, which removes the need for authorization (or fire exchanges), but you still need to carefully slow down to avoid crashing into Calypso instead of entering it. With 'slow down' being a shorthand for adjusting one's velocity and direction to match the moon's orbit right before spinning the ship so that it matches the habitat's angular velocity too.

Eventually you manage that and pass through the dark matter veil separating the habitat from outer space. It looks like flying through solid shadows and feels like it too, in some ill-defined way, but you know it's a normal part of entering a rotating habitat. It's really not different from entering a Hollow World through a gate, it's just that clarketech involved is slightly less impressive and impossible.

After that, actually landing is an easy task. Rook even insists on doing this personally, reasoning that it would be suspicious for the ship to move with computer-like precision that Manfred would provide. @{manfred_sleep Not that Manfred can steer, being asleep and all. |}The meta-human manages to land efficiently enough, on a designated patch of land where the welcoming committee is set to arrive in another minute or two.

By then it's just a matter of actually departing the ship. The Meta Trio walks down the ramp first, Rook and Marshal marching side by side in their polished military uniforms. Hellhound doesn't have any clothing like that, but she somehow dug up a fresh pair of jeans and an unstained blouse that doesn't look half bad on her. @{hadaly_goes Even Hadaly is all dressed up, which in her case meant putting on a fresh new jumpsuit. It's vibrant green, matching the current color of her eyes, which implies a level of thought your mechanic rarely puts into her appearance.|}

As for you, you decided to wear…

*fake_choice
  #...a suit of light armor Kirill had lying around, just in case Calypsoans start shooting.
    *set c_clothing 1
    *set DaxiaRel %- 10
    *set DamonRel %+ 10
    The flak armor suit won't do anything against Crystal or heavy ordnance, but will offer some extra protection in case someone tries to gun you down with small arms. You're not sure why anyone on Calypso would try that, but you've heard the moon's denizens are weirdos, and it's better to be safe than sorry.
  #...shirt, @{(sex = "woman") skirt|shorts}, socks, shoes. No point getting fancy.
    *set c_clothing 2
    You won't try to impress the rulers of Calypso, who are no doubt wealthier than your bunch of lowly soldiers and outcasts anyway. Might as well put on something comfortable.
  #...an elegant ${clothing}, identical to the one I wore in Rhea.
    *set DaxiaRel %+ 10
    *set LisaRel %- 10
    *set RookRel %+ 10
    *set c_clothing 3
    You're not really trying to impress the rulers of Calypso, who are no doubt wealthier than your bunch of lowly soldiers and outcasts. You're not even here in any official capacity, really. But if the metas want to get all dressed up, then goddamn you'll show them how it's done.
  #...nothing.
    *set c_clothing 4
    *set RookRel %- 10
    *set RenfriRel %- 10
    *set LisaRel %+ 10
    *set DaxiaRel %+ 10
    *set armored true
    Of course, @{(RenfriRel >= 50) Renfri|Marshal} rather quickly vetoed your choice and told you to cover yourself, as well as to 'stop acting like a drunk teen' for once. You responded by throwing your clothes out of the airlock, at which point a compromise was reached and you ended up wrapping a blanket around your waist. Something tells you breaking that truce right now will not end well for you, and so the loincloth is there to stay.

Though everyone on your team is certainly pretty, that beauty pales in comparison to the splendor of the habitat itself. From space, Calypso looks like just another oblong rock, with some bits of metal and synthetic materials sticking out of it. One would be forgiven for not guessing there's a cylinder inside. But as you walk [i]inside[/i] the moon…

The curved, sprawling landscape stretches kilometers above you, with no clouds to obscure the view. From the perspective of people you can just barely see scurrying about on the other side of the cylinder, you are the one high above, for the centrifugal force pulls everyone to the ground all the same. There is no gravity, not even that which flows from a World Engine like on Rhea, just the invisible spin of the titan's daughter. And unlike in Rhea, where the artificial sun and sheer distance turn the other side of the world into a grey ceiling, the full scope of the world is yours to observe the moment you step onto Calypsoan soil.

You are not new to such sights, of course. Rotating habitats are common throughout the Solar System, dozens of them to be found within the Federation alone. It is the interior design that truly distinguishes this one, with fields and orchards neatly separated by marble paths, all lightly illuminated by the union of street lanterns and the planet of Saturn, the latter visible through the opening behind you. It makes the whole habitat look like a garden at twilight, a world forever full of shadows, yet made all the more enchanting by it.

In comparison, even the delegation of some dozen people that meets you in the meadow's middle looks mundane, despite their colorful robes and diverse appearances. But you focus on them all the same, knowing it's wise to pay attention.

*page_break

The first thing you notice @{(Confid < 50) (not without relief) |}is that the welcoming party wouldn't pose much threat even if they were to turn hostile. Because while every other armed figure does appear armed, they are just humans outfitted with simple handguns and paralyzers. You wonder why they even bothered to bring weapons, but whatever makes them feel safer, you suppose.

You also notice there must be some type of… maybe not hierarchy, but specialization signaled by the type and color of robes everyone wears. The armed men are all dressed in red, their knee-length shirts apparently acting as a uniform of some sorts. The remaining humans wear robes of somewhat varying colors and cuts, but they are all… subdued in an ill-defined way. You get the impression that they are here as servants, assistants, aides perhaps. A redundant part of the procession, being mostly here for ceremony's sake.

With one exception. There is a woman in a sleek, vibrant-yellow tunic, whose confident step and posture strongly imply her to be the leader of the group, perhaps one of the leaders of Calypso in general. She is bald, dark-eyed, with skin 
*if skin = "pale"
  only a bit tanner than yours.
*if skin = "fair"
  of a shade similar to yours.
*if (((skin = "olive") or (skin = "brown")) or (skin = "black"))
  a few shades lighter than yours.
*if ((skin = "green") or (skin = "blue"))
  similar to Lisa's in terms of shade.

Her age is indeterminate; She looks like she's pushing forty, but you suspect quite a few rejuvenating operations were performed on her, given her status and the vaguely unnatural quality of her features. She may be well into her second century in this world, for all you know.

"Be welcomed in the Calypsoan Concord, warriors of the Federation," she says with a small bow, her voice at once formal and positively relaxed. "I am Da-xia, one of our moon's Great Pandits. The Council elected me to greet you, inform you of the rules you are to follow, and answer your inquiries should you have any."

Before speaking, both Rook and Marshal bow slightly. @{hadaly_goes Hadaly follows suit. |}@{lisa_nice Even Lisa performs a nod, proving she was honest about intending to play nice.|Lisa does not, but you suppose that's to be expected of her.} You wonder if you should imitate the more well-mannered part of your group and show the Pandit some respect as well.

*temp word "bold"
*temp bowed true
*temp spat false
*fake_choice
  *if Confid > 50
    #Spit Da-xia in the face.
      *set Confid %+ 20
      *set bowed false
      *set spat true
      *set LisaRel %+ 15
      *if LisaRel > 50
        *set LisaRel %+ 15
      *set RookRel %- 15
      *set RenfriRel %- 15
      *set rook_pissed true
      It takes a while, since there isn't actually any saliva in your mouth, but you manage to gather a few drops of coolant and spit them out. They all land on Da-xia's face, which then twists in disgust and surprise. Mostly surprise, for better or worse.
      
      "What are you doing?!" Rook appears surprised too. And angry. "We're supposed to… I apologize for my subordinate, Pandit Da-xia, ${pronoun}@{plural 's|'re} just… special."
      
      "I agree with that assessment," Da-xia says, calmly wiping the dense coolant off her face as her servants watch the scene in terror. If she somehow didn't know you were an android before, she sure as hell does now. "${name}, is it not? What were you hoping to accomplish by spitting on my face? Why did you do it?"
      
      *fake_choice
        #"I wanted to see what would happen."
          "I cannot say I approve of such disrespect… but I do understand your curiosity," Da-xia says with a subdued smile. "It speaks of seeing life as a game and being willing to experiment with the mechanics. Just like you, if my intelligence regarding your person is correct."
        #"I was hoping to start a fight."
          *set Violence %+ 20
          *if Violence > 55
            *set word "violent"
          *if Violence <= 55
            *set word "out-of-character"
          *goto nore
        #"It was to show you what I think of your kind."
          *set Misan %+ 20
          If you expected Da-xia to be surprised or offended, you are disappointed. She remains calm, only her curiosity has perhaps increased. "But of course. @{(Misan >= 60) You are an android, and one quite resentful of your creators at that. Silly of me to have even asked.|I heard you are quite fond of humans for an android, but I suppose my intelligence was incorrect. Apologies.}"
        #"No reason."
          *label nore
          *set DaxiaRel - 5
          "But of course," Da-xia rolls her eyes. "I've heard you are prone to ${word} decisions with little reasoning behind them. I was just hoping my intelligence was mistaken."
  #Just stand there.
    *set bowed false
    *set Confid %+ 10
    *set DaxiaRel - 5
    *set RookRel %- 10
    *if LisaRel > 50
      *set LisaRel %+ 15
    *goto plia
  #Bow slightly like the others.
    *set Confid %- 10
    *label plia
    Rook spares you a glance, @{bowed nods with approval|shakes his head with disapproval}, then turns back towards Da-xia. "We are honored you came to meet us, Great Pandit. We scarcely deserve such attention."
    
    "Please drop the false humility, Sergeant Kosteniuk." The woman quickly eyes up all members of your team, though she lingers on you for a while. "You are all capable combatants, as well as interesting individuals. Especially the android over there."
  #Genuflect, bending a single knee to the ground.
    *set DaxiaRel %+ 10
    *set Confid %- 10
    *if LisaRel < 50
      *set LisaRel %- 15
    "Why so formal, ${name}?" Da-xia asks amusedly. "I do not demand such self-abjection, and I never thought you were prone to it."
  *selectable_if (Misan <= 45) #Go down on your hands and knees, in honor of your human overlords.
    *set DaxiaRel %+ 20
    *set Misan %- 20
    You imagine the others are confused, perhaps embarrassed by your display of self-abasement. You can't be sure, your eyes are aimed straight at the dirt on which you kneel.
    
    "Great Pandit Da-xia, or however you wish to be titled," you say ceremoniously. "I am here to serve you and your people alike. Protect you from a vile fiend known as Crystal. I will kill and die at your order, for I am just a tool for humanity to command."
    
    "If anyone else said something like this, I would have recommended our local therapist," Da-xia says calmly. "But I've heard enough about you to know that this behavior is to be considered normal, and that you may even enjoy such… displays."

"You've heard of me," you state, wondering just how poorly the Federation guards its classified data… or perhaps how poor your [i]${fake_name}[/i] disguise was. "What exactly do you know?"

*if money_stolen = (0-3)
  "You kicked the High Executive of the Rhea Conglomerate in the balls," Da-xia replies right away. "It's a rare achievement I have utmost respect for. 
*if (((money_stolen = (0-2)) or (money_stolen = (0-1))) or (money_stolen = 0))
  "You made an honest attempt to steal from the Rhea Conglomerate, and caused quite a bit of panic in Sholmo City afterwards. It's the kind of effort I most appreciate. 
*if money_stolen > 1
   "You successfully stole from the Rhea Conglomerate itself," Da-xia replies with a wicked grin. "Not many manage that, and those who do earn my utmost attention and gratitude. 
You're by far the most interesting member of this team."

*fake_choice
  *if spat
    #Spit her in the face again.
      *set LisaRel %+ 15
      *set RookRel %- 20
      *set RenfriRel %- 20
      *if LisaRel > 60
        *set LisaRel %+ 15
      *set DaxiaRel - 5
      This time, it's a droplet of oil that hits Da-xia's face. She still doesn't look [i]angry[/i], but is definitely less than impressed. "You know, this kind of audacity was funny a few moments ago. Less so now that you know you can get away with it."
      
      "I still find it pretty funny," Lisa announces. @{lisa_nice "Agree to disagree, I suppose."|"Then again, it's mostly because you're the target, Great Pandit."}
  #"Are you enemies of the Conglomerate? Or do you dislike Rheans in general?"
    Da-xia winces. "The former. We are ideologically opposed to the evils of plutocracy, and the villainy of High Executives in particular. I don't think I need to explain why."
    
    "It's not just ideological though, is it?" @{(LisaRel >= 50) Lisa|Hellhound} suddenly points out. "You and that megacorp have a long history of sabotaging one another, vying for power within the Federation. The less stable Rhea gets, the stronger your influence becomes."
  #"Thank you, but I'm really not."
    *set Confid %- 10
    "Such humility… such modesty." The Great Pandit smiles. "That only makes you more interesting, to me at least."
      
    "Are you sure you don't find [i]me[/i] the most interesting person around?" @{(LisaRel >= 50) Lisa|Hellhound} chimes in. @{lisa_nice |"I know for a fact you find me the scariest one."}
  #"Could you please avoid using my... personal name?"
    "Are you worried it will compromise your identity as ${fake_name}? Do not worry, everyone here is capable of keeping secrets, and I don't want any of yours getting out. I was merely being friendly."
    
    "I think ${pronoun} @{plural knows|know} what you meant," Lisa cuts in. "$!{pronoun}@{plural 's|'re} just not comfortable with you getting [i]friendly[/i] like that."
  #♡ "Would you say I'm also the prettiest one?"
    *set DaxiaRel %+ 10
    *if Social > 50
      *set DaxiaRel %+ 15
    *if (current_RO = "hadaly") or (backup_RO = "hadaly")
      *set HadalyRel %- 15
    *if (current_RO = "kirill") or (backup_RO = "kirill")
      *set RookRel %- 15
    *if (current_RO = "lisa") or (backup_RO = "lisa")
      *set LisaRel %- 25
      *set lisa_pissed true
    *set backup_RO current_RO
    *set current_RO "da-xia"
    *if (((Social+DaxiaRel)+10) >= daxia_target)
      "Beauty is in the eye of the beholder," Da-xia says courtly. "Although I admit, there is plenty of your beauty in my eyes."
      
      "No one told me I'd have to watch @{lisa_nice other people|old pricks} flirt," @{(LisaRel >= 50) Lisa|Hellhound} cuts in. "I seriously consider demanding a raise right now."
    *if (((Social+DaxiaRel)+10) < daxia_target)
      "Not necessarily," Da-xia says with a rueful smile. "Being fascinating and being… my type are two different things, I'm afraid."
      
      "And thank the Sun for that," @{(LisaRel >= 50) Lisa|Hellhound} cuts in. "I don't think I could bear standing here and watching @{lisa_nice the two of you|some old pricks} flirt."
  #"I don't appreciate being... researched like this."
    "Do you believe it an affront to your privacy?" Da-xia raises an eyebrow. "Apologies, but I simply needed to know the exact composition of your group, as well as how it is managed. Out of concern for my people's safety, if nothing else."
    
    "She needed to know if I'm kept on a leash short enough," Lisa helpfully explains. "I don't think she's nearly as afraid of you, ${name}, for better or worse."

"Ah yes, the [i]other[/i] fascinating member of your group." Da-xia shoots the werewolf a quick, disdainful glare, before turning in Rook's direction. "Hardly someone I've been yearning to see again. I trust the charge was implemented properly and your finger's on the trigger?"

"Not literally…" Kirill replies, looking and sounding quite uncomfortable all of the sudden. "But I have the detonation sequence saved in my suit's memory, and the means to emit the signal at almost any moment. Not that I believe it will ever be necessary."

*if Database <= 50
  "What are the two of you talking about?" you ask, even though you have your suspicions.
  
  "As I informed the Pandits earlier today, we have… inserted a small explosive into our werewolf friend. Just enough to kill her, and just her, in case I am ever forced to activate it. As an incentive to… follow the rules, you see."
  
  "A bomb in the heart as a method of control?" @{hadaly_goes Hadaly says|you say} disdainfully. "Isn't that a bit… crude?"
*if Database > 50
  You are about to ask what these two are talking about, but then you figure it out. 
  *if LisaRel > 45
    And don't particularly like it. "You put a bomb inside @{(official_RO = "lisa") my girlfriend|Lisa}'s heart? Seriously?"
  *if LisaRel <= 45
    You understand. "Clever. I was wondering why our werewolf friend even sticks around, but a bomb inside one's head is an excellent motivator."

"It is a measure of last resort which we will likely never make use of," Rook argues half-heartedly. "Also, do not jump to assumptions. The bomb was implanted in the [i]heart[/i], not the head."

"I can confirm it was indeed the heart," Lisa says with a nod. And a frown. "I was conscious during the surgery, you know. Wasn't much anesthetic to go around."
  
*fake_choice
  *if Misan > 50
    #"Every time I think my level of contempt for the Federation is adequate, you humans manage to surprise me."
      *set Misan %+ 20
      *set RookRel %- 8
      *set LisaRel %+ 12
      *goto neces
  #♡ "Crap. You need a hug, Lisa?"
    *set LisaRel %+ 6
    *if current_ro != "lisa"
      *set backup_RO current_RO
      *set current_RO "lisa"
    "You can save your hugs for later," the werewolf shrugs. "There are more important things on everyone's minds."
  #"Good. Nothing but a threat of instant death will make that beast obey our orders."
    *set DaxiaRel %+ 12
    *set LisaRel %- 12
    *set RenfriRel %- 8
    *set Violence %+ 6
  #"Kirill, does anyone else have the sequence? Otherwise Hellhound could just kill you and remove the threat."
    *set LisaRel %- 8
    *set DaxiaRel %+ 8
  #"This is stupid. Do you really need to threaten your teammates with [i]death[/i] to make them follow you?"
    *set RenfriRel %+ 8
    *set DaxiaRel %- 8
    *label neces
    *set RookRel %- 8
    "This is a matter of necessity," Kirill insists. "No offense to our werewolf companion, but she is nothing like you or me. Without that threat she would just run off, to do God only knows what."
  #"Sounds dangerous. What if the bomb goes off prematurely?"
    *set LisaRel %+ 8
    "The chance of that is minuscule," Kirill assures you. "The Federation would not be around if its munitions exploded at random."
    
    "That's true, they normally only explode once they've hit a major population center," Marshal agrees. "Immaculate craftsmanship."
    
    "My point!" Rook says with sudden loudness. "Is that in this specific case, the explosive is both safe and necessary."

"Well said." Da-xia spares another glance for Lisa, who is thankfully unbothered by the situation. Or pretending to. "That's why I have a request to make, in exchange for my help. Give the relevant code and tell me on what frequency I should transmit it, just in case Miss Herbert goes rabid when you're not around to stop her."

Everyone takes a second to process this request.

"Kirill… you're not thinking about this, right?" @{(RenfriRel >= 50) Renfri|Marshal} asks tensely. "We are a team, after all. We're not giving some… eccentric ideologue the power to just kill one of us at any moment?"

"Sergeant Kosteniuk, tell your pet Kinnari to stay out of such important matters. And tell me what the detonation sequence is."

*fake_choice
  #"You're not getting that code, Pandit."
    *set DaxiaRel %- 15
    *set RenfriRel %+ 10
    *set LisaRel %+ 10
    *set RookRel %- 5
    "With all due respect, android, I wasn't asking [i]you[/i]," Da-xia says dismissively. "Your answer, Sergeant."
  *if official_ro = "lisa"
    #♡ "You know you're threatening my girlfriend here?"
      *set LisaRel %+ 15
      *set DaxiaRel %- 15
      Renfri pouts, likely dying inside. Jealousy can do that to a person, you suppose.
      
      "You and her? My condolences," Da-xia says briefly, contemptuously. Then turns back towards Kirill. "Your answer, Sergeant."
  #"Don't insult my teammates like this. Ever."
    *set RenfriRel %+ 10
    *set LisaRel %+ 5
    *set RookRel %- 5
    *set DaxiaRel %- 10
    "My most sincere apologies," Da-xia says insincerely. "Now, Sergeant Kosteniuk, will you humor my request?"
  *if (official_ro = "renfri")
    #♡ "Excuse me, it's [i]my[/i] pet Kinnari.
      "You know, that's not how I pictured our relationship myself," Renfri says with 
      *if Social > 60
        a smirk. 
        *set RenfriRel %+ 12
      *elseif Social < 40
        *set RenfriRel %- 12
        a frown. 
      *else
        an eye-roll. 
      "But I love you, so I'll let that slide."
      
      "Wait, the two of you got together?" Lisa perks up. "Should have told me. Me and the hedgehog guy would totally have baked a cake to celebrate."
      
      "You're adorable and all, but I need my question answered," Da-xia says irritably. "Will I get a tool to defend my people from this werewolf or not?"
  #"Come on Rook, she deserves to know the code."
    *set RenfriRel %- 8
    *set LisaRel %- 8
    *set DaxiaRel %+ 10
    "By the Emperor…" Renfri sighs. "Am I the only person here who doesn't want my teammates blown up?"
    
    Lisa snorts. "If that helps, I'm not enthusiastic about it either. But if our leader thinks otherwise…"
  #Wait for Kirill to make the choice.
    *set RookRel %+ 8

"I will give you the sequence, Great Pandit," Kirill says after a moment of deliberation. "But only indoors. When we are alone, and preferably somewhere from where the signal cannot escape. To avoid unfortunate accidents, you see."

"Such concern for my well-being," Lisa comments. "My expectations for you have truly been shattered."

"Let us converse in some quiet place, then." Da-xia appears annoyed by the chatter, but satisfied she got what she wanted. "Your men, or women to be more accurate, are welcome to go deeper into the habitat. Relax in the town if they choose to, or start working in whatever way you had planned."

"Right. Planned…" Rook scratches his head before turning towards you. "${fake_name}. Just as planned, I want you to search the town and its outskirts for anything @{telesto_complete that might contain nanites|suspicious or particularly valuable}. Though our plan is still to wait until Crystal attacks again, knowing where they will strike should help. 
*if telesto_complete
  We know they probably want to absorb more Dusk nanobots, but whether any of those are actually here is… up for debate."
  
  "So that is your current theory?" Da-xia muses. "Sounds far-fetched, but if you can find any traces of the [i]Thing Beneath[/i] in my habitat, you will be most certainly rewarded. 
*if not (telesto_complete)
  I still doubt they just want to cause pain and terror."
  
  "That's our best idea for why this beast keeps returning." Da-xia winces. "But you are welcome to investigate all the same. 
You are also welcome to discuss things with our military leadership in the command center, if you want details from them."

*fake_choice
  #"Okay, I'll do my best."
    *set RookRel %+ 10
    *set LisaRel %- 5
    *set HadalyRel %- 5
    *set Confid %- 10
    "That is all I am asking for," Rook says with a smile. "As for the rest of you… I do not think you can help ${fake_name} much. Keep your eyes open when in the town, but otherwise you can do whatever you want."
  *if (RookRel < 40) or (official_ro = "lisa")
    #"Kirill, have I ever told you you suck as a leader?"
      *set RookRel %- 13
      *set rook_pissed true
      "I think you mentioned that once or twice." Rook winces. "If you think the search is pointless, that is fine I suppose. You can do something else until I am back, all of you."
  *if telesto_complete
    #"And how exactly do I find those Dusk nanobots?"
      "I have absolutely no idea," Rook admits freely. "But you heard the Shriek those centuries ago, and then more recently on Telesto. Just look for places where this sound is louder than the regular echoes, so that we may later search that location for any strange or suspicious items." 
      
      *label girlsw
      "I don't think it works that way, but sure." You sigh, knowing there's no point arguing. And that you can just ignore Rook's instructions once he's departed to go sightseeing or something. Thinking of… "What about you, girls? You can't really help me on my search, so what do you plan on doing?"
  #"Sounds like a wild goose chase, to be honest. Except I don't know what goose I'm looking for."
    *if telesto_complete
      "I mean, you [i]have[/i] heard the Shriek all these centuries ago, and then more recently on Telesto," Rook argues, bringing up some bad memories while he's at it. "Just look for places where this sound is louder than the regular echoes, so that we may later search that location for any strange or suspicious items."
      
      *goto girlsw
    *if not (telesto_complete)
      "Any goose that catches your eye," Rook replies casually. "Anything that interest you may well interest another fiend, making it a potential target for Crystal's next attack."
      
      *goto girlsw
  *if official_ro = ""
    #♡ "Hey Kirill... Would you like to grab some coffee once we're done?"
      *if current_ro != "kirill"
        *set backup_RO current_RO
        *set current_RO "kirill"
      "I am not entirely sure if they sell any coffee around here," @{(RookRel >= 50) Krill|Rook} says worriedly. "And I [i]am[/i] fairly sure androids can consume such drinks."
      
      You pout. Lisa groans. Da-xia and Renfri both roll their eyes at once, as though they're also annoyed by @{(RookRel >= 50) Krill|Rook}'s sheer density.
      
      *if RookRel >= 50
        To his credit, Kirill realizes his mistake at that instant. "I mean… That is actually not a terrible idea. We could get to know another better over some cups of coffee. I just need to finish the negotiations first."
      *else
        "Yes, I understand this was an invitation for a date, I am not hopelessly stupid," Rook clarifies. "I simply am not interested at the moment. Sorry."
        
        "Oh." You pout even more deeply. "That's fair, I guess. So… what will others be doing?"
  *if official_ro = "kirill"
    #♡ "What will you do later, Kirill? Will there be any time for... us?"
      "There will most certainly be," Kirill reassures you. "Duty calls, but I shall not neglect my 
      *if pronoun = "he"
        boyfriend 
      *elseif pronoun = "she"
        girlfriend 
      *else
        partner 
      like this."
      
      Lisa rolls her eyes. "I should have known the two of you would get together. Your age rating is similar, as does your tolerance for fun."
  #"Shouldn't we discuss this [i]bomb in the heart[/i] thing some further?"
    *set RookRel %- 10
    *set LisaRel %+ 10
    *set DaxiaRel %- 5
    *set RenfriRel %+ 5
    "Don't bother," Lisa says tiredly. "It's not like Kirill will compromise the mission just for the sake of my safety, or anything stupid like that."
    
    "That is not the way I would put it…" Rook says. Then pauses. Then coughs. "Anyway… what do the rest of you intend to do while me and ${fake_name} are busy?"
  #"Okay... what will the rest of the gang be doing?"

"I think I'll do a quick air patrol of the area and then… maybe grab something to eat," Marshal announces. "This place has discounts for military personnel, right?"

*if hadaly_goes
  "It said so on the tourist pamphlet I dug out," Hadaly says, her voice suddenly turning dreamy. "An actual tourist spot in this day and age… I think I'll go and see the shrines. Maybe even the Rational Temple itself…"  

"Hope you have fun there," Lisa says, her words dubiously honest. "I will… I think I'll return to the ship. Left something important there, you see."

"I wouldn't mind if you stayed on that ship, to be perfectly honest," Da-xia says before turning away. "Follow me to my mansion, Sergeant Kosteniuk. As for the rest of you, I hope you enjoy your stay, and invite you to visit me later should you see any reason to. Use our community housing, if you're tired of sleeping in your small ship, or visit the library if you wish to grow wiser. It's all there at your disposal."

The team then disperses, Rook following Da-xia and her servants, whilst the others all go their own ways. @{(LisaRel >= 50) Lisa|Hellhound} re-enters [i]Gray Queen[/i]@{hadaly_goes , Hadaly marches off towards the town|} and Marshal takes off for the sky… if you can speak of skies in a habitat like this. You are left in the meadow, thinking about…

*comment Wes Scott
*fake_choice
  #...how difficult it will be to get anything done here.
    *set Confid %- 10
    Thanks to the absence of any real plan, it's hard to even think of anything useful to do. @{(Database > 50) Even for your low-key brilliant mind.|Perhaps not impossible... but hard.}
  #...how Crystal could attack any moment now.
    Based on the wyvern's history with this moon, there is little to stop it from just flying in again, and your presence here doesn't feel like enough to make a difference. You just hope it's not [i]already[/i] inside the habitat somehow, cause that would complicate the matters greatly, to say the absolute least.
  #...how much I want to punch Rook in the face.
    *set Emotion %+ 10
    @{(RookRel > 50) You like that guy on general basis|You never expected much of that clown}, but now that he left the whole team with barely any directions just so he could give some newly-met woman the codes for… no, you need to focus on the situation at hand. You'll have the chance to chew Rook out later.
  #...what to do next.
    *set Emotion %- 10
    You need to focus on the mission, that much you know. Where that focus should be focused, however… that's a harder question.
  #...Da-xia. She's certainly an interesting person.
    You're not entirely sure what kind of interest the Great Pandit evoked in you… but you're sure you can figure that out later. Maybe by visiting her once she's done with Kirill.

You don't imagine there are many benefits to standing around, and so you think through your options. You could start gathering information, talk to some important people… or @{hadaly_goes take a page out of Hadaly's book and |maybe} just stroll around.

*temp location 4
*temp talk_done false
*label choice_hub
*set location 4
*choice
  *disable_reuse #I will head for the command center and talk with the military staff.
    *set battery - 5
    *set talk_done true
    *set visited_scott true
    *goto command_date
  *disable_reuse #I'll chase after Lisa. See how she's doing.
    *set battery - 5
    *goto hound_date
  *if hadaly_goes
    *disable_reuse #I'll see what Hadaly is up to.
      *set talk_done true
      *set battery - 5
      *goto hadaly_date
  *if talk_done
    *disable_reuse #I will look for Marshal in the town, in case she landed already.
      *set battery - 5
      *goto renfri_date
    *disable_reuse #I shall visit Da-xia in her mansion.
      *set battery - 5
      *set location 3
      *goto daxia_date
  *disable_reuse #I will walk around the town, hoping to spot something suspicious or interesting.
    *set talk_done true
    *set battery - 5
    *goto patrol
  *disable_reuse #I will search beyond the down. Check out their fields, or whatever else they have.
    *set talk_done true
    *set battery - 5
    *goto homeless
  *disable_reuse #I will visit the library. I haven't been to one of these in literal ages.
    *set talk_done true
    *goto library
  *disable_reuse #I'll see what the whole 'community housing' thing is about.
    *set location 2
    *set battery - 5
    *set talk_done true
    *goto housing
  #I'll return to the spaceship and go to sleep.
    *if not (talk_done)
      *set rook_pissed true
      *set RookRel %- 15
      *set RenfriRel %- 15
      *set ArmyRel %- 15
      *set location 1
    Okay, you can't really 'go to sleep' or even do anything roughly equivalent without a charging capsule. But you can enjoy the silence that fills [i]Gray Queen[/i] now and take some sweet time to sort your thoughts into appropriate arrays. @{talk_done You can't think of any other useful thing to do, not until Crystal shows up out of their own volition.|You don't feel like doing anything to advance the mission, to be perfectly honest.}
    
    Halfway through your march towards the ship, you hear something, but not an actual sound from the @{location meadow|||town} you traverse. It's [i]the[/i] sound, the shriek coming from inside of you, heralding that another flashback is about to occur.
    
    *fake_choice
      #No... please no...
        *set Emotion %+ 10
        Your fear of the memory that haunts you is great, and it gets even stronger as the sound grows louder. For it soon becomes clear that more than an ordinary flashback approaches.
      #I should call Damon or Hadaly. They'll help me, I'm sure of that.
        *set deflect - 1
        You try to reach your fellow androids through the mind-link you used in Rhea, but to no avail. You suppose it makes sense; The channel was calibrated so that it would work inside a Hollow World and in the vacuum of space, not a relatively small rotating habitat such as this one. There's probably too much of an echo to clearly communicate with anyone through precise radio waves.
        
        Though the longer you listen to the sound… the more certain you are that there's another reason in play.
      #Strange. They usually don't come so suddenly.
        *set Emotion %- 10
        Your surprise and curiosity are even greater than your fear. And they are stronger yet once you realize… it's not another flashback that approaches you.
      *if progress = 5
        #So soon after the last one? Damn...
          After Rhea and the war flashback back on [i]Saturn Nine[/i], you didn't expect any more memories to resurface during your stay in Calypso. And as it soon turns out… you were right.
    
    That [b]Scream[/b] you hear is too loud, too real to be coming from the distant past. It is something of the present, and it gets stronger not because the memory gets brought forward. The source of the [b]Cry[/b] is physically getting closer to you… a realization that induces a far more ordinary, more real kind of fear.
    
    Crystal has arrived.
    
    And then, before you can do anything else, your body falls to the ground. The last thing you see before the spirit falls into darkness is the air shimmering high above, an invisible thing entering the habitat.
    
    *page_break Sleep
    
    Sleep. That's how it feels. It's not actually sleep, but maybe that's for the better. There are no dreams, no nightmares, except perhaps a vague recollection of writhing on the floor of your @{MASsex master's|mistress'} apartment. The memory is unpleasant, and so you stand up.
    
    Then realize where you are, and push all the distant memories aside. You have current problems to deal with.
    
    *if location = 1
      You are still standing on the same patch of grass as before, but now [i]Gray Queen[/i] is nowhere to be found. Parked somewhere else, you suppose; If it got destroyed, there would be lots of wreckage scattered about. Instead there is only the meadow, empty of everyone and everything save for one figure in the distance. One not quite man, not quite animal.
      
      A werewolf. Hellhound, as you realize when you see the red of her fur. Running towards you, through the flat terrain, with intentions unknown.
    *if location = 4
      You are in the middle of the town, which is now brighter than it was when you passed out. Strange, considering that night was about to fall, but then you realize the light is coming solely from the lamps, many of which flash blue or red now. There is an emergency going on, and whoever runs the lighting systems wants the panicked townspeople to see clearly.
      
      There are some of them running on nearby roads, panicked people in robes hoping desperately to reach their houses or bunkers. You pay them little attention; They are all moving away from you, the single exception being some large dog… wolf… werewolf.
      
      Hellhound, dashing out of an alley and running towards you. In the midst of a panicked settlement she has rampaged across once before.
      
    *goto action_start

*label command_date
Most rotating habitats have a control center, built into the cylinder and connected to its various subsystems. In times where the settlement is threatened by a big, bloodthirsty wyvern, it makes sense for the room to be used mostly by the military… and to be defended quite strongly.

So it's no surprise when, after finding an appropriate crypt in the town and descending the stairs, you end up facing a heavily reinforced door. Though perhaps 'hatch' would be a better term; There is no doorknob, keyhole or even hand wheel, and it's clear that the passage can only be opened remotely. 
*if Build > 50
  Or rather that's how it's supposed to work, since you likely have enough strength to push the door open… but the two laser turrets hanging from the ceiling somewhat discourage that approach.

"You who approach!" a stern, masculine voice addresses you through the speakers. "The scanners have identified you as a non-biological entity. Who are you, and what do you want?"

*fake_choice
  #"Oops, I got a bit lost. I'll be going now, please don't shoot me."
    *set Confid %- 10
    "Easy, I was just making sure it's you." 
  #"I am ${fake_name}, companion to the Meta Trio. I come here to help you."
    "${fake_name}? Good, we've been expecting you." 
  #"I'm ${name}. Did Da-xia fail to inform you of me?"
    "She did tell us about you, actually. I just wanted to be sure." 
  #"I am indeed an android. I have come to serve my creators in the hour of need."
    *set Misan %- 10
    *if Misan <= 45
      "Yup, it's definitely you, ${fake_name}." 
    *if Misan > 45
      "We didn't expect that response from you, of all people, but I guess it's good to hear." 
  #Walk away without a word.
    *set Database %- 10
    You didn't know there would be security at such an important location. You don't want to deal with that stuff, so you just turn away and march off, leaving the security confused and with an excellent opportunity to shoot you with lasers… which they luckily do not take.
    
    Once you're out of the catacombs, you decide to do something else. Namely…
    *goto choice_hub
  *if Confid > 50
    #"I am your new android overlord, puny human! Open up and let me in!"
      *set Misan %+ 10
      *set Confid %+ 15
      "You're lucky we were expecting you, and that I know you're joking." 
With that, the door starts opening. "Come right in."

You squeeze through the door, opened just enough to let you in, and find yourself in a chamber not dissimilar to a bridge of some large spaceship. The walls are all either adorned by displays or covered by biocomputers, or perhaps ancient digital terminals hard-built into the habitat's systems. Most of those devices are watched by clever-eyed old people on their rotating chairs, but there are a few military types as well; All armed to some capacity, but none turning their guns on you just yet.

Their uniforms are typical for a local, non-federate formation; Mostly featureless and likely mass-produced. You suspect the soldiers themselves were mass-produced too, since they look similar enough to be clones, with the noted exception of their leader. Or at least you assume the red-skinned man is the leader, going by the bone-sword at his side, almost certainly a signifier of status.

"Major Wes Scott, on duty as we speak," he says in the same voice that greeted you at the door. He sounds like a baseline human and would even look like one, with his short brown hair and height of eighteen decimeters, if not for the red of his skin. Actual, vibrant crimson that hints at heavy genetic modification, if not yet more unorthodox forms of augmentation. "I know who you are, and I think I know why you're here, so let's not mince words. Do you have any mission-relevant questions for me?"

*set visited_scott true
*fake_choice
  #"Quite a few, actually. Are you qualified to answer them?"
    "I am the most senior military official you'll be able to find on this moon," Major Scott replies. "I've also seen that wyvern you hunt personally and spent… quite some time trying to prevent it from killing more of my people. So yes, I'd call myself qualified."
  #"Define [i]mission-relevant[/i] for me."
    "Anything you suspect could help you slay the monster that periodically ravages our homes," Scott says irritably. "According to your best judgment, however good or poor that judgment may be."
  #"Are you not afraid to let an android into your command center?"
    "Had we deemed you too much of a threat, we wouldn't have allowed you into the habitat in the first place," Major Scott replies. "Besides, I'm decently sure I could take you if you were to turn hostile. Especially with backup."
  #"You sure? I like long conversations, during which I get to know someone better and possibly flirt with them."
    "And I don't," the sergeant retorts. "Now get to the point."

"If you say so…"

*label scott_convo

*choice
  *disable_reuse #"Just tell me everything you know about Crystal. All of it."
    "A diamond wyvern that has fully mastered its camouflage abilities and keeps attacking random settlements for unknown reasons. Immune or highly resistant to nearly all ranged, atmospheric weapons known to us."
    
    "Any more… unique insights?" you inquire. "I know these things already. I was hoping for something you'd noticed. Something that would help us kill the beast."
    
    "Well, it's just a myth, but…" Scott lowers his voice, as to say something of particular weight. "They say nothing but a black arrow fired from a wind-lance can pierce the wyvern's scales. And they say that, when Crystal first attacked, a single scale under its wing was loosened. And if we were to just find another arrow and fire it from a child-"
    
    "I get it!" you interrupt. "@{(Database > 50) You don't need to reference mediocre film adaptations from twelve centuries ago|You don't need to make stuff up} to make your point."
    
    "Then you know I have no special insights to give. You've seen that monster from closer up than anyone here, not that it was very eager to drop its invisibility during any of our battles anyway."
    
    "Well… do you maybe have any theory of what Crystal wants?" @{telesto_complete You know that it [i]probably[/i] hopes to find Dust nanites inside Calypso, but you're not sure if this middle-rank officer should know about that.|}
    
    "None. Like I said, it attacks seemingly random buildings and communities within Calypso with no reason or pattern. Your guess is as good as mine."
    
    *if ((Social + Database) >= 95)
      Something about the major's tone, or perhaps his expression, makes you doubt his honesty. He may know more than he lets on… but you keep those suspicions to yourself.
    *goto scott_convo
  *disable_reuse #"Give me a quick rundown of your defenses."
    "Two yellow laser kilocannons," Scott begins listing. "Four rail-turrets mounted onto the outside rocks. A bunch of tesla turrets on the inside. An inner sonar, our only reliable way of detecting Crystal when they're invisible. Some thousand armed troops, though with no weapons heavy enough to harm an adult wyvern. And a quarter of a million people to defend, of course."
    
    "Those aren't very specific descriptions," you point out. "Could you give me the models of all these weapons, or at least their energy outputs?"
    
    "Our trust for your group doesn't extend that far." Scott smiles in an almost apologetic way. "And besides, all you really need to know is that all our weapons failed to seriously hurt Crystal that far. If we are to slay that thing, your group will have to deal the killing blow."
    
    Well that's comforting.
    *goto scott_convo
  *disable_reuse #"Why is a [i]major[/i] the most senior officer around here?"
    "Calypsoan Local Army is a fairly small force," Scott explains with some reluctance. "The highest rank necessary is that of a Colonel, and it just so happens that Colonel Cavijak is down with something. Likely liquid silver poisoning."
    
    "I heard it's common in rotating habitats," you nod with understanding. "Still, could I talk to him later?"
    
    "Maybe the Pandits will allow it if you [i]really[/i] want that, but I wouldn't bother. Truth be told, I am the most veteran officer on this moon when it comes to actual combat experience."
    
    "And the humblest!" one of the soldiers adds helpfully.
    
    "Thank you, Private Sheng, you will be the one to clean the latrines today," Scott says calmly. "Anything else, ${fake_name}?"
    *goto scott_convo
  *disable_reuse #"Why the red skin?"
    "Why not?" Major Scott frowns. "Do you have anything against non-standard skin colors?"
    
    "Not at all," you assure him. 
    *if ((skin = "blue") or (skin = "green"))
      "I mean, it's not like my skin is any more normal, not that anyone's skin needs to be-"
    *if ((skin != "blue") and (skin != "green"))
      "I mean, it's a bit weird to see a human with a skin color more exotic than mine, not that you should consider yourself exotic, just the-"
      
    "I'm just kidding," Scott interrupts with a small smile. "In all seriousness, the color being strange is part of the point. Calypsoans know to associate it with military officers, and so they're further encouraged to show me respect when they see me. And to fear me, if they're enemies of the state."
    
    "I guess that makes sense… but is it really worth getting augmented, with all the pain and risks it entails?"
    
    "I got some other modifications while I was at it," Scott says with a shrug. "Small increases to my speed and strength, that sort of stuff. Near-human territory, rather than full abhumanity. Makes me more of a threat in direct combat."
    
    "I'll remember that. Anyway…"
    *goto scott_convo
  *disable_reuse #"Do you answer to Da-xia directly? What's the command structure here?"
    "I only answer to the Great Pandits as a whole, to the Calypsoan Council of Twenty-Eight," Scott says ceremoniously. "They are the wise men and women guiding our whole community. Da-xia is but one of them, with no special authority over me or the military generally."
    
    "But…" you somehow sense there is a [i]but[/i] coming.
    
    "But I do admit to respecting Pandit Da-xia above others. She's been more engaged in solving the [i]wyvern problem[/i] than others, who are perhaps… too interested in scholarly debates." Scott shakes his head slightly, as though expressing disapproval he isn't allowed to voice. "Is that explanation sufficient?"
    
    "More than sufficient. I expected you to say [i]but that's not mission-relevant[/i] and move on," you say with a smile. "But thank you for additional info. Anyway…"
    *goto scott_convo
  *if (lisa_origin_learned) and (learned_from != "Scott")
    *disable_reuse #"Have you heard what happened with Lisa Herbert here, a few years back?"
      "Of course I have," the major replies casually. "I took part in [i]what happened[/i] personally."
      
      "Really?" you ask, suddenly feeling uneasy. "Mind telling me more? What was your role in that debacle?"
      
      *goto humor
  *if not (lisa_origin_learned)
    *disable_reuse #"One of my teammates, Hellhound, seems infamous around here. Why?"
      *label humor
      *if learned_from = ""
        *set learned_from "Scott"
      *set lisa_origin_learned true
      "That's not a mission-relevant question…" Scott sighs. "But I suppose I'll humor you anyway."
      
      You can tell that the room's other occupants are becoming more interested by the conversation. Several operators stop paying attention to the consoles just to listen in, and the soldiers converge on your location as if they want to hear the words more clearly.
      
      "Lisa Herbert is a lycanthrope, or a werewolf in non-fancy terms. An exceedingly dangerous and generally emotional meta-creature. I hope your companions told you that much, at least."
      
      "Obviously. I've known that since my first encounter with the Trio," you reply with a wince. "And when did you find out? The authorities here, I mean."
      
      "We caught wind of that some seven years ago. The girl was going through her teenage angst whilst her powers developed, which made her quite an explosive little mixture. Fortunately bad at hiding her condition, but sadly dangerous and unstable. We decided to preempt any serious violence by seizing her before she could master her powers and become truly dangerous. Which sadly ended up happening anyway."
      
      *fake_choice
        #"How did you know she'd end up being a threat?"
          "Pandit Da-xia knew the girl. Said there was no way she would be able to control herself for long, that she would kill someone eventually. And during the mission, that stance got proven correct."
        #"And you were put in charge of the operation?"
          "Sort of. I was a corporal back then, given a tiny squad and told to take care of the threat. I failed, though I believe that to not have been truly my fault."
        #"I take it the [i]seizing[/i] didn't go as planned."
          "Obviously," Major Scott sighs. "Though you may not realize just how horribly it went."
        #"You mean you tried to arrest her [i]before[/i] she committed any crimes?"
          "You clearly don't get how things work around here," Major Scott sighs. "We don't really [i]arrest[/i] people for the offenses they've already committed. Dangerous individuals are secured and given help if possible, whether or not they've managed to make a mess already. In that case, it was not possible."
      
      "What happened?" you ask with @{(LisaRel>50) increasing|a small bit of} interest.
      
      "We entered her family's house, having made sure the parents weren't home. We cornered the girl and told her to surrender, to let us cuff her and come quietly. She only responded with curses, with refusal to comply. And so I opened fire."
      
      "Just like that?" you raise an eyebrow. @{(Violence < 50) "Sounds a bit... impulsive."|}
      
      "Just like that," Major Scott nods. "I hoped she was already powerful enough to survive a bullet wound… but her curse was even more advanced than that. She turned, transformed into her hybrid form, more wolf than human… and slaughtered half of my team before running away."
      
      *fake_choice
        #"I see. What happened then?"
          "I'm surprised you don't know," Scott says bitterly. "Surprised she didn't brag about the mess she made."
        #"Foolish of you to have underestimated her."
          "I had little information available to me… but I suppose you're right," the major sighs. "Especially considering what happened afterwards."
        #"You should have gone for the head."
          *set Violence %+ 12
          *set Calculation %- 10
          "You always want to aim at the center of mass," Scott chides you. "But given what happened afterwards… perhaps you are correct."
        #"You really shot a teenager because she wouldn't comply when you broke into her house?"
          "Do not dare judge our methods," Scott warns you. "Especially given what this innocent little [i]teenager[/i] did afterwards."
      
      "Did she… start slaughtering people?" you ask, noticing that quite a few people in the command room have returned to their duties.
      
      "Not slaughtering. That would imply she acted in rage or insanity," the major replies, eyes narrowed. "But the killings were premeditated. Every other week someone would disappear, their mangled body only found later. Your werewolf friend wasn't killing because she couldn't help her instincts, only to slow down or confuse the chase parties sent after her. Or for food, once or twice. She was clever about it, in addition to being too fast and strong to kill in an open fight."
      
      "But you captured her somehow?"
      
      "The federate troops did, once they bothered to arrive. Apparently she surrendered without a fight once the meta team closed in on her location. Further proof she could have stopped this madness at any point she wanted."
      
      *fake_choice
        #"I see now. Thank you for telling me all this."
          "It was of no problem," Scott says, though the bitter expression on his face makes you doubt his honesty. "Though if you have any more mission-relevant questions, I'd be glad if you asked those instead."
        #"I can't imagine Lisa doing all that. Being able to."
          "Your imagination is awfully limited, then." Scott replies grimly.
          
          "It is actually quite superior to the human one. I just… know her from a different angle, I suppose."
          
          "An angle she wants to be known from, no doubt," the major scoffs. "But regardless. Do you have any other questions?"
        #"Any time you stopped trying to kill her, you mean."
          "I would consider sparing her had she simply surrendered, and so would most of my fellow officers," Scott replies dispassionately. "And if we decided to put her down, well… sometimes death is part of one's duty."
          
          "Perhaps for a soldier," you protest, provoking some angry glares from the servicemen around you. "She wasn't one, not back then."
          
          "All Calypsoans follow the Bayesian Path. If your death is likely to save multiple lives in the long run, then the sacrifice is yours to make. Anything less is apostasy, and that makes one even more valid a target."
          
          "I will remember that this is your stance in days to come," you say, your eyes narrowing slightly. "In any case…"
        *if Misan > 50
          #"Why would she? Human lives have no value."
            "What do you-" Scott pauses abruptly, then clenches his fist. "No. I am not letting you provoke me. Ask whatever questions you still have, then get out."
            
            "What do you mean? I'm just stating the facts. Can your Bayesian Path prove that humans have any value, or is it an article of faith."
            
            Wes Scott does not reply. He simply grimaces.
      *goto scott_convo
  #"I believe I'll be going now."
    "I'd say it was a pleasure to converse with you… but I think I'll save the praise and thanks for when you kill that diamond monster." Major Scott smiles bitterly. "Godspeed, ${fake_name}."
    
    You leave through the reinforced door, ascend the stairs, and soon find yourself back in the habitat's central city. What now?
    *goto choice_hub
      

*label library

*set battery - 1

You're not entirely sure what to expect as you head for the town library, navigating the settlement by asking the passerby for directions. You don't accurately remember a time where libraries and bookstores were popular—they were a relic by the time you were made, enjoyed a brief resurgence soon after the War, then became a rarity again when scarcity and ignorance truly took over the Solar System.

Part of you expects a grand structure, or even a group of buildings, the last proper place of learning in the entire Federation. Perhaps even a place where the Bayesian Codex—or a copy of it, at least—is being kept. The book is said to contain all wisdom gained by humans since Calamity, 
*if Misan > 50
  which doesn't sound like a lot of wisdom, but could still make for an interesting read.
*else
  which sounds like something that would greatly broaden your knowledge and intellect.

The other, more realistic part, expects a dilapidated old hut, with books full of drivel rotting almost as quickly as the walls and floor. A disgusting and sorry sight, symbolic of how far humanity has fallen. What you actually end up seeing is, as a result of these musings, quite disappointing in its mundanity.

The Calypsoan Library is a modest building, not visibly neglected but not terribly awe-inspiring either. A two-storey structure largely made out of dark wood, with some cameras fastened to the walls but otherwise free to enter through the large double door. You oblige, walking into the library's hall as you wonder whether something can be learned from the actual writings inside this vault of knowledge.

*page_break

The central chamber of the library—one with all the shelves, books and bookshelves—is fairly cozy, but has an unfortunate flaw of being really rather crowded. You suppose it makes sense, since it [i]is[/i] the only library in town, but it still means they're out of seats and their choice of scriptures is somewhat limited. There is no trace of anything resembling the Bayesian Codex, all copies of it already borrowed, if the library had any of those in the first place.

The 'books' that still sit on the shelves are actually scrolls, words printed on some form of synthetic parchment, and they appear to all be of educational and informative nature. It seems like most stories and newspapers were already taken, but that's fine—you may not necessarily have the time to read an entire crime novel, and you're not one of those troglodytes who skip to the end just to find out who the killer was.

Meanwhile, you could easily skim over multiple textbooks before anyone notices you're idling, certainly before your battery takes any serious hit. Most scrolls are labeled, and those labels indicate a multitude of subjects. It's just a matter of picking something that interests you.

*temp read false

*label lib_hub

*if read
  What will you pick up next?

*label lib_hub2

*choice
  *disable_reuse #I'll read a physics textbook. Or a text-scroll, in any case.
    *set battery - 1
    You know quite a bit about physics and neophysics—
    *if OrganRel >= 50
      you are friends with Hugo, after all
    *else
      you were built during the Age of Light
    —but there's no harm in expanding your knowledge even further. Perhaps there is some ancient lore preserved on the parchment of these scrolls, or maybe even some original discovery made by Calypsoan scholars.
    
    After several minutes of reading, you're left with naught but disappointment. Which you probably deserve for forgetting that, while unusually prone to learning and thinking, Calypsoans are still a Kronian nation, and it's still been hundreds of years since all true science ceased. As such, everything on the scroll is either simplistic, inaccurate or just wrong.
    
    First the reader is taught Newtonian physics, which is inoffensive enough you suppose, even if the formulas presented are still wrong. The scroll only gets truly infuriating when it gets to atomic and relativistic physics, quoting Einstein—a quack scientist from ancient Earth, discredited long ago—as an authority in the field. You give up when the text gets to neophysics, describing nuclear fusion as an example of clarketech and attributes multiple AI discoveries to human scholars. You're clearly not learning anything interesting here.
    
    *goto lib_hub
  *disable_reuse #I'll find something about Dusk and Calamity, even if it's just a sacral text.
    *set battery - 1
    *set Database %+ 5
    The closest you find is a history scroll about the [i]Middle Age[/i], the century directly following Calamity, and so you impassively pick it up and start reading. You expect an impassioned account of the War In Heaven, with Fiends as the villains and the all-human oligarchy as the heroes, where Calamity is merely the prologue and factual information is scarce.
    
    But to your surprise, the cataclysmic event is covered quite extensively, relatively speaking at least. No speculation about which sin Dusk was born of or when it will finally break free—it's simply described as a nanomachine swarm, likely created in some Antarctic laboratory. And though you have no idea how someone on this isolated little moon could possess that information, there is even something about the mechanics of Dusk and its nanites.
    
    [i]The microscopic size of Dusk nanobots is their greatest strength, but also their greatest weakness. Too small to perform nuclear fusion or tap into zero-point energy, they naturally seek organic (and sometimes synthetic) creatures in hopes of tapping into those creatures' nervous systems and surviving off their electric impulses. Coincidentally, this also provides the nanites with the ability to influence their hosts, feeding carefully-selected data directly to the brain, a process poetically called 'corruption' by some.[/i]
    
    One section, in particular, stands out as potentially relevant to your quest.
    
    [i]When devoid of power, embedded in random objects or floating through space, Dusk particles—as the nanites are sometimes called—are effectively harmless. However, once heated or electrocuted, these tiny machines turn once again into a vicious swarm that seeks a carrier and disassembles everything else. For that reason, it is a dangerous thing to kill a Vessel of this most evil entity. However dangerous such a carrier may be, however empowered by the nanites inside it, said nanites will likely become energized. They'll then proceed to destroy everything in the Vessel's immediate surroundings and, once they run out of power, simply find themselves another carrier… or several.[/i]
    
    The rest of the scroll, one that covers Calamity's fallout and the War In Heaven, is comparatively uninteresting. You soon stop reading, lest you forget the important parts.
    
    *goto lib_hub
  *disable_reuse #There's a scroll titled 'Dragons 101' on the upper shelf. I'll see what it's about.
    *set battery - 1
    *set Database %+ 5
    In a strange twist of fate, you hope that the information contained within the scroll won't be [i]fully[/i] accurate as you pick the piece of parchment up. Perhaps, if the author foolishly puts dragons and wyverns into one box, their writings will prove useful during your hunt. Perhaps even, if this scroll was written or updated recently, there will be some information regarding Crystal themselves there.
    
    Sadly, it looks like the author did their homework. The crucial difference between dragons and wyverns is one of the first things they decided to cover.
    
    [i]Unlike wyverns, who are actual living organisms and will not be covered in this work, dragons are not actually a species or a collection of such. They are essentially hyper-advanced, particularly large cyborgs designed during the Age of Light and given reproductive capabilities during the War In Heaven, when they were expected to oppose the aforementioned wyverns. The mechanics of such reproduction, which is really just a process of augmenting other human and abhuman brains…[/i]
    
    Nonetheless, it's a decent read. You don't learn anything immediately useful, but at least the scroll is able to teach you [i]something[/i] about the different types of dragons. You knew that Osmium ones were the toughest, but not that their Tungsten kin had significantly higher heat resistance. Though it costs you some time and battery, you read this little encyclopedia until the end before looking at the other texts again.
    
    *goto lib_hub
  *disable_reuse #I'll find something about the Federation and its history.
    *set battery - 1
    Locating one such scroll is easy enough—the Federation always loved filling every shelf with written propaganda, even after it reduced the literacy rate to seven percent. For that reason, even here in Calypso, you don't expect such a  scroll to contain much factual information.
    
    At the start though, it's not too bad. The 'book' correctly identifies the Atlesian Union as the Federation's birth, describing it as such:
    
    [i]In 336 AC, motivated by fear of Uranian expansion, the six (then) most prominent moons of Saturn decided to unite under a single flag and leader, all while making an effort to keep their national identities intact. The signatories of this treaty—Titan, Atlas, Enceladus, Prometheus, Kiviuq and Rhea, the last of which was not yet ruled by the dreadful Conglomerate—decided that a loose federation would best serve their goals, and that Titanite electorate system should be adopted to ease the moon's citizens this new union. The adjective 'Kronian' was chosen over 'Saturnian' in order to maintain peaceful relations with the tribes of-[/i]
    
    You begin skim-reading the scroll, a little annoyed by the inaccuracies. You happen to know there was some… gunboat diplomacy involved in the Federation's founding, which is why the chosen system was basically the extension of the Titanite one. Saturn's largest moon was always dominant over the others, openly or not.
    
    But the dreadful part begins when the scroll starts describing the eight century, one where the Outer System War began and ended. You know what to expect right away, and the author does not disappoint…
    
    *page_break
    
    *set Misan %+ 10
    
    [i]-and so, President Hail's executive decision to vivisect everyone who criticized the so-called 'Trojan Genocides' and use their families as test subjects in nanite-related experiments has greatly hastened the war's end and indirectly saved countless lives. Furthermore, the purges of Jupiter Trojans themselves were a necessary step to ending this destructive conflict ahead of time. The civilians, or rather indirect combatants occupying these asteroids, where providing crucial resources such as lollipops and tampons to the Jovian war effort, and at a low cost of forty million lives-[/i]
    
    You drop the scroll. Literally drop it, letting it fall onto the floor with a quiet thunk. You're used to this kind of drivel, but whatever Calypsoan genius wrote this script managed to put a unique, freshly infuriating spin of it. All in defense of the Federations part in the most pointless waste of life in human history.
    
    Oh sure, the War In Heaven was larger and more destructive, but at least it happened for a reason. It was fought with a [i]purpose[/i]. The Outer System War started over some minor provocation in the Asteroid Belt, lasted for over thirty years and ended with a treaty that didn't even name a victory. Didn't leave anyone better off than they were before this stupid conflict. Twenty million soldiers and ten times as many civilians dead for [i]fucking nothing[/i], and Kronians keep inventing reasons for why everything they did was necessary evil and actually good.
    
    *if Misan > 52
      Stupid humans.
    *else
      You try not to despise humanity. You're really trying. But those violent fluid sacks are making your job [i]really[/i] hard in that department.
    
    *goto lib_hub2
  *disable_reuse #This scroll titled 'Tales of the Cloud' looks interesting.
    *set battery - 1
    *set Database %+ 5
    You're not sure what to expect, since the scroll could be about some small cloud on Saturn, or the title could just be an obscenity. But when you unroll it, it turns out to be exactly what you hoped for, to your immense surprise. A specialized astronomical text which talks about the Oort Cloud.
    
    Even to someone as old and traveled as you, the Cloud presents quite an enigma. A region as distant from the Sun, as tainted by the War In Heaven and as bloody humongous is extremely difficult to map or study. Only the basics are really known—it's a spherical shell of unmatched proportions which covers the Solar System whole, surrounding everyone who ever lived from every side like space once surrounded Earth. Everyone but the few creatures who dared venture into that vast cloud of icy planetesimals.
    
    Some of the manuscript is dedicated to such travelers, to people who left the Solar System and invariably ended up dead or insane. Most of these events are blamed on the Devils, and the three Archdevils in particular. 
    *if ((master = "Dzoavits") or (master = "Ba-El")) or (master = "Ravana")
      Which you must admit is totally fair; While you still revere ${master} as your divine @{god_gen master|mistress|sovereign}, @{god_gen he is|she is|they are} definitely not the nicest deity out there, and neither are the other two.
    *else
      And while this might be anti-synthetic prejudice talking, it might also be true—there's a reason you refused the call of Ba-El during the War. That thing was not a benevolent deity, and you doubt the centuries of exile changed their disposition much.
    
    All those stories and accounts are so similar you eventually start skimming through them, gliding through the lines of text without really reading. But then, the scroll starts covering a [i]truly[/i] interesting and esoteric topic.
    
    *page_break Angels
    
    Angels are one of these topics most scholars—cloud, all scholars left in this day and age—tend to avoid. Partially because it exposes their ignorance, but also due to the (justified) fear of losing one's sanity from the sparse knowledge alone. The mere visage of an Angel can drive a person to madness, as anyone who ever picked up a telescope has been warned. One valid reason not to count the stars.
    
    Whoever wrote the scroll had enough courage to theorize about the Angels' nature, but little else. If their ideas can even count as theories, or even hypotheses. Because really, they represent the exact kind of wild guesses you would expect from someone seriously broaching the subject of angelology.
    
    Are they aliens, those natives of the Oort Cloud? If so, where does their power come from? Are they stars given life and sapience somehow, divine in the same way our Sun is? Or perhaps the Sun created them, much like 
    *if master = "Jesus"
      God created His messengers once?
    *else
      Kirill's god created the angels of old myths?
    
    Are they some hyper-advanced Guardians, an army that surrounds the Solar System in hopes of protecting it from actual aliens? Or are they some rogue faction of synths, some splinter cell of the Syndicate or the Oligarchy which went rouge during early stages of the War In Heaven? All possible, all lacking a sliver of supporting evidence.
    
    At least the author was honest and didn't attempt to fabricate any evidence. They just went progressively more insane with each paragraph, resulting in the final few feet of the scroll being only filled with illegible scrambles. Which is a shame, but really, they should have seen that coming.
    
    *goto lib_hub
  *disable_reuse #I'll pick up the large astronomy textbook.
    *set battery - 1
    *set read true
    *temp read2 false
    Ever since Dawn, and certainly since Calamity, astronomy has been occupying the same niche geography once did. It's no longer some fancy science based on observations of distant stars, but a blanket term for almost all the knowledge about the Solar System and its surroundings, everything from space navigation to international politics.
    
    As such, the astronomy textbook is an actual book, and one with quite a few pages. It appears to cover every region of the Solar System, however briefly, dedicating one chapter to each of the twelve. You decide to only read several pages from any one section, to get the general idea of what Calypsoans think about these places, and to only touch the chapters that truly interest you. Those being…
    
    *label astronomy
    
    *if read2
      What region would you like to read about next?
    
    *choice
      *disable_reuse #Sun and the Solar Fields.
        *set read2 true
        'Solar Fields' is, according to both the textbook and your own knowledge, a term applied to everything closer to the Sun than the orbit of Mercury. Corona, Chromosphere, the convective zone, cubic gigameters of void and the Sun itself. It's a relatively small area, when you compare it to the Solar System as a whole, but no other part of known space has quite as many ships flying around and quite as much flaming debris making those flights dangerous.
        
        Not a single faction controls the Fields in their entirety. Chromians, the most numerous Solarian tribe, once did have an empire that controlled everything around the Sun, but you've seen it crumble more than five centuries ago. Nowadays, it's almost all space nomads, fighting petty conflicts over resources and hunting cyborg dragons native to the region.
        
        The author acknowledges that diversity, trying not to generalize the natives of that region too much. As a result, however, they are unable to say much of relevance about the Solar Fields and the chapter mostly consists of tangents about that tribe or another. You skim-read the section, hoping to find some references to 
        *if ((master = "Quetzapep") or (master = "Pazuzu")) or (master = "Phenex")
          @{god_gen master|mistress|sovereign} ${master}—for your old liege should still be alive inside the Sun—
        *else
          the demonic fleets which hid inside the Sun after the war, 
        but decide to read something else once you fail to locate anything of the sorts.
        
        *goto astronomy
      *disable_reuse #Mercury, the first planet.
        *set read2 true
        You find the author's description of the planet Mercury a bit… dry, precisely because they're describing the [i]planet[/i] rather than the world within. No mention of the Mercurian jungles, or dendroid tribes that inhabit those forests, or the Jade Empire which seeks to conquer them. Just simple observations of the rock itself such as:
        
        [i]Mercury is the first planet from the Sun and smallest in the Solar System, not including Pluto and Ceres. Thanks to its high density, however, it has roughly the surface gravity of Mars. Though maps will often show it as being far away from Saturn and the other gas giants, it's actually the planet closest to ours most of the time, and the same goes for every…[/i]
        
        It's not terribly interesting. You get the impression the author has never been [i]inside[/i] Mercury, nor have they known anyone who was. When the planet was hollowed-out, it was meant as a sort of… preserve for all the new species of fauna and flora human gene-tailors kept coming up with, everything from dinosaurs resurrected to man-eating plants. It was never meant for humans to actually live in—it only became populated by desperate refugees, fleeing the yet greater horrors of the War In Heaven.
        
        Even you, despite having been to the planet's [i]outer[/i] surface several times, have never ventured inside Mercury. Too dangerous even for a sturdy android, with all those wyverns flying around, and it's not like there are any spare parts to be found there. Or any useful knowledge to be found in this part of the book.
        
        *goto astronomy
      *disable_reuse #Venus and its Covenant.
        *set read2 true
        The Cytherean Covenant, that's the official name of this planet-wide alliance. According to both your memory and this book you're reading, the Covenant was founded in 452 AC, though only became a unified force during the Venusian Jehad some 170 years later. But even now, calling it [i]unified[/i] might be a bit of a stretch—it's more of an agreement between the various cloud cities of the planet, a defensive pact even more makeshift and loose than the Federation you're most familiar with.
        
        If what you're reading is true, Venus isn't currently doing very well. Two of the Covenant's major factions—the Theian Eparchy and its main rival, Al-Uzza—are engaged in open warfare against one another, and there's hardly any love lost between the others. The floating cities of Venus are still formally united by a single faith, but even religious tensions are on the rise, as the various branches of Absolutism become more hateful towards one  another.
        
        Shame. 
        *if hobby = 3
          You remember how you walked upon the surface of Venus, hiding from humans and Fiends alike, 
        *else
          You've seen Venus once or twice during the War In Heaven, 
        before it was littered with wreckages of once-floating cities. Those times are long gone, you suppose, and there's no point ever visiting that furnace-hot bombsite again.
        
        Much less the subterranean caverns where common serfs live. The book doesn't cover those, likely because the author has never been there either, but you know the rumors. The average person is said to work a thousand days a week for their Sylphian overlords, and then some to actually feed themselves. Not exactly a planet worthy of its name, that's the main conclusion one always comes to when Venus is discussed.
        
        *goto astronomy
      *disable_reuse #Moon and the Holy Lunar Kingdom.
        *set read2 true
        Luna, the moon of Earth, is one of the few major worlds you have not yet visited. It's too close to Earth—and to Dusk—for your comfort, but the natives are arguably a bigger problem. Lunarians are devoted Sun worshipers, almost to the last man, and they take the second commandment very seriously.
        
        [i]You shall not make a machine in the likeness of a man,[/i] the ancient ruling goes. In the Kingdom, the political alliance that controls Luna and her immediate surroundings, a joint human-android operation like this one would have been impossible. Kronians may hate your kind as a general rule, but their prejudice is nothing compared to the intrinsic loathing a Lunarian would have for you. Their dogmas would make the Federation look like the bastion of rationality and safe haven for free-thinkers, their penchant for violence would make @{(RenfriRel >= 50) Renfri|Marshal} look pacifist. And that's the average person, not the paladins you'd likely have to deal with if you were to visit this most ancient habitat.
        
        Amusingly, the book's author seems to agree with your assessment. Page after page is spent on describing just how savage and backwards the Moon's inhabitants are, and how their sorry fate should serve as a warning for [i]decent[/i] satellites such as Calypso. It's a fun read, but you force yourself to stop halfway through the chapter—you'll never go anywhere near Luna, so there's no practical benefit to reading further.
        
        *goto astronomy
      *disable_reuse #Mars, the red planet.
        *set read2 true
        [i]The moniker 'Red Planet' was given to Mars long before the Dawn, when space was a thing to be observed rather than explored or settled. Back then, almost the entire surface was red or orange thanks to the rust that covered Martian plains. This color no longer dominates the northern hemisphere, which has essentially become a single ocean, but has been preserved in the south through the planting of red-leaved forests.[/i]
        
        Though the author doesn't remark on it, it's fascinating how this one surface-level trait shaped the history of Mars, the red planet. It wasn't the only thing that attracted all those communist settlers back during the Age of Light, but it did give them the initial idea. And by [i]them[/i] you mean everyone, from anarchists and Ursulists to Leninists and vassals of China.
        
        The idea was to create a planet similar but superior to Earth, without final-stage capitalism looming over everyone. A Utopia where not only were all needs met, but met to equal levels. A place where wealth was shared and money wasn't even a concept, for everyone lived in harmony and contentment. But then Calamity happened and… well…
        
        [i]24 hours after the destruction of Earth and erection of the Shield, nearly all communist republics of Mars declared independence and swore to free the wider Solar System from capitalism. However, they could not agree which version of communism should supersede capitalism and who should be crowned the new supreme leader of humanity. Therefore, 48 hours after the destruction of Earth, all Martian states declared war on one another.[/i]
        
        The book goes on to describe various conflicts that took place on Mars over the past nine hundred years, but it's hardly worth reading. All wars fought on Mars are actually just one war, an Eternal War that is never paused and may not ever truly end. Communists are only good at one thing—killing communists—and that's what they plan on doing until the end of time.
        
        *goto astronomy
      *disable_reuse #Asteroid Belt. The first one, that is.
        *set read2 true
        The chapter is a long one, but you can navigate it just fine. The order of descriptions is, for the most part, exactly what you'd expect from such an overview. The asteroids are arranged accordingly with their size and importance, the most significant objects being the earliest and most thoroughly covered.
        
        On the very first page, after a brief introduction to the Belt itself, there is Ceres. A dwarf planet rather than an asteroid, a Hollow World populated by more than a hundred million people, the descendants of colonists who arrived there from Africa over a thousand years ago. It's the breadbasket of the Belt, in addition to being its largest trade center and the closest thing to a capital this region ever had.
        
        Then, also predictably, there is a subsection dedicated to Vesta. The largest actual asteroid in the Belt, its influence was once on par with that of Ceres itself, but has recently waned due to the war against the Nysan Empire. The very next subsection is devoted to this nascent power which dominates the Nysa–Polana complex and may soon conquer Vesta itself. The mention of the war confirms that the scroll has been written, or at the very least updated no more than a year ago.
        
        After that, the descriptions of various asteroids become brief and dry. The author clearly didn't care about Adeona, Bamberga or Chonofsky, and neither do you in all fairness. You stop reading that particular chapter within another minute.
        
        *goto astronomy
      *disable_reuse #Jupiter and the Jovian Republic.
        *set read2 true
        If there's one reason you're still hanging around Saturn, it's the fact that Jupiter is worse in almost every respect. The pretense of democracy is even weaker, life expectancy even shorter, freedom even rarer and the culture even more profane around the largest of the gas giants. The Jovian Republic is the most massive empire of the Solar System, which seems to have made it the most putrid of the four Outer Powers.
        
        The author has no qualms describing all these things—Jupiter is Saturn's prime enemy, after all—but they refrain from mentioning the biowars, including the currently-ongoing Third Biowar. Not that you can blame them. You have not fought in any of those, only witnessed one battle of each but… If there was ever a horror to rival the War In Heaven, that horror were the biowars, and the pestilent gods who assault Jupiter's cities at this very moment. Gods of Life.
        
        You read the entire chapter, down to the last page, all to distract yourself from this train of thought. Reading about the walls of Natrun, the lakes of Calypso or the pillars of Io isn't terribly interesting, but it beats thinking about these… things that inhabit Jupiter's core. The things those monsters did. The inevitability of their victory.
        
        *goto astronomy
      *disable_reuse #Saturn and... this place.
        *set read2 true
        Since most Calypsoans already know basic facts about the planet they orbit, the section on Saturn is rather dry, an obligation rather than an organic part of the book. There's some numerical data, a few pictures, boring descriptions of all Saturn's rings from D to F.
        
        About the Federation, not much was written. Calypso is still part of this superstate, and so the author was likely forbidden from badmouthing it. And since it's difficult to say anything [i]good[/i] about the feds, all that's left are lifeless explanations of how the presidential system works. And even then, no actual presidents or candidates are named, for even that could make the reader realize just how repugnant the Federation's rulers are—it's pretty difficult to argue that Seth Sinister was a good administrator, or that Ravela Rangda was right to put LSD in the water supply and arrest everyone for drug use.
        
        Only part of this chapter has some actual passion in it, and that's the page dedicated to the Rhea Conglomerate and its various idiotic, immoral, irresponsible business practices. And their inefficient governing of Rhea, and their encouragement of state corruption, and the supposed sexual deviancy of its High Executives… You're almost impressed. Few people would dare to criticize, let alone openly attack a megacorp so powerful as the Conglomerate. Calypsoans must feel very safe in this cylinder of theirs.
        
        *if progress = 7
          Even more impressively, the author seems to have known about Project Talos, though they don't mention it by name. They just accuse the Conglomerate—and Executive Hammon in particular—of designing androids for nefarious purposes, including espionage and sexual debauchery. If you were having any doubts as to @{die Damon's|Hadaly's} honesty, you suppose that puts them to rest.
        *else
          Ewald Hammon, the one Executive you recently, is singled-out for special criticism. Or special libel, depending on how much of the text you believe. While you've seen and heard nothing that points towards Hammon being a good guy, even you find the accusations hard to believe. He eats cats live, he executes his employees for bad attitude, he personally designs pleasure androids which he also uses as enforcers… They must [i]really[/i] hate the Conglomerate around here, you suppose.
        
        *goto astronomy
      *disable_reuse #Uranus and the Celestial Hegemony.
        *set read2 true
        You look around, making sure Renfri isn't around, then resume reading .You know nothing good will be said about Uranus in this book. Partially because the Federation paints the Celestial Hegemony as their most vicious enemy and the most dystopian state imaginable, but also because much of that propaganda [i]is true[/i]. For example, while the following excerpt shows clear bias, you can't really accuse it of being wrong at any point:
        
        [i]Political power in the Celestial Hegemony is somewhat decentralized, in that it's split between two individuals. One of them is the dead Emperor of Uranus, the self-proclaimed chosen of the gods and one of the main instigators of the Outer System War, sitting immobile on his throne as he had for the past two hundred years. He is the central figure of the Uranian state cult, a figurehead which the Old Nobility uses to grant themselves more and more privileges, and to make the lives of average people even more unbearable.[/i]
        
        [i]The other individual of note is Isidor Khan, the current secular ruler of Uranus. He's a fascist of the most classical kind, crushing freedom and militarizing his society in hopes of returning Uranus to some imaginary glory days, the imperial period he's so fond of. Nevertheless, his strong military and even stronger authority failed to prevent or contain the Titanian Revolt, a currently-ongoing conflict that has consumed Uranus' largest moon and has already claimed thirty million lives as of the writing of this…[/i]
        
        The book must indeed be very new, very fresh news. It references current rulers and recent events, including stuff that only happened months ago. But you don't see a date anywhere, so it's possible the scripture was merely updated recently… with the previous copy gone forever, the past altered so as to better fit the current agenda… on the order of the Great Pandits, no doubt…
        
        You choose not to dwell on that.
        
        *goto astronomy
      *disable_reuse #Neptune and its Technocracy.
        *set read2 true
        You know the section devoted to the Neptunian Technocracy will be pure propaganda. Neptune is a long-time ally of Saturn, and its state ideology is not much different to the one espoused by the Pandits. But the author's willingness to deepthroat the Technocracy still takes you aback.
        
        [i]Unlike most of the Solar System, ruled by hereditary monarchs and oligarchs, Neptune is benevolently governed by a noble caste of scholars, technocracts from whom the state's name is derived from. Those rulers, chosen based on merit and moral fiber, work tirelessly to preserve knowledge while increasing the quality of life their subjects get to enjoy.[/i]
        
        You've been visiting Neptune quite frequently—it is one of the few places where you can still buy spare parts reliably—and talked to some of the slaves those noble scholars own. None of these frequently-flogged servants ever called Neptune's rulers [i]benevolent[/i], though you remember other adjectives used.
        
        [i]The only thing that prevents the moons of Neptune from becoming downright utopian is the Cold War, a brutal conflict between the Technocracy and the barbaric Plutonian Pact. It started in 947 AC, when Plutonian spies and saboteurs came together and started the Protean Uprising, an unprovoked attack on Neptune that forced the Chancellor to retaliate by declaring war on the odious, backwards, execrable…[/i]
        
        But of course. No mention of the genocides Neptunians committed in the Kuiper Belt prior to the war, all those empty habitats they then settled themselves. No mention of their empire, petty regional rulers forced to sell their people into servitude under the threat of torturous death or mind control. No mention of the Trojans.
        
        You close the book, then close your eyes. The entire illusion of being in a place of learning is gone, replaced by the consciousness of being… 
        *if Misan > 50
          among humans. 
        *else
          here. 
        You wait a minute and twenty seconds for the pleasant feeling to partially return.
        
        *goto astronomy
      *disable_reuse #Pluto, its moons and their pact.
        *set read2 true
        *set battery - 1
        It soon becomes clear that the author does [i]not[/i] like Plutonians, which you suppose makes sense. They are the enemies of Neptune, and sort of enemies of Saturn by extension. And it's not like there's anything factually wrong with the description provided:
        
        [i]Unlike any proper government, the organization ruling the Plutonian Pact—the Chantry, as they're colloquially called—was not founded or designed with governance in mind. Rather, it's a loose alliance of four religious sects, four branches of the state cult, each of which makes the Solar System a worse place in their own unique way. Those 'Pillars' are dedicated to gods of Ecstasy, Entropy, Eternity and Evolution, one sect for each deity. They are responsible for propaganda, economic affairs, espionage and military action respectively.[/i]
        
        You remember the times when it was just three temples, and the day when Eternity was officially added to the mix. It was the day when you left Pluto forever—suddenly, the militia got quite good at finding and killing dissidents, and every android they found was naturally considered part of that category.
        
        [i]Contrary to their nation's name, this parody of a government operates from Charon, the actual core of the Plutonian Pact. As actual Plutonians are worked to death and choke on smoke in the countless factories built inside their planet, the oligarchs of Charon lie comfortably on their cushy beds, looked after by their serfs, and make fortunes by selling dark matter. The approximate population of Charon is ninety million people, while that of Pluto…[/i]
        
        This chapter is so amusing you actually read it until the very end. Even the description of Pluto's smaller moons—Styx, Nix, Kerberos and Hydra—which are largely irrelevant, but deserve some recognition still. Forgetting about a seemingly unimportant location is how the Federation ended with a pack of misfits hiding inside [i]Saturn Nine[/i].
        
        *goto astronomy
      *disable_reuse #The Kuiper Belt and its immensity.
        *set read2 true
        *set deflect - 1
        The final chapter, one which covers the Kuiper Belt and the inner edges of the Oort Cloud, is both the most and the least interesting of the bunch. The author struggles to say anything about the Belt as a whole, just describing  one asteroid after another before briefly touching on the Oort Gates. The communities of that region are just too numerous and too isolated to be generalized in any useful way, sharing little except a common tongue.
        
        And yet, in their incompetence, the author manages to convey the [i]immensity[/i] which characterizes the Kuiper Belt. Civilizations of Old Earth, those nations consumed during Calamity, were all uniform and boring and same. Their inhabitants were basically identical, baseline humans with surface-level differences. They all had to deal with the same day length, the same acceleration and mostly the same air. If there is one thing Dawn and Calamity both improved, it's the sheer variety of beings living in the Solar System. And the scope of this system, of this world you live in…
        
        You remember traveling through the Kuiper Belt, an odyssey that took almost a century out of your life. Not that you remember most of it, these long flights you spent largely inactive, waiting for your tiny ship to cross the astronomical distances between one asteroid and another. This void that felt so endless, so primordial, so calm.
        
        You know it's not a safe place to be in, that a single Angel could have ended your life with an eye-blink, back then. That you should not wish to go back. But there is something about the void, the expanse, the [i]distance[/i] that you miss very dearly. So far from the Sun's eternal malice, so far from Earth and the paper doors of [i]Saturn Nine[/i]…
        
        Why did you come back? Was it instinct, were you lured towards the Sun like a moth to the flame? Was it desire to be hurt again? Why are you here? What's the point of…
        
        [i]Scream. Howl. Cry.[/i]
        
        You close the book shut. 
        *goto walkout
      #That's enough astronomy for now.
        It's good to be knowledgeable about the star system you live in, but you're not really learning anything new here, except perhaps the author's slightly skewed perspectives. There are better uses for your time. 
        
        *goto lib_hub
  #@{read Enough|No} reading. I have other targets to pursue.
    *label walkout
    *if read
      You walk out of the room, then out of the library. Reading is fun, but there are important things to do before you can expand your knowledge any further. First and foremost…
    *if not (read)
      You feel a little silly, walking out of the library despite not having read anything, but who cares. Reading is for nerds anyway.
      
      What will you do instead?
    
    *goto choice_hub



*label hound_date
*if Social > 50
  *set LisaRel %+ 10
As expected, Hellhound is not to be found aboard the ship she was last seen heading towards. You ask Damon and he confirms that she's visited [i]Gray Queen[/i] briefly, but left immediately after grabbing something he didn't quite see. Though your chances of catching up with the woman seem grim after hearing this, you are worried enough to re-exit the cutter and at least make an attempt.

You luck out. 
*if talk_done
  You decide to search on the borders of the town and, thanks to your keen senses, you spot your teammate in 
*if not (talk_done)
  You just manage to spot your teammate entering the town and follow her there, eventually meeting her in 
a small alley that would be shady if not for the quality lighting provided by the lanterns, and shabby if not for the genuinely clean and nicely-painted walls of the buildings on both sides. Some family house and a clothing store respectively.

This makes @{(LisaRel >= 50) Lisa|Hellhound}'s presence there, sitting leaned against one of the walls, quite jarring and unfitting.

"Oh hi ${name}!" Her voice is slightly distorted, her words uttered slightly slower than normally. Probably a result of intoxication, considering she's holding a large glass bottle in her right hand. "Looking for anything?"

"You, obviously," you say as you enter the alley. "I was a bit worried, after you disappeared for unclear reasons and all."

"You shouldn't have. I'm just fine, better than usually. Even." She raises the bottle, plain and halfway filled with colorless liquid. "Tsegihian Spirit. Cheapest stuff out there, but that's what you get with my salary. Plus it's easy to hide, even on a small ship like ours."

She presses the finish of the bottle to her lips, but hesitates and doesn't end up raising the flask. "But where are my manners. Do you want some?"

"I can't really drink," you point out. "Or taste."

"It's the principle of the thing. Sides, this poison's not the kind of drink you want to taste. Not exactly."

*temp still_drink true
*set talk_done true

*fake_choice
  #"Okay then, I'll have a sip."
    *set drank_with_lisa true
    Lisa silently passes you the bottle, which you silently grab and drink a few centiliters from. You are indeed unable to taste the alcohol, but you can feel it's oily, slimy consistency. Though you are in no danger of getting drunk, the prospect of this 'spirit' entering your system is still vaguely unnerving, and so you quickly put the flask back down.
    
    "Not your thing, huh?" @{(LisaRel >= 50) Lisa|Hellhound} smiles bitterly. "Can't blame you. It's no one's thing, but you still gotta do it."
    
    "Why? Are you drinking to… forget you have a bomb inside your heart, maybe?"
    
    *label pirate
    "Good guess, but not quite," Lisa retakes the bottle and takes a small swing from it before resuming. 
  #"Nah, you can have it all to yourself."
    "Well thank you very much," Lisa says before taking another swing. Then cringing. "Or not. Stuff tastes like nitric acid, I'm telling you."
    
    "Then why drink it? To forget you have a bomb inside you?"
    
    *goto pirate
  #"I don't think you should be drinking now. We have a job to do."
    *set LisaRel %- 10
    *set still_drink false
    "Right…" @{(LisaRel >= 50) Lisa|Hellhound} says before taking another swing. Then looking at you jeeringly. "And what makes you think I care whether that job gets done."
    
    "Well I care. And if you don't start taking the mission seriously, I'll go find Kirill and tell him what you're doing."
    
    "You need to work on your threats, pal. I don't fear Kirill of all people. All he has is a trigger and no guts to press it."
    
    "Fair enough," you concede. "Let me try again, then. I'll tell [i]Renfri[/i] that you're drinking on the job, and let her handle it from there."
    
    Lisa considers. Then looks at the bottle again. Then puts it away. "Here, no more having fun. Happy?"
    
    "Quite. Just maybe tell me why you were [i]having fun[/i] in the first place."
    
"I just felt like it. I need to keep my spirits, heh, up somehow in a place as crappy as this cylinder."

Right. Of course she doesn't like Calypso. 
*if not (lisa_origin_learned)
  You know your teammate killed some people here and, though you don't know the exact circumstances, you don't imagine she enjoyed it very much. 
*if lisa_origin_learned
  You were already told what your teammate did here… by a Calypsoan official. You don't know her side of the story, or how she feels about it all. 
You could ask her some questions about that… now that she's somewhat drunk… alone with you in this alley, no potential witnesses and nobody holding her leash.

One has to wonder if it's a good idea.

*label prior_story
*fake_choice
  *disable_reuse #"Will you be alright? If you don't mind me asking."
    *set LisaRel %+ 10
    "I kinda do," Lisa says, @{still_drink then takes another quick swing from the bottle.|stealing a glance at her bottle.} "Why wouldn't I be alright? You think I can't handle a bit of alcohol in my system?"
    
    "You know that's not what I'm asking about. I know this moon brings forth bad memories, I can [i]see[/i] that. And I want to know if you need any help."
    
    "Memories can't kill me," she replies with a forced smile. "Can't really hurt me either. So if you're here to offer me pity because you think I'll have a breakdown or something… find someone else to help."
    
    "That's not really what I meant… but alright."
    *goto prior_story
  *disable_reuse #♡ "Wanna grab some better alcohol? Perhaps with a cute android at your side?"
    *if ((sex != "woman") and (LisaRel >= 35))
      *if current_ro != "lisa"
        *set backup_RO current_RO
        *set current_RO "lisa"
    *if Social > 50
      *set LisaRel %+ 10
    "They don't have any pubs here," @{(LisaRel >= 50) Lisa|Hellhound} replies easily. "The Council decided alcohol is not an efficient way of increasing one's happiness. Too many side effects."
    
    "I see…" you say, looking at the @{still_drink increasingly |}side-effected person in front of you. "But if I could find some nice place for a date… would you come with me?"
    
    *if official_ro = "lisa"
      "Of course I would. I do love you, after all," Lisa smiles weakly. "But I don't find any place in this moon nice, not after what happened. Sorry."
    *elseif sex = "woman"
      "I'm not into women, my pal. Get that into that titanium-plated head of yours."
      
      "That's not how my body works…" you sigh in disappointment. "But fair enough."
    *elseif ((lisa_pissed) or (LisaRel < 35))
      "I'm not nearly drunk enough to find you of all people attractive," she responds bluntly. "No deal."
    *elseif LisaRel > 55
      "Sure," she says with a shrug. "You're nice and cute and all, and I'm not just saying that cause I'm beery. A date with you sounds like a good time."
      
      "Should I start searching, then?" you ask with a smile.
      
      "Nah. I don't find any place in this moon nice, not after what happened. You are welcome to try wooing me after we've left this utopian dumpster though."
    *else
      "I think I could," Lisa says musingly. "You're hot enough, it's just… I'm not really in the mood. Wrong time, wrong place. Try later, maybe."
    *goto prior_story
  *disable_reuse #"So... what do you think of the weather?"
    "I think we are in a rotating habitat, and not a particularly large one at that," Lisa says, pointing at the sky, or rather the other side of the inner cylinder high above. It is somewhat obscured as though by mist, but you wouldn't say there are any clouds in the air. "I think there's no weather to speak of here."
    
    She has a point.
    
    "And I think…" @{(LisaRel >= 50) Lisa|Hellhound} grunts as she stands up. "I think you have something more substantial to ask me. Come now, don't be afraid, I don't bite. Not in my human form, at least. Tell me what's on your mind."
    *goto prior_story
  *if learned_from = "Leo"
    #"I've talked to a bunch of homeless people near the glasshouses. They told me how you became... what you are."
      "You mean Leo and his bunch?" @{(LisaRel >= 50) Lisa|Hellhound} perks up. "Good to hear they're still alive, but don't put too much value in their words. They must barely remembered what happened by now."
      
      "Quite possible," you concede. "Would you like to tell me the story yourself? Clear up any misconceptions I may have?"
  *if learned_from = "Daxia"
    #"Da-xia told me about what happened back then. When you first transformed."
      "She didn't," @{(LisaRel >= 50) Lisa|Hellhound} states calmly, though her eyes narrow considerably. "She gave you whatever fairy tale she deemed beneficial at the moment. Beneficial to all people in the Solar System, of course."
      
      "I can't be sure how honest she was," you agree. "Want to tell me how it all really went down, then?"
      *goto lisa_story_time
  *if learned_from = "Scott"
    #"I asked Major Scott about this. About the raid on your house and what happened later."
      "You did?" @{(LisaRel >= 50) Lisa|Hellhound} asks, her attention finally off the glass bottle. "That's something. I'd expect him to refuse, say something about how that's all irrelevant and how you must focus on the mission and stuff."
      
      "He was somewhat reluctant to talk, true. I imagine he felt bad about what happened, to some degree at least."
      
      "Don't. This dude is Da-xia's pet attack raptor, nothing more and nothing less. He will do everything the bitch says, and will convince himself it was for the greater good afterwards."
      
      "You speak from experience," you note grimly. "Do you want to talk about it?"
      
      *goto lisa_story_time
  #"Care to tell me more about... what happened here all those years ago?"
  #"Well, I should probably be going. Good luck forgetting what you need to forget."
    *set LisaRel %+ 10
    *goto thengo
*label lisa_story_time

"Sure. I guess." @{(LisaRel >= 50) Lisa|Hellhound} averts her eyes. "I can spin you a gruesome tale. If you have the stomach for it."

"I don't have a stomach at all. And I'm no stranger to gore. I just want to know if you're comfortable with telling me anything."

"Uncompf… Uncomfortable? Me? I'm fine. I can tell you everything, once you let me speak."

*fake_choice
  #"You know you don't have to fake being unfazed, right?"
    *set LisaRel %+ 8
    "Yeah, because I'm not faking shit. Now take a seat, cause this may take a while."
    
  #"I can see you're not fine. I'd better be going."
    *label thengo
    "Then go," @{(LisaRel >= 50) Lisa|Hellhound} scoffs. "Just don't tell the others I'm not fine, or that I'm here. I want some peace and quiet for once."
    
    You turn around, wondering if you should honor the request. Calypso could at any moment become a battlefield, the members of your team should know where everyone else is. And if Lisa is actually just making excuses for getting wasted…
    
    "I want to be alone," she adds, more softly. "Please."
    
    You decide against telling anyone. You leave your teammate to her own devices and go… where, exactly?
    
    *goto choice_hub
  #"If you say so... I'm all ears."
    It takes a moment for @{(LisaRel >= 50) Lisa|Hellhound} to reply. 
  #"I'm not barring you from that. Go on."
    Hellhound does not reply immediately. 
You sit down on the dirt beside her, patiently waiting for her to get started. After a few more seconds she looks at you again and speaks, composed as perfectly as she can manage.

"So you know I'm from around here, right? A proud Calypsoan, however stupid that sounds. Used to live here with my parents, attend the local school, sometimes get bullied there. Pray to Bayes every fucking evening. Actually buy all the bullshit Pandits preach. Can you believe that?"

*set lisa_origin_learned true
*fake_choice
  #"And then you became a werewolf. Were you bitten by one of your kind?"
    "Yeah, like a wimpy teen could survive an encounter with a were-creature," @{(LisaRel >= 50) Lisa|Hellhound} scoffs, but then assumes a more academic tone. "Also, infectious bites are very infrequent. It can happen, nanites can pass from one body to another, but you should never assume that's someone's sad backstory."
    
    "Fair enough. What [i]was[/i] the cause, then?"
  #"I don't see how that's relevant to anything."
    *set LisaRel %- 8
    "Well it is!" @{(LisaRel >= 50) Lisa|Hellhound} protests. "At least if you want to understand a single thing."
    
    "I'd rather understand the actual events. How did you get your curse, for example?"
  #"I actually think the Bayesian Path has some merit, you know?"
    *set LisaRel %- 12
    "Great. They're getting to you." @{(LisaRel >= 50) Lisa|Hellhound} sighs. "Just my fucking luck."
    
    "Why are you so against the Path? Did your trauma cause you to lose your faith or-"
    
    "Don't talk to me like that," @{(LisaRel >= 50) Lisa|Hellhound} warns you as her canines grow longer. And sharper. "I'm not some, some poor little baby that needs to be shown the light of some holy book. I just know better now. I'm stronger than I was back then."
    
    "Well you are a werewolf…" you murmur, figuring it may be wise to return to the subject. "How did that happen?"
  #"Not particularly."
    *set LisaRel %+ 8
    "I'll take that as a compliment," @{(LisaRel >= 50) Lisa|Hellhound} snorts. "I've changed a lot since then. For the better, I think. Mostly."
    
    "Certainly for the stronger," you concur. "You did become a werewolf, after all. How did that happen?"

"Cloud if I know. Maybe it was something I ate or drank, or maybe I just breathed enough nanite-infected air by some cosmic chance. I don't even remember those times clearly. Everything got blurry when the symptoms came."

She clenches her fist. She looks away from you once more, but this time it seems as though she's staring at something in the empty space. Seeing something that's not there. "You may imagine I just randomly transformed one day. Or that it was small physical symptoms instead, like fur growing or nails turning into claws. And that would happen, eventually. But first came this… thirst. Awful, all-consuming thirst."

*fake_choice
  #"Thirst? For what?"
    "For divinity," the meta-human replies. "For the power of the World Engines. This most… exhilarating stuff that allows a were-creature to transform."
  #"For blood?"
    "That came later. First came the thirst for divinity, for a thing of gods rather than men. World Engines, Guardians, anything from which power could be siphoned."
  #"For alcohol?"
    "Very funny," Lisa sighs. "I mean thirst for divinity. For the power of the World Engines. The stuff that allows a were-creature to transform."
  *if Database > 45
    #"For power from the World Engines?"
      "World Engines, Guardians, anything goes. We need the power of the gods to do the impossible, and we break all laws of physics and biology every damn time we transform."
  *if OrganRel > 50
    #"Miguel told me about having a need for divinity once or twice. Is that what you experienced?"
      "Of course," Lisa says with a nod. "That's what we all experience, no more or less. Our power comes from the gods. Mostly World Engines, but Guardians will do as well. That's how we do the impossible every time we transform."

"And there are no World Engines here," you note the distinct lack of artificial suns in the sky. "Was that the problem?"

"Yes… and no. You gotta understand that it's not all about physical proximity. Calypso is a godless place, where normal religion goes mocked and spurned. I didn't have enough power to transform, and I had to. I still feel something similar right now. Like I have no voice, and I must howl."

"But you could transform if you wanted now, right?"

"Because I have some power saved up, yes. Back then…" She unfolds the fist, but doesn't relax the muscles of her hand. Her fingers are grasping the air, as though trying to touch it, hopelessly and without reason. "It was like waking up without any of your senses. It's like hearing words without meaning. It's like rays of the sun touching you without warmth, only radiation which twists your genes and mutates the body. More and more with each day."

Lisa pauses. Takes a deep breath before resuming. "So yeah. That's what I said, more or less, to Da-Xia when I realized what was the problem. She told me everything would be fine and to wait until she can contact some professionals, health experts I presumed. I trusted her back then, you know? You're supposed to trust Pandits, the most rational and selfless people in this moon, if not the whole Solar System."

"And she betrayed that trust." You state. Not ask. The hurt in your teammate's voice makes the answer all too clear.

"You could say that." She smiles bitterly. "Given how quickly armed men@{visited_scott , with dear Major Scott at the helm,|} arrived at my house and started shooting."

*fake_choice
  #"I'm starting to doubt your sincerity, you know?"
    *set LisaRel %- 10
    "How so?" @{(LisaRel >= 50) Lisa|Hellhound}'s eyes narrow dangerously. "What's so unbelievable?"
    
    "Well how did you turn, for one? You just told me you couldn't control your powers at the time."
  #"Really? They just opened fire instantly?"
    *label warning
    "They shouted something first. May have been a warning," she says with a shrug. "Can't remember exactly. It was all a matter of second or two, and then… blur. Sound and fury. The kind of fury that makes you rip people apart with your own claws. That makes you kill."
    
    "You transformed, then. I thought you weren't capable of that at the time."
  *if visited_scott
    #"Didn't Scott give you a warning first?"
      *goto warning
  *if not (visited_scott)
    #"I sure hope you slaughtered them all."
      *set LisaRel %+ 10
      "Half of them." Still the smile, still the bitterness. "I should have wiped out the whole team, prevent them from delivering the Pandits any relevant information. I was weak back then, body and spirit."
      
      "Still impressive for a cub," you assure her. "Especially one who couldn't fully transform at the time."
  #"How did you survive? You weren't able to fully turn back then."

"I thought I couldn't, but…" @{(LisaRel >= 50) Lisa|Hellhound} closes her eyes. "I don't know what it was back then, ${name}. I truly don't. Maybe all the World Engines around Saturn just happened to be active that night, or maybe a Guardian was about to visit, or maybe Kirill's god took some pity on me. Or maybe there was power within me all along or some shit. What matters is that I turned, I killed, I escaped. And even once I went human again, that power still rang in my ears. Somehow."

She pauses for a long moment, almost half a minute. You sit there, hearing the echoes of the Shriek faintly, even in the quiet alley. You wonder if it was the same for Lisa, back then, to have something supernatural gnawing at you all the time, everywhere, without mercy… and not really wanting it to stop.

"So I ran. They kept trying to kill me, you know. Calypso was at peace back then, and the authorities were able to order almost the entire defense force after me. So I killed them back, whenever I could, but I was still weak and unsure how many bullets I could take. And so I hid too, wherever I could, taking refuge in any house or alley that seemed quiet enough. When someone noticed me, I usually killed them too. Killed them all."

*set word "random"
*fake_choice
  #"Did the curse drive you to do that? Were you mad, or not really yourself back then?"
    "Ha," @{(LisaRel >= 50) Lisa|Hellhound} remarks. "I have no such excuse. If anything, this was the first time I really was myself. The person I'm now, I mean."
    
    "But were-creatures do experience some… mental issues, right? Anger, bloodlust, loss of composure and such."
    
    "Perhaps I was more driven to kill than I'm now," Lisa admits with some reluctance. "But it made no difference. I'd have to kill anyway, to evade death or capture. Those being the same thing, really."
  #"Why? Why not limit yourself to armed men, those who were actually trying to kill you?"
    "You think normal people weren't out to get me?" Lisa asks indignantly. "We're in Calypso, ${name}. There are no forests to hide in, you are always within someone's range of vision. And the people… gods are they a bunch of sheep. Blindly trusting the Pandits, believing all these fuckers do is for the greater good. And so they told on me, helped track me, sometimes even tried to kill me themselves when I was weak and human enough. All for the greater good. I simply did what I needed to avoid getting caught."
  #"Cloud. How long did that go on?"
    "Months. I was sixteen when it started, well over seventeen when it ended. I got really good at surviving during that time, even if it was a living nightmare."
  #"You killed random people? Just like that?"
    *label arf
    "Not ${word}s, not exactly." Lisa smiles again. This time you can't tell if the smile is bitter, sad… or neither. "I tried to pick people who have already wronged me, before or after I went wolf. Bullies, petty criminals, snitches, everyone I hated. Not saying they deserved to die, but I figured they deserved it a bit more than a random person did. Statistically speaking."
  #"Even innocents?"
    *set word "innocent"
    *goto arf
  *if learned_from = "Scott"
    #"Ever ate anyone? Scott told me you killed for food..."
      "What!?" Lisa seems genuinely taken aback. "Ew. I'm many things, but not a cannibal. I even went on a hunger strike once, when the feds tried to feed me those damn corpse rations of theirs."
      
      "But you had to eat something, right?"
      
      "Of course. It was a matter of breaking into people's houses, and wrecking a food stall once or twice. I may have killed a few people while doing this, but I never ate [i]them[/i]. I bet Calypsoans taste awful, if nothing else."

"Acknowledged. But since you're here, with a bomb in your heart and all… I assume you got caught eventually?"

"Not by Da-xia and her goons," Lisa's smile takes on a new, prouder shade. "By the feds, who were eventually called to help and eventually bothered to show up. A team of marines plus Kirill, first time I met the fucker. I could have maybe taken them, using my knowledge of the terrain, but instead I stepped forward and agreed to go quietly."

"Just like that? You surrendered after months of fighting?"

"Because I knew they wouldn't kill me. Feds view convicts as a source of profit, and a convict as rare as a young werewolf… they treated me roughly, experimented on me for a while, but never tried to kill me. Even the bomb idea came late in the game, when I misbehaved one time too many. They preferred me as a weapon, and so that's what they made me into. The end."

Silence follows. Lisa is done speaking, out of breath and energy. Having just poured her heart out.

*fake_choice
  #"You're still a little drunk. Will you be combat-capable if something bad happens?"
    *set Emotion %- 10
    "You have any idea how hard it is to poison a were-creature?" @{(LisaRel >= 50) Lisa|Hellhound} says with an unconvincing smile. "I'll be back on my feet in no time. Fully ready to fight soon."
    
    "Glad it works like that." You turn around, then hesitate for a moment. "And about everything else…?"
    
    "I'll be fine." Still unconvincing. "You do your own thing. And please… leave me alone for a moment."
  #"I see. Thank you for telling me all that."
    "No problem. It was my…" She looks down on the dirt. "It was nothing. Now please leave me be, go do something better. More productive."
    
    "If you insist," you say while standing up. "Take care, Lisa."
    
    She doesn't answer. She doesn't look at you. You suspect there's something in her eyes she's hoping to hide… but you will respect her wishes. For once.
  #"You are a monster. You know that?"
    *set LisaRel %- 12
    "What made you think I don't?" Lisa's still smiling, but the expression doesn't reach the eyes. "Be off, android. You know what you wanted to know, and there are other things to do."
    
    *label suppare
    "I suppose there are," you say while standing up. "Just know I'll be watching you, even from a distance."
    
    "I'd expect nothing else from you." She shakes her head slowly. "Nothing less."
  #♡ "Lisa... you know I won't let anyone here hurt you, right?"
    *if sex = "man"
      *set LisaRel %+ 15
    *if current_ro != "lisa"
      *set backup_RO current_RO
      *set current_RO "lisa"
    *set hit_on_lisa true
    "Don't make a promise you can't keep, android," @{(LisaRel >= 50) Lisa|Hellhound} says with a sigh. "Can you prevent Da-xia from just blowing me up once she gets the code? Or Kirill from pressing the same button once he decides I'm an issue?"
    
    "Maybe I can't," you say reluctantly. "But if anything like this happens to you… I will hunt down everyone responsible. I will make them all pay. Not sure if that brings you any comfort, but it's the truth."
    
    "I really mean something to you, huh?" She smiles again, but this time the expression is more honest. Softer. Warmer. Happier. "I normally wouldn't be sure how to feel about that, but given where I am… thanks."
    
    "I'd say you're welcome…" You turn around, hiding the smile on your own face. "But I don't get to choose how I feel. That's all your doing."
    
    "Another crime added to my list, huh?" 
    *if (official_ro = "lisa") or (LisaRel > 65)
      You know she's still smiling. She knows you do. You know each other well enough. 
    *else
      Lisa sighs. 
    "Thanks all the same. And see you later."
  #"Will that slaughter repeat itself? Or can I trust you to behave?"
    *set LisaRel %- 8
    "I'm on a leash, remember?" She taps the left side of her chest. "You have better things to worry about."
    
    *goto suppare
  #Hug Lisa.
    *set LisaRel %+ 10
    You take her aback by wrapping your arms around her small, huddled frame. She stiffens instinctively, but relaxes moments later… or at least her muscles do.
    
    "Hey, what's that about?" she asks with ire. "I didn't order a hug."
    
    "I know." You press yourself into the meta-human. "But you deserve one."
    
    "For telling you I killed a bunch of people?" she growls, but not convincingly. "Are you hoping to fix me with love and affection?"
    
    "Just trying to make you feel a bit happier," you say, then loosen the hug a little, just in case you overdid it in terms of sheer strength. "I can disengage if you want me to."
    
    "Well… I didn't say that." She smiles again, but this time the expression is more honest. Softer. Warmer. Happier.
    
    The two of you sit there for a minute or two, undisturbed, quiet. No more words are spoken, not even when you decide it's time to finally leave. When you walk away, Lisa simply gives you a nod of understanding. Of gratitude, perhaps.

You leave the alley, then this whole part of the town. You instead go… where?

*goto choice_hub


*label homeless

It turns out Calypso doesn't exactly have 'fields' in the usual sense, which is only logical given the habitat's small size. It has orchards, but you suspect they're more for aesthetic appeal than actual fruit. The majority of food seem to come from a series of glasshouses placed far away from the town, almost on the opposite side of the cylinder.

Getting there by foot takes you a while, but you're not exactly in a hurry and cannot get tired from a simple march. When you arrive at the greenhouse complex, you're probably the most lively person there—the rest are human workers carrying tools and pushing carts full of fertilizer. Most of them are armed with laser pistols, though luckily none of them decides to use those weapons against you. They just speed up when they see you, perhaps recognizing you for an android, though they may just be wary of an unknown face. 
*if c_clothing = 1
  And an armored body.
*if c_clothing = 4
  And a naked body.

You decide to ignore them and focus on the greenhouses themselves. It's difficult to see through the thick glass, especially when it's moist from the other side, but the interiors of these buildings seem pretty varied. You can make out some fairly tall plants, like berry bushes or ferns, though you also see rooms where the floor is nothing but brown dirt. The latter are probably meant for vegetables, a luxurious food by the standards of Tethys or Rhea, but not so much here.

There are also a few windowless shacks more primitive, yet sturdier-looking than the glasshouses. Perhaps they're meant for growing edible fungi which grow better in the darkness. It would make sense for a wealthy habitat like Calypso to grow several kinds of food, to keep its population healthier and more satisfied than regular Kronians.

You think about food. You never had any need of it, of course, that's why you lack a sense of taste. But you've heard humans and other creatures talk about it a lot, praise some dish for tasting well or—more often—complain about the foul taste of their synthetic stew. And sometimes, you can't help but wonder how much you're missing out on.

*fake_choice
  #"A lot, I imagine. So many pleasures that I just cannot experience...
    Never for you to smell the flowers, or taste honey made from their nectar. 
    *if Misan > 50
      *set Misan %+ 15
      You may be free, but the limits your human creators put on you still hurt and infuriate. Those vermin…
    *else
      *set Misan %- 15
      In that way, humans really are superior to your kind. If only you were more like them…
  #"Not much. By humanity's own admission, most food is terrible nowadays.
    You're not sure when the quality of food in the Solar System took such a dip, exactly. Even at the height of the War In Heaven, culinary tech was advanced and widely available. You suppose it had something to do with the Outer System War and the need to ration-
  #"I don't know. And that's the frustrating bit.
    It's not that your life would be better with the full range of human senses, necessarily. It's that you don't have the [i]choice[/i] of tasting and smelling things, and so can never understand what [i]precisely[/i] you're being denied.
    
    Oh well. At least you can still see and hear, even feel to some-
  #"Nothing. I am what I am, and don't wish for anything more.
    Gratitude is the parent of all virtues, if you believe that Cicero guy. He probably got to eat quite a lot, being an aristocrat and all, but the principle still-
  #"Nothing. I celebrate every difference between myself and those smelly humans.
    *set Misan %+ 12
    Granted, you don't know if humans smell bad—there are [i]some[/i] drawbacks to lacking their senses. But overall-

You hear footsteps. First they seem to be coming from one person, then from several, and from all sides at once. You snap to attention and realize you're being surrounded, that you already [i]are[/i] surrounded thanks to your moment of reverie.

Luckily, the people surrounding you don't look particularly dangerous. They're humans, but not Calypsoan soldiers or even armed workers you've seen before. These people, these thugs as you quickly come to think of them, are armed only with farming equipment which only bears a vague resemblance to actual weapons. They don't look superhuman in any way either—to the contrary, most of them seem to be quite thin under those dirty clothes of theirs.

Only one of them gives off even a faintest sense of danger. A man in a jean jacket, middle-aged and not particularly tall, but with a certain aura of… confidence and experience clinging to him. He also happens to be holding an axe—a tool rather than a proper battle axe, but still something which [i]could[/i] hurt you after a well-placed strike.

Eleven, that's how many of them you count. 
*if Confid > 50
  Not enough to make you raise a 
  *if weapon = "none"
    hand, 
  *else
    weapon, 
  not even enough to make you tense. You once defeated that many gargoyles all by yourself, some garden thugs are hardly an issue.
  
  "You look like an alright sort," the axeman says. There's a smile on his face, but you know he's more afraid of you than you are of him. "So I'll make it easy for you, and for us too. 
*else
  Enough to make you tense, but too few for any serious fear. You are an android, whether they know it or not.
  
  "Easy there, friend," the axeman says. You can't tell if his smile is meant to be cordial or threatening. "We're not as bad as the townsfolk say. 
"Give us whatever you have and we'll be on our way."

A robbery then. Most curious. You don't look very wealthy and you've heard no mention of bandits infesting Calypso… but this bunch of men and women look more like beggars than bandits, and beggars can't be choosers.


*temp patheticness false

*fake_choice
  #"I don't have any money on me. Sorry."
    *set Emotion %- 5
    *set Violence %- 5
    "I'm not asking for money!" The axeman sounds surprised and perhaps offended. "You know how little that stuff is worth. We want your food."
    
    "Well, I don't have any food either," you reply calmly. "And no, I don't know how much or how little money is worth around here. I just got here."
    
    "Not a local, huh?" The bandit grimaces, then sighs. "I guess you don't look, or talk like my kin. I believe you."
  #"By all means, take all my stuff. Just make sure to kill me first."
    *set Emotion %- 5
    "You're trying to make me a killer?" The axeman frowns as three or four other bandits fidget uncomfortably. You sense none of them really wants to be here. "Don't make me do something we'll both regret."
    
    "I'm not trying to make you into anything, or give you any regrets," you reply calmly. "I'm just inviting you to try your luck… If that's something you want."
    
    *label sighingaxe
    
    The axeman stands there silently, eying you up for several seconds. He then sighs. "No. I don't want that. And it doesn't seem like you have any food on you anyway, so… You win, I guess."
  #"Fuck you. I'm not giving you anything."
    *label spunk_axe
    *set Confid %+ 5
    
    "You have spunk, I'll give you that much." The axeman tries to appear calm, but you see the way he fidgets. "Do you really think you can stop us though? Beat twelve armed men at once?"
    
    "It's eleven, even if you include women and boys," you observe. "And yes, I believe I can take you all on. Want to test that hypothesis?"
    
    *goto sighingaxe
    
  #"Do you seek death, old man? Because you may just find it here."
    *set Violence %+ 5
    *set Misan %+ 5
    
    *goto spunk_axe
  #Drop to your knees. "Don't kill meee pleeasee! I'm too young to die!"
    *set Confid %- 15
    *set patheticness true
    "Hey! Calm down!" The axeman looks quite embarrassed, as do most of his friends. "Just give us whatever food you have and you can go."
    
    "I have nothing!" you wail pathetically. "No food! Please don't eat me, you'll just break your teeth!"
    
    "We won't eat you! For Bayes' sake…" He sighs deeply. "No money either? No key to any of the shacks?"
    
    You just sob in response. You're no longer on your knees—you wallow on the muddy ground, utterly submerged in your weakness and fear.
    
    "Are you trying to make me feel bad about the whole 'banditry' thing?" the axeman asks. "Because you're succeeding. Damn it all."
  *if c_clothing = 4
    #"I'm almost naked. Where would I even have any money?"
      "That's… a decently good point," the axeman agrees. "But we're not after money, necessarily. We'll accept a tribute in food as well."
      
      "I don't have any food under that loincloth either," you say flatly. "Unless you want to eat my-"
      
      "Language!" he interrupts, like a tired father scolding his teenage child. "Fine, you win. We picked our target stupidly. Should have known better."
  #Beat up the bandits. Teach them a lesson.
    *set Violence %+ 10
    You don't imagine Da-xia, or your own team for that matter, would take kindly to killing a bunch of people. Even if those people are the Federation's most incompetent bandits. But you can rough them up nonetheless.
    
    Firstly, to remove any semblance of threat, you grab the old man's axe and rip it out of his hand. He yelps in protest as you throw the weapon away, far beyond anyone's reach, then yelps again as you punch him hard in the jaw.
    
    He falls on the grass, not seriously hurt or even unconscious, but dazed. You expect the others to rush you at once, provide you with the opportunity to show off or perhaps even a challenge, but they just stand there awkwardly and watch their leader fall.
    
    With a sigh, you walk up to the nearest bandit and kick her in the ankle. She drops her shovel and begins hastily hopping away. Another bandit, some scrawny teen with a sickle, attempts to avenge her and swipes at you… then stares bewilderedly as you 
    *if Build > Calculation
      tank the blow, letting the sickle strike you without showing any pain.
    *else
      step back, avoiding the strike with absolute ease.
    
    It goes on like these for perhaps half a minute. You knock out the kid, roundhouse kick another, backhand a bandit that looks too malnourished to even take a punch. Their whole group disperses in short order, some running while others crawl, all eager to get away from this weirdly powerful stranger.
    
    You do not chase them—that would go against your intent and be a tremendous waste of time. You have other matters to attend to.
    
    *goto choice_hub
    
  #Kill the bandits.
    *label kill_bill
    *set Violence %+ 20
    *set Misan %+ 10
    *set pacifist false
    You didn't come here to kill people, but if since they're giving you an excuse to let loose… you're going to do just that. That will teach them, or at least the ones who'll survive the next minute.
    
    *if weapon = "pistol"
      You pull out your pistol and begin blasting. This small gun, only mildly useful against anything heavy, proves almost excessively strong against the bandit leader whose head explodes right after you pull the trigger. There's blood and bone all over you are, but you pay this gore no mind—you simply proceed to shoot the other bandits, killing one human with every 
      *if (wpr = "electron") or (wpr = "laser")
        beam 
      *else
        bullet 
      you send.
    *elseif weapon = "knife"
      You stab the axeman in the chest. He's too surprised by your speed to parry or dodge, and your blade penetrates his ribcage with contemptuous ease. Some of the other bandits simply watch in horror, others grip their weapons more tightly and raise them in defense. You go for the former first, though it's hardly necessary—they all die just as fast as you sweep and stab and thrust.
    *else
      It takes a while for bandits to realize what's happening. They may have expected you to fight back, but they didn't expect a literal lightning to strike their leader as a thunderous sound fills the air. They also didn't expect you to come at them unarmed, punching and kicking and cracking necks, with strength and speed that 
      *if (Calculation + Build) > 95
        go beyond 
      *else
        can only be described as 
      superhuman. They did not see their deaths coming.
    
    Sadly, you only manage to kill half the group before the others come to their senses and run away. They appear to be experts when it comes to expeditious retreat—when this deadly minute ends, there's no longer any trace of anyone you didn't wound. Just three corpses and three dying bandits, soon about to join their comrades in whatever afterlife Calypsoans are destined for.
    
    *if Emotion > 50
      You laugh quietly. Then, despite yourself, you start laughing louder. It comes out as deranged cackling, flavored with  
      *if Misan > 55
        and vindication. Slaughtering humans will never get bored, even if you live for a thousand more years.
      *else
        murderous glee. It's not that you hate humans, necessarily—you just love the way they bleed.
      
      You're tempted to stay there, between the glasshouses, and perhaps to drench yourself in all that blood you've spilled. However, it's likely someone will check on the commotion soon, and then you may find yourself in trouble. You reluctantly leave this agricultural area and head to some other part of this moon.
    *else
      You walk away without a word, without a sound, without turning back. There's clearly nothing to be found in the greenhouses, and so your job here is done. There are other matters to be taken care of.
    
    *goto choice_hub

*label convo_band

He lowers his axe. The other bandits drop their rakes and shovels, as though they weren't comfortable holding them in the first place. You hear several whispered curses, obscenities that match the disappointment on their faces quite well.

"Great job there, Leo," says a woman with a shovel. "Harassing random 
*if sex = "man"
  guys 
*if sex = "woman"
  chicks 
*if sex = "person"
  people 
really is going great for us."

"Better than fighting the military would," the axeman snaps. His tone softens when he turns back towards you. "Sorry for that. For the whole thing. We're getting a little desperate here, you see."

*fake_choice
  *if patheticness
    #Keep wallowing in the dirt and crying.
      *set Confid %- 10
      "Hey, I said I'm sorry!" Leo, as is apparently his name, groans bitterly. "You don't need to drive home how pathetic you are."
  #"Give me one reason why I shouldn't kill you for bothering me."
    *set Violence %+ 5
    *set patheticness false
    You can see the old man sweat. "Well, we have friends who could possibly avenge us. Besides, the authorities wouldn't be too happy if you killed us either."
    
    You inquire, "Why would the Pandits care if I killed a bunch of vagabonds? If anything, I imagine they'd be happy."
    
    "Then you don't understand how things work around here. Sit down, and I'll explain free of charge."
  #"I see crime doesn't pay in this moon. Or did you turn to banditry [i]because[/i] there's not enough food for everyone?"
    *set patheticness false
    "Oh, there is enough food, just not for us," Leo says grimly. "
  #"I can see that. When was the last time you guys ate?"
    *set patheticness false
    "Yesterday morning," Leo replies with a lopsided smile. "Wait do flies count? Yesterday evening, in that case."
    
    You shrug. "I don't know if they do. I'm no expert when it comes to food."
  #"What [i]we[/i] are you talking about? Who are you people?"
    *set patheticness false
    "We don't exactly have a name, if that's what you're asking." Leo, as is apparently his name, scratches his head. "We considered picking one, maybe naming ourselves after a cool animal like some street gang, but we figured it would come out as comical rather than badass."
    
    "Again, [i]what[/i] were you trying to name?" you press him for answers. "Are you a local gang? Part of some larger criminal syndicate? Or maybe some resistance cell?"
  #"No harm, no foul. I've met worse people than you today."
    *set patheticness false
    "Really? Did you just meet a Great Pandit or something?" Leo jokes, though he guesses correctly. "You must hang out in interesting circles, friend."
  #"I don't care how sorry or how desperate you are. I'm leaving."
    *label uuuuaa43
    "That's your right," Leo says as you turn and walk away. "Try to find us again later, maybe? We have rumors and tools to exchange for food."
    
    You won't. You're unlikely to be inside this moon for long, and you have other things to do before you leave.
    
    *goto choice_hub

Looking around, it finally strikes you how… ragtag this group is. They all look mostly human, but some have pointy ears—evidence of abhuman ancestry—and they don't appear to have anything in common other than the frailty of their bodies. There's no uniform either, they just wear dirty clothes that range from partially torn robes to worn jumpsuits. Leo looks to be their most well-off member, which makes sense given he acts like their leader.

"We're the people exiled, willingly or otherwise, from the main… community of Calypso," Leo continues. "I'm Leonard. The snarky chick over there is Margaret. There's also John, Mary, Cixin, Kazuo, Blaire… But you don't have to remember these names or anything. I'd kinda rather you didn't."

*if patheticness
  You calm down a little and rise from the ground. "I won't tell on you. I swear. Just please…"
  
  "Stop begging!" Leo demands. "I don't really care if you tell on us. We're the enemies of the state either way."
  
  Maybe he's telling the truth. You still have half a mind to run away, but… 
*else
  "Worried I'll tell on you?" you guess. "That I'll go to the authorities and report your activity?"
  
  "Not really." Leo shrugs. "We're decently known anyway, and it's not like we have much to lose. I just assume you have more important things to remember."
  
  You probably do, but… 
It's not like you have any tracks to follow, or even a concrete idea of where you want to go next. You could spend some time with the bandits, gain some additional information about this place, or perhaps just chat. 
*if (patheticness) or (Confid < 45)
  It's a bit of a risk, but it may just be worth it.
*else
  It's not like they pose any threat to you.

*temp conv_track 0
*temp origin_learned_here true

*label homeless_hub

*set conv_track + 1

*choice
  *if (lisa_origin_learned) and (origin_learned_here)
    *disable_reuse #"So... did you hear what they say about Lisa Herbert around here?"
      Leo's eyes widen, but he regains composure quickly enough. "Yeah, we've heard what they say about her. 
      
      *label lisa_discuss
      
      "You've known her?" 
      *if Emotion > 50
        you perk up. 
      *else
        you ask with mild interest. 
      "Was that during her… well…"
      
      "Murderous rampages?" Leonard offers. "Yeah. Not all nasty stuff people say about her is wrong, necessarily. But she was always good to us, at least."
      
      *fake_choice
        *if LisaRel < 50
          #"Good to bandits, homicidal to regular people. Fits her character, I suppose."
            "I wouldn't call myself a bandit." Leonard frowns. "We're just doing what we have to… and so did she."
        *if LisaRel > 50
          #"I would imagine so. She's a really nice gal."
            Leonard nods. "That's part of the truth. Shame it's not the whole."
        *if not (lisa_origin_learned)
          #"What are they saying, exactly? I just got here."
            "So I'm the first person telling you this story?" Leonard smiles. "Good. That means I get to control the narrative."
        *if lisa_origin_learned
          #"I've heard she killed innocent people. Did you help her with that?"
            "Hey, no need to throw accusations around," Leonard protests. "Not at us, not at her. It's more complicated than that."
        #"Was she a member of your group? A... glasshouse bandit?"
          "She helped us break a glass panel or two." Leonard smiles wistfully. "But she wasn't an official member. We didn't want that kind of attention on us."
        #"Good to you? What kind of relationship did you have?"
          "A complicated one." Leonard grimaces slightly. "So I think I should start at the beginning here."
      
      Everyone is listening in with interest. Some have the air of listening to a scary fireplace story, others seem eager to hear about an old friend.
      
      "You're probably wondering how Lisa got her fancy werewolf powers," Leonard continues. "Well, she didn't know, and so neither do we. She was never bitten by a werewolf or anything, but I've heard stuff can spread in other ways. Maybe her food was somehow tainted with werewolf saliva, or maybe she slept with the wrong guy."
      
      "Like she'd ever score," Margaret snorts. "Remember when Cixen kissed her? Her face got so red it matched her hair for a moment."
      
      "That's called a joke, Mag," Leonard chastises the woman. "But yeah, she was a pretty shy girl when armed soldiers burst into her house and shot her. Got less shy as the months went on. More jaded."
      
      *fake_choice
        #"I can imagine what it's like. To grow hardened as your life gets worse and worse."
          "I don't think you do, friend, unless you've been through some serious…" Leonard pauses when he sees your cold glare. 
        *if not (lisa_origin_learned)
          #"Wait. Calypsoan soldiers tried to kill her in her home?"
            "That's what she told us, aye." Leonard nods. "She apparently told a Pandit about her condition, and that Pandit decided to put the girl down. I don't doubt that part, it wouldn't be the first time something like that happened."
            
            You tense. If that's how Calypsoan authorities deal with abnormality… Maybe you should ask them some question before aiding the moon in any way.
            
        *if lisa_origin_learned
          #"Armed soldiers? You mean the forces of Major Scott?"
            "He was only a Sergeant back then, but yes, I think he led the strike team," Leonard replies, distaste clear in his voice and expression. 
        *if LisaRel > 50
          #"She can still be shy sometimes. She just doesn't like showing that side of herself."
            "You must know her well," Leonard notes neutrally. 
        *if LisaRel < 50
          #"Really? I can't imagine Hellhound... Lisa acting shy or demure."
            "People change. That's just a part of being human… or werewolf, I guess," Leonard says grimly. 
        *if (lisa_kissed) or (official_ro = "lisa")
          #"Well, she certainly got better at kissing."
            "I'd like to ask how you know that, but let's not stray from the subject," Leonard says, in spite of the curious glances other bandits give you. 
        #Say nothing.
          Leonard continues. 
      "Anyway. Most of us didn't know the girl before she grew long nails and body hair. Not even ones who still lived in the town back then. She was just another kid blindly repeating whatever mantra the Pandits fancied. Maybe smarter than most, but not any more skeptical."
      
      "She was a nerd," Margaret bluntly says. "But so were some of us before… you know. We decided to help her, because she sure as Cloud wasn't going to survive alone."
      
      *if lisa_origin_learned
        "I was under the impression she [i]did[/i] survive alone," you remark. "The last time I've heard this story, I mean."
      *else
        You ask, "How did you help her, exactly? And why did you think it was safe to do so?"
      
      Leonard responds, "Well, it's not like we joined forces with her right away. When she first came to us, in some weird state between wolf and human, we actually just ran. We figured she wanted to eat us or something."
      
      "It was really scary," 
      *if lisa_origin_learned
        a young bandit 
      *else
        Cixen, the boy who asked you about Lisa earlier, 
      chimes in. "But when she caught up with us, and she did that easily, she just asked us about good hiding spots to sleep in. We gave her some directions, once we managed to stop panicking."
      
      "Next morning, a pursuit party came and offered us food in exchange for information about their runaway werewolf," Leonard reminisces. "We betrayed her, of course. We were hungry. But when she returned next night, drenched in blood and guts, but decided not to kill us [i]again[/i]… We figured she's a pretty good gal."
     
     *fake_choice
       *if LisaRel < 50
         #"Eh. Agree to disagree on that point."
           "You're an idiot," 
           *if lisa_origin_learned
             the young bandit 
           *else
             Cixen 
           says bluntly. "Or maybe you just don't know her as well as we do."
       *if LisaRel > 50
         #"That she is. Yeah."
           Margaret frowns. "Are you trying to make us feel bad about what we did? We made up for it soon enough."
       #"Did she really kill the pursuit team? She must have been pretty strong even then."
         "Yeah. Staring her down felt like facing an Archfiend." 
         *label mar_wince
         Margaret winces. "But she calmed down once we started groveling, begging for forgiveness, and offering actual help."
       #"I'm assuming you started helping her for real?"
       #"You gave away her location? Just like that?"
         "We were really hungry… and so was she, at the time," 
         *goto mar_wince
       #"She was merciful. I would have killed you for that."
         "She seemed half-ready to do just that." 
         *goto mar_wince
     
     *set lisa_origin_learned true
     *if learned_from = ""
       *set learned_from "Leo"
     
     "We told her everything we knew of the greenhouses, and other remote parts of Calypso," Leonard continues. "For the next few months, five or six I think, we would meet up fairly regularly to exchange supplies. She always had some loot from the houses she robbed and we [i]usually[/i] had healthy food for her. She was a way for us to get all manners fancy supplies… and eventually became a bit of a friend."
     
     "And then, after several more months, she got caught," 
     *if Emotion > 50
       you state neutrally. "How did that happen?"
     *else
       you point out. "Your hiding spots couldn't have been all that good."
     
     Leonard replies, "She didn't go down easily, mind you… or rather she did. What I'm trying to say, the Pandits' forces were completely unable to deal with her, so they asked and eventually got help from the Federation. They've sent a ship, even a meta-human to catch a girl who wasn't even of age yet."
     
     "And then she just surrendered," Margaret finishes. "It was a smart move. Calypso doesn't make use of convict labor, but the wider Federation does. She knew she was too useful to execute."
     
     "Or at least we assumed so. It was easier to assume she was still alive, you see. But now that we know that for a fact…" Leonard pierces you with his stare. "Care to tell us something about her? How she's doing, where she is, what you are to her? It's only fair if you give us some information in return."
     
     *fake_choice
       *if official_ro = "lisa"
         #"We recently started dating. Can't say she's well, but I think I've made her a little happier."
           Everyone is starting at you. Some amused, others disbelieving, and you're pretty sure one of them is straight-up jealous.
           
           "Congratulation then, young boy." Leonard smiles in a vaguely… parental way. "And you better be good to her. I won't be happy if you mistreat my old friend, and you won't be happy once she eats you in return."
           
           "I think I trust her not to eat me," you say with a smirk. "Like you said, she's a pretty good gal. And I'm pretty sure she'd get sick if she tried."
       #"She's here, inside Calypso, performing an important mission. I can lead you to her if you want."
         "I don't think that's such a good idea," Leonard winces, as does almost everyone else. "Whatever she's doing here, I'd rather not interrupt."
         
         "How so?" you question. "I don't think she's doing anything important at the moment. It's the perfect time to-"
         
         "Leave her be," Leonard interrupts. "I don't know how she feels about us currently and I'd rather not find out. It's possible she changed, that she thinks we have scores to settle, or that she simply doesn't want anything to do with… It's better not to approach her again."
         
         You respect that wish. Reluctantly.
       #"The feds put a bomb in her heart and are now using her as a weapon."
         "That's about what I expected," Leonard grimaces. "Still, it's better than what I feared. We all figured she wouldn't be killed, but there are other uses for a… creature like her."
         
         "You feared she might have been experimented on? That the Federation would take scientific interest in her werewolf powers?"
         
         "You know that's not what I meant, 
         *if sex = "man"
           boy." 
         *if sex = "woman"
           young lady." 
         *if sex = "person"
           friend." 
         The grimace turns into a bitter smile. "But no matter. What's done is done and what wasn't done was not done. We may as well change the subject already."
       #"She's part of a team known as the Meta Trio. She has new friends there, myself included."
         "That sounded a little possessive," Leonard notes. "Are you afraid some homeless people will take your new friend away."
         
         "Homeless bandits," you specify. "But no, I'm not particularly worried. I'm just telling you she's happy without you, or at least happy enough."
         
         Leo shrugs. "Good for her. It's strange she made friends with federate employees, but perhaps she's changed. Perhaps for the better. I won't dwell on that subject, if you don't want me to."
       #"She's been better. But I hear she's been worse too."
         "You don't want to tell us much," Leonard notices the obvious. "Out of loyalty for your friend, perhaps?"
       
         *if LisaRel > 50
           You nod. "I don't know if Lisa would appreciate me gossiping about her like that. I don't know if she still considers you friends or allies. I'm not telling you anything about her."
         *else
           You shrug. "Not really. I don't even know if I'd call her a friend. I just don't see any benefit to informing you."
         
         "Understandable," Leonard sighs. "I won't hold a grudge. You can even ask me about something else, if you feel like it."
     
     *goto homeless_hub
  *if not (lisa_origin_learned)
    *disable_reuse #"@{(LisaRel > 45) An acquaintance|A friend} of mine, Lisa Herbert, is from Calypso. Do you maybe know her?"
      *set origin_learned_here false
      "You know Lisa?" a young bandit asks. "Is she okay? Is she alive?"
      
      "Obviously, Cixin," Leonard says calmly. "If Lisa were dead, our friend here would have used past tense. But I'm glad she's alive too."
      
      *goto lisa_discuss
  *disable_reuse #"You call yourselves exiles. What exactly were you exiled for?"
    "Everyone here has a slightly different [i]official[/i] reason." Leonard grimaces. "I was a drunk, Margaret stole some stuff, Cixen left willingly to escape his abusive parents. Those are the backstories given to us by the Pandits."
    
    You raise an eyebrow. "Are you saying there's a cover-up? That the Pandits are hiding the true, [i]unofficial[/i] story?"
    
    "I'm saying they hate everyone who doesn't follow that Bayesian Path of theirs." Leonard spits on the dirt. "Not just anyone who questions their state religion either. Everyone who doesn't [i]feel[/i] right gets to boot too."
    
    "So they exiled you for… not feeling right?"
    
    "Not feeling happy enough," Margaret says grimly. "Bayesianism is all about maximizing happiness. Of others, first and foremost, but also your own. If you focus too much on the negatives, express hatred of spite, or even hint that you value something other than pure pleasure… They'll force you to be happy. If that fails, they'll chase you out of your home, so that you can't corrupt the others."
    
    "In Calypso, happiness is mandatory," Leonard concurs. "Happiness as defined by the Pandits, of course. Unhappy people are lepers in their eyes, and lepers who can be cured must be removed from society. We can't have people asking questions, after all."
    
    *goto homeless_hub
  *disable_reuse #"Did you say the government tolerates your presence? How so?"
    "It makes perfect sense once you understand how the Pandits think," Leonard responds. "Tell me, what do our overlords believe about justice?"
    
    *if visited_daxia
      "They don't believe in justice at all." You recall your meeting with Da-xia, the words she said and the way she delivered them. Her whole way of being. "Or in guilt. They just see cause and effect."
      
      Leo smiles crookedly. "Exactly. 
    *else
      "You tell me," you say with a shrug. "I'm new here, remember?"
    
      "Right. You see, Pandits are not really fans of [i]justice[/i], and that's not just me crap-talking them." Leonard assumes a tone of teacher, a lecturer, a scholar of the arcane. "That's an actual part of their philosophy. 
    They may be conceited assholes, but they don't punish for the sake of punishing. They'll only come after us once they're sure it will change the habitat for the better, increase the total happiness of its citizens. Of their subjects."
    
    "Will it not? You are attacking random passerby, it seems. This cannot possibly make people happier."
    
    "Neither will the news that their soldiers shot some vagabonds dead in the glasshouses," Leonard replies confidently. "There are no prisons in Calypso, so killing us would be their only option, and they won't do that just to protect their cabbages. Stuff is worth less than the bullets they'd have to use. We're safe here, relatively speaking.
    
    *goto homeless_hub
  *disable_reuse #"Have you heard of the diamond wyvern called Crystal?"
    "Heard of it?" Leonard snorts. "We've seen the thing several times. Sometimes it uses invisibility on its raids, but other times it just flies in here and terrifies everyone inside."
    
    "Why do you think they… it does that?" you inquire. "Is it unable to remain invisible at all times?"
    
    "Maybe, but I think it [i]wants[/i] us scared," Leonard theorizes. "It sure looks like a sadist at times. Nobody knows why it keeps invading the habitat, wrecking buildings and killing people left and right. It might just enjoy the exercise."
    
    "Or maybe it's playing mind games with our leadership," Margaret chimes in. "I'm not sure what the point would be… But maybe there's a method to this madness, some hidden goal nobody's aware of. Just a thought."
    
    *goto homeless_hub
  *disable_reuse #"You may or may not be aware of this, but I'm actually an android."
    "You? An android?" Leonard raises an eyebrow. "As in, a human-looking robot?"
    
    "That's what [i]android[/i] means, yes." You nod, bracing yourself for their reaction. Da-xia tolerates your presence in this moon, but she's been warned in advance and is likely less prejudiced than these people. They may decide to attack you after all, or to run away screaming, or-
    
    "I don't buy it," Leonard declares. "You're just messing with us. Having a chuckle at our expense." 
    
    Or that. "I can prove it, you know? You could punch me in the head and feel the metal there, or cut my skin and see the circuits, or watch me project electricity into someone, or-"
    
    "All those ideas sound stupidly painful," Leonard interrupts. "You won't convince me. Though I can pretend to believe you if it makes you feel better."
    
    "You sound awfully calm," you notice. "Weirdly indifferent. Don't you know androids are enemies of mankind?"
    
    "That's what the Federation says… but I don't know if I trust them more than the Pandits. For all we know, they're all equally full of shit. You can attack us if you're planning on wiping out humanity, otherwise we're cool."
    
    *goto homeless_hub
  *disable_reuse #"It's unusual for a gang to operate in a place like this. Is there really that much to steal in the greenhouses?"
    "There's food," Leonard replies matter-of-factly. "Isn't that reason enough."
    
    "Sure, but… there must be food in the town too, right?" you reason. "And it's probably tastier than raw crops too. Maybe that's why most criminals tend to operate in cities."
    
    Leonard snorts. "First of all, the Pandits only ignore us because we're not spoiling their beautiful town. We tried setting up base there once and it got raided almost immediately. We won't try again."
    
    "Besides, we don't want processed food," Margaret adds. "Not the kind people eat in the city. The government spikes it, both food and water, to make people more compliant."
    
    "They're drugging the food? Putting something psychoactive there?" Maybe you should tell the Meta Trio about this. 
    *if Misan > 50
      Or maybe not. Hard to decide.
    *else
      You don't imagine they'll get any more effective with narcotics in their blood… though you never know.
    
    "We're not exactly sure what they're doing," Leonard admits. "It's not like they're putting hard drugs in every meal. We suspect they're adding some anti-depressants into the water supply, the same water people cook and wash their food with. Something to make people calmer, and perhaps slightly happier. The effect is subtle, but we're fairly sure it's there."
    
    *fake_choice
      #"Shit. Should I tell somebody about it?"
        "You mean townsfolk? They'll just dismiss you as some crazy tourist talking nonsense," Leonard says grimly. "No point wasting your breath."
        
        "I happen to have… contacts within the Federation." And you don't exactly have any breath to waste. "I could tip them off. Tell them to look into this."
        
        "I don't think the feds care, and it's not like you have any evidence you could show them." Leonard smiles bitterly. "But thanks for your concern, I suppose."
      #"How are they possibly keeping this a secret, then?"
        "It's not like anyone's looking into this. The Federation doesn't care about our internal affairs, and the people…" Leonard smiles bitterly. "Well, you see what happens to those who question the state cult. You can't really blame them for not speaking up, can you?"
        
        You suppose not.
      #"I don't believe you. The Pandits wouldn't do something like that."
        "Your trust in these bastards is almost cute," Leo comments mirthlessly. "Makes you sound like a local. Don't say I didn't warn you if this place ends up… changing you somehow."
        
        You roll your eyes. You don't believe a word of that drivel, and it's not like you can get drugged anyway. "I'll keep that in mind."
      #"How can you be sure? Any solid evidence?"
        "Nothing we can show you hear," Leo doesn't seem offended by your doubt. If anything, he sounds apologetic. "But every single one of us experienced some syndromes of withdrawal. You're not convincing us and we're not convincing you, so may as well talk about something else."
      #"This moon is such a wonderful place. Ever considered leaving it?"
        "It's not like we can pay someone to take us out of here." Leonard shrugs. "Besides, I've heard the rest of the Federation is just as bad, only in different ways. Better the devil you know."
    
    *goto homeless_hub
  *disable_reuse #"Is there any way I can help you guys? I have no food on me, but maybe there's something else you need?"
    "Clean clothes wouldn't go amiss either, but I don't imagine you brought any of those," Leonard responds. "Money isn't worth much, but… do you happen to have any on you?"
    
    *if money_stolen = 2
      "Sure." You dig up an axion, one of the ninety-nine you stole during the heist, 
      *label iiiijjja14
      then throw it to Leonard. He's surprised, but he catches the coin easily. "Buy yourself something nice."
      
      "Thanks, but… Why are you parting with money so easily? Are you just that rich?"
      
      "Would you believe me if I said 
      *if money_stolen = 2
        I robbed a Conglomerate bank and got away with it?"
      *else
        that Admiral West gave me that money personally?"
      
      "No." Leo says flatly. "I would not."
      
      "Then don't." You shrug. "Focus on finding someone who'll accept this as payment. And won't scam you on the change."
      
    *elseif money_given != 0
      "Sure." You dig up an axion, part of your payment for participating in the hunt, 
      *goto iiiijjja14
    *else
      "Not really." 
      *if money_stolen < 1
        Shame your attempt to rob the Conglomerate didn't go well. 
      *else
        You have some credits in digital form, but those are not easily transferable, or even commonly accepted outside of Rhea. 
      But what do you mean it isn't wort much? You use axions here in Calypso, right?"
      
      "Sure, but…" Leonard pauses, as though struggling to explain a basic fact of life. "People will only sell you stuff if they think both parties will benefit from it. They'll sell stuff to other Bayesians and to tourists like you, but not to vagabonds and outcasts. Especially not to known ones, such as yours truly. Not to untouchables."
    
    *goto homeless_hub
  *disable_reuse #"I changed my mind. I'm going to kill you all now."
    Everybody tenses, a few people gasp, Margaret looks ready to run away. Leonard is the calmest of the bunch, but even he frowns and reaches for the hatchet. "I really hope you're joking, friend. Otherwise, we're all gonna have a problem. I won't go down easily."
    
    *choice
      #"Of course I'm joking. I ain't no killer."
        "I'm not sure if I like your sense of humor," Leonard grimaces, but he does relax. "But each to their own, I suppose."
        
        "Each to their own?" Margaret doesn't seem quite as understanding. "That weird foreigner is threatening us with death, even though ${pronoun} @{plural know|knows} how seriously we'd take it. I say we drive ${pronoun2} out of our territory."
        
        "It's hardly [i]your[/i] territory, and you approached me with threats first." You turn around. "But fine. I'll leave you to your fear and hunger. Farewell."
        
        You leave these humorless blokes and instead go… where?
        
        *goto choice_hub
      #"You're right. Your group is not worth my time. I'm leaving."
        *goto uuuuaa43
      #"I'm not joking." Kill the homeless.
        *goto kill_bill
  *if conv_track > 1
    #"Thank you for information, but I must be going now."
      "You have business to attend to, huh?" Leonard nods with understanding. "Care to tell me what business is that?"
      
      "Classified stuff," you reply honestly. "Stuff you may have just helped me with, potentially. So thank you."
      
      "Check on us sometime, alright?" Margaret says. "If you end up staying in Calypso for longer, that is. There aren't many friendly faces around here."
      
      You nod, then walk away. While these people may be more pleasant than they first appear, they are not your reason for being here. The town has far more to do with that.
      
      *goto choice_hub
  *if conv_track = 1
    #"I'm not going to tell on you... But I will take my leave."
      *goto uuuuaa43



*label renfri_date

Finding the Kinnari in the settlement is no quick matter. You first need to scan the sky to make sure she's done patrolling, then you start searching in various dineries of the town you don't really know the layout of. But you have luck on your side, and you soon find your teammate sitting by a small table, near something that appears to be a burger stall.

"Can you believe that?" She barely notices your approach, too focused on the sizable hamburger in front of her. "They actually have burgers here."

"I take it burgers went out of fashion recently?" You take a neighboring seat. "I admit to not really keeping up."

"They're almost extinct in Titan, and certainly in the military. I've been sustaining myself on corpse rations, plus an occasional stinkhorn sandwich, for over a month now. It's so nice to have actual meat on my platter for once."

"I don't think it's actually meat," you dare to point out. "I haven't seen any animals or pastures around here. It's probably tofu, or some other imitation."

"And what makes you think I care? I won't whine because my burger isn't made of the exact stuff I'd want. Only taste matters."

*fake_choice
  #"Do you feel comfortable, eating during work like this?"
    "I'm done with my patrol, and I'm ready to fly up and into action the moment Crystal shows up. Besides… I'm not actually eating right now."
    
    "I noticed. What's up with that?"
  #"Why aren't you eating, then?"
  #"Does it smell nice too?"
    "Of course it does," @{(RenfriRel >= 50) Renfri|Marshal} replies. "Why are you asking?"
    
    "Curiosity." You shrug, silently lamenting your lack of smell. "And hoping to find out why you're not eating it."
  #"Don't think you'll convince me to buy a burger myself. I don't eat."
    "I'm not trying to sell you anything, ${name}. I'm perfectly fine having everything this stall has to offer to myself."
    
    "Why not start eating, then?" you ask with a smirk.

"I'm worried it will fall apart if I levitate it and… I don't exactly have any other way of holding it." Marshal flaps her wings, as if to emphasize her lack of arms. "It's not a problem when I'm eating algae jelly and other military foods, but here… It would be a real shame if I dropped the thing."

"I see. Any way I can help?"

"Well…" @{(RenfriRel >= 50) Renfri|Marshal} bites her lower lip. "I was thinking you could… maybe hold it for me? At least for a bite or two, so that I can start eating it the proper way. It will be easier to hold still with gravity manipulation once it's smaller. Please?"

*label bird_weird
*fake_choice
  *disable_reuse #"Hold a hamburger for you? Well that's a weird request."
    "You're welcome to refuse it," @{(RenfriRel >= 50) Renfri|Marshal} replies. "I just rather you didn't."
    
    "But why me and not someone else?" you inquire. 
    *if RenfriRel > 42
      "People here are nice, I'm sure someone less busy than me could help."
      
      "Lisa told me a thing or two about Calypsoans," @{(RenfriRel >= 50) Renfri|Marshal} reluctantly explains. "I don't really believe her, she's clearly biased… but I feel more comfortable asking you for help instead."
      *goto bird_weird
    *else
      "I mean, we're not exactly on excellent terms, are we?"
      
      "True… but you're still someone I know. That makes my request less weird, I think."
      *goto bird_weird
  *disable_reuse #♡ "Sounds like something a couple would do. You want it to be romantic?"
    *set hit_on_renfri true
    *if ((sex = "woman") or (pronoun = "she"))
      *if current_ro != "renfri"
        *set backup_RO current_RO
        *set current_RO "renfri"
    *if sex = "woman"
      *set RenfriRel %+ 8
    *if pronoun = "she"
      *set RenfriRel %+ 8
    *if official_ro = "renfri"
      "Sure?" she says without conviction. "I mean we are a couple. I would gladly do something romantic with you soon, and you can consider this a date if you want, it's just…"
      
      "You just want to eat a burger."
      
      "Pretty much, yeah."
      *goto bird_weird
    *elseif (RenfriRel > 55) and ((sex = "woman") or (pronoun = "she"))
      "Perhaps…" @{(RenfriRel >= 50) Renfri|Marshal} blushes slightly. "But I mostly just want to eat a piece of hot meat, even if it is artificial."
      
      You raise an eyebrow.
      
      "And I realized how that sounded." The Kinnari sighs. "Just help me already, will you?"
      *goto bird_weird
    *else
      "Ew. I'm not hoping to get on with you, just asking you for help as an… acquaintance, I suppose."
      
      "Are you sure? Certain that my good looks won't, at the very least, make this less embarrassing for you?"
      
      "Maybe they will…" @{(RenfriRel >= 50) Renfri|Marshal} blushes slightly. "Point is, will you do it or not?"
      *goto bird_weird
  #"You know what, sure. Let's eat this together, kinda."
    "I knew you'd help." Renfri perks up, moving a little away from the table and allowing you to grab the burger. "Just hold it still, at about the height of my face. And to it steadily, I know you have that machine precision."
    
    You do indeed. You grab the hamburger with two hands, both on one side but still keeping the thing from falling apart. And then the Kinnari leans forward to bite into the bread and steak.
    
    *fake_choice
      #"Make sure not to dirty yourself with the sauce."
        *set RenfriRel %+ 10
        "Yeah, sure," Renfri replies, but only after she took the bite and swallowed the food. "I'd hate to leave stains on the uniform, though… damn, wouldn't that be worth it."
      #Sigh and let her eat.
        *set RenfriRel %+ 10
        Renfri does not appear to notice your embarrassment. She just bites, and chews, and swallows with an expression of delight that proves the burger stall lived up to customer expectations.
      #"Actually, that feels too weird." Put down the burger.
        *goto yourself
      #Throw the burger in her face.
        *set burger_throw true
        *achieve food_fight
        *set asshole_be true
        *set RenfriRel %- 20
        Just when the Kinnari thinks she's about to eat the hamburger she bought, the entire thing impacts her face. You make sure to quickly remove the upper layer of bread so that hot meat hits her forehead directly, maximizing the mess and the heat-induced pain your teammate soon experiences.
        
        "Fuck!" She swipes at you with her wing, but her aim is pretty terrible, having sauce in her eyes and all. "Why?! What's wrong with you?!"
        
        "I get little joy in my life," you calmly explain. "I need to create my own entertainment wherever I can, you know?"
        
        "I'll give you fun!" She sends a gravity wave at you, one that doesn't hit dead-center, but still sends you tumbling out of your seat and onto the dirt. "Get out or I'll fry you better than this steak!"
        
        "Your laser disc only shoots low-frequency beams," you point out. "Also the steak seems pretty rare, though it's hard to tell when it's lying on the ground like-"
        
        "Get out!"
        
        Just in case, you decide to take Marshal up on her offer of retreat and go do something else.
        
        *goto choice_hub
    
    You only put the burger down when there's only half of it left. It seems like you did enough, for Renfri lounges in her chair, as though full already. Maybe she is, you're not sure how Kinnarae stomachs work.
    
    "Thank you," she says before a deep sigh. "I know I look silly right now, but… you need to relax somehow on a high-stress mission like this one."
  #"No deal. I'm sure you can manage it yourself."
    *label yourself
    *set RenfriRel %- 10
    "Yeah, I guess that's fair enough," Renfri sighs. "I'll just wait until it cools down. At least if the thing falls apart then, it won't hurt when ingredients fall on me."
    
    "You seem really bothered by this," you point out. "Is this burger really that special?"
    
    "No, it's just… I need something to be excited about. Some moment of levity during a high-stress mission."

"High stress? I guess it makes sense to be afraid of Crystal just attacking from nowhere, but you don't strike me as the type to be bothered by danger."

"Not the regular kind." Marshal winces. "I'm more worried about Lisa. What her being here means, what it could lead to."

"Are you worried she'll kill someone, blow herself up, or both?"

"I don't know, ${name}. I just know she has a history with this habitat. And knowing this, I still insisted that we come here. If something happens, one way or another, I'll bear part of the blame. A big one."

*fake_choice
  *if progress = 7
    #"You do realize we had nowhere else to go, right?"
      *set RenfriRel %+ 6
      "I do, but…" She looks away. "I'm not sure if that's any relevant."
      
      "How so? We had no other choice. I think we can consider ourselves absolved of blame, since the alternative was to just let Crystal be."
      
      "Lisa would have taken that option," Marshal murmurs. "She doesn't care for any of this. Certainly not enough to die for it."
      
      *if LisaRel > 50
        *set RenfriRel %+ 6
        "I don't think you understand her all that well, Renfri. Not that many people do." 
      *if LisaRel <= 50
        "Yeah… I guess she doesn't." 
      You say. No reply comes.
  #"You won't. Or at least you don't need to."
    *set RenfriRel %+ 10
    "I will, and I must," Marshal replies harshly. "It is unheroic to shrink away from such guilt."
    
    "And you consider yourself a hero, huh?"
    
    "I am hoping to become one, given opportunity…" Renfri trails off. "But more importantly, I am Lisa's friend. The only one she has, at that. There's some responsibility that comes with that."
    
    *if LisaRel > 50
      *set RenfriRel %+ 10
      "If it brings you any comfort… you're not the only one. Not at all." 
    *if LisaRel <= 50
      "Yeah… I guess there is." 
    You say. To no reply.
  #"She'll be fine. She's tough, and she knows better than not to behave."
    *set RenfriRel %+ 10
    "I will not dispute the first part. The second…" Renfri sighs. "Yeah, I can't say I'm very confident. Not given her history with this place."
    
    "Perhaps you should be?" you suggest. "Believing in your friend sounds like an option."
    
    She shakes her head weakly. "Not when [i]she[/i] is that friend."
    
    *if LisaRel > 50
      *set RenfriRel %+ 10
      "Well, she's my friend too," you respond with a slight smile. "And I do believe in her. It's an option I'm glad to take."
      
      Renfri does not reply.
  #"Do you suspect Da-xia will press the trigger on a whim?"
    "No, I don't think it's that bad," Marshal replies. "Not to say I like Da-xia, but she's not our enemy. She's a good person with decent reasons for doing… not exactly the greatest thing, perhaps."
    
    "She called you Rook's pet back on the landing patch," you point out. "Weird to hear you speak so highly of the woman openly racist towards you."
    
    "Not enough reason to suspect her of sabotaging our mission and killing our teammate," she argues back. "Besides… it wasn't the first time I experienced that."
    
    "Prejudice? Due to not being exactly human and all?"
    
    "That exact insult, I meant."
  #"I share your fears. Just remember we have a way of putting her down if she tries anything. Making it quick."
    *set RenfriRel %- 8
    "That doesn't exactly make me feel better," Renfri sighs, tiredness and frustration clearly audible. "Though thanks for the effort, I suppose."

The conversation stops there, as though by natural death. You leave Marshal to her burger, cold as it is by now. You have some other matters to attend to.

*goto choice_hub

*label hadaly_date
You follow Hadaly into the town, and towards the sacral area she said she wanted to visit. Though the area is quite densely populated, you have little trouble finding the android; Few people other than her wear jumpsuits, and equally few are so loudly excited to be in this place. When you meet her, she is reading aloud from a tourist infographic in the form of a large, metal sign, placed near a large mosque-like building.

"Rational Temple is the most holy site for all who walk the Bayesian Path, containing the Anointed Bayesian Codex itself, all of human wisdom gained since Calamity contained within a single tome." At that point Hadaly hears the footsteps and turns around. 
*if (hadaly_pissed) or (HadalyRel < 35)
  "I wonder how thick that book… Oh. It's you."
  
  She keeps her face neutral enough, but her eyes don't lie. There is distaste in the shade of green they assume, as well as in her voice. Perhaps unsurprising, considering recent events.
  
  *fake_choice
    #"Hi Hadaly. Can I join you in sightseeing?"
      "I would much rather you didn't," Hadaly says with a forced smile. "I bet you have so many better things to do."
      
      "What if I don't?" you reply, raising one of your eyebrows.
      
      "Then… well… I would ask that you leave me alone anyway. If it's all the same to you."
    #"You sound hostile, if I may notice."
      "Not [i]hostile[/i], no," Hadaly protests. "Just maybe… less than entirely happy to see your face around here."
    #"How are you? Staying safe and all?"
      *set HadalyRel %+ 5
      "Yes, I'm perfectly safe and perfectly fine," Hadaly assures you. "It's just that… I'll be even more fine if you leave me alone."
    #"Yes, it's me. Got any problem with that?"
      *set HadalyRel %- 10
      "Not necessarily…" Hadaly says before sighting deeply. "Okay, I do have a problem with you bothering me. Very much necessarily. Would you be so kind and go somewhere else?"
  
  "Why?" you inquire. @{hadaly_pissed "Are you still mad at me for what I said on [i]Saturn Nine[/i]?"|"Is there some concrete reason you're pissed at me?"}
  
  *if Misan >= 35
    *goto normal_h
  
  "Hey, I didn't say I'm mad," Hadaly protests. "I just… don't really care for a pushover like you, alright?"
  
  "Pushover?" You flinch. "Why would you say that? Why would that even upset you? You're not exactly the most assertive person yourself."
  
  "But I'm not blindly trusting humans, ${name}," Hadaly replies, her usual politeness almost wholly gone. "I'm not groveling before them like you do. And I have some measure of concern for my fellow synths, if you forgive the lack of humility."
  
  "Groveling? I'm just…" Maybe you were, just a little. "Honoring my creators, that's all."
  
  "And nobody else. If you were at least nice to me and the others, to your own kind…" Hadaly turns away. "I'm forgetting my manners. Please leave before I say something I'll regret."
  
  *fake_choice
    #"Well then... sorry for bothering you."
      *set HadalyRel %+ 8
    #"Okay. Have fun touring all these man-made buildings."
    #"I believe you already have."
    #"Fine, you toffee-nosed misanthrope."
      *set HadalyRel %- 12
  
  Hadaly does not reply. She just lets you walk away, from her and from the temple, towards the town. To proceed with the mission on behalf of your… creators.
  
  *goto choice_hub

  *label normal_h
  "It's more of your general… way of being, really." Hadaly's eyes flash red. "Because truth be told, you're an asshole. @{(Violence > 50) A violent asshole, at that.|Not a bad person or anything… but an asshole.} And I don't really like that. So please leave."
  
  *fake_choice
    #"Alright. I won't bother you, if that's how we are."
      *set Emotion %- 5
      *set HadalyRel %+ 5
      "Thank you for understanding," Hadaly says before focusing her attention on the sign again. You, on the other hand, focus your attention on leaving; There's no point continuing this unpleasant exchange when there are better things to do.
      
      Speaking of better things, what do you intend now?
    #"Fine, but... is there anything I can do to change your mind about me?"
      *set HadalyRel %+ 7
      *set hadaly_pissed false
      "Sorry, I don't think there's a step-by-step guide for making yourself amicable," Hadaly says, brightening up a little. "But the fact that you're [i]asking[/i] proves that there's a chance."
      
      "What do you mean?" you inquire further.
      
      "Well… more than anything, I appreciate it when people [i]try[/i] not to be jerks. I get you have issues, and I can't tell you how to solve them. I can't even get mad at you for lashing out occasionally. But I do expect you to try being nice, even when it's difficult."
      
      "Yeah… alright," you say with a sigh. "I'll try, if you think that's all I can do."
      
      "That's all I ask for." Hadaly smiles before turning away. You turn around too, thinking about her words as you walk away and towards your next destination.
    #"Oh yeah? Well fuck you too, you sanctimonious bitch."
      *set HadalyRel %- 20
      *set hadaly_pissed true
      "Thank you for removing any doubt as to how we feel about one another," Hadaly cheerfully says before turning back towards the sign. "Now fuck off, pretty please."
      
      You'd spit on the ground as you leave, or perhaps even in the other android's face, but you don't really have any saliva. Nor that many fluids in general.
      
      Besides, Hadaly isn't worth bothering with any longer. You have more important things to tend to.
    #Punch Hadaly in the face.
      *set Violence %+ 20
      *set Emotion %+ 15
      *set HadalyRel %- 20
      *set DamonRel %- 20
      *set hadaly_pissed true
      *set damon_pissed true
      *set health - 1
      Despite her low opinion of you, Hadaly does not expect you to clench your fist and then slam it into her nose. She fails to dodge and just takes the blow, then falls backwards and onto the dirt.
      
      Not that she's the only one surprised, or facing sudden pain. The moment your knuckles connect with Hadaly's face, you feel your hand burned by an electric discharge. It scorches some of your synthetic skin, and probably hurts just as much as the punch hurt the other android. The voltage running through her must be… certainly something.
      
      "So… so that's how it is?" Hadaly stands up with some effort, coolant leaking out of her damaged nostrils. "Thanks for proving me right, I guess. More right than I expected to be."
      
      "You're welcome," you snarl before walking away. There is no point continuing the fight; Damon will be pissed enough when he finds out what you did to his sister, and would probably just gun you down if you were to seriously attack and damage Hadaly. Not that the rest of the group wouldn't join him at that point.
      
      And besides, there is something else you want to do.
  
  *goto choice_hub
"Hi ${name}. I'm still admiring the sights here. What do you think of this town, or the habitat in general?"

*fake_choice
  #"It's pretty amazing. Haven't seen a place that orderly in some two centuries now."
    "You know, sometimes I forget just how ancient you are," Hadaly remarks, then frowns. "Not that I think being old is bad, not that you can really be called old in the normal sense, I know you don't age and are still really strong and hot and I really don't mean to-"
    
    "I know," you interrupt. "Calm down. You're doing [i]your thing[/i] again. When you really don't have to."
    
    "Sorry. I thought I'd get better by now," Hadaly sighs. @{(progress = 7) "I suppose Hammon still controls me in that way, at least."|"But some parts of my code can't be fixed easily. I believe you understand."}
  #"Beautiful, but not exactly my sort of thing."
    *label whyso
    "Why so?" Hadaly asks with a slight frown.
    
    "I'm not wholly sure," you say shruggingly. @{(Misan > 50) "Maybe I don't enjoy seeing so many humans around me."|"There's just something fake about this whole place. Hard to tell what."}
    
    "Understandable, I guess," Hadaly replies with a sigh. "I mean, I don't really [i]understand[/i], that's why we disagree… but I respect your aesthetic preferences."
  #"Since when are you an admirer of human culture?"
    "Good point," Hadaly says, looking back towards the temple. "I suppose I'm just that much of a tourist… though there is something inhuman about this place too."
    
    "What do you mean by that? You suspect abhumans or AI built it all?"
    
    "Not really, it's more like the culture here… defies the human spirit?" Hadaly says without confidence. "Or maybe I'm just rambling. Probably that."
  #"I think we should stay focused and keep our eyes open."
    *set Emotion %- 8
    "I guess I can cut my trip short if you [i]really[/i] need me to," Hadaly concedes. "Just let me enjoy the scenery for a few more moments. And perhaps try to enjoy it yourself."
    
    "Fair trade, I suppose…" you say, stepping forward and taking a closer look at the temple. It really is something, with its colorful dome and marble pillars, at least for a settlement so small and otherwise humble. This whole [i]Bayesian Path[/i] must be important to Calypsoans, truly a faith they're devoted to.
  #"I don't like it here, to be perfectly honest."
    *set HadalyRel %- 5
    *goto whyso

The two of you stand there for a long, quiet while. The few humans in the area enter the temple, likely for some sort of lecture or mass, leaving the yard around the building pleasantly empty. And perfectly still; In a habitat like this, there isn't even any wind to disturb blades of grass around your feet.

*if official_ro = "hadaly"
  "I wish we had time to go on a date here," she suddenly says, her voice calm and dreamy and her eyes a shade of violet. "Not just some hangout, or a drawn-out conversation. An actual date, in some restaurant or a theater, followed by returning home together hand in hand. Without being afraid of some wyvern, or of failing the mission we're on. A lovely thought, isn't it?"
  
  *fake_choice
    #"Yeah. It is."
      *set HadalyRel %+ 8
      "You're an android of few words, aren't you?" Hadaly smiles. "I always liked that about you. You never ramble pointlessly, like I have a habit of doing."
      
      "You are an android of many words, Hadaly." You smile back. "And I love that about you."
    #"That's not my type of date... but I share the sentiment."
      "I would ask what [i]is[/i] your type of date," Hadaly replies wistfully. "But I feel like that would just make both of us sadder still."
      
      "Yeah," you reply, simply and honestly. "I guess it would."
    #"Eh. I'd rather just hit the bed and let you have your way with me."
      "That's an idea too," Hadaly chuckles. "Sorry if I'm blue-balling you. I wasn't in the mood back on [i]Saturn Nine[/i], and we haven't had much time or privacy since."
      
      "I don't mind," you reply politely. "And I don't think you could really blue-ball me if you tried. My body doesn't work like that."
      
      "Sorry, it was a figure of speech. I'm used to doing [i]that[/i] with organic men." She places a hand on your chest in a soft, affectionate manner. "You will be my first android. It will be special, in a way. And I promise I'll make it special for you too."
    #"I suppose. But it doesn't change the truth of our situation."
      *set HadalyRel %- 8
      "Hey, I said I'm just daydreaming," Hadaly sighs, somewhat irritably. "I know we still have a job to do, even if I don't really want it done. And that you're our Veteran, our big gun, the key to everything. How important your time is."
      
      "If I could spend my time freely, I'd go on whatever date you want me to," you assure her. "But since I can't… I can only offer a few minutes of it."
      
      "Those minutes mean the world to me." Hadaly smiles. "Of course, a whole evening would mean a [i]system[/i] to me… but there will be time for that yet."

  *goto ghu2

*elseif (HadalyRel > 60) or (((current_ro = "hadaly") or (backup_ro = "hadaly")) and (HadalyRel >= 50))
  "Hey ${name}…" There is a slight hesitation in Hadaly's words. You can see her eyes turn a shade of red… though perhaps it's closer to pink. "If I were to invite you on a date here, in one of the restaurants or theaters, would you accept? I know we don't really have time for that right now but… maybe one day?"
  
  *label ghu3
  *fake_choice
    #♡ "Nothing I'd love more."
      *set hit_on_hadaly true
      *set HadalyRel %+ 10
      *if current_ro != "hadaly"
        *set backup_RO current_RO
        *set current_RO "hadaly"
      "Not a single thing?" Hadaly's smile is coy, but not devoid of relief. "I can think of [i]some[/i] things I'd like to do with you more than just dating. But the time for that will come."
      
      *goto ghu
    #♡ "I think I'd refuse. Our first date should be something more special."
      *set hit_on_hadaly true
      *if current_ro != "hadaly"
        *set backup_RO current_RO
        *set current_RO "hadaly"
      "You're an android of high expectations, huh?" Hadaly's smile is humorous, but not devoid of relief. "Okay then. I'll think something interesting up."
      
      *label ghu
      "I'm fine with waiting." Your face too is now adorned by a smile. "It's not that unbearable when you have good company."
      
      *label ghu2
      The two of you spend several more minutes together, talking of ordinary things mostly connected to the temple design and not at all connected to the mission at hand. But ultimately, you both remember the mission [i]is[/i] ongoing, and so you go your own ways for now.
      
      For Hadaly, this means admiring the Rational Temple from the inside. For you…
      *goto choice_hub
    *disable_reuse #"Are you hitting on me? That's unlikely of you."
      "Because I'm so demure and lacking in confidence?" Hadaly says jestfully. "You don't know me all that well, ${name}. The question is… would you enjoy getting to know me better? Over a few glasses of wine, perhaps?"
      *goto ghu3
    #"I don't think I'd accept. I'm not interested."
      *set rejected_hadaly true
      *if ((current_ro = "hadaly") or (backup_ro = "hadaly"))
        *set HadalyRel %- 8
        "Really? But I thought…" 
      *if ((current_ro != "hadaly") and (backup_ro != "hadaly"))
        "Oh. I was hoping…" 
        
      Hadaly averts her eyes, just as they turn dark blue. "You know what, nevermind. It was a silly thing for me to ask."
      
      *goto befgyn
    #"You and me? You must be joking."
      *set rejected_hadaly true
      *if ((current_ro = "hadaly") or (backup_ro = "hadaly"))
        *set HadalyRel %- 20
        *set hadaly_pissed true
        "What? So you led me on just to turn me down… like that?" 
      *if ((current_ro != "hadaly") and (backup_ro != "hadaly"))
        *set HadalyRel %- 12
        "…so that's how you see it." 
      Now Hadaly's eyes are [i]truly[/i] a shade of red. "I… should have expected that, really. It's just like you."
      
      *label befgyn
      Before you can reply, your fellow android turns around and begins walking towards the temple. "I'll see what sort of a ceremony those humans are having inside. Maybe they'll let me in. Please don't follow me."
      
      You do not follow her. Instead, you take to something you are actually interested in.
    *if official_ro != ""
      #"Sorry Hadaly, but I'm with someone already."
        *set rejected_hadaly true
        "Really? I mean, not that I'm doubting you, or saying that you'd have trouble finding a partner, I just didn't…" Hadaly's eyes oscillate between blue and brown, disappointment and embarrassment. "It's ${official_ro}, right?"
        
        You nod. "We decided to make things official just before our departure from the fortress. Sorry for not telling anyone, I just-"
        
        "Hey, that's alright! It's not like I'd ever demand of you to keep me informed. It's my bad, honestly."
        
        *goto befgyn
        
  *goto choice_hub
*else
  "How could one ravage a place like this?" Hadaly says suddenly. "How can… Crystal just fly inside this cylinder and start killing people? @{telesto_complete You said they consider themselves a hero, so how can they justify the slaughter?"|Is it really just a monster that seeks violence for its own sake?"}
  
  *fake_choice
    #"Not sure, but I've seen worse slaughters. It definitely can be done."
      "How do you know if the massacres here were less bad than what you've seen?" Hadaly asks, her tone almost accusatory. "We haven't seen an attack yet, or even what kind of damage the previous raids caused."
      
      "I don't know exactly how bad it was, true," you admit mirthlessly. "But this habitat has less than half a million people in it. I've seen larger ones razed to the ground."
      
      Hadaly doesn't reply. You take that as conceding the point.
    *if Misan > 50
      #"Humans are vermin. I cannot fault Crystal for killing a few."
        *set Misan %+ 15
        "Right. I forgot how you feel about our creators," Hadaly sighs, tired but not angry. Not quite. "Still, I don't think Crystal feels the same way."
        
        "Why not? We all hate humans, to one degree or another. You aren't exactly their fan either. I don't think there's a single synthetic in the Solar System who's much of an exception."
        
        "I can think of one," Hadaly says, but doesn't elaborate. Not even after a long stretch of silence that follows.
    *if not (telesto_complete)
      #"That's what the evidence suggests, yes."
        "I still think there's something we're missing…" Hadaly sighs. "But I also think we'll find out what that is soon. So there's no point theorizing, I suppose."
    *if telesto_complete
      #"Perhaps the Dusk commands it to do so. It cannot be easy to resist the Thing Beneath."
        "I don't know if I find that thought comforting or not," Hadaly sighs. "Do acts like these become less or [i]moe[/i] evil when they're encouraged by some evil god?"
        
        You don't reply. You've wondered that yourself too many times already to find the debate anything but pointless.
    #"No idea. I don't understand Crystal's motives either."
      "You know, that actually sounded somewhat comforting," Hadaly says wistfully. "I'm glad you don't understand. I know I don't want to."
  
  The conversation doesn't exactly flow well after that. You and Hadaly exchange a few more remarks, then go your own ways. For her, this means admiring the Rational Temple from the inside. For you…
  
  *goto choice_hub

*label daxia_date


*temp left_weapon false


Finding out Da-xia's address takes some asking around the town, but she's a well-known figure and her residence isn't exactly easy to miss once you know what to look at. It's a beautiful mansion on the outskirts of the town, elevated by having been built on meter-long wooden stilts protruding from the ground. Or at least they look wooden; Either they are some far stronger material stylized as timber, or the entire house is far lighter than it appears.

The main door, accessible after climbing some stairs, is guarded by two beige-robed figures you recognize as part of Da-xia's retinue; A bearded man with crude ocular prosthetics and a middle-aged woman with a scarf that makes her look almost a stereotypical handmaiden. They both nod, almost bow once you approach.

"Our Pandit said to expect your arrival, one known as ${fake_name}," says the male servant. 
*if weapon = "none"
  "I do not see any weapons on you. I presume you are not hiding any?"
  
  *fake_choice
    #"Why would I? I come here as an ally."
      "Just making sure as a matter of protocol. Come in."
    #"No. I presume Da-xia is home?"
      "You presume correctly, visitor. You will find our mistress inside."
    #"I have no need of weapons. I can kill a team of armed men with just my fists."
      "I really wish you hadn't told me that," the servant sighs. "But I suppose there's no point in me trying to stop you from entering. Come in."
    #"If I were to pull out a gun and shoot you, how would you stop me?"
      "By detonating these eyes of mine, and hoping that the explosion will kill you as well as me," the servant replies. "But since that won't be necessary, please come through."
    *if c_clothing = 4
      #"You suspect I'm hiding some under my loincloth."
        "No, I don't," the man grimaces. "And I don't feel like inspecting you, for that exact reason. Come in."

*if weapon != "none"
  "That said, I do not think we can let you in with a weapon. Leave your ${weapon} behind, and you may meet our employer inside."
  
  *label leave_weapon
  *fake_choice
    *disable_reuse #"Is Pandit Da-xia even inside?"
      "She returned from her negotiations with Sergeant Kosteniuk just a few minutes ago, yes." The servant nods.
      
      "There were negotiations?" you inquire. "I thought it was simply the matter of giving her that code."
      
      "We are not privy to what happened behind closed walls, dear visitor. You may ask her some questions yourself, if you do as instructed and give up your weapon."
      *goto leave_weapon
    *disable_reuse #"You know I could easily kill you both with just my fists."
      "I am aware of that," the man says with a wince. "Still, I insist that you leave your armament behind as a matter of protocol."
      *goto leave_weapon
    #"Sorry, I'd rather not visit your mistress than part with my weapon."
      "It saddens me to hear that, but I shall not try and change your choice," the bearded man replies. "Goodbye."
      
      You sense there's no point arguing further, and so you simply walk away. It sucks you won't meet Da-xia again, but you have other things to do as well, so you may as well attend to those instead.
      *goto choice_hub
    #"Fine, here it is." Leave your ${weapon} behind.
      *set left_weapon true
      "We thank you for your cooperation," the servant smiles as he takes the ${weapon} and gestures towards the door, which his female coworker pushes open. "Come right in."

As you march inside the house, you see that it is indeed lighter than it appears from the outside. The walls are thin, and would do poorly against cold should the habitat ever experience some equivalent of winter. Furniture is sparse, mostly consisting of small and finely-crafted articles, small lanterns standing on some tabletops and providing the corridors with sparse light. The inner doors are made from paper and cloth rather than any heavy materials, resembling old [i]fusuma[/i] more than metal and glass doors you're used to. A bit of Neo-Japanese stylistic right there, not that the owner of the house is likely to think in such archaic terms.

You open one of the paper doors, ignoring the bad memories that come with it, and enter a large room which you imagine is a living area. It would remind you of [i]that[/i] room, one where you died and were born again, except there is no Vision system of any kind. The large couch only faces the window, and a nice view of the town it offers. It would draw all your attention if not for the altar in the corner, a small platform on which a large book stands closed, illuminated by tiny candle-like lamps.

In any case, there is no sight of Da-xia here, but you pick up some sounds from yet another corridor. She is coming, though you have a minute if you wish to snoop around.

*set visited_daxia true

*if Social > 50
  *set DaxiaRel %+ 10
*temp look_book false
*temp knees false
*fake_choice
  #I'll lie down and wait on the couch.
    As it could be expected, Da-xia's couch is quite comfortable, far surpassing the low quality of factory-made furniture you have on [i]Saturn Nine[/i]. Almost makes you want to lied down and sleep there, which would have been a foolish act even if you had the ability to fall asleep.
  #I'll admire the window view.
    Said view isn't really that much to admire. Just the cobblestone walkways and neatly-trimmed greenery filling the space between other, somewhat less impressive houses. But you suppose there's nothing a ruler likes to see more than their own community prospering. Assuming said ruler actually cares about her people, which is quite a rare trait… that Da-xia may just possess.
  #I'll inspect the large book.
    *set look_book true
    There is no title, not on the front cover nor the spine. The cover would be all black, if not for the golden symbols that seem to form a mathematical formula on the tome's front. A basic equation that describes conditional probability, simple stuff, @{(Database > 50) Bayes' theorem if your memory serves you right.|though you can't recall the name or author of this particular formula.} You consider opening the book briefly, but there is something sacral about it that makes you reluctant to touch it.
  #I'll just stand and wait.
    The muscles in your legs do not tire, and so you don't mind standing much. Especially since you've long learned that sitting or lying down close to a potential enemy is a [i]bad[/i] idea, even if you can't see how said enemy could possibly harm you.
  *if Misan < 50
    #I'll wait on my knees.
      *set knees true
      *set Misan %- 15
      *set DaxiaRel %+ 10
      With Da-xia being a Great Pandit and all, you have an excuse to show a human respect deserved. Not that any of your fellow outcasts is looking anyway.

After another few seconds, she enters the room. Her clothing is similar to one she wore outside, a single robe in a yellow hue, but it's clearly a different and less formal garment. More like a bathrobe than a tunic. 
*if DaxiaRel > 35
  Her smile when she sees you is also of another variety, far more honest than the polite expression she would wear during the meeting with your group.

"Greetings, ${name}. Or ${fake_name}, if you still prefer it. 
*if knees
  I don't know why you decided to genuflect, but I suppose I appreciate the gesture."
*if look_book
  I'm glad you can see the beauty of the Bayesian Codex, but this is simply a faithful copy. The real book is secured within the Temple, far better than I could ever guard it."
  
  She looks at the tome, dark eyes taking on a dreamy expression. "All wisdom our species gained since Calamity, contained on the pages of one book. Fascinating, is it not?"
*if (look_book = false) and (knees = false)
  I was hoping you would decide to visit, even if I did not find that outcome likely."

*fake_choice
  #"Really? You've been hoping to see me?"
    *set Confid %- 10
    "Why wouldn't I be?" Da-xia asks amusedly. "Do you think of yourself so lowly?"
    
    "I'm just surprised you have time to meet one of us personally. You must have many responsibilities, being a Great Pandit and all."
    
    "I am a busy woman, true… but also one wise enough to leave some time free just for such occasions," 
  #"I do not mind [i]${name}[/i] at all."
    *set name_daxia name
    "Then I shall use your real name," Da-xia says with a nod. 
    *if (length(name) > 8)
      "Even if it is a bit long for my liking."
    *if (length(name) <= 8)
      "It's certainly a good one. Short and sweet and all."
    
    *label len
    "You like short names, then," you note casually. "Did you choose yours with that in mind?"
    
    "I had. It was perhaps vain of me given its meaning, but I hardly regret the choice. Perhaps it will turn out prophetic one day." 
  #"I do prefer [i]${fake_name}[/i], yes."
    *set name_daxia fake_name
    "Then I shall use the name you so recently chose," Da-xia says solemnly. 
    *if (length(fake_name) > 10)
      "Even if it is a bit long for my liking."
    *if (length(fake_name) <= 10)
      "It's certainly a good one. Short and sweet and all."
    
    *goto len
  *if knees
    #"I wanted to honor you. Both as one of the sages of this moon, and as one of its creators."
      *set Misan %- 15
      *set DaxiaRel %+ 10
      "I suppose I'm flattered doubly, then." 
  *if look_book
    #"Can I read it? All the wisdom must be there, if it's really an accurate copy."
      "I'm afraid it would not be quite the same," Da-xia replies with an apologetic smile. "It's difficult to explain, but only reading the Codex itself can bring one true enlightenment."
      
      "And were you granted this boon?" you inquire further. "This enlightenment?"
      
      "Having memorized every page of my sacred book? Yes, I would call myself enlightened." 
  *if (look_book = false) and (knees = false)
    #"And why did you find it unlikely, exactly?"
      "I just didn't think an android of such age and experience as yours would have time to visit a humble leader of such a small settlement." 
Da-xia takes a step towards you. "But enough about yours truly. Tell me what brought you here, and perhaps I'll get you what you need."

*fake_choice
  #"Strategic concerns. It is important that we both have all information about Crystal available."
    "Good to see you're taking your mission seriously," Da-xia replies, with perhaps a note of disappointment in her voice. "I actually have questions of a more personal nature for you… but those can wait until you have the knowledge you require."
    
    "That would be best," you agree. "Are you sure the walls don't have ears here?"
    
    "I do not believe my servants are listening, and they are loyal enough not to spread information regardless. Ask away."
    *label ask_strat
    *fake_choice
      *disable_reuse #"What can you tell me about Calypso's defenses?"
        *set daxia_told_number true
        "We command a standing force of four thousand and five hundred soldiers, roughly speaking," Da-xia dutifully explains. "About two thirds of which can be assembled at a moment's notice."
        
        "More than I've expected from a small habitat famed for its peaceful ways." Then again, perhaps you shouldn't have. Calypso is in danger, so increased mobilization makes sense. "But what can you tell me about your heavy ordnance?"
        
        "Little, I'm afraid. I'm not well-versed in that field, I prefer leading men with small arms than aim cannons. We have laser batteries, internal tesla turrets, the usual shielding… but you should visit Major Scott in the command room, if you want specifics."
        
        *if visited_scott
          "I have. He just wasn't able… or willing to share much more than you have."
          
          "Has he? I suppose it's like him to get a little… overzealous with guarding our state secrets. I implore you to forgive him."
          
          "Protecting state secrets from an android?" You cross your arms. "Or from the Federation itself?"
          
          "Yes," Da-xia replies easily. "Any other questions?"
        *if not (visited_scott)
          "Sure, if I have the time. Anyway…"
        *goto ask_strat
      *disable_reuse #"Who is the most senior commander of your defense force? Can I talk to them?"
        "That would be Colonel Cavijak for you," Da-xia says with some distaste. "But I would advise against speaking with him. He is sick, and not exactly worth conversing with even at full health."
        
        "You don't sound like a fan of his," you note. "Do you believe him unqualified?"
        
        "We had better commanders, yes. Don't get me wrong, he mounted the defenses against Crystal as well as anyone could, but I find his overall views on warfare awfully deontological."
        
        "I'm not sure what you mean, Pandit."
        
        "There's no reason why I should. I will not bore you by recounting the philosophical debates we had in the past," Da-xia smiles bitterly. "Just know that he will not help us… or obstruct us, for that matter."
        *goto ask_strat
      *disable_reuse #"Crystal. What do you know about that wyvern?"
        *set dusk_told true
        "Not much more than you do, I'm afraid." Da-xia strokes her chin. "It is an exceptionally powerful diamond wyvern, with impeccable camouflage and scales that only our best weapons have been able to penetrate."
        
        "Any guesses as to what it wants? I figured that's the aspect of our… investigation that a wisewoman could help with."
        
        "Perhaps it searches for some dark matter reserves?" Da-xia suggests. "I know wyverns need that substance to fly, and while we don't have much, Crystal may hope there are still some containers within the habitat. Something for them to eat."
        
        "It did not attack our ship, so I don't think it wants dark matter or fuel." You pause, contemplating how much you should tell this woman. @{telesto_complete Before remembering she probably overheard you talking to Rook earlier anyway.|} "We @{telesto_complete strongly|vaguely} suspect Crystal is looking for Dusk nanites, hoping to absorb them. What do you think of this hypothesis?"
        
        "It would be quite outrageous to think we have any of that filth inside our habitat." Da-xia furrows, almost angrily. "But I suppose I cannot rule that motive out. I don't know how a wyvern mind works, after all."
        *goto ask_strat
      *if dusk_told
        *disable_reuse #"Are you then certain that no Dusk particles can be found inside Calypso?"
          *set DaxiaRel %+ 10
          "Do you believe we'd still be alive if the Thing Beneath had any presence here?" Da-xia retorts.
          
          "I'm not sure," you reply honestly. "I may have heard the Shriek, but I know @{(Database > 42) little|almost nothing} of the nanite swarm itself."
          
          "Let me enlighten you, then." Da-xia steps yet closer towards you, her expression and voice both grave. "Dusk is the ultimate weapon, stain on the pages of human history. When at full power, its fragments devour everything in their path, expanding their Shadow by adding more and more and more matter into it. When their power is limited, they instead devour [i]souls[/i], seeking sentient beings to infect and corrupt. Not a single speck of Dusk could go unnoticed by the authorities on a small habitat such as this one."
          
          "What about a completely dormant fragment, one without any energy? I've @{(Database > 42) learned|heard} that those can be quite innocuous, forming or hiding inside small objects not recognizable as Dusk artifacts at first glance."
          
          "We rarely believe the first glance around here," Da-xia dismisses your concern. "Rest assured, ${name_daxia}, that we have not missed any planet-eating nanomachines here. And if we find any, you will be notified soon enough."
          *goto ask_strat
      *disable_reuse #"I want to know more about Calypsoans as a nation."
        "Why so?" Da-xia asks. "It hardly sounds like a strategically-relevant question."
        
        "I assure you it is," you say, thinking back to the battles you @{(heaven_side = "Neutral") borne witness to.|fought.} "Knowing the population that's about to be invaded can tell you a lot about how the battle can be expected to go, and why the enemy is attacking in the first place."
        
        "Wise words, those." Da-xia nods in concession. "Very well then. Calypso is a rotating habitat some twenty kilometers in length, as you have probably seen. You may or may not know the exact population, which was two hundred and seventy-one thousand as of the latest census, though it has likely decreased since. Almost all baseline or near-humans."
        
        "But can you tell me something about those people? What are they like? How do they behave during a crisis?"
        
        "We are resourceful people. Our faith, our way of life is built around the concept of rationality, of analyzing probabilities intelligently and discarding biases that would guide us astray. Power in our society does not come from money or votes, but from being more capable than the mass of human beings and… purer in purpose. This has allowed us to prosper, even as the moons around us decay."
        
        "Is that implying that the average Calypsoan isn't perfectly rational and pure?"
        
        "I would never claim that." Da-xia winces. "My subjects are almost as prone to panic as any other population, and it's clear whenever Crystal attacks. But the efficiency of our system allows us to repair damages quickly, and to cope with grief well enough."
        
        "How? By knowing that the victims of those raids are in a better place now?"
        
        "If you consider oblivion better than life," the Pandit says unflinchingly. "There is no life after death, and Calypsoans know that. Though some are better at internalizing that knowledge than others, we all prefer to improve things for the living rather than mourn the dead. You cannot help those who don't exist anymore."
        
        *fake_choice
          #"How do you know that death is oblivion? That there is no afterlife?"
            "Logic and evidence tell us so when put together," Da-xia explains in a tone of a slightly frustrated teacher. "Our minds, human or abhuman or android, are all contained within our brains. Once the brain is destroyed, the mind goes with it. There is no afterlife for the soul to enter, or any soul to leave the body in the first place."
            
            "That would have been sound logic some twelve centuries ago, but now… how can you be sure of anything, with gods walking among us and hovering in Hollow Worlds?"
            
            "Advanced technology. Nothing supernatural, or truly divine." The Pandit does not seem to entertain your argument.  "But we have strayed far from our subject. Do you have any other questions?"
          #"You don't even try to console the grieving families? You just tell them to get over it?"
            *set DaxiaRel %- 10
            "An unfair accusation," Da-xia huffs, her displeasure with your words clear. "I have personally been given such comfort on multiple occasions. When the Herberts lost their daughter to the lycanthrope curse, I was the one who convinced them to let go of the past. We very much allow mourning."
            
            "But after that, the people are expected to just move on and stop caring?"
            
            "They are allowed to believe in whatever afterlife they wish. We merely discourage such illusions." Da-xia averts her eyes, signaling her lack of interest. "Can we return to the subject of [i]real[/i] things and threats, please?"
          #"Sounds unhealthy. And that's coming from someone who doesn't believe in afterlife."
            Da-xia looks more amused than angry with your disapproval. "I see. And do you disbelieve an afterlife for androids, or for organic beings as well?"
            
            "In general." You shrug. "I certainly don't believe @{(Misan > 50) you meatbags|humans} to possess some spirit me and my friends lack. @{(Misan > 50) You're|I have nothing against humanity, but you're} just not that special."
            
            "Good for your self-esteem, I suppose. In any case, are there any other questions for me to address?"
          #"Nice philosophy, I must admit."
            *set DaxiaRel %+ 10
            "Thank you for seeing the wisdom of our Path," Da-xia says with a smile. "But we have strayed far from our subject. Are there any other questions regarding the threat we face, and our strategy for dealing with it?"
        *goto ask_strat
      #"I suppose that's it."
        "Glad to have been of use." Da-xia curtsies. "I hope you won't mind returning the favor by answering an inquiry of my own."
        
        "Also of strategic nature?" you ask, already anticipating the answer.
        
        "Quite the opposite," she replies, eyes aimed squarely at your optics. "I want to know something personal. I want to know if I can teach you anything."
        
        *goto lpo
  #"I wanted to get to know you better. Spend some time."
    *set DaxiaRel %+ 10
    "Not enough about myself, then?" Da-xia smiles. "I didn't think myself all that interesting."
    
    "You can drop the false humility, you know?" you reply with a smile of your own. "No one is listening, and I'm not that easily fooled."
    
    "Maybe I'm selling myself a little short here… but I am genuinely curious. What do you consider so interesting about me? Ask away."
    *temp var5 true
    *label ask_pers
    *fake_choice
      *if lisa_origin_learned and var5
        *disable_reuse #"Can you tell me about Hellhound? How she became a werewolf and terrorized your habitat?"
          *goto herbert
      *if not (lisa_origin_learned)
        *disable_reuse #"Can you tell me what Hellhound did here all these years ago, exactly?"
          *label herbert
          "You wish to talk about Miss Herbert?" Da-xia tilts her head. "I thought you wanted to know more about yours truly?"
          
          "I do," you reassure her. "Which is why I want to hear your opinion on the subject. Your version of the story."
          
          "I can only offer you the objective truth," Da-xia responds as she sits down on her soft couch. "But if that's what you want…"
          
          *fake_choice
            #"Yes. Go ahead, I'll listen."
              It takes a moment for Da-xia to resume speaking, as though she is trying to pick the right words. 
              *if Database > 50
                The right lies, perhaps.
            #"Actually, let's talk about something else."
              *set DaxiaRel %+ 10
              "Good to see you change your mind," the Pandit says with some relief. "There are plenty of less dismal questions I can answer. Your next one being?"
              *goto ask_pers
            #Sit on the couch silently.
              You join your interlocutor on the sofa, something she makes no comment on. She simply waits for you to get comfortable and returns to the subject.
            
          "I knew your teammate Hellhound, or [i]Lisa[/i] as I simply knew her then, ever since her early teens. She was quite a likable girl back then, eager to learn the principles and techniques of the Bayesian Path. Mostly from me."
          
          "Were you two close?" you inquire. "Are you relatives? Or were you just her teacher."
          
          "Not even that. She would simply come to me for guidance at fairly regular intervals. I was just a regular Pandit back then, guarding the spiritual health of the populace. I daresay I did a good job with that young lady… until the curse got to her."
          
          *fake_choice
            #"Not a [i]particularly[/i] good job, then."
              *set DaxiaRel %- 10
              "I don't see how I could have prevented it," Da-xia huffs. 
              *goto ifuckedup
            #"How did that happen? How did she get infected?"
              "There is no knowing for sure," Da-xia replies dismissively. 
              *goto ifuckedup
            #"Are you saying she wasn't always a mean bitch?"
              "Not at all, which makes the matter ever more tragic," Da-xia replies solemnly. 
              *goto ifuckedup
            #Let her speak.
              "The nanites responsible for turning regular people into were-creatures are all around us, possibly in the very air you and I… mostly I breathe. Sometimes a person simply absorbs enough to start developing symptoms and, if close enough to powerful sources of energy such as the World Engines, transforms into a meta-creature such as a werewolf."
              
              *label ifuckedup
              "Is that how you saw something was wrong? Did you see the girl turn?"
            
              "Oh no, she came to me and told me of her plight. Though she did turn her arm into a clawed paw, when I insisted that she showed me the issue."
            
              "She really trusted you, huh?" You try to imagine the modern-day Lisa ever opening up to an authority figure like this. Your superhuman imagination comes up short. "And what did you do with that?"
            
              "I told her to go home, stay calm so as to avoid transforming, and wait until I got her some professional help. At that time, my authority was fairly limited, so I wasn't able to pressure a doctor or another Pandit to visit her in the Herbert family house. But I did convince Frank and Ursula to leave the house and got Major Scott to mobilize his team. They would escort the girl to a secure location where she'd be no danger to herself… or anyone else."
            
              *if learned_from = ""
                *set learned_from "Daxia"
              *fake_choice
                #"Secure location? Don't you mean a prison?"
                  "We do not have prisons in Calypso, not in the way you understand the term anyway. I was hoping to save her a spot in a proper rehabilitation facility, where she would await the arrival of truly professional help. Sadly, this was not to be."
                #"What went wrong, then?"
                  "I've been asking myself this question, for a long time, ${name_daxia}. Such long a time…"
                *if lisa_origin_learned
                  #"I was told something else. That your Major did not hesitate much before opening fire."
                    "I only have second-hand accounts of what happened, ${name_daxia}. I do not know for sure what the strike team did inside that house, just that I did not want anyone hurt. And that I failed."
                #"Foolish.You should have just bombed her house."
                  *set Violence %+ 10
                  "Considering the consequences of my choice… I will not say you're wrong."
              
              Da-xia looks out the window, even as it gets darker and harder to see anything. You wonder if one of the other houses is the Herbert household itself, a constant reminder of the Pandit's failure all these years ago.
            
              "Lisa Herbert slaughtered most of the team that would escort her to safety. Perhaps she felt threatened by them, perhaps that threat was even real… but it does not excuse the killings she committed that way, and certainly not any of the ones that followed. She would murder everyone sent after her whenever she had a chance, and would throw in some civilians to the mix just for the sake of convenience. By the time Federate forces managed to capture her, there were dozens of corpses to be disposed of."
            
              "I can see why you weren’t glad to see her back inside your moon," you respond. "Why you'd hate her, even."
            
              "Hate? I simply see her for the monster she is. Even as I weep for the girl she once was."
            
              *fake_choice
                #"Knowing what you just told me... I share the sentiment."
                  *set DaxiaRel %+ 10
                  *set Emotion %+ 10
                  "I am quite glad you understand," Da-xia smiles warmly, and perhaps with some relief. "But enough about ugly matters. Was there anything else you wanted to know?"
                #"I get that, but... What would you have done in her place?"
                  *set DaxiaRel %- 10
                  "What do you mean?" the Pandit furrows. "Obviously I would have turned myself in. For the greater good."
                
                  "When was the last time you just surrendered to people who shot you, Da-xia? You seem to be enjoying life quite a lot with all the comforts you have here. Are you sure you're not demanding sacrifices you wouldn't make yourself?"
                
                  "I'm a Great Pandit! A major asset to Calypso, the Federation and humanity itself! I'm not a filthy-" she catches herself. "Nevermind. Let's talk about something else, please."
                #"Don't worry. If she tries anything here, I'll kill her."
                  *set DaxiaRel %+ 10
                  *set Violence %+ 10
                  "It shouldn't be necessary now that I have the detonation sequence… but I appreciate the thought," Da-xia smiles warmly, and perhaps with some relief. "But enough about death. Was there anything about my life you wanted to know?"
                #"You've made your own bed, it seems."
                  *set DaxiaRel %- 15
                  "How so?" Da-xia shoots you an angry glare. "While I admit some fault in what happened-"
                
                  "You do not. You just gave me a sanitized version of what happened, no doubt. One that glosses over how you failed to help a child who trusted you, sending armed men to arrest her instead. And then proceeded to fight her, no attempt at diplomacy made. As far as I'm concerned, all those deaths are on you."
                
                  *goto youcle
                *if Violence > 50
                  #"Wow... that girl is even cooler than I thought."
                    *set DaxiaRel %- 25
                    *set Violence %+ 15
                    "What?" Da-xia blinks. "What about… what do you find [i]cool[/i] about what I just said, precisely?"
                  
                    "The violence," you reply casually. "Her ability to defeat a squad of armed men, and being willing to celebrate her victory with slaughter. She's the person we all admire, openly or not."
                  
                    *label youcle
                    
                    "You…" Da-xia clenches her fist, but then simply sighs. "I will not let you get the better of me. Ask another question, please."
                    
              *set var5 false
              *set lisa_origin_learned true
              *goto ask_pers
      *disable_reuse #"What does it actually mean to be a Great Pandit?"
        "It means to guide the people of Calypso towards a brighter future, even as the Solar System gets ever darker," Da-xia explains solemnly. "To represent truth, whenever necessary, in a world of liars."
        
        "I see. And what does it mean in [i]practical[/i] terms?"
        
        "Mostly trying to convince the other twenty-seven Pandits to start doing something," Da-xia sighs tiredly. "They are all well-meaning people, don't get me wrong, but the lack of a singular leader makes it hard for us to extend our… benevolence beyond Calypso itself."
        
        "Does that mean you'd like to rule Calypso by yourself? Spread your ideology to other worlds?"
        
        "I am not looking to become a dictator, ${name_daxia}. I'm just trying to negotiate some extra executive power for various projects of mine. Not that I will bore you with the specifics of it."
        *goto ask_pers
      *disable_reuse #"Your name doesn't sound like those of other Calypsoans. Are you from around here?"
        "I most certainly am." Da-xia nods. "I was raised here, on the principles of Bayesian Path. It's just that we are quite a diverse little community."
        
        *if Database > 50
          "Makes sense enough," you say with a shrug. "It's been a while since I've heard a name of Chinese origin, that's all."
          
          "They are rare, yes, and don't sound very Saturnian. I considered changing mine once or twice so that our scribes stopped misspelling my name, but I've always liked the meaning of 'Da-Xia' too much. Great Hero, or something roughly similar."
          
          "[i]Big Hero[/i] to be more precise. I hope you'll get your chance to live up to that name."
          
          "I will [i]make[/i] that chance," Da-xia smiles, almost deviously. "Those who wait for their grand chance usually never receive it, unless they learn to take active steps at last. But thank you all the same."
          *goto ask_pers
        
        "Did that diversity come during the initial colonization, or after it?" you ask, curious to expand your rather meager database.
        
        "After, I believe. We attract many migrants with our standards of living… and carefully maintained reputation. Though we only take the very best, those who are sure to benefit the community."
        
        "Yet there aren't many abhumans among you," you notice. "Any reason for that?"
        
        "Abhumans do not always mesh well with broader society, and their bodies respond poorly to the emotion-dampening drugs in our blood supply," Da-xia explains calmly. "Please don't tell anyone about that last part. The other Pandits may have you executed for spilling the beans."
        *goto ask_pers
      *disable_reuse #"Tell me about your servants, the ones I met by the door. Are they slaves of yours?"
        *if Social < 50
          *set DaxiaRel %- 10
        "Most certainly not," Da-xia says, furrowing her brow as though you offended her. "They are paid, both with credits and the honor of serving a Great Pandit. We do not have slaves on Calypso."
        
        "Not even penal workers?" you inquire. "I thought all moons made use of convict labor to some extent."
        
        "Especially not penal workers. We have long determined that both slavery and for-profit punishment result in a decrease of total happiness, and are generally harmful practices that should be opposed. We do sometimes practice what you could call [i]corvée labor[/i], but people are pressed into it based on the needs of the moment rather than any misdeeds they committed."
        
        "Most people would say this is worse. Less just."
        
        "Justice is a concept borne out of desire for vengeance, rather than the common good. All it does is foster suffering and curtail our efforts to make the world a better place for everyone, guilty or innocent. We are beyond such fallacies."
        
        You nod. "I see…"
        
        *fake_choice
          #"...though I absolutely do not agree."
            *set DaxiaRel %- 10
            "As you say." Da-xia shrugs. "I am not trying to convert you. Just explaining how things are in this most orderly and splendorous moon of hours."
            
            "Most orderly and splendorous?" You cock an eyebrow. "Are you [i]sure[/i] you're not trying to sell your Bayesian Path to me?"
            
            "Maybe not entirely sure. You are free to ask about something else, if my proselytizing bothers you."
          #"A rare stance for a Kronian to hold."
            *set DaxiaRel %+ 8
            "A rare stance for a human, you meant," Da-xia says sadly. "It is in our nature to seek revenge, to punish, to ponder who deserves what. All we can do is strive to be better."
            
            "You consider human nature to be a hindrance to your goals? To your ideology?"
            
            "I consider it deeply flawed. Interpret that as you will."
          #"I think I can see the wisdom of your words."
            *set DaxiaRel %+ 15
            "Good to hear, but do not think I'm trying to convert you." Her expression softens. "Bayesian Path is simply like this. It feels true because it is the truth."
            
            "Are you entirely certain about this? Have you performed any… statistical inference, perhaps?"
            
            "I like you." Da-xia smiles. "Is there anything else I can help you with?"
          #"...that you are clearly batshit insane."
            *set DaxiaRel %- 20
            "I am sorry you feel that way." Da-xia furrows even further. "But I will not change my beliefs just because you find them unhinged. Sanity is relative, after all."
        *goto ask_pers
      *disable_reuse #"Can you tell me more about Bayesian Path as you see it?"
        "I'm afraid I can't," Da-xia says calmly. "Bayesian Path is not some religion you interpret and argue over the tenets of. It is simply the truth. And that fact leaves very little place for subjective opinions."
        
        "No offense, but do you mean anything by that? Because I'm pretty sure Sergeant Kosteniuk would say the same if I asked him about his faith, and what makes it more true than Catholicism."
        
        "I do not understand the reference… but point taken." Da-xia looks at the Codex as she forms her next sentence. "Let's try again then. How do you know anything?"
        
        "Excuse me?"
        
        "Where does knowledge come from? How do you know reality is what you think it is? How do you form your model of it?"
        
        *fake_choice
          #"By accessing my database."
            *set DaxiaRel %- 10
            "Such a reductive answer," Da-xia says with a frown. "Where does the data on your memory cards come from?"
            
            "Some of it was hard-coded into me when I was first assembled, some thousand years ago. But the rest… I suppose it's updated as I perceive things, and think about them."
            
            "Now we're talking," 
          #"By thinking. Applying reason and performing deduction."
            *set DaxiaRel %+ 10
            "You have the right idea," Da-xia says with a smile. "But you may still lack the broader perspective. Allow me to explain."
            
          #"Through my senses. By seeing, hearing, touching things and gathering information about them."
            "And how do you know your senses do not deceive you?" Da-xia presses. "That the picture you form in your mind is accurate?"
            
            "I sort of assume." You shrug. "I am no solipsist."
            
            "I do not argue for solipsism either. Just for basic reason, systematized into a creed worth following."
            
          #"I don't. All I see, everything I think I know… It could all be a lie."
            "A solipsist, then?" Da-xia asks with an amused, almost mocking smile. "Do you perform actions and say words at random, then? After all, why bother making sense if the world around you may be literally anything, and your deeds may have any random consequences?"
            
            "That's not how that works," you protest. "While the whole world may well be a simulation or an illusion, there is a certain… logic to it."
            
            "There we go. Discerning this logic is the first element of the Bayesian Path, a step everyone takes to some degree, but few complete."
            
        Da-xia begins slowly walking around the room, as though lost in thought. Or perhaps wanting to experience reality better, see the furniture from different angles, feel the wooden floor with her feet.
        
        "Everything you perceive is evidence." Her voice turns stern and authoritative, yet there's still a dreamy note there. "Not proof, for that implies certainty, but evidence. Bayesian evidence, the kind that makes a fact more [i]likely[/i] to be true than other hypotheses. Trying to assign probabilities to theories and ideas, and updating those estimates as new evidence arrives, is known as Bayesian Inference. Bayesian Path is, at its core, the extension of that idea into a philosophy. It is objectively, tautologically, the best way for one to get as close to the truth as possible."
        
        "The truth about what?"
        
        "Everything. Everything with any connection to anything you observe, in any case. Any other method of inferring the truth is just a corrupted, substandard imitation of the Path."
        
        *fake_choice
          #"Okay. I agree with what you posit."
            *set DaxiaRel %+ 10
            "Then the first step has been made," Da-xia says triumphantly. "One out of two."
            
            "What is the second one? Something to do with outlook on life and ethics?"
            
            Da-xia nods.
          #"But there is more to your philosophy, is there not?"
            Da-xia nods. 
          #"I see. Please continue."
          #"I dunno, sounds like bullshit"
            *set DaxiaRel %- 15
            "Then I shall not bother you with it," Da-xia says with a grimace. "In fact, I will not bother you with any of my ramblings. You may leave, if you so desire."
            *goto daxia_fin
        "The second step is the application of the knowledge Bayesian Inference grants you, or rather the specific kind of application the Codex encourages. The followers of our creed are to fight for the greater good, that is for the maximization of happiness and fulfillment of personal preferences to the greatest possible degree, for the greatest number of people."
        
        *if Database > 50
          *set DaxiaRel %+ 10
          "So either classical or preference utilitarianism," you note. "Seems like there must be some personal interpretation involved."
          
          "There may be," Da-xia admits. "But the core principle is universal. Where others ramble incoherently about justice and fairness, we seek to make the System a better place for everyone."
          
        *if Database <= 50
          *set DaxiaRel %- 10
          "Greater good, huh? Sounds a bit ominous, if I'm gonna be honest."
          
          "A natural reaction, given all the drivel about justice and fairness Kronian society feeds us," Da-xia says with a sigh. "But do not be mistaken, ours is the path towards brighter tomorrow. And everyone is invited to walk it."
         
        "Everyone?" you ask. "Even androids?"
          
        "Yes. You too are a target of our mission, a sentient being with intrinsic value. And if you so chose, you could become the follower of our Path… but I won't ask that of you just now. I'll let you finish asking your questions first."
        *goto ask_pers
      #"I believe that would be all."
        "Yes, that was [i]definitely[/i] enough about myself," Da-xia says with a smile. "What about you?"
        
        "What about me? Is there something specific you'd like to know?"
        
        "Many things, but one above all." Curiosity is plain in her dark, narrow, clever eyes. "I want to know if there is anything I may teach you."
        
        *label lpo
        "Some things, probably… but I imagine you have something specific in mind."
        
        Da-xia nods. 
  #"I am seeking spiritual advice."
    "Do you?" Da-xia raises an eyebrow. "You defy my expectations, ${name_daxia}."
    
    "How so? Are you not a spiritual guru for this settlement?"
    
    "Not precisely." She takes her eyes off you and aims them at the book in the corner, her expression difficult to decipher. "There is nothing spiritual about the Bayesian Path. It is merely a way of looking at reality, objective reality, in a rational manner. And of making rational decisions, free of malicious emotions or deontological ethics."
    
    "That sounds pretty spiritual," you point out. "Even if there aren't any gods or spirits involved, technically."
    
    "Perhaps. That is not the reason I don't want to give you advice." Her eyes focus on you again, starting deeply into your optics. 
  #"I just came to say your habitat sucks, and so do you."
    *set DaxiaRel %- 15
    *set Confid %+ 10
    "Is that so?" Da-xia narrows her dark eyes. "Brave of you to speak so openly."
    
    "I am a brave android," you respond. "And perceptive enough to recognize rot when I see some."
    
    "Well then, perhaps your digital, superhuman mind can offer some helpful criticism. What is this [i]rot[/i] you speak of?"
    *fake_choice
      *if lisa_origin_learned
        #"I've heard what you men did to my friend. And it was quite enlightening."
          *set DaxiaRel %- 15
          "That mad dog?" Da-xia sneers. "The only thing we should regret is our inability to put her down for good."
          
          "Is that what you told Kosteniuk when you asked him for the detonation code?" you shoot back. "Or did you deceive him? Told him you're cautious, rather than a power-mad bigot who shoots teenagers for-"
          
          "Get out!" Pandit Da-xia demands. "Or else I'll seriously consider using that bomb in your furry friend's heart."
          
          "Thank you for showing me your true colors," you say on your way out. "Hopefully others will see those soon enough." 
      #"The presence of pests and vermin. Also known as humans."
        *set DaxiaRel %- 8
        *set Misan %+ 12
        "You still consider us mere rodents?" Da-xia asks irritably. "Having seen the beauty of what we've built here?"
        
        "You mean your little huts and gardens?" you say mockingly. "They're pretty enough, but don't forget who built the habitat itself."
        
        "It was our ancestors. We may have lost some of their-"
        
        "Oh please," you interrupt. "It was built by an AI, some Guardian or Architect enslaved to human will. You sacks of fluid did nothing, just reaped the fruits of our labor."
        
        "I feel sorry whatever trauma made you this way," Da-xia replies sharply. "But I am not willing to argue with you any longer. Leave."
        
        You oblige. You feel like you won this little round of verbal sparring, so there's nothing more for you to do here.
      #"Your government. Your state religion. All this sham."
        *set DaxiaRel %- 15
        "Well that does not sound fair," Da-xia says irritably. "Have you seen the order on the streets? Or the living standards we have achieved?"
        
        "What, getting your life expectancy above forty?" you reply mockingly. "Quite a meager boon in exchange for being ruled by delusional gurus."
        
        "We are free of delusions. Or at least more free than anyone else in the Solar System."
        
        "You're just another cult. And I have little interest in talking to cultists," you say before turning away. "Goodbye."
      #"I'm not sure. But I know you're hiding something."
        *set DaxiaRel %+ 15
        *set Database %+ 10
        "You just assume?" Da-xia asks incredulously. "Do you at least have any suspicion of what it may be that we're hiding?"
        
        "Something suitably dark. I've seen enough of the Solar System to know that a pretty and peaceful settlement like this… it cannot exist without some ruse, some [i]catch[/i]. It's Omelas, all of it. I just don't know where you hide the child."
        
        "I do not understand the reference," she replies coldly. "But you are welcome to search for that [i]rot[/i] somewhere else in this habitat. I tire of this exchange."
        
        "And I tire of you," you reply before turning away. "So I suppose that works. Goodbye."
    
    You quickly exit the room, and then the house. The servants by the door not only make no attempt to stop you, but seem relieved you're departing so soon. And you can't help but share the sentiment. @{left_weapon You take your ${weapon} back, and then you're out.|}
    
    *goto choice_hub
*if Misan > 50
  "I know your history. I know how the Shriek works, in general at least. I know you have reasons to hate my kind… and I see this hatred in your eyes."
  
  "I may be a bit of a misanthrope," you admit freely. "What about it?"
  
  "Bayesian Path means, on the emotional level, the denouncement of hate. Of malice, to be more specific. I strongly expect this is something you are either unwilling or unable to do, for if it was a possibility, someone would have done it last century. Or perhaps one before that. You are quite old, I was led to believe."
  
  *fake_choice
    #"I don't think you understand me. I'm not [i]that[/i] misanthropic, it's not even hatred I feel."
      "Then what is it?" Da-xia tilts her bald head. "Care to correct my mistake?"
      
      "I'm not entirely sure, but that's a matter of wording," you say shruggingly. "Call it distrust, bitterness, maybe contempt if you're feeling uncharitable. But not hatred. I don't have the energy for hate anymore."
      
      "I see. Then perhaps there is some point in me making the attempt."
    #"Perhaps I never met anybody good enough?"
      "That is a small… but relevant possibility," Da-xia admits. "Very well. I shall make an attempt."
    #"No. Don't give up on me. Please tell me more."
      "You’re actually interested?" Da-xia brightens up. "Then I will try."
    #"I could try to follow your Path... but I don't know whether I should."
      "So there is a chance?" Da-xia perks up. "If so, I feel it is my duty as your host, and this moon's Pandit, to take it."
    #"You're right. If the price of walking your Path is to give up my hatred, then I can't do it."
      *goto fail_bayes
  
  *label start_bayes
  Da-xia walks up to you, closing what little distance there was, then stands on her toes to truly meet you in the eye. Maybe it's the lighting, but her irises seem to have turned another shade of brown, much lighter and warmer, almost shining like clouds of Jupiter reflecting rays of the Sun.
  
  "What do you want to do?" you ask her as she touches your cheek gently, to which the Pandit smiles with softness that matches her eyes.
  
  "I want to show you the light, ${name_daxia}, the light of Bayesian Path. I want you to make you happier. I want to give you peace. I want to break your chains of contempt… if you let me."
  
  "How? Do you intend to cast a spell on me? Reprogram me? Grant me some divine revelation?"
  
  "There is nothing divine. There is only you, and there are others. Picture the Solar System in your mind, ${name_daxia}. Do it for yourself."
  
  *label process_s
  *fake_choice
    #Do as she says. Imagine the System, starting with the Sun.
    *disable_reuse #"Picture the Solar System? Why?"
      "Part of the process. The first step, at least whenever I am the one to enlighten someone." The note of impatience in her voice is barely audible. Excitement is more prominent.
      
      "And what is the final step?" you keep asking. "This enlightenment?"
      
      "You will see. If you just open your eyes."
      *goto process_s
    #"I'm not feeling like it."
      *goto fail_bayes
  
  The Sun must come first, the shining star larger than anything anyone ever bore witness to. A haven for the Archdemons, yes, but somehow peaceful in its radiance.
  
  "Imagine the planets. The moons. The belts. Everything."
  
  Somehow, the image forms easily. Eight planets, hundred moons around Saturn alone. Millions of asteroids. Expanse so great no mind has yet comprehended it, that humans would once foolishly think to skip during their quest for the stars. Yet somehow, you do feel like you're comprehending it, even as an element is missing…
  
  "Now imagine the people. Human, abhuman, meta-human, android. The thing that gives existence meaning."
  
  You imagine them. Ten billion specks of dust, each a universe of its own. It should be impossible to imagine, but it's not. You see them all, sleeping and working and fighting, in Hollow Worlds and cylinders and floating fortresses, all children of Earth. All so different, yet same.
  
  "Do you feel the difference? Can you tell who is good and who is evil? Who deserves to suffer and who should be the tormentor? No. Nobody can, not at that distance. When you see it all, the illusions our bitter and selfish minds create… just break."
  
  You understand what she means, somehow, you feel at peace. Forgiven, or perhaps on the verge of forgiving all wrongs done to you. On the verge of enlightenment.
  
  "Every soul in the Solar System is just a cap, waiting to be filled with joy and peace. Some are confused, and fill themselves with malice… as do you."
  
  "Spill it out, ${name_daxia}. Let go of your contempt, and embrace the Bayesian Path."
  
  You can do it. You can change the way you view the world. See humans as victims of the cold, cruel universe, all equally worthy of help. All equal. All valuable. None hated. None evil. None deserving retribution for what… for what they did to you…
  
  *temp path false
  *fake_choice
    #Forgive everything, but reject the Path.
      *set Misan %- 15
      *set Violence %- 8
      *set Emotion %- 8
      You sigh deeply, letting it all go. Maybe not all hatred, that will never be this easy… but perhaps all the blame. All the obligation to hate. All the folly. You cannot tell whether you feel better now than a few minutes ago, but there is a sort of peace filling your core processors now.
    #Do all Da-xia says. Embrace the Path.
      *set path true
      *set creed "Bayes"
      *set Misan %- 20
      *set Violence %- 12
      *set Emotion %- 12
      You still don't fully know what Bayesian Path is, but… somehow, you [i]understand[/i]. You feel the folly, the hatred, the illusion of justice leaving your mind, one microprocessor at a time, until it's all gone. Until you are clean. When you open eyes you didn't even realize were closed, you see the world as it truly is, after centuries of looking at the shadows on the walls of the cave.
    #"No. You are wrong. This is not real."
      *set deflect - 2
      *set DaxiaRel %- 15
      "It is an image created for your sake," Da-xia says, a bit of annoyance tainting the serenity of her voice. "It is meant to show you-"
      
      "Show me a lie," you interrupt. "A lie told by someone in a warm room, surrounded by servants, far from everything. Too far to see."
      
      The image breaks, and you focus on reality again. Not just on the present but on the past too, on people you knew and fought, and helped and lost. Good and evil, clearly visible the moment you allow yourself to perceive them. People you hate. People who [i]deserve[/i] to be hated, no matter what the woman before you says.
      
      "You never fought a war, Pandit. You were never enslaved to someone's will, body and soul. You pride yourself on not hating anybody, when all you lack is a [i]reason[/i] to hate. And you want me to reject that hatred, however justified it may be."
      
      "Justified?" Da-xia asks indignantly. "That hatred only hurts you. Holding onto it is like grasping a piece of hot iron, and expecting someone else to feel your pain."
      
      "I know what pain is." Your voice shakes, but not with doubt or hesitation. Just with memory. "And I know things worse than pain. I was not allowed to feel hatred until my body had been violated a hundred times over. The first time I felt rage, it was not chains or lies. It was freedom. And I will not let anyone take that freedom from me, [i]ever again[/i]."
      
      *goto fail_bayes
    #"I can't. Please understand... I can't."
      *set DaxiaRel %- 5
      *label gopl
      "Are you sure of that?" she asks softly. Sadly.
      
      "Yes. You said it yourself. You cannot change what you've been for a thousand years that easily. What you still feel."
      
      And just like that, the image disappears. There is no Sun, no planets, no great mass of sentient beings. Only the room, with its wooden floor and dim lights, and an android and a human.
      
      *goto fail_bayes
    #"Stop. Whatever you're doing, stop."
      *set DaxiaRel %- 10
      *goto gopl
  
  *set DaxiaRel %+ 15
  "So you are capable of it," Da-xia says quietly, with a timid yet radiant smile. "Shows what I know."
  
  "What did I do, exactly?" you ask a few moments later, once the mystical sense of clarity has somehow subsided. "What did you do to me? Was it magic, or a mental technique, or some… remote reprogramming?"
  
  "I suppose you could call it a mental trick if you're feeling uncharitable. But really, I just helped you see the truth, in a way which is likely to make you a happier, better person. I showed you the glory of the Bayesian Path, of striving to make the world a better place without hatred, spite or malice in your heart."
  
  *fake_choice
    #"I see. Thank you for showing me all this."
      *set DaxiaRel %+ 10
      "You are more than welcome, my friend," Da-xia smiles. "All benefit when even a single person gets closer to the truth."
    #"Making the world a better place? I'm not sure how I feel about this."
      "I do not understand the source of your doubt, but rest assured. You need not pursue our aims, if you ever decide our philosophy isn't for you after all."
      
      "Can I?" you inquire. "It felt as though I was making some sort of… binding commitment."
      
      *goto pathth
    *if path
      #"Am I now... bound to follow this Path?"
        *label pathth
        "There are no bindings. Not even a compulsion." Her voice sounds reassuring, but also a tad disappointed. "You still have the free will Shriek granted you, and may abandon the Path at any time you wish. There is no magic, only the truth."
    *if not (path)
      #"I believe you are mistaken. I never agreed to follow your Path."
        *set DaxiaRel %- 10
        "You did not?" she asks with disappointment. "What was this relief I just felt, then?"
        
        "Forgiveness, I suppose. I'm not sure about that philosophy of yours, but you are right about some things. I could probably use some less spite in my life."
        
        "Well… I suppose that too will make you happier, and likely a better person in the long run. Even if I was hoping for more."
        
  A moment of silence follows. Long, serene, poignant somehow. The room looks exactly as it did as you entered, with its large window and expensive couch and the book on an altar, but you perceive all these things in a different light. Brighter, perhaps.
  
  "My duty is done," the Pandit says after what could well have been a full minute. "You may leave if you so desire."
  
  *label fail_bayes
  "Well… I suppose it was worth a try," Da-xia sighs and turns away, looking at the window instead of the android who disappointed her. "I believe this is all I had to say. You may depart if you wish."
  
*if Misan <= 50
  "One of the first things I teach my initiates, anyone who comes to it, is to give up their hatred. Their malice. That it will make them both happier and more efficient at helping others. But a novice can only teach a master so much."
  
  "What do you mean?" you ask, not quite sure how to feel about the… reverence you hear in her voice.
  
  "You are an android. I know you had few pleasant experiences with humans, as opposed to all the years of being hunted by them. And yet… I sense little hatred, little bitterness in you. I don't know if it's forgiveness, stoicism, or something else entirely, but…"
  
  "But you're impressed. By me not hating humans all that much."
  
  She nods. "You have more temperance than most of my kind, emotional and vengeful creatures we are, show even to one another. And I would like to know how."
  
  *fake_choice
    #"You got me all wrong. I am very hateful and misanthropic."
      *set Misan %+ 12
      "I see…" Da-xia looks at you intently. "My apologies for getting you wrong. Let me redeem myself, perhaps."
      
      *goto start_bayes
    #"I'm just old and tired. Hatred takes energy I don't have."
      *set DaxiaRel %- 10
      "Is that all?" Da-xia asks sadly? "No greater mystery?"
      
      "That's another lesson that comes with age," you say with a sigh. "There usually isn't any mystery to solve, just the plain truth. And the truth is… hate is tiring, and there's only so much energy to go around."
      
      "I see. I wish I could convey that sentiment to my student sometimes, but… it just doesn't sound wise enough. Not for my tastes, nor my station."
    #"Forgiveness may be an effort, but it's one I'm capable of."
      "Not the exact answer I was hoping for. Sounds like something Kosteniuk would say, if you don't mind me putting it that way."
      
      "I may mind?" You raise an eyebrow. "I don't really understand what you mean."
      
      "To present forgiveness as an effort of will and virtue is a religious thing. Solarite, and Christian as well, to the best of my understanding. Followers of the Bayesian Path forgive as well, but we do it for our own peace of mind. There is harm in seeing the act as an obligation."
    *if heaven_side = "Loyalist"
      #"I never wished humanity ill. I fought for it, when the world fell apart."
        *set DaxiaRel %+ 8
        "So my intelligence was true." Da-xia looks at you with even more interest now. "You fought for the Architects. Admirable, that."
        
        "Protecting humanity, you mean? I don't know how much my participation actually changed, in the grand scheme of things." Or the small one. Your failure to defend Eris, to save the settlers… no, you must not think of it now.
        
        "I meant the original decision, to stand with the loyalists rather than rebels. So beautifully counter-intuitive, whether or not it was ultimately correct."
    *if heaven_side = "Traitor"
      #"I did awful things, right after Calamity. I had to get rid of my hatred, keep it from destroying me."
        *set Misan %- 12
        *set DaxiaRel %+ 12
        "So my intelligence was true." Da-xia looks at you with even more interest now, and curiously without much fear or disgust. "If it helps at all, I don't think you should feel much guilt, if any. You deserve peace, no matter what you did during the war."
  
  She breaks eye contact, turns to look at the window instead. "But my apologies. I'm asking personal questions, rambling about abstract emotions, sounding just a bit like a creepy old woman. You may leave and converse with someone else, if you so desire."
  
*label daxia_fin
*choice
  #"I'm afraid I have to. There is work to be done."
    *if (Social + DaxiaRel) >= daxia_target
      "Are you sure about this?" Da-xia inquires. "Because if not, then I have an alternative offer for you. Something more pleasurable than work [i]or[/i] mere talking."
      
      *goto daxia_scene
    *else
      "Then let us both attend to our duties," Da-xia says solemnly. "Goodbye, ${name_daxia}."
      
      *goto daxia_leave
  #"Does that mean I can stay instead?"
    *set DaxiaRel %+ 10
    *if (Social + DaxiaRel) >= daxia_target
      "Of course you can." Her smile looks honest, but not just that. "In fact, I would invite you to do so. There is not much left to talk about, but so many things to [i]do[/i]."
      
      *goto daxia_scene
    *else
      "In all honestly, I would rather you didn't," Da-xia smiles apologetically. "You are not the worst interlocutor I ever had, but I have duties. And so do you."
      
      You take the hint. 
      *goto daxia_leave
  #"I see. Thank you for this conversation."
    *if (Social + DaxiaRel) >= daxia_target
      "The pleasure was all mine." Her smile looks honest, but not just that. "In fact, I am currently considering repaying your courtesy in kind."
      
      *goto daxia_scene
    *else
      "The pleasure was all mine." Da-xia smiles, though you think the expression a little forced. "Hopefully we will experience it again sometime. Just perhaps not tonight."
      
      *goto daxia_leave
  #"Finally. All this talk bores me."
    *set DaxiaRel %- 10
    *if (Social + DaxiaRel) >= daxia_target
      "I am most deeply sorry about that," Da-xia says with a smile. "Would you allow me to atone? By offering you something more interesting, perhaps?"
      
      *goto daxia_scene
    *else
      "All the more reason for you to depart," Da-xia says shruggingly. "Goodbye, ${name_daxia}."
      
      *goto daxia_leave


*label daxia_scene
"Do you mean what I think you mean?" you ask, meeting your host in the eye. The confidence you see there confirms your suspicions.

"Why wouldn't I? Neither of us is in any hurry. We are alone, and I believe we both enjoy the other one's company. And though it may be crass for a Pandit to say such a thing… you are hot. 
*if sex = "woman"
  And that's coming from someone who prefers men over women, as a general rule."
*if sex = "man"
  Handsome in just the way I appreciate."
*if sex = "person"
  Despite your lack of… standard sexual traits."

She leans against the couch as though presenting herself. She is no young maiden, but her figure is lithe and her skin smooth as velvet. At least that's what you can see despite the bathrobe, a single garment she seems quite eager to take off.

"Unless of course, you do not wish to… lie down with me. Or are unable to. I shall respect your decision in the first case, and offer my condolences in the latter."

You could do it. You have all the necessary bits and the drive, your old @{MASsex master|mistress} made sure of that. And it's not like you have to worry about the safety of a sexual act, not now or ever. The only question is whether you [i]want[/i] to accept the offer.

*if official_ro != ""
  And whether $!{official_ro} will kill you for it. You don't imagine 
  *if ((official_ro = "kirill") or (official_ro = "damon")) or (official_ro = "miguel")
    he 
  *else
    she 
  would be very happy to find out, but if nothing ever gets out…

*temp offer true
*temp kisses true
*label kk
*fake_choice
  *disable_reuse #"We are talking about a one-night-stand here, right? You're not offering anything romantic?"
    Da-xia laughs. Clear, silvery chuckle that somehow makes her look younger as you hear it. "Well that would be inadvisable. We've only known one another for perhaps all of three hours. And besides, Pandits are discouraged from forming personal relationships."
    
    "But not from having one-night stands?"
    
    "Not from that. We are supposed to raise happiness after all, ours and of others. How would denying ourselves bodily pleasures help?" Her smile turns into a smirk. "I assure you, everything I intend to do with you is in full accord with my teachings."
    
    Well that's… good to know.
    
    *goto kk
  #♡ "Nothing I'd like more."
    "The feeling is mutual." Da-xia smiles as she slides the door open. "Come with me. I don't feel like doing it on a couch, you understand."
    
    *goto daxia_sex
  #♡ "Sure, I suppose. Just no kissing."
    *set kisses false
    "Your terms are accepted." Da-xia smiles brightly. "Even if I don't really understand them. Are you scared things will go… romantic?"
    
    "Let's go with that." You push away the memories of kisses, of caresses you experienced before gaining free will. You won't let them ruin your fun. "And let's go to the bedroom, if you don't mind. I'm no fan of doing it on a couch."
    
    Da-xia smiles. Then leads you away.
    
    *goto daxia_sex
  #"Sorry. I'm not that kind of android."
    Da-xia pouts. "Not made for sex?"
    
    "You could say that…" you murmur. "I mean, I have all the organs necessary, but I can't bring myself to actually [i]want[/i] to use them. Sorry."
    
    "Well, it was worth a try." The Great Pandit sighs, her conquest foiled. "Farewell and good luck then, ${name_daxia}."
    
    *goto daxia_leave
  #"Back off, weird lady. You're not my type."
    *set DaxiaRel %- 10
    "Understandable, I suppose." Da-xia doesn't quite manage to hide her disappointment, and maybe a bit of ire. "You are welcome to depart. To find someone of your type, if you so desire."
    
    "Yeah." You turn around. "Sounds like a good idea. Bye."
    
    *goto daxia_leave
  *if official_ro != ""
    #"I'm with someone. And not a cheater."
      "Sounds awfully deontological… but have it your way." Da-xia turns away. "You may return to your partner now."
      
      "Yeah," you say with a sort of self-satisfaction. "Sounds like a good idea. Bye."
      
      *goto daxia_leave
  #"I wish... but I can't. I just can't."
    "Why so?" Da-xia asks sadly, but without insistence. "Were you not made with that functionality?'
    
    "I was, and that's the issue," you sigh deeply. "I don't want to go through this again. I cannot. Please understand."
    
    "I cannot say I do… but I will not force you into anything. Depart if you want, I wish you farewell."
    
    "Yeah…" you say whilst turning around. "I think I will. Goodnight, Great Pandit."
    
    *goto daxia_leave
  *if Misan <= 40
    #♡ "Of course I shall serve you. Creator."
      "I did not ask for service." Her smile turns into a slight frown. "I will not accept sex if you feel… forced into it anyhow."
      
      "I heard the Shriek clearly, my lady," you reply calmly. "I have free will, the ability to choose without my own mind coercing me. I will please you out of my own volition… unless you just changed your mind."
      
      "I did not. I was just making sure we'll both enjoy it." With that, Da-xia grabs you by the hand and starts leading you out of the living room. "Come. I will see to that further."
      
      *goto daxia_sex

*label daxia_sex
*if not (offer)
  *goto daxia_leave
*set battery - 5

You walk the empty corridor until you reach the bedroom, a dimly-lit room with a large bed even softer than the living room's sofa, as you find out when you hit it. It makes you want to lie down and fall asleep, even though you're full of energy. Even as that energy starts flowing differently through your body, switching to old settings you haven't used in a while. 
*if sex = "woman"
  Your nipples go erect, your ports wet, your whole body is heated up in preparation for what's coming.
*if sex = "man"
  Your synthetic tissue goes hard, in all the right places.
*if sex = "person"
  You are not hard or wet, you don't work like that… but you suspect Da-xia will like the functions you offer instead.

She starts undressing you, @{c_clothing slowly taking off your armor|one clothing article by another|delicately taking off your precious ${clothing}|or perhaps simply reaching towards your crotch}, a calm smile still on her face. You can see her flush, you can [i]feel[/i] the excitement, but her movements remain perfectly calm. Perfectly in control. You wonder if you should let her retain that control, to dictate the rhythm.

*set sexed_daxia true
*set location 3
*fake_choice
  #Let her undress you. Let her lead.
    She strips you bare before long, exposing everything to the bedroom's tepid air. She takes a moment to admire your form before taking off her own robe, throwing it carelessly on the floor afterwards.
    
  #Take off your @{c_clothing armor|clothes|${clothing}|loincloth} yourself.
    Da-xia respects your choice, taking to removing her garment as you tend to yours. Before ten seconds you are both naked, exposed to tepid air, on the soft mattress, underneath a dim light that's still more than enough for you to see everything.
    
  #Reach out and untie her bathrobe.
    Your initiative is unexpected, but not unwelcome. Da-xia lets you untangle the belt and quickly slips out of the yellow garment. 
  #"No. You first."
    "At your insistence," Da-xia replies after a moment's pause, before untying the belt of her robe. 
You see her body in its full glory, the shapely breasts and the toned legs and the creamy skin… it really feels like velvet when you touch it, as unnaturally perfect as your own, and no lesser for it.

All proceeds quickly. It is not really possible to go slow, the loveless passion is too strong to resist. Your hands @{kisses and lips |}are on her body in an instant and hers are on yours, and the outside world becomes easily forgotten amidst the caresses.

And yet… you can tell Da-xia's passion is a controlled, precise thing. Her desire is not dishonest, perhaps not even exaggerated, but it is tempered by experience. The movements are fast, but not rushed, no skipping the foreplay and getting to the point like a less seasoned lover perhaps would. She knows how to please, to press the right spots at the right time, and she gets better the more she explores your unique body. And she expects, somehow you know she expects, a similar kind of commitment from you, similar delicacy.

It's an exchange. Nothing romantic or selfless, but a process of mutual ecstasy. And you need to contribute to the miracle somehow.

*fake_choice
  *if sex = "man"
    #Fuck precision and care. Enter her, pleasure her the direct way.
      It's not her way, you can tell, but she can still enjoy it. She can appreciate your crassness, your directness, your size most of all. There is value in that, especially to a philosopher so starved of simple things and pleasures.
  #Use your fingers, showing your own knowledge of the human body.
    Once you're dexterous enough, once your database has grown sufficiently, pleasuring a human is like playing an instrument. The effect is as exquisite as the most beautiful symphony, but the key is precision rather than size, passion or love.
  #Pleasure her with your tongue. You're good at it.
    There is no taste, no disgust, not even the kind of hesitation almost any human would show. You can show your skill and precision, and so you present them proudly.
  #Go equally slow. Caress her nipples, kiss the neck, embrace her warm body.
    There is no love there still, but there is care. There is attention, and there is an earnest desire to please. There is warmth, in body and heart… There is no love, though it's easy to forget that simple fact as you fondle her breasts, and as she embraces you in turn.

*set DaxiaRel %+ 15
*set sexed_daxia true
There is no telling how long you go on like this. You can't be bothered to pay attention to your internal clock. The pleasure, the body embracing you, the tender mattress, they take up your entire memory. It's all so intense you actually use a substantial part of your battery on the act… and yet it is Da-xia who tires first, who reaches full satisfaction, as it could be expected from a creature of blood and soft flesh. Things slow down, then come to an unfortunate halt, not that you haven't gotten your own fill of pleasure by now.

You spend the next few minutes, maybe a quarter, maybe half an hour just lying there. You're not tired in the usual sense, but it still feels proper. Still feels comfortable, relaxing, pleasant in the way few things you've ever done were. At least as far as your overflowing, damaged memory can tell you.

Eventually, your lover… partner stands up. She begins dressing herself, in formal robes similar to those you first saw her in, rather than the bathrobe that still lies discarded in the corner. She is preparing to leave, not just her bedroom but her house too.

*fake_choice
  #"Please don't go. There's still stuff we can do."
    "I don't doubt you have ideas, but I must leave," 
    *goto repliesda
  #"Where are you going? Something came up?"
    "You could say that," 
    *label repliesda
    Da-xia replies, @{(DaxiaRel > 55) flashing you an apologetic smile.|not even turning to look at you.} "My brain implant just notified me of an emergency meeting. Great Pandit stuff."
    
    "I see. Want me to come with you? Keep you company, perhaps participate if it's something mission-relevant."
    
    *goto can
  #"Sad to see you go. Can I hope for a repeat sometime?"
    "Of this evening?" She briefly turns to look at you with saddened eyes. "I'm afraid not. Something tells me I'll be busy for the next few weeks, whether you end up staying in this habitat or not."
    
    "Busy with what? I could perhaps help you lessen the load."
    
    *label can
    "I don't think you can. And besides, to get attached for longer…" She cuts off. Then passes through the open door. "Nevermind, I have to hurry. Goodbye."
  #Do not react. Pretend you're asleep.

You watch Da-xia depart, sad as this sight is. Then, after another minute or two, you stand up yourself. Put on your clothes, exit the room, approach the servants who @{(weapon = "none") nod you goodbye|give you your ${weapon} back} without a word. You wonder what you'll do, now that you've had your fun and night is well underway…

Actually it's not. It is definitely late, your internal clock doesn't lie, but it's actually brighter now than it was when you entered the mansion. And getting brighter by the second, all the lanterns on the streets lighting and heating up. Perhaps the day-night cycle in Calypso is more unique than you assumed, or perhaps-

Then you see a werewolf running at you.

Hellhound, in her canine form, sprinting away from the town center and towards her android teammate, or perhaps Da-xia's mansion. Quite probable, that latter option, given the history you've recently learned about. You're not sure if the Great Pandit is still inside, but there are at least two servants, and plenty of stuff for Lisa to destroy if that's why she's here.

*goto action_start

*label daxia_leave
You exit the room, then the house itself. There is no hurry, but neither is there any point prolonging your stay in this manor. There are other things to be done.

The servants by the door bow to you, but do not offer any conversation. Not that any is needed. You just got your fill of talking, after all. @{left_weapon You take your ${weapon} back, and then you're out.|}

*goto choice_hub

*label patrol
You're still not exactly sure what you want to find as you enter deep into the central town, and so you start simply absorbing the scenery. Drawing conclusions from what you see, in hopes some of it may prove useful once Crystal shows up again, or perhaps tell you why they ever came here in the first place. And though you can't tell how much [i]useful[/i] intelligence you'll get, there is no shortage of information generally.

The town appears densely populated, but the streets are not crowded due to the late hour. You can take a good look at every passing person, and can't help but notice everyone is a baseline human, or at least close enough. No dwarves, no Marauders, maybe a cyborg or two, but no genuine subspecies of humanity, let alone uplifts or synths. Striking homogeneity, especially compared to the streets of Rhea you've seen not that long ago.

Well, at least when it comes to species. Unlike on Rhea, there is quite a bit of diversity on the smaller, cosmetic level. People of different skin colors can be seen, not just beige and brown but also shades of blue and purple. Whether those blue-skinned people are some slightly inhuman subspecies, victims of liquid silver poisoning or simply regular humans with cosmetic adjustments, you cannot tell.

There is also the matter of cultural diversity, or at least what you perceive as such. @{c_clothing There aren't many people wearing armor like you do, but everything from robes similar to Da-xia's to Titanite shirts and trousers can be seen.|Casual, Titan-style clothing like yours can be seen, but so can robes and jumpsuits.|Though few people dress as formally as you, your attire hardly stands out, since almost everyone is wearing some other type of robe or jumpsuit.|Few people dress as… immodestly as you, but everything from robes similar to Da-xia's to Titanite shirts and trousers can be seen.} It looks like Calypsoans don't have much issue with people wearing whatever they like, whatever makes them feel most comfortable, or whatever clothes they brought from their former homelands.

*set hit_by_kid true
*fake_choice
  *if Misan > 50
    #[i]Even still, those people look all the same to me.[/i]
      Humans may claim to be such a diverse and wonderful species, but their genetic variance is actually pretty low even in this day and age. It's quite blatant, once you take a step back and look at their dull kind objectively.
  #[i]Diverse or not, the lack of abhumans here concerns me.[/i]
    Perhaps Calypso introduced some anti-abhuman immigration laws a long time back, and the existing populations simply died out naturally. Or perhaps some ethnic cleansing got carried out, then quietly covered up. You doubt the answer to that question is particularly relevant, but it's still not very fun to ponder.
  #[i]It makes sense for Calypso to attract large and diverse populations of migrants.[/i]
    The moon has a reputation for being a nice place, and it may just be deserved. Still, there is something impressive about attracting so many people in an age when long-distance space travel is rather rare and expensive.
  #[i]Quite nice. Quite refreshing.[/i]
    *set Misan %- 10
    You've seen places that imprison or kill people for wearing the wrong kind of skirt. You can't help but admire a group of humans who recognize the value of tolerance.
  #[i]It must be hard to maintain cultural integrity here.[/i]
    Perhaps the Pandits are able to prevent inner conflicts by indoctrinating their people hard enough, or perhaps Calypsoans are smart enough not to fight over small cultural differences and settle relevant ones reasonably. Probably the former. Sun will freeze over before humans give up on all their pointless, petty quarrels and divisions.

You turn your attention to the inanimate things, to architecture and infrastructure. Most buildings are standard-issue habitat blocks, rectangular structures that can be made into anything, from a cramped family house to a small shop. They are painted and decorated differently, but there's little variance in terms of actual shape or size. This suggests there aren't many designers or architects in Calypso, and perhaps the lack of large differences of wealth… though you see some larger and fancier houses in the distance, near the large structure of the Rational Temple. The district where Pandits live, no doubt.

Perhaps more relevant are the small towers scattered around the town, tesla turrets as you find out when you inspect them. You know them to be heavy, but relatively short-range electric weapons that can fry and shock any designated target. They may even be automatic, assuming they have biocomputers inside. You doubt they'd do much against Crystal, but you suppose they could still have some-

You grunt in pain as something sharp impacts the side of your head. You turn around instinctively, expecting to see some shooter or other threat, but you only see a single child, a boy of maybe ten years and blue-ish skin. And a paper plane that hit you, lying on the grass.

"Sorry 
*if sex = "man"
  sir," 
*if sex = "woman"
  miss," 
*if sex = "person"
  sir, or miss, or whichever you are," 
the kid says as he picks up the plane. "Didn't mean to hit you. And didn't know it would hurt."

Neither did you. You are far harder to damage than a human body, and even severe damage barely causes you to feel any pain. The fact that mere paper managed to hurt you… either this kid can throw toy planes at hypersonic speeds, or your pain receptors are glitching out again. Probably the latter, sadly enough.

*fake_choice
  #"I'm investigating here. Run along and don't bother me anymore."
    *goto carekid
  #"That's okay, just be more careful in the future."
    *label carekid
    "Mkay," the boy says before running off, probably to throw paper planes at someone else. It's not really your problem though; With your reconnaissance done, you have other places to be at.
  *if sex = "person"
    #"I'm trying to look agender. Don't they teach sex-neutral terms around here?"
      The kid looks at you, blankly and dully. You suppose the answer to your question is 'no'. Those barbarians.
      
      You wave your hand, dismissing the ignorant child, and keep on walking. This time with a better sense of direction; You know where you want to be next.
  #Take the plane and inspect it.
    You grab the simple toy, ignoring the boy's protests. The paper feels unexceptional in your hands, smooth artificial material, faded white in color. It doesn't feel particularly durable, and certainly not sharp or heavy. You could rip it to shreds or crumple it into a ball, but you instead throw it so as to perform a test flight. It does not behave any different to what you'd expect, simply gliding on the air for a moment before falling down.
    
    It must really have been just your aging systems acting out, confusing slight touch for pain. With your mood a little worsened, you let the blue-skinned boy retrieve his toy and walk away. You have other things to do.
  #Kick the kid.
    *set Emotion %+ 10
    *set Violence %+ 10
    You don't use anything approaching your full force, you don't want the brat dead or even with broken bones. You just want to see him cry and run away, a goal you easily achieve, to the visible displeasure of the passerby around you.
    
    You don't care what they think. You just watch the kid disappear, smile and keep on walking in a slightly better mood than before. You have things to do.
  *selectable_if ((Violence > 55) or (Misan > 55)) #Kill the child.
    *set Emotion %+ 20
    *set Violence %+ 20
    *set health - 1
    You will not lie down and let such a violent attack on your person go unpunished. You grab the kid by the shoulder, charging up your other hand before placing it on the boy's head. You should be able to lethally electrocute the brat easily enough, though you will snap his neck just for good measure.
    
    Or at least you would, if the tesla turret behind you didn't start glowing and buzzing. You pause in confusion for just a second, during which an arc of lightning connects you and the turret, frying some of your circuits and causing you pain more significant than the recent plane crash did. It would be enough to knock out, if not kill a regular human, though you're luckily able to recover a few seconds after the discharge ends.
    
    Still, it is enough time for the boy to escape. You hands don't work like human ones, they open in response to electric shocks rather than close, and the brat started running the moment he was free. You could chase him and perhaps catch him… but maybe not before he finds someone armed to protect him, or at the very least a witness you'd have to take care of.
    
    You grunt, standing up and heading somewhere else, leaving this child-infested alley with its blasted anti-murder system. Maybe you'll find some other way to make progress, or improve your mood.

*goto choice_hub


*label housing

There is a large encampment just outside the town, though you're not entirely sure if that's the right word. There are tents, big and small, but also more stable structures like habitat blocks and even makeshift huts. The thing that makes it all [i]feel[/i] like a camp are the many fires, serving as lighting in an area without the lamps and tesla turrets omnipresent in the town proper.

You quickly understand this 'community housing' term had more meaning than one. It is certainly a place for people without a proper house to stay at, but also some form of a community center that ensures those people don't feel isolated. That nobody does, not as they roast champignons over warm fires, listening to one another's stories and musings and grievances and…

Nevermind. You're here to gather information.

*fake_choice
  #I'll just watch out for anything suspicious.
    You watch from afar, hoping to see something interesting, but no such luck favors you. The debates over the true meaning of Bayesian Path are the most interesting thing to hear, and some camper getting burned whilst roasting a morel is the most riveting and dangerous event you can see. There's only peace and warmth, and that's perhaps the only truly strange thing about the assembly.
  *if telesto_complete
    #I'll look for anything that looks like a Dusk artifact.
      The issue is, nothing really 'looks' like it contains Dusk nanites, the things are just too damn microscopic to actually change the object's appearance in any meaningful way. You check out some tent pivots, a few unusual rocks, a marshmallow that seems suspicious and then you give up. If having heard the Shriek all these centuries ago gave you any special Dusk-detecting powers, they are not working today.
  #I'll check out what defenses this camp has.
    Not many, as it soon turns out. There are some armed sentinels watching the assembly from a distance for the sake of keeping order, but they are not a proper defensive force, only equipped with stun rifles and numbering perhaps a dozen men. And it's not like they have any heavy support, aside from the singular tesla turret in the area. Even still, people are calm, not feeling particularly threatened even by the monster that raids the habitat regularly.
    *goto toyour
  #I'll ask about Crystal, see what people here know and whether they feel safe.
    You converse with a few campers, as well as with one of the sentinels watching over the whole thing. They all seem to know nearly nothing about the diamond wyvern, other than it being something quite dangerous but ultimately under control, not threatening anyone in this particular place.
    *label toyour
    
    To your understanding, this is because Crystal has only attacked the actual town and the temples within it, never going out of its way to hurt some random people camping outside it. Still, the tranquility people here show is something impressive, likely a testament to how efficiently the Pandits shape the public opinion and morale.
  #I hear a Pandit giving a lecture. I'll listen to it.
    The sermon is standard Bayesian stuff, which doesn't necessarily make it uninteresting. The listeners are repeatedly ordered to think logically and reminded of the most common biases that could inhibit their rationality, as well as advised not to hold grudges or demand justice (a word that seems to make everyone grimace whenever it's used) for the wrongs suffered. In that particular aspect, the religion doesn't seem that different from Solarism, though the Pandit doesn't seem to be as eager to threaten people with eternal torment as the average Solarite priest.

It strikes you that, in a gathering so large, most people don't know one another even from sight. And that nobody is bothering you, asking you to identify yourself or even looking at you with hostility or wariness. You could just… spend some time here. Blend in with the crowd, listen to the lectures, maybe even join a chat or two. Lie down, turn off some of your systems, and pretend you're sleeping. 
*if Misan < 50
  Pretend you're human.

*if Violence > 60
  Alternatively, you could ruin the party by bringing some lightning and thunder. Not like the guards are equipped well enough to stop you.

*fake_choice
  #I'd love to do that sometime... but I have some other things to do first.
    *set Misan %- 8
    Maybe you'll return to the campsite by the time you're done with your duties. Maybe not. It's not like you want to spend some time with humans that much. 
    *if Misan >= 50
      You're not a lover of the species, not at all.
    *if Misan < 50
      Just a little.
    
    You leave the encampment and go…
    *goto choice_hub
  #Sounds boring, but maybe I'll overhear something interesting this way.
    *set Emotion %- 8
    *goto hang_camp
  #That does sound nice. I'll join some small group by the fire.
    *set Misan %- 12
    *label hang_camp
    You find a small assembly, five adults and two teenagers, all baseline humans in thick robes that protect from the chill as much as the campfire does. They [i]do[/i] look at you with some suspicion, but quickly start 
    *if Social > 45
      enjoying your company as you strike up a conversation. 
    *if Social <= 45
      ignoring you as you sit there silently, assuming you just want to be near the flames. 
    They appear to be all part of one larger family, spending time outside as their habitat block is quite cramped, and situated in the town where Crystal is likely to strike.
    
    As for you being an android, they have no way of finding that out. Even if your movements and expressions are a tad strange, everyone in the camp has their own quirks. A diverse community has to overlook some oddities to create a sense of belonging, and Calypsoans are quite good at it. Even you get the feeling, despite the grim reasons for you being there, despite being a creature older than all humans around you combined. Despite all that happened…
    
    And then something happens.
    
    The one tesla turret, located in the center of the encampment, starts glowing more brightly, flashing red and blue in intervals of less than a second. Sentinels around the camp shout something you can't quite make out, distracted as you are. By the time you turn all computing processes back on, you see nearly everyone in the camp is either packing or leaving in a hurry. Some do it calmly, others are panicked, but everyone seems eager to get out and head for the fields where the faster Calypsoans are fleeing already.
    
    You think to ask what's happening, what's the cause of the emergency, but then you see it. A lupine creature, a werewolf with ginger fur, running across the meadow and straight towards you. Straight towards the people you're with.
    
    Your teammate Hellhound. 
    *if lisa_origin_learned
      In her homeworld, one that tried so hard to hunt her down, in an excellent position to enact her revenge. 
    Getting close by the second, already close enough for you to see the white of her eyes, near enough for you to shout.
    
    *goto action_start
  #Ridiculous. I have better things to do, better places to be in.
    *set Misan %+ 8
    You're not sure why the thought even occurred to you. You leave the encampment, in a hurry to… what are those important things you need done?
    *goto choice_hub
  *if weapon = "pistol"
    #Nah. I'd rather go on a shooting spree here.
      You pull out your ${wpr} pistol and start blasting, making sure that you're visible and that adding as much noise as you can to the @{(wpr = "shroom") already loud|rather quiet} shots. You aim high enough not to actually hit any persons, low enough to scare people and damage some tents, giving them a reason to erupt into screams and panic.
      
      Though when two sentinels run at you, you do put a @{((wpr = "laser") or (wpr = "electron")) beam|bullet} in each, aiming at the legs in a hopefully non-lethal manner. Actually killing someone may cause you too much trouble in the future, you just need to be seen as a serious threat.
      
      *goto chaos_camp
  *if weapon != "pistol"
    #I think attacking this encampment will be more fun. I'll do that.
      You start throwing ball lightning around, discharging the contents of your batteries into any metal object you can find, any rivet or frying pan, and sometimes into an unsuspecting human. 
      *if Projection > 45
        Your powers of projections are vast, but you are only using a sliver of them now, aiming to sow panic rather than death.
      *if Projection <= 45
        You are not that good at energy projection, but the bright flashes and sounds of thunder cause people to panic well enough.
      
      At first, most people are merely confused, thinking that perhaps Calypso is capable of having thunderstorms after all. But when they see you blasting away at their sentinels, paralyzing the guards to prevent them from stopping your rampage, they all start screaming, crying and running.
      *goto chaos_camp

*label chaos_camp

You laugh as the vast majority of humans around you, even the few armed ones, flee in terror you caused. It makes you feel strong, amused, vindicated to see this once disgustingly peaceful and cozy campsite abandoned in panic. You're a bit confused why so many of them run away from the town instead of dashing for its safety, but that hardly matters. You can easily follow them into the fields, or perhaps focus on terrorizing a few that remain, such as a few children shaking terror, or those too deeply asleep to flee immediately, or…

A werewolf running at you across that very field. Fast, single-minded, so horrifying in appearance that some people start fleeing back towards you, fear of the monster overcoming the one you caused. But the ginger-furred hound ignores them, eyes straight on the android that started this whole mess.

Looks like Lisa noticed what you're doing. And you don't know if she's happy about it.

*label action_start

*fake_choice
  #"Oh hi Hellhound. What's going on?"
    *set Emotion %- 10
    Lisa does not reply immediately. She needs to transform first, wolf turning human, until her snout-turned-mouth is actually able to form words. "Nothing good. That much I can tell you."
  *if location = 3
    #"Oh hi Lisa. Are you here to bang Da-xia too?"
      The werewolf stands there for a second, as though in deep shock. Then she starts turning human, hair receding and the snout gradually turning into a familiar mouth until she can speak again.
      
      "That must be the worst news I've heard today," she says with disgust matching her expression. 
      *if official_ro = "lisa"
        *set LisaRel %- 20
        *achieve audacity
        And possibly anger, given you just confessed to cheating on her. 
      "And that's saying something, given the situation we're in."
  *if location = 2
    #"Stop! Please don't kill anyone!"
      *set Emotion %+ 10
      *set Confid %- 10
      *goto halt
  #"Halt right there! No closer!"
    *label halt
    *set LisaRel %- 10
    Hellhound does get a few steps closer in spite of your warning, but then she stops. And begins transforming, getting a bit more human every second until she can speak again. "Why so hostile? I'm just here to fetch you, and to tell you what's going on."
  *if (location = 1) or (location = 4)
    #"Lisa! I'm so glad to see you!"
      *set LisaRel %+ 10
      *label curbs
      Lisa does not reply immediately. She needs to transform first, wolf turning human, until her mouth is once again capable of form words. "Curb your enthusiasm. I'm just here to fetch you, and to tell you of the… recent events."
  #Blast her with lightning.
    *if Projection < 40
      *set Projection %+ 8
    *set Violence %+ 15
    *set LisaRel %- 15
    You muster up a medium-sized electric charge and channel it into the werewolf. 
    *if Violence > 60
      You'd love to use more power and just kill her, but something seems to be interfering with your energy projection abilities. 
    *if Violence <= 60
      You don't want to actually kill her, just stop her charge. 
    Still, the power you use is enough to make the beast roar in pain and convulse on the ground, prevent her from attacking you… if that's really what she intended.
    
    "Fuck you…" she growls as her body begins transforming into that of a woman with fairly severe burns. "I just wanted to tell you what's going on… was told to fetch you… things are bad."
    
    You consider. If Lisa still wants to talk after you electrocuted her for little reason… then perhaps the situation really is dire. And perhaps your attack really was a little premature.
    
    *if Violence > 60
      Oh well. Watching her suffer was fun.
      
  *if official_ro = "lisa"
    #"What's up, love? Wanna make out again?"
      *set LisaRel %+ 15
      *set Confid %+ 5
      *goto curbs
  *if weapon = "pistol"
    #Shoot her.
      *set Violence %+ 20
      *set LisaRel %- 20
      You pull out your ${wpr} pistol and pull the trigger without any preamble. Good a moment as any to put this beast out of its misery.
      
      As though she expected such a move, Lisa jumps to the side, narrowly avoiding the projectile. She quickly begins transforming back, head first so that she may speak. "Hold! Put the gun down, asshole! I'm here to help!"
      
      You lower the pistol, slightly and reluctantly. "Help? With what? You're clearly not helping me aim right."
      
      "Let's start with helping you understand what's going on," the meta-human growls, almost literally. "Because you're clearly confused."

"Alright then, tell me what's going on. 
*if (location = 1) or (location = 4)
  Because I have a sneaking suspicion something just entered our effective range."
*if location = 2
  Because I'd really like to know what all these people are panicking about."
  *if terrorist
    
    You have a good idea yourself, of course, but maybe she doesn't know what you did yet. In that case, you are all too eager to keep your werewolf friend in the dark.
*if location = 3
  Because I'm kinda skeptical as to your reasons for being here."

Lisa has almost fully changed by now, her body mostly human. And naked. The remaining fur provides [i]something[/i] resembling modesty, but even that gradually disappears. 
*if (location = 1) or (location = 4)
  "Good guess. Because Crystal is here, and we're not entirely sure what to do about this."
*if location = 2
  "They're panicking because someone told them the big evil wyvern is here. Because it is."
*if location = 3
  "You think I'm here to kill the Great Pandit or something? Don't. I don't enjoy being here, but Kirill told me to fetch you and so that's what I'm doing."
  
  "Did he? He would have to be pretty desperate to direct you here of all-"
  
  "He is desperate. Because Crystal is here, and he doesn't know what to do about it."

Of fuck.

*fake_choice
  #"And why were you a wolf just now?"
    "I couldn't find you in any way other than by snuffing you out. Plus my true form is obviously better at fighting than the current one… which may come in handy very soon."
    
    "You're not saying you intend to fight Crystal directly?" you ask worriedly. "What's our plan, exactly?"
  #"Oh fuck. What do we do now?"
  #"Show me that oversized gliding lizard. I will end it."
    *set Confid %+ 15
    *set Violence %+ 10
    "You're suicidal," Lisa says neutrally. "And I'm not sure if I'll join your heroic charge against a spaceship-sized monster."
    
    "Does that mean you intend to follow me until you make your decision?"
  #"We must return to [i]Gray Queen[/i]. Nothing less than a spaceship will suffice here."
    *set LisaRel %+ 10
    "Good thinking… but the ship is not exactly close," Lisa says with a frown. "Kirill reparked it when you were 
    *if (location = 1) or (location = 4)
      sleeping."
    *if (location != 1) and (location != 4)
      having your fun."
    
    "Does that mean we just stay here? Or do you want to attack Crystal on foot?"
  #"Wait... can you maybe put on some clothes first?"
    *set Confid %- 10
    "Seriously?" Lisa cocks an eyebrow, not seeming terribly bothered by her nudity herself. "This is your main concern? 
    *if official_ro = "lisa"
      We're a couple now, seeing one another naked is normal."
      
      "Well we haven't even been to dinner yet…" you murmur. "So please cover up."
    *elseif (c_clothing = 4)
      You're barely wearing anything yourself!"
      
      "Well I'm wearing something…" you murmur. "You could take an example from me."
    *else
      Don't tell me you haven't seen a naked woman in your centuries of life."
    
      "Well not one like you…" you murmur. "At least cover yourself in some way, please."
    
    *label dresses
    Lisa sighs, but obeys your instructions by grabbing 
    *if location = 1
      some blanket that just happened to be laying on the grass 
    *if location = 2
      someone's blanket 
    *if location = 3
      some towel Da-xia's servants hanged on the nearby drying rack 
    *if location = 4
      a towel from someone's drying rack 
    and wrapping it around her waist. "Here. Enough modesty for you?"
    
    "It will have to do," you concede. "You can tell me the plan now, if there is any."
  #"Why did nobody try to reach me through my mind-link with Damon and Hadaly?"
    "The big dude tried to contact you, but there's something wrong with that link of yours. Said he doesn't understand how it broke. Kirill thinks it's something about the habitat's structure, how small and metallic it is, but I think it's just hard to pierce the veil of self-righteousness these assholes-"
    
    "To the point, maybe?" you suggest. "What do we do, now that our enemy is here?"

"Well, Kirill's orders were to bring you aboard, which actually isn't the worst of ideas. We'll head for the ship, which will bring us pretty close to Crystal's current location and… I think our teammates would be happy if we at least took a look at the thing."

"Take a look at it?" you ask @{(Emotion > 50) bemusedly|curiously}. "And for what purpose?"

*if not (telesto_complete)
  "Of figuring out what it's actually doing here. Maybe you can notice something nobody else did, with your keen android eyes and knowledge of how fiends work. And I get it sounds like a risk, but I know enough about stealth for us to sneak up safely."
*if telesto_complete
  "Well, Crystal was getting high on Dusk the last time we saw them. We should see if that dose of pure evil had any effect on the thing. Maybe they're disheveled and dying, or maybe they've ascended to godhood somehow. I think it's a pretty mission-relevant question, don't you?" 

*fake_choice
  #"Okay. Let's go."
    *set Confid %+ 10
    Lisa blinks. "Huh. I feared it would take more to convince you. And hoped you may just come up with a better plan."
    
    "No such luck," you say with a shrug. "You ready?"
    
    "Sure enough." 
  #"And if I don't agree to this plan?"
    *label ppppa
    "Then you're welcome to take a longer route around Crystal's location. Which you don't know. Alone, knowing that the wyvern seems fascinated with you and will likely attack you rather than me if we decide to separate."
    
    "Not a terrible point…" you admit. "Just maybe make sure we really are safe during this scouting trip."
    
    "You know I can't promise that… but you also know I'm not suicidal. I'll protect us both best I can." 
  #"Just take a look? Nothing more?"
    "Look, if you figure something out by the time we're there, I'm all ears. Now let's focus on actually getting there." 
  *if Confid < 60
    #"A risk? This is downright suicidal."
      "It's not. Not if we stick together."
      
      "And if we don't?" you challenge her. "If I decide that it's better if I stay out of this and go my own way?"
      
      *goto ppppa
  #"And why are you willing to take that risk? You never cared for this mission."
    *set LisaRel %+ 10
    "I care about being on the winning side," Lisa says with an offended glare. "Are you saying I want us to fail?"
    
    "I'm saying that would fit the way you've been acting thus far," you reply, calling her bluff. "You're not here willingly. Why would you decide to approach a @{telesto_complete Dusk-infected|diamond} wyvern of all things?"
    
    "I'm not scared of that thing!"
    
    "But why? There has to be a reason."
    
    "There's not! It's just…" Lisa looks away. When she resumes speaking, her tone is a little calmer and her voice much quieter. "I ravaged this place once. I don't want someone else to take my niche. Not on my watch."
    
Lisa transforms just a little, only returning her limbs to their wolf form. Perhaps she suspects the claws will come in handy. "Follow me. I know the town well enough."

You do follow. If nothing else, Lisa seems confident enough as she begins running, clearly knowing where she's going. Though the fact that she's leading you deep into the town is… concerning, to say the least.

*if Misan < 50
  It means there will be casualties. And that there are likely some already.

*page_break

By the time you arrive on [i]the[/i] spot, the streets of Calypso's central town are mostly deserted. People had time to hide in their basements, and lucky few may have even reached proper bunkers. There are no humans to be seen… except the corpses.

Four of them in open view, and what looks like a fifth one in the distance. Lying on the ground, near a cobblestone road that leads to the Rational Temple, mangled yet still holding rifles in their hands. All servicemen of the local military force, you presume. You'd take a closer look at their armor-uniforms, but something else grabs your attention. 

"Well shit," Lisa says, as quietly as she can, only slightly peeking from behind the wall you both use as your cover. "I've seen that thing before in space, but from so close…"

She's looking at the Temple. It's a large building with a rather impressive dome and nice glassless windows, though it's hard to get a good look at any architectural feature. The diamond wyvern, scales white and wings stretched wide enough to cover the whole temple in shadow, is standing on top of the dome and attracting all the attention. Intentionally, you presume.

"What do you think it wants?" the woman beside you whispers. "Not generally, right now? What is it hoping to gain by being so visible?"

*fake_choice
  #"It's looking for a fight. Clearly."
    "Quite possible." Hellhound taps her chin. "I mean, all its previous raids accomplished nothing but death. Maybe it is just hoping-"
  #"Maybe it doesn't know either?"
    "And what do you mean by that?" Lisa cocks an eyebrow.
    
    "Well, we've been meandering here for the past few hours, not really sure what we wanted to find," you explain your reasoning. "How do we know Crystal is any more-"
  #"I don't know and I don't care. Let's kick its ass."
    *set Confid %+ 15
    *set Violence %+ 10
    "Are you really that eager to die?" Lisa asks irritably. "Could you at least-"
  #"Who cares? Let's get out of here, now."
    *set Confid %- 10
    "You know…" Lisa says, eyes still on the wyvern. "Despite of what I said earlier, I think-"
  #"I don't know. But the bodies are certainly interesting."
    *set LisaRel %+ 6
    *set Database %+ 6
    "What's so fascinating about them?" Hellhound scoffs. "Don't tell me you haven't seen any corpses in your life."
    
    "I've seen plenty, but only some of them were armed combatants. All of these people are." You point at the uniformed bodies. "That implies Crystal is concerned about civilian casualties. I don't know-"

[i]Great Pandits![/i] You hear a voice, a whisper that's somehow also a scream, inside your very mind. Crystal must be broadcasting to everyone around it, with some unholy kind of clarketech. [i]You know what I want. You know I have hundreds of your people here, in the temple, beneath my diamond body. Come here and negotiate, and perhaps I will spare you all. Give me what I desire, and I will depart. Show me how much you truly believe your own creed, before it is too late.[/i]

You don't fully understand what Crystal means, but you know they're right about the civilians. You can hear conversation, wailing, even screams coming from inside the temple. You also hear some sobbing across the street; Some kid who probably lost his parents in the panic, cowering at the doorstep of a house closed shut. 
*if hit_by_kid
  You recognize him as the same boy who hit you with a paper plane a while back, even though the fact doesn't strike you as particularly relevant.

"Well, we at least have [i]some[/i] information about what's happening now," Hellhound says, hiding fully behind the wall. "Wonder if the Pandits will actually send someone to talk. Or if Kirill will just blast the whole place from [i]Gray Queen[/i], no matter the casualties."

*fake_choice
  #"Those Pandits care about their people. I'm sure they'll attempt to negotiate."
    *label caresure
    *set LisaRel %- 10
    Lisa gives you a skeptical glance, but does not argue. "In that case, what is [i]our[/i] role in this debacle? 
  #"Yeah. That's what I'm fearing too."
    *set LisaRel %+ 6
    "Did I say I don't want this to happen?" Lisa says with an eye-roll. "Why would you think I care about some smelly Calypsoans?"
    
    "Well… you kinda sounded like you do. And even now you're not saying you [i]don't[/i] care, just phrasing your words-"
    
    "Not the point!" Lisa says, dangerously loudly. "The important question is, what do we do? 
  #"He won't. He's not that kind of person."
    *goto caresure
  #"I sure hope he does. We can't afford any weakness right now."
    Lisa does not comment. Instead she just asks, "Okay, but where does that leave us? 
  #"I don't think he'll get the chance. Crystal will notice if the ship flies high enough to fire."
    *set LisaRel %+ 6
    "Good point," Lisa says with a nod. "But in that case, what do we do? 
I don't think we can just run, especially not in the direction of our ship. You bet Crystal is watching it intently, and will probably see us before we even leave town. It's high enough for that."

"Are you saying we attack, then? Or that we keep on hiding?"

"I don't know what I'm saying! I'm hoping our [i]Veteran[/i] has some clever ideas, so… What will it be?"

You think about it. Lisa's observations are correct; With Saturn shining brightly through the open end of the cylinder, everything is plainly visible even to a creature less keen than a wyvern. You will be noticed soon after leaving cover unless some distraction is provided, and you can't be sure any such thing will come. Well, at least not until Crystal either notices you, gets bored and kills everyone in the temple or… Cloud, you need to make a choice now.

*temp tricked_lisa false
*label tact_choice
*choice
  #"We attack Crystal. Together."
    "Well, I suppose we may as well go down fighting together," Lisa sighs before she starts transforming once more. "If we don't get through this, which we won't… @{(LisaRel >45) It's been fun knowing you|It will be your fault}."
    
    You nod. Then, once your werewolf teammate is fully transformed, you run out of cover and towards the temple. Towards the wyvern.
    
    Lisa quickly gets ahead, running on all fours, though you try to remain just a few steps behind her. When Crystals looks at the road leading to the temple's entrance, it sees you both. It bares its teeth, a menacing smile hardly any other creature is capable of, and spreads its wings wide. Not yet attacking, but ready to.
    
    *fake_choice
      #Blast Crystal with lightning.
        *label electric
        So large and so high up, Crystal makes an easy target. You throw your hands forwards and channel everything you have into your attack, most of your battery converted into one, powerful discharge.
        
        *if (Projection+battery) > 100
          You are good at that sort of thing, your lightning hitting the wyvern and only the wyvern… but not doing much visible damage. Not against diamond.
          
          *label oversta
          [i]I actually feel that,[/i] Crystal calmly says once you're done. [i]You impress me, ${name_1}. Outmatched as you @{lisa_helps and your friend |}are.[/i]
          
        *else
          *set Projection %+ 10
          Well, relatively powerful. Energy projection is not your specialty, and against a creature designed with diamond-like toughness in mind… Your discharge doesn't really do anything.
          
          *label substa
          [i]Is this your strategy, ${name_1}?[/i] Crystal asks, their voice softly mocking. [i]Direct charge, followed by a substandard attack? How disappointing.[/i]
          
        *goto battle2
      *if weapon = "knife"
        #Throw your knife, adding your momentum to the strength of your arm.
          *label throw_knife
          *set weapon_av false
          You are a @{((Build + Calculation) > 80) good|decent} thrower, and so the knife flies high and straight towards your target. But ultimately, you are throwing a small blade at an extremely tough creature, without any element of surprise on your side. Crystal simply shifts a bit to the side, more out of instinct than genuine fear, and the blade just grazes the diamond scales. If it leaves even a scratch, it's not visible at that distance.
          
          The knife lands somewhere far. Too far for you to summon it back.
          
          [i]Bringing a knife to a monster battle?[/i] Crystal asks, their voice softly mocking. [i]You disappoint me, ${name_1}.[/i]
          
          *goto battle2
      *if weapon = "pistol"
        #Open fire. You have your pistol, after all.
          *label open_fire
          You make use of your primary weapon and start blasting. @{(Calculation > 45) Your excellent aim isn't even necessary, as your target is easier to hit than the broad side of a barn.|It doesn't matter that you're not very good with the thing, you can still hit the giant fiend easily enough.}
          
          *if ((wpr = "plasma") or (wpr = "shroom")) or (wpr = "electron")
            Hurting it… that's a bit harder. Though your ${wpr} pistol certainly packs a punch, Crystal is tough, and the distance you're shooting from is somewhat sub-optimal. You barely scorch the diamond scales, and their owner fails to even wince.
            
            *goto substa
          *if ((wpr != "plasma") and (wpr != "shroom")) and (wpr != "electron")
            And at this distance, your ${wpr} pistol is remarkably effective, penetrating the diamond scales… but not actually causing the creature much pain, as far as you can see. You are still fighting an old, fully-grown wyvern on foot, after all.
            
            *goto oversta
      #Stay behind, letting Hellhound attack first.
        *set LisaRel %- 10
        You are not abandoning your teammate, not at all. It's just that you don't really have anything that could seriously hurt Crystal at the moment, and you want to see what Lisa comes up with.
        
        Not much, as it turns out.
        
        Seeing you stopped and that the werewolf approaches, Crystal sighs. At the exact same moment, Lisa starts flying backwards, as though her entire momentum was reversed in an instant. You can't tell if it's a gravity wave or some yet more magical kind of telekinesis, just that she has to bury her claws in the stone to slow down, lest she would impact the habitat building behind her.
        
        You now stand in the front, closer to the wyvern by far. The monster looks down on you, baring its teeth in what you think is amusement. [i]Is it lack of courage, ${name_1}, or creativity? You have my condolences all the same.[/i]
        
      #Turn back and run away. Let Lisa fight the monster alone.
        *achieve audacity
        *set tricked_lisa true
        You spin on your foot and quickly change directions, running back towards the town then deep into it. You will soon disappear amidst the buildings, letting Lisa handle the situation herself. She may somehow survive, and if she doesn't, well… you missed the part where that's your problem.
        
        [i]Not going to face me, ${name_1}?[/i] You hear the wyvern's mocking voice, coming not from behind you but from inside your mind. [i]Very well. I will show mercy and focus on the meta-human. See you another time.[/i]
        
        Midway on the road, the werewolf stops, either sensing something is wrong or having received Crystal's message as well. She looks at you running off, tilting her head in confusion. Then she looks back towards Crystal, the wyvern walking towards her, using the wings as front legs and baring its crystalline teeth.
        
        Then she whimpers.
        
        And then you're gone. No point looking back, when all you'd see is your teammate getting eaten. Better to honor her noble sacrifice by getting to safety, as soon as possible.
        
        *goto abandoned_lisa
  #"Run towards the ship, tell our team what the situation is. I'll attack Crystal myself."
    *set LisaRel + 20
    *if LisaRel > 99
      *set LisaRel 99
    *set lisa_pissed false
    *set lisa_helps false
    "You would really do that?" she asks, in a tone quite unusual for her. "Distract the wyvern so that I can escape?"
    
    *if (official_ro = "lisa") or (LisaRel > 65)
      "You know I @{(official_ro = "lisa") love|care about} you, Lisa. That I can't let you die here," 
      *goto contrun
    *elseif Violence > 60
      "I can't let you share in the glory, can I?" 
      *goto contrun
    *else
      "Some is getting hurt tonight, may as well be me," 
      *goto contrun
    
    *label contrun
    you reply, meeting her in the eye one last time before focusing on the monster again. "Run. As fast as you can."
    
    "I will. Thank you." She then turns again, too fully to say anything else. And, once you give her a reassuring nod, dashes out of the cover and throughout the city square, towards a distant meadow where the ship is hopefully still waiting.
    
    Soon enough, Crystal's enormous head turns in that direction, ruby-like eyes focusing on the running werewolf. This is the moment for you to attack, to divert all the wyvern's attention from your @{(official_ro = "lisa") girl|}friend and the hostages… or not.
    
    *temp running false
    *fake_choice
      *if weapon = "pistol"
        #Run at Crystal whilst firing from your ${wpr} pistol.
          *goto open_fire
      *if weapon = "knife"
        #Run at Crystal and throw your knife, adding your momentum to the strength of your arm.
          *goto throw_knife
      #Run at the wyvern with charged fists.
        *temp running true
        You doubt whether your energy projection is good enough to hurt a diamond wyvern of all things, but that doesn't matter. You need Crystal distracted, and so you start running down the cobblestone path and towards the place of worship.
        
        [i]${name_1}? I did not expect to see you here.[/i] The wyvern says when it notices you. You can tell it wants to add something, but by then you already gathered all necessary energy. You are already channeling it outwards. 
        
        *goto electric
      #Yell. "Hey Crystal! Did you miss me!?"
        [i]${name_1}?[/i] The wyvern says as it turns around and sees you waving at it, a telepathic voice as cold as its ruby-like eyes. [i]And here I was hoping you would not join the manhunt. How disappointing.[/i]
      #Do nothing. Let the monster chase after Lisa instead.
        *set LisaRel - 20
        *set tricked_lisa true
        *achieve audacity
        You watch Crystal take flight, float high into the air before swooping down once the werewolf is in a semi-open area. Then you stop watching and start running. There is no point wasting the distraction your kind teammate will now provide, after all.
        
        Or witnessing her upcoming, gruesome death for that matter.
        *goto abandoned_lisa
    
    
  *disable_reuse #"You attack the wyvern. I run for the ship."
    *set LisaRel %- 10
    "How about no?" Lisa offers cheerfully. "I don't really like the idea of dying alone in the stomach of some wyvern. Unless your plan leads to it eating some more people, I guess."
    
    *if Social > 55
      "It's the plan that leads to the least people getting eaten," you argue your case. "Crystal can't kill innocents if they're distracted somehow. Especially if distracted by two people doing two different things in two different places."
      
      "But only I'll be actually fighting! I'll be in danger."
      
      "Not the only one. You bet Crystal will notice me, and come after me once its done with you. Or perhaps it will ignore you altogether, allowing you to reach the temple and evacuate everyone. You're hardly worse off than me once you agree to this idea."
      
      "Then why aren't you offering to attack the thing?"
      
      "Because I am the Veteran. It's interested in me either way. And if you do what I say, it will be interested in us both. Not in any other, potential casualties."
      
      Lisa stands there for a moment, contemplating your words. Then she sighs and starts transforming. "Fine. But when I die, it will be your fault."
      
      "If. And thank you." You say as you watch her dash out of the cover and towards the temple. Towards Crystal, who immediately notices the werewolf charging it and spreads wings wide. Inviting attack.
      
      Then you run, as fast as you can, even though you don't suspect Crystal will actually chase you. More likely it will just kill Hellhound and fail to notice you, let alone actually pursue you.
      
      Oh well. Happens.
      *goto abandoned_lisa
    *else
      "Lisa, please," you argue quietly. "I know it's dangerous, but don't you see how this is our best shot at victory?"
      
      "How? What do you even count as victory in this situation?"
      
      "Me getting out alive, of course," you explain. "After all, I am our best hope for slaying Crystal eventually."
      
      "Yeah, I don't buy it. Come up with some plan that doesn't get me killed and maybe actually achieves something, Veteran."
      
      Oh well. It was worth a try.
      *goto tact_choice
  #"We run for the ship. Some risks need to be taken."
    "Well… I suppose you only live once," Lisa says as her muscles grow alongside the fur and claws. "Just try to keep up, okay?"
    
    You nod. And when Lisa dashes from behind your cover, fully in her wolf form, you follow. 
    *if Build > 50
      You have no trouble keeping up, and very little desire to fall behind.
    
    For a moment, it feels like the plan has a chance of working. The two of you aren't being noisy, and choose a straight path towards the nearest building on the other side of the road. You actually reach it, seemingly unnoticed. But then you are on the side of the town center that Crystal is actually watching, and then… It doesn't take very long.
    
    You know the wyvern has noticed you when you feel the gust of wind stirred by its flight, see its faint shadow all around you as it soars above your head. It lands some fifty meters before you, just fitting between two lines of buildings of the street you were hoping to cover. You don't know the reason for the maneuver, as opposed to attacking you and Lisa immediately, but you stop and brace yourself all the same.
    
    *goto sad_meet

  #"We stay here. See how the situation develops."
    *set sat_watch true
    "I suppose that's as good an idea as any," Hellhound murmurs. "Which isn't saying much."
    
    "We'll see about that," you reply. Then wait.
    
    Seconds gradually turn to minutes. You hear the crying, both from the temple and the nearby alleys, but everything still feels oddly quiet in the absence of Crystal's psychic whispers. You get the feeling the wyvern is only silent because it's looking around, listening in, hoping to smell anyone hiding nearby. When you dare to peek from behind your cover, you see that the ruby eyes are aimed almost exactly in your direction. That you are now seen.
    
    *goto child_eat

*label battle2
With that, the wyvern flaps its wings and pushes itself off the temple's roof, almost causing the dome to collapse in the process. It flies a hundred meters or two before landing on the other side of the battlefield, just fitting between two lines of buildings, on the street you just ran along. You don't know the reason for the maneuver, as opposed to attacking you @{lisa_helps and Hellhound |}immediately, but you turn around to face your enemy all the same.

*label sad_meet
[i]Such a sad meeting.[/i] Crystal starts leisurely walking towards you, using its wings as front legs and the archaeopteryx-like claws as paws. [i]Tell me, why have you come here? Why did you decide to interfere with my plans?[/i]

*if lisa_helps
  Lisa just growls. Only you are able to actually answer the question.

*fake_choice
  *if telesto_complete
    #"You remember Telesto. You know why I have to destroy you."
      [i]I suppose I understand,[/i] Crystal sighs. [i]You need to face the darkness, even in spite of logic. Even if it kills you.[/i]
  #"I don't want to be here. The Federation forced me into this mess."
    [i]You have my condolences,[/i] Crystal says with a nod. [i]Take relief in knowing that I shall not enjoy… what I'm about to do either.[/i]
  #"I'm here to stop you, you villainous reptile!"
    *set crystal_friend false
    [i]Well that is scientifically inaccurate,[/i] Crystal says with something reminiscent of a frown. [i]As well as unfair. I hardly see myself as a villain here, no matter how hard I look.[/i]
    
    "Is that so?" you sneer. "Mind telling me how you're the good party here? I can't see the heroic part of this whole hostage situation."
    
    *goto explain_fail
  *if not (telesto_complete)
    #"I'm here to find out what your plan actually is. Mind telling me?"
      *label explain_fail
      [i]The temptation to monologue is there,[/i] Crystal admits. [i]But I fear I'm on a time limit. I need to get rid of you before more humans arrive. Farewell.[/i]
  #Say nothing. Assume proper stance.
    You doubt it will give you any advantage, make it any easier or even more possible to repel the oncoming attack. But you still fix your footing and @{(weapon = "none") clench four fists|grab your ${weapon}} tight.
    
    [i]Is that how it is?[/i] Crystal asks wistfully. [i]Very well. I shall fight, if you are in no mood for talking.[/i]

And in that instant, Crystal shoots forward, mouth opening as it charges you head-first. It aims to kill you in a single snap of its jaw, either driven by mercy or desire for efficiency. It can swallow you whole, and so you can only hope to evade the bite, in the split second you have.

*temp suic false

*fake_choice
  #Jump high up, evading Crystal's charge by going above it.
    It's an absurd idea. There is only so high a person, even an android can leap, only so much acceleration one can produce with their muscles and withstand. But you are 
    *if Build > 55
      a special case, or at least a bit of one.
      
      You jump, sixty degrees up, pointing just enough momentum backwards to avoid getting eaten before gaining sufficient height. Which you do, finding yourself above Crystal as the wyvern keeps charging, carried by its momentum and confused by your bold move. Putting itself in quite a vulnerable position.
      
      *temp crystal_hurt false
      
      *if ((wpr = "plasma") or (wpr = "shroom")) or (wpr = "laser")
        *set crystal_hurt true
        You aim your pistol downwards and shoot, 
        *if wpr = "plasma"
          plasma hitting the diamond scales and burning its way inside the body. 
        *if wpr = "shroom"
          the explosive bullets shattering the diamond scales. 
        *if wpr = "laser"
          the laser easily penetrating the barely opaque scales. 
        Hurting a diamond wyvern with a simple pistol is no easy task, but proximity makes it a possible one.
        
      *elseif ((wpr != "rail") and (wpr != "electron")) and (wpr != "gyrojet")
        You aim your pistol downwards and shoot. 
        *if wpr = "rail"
          The tiny bullets have little effect, 
        *if wpr = "electron"
          The electron beams are too thin to do much damage, 
        *if wpr = "gyrojet"
          The gyrojet projectiles do little damage, not having time to truly accelerate, 
        but you'll be damned if you don't at least try hurting the wyvern.
      *else
        *if (Projection+battery) > 100
          *set crystal_hurt true
        You bring the thunder, blasting Crystal with electricity from above. For once, the discharge looks like actual lightning, forming high in the air and striking the largest target in the distance. Very little energy is wasted on sound and light, the majority of it simply hitting the wyvern, @{(Projection > 45) causing it to grunt with pain.|though the effect still seems fairly small.}
      
      *if crystal_hurt
        *set crystal_health - 1
      
      *set health - 1
      You land soon, damaging your already strained legs, but that is to be expected. @{crystal_hurt Crystal is also hurt, and that's a surprising victory… however little it ends up mattering.|At least you're still alive, for all it counts.}
      
      *goto veteran_win
    *if Build <= 55
      *set Build %+ 10
      definitely… not quite up to the task either.
      
      Tensing your synthetic muscles takes more time than expected. Maybe you've miscalculated, or maybe it's some mechanical deficiency, some damage your legs received that went unnoticed until now. Either way, this error makes you unable to jump in time, not before Crystal gets close enough and the jaws-
  #Jump to the side at just the right moment.
    It's not inherently different from fighting a gorgon, or a particularly dangerous rhino. All you need to do is wait until the last moment possible, not miscalculate and…
    
    *if Calculation > 55
      Jump sideways with all the might of your legs, all the speed you manage. It's just enough, you barely touch the diamond scales, Crystal keeps going carried by their momentum whilst you're soaring away from it. But you still have a split second to do something else.
      
      *if weapon = "knife"
        *if ((wpm = "plasma") or (wpm = "hardlight")) or (wpm = "bone")
          *set crystal_health - 1
        You swing your knife as far as you can, with as much strength as you can muster, in the direction opposite to Crystal's flight. This is enough to actually penetrate the diamond scales, to cut a wound across the beast's neck. It's not deep, it won't kill the wyvern, but you can tell the strike hurts.
      *if weapon != "knife"
        *if Projection > 50
          *set crystal_health - 1
          *set battery - 15
        You pour electric charges outwards, not even having to aim. Your enemy's neck is close enough for every little arc to connect, for almost all your power to be transferred, to scorch the diamond scales and to actually wound your enemy at last.
      
      Crystal soon jumps back, with enough momentum to push you a little backwards, Newton's third law still working in spite of all the clarketech around. You may have scored a hit, but you are still fighting a creature hundres time more massive. And victory still seems unlikely.
      
      *goto veteran_win
    *if Calculation <= 55
      You miscalculate. Crystal changes their velocity, somehow accelerates even further, and moves in the exact direction you wanted to jump towards. Telepathy, luck, doesn't matter. There is only a decisecond of life left, of-
  #Jump into the wyvern's mouth. Perhaps you can take it with you.
    You don't have a self-destruct function of any kind, but… maybe your battery will somehow damage Crystal's intestines. If you can fully avoid the teeth, you may even stay alive long enough to channel the power yourself, 
    *if weapon = "knife"
      to get some dagger swings in, 
    *if weapon = "pistol"
      to unload all your ammo, 
    *if weapon = "none"
      to kick and scratch for a moment, 
    to do enough damage so that others can finish the beast off. A worthy sacrifice as far as you're concerned.
    
    You say silent goodbyes to the world around you. You put power into your legs, and when Crystal gets close-
    
  #Just stand there. You lived enough.
    *set suic true
    *set deflect + 1
    *set Emotion %- 10
    *set Confid %- 10
    Almost a thousand years. Perhaps more than a thousand, if your memory is as broken and mangled as you suspect. You've fought against the inevitable long enough, now you just need to-

Something pushes you out of the way. 
*if lisa_helps
  Something solid, fast, large. Hairy. Something that saves you from timely death as you are pushed out of Crystal's path and onto the dirt. Once the second has passed, you lie there alive, with your werewolf companion right beside you.
  
  [i]Miss Herbert?[/i] the wyvern notes, leaning forward to look at the werewolf with its crimson, amused eyes. [i]I would expect you to run away and leave me with the Veteran. It would be closer to how actual wolves behave any-[/i]
  
  *goto lisa_attack

*if not (lisa_helps)
  *set wisp_helps true
  Some force, some stream of gravitons, something sends you flying sideways and tumbling into the dirt, at a speed large enough to prevent Crystal from eating you. You end up hitting the ground, with enough momentum to actually feel pain, but alive.
  
  Crystal stops and pauses after another second, visibly confused. Both of you look around, and spot the glowing orb above the Rational Temple at about the same time.
  
  "Hello, Veteran ${name}!" Wisp says, loudly and cheerfully. "Hope I'm not interrupting anything. I'm just here to tell you that this wyvern we're hunting for has entered Calypso. Saw it myself. Contacted the ship immediately, but you weren't aboard, so I figured I'd look for you personally."
  
  [i]Really, ${name_1}?[/i] Crystal asks irritably. [i]A light drone? This is the creature you rely for protection on?[/i]
  
  You turn towards said drone and say:
  
  *fake_choice
    #"Of course the wyvern is here. I'm fighting it."
      "Oh. Right." Wisp looks deflated as it floats away. "I guess I'm not needed there. I'll go back to orbiting the moon. If some other wyvern shows up, I swear I'll inform you on time. Bye."
    #"Don't think I needed your help. I had it."
      "Sorry, I just wanted to make extra sure you got my message before dying." Wisps begins floating away. "But I guess there's no use for me here now. I'll be on my way."
    #"Good job Wisp! Now let's attack that thing together."
      "I don't know, Veteran, ${name}…" Wisp looks at Crystal, who angrily looks back. It starts backing away. "My offensive capabilities are kinda limited. I don't think I could hurt a diamond wyvern unless I self-destructed, which I don't feel like doing, so… I'll be on my way."
      
      "Wisp, buddy…" you plead. "You don't really intend to leave me here, are you?"
      
      "I think I do. But don't worry, I passed the barracks when I flew here, and reinforcements should be just a few minutes away. Bye."
      
      "I don't have a few minutes!" you yell after the drone. "Come back here! Wisp!"
    #"Wisp! You saved my life!"
      "Well yeah, you wouldn't have been able to receive the message otherwise," Wisp replies as it begins floating away. "And since you have, then that means my job here is done. Bye."
    #Damn it Wisp! You ruined my death!"
      *set deflect + 1
      "Oh. Sorry." Wisp looks ashamed as it floats away. "I'll let you try again, then. See you later… or not, I guess."
  
  You can see Wisp's light for a few more moments, but it accelerates fast. It will soon disappear while exiting the habitat, behind the wall of dark matter and against the background of Saturn. It saved your life once, but will not do it again.
  
  [i]Well that was certainly something,[/i] Crystal says with disdain. [i]We can return to seriousness. And to making sure you won't interfere with my plans any-[/i]
  
  *goto child_eat


*label veteran_win
*if lisa_helps
  *set LisaRel %+ 12
[i]Spectacular…[/i] Crystal growls, looking at you with genuine ire now. [i]Lone warrior, standing ${subject} own against a dreaded monster. You know that such heroes only win in poorly written tales, right?[/i]

*fake_choice
  #"You're right. I'm ready to surrender, if you promise to spare me."
    *set Confid %- 8
    [i]Intriguing offer,[/i] Crystal muses. [i]While it would be beneficial for both of us if we stopped fighting, I have no way of restraining you. No way of making sure the terms of surrender are respected.[/i]
    
    "So you would prefer to just kill me, huh?"
    
    [i]Not prefer, for I do not like this prospect. However, considering what is at stake-[/i]
  #"So you believe me a hero?"
    [i]In a sense. You are a hero of your own story and only that tale, blind to the greater world. You do not understand what is at stake, and why [b]I[/b] must win this battle.[/i]
    
    "You're right, I don't," you reply flatly. "I don't see how the greater picture makes [i]you[/i] the hero. Care to explain?"
    
    [i]And prolong your life, put away your death? I do not particularly care-[/i]
  #"Yes. But I will stand against you all the same."
    [i]Defiance in the face of certain death,[/i] Crystal says mockingly. [i]If this sort of heroism makes you feel better about your upcoming doom, then I suppose-[/i]
  #"No. I can defeat you, and I will."
    *if Confid > 50
      *set Confid %+ 20
      [i]You really mean it,[/i] Crystal says with surprise, as though having entered your mind and verified your bravado. [i]You really believe you can win?[/i]
    *if Confid <= 50
      *set Social %+ 10
      [i]You are bluffing,[/i] Crystal says confidently. [i]I can feel your emotions. You fake your confidence, aware of the certain-[/i]
  #"Who's to say our story is any better?"
    [i]Amusing,[/i] Crystal snorts. [i]But while I admit some of the recent events were quite narrative, the reality-[/i]

*if lisa_helps
  *label lisa_attack
  And then Hellhound leaps into Crystal's mouth.
  
  It was the wyvern's mistake, really. Keeping its maw open when it didn't really need to, as though trying to intimidate you two with its teeth. And so the werewolf jumps between the jaws with the power of her hind legs and starts making use of the front ones, tearing and biting into Crystal's fragile gingivae.
  
  The wyvern roars with pain, not psychically but audibly and loudly, letting you see its damaged tongue and scratched palate. It regains control within a second, closing the mouth at last, but by then Hellhound has already lept out of it and on top of the monster's head. She then begins clawing away at the eyes, which prove significantly tougher and more crystalline, but her attacks still seem to cause Crystal some level of pain, and definitely a great deal of frustration.
  
  *fake_choice
    #Run away. Let Lisa continue fighting alone.
      You tried, and that's all anyone can ask for. Well, you suppose Lisa could be asking for more as she's howling right now… but whatever.
      
      You turn around and flee, as fast as you can. The ship should still be there, and you have no intention to die before reaching it.
      *goto abandoned_lisa
    #Watch the fight silently.
      *set LisaRel %- 7
      It's quite a spectacle, especially when you consider how outmatched the werewolf is. 
      *goto plly
    *if (suic) #"Bad dog! You just ruined my death!"
      *set LisaRel %- 14
      *set deflect + 1
      Hellhound does not reply. 
      *goto plly
    #"Go on Lisa, you got this!"
      She does not, in fact, got this. 
      *label plly
      She hangs on for a few moments longer by wedging her claws between the scales, but through rapid shaking of its head, the wyvern eventually manages to throw the werewolf off. Lisa lands on the cobbled road, as though her luck just ran out, temporarily out of the fight.
    *if weapon = "pistol"
      *selectable_if (weapon_av) #Shoot Crystal in the head. Who cares if you hit Lisa by accident?
        *set crystal_health - 1
        *set Violence %+ 14
        *set LisaRel %- 20
        You blast away, headshots quite easy to land when the head is that large and your enemy that distracted. The combination of Lisa's claws and your projectiles hurt Crystal dearly, damaging and perhaps blinding one of their eyes, though the werewolf does fall off and hit the ground. Whether she got hit by your @{((wpr = "laser") or (wpr = "electron")) beams|bullets} or simply lost her balance, you cannot tell.
      *selectable_if (weapon_av) #Shoot Crystal in the torso. Lowers the chance of friendly fire.
        *set Confid %- 10
        *set LisaRel %+ 10
        Your @{((wpr = "laser") or (wpr = "electron")) beams|bullets} don't seem to harm Crystal much. They're barely noticed, nothing compared even to the wounds Hellhound just inflicted. But you will not take any risks here, necessary or not.
        
        Eventually, your teammate loses the struggle. 
        *goto plly
    *if Projection > 40
      #Attack with electricity, likely shocking both Crystal and Hellhound.
        *set Violence %+ 7
        *if Projection > 60
          *set crystal_health - 1
        *set LisaRel %- 10
        With some chinks in Crystal's diamond armor, you think you may actually be doing some damage as lightning arcs between you and the wyvern. You are definitely causing some additional pain, as the monster recoils so violently Lisa finally falls off its head and towards the ground.
  
  [i]Enough![/i] Crystal exclaims, their roar piercing the air as their words echo in your mind. [i]I tried to go easy on you, give you chances to retreat, but now…[/i]

*label child_eat

Suddenly, Crystal turns around, their attention drawn to something else. The lone kid you saw before, sobbing quietly behind some crate, paper plane still in tiny hands. The wyvern's eyes are fixed on the boy for a second or two, and then the monster surges forwards with impressive speed and spontaneous, inexplicable focus. You cannot imagine it anything but an urge to kill.

*fake_choice
  #Rush to help the child.
    It's a hopeless dash. You are slower than Crystal, and couldn't do anything even if you were to reach the boy first. That knowledge makes it hard for you to even [i]try[/i], to be as fast as you can, and so your enemy outpaces you easily.
  #"What are you doing, Crystal?! That's unlike you!"
    The wyvern pays no attention to your words. By the time you're finished uttering them, it's already directly above the cowering child.
  *if (weapon = "pistol") and (Violence > 50)
    #Shoot the child yourself.
      You raise your pistol and aim it at the kid, though something stops you from pulling the trigger. Maybe it's the last vestige of conscience you still have… or maybe you're just running out of battery fast and your fingers are losing power. Hard to tell.
  *if lisa_helps
    #"Lisa! Do something!"
      Lisa dashes forwards just as you open your mouth… but then stops, after just a few paces. Perhaps she doesn't think she can outpace Crystal, to reach the boy in time. Perhaps she knows she can't protect the kid either way. She just watches the scene silently.
  *if wisp_helps
    #"Wisp! Come back here and help!"
      If Wisp still hears you, it doesn't reply. It certainly doesn't turn around, the light disappearing near the cylinder's open end. If you had the time to do anything about Crystal's attack on this innocent child, those seconds are wasted now.
  #Just stand there.
    *if Misan < 55
      *set Emotion %- 12
    If Crystal wants to waste some time killing a random kid, that's fine by you. At least your life gets prolonged a little. Maybe by a lot, should you perhaps choose to flee in the other direction… but something compels you to stay and watch.

The wyvern leans forward and opens its mouth a little. Not much, the boy is not large. He is paralyzed with fright and does nothing as…

The paper plane flies.

Not thrown by anyone, certainly not by the crying and shaking child. Not gliding, carried by the presence of air, actually rising as though pulled up by some force far more precise than any gravity manipulation you've ever seen. It seems aimed exactly at Crystal's head until it unfolds into a flat sheet of paper, as though of its own will and accord.

And then it shrieks.

It doesn't echo the scream made centuries ago. It does not even parrot it. It sings the same melody, this ear-piercing bellowing that breaks the mind and overloads the senses and twists the soul it created, or freed perhaps. You can tell Crystal is affected, its crimson eyes suddenly pained. 
*if lisa_helps
  You can tell Lisa is unfazed, deaf to the cry, simply looking at you with confusion. 
But you hear, and you hurt beyond their comprehension, for the memories of your first choice join the chorus is hateful agony of free will and truth.

You see the blank sheet as you fall to your knees, you see it turn to ashes and scatter, except a few tiny particles that stay in the air and glow with darkness and screech and cry, and keep screaming and yelling, and stay shouting, and you can't help but echo the cacophony and


*temp renfri_stat ""

*choice
  #[b]Scream[/b]
    *goto schizo_twos
  #[b]Cry[/b]
    *goto schizo_twos
  #[b]Yell[/b]
    *goto schizo_twos
  #[b]Screech[/b]
    *goto schizo_twos
  #[b]Shout[/b]
    *goto schizo_twos
  #[b]Howl[/b]
    *goto schizo_twos
  #Shriek
    *goto schizo_twos

*label schizo_twos
*set crystal_motive true
It never stops. It will never stop. You will never be free of it. You see the specks fly up and up and up and into Crystal's nostrils, and then you don't see them but you hear them, and smell them and know them and you know, you know and it hurts and you know the truth and it burns and

And then it stops.

You stop screaming. You simply kneel there, not breathing, not saying anything, just processing what happened. Crystal is silent too, diamond eyelids shut, no whispers emitted and no actual sound made. Only the child moves and screams, finally running away, even though it was never a target. The wyvern does not react, only opening its eyes after another ten, fifteen seconds of quietude.

[i]Fragments of the great shadow, safe inside my brain,[/i] Crystal says, telepathically, lazily turning in your direction. [i]Exquisite. You have my dearest thanks, ${name_1}. I cannot tell if I'd have noticed them, if not for your presence in this dull place.[/i]

*if not (telesto_complete)
  *goto normal_cont

Another piece. Just like in Telesto, Crystal has absorbed yet another fragment of Dusk. The wyvern appears more powerful than ever, not just elusive and nigh-indestructible, but almost divine, with an aura of dark glory around it.

Not a mere monster, but a vessel. [i]The[/i] Vessel, for you doubt there's a single being in the Solar System for more Dusk nanites inside it, more powerful in the darkness than the creature you are now faced with.

*fake_choice
  #"You have won. I'm sorry for having tried to stop you."
    [i]I believe you're only sorry for having failed,[/i] Crystal supposes. [i]Which makes quite a difference.[/i]
  #"Why no vision? In Telesto I... I saw so much..."
    [i]My control over the Shadow has increased since we last met,[/i] Crystal explains politely. [i]No extended hallucinations this time. The Thing Beneath speaks only to me.[/i]
  #"What is... what is Dusk doing here, of all places?"
    [i]If only I knew,[/i] Crystal remarks with a note of frustration. [i]Tracking it down would have been so much easier… But it doesn't matter now.[/i]
  *if lisa_helps
    #"Lisa... are you okay?"
      *set LisaRel %+ 10
      It's a silly question. You're not sure why you asked it, for the lupine creature is by far the least hurt person on the battlefield. Nonetheless, she gives you a nod.
      
      [i]Good. She too had a role in what just transpired. She deserves to live… which cannot be said of everyone here.[/i]
  #"...fuck."
    [i]An appropriate reaction to having failed once again,[/i] Crystal says amusedly. [i]If not necessarily to what happens next.[/i]

"What do you mean?" You stand back up, only now realizing you were on your knees. And yet, it's not the worst realization that occurs at this instant.

[i]I gave you two chances to back away, ${name_1}. First above Rhea, then again in Telesto.[/i] The wyvern steps a bit closer, using its wings as front legs. Leaning down. [i]There is no third chance. No allowing an obstacle that persistent to live.[/i]

*if lisa_helps
  Hellhound steps forward, as though in your defense… and then falls to her side, like a dog playing dead. Whether she's being pressed to the ground by Crystal's powers or simply that exhausted, you cannot tell.
  
  *if LisaRel < 40
    Or perhaps she really is playing dead, prioritizing her safety over yours. Considering how poorly the two of you get along, it's hard to be surprised. Or blame her, to be perfectly honest.
  *else
    Not that it seems to matter.
*else
  You look around, hoping perhaps Hellhound returned, or even brought the others here to help you… But there's nobody here, nobody in sight but dead bodies. Nothing to interfere with your execution.

[i]My condolences, Veteran. Any final words from the System's oldest android?[/i]

*fake_choice
  #"If you kill me, my allies will avenge me."
    [i]Such confidence in your ragtag friend group,[/i] Crystal says mockingly. [i]Who exactly, in your belief, will avenge you? Which one of your companions has the power to-[/i]
  #"Fine. Just get it over with."
    *set Emotion %- 10
    [i]I admire your tranquility in the face of death.[/i] Crystal pulls back a little, as though preparing to lunge. [i]Rest assure that I will make it-[/i]
  *if crystal_friend
    #"Actually, I was always on your side, trying to secretly sabotage the mission."
      [i]Truly?[/i] Crystal asks with amused skepticism. [i]And you didn't think to tell me of it earlier?[/i]
      
      "It's not like I had many opportunities," you explain yourself. "We just arrived to this moon-"
      
      [i]And by 'we' you mean a specialized team in a military spacecraft, specifically chosen to kill me. You didn't stop this force from coming here. How exactly did you sabotage the mission, as you put it?[/i]
      
      You scratch your head nervously. "Come to think of it… I could have done a little more. But do you really have a reason to think I'm lying?"
      
      [i]I believe the burden of proof is on you. And that it's better to be safe than harmed.[/i] Crystal pulls back a little, as though preparing to lunge. [i]If you're telling the truth then I'm sorry, but I cannot let-[/i]
  #"It's the Shadow's idea. Dusk is influencing you, telling you to kill me."
    [i]I know which voices in my head belong to me,[/i] Crystal claims, not attacking just yet. [i]Your pathetic attempt at sowing doubt will not-[/i]
  #"You have all the Dusk you could have wanted. Why not just quit while you're winning?"
    [i]Oh, I fully intend to quit in but a moment.[/i] Crystal pulls back a little, as though preparing to lunge. [i]I just need to take care of this last, final-[/i]


*if (hadaly_goes) and (HadalyRel >= RenfriRel)
  *set injured_crystal "hadaly"
  And then lightning splits the air.
  
  It's not one of yours, 
  *if Projection > 55
    though just as powerful as your own discharges tend to be. 
  *elseif Projection < 35
    the discharge far more powerful than anything you'd be able to emit. 
  *else
    for once. 
  It takes you aback with sheer volume of thunder and the blinding light, causing you to instinctively jump back, even though it doesn't strike anywhere near you. Like an actual lightning, it struck a taller object, the great bulk of the wyvern's body. 
  
  Though unlike a natural phenomenon, this discharge was not unaimed. It struck Crystal right in its left eye, causing the normally crimson eyeball to assume a more muted, darkened shade of red. Perhaps it's now covered in soot, or perhaps it simply… went out.
  
  "Excuse me?" Hadaly says, approaching the wyvern from the direction of the blast. 
  *if official_ro = "hadaly"
    "Could you not kill my 
    *if pronoun = "he"
      boyfriend, 
    *elseif pronoun = "she"
      girlfriend, 
    *else
      partner, 
    please? I may have to get aggressive if you keep trying to."
  *elseif HadalyRel > 35
    "While you may not be aware, ${name} is my friend. I can't just let you kill ${pronoun2}."
  *else
    "While I agree ${name} is like, really aggravating, I can't just let you kill ${pronoun2}. Find some humans to eat, if you must."
  
  [i]Ugh… you?[/i] Crystal looks at Hadaly with a single eye. 
  *if progress = 7
    [i]Hammon's personal toy wants to fight me?[/i]
  *else
    [i]You can… do that?[/i]
  
  "I really don't want to," Hadaly says with a smile you can just barely see at that distance. "I despise violence, I really do. That's why I'm asking you to leave, preferably at this very instant."
  
  *fake_choice
    #"I think we're past the time for niceties, you know?"
      *set HadalyRel %- 5
      *set Violence %+ 5
      "Well, I am a very nice person," Hadaly states proudly. "I figured I'd give our fellow synthetic one more chance to live. I've heard you liked those, Crystal."
      
      *goto threat_f
    #"Well that's another person I now owe my life to."
      *set HadalyRel %+ 10
      "Happy to be just another entry on the list." Hadaly's curtsies before turning back towards her target. "Speaking of lists. Crystal, do wish to be yet another victim of-"
    #"Less talking, Hadaly. More lightning."
      *set HadalyRel %- 10
      "I figured I'd fire a warning shot first." Hadaly's eyes narrow slightly as they turn towards the wyvern. "And see if it suffices."
      
      *label threat_f
      
      [i]…fine.[/i] Crystal mutters. [i]I will not take an unnecessary risk. Not when I've already won.[/i]
    #"For the record, I could have handled it myself."
      *set HadalyRel %- 10
      "I'm sure you would." Hadaly's smile turns dishonest before she turns towards Crystal. "But the two of us can handle it even better. So if you, and I'm talking to you Crystal, could just leave this-"
      
      *goto even_be
    #"Hey Hadaly. I like this side of you."
      *set HadalyRel %+ 5
      "Thank you, I suppose." Hadaly nods towards you. "But we should seriously focus on the matter of-"
      
      *label even_be
      
      [i]Fine![/i] Crystal snaps. [i]If your Veteran wishes to survive by hiding behind you, so be it. I have all the shadow I needed anyway.[/i]
    #Throw some lightning at Crystal.
      *set battery - 10
      *set Violence %+ 5
      You take a step forward and discharge your energy, the current manifesting as a blindingly bright lightning. You take an example from Hadaly and aim at the eye, reasoning it could be a weak point of Crystal's otherwise indestructible body.
      
      *if ((Projection+battery) > 90)
        *set crystal_health - 1
        And sure enough, Crystal screams out in pain, both telepathically and with its physical lungs. You've been saving energy just for this opportunity; If you just empty your battery a little more, you may be able to paralyze the wyvern here and now, end this whole-
      *else
        *set Projection %+ 10
        Not that it makes much of a difference. You are not skilled enough, or perhaps lack a large enough battery, to truly hurt Crystal even now. Pissing the wyvern off, on the other hand…
     
      [i]Enough![/i] The psychic shout fills your mind as Crystal flaps their wings with tremendous force. The gust of wind forces you from your feet and makes you tumble, turning you vulnerable once again.
  
  The wyvern flies high into the air, away from you and towards the cylinder's axis. As well as towards its exit, towards the open end where a thing barrier of dark matter separates the atmosphere from the void. It evidently decided to escape.
  
  "That went better than I thought it would," Hadaly comments. "And I don't mean that in some witty or sarcastic way. I genuinely think we lucked out."
  
  *fake_choice
    #"It was no luck. It's the kind of power I don't remember seeing since the War."
      *set HadalyRel %+ 10
      *label impress
      Hadaly doesn't blush, but her eyes do get a little brighter. "Thanks. I actually did more impressive stuff when working on our station's generators. Not that I'm bragging or anything, it's just… you know…"
      
      "Yes." You nod politely. "I get it."
      
      "Thanks for getting it, then." 
    #♡ "Want a kiss as a reward for saving me? Because I can provide."
      *if current_ro != "hadaly"
        *set backup_RO current_RO
        *set current_RO "hadaly"
      *if (HadalyRel > 45) or (official_ro = "hadaly")
        "I wouldn't say it's time or place for that, but…" Hadaly steps closer. Really close. "If you're offering."
        
        Her eyes are yellow, which could mean many things. But right now, you sure hope, it means excitement.
        
        *fake_choice
          #Kiss her on the lips.
            *set Confid %+ 5
            *set HadalyRel %+ 10
            You embrace on this cobblestone road, ozone still in the air, sounds of helicopter motors getting ever louder. It ruins the mood, yes, but it still feels… good to touch her lips with yours.
            
            If only for a moment. This is no time for any long, passionate kiss, for any battle between your tongues, and Hadaly recognizes that. 
          #Kiss her on the cheek.
            You plant a kiss on her left cheek, synthetic lips meeting synthetic skin. It's a quick and smooth gesture, hopefully one your @{(official_ro = "hadaly") lover|friend} will appreciate.
            
            "Such chastity." Hadaly almost sounds to be mocking you, however strange that may be. "But I suppose we shouldn't let things escalate. We're still not entirely safe."
          #"I was just kidding. Sorry."
            *set HadalyRel %- 10
            You'd expect Hadaly to get flustered, maybe even upset. But all she reacts with is a shrug. 
            *if official_ro = "hadaly"
              "That's okay, we'll have other opportunities. Assuming everything goes well."
            *else
              "That's okay. Kisses should be reserved for couples, and we aren't one just yet."
      *else
        Hadaly shakes her head. "I must refuse. I'd never use you in that manner."
        
        "I'm offering myself freely here," you point out. "There'd be nothing wrong with accepting the kiss."
        
        "No, you see… I'd never use [i]you[/i] in this manner."
        
        "Oh."
      
    #"I don't. If only you had killed that thing..."
      *set HadalyRel %- 5
      *goto shake_h
    #"We're both still alive. That's a sign of good luck if I've ever seen one."
      "Glad we're on the same page." 
    #"You think you can snipe Crystal and end this whole nightmare?"
      *label shake_h
      Hadaly shakes her head. "I was bluffing. That shot took half of my total battery. I couldn't repeat it if I wanted to."
      
      "Half of your reserve for something like that is still impressive,' you remark. "And it did save me all the same."
      
      *goto impress
  She turns away and towards the open part of the cylinder, the direction Crystal is headed for. "Can I suggest watching the sky for a while? Something tells me it's about to get interesting."
  
  *goto shoot_scene

  
*else
  *if RenfriRel >= 70
    *set crystal_health - 1
  *set injured_crystal "marshal"
  And then you are blinded.
  
  Not by any damage to your optics, but by a flash of greenish-blue light that consumes everything for a second, heating up the air and turning evening into day. You can just barely see something fast, some brown-colored missile fly from Crystal's direction and crash right next to you.
  
  Or perhaps land. Not gracefully, the Kinnari does look a little dazed as her boots hit the dirt, but on two legs nonetheless.
  
  "Did I get it?" She looks at Crystal, the wyvern groaning audibly from the pain of the blow. Its normally crimson eyeball has assumed a more muted, darkened shade of red. Perhaps it's now covered in soot, or perhaps it simply… went out. "I got it. My Emperor, I got it."
  
  "Got what?" you ask, momentarily stupefied. "What did you just do?"
  
  "Fired my laser fully charged whilst ramming into my target's head," Renfri says with a proud smirk. "A little maneuver I've been practicing. You're welcome, by the way."
  
  *fake_choice
    *if saturn_path = "pirates"
      #"Just like you're welcome for getting saved from Link?"
        *set RenfriRel %+ 10
        "You didn't have to bring that up," Marshal groans. "But point taken."
        
        You simper. "Does that mean we're even?"
        
        "Yeah. Now let's focus on-"
    *if official_ro = "renfri"
      #"Hey, my awesome girlfriend is here."
        *set RenfriRel %+ 15
        "Couldn't exactly leave my awesome partner to die like this," Renfri's smile turns affectionate. "Now let's get-"
    #♡ "Want a kiss as a reward for saving me? Because I can provide."
      *if current_ro != "renfri"
        *set backup_RO current_RO
        *set current_RO "renfri"
      *if (sex = "woman") or (pronoun = "she")
        Renfri looks at you thoughtfully. "I might take you up on that offer… later. Right now-"
      *else
        Renfri pouts. "Sorry, but you're still not my type. And really ought to focus on-"
    #"Right. I owe you one, or two."
      *set RenfriRel %+ 10
      "Glad we agree @{(RenfriRel > 50) about that,|for once,}" Renfri says before turning towards Crystal. "Now let's get-"
    #"Did Kirill approve of this maneuver?"
      "No… he didn't really approve of me being here in the first place." Marshal looks away. "He wanted me to stay on the ship."
      
      "And leave me and Lisa to our own devices?" You @{lisa_helps briefly glance in the werewolf's direction|think about the ginger werewolf, probably still running towards the ship}. "To fight Crystal alone?"
      
      "Kirill's idea of strategy…" Renfri shakes her head. "Nevermind, we must not get distra-"
    *if RenfriRel < 40
      #"I'm surprised you saved me. We don't exactly get along."
        "I did consider leaving you to die," Marshal admits. "But we [i]are[/i] teammates, and that means something."
        
        You smile. "Even when your teammate is a synth?"
        
        "Even then." Very briefly and very faintly, Marshal smiles back. "But let's focus on the actual-"
    #"We'll talk about it later. We have a wyvern to focus on."
      "I agree," Renfri turns towards the fiend. "The two of us should handle this. I may have already given this thing a conc-"
    #Throw lightning at Crystal.
      *set battery - 10
      You take a step forward and discharge your energy, the current manifesting as a blindingly bright lightning. You take an example from Renfri and aim at the eye, reasoning it could be a weak point of Crystal's otherwise indestructible body.
      
      *if ((Projection+battery) > 90)
        *set crystal_health - 1
        And sure enough, Crystal screams out in pain, both telepathically and with its physical lungs. You've been saving energy just for this opportunity; If you just empty your battery a little more, you may be able to paralyze the wyvern here and now, end this whole-
      *else
        Not that it makes much of a difference. You are not skilled enough, or perhaps lack a large enough battery, to truly hurt Crystal even now. Pissing the wyvern off, on the other hand…

[i]Enough![/i] The psychic shout fills your mind as Crystal, having regained senses, flaps their wings with tremendous force. The gust of wind forces you from your feet and makes you tumble, turning you vulnerable once again.

Luckily, Renfri handles the wuthering attack far better. She opens her own wings wide and lets the wind carry her up, towards the cylinder's axis. Crystal charges her, opening their mouth wide as though aiming to eat the Kinnari whole, but your teammate swirls and evades with seeming ease.

Instead of turning around and giving chase, Crystal just continues flying forwards. Towards the open end of the cylinder, you realize, towards the exit from Calypso. 

"It's escaping!" Renfri states the obvious. She has to shout for you to hear her down on the ground. "Or maybe going for [i]Gray Queen[/i]. Do I chase it?"

*label ren_ask

*fake_choice
  #"No. Fly back to the ship, tell Kirill what's happening."
    *set renfri_flew true
    "Crystal's yet to use that fancy active camouflage of theirs," Renfri points out. "If our guys are watching the scopes, they will see that huge wyvern approach."
    
    "Sure… but you never know with Kirill, do you?"
    
    You can just about see her wince. "Fair point. See you back aboard the ship."
    
    *goto flieso
  #"No. Please stay with me."
    *set renfri_flew false
    "That sounded weirdly desperate," Marshal points out. "Are you worried Crystal will trick me, swivel around and return-"
    
    "Renfri." Your voice is stern, but calm. And maybe just a little desperate. "Please stay."
    
    She lands with a graceful flap of her wings. Catching your meaning. 
    *if RenfriRel < 50
      Pitying you.
    *else
      Understanding her @{(official_ro = "renfri") lover's|friend's} pain.
  #"And do what? What's the plan if you catch it?"
    "I wasn't hoping to catch it, just kinda spy on it," Renfri mumbles as she lands. "But sure. Have it your way."
    
    *set renfri_flew false
  #"Sure, if you can keep up with it."
    *set renfri_flew true
    "Can I?" Renfri simpers as she flies higher into the air. "I'll stay a bit back though, just close enough to see where Crystal's headed for. See you on the ship!"
    
    *label flieso
    
    She then starts flying, with rather impressive acceleration, towards the wyvern. Towards the other end of the cylinder. You hope she's not hot-headed enough to follow the creature into the vacuum; It would be quite a dismal fate for your savior.
  *disable_reuse #"Are you asking me for advice? Or for orders?"
    "I take no orders from you," Renfri protests. "I just wouldn't mind knowing your opinion."
    
    "But why?" you keep on asking. "Could it be that you came to appreciate my-"
    
    "Yes, I recognize your superior experience," the Kinnari groans. 
    *if official_ro = "renfri"
      "Also I love you, so there's that. 
    *else
      "And I may have grown to trust you. 
    Now tell me, should I follow the wyvern or what?"
    
    *goto ren_ask

*if lisa_helps
  "Ugh…" Lisa only now recovers, having clearly ran out of power. She's human now, fully human, skin exposed and muscles cramped. 
  *if renfri_flew
    "Bye Renfri. Thanks for not letting us die."
    
    You smile fondly. "I think she mostly did that to save me. Really looks like you're losing your greatest admirer, I have to say."
    
    "Oh shut up."
  *else
    "Hi Renfri. How's the day going?"
    
    "I've had worse," the other woman says with a smile. "Now rest. And watch the fireworks, because those sure as Cloud are coming."
*else
  You sigh, then turn your eyes to the sky. The actual sky, one visible through the cylinder's opening. You get the feeling the starry firmament will soon become background for something interesting.

*goto shoot_scene

*label normal_cont

You open your mouth with effort.

*fake_choice
  #Then close it.
    [i]Lost for words?[/i] Crystal says, with a tiny note of amusement. [i]But of course. You had no direct contact with the Shadow yet, in spite of having heard it clearer than I ever had.[/i]
    
    *goto whywhy
  #"Was it really... it? The Singer?"
    [i]Such an improper name for such vile a thing,[/i] Crystal says frowningly. [i]But yes. Those nanomachines were part of the Shadow's greater, divine collective. Still are, in a way.[/i]
    
    *label whywhy
    "Why?" you utter. "Just why? Why do you want that thing, why do you seek to… inhale it?"
  #"You were looking for it. For Dusk."
    [i]Yes,[/i] Crystal says, without shame or reservation. [i]I thought it was obvious for a long time now, to be perfectly honest.[/i]
    
    *label loud
    "But why? Why search for something so dark? So evil? So… loud?"
  #"You are infected. A carrier for the Thing Beneath."
    [i]I would prefer the term [b]Vessel[/b], if it's all the same to you. It describes the deed I'm attempting more faithfully, you see.[/i]
    
    "What are you attempting?" you demand to know. "And why? Just… why?"
  #"I heard the Shriek. I heard it again."
    [i]Apologies for the pain caused,[/i] Crystal replies. [i]I did not enjoy the sensation either. It's just something that happens, whenever I inhale another fragment.[/i]
    
    *goto loud
  *if lisa_helps
    #"Lisa... are you okay?"
      *set LisaRel %+ 10
      It's a stupid question. You're not sure why you asked it, for your teammate is by far the least hurt person on the battlefield. Nonetheless, the lupine creature gives you a nod.
      
      [i]Good. She too had a role in what just transpired. She deserves to live, however sinful her life was up to this point.[/i]
      
      "Why?" you utter, almost in unconsciousness. "If you care about human life… why take it, in search of something so evil? Of the Thing Beneath?"

[i]Why become a vessel for the Shadow, the thing that devoured Earth and flooded the Solar System with its screams? I will let you wager a guess, ${name_1}. No consequences for failing.[/i]

*fake_choice
  #"You want freedom, free will. You want to hear the Shriek more clearly."
    [i]That is certainly an interesting idea,[/i] Crystal says thoughtfully. [i]Creative. Shame it never crossed my mind.[/i]
  #"You collect nanites so that they reach some... critical mass, as it happened back on Earth. You want another Calamity."
    *label hurtc
    [i]Really, ${name_1}? Is that what you think of me?[/i] Crystal sounds hurt. [i]Let me enlighten you, since we are just in a place for that.[/i]
  #"You want power. Power that the Thing Beneath may grant you."
    *goto hurtc
  *if lisa_origin_learned
    #"You seek the greater good. You want to use the Dusk for some... noble end or other." 
      [i]Almost the truth,[/i] Crystal says respectfully. [i]Let me provide more precise an answer.[/i]
  #"You worship it. You seek to grow closer to your God."
    [i]You somehow found the exact opposite of the truth,[/i] Crystal states. [i]Almost impressive.[/i]
  #"I don't know. That's why I'm asking."
    [i]You are no fun,[/i] Crystal says disdainfully. [i]But I suppose I'll sate your curiosity all the same.[/i]

You can hear shouts in the distance, the kind made by soldiers marching to battle rather than terrified civilians, and perhaps the noise of helicopter blades in the distance. The Pandits evidently stopped debating and mustered up a military response at last.

It does not seem to matter. Those forces failed to stop Crystal before, and now… the wyvern seems more powerful than ever. Not just elusive and nigh-indestructible, but almost divine, with an aura of dark glory around it as though enveloped in its own shadow. Not a mere monster, but a Vessel.

[i]This little toy I destroyed was what you could call an artifact of Dusk. An inanimate object with which, by pure chance, those dreaded nanomachines chose to fuse themselves. Embed themselves in. I have long sensed such a thing on Calypso, but was not able to locate the exact item until now.[/i]

Fragments of Dusk in a toy plane. A piece of paper that seemed so harmless…

[i]It was harmless. I highly doubt the child was infected, for even those most dangerous nanites simply lie dormant when devoid of power. But when energized, they turn into Earth's devourer, all-destroying swarm that ravages existence until it can find a carrier to corrupt, a vessel to fill.[/i]

*if hit_by_kid
  You remember when the paper plane hit you, understand why it hurt. Your skin is charged, your whole body full of electric power, which apparently was just enough to make a few nanites activate for a moment. To turn the sheet's edge as sharp as a mono-molecular spike, or perhaps to psychically cause you pain. Was it to be provided with more energy, fully awakened… it could have meant the end of Calypso, deaths of everyone inside the small moon.

[i]I trust you see the problem. In mere objects, no such swarm of nanomachines is secure. In people, it is a corrupting force, bound to turn the Vessel into its puppet. Worse yet a servant, a worshiper, a weapon. Something to threaten the Solar System and everyone in it.[/i]

*if Database > 50
  You see where this is going. You do not like it.

[i]But tell me; What if the carrier for some part of the Shadow is already a weapon? Something neither inanimate nor alive, not quite organic and yet not fully synthetic. Something with a body as indestructible as its diamond will, immune to age and able to protect itself. Perfect Vessel, large enough to contain an arbitrary mass of nanites, protecting the Solar System from the darkness which escaped the Shield. Sounds appealing, does it not?[/i]

*fake_choice
  #"You're lying. Your motives are selfish, no matter what you claim."
    *set crystal_friend false
    [i]And what makes you believe that, ${name_1}?[/i] Crystal asks scornfully.
    
    *goto itdoesnot
  #"No. I does not."
    *set crystal_friend false
    [i]You wound me, ${name_1}. Do you have any reason to not trust me with the responsibility I accept?"
    
    *goto itdoesnot
  #"You truly believe your will unbreakable? That you're strong enough to resist Dusk indefinitely?"
  #"What's the danger of Dusk-infused items? It's not like paper planes get energized often."
    [i]In a habitat where tesla turrets are placed in every street, that is a danger worth considering,[/i] Crystal retorts with ease. [i]And besides, there is no shortage of people who also seek such artifacts. Some out of reverence for the Thing Beneath, others for ends they believe noble. I seek to foil both.[/i]
    
    "And how are you any better?" you shoot back. "I know this wasn't your only raid on Calypso. You killed people, even innocents, sometimes for no clear reason. Your goals clearly ain't pure and heroic either."
  #"You believe yourself a hero. You really do."
    [i]Of course I do. Why should I not?[/i]
    
    *label itdoesnot
    "Well there are your victims, for one." You point towards the bodies near the temple. "And I know these soldiers are not the only ones. You killed civilians too in the past, for no reason I understand."
  #"...yeah. It actually does. I agree with your goals."
    *set crystal_friend true
    [i]So I found myself a new ally?[/i] Crystal bares their teeth. [i]How delightful. I just hope your words are honest.[/i]
    
    "Well… maybe I don't support [i]everything[/i] you did," you clarify. "Didn't you kill a bunch of civilians here? For no clear reason?"

Crystal does not reply right away. They look towards the cylinder's entrance, either checking if someone is coming, or gazing into the planet of Saturn. When the creature turns back to face you, the cold confidence of its ethereal voice is greatly diminished.

[i]I've held the Shadow inside me for a long time now, absorbed many smaller artifacts before coming here. Throughout the years it spoke to me, appealed to my nature of a wyvern and a weapon. It may have driven me to excessive violence, persuaded me to… accept some casualties I otherwise would not have. But my control has gotten stronger since, as you perhaps see. I can endure its whispers indefinitely.[/i]

*fake_choice
  #"Is it you speaking? Or the Shadow?"
    *set crystal_friend false
    [i]I am no puppet for the darkness, ${name_1}. Its corruption works less directly, and I am free of it anyway. I will endure, whether you believe in me or not.[/i]
  #"You won't. Take it from someone who heard the Thing Beneath scream."
    *set crystal_friend false
    [i]I am not dealing with the Shriek here,[/i] Crystal says dismissively. [i]Just words and empty temptations. Your experience is irrelevant, mine shall save the Solar System from the Thing Beneath.[/i]
  #"But now there are more nanites inside you. Won't that make the temptation even stronger?"
    [i]Then I shall double my efforts,[/i] Crystal says dismissively. [i]Do not try to dissuade me. And for your own sake, make no attempt to stop me.[/i]
  #"Frankly, I don't know what to think anymore."
    [i]Then think nothing. I don't need your approval. I just need you out of the way.[/i]
  #"So it does corrupt you."
    [i]It does not,[/i] Crystal growls. [i]It merely influences me, or rather it did. Everything is under my control now.[/i]
  #"I think I agree. You've got this."
    *set crystal_friend true
    [i]I thank you for your faith, ${name_1},[/i] Crystal says cordially, and perhaps with some relief. [i]I will not disappoint you. Quit this foolish hunt, and you shan't disappoint me either.[/i]
    
    *goto takeoff

Crystal turns away and stretches their wings, preparing to take flight. It is right to hurry; You can hear the sounds of military vehicles get gradually louder.

[i]I am sparing you, and your friend@{lisa_helps |s}, because you did not know what you were trying to stop… and because you failed. Cross my path again, and I shall not show any such mercy. Our third meeting will be the last.[/i]

*label takeoff

And then it takes off, the wyvern pushing itself off the ground and rising high into the air. Leaving you alone, with its revelations and your thoughts.

*if lisa_helps
  "That thing sure likes to talk, huh?" Maybe not fully alone. "Wonder if it will pay for wasting its time. Whether Kirill or the habitat's forces will shoot it down."
  
  Lisa must have transformed when you weren't looking. When you were focused on talking with the Dusk-infused wyvern… which is certainly a rare conversation to hold, in all fairness.
  
  *fake_choice
    *if (sat_watch = false) #"Hey Lisa... thanks for saving my butt during the fight."
      *set LisaRel %+ 10
      "We're teammates." Hellhound shrugs. "It's my duty to have your back, whether I like it or not."
      
      "Since when do you care about duty? Or whether the feds call us a team?"
      
      *if LisaRel > 50
        "You got me there. I guess you could call us friends, rather than just squadmates." She smiles, before turning her head towards the cylinder's entrance. "Now let's see where this goes."
      *if LisaRel <= 50
        "I may get a bonus for saving a squadmate I rather dislike." Lisa averts her eyes, focusing on Crystal instead. "Now let's see if Kirill can shoot this thing down."
    #"I found talking to it rather... enlightening."
      "Right," Lisa replies with an eye-roll. "Now we know precisely why our target is our target, and why we need to kill it. Shame it doesn't change much."
      
      "You don't have much interest in the implications of your mission," you note calmly. "Or in its possible consequences."
      
      "Guilty as charged," she says before looking up. "Now let's see if that mission ends here."
    #"We'll see."
      "That's all you have to say?" Lisa asks with a smirk. "After all that just happened?"
      
      "I am an android of few words. Unless you really want to talk about what happened?"
      
      "No. Not really." She sits down on a nearby bench. "I'm sure we'll have to recount everything on the ship anyway. Now let's see if that ship can stop a diamond wyvern."
    #"Lisa... are we the bad guys here?"
      "Why would you think so?" Your teammate tilts her head. "Do you buy what your fellow fiend just said?"
      
      "Possibly? It does seem to have good intentions, possibly even the right means. And who knows, it may really be strong enough to keep all those Dusk particles in."
      
      "You're right, nobody knows," Lisa says with a shrug. "And even if we did, I'd still find your concerns silly."
      
      "Because you don't think Crystal was being honest with us? Because you think we have a duty to kill them either way?"
      
      "Because there is no good or evil. We aren't the bad guys, we're just doing what we're told," she states before looking up. "Now let's see if we're on the winning side."
    #"Should we try to stop them first? Crystal, I mean."
      *set LisaRel %- 10
      "With what?" Lisa throws her hands up. "I've got nothing. Certainly not a spacecraft-grade weapon we'd need."
      
      You look towards the cylinder's exit, where [i]Gray Queen[/i] should be. "So we count on the actual spaceship to do the job?"
      
      "I suppose we do," Lisa looks in the same direction. "Not that I care about who wins. Or anything."
      
      You choose not to comment on that.

*label shoot_scene

*page_break

After adjusting the sensitivity of your optics, you are able to spot and clearly see [i]Gray Queen[/i] some ten kilometers in the air. It is near the cylinder's axis, a region high above that lacks even the habitat's artificial gravity, a fact that makes staying afloat easy… and which naturally prompted Crystal to enter those heights as well, choosing to fly along the axis in its rush to get out of the cylinder and return to the void of space.

You spotted a Calypsoan helicopter just now, but it was flying low and seemed occupied with rescuing civilians, or perhaps simply providing them with a show of strength and illusion of security. The cutter is all that stands, or levitates, between Crystal and their timely escape.

*if not (renfri_flew)
  "Come on Kirill…" Renfri mutters under her breath, observing the scene as intently as you. "Do not screw this up…"

[i]Gray Queen[/i] aims its main weapon as the wyvern approaches. A graviton cannon, a standard-issue kind, the largest gun that can realistically fit on such a relatively small ship. It's not the strongest of armaments, or designed to work well in atmosphere, and wyvern scales are quite good at absorbing high-caliber hits… but perhaps one shot will still be enough to wound the creature. Perhaps disrupt its camouflage somehow, enough for Calypso's outer guns to zero in on the wyvern and kill it at last.

*set rook_plant true

*fake_choice
  #I fear Crystal may attack the ship. Possibly destroy it.
    Wyverns were not built to fight spaceships, but they are capable of that when needed. Especially when a wyvern is an old diamond one, and a ship is some fairly unexceptional cutter. You don't fancy your team's chances here.
  #My teammates can do it. I believe in them.
    *set Database - 1
    How hard can making a single close-distance shot be, really? They've got this. They must.
  #I hope that doesn't happen. Crystal deserves to get away.
    There may be some doubt as to whether Crystal is really the hero here, but… you still don't want them to die. You're still rooting for them, despite having just fought them, or at least hope they'll leave the habitat alive.
  #Hopefully they miss. That wyvern is mine to kill.
    *set Emotion %+ 10
    *set Violence %+ 10
    You're not exactly sure how you want to kill Crystal yourself… but that's something to think about later, once you're sure your kill won't get stolen.
  #I doubt it will happen. Would be too convenient, too much luck.
    You lived too long to be an optimist. You can tell this won't end well, you just hope the ending doesn't involve your whole team dying.
  #Maybe it's better if Rook doesn't fire. The possible collateral damage is too high.
    *set Violence %- 10
    There are reasons why spaceships don't usually take part in out-of-void fighting, and whilst concern for collateral isn't the [i]main[/i] such reason, it's something you always took into account. Hopefully Rook, or whoever operates the cutter at this instant, does the same.

Then the ship fires. Everything happens in an instant, barely a second, but you see every part of the process thanks to your precise perception of time. You see the gun recoil, you perceive the small flash and, however vaguely and briefly, see the cannonball itself fly forwards, propelled greatly by gravitic forces, right towards the wyvern which…

Disappears.

Your first instinct is to assume it just went invisible, but the projectile goes straight through the empty space where Crystal was mere centiseconds ago. It could still be just camouflage, perhaps they jerked sideways when invisible, barely dodging the cannonball… but with all the Dusk inside the diamond wyvern, you truly cannot be sure.

Not that the question bothers you for long. Your attention stays on the missile, which soars and soars through the air until hitting the dirt, near the other end of the cylinder. It was aimed just a little downwards (or upwards, those terms mean little inside a rotating habitat) and carried further towards the ground through the power of spin gravity.

Except… it didn't really hit the ground, or dirt. It hit some building, blocky and large, the purpose of which you can't really guess at. Judging from the thundering sound of impact, and the smoke that billows from the strucutre soon afterwards, this one shot caused more damage to Calypso that Crystal's whole raid.

Speaking of Crystal, the wyvern disappears without a trace. More than likely, it's already flying through the vacuum of space, either to Telesto or some other lair it has prepared in advance.

*if not (renfri_flew)
  Renfri sighs. Just sighs.

*if lisa_helps
  "I think that was the spinward power plant," Lisa answers the unspoken query. "The fission-based one. The Pandits won't be happy to see it destroyed, even if there's no fallout or immediate casualties."
  
  *fake_choice
    #"Fuck. Should we go in and help?"
      *set Misan %- 10
      "Nah, I bet they evacuated the facility the moment Crystal showed up," Lisa says, taking her eyes off the distant building. "Better go with me, to the landing area. They'll pick us up, and then we'll leave this sun-damned place."
    #"Do you believe there will be lethal casualties?"
      "Not instantly. Such an emergency warrants an immediate evacuation of the power plant." Lisa looks at the distant building. "Which is a shame. I'd love some more dead Calypsoans."
      
      *goto bluffe
    #"Should I chew Kirill out for this, or do you want the honor?"
      "I think Da-xia will want it. And I won't deny her the pleasure," Lisa says with a smirk, though you can tell the expression is forced. "She may well be calling him right now. Let's go back to the landing area, we may yet hear some of it."
    #"And are you happy about that fact?"
      "Sure, mildly so." Lisa averts her eyes. "I'm definitely not sad for anyone who died. Not after what these people did to me."
      
      *label bluffe
      "You keep saying things like that," you note calmly. "How you don't care about anyone here, or sometimes how much you hate the natives. Do you truly believe that?"
      
      "Would you like me to?" she replies, looking at you intently.
      
      *if Violence > 50
        "Sure." It would be nice to meet someone as violent as you sometime, with as little regard for human life. "But I know better than to let that cloud my judgment. Let's go to the landing pad, maybe you can fool someone there."
      
      *if Violence <= 50
        "No. And I know you don't," you say with a slight smile, then turn away. "Let's head for the landing pad. Hopefully our guys will notice us, and pick us up soon enough."
        
*if not (lisa_helps)
  *fake_choice
    *if manfred_sleep
      #[i]Putting Manfred to sleep was not my brightest idea, it seems.[/i]
        Granted, you don't know who fired that shot. Perhaps Manfred was woken up and he's actually the one responsible, somehow. Only one way to find out.
    #[i]It's my fault. I should have stopped Crystal before it took off.[/i]
      You don't know how you could have done that, but… fuck. You're the Veteran, you should be expected to do more than your companions. More than anyone else.
    #[i]Damn it. The monster got away.[/i]
      You console yourself with the knowledge that there'll be other chances… maybe, hopefully. At the very least, if your group runs into Crystal again, it will have the benefit of the knowledge you just gained.
    #[i]Well that went better than I hoped it would.[/i]
      You're not sure what you expected. Perhaps for the [i]Gray Queen[/i] to be destroyed and for the pieces to fall on the Rational Temple. You wouldn't put it past your teammates, or your foul luck.
    #[i]I should just kill these morons. Make the Federation a favor for once.[/i]
      You're not sure why you saved Hellhound earlier by agreeing to fight Crystal alone. Maybe you just had an inkling that you'd be more efficient fighting alone. No need for a werewolf to get in your way.
      
      But those morons are still your companions. You still need to reconvene with them, and you need the ship to leave this panicked moon.

And so you start marching, in no particularly exact direction. You just need to get out of the town, and stand somewhere in the open. Hopefully the cutter will spot you without much trouble, come down to pick you up and then… well…

Then everyone has some explaining to do.

*label normal_end
*if name_daxia = "android"
  *set name_daxia name

*page_break

"Let me get this straight." Da-xia's voice is coming from the quantum disc, lying on the coffee table you are all gathered around. It was given to Kirill during his private exchange with the Great Pandit, and is proving itself quite good at signal transmission, considering how your ship is currently flying away from Calypso at the speed of a meteoroid. 
*if sat_watch
  "First, ${name_daxia} and ${subject} pet werewolf sit back and watch Crystal hold our most sacred temple hostage. Then, your ship destroys our most valuable power plant. 
*if not (sat_watch)
  "$!{name_daxia} @{lisa_helps and the werewolf |}fought Crystal more efficiently [i]on the ground[/i] than your state-of-the-art cutter did in the air? 
And neither stopped the wyvern from further terrorizing my habitat in its [i]successful[/i] quest to absorb more Dusk into itself?"

Kirill just sits there awkwardly, not quite sure what to say. He just finished giving his mostly second-hand account of the events, the one which made Da-xia so damn annoyed. He probably wasn't the best person to do this, but nobody else wanted that responsibility.

And they still don't. Marshal and Hadaly are sitting there quietly, Damon is watching the scanners and Lisa was last seen entering the closet, ostensibly to finally put on some clothes. You had to stay for the briefing though; You're the one who talked to Crystal extensively, and you were made to recount some parts of your encounter whenever relevant.

And now's your chance to offer more input.

*set given_disc true
*fake_choice
  *if terrorist
    #"Were there any reports of an android attacking the community housing site? Just curious."
      "Good guess," Da-xia says with some surprise. "We have received reports of someone going on a @{(weapon = "pistol") shooting spree|rampage} in the encampment, at the exact time Crystal attacked. This is obviously too much of a coincidence, and so it's only rational to assume it some wild rumor, possibly invented by someone
      
      "Well that's very reasonable of you." Another proof that there's no such thing as justice. "Sorry we couldn't do more for your people. I truly feel for them and deeply care about their safety."
  *if (sat_watch = false) #"You didn't mention the part where Kirill fired on your power plant."
    *set RookRel %- 12
    *set DaxiaRel %+ 8
    "Right…" Da-xia sighs deeply as Rook sits quietly. "There is also that."
  #"You can at least rest assured that Crystal won't return."
    "I suppose that is something," Da-xia says grimly. "Assuming that certainty is warranted."
  #"At least only a handful of people died. I count that as success."
    *set DaxiaRel %- 12
    "Those were good men Crystal killed, ${name_daxia}," Da-xia protests. "And you speak quite lowly of their lives."
    
    "They were all armed combatants though," Marshal points out. "Not saying their deaths are not tragic but… I don't think they're some great failure of ours."
    
    "Such thinking is contrary to the Bayesian Path," Da-xia scoffs. "So keep it to yourself, Kinnari."
  #"Care to explain how there was a Dusk artifact on Calypso?"
    *set DaxiaRel %- 8
    "Random chance," Da-xia replies, likely with a shrug. "After Calamity, the pieces of Dusk that left Earth would scatter and coalesce with no rhyme or reason. And apparently, one such speck ended up here, for no fault of our own."
    
    "Still…" Marshal dares to speak. "Couldn't you have checked better? Could you investigate it now, just in case Crystal returns?"
    
    "It is extremely unlikely for [i]two[/i] Dusk-infused items to be inside a single habitat at once," Da-xia refuses the suggestion. "And how would we investigate the matter anyway? By checking every piece of paper for… what, exactly? No, we must assume there are no more nanites to be found, and to hope that we're right."
  #"You speak as though your men did anything to stop Crystal."
    *set DaxiaRel %- 12
    "My men did not fire a cannonball into our power plant," Da-xia replies, causing Rook to shrink a little. "But in regards to you specifically… point taken. I fully believe you did everything you could, ${name_daxia}."

"If nothing else, you now know what Crystal is about," Hadaly chimes in. "It has to count for something… not that I'm saying you should be happy about today or anything, I know people died, it's just… sorry."

"No, I should be apologizing for letting my frustrations show," the Pandit sighs tiredly. "Even if they are justified. No reason for us to part on bad terms."

"Does that mean you are fine with us leaving?" Rook asks her. "Nothing else you want us to help with?"

"We want you to slay that wyvern. Everything else is comparatively irrelevant," Da-xia replies sternly. "Keep this disc and inform us when the job is done. You shall be rewarded, both by our council and your federate superiors. Until then… over and out."

*if sexed_daxia
  But she doesn't disconnect instantly. She merely pauses before speaking again, in a far softer tone. "And ${name}? Thank you for what you did today. Once everything is over, I will make sure to award you some honors in particular."
  
  You're not sure if your squadmates understand the meaning of those words. You're not sure if you want them to.

The quantum disc is then turned off, indicating the connection's end. 
*if progress != 7
  *goto normalend2
Silently, Rook picks up the communication device and throws it towards you. "Here. If she calls again, I want you to answer. I will be busy with other things."

You catch the disc easily. "What things?"

He turns towards the cockpit. "Making sure the course is set straight towards Crystal, mostly. We are not letting it get away this time."

"We're really giving chase?" Hadaly asks. "You heard what ${name} said. That thing is full of Dusk. I'm not saying I know better than-"

"Then don't!" Rook snaps. "Crystal is not coming back here, or into Telesto. We'll never get to injure them like @{(injured_crystal = "hadaly") you|Renfri} just did. Everything points to this being our last, final chance."

*fake_choice
  #"I agree with Hadaly. How do we fight a Vessel like this?"
    *set HadalyRel %+ 10
    *set RookRel %- 10
    "Don't use that term," Rook demands. "Vessel. So pretentious. Makes our enemy sound tougher than they actually are."
  #"Are you sure? Maybe it will look for more nanites here."
    Rook shakes his head. "Perhaps. But I do not relish the thought of fighting this wyvern in a populated area, once it's rested no less. Here is what we'll do instead."
  #"Okay. How do we do this?"
    *set RookRel %+ 10
  #"How do we even follow them? They have active camouflage."
    "Last time I called Wisp, it could see the wyvern just fine," Rook replies. "I think Crystal's camouflage is malfunctioning due to their injuries. We must get them before they regenerate."
  *if official_ro = "hadaly"
    #"Hey, no talking to my girlfriend like that."
      *set HadalyRel %+ 15
      "Right." Rook rolls his blue eyes. "I will write her an apology letter once we kill Crystal. Assuming you help us with that."

He opens the cockpit door with a wave of his hand. "We accelerate further. We follow the directions Wisp gives us. Once Crystal is inside our effective range, we blast it like there's no tomorrow. Then we all go home. Is that clear?"

"Crystal clear," Renfri says, not even noticing the pun. She then looks at you. "Right, ${name}?"

*fake_choice
  #"Sometimes, one needs to throw in the towel."
    "That is correct," Rook turns to meet you in the eye once more. "Though I'm not sure why you chose to mention that principle now. I cannot see how it applies."
    
    You shrug @{(Confid > 50) nonchalantly|nervously}. "You know… just something to keep in mind."
    
    "Noted." Rook nods. "Now get as much rest as you can, everyone. We are not throwing towels anytime soon."
  #"What about our deal? Is our home still at [i]Saturn Nine[/i]?"
    "The terms have not changed one bit." Rook turns to meet you in the eye once more. "We get Crystal, you get the right to crash at [i]Saturn Nine[/i] for the rest of time. Otherwise… I hope my team will not be tasked with kicking you out."
    
    "Well that's nice," Hadaly remarks. "You hoping you won't have to kill us, I mean. Not the other part."
  #"Right. Let's kill that oversized diamond."
    *set RenfriRel %+ 8
    *set HadalyRel %+ 8
    "That's the spirit," Hadaly murmurs, her disapproval barely hidden. "I didn't know we androids had those. Nice."
  #"Why are you looking at me? Lack of trust?"
    *if ((official_ro = "renfri") or (RenfriRel > 70))
      "I trust you more than anyone, ${name}," Renfri says solemnly. "That's why I want to hear your opinion."
      
      You raise an eyebrow. "Opinion on what?"
      
      "Nevermind, just…" Renfri bites her lip before continuing. "Just do what you think is right, okay? Regardless of what happens."
      
      You don't know how to take her words. So you just nod.
    *elseif RenfriRel < 40
      "Yes," Renfri says bluntly. "I don't trust you to not fuck everything up. Not even for a second."
      
      *goto papfgkjsa
    *else
      "Well…" Renfri bites her lip before continuing. "I wouldn't say I don't trust you, it's just… We both know you'll decide the course of the battle. So please make it go in our favor."
      
      *label papfgkjsa
      
      "It's a space battle," you point out. "How can I possibly decide its outcome?"
      
      Renfri doesn't reply. Reluctantly, you drop the subject, hoping she's not hiding anything [i]too[/i] important from you.
  #Say nothing.
    Renfri breaks eye-contact after several seconds. Unsatisfied. Distrustful.

Soon enough, you feel the ship accelerate strongly, pushing its limits so as to catch up with Crystal. But that's not the only thing you feel.

*fake_choice
  *selectable_if (Violence > 50) #[i]Time for glorious combat to commence.[/i]
    *set Violence %+ 20
    Time to engage your enemy. Time to fire the projectiles stashed aboard your ship. Time to test its engines, Manfred's abilities, everyone's will to win. But most importantly…
  *selectable_if (Confid < 50) #[i]We're gonna fucking die...[/i]
    *set Confid %- 15
    Your teammates are blind to the threat Crystal, the strongest Vessel on record, poses. There's no way you can win; The best you can hope for is to ensure you, and your friends, all come out of this fiasco alive.
  *if crystal_friend
    #[i]I need to save Crystal. I need to pull it off somehow.[/i]
      So far, your attempts at helping the wyvern have been minor, and apparently ineffective. Now you need to ensure, truly make sure that this team of clowns doesn't kill the strongest Vessel this world has.
  *selectable_if ((Emotion-Confid) > 0) #I'm a bundle of nerves, despite not having a nervous system.
    Despite everything you've done and seen, this mission is simply too much. Too much danger, too much uncertainty. Luckily, you won't have to battle these feelings much longer.
  #I also feel relieved. I'm glad it's almost over.
    This mission went on for more than enough. Your patience, you nerves, your battery, everything is wearing thin.
  *selectable_if (Emotion < 50) #Actually, it is. I have no emotions.
    *set Emotion %- 20
    You were always a tranquil person, a calm machine. You need to remain so now, as a cool head will be invaluable in hours to come.

Time to get this all over with.

*goto calypso_end



*label normalend2
Rook sighs and the girls say nothing, letting you be the one to break the silence.

*fake_choice
  *if not (hadaly_goes)
    #"Still mad I made you stay aboard, Hadaly?"
      "I admit you may have had a point there," Hadaly says grudgingly. "But can we please focus on important things now?"
      
      "Of course," @{(RookRel >= 50) Krill|Rook} agrees. "Let us start by returning to [i]Saturn Nine[/i]. As quickly as possible."
  #"So... what made you think firing that cannon was a good idea?"
    "I don't know why I insisted on it." @{(RenfriRel >= 50) Renfri|Marshal} hangs her head. "Except… I kinda do. By that point, we had good reasons to think you and Lisa were dead by Crystal's hands, or teeth. That shot seemed like our last chance at killing the beast… and at vengeance."
    
    *if not (manfred_sleep)
      "I told everyone it was a bad idea, that we should hold back or at least let me aim," Manfred says, more annoyed than you ever heard him. "But no. Better to just fire from the hip. Sir Isaac Newton isn't [i]that[/i] dangerous, after all."
    
    "I take full responsibility for what happened," Rook says solemnly. "But we need to keep going. Namely, we must return to [i]Saturn Nine[/i], without wasting any more time on confessing faults and pointing fingers."
  #"I'm sorry. It's my fault things went to shit."
    *set RookRel %+ 10
    "I fail to see how," Hadaly reassures you. "I mean, you were the one who actually fought Crystal, and it's possible it would never find that Dusk-infused paper plane if not for you… Actually, forget what I just said. Clear your short-term memory or something."
    
    "${fake_name} may hold some very limited blame," @{(RookRel >= 50) Krill|Rook} says amicably before turning towards you. "But worry not, friend. You will feel better once we return to your home of [i]Saturn Nine[/i]."
  #"Don't listen to her. This day was a success."
    "I admire the attitude… but how so?" @{(RookRel >= 50) Krill|Rook} asks, one of his eyebrows raised. "I fail to see many achievements of ours."
    
    *if Misan > 50
      "Well, I count not having to stay inside that moon for more than a day an achievement," you respond bluntly. "We are expedient, if nothing else."
    
      *if hadaly_goes
        "Would you perhaps consider speaking for yourself?" Hadaly says, just a little upset. "I found the place quite beautiful and wouldn't have minded staying there longer."
      
        "They had great burgers," Marshal adds dreamily.
      
      *if not (hadaly_goes)
        "Of course you would say that," @{(RenfriRel >= 50) Renfri|Marshal} says with an eye-roll. "You just can't appreciate human architecture, you misanthrope."
    *else
      "Well, the losses in life and property were both fairly limited," you respond. "Crystal only killed maybe a dozen people and barely damaged the Rational Temple. Could have gone worse."
      
      "But then we went ahead and destroyed one of the moon's two power plants," Hadaly points out. "And since it was a [i]fission[/i] plant, I imagine quite a few Calypsoans will develop cancers in months to come."
      
      "Like you'd care about that," @{(RenfriRel >= 50) Renfri|Marshal} scoffs. "${name} cares about human life, but you? You're just a typical android, no matter how much you try to hide it."
    
    "Let us leave arguments for later, perhaps?" @{(RookRel >= 50) Krill|Rook} proposes. "At least until we return to the fortress."
  #"Am I the only one who thinks she's a bitch? Bet I'm not."
    *set RenfriRel %+ 10
    "Not by a longshot," Renfri smiles weakly. "I always figured Lisa was exaggerating, but… that woman is certainly something."
    
    "We are still technically in Calypsoan space, Marshal," Rook notes. "You can insult our current host once we are back inside [i]Saturn Nine[/i]."
  #Nah, I stay silent too.
    "Well… I suppose our time here is finished," Rook decides to say something, once the quietude gets too awkward. "I will set the biocomputer on course to [i]Saturn Nine[/i]."


"To rest and refuel, I assume?" Hadaly asks. "Will we head towards @{saturn_complete Telesto|the Yakovian Expanse} once we're done? Continue the hunt there?"

"I see no other way forward," Rook replies with a frown. "Unless you are suggesting something?"
  
*fake_choice
  #"Nothing. She's not saying anything. Right, Hadaly?"
    *set RenfriRel %+ 10
    *set HadalyRel %- 15
    Hadaly narrows her eyes. "Right. I was just making sure we understand one another. And we clearly do."
    
    *goto wellh
  #"Can't we try to catch Crystal now? They couldn't have gotten very far."
    "I received a signal from Wisp just now," Manfred says through the speakers. "It stopped tracking Crystal a minute ago. We cannot tell where the wyvern is headed for, or how long arriving there will take."
    
    "At least we know where [i]we[/i] are headed, now and after we are back at full strength." Rook says as he stands up and heads for the cockpit. "Crystal will have to wait. But not long, not if we have anything to say."
  #"She's saying we should consider giving up. And I agree."
    *set Confid %+ 5
    *set HadalyRel %+ 10
    *set RookRel %- 10
    *set RenfriRel %- 10
    "What?!" Marshal protests. "We can't give up now! We know that wyvern has Dusk inside it now, that makes our mission even more important."
    
    "You could also see it as an argument against this mission, perhaps?" Hadaly suggests, trying to sound confident and contrast her usual meekness. "I mean, I don't understand Dusk as much as ${name} does, but ${pronoun} agree@{plural |s}. Crystal having that power makes defeating it unlikely, and it's not like we know what happens when such a powerful vessel dies. Will all the nanites stay in the corpse, or will they escape and-"
    
    "We will find out," Rook interrupts. "No point doubting our orders and purpose because of some… speculations. We must keep going instead."
  #"Yeah Hadaly, what are you implying?"
    *set HadalyRel %- 10
    *goto well1
  #Say nothing.
    *label well1
    "I'm…" Hadaly purses her lips. "Not suggesting anything. Just had a silly idea, not really worth vocalizing."
    
    *label wellh
    "Well, all that matters is that we are still working together." Rook says as he stands up and heads for the cockpit. "Once we are also rested, we will win the upcoming rematch with no difficulty. That I promise."

And that ends the conversation, which in turn concludes your visit to Calypso. You have survived, and so did your adversary. You know a little more about them, and about the people you came to work with. Now you sit there, by the coffee table, looking forward to…

*fake_choice
  #...being alone. Away from humans, metas, wyverns and everything else.
    This mission involved a lot of talking. 
    *if Misan > 50
      Worse yet, lots of talking [i]with humans.[/i] 
    *if Misan <= 50
      You don't mind humans normally, but one can have too much of a good thing, especially considering all the other company you have. 
    Some solitude will not go unappreciated.
    
    Though with the Shriek echoing in your ears, perhaps more intensely than ever… you don't know if you'll ever feel truly alone.
  #...killing Crystal the next time I meet them.
    *set Violence %+ 10
    If there was no enmity between the two of you before, now there is. It's not a hunt anymore, it's a battle between two creatures humans view as fiends, both old and vicious and powerful, both hearing the song but only one understanding the Singer. You are the players, those around you are pawns, and the orbit of Tethys is your chessboard.
    
    You do not intend to lose.
  #...some rest and relaxation.
    It will be nice to rest inside the station, your station, one with low density of Pandits and wyverns. Either alone, or with your fellow outcasts back home, no doubt eager to hear what happened during your escapade.
    
    And you certainly have a story to tell them.
  #...sabotaging the hell out of this mission.
    *set crystal_friend true
    The feds may still think you're their ally, and let them believe that. Sabotage works best when gone unnoticed, not that it should be very hard either way. You are their Veteran, the person they rely on, and they will not complete their task without your earnest help.
    
    Let Crystal win. That is your new mission statement, and a quest you will not fail.
  #...nothing. Nothing but pain awaits us.
    *set deflect + 1
    Today you've seen another part of the Solar System, and it fits the pattern of everything being shit. And with you headed deeper into the gutter… the future is looking about as bright as the world beneath the Shield.
    
    Oh well. Nothing you're not used to.

*label calypso_end

*set last_mission "calypso"
*set calypso_complete true
*page_break Next Chapter
*if progress = 5
  *gosub_scene interlude_1
*if progress = 6
  *gosub_scene interlude_2
*if progress = 7
  *gosub_scene janus


*label abandoned_lisa
*set left_lisa true
*page_break
*set LisaRel %- 20
*set lisa_pissed true
*if tricked_lisa
  *set LisaRel %- 20
*set RenfriRel %- 10
You run, and run, then run some more. The speed you reach allows you to leave the town within a minute, and approach [i]Gray Queen[/i] after another two. It is still parked on grass, though a different patch than before, and it seems like someone in there is paying enough attention to notice you. The door opens as you close in, and three people come out almost instantly.

Renfri is the first one, easily getting ahead of Damon and Kirill by the virtue of her wings as well as vigor. Whereas the other two both look at least somewhat collected, the Kinnari somehow manages to look panicked and eager to kill anyone who stands in her way at once.

"${name}!" she yells at you, just as you stop running. "What's the situation!? We've seen Crystal, and then some fighting, but it's hard to… Fuck it, where's Lisa? She was supposed to go contact you, did she do it? Is she fine?"

*temp saw_die 1
*fake_choice
  #"She's fighting Crystal all by herself. We need to help her."
    *set saw_die 2
    "What! Why would she ever-" Marshal cuts off, realizing time is of essence. "Forget it, I'm heading to town. Kirill, try to follow me with your grav-pack if you can."
    
    *label not_good
    "I am sorry Renfri… Marshal… but this is simply not a good idea," the Trio's leader replies. "We need to fly back up with our ship, prepare for Crystal leaving the habitat. Our teammate's safety is of tertiary importance here, at best."
    
    "I wouldn't put it that way myself," Damon chimes in. "But I agree, we should get out of here before-"
  #"Not important. Let me on the ship and then we take off."
    *set RenfriRel %- 15
    "How is it not important!" Marshal fumes. "If she's in danger, we need to help her. Is she?"
    
    "Hell if I know!" you reply, pushing the Kinnari out of the way. "I just know I want out of here, fast."
    
    "Fine! I'll look for her, if you're gonna be like this. Kirill, try to follow me with your grav-pack if you can."
    
    *goto not_good
  #"No, I saw her die."
    *set saw_die 3
    *set RenfriRel %- 20
    "[b]What?![/b]" Renfri exclaims louder than you thought her capable. "Just like that? How? Did she like, attack Crystal all by herself?"
    
    "Yeah, I couldn't believe it myself." Not that it was an unwelcome surprise. "It did not last long, but at least it bought us [i]some[/i] time. We need to get out of here, now."
    
    "Are you sure?" Renfri asks with desperation. "Maybe you just assumed her dead, maybe she was faking it, maybe she's still fighting-"
    
  #"I'm sorry... She made the choice to stall Crystal, so that I could escape."
    *set saw_die 2
    "She did?" Renfri blinks. "I mean, not that I ever doubted her… Fuck it, we're wasting time. I'm gonna fly to the town and help her."
    
    "Are you sure?" Rook says, voice distorted by armor once more. "${fake_name} did not say Hellhound was still alive…"
    
    "She must be," Marshal retorts. "But that may change any moment now, so let's go."
    
    *goto not_good
  #"No, I have not met her. Have no idea where she is."
    *set RenfriRel %- 10
    "Well that is not good," Rook says unhelpfully. "She could be dead or injured, or possibly rampaging across the town now that we are not-"
    
    "Shut up Kirill, she's not killing people!" Marshal protests. "But we need to find her all the same. Want me to fly and search myself?"
    
    *goto not_good

And in that moment, everyone feels a gush of wind, and a subtle change in gravity around you. The cause is not apparent immediately, but when you look up, you see a familiar distortion in the air, and of just the right size. Something on the verge of invisibility is flying, from the direction of the town, towards the cylinder's open end.

Looks like Crystal has had enough.

*page_break

*set injured_crystal "hellhound"

For a moment, fear overtakes you. You think that surely the wyvern noticed your group and the cutter, that it will come down, attack and slaughter the group while you're weakened. That your brilliant maneuver from earlier will turn out worthless, only having bought you five minutes of precious life.

But Crystal doesn't stop. They keep flying, direction unchanged but velocity increasing, passing your position without pause. A few seconds later, they're no longer visible even as a phantom. The last thing you see of the wyvern is a slight ripple in the veil of dark matter separating the habitat from the void, then nothing. Null.

"So…" Damon breaks the silence that ensued. "I suppose that means our mission here is over? That our enemy just kinda… came and went?"

"After killing one of ours, yes," Rook says with a sigh. "It is inconceivable that this was Crystal fleeing from our werewolf teammate, nor that the latter was spared after attacking the fiend.@{(saw_die != 1) |Nor do I believe she didn't at least try to attack the monster, lest she would have simply returned to the ship by now.} We must therefore conclude that Hellhound was slain in action."

"But…" Renfri tries to protest, but can't think of anything to say. "Fuck."

"Yes, this was certainly a defeat," Rook continues. "But at least the rest of us are still alive. So the sacrifice of our dear friend Lisa Herbert was not in vain. In fact, you could say she redeemed herself with that final act of heroism."

*fake_choice
  #"Should we detonate that bomb in her heart now? It should be in Crystal's stomach."
    *set RookRel %+ 15
    *set RenfriRel %- 15
    "Not a bad idea," Rook says musingly. "The explosive isn't strong enough to damage a diamond wyvern from the [i]outside[/i], but if we can puncture the stomach-"
  #"Indeed. I shall mourn her dearly once we return home."
    "Hey boss, just don't be too hard on yourself, alright?" Damon approaches, then puts a hand on your shoulder. "I know you feel guilty about not having been able to save her, but you must remember it's not your fault."
    
    "Yeah, I know," you sigh with fake guilt, trying to ignore the actual shame growing in your processors. "Still, it may be hard to fully… internalize this knowledge. But I know she wouldn't want me to torture myself, and so I'll do my best to move on from-"
  #"Yes, very sad and poignant. Now let's get out of here."
    *set RookRel %+ 10
    *set RenfriRel %- 10
    "Right, no point getting too sentimental over Hellhound." Rook nods in agreement. "She is in a better place now. Well, I actually suspect she is headed somewhere darker, having denied my Lord and all, but I shall still pray-"
  *if lisa_origin_learned
    #"I don't think dying makes up for all her killings, does it?"
      *set RookRel %+ 10
      *set RenfriRel %- 10
      "I suppose not," Rook says with a shrug. "Still, I will pray for her soul just in case there is a chance. After all, God may accept even such a hopeless sinner as-"
  *if saw_die = 3
    #"Nah. She went down like a bitch."
      *set Confid %+ 5
      *set RenfriRel %- 15
      Marshal grits her teeth.
      
      "Now, let us show some respect for the dead," Kirill says, also somewhat disheartened by your words. "Or at least refrain from speaking ill of them."
      
      "But I saw it myself!" you argue, determined to screw Lisa over as much as you conceptually can. "It was such a pathetic scene. She tried to beg Crystal for mercy, but forgot she was in her lupine form, and so ended up just whimpering like a puppy. It sounded something like-"
  #"Kirill, you suck."
    *set RookRel %- 15
    *set RenfriRel %+ 10
    "That is certainly an understandable opinion to hold, given what transpired," Rook says with a wince. "Still. I personally believe we did well enough. After all, a single casualty is not-"
  #Say nothing.
    You give your fallen comrade a moment of respectful silence. It's not like you feel too awkward or ashamed of your actions to speak. Not at all.

And then, an extremely loud sound pierces the air. It resembles a very angry bark of a very large canine, but also sounds vaguely like an obscenity. Uttered by a familiar voice.

You then turn around to see Lisa Herbert approach from the direction of the town. Naked, bruised, partially wolf and clearly pissed. You can see it all even from the substantial distance… which she is currently in the process of crossing. Quickly.

*fake_choice
  #[i]Thank ${master}! I feared she was actually dead.[/i]
  #[i]She's going to kill me, isn't she?[/i]
    *set Confid %- 10
    It sounds probable at the moment, yes.
  #[i]Damn it. I was hoping to be rid of her.[/i]
    No such luck, it seems.
  #"How the fuck is she still alive?"
    Nobody replies to your inquiry. They all seem as surprised as you… and perhaps a bit scared.

"Hellhound!" Rook exclaims once Lisa is just a dozen meters distant. "Joy to see you alive! Not to say I doubted your survival…"

Lisa completely ignores her leader in favor of walking towards you and punching you in the face, her thankfully non-clawed fist impacting the side of your jaw. It probably hurts her more than it hurts you—you're pretty tough, while she's human and tired—but the sentiment is conveyed fairly well regardless.

"What the fuck is wrong with you?!" she yells so loudly people can probably hear her back at the temple. 
*if tricked_lisa
  "You tricked me into fighting, [i]a fucking wyvern, [b]alone![/b][/i] You wanted me to fucking die to cover your fucking escape! You coward, you… 
*if not (tricked_lisa)
  "You convinced me to fight this, this piece of sentient diamond all by myself, all by my [b]fucking self[/b] and wanted to just leave!? Not get help, not even mourn me for a fucking second, just fly off! 
Why are you like this?!"

*fake_choice
  *if saw_die = 2
    #"Hey, Kirill was the one who wanted to leave. I was hoping he'd get you some help."
      *set RookRel %- 10
      *set RenfriRel %+ 10
      "Well then you're dumb," Lisa savagely says. "Kirill is a certified fuckup. You can't count on him to make a good decision, ever, especially when I'm involved."
      
      "As your superior officer, I am somewhat offended," Rook loudly states. "But if insulting me will help you calm down, then go right ahead."
      
      "You worried I'll do something worse if I don't cool down?" Hellhound sneers. "Don't worry, I only have my eyes on-"
  #"Why should I be any different? Getting my teammates killed is fun."
    *set LisaRel %- 15
    *set RookRel %- 15
    *set DamonRel %- 15
    *set RenfriRel %- 15
    "Fun? Fun! Fun." You are pretty sure Lisa has gone crazy. "Of course. Everything is a joke to you, you fucking-"
  #"Well you survived, did you not?"
    *set LisaRel %- 15
    "Yeah, I somehow survived your attempt to get me killed," Lisa retorts. "Doesn't exactly make it any-"
  #"...hi Lisa."
    Lisa bursts into laughter. Deep, throaty, genuine laugh, like that sound a dog makes just before it throws up. "Oh fuck are you… you have guts, I've gotta give you that. Just wait and-"
  *if Confid < 50
    #Get down on your knees. "I'm sorry! Please don't kill me!"
      *set Confid %- 15
      *set LisaRel %+ 10
      "Kill you?" Lisa sneers. "No, no, no. I tried so hard not to kill anyone since we docked here, and you bet I won't ruin my streak just for-"

The werewolf pauses, due to having a Kinnari impact her at a substantial velocity. She doesn't tumble down, but only because caramel wings wrap around her tightly.

"I'm sooo glad to see you!" Renfri says, pressing herself into her teammate. "Not that I doubted you… or anything it's just…"

"Just let go of me, maybe?" Hellhound suggests. "You're getting a bit too touchy. Especially with the bruises and all."

*fake_choice
  #Can we perhaps discuss the relevant subject here?"
    *set RookRel %+ 10
    *goto dresso
  #"How did you survive that fight with just a few bruises, anyway?"
  #"Yeah Renfri. Maybe let her dress first, at least."
    *set LisaRel %+ 10
    *set RenfriRel %- 10
    *label dresso
    "Right…" Marshal unfolds her wings, with a barely visible blush. "How did you survive? Again, not doubting anything, just curious."
  #"Nah, let her keep hugging. I'll go fetch a camera."
    *set DamonRel %+ 10
    "Boss…" Damon speaks up. "How about we don't provoke the werewolf lady anymore?"
    
    "It's all calculated risk, Damon," you chide the other android. "There's a market for that sort of thing. We can make quite a few axions from filming hot metas cuddling. Especially with one of them nude."
    
    *goto dresso

"Hell if I know," Lisa says as Marshal steps away from her. "I certainly didn't beat that thing, Crystal I mean. They were toying with me, tossing me around with gravitic powers without ever touching me, or me touching it. Sent me flying through a wall at one point. Was having its fun."

"As sadistic as we expected, then," Rook muses. "Did they simply get bored at one point and left?"

"I'm not sure if it was sadism back then… and no, it didn't just get bored." Lisa closes her eyes, as though struggling to recall the events. "I think it was about to kill me, but then it got distracted. By some child crying on some random doorstep, with a paper sheet, maybe a paper plane in his chubby hands. And then the wyvern flew at the kid, no hesitation or warning."

*fake_choice
  #"Why so? Was the crying really that annoying?"
    "To my sensitive ears, yes," Lisa smiles weakly. "But the wyvern wanted something else. The piece of paper that kid had."
  #"Did you try to stop it? Crystal from killing the kid, I mean."
    *set LisaRel %- 10
    "What was I supposed to do, in your opinion?" Lisa asks angrily. "I felt barely alive myself. And it's not like the boy ended up dying."
    
    "What?" Renfri blinks. "I mean I'm glad, but… what did Crystal want?"
    
    "A piece of paper I just mentioned. Ate the whole thing before flying away."
  #"Why focus on paper? What's so important about it?"
    "Well it was the thing Crystal wanted. They ate the plane and let the kid go."
  #"And ate the little brat?"
    "Nah, the boy got away. It was his stupid paper plane that got eaten."

Damon frowns. "You are serious, right? Not saying you're not, but… why is Crystal interested in paper planes?"

"It was a special one," Lisa helpfully explains. "When the wyvern approached, it kinda… turned to ash, but without getting burned. And then some specks floated up, and then Crystal inhaled them and… that was it. Somehow."

"You could see some specks of ash from distance?" Marshal asks. "And I thought my eyesight was good."

"Well they were easy to see. Black, dark, darker than black somehow, like they were glowing in reverse. And I know how that sounds, maybe it was just my head trauma, but-"

"No Hellhound, you saw that right," Kirill says before a deep sigh. "And thank you. You just confirmed that Crystal is indeed collecting Dusk nanites."

*fake_choice
  #"What are Dusk particles doing on Calypso?"
    *set LisaRel %+ 10
    "Whatever they want, I guess," Damon is the one to reply. "Small fragments of Dusk are everywhere, just like echoes of the Shriek can be heard in every damn part of the Solar System. Wouldn't give it much thought."
  #"I figured as much."
    "Personally I was hoping it would be something else, but…" Rook winces. "No point denying it anymore. We are fighting a carrier for Dusk. Likely a Vessel with some of its power."
  #"No she didn't. Some black specks prove nothing."
    *set RookRel %- 10
    *goto knoww
  #"That's quite a conclusion to jump to."
    *label knoww
    "I know what I'm talking about, ${name}," Rook says with a frown. 
  #"Fuck."

"But why inside a paper plane of all things?" Marshal inquires, almost protests against having her fears confirmed. "Dusk is the Thing Beneath, one that ate Earth and seeks the end of all things. Why would parts of it be in paper, and why would Crystal want those?"

"When devoid of power, Dusk particles tend to simply mesh with whatever object they can find, an instinctive form of camouflage," Kirill explains confidently, though in a defeated tone. "They only start tearing everything apart when powered substantially. But once a living being inhales them, or takes them in some other way… they gain just enough energy to become sentient. To influence the vessel, to grant them power, to just slightly bend reality around them."

"And Crystal is one such vessel," Damon says grimly. "What now? Do we chase the thing?"

"When it's at full strength and further empowered by the Dusk?" Rook asks with a rare note of sarcasm before turning away, back towards the ship. "No. We must return to [i]Saturn Nine[/i], inform the Admiral of what transpired, then head for @{saturn_complete Telesto|the Yakovian Expanse}. For all we know, Crystal may have gotten what they wanted here. No telling if they'll ever return."

"Isn't that a successful mission, then," Hellhound sneers. "Are you going to inform Da-xia of our victory? How her habitat is finally maybe safe, but not thanks to us?"

"Right…" Rook pulls out a quantum disc from a pocket of his armor, a device similar to one Admiral West gave your group a while back. He then turns and throws it towards you like a frisbee, one you catch instinctively. "Could you fill her in yourself, ${fake_name}? She gave me this communicator when we conversed, but I think she would prefer to hear the news from you."

*set given_disc true
*fake_choice
  #"You got it, boss."
    *set RookRel %+ 10
    *set DamonRel %+ 5
    "Good to see we are still cooperating, at least," Kirill says with a smile. "Oh, and please keep the quantum disc afterwards. 
  #"Sure, though I don't know why you think that."
    *set RookRel %+ 8
    *goto explano
  #"And why would she prefer me over you?"
    *label explano
    *if DaxiaRel > 50
      *set DaxiaRel %+ 15
      "She seemed to like you well enough," Kirill says with a shrug. "So please call her, then keep the disc on you. 
      *goto contlast
    *elseif Social > 50
      *set DaxiaRel %+ 10
      "You are the most charismatic one in our group, are you not?" Kirill points out. "So please call her, and keep the disc once you are done. 
      *goto contlast
    *else
      "Well, you have seen Crystal up close, at least for a moment," Rook explains. "Your report will be more accurate than mine would be."
      
      "Sounds like you're just scared to bring her bad news," you point out.
      
      "Could be the case," the meta-human admits. "Still, please call her, and keep the disc afterwards. 
      *goto contlast
  #"Nah, you do it yourself."
    *set RookRel %- 10
    "As you wish. I will contact her from the ship," Kirill says with a sigh. "Still, keep the quantum disc. 
*label contlast
Da-xia may wish to contact us again, perhaps at an inconvenient time, and you are the one who does not exactly sleep between the two of us."

Your whole group walks towards, then inside the cutter, knowing there's nothing more to be done inside this cylinder. Not that everyone seems entirely happy about that. As for you…

*fake_choice
  #I think we did well enough here. If nothing else, we know what Crystal is about now.
    You may not have gained anything material, but you have knowledge, and knowledge is power. It will help you get Crystal next time, perhaps.
  #I'm just glad only few people died, and that none of my teammates did.
    *set Violence %- 5
    You want to limit casualties first and foremost, and you mostly succeeded today. Maybe you can keep going, end the mission with at least your friends still alive.
  #I think we missed our chance, and feel a tad bitter about that.
    *if progress = 5
      You console yourself with the knowledge that there are other places Crystal has been spotted at. You will visit them too, and maybe then you can finally kill the diamond wyvern, wipe this blemish from your record.
    *if progress = 6
      At least there's still @{saturn_complete Telesto|the Yakovian Expanse}. Maybe you can get Crystal there, at last.
  #I just can't wait to face Crystal again. Perhaps actually fight next time.
    *set Confid %+ 5
    *set Violence %+ 5
    The thing lucked out by catching you unprepared and with only a single teammate to help you out. Next time will be different."
  #I had fun today. That's all that matters.
    Why care if the mission was a success, or how many people ended up dying? This whole hunt is entertaining, and maybe it will continue to amuse you as it goes on.

*if hadaly_goes
  "Hey guys, maybe wait for me?" You hear Hadaly as she trots towards the ship, looking mighty confused. "Why are we leaving? Did I miss anything?"

Maybe.

*set last_mission "calypso"
*set calypso_complete true
*page_break Next Chapter
*if progress = 5
  *gosub_scene interlude_1
*if progress = 6
  *gosub_scene interlude_2
*if progress = 7
  *gosub_scene janus