*comment from afterattack label in alternateroute	
*looplimit 1000000000000

*comment willpower 58-80

*temp southroll 0

*page_break 
*image story2_header.png

From your vantage point you observe the human hastily gathering the scattered items from the snow that had dropped from their grasp during the exchange. 
*if (attackraishall = "yes")
	$!{herhis} hands have an obvious tremor as they work. It seems that you were not the only one rattled by the encounter.
*if (attackraishall != "yes")
	$!{herhis} movements become more sure as they work. Perhaps they believe you chased away and feel themselves safe for the moment. You sniff in disdain. If only they knew that you watch them yet and are far from defeated.
	
You hear an involuntary gasp as they catch sight of the sky as they notice the unexpected passage of time that occurred while they remained entranced. $!{herhis} actions become hurried by the shortness of time. With an eager smile you observe the scene keenly for any sign of a mistake brought on by the rushed preparations. 

Hours may pass when in contact with the spirit realm, even when it may only seem like a blink of the eye to those involved. Time has a tendancy to behave strangely within the mind's eye. Any Raishall worth their salt should know this rather than be caught unawares. This only provides further confirmation to your suspicion of just how precarious this human's control of the ritual they plan will likely be. Inexperience and powerful magics are not a combination their kind tends to survive unscathed.	

*page_break
*image story2_header.png

The human proceeds to arrange four items atop a snow dusted tree stump at the edge of the clearing. You observe each as it is revealed with interest.

[i]A chunk of smoky quartz.[/i]

[i]A dull grey slither of flint paired with a handful of tinder.[/i]

[i]An empty waterskin.[/i]

[i]A stoppered earthenware jug filled with water next to a polished obsidian bowl.[/i]

A toothy smirk of anticipation spreads unbidden across your face. So it is to be a summoning after all, your instincts weren't mistaken. You know enough about such rituals to realise the items will be arranged in a particular order, one for each cardinal point, and that order is crucial to the working's outcome. The Raishall still seems slightly rattled. Perhaps you could take advantage of that lack of focus to influence them? 

The human's hand hovers uncertainly over the objects. On a whim you prompt them to take...

*set willpower -10
*comment willpower 48-70

*fake_choice
	#The quartz.
		*image story2_header.png
		
		*set northobject "earth"
		You reach out, the effort taxing your strength and
		*if (finesse > 49)
			as gently as you can
		*if (finesse < 50)
			with as subtle a prod as you can manage
		push them towards the piece of rock lying on the snow dusted stump. 
		
		[i]"North is for the element of earth you whisper. You know what you must do."[/i]
	
	#The flint.
		*image story2_header.png
		
		*set northobject "fire"
		You reach out, the effort taxing your strength and
		*if (finesse > 49)
			as gently as you can
		*if (finesse < 50)
			with as subtle a prod as you can manage
		push them towards the flint and tinder that lies on the snow dusted stump. 
		
		[i]"North is for the element of fire you whisper. You know what you must do."[/i]
	
	#The empty waterskin.
		*image story2_header.png
		
		*set northobject "air"
		You reach out, the effort taxing your strength and
		*if (finesse > 49)
			as gently as you can
		*if (finesse < 50)
			with as subtle a prod as you can manage
		push them towards the empty waterskin that lies upon the snow dusted stump. 
		
		[i]"North is for the element of air you whisper. You know what you must do."[/i]
	
	#The stone bowl.
		*image story2_header.png
		
		*set northobject "water"
		You reach out, the effort taxing your strength and
		*if (finesse > 49)
			as gently as you can
		*if (finesse < 50)
			with as subtle a prod as you can manage
		push them towards the polished bowl that gleams dimly in the moonlight. 
		
		[i]"North is for the element of water you whisper. You know what you must do."[/i]

*set elementsset 1

With a rising sense of triumph you observe the human shake their head slightly as if trying to clear it, then reach towards the object of your choice. Taking it to the far end of the clearing they
*set firstplace "yes"
*if (northobject = "earth")
	push the piece of quartz firmly into the dark soil while whispering a word of power. As ${she} brushes dirt from their hands you feel energy crackle and shimmer against the barrier. 
*if (northobject = "fire")	
	clear the snow from a small spot on the ground to place the modest pile of dried twigs and leaves. With practiced fingers ${she} deftly strikes the flint to send a shower of sparks flying onto the carefully prepared tinder and blow softly until flames rise from the smoke. 
	
	!${she} whispers a word of power and the fire flares brightly in response sending a wave of energy crackling against the barrier on which you eagerly lean. 
*if (northobject = "air")
	crouch down in the snow, whispering a word as ${she} breathes into the empty waterskin. The air crackles with a power you can feel despite still being trapped behind the veil. As the human gently releases the object you notice it hovers just above the ice as if reluctant to touch the ground below.		
*if (northobject = "water")
	set the bowl down gently, before filling it with liquid that reflects the stars above in distorted ripples. !${she} whispers a word of power and you note the water's surface tremors in response, while energy washes as if in a wave up against the barrier which holds you captive. 
The ritual has begun. 

Other spectres begin to drift resentfully away, sensing the taint of your influence on the working. Should it be a success you will be the one summoned should you decide to answer the call. You smile again, mouth opening to reveal a maw with too many teeth not to be unnerving despite your expression of delight. Perhaps you can salvage something from this night after all.

*page_break
*image story2_header.png

The young Raishall walks back to the remaining assembled objects, footsteps crunching through crusted snow in the otherwise now silenced woods. As ${she} reaches towards the next object, you wonder if you could influence ${herhim} once again. 

Then again, perhaps it is wise to conserve your strength for later. 

*set southroll 0

*label rollsobject
		
*if (randsouth = 1)
	*set southobject "earth"
*if (randsouth = 2)
	*set southobject "air"
*if (randsouth = 3)
	*set southobject "water"
*if (randsouth = 4)
	*set southobject "fire"

*if (southobject = northobject)
	
	*if (southroll > 2)
		*if (randsouth = 4)
			*set randsouth 1
			*goto rollsobject
		*if (randsouth != 4) 
			*set randsouth +1
			*goto rollsobject
			
	*set southroll +1		
	*rand randsouth 1 4
	*goto rollsobject
			
	

*choice
	#Try to push the human towards setting the object of your choice to the south.
		*image story2_header.png
		*set willpower -5
		*comment willpower 38-60
		The taste of victory still vivid in your thoughts, you cannot help but to try your hand and twisting the Raishall's mind once more. But in what way to do so?
		
		To the north, the element of ${northobject} has been anchored. There is no changing that now entwinded in the fabric of the spell as it is. So given that, which element do you feel would best suit your purposes when placed to the south?
			
		
		*choice
			*if (northobject != "earth") #The stone representing earth. 
				*set southobject "earth"
				*goto southcheck
			
			*if (northobject != "fire") #The flint and tinder signifying fire. 
				*set southobject "fire"
				*goto southcheck
				
			*if (northobject != "air") #The empty waterskin used to summon the element of air.
				*set southobject "air"
				*goto southcheck
				
			*if (northobject != "water") #The polished bowl and liquid which represents water.
				*set southobject "water"
				*goto southcheck
		
		*label southcheck
		*image story2_header.png
		
		*if (willpower < 51)
			*set failinfluence "yes"
			
			You reach out once again, but the energy cracking around the clearing disrupts your concentration. Desperately you try to push the human towards your intended object, but with a shiver they manage to shake your compulsion away. 
			
			Exhausted, you've no choice but to allow them to proceed for now without your input. 
			
			*comment You can be pleased if they choose the way you hoped anyway although it cost you energy you didn't need to expend. Put in a variable re this.
			*set hopedelement southobject
			*set southobject ""
			
					
			*goto failedinfluence
		
		
		*if (willpower > 50)
			You reach out once again, guiding their thoughts towards the element of ${southobject}. The Raishall hesitates for just a moment more, before 
			*if (southobject = "earth") 
				closing their hands around the translucent stone. 
			*if (southobject = "fire")
				gathering the tinder and tapered flint tightly in fingers now almost numb from the wintry air.
			*if (southobject = "air") 
				retrieving the empty container from the stump.
			*if (southobject = "water") 
				closing their fingers around the heavy stone bowl.
				
			$!{she} proceeds to the southern end of the clearing, holding the object out to the moonlight. With another whisper a shimmer of energy reverberates around the clearing, even stronger than before.	
						
			Relief at your triumph wars with renewed eagerness. Though drained, you've successfully pushed a Raishall into doing as you wished to set the primary elements of this ritual to your liking. Now all that's left is to allow them to set the remaining coordinates	and await the results.

		*set elementsset 2
		
		*achieve setplacement		
		*goto successplacement
	
	#Allow them to continue unimpeded... at least for now. 
		*image story2_header.png 
		
		You decide to bide your time and wait. After all, the ritual is in motion but you do not yet know for what purpose they intend to summon your services. It seems prudent to save your power for when you may most be in need of it.
		
				
		*goto noinfluencecircle
			

