*label sirid_convo_intro
*set sirid_convo_intro +1
*if sirid_convo_intro = 1
	Sirid welcomes your questions. She has a wealth of knowledge to share with you.
	*goto sirid_convo_choice
*elseif sirid_convo_intro = 2
	"I'm so glad you asked, ${name} ${patronym}."
	*goto sirid_convo_choice
*else
	Sirid smiles. "Some things you want to review?"
	*goto sirid_convo_choice

*label sirid_convo_choice

*choice
	#I want to discuss crops.
		*label discuss_crops
		
		What crops do you want to ask about?
		*choice
			#Apples.
				"The apple orchards are the pride of any manor. Of course, they are too much of a luxury for the commoners to devote acreage to, but how else would we celebrate the communion of Sénan? Therefore, all manors have some acres devoted to apple orchards, for guests, feasts, and religious ceremonies.
				
				"Of course, we set the cider aside for a year so that it ferments," she says with a wink.
				
				"This also means that any excess cider fetches a good price at market, as the villages, towns, and cities of the Quinn need a constantly supply of cider."
				*goto discuss_crops
			#Oats.
				"We can eat oats, sure. But I take it you want to know why oats are important to the manor.
		
				"Oats are eaten by oxen and horses. Warhorses require four acres of barley each to feed them through the year. Oxen require two-thirds of an acre each."
				*goto discuss_crops
			#Vetches.
				"Vetches are a generic terms for beans, peas, and lentils. In the old days, we had to leave the land fallow on alternating years, so that the soil could replenish itself from the sowing of grains. But Odo Sógurn discovered that, by planting vetches, we could make use of that fallow land.
				
				"Most of the vetches that you grow go to feed your swine. However, I have noticed them on your table sometimes. That said, they provide a lot of variety to the commoners' diets. The cottars, for example, used to survive on rye bread and cabbage, with an egg every once in a while. Now, with beans and peas, they have a much more diverse diet."
				*goto discuss_crops
			#Wheat.
				"Wheat is both the basis of wheat bread and the medium of exchange among the Quinn. Most everything is denominated in terms of bushels of wheat. Moreover, taxes on the land itself—both from us to you and from you to the thorne—must be paid in bushels of wheat. It is said that a serf family can trade a bushel of wheat for enough other food to feed themselves for a week.

				"Wheat comes in two varieties: spring and winter. Winter wheat is planted in the early winter, before the ground hardens, and gestates over the winter, sprouting in the spring. We harvest it in the summer. Spring wheat is planted in the spring, and reaped in the fall. The two types are useful because it spreads out the harvest. However, spring wheat doesn't grow as much or as tall as winter wheat, but winter wheat is more susceptible to failure due to frosts.
				
				"Of course, the commoners can't afford wheat bread themselves. The serfs eat rye or barley bread, and the freeholders mostly eat maslin—a blend of rye and wheat. It's only pharen like you that can that afford to eat wheat bread morning, noon, and night."
				*goto discuss_crops
			#I want to ask Sirid about something else.
				*goto sirid_convo_choice
			#I'm done asking questions.
				*return
	#I want to discuss livestock.
		*label livestock
		
		What livestock do you want to ask about?
		*choice
			#Tell me about calves.
				"Calves are cattle that have not yet seen winter. If we keep them through their first winter, they grow into yearlings.
				
				"As soon as we can wean them off their dam's teat, we put them out to pasture. We only need hay for them if we plan to keep them to become yearlings. If we don't, we can cull them for beef and leather.
				
				"The greatest difficulty with calves is that an unfortunate number of them don't survive to winter. They are stillborn or otherwise malformed, and die before they can be culled. That said, I've long thought that, with the proper care, we might be able to improve both the birth rate and the survival rate of calves."
				*comment TODO change to CALFSKIN / VELLUM
				*goto livestock
			#Tell me about yearlings.
				"Yearlings are cattle that have been kept through one winter. If slaughtered, they produce a respectable amount of beef and leather. They spend the spring, summer, and fall in pasture, so it doesn't take that much hay to keep them from calves.
				
				"If we keep them through a third winter, they grow into bulls, oxen, or cows."
				*goto livestock
			#Tell me about dairy cows.
				"The dairy cows are, I suppose, the one small luxury we have on this manor. We don't actually breed them until after their third winter, and not all those that we do foal. However, they are the source of milk on the manor. We use the milk to make butter and two kinds of cheese, soft cheese and hard cheese.
				
				"The soft cheese doesn't last as long and can't ship as far, but we can get twice as much from the same amount of milk as hard cheese. Our wheels of hard cheese will last…well, I've heard that the Mazurani love our cheese. Regardless, making cheese requires salt. And while we have to import salt, the towns and cities of the Sónenstom have an insatiable need for cheese; merchants will buy as much as we can make.
				*comment this is totally incorrect. you get a pound of cheese from a gallon milk regardless of the type. It's a matter of how much labor and aging is involved.
				
				"The reason why dairy cows are a luxury is that they can't be put out to pasture if they're being milked. Therefore, unlike the rest of our livestock, we have to store enough hay every fall to feed the dairy cows through the whole year. To give you an idea, five acres of meadow can support four cows for a year.
				
				"Of course, when a dairy cow gets too old to foal, we cull them. Dairy cows live for about ten years."
				*goto livestock
			#Tell me about oxen.
				"Oxen are castrated male cattle. We castrate them to calm them down. They would never pull a plow together as a team if they had their testicles; they'd tear the yoke and each other apart.
				
				"We need one ox for every fifteen acres under the plow. For the demense, we yoke two together, and a team of two can plow thirty acres. The serfs do it differently: some have single-ox yokes, and work their fifteen acres. Others have two-ox yokes, and work together on each others' land.
				
				"The oxen grow quite large as they graduate from being yearlings. And we have to plan on feeding them both during the winter and during the plowing season. They eat a lot, and during the plowing season, they could either be put in the pasture or they can work. Since we need them to work, we have to put away enough hay for them every harvest to sustain them through two-thirds of the year. To give you an idea, we can support three oxen on two acres of meadow through the winter.
				
				"In addition to that, however, oxen eat oats. They need a third of a bushel a day during the spring and summer, to keep their strength up.
				
				"When they grow old—or you find yourself in need of a ready-made feast—they can be slaughtered. Their meat and leather is quite valuable. I've heard it said that in towns where oxen are more populous, fourteen live oxen can be traded for sixteen dead ones."
				*goto livestock
			#Tell me about bulls.
				"Bulls are breeding male cattle. They're basically useless except as studs; they're too aggressive to be yoked. We have to feed them hay through the winter and then put them out to pasture during the spring, summer, and fall. Thankfully, we don't need more than one. 
				
				"The main concern with bulls is that we not upset them; they can be dangerous when provoked."
				*goto livestock
			#Tell me about lambs.
				"Lambs are sheep that have not yet seen a winter. They are born in the spring and mature through the summer and fall while out to pasture.
				
				"When we cull lambs, we harvest their meat—which is called mutton—their wool, and their hides, which we turn into lambskin. Lambskin is very soft, and commands a higher price than regular leather.
				
				"Thankfully, there is very little lamb attrition; there are few stillbirths or other malformations that make them unusable."
				*goto livestock
			#Tell me about ewes and wethers.
				"Ewes are female sheep. We can expect most ewes to give birth every year.
				
				"Ewes produce about three pounds of wool a year. When they're slaughtered, we make sure that none of their meat goes to waste.
				
				"Wethers, on the other hand, are castrated male sheep. They produce about four pounds of wool a year, and their wool is valued more highly than that of ewes. However, because we need to constantly replenish our flock, we keep an even mix of ewes and wethers.
				
				"Besides the wool, we make use of the meat that a culled wether offers.
				
				"In total, we need a little more than one sheep per person on the manor; that's the bare minimum of how much wool it takes for the commoners to get a new outfit every year, plus some bedding and other needs. We can feed just shy of fifteen sheep through the winter on one acre of meadow."
				*goto livestock
			#Tell me about rams.
				"Much like a bull, a ram is a male breeding sheep. Like bulls, they are nigh-useless; even their wool is considered waste. However, we have to keep a small number in order to maintain the flock."
				*goto livestock
			#Tell me about piglets and hogs.
				"Piglets are baby swine. They feed from their mother through the summer, and then we release them into the forest during the fall to feed on acorns and insects during the fall. By the end of the fall, they have swelled in size and are called hogs. It should be noted that we need two acres of forest for every swine that we release there. More than that, and the trees will be slowly uprooted, producing dead-zones that require a lot of labor to correct.
				
				"Hogs can be kept through the winter to become sows or boars, but most hogs are culled during the harvest for pork and leather."
				*goto livestock
			#Tell me about sows.
				"Sows are breeding swine. They produce a litter of usually four piglets in the spring.
				
				"When they grow too old to breed, we cull them for pork and leather.
				
				"As with calves, I have long thought that with some experimentation, we might be able to increase the litter size of our sows."
				*goto livestock
			#Tell me about boars.
				"As with bulls and rams, boars are male breeding swine. We put ours out to pasture for most of the year, and only bring them in during the winter."
				*goto livestock
			#I want to ask Sirid about something else.
				*goto sirid_convo_choice
			#I'm done asking questions.
				*return
	#I want to discuss infrastructure and resources.
		*label infrastructure
		
		What questions do you have about infrastructure and resources?
		*choice
			#Tell me about the meadow.
				"The meadow is perhaps the largest limiting factor on the size of the manor. The meadow produces hay—quite a bit of it—but is special because we don't have to seed that hay, and because it is typically flooded by the river in the spring. It's at just the right elevation to both be flooded and then dry enough to produce hay; we just have to mow the hay in the late summer, before we begin on the harvest proper. And hay is how we keep livestock through the winter. Without hay, there would be no way to feed the livestock.
				
				"Therefore, to truly grow the potential of the manor, you have to increase the size of the meadow. Your only real option is to claim some meadow from the fens, but that requires earthworks and irrigation systems, two things that are beyond my ken."
				*goto infrastructure
			#Tell me about the forest.
				"You have ${forest_acreage} acres of forest. The forest is valuable for multiple reasons. The first is that it supports the swine population during the fall; they get fat by rooting around in the dirt.
				
				"The forest is also where pharen and linnen hunt. Were the thorne of Ulmheit older—or should you ever be visited by the arthorne of Sturmreich—you would likely have to entertain them with a hunt. @{hunting_license You have a hunting license, allowing you to hunt five deer and one boar per year.| You can petition the thorne of Ulmheit for a hunting license in your forest, but like a dovecote, it will cost you, and such a license is limited and does not pass to your heirs.}
				
				"Of course, you are also charged with defending the forest from poachers. It is forbidden for commoners to take game of any sort from the forest, and you are charged with punishing such crimes harshly."
				*goto infrastructure
			#Tell me about the roads of the manor.
				"The manor is about five and a half square miles in total. It takes time to get from the hamlet—where the commoners live—and the fields, the pasture, the forest…. When we keep the roads clear of debris and cover over any holes, it makes the whole manor run more efficiently. The oxen in particular rely about the roads being clear and level to get to the fields in a timely manner."
				*goto infrastructure
			#Tell me about the road to Ulmheit and the docks.
				"As with the roads about the manor, the road to Ulmheit needs maintenance to keep it functioning. Additionally, there are places where it could be straightened, smoothed, or leveled to make transit to and from the village easier. Having a good road to Ulmheit means our goods can find better prices, and the goods that we purchase in turn will not be so dear.
				
				"It is the same with the docks. As you know, they were damaged in the bandit raid. @{docks_damaged Once they are fixed, goods will be| Now that they are fixed, goods can be} loaded on and off of boats there.
				
				"Neither route is better than the others; they work in tandem to make the manor more connected to the rest of the region."
				*goto infrastructure
			#I want to ask Sirid about something else.
				*goto sirid_convo_choice
			#I'm done asking questions.
				*return
	#I'm done speaking with Sirid.
		*return