*sm_save 0 | false | Start of Forest

*TEMP wyvernaorder ""
*TEMP defended false

[b]The Forest[/b]

The forest is indeed shady — more shadows than light, in truth. The foliage is as thick as the fecund odor that stifles your breaths.

*IF art and not(whoaway="Art")
	"Ah, the rank scent of the living earth," Art mutters. "Us dwarves know it well."
	
	*IF tekoa
		"Because you're so short?" Tekoa asks.

		Art frowns. "Aye."

		*IF (ghinty) and not(whoaway="Ghinty")
			Ghinty says, "It's not the stature of the creature, it's the mass of the blast!" The goblin mage twiddles her fingers to produce a poof of fire and smoke.

			Oferi says, "Save that for the bandits, Ghinty."

	*IF (ghinty and not(tekoa)) and not(whoaway="Ghinty")
		Ghinty says, "That's because this is what dwarves smell like!"

		Art says, "Aye, and goblins smell like..."

		"Rose farts!" Ghinty says, giggling.

		"Flowers don't fart!" Art asserts.

		"You have to sneak up on them and listen closely," Ghinty says. "They're very shy with their toots."

*IF kerwain
	"I haven't traveled this way before," Kerwain says, "but I have ridden through the King's forests in the north." He looks around, grimacing. "It seems no two woods are alike."

	*IF lish and not(whoaway="Lish")
		"Same in my experience," Lish says, grinning at him.

*IF finnur and not(whoaway="Finnur")
	"Sacred are the forests and sage are the trees."

	Oferi says, nodding, "We elves believe the same."

	"Only your kind fells the trees for spears and arrows. Implements of war, Oferi."

	She shrugs. "Well [i]your[/i] kind shits in the forest. We all do crappy things, don't we?"

	Finnur gazes at her for a moment. Finally, he says, smiling faintly, "Yes. We do."

*IF ghinty and not(whoaway="Ghinty")
	Ghinty moans. "My tummy is bubbling something fierce! Where are those tasty pastries?!"

*IF (whoaway="Finnur")
	Finnur is suddenly with the group again. You didn't hear a single sound when he approached and apparently neither did anyone else.

	"Soft sweets for sinners and saints," Finnur says, handing out small packages to everyone.

	*IF wyverna
		"Fitting," Wyverna says, "for zay taste of heaven and zan go zroo hell."

		"Ah," Finnur says. "Disgusting."

*IF (whoaway="Tekoa")
	Everyone stops and spins around, combat-ready, when the flutter of fabric sounds behind you.

	Tekoa jogs up to the group — her ugly, oversized robe loudly swishing about — and starts tossing small packages to everyone.

	"Apologies for the delay," she says, "I ran into an old debtor — quite literally — and had to explain why I had no money yet many pastries."

	Oferi raises her eyebrows. "Okay, I'll bite: how'd you explain that?"

	"A quick punch to the noggin," Tekoa says. "His noggin, I mean. Not mine. Honestly, Oferi, I don't think punching [i]myself[/i] would have solved anything."

	*IF art
		Art says, "Oh, I'm sure that's all well and settled then!"

	*IF kerwain
		"Quite a blackguardly story," Kerwain says, shaking his head. "Debtors and violence! You are on the wrong path, madam."

	*IF finnur
		Finnur says, "Perhaps a moment to explain would have sufficed."

		"That takes like, four times as long as a fist to the cheek," Tekoa says. "It's time management, buddy."

*IF (whoaway="Ghinty")
	A great plume of fog suddenly bursts into existence in the front of the group. Everyone drops into various combat stances and Oferi clutches the hilt of her sword, white-knuckled and bicep straining.

	"Behold!" Ghinty says, and then breaks down into a sputter of coughing. "Ugh! Too much showmanship. [i]Way[/i] too much."

	"Dammit, Ghinty," Oferi says, relaxing and taking a deep breath.

	*IF art
		Art rolls his head about and cracks his knuckles. "Ah, yer right lucky I didn't roast you, pickleskin."

		"Uh huh," Ghinty says, nodding at Art with wide eyes and a silly grin on her face.

		Art crosses his arms. "Well, did ya burn the pastries with yer blasted palor tricks?"

	"Sorry." Ghinty holds up a bundled sack. "Ah, smoked pastries anyone?" She unwraps the bundle and hands out smaller packages to everyone.

	*IF lish
		Lish says, "Haven't tried them smoked before! I'm excited!"

*IF (whoaway="Lish")
	"Weeoooweeooo!" a voice shouts from the forest behind you. Everyone turns and stares, half confused and half ready for a fight.

	Lish comes bounding around the trees and doesn't stop her sprint until she's right at the group. She stumbles a bit at the stop then braces her hands on her knees and swallows a few times trying to catch her breath.

	From where you stand, you can see right down Lish's tunic! You...
	*FAKE_CHOICE
		#...make it obvious that you're getting an eyeful so Lish will notice you noticing.
			Lish goes wide-eyed when she realizes that you're openly oogling her. She draws her hand over her chest and stands up, smiling sheepishly. Her cheeks flush red.
			*SET dig_lish %+10
			
		#...look but make sure you're sneaky about it so you're not caught staring.
			As furtive as you are with your glances, you think Lish saw you looking. She stands up, smiling sheepishly, and her cheeks flush red.
			*SET dig_lish %+20
			
		#...turn away, feeling a little flustered about what you've already seen.
			You quickly turn away, feeling a heat rush in your face and tingle on your cheeks.				

	"I... got... food," she says, holding up a bundled sack.

	Oferi frowns. "Lish, if you were running that fast, you would have caught up with us a long while back."

	"Oh, that!" she says. "Turns out my fourty coin credit was... ah... a fourty coin [i]debt[/i]." She gives Oferi a sheepish smile. "You know I, uh, eat lots of pastries."

	*IF kerwain
		Kerwain looks at the pastry that he's already half eaten. "You've [i]stolen[/i] these?"

	"Lish," says Oferi, shaking her head.

	*IF ghinty
		Ghinty laughs and takes a large bite of the pastry in her hand. "If you ask me — which you should — stolen pastries [i]always[/i] taste better than the non-stolen variety."

	"Ah, yeah, I did steal them, technically." Lish shrugs and tries another smile on Oferi. "Think you can talk to the town guard for me?"

	"We will all pitch in for the cost to pay the bakery for the goods," Oferi says, "but the fine for petty theft will come out of [i]your[/i] pay for this assignment."

	Lish nods. "Deal."

	*IF kerwain
		Kerwain sighs. "I'm conflicted," he says around the hunk of pastry in his mouth.

		"Don't frown all pruney like that, it ruins your symmetry, big guy," Lish says, reaching up to pat Kerwain on his armored shoulder. "And don't worry about it, we'll pay for them when we get back."

*IF (whoaway="Art")
	The sounds of horsehooves grows louder from behind the group. Everyone stops and spins around, combat-ready, as a horse with two riders approaches the group.

	Art slides off the horse when it stops. He stumbles forward a bit but catches himself and makes to dust off his clothing before facing the group. The other man on the horse gives the group a nod and rides back the way he came.

	"Was offered a ride," Art explains as he hands out packages of pastry. "It'd be rude to turn the man down."

	Oferi nods to him. "Glad to have you back so soon."

	"Aye," Art says. "And you lot will be paying me back for these, of course!"

	"We'll settle up when we're all paid, my friend," Oferi says with a nod.

	"Good enough, then."

	*IF ghinty
		"We're not pitching in for the transportation, ya lazy git," Ghinty says.

		"I told ya, he offered a ride!" Art grumbles.

		Ghinty laughs. "Ha! Like any respectable person wants a dwarf bouncing around behind 'em!"

		Oferi snorts into her fist, trying not to laugh.

*FAKE_CHOICE
	#Take two pastries.
		[i]Why hasn't anyone thought of this? Two pastries! It's first and second breakfast in one meal![/i]
	
	#Take three pastries.
		[i]Well, you haven't eaten in a while and, besides, you were never a fan of even numbers.[/i]
	
	#Take four pastries!
		[i]Damn the torpedoes and the tummy-aches! If you eat enough of them, you'll surely gain an immunity to their delicious powers sooner or later.[/i]


The group continues into the forest but more slowly given the sticky trickiness of pastry consumption. You soon finish your portion of the delicious delicacies and have to resort to licking at your fingers.

*IF art
	Art lets out a satisfied burp.

*IF ghinty
	Ghinty says, "I feel the sugary alchemy at work already! Ahahahaha!"

*IF lish and (whoaway="Ghinty")
	"My gosh!" Lish exclaims. "They ARE better smoked!"

The group enters a small clearing in the forest.
*IF wyverna
	Wyverna suddenly stops and looks around, eyes narrowed. She whispers, "Zar is an ambush ahead. Bandits in the trees on za left and za right."

	*IF kerwain
		"Defend our charge," she tells Kerwain. The knight swiftly takes position in front of you, shield at the ready.

	*IF finnur
		Wyverna turns to Finnur and motions to the left. Finnur fleetly sheds his clothing. His motley rags scatter as he leaps into action. You barely catch a glimpse of his wiry tail and the perky cat ears on his head before he skitters away through the brush in the direction indicated by Wyverna.

	*IF tekoa
		After a glance at Tekoa, Wyverna makes a gesture with her hand to the right. Tekoa whips her robe away, revealing that her awkward bulkiness was only due to the leather harness she wears. Myriad knives, daggers, and throwing blades are latched to the straps tightened around her brawny arms and thick thighs. She draws two curved blades from her trappings and springs off towards the right with an acrobatic vault, disappearing into the forest.

	*IF ghinty
		"Now, Ghinty!" Wyverna orders. "Light zam up!" With a twist of her wrist and a fist clutched in the air, Ghinty lights up the forest ahead as if the sun itself was down for a visit.
		
	*IF lish
		*IF ghinty
			"You have your light, ranger! Maim one of zose bastards!" she orders of Lish. In one fluid motion, Lish drops to a knee, brings her rifle up, and fires without even seeming to aim. A cry from the forest ahead evinces that her shot was true.

		*IF not(ghinty)
			"Ranger! Maim one of zose bastards!" she orders of Lish. In one fluid motion, Lish drops to a knee, brings her rifle up, and fires without even seeming to aim. A cry from the forest ahead evinces that her shot was true.

		*IF kerwain
			"A fine shot!" Wyverna exclaims. "Keep at it!"

			Lish nods and quickly reloads.

		*IF not(kerwain)
			"A fine shot!" Wyverna exclaims. "Stay with our charge and defend at range!"

			Lish nods and quickly reloads.

	Wyverna pulls the long scarf from around her neck and whips it in the air — literally. The fabric of the scarf falls away and reveals a long leather lash. She cracks it over her head with a flick of her slender arm and a clap of thunder rattles the forest.

	*IF art and not(ghinty)
		"Auferi, Art, you are with me! Dwarf, ready that fire in your belly!"

		Art nods and both he and Oferi trail Wyverna as she sprints towards the tree line ahead, her whip slithering in the grass behind her like an obedient snake.

	*IF ghinty and not(art)
		"Auferi, Ghinty, you are with me! Ready your thunder, wizard!"

		Ghinty grins, eyes wide, and both she and Oferi trail Wyverna as she sprints towards the tree line ahead, her whip slithering in the grass behind her like an obedient snake.

	*IF art and ghinty
		"Auferi, Ghinty, Art, you are with me! Ready your fire!"

		The group trails Wyverna as she sprints towards the tree line ahead, her whip slithering in the grass behind her like an obedient snake.

	*IF not(art) and not(ghinty)
		"Auferi, you are with me!"

		Oferi nods and sprints alongside Wyverna towards the tree line ahead, her whip slithering in the grass behind her like an obedient snake.
	
	*PAGE_BREAK
	*GOTO aftertactics

