*label appoint_squire
*page_break
You are a knight. Every knight needs a squire.

*label pick_squire
The most appropriate choice would be your little brother Karol. The yeoman Jarl Sorenich has a daughter who is the right age and has show some interest and skill during the militia training. Additionally, you could reach out to the neighboring thornet, Paster Donnelich Fievenreivar, to see about his son, Javand Pasterich.

*label another_squire
*temp just_lost_page false
*choice
	*if karol_age >= 12
		*if (karol_status = "") #I will take my brother Karol as my squire.
			*set squire "Karol Hardanich"
			*set squire_inf "Karol"
			*set squire_support -20
			*set karol_status "squire"
			*goto squire_chosen
		*if (karol_status = "page") #It is time to promote Karol to be my squire.
			*set squire "Karol Hardanich"
			*set squire_inf "Karol"
			*set squire_support -20
			*set squire_him "him"
			*set karol_support 0
			*set karol_status "squire"
			*set page false
			*set page_name ""
			*set page_inf ""
			*set just_lost_page true
			*goto squire_chosen
	*if karol_age < 12
		*if (karol_status = "page") #I want Karol to be my squire, but he is too young. I will promote him as soon as he is old enough, and do without in the meanwhile.
			*set squire "Karol_delayed"
			*return
	#I will take the daughter of Jarl Sorenich.
		*set squire "Myvonna Jarlich"
		*set squire_inf "Myvonna"
		*set squire_him "her"
		*set manor_morale %+5
		*set rep_freeholders %+15
		*set rep_gentry %-10
		*set squire_support -40
		*set hubris %-20
		Jarl Sorenich is deeply honored by your request to take his daughter Myvonna Jarlich as @{knight your squire| a squire for ${knight_name}}. From your perspective, you can skimp on some of the costs normally associated with supporting a squire, since a yeoman's child won't know any better.
		
		You welcome Jarl Sorenich's family into your hall for a meal that night. @{knight | ${knight_name} looks at her with some suspicion; she gives him the stinkeye back.} The next day, her training will begin.
		*goto squire_chosen
	*hide_reuse #I will reach out to the thornet of Fievenreid.
		*if rep_gentry > 40
			*set squire "Javand Pasterich"
			*set squire_inf "Javand"
			*set squire_him "him"
			A week later, two figures appear on the road from Fievenreid.
			
			You receive Javand Pasterich and the eorwald of Fievenreid and welcome them to your great hall.
			
			You're not sure what sort of reception Javand Pasterich was expecting, @{household_support_index but your meagre feast and threadbare furnishing was not it. To your surprise, he has the manners to keep his opinion to himself.| but your modest feast and sparse furnishings was not it. To your surprise, he has the manners to keep his opinion to himself.| but your modest feast and substandard furnishings was not it. Somewhat to your surprise, he has the manners to keep his opinion to himself.| but he seems comforted by the warm meal and the surroundings. It must remind him of home.| but he seems impressed by the feast and the appointment of the hall.} @{knight You promise| ${knight_name} promises} him that tomorrow his training will begin.
			
			The eorwald departs the next day, no doubt anxious to deliver a report on the conditions in which the thornet's son now finds himself.
			*goto squire_chosen
		*else
			You receive word back from the thornet of Fievenreid declining your offer.
			
			You will have choose another squire.
			*goto another_squire

*label squire_for_proxy

You now have a knight in your employ. A knight needs a squire.
*goto pick_squire

*label squire_chosen
*page_break
*set squire_support 80
*set ridinghorse +1
*set manor_liquid -round(150 / trade_efficiency)

Of course, one of the first things you have to do for a squire is provide ${squire_him} with a horse. You arrange for one to be purchased from Ulmheit.
*if manor_liquid < 0
	Of course, you'll have to borrow the capital to conclude the purchase.
	*set manor_debt -(manor_liquid / trade_efficiency)
	*set manor_liquid 0
*if just_lost_page = false
	
	You are also now without a page.

	This is not an uncommon occurance. Until the opportunity arises to take on a young pharen, you will take on children from the freeholders of the manor to serve you for limited periods.
*return

*label javand_knighted

*if knight
	*set rep_gentry %+10
	Javand Pasterich has been a squire for over a decade now. It is time for them to be knighted.
	
	You invite his family to your manor for the occasion. They arrive in the afternoon, their banners snapping in the wind.
	
	TODO
	*return
*else
	*return