*label mom_initial_convo

Your mother approaches you one summer evening. "How is your shoulder?" she inquires. You wince as you flex it.

*fake_choice
	#"It still hurts, but it gets better every day."
		*set hubris %-5
	#"It is nothing, mother."
		*set hubris %+5
	#"It is my heart that hurts, for my lost father."
		*set compassion %+5

She smiles sadly; she has long been accustomed to hardship. 

She married your father when she was young, not knowing what sort of man he was.

*fake_choice
	#She was the scion of a now-defunct linne.
		*set mother_origin 1
		*set spendthrift %-10
		Your grandfather was a thornet who held multiple fees. However, he became so indebted that the thurnets were reclaimed by their lieges and sold to the highest bidder. Of course, such auctions aren't called "auctions" or the transactions "sales," but you know them for what they are.
		
		Watching her profligate father lose all that the family had was a lesson that she swore never to repeat; she instilled a focus on frugality in you.
	#She was the third child of a thornet.
		*set mother_origin 2
		You suppose that, if a certain number of individuals died in the right order, you would inherit another fee. But that is unlikely.
		
		Life with her family was similar to here at ${thurnet}: her family lived close to the peasants, working in the fields and soldiering with them while on campaign.
	#She was born to a burgher family in Sturmreich.
		*set mother_origin 3
		*set spendthrift %-5
		*set compassion %-5
		Life in Sturmreich sounds glorious to you: the fountains, the amphitheater, the townhouses…but she has not been back since arriving in ${thurnet}.
		
		That said, she was working in the guildhall from almost the time she could speak. To help her family, she labored from morning until night. Unlike here, where the peasants are free to enjoy their meals and their leisure, she says there was no leisure there. The pace of life was unending, and it made people hard. She still holds this edge, and her impatience sometimes offends the peasants, but it has proven useful many times.
	#She was born to a yeoman family.
		*set mother_origin 4
		*set piety %+5
		Your mother was born in Navarmass, another thurnet of Ulmheit. Her father managed to scrape together the funds to send her to Ulmheit for a rotation as a macron in the temple of Odo Donel. Your father happened to be on guard duty at the same time, whereupon the two met.
		
		Though she may have married for love, she brought little to the table other than a strong work ethic. When she and your father returned to ${thurnet}, she set about helping him right the accounts of the manor.

When you were young, she took the time to impart some of what she knew to you.
*fake_choice
	*if (mother_origin != 4) #She is a fierce negotiator.
		*set trade +1
	*if (mother_origin != 2) #She is more educated than anyone else you know.
		*set academics +1
	*if (mother_origin != 3) #Her talent for managing the household was unparalleled.
		*set domestics +1
	*if (mother_origin != 1) #Her [??]
		*comment another stat bump for non-linne members.

You learned as much as you could from her. She certainly spent more time attending to your upbringing than your father did.

"You have a great task before you, ${name}. You are now the thornet. The peasants look to you for leadership. Your brother Karol's future is in your hands."

*fake_choice
	#"This is too great a task, mother. I am not prepared for it."
		*set hubris %-10
		"You have no choice. I did not raise you to shirk your duty.
	#"I care only about avenging father's death."
		*set hubris %+10
		"You must care for more than war and honor. Honor will not feed your family and your people during the long winters.
	#"Now that I have the authority to make changes, we will grow rich. Have no fear."
		*set compassion %-10
		"Greed us unbecoming on you, child. You do not realize the extent of the misfortunes that will strike you in the coming years. You may look on the accounts and think that stewardship is child's play, but I assure you that it is not.
*comment endif

"You must have a spine of iron to bear this burden. You must carry you the history of your phare, the needs of your family, and the well-being of your tenants until it is time for someone else to take up this burden. Can you do that?"

"Yes, mother."

"Good. Now, let us…"

*fake_choice
	#"…give praise to Sénan for all his gifts."
		*set piety %+20
		Your mother clasps your hands and says a short prayer to Sénan. She has never entertained questions outside the orthodoxies of the faith.
	#"…thank all the gods: the gods above and the gods below; the gods around and the gods about."
		*set orthodoxy %-20
		Your mother prays to the Sénan, but also to Pallerian and Siriol, as well as the gods of the forest and the field, the family and the hearth.
	#"…remember you father, who sacrificed so much for us."
		*set hubris %-10
		*set piety %-10
		Memories of your father—the smell of his beard, the gruff and gravely sound of his voice—rises from within you. You hold back a well a tears, and clasp your mother's hands in sympathy.

After a few moments more of silence, your mother continues: "There is also the matter of your brother. You must consider his future. At the very least, he is old enough now to begin contributing to the household."