*IF tekoa
	"Trouble," whispers Tekoa.

*IF finnur
	Finnur stops and looks about. "I feel... unrest in the forest."

An arrow zips by Oferi's head. Another buzzes the wind as it whips past your own ear.

*PAGE_BREAK

"Down!" shouts Oferi, dropping to a crouch and yanking her ponderous sword from its scabbard.

*IF tekoa
	"Poor shots," Tekoa says, shaking her head.

*IF finnur
	Finnur waves for you to stay down. "Wild, but deadly just the same."

*IF kerwain
	Kerwain stands his ground, batting arrows out of the sky with his shield. "Cowards!" he shouts, thrusting his sword at the forest ahead. "Where is your HONOR?!"

*IF art
	"Ay, bandits!" Art shouts. "It's proper manners to parlay first, ya rotten mongrels!" He brings his gnarly hands out to his sides and a geyser of rolling flames erupts from his howling mouth. The fire swirls into the air and dissapates, leaving the trees ahead smoking but thankfully not alight.

*IF tekoa
	Tekoa whips her robe away, revealing that her awkward bulkiness was only due to the leather harness she wears. Myriad knives, daggers, and throwing blades are latched to the straps tightened around her brawny arms and thick thighs. She draws two curved blades from her trappings and springs off towards the right with an acrobatic vault, disappearing into the forest.

*IF (finnur) and (tekoa)
	Finnur, too, fleetly sheds his clothing. His motley rags scatter as he leaps into action. You barely catch a glimpse of his wiry tail and the perky cat ears on his head before he skitters away through the brush on the left.

*IF (finnur) and not(tekoa)
	Finnur fleetly sheds his clothing. His motley rags scatter as he leaps into action. You barely catch a glimpse of his wiry tail and the perky cat ears on his head before he skitters away through the brush on the left.

*IF ghinty
	With a twist of her wrist and a fist clutched in the air, Ghinty sends several bolts of slim lightning down into the trees ahead. Panicked screams and shouts follow each strike.

*IF kerwain
	Kerwain swiftly takes position in front of you, easily blocking incoming arrows with his sturdy shield.

*IF lish
	In one fluid motion, Lish drops to a knee, brings her rifle up, and fires without even seeming to aim. A cry from the forest ahead evinces that her shot was true.

"Parlay! Parlay!" several voices call out repeatedly.

"${name}, stay here and stay down. Your presense might... complicate things," Oferi says. She advances toward the shouting voices. 
*IF art
	Art accompanies Oferi, fist held up in a ready boxer's stance.

*IF ghinty
	Ghinty disappears in a puff of smoke.

*IF lish
	Now with her blunderbuss drawn, Lish skirts the edge of the clearing towards the bandits.

*IF kerwain
	"Do not fear, ${name}. No harm shall come to you this day!" Kerwain vows, standing in front of you with sword and shield at the ready.

	*SET defended true
	*GOTO kerwaindefends

You're left alone, crouched low on hands and knees.

*PAGE_BREAK
Long, quiet minutes pass.

Then, from out of the treeline ahead, a burly bandit appears. He advances toward you in a purposeful stride, a well-used longsword perched on his shoulder. His scarred face is made even more menacing with a crooked smirk on his lips.

He obviously sees you and will be upon you imminently. Your heart thumps in your ears. Your mouth is dry. Your party is... [i]dead?[/i] Was it an ambush? How many... he only a moment away! The longsword eases off his shoulder...

*CHOICE
	#You have no choice! You're going to die! You have to use... [i]the spell[/i].
		*GOTO explodiousblowupicus
	#Give up and hope he lops your head from your shoulders with one clean swing.
		*GOTO luckedout
	#Wait! You could hide in your lantern... but what might happen to you then?
		*GOTO stayingin

*LABEL explodiousblowupicus

You quickly chant [i]the spell[/i]. The only spell that the spiteful old wizard taught you. The spell that, for you to learn, ended the lives of many rabbits. [i]Explosively.[/i]

The bandit drops his smirk and his longsword. He looks like he's about to burp, about to be sick, about to...

The sound is sickening: a wet, sloppy eruption and crackling and wailing all at once. The bandit, more liquid than anything else now, rains down in the clearing and dapples you in red. A few odd chucks of cartilage and some bone splinters bespeckle your skin.

*IF defended
	"Good mercy..." Kerwain whispers. He lowers his sword. The weapon slips from his lax fingers and falls into the grass. He stares at the mess that was once the bandit leader.

You gag and turn away. You had never been that close to the rabbits when they... [i]popped[/i]. The sickness you remember from those days learning the spell washes over you again. It's the same sickness you felt when you snuck away with a bottle of Tarson's wine.

"What the—"

You look up to see Oferi staring down at you, eyes wide and mouth agape.

*IF art
	Art lumbers up beside Oferi. His lip curls and he groans. "Did that man... fall apart? Violently?"

"You, what, blew him up?" Oferi asks.

*IF ghinty
	"Wow! What nasty wizardry," Ghinty says from somewhere behind you. "You've lost a few days of your life for that cast, ${name}."

*FAKE_CHOICE
	#"I just thought he might look better that way. Turns out, not so much."
		*IF snarky
			*SET arrpee +10

	#"That's the only spell the wizard taught me. It doesn't work on him though. I tried."
		*IF bitter
			*SET arrpee +10

	*IF not(defended)
		#"I thought everyone... I... I thought he was going to murder me."
			*IF naive
				*SET arrpee +10
	*IF defended
		#"I thought... I didn't want Kerwain to have to do it..."
			*IF naive
				*SET arrpee +10

	#"Hey, why are we blaming me? Maybe he blew up on his own! Yeah? Ok, no. Fine. It was me."
		*IF lively
			*SET arrpee +10

	*IF lively or (snarky or bitter)
		#Just shrug

	*IF naive
		#Just nod

"I'll renegotiate the terms," Oferi says. She turns and heads back to the bandits hiding in the forest.

*IF ghinty
	"That magic is wicked," Ghinty says. "Your master must be powerful to have taught you it — and probably foul as a ghoul's marrow, too."

*IF finnur
	Finnur says, "That spell is assuredly costly. You must have truly feared your death was upon you."

*IF wyverna
	"I know zat sort of magic steals your temperance," Wyverna says with a nod. "We will need to rest a mo-mend for ${himher} to regain ${hisher} sobriety."

You look up, feeling woozy. Everyone is standing around you, looking concerned and maybe even repulsed.

*IF defended
	Kerwain turns to look at you, but his expression is blank underneath the sprinkle of peppering of blood across his face.

*IF tekoa
	Tekoa grabs her robe from the ground and says, "Here, you can wipe yourself off with this. It's ugly anyway."

	You try to shake your head but your body is sluggish in responding. She tosses the robe to you and it disintegrates when it touches your outstretched hand, causing a shower of ash to fall over you and stick to the droplets of blood on your skin.

	"Ah," Tekoa says, flinching. "Oops." She huffs. "That... definitely made it worse."

	*IF art
		"Twas a right ugly thing, Tekoa," Art says, "and so no loss for being lost."

		*IF ghinty
			"Coming from a tasteless dwarf, that's saying something!" Ghinty says.

		"I was more concerned about the dust I just threw all over ${name}, Art."

		"Ah, that." Art nods. "[i]That's[/i] a right mess."

Oferi returns to the group, smiling. "Well," she says, "they didn't like him anyway. So no harm done. The toll is paid and we've free rein in the forest now. I even got you this to use to defend yourself, if you like." She stabs a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"All right," Oferi says, "let's march!"

*IF lish
	Lish says, "I'm sure ${name} would like to wash up, Oferi. We should take a detour by the lake. It's not that far."

*IF finnur and not(lish)
	Finnur says, "We should visit the lake for ${name}'s sake, Oferi."

*IF finnur and lish
	"I quite agree," Finnur says. "We shoudl visit the lake for ${name}'s sake, Oferi."

*IF tekoa and (not(finnur) and not(lish))
	Tekoa says, "I made a mess of ${name}. We should stop by the lake for ${himher}."

*IF tekoa and (finnur or lish)
	Tekoa says, "I did make a mess of ${name}. We should stop by the lake for ${himher}."

With a sigh, Oferi nods. "Fine. But we'll have to double-time it from there through the marsh or we'll be sleeping in the muck tonight."

*IF art
	"Sleeping, aye, 'til we're eaten by crocolisks," Art grumbles.

*GOSUB wizsol

*GOTO lakedetour

*LABEL stayingin
*COMMENT hid in the latern

You search in the grass for your lantern — it fell aside when you ducked from the arrows — but thankfully you find it quickly. A twist of the right knob and [i]*poof*[/i] you're safely inside.

