*title Obsolete Stars
*author Anandra
*scene_list
  startup
  chapter01
  chapter02
  chapter03
  chapter04
  chapter05
  chapter06
  chapter07
  chapter08
  chapter09
*create name "unknown"
*create nickname ""
*create team "prologue"
*create knowsSascha "false"
*create knowsKate "false"
*create knowsAlia "false"
*create knowsMikhail "false"
*create knowsS "false"
*create knowsTK "false"
*create knowsGigi "false"
*create Sascha ""
*create Kate ""
*create Alia ""
*create Mikhail ""
*create S "Samuel"
*create TK "Tarek"
*create T ""
*create Sa ""
*create Gigi ""
*create gender ""
*create they "they"
*create them "them"
*create their "their"
*create theirs "theirs"
*create themselves "themselves"
*create Highness "your Highness"
*create plural true
*create TKthey "he"
*create TKthem "him"
*create TKtheir "his"
*create TKtheirs "his"
*create TKthemself "himself"
*create TKman "man"
*create TKC "none"
*create SC "none"
*create Sthey "he"
*create Sthem "him"
*create Stheir "his"
*create Stheirs "his"
*create Sthemself "himself"
*create Sman "man"
*create SaschaF 0
*create SaschaR 0
*create SaschaA 0
*create KateF 0
*create KateR 0
*create AliaF 0
*create AliaR 0
*create MikhailR 0
*create MikhailF 0
*create TKR 0
*create TKF 0
*create SR 0
*create SF 0
*create GigiF 0
*create GigiR 0
*create TKSP 0
*create TKMP 0
*create SGP 0
*create height ""
*create hairlength ""
*create haircolor ""
*create hairstyle ""
*create skincolor ""
*create skintexture1 ""
*create skintexture2 ""
*create eyecolor ""
*create glasses ""
*create headcover ""
*create hairtexture ""
*create hairtie ""
*create warnings "false"
*create touchaversion false
*create cheater false
*create sex ""
*create trans ""
*create execution false
*create rebel 0
*create angry 0
*create knowsMAbleeding false
*create knowsMAbones false
*create knowsfamine 0
*create time ""
*create virgin true
*create kissedA "no"
*create knowsPirates false
*create dogs true
*create knowswar false
*create weapon ""
*create death 0
*create mikhaildeath 0
*achievement death visible 10 First Time here?
 You have met a terrible fate, haven't you?
 Get your first game over. I'm proud of you.
*achievement mikhaildeath visible 10 Beloved Warrior.
 Lover of a War.
 People don't always change, eh?

*sm_init obsoletestars | 10
I'm not gonna do the whole "Looking into a mirror" for customization, so lets get all the customization part out of the way first. 

*temp person 0
*temp game 0
*temp look 0
*temp hair 0
*temp skin 0
*temp eyes 0

*label base
Even if anything doesn't directly apply to you during the customization (example, headcovering, or hairstyle when you are bald), please still go through it and simply chose the "No" option, so the code actually knows you've been through everything and didn't skip anything, otherwise that might lead to future errors for some situations.

The code shouldn't even let you skip any options, but I mightve messed up somewhere.

*choice
 *selectable_if (game < 3) #Game Basics (warnings, game settings, etc)
  *goto game
 *selectable_if (person < 6) #Personal stuff (name, pronouns, etc)
  *goto person
 *selectable_if (look < 5) #Actual customization (what you look like)
  *goto look
 #Can I get a preset?
   Sure.
   *goto preset
 *selectable_if (((game = 3) and (person = 6)) and (look = 5)) #Skip to a different chapter (Only selectable if you finish the customization, or use a preset)
  *goto skip 
 *selectable_if (((game = 3) and (person = 6)) and (look = 5)) #I think I'm done. 
  *goto prologue

*label look
Please imagine some dramatic "Looking into the mirror, I inspect myself" situation for this.

*choice
 *disable_reuse #Height
  *set look +1
  *goto height
 *selectable_if (hair < 4) #Hair
  *set look +1
  *comment dont forget hair lenght, texture, style, and color 
  *goto hair 
 *disable_reuse #Headcovering
  *set look +1
  *goto headcovering
 *disable_reuse #Skin
  *comment skin color, feature 1 and 2
  *set look +1
  *goto skin
 *disable_reuse #Eyes
  *set look +1
  *goto eyes
 #Return
  *goto base

