*temp event 0
*temp desc 0
*rand desc 1 4
*gosub_scene subs calamity_rand
*temp longWinterLength 0
*rand event 1 100
*comment kid gloves for starting out
*if year < 571
	*set event -60
*if (year >= 571) and (year < 576)
	*set event -40
*if (year >= 576) and (year < 580)
	*set event -20
*label which_calamity
*goto {calamity}

*comment *page_breaks are under the *labels, because the "annual activity" doesn't have a closing *page_break. Will help resolve *rand issue, and give a little more freedom for descriptions.

*label 0
*bug no calamity
*return

*label 1
*comment illness
*page_break
*set seasons_since_calamity 0
*if calamity_season = 1
	*if event < 40
		*set weather_index * 0.9
		*set weather_index +(medicine * 0.02)
		*set log & " That spring, several serfs fell ill, but soon recovered."
		When the plowing season arrives, you notice that several of the serfs are looking…drawn. It soon becomes clear that some sort of contation has settled upon them and those that fall ill are weakened by insististen diarrhea. @{(medicine > 0) You do your best to help alleviate the symptoms. All the same, the| The} plowing will suffer from the distracted workforce.
		*if landless_pop > 10
			*set landless_pop -1
		*return
	*elseif event < 80
		*set weather_index * 0.8
		*set weather_index +(medicine * 0.02)
		*set log & " That spring, several serfs fell very ill, but most eventually recovered."
		During the middle of the plowing season, a fever strikes the serfs. It interrupts the plowing and claims the lives of several of them. @{(medicine > 0) You do your best to help alleviate the symptoms. All the same, the| The} plowing will suffer from the distracted workforce.
		*set hv_pop -2
		*set hv_child_pop -1
		*set cottar_pop -1
		*set cottar_child_pop -1
		*if landless_pop > 10
			*set landless_pop -2
		*return
	*else
		*set weather_index * 0.7
		*set weather_index +(medicine * 0.02)
		*set log & " That spring, several serfs fell violently ill, and there were numerous deaths."
		TODO severe spring illness
		*set trade_pop -4
		*set trade_child_pop -2
		*set villein_pop -14
		*set villein_child_pop -7
		*set hv_pop -28
		*set hv_child_pop -15
		*set cottar_pop -8
		*set cottar_child_pop -4
		*set fisher_pop -3
		*set fisher_child_pop -1
		*if landless_pop > (servant_pop + 4)
			*set landless_pop -4
		*return
*elseif calamity_season = 2
	*if event < 40
		*set weather_index * 0.85
		*set weather_index +(medicine * 0.02)
		*set log & " That summer, several serfs fell ill, but soon recovered."
		As harvest approaches, you notice that several of the serfs are looking…drawn. It soon becomes clear that some sort of contagion has settled upon them and those who fall ill are weakened by insistent diarrhea. @{(medicine > 0) You do your best to help alleviate the symptoms. All the same, the| The} harvest will suffer from the distracted workforce.
		*if landless_pop > 10
			*set landless_pop -1
		*return
	*elseif event < 80
		*set weather_index * 0.75
		*set weather_index +(medicine * 0.02)
		*set log & " That summer, several serfs fell very ill, but most eventually recovered."
		As the time for mowing the meadow arrives, a fever strikes the serfs. It delays the mowing and claims the lives of several of them. @{(medicine > 0) You do your best to help alleviate the symptoms. All the same, the| The} mowing will suffer from the distracted workforce.
		*set hv_pop -2
		*set hv_child_pop -1
		*set cottar_pop -1
		*set cottar_child_pop -1
		*if landless_pop > 10
			*set landless_pop -2
		*return
	*else
		*set weather_index * 0.65
		*set weather_index +(medicine * 0.02)
		*set log & " That spring, several serfs fell violently ill, and there were numerous deaths."
		TODO severe summer illness
		*set villein_pop -18
		*set villein_child_pop -9
		*set hv_pop -30
		*set hv_child_pop -17
		*set cottar_pop -8
		*set cottar_child_pop -4
		*set trade_pop -4
		*set trade_child_pop -2
		*if landless_pop > (servant_pop +4)
			*set landless_pop -4
		*return
*elseif calamity_season = 3
	*if event < 40
		*set weather_index * 0.9
		*set weather_index +(medicine * 0.02)
		*set log & " That summer, several serfs fell ill, but soon recovered."
		TODO light fall illness
		*if landless_pop > 10
			*set landless_pop -2
		*return
	*elseif event < 80
		*set weather_index * 0.8
		*set weather_index +(medicine * 0.02)
		*set log & " That fall, several serfs fell very ill, but most eventually recovered."
		During the middle of the harvest, a fever strikes the serfs. It interrupts the reaping, claiming the lives of several of your tenants in the process. @{(medicine > 0) You do your best to help alleviate the symptoms. All the same, the| The} harvest will suffer from the distracted workforce.
		*set hv_pop -2
		*set hv_child_pop -1
		*set cottar_pop -1
		*set cottar_child_pop -1
		*if landless_pop > 10
			*set landless_pop -2
		*return
	*else
		*set weather_index * 0.7
		*set weather_index +(medicine * 0.02)
		*set log & " That fall, several serfs fell violently ill, and there were numerous deaths."
		A villein returns from Ulmheit in the month of the Dragon already flush with fever. Unfortunately, you are summoned too late to stop the contagion from spreading. You order the infected homes to be marked and the residents to stay inside at all costs, only emerging to bring out the dead.
		
		It takes weeks before the fever burns itself out. Dozens of people die—mostly children—burnt up by fever and emptied of fluids. Their bodies are burned in a pyre at the edge of the manor.
		*set villein_pop -18
		*set villein_child_pop -9
		*set hv_pop -30
		*set hv_child_pop -17
		*set cottar_pop -8
		*set cottar_child_pop -4
		*set trade_pop -4
		*set trade_child_pop -2
		*if landless_pop > (servant_pop +4)
			*set landless_pop -4
		*return
*else
	*if event <= 20
		*set log & " That winter, several serfs fell ill, but almost all soon recovered."
		You are warm in your hall, but you hear word that the serfs have fallen ill. In the middle of the winter like this, there is no delay to their work, but still, the illness claims the lives of a handful of the young and the elderly.
		*set villein_pop -1
		*set cottar_pop -1
		*set cottar_child_pop -1
		*if landless_pop > 10
			*set landless_pop -1
		*return
	*elseif event <= 80
		*set log & " That winter, several serfs fell very ill, but most eventually recovered."
		You've always found the month of the Vulture to be appropriately named. This year is no different.
		
		It begins with sniffles and coughs among the serfs. Then you hear from ${eorwald_inf} that several have become bedridden. Then the deaths begin.
		
		There are deaths due to illness every winter, but this contagion claims more than its fair share. @{(medicine > 0) You do your best to help alleviate the symptoms, but there is only so much that can be done.|} The caris is busy with funeral services for several weeks.
		*set villein_pop -7
		*set villein_child_pop -3
		*set hv_pop -11
		*set hv_child_pop -6
		*set cottar_pop -2
		*set cottar_child_pop -1
		*if landless_pop > 10
			*set landless_pop -2
		*return
	*else
		*set log & " That fall, several serfs fell violently ill, and there were numerous deaths."
		TODO severe winter illness
		*set villein_pop -18
		*set villein_child_pop -9
		*set hv_pop -30
		*set hv_child_pop -17
		*set cottar_pop -8
		*set cottar_child_pop -4
		*set trade_pop -4
		*set trade_child_pop -2
		*if landless_pop > (servant_pop +4)
			*set landless_pop -4
		*return


*label 2
*comment dead calf
*if (calves = 0) or (cows = 0)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set seasons_since_calamity 0
*comment the survival rate for calves is only 80%. This "event" test below should really be lower, but I can't be bothered.
*comment well, by adding the possibility of hitting this calamity multiple times during the year, I hope it has better reality-reflection.
You are summoned to the ${cattle_pasture} one night.
*if annual_focus = "livestock"
	*set event -(husbandry * 5)
*if event < 20
	It's a false alarm. ${dairymaid} the dairymaid thought that one of the cows was in distress, but the matter seems to have passed. @{(compassion < 50) You chastise her for waking you needlessly| You thank her for her diligence} and return to your bed.
	*return