*label failedinfluence

*set southroll 0

*label rollsobject2


*if (randsouth = 1)
	*set southobject "earth"
*if (randsouth = 2)
	*set southobject "air"
*if (randsouth = 3)
	*set southobject "water"
*if (randsouth = 4)
	*set southobject "fire"
	
*if (southobject = northobject)
	*rand randsouth 1 4
	*goto failedinfluence
	
*if (southobject = northobject)
	
	*if (southroll > 3)
		*if (randsouth = 4)
			*set randsouth 1
			*goto rollsobject2
		*if (randsouth != 4)
			*set randsouth +1
			*goto rollsobject2
			
	*set southroll +1		
	*rand randsouth 1 4
	*goto rollsobject2	


*page_break
*image story2_header.png

Waiting impatiently, you can only watch as the human decides on which item to select. Dithering for a moment they reach for 
*if (southobject = "earth") 
	the stone that that will be used to weave the element of earth into the ritual. 	
*if (southobject = "fire") 
	the flint and tinder that will be used to weave the element of fire into the ritual.			
*if (southobject = "air") 
	the empty container that will be used to weave the element of air into the ritual.		
*if (southobject = "water") 
	the polished bowl that will be filled with liquid to weave the element of water into the ritual.
With another whisper, a new shimmer of energy reverberates around the clearing. It feels stronger now as the additional item is set in its place.
	
*if (hopedelement = southobject)
	Did your attempt at compulsion work after all? You dismiss the thought after a a brief moment of contemplation. It seems more likely that fortune has favoured you and your target has merely selected ${southobject} for the southern co-ordinate by happy chance. Though the energy you needlessly extended is irritating, at least you have gotten what you wished for in the end.
	
	*achieve luckelement

*if (hopedelement != southobject)
	You feel a stab of disappointment as the Raishall selects differently to what you had intended. If only you weren't so weakened by this wretched barrier. For now, all you can do is continue to watch and wait as the magic user continues to weave their spell. 
	
*goto lasttwoobjects	



*label noinfluencecircle
	
Waiting quietly you watch as the human dithers for a moment, then selects 
*if (southobject = "earth") 
	the stone that that will be used to weave the element of earth into the ritual. 	
*if (southobject = "fire") 
	the flint and tinder that will be used to weave the element of fire into the ritual.			
*if (southobject = "air") 
	the empty container that will be used to weave the element of air into the ritual.		
*if (southobject = "water") 
	the polished bowl that will be filled with liquid to weave the element of water into the ritual.
With another whisper, a new shimmer of energy reverberates around the clearing. It feels stronger now as the additional item is set in its place. Perhaps it was wise to let the magic user continue without further interference for now. The balance of power feels delicate. Any disturbance could potentially unravel the working and ruin your chances of breaching the veil at all.

*goto lasttwoobjects


*label lasttwoobjects
*label successplacement

*page_break
*image story2_header.png

*if (northobject = "fire")
	*if (southobject = "water")
		*set unbalancedsummon "no"
		*set westobject "earth"
		*set eastobject "air"
		*set addcreature ""

	*if (southobject = "earth")
		*set unbalancedsummon "yes"
		*set westobject "water"
		*set eastobject "air"
		*set addcreature "magma"
		
	*if (southobject = "air")
		*set unbalancedsummon "yes"
		*set westobject "earth"
		*set eastobject "water"		
		*set addcreature "smoke"

*if (northobject = "earth")
	*if (southobject = "air")
		*set unbalancedsummon "no"
		*set westobject "fire"
		*set eastobject "water"	
		*set addcreature ""
		
	*if (southobject = "fire")
		*set unbalancedsummon "yes"
		*set westobject "water"
		*set eastobject "air"
		*set addcreature "magma"
		
	*if (southobject = "water")
		*set unbalancedsummon "yes"
		*set westobject "fire"
		*set eastobject "air"	
		*set addcreature "plants"
		
*if (northobject = "water")
	*if (southobject = "fire")
		*set unbalancedsummon "no"
		*set westobject "earth"
		*set eastobject "air"
		*set addcreature ""

	*if (southobject = "air")
		*set unbalancedsummon "yes"
		*set westobject "fire"
		*set eastobject "earth"
		*set addcreature "snow"
		
	*if (southobject = "earth")
		*set unbalancedsummon "yes"
		*set westobject "fire"
		*set eastobject "water"	
		*set addcreature "plants"

*if (northobject = "air")
	*if (southobject = "earth")
		*set unbalancedsummon "no"
		*set westobject "fire"
		*set eastobject "water"	
		*set addcreature ""
		
	*if (southobject = "water")
		*set unbalancedsummon "yes"
		*set westobject "fire"
		*set eastobject "earth"
		*set addcreature "snow"
		
	*if (southobject = "fire")
		*set unbalancedsummon "yes"
		*set westobject "earth"
		*set eastobject "water"	
		*set addcreature "smoke"
		
		
The Raishall continues, returning to the stump to collect the representation of ${eastobject} you know they will place to the east.	
*if (eastobject = "earth")
	The large piece of clouded quartz glows, lit by the moon itself as ${she} pushes the stone firmly into the frost hardened soil. With a word infused with power, the earth quivers as ${she} brushes dirt from ${herhis} hands. 
*if (eastobject = "fire")
	$!{she} brushes away a patch of snow to place small pile of dried twigs and leaves. With practiced fingers ${she} deftly strikes the flint to send a shower of sparks flying onto the carefully prepared tinder and blows softly until flames rise from the smoke. A flickering orange glow overwhelms the silvered light of the moon as ${she} whispers another arcane word causing the fire to flare brightly in response.
*if (eastobject = "air")
	$!{she} kneels down in the snow holding the chosen object up to the sky before breathing a word of power into the empty waterskin. Tying it tightly closed with a strip of hide, ${she} places it upon the ground where it rises to hover slightly as if not willing to touch its antithesis.
*if (eastobject = "water")
	The human walks purposefully to the chosen cardinal point and closes their eyes, breathing deeply as if quietening thoughts into sharp focus. They unstopper the jar pouring a small amount of colourless liquid into the polished obsidian bowl. It ripples softly, reflecting a distorted image of the sky above. 
	
	Placing the bowl on the ground, the Raishall whispers an arcane word and the liquid quivers in response. 
	
	
*page_break You continue to watch intently with a mixture of eagerness tempered with anxiety.
*image story2_header.png

Energy swirls about the forest, powerful but as yet unfocused. You've been witness to such rituals before. $!{she} will attempt a summoning, of that you are now almost completely certain. The thought of being in the world of the living is both enticing, yet tainted with the knowledge that the human will attempt to chain you to their will. As much as you pretend invulnerability, the truth is sometimes they succeed.

Footsteps crunch loudly through the frost capped snow as the human returns to collect the final item. The last element to be anchored, will be ${westobject} to the west.	

*if (westobject = "earth")
	The large piece of clouded quartz glows lit by the moon itself as ${she} pushes the stone firmly into the frost hardened soil. Speaking a word infused with power, it is as if the earth itself trembles, while the air vibrates with such force that you are surprised the trees do not thrash and fall. Though ${she} too had to feel the powerful, swirling energies, the human calmly rises brushing the dirt from ${herhis} hands.
*if (westobject = "fire")
	$!{she} brushes away a patch of snow to place small pile of dried twigs and leaves. With practiced fingers ${she} deftly strikes the flint to send a shower of sparks flying onto the carefully prepared tinder and blows softly until flames rise from the smoke. A flickering orange glow overwhelms the silvered light of the moon as ${she} whispers another arcane word causing the fire to flare brightly in response and the air to quiver with yet unfocused power.