You could hire a tutor, but that will be expensive. However, with an education, the path of the church would be opened to him. Relatedly, you could take him as your page. This too would cost you, but not as much as a tutor. You could ask Mordain to teach him how to fight, but he will not learn the customs of the pharen from him and that will lower you in the esteem of your peers. You could send him to study with ${eorwald_inf}, where he would learn how to administer the manor. Finally, you could commend him to the care of your mother, which would be the least costly. With her, he would learn about the administration of the manorhouse.

*fake_choice
	#"Let us send for a tutor, so that he might become educated."
		"Very well. I will write to the eorwald of Ulmheit; if there is a sage in the region seeking employ, he will know."
		
		She bids you goodnight.
		*page_break
		*set karol_status "student"
		*set servant_pop +1
		*set karol_support 30
		*set rep_gentry %+5
		Some weeks later, a young man appears on the road from Ulmheit. His beard is red and curly. You introduce him to Karol and the two spend some time squaring off.
		
		The tutor, Eddarn Eomarrich, thanks you for his employment and promises to impart as much of what he knows of the world to Karol as possible.
		*return
	#"I will take him as my page. Some day he will become a squire and then a knight."
		*set karol_status "page"
		*set karol_support 20
		*set rep_gentry %+10
		*set page true
		*set page_he "he"
		*set page_him "him"
		*set page_his "his"
		*set page_name "Karol Hardanich"
		*set page_inf "Karol"
		"But we do not have the resources to field two knights."
		
		"That is at least ten, twelve years from now. Who knows what the future will hold."
		
		Your mother purses her lips and nods her assent.
		
		Karol seems excited by the idea of being your page and he is eager to officially join the exercises of the militia.
		*return
	#"I will ask Mordain to train him to fight."
		*set karol_support 15
		*set rep_gentry %-10
		*set manor_morale %+5
		"Mordain will teach Karol how to fight, but not the other responsibilities of a knight."

		"I think it is the best option, mother."

		Karol's eyes go wide when you tell him that he will begin training with the leathery farmer. He has seen Mordain knock other serfs flat with a single blow; you doubt that he will have any problems with discipline.
		*return
	#"The peasants will be cheered to see Karol learning from one of them; let us give him to ${eorwald} for his education."
		*set manor_morale %+5
		*set karol_support 10
		"Very well. I will leave the arrangements to you. ${eorwald_inf} will do ${eorwald_his} best, I'm sure."
		
		"Yes, ${eorwald_he} will. Good night, mother."
		*return
	#"Mother, we cannot afford any further expenses. You will have to train him in the ways of the manor."
		*set spendthrift %-10
		*set hubris %-5
		*set rep_gentry %-10
		*set karol_status "domestic"
		*comment TODO set tempDomEfficiency to reflect Karol's attentions.
		She nods. "I feared that would be your decision. I shall do my best."
		
		She bids you goodnight. Tomorrow, Karol will be put to work in the kitchens for the first time.
		*return

*label reflection_on_pcs_confirmation
*set first_year false
Your first harvest is now stored away. You collapse into your bed, exhausted. Strangely, you find sleep elusive. You recount the events of the day, the week, the season, the months since your father's passing…until finally your eyes light upon the box that holds the your nodi. You remember the first time you were allowed to touch them, at your confirmation.

It was only two years before your father's death; you remember it clearly. Your father enticed a diom from Ulmheit to come and officially recognize you as an adult. It was a small ceremony in the manor chapel, with Sirid and a few other officials of the manor.