*label eyes
*choice
 *disable_reuse #Eyecolor
  *set eyes +1
  *goto eyecolor
 *disable_reuse #Glasses
  *set eyes +1
  *goto glasses
 *selectable_if (eyes = 2) #Return
  *goto look

*label skin
Skin texture is meant for scars, freckles, moles, vitilligo and more, if none apply, still go through skin texture 1 and choose "perfect skin".
*choice
 *disable_reuse #Skin color.
  *goto skincolor
 *disable_reuse #Skin texture 1
  *set skin +1
  *goto skintexture1
 *selectable_if (skin = 1) #Skin texture 2
  *set skin +1
  *goto skintexture2
 *selectable_if (skin = 2) #Return
  *goto look

*label hair
*choice
 *disable_reuse #Hair length
  *set hair +1
  *goto hairlength
 *disable_reuse #Hair texture
  *set hair +1
  *goto hairtexture
 *disable_reuse #Hair style
  *set hair +1
  *goto hairstyle
 *disable_reuse #Hair color
  *set hair +1
  *goto haircolor
 #Return
  *goto look

*label person
These are meant for the information of your character.
*choice
 *disable_reuse #Name
  *set person +1
  *goto name
 *disable_reuse #Nickname
  *set person +1
  *goto nickname
 *disable_reuse #Gender
  *set person +1
  *goto gender
 *disable_reuse #Sex
  *set person +1
  *goto sex
 *disable_reuse #Cis/Transgender
  *set person +1
  *goto trans
 *disable_reuse #Pronouns
  *set person +1
  *goto pronouns
 #Return
  *goto base

*label game
These are meant for general experience and game settings, of which you can change most of them in the stat seetings.
*choice
 *disable_reuse #Warning settings
  *set game +1
  *goto warningsetting
 *disable_reuse #Touch aversion
  *set game +1
  *goto touchaversion
 *disable_reuse #Romantic preferances
  *set game +1
  *goto TKS
 #Return
  *goto base

*label warningsetting
This book plans to include multiple heavy topics that may be triggering for some readers.
*line_break
This book will [b]not[/b] include Trans-/Homophobia and/or Xenophobia. 
*line_break
This book is meant as an exploration of many topics, but not intolerance itself. If I miss certain topics that should be included on the list, please let me know. 
*choice
 #I'd like to see the list of warnings.
  Here's a list of potential warnings of topics mentioned, discussed, and experienced throughout the book:
  *line_break
  Currently mentioned: past self-harm, burn scars, vomit and sickness, blackmail.
  *line_break
  Planned: descriptions of famine, war, and illnesses. Mentioned (war) crimes, murder, and wounds. An exploration of one's mental health. Death and loss of characters and possibly your character. 
  *line_break
  This list will be expanded as the story continues.
  *goto warningschoice
 #I'd like to skip the warnings.
  *goto warningschoice
*label warningschoice
Would you like to turn on warnings for each chapter? (You can turn it on/off in your stats)
*fake_choice
 #Turn it [i]on[/i].
  *set warnings "true"
 #Keep it [i]off[/i].
*goto game
*label touchaversion
Before we can start, we need to get a few things sorted out beforehand.
*line_break
Actions that have romantic or sexual intent will be marked by "[b]♡[/b]", meanwhile friendship actions will be marked by "[b]☆[/b]". 
*line_break
Options that will [i]greatly negatively[/i] impact friendships or romance will be marked by "[b]▽[/b]".
*line_break 
You do not need to choose friendship or romantic options to befriend or romance any of the characters, however, it is to keep track of your interest in them.
*line_break
*line_break
Romance is a focus of this book, although not required to finish, you can play as however you see fit. Regardless of how you chose to play this, interactions with the characters are in the foreground. 
*line_break
Therefore, are you touch-averse? (You can change this at any time in the stats settings)
*label TAs
*choice
 *disable_reuse #What is touch aversion?
  Broadly speaking, touch aversion describes the stress, dislike, and/or fear of being touched by other people. Toggling the touch aversion will change the characters' behavior around you, to not needlessly touch you. This will not change any friendship or romance-related stats, however, it will change friendship and romance-related scenes to be mindful of your touch aversion. This is purely to make you (or your character for that matter) feel more comfortable.
  *goto touchaversion
 #Yes. I am touch averse.
  *set touchaversion true
  *goto game
 #No. I am not touch averse.
  *set touchaversion false
  *goto game