*if (westobject = "air")
	$!{she} kneels down in the snow holding the chosen object up to the sky before breathing a word of power into the empty waterskin. Tying it tightly closed with a strip of hide, ${she} places it upon the ground where it rises to hover slightly as if not willing to touch its antithesis. Rapidly you feel power rising, barely restrained, chaotic and dangerous.
*if (westobject = "water")
	The human walks purposefully to the chosen cardinal point and closes their eyes, breathing deeply as if quietening thoughts into sharp focus. They unstopper the jar, pouring a small amount of colourless liquid into the polished obsidian bowl. It ripples softly, reflecting a distorted image of the sky above. 
	
	Placing the bowl in the ground, the Raishall whispers an arcane word and the liquid quivers in response, a tremor that spreads both deep into the earth and rises high through the air building with a wild and dangerous power.
	

*page_break
*image story2_header.png

Glancing around the clearing, the tightness around their lips and eyes the only visible sign that the stress of such a working is taking its toll on the young Raishall. You can only imagine the strain their fragile mortal form must be under as they try to guide the turbulent magic that threatens to pull the mountain apart beneath their feet at the slightest hesitation or misstep. In a fluid motion ${she} draws a dagger etched with runes from ${herhis} belt to begin swiftly etching a ring into the soft loamy soil. Stepping within, ${she} closes it with a final stroke of the knife causing energy to flow into the carved lines, spiralling in a blinding furnace of light to your arcane enhanced eyes. 

This imposing display of summoned magical power, however tenuously contained, is unexpected. Though you'd not been so foolish as to imagine the human to be harmless, the shear amount of raw energy they have managed to call forth is far more than you'd originally imagined them capable of.

*fake_choice
	#You flinch back suddenly uncertain. Was it a mistake to become entangled with this mortal's schemes after all?
		*image story2_header.png
		
		You loathe even the possibility of being bound to carry out another's command, and irritatingly that prospect has suddenly that prospect has become a lot more likely. Still, you're far too committed to withdraw now. Steeling nerves that scream at you to flee before it’s too late, instead you continue to watch.
		
	#You are not overly concerned, at least not quite yet. You have power of your own and the experience you are certain the mortal lacks. 
		*image story2_header.png
		
		Power is strength, giving you the ability to bludgeon your enemy into submission. Some feel that power triumphs over all... But they are wrong. Many a proud warrior has been brought to their knees by a fatal mistake, one born of ignorance or simply being out-maneuvered by an opponent more cunning and skilful than themselves. Though you're no weakling yourself, you have the experience born of an existance that stretches to far before ${herhis} distant ancestors ever even set foot on these mountains. If there is yet a way to twist this situation to your advantage, you'll find it. 

	#At least it means there is a high chance the summoning will succeed... 
		*image story2_header.png
		
		It is always so [i]disappointing[/i] to put so much effort into pushing yourself forward to be chosen, only to have the human reduced to a pile of ashes when the power they seek to control turns on them as being an unworthy vessel. 
		
		As much as the thought of being bound to another's command fills you with revulsion, the idea of being stuck in this place of shadows without sustenance for yet another year at this moment seems a worse fate. Though you could more easily have overcome a weaker opponent, perhaps it is a good sign they possess far more than the required raw strength required to carry this ritual successfully to its completion. Once the summoning is complete, then you will see how the situation can best be twisted to your own ends... if that is possible.
		

As you turn your attention back to the human, you notice ${herhim} studying the gathered piles of raw materials required for the next stage of the spell. It seems as if they will choose not to draw you within their own flesh, instead building a simulacra to house your essence. A body real or made is required. Without that protection you'd last but moments before being torn apart by the forces that seek to keep a separation between the realms distinct. 

*fake_choice
	#You were never overly vain about what flesh you wear while in the living world.
		*image story2_header.png
		
		As long as it proves functional you care little of your outward appearance, however certain forms have proven more useful for your hunting styles than others over the years. If you can force the Raishall's hand, perhaps you can get something of what body you would prefer.
		
	#You certainly have particular preferences for the forms you prefer to wear, though unfortunately it is not always possible to be overly choosey.
		*image story2_header.png
		
		Your mind flits back to previous incarnations that have been built to house your essence while you stalked the world above. Certain forms have proven more useful for your hunting styles than others over the years. If you can force the Raishall's hand, perhaps you will get what you desire.


You know that each time you try to make the Raishall do as you wish, it will drain you further however. For a moment you ponder over how much you will be able to influence the human beyond... and how much energy you feel safe in expending. Arriving already weakened on this plane may not be the best idea either. 

*comment willpower 33-70
*if (willpower > 55)	
	*set image 4
*if ((willpower < 56) and (willpower > 37))		
	*set image 3
*if (willpower < 38)	
	*set image 2


Blind to your dilemma, the human continues to hurry through their preparations. The first to be built will be a skeleton, the makeshift bones on which the rest of the simulacra will be styled. From your vantage point you can see three piles of materials ready to be selected. 

[i]With your current energy reserves, you suspect you can influence the Raishall's decisions approximately ${image} times.[/i]

You decide to try to influence the human to choose...

*choice
	#Green sticks tied with vines. Flexible and fast.
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		The Raishall easily accepts your mental prod as if they'd already been ready to select the slender sticks and vines as the base for their creation. 
		
		Working quickly, they cut branches to size before roping them together into the rough shape of a four-legged animal as high as their knees. You grin in satisfaction, watching as they cover the "bones" with a layer of clay. This body will prove to be fleet, agile and able to outdistance any humans you may come across during your hunt.

		*set size "medium"
		*set chooseform +1
		
		*goto selecttail
		
	#Bleached branches hardened by the sun. Slower perhaps, but strong. 
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		The Raishall easily accepts your mental prod as if they'd already been ready to select the sold pieces of wood as the base for their creation.
		
		The building progress takes more time than you would have liked. The brances are heavy and difficult for the human to manipulate into a shape they are pleased with. Finally the semblance of a four-legged creature standing as tall as the human's hip emerges. These bones will make you slower and less agile than if one of the other materials had been chosen, however it will give you extra strength making you difficult to destroy. The "skeleton" complete, you wait impatiently as ${she} applies a layer of clay over the top to bind the structure together. 
 
		*set size "large"
		*set chooseform +1
		
		*goto selecttail


	#Clay. Though not particularly sturdy, it should prove fast to build and allow you to shift your appearance in ways that would be otherwise impossible.
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		The Raishall easily accepts your mental prod as if they'd already been ready to select the damp sticky clay as the base for their creation.
		
		As you anticipated, the human finds the clay easy to work with and the form of a small four-legged creature quickly emerges. It is smaller than you would have preferred, standing no higher than the Raishall's calf, but perhaps that is for the best if you wish to travel unseen. With the right kind of weaponry even a body as diminutive as this could be equally as deadly as one far larger, particularly given the extra stealth you can use to your advantage to get closer to your prey than may otherwise be possible. 
		
		*set size "small"		
		*set chooseform +1
		
		*goto selecttail
	
	
	#On second thoughts it matters little to me what bones the human choses to give this form.
		*image story2_header.png
		
		*set dontchooseform +1
		You choose to reserve your strength, deciding that you can work with what ever form the little human chooses to house you in for now. Watching on, you see ${herhim} move towards
		*if (boneset = 1)
			the tangled pile of flexible sticks and vines.
			
			To your satisfaction, the human proceeds quickly about their work cutting branches to size and roping them together into the rough shape of a four-legged creature standing as high as ${herhis} knees. You nod deciding that the simulacra will do nicely as ${she} covers the "bones" with a layer of clay. This body should be fleet, agile and able to outdistance any humans you may happen across during your hunt.

			*set size "medium"
			
			*goto selecttail
			
		*if (boneset = 2)
			the neatly stacked pile of solid looking branches.
			
			Progress in building the simulacra takes more time than you would like. It seems as if the heavy pieces of wood are difficult for the human to piece together in a way that meets their satisfaction. Finally the semblance of a four-legged creature standing as tall as ${herhis} hip emerges. These solid bones will make you slower and less agile than if one of the other materials had been chosen, however it will give you an extra strength that makes you difficult to destroy. The "skeleton" now complete, you wait impatiently as the human applies a layer of clay over the top to bind the structure together. 
			
			*set size "large"
			
			*goto selecttail
			
		*if (boneset = 3)
			the mound of whetted deep brown clay. 
			
			The human finds the clay easy to work with and the form of a small four-legged creature quickly emerges. It is perhaps smaller than you would have preferred, standing no higher than the Raishall's calf, but perhaps that is for the best if you wish to remain unseen. With the right kind of weaponry even a body as diminutive as this could be equally as deadly as one far larger, particularly given the extra stealth you can use to your advantage to get closer to your prey than may otherwise be possible.
			
			*set size "small"
			
		*goto selecttail
			
			
