*title Multipronoun Example
*author A.E. Elm
*scene_list
  startup

*comment these variables are for the first set of pronouns, and were made via Hannah Powell-Smith's Gender Setting Example code:
*create pc_gender 1
*create pc_he ""
*create pc_him ""
*create pc_his ""
*create pc_singular true

*comment these additional variables are for the second set of pronouns (via A.E. Elm):
*create pc_he2 ""
*create pc_him2 ""
*create pc_his2 ""
*create pc_singular2 true

*comment and these variables are for the third set:
*create pc_he3 ""
*create pc_him3 ""
*create pc_his3 ""
*create pc_singular3 true

*comment these variables are for distinguishing between players using multiple sets or a single set of pronouns:
*create multi_pronoun false
*create third_set false

*label pronouns
What are your main character's pronouns?
*set multi_pronoun false
*set third_set false
*choice
  #She/her.
    *gosub pc_she
    *goto is_that_correct
  #He/him.
    *gosub pc_he
    *goto is_that_correct
  #They/them.
    *gosub pc_they
    *goto is_that_correct
  #Ey/em.
    *gosub pc_ey
    *goto is_that_correct
  #Zie/hir.
    *gosub pc_zie
    *goto is_that_correct
  #Xe/xir.
    *gosub pc_xe
    *goto is_that_correct
  #I use multiple pronouns interchangeably (she/they, he/they, etc).
    What are your pronouns?
    *set multi_pronoun true
    *fake_choice
      #She/they.
        *gosub pc_she_they
        *goto is_that_correct
      #He/they.
        *gosub pc_he_they
        *goto is_that_correct
      #She/he.
        *gosub pc_she_he
        *goto is_that_correct
      #She/they/he.
        *set third_set true
        *gosub pc_she_they_he
        *goto is_that_correct
      #Something else (enter multiple custom pronouns).
        *label multi_pronoun_select
        How many pronoun sets will you use? 
        *fake_choice
          #Two sets (for example, she/they).
            Ok, two sets.
            *label pronounselect1
            Please enter the subjective pronoun @{multi_pronoun for the first set|} (for example, he, she, they).
            *comment the if/else in each section are to make randomtest happy. without them you get an error when randomtest runs:
            *if choice_randomtest
              *set pc_he "she"
              *goto objpronoun1
            *else 
              *input_text pc_he
              *set pc_he2 "${pc_he}"
              *set pc_he3 "${pc_he2}"
              *goto objpronoun1
            *label objpronoun1
            Please enter your objective pronoun @{multi_pronoun for the first set|} (for example, him, her, them).
            *if choice_randomtest
              *set pc_him "her"
              *goto pospronoun1
            *else 
              *input_text pc_him
              *set pc_him2 "${pc_him}"
              *set pc_him3 "${pc_him2}"
              *goto pospronoun1
            *label pospronoun1
            Please enter your possessive pronoun @{multi_pronoun for the first set|} (for example his, her, their).
            *if choice_randomtest
              *set pc_his "her"
              *goto singular_or_plural1
            *else 
              *input_text pc_his
              *set pc_his2 "${pc_his}"
              *set pc_his3 "${pc_his2}"
              *goto singular_or_plural1
            *label singular_or_plural1
            Do your pronouns @{multi_pronoun in the first set|} work best with singular or plural verbs?
            *fake_choice
              #Singular (for example "he says", "she says").
                *set pc_singular true
                *set pc_singular2 true
                *set pc_singular3 true
              #Plural (for example "they say").
                *set pc_singular false
                *set pc_singular2 false
                *set pc_singular3 false

            *if multi_pronoun = true
              *goto pronounselect2
            *if multi_pronoun != true
              *goto is_that_correct

            *label pronounselect2
            Please enter the subjective pronoun for the second set (for example, he, she, they).
            *if choice_randomtest
              *set pc_he2 "she"
              *set pc_he3 "${pc_he2}"
              *goto objpronoun2
            *else 
              *input_text pc_he2
              *set pc_he3 "${pc_he2}"
              *goto objpronoun2
            *label objpronoun2
            Please enter your objective pronoun for the second set (for example, him, her, them).
            *if choice_randomtest
              *set pc_him2 "her"
              *set pc_him3 "${pc_him2}"
              *goto pospronoun2
            *else 
              *input_text pc_him2
              *set pc_him3 "${pc_him2}"
              *goto pospronoun2
            *label pospronoun2
            Please enter your possessive pronoun for the second set (for example his, her, their).
            *if choice_randomtest
              *set pc_his2 "her"
              *set pc_his3 "${pc_his2}"
              *goto singular_or_plural2
            *else 
              *input_text pc_his2
              *set pc_his3 "${pc_his2}"
              *goto singular_or_plural2
            *label singular_or_plural2
            Do your pronouns in the second set work best with singular or plural verbs?
            *choice
              #Singular (for example "he says", "she says").
                *set pc_singular2 true
                *set pc_singular3 true
                *goto two_or_three_direct
              #Plural (for example "they say").
                *set pc_singular2 false
                *set pc_singular3 false
                *goto two_or_three_direct 
            
            *label two_or_three_direct

            *if third_set != true
              *goto is_that_correct
            *if third_set = true
              *goto pronounselect3

            *label pronounselect3
            Please enter the subjective pronoun for the third set (for example, he, she, they).
            *if choice_randomtest
              *set pc_he3 "she"
              *goto objpronoun3
            *else 
              *input_text pc_he3
              *goto objpronoun3
            *label objpronoun3
            Please enter your objective pronoun for the third set (for example, him, her, them).
            *if choice_randomtest
              *set pc_him3 "her"
              *goto pospronoun3
            *else 
              *input_text pc_him3
              *goto pospronoun3
            *label pospronoun3
            Please enter your possessive pronoun for the third set (for example his, her, their).
            *if choice_randomtest
              *set pc_his3 "her"
              *goto singular_or_plural3
            *else 
              *input_text pc_his3
              *goto singular_or_plural3
            *label singular_or_plural3
            Do your pronouns in the third set work best with singular or plural verbs?
            *fake_choice
              #Singular (for example "he says", "she says").
                *set pc_singular3 true
                *goto is_that_correct
              #Plural (for example "they say").
                *set pc_singular3 false
                *goto is_that_correct

          #Three sets (for example, she/they/he).
            Ok, three sets.
            *set third_set true
            *goto pronounselect1

  #Something else (enter custom pronouns).
    Do you use a single set of custom pronouns, or multiple?
    *choice
      #A single set (for example they/them/their).
        Ok, a single set.
        *goto pronounselect1
      #Two sets used interchangeably (for example she/they).
        Ok, two sets.
        *set multi_pronoun true
        *goto pronounselect1
      #Three sets used interchangeably (for example she/they/he).
        Ok, three sets.
        *set multi_pronoun true
        *set third_set true
        *goto pronounselect1      

