*label start

It's your first day of college!

You stretch in your dorm room and sleepily hit the snooze button on your alarm clock for about the third time. It's so [i]early[/i]. Why are freshman orientations so [i]early[/i]?

Unfortunately, your circa five seconds of extra sleep are interrupted by your roommate calling your name.

*if (name = "")
    *goto namechoice
*else
    "${name}!" yells Natalie from somewhere to your right. "It's already seven-thirty!"
    *goto continuing

*label namechoice
*fake_choice
    #"Jules!"
        *set name "Jules"
    #"Avery!"
        *set name "Avery"
    #"Ella!"
        *set name "Ella"
    #"Elliot!"
        *set name "Elliot"
    #"Dora!"
        *set name "Dora"
    #"Diego!"
        *set name "Diego"
    #My roommate yells something else.
        *input_text name

Your name is ${name}?

*choice
    #Yep, that's me!
        Natalie's footsteps approach. "${name}?"
        *goto continuing
    #Hang on…
        What does your roommate yell?
        *goto namechoice

*label continuing

"Okay, okay, I'm up," you groan, rolling out of bed and accidentally knocking your alarm clock off of the dresser. Natalie tries and fails to hide a smile as you curse and put it back in its place.

She's already dressed, immaculately turned out in pinstripes and dress shoes. Leave it to Natalie to look completely unruffled at the prospect of waking up this early for orientation.

You, on the other hand…

*fake_choice
    #…are throwing on a similar suit.
        *set style "suit"
        
        "Stealing my thunder, are you?" Natalie asks, eyebrow raised.
        
        You grin, lopsided, and place a hand over your heart. "I would never."
    #…are slipping into a ballgown.
        *set style "gown"
        
        "This isn't the Met Gala," Natalie comments.
        
        You scowl at her. "[i]You're[/i] in a [i]pinstripe suit.[/i]"
        
        "Point taken."
    #…are throwing on a hoodie. (And jeans.)
        *set style "hoodie"
        
        It's orientation. It's not that big of a deal. Plus, baggy clothing has always been your thing.
        
        "What a pair we make," Natalie deadpans. "The dynamic duo, truly."
        
        You contemplate throwing the alarm clock at her.
    #…are throwing on a T-shirt. (And jeans.)
        *set style "shirt"
        
        It's orientation. It's not that big of a deal. Probably.
        
        "What a pair we make," Natalie deadpans. "The dynamic duo, truly."
        
        You contemplate throwing the alarm clock at her.

You pick up your tote bag filled with freshman orientation files, smiling at the pin haphazardly tacked onto its side. This was your first gift from Natalie back in high school — a pronoun pin.
*if (you_xe = "")
    *goto pronounchoice
*else
    *if (you_fluid)
        It reads "depends" on it in Comic Sans (Natalie didn't have the greatest graphic design skills) and is colored a violent shade of yellow. You fondly recall having to convince her not to cram "please ask pronouns" onto one pin; she still pouts about it sometimes.
    *else
        It reads "${you_xe}/${you_xem}" on it in Comic Sans (Natalie didn't have the greatest graphic design skills) and is colored a violent shade of yellow.
    
    *goto afterpin

*label pronounchoice
The pin reads…

[[i]Note: You can always change your pronouns (and name) in the stats screen.[/i]]

*fake_choice
    #"she/her"
        *gosub_scene sub_setpronouns she
    #"he/him"
        *gosub_scene sub_setpronouns he
    #"they/them"
        *gosub_scene sub_setpronouns they
    #"depends" [[i]You will have the option to change your pronouns before each major scene.[/i]]
        *set you_fluid true
        You had had to convince Natalie not to cram "please ask pronouns" onto one pin. She still pouts about it sometimes.
        
        Nevertheless, what are your pronouns as of right now?
        *fake_choice
            #She/her.
                *gosub_scene sub_setpronouns she
            #He/him.
                *gosub_scene sub_setpronouns he
            #They/them.
                *gosub_scene sub_setpronouns they
            #Different pronouns.
                *gosub_scene sub_setpronouns custom
    #I use neopronouns.
        *gosub_scene sub_setpronouns custom

Your pin reads "${you_xe}/${you_xem}"?
*choice
    #Yep, those are my pronouns.
        *goto afterpin
    #Wait, no, that's not right.
        *goto pronounchoice

*label afterpin
"Come on, slowpoke!" Natalie calls from the doorway, and you pause your reminiscing, hurriedly slinging your bag over your shoulder and standing up. "We're going to be late!"

*page_break "I'm ready!"

[[i]This is where one would put the rest of the chapter, if this were an actual game. Since it is instead a tutorial, I'm just putting this author's note here as a transition to the next chapter.[/i]]

*finish