*label TKS
There are 7 Love Interests, 2 of which identify as male, 3 of them identify as female, and the other 2 are gender selectable, meaning you get to choose their genders.
*choice
 #I want them both to be female.
  *set S "Samira"
  *set Sthey "she"
  *set Sthem "her"
  *set Stheir "her"
  *set Stheirs "hers"
  *set Sthemself "herself"
  *set Sman "woman"
  *set TK "Takischa"
  *set TKthey "she"
  *set TKthem "her"
  *set TKtheir "her"
  *set TKtheirs "hers"
  *set TKthemself "herself"
  *set TKman "woman"
  *goto game
 #I want them both to be male.
  *set TK "Tarek"
  *set S "Samuel"
  *goto game
 #I want Sammy to be female, and TK to be male.
  *set TK "Tarek"
  *set S "Samira"
  *set Sthey "she"
  *set Sthem "her"
  *set Stheir "her"
  *set Stheirs "hers"
  *set Sthemself "herself"
  *set Sman "woman"
  *goto game
 #I want Sammy to be male, and TK to be female.
  *set TK "Takischa"
  *set TKthey "she"
  *set TKthem "her"
  *set TKtheir "her"
  *set TKtheirs "hers"
  *set TKthemself "herself"
  *set TKman "woman"
  *set S "Samuel"
  *goto game

*label name
What is your name?
*fake_choice
 #Cain
  *set name "Cain"
  *goto person
 #Hagar
  *set name "Hagar"
  *goto person
 #Rahab
  *set name "Rahab"
  *goto person
 #Haman
  *set name "Haman"
  *goto person
 #Saul
  *set name "Saul"
  *goto person
 #Jezebel
  *set name "Jezebel"
  *goto person
 #Who chose these names? I'll spell it out for you.
  Forgive me, your Highness. Let me get you a pen. Here, write down your name, please capitalize.
  *input_text name
*if name = ("Kate")
 *goto warning
*elseif name = ("Samuel")
 *goto warning
*elseif name = ("Samira")
 *goto warning
*elseif name = ("Alia")
 *goto warning
*elseif name = ("Tarek")
 *goto warning
*elseif name = ("Takischa")
 *goto warning
*elseif name = ("Mikhail")
 *goto warning
*elseif name = ("Sascha")
 *goto warning
*elseif name = ("Gigi")
 *goto warning
*elseif name = ("Adam")
 *goto warning 
*else
 Am I reading this correctly, your name is $!{name}, your Highness?
 *choice
  #Yes, of course, I don't make mistakes.
   *goto person
  #No, of course not, you imbecile!
   I am deeply sorry, your Highness, forgive me. Please correct me, once again.
   *goto name
*label warning
The name you input is the same as one of the characters that will play a role in the game, to reduce confusion in the future, I would advise you to perhaps choose a different name.
*fake_choice
 #I want to choose a different name.
  *goto name
 #Do you have any idea how many people I know that are named $!{name}? I can manage myself without your help.
  I am sorry for making assumptions, your Highness. 
  *goto person

*label nickname
As your name is $!{name}, do you go by any nickname? Or would you prefer not to? (Again, please use proper capitalization)
*choice 
 #No. I prefer not to have a nickname.
  *set nickname "no" 
  *goto person
 #Yes, I also go by the nickname...
  *input_text nickname
   *comment check capitalization
Is $!{nickname} correct?
*choice
 #Yes.
  *goto person
 #No.
   *goto name

*label gender
Please select your gender. This is what people will refer to as this is not about biology, but rather about the social aspects.
*fake_choice
 #Man.
  *set gender "man"
  *goto person
 #Woman.
  *goto person
  *set gender "woman"
  *goto person
 #Non-binary.
  *set gender "person"
  *goto person

*label sex
Please select your sex.
*fake_choice
 #Male.
  *set sex "male"
  *goto person
 #Female.
  *set sex "female"
  *goto person
 #Intersex.
  *set sex "intersex"
  *goto person
 *disable_reuse #What is intersex?
  Intersex describes people who have biological sex characteristics from both male and female sex, making it impossible to say that they're one or the other; or the lack thereof these sex characteristics.
  *goto sex