At the time…
*fake_choice
	#I only participated reluctantly. I saw no signs of Sénan in my life; why should I honor him?
		*set piety %-20
		During the ceremony, your wrists are tied with your family's nodi. They bite against your flesh while the diom intones the prayers of incorporation.
		*gosub nodi

		Thankfully, the diom kept the ceremony short; the nodi are soon unwound from your wrists, which you immediately rubbed in an effort to banish the discomfort. 

		Over dinner, the diom tried to engage you in conversation, urging you to relate your favorite tale of the odos. After much prompting, 
		*if academics > 1
			you finally began relating the story of Odo Astrid, the diom cut you off and changed the subject.
		*if academics <= 1
			@{(chivalry >= 50) you began to relate the Final Stand of Odo Macanh. Even if the tale is exaggerated, it is easy to remember.|you begin to relate the tale of Odo Meguil and his invention of accounting. It is the driest of tales, and you are soon interrupted by more lively fare.}
	#I was proud to be recognized as an adult by the community.
		*set chivalry %-20
		During the ceremony, your wrists are tied with your family's nodi. They bite against your flesh while the diom intones the prayers of incorporation.
		*gosub nodi
		
		Returning your attention to your surroundings, you snap to attention; you are proud of both your family, your people, and your place in the great system of things. The trappings of religion were incidental to those concerns.
	#I stayed up all night before, keeping a vigil over the family nodi.
		*set piety %+20
		*gosub nodi
		
		You commit yourself to prayer and reflection, pondering the sacrifices of your ancestors in the name of Sénan and his odos through the length of the darkness.

		When morning comes, you stand straight and tall as the diom winds the nodi around your wrists as the first stage of the ceremony. When all is said and done, you break your fast with bread, salt, and cider, and the officials of the community clap and cheer in appreciation.
	#I wondered why the shrine only honored Sénan. What of all the other gods and goddesses?
		*set orthodoxy %-30
		What of Siriol and Pallerian? Varnasia and Lathron?

		You were told in no uncertain terms by your mother that you should not mention the other gods during the ceremony.

		But when the caris finishes his prayer and taps his foot sharply, you jerk to attention and perform the rites that are required of you.
And so you were recognized as an adult of the Quinn, with all the rights and responsibilities that that entailed.

With a small smile, you turn over, pushing away the sight of the box and the thoughts of the past.
*return

*label nodi
The family nodi have been passed down since before even Sirid Quarringrich marched with Adeline Jarlich Sturmreich. Connected by a length of oft-replaced leather, the string of nodes tells the story of your family. The one your father was most proud of was made of carved wood and bearing the sign of a lance, which he purchased from an odoma of Macanh outside of Amerlich. Several of the oldest ones, also wood, bear the shepherd's crook, the sign of Odo Paster; some of them may predate the granting of ${thurnet} to your great-grandmother. There is even an iron node that your grandmother purchased at the odoma of Cluranh in Hisbroke, acquired when she completed her pilgrimage there. Most amazing of all is a bright blue one made of glass. Your mother contributed it to the collection, but she has always avoided explaining its history; at some point, years ago, you simply stopped asking.
*return


*label karol_aged_out
Your brother Karol is now fourteen. It is time for his confirmation.

*fake_choice
	#The caris can perform the rite and we can do it the day of the summer feast; there is no reason to go to any unnecessary expense.
		*set manor_morale %-5
		*set karol_rapport %-10
		*set spendthrift %-25
		The ceremony is sparse, even moreso than your own. A few officers of the manor attend, but otherwise the ceremony is subdued.

		Karol is disappointed, certainly. But you justify it to yourself with the thought that you are saving for the family's future.
	#I entreat a diom to visit from Ulmheit to perform the rite.
		*set wheat -30
		The diom visits—the same one that performed your confirmation nine years ago—and you greet him warmly.

The ceremony proceeds much as it did before. Karol stands tall and proud, his wrists bound with @{(hubris > 50) your| the family's} nodi. The now-familiar prayers are intoned and 

*page_break
Now is an appropriate time to consider his future.

You could send him to Ulmheit to take the vows of a macron. Many young pharen serve a three year stint as a macron, serving the church in exchange for some academic training, as well as pratical training and the opportunity to develop friendships with other young pharen. Of course, you would have to compensate the temple for Karol's living expenses and needs during the time, but everyone says that the investment is worth it.

Of course, you could also send Karol to court, to serve as a squire to another knight. This too would allow him to develop friendships with other young pharen, in addition to learning the arts of war and chivalry.

*choice
	#I want to send him to Ulmheit to serve as a macron.
		*set karol_status "macron"
		*set karol_support 120
		*set rep_senan %+10
		Karol packs his things—such as they are—and says goodbye to you and mother. He is grateful for this opportunity.

		Your mother sheds no tears. She has long since drained that well.
		*return
	*if knight and (karol_status != "squire")
		#I want to take him as my squire.
			*set karol_status "squire"
			*set rep_gentry %+5
			*set squire "Karol Hardanich"
			*set squire_support 60
			*set squire_him "him"
			*set karol_support 0
			Karol is thrilled with the
			*return
	*if knight and (karol_status = "squire")
		#I will keep him as my squire.
			What would you do without him?
			*return
	*if (rep_ulrich > 45) #I will send him to squire for a knight in the household of the thorne.
		*set karol_status "squire_ulmheit"
		*set karol_support 140
		*set rep_gentry %+10
		*set rep_ulrich %+5
		Karol packs his things—such as they are—and says goodbye to you and mother. He is grateful for this opportunity.

		Your mother sheds no tears. She has long since drained that well.
		*return