*label he
*set you_xe "he"
*set you_xyr "his"
*set you_xyrs "his"
*set you_xem "him"
*set you_s "s"
*set you_es "es"
*set you_re "s"
*set you_plural false
*return

*label she
*set you_xe "she"
*set you_xyr "her"
*set you_xyrs "hers"
*set you_xem "her"
*set you_s "s"
*set you_es "es"
*set you_re "s"
*set you_plural false
*return

*label they
*set you_xe "they"
*set you_xyr "their"
*set you_xyrs "theirs"
*set you_xem "them"
*set you_s ""
*set you_es ""
*set you_re "re"
*set you_plural true
*return

*label custom
What's your [b]subjective pronoun[/b] (he/she/they)? (For example: [pronoun] walked to the store.)
*input_text you_xe
What's your [b]possessive adjective[/b] (his/her/their)? (For example: I took [pronoun] pencil.)
*input_text you_xyr
What's your [b]possessive pronoun[/b] (his/hers/theirs)? (For example: That backpack is [pronoun]).
*input_text you_xyrs
What's your [b]objective pronoun[/b] (him/her/them)? (For example: The teacher called on [pronoun]).
*input_text you_xem
And finally: is your pronoun singular or plural?
*fake_choice
    #Singular. ("$!{you_xe} [i]writes[/i] ${you_xyr} homework.")
        *set you_s "s"
        *set you_es "es"
        *set you_re "s"
        *set you_plural false
    #Plural. ("$!{you_xe} [i]write[/i] ${you_xyr} homework.")
        *set you_s ""
        *set you_es ""
        *set you_re "re"
        *set you_plural true
*return

*label example
So, this is how your pronouns work. (Practice sentences are stolen from [i]Welcome to Night Vale[/i] and, more specifically, from the
*link https://www.practicewithpronouns.com/ Practice with Pronouns
website.)

*temp dieroll
*rand dieroll 1 6

*if (dieroll = 1)
    [i]$!{you_xe} stay${you_s} inside ${you_xyr} office at all times, only communicating with us through sealed envelopes that are spat out from under the door like a sunflower shell through teeth.[/i]
*elseif (dieroll = 2)
    [i]A happy big three-oh to the immortal screen legend, who is celebrating ${you_xyr} special day by opening ${you_xyr} seventh eye, and incinerating onlookers by the wailing hundreds with ${you_xyr} holy light.[/i]
*elseif (dieroll = 3)
    [i]Whatever ${you_xe}
    *if (you_plural)
        are,
    *else
        is,
    and whatever ${you_xyr} effects on neighborhoods, ${you_xe}'${you_re} a Night Vale landmark and should be protected.[/i]
*elseif (dieroll = 4)
    [i]$!{you_xe} moved on from ${you_xyr} energy tips to reminisce a bit about some projects of ${you_xyrs} that didn't go exactly according to plan.[/i]
*elseif (dieroll = 5)
    [i]$!{you_xe}'${you_re} shutting down the Earth Sciences program in order to devote ${you_xem}self fully to understanding what has happened to ${you_xyr} mind, and this ended — but yet also not ended — world.[/i]
*else
    [i]The cave paintings mainly resemble smudges now, after ${you_xe} attempted to power wash them off the wall because ${you_xe} - on religious grounds - did not believe in the past.[/i]

Is that right?
*return