*label homescreen
*if (name != "")
    Name: ${name}
*else
    Name: [i]As yet unknown[/i]
*line_break
*if (you_xe != "")
    Pronouns: ${you_xe}/${you_xem}
*else
    Pronouns: [i]As yet unknown[/i]

*if ((you_xe != "") or (name != ""))
    *choice
        *selectable_if (you_xe != "") #Change pronouns.
            *label proswitch
            Your current pronouns are ${you_xe}/${you_xem}.

            *choice
                #I want to keep using ${you_xe}/${you_xem}. (Back to homescreen.)
                    *goto homescreen
                *if (you_xe != "he")
                    #I want to use he/him.
                        *gosub_scene sub_setpronouns he
                        *goto test
                *if (you_xe != "she")
                    #I want to use she/her.
                        *gosub_scene sub_setpronouns she
                        *goto test
                *if (you_xe != "they")
                    #I want to use they/them.
                        *gosub_scene sub_setpronouns they
                        *goto test
                #Here, let me type in my new pronouns for you.
                    *gosub_scene sub_setpronouns custom
                    *goto test

            *label test
            *gosub_scene sub_setpronouns example
            *choice
                #Yes, that's right. (Back to homescreen.)
                    *goto homescreen
                #Let me try that again…
                    *goto proswitch
        *selectable_if (name != "") #Change name.
            *label nameswitch
            Your name is…
            *input_text name
            ${name}? Is that you?
            *choice
                #Yes, that's me!
                    *goto homescreen
                #No, wait a sec.
                    *goto nameswitch