*label road_to_ulmheit
The road to Ulmheit is
*if trade_efficiency <= 0.8
	uneven and somewhat treacherous.
*if (trade_efficiency > 0.8) and (trade_efficiency <= 0.95)
	somewhat uneven.
*if (trade_efficiency > 0.95) and (trade_efficiency <= 1.05)
	not difficult.
*if (trade_efficiency > 1.05)
	smooth and easy.
*return

*label swear_fealty
*set log & " That summer, you traveled to Ulmheit to swear fealty to your liege."
*gosub road_to_ulmheit
It has been some years since you last traveled it. You have only been to Ulmheit twice, and never to Sturmreich. This is yet one more reason that you were so dismayed by the broken arm that prevented you from accompanying your father to the tournament.

The palisade around the heart of the village is still impressive, even though you've seen it before. The amount of timber and labor it would take to build such a structure verges on the staggering. But then again, the castle that stands above Ulmheit, with its low wall of stone, is even more daunting. It sits atop a partially man-made hill overlooking the village, offering clear views of the surrounding countryside.

Not that there is much need for walls in the realm of the Quinn. While thornes sometimes come to blows over matters of honor and inheritance, most such matters are ultimately decided in the courts of law rather than on the battlefield. Still, not everyone lives within the bounds of Sénan's law, and these walls are stark reminders of that.

*if manor_liquid < round(manor_acreage /4)
	*goto borrow_inheritance_funds
You pass throught the market square—trying to keep your eyes in your head at the sight of vegetables you've never seen before—before passing through the other side to the palisde walls of the castle.

After some back-and-forth with the guards at the game, you and your entourage are admitted.
*label audience
*page_break
The thordain, Osa Fenich, greets you with bread, salt, and cider, and welcomes you to Ulmheit. She indicates a place for Mordain to lay his things in the great hall and offers you the chamberlain's room for the duration of your stay.

Once you are settled, you are invited to join Osa Fenich in the bailey to discuss the matter of the defense of your soon-to-be-liege.

"And who will represent the thornet of ${thurnet} on the field of battle, when Lord Ulrich issues the call to arms?"

*choice
	#"I will."
		*set log & " When challenged by the thordain, you proclaimed"
		*set hubris %+5
		"To champion a thurnet, you must be a knight. Are you a knight?"
		*if knight
			*set log & " that you were a knight, ready to defend your liege."
			
			"Yes, Ser Osa Fenich."
			
			"Very well. A feast will be held after sundown."
			*goto post_knight
		
		"No, thordain. My father died before he could finish my training."
		*set log & " that you were not yet a knight, but that you were prepared to defend your liege anyway."
		
		"But you think you are ready to be knighted now?"
		
		"I do."
		
		*if sword = 2
			"I see that you have recovered your family sword. Draw it, and let me see what you are made of."
		*if sword != 2
			"Do you even have a sword with which to prove yourself?"
			
			*if sword > 1
				You draw your sword in answer.
			*if sword = 1
				"No, Ser Osa Fenich."
				
				The thordain gestures to one of the men-at-arms, who draws his sword and hands it to you.
				*if combat > 1
					You give it a swing. It is not balanced to your hand. You grimace.
		She draws her own sword and the two of you begin to circle.
		
		*if (combat = 1) and (tactics = 0)
			Within a few moments, it becomes clear that you are a sorry excuse for a warrior. You are disarmed and spitting out dust.
			
			Osa Fenich sheathes her sword. "You will have to find another to represent you. At least until you learn something more about swordplay."
			*label lose_combat_pledge_knight
			*set rep_ulrich %-10
			*set rep_gentry %-10
			*set pledge_employ_knight true
			*set log & " The thordain challenged you to prove yourself, and you failed. In the aftermath, you pledged to hire a knight to serve as your proxy."
			
			"How much time do I have?"
			
			Osa Fenich frowns. "I suspect that Lady Ulrich would give you until next year to find a suitable proxy."
			
			"Then I will find one."
			
			"I shall inform Lady Ulrich. The feast should begin after sundown."
			
			With that, she departs.
			*goto post_knight
		*elseif (combat = 1) and (tactics = 1)
			For a brief moment, it looks like you might actually have a chance when you manage to back Osa into a barrel. Her momentary confusion, however, is not sufficient advantage for you to overcome her talents as a swordswoman.
			
			A few moments more and you are disarmed and spitting out dust. "You will have to find another to represent you. At least until you learn something more about swordplay," she says, sheathing her sword.
			*goto lose_combat_pledge_knight
		*elseif (combat = 2) and (tactics = 0)
			Your swordplay is respectable, but when you trip over a barrel, the men-at-arms break into laughter.
			
			Osa holds her swordpoint to you and you relent. "You will have to find another to represent you. At least until you learn something more about swordplay," she says, sheathing her sword.
			*goto lose_combat_pledge_knight
		*elseif (combat + tactics) = 3
			*set log & " The thordain challenged you to prove yourself, and you did."
			You manage to hold you own long enough to see Osa Fenich nod. Finally, just when you were about to collapse in exhuastion, she lowers the tip of her sword.
			
			"I have seen enough. You're still inexperienced, but it's something I can work with." 
			
			You would respond, but you're too busy catching your breath.
			
			"I shall inform Lady Ulrich. The feast should begin after sundown."
			*goto post_knight
		*else
			*set log & " The thordain challenged you to prove yourself, and you did."
			You may be no match for Osa Fenich, but that doesn't mean you don't make a good showing of your skills. She nods appreciatively, and after just a few minutes lowers her sword.
			
			"Yes, that will do. I shall inform Lady Ulrich. The feast should begin after sundown."
			*goto post_knight
	*if (knight_hired) #"I have employed a knight, Ser ${knight_name}, to champion me."
		TODO
		*goto post_knight
	#"I pledge to employ a knight to champion ${thurnet}."
		*set log & " Once before the thordain, you pledged to hire a knight to serve as your proxy."
		*set pledge_employ_knight true
		*set rep_gentry %-5
		Osa Fenich looks at you with disdain.
		
		"I will inform the Lady Ulrich. The feast should begin after sundown."
		*goto post_knight	