*label trans
Are you cisgender or transgender?
*fake_choice
 *disable_reuse #What does cisgender and transgender mean?
  Cisgender describes that the sex you were born as is the same as your social gender.  
  *line_break
  Transgender describes the opposite. That you do not feel like the biological sex is the same as your gender.
  *goto trans
 #I'm transgender.
  *set trans "transgender"
  *goto person
 #I'm cisgender.
  *set trans "cisgender"
  *goto person

*label pronouns
Please choose a set of pronouns that you use. (Changeable in the Stats settings)
*fake_choice
 #[i](he/him)[/i]
  *set they "he"
  *set them "him"
  *set their "his"
  *set theirs "his"
  *set themselves "himself"
  *set Highness "my Prince"
  *set plural false
  *goto person
 #[i](she/her)[/i]
  *set they "she"
  *set them "her"
  *set their "her"
  *set theirs "hers"
  *set themselves "herself"
  *set Highness "my Princess"
  *set plural false
  *goto person
 #[i](they/them)[/i]
  *goto person
 #[i](create your own pronouns)[/i]
  *goto input_pronoun
*label input_pronoun
Please input:
Your subjective pronoun [i](he, she, they...)[/i]
*input_text they
Your objective pronoun [i](him, her, them...)[/i]
*input_text them
Your dependent possessive pronouns [i](his, her, their...)[/i]
*input_text their
Your independent possessive pronouns [i](his, hers, theirs...)[/i]
*input_text theirs
Your reflexive pronouns [i](himself, herself, themselves...)[/i]
*input_text themselves
Using your pronouns, will verbs be set in singular or plural?
*line_break
She/he look[b]s[/b] angry. [i](Singular)[/i]
*line_break
They look angry. [i](Plural)[/i]
*fake_choice
 #Singular
  *set plural false
  *goto checkpronouns
 #Plural
  *goto checkpronouns
*label checkpronouns
So it would be...
*line_break
[b]$!{they}[/b] look@{plural |s} angry.
*line_break
Can you help [b]${them}[/b]?
*line_break
That is [b]${their}[/b] bag.
*line_break
These books are [b]${theirs}[/b].
*line_break
$!{they} thanked [b]${themselves}[/b]
Correct?
*fake_choice
 #Yes.
  *goto person
 #No...
  *goto input_pronoun


*label height
You would describe your height as...
*fake_choice
 #Very tall. [i](over 6"4/1.95m)[/i]
  *set height "very tall"
  *goto look
 #Tall. [i](6"3-5"9/1.94m-1.80m)[/i]
  *set height "tall"
  *goto look
 #Average. [i](5"8-5"5/1.79m-1.65m)[/i]
  *set height "average"
  *goto look
 #Below Average. [i](5"4-5"/1.64m-1.50m)[/i]
  *set height "below average"
  *goto look
 #Small. [i](under 5"/1.49m)[/i]
  *set height "small"
  *goto look
*label hairlength
Now about your hair... How long was it again?
*fake_choice
 #very long hair, falling down the entire length of your back.
  *set hairlength "very long"
  *goto hair
 #long hair, cutting off at the midway point of your back.
  *set hairlength "long"
  *goto hair
 #shoulder length hair, it falls just over your shoulders comfortably.
  *set hairlength "shoulder length"
  *goto hair
 #shoulder length hair, cutting off right at your shoulders, the tips ghosting over them. 
  *set hairlength "shoulder length"
  *goto hair
 #chin length hair, cutting off comfortably at your chin.
  *set hairlength "chin length"
  *goto hair
 #short, cutting off at your ears.
  *set hairlength "short"
  *goto hair
 #very short hair.
  *set hairlength "very short"
  *goto hair
 #buzzed hair.
  *set hairlength "buzzed"
  *goto hair
 #bald scalp.
  *set hairlength "bald"
  *goto hair

*label hairtexture
Your hair texture, you would describe as...
*fake_choice
 #Kinky.
  *set hairtexture "kinky"
  *goto hair
 #Tight curls.
  *set hairtexture "tight curls"
  *goto hair
 #Thick curls.
  *set hairtexture "thick curls"
  *goto hair
 #Wavy.
  *set hairtexture "waves"
  *goto hair
 #Loose waves.
  *set hairtexture "loose waves"
  *goto hair
 #Straight.
  *set hairtexture "straight"
  *goto hair
 #Bald.
  *goto hair