*label selecttail

*page_break Onto the tail...
*image story2_header.png

Next the Raishall seems to be weighing the pros and cons of choosing each of the three available materials that you assume has been gathered as options to be used in place of a tail. 
*if (image = 1)
	[i]The events of the night have left you feeling uncharacteristically tired and unfocused. You suspect you may only manage to influence the Raishall one more time at most while still trapped on this side of the veil should you choose to try to do so.[/i]
*if (image > 1)	
	[i]With your current energy reserves, you suspect you can influence the Raishall's decisions approximately ${image} times.[/i]	

You push them towards...

*choice
	#A long thin section of cane. You feel it will be good for balance when running and lunging for prey. 
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		You reach out with your mind to prompt them towards choosing a piece of cane. The human resists as if they had a different design planned, but with your feather light influence they do not realise the indecision is not their own making and eventually cave to your will.
		
		Reaching for the lengths of cane they whip each through the air several times sharply, until deciding on one that gives a satisfying snap at the end of each stroke. Seemingly pleased, they push the wooden tail into place and mould more clay about its base to make it secure.
		
		*set tail "cane"
		
		*goto setskin

	#A tendril torn from a vine. Though more easily broken, wickedly sharp thorns sprout from its surface that could be used to inflict serious damage.
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		You reach out with your mind to prompt the human to select the vine. $!{she} resists as if ${she} had a different design planned, but with your feather light influence they do not realise their indecision is not their own making and eventually cave to your will.
		
		$!{she} picks up the vine gingerly, trying to avoid being scratched by the barbs that adorn its surface before pressing the end into place as a tail and securing it with more clay. You nod in satisfaction thinking that any who stand in your way will be in for a nasty surprise indeed. 
		
		*set tail "vine" 
		
		*goto setskin
		
	#A length of woven rope. It could be used for entangling prey and binding it helpless on the ground.	
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		You reach out with your mind to prompt them towards picking up the rope. The human resists as if they had a different design planned, but with your feather light influence they do not realise their indecision is not of their own making and eventually cave to your will.
		
		The section of rope appears thick and sturdy, certainly it will not break easily. Digging a hole into the similcra, the human pushes the rope within and secures it with more clay around the base to form the tail.
		
		*set tail "rope"	
		
		*goto setskin
		
	#You will graciously allow the human to choose this time. 
		*image story2_header.png
		
		*set dontchooseform +1
		You choose to reserve your strength, not finding the choice of a tail worthy of depleting your reserves. 
		
		As you watch they humans selects
		*if (tailset = 1)	
			a long section of flexible cane. Reaching for the chosen item, ${she} whips it through the air several times sharply as the wood gives a satisfying snap at the end of each stroke. Seemingly pleased by the balance it will provide when running and lunging, ${she} pushd the cane tail into place and mould more clay about its base to make it secure.
		
			*set tail "cane"
		*if (tailset = 2)
			a thorn covered length of vine. $!{she} picks it up gingerly, trying to avoid being scratched by the barbs that adorn its surface before pressing the end into place as a tail and securing it with more clay. You nod in satisfaction thinking that any who stand in your way will be in for a nasty surprise indeed. 
		
			*set tail "vine" 
		*if (tailset = 3)
			a length of rope that appears thick and sturdy. Certainly it will not break easily and could prove useful for entangling prey should you have need of it. Making a hole in the clay, ${she} forces the rope within and secures it with more earth around the base to form the tail.
			
			*set tail "rope"	
		
		*goto setskin



*label setskin		
		
*page_break The simulacra continues to take shape.
*image story2_header.png

The vessel for your essence continues to take shape as the human works quickly to cover it with yet another layer of clay etching the muscles and tendons deep into the surface that it will require to be able to run.

*if (image = 1)
	[i]The events of the night have left you feeling uncharacteristically tired and unfocused. You suspect you may only manage to influence the Raishall one more time at most while still trapped on this side of the veil should you choose to try to do so.[/i]
*if (image > 1)	
	[i]With your current energy reserves, you suspect you can influence the Raishall's decisions approximately ${image} times.[/i]

Finally it comes to building the outer layer. To create the skin you would prefer...

*choice

	*selectable_if (image > 0) #Rocks and pebbles to form an armoured coating.
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		The human already seems divided on how to proceed, so it take little work to convince them to choose an armoured coating. 
		
		Meticulously they fit the stones together to form a barrier against knives and arrows. Should you be forced into battle, it will be far more difficult for an enemy to strike a killing blow. 
		
		*set skin "rock"
		
		*goto setform
		
	*selectable_if (image > 0) #Soil and leaves should form the hide allowing you to better blend with the surroundings. 
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		The human already seems divided on how to proceed, so it take little work to convince them to choose an earthy coating. 
		
		A dark coating of loamy soil followed by leaves placed like scales form a camouflaging disguise. Finally, they add small twigs which sprout at angles serving to further break up the creature's outline. 
		
		You are pleased with their work. It will likely prove a stealthy vessel for creeping through shadows and remaining unseen until it is too late for your prey to defend themselves.
		
		*set skin "leaves"
		
		*goto setform
		
	*selectable_if (image > 0) #Sharpened sticks, spines and stones that will slice any who get too close.
		*image story2_header.png
		
		*set willpower -5
		*set image -1
		*set chooseform +1
		
		The human already seems divided on how to proceed, so it take little work to convince them to choose the dagger-like coating you wish for. 
		
		Warily they pick through the pile of sharp-edged objects, painstakingly fitting them together to form a carpet of bristling knives and spines. Though you think to yourself that the unusual appearance will draw attention, that will surely be offset by the ability to damage any who try to capture you. 
		
		*set skin "sharp"
		
		*goto setform
	
	#You have no preference. It will be more interesting to see what the human selects. 
		*image story2_header.png
		
		*set dontchooseform +1
		You choose to reserve your strength. Surely the human can choose a hide most suitable for the job they seek to summon you for. 
		
		*label autoskin
		
		As you watch they humans selects
		*if (skinset = 1)
			rocks and pebbles with which to form an armoured coating. Meticulously they fit the stones together to form a barrier against knives and arrows. Should you be forced into battle, it will be difficult for an enemy to strike a killing blow. 
		
			*set skin "rock"		
		*if (skinset = 2)
			soil and leaves with which to form a skin that will surely allow you to better blend in with the surroundings. A dark coating of loamy soil followed by leaves placed like scales form a camouflaging disguise. Finally, they add small twigs which sprout at angles serving to further break up the body's outline. 
		
			You are relatively satisfied with their work. It will likely prove stealthy for creeping through shadows unseen until it is too late for those you hunt to mount a defence.
		
			*set skin "leaves"	
		*if (skinset = 3)
			sharpened sticks and stones that will slice any who get too close. Warily they pick through the pile of razor-edged objects, painstakingly fitting them together to form a carpet of bristling knives and spines. Though you think to yourself that the unusual appearance will draw attention, that will surely be offset by the ability to damage any who try to capture you without effort. 
		
			*set skin "sharp"
		
		
		*goto setform
	
	*if (image = 0) #As much as you'd like to try and force the human to choose as you wish, you haven't the willpower left to manage such a feat.
		*image story2_header.png
		
		*set dontchooseform +1
		You grumble and curse at your weakened state that prevents you from doing as you freely desire. You can only hope the human chooses wisely. 
		
		*goto autoskin
	

*label setform

*page_break The stars turn...
*image story2_header.png

The human's breath now comes raggedly in small puffs of mist as they kneel trying not to freeze in cold of the frigid night. Still they push on, knowing their chore is almost complete. 

