*title Multipronoun Example
*author A.E. Elm
*scene_list
  startup

*comment these variables are for the first set of pronouns, and were made via Hannah Powell-Smith's Gender Setting Example code:
*create pc_gender 1
*create pc_he ""
*create pc_him ""
*create pc_his ""
*create pc_singular true

*comment these additional variables are for the second set of pronouns:
*create pc_he2 ""
*create pc_him2 ""
*create pc_his2 ""
*create pc_singular2 true

*comment this variable is for distinguishing between players using multiple sets or a single set of pronouns:

*create multi_pronoun false

*label pronouns
What are your main character's pronouns?
*set multi_pronoun false
*choice
  #She/her.
    *gosub pc_she
    *goto is_that_correct
  #He/him.
    *gosub pc_he
    *goto is_that_correct
  #They/them.
    *gosub pc_they
    *goto is_that_correct
  #Ey/em.
    *gosub pc_ey
    *goto is_that_correct
  #Zie/hir.
    *gosub pc_zie
    *goto is_that_correct
  #I use multiple pronouns interchangeably (she/they, he/they, etc).
    What are your pronouns?
    *set multi_pronoun true
    *fake_choice
      #She/they.
        *gosub pc_she_they
        *goto is_that_correct
      #He/they.
        *gosub pc_he_they
        *goto is_that_correct
      #She/he.
        *gosub pc_she_he
        *goto is_that_correct
      #Something else (enter multiple custom pronouns).
        *label pronounselect1
        Please enter your subjective pronoun @{multi_pronoun for the first set|} (for example, he, she, they). 
        *input_text pc_he
        *comment for each input, we set the second set identically to the first, in case the player is only using one set:
        *set pc_he2 "${pc_he}"
        Please enter your objective pronoun @{multi_pronoun for the first set|} (for example, him, her, them). 
        *input_text pc_him
        *set pc_him2 "${pc_him}"
        Please enter your possessive pronoun @{multi_pronoun for the first set|} (for example his, her, their). 
        *input_text pc_his
        *set pc_his2 "${pc_his}"
        Do your pronouns @{multi_pronoun in the first set|} work best with singular or plural verbs?
        *fake_choice
          #Singular (for example "he says", "she says").
            *set pc_singular true
            *set pc_singular2 true
          #Plural (for example "they say").
            *set pc_singular false
            *set pc_singular2 false

        *comment players inputing two sets of pronouns move on to set the second set, otherwise they go to the end:
 
        *if multi_pronoun = true
          *goto pronounselect2
        *else
          *goto is_that_correct

        *label pronounselect2
        Please enter the subjective pronoun for the second set (for example, he, she, they). 
        *input_text pc_he2
        Please enter your objective pronoun for the second set (for example, him, her, them).
        *input_text pc_him2
        Please enter your possessive pronoun for the second set (for example his, her, their).
        *input_text pc_his2
        Do your pronouns in the second set work best with singular or plural verbs?
        *choice
          #Singular (for example "he says", "she says").
            *set pc_singular2 true
            *goto is_that_correct
          #Plural (for example "they say").
            *set pc_singular2 false
            *goto is_that_correct 
   
  #Something else (enter custom pronouns).
    Do you use a single set of custom pronouns, or multiple?
    *choice
      #A single set (for example they/them/their).
        Ok, a single set.
        *goto pronounselect1
      #Two sets used interchangeably (for example she/they).
        Ok, two sets.
        *set multi_pronoun true
        *goto pronounselect1      

*label pc_she
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "she"
*set pc_him2 "her"
*set pc_his2 "her"
*set pc_singular2 true
*return

*label pc_he
*set pc_he "he"
*set pc_him "him"
*set pc_his "his"
*set pc_singular true
*set pc_he2 "he"
*set pc_him2 "him"
*set pc_his2 "his"
*set pc_singular2 true
*return

*label pc_they
*set pc_he "they"
*set pc_him "them"
*set pc_his "their"
*set pc_singular false
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*return  

*label pc_ey
*set pc_he "ey"
*set pc_him "em"
*set pc_his "eir"
*set pc_singular true
*set pc_he2 "ey"
*set pc_him2 "em"
*set pc_his2 "eir"
*set pc_singular2 true
*return 

*label pc_zie
*set pc_he "zie"
*set pc_him "hir"
*set pc_his "hir"
*set pc_singular true
*set pc_he2 "zie"
*set pc_him2 "hir"
*set pc_his2 "hir"
*set pc_singular2 true
*return 

*label pc_she_they
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*return

*label pc_he_they
*set pc_he "he"
*set pc_him "him"
*set pc_his "his"
*set pc_singular true
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*return

*label pc_she_he
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "he"
*set pc_him2 "him"
*set pc_his2 "his"
*set pc_singular2 true
*return


*label is_that_correct
So, your pronouns are 
*if (multi_pronoun != true)
  ${pc_he}/${pc_him}/${pc_his}, as in: "$!{pc_he} survey@{pc_singular s|} the shop windows, wondering what ${pc_his2} sister would buy for ${pc_him2}."
*if (multi_pronoun = true)
  ${pc_he}/${pc_him} and ${pc_he2}/${pc_him2}, as in:

  "$!{pc_he} need@{pc_singular s|} to slow down if we're going to get this done properly. $!{pc_he}@{pc_singular 's|'re} always rushing around."

  "Yeah, ${pc_he2} can be like that. $!{pc_he2} never take@{pc_singular2 s|} a breather."

*fake_choice
  #Yes, that's right.
  #No, I want to change something.
    *goto pronouns

All right, that concludes this demonstration.
*ending