*temp rgold 0


*set home "Nomad"
*page_break On Your Own
The decades passed quickly as you sought a new home and possible territory for yourself. You passed small human villages, thick elven forest, even once inspected the entrance of a dwarven mine. You caught distant glimpses of human cities and kingdoms, great elven palaces built into the trees, and once thought you could hear the thundering of Centaurs in the woods where they made their homes.
*line_break
*line_break
After three decades of traveling, inspecting caves, mountains, abandoned castle ruins, and any place that could make a suitable living area, you finally come across a nice deep cave.
*line_break
*if (size = "Large")
  You know from the start this will not last. You're already too big to fit through the entrance without great difficulty and you know once your full grown in about a century you will be unable to fit in here at all. At first you thought about keeping it as a stash for potential treasure, but you decide it's not worth it if you won't be able to get inside.
  *line_break
  With a sigh, you curl up as comfortable as you can and settle down for the night.
  *goto firstcave
*if (size = "Medium")
  You're having a hard time fitting through the entrance at first but manage to get in after some squeezing. You know in a century you'll be unable to fit into this cave, but it should do for the moment. You consider using this as a stash for potential treasure, but decide it's not worth hurting yourself getting in and out.
  *line_break
  With a sigh, you curl up as comfortable as you can and settle down for the night.
  *goto firstcave
*if (size = "Small")
  You fit through pretty easily, though when you're full grown in a century it might be a bit if a squeeze. You search the cave as thoroughly as you can and find a pool of water in the back, as well as a few smaller caves you can't get into.
  *line_break
  Looking around, you decide to use this as a stash for any potential treasure. You head outside for a moment and use your teeth to scratch a special symbol, called a Dragon Rune, to mark your first stash and settle down for the night.
  *set caves +1
  *set magick %+1
  *goto firstcave
*if (size = "Tiny")
  You have no trouble walking through the entrance and know you will never have issues. You search the cave as thoroughly as you can and find a pool of water in the back, as well as a few smaller caves you can squeeze into with little trouble.
  *line_break
  Looking around, you decide to use this as a stash for any potential treasure. You head outside for a moment and use your teeth to scratch a special symbol, called a Dragon Rune, to mark your first stash and settle down for the night.
  *set caves +1
  *set magick %+1
  *goto firstcave

*label firstcave
*page_break Daybreak
*set home "Small Cave"
You're woken with the bright sunshine on your face. Grumbling, you get up and leave the cave. Once outside, you stretch and head off for some hunting.

*page_break The Elves
You enter the forest in the distance and begin sniffing around. Deer, boars, some wild oxen, typical forest creatures. You pick up the trail of some oxen when you encounter a new smell. Fragrant, like algae and lily blossoms in the lake near your mothers den. You're too engrossed with trying to figure out what it is when a strange creature drops from the trees.
*line_break
Tall, standing on two legs, with silvery white hair cascading down it's back, the male creature is holding some kind of stick with a vine and pointing a stone edged stick at you. You blink for a moment and recognize this as an elf with a bow.
*line_break
"Kugi daʉwà!" The arrow is pointed at your snout, steady and you can smell the herbs coating the tip; they won't kill you, but they will definitely cause some damage.
*page_break
*if (start = 2)
  Your mind works for a split second before you recognize the word "Halt, dragon!" With a snort, you stare at him and speak. "Ochoga,tà ràchiva naʉgo she,shu." (No threat to you)
  *set int %+5
  *line_break
  He lowers his arrow barely an inch and speaks the common tongue, which you learned long ago. "You speak my language, dragon?"
  *line_break
  You snort again. "A little, elf." You think for a second.
  *set lang +1
  *set eknow "Yes"
  *set epro %+1
  *goto firstelf
*else
  Your mind tries to recognize what he said, but draws a blank.
  *line_break
  Without lowering his arrow, he sneers and speaks again, this time in the common tongue that you learned long ago. "What do you want, dragon?"
  *line_break
  You think for a second.
  *goto firstelf