*else
	*if calamity_season = 1
		*set deadCalf true
		*if desc <= 2
			*set log & " That spring, one of the calves died unexpectedly."
			When you arrive, you find a cow lowing mournfully. The calf that was born last week is already cold.
	
			There is nothing to be done.
			*return
		*else
			*set log & " That spring, one of your calves was stillborn."
			When you arrive, you find a stillborn calf in a pile of hay. @{(compassion > 50) You try to comfort the dam while ${dairymaid} takes away the carcass.| You direct ${dairymaid} to dispose of the carcass and return to your bed.}

			There is nothing to be done.
			*return
	*elseif calamity_season = 2
		*set deadCalf true
		*set log & " That summer, your bull killed one of your calves."
		When you arrive, @{(bulls > 1) a|the} bull is stomping and huffing. There's a corpse of a young male calf laying nearby.

		It is almost an hour before the bull calms down enough that you can remove the carcass. The direct ${dairymaid} to dispose of it and head back to your bed.
		*return
	*elseif (yearlings > 0)
		*set hay +yearlingConsump
		*set deadYearling true
		*set yearlings -1
		*set log & " That fall, one of your yearlings developed a growth on its face; you had to put it down."
		One of the calves you had intended to keep into the spring as a yearling has developed some sort of growth on its face. ${dairymaid} wants nothing to do with the creature.
		
		You slaughter the poor animal yourself and direct for its body to be burned. At least you will retain the hay that would have fed the creature.
		*return
	*else
		*set cows -1
		*set hay +cowConsump
		*set log & " That winter, one of the cows developed some sort of illness. You put it down before it spread to any of the others."
		One of the cows has fallen ill. Before the illness can spread to the rest of the cattle, you order it slaughtered and the carcass disposed of.
		
		At least you will retain the hay that would have fed the poor creature.
		*return
		

*label 3
*comment rats
*if (((wheat + oats) + barley) + rye) < 300
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set seasons_since_calamity 0
*if barncat
	*set event -30
*if annual_focus = "crops"
	*set event -10
	*set event -(2 * agriculture)
*set event -(2 * agriculture)
*if event <= 25
	*set log & " That @{calamity_season spring|summer|fall|winter}, you had a rat infestation. It depleted your stores."
	It's the smell that draws your attention. @{grain_infested_by_rats You've smelled it before.|} Slipping deeper into the barn, you turn a corner and accidentally kick a sack of wheat. When you do, several rats go skittering away across the floor. @{barncat The barn cat must be sleeping on the job.|}
	
	Rats are a serious threat to the functioning of the manor. They love to eat grain, and even if they don't eat at all, they ruin it by pissing and defecating in it.
	
	Cleaning the barn and investigating the extent of the loss is going to be a time-consuming process, only adding to the actual ruined grain. You order it done.
	*set laborDays -100
	*if wheat < 400
		@{calamity_season The thought occurs to you that you may not have enough food to make it through the spring and summer.| This is a critical juncture, but you suppose better than any other. Though everyone will be hungry, the harvest is about to be brought in.| It is the worst possible time for this: the entire crop for the year had just be laid up.| It will be a long year, trying to survive through three seasons on what stores will survive this pestilence.}
	*if wheat > 0
		*set wheat * 0.7
		*set oats * 0.9
		*set barley * 0.9
		*set rye * 0.9
	*if (calamity_season = 3)
		*set annual_manor_morale %-5
	*set rat_calamity_index * 0.9
	*set grain_infested_by_rats true
	*return
