*comment Copyright 2010 by Dan Fabulich.
*comment 
*comment Dan Fabulich licenses this file to you under the
*comment ChoiceScript License, Version 1.0 (the "License"); you may
*comment not use this file except in compliance with the License. 
*comment You may obtain a copy of the License at
*comment 
*comment	http://www.choiceofgames.com/LICENSE-1.0.txt
*comment 
*comment See the License for the specific language governing
*comment permissions and limitations under the License.
*comment 
*comment Unless required by applicable law or agreed to in writing,
*comment software distributed under the License is distributed on an
*comment "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,
*comment either express or implied.

*title Gender Setting Example
*author Harris Powell-Smith
*scene_list
	startup

*comment this variable controls whether the player is asked to define NPC genders when they're met ingame
*create genderchoice false

*comment PC's personal info

*create pc_gender 1
*create pc_they ""
*create pc_them ""
*create pc_their ""
*create pc_theirs ""
*create pc_boy ""
*create pc_sibling ""
*create pc_child ""
*create pc_plural true
*comment the pc_say variable controls whether or not verbs will be pluralised.
*comment Rather than having to write '$!{pc_they} @{pc_plural say|says} the sky is blue' it saves time, and reduces errors, to write '$!{pc_they} ${pc_say} the sky is blue'
*comment You can include as many of these as you like if there are particular verbs that gender-selectable characters use a lot.
*create pc_say ""

*comment Freddie's personal info

*create freddie_rand 0
*create freddie_singular true
*create freddie_gender 1
*create freddie_they ""
*create freddie_them ""
*create freddie_their ""
*create freddie_theirs ""
*create freddie_title ""
*create freddie_child ""
*create freddie_firstname ""
*create freddie_say ""

*comment Gonzalez's personal info

*create gonzalez_rand 0
*create gonzalez_singular true
*create gonzalez_gender 1
*create gonzalez_they ""
*create gonzalez_them ""
*create gonzalez_their ""
*create gonzalez_theirs ""
*create gonzalez_title ""
*create gonzalez_child ""
*create gonzalez_say ""
	
You can form romances or partnerships with some side characters, and they can have varied genders (male, female, and non-binary) on each playthrough. How would you like the genders to be set?
*choice
	#Randomize the genders of variable side characters.
		*rand freddie_rand 1 3
		*if freddie_rand = 1
			*gosub freddie_male
			*goto gonzalez_randomize
		*elseif freddie_rand = 2
			*gosub freddie_female
			*goto gonzalez_randomize
		*elseif freddie_rand = 3
			*gosub freddie_nb
			*goto gonzalez_randomize
		*else
			*bug freddie_rand is ${freddie_rand}; expected value 1-3
		*label gonzalez_randomize
		*rand gonzalez_rand 1 3
		*if gonzalez_rand = 1
			*gosub gonzalez_male
			*goto npcgenders
		*elseif gonzalez_rand = 2
			*gosub gonzalez_female
			*goto npcgenders
		*elseif gonzalez_rand = 3
			*gosub gonzalez_nb
			*goto npcgenders
		*else
			*bug gonzalez_rand is ${gonzalez_rand}; expected value 1-3
	#Pick a single gender for all variable side characters.
		All side characters with variable genders will be:
		*choice
			#Female.
				*gosub freddie_female
				*gosub gonzalez_female
				*goto npcgenders
			#Non-binary.
				*gosub freddie_nb
				*gosub gonzalez_nb
				*goto npcgenders
			#Male.
				*gosub freddie_male
				*gosub gonzalez_male
				*goto npcgenders
	#Choose the genders of variable side characters as you play.
		*set genderchoice true
		*goto npcgenders

*label npcgenders
*if genderchoice
	When you meet Freddie...
	*fake_choice
		#He introduces himself.
			*gosub freddie_male
		#She introduces herself.
			*gosub freddie_female
		#They introduce themself.
			*gosub freddie_nb
	Then Gonzalez shows up.
	*fake_choice
		#He says hello.
			*gosub gonzalez_male
		#She says hello.
			*gosub gonzalez_female
		#They say hello.
			*gosub gonzalez_nb
	*goto pronouns