Through the glassy wall of your home you watch as the bandit looks around the clearing in an attempt to determine where you went. He spots your lantern, frowns, and leans over to retrieve it. You crouch to keep from tumbling over as he picks up the lantern. When he lifts the lantern to peer inside, a familiar sick feeling overcomes you — as if your stomach slipped down into your feet.

"Oh, hello!" the bandit says, showing off his oddly sharp teeth with a wide grin as he stares at you through the glass. "What a trick! Are you some fairy or sprite?"

Oferi steps up beside him, frowning. "I wasn't aware ${heshe} could do that, good sir." To you, she says, "${name}, this is [b]Don Etsillo[/b], Captain of the Forest Keepers. He wished to have a word with you after our parlay."

The rest of the group walks up and stands around the bandit Don Etsillo.

"How much do you want for this fairy?" he asks.

"$!{sheis} no fairy, good sir, but a charge we are escorting to the sorcerer's tower."

*FAKE_CHOICE
	*IF snarky
		#"Hey! I'm not for sale, you googly-eyed snaggle-toothed half-wit!"
	*IF lively
		#"If I were a fairy I'd turn you into a toad! If fairies can do that. I don't know!"
	*IF naive
		#"Sir, I am no fairy! Please, listen, it's the truth!"
	*IF bitter
		#"Buying me would be the biggest mistake of your life! I'd make damn sure of it!"
	#Keep quiet

"Ah-ah! [i]This[/i] is a fairy if I've ever seen one." The bandit peers into the lantern with narrowed eyes. "I will return your toll, tripled, for this fairy."

*IF art
	Art says, "Bah, if ${heshe} were a true fairy, yer offer would be insulting!"

*IF ghinty and not(art)
	"That's ridiculous!" Ghinty says. "A real fairy would be worth twenty tolls or more."

*IF ghinty or art
	"But you've pulled it's wings off," Don Etsillo says. "For it being damaged, I must detract a goodly sum."

"I'm sorry, Don Etsillo," Oferi says, "but I cannot sell you this person. We have been hired to escort ${himher} and we will not forsake our duty."

"It pains me to hear it." The bandit sighs, lowering the lantern to his side and making you feel as if your stomach crawled into your head. "I will return your toll and we will slaughter you in a righteous fray. And then we will take your toll. And the fairy." He shrugs. "It seems a bad deal for you, but it is your choice."

Oferi scowls and says, "I am done with your foolishness. Hand over the lantern and let us go about our business or die where you stand."

"Ha! I am Don Etsillo! I am the leader of the great Forest Keepers! You cannot command me! My men—"

Oferi sighs, waves her hand in dismissal, 
*IF tekoa
	and Tekoa interrupts the bandit's speech by deftly lopping off his head with a flick of her daggers.

	*GOTO dondone
*IF wyverna
	and Wyverna stops the bandit's speech — and the rest of his life — with a quick chop of her hand to his throat.

	*GOTO dondone

*IF ghinty
	and Ghinty snaps her fingers, bringing the bandit's speech to a shocking conclusion with a precision bolt of lightning from the sky.

	*GOTO dondone
*IF art
	and Art ends the bandit's ranting with an uppercut to the jaw so hard his head flops over backward on his shoulders.

*LABEL dondone
*PAGE_BREAK

Your lantern tumbles into the grass, causing you to topple around inside it. You bounce your shoulder off the glass and skin your knee on the flooring but a quick check over yourself thankfully proves you're not badly injured.

"I'll renegotiate the terms," Oferi says, turning to head back to the bandits hiding in the forest.

*TEMP whoturns ""

*IF finnur
	*SET whoturns "Finnur"
	Finnur carefully retrieves your lantern from the grass.

	"${name}? You appear to be no worse for the wear but, just to be safe..." He presses his clawed hand against the glass of the lantern. You feel an eerie warmth pulse through your body — a disconcerting feeling for someone who has been immune to temperature for many years — but you feel much better after the sensation passes.

	"That should ease any discomfort," Finnur says. "Now, how does one go about releasing you from this contraption?"

	*GOTO pickedup

*IF lish
	*SET whoturns "Lish"
	Lish carefully retrieves your lantern from the grass. "Are you okay?" she asks, peering in. "Hey, just how the heck do we get you back out of there?"

	*GOTO pickedup

*IF ghinty
	*SET whoturns "Ghinty"
	Ghinty retrieves your lantern from the grass and peers inside at you. "Hey, look at you! Impressive magics at work here. When we're done with this quest you gotta introduce me to your wizard, ${name}. I got loads of questions!"

	*GOTO pickedup
*IF tekoa
	*SET whoturns "Tekoa"
	Tekoa retrieves your lantern from the grass and peers inside at you. "Seems to be unharmed," she says to the group. "How do we get you out of here, ${name}?"

	*GOTO pickedup
*IF kerwain
	*SET whoturns "Kerwain"
	Kerwain retrieves your lantern from the grass and peers inside at you. "Thankfully, ${heshe} appears to be unharmed," he says to the group. "How do I get you out of here, ${name}?"

*LABEL pickedup

*IF art
	"Might be best to leave ${himher} in there, aye?" Art says. "We'll make better time not having to worry on ${himher} keeping up!"

	*IF lish
		Lish shakes her head. "No, we can't just leave ${himher} in there, Art. That's cruel."

*IF wyverna
	"Zis is very interesting magics, ah-no?" Wyverna says. "It would take a powerful magician indeed to create such a wonderous enchant-mend."

*IF ghinty
	"Aww, ${sheis} so cute all small and tiny in there!" Ghinty squeals. "I wanna keep ${himher}!"

You gesture to the knob at the side of the lantern that will release you. ${whoturns} twists the knob you are pointing to and in a [i]*poof*[/i] you are once again outside the lantern and at your usual height.

"Interesting," ${whoturns} says, carefully handing you your lantern.

Oferi returns to the group, smiling. "Well," she says, "they didn't like him anyway. So no harm done. I even got you this to use to defend yourself, if you like." She stabs a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"All right," Oferi says, "everyone ready?"

*IF art
	"We'll be caught in the marsh come nightfall," Art grumbles.

*IF wyverna
	Wyverna says, "We must make haste. Za marsh is not pleas-and in the light and even less so in za dark."

	"What are you scared of?" taunts Oferi.

	"Za same zhings of which you are scared, Auferi, only I have the strength to admit it."

*IF snarky
	*SET dig_oferi %+10
	You say, "I guess even bandits have taste in people. And Don [i]Whatshisbutt[/i] tasted like jerk."

*IF lively
	You say, "I guess being Captain of the Forest Keepers is a cutthroat livelihood! Aha!"

	*IF tekoa
		*SET dig_tekoa %+10
		Tekoa laughs but covers her mouth to muffle it when everyone looks at her.

*IF bitter
	You say, "Poor Don [i]Whateverhisnamewas[/i]. It's a thankless job, being martyr to morons."

*IF naive
	*SET dig_lish %+10
	You say, "I wish he would have listened to reason. I hope this lesson will serve him wherever he has gone."

"No matter. The toll is paid and we've free reign in the forest now. Let's march!" Oferi starts through the forest once again, waving for everyone to follow.

*IF art and snarky
	Art strides beside you, frowning. "What did ya mean about tasting people?"

	"$!{heshe} didn't mean [i]eating[/i] people, Art," Oferi says, laughing.

	"Ah. Good." Art nods, seemingly satisfied.

*IF finnur and bitter
	Finnur starts walking beside you. "His name was Don Etsillo," he says. "Not that I suppose it matters to you, but the dead deserve respect — regardless of how they lived."

	*IF tekoa
		"That's total bullshit," Tekoa says. "All the dead deserve is to be forgotten."

	*IF wyverna
		Wyverna says, "If I lived as zat man lived all I would hope for in death would be for za gods to ignore my passing. Ozarwize, he is in for an awful afterlife."

*IF lish and naive
	"Hey," Lish says, stepping up to walk beside you, "what you said about the bandit was almost like a prayer or something. I mean, it was nice." She smiles and hurries away.

*GOSUB wizsol
*GOTO movingon

*LABEL luckedout
*COMMENT didn't react to Don Etsillo

"I am Don Etsillo!" the bandit says, stopping in front of you. He smiles and nods. You realize you have your hands up defensively. You drop them to your lap as you sit back in the grass and try to resume breathing normally as your adrenaline rush fades.

"I am Captain of the Forest Keepers — protectors of this forest!" he says proudly. "I saw you from across the field and asked your party if I might have a word. They, but of course, acquiesced. I am, as I said, [i]Don Etsillo[/i]."

You stare at the bandit, unsure of what to say, as he continues to grin down at you. He shrugs the longsword off his shoulder, plants it into the ground beside him, and sits down in front of you.

"So, you are naked! Are you an ascetic? Have you, perhaps, eschewed clothing for enlightenment? A monk of some sort? But, if yes, have you found wisdom? Do they gods speak to you?"

*FAKE_CHOICE
	#"Well, there's this curse, you see—"
		The bandit cuts you off with a wave of his hand, saying, "Ah! Magic! Always a misery, of course."
		*IF naive
			*SET arrpee +10

	#"Look, Dan Eskimo, if I had achieved enlightenment I'd be sitting on a cloud and not this itchy-ass grass."
		He frowns. He presses his forefinger and thumb together in front of you and says, "[i]Don Etsillo[/i]." He nods, sure that you know his name now. "But you wish to sit in the sky? Interesting!"
		*IF snarky
			*SET arrpee +10

	#"Oh yeah, the gods speak to me! But it just sounds like a lot of burping, you know?"
		*IF lively
			*SET arrpee +10
		"Hmm!" The bandit tilts his head to the side. "I suppose you've not learned their language — though if it sounded of burps I would be reluctant to learn it as well!"

	#"I would have preferred you chopping off my head to answering all your asinine questions."
		"Oh? I would be happy to oblige," he says, smiling, "but your friends have unfortunately already bartered safe passage through my forest."
		*IF bitter
			*SET arrpee +10

	#Say nothing
		*SET Etsillo true
		*GOTO beforemovingon

The bandit Don Etsillo springs to his feet and plucks his sword from the ground to return it to his shoulder.

"I think," he says, "we shall keep you! It is a great honor to join the Keepers of the Forest!" He makes a grandiose wave with his arm. "Think of a bandit name for yourself while I arrange your stay with your former friends."