*label hairstyle
And you normally wear it as...
*fake_choice
 #Natural, hair down.
  *set hairstyle "natural"
  *goto hair
 #In a hime cut.
  *set hairstyle "himecut"
  *goto hair
 #In a wolf's cut.
  *set hairstyle "wolfs cut"
  *goto hair
 #Kinky.
  *set hairstyle "kinky"
  *goto hair
 #In ringlets
  *set hairstyle "ringlets"
  *goto hair
 #In a mohawk.
  *set hairstyle "mohawk"
  *goto hair
 #With an undercut.
  *set hairstyle "undercut"
  *goto hair
 #Pulled back into a ponytail.
  *set hairstyle "ponytail"
  *goto hair
 #Pulled into pigtails.
  *set hairstyle "pigtails"
  *goto hair
 #In a mullet.
  *set hairstyle "mullet"
  *goto hair
 #Pulled into a braid.
  *set hairstyle "braid"
  *goto hair
 #In an updo.
  *set hairstyle "updo"
  *goto hair
 #As cornrows.
  *set hairstyle "cornrows"
  *goto hair
 #As dreadlocks.
  *set hairstyle "dreadlocks"
  *goto hair
 #In locks.
  *set hairstyle "locks"
  *goto hair
 #In waves.
  *set hairstyle "waves"
  *goto hair
 #As an afro.
  *set hairstyle "afro"
  *goto hair

*label haircolor
Your hair is naturally...
*fake_choice
 #Jet black.
  *set haircolor "jet black"
  *goto hair
 #Black.
  *set haircolor "black"
  *goto hair
 #Grey.
  *set haircolor "grey"
  *goto hair
 #Dark brown.
  *set haircolor "dark brown"
  *goto hair
 #Brown.
  *set haircolor "brown"
  *goto hair
 #Light brown.
  *set haircolor "light brown"
  *goto hair
 #Bright red.
  *set haircolor "bright red"
  *goto hair
 #Red.
  *set haircolor "red"
  *goto hair
 #Orange.
  *set haircolor "orange"
  *goto hair
 #Dark blonde.
  *set haircolor "dark blonde"
  *goto hair
 #Blonde.
  *set haircolor "blonde"
  *goto hair
 #Light blonde.
  *set haircolor "light blonde"
  *goto hair
 #White.
  *set haircolor "white"
  *goto hair

*label headcovering
Do you wear any headcovering?
*fake_choice
 #No.
  *set headcover "no"
  *goto look
 #Yes, a veil.
  *set headcover "veil"
  *goto look
 #Yes, a headscarf.
  *set headcover "headscarf"
  *goto look

*label skincolor
And how would you describe your skin color?
*label skincolorchoice
*fake_choice
 #Porcelain.
  *set skincolor "porcelain"
  *goto skin
 #Ivory.
  *set skincolor "ivory"
  *goto skin
 #Sand.
  *set skincolor "sand"
  *goto skin
 #Limestone.
  *set skincolor "limestone"
  *goto skin
 #Beige.
  *set skincolor "beige"
  *goto skin
 #Sienna.
  *set skincolor "sienna"
  *goto skin
 #Honey.
  *set skincolor "honey"
  *goto skin
 #Amber.
  *set skincolor "amber"
  *goto skin
 #Olive.
  *set skincolor "olive"
  *goto skin
 #Tan.
  *set skincolor "tan"
  *goto skin
 #Almond.
  *set skincolor "almond"
  *goto skin
 #Bronze.
  *set skincolor "bronze"
  *goto skin
 #Sepia.
  *set skincolor "sepia"
  *goto skin
 #Umber.
  *set skincolor "umber"
  *goto skin
 #Black. 
  *set skincolor "black"
  *goto skin

*label skintexture1
And your ${skincolor} skin...
*fake_choice
 #Has freckles all over.
  *set skintexture1 "freckles"
  *goto skin
 #Has moles.
  *set skintexture1 "moles"
  *goto skin
 #With vitiligo.
  *set skintexture1 "vitiligo"
  *goto skin
 #with dimples in my face.
  *set skintexture1 "dimples"
  *goto skin
 #Is scarred.
  *fake_choice
   #My face has acne scars.
    *set skintexture1 "acne scars"
    *goto skin
   #Has burn scars.
    *set skintexture1 "burn scars"
    *goto skin
   #I have self harm scars.
    *set skintexture1 "selfharm scars"
    *goto skin
 #Is perfect otherwise.
  *set skintexture1 "perfect skin"
  *set skin 2
  *goto skin