*label firstelf
*line_break
*choice
  *selectable_if (moral <= 60) #Attack him
    With a roar, you lung at him. He's too quick though and disappears before you can strike again.
    *line_break
    With a furious roar, you stalk off into the forest for food. You realize after a time that you could have handled that better, but just shake your head and settle down with a large deer.
    *set elves 10
    *set scare %-5
    *set moral %-5
    *set moral2 %-5
    *goto decade1
  #Talk to him
    You dip your head. "I am just hunting, I'm not looking for a fight."
    *line_break
    He lowers his arrow til the tip touches the ground. "You are strange, dragon. Be careful passing through these woods; danger lurks not far from the Silver Clearing." With that, he turns and disappears into the trees.
    *line_break
    You stare after him for a moment, then turn and continue hunting, eventually bringing down a large deer.
    *set scare %+5
    *set int %+1
    *set chr %+10
    *set moral %+5
    *set moral2 %+5
    *set gods %+1
    *set ppl %+5
    *set elves 40
    *goto decade1
  #Leave
    You snort. "I am busy, elf." With that, you push past him and head into the forest.
    *line_break
    The elf watches you go then disappears into the forest.
    *set elves 25
    *set fair %-5
    *goto decade1
  *if (ability = "Lightning") #Attack with Lightning
    You glare at him for a split second then shoot a bolt of lightning from your mouth.
    *line_break
    He dodges, but you smell singed hair and skin. He looses an arrow and it strikes your leg before you can react quick enough. It stings like hell and you yank the arrow out with your teeth quickly.
    *line_break
    Before you can retaliate he's gone. With a roar and a bolt of lightning from the sky, you rush off and bring down the biggest animal you can find, a deer, and finish your hunt.
    *set elves -50
    *set moral %-50
    *set gods %-1
    *set ppl %-10
    *set moral2 %-15
    *set agi %+3
    *set health %-30
    *goto decade1
  *if (ability = "Flame Breath") #Shoot fire
    You take a deep breath and shoot a large fireball at him.
    *line_break
    He dodges, but you smell burning flesh and see a large burn on his arm. With a pained grunt, he looses and arrow but it merely grazes your leg. It stings and you shoot another fireball, but he's gone.
    *line_break
    You give a roar and a stream of fire erupts into the sky. With another roar, you continue your hunt, eventually bringing down a large deer.
    *set elves -80
    *set health %-15
    *set moral %-25
    *set moral2 %-10
    *set ppl %-5
    *goto decade1
  *if (ability = "Life Breath") #Kill him
    You breathe out slowly, the air in front of you losing color. The elf watches the strange fog warily but as it gets close he suddenly screams and tries to run.
    *line_break
    Not fast enough though. The fog, turning the air a sickly grey-green color, follows him and he collapses as it touches him. You make your way over and sniff him; he smells disgusting now, as if the fog began to rot his body immediately.
    *line_break
    With a snort, you continue your hunt. No matter how hungry you are, you could not eat [i]that[/i]. You have one thought while hunting; it wasn't entirely fair of you to use that power. With a shrug, you push the thought away and take down a large deer.
    *set elves -100
    *set moral %-80
    *set scare %-10
    *set moral2 %-25
    *set fair %-15
    *goto decade1
  *if (ability = "Basilisk Stare") #Turn him to stone
    Your eyes flash and you stare straight into his. At first he looks confused, but then you both hear a cracking sound.
    *line_break
    He looks down in time to see his legs up to his knees are turning to stone. He starts jerking, as if he can shake this off, but it begins to spread faster. He looks at you in fear as his eyes are the last to turn.
    *set elves -30
    *choice
      #Smash him
        You snort and smash your tail into the statue, shattering it. You inspect the pieces for a moment but then turn away to hunt, eventually bringing down a large deer.
        *set moral %-50 
        *set str %+1
        *set moral2 %-10
        *set scare %-5
        *set gods %-2
        *set ppl %-5
        *goto decade1
      #Ignore the statue
        You turn away, leaving the statue alone, and continue to hunt. As you bring down a large deer,  you have the thought that maybe you shouldn't have done that but shrug it off.
        *set moral %-20
        *set moral2 %-5
        *set scare %-10
        *set gods %-1
        *set ppl %-10
        *goto decade1
  *if (ability = "Frost Breath") #Freeze him
    You breathe out quickly but he's too fast for the icy mist to touch him. He looses and arrow at you and you roar in pain as you do not move fast enough. The arrow tip is imbedded in your side and he disappears as you yank it out.
    *line_break
    You growl and freeze a tree, only to smash it moments later in a brilliant display of glittering blue-white shards. You set off through the forest and freeze a couple smaller deer in anger, then settle down to enjoy a meal of frozen venison.
    *set elves -40
    *set moral %-25
    *set agi %-5
    *set health %-30
    *set scare %-5
    *set ppl %-5
    *goto decade1

*label decade1
*page_break
The next decade is uneventful, except you do manage to find a few stray ruins with a tiny amount of treasure.
*line_break
*if (caves >= 1)
  You stash some of the gold away in the cave, feeling like a true and proper dragon now that you have some gold.
  *rand rgold 1 4
  *if (rgold = 1)
    *set gold +200
    You don't find a lot, just a tiny pile, but it's enough to make you feel accomplished.
    *goto decade2
  *if (rgold = 2)
    *set gold +500
    You don't find a lot, just a small pile, but it's enough to make you feel accomplished.
    *goto decade2
  *if (rgold = 3)
    *set gold +700
    You find a small pile of gold, as well as few goblets and a chalice. Not as much as you would like, but enough to make you happy for now.
    *goto decade2
  *if (rgold = 4)
    *set gold +1000
    You find a decent pile of gold hidden in some rubble; mostly coins, but also a couple goblets, a ruby necklace, and a strange book of ancient symbols. You keep it in your stash, but read it when you get the chance; it's written in Pomaiin and gives you a boost to magickal control and understanding of the Pomaiin language!
    *set art1 "Yes"
    *achieve book1
    *set magick %+5
    *if (eknow = "No")
      *set eknow "Yes"
      *set epro %+2
      *goto decade2
    *if (eknow = "Yes")
      *set epro %+2
      *goto decade2
*if (caves = 0)
  You snort in frustration. If you could return to the cave when you're older, you use it as a stash but must leave the treasure in the ruins for the time being. Maybe when you find a bigger place you'll come back….
  *goto decade2

*label decade2
*page_break
(not done yet!)
*finish