The bandit begins to stride back into the forest but stops when he meets the rest of your party on their return. There is some muttering and then some arguing and then Oferi and Don Etsillo square off, swords drawn, for a duel.

Oferi is quick to strike, even with her oversized sword, but Don Etsillo parries and dodges her swings with seemingly little effort. Unfortunately, Oferi seems to be having trouble doing the same with his attacks.

One of Don Etsillo's swings bounces off her shoulder armor. Another, one that would have surely skewered Oferi through her bare abdomen, is narrowly avoided by the burly elf stumbling backward.

You stand up, feeling panicky. You have to do something!

The bandit leader smacks Oferi in the side of the head with the flat of his blade. She tetters in a circle and he bursts out laughing.

That is until Oferi gracefully whirls around, sword outstretched, and cleanly separates his top half from his bottom half. Don Etsillo's laughter stops abruptly. You look away as his two halves tumble to the ground.

*PAGE_BREAK

Oferi waves to the bandits hidden in the treeline, wipes her sword off on one part of Don Etsillo, and returns the impressive weapon to its scabbard on her back. She then leads the group over to you.

"To be clear," Oferi says as she approaches, rubbing the side of her head, "that fight had nothing to do with you."

*IF art
	"Aye, twas another matter altogether," says Art.

*IF tekoa
	Tekoa says, "Well, maybe a little—"

	Oferi shoots Tekoa a scowl and the buxom rogue mashes her lips tightly shut.

*IF ghinty
	"Ah, the old fart just want a fight," Ghinty says. "He just probably should have learned how first!"

*IF kerwain
	"The arrangement was honorable," says Kerwain. "However, the bout was much less so."

*FAKE_CHOICE
	#"I am sorry that happened for any reason and I'm grateful you were here to handle it."
		*SET synergy %+10
		*SET social %+10
		*SET dig_oferi %+10
		*IF naive
			*SET arrpee +10
		*IF finnur
			Finnur says, "This was not your fault, ${name}. Do not take that grievance upon yourself."
			*SET dig_finnur %+10

	#"I wasn't worried — he's not [i]half[/i] the man you are, Oferi!"
		*SET synergy %+10
		*IF snarky
			*SET arrpee +10
		*SET dig_oferi %+10
		*IF tekoa
			*SET dig_tekoa %+10
			Tekoa snorts and covers her mouth.

	#"Oh but I rather like having a girl fight my battles, you know!"
		*SET social %+10
		*SET synergy %+10
		*SET dig_oferi %+10
		*IF lively
			*SET arrpee +10
		*IF tekoa
			Tekoa winks at you and whispers, "I like to watch her fight too."
			*SET dig_tekoa %+10

	#"Even if it had anything to do with me, you're just doing your damn job."
		*SET dig_oferi %-10
		*SET synergy %-10
		*SET social %-10
		*IF bitter
			*SET arrpee +10
		*IF art
			"Aye, and the job is being done," Art says, scowling. "You've no complaints, ${ladlass}."
			*SET dig_art %-10

	#"Thank you, Oferi."
		*SET dig_oferi %+10
		*SET synergy %+10

	#Stay silent

"No matter," Oferi says, "they didn't like him anyway. So no harm done. I even got you this to use to defend yourself, if you like." She stabs a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"All right," Oferi says, "everyone ready? Let's march!" Oferi starts through the forest once again, waving for everyone to follow.

*GOSUB wizsol
*GOTO movingon

*LABEL beforemovingon
*COMMENT said nothing to Don Etsillo

"Ah! A vow of silence as well, perhaps? Ah-ah, that is too bad." The bandit Don Etsillo springs to his feet and plucks his sword from the ground to return it to his shoulder. "It was pleasant for you to meet me, I am sure. Good luck in your travels, strange one!"

The bandit strides back into the forest and your party passes him on their return. You stand up as they approach.

"Well," Oferi says, "the toll is paid and we've free reign in the forest now. I even got you this to use to defend yourself, if you like." She stabs a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"Okay," Oferi says, "Let's march!" Oferi starts through the forest once again, waving for everyone to follow.

*GOSUB wizsol
*GOTO movingon

*LABEL kerwaindefends
*PAGE_BREAK
Long, quiet minutes pass.

Then, from out of the treeline ahead, a burly bandit appears. He advances toward you in a purposeful stride, a well-used longsword perched on his shoulder. His scarred face is made even more menacing with a crooked smirk on his lips.

"Hold, scoundrel!" Kerwain orders, readying his sword at this side.

"I am [i]Don Etsillo[/i]!" the man exclaims, continuing to approach. "I am Captain of the Forest Keepers!"

"Stay your approach or feel my steel!" warns Kerwain.

"No one speaks to Don Etsillo in such a manner!" the bandit says. He takes his longsword from his shoulder in a flourish and slashes the air in front of himself with several showy maneuvers. "Stand aside, man of tin. I've come to speak to the naked one."

Don Etsillo stops just out of range of Kerwain's sword. He holds his longsword out from his side with one arm, rocksteady.

"$!{heshe} is in my charge. I will not suffer ${himher} your discourtesy."

"You will not suffer long at all!" Don Etsillo promises as he advances.

Surprisingly, Kerwain throws aside his shield. He lunges into the bandit's advance and backhands the man's face with his ironclad fist.

Don Etsillo stumbles to the side, dragging his longsword, but quickly recovers. He spits blood and teeth from his mouth.

"THAT is every respect a man of your station deserves, sir!" Kerwain says with a clenched fist trembling in front of him. "If you step to my ward again, I shall have the soul from your body as surely as I have had your teeth."

The bandit sneers at Kerwain. For a moment, it seems he might turn back. But then he raises his sword and makes his advance.

Kerwain drives his sword forward and twists his wrist at the moment of impact with the bandit's longsword. Don Etsillo has to dive aside and clutch his sword with both hands to keep the weapon from being spun out of his grip. He swiftly regains his footing and adopts a two-handed grip.

"You are supremely skilled with your sword, sir knight," the bandit says.

"I have had nothing but my sword and my chivalry in life," Kerwain says. He nods to Don Etsillo. "There is no disgrace in disengagement, sir."

"You say to a man of worth of no respect." The bandit laughs through broken teeth. "Retreat is out of the question, sir knight. If I turn, my men turn on me! I shall give you a fight — the fight of my life! — and hope my lady luck bears out against your lady, skill."

Kerwain shakes his head. "That is a fool's bet."

"I am nothing if not a fool!" Don Etsillo says, pressing his advance again.

The swords of Don Etsillo and Kerwain clash violently again and again. The knight's sword is clearly better made, as it takes chips and chunks from the bandit's weapon with nearly every strike. Still, Don Etsillo presses on, fighting with a fervor of a man possessed.

[i]*CLANG CLANG CLANG*[/i] go their blades. Both men huff and sweat. Both dance and dodge. The birds have quieted their singing, the wind has paused. Skill or luck: the world awaits the victor. The earth awaits the defeated.

Don Etsillo's sword shears in two. He is left holding naught but a splintered shaft of metal above a twisted hilt.

"Yield!" Kerwain orders, holding the point of his sword to him.

The bandit smiles. "Never a choice for me, my friend. I will be honored to die at your hand."

You see the point of Kerwain's sword falter and tremble. "Do not force me to slay you, sir!"

Don Etsillo holds his broken sword up in front of him, as if it were some holy object, and he bows to Kerwain. He then stands tall, with his chest puffed out, and smiles. The moment of his death is upon him as he steps forward again.

*FAKE_CHOICE
	#Plead with Don Etsillo to yield
		"Don Etsillo, don't!" is all you can say before it happens.

	#Use "the spell" on the bandit
		*GOTO explodiousblowupicus

	#Do not interfere

The bandit leader doesn't make a move to stop Kerwain's sword as it thrusts through his chest. He is dead, pierced through the heart, before the smile can even fade from his lips.

Kerwain draws back his blade and Don Etsillo slumps to the ground. The knight begins to say something, but stops himself and sets about cleaning his bloodied sword with a rag. But then the sword tumbles from his grip, falling to the grass below, and he gazes off into the woods.

The group appears from the tree line ahead and starts over towards you, lead by Oferi.

When Oferi reaches you, she nods gravely at Kerwain, who returns the nod, and then she turns to you.

"The toll is paid and we've free reign in the forest now," she says. "No matter that Don Etsillo is dead. Everyone saw that it was an honorable duel."

*IF finnur
	"I am sorry, Kerwain," Finnur says, placing his hand on the knight's shoulder. "If I could heal the wounds we receive from killing others, I would gladly do so for you."

*IF art
	"Did what you had to do, friend," Art says. "You protected ${name}, just as you said you would."

*IF lish
	Lish retrieves Kerwain's sword and carefully places it in his sheath for him. He then picks up Kerwain's shield and places it in its mounting brace on Kerwain's back.

	She takes Kerwain's hand briefly and he glances at her. She gives him a slight smile and he nods, then turns away.

*IF not(lish)
	The others retrieve Kerwain's sword and shield and hand them to him with words of encouragement.

"I got you this to use to defend yourself, if you like." Oferi stabs a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"Okay," Oferi says, "Let's march!" Oferi starts through the forest once again, waving for everyone to follow.

*GOSUB wizsol
*GOTO movingon

*LABEL aftertactics
*COMMENT Wyverna prevented the ambush
*IF kerwain
	Kerwain stands guard, stalwart and steady despite holding both his shield and sword at the ready. He vigilantly scouts the area with his gaze, his breaths quick but as regular as ticks on a clock.

*IF lish
	Lish scans the treeline with her rifle at the ready.

	"Ragged. Dirty." She pauses. "Dirty. Very dirty! Eww. Where are your pants? Ragged. Dirty." Another pause. Then she whispers, "Ooh. Pretty." Her rifle bucks in her hands and splits fire, the sound cracking loud off the trees around you.

	She quickly reloads. Then, scouting down her scope again, she continues murmuring to herself.

	*IF kerwain
		"You only shoot the handsome ones?" Kerwain asks, frowning.

		"I shoot the ones in pretty armor," she answers. "They're the ones in charge, silly."

		"Ah." Kerwain nods. "[i]That[/i] is an acceptable tactic."

		"Thanks, big guy," she says. Her rifle pops as, presumably, another bandit leader dies.

	*IF not(kerwain)
		*FAKE_CHOICE
			#Ask Lish what she is muttering about
				"I shoot the ones in pretty armor," she answers. "They're the ones in charge."

			#Leave her alone to do her work

		Her rifle pops as, presumably, another bandit dies.

