Your father is dead.

The messenger shuffles her feet and looks for an exit.

"You are certain? My father? He is dead?"

"Yes, thornet…your father died at the tournament. And his sword and armore is being retained by the thorne of Yardwen…with his condolences."

"He…died?"

"The two knights were both unhorsed on the third pass, and so the joust turned to a duel. The fighting was fierce, but the thorne of Yardwen's final blow caught your father unawares, and drew blood. He acknowledged his defeat and surrendered his sword. But then the flesh around the wound grew corrupted, and three days later he was dead."

*fake_choice
	#If he defeated your father, it is his right to do so.
		*set chivalry %+25
		Though it rankles you to admit, the thorne of Yardwen is justified in keeping the sword. He won it, your father surrendered it…there is no misdeed here.
	#I would not have done the same.
		*set compassion %+25
		You would have taken pity on the family of any knight who died from such unfortunate circumstances. 
	#I silently swear that some day the thorne of Yardwen will be punished for this slight.
		*set hubris %+25
		The thorne of Yardwen's condolences mean little. His retention of your family's sword is a slight against your honor, one which must be avenged.
	*if (choice_randomtest = false) #Jump to management.
		*set name "Tansil"
		*set patronym "Horich"
		*set toponym "Quarringreivar"
		*set thurnet "Quarringreid"
		*set gender 1
		*set o_gender 2
		*set o_he "she"
		*set o_his "her"
		*set o_him "her"
		*set woodcraft +1
		*set piety %+5
		*set tactics +1
		*set hubris %+5
		*set rep_gentry %+10
		*set spendthrift %+15
		*set oxen -1
		*set ox_slaughtered true
		*set wheat -600
		*set cider -25
		*set ale -100
		*set winterSquash -50
		*set wheels -10
		*goto_scene annual_hub

Several weeks ago, your father set out for the tournament at Amerlich, hoping to find some fortune in the lists. Unfortunately, the tournaments are not without risk. Most knights wager their arms and armor on the outcome of their bouts. When they lose, they are bound by honor to ransom back their equipment; similarly, the victor is bound to maintain the equipment until the vanquished can organize the resources to make the ransom payment.
*set log "At the age of 15, you learned that you father had died in a tournament. Not only that, but his arms and armor were being held for ransom by his opponent. The winter had been hard; bandits had attacked,"

That leaves you, a youth of fifteen, the new thornet of the manor. And a new thornet without the benefit of your family's sword or a suit of armor.

You dismiss the messenger with your thanks.

*page_break

Once the messenger departs, your mother exhales. By the end, it has turned to sobs.

You mother is not given to sobbing.

*fake_choice
	#I hold her close.
		*set compassion %+5
		You hold her until the noises stop. She wipes her tears and stands.
		
		She is strong; she always has been. She will persevere.
	#I say a prayer to Odo Macanh, the patron of knights.
		*set piety %+5
		You clasp your hands, close your eyes, and intone a prayer of conveyance.
		
		You father was not a terribly religious man in life; you hope that the odos will not hold that against him in death.
	#I have to see to the staff and the tenants of the manor; the news will spread quickly.
		*set chivalry %-5
		You squeeze your mother's shoulder quickly before darting from the room. The chamberlain and cook must be silenced before the entire manor is abuzz with the news. You want to make the announcement yourself.
		
		You find the messenger in the kitchen, mid-mouthful; a meal is a customary gesture of gratitude for a messenger, but also an opportunity for the tenants to hear tales of the world beyond the manor. This instance is no different.
		
		You make it clear to the cook and the chamberlain that this news is not to leave the room until you share it.

You take a moment to reflect on your circumstances. The winter was harsh on the manor, even before this news. Bandits attacked during the month of the Bear. Your father, his good friend Mordain Cluranich, and the eorwald—Sirid Marlinich—managed to rally the serfs and the freeholders and fight them off, but not before the manor suffered losses.

What did you do during the bandit raid?
*temp first_response 0
*fake_choice
	#I fought side-by-side with my father.
		*set log & " and you fought alongside your father during the raid."
		*set first_response 2
		*set combat +1
		The fight was bloody, but the bandits were more hungry than vicious. A strong and determined showing drove them off before too much damage was done.
	#I tended the wounded.
		*set log & " and you tended the wounded during the raid."
		*set first_response 1
		*set medicine +1
		While your father and Sirid lead the charge, there were a variety of gashes and breaks that needed tending. Comfortable with linen wraps and poultices, you leapt to the task.
	#I rallied the peasants and directed their efforts.
		*set log & " and you organized the peasants to present a unified front against them."
		*set first_response 3
		*set tactics +1
		You may or may not be a warrior yourself, but you are more than capabale of reading the contours of a conflict. While your father rushed headlong towards the bandits, you directed the peasants to form up—as they have been occasionally trained to do—and advance as a unit.