*label pc_she
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "she"
*set pc_him2 "her"
*set pc_his2 "her"
*set pc_singular2 true
*set pc_he3 "she"
*set pc_him3 "her"
*set pc_his3 "her"
*set pc_singular3 true
*return

*label pc_he
*set pc_he "he"
*set pc_him "him"
*set pc_his "his"
*set pc_singular true
*set pc_he2 "he"
*set pc_him2 "him"
*set pc_his2 "his"
*set pc_singular2 true
*set pc_he3 "he"
*set pc_him3 "him"
*set pc_his3 "his"
*set pc_singular3 true
*return

*label pc_they
*set pc_he "they"
*set pc_him "them"
*set pc_his "their"
*set pc_singular false
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*set pc_he3 "they"
*set pc_him3 "them"
*set pc_his3 "their"
*set pc_singular3 false
*return  

*label pc_ey
*set pc_he "ey"
*set pc_him "em"
*set pc_his "eir"
*set pc_singular true
*set pc_he2 "ey"
*set pc_him2 "em"
*set pc_his2 "eir"
*set pc_singular2 true
*set pc_he3 "ey"
*set pc_him3 "em"
*set pc_his3 "eir"
*set pc_singular3 true
*return 

*label pc_zie
*set pc_he "zie"
*set pc_him "hir"
*set pc_his "hir"
*set pc_singular true
*set pc_he2 "zie"
*set pc_him2 "hir"
*set pc_his2 "hir"
*set pc_singular2 true
*set pc_he3 "zie"
*set pc_him3 "hir"
*set pc_his3 "hir"
*set pc_singular3 true
*return 

*label pc_xe
*set pc_he "xe"
*set pc_him "xem"
*set pc_his "xir"
*set pc_singular true
*set pc_he2 "xe"
*set pc_him2 "xem"
*set pc_his2 "xir"
*set pc_singular2 true
*set pc_he3 "xe"
*set pc_him3 "xem"
*set pc_his3 "xir"
*set pc_singular3 true
*return 

*label pc_she_they
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*set pc_he3 "they"
*set pc_him3 "them"
*set pc_his3 "their"
*set pc_singular3 false
*return

*label pc_he_they
*set pc_he "he"
*set pc_him "him"
*set pc_his "his"
*set pc_singular true
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*set pc_he3 "they"
*set pc_him3 "them"
*set pc_his3 "their"
*set pc_singular3 false
*return

*label pc_she_he
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "he"
*set pc_him2 "him"
*set pc_his2 "his"
*set pc_singular2 true
*set pc_he3 "she"
*set pc_him3 "him"
*set pc_his3 "her"
*set pc_singular3 true
*return

*label pc_she_they_he
*set pc_he "she"
*set pc_him "her"
*set pc_his "her"
*set pc_singular true
*set pc_he2 "they"
*set pc_him2 "them"
*set pc_his2 "their"
*set pc_singular2 false
*set pc_he3 "he"
*set pc_him3 "him"
*set pc_his3 "his"
*set pc_singular3 true
*return


*label is_that_correct
So, your pronouns are 
*if (third_set != true) and (multi_pronoun != true)
  ${pc_he}/${pc_him}/${pc_his}, as in: "$!{pc_he} survey@{pc_singular s|} the shop windows, wondering what ${pc_his3} sister would buy for ${pc_him2}."
*if (third_set != true) and (multi_pronoun = true)
  ${pc_he}/${pc_him} and ${pc_he2}/${pc_him2}, as in:

  "$!{pc_he} need@{pc_singular s|} to slow down if we're going to get this done properly. $!{pc_he}@{pc_singular 's|'re} always rushing around."

  "Yeah, ${pc_he2} can be like that. $!{pc_he3} never take@{pc_singular3 s|} a breather."
*if (third_set = true) 
  ${pc_he}/${pc_him}, ${pc_he2}/${pc_him2}, and ${pc_he3}/${pc_him3}, as in: 

  "$!{pc_he} need@{pc_singular s|} to slow down if we're going to get this done properly. $!{pc_he2}@{pc_singular2 's|'re} always rushing around."

  "Yeah, ${pc_he3} can be like that. $!{pc_he3} never take@{pc_singular3 s|} a breather."  

Is that right?

*fake_choice
  #Yes, that's right.
  #No, I want to change something.
    *goto pronouns

All right, that concludes this demonstration.
*ending