A quarter hour passes. Finally, Wyverna appears from the tree line ahead and starts toward you, followed by the rest of the group.

"Routed," she says, smiling, when she reaches you. "Almost dead to a man."

*IF lish
	"A few stragglers took flight," says Lish, standing up. "Raggedy ones, though."

*IF kerwain
	"We have you to thank for such an easy victory," Kerwain says, shaking Wyverna's hand.

*IF not(kerwain)
	"Good work," Oferi tells Wyverna. "But I still don't like you."

	Wyverna smirks. "And I zink you're a boring bitch, Auferi. But your sword is strong."

	You get the impression that's probably the best they'll ever get along.

*IF finnur
	"It saddens me the loss of life today," Finnur pouts, "but your leadership in battle prevented us and ours from suffering or death. For that, you have my sincere thanks, Wyverna."

*IF ghinty
	"I got to put some fire to use," says Ghinty, grinning. "That makes any day a good day!"

*IF art
	Art smiles and nods to the others. "Those bastards won't be troublin' travelers for a while, now!"

"Anyway, I got you this, tenderfoot," Oferi says, sticking a shortsword in the ground at your feet. "Take it or leave it, your choice."

*FAKE_CHOICE
	#Take the shortsword
		You take up your lantern in your left hand and the shortsword in your right. While you haven't had any training with weapon at all, it seems fairly obvious that the pointy end should go in the bad guys.

		*SET armed true
	#Leave the shortsword

"Okay," Oferi says, "Let's march!" Oferi starts through the forest once again, waving for everyone to follow.

*GOSUB wizsol

*LABEL movingon
*COMMENT hid in lantern or Oferi-Etsillo duel or Kerwain defends, moving on
*PAGE_BREAK

As the party continues deeper into the forest, sounds of life grow louder all around you: chirping, skittering, growling, mewling, and all sorts of such noises wild creatures make.

Oferi laughs and mutters, "Bandits and bearwolves."

*IF art
	Art seems to be agitated, looking over his shoulder at every noise. "What was it the bandits were saying about the bearwolves?"

	Oferi laughs. "Packs. That they were running in [i]packs[/i]. Come on, Art, you know that's absurd. Bearwolves are highly territorial lone hunters."

	*IF tekoa
		"Can you imagine that?" Tekoa asks, shaking her head and laughing. "I should have asked for a cup of whatever those bandits were drinking!"

	"Packs of four and five, they said." Art grunts. "If it were true, there'd be no hope for a battery of kingsmen, much less a ragtag group of mercenaries."

	Oferi frowns at Art. "You know better than to put any stock in the wild tales of bored thieves and liars."

	*IF wyverna
		"And, if it were true, zer is no sense in worrying about it, Art," Wyverna says. "We will be dead quite quickly should we happen upon such a sight."

	"Aye," Art says, "but I'm alive today because I pay any tale, tall or no, [i]proper[/i] caution."

*IF finnur
	"Perhaps the number of bearwolves was exaggerated," Finnur says, "but we would be wise to be wary."

	*IF tekoa
		Tekoa laughs. "[i]W[/i]ould [i]w[/i]e?"
	
		"The alliteration was unintended."

		"Well wing-wang-wobble," Tekoa says.

		Finnur frowns and asks, "And what, pray tell, was [i]that[/i]?"

		"Oh." Tekoa sighs and slumps her shoulders. "I'm not very good at it."

	*IF ghinty
		"Packs of bearwolves!" Ghinty says, laughing. "I'd like to see that!"

		"I doubt you truly would," Finnur says.

		"Well, not literally," says Ghinty. "That would just be silly and suicidal. But maybe in a painting or something."

	*IF wyverna
		Wyverna says, "If, by some tragic contretemps, we do happen upon a pack of bearwolves, we must make an effort to square off with each of zam lest we be surrounded. If fortunate, some of us may survive za encounter."

		*IF ghinty
			"Of course! That way none of them will go hungry," Ghinty says.

		"Such fortune rarely follows such misfortunate," Finnur says, "especially on such a grand scale as you propose."

		"You are right, of course," Wyverna says, rolling her eyes. "Better we all lie down and die right here."

*IF kerwain
	"I fought a bearwolf once," Kerwain says. "That I survived the encounter is surely due to the fact that there were seven others fighting it alongside me."

	*IF ghinty
		"Hardly seems fair," Ghinty says.

		"Truly," says Kerwain. "There should have been more of us. Three of our contingent died and two others were maimed beyond holding a sword again."

		Ghinty clears her throat. "Ah. Well."

*IF lish
	Lish slings her rifle across her back and sets about unloading and repacking ammunition into her blunderbuss.

	Oferi chuckles. "That's an awful lot of powder you're putting in there, Lish."

	*IF ghinty
		Ghinty nods at Lish and says, "I know it's tempting to mimic my impressive magics, but that much powder is likely to shatter that contraption to pieces."

	"Bearwolf hide is really thick," Lish says. "Only way I can hope to get through it is with a good clump of powder behind the ball."

Oferi asks, "Have you all lost your minds and guts? Bearwolves in packs! Why would you even give the idea any credance at all?"

*IF art
	"Well," says Art, frowning, "aye, I suppose the idea is downright balmy."

*IF finnur
	"It does seem rather implausible," Finnur says.

*IF kerwain
	"I suppose there is no reason to worry for it," Kerwain says. "If it were to be true, there is little we could do anyway."

*IF wyverna
	"I have seen stranger zings," Wyverna says, "but such absurdity does tend to involve magicians and not animals."

Oferi stops walking and holds up her hand for everyone to pause. Everyone in the party takes on a defensive stance, scanning the surrounding forest for trouble.

After a long while, Oferi shrugs and waves for everyone to continue.

*TEMP yesasked false
*IF wyverna
	*SET yesasked true
	Wyverna asks, "And just za hell are you doing, Auferi?"

*IF ghinty and yesasked
	"Yeah," Ghinty says, "what the heckfire was that about, babe?"

*IF ghinty and not(yesasked)
	*SET yesasked true
	Ghinty asks, "What the heckfire was that about, babe?"

*IF tekoa and (ghinty and yesasked)
	"Yeah, [i]babe[/i], what was that all about?" Tekoa asks. Ghinty shoots her a narrowed-eye look and Tekoa mimics the expression right back at her. Both of them soon have trembling smiles on their lips but neither seems to want to break off the staring contest first.

*IF tekoa and not(yesasked)
	*SET yesasked true
	Tekoa asks, "Um, Oferi, what was that all about?"

*IF lish and not(yesasked)
	*SET yesasked true
	Lish asks, "What was that about?"

"Well," Oferi says, "I figured that would be the part of the bard's story where suddenly we're surrounded by bearwolves."

*IF art
	"Aye," Art says, "but maybe this bard is a better storyteller."

	"No bearwolves, then?" Oferi asks.

	"Oh, surely there will be!" Art says. "But not until we've forgotten to be vigilant of them."

*IF wyverna
	"You are just as apprehensive as za rest of us," Wyverna says.

	"Maybe," says Oferi, "but at least I'm the prettiest elf here."

	*IF art
		Wyverna snorts and looks to Art, who opens his mouth to say something but then clamps his lips shut and holds his hands up in apology to her. She rolls her eyes and waves her hand in dismissal at him, causing his shoulders to slump. A long sigh escapes him and he kicks at a clump of dirt on the ground.

*IF lish
	*IF not(gender = "male")
		Lish says, "If [i]I[/i] were telling this story, I'd put naked men in it!"

	*IF (gender = "male")
		Lish says, "If [i]I[/i] was telling this story, I'd put naked men in it!" She looks over to you and grins. "Err, even [i]more[/i] naked men, I mean."

	*IF ghinty
		*IF not(gender = "male")
			Ghinty laughs. "I like it! But I think men look better with [i]something[/i] covering their bits. Otherwise they just bobble about everywhere!"
		*IF (gender = "male")
			Ghinty laughs. "I like it! But I think men look better with [i]something[/i] covering their bits. Otherwise they just bobble about everywhere!" She grins at you. "No offense to your waggly whatsits, of course!"

*PAGE_BREAK
After another hour of walking, mostly in vigilant silence, Oferi calls the group to a halt and assigns tasks for setting up camp.

*IF artincharge
	Art repeats her orders to the other two, emphasizing the supervisory responsibility you granted to him upon hiring him into the group.

*IF attendwyverna
	Wyverna sits on a rock and begins the complicated endeavor of removing her knee-high armored boots.

	"Wyverna, let's gather the firewood before it gets dark," Oferi says. "That's an order."

	"My atten-dand will see to it," Wyverna says, looking to you, "it was a condition of my enlistment zat ${heshe} carry out such mundane tasks for me."

	Oferi frowns at you. "Come on, then, tenderfoot. I'll not tolerate you shirking any responsibilities you willingly undertook."

	"Hurry back," Wyvera says. "My poor little feet require your attention."

*IF not(attendwyverna)
	"Tenderfoot," Oferi says, "come with me to gather the firewood."

You follow Oferi through the forest around the proposed campsite as she stacks various pieces of dry timber in your arms.

Oferi clears her throat and stops to look at you.

"This is a... difficult subject to broach. You see, there is a tradition, on these longer journeys, for — ah — road romance." She winces as she says it. "What I mean is that [i]pairings[/i] often occur on these adventures. It's common. Nothing strange about it. But no one talks about it, either."

She places a few more sticks on top of the already uncomfortably heavy pile of wood in your arms.

"So," Oferi says, shrugging, "if you wanted to get to know someone or [i]whatever[/i], you should let me know now so that I can ease the arrangement."