*label skintexture2
Besides ${skintexture1} your skin also has...
*fake_choice
 *disable_reuse *selectable_if (skintexture1 != "freckles") #Freckles.
  *set skintexture2 "freckles"
  *goto skin
 *disable_reuse *selectable_if (skintexture1 != "moles") #Moles.
  *set skintexture2 "moles"
  *goto skin
 *disable_reuse *selectable_if (skintexture1 != "vitilligo") #Vitilligo.
  *set skintexture2 "vitilligo"
  *goto skin
 *disable_reuse *selectable_if (skintexture1 != "dimples") #Dimples.
  *set skintexture2 "dimples"
  *goto skin
 #Scars.
  *fake_choice
   *disable_reuse *selectable_if (skintexture1 != "acne scars") #Acne scars.
    *set skintexture2 "acne scars"
    *goto skin
   *disable_reuse *selectable_if (skintexture1 != "burn scars") #Burn scars.
    *set skintexture2 "burn scars"
    *goto skin
   *disable_reuse *selectable_if (skintexture1 != "selfharm scars") #Selfharm Scars.
    *set skintexture2 "selfharm scars"
    *goto skin
 #Pretty sure ${skintexture1} is all to it!
  *set skintexture2 "false"
  *goto skin

*label eyecolor
How about your eyes again?
*fake_choice
 #Black.
  *set eyecolor "black"
  *goto eyes
 #Grey.
  *set eyecolor "grey"
  *goto eyes
 #White.
  *set eyecolor "white"
  *goto eyes
 #Dark brown.
  *set eyecolor "dark brown"
  *goto eyes
 #Brown.
  *set eyecolor "brown"
  *goto eyes
 #Light brown.
  *set eyecolor "light brown"
  *goto eyes
 #Hazel.
  *set eyecolor "hazel"
  *goto eyes
 #Golden.
  *set eyecolor "golden"
  *goto eyes
 #Dark green.
  *set eyecolor "dark green"
  *goto eyes
 #Green.
  *set eyecolor "green"
  *goto eyes
 #Light green.
  *set eyecolor "light green"
  *goto eyes
 #Dark blue.
  *set eyecolor "dark blue"
  *goto eyes
 #Blue.
  *set eyecolor "blue"
  *goto eyes
 #Light blue.
  *set eyecolor "light blue"
*label glasses
Are your ${eyecolor} eyes framed by glasses?
*fake_choice
 #Yes.
  *set glasses "true"
  I see, but you don't then. Thank you.
  *goto eyes
 #No. I can see just fine.
  *set glasses "false"
  You see, thank you.
  *goto eyes

*label preset
*choice
 #Show me Cain.
  *goto Cain
 #Show me Saul.
  *goto Saul
 #Show me Hagar.
  *goto Hagar
 #Show me Rahab.
  *goto Rahab
 #Show me Haman.
  *goto Haman
 #Return.
  Okay, rude? All this extra work for nothing?
  *goto base

*label Haman
Haman uses he/him pronouns. He was burn male and identifies as a man.
*line_break
Haman is small, he has green eyes; shoulder length, straight, orange hair with an undercut. His skin is ivory.

Haman has acne scars and selfharm scars.

*choice
 #I can see myself as Haman.
  *set name "Haman"
  *set plural "false"
  *set nickname "no"
  *set trans "cis"
  *set height "small"
  *set hairlength "shoulder length"
  *set hairtexture "straight"
  *set hairstyle "undercut"
  *set haircolor "orange"
  *set skincolor "ivory"
  *set skintexture1 "acne scars"
  *set skintexture2 "selfharm scars"
  *set eyecolor "green"
  *set glasses "false"
  *set headcover "no"
  *set warnings true
  *goto TKS2
 #The only thing I see here is a stranger.
  *goto preset

*label Rahab
Rahab uses she/her pronouns. She was born female and identifies as a woman.
*line_break
Her height is below average, she has dark blue eyes; long, curly, white dreadlocks. She has an umber skintone.
*line_break
Rahab has moles.