*elseif event <= 50
	*set log & " That @{calamity_season spring|summer|fall|winter}, you had a rat infestation. It significantly reduced your stores."
	@{grain_infested_by_rats "What can I do for you, ${eorwald_inf}?" you inquire. $!{eorwald_he} looks upset.|"What's that smell?" you ask ${eorwald_inf}.}
	
	"Rats."
	
	"Mazuran take them…" you curse.
	
	Rats have taken up residence in the barn and getting them out @{grain_infested_by_rats again|} will be a challenge. @{barncat You're going to have to have a stern conversation with the barn cat about sleeping on the job.|} You order the cleanup to begin.
	*set laborDays -150
	*if wheat < 400
		@{calamity_season The thought occurs to you that you may not have enough food to make it through the spring and summer.| This is a critical juncture, but you suppose better than any other. Though everyone will be hungry, the harvest is about to be brought in.| It is the worst possible time for this: the entire crop for the year had just be laid up.| It will be a long year, trying to survive through three seasons on what stores will survive this pestilence.}
	*if wheat > 0
		*set wheat * 0.6
		*set oats * 0.8
		*set barley * 0.8
		*set rye * 0.8
	*if (calamity_season = 3)
		*set annual_manor_morale %-5
	*set rat_calamity_index * 0.8
	*set grain_infested_by_rats true
	*return
*elseif event <= 75
	*label winter_rats
	*set log & " That @{calamity_season spring|summer|fall|winter}, you had a rat infestation. It severely reduced your stores."
	The grain stores have been infested with @{grain_infested_by_rats rats, again| rats}. The serfs try to sort the good from the ruined wheat, but in the end, you have to burn a significant portion of your stores.
	
	*set laborDays -200
	*if wheat < 400
		@{calamity_season The thought occurs to you that you may not have enough food to make it through the spring and summer.| This is a critical juncture, but you suppose better than any other. Though everyone will be hungry, the harvest is about to be brought in.| It is the worst possible time for this: the entire crop for the year had just be laid up.| It will be a long year, trying to survive through three seasons on what stores will survive this pestilence.}
	*if wheat > 0
		*set wheat * 0.5
		*set oats * 0.7
		*set barley * 0.7
		*set rye * 0.7
	*if (calamity_season = 3)
		*set manor_morale %-5
	*set rat_calamity_index * 0.7
	*set grain_infested_by_rats true
	*return
*elseif calamity_season != 4
	*if grain_infested_by_rats = false
		*gosub_scene subs calamity_rand
		*goto which_calamity
	*set log & " That @{calamity_season spring|summer|fall|winter}, you had a rat infestation. It drastically reduced your stores, and even necessitated the replacement of the barn."
	The rats have returned. Only this time, they managed to nest in the walls, the rafters, and under the floorboards. The whole building is rotten; your only option is to burn it to the ground and build another.
	
	The serfs treat it as a celebration and open a few casks of ale. You suppose you can't begrudge them the levity; the next few weeks are going to be a burden on all of you as you rebuild it. Not to mention the tax on your stomachs.
	
	*gosub replace_barn
	*set rat_calamity_index * 0.6
	*set grain_infested_by_rats true
	*return
*else
	*goto winter_rats

*label 4
*comment fire
*page_break
*set seasons_since_calamity 0
*if bell
	*set event -20
*if event <= 20
	*set log & " That @{calamity_season spring|summer|fall|winter}, there was a fire, and a cottar family lost their home."
	During your evening meal, you hear @{bell the bell clang anxiously|a shout}. Stepping out from your hall, you see that one of the cottars' homes has caught fire. @{bell Alerted by the bell, the| The} serfs prevent the fire from leaping to any of the other thatched roofs, but there is nothing they can do about the one that is already a roaring inferno.
	*set cottar_households - 1
	*set households -1
	*set houses - 1
	*return
*elseif event <= 60
	*set log & " That @{calamity_season spring|summer|fall|winter}, there was a fire, and a cottar family lost their home and two of them died."
	During your evening meal, you hear @{bell the bell clang anxiously|a shout}. Stepping out from your hall, you see that one of the cottars' homes has caught fire. @{bell Alerted by the bell, the| The} serfs prevent the fire from leaping to any of the other thatched roofs, but there is nothing they can do about the one that is already a roaring inferno.
	
	You later learn that a child was trapped in the blaze; his mother tried to brave the flames to save him, but succumbed to the heat and smoke herself.
	*set cottar_households - 1
	*set households -1
	*set houses - 1
	*set cottar_pop -2
	*set cottar_child_pop -1
	*return
*elseif (hay > 2000) and (calamity_season != 4)
	*set log & " That @{calamity_season spring|summer|fall|winter}, there was a dangerous fire. The barn was destroyed, and you lost a significant portion of your hay."
	The barn—full of hay that it is—is a firetrap just waiting for a spark. There are a number of thing that you and your people do to prefer fires from happening, but none of them are foolproof. @{bell And even the churchbell can only alert the community once the fire has already begun.|}

	Today just happens to be that day.

	The serfs do their best to put out the fire and save the animals. In the end, you only lose the hay and the barn. It will take some effort to erect a new one, but you will have to wait until harvest time to begin to replace the hay.
	*gosub replace_barn
	*if hay <= 3000
		*set hay -1500
	*if hay > 3000
		*set hay / 2
	*return
*else
	*comment TODO add bakery or mill fire??
	*set log & " That @{calamity_season spring|summer|fall|winter}, there was a dangerous fire. Several houses burned down and a handful of serfs died."
	TODO bad fire
	*set cottar_households - 1
	*set hv_households -1
	*set households -2
	*set houses - 2
	*set cottar_pop -2
	*set cottar_child_pop -1
	*set hv_pop -3
	*set hv_child_pop -1
	*return
	

*label 5
*comment poachers
*if poachers_about or (calamity_season = 4)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set seasons_since_calamity 0
*set poachers_about true
*if calamity_season = 1
	*if event <= 40
		*set log & " TODO spring poachers."
		TODO spring poachers
		*return
	*else
		*if page = ""
			*goto poached_sow
		*set log & " That spring, you discovered evidence of poachers in the forest."
		You've been cooped up on the manor grounds for too long. You call for ${page} to join you at the stables. You mount your palfrey and set out for a ride in the forest, ${page} trotting along at your side. It's a beautiful Sparrow morning and the forest air invigorates you.
		
		Some miles later, ${page}'s cry of pain shatters the peace.
		
		"What's happened?"
		
		"A trap, thornet."
		
		"A trap?"
		
		"It's caught my foot."
		
		"Are you hurt?"
		
		"More surprised, thornet. Just give me a moment," ${page_he} says as ${page_he} draws a knife and cuts himself free.
		
		$!{page_he} brings the remains of the trap to you. It's a crude affair, designed to trip and maim a deer. @{(compassion > 55) "You're lucky you didn't break a leg," you observe.|}
		
		"Poachers?" ${page} inquires.
		
		"Certainly." You scan the path in both directions, but you spot no other evidence. "Come, let us continue with our ride. We can deal with this thieves later."
		*return
*elseif calamity_season = 2
	*if event < 20
		*set log & " That summer, you discovered evidence of poachers in the forest."
		Out for a walk one afternoon in the forest, you hear a commotion. It sounds like a bird in distress.
		
		Pushing through the bush, you find a pheasant trapped in a snare. @{(falcons = 0) Though you have no falcons with which to hunt, that is how you would bring down fowl.| If you were hunting fowl, you would use a falcon}. A snare like this is the work of a poacher.
		
		You break the pheasant's neck and unwrap it from the snare. With the pheasant over one shoulder and the dismantled snare over the other, you turn for home.
		*return
	*else
		*set log & " That summer, TODO."
		TODO ??
		*return
*else
	*if event <= 50
		*label poached_sow
		*set sows -1
		*set log & " That @{calamity_season spring|summer|fall|winter}, you discovered the remains of a poached sow in the forest."
		${swineherd} the swineherd finds you in the fields. $!{swineherd_he} informs you that there is a dead sow in the forest. $!{swineherd_he} urges you to follow him.
		
		You put down your threshing-flail and follow.
		*page_break
		A few miles later, ${swineherd} points out the body of the sow. A pair of arrows still stand out from its side and is missing one haunch. "Poachers?"
		
		"I believe so, thornet."
		
		"Did you see them?"
		
		"Not closely. When I realized what they were doing, I started yelling and they ran."
		
		"Thank you for showing me, ${swineherd}."
		*set deadLeather +(swineLeatherYield * 0.5)
		
		You hurry back to the fields; the harvest can't wait on a dead sow.
		*return
	*else
		*set log & " That @{calamity_season spring|summer|fall|winter}, you discovered the remains of a poached sow and its piglets in the forest."
		*set sows -1
		*set piglets -3
		TODO more poachers
		*return

*label 6
*comment bandits
*gosub_scene subs calamity_rand
*goto which_calamity
*set log & " TODO bandits."
TODO bandits
*return

*label 7
*comment bad_weather
*page_break
*set seasons_since_calamity 0
*if calamity_season = 1
	*if event <= 20
		*set weather_index * 0.90
		*set log & " That spring, there was a late frost, which damaged some of the early plantings."
		At the very beginning of the month of the Lamb, there is a late frost. It damages some of the earliest plantings of the season.
		*goto smooth_weather_index
	*elseif event <= 40
		*set weather_index * 0.85
		*set log & " That spring, there was an early rain, which damaged some of the early plantings."
		The rains of the spring are longer and harder than they should be. Some of the topsoil is washed away, exposing the grain underneath.
		*goto smooth_weather_index
	*elseif event <= 80
		*set weather_index * 0.80
		*set log & " That spring, there was a late frost, which damaged the early plantings."
		A late frost strikes in the month of the Lamb, taking a notable portion of your crop before the summer even arrived.
		*goto smooth_weather_index
	*else
		*set weather_index * 0.75
		*set log & " That spring, TODO."
		TODO bad spring weather
		*goto smooth_weather_index
*elseif calamity_season = 2
	*if event <= 20
		*set weather_index *0.90
		*set log & " That summer, the weather was just too hot; some of the crops were damaged."
		The heat of the summer is just a little too long and a little too hot.
		*label smooth_weather_index
		You do everything that you can to mitigate the damage, but there's only so much that can be done.
		*if agriculture > 0
			*set weather_index +(agriculture * 0.1)
			*if annual_focus = "crops"
				*set weather_index +(agriculture * 0.1)
		*if weather_index > 1
			*set weather_index 1
			*set calamity_event false
			In the end, though, you think that you saved the crops.
		*return
	*elseif event <= 60
		*set weather_index * 0.8
		*set log & " That summer, the storms damaged some of the crops."
		A bank of stormclouds arrives with the month of the Stallion. It is time to mow the hay, but it won't dry in the rain. And the crops are very much in danger as well.
	
		After two weeks, the stormclouds finally break.
		*goto smooth_weather_index
	*else
		*set weather_index * 0.7
		*set log & " That summer, TODO."
		TODO bad summer weather
		*goto smooth_weather_index
*elseif calamity_season = 3
	*if event <= 40
		*set weather_index * 0.9
		*set log & " That fall, the heat was just too hot; some of the crops were damaged."
		The summer heat doesn't break until almost the end of the month of the Stallion. The crops start to wilt before you're quite ready to harvest them.
		*goto smooth_weather_index
	*elseif event <= 80
		*set weather_index * 0.8
		*set log & " That fall, early fall storms damaged some of the crops."
		A vicious rainstorm sweeps down out of the mountains from the north, a bit earlier than usual, and washes away some of the harvest before it can be collected.
		*goto smooth_weather_index
	*else
		*set weather_index * 0.7
		*set log & " That fall, a tornado touched down in the fields just before harvest, damaging the crops."
		A tornado touches down in the fields, right before the harvest. It tears through the meadow and the fields, ripping up grains and vegetables indiscriminately. Thankfully, no one is hurt, but the damage to the crops is substatial.
		*goto smooth_weather_index
*else
	*if event <= 20
		*set longWinterLength 7
		*set log & " Winter lasted longer than expected, and required 7 extra days of hay and crops to feed the livestock."
		The winter this year is longer and harder than you had anticipated. You are forced to go into you stores to feed the livestock of the manor through the extra days.
		
		*gosub longWinter
		*return
	*elseif event <= 40
		*set longWinterLength 14
		*set log & " Winter lasted longer than expected, and required 14 extra days of hay and crops to feed the livestock."
		The winter this year is longer and harder than you had anticipated. You are forced to go into you stores to feed the livestock of the manor through the extra days.
		
		*gosub longWinter
		*return
	*elseif event <= 60
		*set longWinterLength 21
		*set log & " Winter lasted longer than expected, and required 21 extra days of hay and crops to feed the livestock."
		The winter this year is longer and harder than you had anticipated. You are forced to go into you stores to feed the livestock of the manor through the extra days.
		
		*gosub longWinter
		*return
	*elseif event <= 80
		*set longWinterLength 28
		*set log & " Winter lasted longer than expected, and required 28 extra days of hay and crops to feed the livestock."
		The winter this year is longer and harder than you had anticipated. You are forced to go into you stores to feed the livestock of the manor through the extra days.
		
		*gosub longWinter
		*return
	*else
		*set longWinterLength 46
		*set log & " Winter lasted longer than expected, and required 46 extra days of hay and crops to feed the livestock."
		The winter this year is longer and harder than you had anticipated. You are forced to go into you stores to feed the livestock of the manor through the extra days.
		
		*gosub longWinter
		*return

*label 8
*comment guard_service
*if at_war or (swore_fealty = false)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set log & " TODO guard service."
TODO guard service in Ulmheit.
*return

*label 9
*comment dead_warhorse
*if at_war or (knight = false)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*if calamity_season <= 2
	During a militia exercise with the serfs in the month of the @{(calamity_season = 1) Sparrow|Hawk}, one of the serfs spooks your warhorse. It twists at just the wrong angle, 
	*if ((husbandry > 1) and (event < 50))
		*set log & " That @{calamity_season spring|summer|fall|winter}, your warhorse almost meets an untimely end during training with the serfs."
		and is about to break meet an untimely end due to a broken leg, but your sure hand manages to pull the animal out of its dive.
		
		The horse gives a loud whinny and shakes its head. You pat it on the neck and whisper sweet nothings in its ear while glaring at the downcast serf. You send the serf to the back of the formation and restart the drill.
		*return
	*else
		*set log & " That @{calamity_season spring|summer|fall|winter}, your warhorse was injured during training with the peasants. You had to put the animal down and buy a new one."
		slips into a ditch, and breaks its leg with a sickening crunch.
		*set seasons_since_calamity 0
	
		There is nothing to do but put the animal down and buy another one.
		*comment TODO JUDGEMENT against serf?
		*set manor_liquid -(300 / trade_efficiency)
		*set deadLeather +(horseLeatherYield)
		*return
*elseif calamity_season = 3
	*set seasons_since_calamity 0
	*set log & " That fall, one of your warhorses falls ill and does not recover. You have to send for another."
	Once the harvest is done, you are able to take your coursers out for exercise again. One afternoon, however, you find that one has fallen ill. ${dairymaid} and ${swineherd} do their best to keep it alive, but their knowledge of horses is limited.
	
	When spring comes you will have to purchase another.
	*set manor_liquid -(300 / trade_efficiency)
	*return
*else
	*set seasons_since_calamity 0
	*set log & " That winter, one of your warhorses falls ill and does not recover. You have to send for another."
	During the winter, one of the warhorses falls ill. ${dairymaid} and ${swineherd} do their best to keep the courser alive, but to no avail.
	
	When spring comes you will have to purchase another.
	*set manor_liquid -(300 / trade_efficiency)
	*return

*label 10
*comment dead_palfrey
*page_break
*if calamity_season <= 3
	@{calamity_season You have been cooped up inside due to the snow for too long. The first chance you get, you mount a palfrey and set out to ride through the forest and get some fresh air.|The plowing is finally done. Wanting some fresh air—away from the soil and sheepdung of the fields—you mount your palfrey and set out on a ride through the forest.|The harvest is done. The wheat is threshed and stored. The excess has been delivered to Ulmheit and sold. You take the opportunity to go on an excursion on your palfrey in the forest.}
	
	There's a hiss from the underbrush—too close for the horse's comfort. She jerks away,
	*if ((husbandry > 1) and (event < 50))
		*set log & " That @{calamity_season spring|summer|fall|winter}, your palfrey almost meets an untimely end during a ride in the forest, but you avoid the danger."
		but by a stroke of luck you manage to keep her on the path. Over your shoulder you see a bobcat and her cubs in the brush. You kick your heels, the horse turns, and you continue on your way.
		*return
	*else
		*set seasons_since_calamity 0
		*set log & " That @{calamity_season spring|summer|fall|winter}, your palfrey breaks its leg while on a ride in the forest; you have to buy another."
		but in doing so, stumbles over a fallen log. Her left foreleg snaps audibly and you are thrown into the brush.
	
		When you rise, her cries of pain lead you back to her. You slit her throat and @{(compassion > 50) stroke her mane as the light goes out of her eyes| wipe your blade on her coat}. From the bushes across the path you see the eyes of a bobcat and her cubs staring at you.
	
		It will be a long walk back to the @{calamity_season manorhouse in the cold|manorhouse|manorhouse}. You'll have to buy another palfrey at the earliest opportunity.
		*set manor_liquid -(150 / trade_efficiency)
		*return
*else
	*set seasons_since_calamity 0
	*set log & " That @{calamity_season spring|summer|fall|winter}, one of your palfreys falls ill and does not recover. You have to send for another."
	You are summoned to the stables early one morning. @{(ridinghorse > 0) One of your palfreys|Your palfrey} has fallen ill. ${dairymaid} and ${swineherd} do their best to keep the it alive, but their knowledge of horses is limited.
	
	When spring comes you will have to purchase another.
	*set manor_liquid -(150 / trade_efficiency)
	*return

*label 11
*comment border_disagreement
*if border_disagreement or (year < 575)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*set log & " TODO border disagreement."
TODO border disagreement.
*return

*label 12
*comment rabies
*gosub_scene subs calamity_rand
*goto which_calamity
*return

*label 13
*comment drunk_boar
*if drunk_boar
	*gosub_scene subs calamity_rand
	*goto which_calamity
*gosub_scene subs randname "male" "1"
*temp full1 ((malename_1 & " ") & malepatronym_1)
*page_break
*set drunk_boar true
A scream from the pasture draws your attention.
*set log & " That @{calamity_season spring|summer|fall|winter}, the youths of the manor got a boar drunk on cider. One of them ended up gored for his troubles."

A boar is jumping and kicking like someone stuck a bee up its backside. A young serf whom you recognize—the ${descmale_1} son of ${full1}—is lying bloody and @{(calamity_season = 4) gored in the snow,|gored,} while several of his friends are trying to draw the beast away as best they can. 

Amid the blood and the pigshit you smell something sweet…cider. The fools must have thought getting the boar drunk would be good for a laugh. @{(drunk_boar_once) They must have heard the stories of the last time.|}
*set drunk_boar_once true

*choice
	#I try to organize the youths to drive the boar away from the wounded one.
		*set seasons_since_calamity 0
		*if tactics >= 2
			*set maimed_pop +1
			*set annual_manor_morale %+10
			*set log & " He was maimed but survived."
			As soon as the boar starts to move away, ${eorwald_inf} is there with clumps of wool to staunch the bleeding.

			The young ${malename_1}ich will never be the same, but he will live to see another day.
			*return
		*else
			*set hv_pop -1
			*set hv_child_pop -1
			*set annual_manor_morale %-5
			*set log & " He died from his wounds."
			You manage to drive the boar away, but by the time anyone reaches young ${malename_1}ich, he's already dead.
			*return
	#I charge forward and punch the boar on the nose.
		*set seasons_since_calamity 0
		*if hubris > 70
			*set maimed_pop +1
			*set fame +5
			*set annual_manor_morale %+15
			*set log & " You punched the boar on the nose and saved the boy."
			To everyone's astonishment, you dash through the disorganized youths and strike the cider-crazed boar right on the snout. The boar looks at you with wild eyes, which you match with your own steely gaze. After a heart-stopping pause, the boar squeals and tears away.

			Everyone is speechless. You have to point the bleeding ${malename_1}ich boy out before ${eorwald_inf} has the presence of mind to tend his wounds. Thankfully, your decisive action saves the boy's life. True, he will never be the same, but he will live to see another day.
			*return
		*else
			*set hv_pop -1
			*set hv_child_pop -1
			*set annual_manor_morale %-15
			*set log & " You tried to challenge the boar, but your courage failed you. The boy died from his wounds."
			You dash through the line of boys, determination in your eyes, only to come nose-to-snout with a very drunk, very angry, 600-pound boar. Your resolve crumbles.

			The boar turns to regard your approach with disdain. He is the king of this pasture, and he knows it.

			He turns, empties his bowels, kicks his feces in your general direction, and goes to find a sow.

			Meanwhile, ${eorwald_inf} has rushed to the side of the ${malename_1}ich boy, but it's too late.
			*return
	#I ignore the boar and rush to tend the boy's wounds.
		*if medicine > 1
			*set annual_manor_morale %+15
			*set log & " Your skill with bandages and poultices saved the boy."
			Your skills as a healer serve you well. You're able to staunch the bleeding in time to prevent permanent damage. The other youths eventually drive the boar away, and the young ${malename_1}ich boy is transported to his family's home, somewhat worse for wear.
			*return
		*elseif medicine = 1
			*set maimed_pop +1
			*set annual_manor_morale %+5
			*set seasons_since_calamity 0
			*set log & " Your skill with bandages and poultices saved the life of the boy, but he was still maimed."
			Your skills as a healer are not as strong as you would like. You staunch the bleeding, but it would take a more talented individual than yourself to truly save the boy. He will live to see another day, but he will never be the same.
			*return
		*else
			*set seasons_since_calamity 0
			*set annual_manor_morale %-5
			*set hv_pop -1
			*set hv_child_pop -1
			*set log & " You sought to tend to the boy's wounds, but you could not save him."
			Unfortunately, you are no healer. Though you reach the young ${malename_1}ich boy in time, all you can do is hold his hand and stroke his forehead as the blood runs from his body.
			*return

*label 14
*comment wolves
*page_break
*set seasons_since_calamity 0
*if annual_focus = "livestock"
	*set event -5
*if (calamity_season = 1) or (calamity_season = 2)
	*set log & " That @{calamity_season spring|summer|fall|winter}, your shepherd informed you that wolves claimed several sheep from your flock."
	${shepherd} brings word that wolves have claimed several sheep from the flock.
	*set sheep -5
	*return
*elseif calamity_season = 3
	*if sows < 7
		*set log & " That fall, your shepherd informed you that wolves claimed several sheep from your flock."
		${shepherd} brings word that wolves have claimed several sheep from the flock.
		*set sheep -5
		*return
	*elseif event < 40
		*set log & " That fall, your swineherd informed you that wolves claimed two sows from your herd."
		${swineherd} comes tromping out of the forest towards the fields where you're overseeing the reaping. It's easy to identify ${swineherd_him} by ${swineherd_his} trudge and his staff.
		
		About an hour later, he gets close enough to converse with you. "Two sows are dead. Wolves got 'em."
		
		"What about the hogs?"
		
		"A few of 'em as well."
		
		You shake your head. The wolves roam between the manors. They're clever and determined. Even if you managed to take down one or two or even a whole pack, they would be back with two or three winters. And a few fat sows must be a very tempting target.
		*set sows -2
		*return
	*else
		*set log & " That fall, your swineherd informed you that wolves claimed five sows from your herd."
		${swineherd} brings word that wolves have taken down several sows in the forest. It is a serious blow to the herd.
		
		*set sows -5
		*return
*else
	*if event < 40
		*set log & " That winter, your shepherd informed you that wolves claimed several sheep from your flock."
		The snow is melting. Yesterday is was just warm enough that the sheep were let out to pasture for the first time this spring.
		
		Too early, perhaps. The wolves were there. ${shepherd} brings word they brought down four sheep before ${shepherd_he} could intervene. They've been chased off for now.
		*set sheep -4
		*return
	*else
		*set log & " That winter, your shepherd informed you that wolves claimed a number of sheep from your flock."
		They must be really hungry.
		
		During the night, wolves manage to worry open the gate to the sheepfold. Once inside, they feast on your flock. Eventually their bleats roused the sheepdog, who eventually roused ${shepherd}. But by then, the wolves had had their fill and were happy to slink back into the forest.
		
		*set laborDays -10
		*set sheep -15
		*return

*label 15
*comment fires of mazuran
*if (calamity_season != 3) or (weather_index < 0.9)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*return

*label 16
*if year < 575
	*gosub_scene subs calamity_rand
	*goto which_calamity
*comment religious fanatics
*return

*label 17
*comment insufficient maintenance
*if maintenanceDebt <= 100
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*if calamity_season = 1
	*set seasons_since_calamity 0
	*comment *if event < 20
	*set log & " That spring, the rains clogged up the mill, adding another task to your maintenance list."
	With the arrival of spring comes rain. You are always grateful for that, but today you're also a little annoyed.
	
	As you're aware, you're behind on the maintenance for the manor. The rain has now exacerbated that by washing away a retaining wall along the river, clogging up the mechanism of the mill.
	
	It's going to even more work to repair this breach.
	*set laborDays -25
	*return
*elseif calamity_season = 2
	*return
*elseif calamity_season = 3
	*set seasons_since_calamity 0
	*if event <= 50
		*set log & " That fall, a cottar died during sheep-shearing."
		You are there when it happens. The sheep are being sheared, and one ornery wether wants nothing to do with the whole affair.
		
		Pinned between between rows of fencing, the wether should have no where to go. Most days. Most years. But not today.
		
		The fencing breaks under the wether's strains. A cottar on the other side of one side of the fence yelps in alarm as she trips over the wether's confused and anxious limbs; he doesn't know where he is going, but that doesn't stop him from cartwheeling his legs through the air in determination. And then he's on the other side, and all seems well. The cottar turns to make sure no other sheep escape the chute. And that's when she notices the ram. She turns to run.
		
		The ram lowers its head and charges the poor cottar. The crack of skull against spine is deafening. She's dead before she hits the ground.
		
		It's hours before you get the chute repaired and the sheep back in line to be sheared.
		
		By the time the work-day is done, the cottar's family has come to collect their daughter's body. You can sense their anger. It is your responsibility to make sure the infrastructure of the manor is maintained. And, yes, accidents happen. But this was preventable.
		*set annual_manor_morale %-5
		*set laborDays -5
		*set cottar_pop -1
		*return
	*else
		*set log & " That fall, two serfs died when the bull escaped his pen."
		${eorwald} appears before you, cap in ${eorwald_his} hands. $!{eorwald_he} informs you that two serfs were dragged to their deaths when @{(bulls > 1) a|the} bull broke through the fencing. They attempted to corral the animal, but it was too strong for them.
		
		$!{eorwald_he} keeps ${eorwald_his} thoughts to ${eorwald_him}self, but you can read ${eorwald_his} eyes: it was your responsibility to keep the manor in good repair. The bull never should have escaped and these deaths are on you.
		*set annual_manor_morale %-5
		*set laborDays -10
		*set cottar_pop -1
		*set hv_pop -1
		*return
*else
	*return

*label 18
*comment runaway serfs
*if (landless_pop < 5) or (annual_manor_morale > 40)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set seasons_since_calamity 0
*temp runaways 0
*if event < 30
	*set runaways 1
	*goto runaways
*elseif event <= 60
	*set runaways 2
	*goto runaways
*elseif event <= 90
	*set runaways 3
	*goto runaways
*else
	*set runaways 4
	*goto runaways
*label runaways
*set log & " That @{calamity_season spring|summer|fall|winter}, ${eorwald_inf} informed you that ${runaways} serf@{(runaways > 1) s|} fled the manor to presumably become outlaws."
${eorwald} regrets to inform you that ${runaways} landless serfs have fled the manor. It seems that their numbers were too great and their discontent too all-encompassing to remain under your governance.
*set landless_pop -runaways
*set outlaws +runaways
*return

*label 19
*comment judgments!
*if seasons_since_calamity > 2
	*gosub_scene subs calamity_rand
	*goto which_calamity
*gosub_scene subs randname "male" "1"
*temp full1 ((malename_1 & " ") & malepatronym_1)
*gosub_scene subs randname "fem" "1"
*temp full2 ((femname_1 & " ") & fempatronym_1)
*gosub_scene subs randname "male" "2"
*temp full3 ((malename_2 & " ") & malepatronym_2)
*gosub_scene subs randname "fem" "2"
*temp full4 ((femname_2 & " ") & fempatronym_2)
*if (full1 = full3) or (full2 = full4)
	*goto 19
*page_break
As thornet, you have the right of justice over the peasants of the manor. You hold court once a quarter to judge the grievances between them. Of course, you are entitled to twenty percent of any judgments you levy in suits. In situations where there is no plaintiff, the eorwald prosecutes on behalf of the community.

This evening, two of your serfs have found themselves at odds and unable to find amicable resolution.

*if event < 30
	${full2}, a half-villein, found ${full1}, a villein, asleep amid her barrels of ale. ${femname_1} accuses ${malename_1} of drinking her ale without her permission, which ${malename_1} denies vociferously. He claims that, while he was drunk, he was drunk on his own ale, not hers.
	*fake_choice
		#I find for ${full2}, fining ${malename_1} half a bushel of wheat.
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you fined ${full1} a bushel of wheat for drinking ${full2}'s ale."
			*set hubris %-5
			${full1} is outraged, but there is nothing he can do but pay the fine.
		#Since he is a villein, I accept ${malename_1}'s word over that of ${femname_1} and dismiss the suit.
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you dismissed a suit against ${full1} for drinking ${full2}'s ale."
			*set justice %-5
			${full2} is angered, but as a serf, there is nothing she can do but accept your judgment.
		#I find for ${full2}, charging ${malename_1} with replacing the barrel of ale. This is much less than a bushel of wheat, and your profit will be negligible.
			*set justice %+5
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you fined ${full1} a barrel of ale."
			${full1} is angered, but there is nothing to be done but pay the fine.
	
	${eorwald} will see to the enforcement of the judgment.
	*return
*elseif event < 60
	*comment *if calamity_season = 1
	*comment *goto 19
	*comment not sure what the intention was here ^^ Investigate! TODO
	*temp full5 ((malename_1 & " ") & fempatronym_1)
	${full2} and her younger brother, ${malename_1}, are arguing over their inheritance. Typically, goods pass to the eldest child of a family. However, some portion of the time, two-thirds are given to the eldest, while the second eldest takes a third, if such is the will of the deceased.

	In this instance, ${malename_1} claims that their father wished for such a partition, but could afford no scrivener to document it. ${femname_1} denies this claim.

	As half-villeins, splitting the acreage at stake would reduce them both to cottars—if there's a house available for ${malename_1} to occupy. If you award the entirety of the acreage to ${femname_1}, she will have a house and a home and be able to support a family, but ${malename_1} will become one of the landless.

	It should not matter, of course, but ${full2} is married and already has a child with her husband, whereas ${malename_1} is unmarried.
	*fake_choice
		#I will award the full inheritance to ${femname_1}; it would be too disruptive to the manor to trade a half-villein household for two cottars.
			*set justice %-10
			*set compassion %-10
			*label caselaw_inheritance
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you awarded the full inheritance to ${full2}."
			*set hv_pop -1
			*set landless_pop +1
			${full5} is distraught; he storms angrily out of your hall. ${femname_1} rolls her eyes at her brother before thanking you vociferously for your generosity.
		#I will award the full inheritance to ${femname_1}; absent corroboration, I am guided by the law.
			*set justice %-5
			*goto caselaw_inheritance
		#I will award the full inheritance to ${femname_1}; I cannot put this man's claims before the needs of a child.
			*set compassion %+10
			*goto caselaw_inheritance
		#I believe ${full5} and split the inheritance accordingly.
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you split the inheritance between ${full2} and her brother, ${malename_1}."
			*set hv_pop -4
			*set hv_child_pop -1
			*set cottar_pop +4
			*set cottar_child_pop +1
			*set hv_acreage -15
			*set cottar_acreage +15
			*set hv_households -1
			*set cottar_households +1
			*set justice %+5
			${full5} is obsequious with his gratitude. ${full2}, on the other hand, looks striken. Her understanding of the world and her place in it has just been upended.

	${eorwald} will see to the enforcement of the judgment.
	*set wheat +10
	*return
*else
	${full1}, a cottar, lost his chickens to a fox. However, his rooster survived the attack. A few days later, ${full2}, a half-villein, lost her rooster—probably to the same fox. Regardless, the two struck a deal: ${femname_1} could use ${malename_1}'s rooster to replace the lost stock. They were to split the new hens, and ${femname_1} was to keep a new rooster. Unfortunately, ${malename_1}'s rooster was old and died after only a few eggs were hatched: eight females and one male. Since ${malename_1}'s rooster was in ${femname_1}'s care at the time, ${malename_1} is demanding the new rooster, in addition to his half of the hens. ${femname_1} insists that she can keep the rooster, and moreover that she only has to turn over three hens, since she's been feeding and caring for them.
	
	Of course, ${malename_1} is so poor that if you award him a judgment, it is unlikely that he will be able to pay you your customary fee.
	
	*fake_choice
		#I find in favor of ${femname_1}; she can keep the rooster and the fifth hen.
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you awarded the rooster and hen to ${full2}."
			*set justice %-5
			*set spendthrift %+5
			${malename_1} is understandably disconsolate. Unwilling to slaughter the hen and rooster, ${femname_1} promishes you an extra share of the eggs for the next year as your fee.
		#I find in favor of ${malename_1}; ${femname_1} must deliver the hen and the rooster to Gorm.
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you awarded the rooster and hen to ${full1}."
			*set hubris %-5
			*set compassion %-5
			${femname_1} mutters darkly at your decision. ${malename_1} stutters in surprise and offers you the hen as your fee. You promptly sell the hen to ${femname_1}, who promises to see the salter about recording the transaction.
		#I order ${femname_1} to deliver the hen to ${malename_1}, but she can keep the rooster, as long as she delivers another rooster to ${malename_1} when it becomes available.
			*set justice %+5
			*set log & " In the manor court that @{calamity_season spring|summer|fall|winter}, you awarded the hen to ${full1} and the rooster to ${full2}, on the condition that she later furnish a rooster to ${malename_1}."
			Unfortunately, neither of them have the resources to pay their fee to you at the moment. You tell them to record their debt with the salter; they can settle with you at the harvest.
			
	${eorwald} will see to the enforcement of the judgment.
	*return

*label 20
*comment good harvest weather
*if (calamity_season >= 3) or (seasons_since_calamity > 2)
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*if calamity_season = 1
	*set log & " The weather that spring is mild, perfect growing weather."
	The spring is mild. The sky is wide and blue, except for a few rains that are perfectly timed. It promises a bountiful harvest.
	*if event > 50
		*set weather_index * 1.05
		*return
	*else
		*set weather_index * 1.1
		*return
*else
	*set log & " The weather that summer is warm but not too hot, perfect growing weather."
	The summer is warm but not hot. The sky is clear and the rain intermittant. 
	*if event > 50
		*set weather_index * 1.05
		*return
	*else
		*set weather_index * 1.1
		*return

*label 21
*comment broken bell
*if bell = false
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
The bell in the church rings the hour, as it has every day since it was ensconced in the steeple. 

*if (event > 80) or (bell_flawed and (event > 20))
	*set seasons_since_calamity 0
	*set log & " That @{calamity_season spring|summer|fall|winter}, the bell in the church cracked."
	*set bell false
	*set bell_flawed false
	*set ruined_bell true
	*set manor_morale %-10
	*set rep_senan %-10
	But this evening, you cock your head from the first blow. Something sounds off.

	@{calamity_season You put down your hoe|You put down your scythe|You put down your flail|You throw off your furs} and begin walking, then jogging, then sprinting towards the sound.

	You hear it. It's unmistakeble. On the seventh sounding, it groans. The two subsequent blows do nothing to help the matter. By the time you arrive, it is thoroughly ruined, with a massive crack from the lip halfway up the hood. The sheepish macron apologizes to you, while the caris turns beet red in both rage and embarrassment.

	There is nothing to be done but sell it for scrap.
	*return
*else
	*set log & " That @{calamity_season spring|summer|fall|winter}, you greatly enjoyed the tones of the church bell."
	You look around in pride at your serfs. Together, you have built so much. And the periodic tolling of the bell reminds you of that progress.

	You take a few moments to put your thoughts into words.
	*choice
		#I express my deep gratitude for all that they have done for ${thurnet}.
			*if hubris < 40
				*label bell_success
				*set manor_morale %+5
				Your words ring true. Your audience nods in agreement, seemingly grateful to have you as their thornet.
				*return
			*else
				*label bell_failure
				*set manor_morale %-5
				Unfortunately, your words ring hollow. Your audience shifts uncomfortably as your words trail off into silence.

				You are discomfited to be seen so clearly by your serfs.
				*return
		#I thank Sénan for the gifts that he has bestowed upon ${thurnet}.
			*if piety > 60
				*goto bell_success
			*else
				*goto bell_failure
		#I take credit for the success that the ${thurnet} has had since I became thornet.
			*if hubris > 60
				*goto bell_success
			*else
				*goto bell_failure

*label 22
*if outlaw_betrayer and (cottar_pop > 5)
	*gosub_scene subs randname "male" "1"
	*gosub_scene subs randname "fem" "1"
	*temp outlaw_full ((outlaw_name & " ") & outlaw_patronym)
	*page_break
	*set manor_morale %-10
	*if outlaw_resident_promoted_to_cottar
		*set cottar_pop -1
	*if outlaw_resident_promoted_to_cottar = false
		*set landless_pop -1
	*set cottar_pop -1
	*set outlaw_resident false
	*set outlaw_betrayer false
	*set outlaw_resident_promoted_to_cottar false
	*set seasons_since_calamity 0
	It seems that your generosity has been repaid in the worst possible way.

	${eorwald} comes screaming into your hall one evening. It seems that ${outlaw_full} fell to quarreling with a cottar by the name of ${femname_1} ${fempatronym_1}. When another cottar, ${malename_1} ${malepatronym_1} tried to intercede, ${outlaw_full} became agitated and put a clever between his eyes.

	Realizing what ${outlaw_he} had done, ${outlaw_he} immediately fled to the woods.
	*choice
		#We must find ${outlaw_full} and bring ${outlaw_him} to justice!
			*if woodcraft > 2
				${outlaw_full} has a notable headstart on you, but you are a talented tracker. It's only a matter of time before you covern ${outlaw_him} in a gully. You order ${outlaw_him} bound and led back home.
				*label address_fleeing_outlaw

				Now that you have ${outlaw_him} in your custody, however, what will you do with ${outlaw_him}?
				*choice
					#I try ${outlaw_him}, find ${outlaw_him} guilty, and hang ${outlaw_him}.
						The trial is brief: the dead body, ${femname_1} ${fempatronym_1} as a witness, ${outlaw_full}'s own history
						*goto hang_outlaw
					#Though it will be expensive, I have ${outlaw_him} taken to Ulmheit; ${outlaw_he} can be tried by the judge there.
						*set wheat -100
						A cart carries ${outlaw_full} to Ulmheit. Your tenants spit and scream at ${outlaw_him} as the cart wends its way from your hall to the edge of the manor.
						
						Unsurprisingly, ${outlaw_full} is ordered hanged by the judge.
						*goto end_outlaw_betrayer
					#I try ${outlaw_him}, find ${outlaw_him} guilty, and have ${outlaw_him} hanged upside down until death.
						*set justice %-15
						*set compassion %-10
						${outlaw_his} hands are bound, ${outlaw_his} mouth is gagged, and ${outlaw_he} is hung by the ankles from the hanging tree.
						
						It's a slow and painful death, taking almost ten hours to complete. Finally, the blood begins to pour from ${outlaw_his} ears and the sentence is pronounced complete.
						*goto end_outlaw_betrayer
			*else
				*set manor_morale %-5
				Unfortunately, your skills as a tracker are not sufficient to catch up to ${outlaw_full}, especially in the dark. By dawn, the trail has begun to grow cold.

				You return home, reflecting on your failures.
				*goto end_outlaw_betrayer
		*if (woodward) #This is why I appointed a woodward!
			*set rep_freeholders %+5
			*temp woodward_full ((woodward_name & " ") & woodward_patronym)
			${woodward_full} sets out with ${eorwald} and several other freeholders.

			Two days later, you hear their horns announcing their return. They succesfully captured ${outlaw_full}.
			*goto address_fleeing_outlaw
		#Sénan will punish the guilty.
			*set piety %+10
			*set manor_morale %-5
			*set rep_senan %+5
			Your inaction is poorly received by your tenants, but at least the caris offers some half-hearted words of praise for your piety.

			You do not hear of ${outlaw_full} again.
			*goto end_outlaw_betrayer
	*label end_outlaw_betrayer
	*set outlaw_name "ERROR"
	*set outlaw_patronym "ERROR"
	*return
*if outlaw_resident
	*page_break
	TODO neighbor discovers that you're harboring the outlaw serf.
	*return
*if years_since_outlaw_from_neighbor < 6
	*gosub_scene subs calamity_rand
	*goto which_calamity
*set years_since_outlaw_from_neighbor 0
*rand outlaw_gender 1 2
*temp bad_egg 0
*rand bad_egg 1 2
*if outlaw_gender = 1
	*set outlaw_gender "male"
*if outlaw_gender = 2
	*set outlaw_gender "fem"
	*set outlaw_he "she"
	*set outlaw_him "her"
	*set outlaw_his "her"
*gosub_scene subs randname outlaw_gender "1"
*if outlaw_gender = "male"
	*set outlaw_name malename_1
	*set outlaw_patronym malepatronym_1
*if outlaw_gender = "fem"
	*set outlaw_name femname_1
	*set outlaw_patronym fempatronym_1
*page_break
An escaped serf has turned up on the manor; ${eorwald} found ${outlaw_him} sleeping in a sheepfold.

After some interrogation, ${outlaw_he} discloses ${outlaw_his} name: ${outlaw_name} ${outlaw_patronym}. $!{outlaw_he} is a cottar from a neighboring manor.
*comment later, add notes about the different neighbors, and their proclivities, and your own relationship with them.

You order ${outlaw_him} held while you consider what to do.
*if event > 60

	A few days later, a visitor from ${outlaw_name}'s manor brings word that ${outlaw_name} is wanted for murder, and has been pronounced an outlaw for having fled the manor.

*choice
	*if (event > 60) #This individual is an outlaw; by the laws of Sénan, ${outlaw_he} should be hanged.
		*set compassion %-10
		*set piety %+10
		*set rep_gentry %+5
		*set rep_senan %+5
		*label hang_outlaw
		*if hanging_tree
			The execution is held at sunset from the hanging tree in the square.

			The serfs of the thurnet spit on the corpse once it stops jerking. Supposedly, to spit on the corpse of a condemned person brings good fortune?
			*comment really?
			*goto end_outlaw_betrayer
		*else
			*set manor_morale %-5
			With the hanging tree having been cut down, you're forced to lead a party to the woods to find a suitable tree for the deed. By the time ${outlaw_name} ${outlaw_patronym} is finished jerking, the audience has become generally disgusted with the matter.

			You order his body stripped and @{(compassion > 50) buried in an unmarked grave|left for the crows}.
			*goto end_outlaw_betrayer
		
	#@{(event > 60) Just because ${outlaw_he} fled, doesn't mean ${outlaw_he}'s guilty; I send word that I have ${outlaw_him} in my custody|${outlaw_he} belongs to my neighbor; I return ${outlaw_him} to ${outlaw_his} home}.
		*set chivalry %-10
		*set rep_gentry %+10
		The eorwald of the neighboring fee arrives a few days late to fetch ${outlaw_name} ${outlaw_patronym} and take ${outlaw_him} home. The eorwald thanks you on behalf of her thornet.

		${outlaw_name} hangs ${outlaw_his} head as he trudges out of view.
		*if event > 60
			A few days later, word reaches you that ${outlaw_he} was found guilty and hanged.
		*return
	#$!{outlaw_he} will face a wretched homecoming if forced to return; we will accept ${outlaw_him} as a landless here.
		*set landless_pop +1
		*set compassion %+10
		*set manor_morale %+5
		*set outlaw_resident true
		*if (event > 60) and (bad_egg = 1)
			*set outlaw_betrayer true
		You negotiate a bed for ${outlaw_name} ${outlaw_patronym} in the home of one of your freeholders. In time, ${outlaw_he} will be responsible for ${outlaw_his} own upkeep, but for now, you offer a bit of charity.

		$!{outlaw_he} drops to ${outlaw_his} knees in gratitude, having never met a member of the gentry willing to give ${outlaw_him} a second look, much less a second chance.
		*return
	#I pack ${outlaw_him} a rucksack and send ${outlaw_him} on ${outlaw_his} way. I then make up a story about how ${outlaw_he} escaped my custody.
		*set compassion %+20
		*set rep_gentry %-5
		*set rep_freeholders %-5
		With the help of ${eorwald}, you establish a sufficiently convincing ruse. ${outlaw_name} flees into the night, and you head off with ${eorwald} in the opposite direction.

		By the time you "discover" the mistake, ${outlaw_name} has @{(compassion > 60) fled beyond a reasonable distance for you to pursue|become someone else's problem}.
		*return

*label 23
*comment free crop acre
*if seasons_since_calamity > 2
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set forest_acreage -1
*set unassigned_acreage +1
*set log & " That @{calamity_season spring|summer|fall|winter}, the peasants cleared an acre of forest for you."
${eorwald} informs you that the peasants have taken it upon themselves to clear an acre of forest for you. Apparently several the trees were in need of being felled, and the amount of work necessary to complete the clearing was almost negligible.
*comment use manor morale to make this better?
*return

*label 24
*comment free meadow acre
*if free_meadow or (((calamity_season = 4) or (fen_acreage < 4)) or (seasons_since_calamity > 2))
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set free_meadow true
*set fen_acreage -1
*set meadow_acreage +1
*if calamity_season = 1
	The spring brings with it torrential rains. It delays the plowing and the sowing a few days, putting you in a foul mood. Thus, when ${eorwald_inf} approaches you hurriedly, you scowl at ${eorwald_him} in anticipation of more ill news. Your eyes scan the treeline, trying to anticipate the danger.

	"Thornet, the river…"

	You drop your bag of seed. Your muscles tense in preparation.

	${eorwald_inf} clears ${eorwald_his} throat and continues: "…the river has adjusted course."

	You pause. "What does that mean, ${eorwald}?"

	"I think that, if we hurry, we might be able to fortify the bank, and claim some land from the fens, ${name} ${patronym}."

	*label claim_fens
	*set weather_index - 0.02
	Claim some land from the fens? That would mean more meadow. And more meadow means more hay, and more hay means more livestock.…

	"Lead the way, ${eorwald}!" your face splits into a grin. It seems @{(orthodoxy > 50) Sénan has blessed|Siriol has not further cursed} you this day.
	*return
*elseif calamity_season = 2
	The summer is very dry. You pace the fields throughout the month of the Dragon, wondering when the rains will come.

	During one of these sessions of fruitless pacing, you are joined by ${eorwald}. This particular morning, ${eorwald_inf} clears ${eorwald_his} throat.

	"Yes, ${eorwald}, speak your mind."

	"Thornet, I do not know if you have been to the riverbank recently…"

	"I have not."

	"Well, just as the rains have not watered your crops, so too does the river lose strength."

	"Are you going to tell me that the fish are dying? Or that we have no more water to drink? I do not think I could hear it, ${eorwald}."

	"No, thornet. Rather, I believe the rains will return soon enough. In the meantime, however, I have observed that certain portions of the fens that border the river have dried out. If we build a small embankment, we may be able to prevent the river from returning to that land."
	*goto claim_fens
*else
	Autumn arrives with cool winds from the east. 

	You are seated in your hall enjoying your evening meal when ${eorwald} enters. You bid ${eorwald_him} approach and speak ${eorwald_his} mind.

	"Thornet, today I was down in the meadow supervising the hay mowing, when I spied a beaver dam in the fens."

	"A beaver dam? Did you see beavers?"

	"Well, yes thornet, but that is not my point." There is a pregnant pause, until you finally gesture for ${eorwald_him} to continue. "The dam has blocked a certain branch of the river. Suddenly, some of the fens are looking very dry."

	"And if we seize on the opportunity, and build an embankment…" you interject, finally understanding ${eorwald_his} point.

	"Then we can claim some meadow from the fens, thornet."

	More meadow would mean more hay. More hay means more livestock.…
	
	"Lead the way, ${eorwald}!" your face splits into a grin. It seems @{(orthodoxy > 50) Sénan has blessed|Siriol has not further cursed} you this day.
	*return

*label 25
*comment free house
*if seasons_since_calamity > 2
	*gosub_scene subs calamity_rand
	*goto which_calamity
*return

*label 26
*comment wheat failure
*if year < 570
	*gosub_scene subs calamity_rand
	*goto which_calamity
*page_break
*set seasons_since_calamity 0
*if calamity_season = 1
	*if event < 50
		*set winter_wheat_failure true
		*set log & " That spring, a late snow damages the winter wheat."
		The winter lasts too long. It's cold in a penetrating way, such that the winter wheat fails to sprout. Almost the entire crop is ruined.

		It's going to be a lean year. Thankfully, your other crops aren't as delicate as wheat.
		*return
	*else
		*set wheat_failure true
		*set log & " That spring, a late snow damages the entire wheat crop."
		The snowstorm comes at the worst possible time: deep in the month of the Sow. The winter wheat was standing tall and golden, while the spring wheat was young and green. Now, almost the entire crop is ruined.

		It's going to be a very lean year. Thankfully, your other crops aren't as delicate as wheat.
		*return
*elseif calamity_season = 2
	*if event < 50
		*set spring_wheat_failure true
		*set log & " That summer, hail damages the spring wheat before you can harvest it."
		Late in the summer, dark clouds begin to gather along the horizon. You urge your tenants to speed their work, and they manage to harvest the winter wheat before the hail comes. But the spring wheat was not ready, and there is nothing you can do as the crop is ruined by the relentless pounding.

		It's going to be a lean year. Thankfully, your other crops aren't as delicate as wheat.
		*return
	*else
		*set wheat_failure true
		*set log & " That summer, hail ruins the spring wheat before you can harvest it."
		The heat is relentless. By midsummer, the wheat is wilting in the fields. By the month of the Stallion, when the winter wheat would be harvested, you finally acknowledge that the entire crop is ruined.

		It's going to be a lean year. Thankfully, your other crops aren't as delicate as wheat.
		*return
*elseif calamity_season = 3
	*set spring_wheat_failure true
	*set log & " That fall, an early snowstorm ruins the spring wheat before you can harvest it."
	An early snowstorm pelts the fields. There is nothing you can do but watch as it accumulates, flake by flake. By the time it is finishd, the spring wheat is ruined.

	It's going to be a lean year. Thankfully, your other crops aren't as delicate as wheat.
	*return
*else
	*set winter_wheat_failure true
	*set log & " That winter, an early warm period causes the winter wheat to sprout early and then freeze when the cold returns. The entire crop is lost."
	The winter is fitful. What at first seems like an early spring turns out to simply be a momentary reprieve. Unfortunately, the winter wheat doesn't know that. Awoken and called forth by the sunshine, green shoots reach up and out during the month of the Vulture. Unfortunately, the Lamb brings a deep blanket of snow, ruining the entirety of the crop.

	It's going to be a lean year. Thankfully, your other crops aren't as delicate as wheat.
	*return


*label longWinter
*set hay -((oxen * dailyOxenConsump) * longWinterLength)
*set hay -((yearlings * dailyYearlingConsump) * longWinterLength)
*set hay -((sheep * dailySheepConsump) * longWinterLength)
*set hay -((warhorse * dailyWarhorseConsump) * longWinterLength)
*set hay -((ridinghorse * dailyRidinghorseConsump) * longWinterLength)
*set hay -((bulls * dailyBullConsump) * longWinterLength)
*set hay -((rams * dailySheepConsump) * longWinterLength)
*set vetches -((sows * 0.12) * longWinterLength)
*set vetches round(vetches)
*set hay round(hay)
*return

*label replace_barn
*set laborDays -300
*set timber -100
*if timber <= 0
	*set wheat +(timber)
	*set timber 0
	You have to purchase some timber to supplement your own stores.
*if wheat > 0
	*set wheat * 0.4
*set newBarn true
*return