*TEMP triedoferi false
*LABEL whoknows
*FAKE_CHOICE
	*HIDE_REUSE #"What if I'd like to get to know more than one person?"
		*GOTO panexplain
	*IF art
		#"I'd like to get to know Art."
			*GOTO knowart
	*IF kerwain
		#"I'd like to get to know Kerwain."
			*GOTO knowkerwain
	*IF lish
		#"I'd like to get to know Lish."
			*GOTO knowlish
	*IF ghinty
		#"I'd like to get to know Ghinty."
			*GOTO knowghinty
	*IF finnur
		#"I'd like to get to know Finnur."
			*GOTO knowfinnur
	*IF wyverna
		#"I'd like to get to know Wyverna."
			*GOTO knowwyverna
	*IF tekoa
		#"I'd like to get to know Tekoa."
			*GOTO knowtekoa
	#"I'd like to get to know you, Oferi."
		*GOTO knowoferi
	#"I'm not interested in that sort of thing."
		*GOTO knowdone
	*IF wizardlove
		#"I still want to remain faithful to Tarson."
			*GOTO knowdone

*LABEL panexplain
Oferi smirks. "Well, that often does happen," she says, "and whether you decide to take up with someone for the duration or play the field is up to you, tenderfoot."
*GOTO whoknows

*LABEL knowart
*IF (gender="female") or (gender="nonbinary")
	Oferi's eyebrows raise.

	"Oh," she says. "That's great. I'm sure Art would love to get to know you better. I just — hmm — I didn't see that coming." She smiles. "But really, that's great. Art is a great guy."

	*SET romancing "Art"
	*GOTO knowdone
*IF (gender="male")
	Oferi shakes her head.

	"Ah, I'm afraid that's not going to happen," she says. "Art isn't — um — open-minded about that sort of relationship."

	*GOTO whoknows

*LABEL knowkerwain
*IF (gender="female") or (gender="nonbinary")
	Oferi nods.

	"I understand the attraction, he's a handsome man," she says. "I think he's dull as a rock, myself, but I've been tempted to give him a shot in the past. I'll talk to him for you."

*IF (gender="male")
	Oferi says, "I don't know if he'll be interested but I can certainly talk to him. He's more into women but I know he's made exceptions in the past."

*SET romancing "Kerwain"
*GOTO knowdone

*LABEL knowghinty
Oferi chuckles.

"You're in for an interesting night," she says, smiling. "I'll talk to her for you."

*SET romancing "Ghinty"
*GOTO knowdone

*LABEL knowlish
*IF (gender="female")
	"Ah, Lish," Oferi says, nodding. "She is damn cute, that's for sure. As for [i]road romance[/i], though, you may have to put in some effort to get her to warm up to you. I know she's taken up with women before but not often. But I'll talk to her for you."

*IF (gender="male") or (gender="nonbinary")
	"Ah, Lish," Oferi says, nodding. "She is damn cute, that's for sure. I certainly can't fault your taste. I'll talk to her for you."

*SET romancing "Lish"
*GOTO knowdone

*LABEL knowwyverna
"Ugh," Oferi says. Her lip curls. "I do [i]not[/i] understand that attraction. I know I said I'd talk to the person for you but not Wyverna. Besides, you don't even have to [i]try[/i] with her. Just walk up to her and say something dirty and you're golden."

*SET romancing "Wyverna"
*GOTO knowdone

*LABEL knowtekoa
*IF (gender="female") or (gender="nonbinary")
	Oferi laughs. "Yeah, well, I hope you're obedient because she's going to wrestle for control and she's damn strong. Not to mention she'll smother you with those funbags of hers." Oferi laughs again. "Okay, tenderfoot I'll talk to her for you."

	*SET romancing "Tekoa"
	*GOTO knowdone

*IF (gender="male")
	Oferi shakes her head. "Sorry, tenderfoot, that's not going to happen. Tekoa isn't interested in men."
	*GOTO whoknows

*LABEL knowfinnur
*IF (gender="female")
	"Sorry, no can do, tenderfoot." Oferi frowns and shrugs. "I've been pestering that beautiful boy for years and he isn't the least bit interested. Likes us women-folk as friends but not even a little bit more than that."
	*GOTO whoknows
*IF (gender="male") or (gender="nonbinary")
	Oferi sighs and shrugs. "Well I suppose I'm jealous but I don't have a shot anyway. Tell you what: I'll talk to him for you but you have to promise to tell me [i]everything[/i] in deep, disgusting detail." She laughs and winks at you.

	*SET romancing "Finnur"
	*GOTO knowdone

*LABEL knowoferi
*IF triedoferi
	*SET dig_oferi %+10
*IF dig_oferi > 60
	"Hmm." Several confusing looks pass over Oferi's face as she apparently decides how to handle your admission. She looks away, into the forest, and says, "Well, I suppose that we could talk. You and I. And see how we like one another. We haven't had any time to really get to know one another so — okay. Sure. I maybe wouldn't mind getting to know you."

	*SET romancing "Oferi"
	*GOTO knowdone
*IF dig_oferi >40
	"Hmm." Oferi crosses her arms. "I suppose we can talk but I can't say I'm enthusiastic about the idea. Maybe I just don't know you well enough but, right now, I don't think I care for you all that much."

	*SET romancing "Oferi"
	*GOTO knowdone
*IF not(triedoferi)
	Oferi shakes her head. "Look, I don't know why you'd think I'd even consider that. We don't [i]mesh[/i]. At all. So get that idea out of your head."
*IF triedoferi
	Oferi rolls her eyes. "Are you just going to keep asking until I say yes?" She smirks. "That's [i]probably[/i] not going to work."
*SET triedoferi true
*GOTO whoknows

*LABEL knowdone
*IF (romancing="Oferi")
	Oferi looks back to you and gives you a nod.

	"I'm going to scout the perimeter and gather more firewood. You head back to camp. That way." Before she turns and heads off into the woods, she smirks and says, "I suppose we'll talk later."

	*GOTO backtocamp
*IF (romancing="Wyverna")
	Oferi says, "I'm going to scout the perimeter and gather more firewood. You head back to camp. That way."

	*GOTO backtocamp
*IF (romancing="none")
	"Just to be sure, you're not interested in getting to know anyone more, right?" Oferi asks.
	*GOTO confirmchoice
"Just to be sure, you do want me to talk to ${romancing} for you, right?" Oferi asks.
*LABEL confirmchoice
*FAKE_CHOICE
	#"Yes."
		"Okay," Oferi says with a nod. "I'm going to scout the perimeter and gather more firewood. You head back to camp. That way."

		*GOTO backtocamp
	#"No."
		"Fickle, aren't you?" Oferi asks. "So who's on your mind [i]now[/i]?"
		*GOTO whoknows


*LABEL backtocamp
*FINISH

*LABEL lakedetour
*COMMENT got all messy with gore

"The sun's beating a hasty retreat now," Oferi says, frowning. "Let's get to the lake and make as much headway towards the marsh as possible. Regardless of how far we get, we'll camp in the forest tonight."

Oferi starts through the forest again and everyone trails.

*IF finnur
	Finnur smiles. "Then let us look upon it as blessing, for a night spent in the woods rejuvenates mind and body alike. With friends, doubly so."

	*IF art
		"Well said," Art says, nodding. "You might ought to have been a bard, my friend."

		"I have not the voice," Finnur replies. "Nor have I the hands for a lute." He flexes his clawed fingers in front of him, sighing.

*IF kerwain
	Kerwain says, "I could certainly use a bath. Let us make haste."

	*IF lish
		"Yeah," Lish says, smiling, "let's get moving already so that there's enough daylight left for — you know — Mister Muscles to wash himself."

*IF tekoa
	"We'll have a fire, of course," Tekoa says. "Bearwolves hate fire. Err, right?"

	*IF wyverna
		Wyverna shakes her head. "I zink not. It only helps zem see zar prey all za better."

		"Well that's a sobering thought," Tekoa says. "And I so hate being sober."

		"Luckily, I have brought wine," Wyvera says.

		Tekoa looks over to her with a half-smile. "Are you offering to share?"

		Wyverna laughs haughtily. "No," she says, simpering, "zo perhaps you might barter for it, ah-no?"

		"I only have what you see," Tekoa replies, waving a hand over herself.

		"Hmm." Wyverna looks her over with a raised eyebrow. "We have a deal, zan."

		Tekoa grins.

		*IF art
			Art lets out a wistful sigh as he gazes back and forth between Tekoa and Wyverna. He hurries ahead of them to walk beside Oferi.

*IF art
	"Prefer the forest to the marsh, aye," Art says, "but I'd prefer a rock in a cave over either."

	*IF ghinty
		"Oh yeah? What you got planned for the poor rock?" Ghinty asks, giggling.

		"To rest my head on, you foul-minded creature," Art says, scowling.

		"Eww!" Ghinty squeals. "That's even [i]worse[/i] than I imagined! That poor rock will be crushed to dust by that massive noggin of yours."

*IF wyverna
	"I don't suppose zis lake has a waterfall?" Wyverna asks.

	"No," Oferi says.

	"Ach. Such a waste of water without a fall, ah-no?"

	"No," Oferi says.

	"You are so [i]no no no[/i] all za time to every question, Auferi. So I ask: if I were drowning in za lake, would you not rescue me?"

	"No," Oferi says.

	"Ach! How cruel."

	"It's not cruelty," Oferi says, "but I wouldn't know you were calling [i]me[/i] for help since you apparently can't say my name correctly."

	Wyverna scoffs and rolls her eyes.

*IF art
	Art says, "Dwarves aren't fond of water."

	*IF ghinty
		"The smell of ya told us that already," Ghinty says.

		"Ya like to tempt my fire, don't ya, pickleskin?"

		"My fire against your fire, let's see who wins!"

		"Ah, no thank you to that!" Art says. "Roasted goblin smells fouler than troll farts."

	"Art, you have to drink water," Oferi says, "and you have to bathe. Otherwise, you'll die. Or someone will kill you."

	"Aye, it's a necessity," says Art, "I only wish there were enough beer for both."

	Oferi laughs and shakes her head.

	Art frowns at her. "But I'm [i]serious[/i]."

The "lake" is more of a pond, really, and although it doesn't have a waterfall it is run through by a stream which thankfully keeps the water from stagnating.

*IF art
	"There ya are," says Art, pointing you to the water. "Oh, don't be shy now. You've no use for it."

*IF tekoa
	"Nothing brings people together like brazen nudity!" Tekoa says, ambling towards the water.

*IF (purchase="soap")
	*FAKE_CHOICE
		#Ask Oferi for the soap you bought back in town
			*SET purchase "used"
			Oferi pulls your package out of her pack and tosses it to you. You unwrap it and take a sniff of the delightful fragrance.

			*IF art
				"That's going to attract animals," Art grumbles, eyeing the soap.

				Oferi smirks. "I think it attracts everyone but dwarves," she says.

				Art frowns at her and crosses his arms.

		#Bathe without the soap