*label post_knight
*page_break
You suspect that this is what the Lady Ulrich would consider a small feast, but it is larger than any you have ever seen.
*if (year <= 566)
	The lady of the house, Nym Pappernodich Cradzlerfein Ulrich, sits at the center of the great table. The toddler thorne, Eomarr Jarlich, sits in her lap during your formal audience, but seems mostly interested in the hounds that sit patiently for scraps. You muse to yourself that the household must have a talented huntsmaster for such well-behaved animals.
	
	*gosub resolve_knighthood
	
	Eomarr Jarlich laughs in delight and claps his hands. @{(chivalry > 50) You are proud that your liege already shows such magnaninmity.| Surely he has no sense of your words, but you are duty-bound to pretend that he does.}

	When the toast is done, a man steps forward.
	*gosub phare_history
	*goto depart_fealty
*elseif (year = 567) or (year = 568)
	The young thorne, Eomarr Jarlich Cradzlerfein Ulrich, sits at the head of the table, with his mother, Nym Pappernodich, at his side. During the audience, Eomarr Jarlich manages to say his part as liege lord, but he clearly thinks of this as some sort of game. He is more interested in the harpist who has taken a break from her instrument to eat a bite of mutton while your audience unfurls.
	
	*gosub resolve_knighthood

	When the toast is done, a man steps forward.
	*gosub phare_history
	*goto depart_fealty
*elseif (year = 569) or (year = 570)
	*set rep_gentry %-10
	The young thorne, Eomarr Jarlich Cradzlerfein Ulrich, sits at the head of the table, with his mother, Nym Pappernodich, at his side. During the audience, there are several uncomfortable moments, as Eomarr Jarlich demands to know why it has taken you so many winters to appear before him. You stammer your excuses until Nym Pappernodich intervenes.
	
	*gosub resolve_knighthood

	When the toast is done, a man steps forward.
	*gosub phare_history
	*goto depart_fealty
*else
	TODO is this possible?
	*goto depart_fealty

*label depart_fealty
*set swore_fealty true