Fragments of stone are pushed into carved paws as makeshift claws before they turn their attention to the yet roughly formed head. The simulacra appears almost finished, this will surely be the final detail. 


*choice
	*selectable_if (image > 0) #With a grin you send the image of a hunting dog.
		*image story2_header.png
		
		*set chooseform +1
		*set willpower -5
		*set image -1
		
		You've always favoured this appearance. When you are in need for a creature built for hunting there is no better form to take. It seems the human agrees as they readily accept the image you present, carving details into the yet exposed clay. Jaws are lengthened and widened to accommodate a set of sharpened rocks for teeth that will easily rend flesh from bone. Tall, pointed ears are raised that will allow you to hear even the softest of footfalls hidden from sight.
		
		*set head "canine"
	
		*goto completeform
		
	*selectable_if (image > 0) #Surely a feline shape is most fitting for stalking the night for prey. 
		*image story2_header.png
		
		*set chooseform +1
		*set willpower -5
		*set image -1
	
		While large cats are a rarity in these forests, their ability to stalk the shadows unseen is unmatched. It seems the human agrees as it takes little effort to get them to accept the image you present, carving the details into the yet exposed clay. They widen the previously shapeless maw, setting pointed quills in place of teeth within. With these you suspect you will be able to bite effortlessly through skin, holding fast while sharpened stone claws rend flesh from bone. Small delicate ears are fashioned atop the head which will allow you to hear the heartbeat of your prey when you close in for the attack.
		
		*set head "feline"
		
		*goto completeform
		
	*selectable_if (image > 0) #In a fit of whimsy you picture one of the long extinct fire breathing lizards that used to roam these lands. 
		*image story2_header.png
		
		*set chooseform +1
		*set willpower -5
		*set image -1
		
		It seems fitting that you as something that does not belong of this world would take the form of such a vessel. 
		
		At first the human seems perplexed at the image that has formed in their mind, but then as if inspired sets to work carving scales into the areas of exposed clay and adding a pair of branching horns made from branches discarded on the forest floor. The previously shapeless maw is widened into heavy set jaws lined with jagged rocks in place of teeth. Finally they caarefully retrieve a glowing coal from the fire burning to the 
		*if (northobject = "fire")
			north,
		*if (southobject = "fire")
			south,
		*if (westobject = "fire")
			west,
		*if (eastobject = "fire")
			east,
		and push the burning ember deep into the base of its throat. With a breath of flames, you'll be a deadly foe indeed. 
		*set head "dragon"
		
		*goto completeform
	
	#The human knows the task they will try to set. Let them choose. 
		*image story2_header.png
		
		*set dontchooseform +1
		You decide to reserve your strength. Surely the human can pick the final form most suitable for the task they seek to summon you for. 
		
		*label autoform
		
		Under their fingertips a recognisable shape begins to appear. 
		*if (formset = 1)
			Jaws are lengthened and widen to accommodate a set of sharpened rocks for teeth that will easily rend flesh from bone, and ears are raised atop its head. It seems the human sees you as their hunting dog. Well, you'll soon see if they truly are the hunt-master or the prey. 
			*set head "canine"
		*if (formset = 2)
			Jaws are widened, and delicate ears pricked up on the top of the head. A leopard. You're surprised the Raishall has seen one. They're rare in these forests but the detail they etch makes it clear it is from experience rather than fanciful stories that they get their inspiration. Pointed quills are set in place of teeth that will easily sink through skin and will be a lethal combination when paired with the stone claws that could easily rend flesh off the bone. 
			
			Just what task does this human have in store for you to warrant such deadly force? You restrain your curiosity knowing that soon enough all will become clear. 
			*set head "feline"
		*if (formset = 3)
			At first you're uncertain what the human seeks to design. Heavy set jaws lined with jagged rocks as teeth, branching wooden horns, and scales etched into exposed clay. It is only once they carefully retrieve a glowing coal from the fire burning to the 
			*if (northobject = "fire")
				north,
			*if (southobject = "fire")
				south,
			*if (westobject = "fire")
				west,
			*if (eastobject = "fire")
				east,
			and push the burning ember deep into the base of the simulacra’s throat that you realise the answer.

			A dragon, and one that breathes fire none the less. An imaginative one this little human is. There is no way ${she} could have ever seen its ilk. They were long gone before her distant ancestors were ever born. The form of the lizard ${she} carves is not quite correct. Instead it carries the spark of creativity born of wild stories told around a campfire. 
		
			Nevertheless, you are fairly pleased with the result. As one not from this world, it is only fitting you should have a whimsical yet deadly form to match.
		
			*set head "dragon"
	
		*goto completeform
		
	*if (image = 0) #Though wishing you could influence the completion of the simulacra, you haven't the energy left to do so.
		*image story2_header.png
		
		*set dontchooseform +1
		The annoyance at your weakened state that prevents you from doing as you freely desire grows. Still, your wait is almost over. You can only hope the human chooses wisely. 
		
		*goto autoform


	
*label completeform

*page_break
*image story2_header.png

*comment willpower 28-70


The magic user glances at the sky, the moon now well overhead and bathing the forest in its sliver light. They take a final steadying breath then turn towards the yet lifeless clay creature.

[i]"I give you ears with which to hear the heartbeat of your prey,"[/i] ${she} intones, marking the insides of the triangular clay shapes above its head. 

[i]"A nose with which to track their footsteps wherever they may flee,"[/i] ${she} continues, slashing a fingernail across each side of its muzzle. 

[i]"And eyes that will see, even when the paths are dark and hidden,"[/i] the human concludes, pushing fingers deeply into its skull to form shadowed pits. 

Power rises as she holds ${herhis} hands out wide, beckoning to the sky. Energy swirls catching you up and pulling you through the barrier, rushing down... down... down... 

[i]"Spirit of the netherworld come forth. I bid thee to heed my summons. Arise..."[/i]


*choice
	#Kalanorya
		*set creaturename "Kalanorya"
		*goto name
	#Tyrenerat
		*set creaturename "Tyrenerat"
		*goto name
	#Caroparn
		*set creaturename "Caroparn"
		*goto name
	#Shopart
		*set creaturename "Shopart"
		*goto name
	#A different name rings through the forest. 
		*image story2_header.png
		
		The name they call, your name, is...
	
		*input_text creaturename
			
		*page_break [i]Arise ${creaturename}![/i]

		*goto name
	


*label name
*image story2_header.png

*set summoned "yes"	
*set placement "complete"

*gosub elementcheck

There is a rushing sound, the sickening feeling of being stretched, pulled and at the same time condensed and weighted down. Finally the wrenching subsides leaving you in darkness once more. No longer do you float upon the ether's currents, solid limbs anchor you to the solid earth below. A breath brings the scent of soil, trees and metalic blood to your nostrils. Ears twitch at the soft scratchings of creatures fleeing through the undergrowth, they know enough to run from your presence it seems. 

[i]Finally, you are here.[/i] 

*set willpower +15

*if (dontchooseform = 0)
	*achieve chooseform

As you settle into this new body, a flash of energy revitalises your senses as your sight swims slowly into focus revealing a weary looking human threaded with glowing lines of silver and gold. Blood drips from ${herhis} hand staining the snow by their feet crimson. Blood that brought you here, but still you crave more. Though the summoning settles like an invisible chain wrapped tightly around your throat, it has done nothing to suppress your appetite. This human is so close that their life force draws you like a moth to a flame. Their energy would sate the hunger that gnaws at your belly... at least for a while. 

*page_break Instinctually you move forward.
*image story2_header.png

You take a tentative step forward and the human gasps, drawing themselves up to their full height and tightening the magical leash with which they hold your presence here. Careful you must be, lest you be burned to ash like the moth you just considered. 
*if (unbalancedsummon != "yes")
	The sensation of being chained is as chafing as ever, but the mortal is exhausted. You may yet break free from their influence.
	
	Ears twitch you stretch new muscles while keeping a watchful eye on the one who summoned you here. Dark circles and a haunted look adorn their face, but still they stand tall and firm. 