"Father always said to take the opportunities that come your way," Oferi says. She removes her armor and leaves it in a pile around her sword. She jogs toward the water and dives in without hesitation.

*IF tekoa
	Tekoa unstraps her leather harness and starts to join Oferi in the lake but stops when the water laps around her ankles. "It's freezing!" she squeals.

	Oferi pops up, grabs her by the ankles, and yanks her down into the water. Tekoa shrieks and splashes water at Oferi.

*IF finnur
	"People often say my kind have an aversion to water," Finnur says, whipping off his loincloth to reveal a noteworthy attribute, "but I've always suspected I'm personally more kin to otters than cats." He smiles — something you've yet to have seen so far — and dashes into the water at an inhuman velocity.

*IF wyverna
	Wyverna saunters down to the water, discarding pieces of armor along the way, and slips into the water so gracefully her entry emits no ripples.

*IF kerwain
	Kerwain neatly stacks his armor upon his shield close to the shore and marches into the lake where he then begins to methodically wash himself.

*IF ghinty
	Ghinty walks straight into the water, robes and all, and starts doggy-paddling in circles while giggling maniacally. She then settles down, floating on her back.

	"Look at me!" Ghinty squeals. "I've got my own buoys!"

*IF lish
	"Maybe someone should be standing watch," Lish says, looking around.

	*IF art
		"Aye, I'll stand watch, lass," Art says.

		Lish gives Art a thin smile. "Oh. Okay."

	"Get that cute little ass in here right now or I'll come out and toss you in!" Oferi yells.

	Lish laughs and disrobes then creeps into the water, shoulders shivering.

	*IF tekoa
		Tekoa bounces out of the water with her hands cupped, throwing a wave of water over Lish.

		"Tekoa!" Lish yelps, shaking a fist. She dives in after the quickly retreating rogue.

*IF (purchase="used")
	You walk into the water, unable to really tell if it is indeed cold or not, and lather up with your soap.

	*IF tekoa
		Tekoa swims by and swipes the soap from you with a chuckle and soaps herself up as well. She passes the bar along to the others, giving you a wink.
	
	*IF not(tekoa)
		Oferi swims by and swipes the soap from you as you're finishing.
		
		"How sweet of you," she says, smirking. She soaps herself up and passes the bar along to the others.

*IF not(purchase="used")
	You walk into the water, unable to tell if it is indeed cold or not, but at least the splashes from the others don't bother you.

*IF finnur
	Finnur shoots out of the lake — high enough to clear the surface entirely — and then glides back underwater with barely a splash.

	*IF wyverna
		Wyverna pops up where Finnur was a moment ago and gasps for air.

		"Gottess, he's quick!" she says. She gives you a wide-eyed grin and, after a deep breath, disappears under the water again.

		Oferi sighs and smirks at you. "I don't know what it is about that boy," she says, "but it seems us elves just can't resist him."

*IF lish
	"This was a nice idea," Lish says.

	"Oh, because it was [i]your[/i] idea?" Oferi asks.

	Lish nods. "Oh, so I have nice ideas! Don't be jealous."

	*IF (whoaway="Lish")
		Oferi snorts. "Nice ideas like stealing pastries?"

		Lish shrugs and laughs. "Well, the pastries were nice. So... kinda!"

	Oferi rolls her eyes, splashes her, and slips away under the water.

*IF ghinty
	Slowly Ghinty drifts by you, propelling herself with regular paddling of her feet. She spurts a fountain of water out of her mouth into the air and follows it with a fit of laughter.

	"The only difference between goblins and mermaids," she says to you, "is that we don't smell like fish!"

	"Well, that and the fins, right?" Oferi says.

	*IF art
		"And the grace and beauty!" Art shouts from the shoreline.

		"Quiet, stinky!" Ghinty shouts back.

		"Someone's got to watch our backs," Art says.

		"And some of us should [i]wash[/i] our backs," Ghinty replies.

		Art grunts and crosses his arms.

After an another quarter hour of horseplay, Oferi strides out of the lake and begins drying off and donning her armor again.

"Hey, c'mon!" she shouts at the others. "Out out out!"

*IF kerwain
	Kerwain had already left the water some time ago and now stands patiently on the shore for the rest of the group. Everyone else grumbles as they leave the water to redress.

*IF not(kerwain) and armed
	Everyone grumbles as they leave the water to redress. Except, of course, for you. You pick up your lantern and shortsword and wait for the others to ready themselves.

*IF not(kerwain) and not(armed)
	Everyone grumbles as they leave the water to redress. Except, of course, for you. You pick up your lantern and wait for the others to ready themselves.

*IF lish
	"I feel energized," Lish says, "how about you?" She nearly pats you on the shoulder but catches herself. "Whew! I keep doing that."

	*IF kerwain
		"I am sure ${name} would not mind the solidarity," Kerwain says, smiling for once.

		"And I'm sure you wouldn't mind the view, huh big guy?" Lish says.

		Kerwain clears his throat. His cheeks flush red and he turns away to inspect the fastening of his shield.

*IF finnur and wyverna
	After tying on his loincloth, Finnur helps Wyverna back into her armor as she chats away at him. You can't make out their conversation, but he often smiles and shakes his head.

	Finally she huffs and slumps her shoulders. He gives her a quick kiss on the forehead and she sighs as she watches him walk away.

*IF ghinty
	Ghinty bobbles past you, her robe dripping wet. She shoots you a grin and says, "Don't get all excited just because I'm wet, adventure-eyes. Oh, what am I saying? Go ahead, get excited!" She laughs and winks at you.

	*IF art
		Art dodges Ghinty's attempts to sprinkle water on him as she walks by.

		"Hey," he grumbles, "leave me be! Aren't goblins supposed to melt in water, anyway?"

		"That's silly." Ghinty says with a frown. "I think you're mixing goblins up with ice cubes."

	Raising her arms, Ghinty is suddenly engulfed in a flash and a puff of smoke. When it disappates, her robes are completely dry again. She lets out a little cough and licks her tongue at her lips as if there were a bad taste in her mouth.

*IF tekoa
	Tekoa fumbles with her harness, trying to get strapped back up, and finally Oferi, with a deep sigh, walks over to her and helps her buckle up.

	"There," Oferi says, tugging a strap to ensure it's secure and causing Tekoa's ample assets to wobble a bit.

	Tekoa suddenly leans forward and plants her lips on Oferi's. Tekoa's hand grasps the back of Oferi's neck and you see Oferi's fingers tremble and dance on Tekoa's generous hips. After a moment, Oferi breaks away and takes a step back.

	"You stop that," she says, but completely without conviction.

	Tekoa's response is a smile and a wiggle of her eyebrows.

"Let's march!" Oferi says. She leads the march back into the forest after everyone is prepared.

*GOTO movingon
*COMMENT end of lake detour


*LABEL wizsol

*IF ghinty
	"Wait," Ghinty says. Everyone in the group stops and turns to her. "There's some... [i]thing[/i]... watching us."

	*IF finnur
		"I feel it as well," Finnur says.

	Oferi unsheaths her mighty sword and looks around. "What?"

	The goblin mage furrows her brow and holds up a finger. She twitches it in the air and takes a step in your direction. Then another step and another, until she's standing right in front of you. She points to the ring on your finger.

	"There," Ghinty says. "That ring! It's an anchor."

	*IF snarky and not(wizardlove)
		"You're telling me," you say. "Married for all the wrong reasons and the honeymoon was cut short by the old fart's bedtime!"

	*IF lively and not(wizardlove)
		"Well, it could probably work as a fishing lure," you say, "but I highly doubt a ring would make an effective anchor, silly!"

	*IF bitter and not(wizardlove)
		"It's a symbol of drowning dreams," you say, "so an anchor as much as anything else, I suppose."

	*IF naive and not(wizardlove)
		"It's my wedding ring," you say. "I thought it was only an old copper band."

	*IF wizardlove
		"This is my wedding ring, Ghinty," you say. "It may be hard to believe, but I am happily married."

	*IF not(finnur)
		Ghinty shakes her head. "It's more than that. That ring has an impressive enchantment upon it. One that allows the enchanter to observe the wearer at all times."

	*IF finnur
		Ghinty shakes her head. "It's more than that. That ring has an impressive enchantment upon it."

		Finnur kneels down in front of you and peers at the ring. "An enchantment that allows the enchanter to observe the wearer at all times," he says.

	Oferi frowns. "That old wizard is watching us?"

	*IF art
		Art groans. "Wizards! Bah! You can never trust that lot."

		*IF lish
			Lish says, "Oh, I don't know about that! I knew a very cute wizard's apprentice once."

			"But could you TRUST him?" Art asks, crossing his arms.

			After a moment of thought, Lish says, "No, I suppose not! One time I [i]know[/i] he farted but he just kept saying it wasn't him."

			"Aye, then," Art says, throwing his arms up. "You can't trust the LOT of them!"

	*IF wyverna
		Wyverna mutters something in her florid elvish tongue. Pretty as it sounds, you're sure there's some cursing in there.

		"Our words are not meant to be twisted in such a vile manner," Oferi says, glowering at Wyverna.

		Wyverna rolls her eyes and looks away but then says, "You are right, Auferi. I [i]apologize[/i]."

	"Yes, he's watching us," Ghinty says with a nod. "The enchantment is too powerful for me to break, but luckily it is dependent upon a consensual bond."

	"My marriage?" you ask.

	"We can't be under the eye of that old wizard," Oferi says. "I know he is your husband, but I don't know him and I don't trust him."

	"Agreed," Ghinty says. "Though sadly, I have no way to break this bond."
	*GOTO oferidoes