The rest of the evening consists of more drinking, singing of songs, and other forms of entertainment. You stagger to your bed a few hours before dawn.
*page_break
The next day, you sign the papers that transfer the necessary capital to the thorne's accounts. The fee is staggering, but no more than you were expecting; in the eyes of the law, you are rightful thornet of ${thurnet}.
*set manor_liquid - round(manor_acreage /4)

Of course, that also means that you may now raise your banner.
*gosub_scene subs raise_banner

You depart the castle and pass back through the village.
*label after_ulrich_visit
*choice
	#I return home straightaway.
		*return
	#I want to visit the market.
		*temp markettime 0
		*temp marketTradeEfficiency trade_efficiency
		*set marketTradeEfficiency +(trade * 0.05)
		*goto market

*label borrow_inheritance_funds
*temp difference (round(manor_acreage /4) - manor_liquid)
*set manor_debt +difference
*set manor_liquid +difference
*set log & " Because you were short on funds, you were forced to borrow the necessary amount from the Mercer's Guild."
You borrow the necessary funds.
*page_break
TODO get to castle
*goto audience

*label resolve_knighthood
*if knight
	*set log & " You knelt before the Lady Ulrich and pledged your sword to her son."
	"It is time to kneel, Ser ${name} ${patronym} ${toponym}," Lady Ulrich says.
	
	You kneel.
	*label kneel
	She stands and comes around the great table. Along the way, someone hands her the sword of the phare Ulrich. You run your hand along the edge of the blade until it is bright red with blood.
	
	"As I have spilt my blood for you here today, so shall I again."
	
	"The phare Ulrich accepts your fealty and recognizes your right to ${thurnet}. The phare Ulrich accepts your blood, and pledges in return to not ask you to spill it in vain. Rise, Ser ${name} ${patronym}, thornet of ${thurnet}."
	
	A@{knight |nother} cheer goes up in the hall and a toast is raised to the thorne. The bond is sealed.
	*set knight true
	*return
*elseif pledge_employ_knight

	"I understand that you have pledged to bring a knight into your household, to be your proxy when called upon."
	*set log & " You knelt before the Lady Ulrich and pledged your support to her son."
	
	"Yes, Lady Ulrich."
	
	"I accept your pledge and I accept your fealty. As you swear your blood to the phare Ulich, so to do we swear to not ask you to spill it in vain."
	
	A cheer goes up and you raise a toast to the thorne of Ulmheit.
	*return
*else
	*set log & " First, you knelt before the ardiom, who anointed you; then you knelt before the thordain, who knighted you. Finally, you knelt before the Lady Ulrich, who accepted your pledge of fealty."
	Finally, the matter of your knighthood arises. "I understand you committed yourself well in the bailey this afternon."
	
	"That is not for me to say, m'lady."
	
	"It is so said. Eamon Oslich, Ser Osa Fenich, will you please?"
	
	You kneel before the great table. A clergyman—Eamon Oslich, you presume—steps forward. He anoints your forehead with oil and says a prayer to Odo Macanh, enjoining you to upload the laws of Sénan and the the Judges with all your strength. When he is finished, Osa draws her sword. You kiss the blade and pledge your heart to the virtues of chivalry.
	
	When you rise, you are a knight of the realm. The room erupts into a cheer and a toast is raised in your name. A second toast is raised in the name of your father.
	
	"And now, it is time to kneel again, Ser ${name} ${patronym} ${toponym}," Lady Ulrich says.
	
	You kneel again.
	*goto kneel

*label resolve_knight
*if knight
	Of course, you are a knight, so you pledge your sword to her son, and the matter is concluded.
	*return
*elseif (combat + tactics) >= 4
	*set knight true
	You proclaim your preparedness to take on the mantle of knightood. Osa Fenich, the thordain, draws a sword and the two of you begin to exercise your mettle.
	
	When all is said and done, you have proven yourself worthy of the title. You are knighted.
	*return
*else
	*set pledge_employ_knight true
	You pledge to employ a knight as proxy within the next year.
	
	Osa Fenich makes no effort to disguise her disdain.
	*return

