*gosub_scene savegame save_chapter3
[b]Chapter 3[/b]

You've reached Chapter 3. Your progress from earlier in the game has been saved.

This chapter shows how to place checkpoints within a scene file.

When using checkpoints within a scene file, you must declare your variables using [b]*create[/b] in startup, not [b]*temp[/b].

An example selection of choices and checkpoints follows.
*page_break
*label butterfly
You walk along a path and see a lovely butterfly.
*fake_choice
	#Catch it.
		*set butterfly_caught true
	#Admire it.
	#Continue.
*if butterfly_caught
	You caught the butterfly!
*if (not(butterfly_caught))
	You didn't catch the butterfly.
*fake_choice
	#Restart the section about the butterfly.
		*gosub_scene savegame load_chapter3
		*goto_scene chapter_3 butterfly
	#Save and continue.

*label meet_dog
*hide_reuse
*gosub_scene savegame save_chapter3
This section uses [b]*hide_reuse[/b] to avoid repeated options.

*label meet_dog_choice
*if met_dog

	The dog barks happily.
*if (not(met_dog))
	As you're walking along, you meet a friendly dog.
*set met_dog true
*fake_choice
	#Pet the dog.
		*set dog_petted true
		You pet the dog.
		*goto meet_dog_choice
	#Throw a stick for the dog.
		You throw a stick for the dog.
		*if dog_petted
			He's extra excited because you petted him before.
		*goto meet_dog_choice
	#Walk on.
You walk further down the path.
*fake_choice
	#Restart the section about meeting the dog.
		*gosub_scene savegame load_chapter3
		*goto_scene chapter_3 meet_dog
	#Save and continue.
*page_break
*label meet_dog_again
*gosub_scene savegame save_chapter3
This section uses [b]*disable_reuse[/b] to avoid repeated options.

When you come back, the dog rolls on its back excitedly.
*label meet_dog_again_choice
*disable_reuse
*fake_choice
	#Pat the dog's head.
		*goto meet_dog_again_choice
	#Give the dog a treat.
		*goto meet_dog_again_choice
	#Walk on.

You carry on your way.
*fake_choice
	#Save and continue.
	#Restart the section about meeting the dog for the second time.
		*gosub_scene savegame load_chapter3
		*goto_scene chapter_3 meet_dog_again
	#Replay from the start of Chapter 1.
		*gosub_scene savegame load_chapter1
		*goto_scene chapter_1
	#Replay from the start of Chapter 2.
		*gosub_scene savegame load_chapter2
		*goto_scene chapter_2
	#Replay the whole of Chapter 3.
		*gosub_scene savegame load_chapter3
		*goto_scene chapter_3
	
*gosub_scene savegame save_chapter3
Then you continue on your way.

And that's it!

To view the code for this template, go
*link https://dashingdon.com/play/hannahps/savepoint-example/mygame/scenes here.
*ending