*IF finnur and not(ghinty)
	"Hold a moment," Finnur says. Everyone in the group stops and turns to him. "There is some powerful magic upon us." His cat ears twitch as he looks carefully around and then, when he spots the ring on your hand, he crouches down in front of you to get a better look at it.

	Oferi asks, "What is it?"

	"This ring is an anchor to a scrying stone," Finnur says. "It allows the enchanter to observe the wearer."

	Oferi frowns. "That old wizard is watching us?"

	*IF art
		Art groans. "Wizards! Bah! You can never trust that lot."

		*IF lish
			Lish says, "Oh, I don't know about that! I knew a very cute wizard's apprentice once."

			"But could you TRUST him?" Art asks, crossing his arms.

			After a moment of thought, Lish says, "No, I suppose not! One time I [i]know[/i] he farted but he just kept saying it wasn't him."

			"Aye, then," Art says, throwing his arms up. "You can't trust the LOT of them!"

	*IF wyverna
		Wyverna mutters something in her florid elvish tongue. Pretty as it sounds, you're sure there's some cursing in there.

		"Our words are not meant to be twisted in such a vile manner," Oferi says, glowering at Wyverna.

		Wyverna rolls her eyes and looks away but then says, "You are right. I [i]apologize[/i]."

	"Yes, the old wizard is watching us. And the enchantment is powerful," Finnur says, "but it is dependent upon a consensual bond."

	"My marriage?" you ask.

	"We can't be under the eye of that old wizard," Oferi says. "I know he is your husband, but I don't know him and I don't trust him."

*IF finnur
	Finnur asks, "${name}, did you consummate your marriage to the wizard?"

	*FAKE_CHOICE
		*IF not(wizardlove)
			#"No, we never did [i]that[/i]."
				*TEMP welldidja "nope"

			#"Yes, we consummated the marriage."
				*TEMP welldidja "yeah"

		*IF wizardlove
			#"No, I decided I wasn't ready."
				*TEMP welldidja "nope"

			#"Yes, of course we consummated our marriage."
				*TEMP welldidja "yeah"

	*IF (welldidja="nope")
		Finnur nods. "Then it is a simple matter of annulment. As a senior member of the cardinalate, I have the authority to nullify this marriage at your request."

		"$!{heshe} so requests," says Oferi, nodding to you. "If you wish it, you can remarry him after this task is complete, but I will not permit that wizard to spy upon us for purposes unknown."

		Having no other choice anyway, you nod. Finnur waves his hand and you feel something break away from you that you never realized was attached. He carefully removes the ring from your left hand and slides it on your right hand ring finger.

		"It is done," Finnur says. "The wizard can no longer spy on us. And you are a free ${manwoman} once again."
		*GOTO divorced

	*IF (welldidja="yeah")
		Finnur frowns. He says, "Then I am afraid I have no authority to nullify this marriage."
		*GOTO oferidoes

*IF not(ghinty) and not(finnur)
	Only a few minutes beyond the bandits, Finnur suddenly springs through the bushes and comes to a skittering stop at the group.

	"Ah!" he says, breathing heavily. He holds up his finger, asking for a moment to catch his breath.

	Finnur is not wearing his robes anymore. In fact, he's not wearing much at all: just a leather loincloth hanging between his slender hips and a small pack with the strap crossing his chest.

	It's clear now that he's a [i]catboy[/i] — although you're not sure if that's an appropriate or deragatory name for his kind. They are [i]mostly[/i] human — outside of the ears, tail, claws, and the fact that where hair would be is fur instead — but they certainly have a undeniable feline way about them; especially the way they move.

	The catboy druid stands up, his lean and muscular body covered in a sheen of sweat. He shakes some of the sweat out of his wild furry hair and a few droplets land on you.

	*FAKE_CHOICE
		#"Uh. It, um, seems like you've been [i]quite[/i] active."
			*IF naive
				*SET arrpee +10
		#"Yah, thanks," you say, "really needed a sweat shower just now."
			*SET dig_finnur %-10
			*IF snarky or bitter
				*SET arrpee +10
		#"Oh, geez, does this mean he's claimed us or is that only a thing with pee?"
			*IF lively
				*SET arrpee +10
		*IF (gender="male")
			#You're too busy hiding your sudden [i]excitement[/i] to say anything right now.
				*SET likesfinnur true
				*SET dig_finnur %+10
		*IF (gender="female") or (gender="nonbinary")
			#You don't discern temperature normally, but it certainly feels like someone's turned up the heat [i]inside[/i] you.
				*SET likesfinnur true
				*SET dig_finnur %+10
		#"Gross! You're a damned filthy creature, aren't you?"
			*SET dig_finnur %-20
			*IF bitter
				*SET arrpee +10
		#"Eww. Could you not?"
			*SET dig_finnur %-10
			*IF snarky or lively
				*SET arrpee +10
		#Say nothing

	"Apologies for the rude interruption," Finnur says, still taking heavy breaths, "but upon seeing ${name} in the tavern, a strange feeling came upon me. I had a long talk with Ghinty and, with her aid, I was able to determine the cause. You, ${sirmaam}, are being watched. Magically surveilled, to be more specific."

	Oferi grunts. "The wizard. [i]Tarson[/i]. He's watching ${name}?"

	Finnur nods. "Something—" he pauses and steps up to you, looking you over. He kneels down in front of you and peers at your ring. "This! This ring. It is imbued with an impressive spell that allows the enchanter to observe the wearer at all times. But, while the enchantment is powerful, it is entirely dependent upon a consensual bond."

	"My marriage?" you ask.

	"We can't be under the eye of that old wizard," Oferi says. "I know he is your husband, but I don't know him and I don't trust him."

	Finnur asks, "${name}, did you consummate your marriage to the wizard?"

	*FAKE_CHOICE
		*IF not(wizardlove)
			#"No, we never did [i]that[/i]."
				*TEMP welldidja "nope"

			#"Yes, we consummated the marriage."
				*TEMP welldidja "yeah"

		*IF wizardlove
			#"No, I decided I wasn't ready."
				*TEMP welldidja "nope"

			#"Yes, of course we consummated our marriage."
				*TEMP welldidja "yeah"

	*IF (welldidja="nope")
		Finnur nods. "Then it is a simple matter of annulment. As a senior member of the cardinalate, I have the authority to nullify this marriage at your request."

		"$!{heshe} so requests," says Oferi, nodding to you. "If you wish it, you can remarry him after this task is complete, but I will not permit that wizard to spy upon us for purposes unknown."

		Having no other choice anyway, you nod your consent. Finnur waves his hand and you feel something break away from you that you never realized was attached. He carefully removes the ring from your left hand and slides it on your right hand ring finger.

		"It is done," Finnur says. "You are a free ${manwoman} once again and the wizard can no longer spy on us"
		*GOTO divorced

	*IF (welldidja="yeah")
		Finnur frowns. He says, "Then I am afraid I have no authority to nullify this marriage."
		*GOTO oferidoes


*LABEL oferidoes

"But I do," Oferi says. "Any binding contract made by a citizen under duress may be contested and overturned by the justice authority — which happens to be [i]me[/i]. So, by this authority, I hereby overturn the contract of marriage between the wizard Tarson and ${name} on the grounds that the contract was made under duress and, even if it were not made under duress, the full terms of the contract were not disclosed to both parties — chiefly that ${name} was not aware the contract provided for constant survellience of ${hisher} person."

You feel something break away from you that you never realized was attached. Oferi carefully removes the ring from your left hand and slides it on your right hand ring finger.

*IF finnur
	"That was effective," Finnur says. "The wizard can no longer spy on us. And you are a free ${manwoman} once again."

*IF ghinty and not(finnur)
	"That worked," says Ghinty. "The enchantment is gone. No more wizard voyeur! And you're a free ${manwoman} again, ${name}!"

You nod to Oferi. "I felt the bond break," you say.

Oferi shouts up at the sky, "Even wizards must follow the rules!"

*IF finnur
	"Ah," Finnur says, "you should have done [i]before[/i] overturning the marriage contract."

	"Still," Oferi says. She frowns. "I will tell him later, then."

*IF ghinty and not(finnur)
	Ghinty says, "Umm, Oferi, honey, you know you shoulda shouted at him [i]before[/i] the whole contract-breaking thing."

	"Still," Oferi says. She frowns. "I will tell him later, then."

*LABEL divorced

*IF lish
	"Now you can sow your wild oats, as they say," Lish says, smiling. She then drops her smile and clears her throat. "I mean, umm, sorry about your marriage and all, of course."

*IF tekoa
	"I was never one for being tied down," Tekoa says. "Umm, in matrimony, I mean. Being tied down [i]literally[/i], well..." she drifts off with a smile and a shrug of her shoulders.

	*IF wyverna
		Wyverna shoots Tekoa a lurid glance and Tekoa winks at her.

*IF kerwain
	Kerwain says, "It is offensive to civility to end a marriage for any reason other than death. However, in this case, I understand it was necessary and I do not see your virtue as tarnished."

	*IF ghinty
		"Oh, I'm sure your sanctimonious judgment means [i]oodles[/i] to ${himher}, ya stuffy can of ham," Ghinty says.

	*IF lish
		"Easy there up, big guy," Lish says. "If you're gonna see anyone's virtue tarnished, I want it to be mine!" She laughs and slaps his armored shoulder.

		Kerwain clears his throat and busies himself checking the straps of his shield.

*IF art
	"I prefer weddings to divorces," Art says, "but that's on account that dwarven divorces tend to involve a beard gettin' shaved and [i]that's[/i] an offense to civility."

*IF not(ghinty) and not(finnur)
	Finnur nods to the group. "I will be off now," he says.

	*FAKE_CHOICE
		#"Wait, Finnur. Why don't you join us?"
			*SET finnur true
			*SET dig_finnur %+10
			"You may as well," Oferi says, nodding, "you're here now and, given the valuable service you've provided, I can easily convince the duchess to approve an additional mercenary contract."

			Finnur looks to you and then to Oferi. "I will not kill," he says, "but if I may be otherwise useful, I will accept your offer."

			Oferi grabs his wrist and shakes his hand in the old way. "Be welcome."

			*IF lish
				"The more men the merrier," Lish says, shaking Finnur's hand as well.
			
			*IF ghinty
				"Yay!" Ghinty says. She gives Finnur's backside a light smack. "Our party has a kitty-cat mascot now!"

				"Uncouth as ever, Ghinty," Finnur says with a sigh.

			*IF wyverna
				Wyverna smiles and arches an eyebrow. "Zis is good! Now we may consider more dangerous and productive tactics wiz za druid aboard, ah-no?"

		#Stay quiet
			Finnur says something to Oferi in the elven language and then caroms off into the forest with barely a sound.

*RETURN