*label phare_history
"I am Eadhan Korenich Hardanich-ye-Coravar, here to safeguard our liege." You raise your drinking-horn to Eadhan Korenich. Hardanich-ye-Corarch is a bit upriver, almost closer to the village of Loren than Ulmheit. "Come, ${name} ${patronym}, tell us how your phare came to serve the Cradzlerfein Ulrich."

You pause a moment, realizing that your horn is empty. "Ser Eadhan Korenich, if you will share your cup with me, as mine is empty and my story is long." @{swore_fealty He circles the bonfire|He comes around the table} and offers you a drink from his. You sip it slowly. You knew this moment was coming; you let the silence add to the tension.

"During the time of the Gorji occupation, the caol of Amerlich anointed Adeline Jarlich Sturmreich arthorne of Sturmreich, commanding him to raise an army and join with him to expel the Gorji from Fassmein. The arthorne of Sturmreich traveled the region with his thordain, calling the Quinn people to arms.

"The volunteers assembled at Sturmreich, where he taught them to fight in formation—with shield and spear—to defeat the Gorji horsemen. He ordered the archers to practice with their bows until their fingers bled.

"Among them was my grandmother's mother, who left her parents' home to oust the Gorji from the lands of her countrymen. She quickly became a leader among her shieldmates, because…"

*fake_choice
	#"She was clever and understood how to press an advantage."
		*set chivalry %-10
	#"She was honorable and inspired others with her sense of fairness."
		*set chivalry %+10
	#"She was pious and her faith inspired her shieldmates."
		*set piety %+10

"As you know, Adeline Jarlich never met the Gorji Horde on the field of battle. While he camped at Amerlich, the old arthorne caught ill and died. But his son Daneuil Adelinich took over command of his army.

"And so the caol of Amerlich road south with the knights of Amerlich, Sturmreich, Plodnaven, and Rasteninch-ye-Javandarch at his back to liberate Fassmein.
*comment this army was probably about 300 knights, 900-odd squires, pages, and retainers, 1500 archers, and 15,000 peasant-infantry. That said, these knights were not in plate with heavy horse.

"When the armies of the caol arrived at Fassmein, the Gorji garrison rode out to meet them. The Gorji believed that only cowards hid behind castles and walls. And besides, their horses were of no use in the stables.

"And so the battle was met on the fields of Fassmein, in the month of the Hawk, five-hundred, seventeen years from our Exodus."

"From our Exodus," the @{swore_fealty gathering|room} chants and drinks from their cider.

"At the battle, my great-grandmother distinguished herself by…"
*temp sirids_virtue 0

*fake_choice
	#"Showing mercy to the fallen Gorji."
		*set compassion %+10
		*set sirids_virtue 1
		"After the battle was done, she organized her shieldmates to tend the wounded Gorji who could survive. When they were well, they agreed to go back to the far side of the Eastern Pass and trouble the peoples of the Sónenstom no more."
	#"Avoiding a trap laid for her regiment by the enemy."
		*set chivalry %-10
		*set sirids_virtue 2
		"As a sergeant charged with directing her shieldmates, she saw through the feints of the Gorji horse-archers. Though her shieldmates were angry, she exhorted them to hold fast despite their losses. And so they did."
	#"Braving the worst of the fighting to bring honor to family."
		*set hubris %+10
		*set sirids_virtue 3
		"When the Gorji horse-archers neared, she ordered a charge. The battle turned into a melee, and she claimed the lives of many of her enemies that day."

There are murmurs of approval from the crowd.

"And tells us, ${name} ${patronym}, who was responsible for the victory that day?" Eadhan Korenich asks.