She wears glasses.
*choice
 #I have never felt this seen.
  *set name "Rahab"
  *set plural "false"
  *set nickname "no"
  *set trans "cis"
  *set height "below average"
  *set hairlength "long"
  *set hairtexture "curly"
  *set hairstyle "dreadlocks"
  *set haircolor "white"
  *set skincolor "umber"
  *set skintexture1 "moles"
  *set eyecolor "dark blue"
  *set glasses "true"
  *set headcover "no"
  *set warnings true
  *goto TKS2
 #I don't think that is me.
  *goto preset

*label Hagar
Hagar uses she/her pronouns. She was born male, and identifies as a woman.
*line_break
She is tall, with hazel eyes; loosely wavy, chin length, light brown hair, that she wears open. Her skin is sienna toned.
*line_break
Hagar has acne scars and dimples.

She wears a headscarf.
*choice
 #I can vibe with this.
  *set name "Hagar"
  *set plural "false"
  *set nickname "no"
  *set trans "trans"
  *set height "tall"
  *set hairlength "chin length"
  *set hairtexture "loose waves"
  *set hairstyle "natural"
  *set haircolor "light brown"
  *set skincolor "sienna"
  *set skintexture1 "acne scars"
  *set skintexture2 "dimples"
  *set eyecolor "hazel"
  *set glasses "false"
  *set headcover "headscarf"
  *set warnings true
  *goto TKS2
 #Couldn't be me.
  *goto preset

*label Saul
Saul uses he/him pronouns. He was born female, and identifies as a man.
*line_break
He is of average height, with black eyes; wavy, black hair, pulled into pigtails that barely touch his shoulder. He has a sepia skintone.
*line_break
Saul has vitiligo and moles. 

He wears glasses.
*choice
 #Sounds about right.
  *set name "Saul"
  *set plural "false"
  *set nickname "no"
  *set trans "trans"
  *set height "average"
  *set hairlength "shoulder length"
  *set hairtexture "waves"
  *set hairstyle "pigtails"
  *set haircolor "black"
  *set skincolor "sepia"
  *set skintexture1 "vitiligo"
  *set skintexture2 "moles"
  *set eyecolor "black"
  *set glasses "true"
  *set warnings "true"
  *set headcover "no"
  *goto TKS2
 #Who is this person? Not me.
  *goto preset

*label Cain
Cain uses they/them pronouns. They are intersex, and they identify as nonbinary.
*line_break
They are tall, with brown eyes; straight, brown, long, braided hair and tan skin.
*line_break
Cain has burn and selfharm scars.

*choice
 #Sounds like me.
  *set name "Cain"
  *set nickname "no"
  *set trans "trans"
  *set height "tall"
  *set hairlength "long"
  *set hairtexture "straight"
  *set hairstyle "braided"
  *set haircolor "brown"
  *set skincolor "tan"
  *set skintexture1 "burnscars"
  *set skintexture2 "selfharm"
  *set eyecolor "brown"
  *set glasses "false"
  *set warnings "true"
  *set headcover "no"
  *goto TKS2
 #Couldn't be further from me.
  *goto preset

*label TKS2
There are 7 Love Interests, 2 of which identify as male, 3 of them identify as female, and the other 2 are gender selectable, meaning you get to choose their genders.
*choice
 #I want them both to be female.
  *set S "Samira"
  *set Sthey "she"
  *set Sthem "her"
  *set Stheir "her"
  *set Stheirs "hers"
  *set Sthemself "herself"
  *set Sman "woman"
  *set TK "Takischa"
  *set TKthey "she"
  *set TKthem "her"
  *set TKtheir "her"
  *set TKtheirs "hers"
  *set TKthemself "herself"
  *set TKman "woman"
  *goto skip
 #I want them both to be male.
  *set TK "Tarek"
  *set S "Samuel"
  *goto skip
 #I want Sammy to be female, and TK to be male.
  *set TK "Tarek"
  *set S "Samira"
  *set Sthey "she"
  *set Sthem "her"
  *set Stheir "her"
  *set Stheirs "hers"
  *set Sthemself "herself"
  *set Sman "woman"
  *goto skip
 #I want Sammy to be male, and TK to be female.
  *set TK "Takischa"
  *set TKthey "she"
  *set TKthem "her"
  *set TKtheir "her"
  *set TKtheirs "hers"
  *set TKthemself "herself"
  *set TKman "woman"
  *set S "Samuel"
  *goto skip