*if (unbalancedsummon = "yes")
	Still, something is different this time. Though the human still retains some control over your actions, it seems more tenuous than any of the summons you have been brought to in the past. What have they done? 
	
	
	*if (addcreature = "snow")
		*achieve snow
		You take another experimental step forward feeling the surrounding temperature plummets. Snow hardens under your paws, while a flick of your head sends a shimmer of tiny ice crystals into the air which twist and swirl in a sparkling halo around your new form. 
		
	*if (addcreature = "smoke")
		*achieve smoke
		You take another experimental step forward, a wave of heat causing the snow to hiss and melt into steam which swirls in a restless mist around your new form. Sparks of energy arc and dance along your hide illuminating the clearing with flickering golden light. 
		
	*if (addcreature = "magma")
		*achieve magma
		You raise your head defiantly towards the sorcerer, feeling your skin morph until it traced in veins of liquid gold and silver as if burnished by metals drawn from deep within the earth. Heat shimmers from your body in waves, causing the nearby snow to hiss as it is evaporated. 
		
	*if (addcreature = "plants")
		*achieve plants
		As you contemplate your next move, you feel seeds buried within the clay of your body burst into life rapidly growing to form a covering of green shoots and leaves. What's this? You look towards the tree line, feeling a connection there as the branches sway in response and send icicles clinking to the ground. You smirk at the irony of a harbinger of death being connected however temporarily to a force for creation of life.
	 
 
	You chuckle to yourself, the sound rough and earthy. A rather serious miscalculation for this little Raishall to grant you this amount of strength for surely they would not have allowed it on purpose. You are fuelled by not one, but two elements working in synergy. It makes you far more powerful, dangerous and best of all... difficult to keep chained.
	
	You glance about, taking in the surroundings and less concerned about the Raishall who has paled with more that weariness. Ha! So they are weakened and what's that? You can taste a hint of fear carried by the air. Your eyes glow brightly with anticipation. A fearful foe is one that is all that much closer to defeat.
 

*page_break The human reaches into their pocket.
*image story2_header.png

Your mouth hangs open in a toothy grin. Your summoner has kept their nerve long enough to remember they must quickly inform you of the purpose for which you were brought here... And see if it meets with your approval. Perhaps it will be something worthy of your time. If not, well... the keen vision you've been granted can see the Raishall's fingers shake slightly as they pull a piece of torn cloth from their pocket. They have to know it is unwise to show any sign of weakness, but their frail, mortal body betrays them. 

Again they hesitate, hand deep within their pocket, but not voiceing the command for the task at hand. 
*if (tail = "cane")
	Whipping your long wooden tail back and forth in irritation
*if (tail = "vine")
	Slashing the undergrowth with your thorn covered tail
*if (tail = "rope")
	Swishing your long woven tail across the ground
you wonder why they continue to stall. The night will soon be over, and the longer they hold you here within the circle the weaker they become. It makes little sense. 

Finally, they raise their arm, a small piece of chestnut brown material fluttering between their fingertips with the motion. 

"${creaturename}," they call with a slight waver in their voice. "I am the one who has summoned you here tonight for a task of my choosing. Submit to my will and only then will you have your reward."


*choice
	#Hold your ground impassively. You resent being ordered about in such a way.
		*image story2_header.png
		
		They may have power over you, that much is true. But simple respect demands they not treat you like a whipped dog either. If they choose to treat you with such disdain, they will need to force your compliance.
		*set willpower -2
		
		"I gave you a command spectre. You will obey me," the human tries again. 
		
		Your keen hearing detects a heartbeat. You tilt your head, listening closely.
		
		[i]*Thump-thump... Thump-thump.. Thump-thump. Thump-Thump.Thump-Thump.Thump-Thump.*[/i]
		
		It gallops in a rhythm that is far too fast. They are fearful and only becoming more afraid by the second as you refuse to obey. 
		
		*goto reactionchoice
		
	#Try to leave the circle. You'll go your own way tonight. 
		*image story2_header.png
		
		Feeling righteous indignation at the gall of the human to attempt order one such as yourself using such disrespect, you decide it is time to leave. Trying to harm the Raishall directly may be risky, but if they are weak enough perhaps you can destroy the barrier that cages you.
		*set willpower -2
		
		Stalking towards the edge of the clearing, you trace the edge of the circle looking for a sign of weakness you can exploit. Each prod at the line etched into the ground only serves to send a lance of pain through your makeshift form. Unable to break through, you snarl in frustration and building rage. 
		
		Turning on the human with eyes that 
		*if (addcreature = "snow") or (addcreature = "plants")
			glint coldly with malice, 
		*if (addcreature = "smoke") or (addcreature = "magma")
			are cold and calculating despite the heat which emanates from your body in waves,	
		*if (unbalancedsummon != "yes")
			*if (northobject = "fire")
				radiate the heat of your malice,
			*if (northobject != "fire")	
				glint coldly with malice, 
		the Raishall falls back a step in alarm. Encouraged, you stalk closer still. 	
		
		*goto reactionchoice		
	
	#Pretend meek compliance. 
		*image story2_header.png
		
		You've not lived this long without learning a little patience when necessary. Trying not to growl, you bow your head in what appears to be acceptance. 
		
		Rather than seeming reassured, the Raishall seems alarmed by your easy accedence of their demands and proceeds guardedly. 

		*choice
			#This will never do. Try to leave.
				*image story2_header.png
				
				The human flinches as you turn and stalk towards the edge of the clearing. There you trace the edge of the circle looking for a sign of weakness you can exploit. Each prod at the line etched into the ground only serves to send a lance of pain through your makeshift form. Unable to break through, you snarl in frustration and building rage. 
		
				Turning on the human, you ffix them with eyes 
				*if (addcreature = "snow") or (addcreature = "plants")
					that glint coldly with malice. 
				*if (addcreature = "smoke") or (addcreature = "magma")
					that are cold and calculating despite the heat which emanates from its body in waves.	
				*if (unbalancedsummon != "yes")
					that glint coldly with malice.
			
				The Raishall falls back a step in alarm at your challenge. Encouraged, you stalk closer still. 
				
				*goto reactionchoice
		
			#Perhaps what they wish you to do will also suit your purposes. Remain 	quiet, waiting. 
				*image story2_header.png
				Though your ire rises at keeping up the pretence, you force yourself to remain still. Upsetting the human further at this point will not serve your needs whether that be to accept the task they offer... or fight it.
				
				Sweat drips from the mortal's brow despite the wintery night, the effort of keeping you contained taxing the last of their strength. They know better than to dither further despite any misgivings they might have about your appearance of seeminly docile obedience.
	
				With a show of external confidence that ${herhis} racing heart beat does not mirror, the human steps forward to throw the rag to the ground by your feet. 
				
				"You will track the owner of this piece of cloth. Find him before the night is done... And you will kill him as the chieftain's justice demands."
				
				So it is a tracking mission they have brought you here for. One that will end in blood. As to whether he deserves such a fate? It is hard to know. Humans can be fickle in their sense of what constitutes the justice they choose to meet out to their own kind. 
				
				*choice
					#Accept the command and take up the scent. If you are fed, you do not particularly care about the specifics.
						*image story2_header.png
						
						*set trackwillingly "yes"
						
						The blood that awakened you has only caused the desire for more to flare until it is almost unbearable. Which human you target means less than being able to have a time where this cruel hunger no longer gnaws at your innards. 
						
						*goto smellcloth
					
					#Accept the command... for now. You'll save your energy to reserve judgement on how you carry out the final command for later.
						*image story2_header.png
						
						*set trackwillingly "yes"
						
						The blood that awakened you has only caused the desire for more to flare until it is almost unbearable. Though you'd rather it be on your own terms, at least should you achieve your task you will leave this realm sated... at least for a little while. However the Raishall's manner of dealing with your kind leaves much to be desired. It is unwise to anger the deziens of the Abyss. You will meet this target of ${hershis}, and should you find them wanting, decide on their final fate then. You may be chained, but you doubt this yound Raishall's control will be enough to leave you devoid of all choice when the time comes.
						
						*label smellcloth
						
						Lowering your head, you inhale the scent of your intended quarry.
						
						*page_break *Snap*
						*image story2_header.png
	
						Your eyes darken as your focus moves inwards. The smell of sweat and leather fills your nostrils. In your mind's eye the image of a young man forms. Tall, dark haired and tanned from long days out under a sun you will never see. You observe his long stride making deep prints in the soft soil, the low melodic sound of his laughter. Deep brown eyes and an easy manner hide a stain on his soul though you can't tell from this distance what the secret is that his blackened heart hides. Still, from this day onwards you'd know him anywhere. Track him over mountains, rivers or lakes as may be, nothing could stop you from following his trail. And he not far. That you can feel it in your every fibre. Yes, you can find this human before the night is out should you choose. Of that you have no doubt.

						*goto inhalescent
						
					#There is one closer that seems more appealing to drink your fill. They are close now. Perhaps too close to react in time. 
						*image story2_header.png
						
						
						*set trackwillingly "no"
					
						The Raishall drew you here and made haughty demands rather than requesting your co-operation as civility demands. It seems only fitting they are the one to pay for such impertinence. Besides, you are [i]starving.[/i] The small droplets of blood you have been fed has only whet your appetite. They are here and whomever they wish you to track is likely far away. With the time wasted in the preparations for this ritual, perhaps too far for you to find before the night is over. 
						
						Making your decision, you lunge...
						
						*page_break
						*image story2_header.png
						
						*if (willpower < 46)
							*achieve failedrelease
							
							"Stop!" ${she} yells, throwing the weight of their remaining power and resolve behind the command.
							
							You find your legs freeze in place, unable to spring for their throat. Helpless you snarl in frustration. If only you were that bit more powerful, you'd have them. The human shakes visibly as the invisible bindings force you to your knees. Though they're almost out of power, you know the Raishall will not be so foolish as to let down their guard so easily again.
							
							"Y-You will track the owner of this item. Kill him. Do as you are bid ${creaturename}."
							
							The invocation of your name leaves you powerless but to obey. Lowering your head, you inhale the scent of your quarry.
							
							*page_break *Snap*
							*image story2_header.png
							
							Your eyes darken as your focus moves inwards. The smell of sweat and leather fills your nostrils. In your mind's eye the image of a young man forms. Tall, dark haired and tanned from long days out under a sun you will never see. You observe his long stride making deep prints in the soft soil, the low melodic sound of his laughter. Deep brown eyes and an easy manner hide a stain on his soul though you couldn't tell from this distance what secret his blackened heart hides. Still, from this day onwards you'd know him anywhere. Track him over mountains, rivers or lakes as may be, nothing will stop you. And he not far, you can feel it in your every fibre. Yes, you can find this human before the night is out. Of that you have no doubt.
						
							*goto inhalescent


						*comment else is a successful rebellion 
						
						"Stop!" they yell, throwing the weight of their remaining power and resolve behind the command.
						
						The force of the impact knocks you off balance to sprawl on the ground. With a snarl of anger, you shake off the compulsion climbing once more to your feet. The human's eyes widen, disbelief giving way to horror.
						
						*goto higherwillpowerreaction
						
						
						

