Before we begin, a quick question: would you like to choose your name and pronouns now, or more organically in the story?

*choice
    #Choose now.
        *goto namechoice
    #No, on with the story!
        As you wish.
        
        *finish Onwards!

*label namechoice
What's your name?
*fake_choice
    #Jules.
        *set name "Jules"
    #Avery.
        *set name "Avery"
    #Ella.
        *set name "Ella"
    #Elliot.
        *set name "Elliot"
    #Dora.
        *set name "Dora"
    #Diego.
        *set name "Diego"
    #Here, I'll type it in for you.
        *input_text name

Your name is ${name}?

*choice
    #Yep, that's me!
        Excellent.
    #Hang on…
        *goto namechoice

Now for your pronouns (you can change these later).
*label pronounchoice
You use…

*fake_choice
    #They/them.
        *gosub_scene sub_setpronouns they
    #He/him.
        *gosub_scene sub_setpronouns he
    #She/her.
        *gosub_scene sub_setpronouns she
    #Here, let me type it in for you.
        *gosub_scene sub_setpronouns custom

*label test
*gosub_scene sub_setpronouns example
*choice
    #Yep, those are my pronouns.
        *goto genderfluid
    #Wait, no, that's not right.
        *goto pronounchoice

*label genderfluid
One last thing — do your pronouns change from day to day?
*fake_choice
    #Yes. [[i]You'll have the opportunity to choose new pronouns at the start of each scene.[/i]]
        *set you_fluid true
    #No.
        *set you_fluid false

Alright, looks like we're all set! [[i]Note: You can always go to the stats screen to adjust your name and pronouns.[/i]]
*finish Onwards!