Once it was clear the bandits were gone, you stopped to breathe through gritted teeth. Your arm was broken: @{first_response even though you were tending the wounded, amid the chaos an irate mule kicked you at just the right angle.| one of the bandits wielded a blacksmith's hammer; one blow from that and you heard bone snap.| one of the poorly-trained peasants managed to smash his hammer into your forearm while you were gesturing instructions.} You bit your lip and continued on at the time, but the pain could no longer be denied and you passed out to your little brother Karol's startled cry.

When the sun rose, your arm was wrapped and in a sling. You fought back the waves of pain and sought your father in order to survey the damage. The docks were severely damaged and you counted a number of broken limbs, one missing eye, two missing sheep, and one dead cottar. 

This particular cottar, a young girl by the name of Pippa, was apparently trying to make a name for herself. She was the first to spot the bandits on their approach to the manor. You are told that she let out a cry and charged, but only ended up skewered on a spear. @{first_response By the time she was brought to you, she was already dead.||}

Pippa's parents dug a grave behind the manor's shrine and the caris was asked to say a prayer. The manor's shrine to Odo Paster is a @{(piety > 50) discredit to the thurnet. Your father was always embarrassed to attend services there, so he tried to keep as many as possible to the chapel in the manorhouse. | sorry affair. You always hated attending services there—the small chapel in the manor is much warmer—but there are certain occasions when it is unavoidable.}
*set log & " During the melee, however, a young serf girl by the name of Pippa died."
*fake_choice
	#I attended the service.
		*set piety %+5
		*set academics +1
		*set manor_morale %+5
		*set log & " You attended her funeral service."
		Your father did not deign to attend the funerals of his serfs, and so Pippa's family was astonished at your appearance. You suspected that the caris even stood a little straighter than normal.
		
		In a surprising bit of sophistication, the caris manages to recall a prayer to Odo Mura, the patron of children and the innocent. The prayer seems to bring some comfort to the girl's parents.
	#I double-check the inventory of the barn, to make sure none of the serfs make off with any goods in the confusion.
		*set spendthrift %-5
		*set oats +5
		*set domestics +1
		*set log & " During her funeral, you checked the double-checked the inventory of the barn."
		The bandits may have been gone, but that didn't mean the urge to thievery was. Without a close eye, the serfs would eat all the food and drink all the ale and there would be none left for the depths of winter.
		
		During your investigations, you found a few bushels of oats which seem rather suspiciously mislaid. You set them back in their place and mentioned the problem to Sirid.
	#I joined my father as he sallied into the woods in search of the bandits.
		*set woodcraft +1
		*set hubris %+5
		*set log & " You were unable to attend, as you and your father set out into the woods in search of the bandits."
		The expedition turned up nothing, but you it was good to refresh you skills at tracking and woodcraft. It is all too easy for those to atrophy.
*page_break

But the raid was three months ago. Since then, your father staked his honor and his life on the tournament and lost. Because of your broken arm, you didn't follow your father to the tournament as his squire. Instead, Mordain went with him; the two had campaigned together in their youth and remained good friends. According to the messenger, Mordain will arrive in a few days with your father's body and the family's warhorses.

Of course, the first decision you have to make—as the new thornet—is how to honor your father. You could entomb your father in the walls of the manor's shrine, but the shrine is so paltry that it makes no sense to do so at this time. Perhaps, someday, you'll be able to afford to entomb him in a temple in Ulmheit? For now, his body will be enterred in a place of honor beside the shrine of Odo Paster.

Eventually, you will have to travel to Ulmheit and swear fealty to your father's liege, the thorne, for the right to inherit your father's title and lands. Of course, such consideration will come at a hefty price: ${manor_acreage} bushels of wheat, one for every acre of the manor. Between now and then, you technically are in violation of the law. Of course, the thorne of Ulmheit is a toddler with a mother-regent who is preoccupied with other concerns; you might have a few months or years before her ire is sufficiently raised to do anything about your breach of duty.
*set log & "[n/][n/]Your first decision as thornet was how to honor your dead father."

*temp guests 0
*fake_choice
	#Until I have paid the ransom for the family sword and armor to the thorne of Ulmheit, there is no money for anything more than a simple burial, a prayer by the caris, and a small meal.
		*set manor_morale %-10
		*set spendthrift %-10
		*set wheat -4
		*set wheels -1
		*set cider -3
		*set ale -3
		*set winterSquash -1
		*set meat -5
		*set guests 1
		*set log & " You decided to hold a quiet, family affair. You didn't even invite the serfs."
		You prevail upon the caris to be as inspiring as he can be, but the caris is a simple man. His language is simple and his concerns moreso.
		
		Afterwards, the mourners retire to the hall of the manor house for the meal. Mordain and Sirid are both surprised by the paucity of the offering, but at least Sirid understands your reasoning. 
		
		As the the meal progresses, it comes to be time for you to address the room.
		*gosub funeral_speech
		
		You suppose that your father would have been disappointed with the display, but couldn't fault you for your attention to the finances of the manor.
	#At the very least, we can send for a diom to pray for father.
		*set piety %+5
		*set rep_senan %+10
		*set wheat -8
		*set cider -10
		*set ale -20
		*set winterSquash -2
		*set wheels -3
		*set meat -20
		*set guests 2
		*set log & " You decided to hold a modest funeral, sending for a diom from Ulmheit to come and pray for him."
		A diom and her attendant macrons arrive on the same day as your father's body. Eddom the caris bows and scrapes before the diom and her attendants.
		
		The diom thanks you for your generous donation to the temple of Odo Paster. She stands in the rickety pulpit of the shrine and delivers a sermon that seems to instill a sense of peace in the peasants; Sénan will provide, even if the means of that care are unclear.
		*set manor_liquid -25
		
		After the ceremony, you host a small feast for your guests. Eventually, it comes time for you to speak.
		*gosub funeral_speech
		
		The next day, the diom and her macrons strike their tents and return to Ulmheit.
	#We should have a feast to share father's bounty with the peasants.
		*set manor_morale %+10
		*set spendthrift %+10
		*set wheat -(households / 4)
		*set cider -(households / 2)
		*set ale -(households * 3)
		*set winterSquash -40
		*set wheels -5
		*set meat -50
		*set guests 3
		*set log & " You decided to hold a small feast in his honor, so that the peasants might remember him fondly."
		It is a meagre feast, but a feast nonetheless.

		The entire manor attends—as well they should—to raise a mug of ale to the late thornet. Once everyone is gathered, it is time for you to speak.
		*gosub funeral_speech
		
		The revelry goes late into the night. There is a bonfire and signing and dancing. And a lot of ale. The next day, the tenants groan 
	#We should slaughter an ox and invite the neighboring pharen.
		*set rep_gentry %+10
		*set spendthrift %+15
		*set oxen -1
		*set ox_slaughtered true
		*set wheat -600
		*set cider -25
		*set ale -100
		*set winterSquash -50
		*set wheels -10
		*set guests 4
		*set log & " You decided to hold a feast in his honor; you ordered an ox slaughtered and invited the neighboring pharen to attend."
		In other circumstances, such a move would be ruinous. However, becuase the thorne of Ulmheit and his mother will certainly not attend, the danger is somewhat mitigated. At most, three or four neighboring thornets may accept the invitation and come seeking your hospitality.

		You send word to the neighboring thornets that a feast will be held in your father's honor. You do your best not to clench your teeth as you anticipate the cost that you will incur.
		
		*page_break
		
		Three thornets—of Fievenreid, Navarmass, and Pappervale—and their entourages arrive on the appointed day. Conveniently, it is the day after your father's body arrives; you and your mother have had a few hours to wash away the worst of the stink of death. Even so, everyone is grateful when the caris is finished with his prayers and the earth begins to cover the body.
		
		The thornet of Pappervale rolls her eyes at the whole affair, clearly unimpressed with the reception. However, the smell of the roasting ox has filled the whole hamlet with its aroma and her disdain means nothing next to the prospect of a full belly. Before you can eat, however, you must give a speech.
		*gosub funeral_speech
		
		Eventually, the feast winds to a close. The next day, the visiting thornets depart, leaving a mess of the field where they camped for the night.
*page_break

Your father is buried. The funeral is concluded. The thurnet of ${thurnet} is yours.
*set log & " And then the thurnet of ${thurnet} was yours."

*finish Begin

*label funeral_speech

"My father…"

*fake_choice
	#"Donnel…"
		*set patronym "Donnelich"
	#"Hor…"
		*set patronym "Horich"
	#"Lannard…"
		*set patronym "Lannardich"
	#"Prazter…"
		*set patronym "Prazterich"

"…was the thornet of this manor for nearly seventeen years. He was proud to serve his liege, the thorne of Ulmheit as the caretaker of…"

*fake_choice
	#"Loonreid-ye-Osterdarn…"
		*set toponym "Loonreid-ye-Osterdarnvar"
		*set thurnet "Loonreid-ye-Osterdarn"
	#"Loreneid…"
		*set toponym "Loreneivar"
		*set thurnet "Loreneid"
	#"Papperbroke-ye-Osterdarn…"
		*set toponym "Papperbroke-ye-Osterdarnvar"
		*set thurnet "Papperbroke-ye-Osterdarn"
	#"Quarringreid…"
		*set toponym "Quarringreivar"
		*set thurnet "Quarringreid"
	#"Ulmnaven…"
		*set toponym "Ulmnavenfar"
		*set thurnet "Ulmnaven"

"As his…"

*fake_choice
	#"son,"
		*set gender 1
		*set brother "brother"
	#"son," though I have never been comfortable with that designation,
		*set gender 2
		*set brother "brother"
	#"daughter,"
		*set gender 3
		*set brother "sister"
		*set he "she"
		*set him "her"
		*set his "her"
		*set hiss "hers"
		*set o_he "she"
		*set o_his "her"
		*set o_him "her"
		*set o_son "daughter"
	#"daughter," though I have never been comfortable with that designation,
		*set gender 4
		*set brother "sister"
		*set he "she"
		*set him "her"
		*set his "her"
		*set hiss "hers"
		*set o_he "she"
		*set o_his "her"
		*set o_him "her"
		*set o_son "daughter"

"…and eldest child, I pledge to uphold the family honor. I offer this bread, salt, and cider—as our father Sénan did with Quinn, Colm, Elza, and Osl on their last night in bondage—as proof, that I…"

*fake_choice
	*if gender <= 2
		#"Colm ${patronym} ${toponym},…"
			*set name "Colm"
		#"Jóren ${patronym} ${toponym},…"
			*set name "Jóren"
		#"Tansil ${patronym} ${toponym},…"
			*set name "Tansil"
		#"Tuanan ${patronym} ${toponym},…"
			*set name "Tuanan"
		#"Werden ${patronym} ${toponym},…"
			*set name "Werden"
		#"Wren ${patronym} ${toponym},…"
			*set name "Wren"
	*if gender >= 3
		#"Astrid ${patronym} ${toponym},…"
			*set name "Astrid"
		#"Cora ${patronym} ${toponym},…"
			*set name "Cora"
		#"Loone ${patronym} ${toponym},…"
			*set name "Loone"
		#"Mura ${patronym} ${toponym},…"
			*set name "Mura"
		#"Tóra ${patronym} ${toponym},…"
			*set name "Tóra"
		#"Wrenna ${patronym} ${toponym},…"
			*set name "Wrenna"
	#Something else.
		*input_text name
		"…${name} ${patronym} ${toponym},…"

"…that I, ${name} ${patronym} ${toponym} so swear it. On Sénan, Quinn, and all the odos." @{(guests = 2) The diom blesses the bread after you break it| You break the bread} and your little brother carries it around for the others to partake with the salt and cider.

@{guests Your mother, brother, Sirid, and the other guests| The diom, her macrons, and your family| Your family and the gathered tenants of the manor| Your family and your guests} raise a toast in your honor.
*return

*comment CRUFT

*temp bonus_forest
*rand bonus_forest 1 200
*temp bonus_fen
*rand bonus_fen 1 50
*temp bonus_farmland 
*rand bonus_farmland 1 100
*temp bonus_pasture
*rand bonus_pasture 1 50
*temp bonus_meadow
*rand bonus_meadow 1 20
*set manor_acreage +bonus_forest
*set forest_acreage +bonus_forest
*set manor_acreage +bonus_fen
*set fen_acreage +bonus_fen
*set manor_acreage +bonus_farmland
*set farmland_acreage +bonus_farmland
*set manor_acreage +bonus_pasture
*set pasture_acreage +bonus_pasture
*set manor_acreage +bonus_meadow
*set meadow_acreage +bonus_meadow

*page_break
*goto_scene annual_hub