*fake_choice
	#"Sénan, the law-giver, blessed his people with victory that day."
		*set piety %+5
		*set rep_senan %+10
		@{swore_fealty |The ardiom of Ulmheit, Eamon Oslich, is clearly pleased with your reply.} "A pious man you are, ${name} ${patronym}," Eadhan Korenich says.

		"Just as we owe our freedom to Sénan, so too do we owe our victories," you reply.

		Perhaps a bit disappointed, he continues on.
	#"The Caol of Amerlich, whose strategems drew the Gorji forces out where they could be smashed by his brave knights."
		*set hubris %+5
		*set rep_gentry %+10
		@{swore_fealty Your audience nods their head. While Lady Ulrich's retinue—and Eadhan Korenich in particular—may wish for glory on the field of battle someday, the residents of your manor are less bloodthirsty.| The room lets out a cheer. All of the guests hope to someday have a moment of glory for themselves like the Battle of Fassmein. Eadhan Korenich is among them.}
	#"The knights, like Lord Ulrich's grandfather, who faced the Gorji and won glory for their phares."
		*set chivalry %+5
		*set rep_ulrich %+5
		*set rep_gentry %+5
		*if swore_fealty = false
			*if year <= 568
				Though Eomarr Jarlich is too young to catch the meaning of your words, they do not escape the notice of Lady Ulrich.
			*if year > 568
				You note that Eomarr Jarlich—who was growing bored with this tale—stands a little straighter at the mention of his grandfather.
			@{(chivalry < 50) You only hope that your flattery is not overdone.| You hope the young thorne will live up to his grandfather's example.}
		
		*if swore_fealty
			Though it is hard to say in the light of the bonfire, you think Lady Ulrich rolled her eyes at your attempt at flattery.
		Eadhan Korenich @{swore_fealty |simply} nods at your words.
	#"The common folk, whose blood and courage held the line long enough for the Gorji cavalry to expose themselves to the archers and knights."
		*set hubris %-10
		*set rep_freeholders %+15
		*set rep_gentry %-10
		*set manor_morale %+5
		*if swore_fealty
			Your audeince goes silent. That was not the expected response.

			Finally, a diom who traveled with the Lady Ulrich stands and interjects, "The young thornet speaks wisely. We were all slaves before the Exodus. And we had the courage to free ourselves. Why would our kind be any different today?"

			"I'll drink to that," exclaims one of your yeomen. A somewhat uncomfortable toast is raised, but it gives Eadhan Korenich the opportunity to regain his footing.
		*if swore_fealty = false
			The room goes silent. That was not the expected response.

			Finally, the ardiom Eamon Oslich stands. "The young thornet speaks wisely. We were all slaves before the Exodus. And we had the courage to free ourselves. Why would our kind be any different today?"

			"To the common folk," says someone from the back of the room. A somewhat begruding toast is raised, but at least your point has been somewhat deflected.

			After the toast, Eadhan Korenich recovers his footing.
"Welcome, ${brother}, to the vassals of @{knight Ulmheit. I look forward to the day that we may ride into battle together, side-by-side| Ulmheit}." Then he address the @{swore_fealty crowd|room}. "Let us raise our horns again to the @{sirids_virtue mercy|cleverness|bravery} of Sirid Quarringrich."

And so you raise your horn and drink with the assembled guests to the memory of your great-grandmother.
*return


*label market
*if markettime > 2
	You have been in Ulmheit long enough. It is time to return home.
	*page_break
	*return

What would you like to trade in the market?

*choice
	*if (barncat = false) #I want to buy a barn cat, to chase the rats away from the grain.
		*set log & " You bought a barncat in the market of Ulmheit."
		*set manor_liquid -1
		*set barncat true
		*set markettime +1
		*goto market
	*if (manor_liquid > 200) #Buy a palfrey.
		*set log & " You bought a palfrey in the market of Ulmheit."
		*set ridinghorse +1
		*set rep_gentry %+5
		*set manor_liquid -(150 / marketTradeEfficiency)
		*set markettime +1
		*goto market
	*if (manor_liquid > 400) #Buy a warhorse.
		*set log & " You bought a warhorse in the market of Ulmheit."
		*set warhorse +1
		*set rep_gentry %+10
		*set manor_liquid -(300 / marketTradeEfficiency)
		*set markettime +1
		*goto market
	*if (ruined_bell) #I sell the ruined bell for scrap.
		*set log & " You sold the ruined bell for scrap."
		*set manor_liquid +(500 * marketTradeEfficiency)
		*set markettime +1
		*set ruined_bell false
		*goto market
	#I want to sell some of my excess stores.
		*set markettime +1
		*label sell_more_goods
		
		What do you want to sell?
		*choice
			*selectable_if (cider > 1) #Cider.
				How much cider do you want to sell?
				*temp sellCider 0
				*input_number sellCider 1 cider
				*set manor_liquid +(sellCider / marketTradeEfficiency)
				*set cider -sellCider
				You have sold ${sellCider} gallons of cider.
				*set log & " You sold ${sellCider} gallons of cider in the market of Ulmheit."
				*goto sell_more_goods
			*selectable_if (wheat > 1) #Wheat.
				How much wheat do you want to sell?
				*temp sellWheat 0
				*input_number sellWheat 1 wheat
				*set manor_liquid +(sellWheat / marketTradeEfficiency)
				*set wheat -sellWheat
				You have sold ${sellWheat} bushels of wheat.
				*set log & " You sold ${sellWheat} bushels of cider in the market of Ulmheit."
				*goto sell_more_goods
			#That's all that I want to sell from my stores.
				*goto market

*label dovecote

The journey to Ulmheit is thankfully quiet.

Your banner streams behind you as you approach the gate of the castle of Ulmheit. By the time you pass through the gates, the chamberlain has arrived to great you.

"The thornet ${toponym} must be tired from ${his} journey. Unfortunately, there are no suitable rooms for you in the castle, but you are welcome to set up camp. But please, let us see your horses tended and let us break bread together."

Your party surrenders your horses and make your way into the great hall.

*temp dovecotePriceIndex 1
*if rep_ulrich > 60
	*set dovecotePriceIndex -0.05
*if rep_ulrich > 50
	*set dovecotePriceIndex -0.05
*if rep_ulrich > 40
	*set dovecotePriceIndex -0.05
*if rep_ulrich < 30
	*set dovecotePriceIndex +0.05
*if rep_ulrich < 20
	*set dovecotePriceIndex +0.05
*comment yes, those are meant to be cumulative
*page_break

The chamberlain offers you bread, salt, and cider, and sits with you for a time indulging in gossip—a sign of respect to one of his liege's vassals. Eventually, however, he informs you that you should expect an audience with the Lady Ulrich and the thorne of Ulmheit during dinner. He is periodically interrupted by servants bringing in frest straw to serve as bedding for you for the night; unlike last time, you will not have a chamber of your own this evening; tonight, you will sleep in the loft above the hall. Thankfully, you brought one of your favorite bearskins.

At dinner, there are the customary toasts to you and your ancestors and to the thorne Ulmheit and his. 

Finally, the time comes to negotiate. Lady Ulrich asks why you have sought this audience; you intimate your desire for a dovecote.

"And why should my son grant you this license, ${name} ${patronym}?"

"Lady Ulrich…
*fake_choice
	#"…it is all for your benefit. In the future, when you and the Lord Ulrich grace ${thurnet} with your presence, we will be better equiped to satisfy your culinary needs. Who am I to deny you such pleasures?"
		*if spendthrift > 55
			*set dovecotePriceIndex -0.1
		*if spendthrift <= 55
			*set dovecotePriceIndex +0.1
	#"…if my manor becomes more prosperous, it would allow me to better serve you."
		*if chivalry < 45
			*set dovecotePriceIndex -0.1
		*if chivalry >= 45
			*set dovecotePriceIndex +0.1
	#"…because it is my right to ask it of you. And you have no right to deny me, only to set the price." 
		*if hubris > 55
			*set dovecotePriceIndex -0.1
		*if hubris <= 55
			*set dovecotePriceIndex +0.1

She purses her lips and nods at your words. You are unsure if that is good or bad.

*temp dovecotePrice (1000 * dovecotePriceIndex)
*set dovecotePrice round(dovecotePrice)
"Very well. The price is ${dovecotePrice} bushels."

"Thank you, Lady Ulrich."
*set manor_liquid -dovecotePrice
*set dovecote_license true

You step to the side, where the chamberlain draws up the license, as well as a draft on your account with the Mercer's Guild.  You make your mark on the documents.

With the paperwork done, you return and raise a toast to your liege.

"Long may he live, long may he uphold the honor of his ancestors and the laws of Sénan!"

The young Lord Ulrich nods gravely at your words.

*page_break

The rest of the night is long and drunken. Eventually, you make your way to your bed in the loft. The next morning, you eat a small breakfast, say your goodbyes, and set out from the gate.

*goto after_ulrich_visit