*label reactionchoice
*page_break
*image story2_header.png

*if (willpower < 46)

	The Raishall retreats another step, hitting the invisible barrier of the circle. It seems to give them the resolve they need. 
	
	"You will obey," they intone, throwing the full weight of their will and magic behind it. 
	
	Though you struggle, you feel invisible threads of power pulling you to your knees and rendering you helpless. You snarl wildly but cannot move towards the human that holds you chained.
	
	Sweat drips from ${herhis} brow despite the wintery night, the effort of keeping you contained taking the last of their strength. They know better than to dither further.
	
	They throw the rag to the ground by your head. "You will track the owner of this cloth. Find him before the night is done. Kill him as the chieftain's justice demands."
	
	Though you struggle, your head lowers to inhale the scent.
	

	*page_break *Snap*
	*image story2_header.png
	
	Your eyes darken as your focus moves inwards. The smell of sweat and leather fills your nostrils. In your mind's eye the image of a young man forms. Tall, dark haired and tanned from long days out under a sun you will never see. You observe his long stride making deep prints in the soft soil, the low melodic sound of his laughter. Deep brown eyes and an easy manner hide a stain on his soul though you couldn't tell from this distance what secrets his heart hides. Still, from this day onwards you'd know him anywhere. Track him over mountains, rivers or lakes as may be, nothing will stop you. And he not far, you can feel it in your every fibre. Yes, you can find this human before the night is out. Of that you have no doubt.
	
	So it seems you can track the human's target successfully. But the question still remains... do you want to?
	
	*fake_choice
		#You're left with little choice, but at least you will be fed.
			*image story2_header.png
			
			*set trackwillingly "no"
			The blood that awakened you has only caused the desire for more to flare until it is almost unbearable. Though you'd rather it be on your own terms, at least should you achieve your task you will leave this night sated... at least for a while.
		
		#At long as you are given your fill, you care little. 
			*image story2_header.png
			
			*set trackwillingly "yes"
			The blood that awakened you has only caused the desire for more to flare until it is almost unbearable. Which human you target means less than being able to have a time where the hunger no longer gnaws at your innards. 
		
		#Though you cannot go against the Raishall's will, you mark them for vengeance in the future.
			*image story2_header.png
			
			*set trackwillingly "no"
			Though you rage against your binding, you cannot break free. It seems once again you will be subject to a mere mortal's wishes. Still, you will remain after this night and your memory is long. The human's face is etched into your memories now and you vow that you will meet them again, and next time you will ensure that it will not be under the conditions of their choosing.
	
	*goto inhalescent


*comment if unbalanced summon or more willpower goto next section- Successfully break through the initial control.

*goto higherwillpowerreaction




*label inhalescent
	
*page_break "Be gone!"
*image story2_header.png

With a final command, the Raishall scuffs their shoe through the etching on the ground releasing the working. You find your legs moving of their own accord as you spring into a run, 
*if (size != "large")
	all but flying through the forest. 
*if (size = "large")
	crashing thought the thick undergrowth of the forest.
In your mind's eye acts like compass, but it does not draw you north. Instead it inexorably pulls you forward towards your target. 

*goto_scene alternatetarget 
	




*label higherwillpowerreaction


The human knows they are in danger of letting the working slip completely from their control. Should they do so, you will be released to do as you wish for the remainder of your time in this realm. Given ${she} tried to shackle you, it is likely they also know that the night is unlikely to end well for them.

"Enough of this," they growl sternly, though you can all but taste the desperation that lies beneath. "I brought you here and I hold the reins of this spell I can send you back from whence you came if you displease me."

Now you really do laugh, a sound absent of mirth that chills the blood of the mortal standing before you. Too late they realise that you know full well that this threat is nothing but a desperate bluff. A single Raishall, no matter how powerful, does not have the power to dismiss you back beyond the veil against your wishes until you have the blood promised by the ritual that binds them as surely as yourself. You will have your fill or they will have to fight. After all, the only alternative they have to feeding you is to destroy your newly created form, something that even an experienced warrior would struggle to achieve.

To show such weakness so clearly invites death. There is good reason so few of their ilk grow to be old and grey. Instinctively the human takes a step backwards bumping up against the invisible edge of the barrier. Trapped, they cannot run. The only options remainint to ${herhim} are to bargain or fight.

*page_break
*image story2_header.png

Trying to regain control, the young Raishall waves an arm from side to side, the rag fluttering in their fingertips in an attempt to divert your attention from their mistake of showing such frailty in the face of one summoned to kill. 

"This is the target for which you were summoned," they say slowly, careful to keep any tremors from their voice. "It will provide you with more sustenance than one who is already drained such as I. They have no talent with the sight, you will take them down with ease. You can kill only one this night, I bid it to be one who deserves it."


*fake_choice
	#You snort in derision as if you'd believe the rantings of one human accusing another. 
		*image story2_header.png
		
		Your kind operate on a different set of rules, and this one has earnt your ire. 
		
	#You look on with renewed interest. The taste of those with blackened hearts is always better.
		*image story2_header.png
		
		Still this human has earnt your ire. You're not certain if you're ready to let that go regardless of what other quarry is on offer.

"Here, take this," the Raishall extends their hand towards you once more, 
*if (addcreature = "snow")
	the material flapping lightly in the unnatural arctic breeze circulating around the clearing.
*if (addcreature = "magma")	
	the material smoking at the edges due to the intense heat you radiate.
*if (addcreature = "plants")
	while they try their best not to flinch away from the claw like branches that reach towards them on all sides at yor bidding. 