*else
	When you meet Freddie, ${freddie_they} @{freddie_singular introduces|introduce} ${freddie_them}self and ${freddie_say} hi.

	Then Gonzalez shows up. $!{gonzalez_they} ${gonzalez_say} hello too.

*label pronouns
*page_break
What do you want your main character's pronouns to be?
*choice
	#He/him.
		*gosub pc_male
		*goto genderfeedback
	#She/her.
		*gosub pc_female
		*label genderfeedback
		Characters in the game will refer to you with the pronouns ${pc_they}/${pc_them}/${pc_their}, as in: "$!{pc_they} @{pc_plural survey|surveys} the shop windows, wondering what ${pc_their} sister would buy for ${pc_them}."

		Is that right?
		*choice
			#Yes.
				*finish
			#No.
				*goto pronouns
	#Something else. [enter your own]
		*gosub pc_nb
		*label pronounselect
		Please enter your subjective pronoun (for example, he, she, they).
		*input_text pc_they
		Please enter your objective pronoun (for example, him, her, them).
		*input_text pc_them
		Please enter your possessive pronoun (for example his, her, their).
		*input_text pc_their
		Do your pronouns work best with singular or plural verbs?
		*fake_choice
			#Singular (for example "he says", "she says").
				*set pc_plural false
			#Plural (for example "they say".)
		Characters in the game will refer to you with the pronouns ${pc_they}/${pc_them}/${pc_their}, as in: "$!{pc_they} @{pc_plural survey|surveys} the shop windows, wondering what ${pc_their} sister would buy for ${pc_them}."

		Is that right?
		*choice
			#Yes.
				*finish
			#No.
				*goto pronounselect

*label freddie_male
*set freddie_they "he"
*set freddie_them "him"
*set freddie_their "his"
*set freddie_theirs "his"
*set freddie_title "Mr."
*set freddie_child "son"
*set freddie_firstname "Frederic"
*set freddie_say "says"
*return

*label freddie_female
*set freddie_gender 2
*set freddie_they "she"
*set freddie_them "her"
*set freddie_their "her"
*set freddie_theirs "hers"
*set freddie_title "Miss"
*set freddie_child "daughter"
*set freddie_firstname "Winifred"
*set freddie_say "says"
*return

*label freddie_nb
*set freddie_gender 3
*set freddie_singular false
*set freddie_they "they"
*set freddie_them "them"
*set freddie_their "their"
*set freddie_theirs "theirs"
*set freddie_title "Mx."
*set freddie_child "child"
*set freddie_firstname "Robin"
*set freddie_say "say"
*return

*label gonzalez_male
*set gonzalez_they "he"
*set gonzalez_them "him"
*set gonzalez_their "his"
*set gonzalez_theirs "his"
*set gonzalez_title "Mr."
*set gonzalez_child "son"
*set gonzalez_say "says"
*return

*label gonzalez_female
*set gonzalez_gender 2
*set gonzalez_they "she"
*set gonzalez_them "her"
*set gonzalez_their "her"
*set gonzalez_theirs "hers"
*set gonzalez_title "Miss"
*set gonzalez_child "daughter"
*set gonzalez_say "says"
*return

*label gonzalez_nb
*set gonzalez_gender 3
*set gonzalez_singular false
*set gonzalez_they "they"
*set gonzalez_them "them"
*set gonzalez_their "their"
*set gonzalez_theirs "theirs"
*set gonzalez_title "Mx."
*set gonzalez_child "child"
*set gonzalez_say "say"
*return

*label pc_male
*set pc_gender 1
*set pc_they "he"
*set pc_them "him"
*set pc_their "his"
*set pc_boy "boy"
*set pc_sibling "brother"
*set pc_child "son"
*set pc_say "says"
*return

*label pc_female
*set pc_gender 2
*set pc_they "she"
*set pc_them "her"
*set pc_their "her"
*set pc_boy "girl"
*set pc_sibling "sister"
*set pc_child "daughter"
*set pc_say "says"
*return

*label pc_nb
*set pc_gender 3
*set pc_boy "student"
*set pc_sibling "sibling"
*set pc_child "child"
*set pc_say "say"
*return