*label skip
*temp chapter 0
Would you like to skip to a different part of the story?
*choice
 #No, just get me started on the beginning.
  *goto prologue
 #Skip to chapter 1.
  *goto_scene chapter01
 #Skip to chapter 2.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set time "Esma, 22nd of Awal, Season Dajan, Koi"
  *goto_scene chapter02
 #Skip to chapter 3.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set time "Esma, 22nd of Awal, Season Dajan, Koi"
  *set knowsfamine 1
  *goto_scene chapter03
 #Skip to chapter 4.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set time "Bine, 5th of Lota, Season Dajan, Koi"
  *set knowsfamine 1
  *goto_scene chapter04
 #Skip to Chapter 5.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set time "Esma, 7th of Lota, Season Dajan, Koi"
  *set knowsfamine 1
  *goto_scene chapter05
 #Skip to chapter 6.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set dogs false
  *set knowsMikhail "true"
  *set time "Kumi, 8th of Lota, Season Dajan, Koi"
  *set knowsfamine 1
  *goto_scene chapter06
 #Skip to chapter 7.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set dogs false
  *set knowsMikhail "true"
  *set time "Kumi, 18th of Lota, Season Dajan, Sow"
  *set knowsfamine 1
  *goto_scene chapter07
 #Skip to chapter 8.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set dogs false
  *set knowsMikhail "true"
  *set time "Kumi, 8th of Tap, Season Poligat, Maggot"
  *set knowsfamine 1
  *set execution false
  *goto_scene chapter08
 #Skip to Chapter 9.
  *set knowsTK "true"
  *set knowsS "true"
  *set team "true"
  *set knowsAlia "true"
  *set knowsSascha "true"
  *set knowskate "true"
  *set dogs false
  *set knowsMikhail "true"
  *set time "Kumi, 8th of Tap, Season Poligat, Maggot"
  *set knowsfamine 1
  *set execution false
  *set knowsGigi "true"
  *set chapter 9
  *goto weaponcheck


*label weaponcheck
Before we can start please select a weapon:

*fake_choice
 #The Bow.
  *set weapon "bow"
 #The Dagger.
  *set weapon "dagger"
 #The Warpick.
  *set weapon "war pick"

Thank you, have fun.
*if (chapter = 9)
 *page_break
 *goto_scene chapter09


  
*label prologue
*set team "false"
[i][b]Prologue[/i][/b]

[b][i]Somewhere, sometime ago...[/b][/i]
*line_break
You watch the girl you have known for your entire life, her ash-blond hair falls just below her shoulders, she is sitting with her back to you, a string of a golden ribbon tied neatly at the back of her head, holding a mask in place that you can't see, but you don't need to, you know the white expressionless mask they made her wear since she was little. 
*line_break

Gently she calls out your name, turning her head around to meet your eyes, her eyes are a light brown, in the sun and fire they look golden, at night they are a dusky pale brown tone. 
*line_break
“I didn’t recognize you.” It is not an accusation, but it feels like one nonetheless. She follows you with her eyes as you walk around her, eventually, your knees landing before her feet.
*line_break
“You’ve done it.” She calls out.

“I am so sorry.” You tell her. 

Not that it matters.
*page_break
“Oh no, don’t be.” She cradles your face with her hands and holds it in place, so you two cannot break eye contact.
“You don’t have to do this.” Your offer is weak.
*line_break
She hums and you hold her hands in place with yours. “You did what you had to do, and so will I. We both have our fates that we must follow.” She answers.
*line_break
A grin appears on your face, “We could run away together.” Her eyes have this sparkle as you say this, she wants to, she should, she could. But she can’t.
*line_break

“Will you watch me?” Her rejection is gentle and soft.

“I will try to.”

You promise.
*page_break
The flames are kissing the sky. The beyond melting with the here and now, you are in awe of the Gods coming down, the stars touching the ground, and the moon engulfed in flames. You aren't even close to her, yet you can hear the others sing the song, a deep background noise, humming, the Gods must be pleased.

You can’t see her, but you can hear her screams, rippling through the night, animals searching for shelter, she is screaming your name out. You wish you could save her.

It is too late.
*page_break

The sacrifice withdrew her consent.

The Gods- no, they aren’t Gods anymore- consumed by anger and agony.

And it is your fault.

It is all your fault.
*finish