*if (addcreature = "smoke")	
	the material flapping in the unnatural breeze circulating around the clearing. Dark scorch marks appear on the material as floating embers drift across it.
*if (addcreature = "")
	the material flapping lightly in the unnatural breeze that now circulates around the clearing.

*label rechoice
*allow_reuse

*choice
	#Accept the task. A proper hunt will be so much more amusing than ending your time on the surface here so quickly.
		*image story2_header.png
		
		You tell yourself you are not being ordered if it is your choice to accept the task offered. Besides, a run through the wilds will only extend your time away from the nothingness of the worlds that lie beyond the living realms and there is a certain thrill in hunting down a quarry that does not wish to be found. And once you find them? Well, perhaps the hold the Raishall has on you may have weakened enough for you to choose how to act. It may not be much of a challenge though. Your hunger is rising by the second. You wonder if by the time you track down the unfortunate target, you will be too ravenous to think of anything else but completing your assigned task. 
		
		Stepping forward, you touch your nose to the scrap of clothing.
		
		*set trackwillingly "yes"
		
		*goto accepttrack	
	
	#Accept the task. This human won't make for a good or certain meal. 
		*image story2_header.png
		
		The Raishall who stands before you is drained of energy and likely no more than a snack that will fail to keep you satiated for long once you return to the darkened lands. Moreover this snack has a bite, however weary they may be. You have no wish to risk being torn apart by their magic, particularly if there are easier prey being offered with which to take your fill. Perhaps you will accept the human's task and see what lies at the end of that trail instead. 
		
		Stepping forward, you touch your nose to the scrap of clothing.
		
		*set trackwillingly "yes"
		
		*goto accepttrack
	
	#Accept the task. From the darkness you may be, but that does not mean you completely lack a conscience.
		*image story2_header.png
		
		As much as the human has incited your fury with the disrespect shown by thinking to enslave your kind to their wishes and disrespectful manner, you can see into their heart and it is not tainted by any form of deliberate evil intent. Those that harbour a corrupted soul always taste so much better. For a Raishall conduct such a risky ritual, makes it highly likely that your target has done something unforgivable as human morality reckons these things. 
		
		Very well, let us see what kind of person you have been bid to hunt this night. Stepping forward, you touch your nose to the scrap of clothing.
		
		*set trackwillingly "yes"
		
		*goto accepttrack
	
	#Accept the task begrudgingly. Perhaps when released from the binding magic of this circle you may be more able to choose your actions freely.
		*image story2_header.png
		
		Though you hiss in anger at the order, still you are uncertain of your ability to take on one who holds the leash of your summons however weakened they may currently seem. One mistake and it could be your last. Defying a Raishall is a dangerous game, as potentially deadly for you as it is for them. Perhaps your best course of action is to distance yourself before then reassessing the options available. 
		
		With one last snarl, you stalk closer and touch your nose to the scrap of clothing. 
		
		*set trackwillingly "no"
		
		*goto accepttrack
	
	#Refuse. This ends now. 
		*image story2_header.png
		
		You snarl at the impertinence of a mortal who thinks to order you about, rather than ply you with gifts and praise. Still, the only way you will leave this circle is at their bidding, or by their death. Attacking the one who holds the reins of the summoning will be dangerous. In the end it could prove as perilous for yourself as to the Raishall.
		*choice
			#So be it.
				*image story2_header.png
				
				The human should know the outcome if they were desperate... or foolish enough to summon you to this place. If they want to force your compliance, they will be in for a fight. Apart from the unlikely outcome of your untimely destruction, only blood can send you home before the night is done, whether that be theirs or that of their intended victim. You will have your fill one way or the other. 
			
				*goto_scene finalattackraishall
			
			#Reconsider your actions.
				*image story2_header.png
				
				As furious and ravenous as you are, you try to calm yourself for a moment and decide if this is truly what you wish to do.
				
				*goto rechoice
		
		



*label accepttrack


Your eyes darken as your focus moves inwards. The smell of sweat and leather fills your nostrils. In your mind's eye the image of a young man forms. Tall, dark haired and tanned from long days out in the open air. You see his long stride making prints in the dirt, the low melodic sound of his laughter. Deep brown eyes and an easy manner hide a stain on his soul though you couldn't tell from this distance what secrets his heart hides. Still you'd know him anywhere. Track him over hills, rivers or lakes as may be. And he is close, you can feel it in your every fibre. 
	
*page_break

*goto inhalescent	








*comment *****GOSUB ROUTINES BELOW*****	


	
*label elementcheck

*comment north/south check

*if (northobject = "water") and (southobject = "earth")
	*set unbalancedsummon "yes"
	*set addcreature "plants"
	
*if (northobject = "water") and (southobject = "air")
	*set unbalancedsummon "yes"
	*set addcreature "snow"		

*if (northobject = "earth") and (southobject = "water")
	*set unbalancedsummon "yes"
	*set addcreature "plants"
		
*if (northobject = "air") and (southobject = "water")
	*set unbalancedsummon "yes"
	*set addcreature "snow"	

*if (northobject = "earth") and (southobject = "fire")
	*set unbalancedsummon "yes"
	*set addcreature "magma"

*if (northobject = "fire") and (southobject = "earth")
	*set unbalancedsummon "yes"
	*set addcreature "magma"

*if (northobject = "air") and (southobject = "fire")
	*set unbalancedsummon "yes"
	*set addcreature "smoke"

*if (northobject = "fire") and (southobject = "air")
	*set unbalancedsummon "yes"
	*set addcreature "smoke"	



*return








*comment east/west check and faulty north south check (I don't think this is required, keep for now.)


*if (northobject = "water") and (southobject = "earth")
	*set unbalancedsummon "yes"
	*if (element = "water") or (element = "earth")
		*set addcreature "plants"
	
*if (northobject = "water") and (southobject = "air")
	*set unbalancedsummon "yes"
	*if (element = "water") or (element = "air")
		*set addcreature "snow"		

*if (northobject = "earth") and (southobject = "water")
	*set unbalancedsummon "yes"
	*if (element = "earth") or (element = "water")
		*set addcreature "plants"
		
*if (northobject = "air") and (southobject = "water")
	*set unbalancedsummon "yes"
	*if (element = "air") or (element = "water")
		*set addcreature "snow"	


*if (northobject = "earth") and (southobject = "fire")
	*set unbalancedsummon "yes"
	*if (element = "earth") or (element = "fire")
		*set addcreature "magma"

*if (northobject = "fire") and (southobject = "earth")
	*set unbalancedsummon "yes"
	*if (element = "fire") or (element = "earth")
		*set addcreature "magma"

*if (northobject = "air") and (southobject = "fire")
	*set unbalancedsummon "yes"
	*if (element = "air") or (element = "fire")
		*set addcreature "smoke"

*if (northobject = "fire") and (southobject = "air")
	*set unbalancedsummon "yes"
	*if (element = "fire") or (element = "air")
		*set addcreature "smoke"	

	
		


*if (eastobject = "water") and (westobject = "earth")
	*set unbalancedsummon "yes"
	*if (element = "water") or (element = "earth")
		*set addcreature "plants"
	
*if (eastobject = "water") and (westobject = "air")
	*set unbalancedsummon "yes"
	*if (element = "water") or (element = "air")
		*set addcreature "snow"		

*if (eastobject = "earth") and (westobject = "water")
	*set unbalancedsummon "yes"
	*if (element = "earth") or (element = "water")
		*set addcreature "plants"
		
*if (eastobject = "air") and (westobject = "water")
	*set unbalancedsummon "yes"
	*if (element = "air") or (element = "water")
		*set addcreature "snow"	


*if (eastobject = "earth") and (westobject = "fire")
	*set unbalancedsummon "yes"
	*if (element = "earth") or (element = "fire")
		*set addcreature "magma"

*if (eastobject = "fire") and (westobject = "earth")
	*set unbalancedsummon "yes"
	*if (element = "fire") or (element = "earth")
		*set addcreature "magma"

*if (eastobject = "air") and (westobject = "fire")
	*set unbalancedsummon "yes"
	*if (element = "air") or (element = "fire")
		*set addcreature "smoke"

*if (eastobject = "fire") and (westobject = "air")
	*set unbalancedsummon "yes"
	*if (element = "fire") or (element = "air")
		*set addcreature "smoke"